qcsrc/client/View.qc

   1 #define spider_rocket_icon "gfx/vehicles/rocket_ico.tga"
   2 #define spider_rocket_targ "gfx/vehicles/target.tga"
   3 #define SPIDER_CROSS "textures/spiderbot/cross.tga"
   4 #define rkt_size 32
   5 #define rld_size_x 256
   6 #define rld_size_y 16
   7
   8 void CSQC_WAKIZASHI_HUD();
   9
  10 entity porto;
  11 vector polyline[16];
  12 float trace_dphitcontents;
  13 float trace_networkentity;
  14 float Q3SURFACEFLAG_SLICK = 2; // low friction surface
  15 float DPCONTENTS_SOLID = 1; // blocks player movement
  16 float DPCONTENTS_BODY = 32; // blocks player movement
  17 float DPCONTENTS_CORPSE = 64; // blocks player movement
  18 float DPCONTENTS_PLAYERCLIP = 256; // blocks player movement
  19 void Porto_Draw()
  20 {
  21         vector p, dir, ang, q, nextdir;
  22         float idx, portal_number, portal1_idx;
  23
  24         if(activeweapon != WEP_PORTO || spectatee_status || gametype == GAME_NEXBALL)
  25                 return;
  26         if(intermission == 1)
  27                 return;
  28         if(intermission == 2)
  29                 return;
  30         if (getstati(STAT_HEALTH) <= 0)
  31                 return;
  32
  33         dir = view_forward;
  34
  35         if(angles_held_status)
  36         {
  37                 makevectors(angles_held);
  38                 dir = v_forward;
  39         }
  40
  41         p = view_origin;
  42
  43         polyline[0] = p;
  44         idx = 1;
  45         portal_number = 0;
  46         nextdir = dir;
  47
  48         for(;;)
  49         {
  50                 dir = nextdir;
  51                 traceline(p, p + 65536 * dir, TRUE, porto);
  52                 if(trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT)
  53                         return;
  54                 nextdir = dir - 2 * (dir * trace_plane_normal) * trace_plane_normal; // mirror dir at trace_plane_normal
  55                 p = trace_endpos;
  56                 polyline[idx] = p;
  57                 ++idx;
  58                 if(idx >= 16)
  59                         return;
  60                 if(trace_dphitq3surfaceflags & Q3SURFACEFLAG_SLICK || trace_dphitcontents & DPCONTENTS_PLAYERCLIP)
  61                         continue;
  62                 ++portal_number;
  63                 ang = vectoangles2(trace_plane_normal, dir);
  64                 ang_x = -ang_x;
  65                 makevectors(ang);
  66                 if(!CheckWireframeBox(porto, p - 48 * v_right - 48 * v_up + 16 * v_forward, 96 * v_right, 96 * v_up, 96 * v_forward))
  67                         return;
  68                 if(portal_number == 1)
  69                         portal1_idx = idx;
  70                 if(portal_number >= 2)
  71                         break;
  72         }
  73
  74         while(idx >= 2)
  75         {
  76                 p = polyline[idx-2];
  77                 q = polyline[idx-1];
  78                 if(idx == 2)
  79                         p = p - view_up * 16;
  80                 if(idx-1 >= portal1_idx)
  81                 {
  82                         Draw_CylindricLine(p, q, 4, "", 1, 0, '0 0 1', 0.5, DRAWFLAG_NORMAL, view_origin);
  83                 }
  84                 else
  85                 {
  86                         Draw_CylindricLine(p, q, 4, "", 1, 0, '1 0 0', 0.5, DRAWFLAG_NORMAL, view_origin);
  87                 }
  88                 --idx;
  89         }
  90 }
  91
  92 /**
  93  * Checks whether the server initiated a map restart (stat_game_starttime changed)
  94  *
  95  * TODO: Use a better solution where a common shared entitiy is used that contains
  96  * timelimit, fraglimit and game_starttime! Requires engine changes (remove STAT_TIMELIMIT
  97  * and STAT_FRAGLIMIT to be auto-sent)
  98  */
  99 void CheckForGamestartChange() {
 100         float startTime;
 101         startTime = getstatf(STAT_GAMESTARTTIME);
 102         if (previous_game_starttime != startTime) {
 103                 if ((time + 5.0) < startTime) {
 104                         //if connecting to server while restart was active don't always play prepareforbattle
 105                         sound(world, CHAN_AUTO, strcat("announcer/", autocvar_cl_announcer, "/prepareforbattle.wav"), VOL_BASEVOICE, ATTN_NONE);
 106                 }
 107                 if (time < startTime) {
 108                         restartAnnouncer = spawn();
 109                         restartAnnouncer.think = restartAnnouncer_Think;
 110                         restartAnnouncer.nextthink = startTime - floor(startTime - time); //synchronize nextthink to startTime
 111                 }
 112         }
 113         previous_game_starttime = startTime;
 114 }
 115
 116 void Porto_Init()
 117 {
 118         porto = spawn();
 119         porto.classname = "porto";
 120         porto.draw = Porto_Draw;
 121         porto.dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY | DPCONTENTS_PLAYERCLIP;
 122 }
 123
 124 float drawtime;
 125 float avgspeed;
 126 vector GetCurrentFov(float fov)
 127 {
 128         float zoomsensitivity, zoomspeed, zoomfactor, zoomdir, velocityzoom;
 129
 130         zoomsensitivity = autocvar_cl_zoomsensitivity;
 131         zoomfactor = autocvar_cl_zoomfactor;
 132         if(zoomfactor < 1 || zoomfactor > 16)
 133                 zoomfactor = 2.5;
 134         zoomspeed = autocvar_cl_zoomspeed;
 135         if(zoomspeed >= 0)
 136                 if(zoomspeed < 0.5 || zoomspeed > 16)
 137                         zoomspeed = 3.5;
 138
 139         zoomdir = button_zoom;
 140         if((getstati(STAT_ACTIVEWEAPON) == WEP_NEX && nex_scope) || (getstati(STAT_ACTIVEWEAPON) == WEP_SNIPERRIFLE && sniperrifle_scope)) // do NOT use switchweapon here
 141                 zoomdir += button_attack2;
 142         if(spectatee_status > 0 || isdemo())
 143         {
 144                 if(spectatorbutton_zoom)
 145                         zoomdir = 0 + !zoomdir;
 146                 // do not even THINK about removing this 0
 147                 // _I_ know what I am doing
 148                 // fteqcc does not
 149         }
 150
 151         if(zoomdir)
 152                 zoomin_effect = 0;
 153
 154         if(zoomin_effect || camera_active)
 155         {
 156                 current_viewzoom = min(1, current_viewzoom + drawframetime);
 157         }
 158         else
 159         {
 160                 if(zoomspeed < 0) // instant zoom
 161                 {
 162                         if(zoomdir)
 163                                 current_viewzoom = 1 / zoomfactor;
 164                         else
 165                                 current_viewzoom = 1;
 166                 }
 167                 else
 168                 {
 169                         if(zoomdir)
 170                                 current_viewzoom = 1 / bound(1, 1 / current_viewzoom + drawframetime * zoomspeed * (zoomfactor - 1), zoomfactor);
 171                         else
 172                                 current_viewzoom = bound(1 / zoomfactor, current_viewzoom + drawframetime * zoomspeed * (1 - 1 / zoomfactor), 1);
 173                 }
 174         }
 175
 176         if(almost_equals(current_viewzoom, 1))
 177                 current_zoomfraction = 0;
 178         else if(almost_equals(current_viewzoom, 1/zoomfactor))
 179                 current_zoomfraction = 1;
 180         else
 181                 current_zoomfraction = (current_viewzoom - 1) / (1/zoomfactor - 1);
 182
 183         if(zoomsensitivity < 1)
 184                 setsensitivityscale(pow(current_viewzoom, 1 - zoomsensitivity));
 185         else
 186                 setsensitivityscale(1);
 187
 188         velocityzoom = bound(0, drawframetime / max(0.000000001, autocvar_cl_velocityzoomtime), 1);
 189         avgspeed = avgspeed * (1 - velocityzoom) + (vlen(pmove_vel) / 1000) * velocityzoom;
 190         velocityzoom = exp(float2range11(avgspeed * -autocvar_cl_velocityzoom / 1) * 1);
 191
 192         //print(ftos(avgspeed), " avgspeed, ", ftos(autocvar_cl_velocityzoom), " cvar, ", ftos(velocityzoom), " return\n"); // for debugging
 193
 194         float frustumx, frustumy, fovx, fovy;
 195         frustumy = tan(fov * M_PI / 360.0) * 0.75 * current_viewzoom * velocityzoom;
 196         frustumx = frustumy * vid_width / vid_height / vid_pixelheight;
 197         fovx = atan2(frustumx, 1) / M_PI * 360.0;
 198         fovy = atan2(frustumy, 1) / M_PI * 360.0;
 199
 200         return '1 0 0' * fovx + '0 1 0' * fovy;
 201 }
 202
 203 // this function must match W_SetupShot!
 204 float zoomscript_caught;
 205
 206 vector wcross_origin;
 207 float wcross_scale_prev, wcross_alpha_prev;
 208 vector wcross_color_prev;
 209 float wcross_scale_goal_prev, wcross_alpha_goal_prev;
 210 vector wcross_color_goal_prev;
 211 float wcross_changedonetime;
 212
 213 string wcross_name_goal_prev, wcross_name_goal_prev_prev;
 214 float wcross_resolution_goal_prev, wcross_resolution_goal_prev_prev;
 215 float wcross_name_changestarttime, wcross_name_changedonetime;
 216 float wcross_name_alpha_goal_prev, wcross_name_alpha_goal_prev_prev;
 217 entity trueaim;
 218 entity trueaim_rifle;
 219
 220 #define SHOTTYPE_HITTEAM 1
 221 #define SHOTTYPE_HITOBSTRUCTION 2
 222 #define SHOTTYPE_HITWORLD 3
 223 #define SHOTTYPE_HITENEMY 4
 224
 225 void TrueAim_Init()
 226 {
 227         trueaim = spawn();
 228         trueaim.classname = "trueaim";
 229         trueaim.dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY | DPCONTENTS_CORPSE;
 230         trueaim_rifle = spawn();
 231         trueaim_rifle.classname = "trueaim_rifle";
 232         trueaim_rifle.dphitcontentsmask = DPCONTENTS_BODY | DPCONTENTS_CORPSE;
 233 }
 234
 235 float EnemyHitCheck()
 236 {
 237         float t;
 238         wcross_origin = project_3d_to_2d(trace_endpos);
 239         wcross_origin_z = 0;
 240         if(trace_networkentity < 1)
 241                 return SHOTTYPE_HITWORLD;
 242         if(trace_networkentity > maxclients)
 243                 return SHOTTYPE_HITWORLD;
 244         t = GetPlayerColor(trace_networkentity - 1);
 245         if(teamplay)
 246                 if(t == myteam)
 247                         return SHOTTYPE_HITTEAM;
 248         if(t == COLOR_SPECTATOR)
 249                 return SHOTTYPE_HITWORLD;
 250         return SHOTTYPE_HITENEMY;
 251 }
 252
 253 float TrueAimCheck()
 254 {
 255         float nudge = 1; // added to traceline target and subtracted from result
 256         vector vecs, trueaimpoint, w_shotorg;
 257         vector mi, ma, dv;
 258         float shottype;
 259         entity ta;
 260         float mv;
 261
 262         mi = ma = '0 0 0';
 263         ta = trueaim;
 264         mv = MOVE_NOMONSTERS;
 265
 266         switch(activeweapon)
 267         {
 268                 case WEP_TUBA: // no aim
 269                 case WEP_PORTO: // shoots from eye
 270                 case WEP_HOOK: // no trueaim
 271                 case WEP_GRENADE_LAUNCHER: // toss curve
 272                         return SHOTTYPE_HITWORLD;
 273                 case WEP_NEX:
 274                 case WEP_MINSTANEX:
 275                         mv = MOVE_NORMAL;
 276                         break;
 277                 case WEP_SNIPERRIFLE:
 278                         ta = trueaim_rifle;
 279                         mv = MOVE_NORMAL;
 280                         if(zoomscript_caught)
 281                         {
 282                                 tracebox(view_origin, '0 0 0', '0 0 0', view_origin + view_forward * MAX_SHOT_DISTANCE, mv, ta);
 283                                 return EnemyHitCheck();
 284                         }
 285                         break;
 286                 case WEP_ROCKET_LAUNCHER: // projectile has a size!
 287                         mi = '-3 -3 -3';
 288                         ma = '3 3 3';
 289                         break;
 290                 case WEP_FIREBALL: // projectile has a size!
 291                         mi = '-16 -16 -16';
 292                         ma = '16 16 16';
 293                         break;
 294                 case WEP_SEEKER: // projectile has a size!
 295                         mi = '-2 -2 -2';
 296                         ma = '2 2 2';
 297                         break;
 298                 case WEP_ELECTRO: // projectile has a size!
 299                         mi = '0 0 -3';
 300                         ma = '0 0 -3';
 301                         break;
 302         }
 303
 304         vecs = decompressShotOrigin(getstati(STAT_SHOTORG));
 305
 306         traceline(view_origin, view_origin + view_forward * MAX_SHOT_DISTANCE, mv, ta);
 307         trueaimpoint = trace_endpos;
 308
 309         if(vlen(trueaimpoint - view_origin) < g_trueaim_minrange)
 310                 trueaimpoint = view_origin + view_forward * g_trueaim_minrange;
 311
 312         if(vecs_x > 0)
 313                 vecs_y = -vecs_y;
 314         else
 315                 vecs = '0 0 0';
 316
 317         dv = view_right * vecs_y + view_up * vecs_z;
 318         w_shotorg = view_origin + dv;
 319
 320         // now move the vecs forward as much as requested if possible
 321         tracebox(w_shotorg, mi, ma, w_shotorg + view_forward * (vecs_x + nudge), MOVE_NORMAL, ta); // FIXME this MOVE_NORMAL part will misbehave a little in csqc
 322         w_shotorg = trace_endpos - view_forward * nudge;
 323
 324         tracebox(w_shotorg, mi, ma, trueaimpoint, MOVE_NORMAL, ta);
 325         shottype = EnemyHitCheck();
 326         if(shottype != SHOTTYPE_HITWORLD)
 327                 return shottype;
 328
 329 #if 0
 330         // FIXME WHY DOES THIS NOT WORK FOR THE ROCKET LAUNCHER?
 331         // or rather, I know why, but see no fix
 332         if(vlen(trace_endpos - trueaimpoint) > vlen(ma) + vlen(mi) + 1)
 333                 // yes, this is an ugly hack... but it seems good enough to find out whether the test hits the same place as the initial trace
 334                 return SHOTTYPE_HITOBSTRUCTION;
 335 #endif
 336
 337         return SHOTTYPE_HITWORLD;
 338 }
 339
 340 void CSQC_common_hud(void);
 341
 342 void PostInit(void);
 343 void CSQC_Demo_Camera();
 344 float HUD_WouldDrawScoreboard();
 345 float view_set;
 346 float camera_mode;
 347 float reticle_type;
 348 string NextFrameCommand;
 349 void CSQC_SPIDER_HUD();
 350 void CSQC_RAPTOR_HUD();
 351
 352 vector freeze_pmove_org, freeze_input_angles;
 353 entity nightvision_noise, nightvision_noise2;
 354
 355 float pickup_crosshair_time, pickup_crosshair_size;
 356 float hit_time, typehit_time;
 357 float nextsound_hit_time, nextsound_typehit_time;
 358 float hitindication_crosshair_time, hitindication_crosshair_size;
 359 float use_nex_chargepool;
 360
 361 float myhealth, myhealth_prev;
 362 float myhealth_flash;
 363
 364 float old_blurradius, old_bluralpha;
 365 float old_sharpen_intensity;
 366
 367 vector myhealth_gentlergb;
 368
 369 float contentavgalpha, liquidalpha_prev;
 370 vector liquidcolor_prev;
 371
 372 vector damage_blurpostprocess, content_blurpostprocess;
 373
 374 void CSQC_UpdateView(float w, float h)
 375 {
 376         entity e;
 377         float fov;
 378         float f, i, j;
 379         vector v, vo;
 380         vector vf_size, vf_min;
 381         float a;
 382
 383         vf_size = R_SetView3fv(VF_SIZE);
 384         vf_min = R_SetView3fv(VF_MIN);
 385         vid_width = vf_size_x;
 386         vid_height = vf_size_y;
 387
 388         vector reticle_pos, reticle_size;
 389
 390         WaypointSprite_Load();
 391
 392         if(spectatee_status)
 393                 myteam = GetPlayerColor(spectatee_status - 1);
 394         else
 395                 myteam = GetPlayerColor(player_localentnum - 1);
 396
 397         ticrate = getstatf(STAT_MOVEVARS_TICRATE) * getstatf(STAT_MOVEVARS_TIMESCALE);
 398         vo = '0 0 1' * getstati(STAT_VIEWHEIGHT);
 399
 400         warpzone_fixview_origin = pmove_org + vo;
 401         warpzone_fixview_cl_viewangles = input_angles;
 402         warpzone_fixview_angles = view_angles;
 403         WarpZone_FixView();
 404         pmove_org = warpzone_fixview_origin - vo;
 405         input_angles = warpzone_fixview_cl_viewangles;
 406         view_angles = warpzone_fixview_angles;
 407
 408         if(autocvar_cl_lockview || (autocvar__hud_configure && spectatee_status <= 0))
 409         {
 410                 pmove_org = freeze_pmove_org;
 411                 input_angles = view_angles = freeze_input_angles;
 412                 R_SetView(VF_ORIGIN, pmove_org + vo);
 413                 R_SetView(VF_ANGLES, view_angles);
 414                 //R_SetView(VF_CL_VIEWANGLES, input_angles);
 415         }
 416         freeze_pmove_org = pmove_org;
 417         freeze_input_angles = input_angles;
 418
 419         // Render the Scene
 420         if(!intermission || !view_set)
 421         {
 422                 view_origin = pmove_org + vo;
 423                 view_angles = input_angles;
 424                 makevectors(view_angles);
 425                 view_forward = v_forward;
 426                 view_right = v_right;
 427                 view_up = v_up;
 428                 view_set = 1;
 429         }
 430
 431 #ifdef BLURTEST
 432         if(time > blurtest_time0 && time < blurtest_time1)
 433         {
 434                 float r, t;
 435
 436                 t = (time - blurtest_time0) / (blurtest_time1 - blurtest_time0);
 437                 r = t * blurtest_radius;
 438                 f = 1 / pow(t, blurtest_power) - 1;
 439
 440                 cvar_set("r_glsl_postprocess", "1");
 441                 cvar_set("r_glsl_postprocess_uservec1", strcat(ftos(r), " ", ftos(f), " 0 0"));
 442         }
 443         else
 444         {
 445                 cvar_set("r_glsl_postprocess", "0");
 446                 cvar_set("r_glsl_postprocess_uservec1", "0 0 0 0");
 447         }
 448 #endif
 449
 450         TargetMusic_Advance();
 451         Fog_Force();
 452
 453         drawframetime = max(0.000001, time - drawtime);
 454         drawtime = time;
 455
 456         // watch for gametype changes here...
 457         // in ParseStuffCMD the cmd isn't executed yet :/
 458         // might even be better to add the gametype to TE_CSQC_INIT...?
 459         if(!postinit)
 460                 PostInit();
 461
 462         if(intermission && !isdemo() && !(calledhooks & HOOK_END))
 463                 if(calledhooks & HOOK_START)
 464                 {
 465                         localcmd("\ncl_hook_gameend\n");
 466                         calledhooks |= HOOK_END;
 467                 }
 468
 469         CheckForGamestartChange();
 470         serverAnnouncer();
 471         maptimeAnnouncer();
 472         carrierAnnouncer();
 473
 474         fov = autocvar_fov;
 475         if(button_zoom || fov <= 59.5)
 476         {
 477                 if(!zoomscript_caught)
 478                 {
 479                         localcmd("+button4\n");
 480                         zoomscript_caught = 1;
 481                         ignore_plus_zoom += 1;
 482                 }
 483         }
 484         else
 485         {
 486                 if(zoomscript_caught)
 487                 {
 488                         localcmd("-button4\n");
 489                         zoomscript_caught = 0;
 490                         ignore_minus_zoom += 1;
 491                 }
 492         }
 493
 494         ColorTranslateMode = autocvar_cl_stripcolorcodes;
 495         activeweapon = getstati(STAT_SWITCHWEAPON);
 496         f = (serverflags & SERVERFLAG_TEAMPLAY);
 497         if(f != teamplay)
 498         {
 499                 teamplay = f;
 500                 HUD_InitScores();
 501         }
 502
 503         if(last_weapon != activeweapon) {
 504                 weapontime = time;
 505                 last_weapon = activeweapon;
 506
 507                 e = get_weaponinfo(activeweapon);
 508                 if(e.netname != "")
 509                         localcmd(strcat("\ncl_hook_activeweapon ", e.netname), "\n");
 510                 else
 511                         localcmd("\ncl_hook_activeweapon none\n");
 512         }
 513
 514         // ALWAYS Clear Current Scene First
 515         R_ClearScene();
 516
 517         // FIXME engine bug? VF_SIZE and VF_MIN are not restored to sensible values by this
 518         R_SetView(VF_SIZE, vf_size);
 519         R_SetView(VF_MIN, vf_min);
 520
 521         // Assign Standard Viewflags
 522         // Draw the World (and sky)
 523         R_SetView(VF_DRAWWORLD, 1);
 524
 525         // Set the console size vars
 526         vid_conwidth = autocvar_vid_conwidth;
 527         vid_conheight = autocvar_vid_conheight;
 528         vid_pixelheight = autocvar_vid_pixelheight;
 529
 530         R_SetView(VF_FOV, GetCurrentFov(fov));
 531
 532         // Camera for demo playback
 533         if(camera_active)
 534         {
 535                 if(autocvar_camera_enable)
 536                         CSQC_Demo_Camera();
 537                 else
 538                 {
 539                         cvar_set("chase_active", ftos(chase_active_backup));
 540                         cvar_set("cl_demo_mousegrab", "0");
 541                         camera_active = FALSE;
 542                 }
 543         }
 544 #ifdef CAMERATEST
 545         else if(autocvar_camera_enable)
 546 #else
 547         else if(autocvar_camera_enable && isdemo())
 548 #endif
 549         {
 550                 // Enable required Darkplaces cvars
 551                 chase_active_backup = autocvar_chase_active;
 552                 cvar_set("chase_active", "2");
 553                 cvar_set("cl_demo_mousegrab", "1");
 554                 camera_active = TRUE;
 555                 camera_mode = FALSE;
 556         }
 557
 558         // Draw the Crosshair
 559         R_SetView(VF_DRAWCROSSHAIR, 0); //Make sure engine crosshairs are always hidden
 560
 561         // Draw the Engine Status Bar (the default Quake HUD)
 562         R_SetView(VF_DRAWENGINEHUD, 0);
 563
 564         // fetch this one only once per frame
 565         hud_showbinds = autocvar_hud_showbinds;
 566         hud_showbinds_limit = autocvar_hud_showbinds_limit;
 567
 568         // Update the mouse position
 569         /*
 570            mousepos_x = vid_conwidth;
 571            mousepos_y = vid_conheight;
 572            mousepos = mousepos*0.5 + getmousepos();
 573          */
 574
 575         e = self;
 576         for(self = world; (self = nextent(self)); )
 577                 if(self.draw)
 578                         self.draw();
 579         self = e;
 580
 581         R_AddEntities(MASK_NORMAL | MASK_ENGINE | MASK_ENGINEVIEWMODELS);
 582         R_RenderScene();
 583
 584         // now switch to 2D drawing mode by calling a 2D drawing function
 585         // then polygon drawing will draw as 2D stuff, and NOT get queued until the
 586         // next R_RenderScene call
 587         drawstring('0 0 0', "", '1 1 0', '1 1 1', 0, 0);
 588
 589         if(autocvar_r_fakelight >= 2 || autocvar_r_fullbright)
 590         if not(serverflags & SERVERFLAG_ALLOW_FULLBRIGHT)
 591         {
 592                 // apply night vision effect
 593                 vector rgb, tc_00, tc_01, tc_10, tc_11;
 594
 595                 if(!nightvision_noise)
 596                 {
 597                         nightvision_noise = spawn();
 598                         nightvision_noise.classname = "nightvision_noise";
 599                 }
 600                 if(!nightvision_noise2)
 601                 {
 602                         nightvision_noise2 = spawn();
 603                         nightvision_noise2.classname = "nightvision_noise2";
 604                 }
 605
 606                 // color tint in yellow
 607                 drawfill('0 0 0', autocvar_vid_conwidth * '1 0 0' + autocvar_vid_conheight * '0 1 0', '0.5 1 0.3', 1, DRAWFLAG_MODULATE);
 608
 609                 // draw BG
 610                 a = Noise_Pink(nightvision_noise, frametime * 1.5) * 0.05 + 0.15;
 611                 rgb = '1 1 1';
 612                 tc_00 = '0 0 0' + '0.2 0 0' * sin(time * 0.3) + '0 0.3 0' * cos(time * 0.7);
 613                 tc_01 = '0 2.25 0' + '0.6 0 0' * cos(time * 1.2) - '0 0.3 0' * sin(time * 2.2);
 614                 tc_10 = '1.5 0 0' - '0.2 0 0' * sin(time * 0.5) + '0 0.5 0' * cos(time * 1.7);
 615                 //tc_11 = '1 1 0' + '0.6 0 0' * sin(time * 0.6) + '0 0.3 0' * cos(time * 0.1);
 616                 tc_11 = tc_01 + tc_10 - tc_00;
 617                 R_BeginPolygon("gfx/nightvision-bg.tga", DRAWFLAG_ADDITIVE);
 618                 R_PolygonVertex('0 0 0', tc_00, rgb, a);
 619                 R_PolygonVertex(autocvar_vid_conwidth * '1 0 0', tc_10, rgb, a);
 620                 R_PolygonVertex(autocvar_vid_conwidth * '1 0 0' + autocvar_vid_conheight * '0 1 0', tc_11, rgb, a);
 621                 R_PolygonVertex(autocvar_vid_conheight * '0 1 0', tc_01, rgb, a);
 622                 R_EndPolygon();
 623
 624                 // draw FG
 625                 a = Noise_Pink(nightvision_noise2, frametime * 0.1) * 0.05 + 0.12;
 626                 rgb = '0.3 0.6 0.4' + '0.1 0.4 0.2' * Noise_White(nightvision_noise2, frametime);
 627                 tc_00 = '0 0 0' + '1 0 0' * Noise_White(nightvision_noise2, frametime) + '0 1 0' * Noise_White(nightvision_noise2, frametime);
 628                 tc_01 = tc_00 + '0 3 0' * (1 + Noise_White(nightvision_noise2, frametime) * 0.2);
 629                 tc_10 = tc_00 + '2 0 0' * (1 + Noise_White(nightvision_noise2, frametime) * 0.3);
 630                 tc_11 = tc_01 + tc_10 - tc_00;
 631                 R_BeginPolygon("gfx/nightvision-fg.tga", DRAWFLAG_ADDITIVE);
 632                 R_PolygonVertex('0 0 0', tc_00, rgb, a);
 633                 R_PolygonVertex(autocvar_vid_conwidth * '1 0 0', tc_10, rgb, a);
 634                 R_PolygonVertex(autocvar_vid_conwidth * '1 0 0' + autocvar_vid_conheight * '0 1 0', tc_11, rgb, a);
 635                 R_PolygonVertex(autocvar_vid_conheight * '0 1 0', tc_01, rgb, a);
 636                 R_EndPolygon();
 637         }
 638
 639         // Draw the aiming reticle for weapons that use it
 640         // reticle_type is changed to the item we are zooming / aiming with, to decide which reticle to use
 641         // It must be a persisted float for fading out to work properly (you let go of the zoom button for
 642         // the view to go back to normal, so reticle_type would become 0 as we fade out)
 643         if(spectatee_status || getstati(STAT_HEALTH) <= 0)
 644                 reticle_type = 0; // prevent reticle from showing during the respawn zoom effect or for spectators
 645         else if(activeweapon == WEP_NEX && (button_zoom || zoomscript_caught) || activeweapon == WEP_SNIPERRIFLE && (button_zoom || zoomscript_caught) || activeweapon == WEP_MINSTANEX && (button_zoom || zoomscript_caught))
 646                 reticle_type = 2; // nex zoom
 647         else if(button_zoom || zoomscript_caught)
 648                 reticle_type = 1; // normal zoom
 649         else if(activeweapon == WEP_NEX && button_attack2 || activeweapon == WEP_SNIPERRIFLE && button_attack2)
 650                 reticle_type = 2; // nex zoom
 651
 652         if(autocvar_cl_reticle_stretch)
 653         {
 654                 reticle_size_x = vid_conwidth;
 655                 reticle_size_y = vid_conheight;
 656                 reticle_pos_x = 0;
 657                 reticle_pos_y = 0;
 658         }
 659         else
 660         {
 661                 reticle_size_x = max(vid_conwidth, vid_conheight);
 662                 reticle_size_y = max(vid_conwidth, vid_conheight);
 663                 reticle_pos_x = (vid_conwidth - reticle_size_x) / 2;
 664                 reticle_pos_y = (vid_conheight - reticle_size_y) / 2;
 665         }
 666
 667         f = current_zoomfraction;
 668         if(zoomscript_caught)
 669                 f = 1;
 670         if(autocvar_cl_reticle_item_normal)
 671         {
 672                 precache_pic("gfx/reticle_normal");
 673                 if(reticle_type == 1 && f)
 674                         drawpic(reticle_pos, "gfx/reticle_normal", reticle_size, '1 1 1', f * autocvar_cl_reticle_item_normal, DRAWFLAG_NORMAL);
 675         }
 676         if(autocvar_cl_reticle_item_nex)
 677         {
 678                 precache_pic("gfx/reticle_nex");
 679                 if(reticle_type == 2 && f)
 680                         drawpic(reticle_pos, "gfx/reticle_nex", reticle_size, '1 1 1', f * autocvar_cl_reticle_item_nex, DRAWFLAG_NORMAL);
 681         }
 682
 683
 684         // improved polyblend
 685         vector rgb;
 686         if(autocvar_hud_contents)
 687         {
 688                 float contentalpha_temp, incontent, liquidalpha, contentfadetime;
 689                 vector liquidcolor;
 690
 691                 switch(pointcontents(view_origin))
 692                 {
 693                         case CONTENT_WATER:
 694                                 liquidalpha = autocvar_hud_contents_water_alpha;
 695                                 liquidcolor = stov(autocvar_hud_contents_water_color);
 696                                 incontent = 1;
 697                                 break;
 698
 699                         case CONTENT_LAVA:
 700                                 liquidalpha = autocvar_hud_contents_lava_alpha;
 701                                 liquidcolor = stov(autocvar_hud_contents_lava_color);
 702                                 incontent = 1;
 703                                 break;
 704
 705                         case CONTENT_SLIME:
 706                                 liquidalpha = autocvar_hud_contents_slime_alpha;
 707                                 liquidcolor = stov(autocvar_hud_contents_slime_color);
 708                                 incontent = 1;
 709                                 break;
 710
 711                         default:
 712                                 liquidalpha = 0;
 713                                 liquidcolor = '0 0 0';
 714                                 incontent = 0;
 715                                 break;
 716                 }
 717
 718                 if(incontent) // fade in/out at different speeds so you can do e.g. instant fade when entering water and slow when leaving it.
 719                 { // also lets delcare previous values for blending properties, this way it isn't reset until after you have entered a different content
 720                         contentfadetime = autocvar_hud_contents_fadeintime;
 721                         liquidalpha_prev = liquidalpha;
 722                         liquidcolor_prev = liquidcolor;
 723                 }
 724                 else
 725                         contentfadetime = autocvar_hud_contents_fadeouttime;
 726
 727                 contentalpha_temp = bound(0, drawframetime / max(0.0001, contentfadetime), 1);
 728                 contentavgalpha = contentavgalpha * (1 - contentalpha_temp) + incontent * contentalpha_temp;
 729
 730                 if(contentavgalpha)
 731                         drawfill('0 0 0', eX * vid_conwidth + eY * vid_conheight, liquidcolor_prev, contentavgalpha * liquidalpha_prev, DRAWFLAG_NORMAL);
 732
 733                 if(autocvar_hud_postprocessing)
 734                 {
 735                         if(autocvar_hud_contents_blur && contentavgalpha)
 736                         {
 737                                 content_blurpostprocess_x = 1;
 738                                 content_blurpostprocess_y = contentavgalpha * autocvar_hud_contents_blur;
 739                                 content_blurpostprocess_z = contentavgalpha * autocvar_hud_contents_blur_alpha;
 740                         }
 741                         else
 742                         {
 743                                 content_blurpostprocess_x = 0;
 744                                 content_blurpostprocess_y = 0;
 745                                 content_blurpostprocess_z = 0;
 746                         }
 747                 }
 748         }
 749
 750         if(autocvar_hud_damage)
 751         {
 752                 float myhealth_flash_temp;
 753                 myhealth = getstati(STAT_HEALTH);
 754
 755                 // fade out
 756                 myhealth_flash = max(0, myhealth_flash - autocvar_hud_damage_fade_rate * frametime);
 757                 // add new damage
 758                 myhealth_flash = bound(0, myhealth_flash + dmg_take * autocvar_hud_damage_factor, autocvar_hud_damage_maxalpha);
 759
 760                 float pain_threshold, pain_threshold_lower, pain_threshold_lower_health;
 761                 pain_threshold = autocvar_hud_damage_pain_threshold;
 762                 pain_threshold_lower = autocvar_hud_damage_pain_threshold_lower;
 763                 pain_threshold_lower_health = autocvar_hud_damage_pain_threshold_lower_health;
 764
 765                 if(pain_threshold_lower && myhealth < pain_threshold_lower_health)
 766                 {
 767                         pain_threshold = pain_threshold - max(autocvar_hud_damage_pain_threshold_pulsating_min, fabs(sin(M_PI * time / autocvar_hud_damage_pain_threshold_pulsating_period))) * pain_threshold_lower * (1 - max(0, myhealth)/pain_threshold_lower_health);
 768                 }
 769
 770                 myhealth_flash_temp = bound(0, myhealth_flash - pain_threshold, 1);
 771
 772                 if(myhealth_prev < 1)
 773                 {
 774                         if(myhealth >= 1)
 775                         {
 776                                 myhealth_flash = 0; // just spawned, clear the flash immediately
 777                                 myhealth_flash_temp = 0;
 778                         }
 779                         else
 780                         {
 781                                 myhealth_flash += autocvar_hud_damage_fade_rate * frametime; // dead
 782                         }
 783                 }
 784
 785                 if(spectatee_status == -1 || intermission)
 786                 {
 787                         myhealth_flash = 0; // observing, or match ended
 788                         myhealth_flash_temp = 0;
 789                 }
 790
 791                 myhealth_prev = myhealth;
 792
 793                 if(autocvar_cl_gentle_damage || autocvar_cl_gentle)
 794                 {
 795                         if(autocvar_cl_gentle_damage == 2)
 796                         {
 797                                 if(myhealth_flash < pain_threshold) // only randomize when the flash is gone
 798                                 {
 799                                         myhealth_gentlergb = eX * random() + eY * random() + eZ * random();
 800                                 }
 801                         }
 802                         else
 803                                 myhealth_gentlergb = stov(autocvar_hud_damage_gentle_color);
 804
 805                         drawfill('0 0 0', eX * vid_conwidth + eY * vid_conheight, myhealth_gentlergb, autocvar_hud_damage_gentle_alpha_multiplier * bound(0, myhealth_flash_temp, 1) * autocvar_hud_damage, DRAWFLAG_NORMAL);
 806                 }
 807                 else
 808                         drawpic(reticle_pos, "gfx/blood", reticle_size, stov(autocvar_hud_damage_color), bound(0, myhealth_flash_temp, 1) * autocvar_hud_damage, DRAWFLAG_NORMAL);
 809
 810                 if(autocvar_hud_postprocessing)
 811                 {
 812                         if(autocvar_hud_damage_blur && myhealth_flash_temp)
 813                         {
 814                                 damage_blurpostprocess_x = 1;
 815                                 damage_blurpostprocess_y = bound(0, myhealth_flash_temp, 1) * autocvar_hud_damage_blur;
 816                                 damage_blurpostprocess_z = bound(0, myhealth_flash_temp, 1) * autocvar_hud_damage_blur_alpha;
 817                         }
 818                         else
 819                         {
 820                                 damage_blurpostprocess_x = 0;
 821                                 damage_blurpostprocess_y = 0;
 822                                 damage_blurpostprocess_z = 0;
 823                         }
 824                 }
 825         }
 826
 827         if(autocvar_hud_postprocessing)
 828         {
 829                 // lets apply the postprocess effects from the previous two functions if needed
 830                 if(damage_blurpostprocess_x || content_blurpostprocess_x)
 831                 {
 832                         float blurradius = bound(0, damage_blurpostprocess_y + content_blurpostprocess_y, autocvar_hud_postprocessing_maxblurradius);
 833                         float bluralpha = bound(0, damage_blurpostprocess_z + content_blurpostprocess_z, autocvar_hud_postprocessing_maxbluralpha);
 834                         if(blurradius != old_blurradius || bluralpha != old_bluralpha) // reduce cvar_set spam as much as possible
 835                         {
 836                                 cvar_set("r_glsl_postprocess_uservec1", strcat(ftos(blurradius), " ", ftos(bluralpha), " 0 0"));
 837                                 cvar_set("r_glsl_postprocess_uservec1_enable", "1");
 838                                 old_blurradius = blurradius;
 839                                 old_bluralpha = bluralpha;
 840                         }
 841                 }
 842                 else if(cvar("r_glsl_postprocess_uservec1_enable")) // reduce cvar_set spam as much as possible
 843                 {
 844                         cvar_set("r_glsl_postprocess_uservec1", "0 0 0 0");
 845                         cvar_set("r_glsl_postprocess_uservec1_enable", "0");
 846                 }
 847
 848                 if(autocvar_hud_powerup)
 849                 {
 850                         float sharpen_intensity;
 851                         if (getstatf(STAT_STRENGTH_FINISHED) - time > 0)
 852                                 sharpen_intensity += (getstatf(STAT_STRENGTH_FINISHED) - time);
 853                         if (getstatf(STAT_INVINCIBLE_FINISHED) - time > 0)
 854                                 sharpen_intensity += (getstatf(STAT_INVINCIBLE_FINISHED) - time);
 855                         sharpen_intensity = bound(0, sharpen_intensity, 5); // powerup warning time is 5 seconds, so fade the effect from there
 856
 857                         if(sharpen_intensity > 0)
 858                         {
 859                                 if(sharpen_intensity != old_sharpen_intensity) // reduce cvar_set spam as much as possible
 860                                 {
 861                                         cvar_set("r_glsl_postprocess_uservec2", strcat("0 ", ftos(-sharpen_intensity * cvar("hud_powerup")), " 0 0"));
 862                                         cvar_set("r_glsl_postprocess_uservec2_enable", "1");
 863                                         old_sharpen_intensity = sharpen_intensity;
 864                                 }
 865                         }
 866                         else if(cvar("r_glsl_postprocess_uservec2_enable")) // reduce cvar_set spam as much as possible
 867                         {
 868                                 cvar_set("r_glsl_postprocess_uservec2", "0 0 0 0");
 869                                 cvar_set("r_glsl_postprocess_uservec2_enable", "0");
 870                         }
 871                 }
 872         }
 873
 874         if not(autocvar_hud_damage && autocvar_hud_postprocessing)
 875         {
 876                 // don't allow blur to get stuck on if we disable the cvar while damaged
 877                 cvar_set("r_glsl_postprocess_uservec1", "0 0 0 0");
 878                 cvar_set("r_glsl_postprocess_uservec1_enable", "0");
 879         }
 880         if not(autocvar_hud_powerup && autocvar_hud_postprocessing)
 881         {
 882                 // don't allow sharpen to get stuck on if we disable the cvar while powered up
 883                 cvar_set("r_glsl_postprocess_uservec2", "0 0 0 0");
 884                 cvar_set("r_glsl_postprocess_uservec2_enable", "0");
 885         }
 886
 887         // Draw the mouse cursor
 888         // NOTE: drawpic must happen after R_RenderScene for some reason
 889         //drawpic(getmousepos(), "gfx/cursor.tga", '11 14 0', '1 1 1', 1, 0);
 890         //drawstring('50 50', ftos(game), '10 10 0', '1 1 1', 1, 0);
 891         //self = edict_num(player_localnum);
 892         //drawstring('0 0', vtos(pmove_org), '8 8 0', '1 1 1', 1, 0);
 893         //drawstring('0 8', strcat("ORG: ", vtos(self.origin), " state: ", ftos(self.ctf_state), " HP: ", ftos(self.health)), '8 8 0', '1 1 1', 1, 0);
 894         // as long as the ctf part isn't in, this is useless
 895         if(menu_visible)
 896                 menu_show();
 897
 898         /*if(gametype == GAME_CTF)
 899           {
 900           ctf_view();
 901           } else */
 902
 903         // draw 2D entities
 904         e = self;
 905         for(self = world; (self = nextent(self)); )
 906                 if(self.draw2d)
 907                         self.draw2d();
 908         self = e;
 909
 910         scoreboard_active = HUD_WouldDrawScoreboard();
 911
 912         hit_time = getstatf(STAT_HIT_TIME);
 913         if(hit_time > nextsound_hit_time && autocvar_cl_hitsound)
 914         {
 915                 sound(world, CHAN_AUTO, "misc/hit.wav", VOL_BASE, ATTN_NONE);
 916                 nextsound_hit_time = time + autocvar_cl_hitsound_antispam_time;
 917         }
 918         typehit_time = getstatf(STAT_TYPEHIT_TIME);
 919         if(typehit_time > nextsound_typehit_time)
 920         {
 921                 sound(world, CHAN_AUTO, "misc/typehit.wav", VOL_BASE, ATTN_NONE);
 922                 nextsound_typehit_time = time + autocvar_cl_hitsound_antispam_time;
 923         }
 924
 925         float hud;
 926         hud = getstati(STAT_HUD);
 927         if(hud == HUD_SPIDERBOT)
 928                 CSQC_SPIDER_HUD();
 929         else if(hud == HUD_WAKIZASHI)
 930         CSQC_WAKIZASHI_HUD();
 931     else if(hud == HUD_RAPTOR)
 932         CSQC_RAPTOR_HUD();
 933         else
 934         {
 935                 if(gametype == GAME_FREEZETAG)
 936                 {
 937                         if(getstati(STAT_FROZEN))
 938                                 drawfill('0 0 0', eX * vid_conwidth + eY * vid_conheight, '0.25 0.90 1', autocvar_hud_colorflash_alpha, DRAWFLAG_ADDITIVE);
 939                         if(getstatf(STAT_REVIVE_PROGRESS))
 940                         {
 941                                 DrawCircleClippedPic(eX * 0.5 * vid_conwidth + eY * 0.6 * vid_conheight, 0.1 * vid_conheight, "gfx/crosshair_ring.tga", getstatf(STAT_REVIVE_PROGRESS), '0.25 0.90 1', autocvar_hud_colorflash_alpha, DRAWFLAG_ADDITIVE);
 942                                 drawstring_aspect(eY * 0.64 * vid_conheight, "Revival progress", eX * vid_conwidth + eY * 0.025 * vid_conheight, '1 1 1', 1, DRAWFLAG_NORMAL);
 943                         }
 944                 }
 945
 946                 if(autocvar_r_letterbox == 0)
 947                         if(autocvar_viewsize < 120)
 948                                 CSQC_common_hud();
 949
 950                 // crosshair goes VERY LAST
 951                 if(!scoreboard_active && !camera_active && intermission != 2) {
 952                         string wcross_style;
 953                         float wcross_alpha, wcross_resolution;
 954                         wcross_style = autocvar_crosshair;
 955                         if (wcross_style == "0")
 956                                 return;
 957                         wcross_resolution = autocvar_crosshair_size;
 958                         if (wcross_resolution == 0)
 959                                 return;
 960                         wcross_alpha = autocvar_crosshair_alpha;
 961                         if (wcross_alpha == 0)
 962                                 return;
 963
 964                         // TrueAim check
 965                         float shottype;
 966                         float bullets, ring_scale;
 967                         // wcross_origin = '0.5 0 0' * vid_conwidth + '0 0.5 0' * vid_conheight;
 968                         wcross_origin = project_3d_to_2d(view_origin + MAX_SHOT_DISTANCE * view_forward);
 969                         wcross_origin_z = 0;
 970                         if(autocvar_crosshair_hittest)
 971                         {
 972                                 vector wcross_oldorigin;
 973                                 wcross_oldorigin = wcross_origin;
 974                                 shottype = TrueAimCheck();
 975                                 if(shottype == SHOTTYPE_HITWORLD)
 976                                 {
 977                                         v = wcross_origin - wcross_oldorigin;
 978                                         v_x /= vid_conwidth;
 979                                         v_y /= vid_conheight;
 980                                         if(vlen(v) > 0.01)
 981                                                 shottype = SHOTTYPE_HITOBSTRUCTION;
 982                                 }
 983                                 if(!autocvar_crosshair_hittest_showimpact)
 984                                         wcross_origin = wcross_oldorigin;
 985                         }
 986                         else
 987                                 shottype = SHOTTYPE_HITWORLD;
 988
 989                         vector wcross_color, wcross_size;
 990                         string wcross_wep, wcross_name;
 991                         float wcross_scale, wcross_blur;
 992
 993                         if (autocvar_crosshair_per_weapon || autocvar_crosshair_color_per_weapon) {
 994                                 e = get_weaponinfo(activeweapon);
 995                                 if (e && e.netname != "")
 996                                 {
 997                                         wcross_wep = e.netname;
 998                                         if(autocvar_crosshair_per_weapon)
 999                                         {
1000                                                 wcross_resolution *= cvar(strcat("crosshair_", wcross_wep, "_size"));
1001                                                 if (wcross_resolution == 0)
1002                                                         return;
1003                                                 wcross_alpha *= cvar(strcat("crosshair_", wcross_wep, "_alpha"));
1004                                                 if (wcross_alpha == 0)
1005                                                         return;
1006
1007                                                 wcross_style = cvar_string(strcat("crosshair_", wcross_wep));
1008                                                 if(wcross_style == "" || wcross_style == "0")
1009                                                         wcross_style = wcross_wep;
1010                                         }
1011                                 }
1012                         }
1013                         if(wcross_wep != "" && autocvar_crosshair_color_per_weapon)
1014                                 wcross_color = stov(cvar_string(strcat("crosshair_", wcross_wep, "_color")));
1015                         else if(autocvar_crosshair_color_by_health)
1016                         {
1017                                 local float x = getstati(STAT_HEALTH);
1018
1019                                 //x = red
1020                                 //y = green
1021                                 //z = blue
1022
1023                                 wcross_color_z = 0;
1024
1025                                 if(x > 200)
1026                                 {
1027                                         wcross_color_x = 0;
1028                                         wcross_color_y = 1;
1029                                 }
1030                                 else if(x > 150)
1031                                 {
1032                                         wcross_color_x = 0.4 - (x-150)*0.02 * 0.4;
1033                                         wcross_color_y = 0.9 + (x-150)*0.02 * 0.1;
1034                                 }
1035                                 else if(x > 100)
1036                                 {
1037                                         wcross_color_x = 1 - (x-100)*0.02 * 0.6;
1038                                         wcross_color_y = 1 - (x-100)*0.02 * 0.1;
1039                                         wcross_color_z = 1 - (x-100)*0.02;
1040                                 }
1041                                 else if(x > 50)
1042                                 {
1043                                         wcross_color_x = 1;
1044                                         wcross_color_y = 1;
1045                                         wcross_color_z = 0.2 + (x-50)*0.02 * 0.8;
1046                                 }
1047                                 else if(x > 20)
1048                                 {
1049                                         wcross_color_x = 1;
1050                                         wcross_color_y = (x-20)*90/27/100;
1051                                         wcross_color_z = (x-20)*90/27/100 * 0.2;
1052                                 }
1053                                 else
1054                                 {
1055                                         wcross_color_x = 1;
1056                                         wcross_color_y = 0;
1057                                 }
1058                         }
1059                         else
1060                                 wcross_color = stov(autocvar_crosshair_color);
1061
1062                         wcross_name = strcat("gfx/crosshair", wcross_style);
1063
1064                         if(autocvar_crosshair_effect_scalefade)
1065                         {
1066                                 wcross_scale = wcross_resolution;
1067                                 wcross_resolution = 1;
1068                         }
1069                         else
1070                         {
1071                                 wcross_scale = 1;
1072                         }
1073
1074                         if(autocvar_crosshair_pickup)
1075                         {
1076                                 if(pickup_crosshair_time < getstatf(STAT_LAST_PICKUP))
1077                                 {
1078                                         pickup_crosshair_size = 1;
1079                                         pickup_crosshair_time = getstatf(STAT_LAST_PICKUP);
1080                                 }
1081
1082                                 if(pickup_crosshair_size > 0)
1083                                         pickup_crosshair_size -= autocvar_crosshair_pickup_speed * frametime;
1084                                 else
1085                                         pickup_crosshair_size = 0;
1086
1087                                 wcross_scale += sin(pickup_crosshair_size) * autocvar_crosshair_pickup;
1088                         }
1089
1090                         vector hitindication_color;
1091                         if(autocvar_crosshair_hitindication)
1092                         {
1093                                 hitindication_color = stov(autocvar_crosshair_hitindication_color);
1094                                 if(hitindication_crosshair_time < hit_time)
1095                                 {
1096                                         hitindication_crosshair_size = 1;
1097                                         hitindication_crosshair_time = hit_time;
1098                                 }
1099
1100                                 if(hitindication_crosshair_size > 0)
1101                                         hitindication_crosshair_size -= autocvar_crosshair_hitindication_speed * frametime;
1102                                 else
1103                                         hitindication_crosshair_size = 0;
1104
1105                                 wcross_scale += sin(hitindication_crosshair_size) * autocvar_crosshair_hitindication;
1106                                 wcross_color_x += sin(hitindication_crosshair_size) * hitindication_color_x;
1107                                 wcross_color_y += sin(hitindication_crosshair_size) * hitindication_color_y;
1108                                 wcross_color_z += sin(hitindication_crosshair_size) * hitindication_color_z;
1109                         }
1110
1111                         if(shottype == SHOTTYPE_HITENEMY)
1112                                 wcross_scale *= autocvar_crosshair_hittest; // is not queried if hittest is 0
1113                         if(shottype == SHOTTYPE_HITTEAM)
1114                                 wcross_scale /= autocvar_crosshair_hittest; // is not queried if hittest is 0
1115
1116                         f = autocvar_crosshair_effect_speed;
1117                         if(f < 0)
1118                                 f *= -2 * g_weaponswitchdelay;
1119                         if(wcross_scale != wcross_scale_goal_prev || wcross_alpha != wcross_alpha_goal_prev || wcross_color != wcross_color_goal_prev)
1120                         {
1121                                 wcross_changedonetime = time + f;
1122                         }
1123                         if(wcross_name != wcross_name_goal_prev || wcross_resolution != wcross_resolution_goal_prev)
1124                         {
1125                                 wcross_name_changestarttime = time;
1126                                 wcross_name_changedonetime = time + f;
1127                                 if(wcross_name_goal_prev_prev)
1128                                         strunzone(wcross_name_goal_prev_prev);
1129                                 wcross_name_goal_prev_prev = wcross_name_goal_prev;
1130                                 wcross_name_goal_prev = strzone(wcross_name);
1131                                 wcross_name_alpha_goal_prev_prev = wcross_name_alpha_goal_prev;
1132                                 wcross_resolution_goal_prev_prev = wcross_resolution_goal_prev;
1133                                 wcross_resolution_goal_prev = wcross_resolution;
1134                         }
1135
1136                         wcross_scale_goal_prev = wcross_scale;
1137                         wcross_alpha_goal_prev = wcross_alpha;
1138                         wcross_color_goal_prev = wcross_color;
1139
1140                         if(shottype == SHOTTYPE_HITTEAM || (shottype == SHOTTYPE_HITOBSTRUCTION && autocvar_crosshair_hittest_blur && !autocvar_chase_active))
1141                         {
1142                                 wcross_blur = 1;
1143                                 wcross_alpha *= 0.75;
1144                         }
1145                         else
1146                                 wcross_blur = 0;
1147                         // *_prev is at time-frametime
1148                         // * is at wcross_changedonetime+f
1149                         // what do we have at time?
1150                         if(time < wcross_changedonetime)
1151                         {
1152                                 f = frametime / (wcross_changedonetime - time + frametime);
1153                                 wcross_scale = f * wcross_scale + (1 - f) * wcross_scale_prev;
1154                                 wcross_alpha = f * wcross_alpha + (1 - f) * wcross_alpha_prev;
1155                                 wcross_color = f * wcross_color + (1 - f) * wcross_color_prev;
1156                         }
1157
1158                         wcross_scale_prev = wcross_scale;
1159                         wcross_alpha_prev = wcross_alpha;
1160                         wcross_color_prev = wcross_color;
1161
1162                         wcross_scale *= 1 - autocvar__menu_alpha;
1163                         wcross_alpha *= 1 - autocvar__menu_alpha;
1164
1165                         ring_scale = autocvar_crosshair_ring_size;
1166
1167                         wcross_size = drawgetimagesize(wcross_name) * wcross_scale;
1168
1169                         float nex_charge, nex_chargepool;
1170                         nex_charge = getstatf(STAT_NEX_CHARGE);
1171                         nex_chargepool = getstatf(STAT_NEX_CHARGEPOOL);
1172
1173                         if(nex_charge_movingavg == 0) // this should only happen if we have just loaded up the game
1174                                 nex_charge_movingavg = nex_charge;
1175
1176                         // ring around crosshair representing bullets left in camping rifle clip
1177                         if (activeweapon == WEP_SNIPERRIFLE && cr_maxbullets)
1178                         {
1179                                 bullets = getstati(STAT_BULLETS_LOADED);
1180                                 f = bound(0, bullets / cr_maxbullets, 1);
1181
1182                                 a = autocvar_crosshair_ring_sniperrifle_alpha;
1183                                 DrawCircleClippedPic(wcross_origin, wcross_size_x * ring_scale, "gfx/crosshair_ring.tga", f, wcross_color, wcross_alpha * a, DRAWFLAG_ADDITIVE);
1184                         }
1185                         else if (activeweapon == WEP_NEX && nex_charge) // ring around crosshair representing velocity-dependent damage for the nex
1186                         {
1187                                 if(nex_chargepool || use_nex_chargepool)
1188                                 {
1189                                         use_nex_chargepool = 1;
1190
1191                                         a = autocvar_crosshair_ring_nex_inner_alpha;
1192                                         rgb = eX * autocvar_crosshair_ring_nex_inner_color_red + eY * autocvar_crosshair_ring_nex_inner_color_green + eZ * autocvar_crosshair_ring_nex_inner_color_blue;
1193                                         DrawCircleClippedPic(wcross_origin, wcross_size_x * ring_scale, "gfx/crosshair_ring_inner.tga", nex_chargepool, rgb, wcross_alpha * a, DRAWFLAG_ADDITIVE);
1194                                 }
1195                                 else
1196                                 {
1197                                         // indicate how much we're charging right now with an inner circle
1198                                         a = autocvar_crosshair_ring_nex_inner_alpha;
1199                                         nex_charge_movingavg = (1 - autocvar_crosshair_ring_nex_currentcharge_movingavg_rate) * nex_charge_movingavg + autocvar_crosshair_ring_nex_currentcharge_movingavg_rate * nex_charge;
1200
1201                                         rgb = eX * autocvar_crosshair_ring_nex_inner_color_red + eY * autocvar_crosshair_ring_nex_inner_color_green + eZ * autocvar_crosshair_ring_nex_inner_color_blue;
1202                                         DrawCircleClippedPic(wcross_origin, wcross_size_x * ring_scale, "gfx/crosshair_ring_inner.tga", bound(0, autocvar_crosshair_ring_nex_currentcharge_scale * (nex_charge - nex_charge_movingavg), 1), rgb, wcross_alpha * a, DRAWFLAG_ADDITIVE);
1203                                 }
1204
1205                                 // draw the charge
1206                                 a = autocvar_crosshair_ring_nex_outer_alpha;
1207                                 DrawCircleClippedPic(wcross_origin, wcross_size_x * ring_scale, "gfx/crosshair_ring.tga", nex_charge, wcross_color, wcross_alpha * a, DRAWFLAG_ADDITIVE);
1208                         }
1209
1210 #define CROSSHAIR_DO_BLUR(M,sz,wcross_name,wcross_alpha) \
1211                         do \
1212                         { \
1213                                 if(wcross_blur > 0) \
1214                                 { \
1215                                         for(i = -2; i <= 2; ++i) \
1216                                                 for(j = -2; j <= 2; ++j) \
1217                                                         M(i,j,sz,wcross_name,wcross_alpha*0.04); \
1218                                 } \
1219                                 else \
1220                                 { \
1221                                         M(0,0,sz,wcross_name,wcross_alpha); \
1222                                 } \
1223                         } \
1224                         while(0)
1225
1226 #define CROSSHAIR_DRAW_SINGLE(i,j,sz,wcross_name,wcross_alpha) \
1227                         drawpic(wcross_origin - ('0.5 0 0' * (sz * wcross_size_x + i * wcross_blur) + '0 0.5 0' * (sz * wcross_size_y + j * wcross_blur)), wcross_name, sz * wcross_size, wcross_color, wcross_alpha, DRAWFLAG_NORMAL)
1228
1229 #define CROSSHAIR_DRAW(sz,wcross_name,wcross_alpha) \
1230                         CROSSHAIR_DO_BLUR(CROSSHAIR_DRAW_SINGLE,sz,wcross_name,wcross_alpha)
1231
1232                         if(time < wcross_name_changedonetime && wcross_name != wcross_name_goal_prev_prev && wcross_name_goal_prev_prev)
1233                         {
1234                                 f = (wcross_name_changedonetime - time) / (wcross_name_changedonetime - wcross_name_changestarttime);
1235                                 wcross_size = drawgetimagesize(wcross_name_goal_prev_prev) * wcross_scale;
1236                                 CROSSHAIR_DRAW(wcross_resolution_goal_prev_prev, wcross_name_goal_prev_prev, wcross_alpha * f * wcross_name_alpha_goal_prev_prev);
1237                                 f = 1 - f;
1238                         }
1239                         else
1240                         {
1241                                 f = 1;
1242                         }
1243
1244                         wcross_size = drawgetimagesize(wcross_name) * wcross_scale;
1245                         CROSSHAIR_DRAW(wcross_resolution, wcross_name, wcross_alpha * f);
1246
1247                         if(autocvar_crosshair_dot)
1248             {
1249                 vector wcross_color_old;
1250                 wcross_color_old = wcross_color;
1251                 if(autocvar_crosshair_dot_color != "0")
1252                     wcross_color = stov(autocvar_crosshair_dot_color);
1253                                 CROSSHAIR_DRAW(wcross_resolution * autocvar_crosshair_dot_size, "gfx/crosshairdot.tga", f * autocvar_crosshair_dot_alpha);
1254                 wcross_color = wcross_color_old;
1255             }
1256
1257                         wcross_name_alpha_goal_prev = f;
1258                 }
1259                 else
1260                 {
1261                         wcross_scale_prev = 0;
1262                         wcross_alpha_prev = 0;
1263                         wcross_scale_goal_prev = 0;
1264                         wcross_alpha_goal_prev = 0;
1265                         wcross_changedonetime = 0;
1266                         if(wcross_name_goal_prev)
1267                                 strunzone(wcross_name_goal_prev);
1268                         wcross_name_goal_prev = string_null;
1269                         if(wcross_name_goal_prev_prev)
1270                                 strunzone(wcross_name_goal_prev_prev);
1271                         wcross_name_goal_prev_prev = string_null;
1272                         wcross_name_changestarttime = 0;
1273                         wcross_name_changedonetime = 0;
1274                         wcross_name_alpha_goal_prev = 0;
1275                         wcross_name_alpha_goal_prev_prev = 0;
1276                         wcross_resolution_goal_prev = 0;
1277                         wcross_resolution_goal_prev_prev = 0;
1278                 }
1279         }
1280
1281         if(NextFrameCommand)
1282         {
1283                 localcmd("\n", NextFrameCommand, "\n");
1284                 NextFrameCommand = string_null;
1285         }
1286
1287         // we must do this check AFTER a frame was rendered, or it won't work
1288         if(cs_project_is_b0rked == 0)
1289         {
1290                 string w0, h0;
1291                 w0 = ftos(autocvar_vid_conwidth);
1292                 h0 = ftos(autocvar_vid_conheight);
1293                 //R_SetView(VF_VIEWPORT, '0 0 0', '640 480 0');
1294                 //R_SetView(VF_FOV, '90 90 0');
1295                 R_SetView(VF_ORIGIN, '0 0 0');
1296                 R_SetView(VF_ANGLES, '0 0 0');
1297                 R_SetView(VF_PERSPECTIVE, 1);
1298                 makevectors('0 0 0');
1299                 vector v1, v2;
1300                 cvar_set("vid_conwidth", "800");
1301                 cvar_set("vid_conheight", "600");
1302                 v1 = cs_project(v_forward);
1303                 cvar_set("vid_conwidth", "640");
1304                 cvar_set("vid_conheight", "480");
1305                 v2 = cs_project(v_forward);
1306                 if(v1 == v2)
1307                         cs_project_is_b0rked = 1;
1308                 else
1309                         cs_project_is_b0rked = -1;
1310                 cvar_set("vid_conwidth", w0);
1311                 cvar_set("vid_conheight", h0);
1312         }
1313
1314         if(autocvar__hud_configure)
1315                 HUD_Panel_Mouse();
1316
1317         // let's reset the view back to normal for the end
1318         R_SetView(VF_MIN, '0 0 0');
1319         R_SetView(VF_SIZE, '1 0 0' * w + '0 1 0' * h);
1320 }
1321
1322 #define spider_h "gfx/vehicles/hud_bg.tga"
1323 #define spider_b "gfx/vehicles/sbot.tga"
1324 #define spider_r "gfx/vehicles/sbot_rpods.tga"
1325 #define spider_g "gfx/vehicles/sbot_mguns.tga"
1326 #define spider_s "gfx/vehicles/shiled.tga"
1327 #define spider_a1 "gfx/hud/sb_rocket.tga"
1328 #define spider_a2 "gfx/sb_bullets.tga"
1329
1330 void CSQC_SPIDER_HUD()
1331 {
1332         float rockets, reload, heat, hp, shield;
1333         vector picsize, hudloc;
1334
1335     // Fetch health & ammo stats
1336     hp      = bound(0,getstatf(STAT_VEHICLESTAT_HEALTH), 1);
1337         shield  = bound(0,getstatf(STAT_VEHICLESTAT_SHIELD), 1);
1338         heat    = min(getstatf(STAT_VEHICLESTAT_RELOAD1), 2);
1339         rockets =     getstati(STAT_VEHICLESTAT_AMMO2);
1340         reload  = min(getstatf(STAT_VEHICLESTAT_RELOAD2), 1);
1341
1342     // Draw the crosshairs
1343     picsize = drawgetimagesize(SPIDER_CROSS);
1344     picsize_x *= autocvar_cl_vehicle_spiderbot_cross_size;
1345     picsize_y *= autocvar_cl_vehicle_spiderbot_cross_size;
1346     drawpic('0.5 0 0' * (vid_conwidth - picsize_x) + '0 0.5 0' * (vid_conheight - picsize_y), SPIDER_CROSS, picsize, '1 1 1', autocvar_cl_vehicle_spiderbot_cross_alpha, DRAWFLAG_NORMAL);
1347
1348     hudloc_y =  4;
1349     hudloc_x = 4;
1350
1351     picsize = drawgetimagesize(spider_h) * 0.5;
1352     drawpic(hudloc, spider_h, picsize, '1 1 1', 1, DRAWFLAG_NORMAL);
1353
1354     picsize = drawgetimagesize(spider_a2) * 0.5;
1355     drawpic(hudloc + '120 96  0', spider_a2, picsize, '1 1 1', 1, DRAWFLAG_NORMAL);
1356
1357     drawstring(hudloc + '145 19  0', strcat(ftos(rint(hp * 100)), "%"),'15 15 0','0 1 0', 1, DRAWFLAG_NORMAL);
1358     drawstring(hudloc + '175 34  0', strcat(ftos(rint(shield * 100)), "%"),'15 15 0','0 0 1', 1, DRAWFLAG_NORMAL);
1359     drawstring(hudloc + '136 102  0', strcat(ftos(100 - rint(heat * 100)), "%"),'14 14 0','1 1 0', 1, DRAWFLAG_NORMAL);
1360
1361     picsize = drawgetimagesize(spider_a1) * 0.85;
1362     if(rockets == 9)
1363     {
1364         drawpic(hudloc + '132 54  0', spider_a1, picsize, '-1 -1 -1', 1, DRAWFLAG_NORMAL);
1365         drawstring(hudloc + '179 69 0', strcat(ftos(rint(reload * 100)), "%"),'14 14 0','1 1 0', 1, DRAWFLAG_NORMAL);
1366     }
1367     else
1368     {
1369         drawpic(hudloc + '132 54  0', spider_a1, picsize, '1 1 1', 1, DRAWFLAG_NORMAL);
1370         drawstring(hudloc + '179 69  0', strcat(ftos(9 - rockets), "/8"),'14 14 0','1 1 0', 1, DRAWFLAG_NORMAL);
1371     }
1372
1373     picsize = drawgetimagesize(spider_b) * 0.5;
1374     hudloc_y = 10.5;
1375     hudloc_x = 10.5;
1376
1377     drawpic(hudloc, spider_s, picsize, '1 1 1', shield, DRAWFLAG_NORMAL);
1378     drawpic(hudloc, spider_b, picsize, '0 1 0' * hp + '1 0 0' * (1 - hp), 1, DRAWFLAG_NORMAL);
1379     drawpic(hudloc, spider_r, picsize, '1 1 1' * reload + '1 0 0' * (1 - reload), 1, DRAWFLAG_NORMAL);
1380     drawpic(hudloc, spider_g, picsize, '1 1 1' * (1 - heat) + '1 0 0' *  heat, 1, DRAWFLAG_NORMAL);
1381
1382
1383         /*
1384         // Draw health bar
1385         p = '0.5 0 0' * (vid_conwidth - (rkt_size * 8));
1386         p = p + '0 1 0' * vid_conheight - '0 32 0';
1387         //pp = ('0 1 0' * hp) + ('1 0 0' * (1-hp));
1388         drawfill(p, '256 0 0' * shield + '0 8 0' , '0.5 0.5 1', 0.75, DRAWFLAG_NORMAL);
1389         p_y += 8;
1390         drawfill(p, '256 0 0' * hp + '0 8 0' , '0 1 0', 0.75, DRAWFLAG_NORMAL);
1391         p_x += 256 * hp;
1392         drawfill(p, '256 0 0' * (1-hp) + '0 8 0' , '0 0 0', 0.75, DRAWFLAG_NORMAL);
1393
1394         // Draw minigun heat indicator
1395         p = '0.5 0 0' * (vid_conwidth - 256);
1396         p = p + '0 1 0' * vid_conheight - '0 34  0';
1397         drawfill(p, '256 0 0' * (1-heat) + '0 2 0' ,'0 0 1', 0.5, DRAWFLAG_NORMAL);
1398         p_x += 256 * (1-heat);
1399         drawfill(p, '256 0 0' * heat  + '0 2 0' , '1 0 0', 0.5, DRAWFLAG_NORMAL);
1400
1401
1402         // Draw rocket icons for loaded/empty tubes.
1403         pp = '0.5 0 0' * (vid_conwidth - (rkt_size * 8));
1404         pp += '0 1 0' * vid_conheight - '0 64 0';
1405         for(i = 0; i < 8; ++i)
1406         {
1407                 p = pp + '1 0 0' * (rkt_size * i);
1408                 if(rockets == 8)
1409                 {
1410                         if(floor(reload * 8) == i)
1411                         {
1412                                 drawpic(p, spider_rocket_icon, '1 1 0' * rkt_size, '1 0 0' + '0 1 0' * ((reload*8)-i), 0.75 , DRAWFLAG_NORMAL);
1413                         }
1414                         else if(i < reload * 8)
1415                                 drawpic(p, spider_rocket_icon, '1 1 0' * rkt_size, '1 1 0', 0.75 , DRAWFLAG_NORMAL);
1416                         else
1417                                 drawpic(p, spider_rocket_icon, '1 1 0' * rkt_size, '0.5 0.5 0.5', 0.75, DRAWFLAG_NORMAL);
1418                 }
1419                 else
1420                 {
1421                         if(i < rockets)
1422                                 drawpic(p, spider_rocket_icon, '1 1 0' * rkt_size, '0 0 0', 0.25, DRAWFLAG_NORMAL);
1423                         else
1424                                 drawpic(p, spider_rocket_icon, '1 1 0' * rkt_size, '0 1 0' * reload, 0.75, DRAWFLAG_NORMAL);
1425                 }
1426         }
1427         */
1428
1429         if (scoreboard_showscores)
1430         {
1431                 HUD_DrawScoreboard();
1432                 HUD_DrawCenterPrint();
1433         }
1434
1435 }
1436
1437 #define raptor_h "gfx/vehicles/hud_bg.tga"
1438 #define raptor_b "gfx/vehicles/raptor.tga"
1439 #define raptor_g1 "gfx/vehicles/raptor_guns.tga"
1440 #define raptor_g2 "gfx/vehicles/raptor_bombs.tga"
1441 #define raptor_s "gfx/vehicles/shiled.tga"
1442
1443 void CSQC_RAPTOR_HUD()
1444 {
1445         float reload, hp, shield, energy;
1446         vector picsize, hudloc;
1447
1448     // Fetch health & ammo stats
1449     hp      = bound(0,getstatf(STAT_VEHICLESTAT_HEALTH), 1);
1450         shield  = bound(0,getstatf(STAT_VEHICLESTAT_SHIELD), 1);
1451         reload  = min(getstatf(STAT_VEHICLESTAT_RELOAD1), 1);
1452         energy  = min(getstatf(STAT_VEHICLESTAT_ENERGY),  1);
1453
1454     // Draw the crosshairs
1455     picsize = drawgetimagesize(SPIDER_CROSS);
1456     picsize_x *= autocvar_cl_vehicle_spiderbot_cross_size;
1457     picsize_y *= autocvar_cl_vehicle_spiderbot_cross_size;
1458     drawpic('0.5 0 0' * (vid_conwidth - picsize_x) + '0 0.5 0' * (vid_conheight - picsize_y), SPIDER_CROSS, picsize, '1 1 1', autocvar_cl_vehicle_spiderbot_cross_alpha, DRAWFLAG_NORMAL);
1459
1460     hudloc_y =  4;
1461     hudloc_x = 4;
1462
1463     picsize = drawgetimagesize(raptor_h) * 0.5;
1464     drawpic(hudloc, raptor_h, picsize, '1 1 1', 1, DRAWFLAG_NORMAL);
1465
1466     picsize = drawgetimagesize(spider_a2) * 0.5;
1467     drawpic(hudloc + '120 96  0', spider_a2, picsize, '1 1 1', 1, DRAWFLAG_NORMAL);
1468
1469     drawstring(hudloc + '145 19  0', strcat(ftos(rint(hp * 100)), "%"),'15 15 0','0 1 0', 1, DRAWFLAG_NORMAL);
1470     drawstring(hudloc + '175 34  0', strcat(ftos(rint(shield * 100)), "%"),'15 15 0','0 0 1', 1, DRAWFLAG_NORMAL);
1471     drawstring(hudloc + '136 102 0', strcat(ftos(rint(energy * 100)), "%"),'15 15 0','0.5 0.5 1', 1, DRAWFLAG_NORMAL);
1472
1473
1474     picsize = drawgetimagesize(spider_a1) * 0.85;
1475     if(reload == 1)
1476     {
1477         drawpic(hudloc + '132 54  0', spider_a1, picsize, '1 1 1', 1, DRAWFLAG_NORMAL);
1478         drawstring(hudloc + '179 69  0', strcat(ftos(rint(reload * 100)), "%"),'14 14 0','0 1 0', 0.5, DRAWFLAG_NORMAL);
1479     }
1480     else
1481     {
1482         drawpic(hudloc + '132 54  0', spider_a1, picsize, '1 1 1', 1, DRAWFLAG_NORMAL);
1483         drawstring(hudloc + '179 69  0', strcat(ftos(rint(reload * 100)), "%"),'14 14 0','0 0 1', 1, DRAWFLAG_NORMAL);
1484     }
1485
1486     picsize = drawgetimagesize(raptor_b) * 0.5;
1487     hudloc_y = 10.5;
1488     hudloc_x = 10.5;
1489
1490     drawpic(hudloc, raptor_s, picsize, '1 1 1', shield, DRAWFLAG_NORMAL);
1491     drawpic(hudloc, raptor_b, picsize, '0 1 0' * hp + '1 0 0' * (1 - hp), 1, DRAWFLAG_NORMAL);
1492     drawpic(hudloc, raptor_g1, picsize, '1 1 1' * energy + '1 0 0' * (1 - energy), 1, DRAWFLAG_NORMAL);
1493     drawpic(hudloc, raptor_g2, picsize, '1 1 1' * reload + '1 0 0' *  (1 - reload), 1, DRAWFLAG_NORMAL);
1494
1495
1496         if (scoreboard_showscores)
1497         {
1498                 HUD_DrawScoreboard();
1499                 HUD_DrawCenterPrint();
1500         }
1501
1502 }
1503
1504 #define waki_h "gfx/vehicles/hud_bg.tga"
1505 #define waki_b "gfx/vehicles/waki.tga"
1506 #define waki_e "gfx/vehicles/waki_e.tga"
1507 #define waki_g "gfx/vehicles/waki_guns.tga"
1508 #define waki_r "gfx/vehicles/waki_rockets.tga"
1509 #define waki_s "gfx/vehicles/shiled.tga"
1510
1511 #define waki_a1 "gfx/hud/sb_rocket.tga"
1512 #define waki_a2 "gfx/sb_cells.tga"
1513
1514 void CSQC_WAKIZASHI_HUD()
1515 {
1516         // 0--1 floats. 1 = 100%, 0.6 = 50%.
1517         float health, shield, energy, rockets;
1518         vector picsize, hudloc;
1519
1520     picsize = drawgetimagesize(SPIDER_CROSS);
1521     picsize_x *= autocvar_cl_vehicle_spiderbot_cross_size;
1522     picsize_y *= autocvar_cl_vehicle_spiderbot_cross_size;
1523     drawpic('0.5 0 0' * (vid_conwidth - picsize_x) + '0 0.5 0' * (vid_conheight - picsize_y), SPIDER_CROSS, picsize, '1 1 1', autocvar_cl_vehicle_spiderbot_cross_alpha, DRAWFLAG_NORMAL);
1524
1525 /*
1526 const float STAT_VEHICLESTAT_HEALTH  = 60;
1527 const float STAT_VEHICLESTAT_SHIELD  = 61;
1528 const float STAT_VEHICLESTAT_ENERGY  = 62;
1529 const float STAT_VEHICLESTAT_AMMO1   = 63;
1530 const float STAT_VEHICLESTAT_RELAOD1 = 64;
1531 const float STAT_VEHICLESTAT_AMMO2   = 65;
1532 const float STAT_VEHICLESTAT_RELOAD2 = 66;
1533 */
1534     health  = min(getstatf(STAT_VEHICLESTAT_HEALTH),  1);
1535         shield  = min(getstatf(STAT_VEHICLESTAT_SHIELD),  1);
1536         energy  = min(getstatf(STAT_VEHICLESTAT_ENERGY),  1);
1537         rockets = bound(0,getstatf(STAT_VEHICLESTAT_RELOAD1), 1);
1538
1539     hudloc_y =  4;
1540     hudloc_x = 4;
1541
1542     picsize = drawgetimagesize(waki_h) * 0.5;
1543     drawpic(hudloc, waki_h, picsize, '1 1 1', 1, DRAWFLAG_NORMAL);
1544
1545     picsize = drawgetimagesize(waki_a2) * 0.7;
1546     drawpic(hudloc + '116 92  0', waki_a2, picsize, '1 1 1', 1, DRAWFLAG_NORMAL);
1547
1548
1549     drawstring(hudloc + '145 19  0', strcat(ftos(rint(health * 100)), "%"),'15 15 0','0 1 0', 1, DRAWFLAG_NORMAL);
1550     drawstring(hudloc + '175 34  0', strcat(ftos(rint(shield * 100)), "%"),'15 15 0','0 0 1', 1, DRAWFLAG_NORMAL);
1551
1552     drawstring(hudloc + '136 102  0', strcat(ftos(rint(energy * 100)), "%"),'14 14 0','1 1 1', 1, DRAWFLAG_NORMAL);
1553
1554     picsize = drawgetimagesize(waki_a1) * 0.75;
1555     if(rockets == 1)
1556     {
1557         drawpic(hudloc + '140 55  0', waki_a1, picsize, '1 1 1', 1, DRAWFLAG_NORMAL);
1558         drawpic(hudloc + '144 59  0', waki_a1, picsize, '1 1 1', 1, DRAWFLAG_NORMAL);
1559     }
1560     else
1561     {
1562         drawpic(hudloc + '140 55  0', waki_a1, picsize, '-1 -1 -1', 1, DRAWFLAG_NORMAL);
1563         drawpic(hudloc + '144 59  0', waki_a1, picsize, '-1 -1 -1', 1, DRAWFLAG_NORMAL);
1564         drawstring(hudloc + '165 69 0', strcat(ftos(rint(rockets * 100)), "%"),'14 14 0','1 1 0', 1, DRAWFLAG_NORMAL);
1565     }
1566
1567     picsize = drawgetimagesize(waki_b) * 0.5;
1568     hudloc_y = 10.5;
1569     hudloc_x = 10.5;
1570
1571     drawpic(hudloc, waki_s, picsize, '1 1 1', shield, DRAWFLAG_NORMAL);
1572     drawpic(hudloc, waki_b, picsize, '0 1 0' * health + '1 0 0' * (1 - health), 1, DRAWFLAG_NORMAL);
1573     drawpic(hudloc, waki_r, picsize, '1 1 1' * rockets + '1 0 0' * (1 - rockets), 1, DRAWFLAG_NORMAL);
1574     drawpic(hudloc, waki_e, picsize, '1 1 1' * energy + '1 0 0' *  (1 - energy), 1, DRAWFLAG_NORMAL);
1575
1576
1577
1578         /*
1579         p = '0.5 0 0' * (vid_conwidth - (rkt_size * 8));
1580         p = p + '0 1 0' * vid_conheight - '0 32 0';
1581
1582         // Draw health bar
1583         p_y += 8;
1584         drawfill(p, '256 0 0' * health + '0 8 0' , '0 0.7 0', 0.75, DRAWFLAG_NORMAL);
1585         p_x += 256 * health;
1586         drawfill(p, '256 0 0' * (1 - health) + '0 8 0' , '0 0 0', 0.75, DRAWFLAG_NORMAL);
1587
1588         // Draw shiled bar
1589         p_x -= 256 * health;
1590         p_y += 4;
1591         drawfill(p, '256 0 0' * shield + '0 4 0' , '0.25 0.25 1', 0.5, DRAWFLAG_NORMAL);
1592
1593         // Draw energy
1594         //p_x -= 256 * health;
1595         p_y -= 8;
1596         drawfill(p, '256 0 0' * energy + '0 4 0' , '1 1 1', 0.75, DRAWFLAG_NORMAL);
1597
1598         // Draw rockets bar
1599         p_y += 12;
1600         drawfill(p, '256 0 0' * rockets + '0 4 0' , '1 0 0', 0.75, DRAWFLAG_NORMAL);
1601         */
1602
1603
1604
1605
1606         if (scoreboard_showscores)
1607         {
1608                 HUD_DrawScoreboard();
1609                 HUD_DrawCenterPrint();
1610         }
1611
1612 }
1613
1614
1615 void CSQC_common_hud(void)
1616 {
1617         // HUD_SortFrags(); done in HUD_Draw
1618         float hud;
1619         hud = getstati(STAT_HUD);
1620
1621         //hud = 10;
1622         switch(hud)
1623         {
1624                 case HUD_NORMAL:
1625                         // do some accuracy var caching
1626                         float i;
1627                         if(!(gametype == GAME_RACE || gametype == GAME_CTS))
1628                         {
1629                                 if(autocvar_accuracy_color_levels != acc_color_levels)
1630                                 {
1631                                         if(acc_color_levels)
1632                                                 strunzone(acc_color_levels);
1633                                         acc_color_levels = strzone(autocvar_accuracy_color_levels);
1634                                         acc_levels = tokenize(acc_color_levels);
1635                                         if (acc_levels > MAX_ACCURACY_LEVELS)
1636                                                 acc_levels = MAX_ACCURACY_LEVELS;
1637
1638                                         for (i = 0; i < acc_levels; ++i)
1639                                                 acc_lev[i] = stof(argv(i)) / 100.0;
1640                                 }
1641                                 // let know that acc_col[] needs to be loaded
1642                                 acc_col_x[0] = -1;
1643                         }
1644
1645                         HUD_Main(); // always run these functions for alpha checks
1646                         HUD_DrawScoreboard();
1647
1648                         if (scoreboard_active) // scoreboard/accuracy
1649                         {
1650                                 HUD_Reset();
1651                                 // HUD_DrawScoreboard takes care of centerprint_start
1652                         }
1653                         else if (intermission == 2) // map voting screen
1654                         {
1655                                 HUD_FinaleOverlay();
1656                                 HUD_Reset();
1657
1658                                 centerprint_start_x = 0;
1659                                 centerprint_start_y = autocvar_scr_centerpos * vid_conheight;
1660                         }
1661                         else // hud
1662                         {
1663                                 centerprint_start_x = 0;
1664                                 centerprint_start_y = autocvar_scr_centerpos * vid_conheight;
1665                         }
1666
1667                         HUD_DrawCenterPrint();
1668                         break;
1669
1670                 case HUD_SPIDERBOT:
1671                         CSQC_SPIDER_HUD();
1672                         break;
1673
1674                 case HUD_WAKIZASHI:
1675                         CSQC_WAKIZASHI_HUD();
1676                         break;
1677         }
1678 }
1679
1680
1681 // following vectors must be global to allow seamless switching between camera modes
1682 vector camera_offset, current_camera_offset, mouse_angles, current_angles, current_origin, current_position;
1683 void CSQC_Demo_Camera()
1684 {
1685         float speed, attenuation, dimensions;
1686         vector tmp, delta;
1687
1688         if( autocvar_camera_reset || !camera_mode )
1689         {
1690                 camera_offset = '0 0 0';
1691                 current_angles = '0 0 0';
1692                 camera_direction = '0 0 0';
1693                 camera_offset_z += 30;
1694                 camera_offset_x += 30 * -cos(current_angles_y * DEG2RAD);
1695                 camera_offset_y += 30 * -sin(current_angles_y * DEG2RAD);
1696                 current_origin = view_origin;
1697                 current_camera_offset  = camera_offset;
1698                 cvar_set("camera_reset", "0");
1699                 camera_mode = CAMERA_CHASE;
1700         }
1701
1702         // Camera angles
1703         if( camera_roll )
1704                 mouse_angles_z += camera_roll * autocvar_camera_speed_roll;
1705
1706         if(autocvar_camera_look_player)
1707         {
1708                 local vector dir;
1709                 local float n;
1710
1711                 dir = normalize(view_origin - current_position);
1712                 n = mouse_angles_z;
1713                 mouse_angles = vectoangles(dir);
1714                 mouse_angles_x = mouse_angles_x * -1;
1715                 mouse_angles_z = n;
1716         }
1717         else
1718         {
1719                 tmp = getmousepos() * 0.1;
1720                 if(vlen(tmp)>autocvar_camera_mouse_threshold)
1721                 {
1722                         mouse_angles_x += tmp_y * cos(mouse_angles_z * DEG2RAD) + (tmp_x * sin(mouse_angles_z * DEG2RAD));
1723                         mouse_angles_y -= tmp_x * cos(mouse_angles_z * DEG2RAD) + (tmp_y * -sin(mouse_angles_z * DEG2RAD));
1724                 }
1725         }
1726
1727         while (mouse_angles_x < -180) mouse_angles_x = mouse_angles_x + 360;
1728         while (mouse_angles_x > 180) mouse_angles_x = mouse_angles_x - 360;
1729         while (mouse_angles_y < -180) mouse_angles_y = mouse_angles_y + 360;
1730         while (mouse_angles_y > 180) mouse_angles_y = mouse_angles_y - 360;
1731
1732         // Fix difference when angles don't have the same sign
1733         delta = '0 0 0';
1734         if(mouse_angles_y < -60 && current_angles_y > 60)
1735                 delta = '0 360 0';
1736         if(mouse_angles_y > 60 && current_angles_y < -60)
1737                 delta = '0 -360 0';
1738
1739         if(autocvar_camera_look_player)
1740                 attenuation = autocvar_camera_look_attenuation;
1741         else
1742                 attenuation = autocvar_camera_speed_attenuation;
1743
1744         attenuation = 1 / max(1, attenuation);
1745         current_angles += (mouse_angles - current_angles + delta) * attenuation;
1746
1747         while (current_angles_x < -180) current_angles_x = current_angles_x + 360;
1748         while (current_angles_x > 180) current_angles_x = current_angles_x - 360;
1749         while (current_angles_y < -180) current_angles_y = current_angles_y + 360;
1750         while (current_angles_y > 180) current_angles_y = current_angles_y - 360;
1751
1752         // Camera position
1753         tmp = '0 0 0';
1754         dimensions = 0;
1755
1756         if( camera_direction_x )
1757         {
1758                 tmp_x = camera_direction_x * cos(current_angles_y * DEG2RAD);
1759                 tmp_y = camera_direction_x * sin(current_angles_y * DEG2RAD);
1760                 if( autocvar_camera_forward_follows && !autocvar_camera_look_player )
1761                         tmp_z = camera_direction_x * -sin(current_angles_x * DEG2RAD);
1762                 ++dimensions;
1763         }
1764
1765         if( camera_direction_y )
1766         {
1767                 tmp_x += camera_direction_y * -sin(current_angles_y * DEG2RAD);
1768                 tmp_y += camera_direction_y * cos(current_angles_y * DEG2RAD) * cos(current_angles_z * DEG2RAD);
1769                 tmp_z += camera_direction_y * sin(current_angles_z * DEG2RAD);
1770                 ++dimensions;
1771         }
1772
1773         if( camera_direction_z )
1774         {
1775                 tmp_z += camera_direction_z * cos(current_angles_z * DEG2RAD);
1776                 ++dimensions;
1777         }
1778
1779         if(autocvar_camera_free)
1780                 speed = autocvar_camera_speed_free;
1781         else
1782                 speed = autocvar_camera_speed_chase;
1783
1784         if(dimensions)
1785         {
1786                 speed = speed * sqrt(1 / dimensions);
1787                 camera_offset += tmp * speed;
1788         }
1789
1790         current_camera_offset += (camera_offset - current_camera_offset) * attenuation;
1791
1792         // Camera modes
1793         if( autocvar_camera_free )
1794         {
1795                 if ( camera_mode == CAMERA_CHASE )
1796                 {
1797                         current_camera_offset = current_origin + current_camera_offset;
1798                         camera_offset = current_origin + camera_offset;
1799                 }
1800
1801                 camera_mode = CAMERA_FREE;
1802                 current_position = current_camera_offset;
1803         }
1804         else
1805         {
1806                 if ( camera_mode == CAMERA_FREE )
1807                 {
1808                         current_origin = view_origin;
1809                         camera_offset = camera_offset - current_origin;
1810                         current_camera_offset = current_camera_offset - current_origin;
1811                 }
1812
1813                 camera_mode = CAMERA_CHASE;
1814
1815                 if(autocvar_camera_chase_smoothly)
1816                         current_origin += (view_origin - current_origin) * attenuation;
1817                 else
1818                         current_origin = view_origin;
1819
1820                 current_position = current_origin + current_camera_offset;
1821         }
1822
1823         R_SetView(VF_ANGLES, current_angles);
1824         R_SetView(VF_ORIGIN, current_position);
1825 }