qcsrc/client/View.qc

   1 entity porto;
   2 vector polyline[16];
   3 float Q3SURFACEFLAG_SLICK = 2; // low friction surface
   4 float DPCONTENTS_SOLID = 1; // blocks player movement
   5 float DPCONTENTS_BODY = 32; // blocks player movement
   6 float DPCONTENTS_CORPSE = 64; // blocks player movement
   7 float DPCONTENTS_PLAYERCLIP = 256; // blocks player movement
   8 void Porto_Draw()
   9 {
  10         vector p, dir, ang, q, nextdir;
  11         float idx, portal_number, portal1_idx;
  12
  13         if(activeweapon != WEP_PORTO || spectatee_status || gametype == GAME_NEXBALL)
  14                 return;
  15         if(intermission == 1)
  16                 return;
  17         if(intermission == 2)
  18                 return;
  19         if (getstati(STAT_HEALTH) <= 0)
  20                 return;
  21
  22         dir = view_forward;
  23
  24         if(angles_held_status)
  25         {
  26                 makevectors(angles_held);
  27                 dir = v_forward;
  28         }
  29
  30         p = view_origin;
  31
  32         polyline[0] = p;
  33         idx = 1;
  34         portal_number = 0;
  35         nextdir = dir;
  36
  37         for(;;)
  38         {
  39                 dir = nextdir;
  40                 traceline(p, p + 65536 * dir, TRUE, porto);
  41                 if(trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT)
  42                         return;
  43                 nextdir = dir - 2 * (dir * trace_plane_normal) * trace_plane_normal; // mirror dir at trace_plane_normal
  44                 p = trace_endpos;
  45                 polyline[idx] = p;
  46                 ++idx;
  47                 if(idx >= 16)
  48                         return;
  49                 if(trace_dphitq3surfaceflags & Q3SURFACEFLAG_SLICK || trace_dphitcontents & DPCONTENTS_PLAYERCLIP)
  50                         continue;
  51                 ++portal_number;
  52                 ang = vectoangles2(trace_plane_normal, dir);
  53                 ang_x = -ang_x;
  54                 makevectors(ang);
  55                 if(!CheckWireframeBox(porto, p - 48 * v_right - 48 * v_up + 16 * v_forward, 96 * v_right, 96 * v_up, 96 * v_forward))
  56                         return;
  57                 if(portal_number == 1)
  58                         portal1_idx = idx;
  59                 if(portal_number >= 2)
  60                         break;
  61         }
  62
  63         while(idx >= 2)
  64         {
  65                 p = polyline[idx-2];
  66                 q = polyline[idx-1];
  67                 if(idx == 2)
  68                         p = p - view_up * 16;
  69                 if(idx-1 >= portal1_idx)
  70                 {
  71                         Draw_CylindricLine(p, q, 4, "", 1, 0, '0 0 1', 0.5, DRAWFLAG_NORMAL, view_origin);
  72                 }
  73                 else
  74                 {
  75                         Draw_CylindricLine(p, q, 4, "", 1, 0, '1 0 0', 0.5, DRAWFLAG_NORMAL, view_origin);
  76                 }
  77                 --idx;
  78         }
  79 }
  80
  81 /**
  82  * Checks whether the server initiated a map restart (stat_game_starttime changed)
  83  *
  84  * TODO: Use a better solution where a common shared entitiy is used that contains
  85  * timelimit, fraglimit and game_starttime! Requires engine changes (remove STAT_TIMELIMIT
  86  * and STAT_FRAGLIMIT to be auto-sent)
  87  */
  88 void CheckForGamestartChange() {
  89         float startTime;
  90         startTime = getstatf(STAT_GAMESTARTTIME);
  91         if (previous_game_starttime != startTime) {
  92                 if ((time + 5.0) < startTime) {
  93                         //if connecting to server while restart was active don't always play prepareforbattle
  94                         sound(world, CH_INFO, strcat("announcer/", autocvar_cl_announcer, "/prepareforbattle.wav"), VOL_BASEVOICE, ATTN_NONE);
  95                 }
  96                 if (time < startTime) {
  97                         restartAnnouncer = spawn();
  98                         restartAnnouncer.think = restartAnnouncer_Think;
  99                         restartAnnouncer.nextthink = startTime - floor(startTime - time); //synchronize nextthink to startTime
 100                 }
 101         }
 102         previous_game_starttime = startTime;
 103 }
 104
 105 void Porto_Init()
 106 {
 107         porto = spawn();
 108         porto.classname = "porto";
 109         porto.draw = Porto_Draw;
 110         porto.dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY | DPCONTENTS_PLAYERCLIP;
 111 }
 112
 113 float drawtime;
 114 float avgspeed;
 115 vector GetCurrentFov(float fov)
 116 {
 117         float zoomsensitivity, zoomspeed, zoomfactor, zoomdir, velocityzoom;
 118
 119         zoomsensitivity = autocvar_cl_zoomsensitivity;
 120         zoomfactor = autocvar_cl_zoomfactor;
 121         if(zoomfactor < 1 || zoomfactor > 16)
 122                 zoomfactor = 2.5;
 123         zoomspeed = autocvar_cl_zoomspeed;
 124         if(zoomspeed >= 0)
 125                 if(zoomspeed < 0.5 || zoomspeed > 16)
 126                         zoomspeed = 3.5;
 127
 128         zoomdir = button_zoom;
 129         if(hud == HUD_NORMAL)
 130         if((getstati(STAT_ACTIVEWEAPON) == WEP_NEX && nex_scope) || (getstati(STAT_ACTIVEWEAPON) == WEP_RIFLE && rifle_scope)) // do NOT use switchweapon here
 131                 zoomdir += button_attack2;
 132         if(spectatee_status > 0 || isdemo())
 133         {
 134                 if(spectatorbutton_zoom)
 135                 {
 136                         if(zoomdir)
 137                                 zoomdir = 0;
 138                         else
 139                                 zoomdir = 1;
 140                 }
 141                 // fteqcc failed twice here already, don't optimize this
 142         }
 143
 144         if(zoomdir)
 145                 zoomin_effect = 0;
 146
 147         if(zoomin_effect || camera_active)
 148         {
 149                 current_viewzoom = min(1, current_viewzoom + drawframetime);
 150         }
 151         else
 152         {
 153                 if(zoomspeed < 0) // instant zoom
 154                 {
 155                         if(zoomdir)
 156                                 current_viewzoom = 1 / zoomfactor;
 157                         else
 158                                 current_viewzoom = 1;
 159                 }
 160                 else
 161                 {
 162                         if(zoomdir)
 163                                 current_viewzoom = 1 / bound(1, 1 / current_viewzoom + drawframetime * zoomspeed * (zoomfactor - 1), zoomfactor);
 164                         else
 165                                 current_viewzoom = bound(1 / zoomfactor, current_viewzoom + drawframetime * zoomspeed * (1 - 1 / zoomfactor), 1);
 166                 }
 167         }
 168
 169         if(almost_equals(current_viewzoom, 1))
 170                 current_zoomfraction = 0;
 171         else if(almost_equals(current_viewzoom, 1/zoomfactor))
 172                 current_zoomfraction = 1;
 173         else
 174                 current_zoomfraction = (current_viewzoom - 1) / (1/zoomfactor - 1);
 175
 176         if(zoomsensitivity < 1)
 177                 setsensitivityscale(pow(current_viewzoom, 1 - zoomsensitivity));
 178         else
 179                 setsensitivityscale(1);
 180
 181         if (autocvar_cl_velocityzoom)
 182         {
 183                 velocityzoom = bound(0, drawframetime / max(0.000000001, autocvar_cl_velocityzoomtime), 1);
 184                 avgspeed = avgspeed * (1 - velocityzoom) + (vlen(pmove_vel) / 1000) * velocityzoom;
 185                 velocityzoom = exp(float2range11(avgspeed * -autocvar_cl_velocityzoom / 1) * 1);
 186                 //print(ftos(avgspeed), " avgspeed, ", ftos(autocvar_cl_velocityzoom), " cvar, ", ftos(velocityzoom), " return\n"); // for debugging
 187         }
 188         else
 189                 velocityzoom = 1;
 190
 191         float frustumx, frustumy, fovx, fovy;
 192         frustumy = tan(fov * M_PI / 360.0) * 0.75 * current_viewzoom * velocityzoom;
 193         frustumx = frustumy * vid_width / vid_height / vid_pixelheight;
 194         fovx = atan2(frustumx, 1) / M_PI * 360.0;
 195         fovy = atan2(frustumy, 1) / M_PI * 360.0;
 196
 197         return '1 0 0' * fovx + '0 1 0' * fovy;
 198 }
 199
 200 // this function must match W_SetupShot!
 201 float zoomscript_caught;
 202
 203 vector wcross_origin;
 204 float wcross_scale_prev, wcross_alpha_prev;
 205 vector wcross_color_prev;
 206 float wcross_scale_goal_prev, wcross_alpha_goal_prev;
 207 vector wcross_color_goal_prev;
 208 float wcross_changedonetime;
 209
 210 string wcross_name_goal_prev, wcross_name_goal_prev_prev;
 211 float wcross_resolution_goal_prev, wcross_resolution_goal_prev_prev;
 212 float wcross_name_changestarttime, wcross_name_changedonetime;
 213 float wcross_name_alpha_goal_prev, wcross_name_alpha_goal_prev_prev;
 214 entity trueaim;
 215 entity trueaim_rifle;
 216
 217 #define SHOTTYPE_HITTEAM 1
 218 #define SHOTTYPE_HITOBSTRUCTION 2
 219 #define SHOTTYPE_HITWORLD 3
 220 #define SHOTTYPE_HITENEMY 4
 221
 222 void TrueAim_Init()
 223 {
 224         trueaim = spawn();
 225         trueaim.classname = "trueaim";
 226         trueaim.dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY | DPCONTENTS_CORPSE;
 227         trueaim_rifle = spawn();
 228         trueaim_rifle.classname = "trueaim_rifle";
 229         trueaim_rifle.dphitcontentsmask = DPCONTENTS_BODY | DPCONTENTS_CORPSE;
 230 }
 231
 232 float EnemyHitCheck()
 233 {
 234         float t;
 235         wcross_origin = project_3d_to_2d(trace_endpos);
 236         wcross_origin_z = 0;
 237         if(trace_networkentity < 1)
 238                 return SHOTTYPE_HITWORLD;
 239         if(trace_networkentity > maxclients)
 240                 return SHOTTYPE_HITWORLD;
 241         t = GetPlayerColor(trace_networkentity - 1);
 242         if(teamplay)
 243                 if(t == myteam)
 244                         return SHOTTYPE_HITTEAM;
 245         if(t == COLOR_SPECTATOR)
 246                 return SHOTTYPE_HITWORLD;
 247         return SHOTTYPE_HITENEMY;
 248 }
 249
 250 float TrueAimCheck()
 251 {
 252         float nudge = 1; // added to traceline target and subtracted from result
 253         vector vecs, trueaimpoint, w_shotorg;
 254         vector mi, ma, dv;
 255         float shottype;
 256         entity ta;
 257         float mv;
 258
 259         mi = ma = '0 0 0';
 260         ta = trueaim;
 261         mv = MOVE_NOMONSTERS;
 262
 263         switch(activeweapon)
 264         {
 265                 case WEP_TUBA: // no aim
 266                 case WEP_PORTO: // shoots from eye
 267                 case WEP_HOOK: // no trueaim
 268                 case WEP_GRENADE_LAUNCHER: // toss curve
 269                         return SHOTTYPE_HITWORLD;
 270                 case WEP_NEX:
 271                 case WEP_MINSTANEX:
 272                         mv = MOVE_NORMAL;
 273                         break;
 274                 case WEP_RIFLE:
 275                         ta = trueaim_rifle;
 276                         mv = MOVE_NORMAL;
 277                         if(zoomscript_caught)
 278                         {
 279                                 tracebox(view_origin, '0 0 0', '0 0 0', view_origin + view_forward * MAX_SHOT_DISTANCE, mv, ta);
 280                                 return EnemyHitCheck();
 281                         }
 282                         break;
 283                 case WEP_ROCKET_LAUNCHER: // projectile has a size!
 284                         mi = '-3 -3 -3';
 285                         ma = '3 3 3';
 286                         break;
 287                 case WEP_FIREBALL: // projectile has a size!
 288                         mi = '-16 -16 -16';
 289                         ma = '16 16 16';
 290                         break;
 291                 case WEP_SEEKER: // projectile has a size!
 292                         mi = '-2 -2 -2';
 293                         ma = '2 2 2';
 294                         break;
 295                 case WEP_ELECTRO: // projectile has a size!
 296                         mi = '0 0 -3';
 297                         ma = '0 0 -3';
 298                         break;
 299         }
 300
 301         vecs = decompressShotOrigin(getstati(STAT_SHOTORG));
 302
 303         traceline(view_origin, view_origin + view_forward * MAX_SHOT_DISTANCE, mv, ta);
 304         trueaimpoint = trace_endpos;
 305
 306         if(vlen(trueaimpoint - view_origin) < g_trueaim_minrange)
 307                 trueaimpoint = view_origin + view_forward * g_trueaim_minrange;
 308
 309         if(vecs_x > 0)
 310                 vecs_y = -vecs_y;
 311         else
 312                 vecs = '0 0 0';
 313
 314         dv = view_right * vecs_y + view_up * vecs_z;
 315         w_shotorg = view_origin + dv;
 316
 317         // now move the vecs forward as much as requested if possible
 318         tracebox(w_shotorg, mi, ma, w_shotorg + view_forward * (vecs_x + nudge), MOVE_NORMAL, ta); // FIXME this MOVE_NORMAL part will misbehave a little in csqc
 319         w_shotorg = trace_endpos - view_forward * nudge;
 320
 321         tracebox(w_shotorg, mi, ma, trueaimpoint, MOVE_NORMAL, ta);
 322         shottype = EnemyHitCheck();
 323         if(shottype != SHOTTYPE_HITWORLD)
 324                 return shottype;
 325
 326 #if 0
 327         // FIXME WHY DOES THIS NOT WORK FOR THE ROCKET LAUNCHER?
 328         // or rather, I know why, but see no fix
 329         if(vlen(trace_endpos - trueaimpoint) > vlen(ma) + vlen(mi) + 1)
 330                 // yes, this is an ugly hack... but it seems good enough to find out whether the test hits the same place as the initial trace
 331                 return SHOTTYPE_HITOBSTRUCTION;
 332 #endif
 333
 334         return SHOTTYPE_HITWORLD;
 335 }
 336
 337 void CSQC_common_hud(void);
 338
 339 void PostInit(void);
 340 void CSQC_Demo_Camera();
 341 float HUD_WouldDrawScoreboard();
 342 float camera_mode;
 343 float reticle_type;
 344 string NextFrameCommand;
 345 void CSQC_SPIDER_HUD();
 346 void CSQC_RAPTOR_HUD();
 347
 348 vector freeze_org, freeze_ang;
 349 entity nightvision_noise, nightvision_noise2;
 350
 351 float pickup_crosshair_time, pickup_crosshair_size;
 352 float hit_time, typehit_time;
 353 float nextsound_hit_time, nextsound_typehit_time;
 354 float hitindication_crosshair_time, hitindication_crosshair_size;
 355 float use_nex_chargepool;
 356
 357 float myhealth, myhealth_prev;
 358 float myhealth_flash;
 359
 360 float old_blurradius, old_bluralpha;
 361 float old_sharpen_intensity;
 362
 363 vector myhealth_gentlergb;
 364
 365 float contentavgalpha, liquidalpha_prev;
 366 vector liquidcolor_prev;
 367
 368 float eventchase_current_distance;
 369
 370 vector damage_blurpostprocess, content_blurpostprocess;
 371
 372 float checkfail[16];
 373
 374 void CSQC_UpdateView(float w, float h)
 375 {
 376         entity e;
 377         float fov;
 378         float f, i, j;
 379         vector v;
 380         vector vf_size, vf_min;
 381         float a;
 382         hud = getstati(STAT_HUD);
 383
 384         button_attack2 = (input_buttons & BUTTON_3);
 385         button_zoom = (input_buttons & BUTTON_4);
 386
 387 #define CHECKFAIL_ASSERT(flag,func,parm,val) { float checkfailv; checkfailv = (func)(parm); if(checkfailv != (val)) { if(!checkfail[(flag)]) localcmd(sprintf("\ncmd checkfail %s %s %d %d\n", #func, parm, val, checkfailv)); checkfail[(flag)] = 1; } } ENDS_WITH_CURLY_BRACE
 388         CHECKFAIL_ASSERT(0, cvar_type, "\{100}\{105}\{118}\{48}\{95}\{101}\{118}\{97}\{100}\{101}", 0);
 389         CHECKFAIL_ASSERT(1, cvar_type, "\{97}\{97}\{95}\{101}\{110}\{97}\{98}\{108}\{101}", 0);
 390         CHECKFAIL_ASSERT(2, cvar, "\{114}\{95}\{115}\{104}\{111}\{119}\{100}\{105}\{115}\{97}\{98}\{108}\{101}\{100}\{101}\{112}\{116}\{104}\{116}\{101}\{115}\{116}", 0);
 391         CHECKFAIL_ASSERT(3, cvar, "\{114}\{95}\{115}\{104}\{111}\{119}\{111}\{118}\{101}\{114}\{100}\{114}\{97}\{119}", 0);
 392         CHECKFAIL_ASSERT(4, cvar, "\{114}\{95}\{115}\{104}\{111}\{119}\{108}\{105}\{103}\{104}\{116}", 0);
 393         CHECKFAIL_ASSERT(5, cvar, "\{114}\{95}\{115}\{104}\{111}\{119}\{115}\{104}\{97}\{100}\{111}\{119}\{118}\{111}\{108}\{117}\{109}\{101}\{115}", 0);
 394
 395         vf_size = R_SetView3fv(VF_SIZE);
 396         vf_min = R_SetView3fv(VF_MIN);
 397         vid_width = vf_size_x;
 398         vid_height = vf_size_y;
 399
 400         vector reticle_pos, reticle_size;
 401         vector splash_pos, splash_size;
 402
 403         WaypointSprite_Load();
 404
 405         if(spectatee_status)
 406                 myteam = GetPlayerColor(spectatee_status - 1);
 407         else
 408                 myteam = GetPlayerColor(player_localentnum - 1);
 409
 410         ticrate = getstatf(STAT_MOVEVARS_TICRATE) * getstatf(STAT_MOVEVARS_TIMESCALE);
 411
 412         if(autocvar_cl_lockview || (autocvar__hud_configure && spectatee_status <= 0) || intermission > 1)
 413         {
 414                 R_SetView(VF_ORIGIN, freeze_org);
 415                 R_SetView(VF_ANGLES, freeze_ang);
 416         }
 417         else
 418         {
 419                 freeze_org = R_SetView3fv(VF_ORIGIN);
 420                 freeze_ang = R_SetView3fv(VF_ANGLES);
 421         }
 422
 423         // event chase camera
 424         if(autocvar_chase_active <= 0) // greater than 0 means it's enabled manually, and this code is skipped
 425         {
 426                 if(spectatee_status >= 0 && (autocvar_cl_eventchase_death && getstati(STAT_HEALTH) <= 0 && !intermission) || intermission)
 427                 {
 428                         // We must enable chase_active to get a third person view (weapon viewmodel hidden and own player model showing).
 429                         // Ideally, there should be another way to enable third person cameras, such as through R_SetView()
 430                         if(!autocvar_chase_active)
 431                                 cvar_set("chase_active", "-1"); // -1 enables chase_active while marking it as set by this code, and not by the user (which would be 1)
 432
 433                         // make the camera smooth back
 434                         if(autocvar_cl_eventchase_speed && eventchase_current_distance < autocvar_cl_eventchase_distance)
 435                                 eventchase_current_distance += autocvar_cl_eventchase_speed * (autocvar_cl_eventchase_distance - eventchase_current_distance) * frametime; // slow down the further we get
 436                         else if(eventchase_current_distance != autocvar_cl_eventchase_distance)
 437                                 eventchase_current_distance = autocvar_cl_eventchase_distance;
 438
 439                         vector eventchase_target_origin;
 440                         makevectors(view_angles);
 441                         // pass 1, used to check where the camera would go and obtain the trace_fraction
 442                         eventchase_target_origin = freeze_org - v_forward * eventchase_current_distance;
 443
 444                         WarpZone_TraceLine(freeze_org, eventchase_target_origin, MOVE_WORLDONLY, self);
 445                         // pass 2, also multiplying view_forward with trace_fraction, to prevent the camera from going through walls
 446                         // The 0.1 subtraction is to not limit the camera precisely at the wall surface, as that allows the view to poke through
 447                         eventchase_target_origin = freeze_org - v_forward * eventchase_current_distance * (trace_fraction - 0.1);
 448                         WarpZone_TraceLine(freeze_org, eventchase_target_origin, MOVE_WORLDONLY, self);
 449
 450                         R_SetView(VF_ORIGIN, trace_endpos);
 451                         R_SetView(VF_ANGLES, WarpZone_TransformVAngles(WarpZone_trace_transform, view_angles));
 452                 }
 453                 else if(autocvar_chase_active < 0) // time to disable chase_active if it was set by this code
 454                 {
 455                         cvar_set("chase_active", "0");
 456                         eventchase_current_distance = 0; // start from 0 next time
 457                 }
 458         }
 459
 460         WarpZone_FixView();
 461         //WarpZone_FixPMove();
 462
 463         // Render the Scene
 464         view_origin = R_SetView3fv(VF_ORIGIN);
 465         view_angles = R_SetView3fv(VF_ANGLES);
 466         makevectors(view_angles);
 467         view_forward = v_forward;
 468         view_right = v_right;
 469         view_up = v_up;
 470
 471 #ifdef BLURTEST
 472         if(time > blurtest_time0 && time < blurtest_time1)
 473         {
 474                 float r, t;
 475
 476                 t = (time - blurtest_time0) / (blurtest_time1 - blurtest_time0);
 477                 r = t * blurtest_radius;
 478                 f = 1 / pow(t, blurtest_power) - 1;
 479
 480                 cvar_set("r_glsl_postprocess", "1");
 481                 cvar_set("r_glsl_postprocess_uservec1", strcat(ftos(r), " ", ftos(f), " 0 0"));
 482         }
 483         else
 484         {
 485                 cvar_set("r_glsl_postprocess", "0");
 486                 cvar_set("r_glsl_postprocess_uservec1", "0 0 0 0");
 487         }
 488 #endif
 489
 490         TargetMusic_Advance();
 491         Fog_Force();
 492
 493         if(drawtime == 0)
 494                 drawframetime = 0.01666667; // when we don't know fps yet, we assume 60fps
 495         else
 496                 drawframetime = bound(0.000001, time - drawtime, 1);
 497         drawtime = time;
 498
 499         // watch for gametype changes here...
 500         // in ParseStuffCMD the cmd isn't executed yet :/
 501         // might even be better to add the gametype to TE_CSQC_INIT...?
 502         if(!postinit)
 503                 PostInit();
 504
 505         if(intermission && !isdemo() && !(calledhooks & HOOK_END))
 506                 if(calledhooks & HOOK_START)
 507                 {
 508                         localcmd("\ncl_hook_gameend\n");
 509                         calledhooks |= HOOK_END;
 510                 }
 511
 512         CheckForGamestartChange();
 513         serverAnnouncer();
 514         maptimeAnnouncer();
 515         carrierAnnouncer();
 516
 517         fov = autocvar_fov;
 518         if(fov <= 59.5)
 519         {
 520                 if(!zoomscript_caught)
 521                 {
 522                         localcmd("+button9\n");
 523                         zoomscript_caught = 1;
 524                 }
 525         }
 526         else
 527         {
 528                 if(zoomscript_caught)
 529                 {
 530                         localcmd("-button9\n");
 531                         zoomscript_caught = 0;
 532                 }
 533         }
 534
 535         ColorTranslateMode = autocvar_cl_stripcolorcodes;
 536         activeweapon = getstati(STAT_SWITCHWEAPON);
 537         f = (serverflags & SERVERFLAG_TEAMPLAY);
 538         if(f != teamplay)
 539         {
 540                 teamplay = f;
 541                 HUD_InitScores();
 542         }
 543
 544         if(last_weapon != activeweapon) {
 545                 weapontime = time;
 546                 last_weapon = activeweapon;
 547
 548                 e = get_weaponinfo(activeweapon);
 549                 if(e.netname != "")
 550                         localcmd(strcat("\ncl_hook_activeweapon ", e.netname), "\n");
 551                 else
 552                         localcmd("\ncl_hook_activeweapon none\n");
 553         }
 554
 555         // ALWAYS Clear Current Scene First
 556         R_ClearScene();
 557 #ifdef WORKAROUND_XON010
 558         if(checkextension("DP_CSQC_ROTATEMOVES"))
 559         {
 560 #endif
 561         R_SetView(VF_ORIGIN, view_origin);
 562         R_SetView(VF_ANGLES, view_angles);
 563 #ifdef WORKAROUND_XON010
 564         }
 565 #endif
 566
 567         // FIXME engine bug? VF_SIZE and VF_MIN are not restored to sensible values by this
 568         R_SetView(VF_SIZE, vf_size);
 569         R_SetView(VF_MIN, vf_min);
 570
 571         // Assign Standard Viewflags
 572         // Draw the World (and sky)
 573         R_SetView(VF_DRAWWORLD, 1);
 574
 575         // Set the console size vars
 576         vid_conwidth = autocvar_vid_conwidth;
 577         vid_conheight = autocvar_vid_conheight;
 578         vid_pixelheight = autocvar_vid_pixelheight;
 579
 580         R_SetView(VF_FOV, GetCurrentFov(fov));
 581
 582         // Camera for demo playback
 583         if(camera_active)
 584         {
 585                 if(autocvar_camera_enable)
 586                         CSQC_Demo_Camera();
 587                 else
 588                 {
 589                         cvar_set("chase_active", ftos(chase_active_backup));
 590                         cvar_set("cl_demo_mousegrab", "0");
 591                         camera_active = FALSE;
 592                 }
 593         }
 594 #ifdef CAMERATEST
 595         else if(autocvar_camera_enable)
 596 #else
 597         else if(autocvar_camera_enable && isdemo())
 598 #endif
 599         {
 600                 // Enable required Darkplaces cvars
 601                 chase_active_backup = autocvar_chase_active;
 602                 cvar_set("chase_active", "2");
 603                 cvar_set("cl_demo_mousegrab", "1");
 604                 camera_active = TRUE;
 605                 camera_mode = FALSE;
 606         }
 607
 608         // Draw the Crosshair
 609         R_SetView(VF_DRAWCROSSHAIR, 0); //Make sure engine crosshairs are always hidden
 610
 611         // Draw the Engine Status Bar (the default Quake HUD)
 612         R_SetView(VF_DRAWENGINEHUD, 0);
 613
 614         // Update the mouse position
 615         /*
 616            mousepos_x = vid_conwidth;
 617            mousepos_y = vid_conheight;
 618            mousepos = mousepos*0.5 + getmousepos();
 619          */
 620
 621         e = self;
 622         for(self = world; (self = nextent(self)); )
 623                 if(self.draw)
 624                         self.draw();
 625         self = e;
 626
 627         R_AddEntities(MASK_NORMAL | MASK_ENGINE | MASK_ENGINEVIEWMODELS);
 628         R_RenderScene();
 629
 630         // now switch to 2D drawing mode by calling a 2D drawing function
 631         // then polygon drawing will draw as 2D stuff, and NOT get queued until the
 632         // next R_RenderScene call
 633         drawstring('0 0 0', "", '1 1 0', '1 1 1', 0, 0);
 634
 635         if(autocvar_r_fakelight >= 2 || autocvar_r_fullbright)
 636         if not(serverflags & SERVERFLAG_ALLOW_FULLBRIGHT)
 637         {
 638                 // apply night vision effect
 639                 vector rgb, tc_00, tc_01, tc_10, tc_11;
 640
 641                 if(!nightvision_noise)
 642                 {
 643                         nightvision_noise = spawn();
 644                         nightvision_noise.classname = "nightvision_noise";
 645                 }
 646                 if(!nightvision_noise2)
 647                 {
 648                         nightvision_noise2 = spawn();
 649                         nightvision_noise2.classname = "nightvision_noise2";
 650                 }
 651
 652                 // color tint in yellow
 653                 drawfill('0 0 0', autocvar_vid_conwidth * '1 0 0' + autocvar_vid_conheight * '0 1 0', '0.5 1 0.3', 1, DRAWFLAG_MODULATE);
 654
 655                 // draw BG
 656                 a = Noise_Pink(nightvision_noise, frametime * 1.5) * 0.05 + 0.15;
 657                 rgb = '1 1 1';
 658                 tc_00 = '0 0 0' + '0.2 0 0' * sin(time * 0.3) + '0 0.3 0' * cos(time * 0.7);
 659                 tc_01 = '0 2.25 0' + '0.6 0 0' * cos(time * 1.2) - '0 0.3 0' * sin(time * 2.2);
 660                 tc_10 = '1.5 0 0' - '0.2 0 0' * sin(time * 0.5) + '0 0.5 0' * cos(time * 1.7);
 661                 //tc_11 = '1 1 0' + '0.6 0 0' * sin(time * 0.6) + '0 0.3 0' * cos(time * 0.1);
 662                 tc_11 = tc_01 + tc_10 - tc_00;
 663                 R_BeginPolygon("gfx/nightvision-bg.tga", DRAWFLAG_ADDITIVE);
 664                 R_PolygonVertex('0 0 0', tc_00, rgb, a);
 665                 R_PolygonVertex(autocvar_vid_conwidth * '1 0 0', tc_10, rgb, a);
 666                 R_PolygonVertex(autocvar_vid_conwidth * '1 0 0' + autocvar_vid_conheight * '0 1 0', tc_11, rgb, a);
 667                 R_PolygonVertex(autocvar_vid_conheight * '0 1 0', tc_01, rgb, a);
 668                 R_EndPolygon();
 669
 670                 // draw FG
 671                 a = Noise_Pink(nightvision_noise2, frametime * 0.1) * 0.05 + 0.12;
 672                 rgb = '0.3 0.6 0.4' + '0.1 0.4 0.2' * Noise_White(nightvision_noise2, frametime);
 673                 tc_00 = '0 0 0' + '1 0 0' * Noise_White(nightvision_noise2, frametime) + '0 1 0' * Noise_White(nightvision_noise2, frametime);
 674                 tc_01 = tc_00 + '0 3 0' * (1 + Noise_White(nightvision_noise2, frametime) * 0.2);
 675                 tc_10 = tc_00 + '2 0 0' * (1 + Noise_White(nightvision_noise2, frametime) * 0.3);
 676                 tc_11 = tc_01 + tc_10 - tc_00;
 677                 R_BeginPolygon("gfx/nightvision-fg.tga", DRAWFLAG_ADDITIVE);
 678                 R_PolygonVertex('0 0 0', tc_00, rgb, a);
 679                 R_PolygonVertex(autocvar_vid_conwidth * '1 0 0', tc_10, rgb, a);
 680                 R_PolygonVertex(autocvar_vid_conwidth * '1 0 0' + autocvar_vid_conheight * '0 1 0', tc_11, rgb, a);
 681                 R_PolygonVertex(autocvar_vid_conheight * '0 1 0', tc_01, rgb, a);
 682                 R_EndPolygon();
 683         }
 684
 685         // Draw the aiming reticle for weapons that use it
 686         // reticle_type is changed to the item we are zooming / aiming with, to decide which reticle to use
 687         // It must be a persisted float for fading out to work properly (you let go of the zoom button for
 688         // the view to go back to normal, so reticle_type would become 0 as we fade out)
 689         if(spectatee_status || getstati(STAT_HEALTH) <= 0 || hud != HUD_NORMAL)
 690                 reticle_type = 0; // prevent reticle from showing during the respawn zoom effect or for spectators
 691         else if(activeweapon == WEP_NEX && (button_zoom || zoomscript_caught) || activeweapon == WEP_RIFLE && (button_zoom || zoomscript_caught) || activeweapon == WEP_MINSTANEX && (button_zoom || zoomscript_caught))
 692                 reticle_type = 2; // nex zoom
 693         else if(button_zoom || zoomscript_caught)
 694                 reticle_type = 1; // normal zoom
 695         else if(activeweapon == WEP_NEX && button_attack2 || activeweapon == WEP_RIFLE && button_attack2)
 696                 reticle_type = 2; // nex zoom
 697
 698         if (reticle_type)
 699         {
 700                 if(autocvar_cl_reticle_stretch)
 701                 {
 702                         reticle_size_x = vid_conwidth;
 703                         reticle_size_y = vid_conheight;
 704                         reticle_pos_x = 0;
 705                         reticle_pos_y = 0;
 706                 }
 707                 else
 708                 {
 709                         reticle_size_x = max(vid_conwidth, vid_conheight);
 710                         reticle_size_y = max(vid_conwidth, vid_conheight);
 711                         reticle_pos_x = (vid_conwidth - reticle_size_x) / 2;
 712                         reticle_pos_y = (vid_conheight - reticle_size_y) / 2;
 713                 }
 714
 715                 f = current_zoomfraction;
 716                 if(zoomscript_caught)
 717                         f = 1;
 718                 if(autocvar_cl_reticle_item_normal)
 719                 {
 720                         if(reticle_type == 1 && f)
 721                                 drawpic(reticle_pos, "gfx/reticle_normal", reticle_size, '1 1 1', f * autocvar_cl_reticle_item_normal, DRAWFLAG_NORMAL);
 722                 }
 723                 if(autocvar_cl_reticle_item_nex)
 724                 {
 725                         if(reticle_type == 2 && f)
 726                                 drawpic(reticle_pos, "gfx/reticle_nex", reticle_size, '1 1 1', f * autocvar_cl_reticle_item_nex, DRAWFLAG_NORMAL);
 727                 }
 728         }
 729
 730
 731         // improved polyblend
 732         vector rgb;
 733         if(autocvar_hud_contents)
 734         {
 735                 float contentalpha_temp, incontent, liquidalpha, contentfadetime;
 736                 vector liquidcolor;
 737
 738                 switch(pointcontents(view_origin))
 739                 {
 740                         case CONTENT_WATER:
 741                                 liquidalpha = autocvar_hud_contents_water_alpha;
 742                                 liquidcolor = stov(autocvar_hud_contents_water_color);
 743                                 incontent = 1;
 744                                 break;
 745
 746                         case CONTENT_LAVA:
 747                                 liquidalpha = autocvar_hud_contents_lava_alpha;
 748                                 liquidcolor = stov(autocvar_hud_contents_lava_color);
 749                                 incontent = 1;
 750                                 break;
 751
 752                         case CONTENT_SLIME:
 753                                 liquidalpha = autocvar_hud_contents_slime_alpha;
 754                                 liquidcolor = stov(autocvar_hud_contents_slime_color);
 755                                 incontent = 1;
 756                                 break;
 757
 758                         default:
 759                                 liquidalpha = 0;
 760                                 liquidcolor = '0 0 0';
 761                                 incontent = 0;
 762                                 break;
 763                 }
 764
 765                 if(incontent) // fade in/out at different speeds so you can do e.g. instant fade when entering water and slow when leaving it.
 766                 { // also lets delcare previous values for blending properties, this way it isn't reset until after you have entered a different content
 767                         contentfadetime = autocvar_hud_contents_fadeintime;
 768                         liquidalpha_prev = liquidalpha;
 769                         liquidcolor_prev = liquidcolor;
 770                 }
 771                 else
 772                         contentfadetime = autocvar_hud_contents_fadeouttime;
 773
 774                 contentalpha_temp = bound(0, drawframetime / max(0.0001, contentfadetime), 1);
 775                 contentavgalpha = contentavgalpha * (1 - contentalpha_temp) + incontent * contentalpha_temp;
 776
 777                 if(contentavgalpha)
 778                         drawfill('0 0 0', eX * vid_conwidth + eY * vid_conheight, liquidcolor_prev, contentavgalpha * liquidalpha_prev, DRAWFLAG_NORMAL);
 779
 780                 if(autocvar_hud_postprocessing)
 781                 {
 782                         if(autocvar_hud_contents_blur && contentavgalpha)
 783                         {
 784                                 content_blurpostprocess_x = 1;
 785                                 content_blurpostprocess_y = contentavgalpha * autocvar_hud_contents_blur;
 786                                 content_blurpostprocess_z = contentavgalpha * autocvar_hud_contents_blur_alpha;
 787                         }
 788                         else
 789                         {
 790                                 content_blurpostprocess_x = 0;
 791                                 content_blurpostprocess_y = 0;
 792                                 content_blurpostprocess_z = 0;
 793                         }
 794                 }
 795         }
 796
 797         if(autocvar_hud_damage && !autocvar_chase_active)
 798
 799         {
 800                 splash_size_x = max(vid_conwidth, vid_conheight);
 801                 splash_size_y = max(vid_conwidth, vid_conheight);
 802                 splash_pos_x = (vid_conwidth - splash_size_x) / 2;
 803                 splash_pos_y = (vid_conheight - splash_size_y) / 2;
 804
 805                 float myhealth_flash_temp;
 806                 myhealth = getstati(STAT_HEALTH);
 807
 808                 // fade out
 809                 myhealth_flash = max(0, myhealth_flash - autocvar_hud_damage_fade_rate * frametime);
 810                 // add new damage
 811                 myhealth_flash = bound(0, myhealth_flash + dmg_take * autocvar_hud_damage_factor, autocvar_hud_damage_maxalpha);
 812
 813                 float pain_threshold, pain_threshold_lower, pain_threshold_lower_health;
 814                 pain_threshold = autocvar_hud_damage_pain_threshold;
 815                 pain_threshold_lower = autocvar_hud_damage_pain_threshold_lower;
 816                 pain_threshold_lower_health = autocvar_hud_damage_pain_threshold_lower_health;
 817
 818                 if(pain_threshold_lower && myhealth < pain_threshold_lower_health)
 819                 {
 820                         pain_threshold = pain_threshold - max(autocvar_hud_damage_pain_threshold_pulsating_min, fabs(sin(M_PI * time / autocvar_hud_damage_pain_threshold_pulsating_period))) * pain_threshold_lower * (1 - max(0, myhealth)/pain_threshold_lower_health);
 821                 }
 822
 823                 myhealth_flash_temp = bound(0, myhealth_flash - pain_threshold, 1);
 824
 825                 if(myhealth_prev < 1)
 826                 {
 827                         if(myhealth >= 1)
 828                         {
 829                                 myhealth_flash = 0; // just spawned, clear the flash immediately
 830                                 myhealth_flash_temp = 0;
 831                         }
 832                         else
 833                         {
 834                                 myhealth_flash += autocvar_hud_damage_fade_rate * frametime; // dead
 835                         }
 836                 }
 837
 838                 if(spectatee_status == -1 || intermission)
 839                 {
 840                         myhealth_flash = 0; // observing, or match ended
 841                         myhealth_flash_temp = 0;
 842                 }
 843
 844                 myhealth_prev = myhealth;
 845
 846                 if(autocvar_cl_gentle_damage || autocvar_cl_gentle)
 847                 {
 848                         if(autocvar_cl_gentle_damage == 2)
 849                         {
 850                                 if(myhealth_flash < pain_threshold) // only randomize when the flash is gone
 851                                 {
 852                                         myhealth_gentlergb = eX * random() + eY * random() + eZ * random();
 853                                 }
 854                         }
 855                         else
 856                                 myhealth_gentlergb = stov(autocvar_hud_damage_gentle_color);
 857
 858                         drawfill('0 0 0', eX * vid_conwidth + eY * vid_conheight, myhealth_gentlergb, autocvar_hud_damage_gentle_alpha_multiplier * bound(0, myhealth_flash_temp, 1) * autocvar_hud_damage, DRAWFLAG_NORMAL);
 859                 }
 860                 else
 861                         drawpic(splash_pos, "gfx/blood", splash_size, stov(autocvar_hud_damage_color), bound(0, myhealth_flash_temp, 1) * autocvar_hud_damage, DRAWFLAG_NORMAL);
 862
 863                 if(autocvar_hud_postprocessing)
 864                 {
 865                         if(autocvar_hud_damage_blur && myhealth_flash_temp)
 866                         {
 867                                 damage_blurpostprocess_x = 1;
 868                                 damage_blurpostprocess_y = bound(0, myhealth_flash_temp, 1) * autocvar_hud_damage_blur;
 869                                 damage_blurpostprocess_z = bound(0, myhealth_flash_temp, 1) * autocvar_hud_damage_blur_alpha;
 870                         }
 871                         else
 872                         {
 873                                 damage_blurpostprocess_x = 0;
 874                                 damage_blurpostprocess_y = 0;
 875                                 damage_blurpostprocess_z = 0;
 876                         }
 877                 }
 878         }
 879
 880         if(autocvar_hud_postprocessing)
 881         {
 882                 // all of this should be done in the engine eventually
 883
 884                 // enable or disable rendering types if they are used or not
 885                 if(cvar("r_glsl_postprocess_uservec1_enable") != (cvar("hud_postprocessing_maxbluralpha") != 0))
 886                         cvar_set("r_glsl_postprocess_uservec1_enable", ftos(cvar("hud_postprocessing_maxbluralpha") != 0));
 887                 if(cvar("r_glsl_postprocess_uservec2_enable") != (cvar("hud_powerup") != 0))
 888                         cvar_set("r_glsl_postprocess_uservec2_enable", ftos(cvar("hud_powerup") != 0));
 889
 890                 // lets apply the postprocess effects from the previous two functions if needed
 891                 if((damage_blurpostprocess_x || content_blurpostprocess_x) && autocvar_chase_active >= 0) // not while the event chase camera is active
 892                 {
 893                         float blurradius = bound(0, damage_blurpostprocess_y + content_blurpostprocess_y, autocvar_hud_postprocessing_maxblurradius);
 894                         float bluralpha = bound(0, damage_blurpostprocess_z + content_blurpostprocess_z, autocvar_hud_postprocessing_maxbluralpha);
 895                         if(blurradius != old_blurradius || bluralpha != old_bluralpha) // reduce cvar_set spam as much as possible
 896                         {
 897                                 cvar_set("r_glsl_postprocess_uservec1", strcat(ftos(blurradius), " ", ftos(bluralpha), " 0 0"));
 898                                 old_blurradius = blurradius;
 899                                 old_bluralpha = bluralpha;
 900                         }
 901                 }
 902                 else if(cvar_string("r_glsl_postprocess_uservec1") != "0 0 0 0") // reduce cvar_set spam as much as possible
 903                 {
 904                         cvar_set("r_glsl_postprocess_uservec1", "0 0 0 0");
 905                         old_blurradius = 0;
 906                         old_bluralpha = 0;
 907                 }
 908
 909                 float sharpen_intensity;
 910                 if (getstatf(STAT_STRENGTH_FINISHED) - time > 0)
 911                         sharpen_intensity += (getstatf(STAT_STRENGTH_FINISHED) - time);
 912                 if (getstatf(STAT_INVINCIBLE_FINISHED) - time > 0)
 913                         sharpen_intensity += (getstatf(STAT_INVINCIBLE_FINISHED) - time);
 914
 915                 if(autocvar_hud_powerup && sharpen_intensity > 0 && autocvar_chase_active >= 0) // not while the event chase camera is active
 916                 {
 917                         sharpen_intensity = bound(0, sharpen_intensity, 5); // powerup warning time is 5 seconds, so fade the effect from there
 918
 919                         if(sharpen_intensity != old_sharpen_intensity) // reduce cvar_set spam as much as possible
 920                         {
 921                                 cvar_set("r_glsl_postprocess_uservec2", strcat("0 ", ftos(-sharpen_intensity * cvar("hud_powerup")), " 0 0"));
 922                                 old_sharpen_intensity = sharpen_intensity;
 923                         }
 924                 }
 925                 else if(cvar_string("r_glsl_postprocess_uservec2") != "0 0 0 0") // reduce cvar_set spam as much as possible
 926                 {
 927                         cvar_set("r_glsl_postprocess_uservec2", "0 0 0 0");
 928                         old_sharpen_intensity = 0;
 929                 }
 930         }
 931
 932         if(menu_visible)
 933                 menu_show();
 934
 935         /*if(gametype == GAME_CTF)
 936           {
 937           ctf_view();
 938           } else */
 939
 940         // draw 2D entities
 941         e = self;
 942         for(self = world; (self = nextent(self)); )
 943                 if(self.draw2d)
 944                         self.draw2d();
 945         self = e;
 946         Draw_ShowNames_All();
 947
 948         scoreboard_active = HUD_WouldDrawScoreboard();
 949
 950         hit_time = getstatf(STAT_HIT_TIME);
 951         if(hit_time > nextsound_hit_time && autocvar_cl_hitsound)
 952         {
 953                 sound(world, CH_INFO, "misc/hit.wav", VOL_BASE, ATTN_NONE);
 954                 nextsound_hit_time = time + autocvar_cl_hitsound_antispam_time;
 955         }
 956         typehit_time = getstatf(STAT_TYPEHIT_TIME);
 957         if(typehit_time > nextsound_typehit_time)
 958         {
 959                 sound(world, CH_INFO, "misc/typehit.wav", VOL_BASE, ATTN_NONE);
 960                 nextsound_typehit_time = time + autocvar_cl_hitsound_antispam_time;
 961         }
 962
 963         //else
 964         {
 965                 if(gametype == GAME_FREEZETAG)
 966                 {
 967                         if(getstati(STAT_FROZEN))
 968                                 drawfill('0 0 0', eX * vid_conwidth + eY * vid_conheight, '0.25 0.90 1', autocvar_hud_colorflash_alpha, DRAWFLAG_ADDITIVE);
 969                         if(getstatf(STAT_REVIVE_PROGRESS))
 970                         {
 971                                 DrawCircleClippedPic(eX * 0.5 * vid_conwidth + eY * 0.6 * vid_conheight, 0.1 * vid_conheight, "gfx/crosshair_ring.tga", getstatf(STAT_REVIVE_PROGRESS), '0.25 0.90 1', autocvar_hud_colorflash_alpha, DRAWFLAG_ADDITIVE);
 972                                 drawstring_aspect(eY * 0.64 * vid_conheight, "Revival progress", eX * vid_conwidth + eY * 0.025 * vid_conheight, '1 1 1', 1, DRAWFLAG_NORMAL);
 973                         }
 974                 }
 975
 976                 if(autocvar_r_letterbox == 0)
 977                         if(autocvar_viewsize < 120)
 978                                 CSQC_common_hud();
 979
 980                 // crosshair goes VERY LAST
 981                 if(!scoreboard_active && !camera_active && intermission != 2 && spectatee_status != -1 && hud == HUD_NORMAL) {
 982                         string wcross_style;
 983                         float wcross_alpha, wcross_resolution;
 984                         wcross_style = autocvar_crosshair;
 985                         if (wcross_style == "0")
 986                                 return;
 987                         wcross_resolution = autocvar_crosshair_size;
 988                         if (wcross_resolution == 0)
 989                                 return;
 990                         wcross_alpha = autocvar_crosshair_alpha;
 991                         if (wcross_alpha == 0)
 992                                 return;
 993
 994                         // TrueAim check
 995                         float shottype;
 996
 997                         // wcross_origin = '0.5 0 0' * vid_conwidth + '0 0.5 0' * vid_conheight;
 998                         wcross_origin = project_3d_to_2d(view_origin + MAX_SHOT_DISTANCE * view_forward);
 999                         wcross_origin_z = 0;
1000                         if(autocvar_crosshair_hittest)
1001                         {
1002                                 vector wcross_oldorigin;
1003                                 wcross_oldorigin = wcross_origin;
1004                                 shottype = TrueAimCheck();
1005                                 if(shottype == SHOTTYPE_HITWORLD)
1006                                 {
1007                                         v = wcross_origin - wcross_oldorigin;
1008                                         v_x /= vid_conwidth;
1009                                         v_y /= vid_conheight;
1010                                         if(vlen(v) > 0.01)
1011                                                 shottype = SHOTTYPE_HITOBSTRUCTION;
1012                                 }
1013                                 if(!autocvar_crosshair_hittest_showimpact)
1014                                         wcross_origin = wcross_oldorigin;
1015                         }
1016                         else
1017                                 shottype = SHOTTYPE_HITWORLD;
1018
1019                         vector wcross_color, wcross_size;
1020                         string wcross_wep, wcross_name;
1021                         float wcross_scale, wcross_blur;
1022
1023                         if (autocvar_crosshair_per_weapon || autocvar_crosshair_color_per_weapon) {
1024                                 e = get_weaponinfo(activeweapon);
1025                                 if (e && e.netname != "")
1026                                 {
1027                                         wcross_wep = e.netname;
1028                                         if(autocvar_crosshair_per_weapon)
1029                                         {
1030                                                 wcross_resolution *= cvar(strcat("crosshair_", wcross_wep, "_size"));
1031                                                 if (wcross_resolution == 0)
1032                                                         return;
1033                                                 wcross_alpha *= cvar(strcat("crosshair_", wcross_wep, "_alpha"));
1034                                                 if (wcross_alpha == 0)
1035                                                         return;
1036
1037                                                 wcross_style = cvar_string(strcat("crosshair_", wcross_wep));
1038                                                 if(wcross_style == "" || wcross_style == "0")
1039                                                         wcross_style = wcross_wep;
1040                                         }
1041                                 }
1042                         }
1043                         if(wcross_wep != "" && autocvar_crosshair_color_per_weapon)
1044                                 wcross_color = stov(cvar_string(strcat("crosshair_", wcross_wep, "_color")));
1045                         else if(autocvar_crosshair_color_by_health)
1046                         {
1047                                 local float x = getstati(STAT_HEALTH);
1048
1049                                 //x = red
1050                                 //y = green
1051                                 //z = blue
1052
1053                                 wcross_color_z = 0;
1054
1055                                 if(x > 200)
1056                                 {
1057                                         wcross_color_x = 0;
1058                                         wcross_color_y = 1;
1059                                 }
1060                                 else if(x > 150)
1061                                 {
1062                                         wcross_color_x = 0.4 - (x-150)*0.02 * 0.4;
1063                                         wcross_color_y = 0.9 + (x-150)*0.02 * 0.1;
1064                                 }
1065                                 else if(x > 100)
1066                                 {
1067                                         wcross_color_x = 1 - (x-100)*0.02 * 0.6;
1068                                         wcross_color_y = 1 - (x-100)*0.02 * 0.1;
1069                                         wcross_color_z = 1 - (x-100)*0.02;
1070                                 }
1071                                 else if(x > 50)
1072                                 {
1073                                         wcross_color_x = 1;
1074                                         wcross_color_y = 1;
1075                                         wcross_color_z = 0.2 + (x-50)*0.02 * 0.8;
1076                                 }
1077                                 else if(x > 20)
1078                                 {
1079                                         wcross_color_x = 1;
1080                                         wcross_color_y = (x-20)*90/27/100;
1081                                         wcross_color_z = (x-20)*90/27/100 * 0.2;
1082                                 }
1083                                 else
1084                                 {
1085                                         wcross_color_x = 1;
1086                                         wcross_color_y = 0;
1087                                 }
1088                         }
1089                         else
1090                                 wcross_color = stov(autocvar_crosshair_color);
1091
1092                         wcross_name = strcat("gfx/crosshair", wcross_style);
1093
1094                         if(autocvar_crosshair_effect_scalefade)
1095                         {
1096                                 wcross_scale = wcross_resolution;
1097                                 wcross_resolution = 1;
1098                         }
1099                         else
1100                         {
1101                                 wcross_scale = 1;
1102                         }
1103
1104                         if(autocvar_crosshair_pickup)
1105                         {
1106                                 if(pickup_crosshair_time < getstatf(STAT_LAST_PICKUP))
1107                                 {
1108                                         pickup_crosshair_size = 1;
1109                                         pickup_crosshair_time = getstatf(STAT_LAST_PICKUP);
1110                                 }
1111
1112                                 if(pickup_crosshair_size > 0)
1113                                         pickup_crosshair_size -= autocvar_crosshair_pickup_speed * frametime;
1114                                 else
1115                                         pickup_crosshair_size = 0;
1116
1117                                 wcross_scale += sin(pickup_crosshair_size) * autocvar_crosshair_pickup;
1118                         }
1119
1120                         vector hitindication_color;
1121                         if(autocvar_crosshair_hitindication)
1122                         {
1123                                 hitindication_color = stov(autocvar_crosshair_hitindication_color);
1124                                 if(hitindication_crosshair_time < hit_time)
1125                                 {
1126                                         hitindication_crosshair_size = 1;
1127                                         hitindication_crosshair_time = hit_time;
1128                                 }
1129
1130                                 if(hitindication_crosshair_size > 0)
1131                                         hitindication_crosshair_size -= autocvar_crosshair_hitindication_speed * frametime;
1132                                 else
1133                                         hitindication_crosshair_size = 0;
1134
1135                                 wcross_scale += sin(hitindication_crosshair_size) * autocvar_crosshair_hitindication;
1136                                 wcross_color_x += sin(hitindication_crosshair_size) * hitindication_color_x;
1137                                 wcross_color_y += sin(hitindication_crosshair_size) * hitindication_color_y;
1138                                 wcross_color_z += sin(hitindication_crosshair_size) * hitindication_color_z;
1139                         }
1140
1141                         if(shottype == SHOTTYPE_HITENEMY)
1142                                 wcross_scale *= autocvar_crosshair_hittest; // is not queried if hittest is 0
1143                         if(shottype == SHOTTYPE_HITTEAM)
1144                                 wcross_scale /= autocvar_crosshair_hittest; // is not queried if hittest is 0
1145
1146                         f = autocvar_crosshair_effect_speed;
1147                         if(f < 0)
1148                                 f *= -2 * g_weaponswitchdelay;
1149                         if(wcross_scale != wcross_scale_goal_prev || wcross_alpha != wcross_alpha_goal_prev || wcross_color != wcross_color_goal_prev)
1150                         {
1151                                 wcross_changedonetime = time + f;
1152                         }
1153                         if(wcross_name != wcross_name_goal_prev || wcross_resolution != wcross_resolution_goal_prev)
1154                         {
1155                                 wcross_name_changestarttime = time;
1156                                 wcross_name_changedonetime = time + f;
1157                                 if(wcross_name_goal_prev_prev)
1158                                         strunzone(wcross_name_goal_prev_prev);
1159                                 wcross_name_goal_prev_prev = wcross_name_goal_prev;
1160                                 wcross_name_goal_prev = strzone(wcross_name);
1161                                 wcross_name_alpha_goal_prev_prev = wcross_name_alpha_goal_prev;
1162                                 wcross_resolution_goal_prev_prev = wcross_resolution_goal_prev;
1163                                 wcross_resolution_goal_prev = wcross_resolution;
1164                         }
1165
1166                         wcross_scale_goal_prev = wcross_scale;
1167                         wcross_alpha_goal_prev = wcross_alpha;
1168                         wcross_color_goal_prev = wcross_color;
1169
1170                         if(shottype == SHOTTYPE_HITTEAM || (shottype == SHOTTYPE_HITOBSTRUCTION && autocvar_crosshair_hittest_blur && !autocvar_chase_active))
1171                         {
1172                                 wcross_blur = 1;
1173                                 wcross_alpha *= 0.75;
1174                         }
1175                         else
1176                                 wcross_blur = 0;
1177                         // *_prev is at time-frametime
1178                         // * is at wcross_changedonetime+f
1179                         // what do we have at time?
1180                         if(time < wcross_changedonetime)
1181                         {
1182                                 f = frametime / (wcross_changedonetime - time + frametime);
1183                                 wcross_scale = f * wcross_scale + (1 - f) * wcross_scale_prev;
1184                                 wcross_alpha = f * wcross_alpha + (1 - f) * wcross_alpha_prev;
1185                                 wcross_color = f * wcross_color + (1 - f) * wcross_color_prev;
1186                         }
1187
1188                         wcross_scale_prev = wcross_scale;
1189                         wcross_alpha_prev = wcross_alpha;
1190                         wcross_color_prev = wcross_color;
1191
1192                         wcross_scale *= 1 - autocvar__menu_alpha;
1193                         wcross_alpha *= 1 - autocvar__menu_alpha;
1194                         wcross_size = drawgetimagesize(wcross_name) * wcross_scale;
1195
1196                         if(wcross_scale >= 0.001 && wcross_alpha >= 0.001)
1197                         {
1198                                 // crosshair rings for weapon stats
1199                                 if (autocvar_crosshair_ring || autocvar_crosshair_ring_reload)
1200                                 {
1201                                         // declarations and stats
1202                                         float ring_value, ring_scale, ring_alpha, ring_inner_value, ring_inner_alpha;
1203                                         string ring_image, ring_inner_image;
1204                                         vector ring_rgb, ring_inner_rgb;
1205
1206                                         ring_scale = autocvar_crosshair_ring_size;
1207
1208                                         float weapon_clipload, weapon_clipsize;
1209                                         weapon_clipload = getstati(STAT_WEAPON_CLIPLOAD);
1210                                         weapon_clipsize = getstati(STAT_WEAPON_CLIPSIZE);
1211
1212                                         float nex_charge, nex_chargepool;
1213                                         nex_charge = getstatf(STAT_NEX_CHARGE);
1214                                         nex_chargepool = getstatf(STAT_NEX_CHARGEPOOL);
1215
1216                                         if(nex_charge_movingavg == 0) // this should only happen if we have just loaded up the game
1217                                                 nex_charge_movingavg = nex_charge;
1218
1219
1220                                         // handle the values
1221                                         if (autocvar_crosshair_ring && activeweapon == WEP_NEX && nex_charge && autocvar_crosshair_ring_nex) // ring around crosshair representing velocity-dependent damage for the nex
1222                                         {
1223                                                 if (nex_chargepool || use_nex_chargepool) {
1224                                                         use_nex_chargepool = 1;
1225                                                         ring_inner_value = nex_chargepool;
1226                                                 } else {
1227                                                         nex_charge_movingavg = (1 - autocvar_crosshair_ring_nex_currentcharge_movingavg_rate) * nex_charge_movingavg + autocvar_crosshair_ring_nex_currentcharge_movingavg_rate * nex_charge;
1228                                                         ring_inner_value = bound(0, autocvar_crosshair_ring_nex_currentcharge_scale * (nex_charge - nex_charge_movingavg), 1);
1229                                                 }
1230
1231                                                 ring_inner_alpha = autocvar_crosshair_ring_nex_inner_alpha;
1232                                                 ring_inner_rgb = eX * autocvar_crosshair_ring_nex_inner_color_red + eY * autocvar_crosshair_ring_nex_inner_color_green + eZ * autocvar_crosshair_ring_nex_inner_color_blue;
1233                                                 ring_inner_image = "gfx/crosshair_ring_inner.tga";
1234
1235                                                 // draw the outer ring to show the current charge of the weapon
1236                                                 ring_value = nex_charge;
1237                                                 ring_alpha = autocvar_crosshair_ring_nex_alpha;
1238                                                 ring_rgb = wcross_color;
1239                                                 ring_image = "gfx/crosshair_ring_nexgun.tga";
1240                                         }
1241                                         else if (autocvar_crosshair_ring && activeweapon == WEP_MINE_LAYER && minelayer_maxmines && autocvar_crosshair_ring_minelayer)
1242                                         {
1243                                                 ring_value = bound(0, getstati(STAT_LAYED_MINES) / minelayer_maxmines, 1); // if you later need to use the count of bullets in another place, then add a float for it. For now, no need to.
1244                                                 ring_alpha = autocvar_crosshair_ring_minelayer_alpha;
1245                                                 ring_rgb = wcross_color;
1246                                                 ring_image = "gfx/crosshair_ring.tga";
1247                                         }
1248                                         else if (activeweapon == WEP_HAGAR && getstati(STAT_HAGAR_LOAD) && autocvar_crosshair_ring_hagar)
1249                                         {
1250                                                 ring_value = bound(0, getstati(STAT_HAGAR_LOAD) / hagar_maxrockets, 1);
1251                                                 ring_alpha = autocvar_crosshair_ring_hagar_alpha;
1252                                                 ring_rgb = wcross_color;
1253                                                 ring_image = "gfx/crosshair_ring.tga";
1254                                         }
1255
1256                                         if(autocvar_crosshair_ring_reload && weapon_clipsize) // forces there to be only an ammo ring
1257                                         {
1258                                                 ring_value = bound(0, weapon_clipload / weapon_clipsize, 1);
1259                                                 ring_scale = autocvar_crosshair_ring_reload_size;
1260                                                 ring_alpha = autocvar_crosshair_ring_reload_alpha;
1261                                                 ring_rgb = wcross_color;
1262
1263                                                 // Note: This is to stop Taoki from complaining that the image doesn't match all potential balances.
1264                                                 // if a new image for another weapon is added, add the code (and its respective file/value) here
1265                                                 if ((activeweapon == WEP_RIFLE) && (weapon_clipsize == 80))
1266                                                         ring_image = "gfx/crosshair_ring_rifle.tga";
1267                                                 else
1268                                                         ring_image = "gfx/crosshair_ring.tga";
1269                                         }
1270
1271                                         if (autocvar_crosshair_ring_inner && ring_inner_value) // lets draw a ring inside a ring so you can ring while you ring
1272                                                 DrawCircleClippedPic(wcross_origin, wcross_size_x * ring_scale, ring_inner_image, ring_inner_value, ring_inner_rgb, wcross_alpha * ring_inner_alpha, DRAWFLAG_ADDITIVE);
1273
1274                                         if (ring_value)
1275                                                 DrawCircleClippedPic(wcross_origin, wcross_size_x * ring_scale, ring_image, ring_value, ring_rgb, wcross_alpha * ring_alpha, DRAWFLAG_ADDITIVE);
1276                                 }
1277
1278 #define CROSSHAIR_DO_BLUR(M,sz,wcross_name,wcross_alpha) \
1279                                 do \
1280                                 { \
1281                                         if(wcross_blur > 0) \
1282                                         { \
1283                                                 for(i = -2; i <= 2; ++i) \
1284                                                 for(j = -2; j <= 2; ++j) \
1285                                                 M(i,j,sz,wcross_name,wcross_alpha*0.04); \
1286                                         } \
1287                                         else \
1288                                         { \
1289                                                 M(0,0,sz,wcross_name,wcross_alpha); \
1290                                         } \
1291                                 } \
1292                                 while(0)
1293
1294 #define CROSSHAIR_DRAW_SINGLE(i,j,sz,wcross_name,wcross_alpha) \
1295                                 drawpic(wcross_origin - ('0.5 0 0' * (sz * wcross_size_x + i * wcross_blur) + '0 0.5 0' * (sz * wcross_size_y + j * wcross_blur)), wcross_name, sz * wcross_size, wcross_color, wcross_alpha, DRAWFLAG_NORMAL)
1296
1297 #define CROSSHAIR_DRAW(sz,wcross_name,wcross_alpha) \
1298                                 CROSSHAIR_DO_BLUR(CROSSHAIR_DRAW_SINGLE,sz,wcross_name,wcross_alpha)
1299
1300                                 if(time < wcross_name_changedonetime && wcross_name != wcross_name_goal_prev_prev && wcross_name_goal_prev_prev)
1301                                 {
1302                                         f = (wcross_name_changedonetime - time) / (wcross_name_changedonetime - wcross_name_changestarttime);
1303                                         wcross_size = drawgetimagesize(wcross_name_goal_prev_prev) * wcross_scale;
1304                                         CROSSHAIR_DRAW(wcross_resolution_goal_prev_prev, wcross_name_goal_prev_prev, wcross_alpha * f * wcross_name_alpha_goal_prev_prev);
1305                                         f = 1 - f;
1306                                 }
1307                                 else
1308                                 {
1309                                         f = 1;
1310                                 }
1311                                 wcross_name_alpha_goal_prev = f;
1312
1313                                 wcross_size = drawgetimagesize(wcross_name) * wcross_scale;
1314                                 CROSSHAIR_DRAW(wcross_resolution, wcross_name, wcross_alpha * f);
1315
1316                                 if(autocvar_crosshair_dot)
1317                                 {
1318                                         vector wcross_color_old;
1319                                         wcross_color_old = wcross_color;
1320                                         if(autocvar_crosshair_dot_color != "0")
1321                                                 wcross_color = stov(autocvar_crosshair_dot_color);
1322                                         CROSSHAIR_DRAW(wcross_resolution * autocvar_crosshair_dot_size, "gfx/crosshairdot.tga", f * autocvar_crosshair_dot_alpha);
1323                                         // FIXME why don't we use wcross_alpha here?
1324                                         wcross_color = wcross_color_old;
1325                                 }
1326                         }
1327                 }
1328                 else
1329                 {
1330                         wcross_scale_prev = 0;
1331                         wcross_alpha_prev = 0;
1332                         wcross_scale_goal_prev = 0;
1333                         wcross_alpha_goal_prev = 0;
1334                         wcross_changedonetime = 0;
1335                         if(wcross_name_goal_prev)
1336                                 strunzone(wcross_name_goal_prev);
1337                         wcross_name_goal_prev = string_null;
1338                         if(wcross_name_goal_prev_prev)
1339                                 strunzone(wcross_name_goal_prev_prev);
1340                         wcross_name_goal_prev_prev = string_null;
1341                         wcross_name_changestarttime = 0;
1342                         wcross_name_changedonetime = 0;
1343                         wcross_name_alpha_goal_prev = 0;
1344                         wcross_name_alpha_goal_prev_prev = 0;
1345                         wcross_resolution_goal_prev = 0;
1346                         wcross_resolution_goal_prev_prev = 0;
1347                 }
1348         }
1349
1350         if(NextFrameCommand)
1351         {
1352                 localcmd("\n", NextFrameCommand, "\n");
1353                 NextFrameCommand = string_null;
1354         }
1355
1356         // we must do this check AFTER a frame was rendered, or it won't work
1357         if(cs_project_is_b0rked == 0)
1358         {
1359                 string w0, h0;
1360                 w0 = ftos(autocvar_vid_conwidth);
1361                 h0 = ftos(autocvar_vid_conheight);
1362                 //R_SetView(VF_VIEWPORT, '0 0 0', '640 480 0');
1363                 //R_SetView(VF_FOV, '90 90 0');
1364                 R_SetView(VF_ORIGIN, '0 0 0');
1365                 R_SetView(VF_ANGLES, '0 0 0');
1366                 R_SetView(VF_PERSPECTIVE, 1);
1367                 makevectors('0 0 0');
1368                 vector v1, v2;
1369                 cvar_set("vid_conwidth", "800");
1370                 cvar_set("vid_conheight", "600");
1371                 v1 = cs_project(v_forward);
1372                 cvar_set("vid_conwidth", "640");
1373                 cvar_set("vid_conheight", "480");
1374                 v2 = cs_project(v_forward);
1375                 if(v1 == v2)
1376                         cs_project_is_b0rked = 1;
1377                 else
1378                         cs_project_is_b0rked = -1;
1379                 cvar_set("vid_conwidth", w0);
1380                 cvar_set("vid_conheight", h0);
1381         }
1382
1383         if(autocvar__hud_configure)
1384                 HUD_Panel_Mouse();
1385
1386     if(hud && !intermission)
1387     {
1388         if(hud == HUD_SPIDERBOT)
1389             CSQC_SPIDER_HUD();
1390         else if(hud == HUD_WAKIZASHI)
1391             CSQC_WAKIZASHI_HUD();
1392         else if(hud == HUD_RAPTOR)
1393             CSQC_RAPTOR_HUD();
1394         else if(hud == HUD_BUMBLEBEE)
1395             CSQC_BUMBLE_HUD();
1396     }
1397         // let's reset the view back to normal for the end
1398         R_SetView(VF_MIN, '0 0 0');
1399         R_SetView(VF_SIZE, '1 0 0' * w + '0 1 0' * h);
1400 }
1401
1402
1403 void CSQC_common_hud(void)
1404 {
1405     // do some accuracy var caching
1406     float i;
1407     if(!(gametype == GAME_RACE || gametype == GAME_CTS))
1408     {
1409         if(autocvar_accuracy_color_levels != acc_color_levels)
1410         {
1411             if(acc_color_levels)
1412                 strunzone(acc_color_levels);
1413             acc_color_levels = strzone(autocvar_accuracy_color_levels);
1414             acc_levels = tokenize(acc_color_levels);
1415             if (acc_levels > MAX_ACCURACY_LEVELS)
1416                 acc_levels = MAX_ACCURACY_LEVELS;
1417
1418             for (i = 0; i < acc_levels; ++i)
1419                 acc_lev[i] = stof(argv(i)) / 100.0;
1420         }
1421         // let know that acc_col[] needs to be loaded
1422         acc_col_x[0] = -1;
1423     }
1424
1425     HUD_Main(); // always run these functions for alpha checks
1426     HUD_DrawScoreboard();
1427
1428     if (scoreboard_active) // scoreboard/accuracy
1429     {
1430         HUD_Reset();
1431         // HUD_DrawScoreboard takes care of centerprint_start
1432     }
1433     else if (intermission == 2) // map voting screen
1434     {
1435         HUD_FinaleOverlay();
1436         HUD_Reset();
1437
1438         centerprint_start_x = 0;
1439         centerprint_start_y = autocvar_scr_centerpos * vid_conheight;
1440     }
1441     else // hud
1442     {
1443         centerprint_start_x = 0;
1444         centerprint_start_y = autocvar_scr_centerpos * vid_conheight;
1445     }
1446
1447         /*
1448         switch(hud)
1449         {
1450                 case HUD_SPIDERBOT:
1451                         CSQC_SPIDER_HUD();
1452                         break;
1453
1454                 case HUD_WAKIZASHI:
1455                         CSQC_WAKIZASHI_HUD();
1456                         break;
1457
1458         case HUD_BUMBLEBEE:
1459             CSQC_BUMBLE_HUD();
1460             break;
1461         }
1462         */
1463
1464     HUD_DrawCenterPrint();
1465
1466 }
1467
1468
1469 // following vectors must be global to allow seamless switching between camera modes
1470 vector camera_offset, current_camera_offset, mouse_angles, current_angles, current_origin, current_position;
1471 void CSQC_Demo_Camera()
1472 {
1473         float speed, attenuation, dimensions;
1474         vector tmp, delta;
1475
1476         if( autocvar_camera_reset || !camera_mode )
1477         {
1478                 camera_offset = '0 0 0';
1479                 current_angles = '0 0 0';
1480                 camera_direction = '0 0 0';
1481                 camera_offset_z += 30;
1482                 camera_offset_x += 30 * -cos(current_angles_y * DEG2RAD);
1483                 camera_offset_y += 30 * -sin(current_angles_y * DEG2RAD);
1484                 current_origin = view_origin;
1485                 current_camera_offset  = camera_offset;
1486                 cvar_set("camera_reset", "0");
1487                 camera_mode = CAMERA_CHASE;
1488         }
1489
1490         // Camera angles
1491         if( camera_roll )
1492                 mouse_angles_z += camera_roll * autocvar_camera_speed_roll;
1493
1494         if(autocvar_camera_look_player)
1495         {
1496                 local vector dir;
1497                 local float n;
1498
1499                 dir = normalize(view_origin - current_position);
1500                 n = mouse_angles_z;
1501                 mouse_angles = vectoangles(dir);
1502                 mouse_angles_x = mouse_angles_x * -1;
1503                 mouse_angles_z = n;
1504         }
1505         else
1506         {
1507                 tmp = getmousepos() * 0.1;
1508                 if(vlen(tmp)>autocvar_camera_mouse_threshold)
1509                 {
1510                         mouse_angles_x += tmp_y * cos(mouse_angles_z * DEG2RAD) + (tmp_x * sin(mouse_angles_z * DEG2RAD));
1511                         mouse_angles_y -= tmp_x * cos(mouse_angles_z * DEG2RAD) + (tmp_y * -sin(mouse_angles_z * DEG2RAD));
1512                 }
1513         }
1514
1515         while (mouse_angles_x < -180) mouse_angles_x = mouse_angles_x + 360;
1516         while (mouse_angles_x > 180) mouse_angles_x = mouse_angles_x - 360;
1517         while (mouse_angles_y < -180) mouse_angles_y = mouse_angles_y + 360;
1518         while (mouse_angles_y > 180) mouse_angles_y = mouse_angles_y - 360;
1519
1520         // Fix difference when angles don't have the same sign
1521         delta = '0 0 0';
1522         if(mouse_angles_y < -60 && current_angles_y > 60)
1523                 delta = '0 360 0';
1524         if(mouse_angles_y > 60 && current_angles_y < -60)
1525                 delta = '0 -360 0';
1526
1527         if(autocvar_camera_look_player)
1528                 attenuation = autocvar_camera_look_attenuation;
1529         else
1530                 attenuation = autocvar_camera_speed_attenuation;
1531
1532         attenuation = 1 / max(1, attenuation);
1533         current_angles += (mouse_angles - current_angles + delta) * attenuation;
1534
1535         while (current_angles_x < -180) current_angles_x = current_angles_x + 360;
1536         while (current_angles_x > 180) current_angles_x = current_angles_x - 360;
1537         while (current_angles_y < -180) current_angles_y = current_angles_y + 360;
1538         while (current_angles_y > 180) current_angles_y = current_angles_y - 360;
1539
1540         // Camera position
1541         tmp = '0 0 0';
1542         dimensions = 0;
1543
1544         if( camera_direction_x )
1545         {
1546                 tmp_x = camera_direction_x * cos(current_angles_y * DEG2RAD);
1547                 tmp_y = camera_direction_x * sin(current_angles_y * DEG2RAD);
1548                 if( autocvar_camera_forward_follows && !autocvar_camera_look_player )
1549                         tmp_z = camera_direction_x * -sin(current_angles_x * DEG2RAD);
1550                 ++dimensions;
1551         }
1552
1553         if( camera_direction_y )
1554         {
1555                 tmp_x += camera_direction_y * -sin(current_angles_y * DEG2RAD);
1556                 tmp_y += camera_direction_y * cos(current_angles_y * DEG2RAD) * cos(current_angles_z * DEG2RAD);
1557                 tmp_z += camera_direction_y * sin(current_angles_z * DEG2RAD);
1558                 ++dimensions;
1559         }
1560
1561         if( camera_direction_z )
1562         {
1563                 tmp_z += camera_direction_z * cos(current_angles_z * DEG2RAD);
1564                 ++dimensions;
1565         }
1566
1567         if(autocvar_camera_free)
1568                 speed = autocvar_camera_speed_free;
1569         else
1570                 speed = autocvar_camera_speed_chase;
1571
1572         if(dimensions)
1573         {
1574                 speed = speed * sqrt(1 / dimensions);
1575                 camera_offset += tmp * speed;
1576         }
1577
1578         current_camera_offset += (camera_offset - current_camera_offset) * attenuation;
1579
1580         // Camera modes
1581         if( autocvar_camera_free )
1582         {
1583                 if ( camera_mode == CAMERA_CHASE )
1584                 {
1585                         current_camera_offset = current_origin + current_camera_offset;
1586                         camera_offset = current_origin + camera_offset;
1587                 }
1588
1589                 camera_mode = CAMERA_FREE;
1590                 current_position = current_camera_offset;
1591         }
1592         else
1593         {
1594                 if ( camera_mode == CAMERA_FREE )
1595                 {
1596                         current_origin = view_origin;
1597                         camera_offset = camera_offset - current_origin;
1598                         current_camera_offset = current_camera_offset - current_origin;
1599                 }
1600
1601                 camera_mode = CAMERA_CHASE;
1602
1603                 if(autocvar_camera_chase_smoothly)
1604                         current_origin += (view_origin - current_origin) * attenuation;
1605                 else
1606                         current_origin = view_origin;
1607
1608                 current_position = current_origin + current_camera_offset;
1609         }
1610
1611         R_SetView(VF_ANGLES, current_angles);
1612         R_SetView(VF_ORIGIN, current_position);
1613 }