qcsrc/client/command/cl_cmd.qc

   1 // ==============================================
   2 //  CSQC client commands code, written by Samual
   3 //  Last updated: December 28th, 2011
   4 // ==============================================
   5
   6 void DrawDebugModel()
   7 {
   8         if(time - floor(time) > 0.5)
   9         {
  10                 PolyDrawModel(self);
  11                 self.drawmask = 0;
  12         }
  13         else
  14         {
  15                 self.renderflags = 0;
  16                 self.drawmask = MASK_NORMAL;
  17         }
  18 }
  19
  20
  21 // =======================
  22 //  Command Sub-Functions
  23 // =======================
  24
  25 void LocalCommand_blurtest(int request)
  26 {
  27         // Simple command to work with postprocessing temporarily... possibly completely pointless, the glsl shader is used for a real feature now...
  28         // Anyway, to enable it, just compile the client with -DBLURTEST and then you can use the command.
  29
  30         #ifdef BLURTEST
  31         switch(request)
  32         {
  33                 case CMD_REQUEST_COMMAND:
  34                 {
  35                         blurtest_time0 = time;
  36                         blurtest_time1 = time + stof(argv(1));
  37                         blurtest_radius = stof(argv(2));
  38                         blurtest_power = stof(argv(3));
  39                         print("Enabled blurtest\n");
  40                         return;
  41                 }
  42
  43                 default:
  44                 case CMD_REQUEST_USAGE:
  45                 {
  46                         print("\nUsage:^3 cl_cmd blurtest\n");
  47                         print("  No arguments required.\n");
  48                         return;
  49                 }
  50         }
  51         #else
  52         if(request)
  53         {
  54                 print("Blurtest is not enabled on this client.\n");
  55                 return;
  56         }
  57         #endif
  58 }
  59
  60 void LocalCommand_boxparticles(int request, int argc)
  61 {
  62         switch(request)
  63         {
  64                 case CMD_REQUEST_COMMAND:
  65                 {
  66                         if (argc == 9)
  67                         {
  68                                 int effect = particleeffectnum(argv(1));
  69                                 if (effect >= 0)
  70                                 {
  71                                         int index = stoi(argv(2));
  72                                         entity own;
  73                                         if(index <= 0)
  74                                                 own = entitybyindex(-index);
  75                                         else
  76                                                 own = findfloat(world, entnum, index);
  77                                         vector org_from = stov(argv(3));
  78                                         vector org_to = stov(argv(4));
  79                                         vector dir_from = stov(argv(5));
  80                                         vector dir_to = stov(argv(6));
  81                                         int countmultiplier = stoi(argv(7));
  82                                         int flags = stoi(argv(8));
  83                                         boxparticles(effect, own, org_from, org_to, dir_from, dir_to, countmultiplier, flags);
  84                                         return;
  85                                 }
  86                         }
  87                 }
  88
  89                 default:
  90                         print("Incorrect parameters for ^2boxparticles^7\n");
  91                 case CMD_REQUEST_USAGE:
  92                 {
  93                         print("\nUsage:^3 lv_cmd boxparticles effectname own org_from org_to, dir_from, dir_to, countmultiplier, flags\n");
  94                         print("  'effectname' is the name of a particle effect in effectinfo.txt\n");
  95                         print("  'own' is the entity number of the owner (negative for csqc ent, positive for svqc ent)\n");
  96                         print("  'org_from' is the starting origin of the box\n");
  97                         print("  'org_to' is the ending origin of the box\n");
  98                         print("  'dir_from' is the minimum velocity\n");
  99                         print("  'dir_to' is the maximum velocity\n");
 100                         print("  'countmultiplier' defines a multiplier for the particle count (affects count only, not countabsolute or trailspacing)\n");
 101                         print("  'flags' can contain:\n");
 102                         print("    1 to respect globals particles_alphamin, particles_alphamax (set right before via prvm_globalset client)\n");
 103                         print("    2 to respect globals particles_colormin, particles_colormax (set right before via prvm_globalset client)\n");
 104                         print("    4 to respect globals particles_fade (set right before via prvm_globalset client)\n");
 105                         print("    128 to draw a trail, not a box\n");
 106                         return;
 107                 }
 108         }
 109 }
 110
 111 void LocalCommand_create_scrshot_ent(int request)
 112 {
 113         switch(request)
 114         {
 115                 case CMD_REQUEST_COMMAND:
 116                 {
 117                         string filename = strcat(MapInfo_Map_bspname, "_scrshot_ent.txt");
 118                         int fh = fopen(filename, FILE_WRITE);
 119
 120                         if(fh >= 0)
 121                         {
 122                                 fputs(fh, "{\n");
 123                                 fputs(fh, strcat("\"classname\" \"info_autoscreenshot\"\n"));
 124                                 fputs(fh, strcat("\"origin\" \"", strcat(ftos(view_origin.x), " ", ftos(view_origin.y), " ", ftos(view_origin.z)), "\"\n"));
 125                                 fputs(fh, strcat("\"angles\" \"", strcat(ftos(view_angles.x), " ", ftos(view_angles.y), " ", ftos(view_angles.z)), "\"\n"));
 126                                 fputs(fh, "}\n");
 127
 128                                 print("Completed screenshot entity dump in ^2data/data/", MapInfo_Map_bspname, "_scrshot_ent.txt^7.\n");
 129
 130                                 fclose(fh);
 131                         }
 132                         else
 133                         {
 134                                 print("^1Error: ^7Could not dump to file!\n");
 135                         }
 136                         return;
 137                 }
 138
 139                 default:
 140                 case CMD_REQUEST_USAGE:
 141                 {
 142                         print("\nUsage:^3 cl_cmd create_scrshot_ent\n");
 143                         print("  No arguments required.\n");
 144                         return;
 145                 }
 146         }
 147 }
 148
 149 void LocalCommand_debugmodel(int request, int argc)
 150 {
 151         switch(request)
 152         {
 153                 case CMD_REQUEST_COMMAND:
 154                 {
 155                         string modelname = argv(1);
 156                         entity debugmodel_entity;
 157
 158                         debugmodel_entity = spawn();
 159                         precache_model(modelname);
 160                         setmodel(debugmodel_entity, modelname);
 161                         setorigin(debugmodel_entity, view_origin);
 162                         debugmodel_entity.angles = view_angles;
 163                         debugmodel_entity.draw = DrawDebugModel;
 164                         debugmodel_entity.classname = "debugmodel";
 165
 166                         return;
 167                 }
 168
 169                 default:
 170                 case CMD_REQUEST_USAGE:
 171                 {
 172                         print("\nUsage:^3 cl_cmd debugmodel model\n");
 173                         print("  Where 'model' is a string of the model name to use for the debug model.\n");
 174                         return;
 175                 }
 176         }
 177 }
 178
 179 void LocalCommand_handlevote(int request, int argc)
 180 {
 181         switch(request)
 182         {
 183                 case CMD_REQUEST_COMMAND:
 184                 {
 185                         int vote_selection;
 186                         string vote_string;
 187
 188                         if(InterpretBoolean(argv(1)))
 189                         {
 190                                 vote_selection = 2;
 191                                 vote_string = "yes";
 192                         }
 193                         else
 194                         {
 195                                 vote_selection = 1;
 196                                 vote_string = "no";
 197                         }
 198
 199                         if(vote_selection)
 200                         {
 201                                 if(uid2name_dialog) // handled by "uid2name" option
 202                                 {
 203                                         vote_active = 0;
 204                                         vote_prev = 0;
 205                                         vote_change = -9999;
 206                                         localcmd(strcat("setreport cl_allow_uid2name ", ftos(vote_selection - 1), "\n"));
 207                                         uid2name_dialog = 0;
 208                                 }
 209                                 else { localcmd(strcat("cmd vote ", vote_string, "\n")); }
 210
 211                                 return;
 212                         }
 213                 }
 214
 215                 default:
 216                         print("Incorrect parameters for ^2handlevote^7\n");
 217                 case CMD_REQUEST_USAGE:
 218                 {
 219                         print("\nUsage:^3 cl_cmd handlevote vote\n");
 220                         print("  Where 'vote' is the selection for either the current poll or uid2name.\n");
 221                         return;
 222                 }
 223         }
 224 }
 225
 226 void LocalCommand_hud(int request, int argc)
 227 {
 228         switch(request)
 229         {
 230                 case CMD_REQUEST_COMMAND:
 231                 {
 232                         switch(argv(1))
 233                         {
 234                                 case "configure":
 235                                 {
 236                                         cvar_set("_hud_configure", ftos(!autocvar__hud_configure));
 237                                         return;
 238                                 }
 239
 240                                 case "save":
 241                                 {
 242                                         if(argv(2))
 243                                         {
 244                                                 HUD_Panel_ExportCfg(argv(2));
 245                                                 return;
 246                                         }
 247                                         else
 248                                         {
 249                                                 break; // go to usage, we're missing the paramater needed here.
 250                                         }
 251                                 }
 252
 253                                 case "scoreboard_columns_set":
 254                                 {
 255                                         Cmd_HUD_SetFields(argc);
 256                                         return;
 257                                 }
 258
 259                                 case "scoreboard_columns_help":
 260                                 {
 261                                         Cmd_HUD_Help();
 262                                         return;
 263                                 }
 264
 265                                 case "radar":
 266                                 {
 267                                         if(argv(2))
 268                                                 hud_panel_radar_maximized = InterpretBoolean(argv(2));
 269                                         else
 270                                                 hud_panel_radar_maximized = !hud_panel_radar_maximized;
 271                                         return;
 272                                 }
 273                         }
 274                 }
 275
 276                 default:
 277                         print("Incorrect parameters for ^2hud^7\n");
 278                 case CMD_REQUEST_USAGE:
 279                 {
 280                         print("\nUsage:^3 cl_cmd hud action [configname | radartoggle | layout]\n");
 281                         print("  Where 'action' is the command to complete,\n");
 282                         print("  'configname' is the name to save to for \"save\" action,\n");
 283                         print("  'radartoggle' is to control hud_panel_radar_maximized for \"radar\" action,\n");
 284                         print("  and 'layout' is how to organize the scoreboard columns for the set action.\n");
 285                         print("  Full list of commands here: \"configure, save, scoreboard_columns_help, scoreboard_columns_set, radar.\"\n");
 286                         return;
 287                 }
 288         }
 289 }
 290
 291 void LocalCommand_localprint(int request, int argc)
 292 {
 293         switch(request)
 294         {
 295                 case CMD_REQUEST_COMMAND:
 296                 {
 297                         if(argv(1))
 298                         {
 299                                 centerprint_hud(argv(1));
 300                                 return;
 301                         }
 302                 }
 303
 304                 default:
 305                         print("Incorrect parameters for ^2localprint^7\n");
 306                 case CMD_REQUEST_USAGE:
 307                 {
 308                         print("\nUsage:^3 cl_cmd localprint \"message\"\n");
 309                         print("  'message' is the centerprint message to send to yourself.\n");
 310                         return;
 311                 }
 312         }
 313 }
 314
 315 void LocalCommand_mv_download(int request, int argc)
 316 {
 317         switch(request)
 318         {
 319                 case CMD_REQUEST_COMMAND:
 320                 {
 321                         if(argv(1))
 322                         {
 323                                 Cmd_MapVote_MapDownload(argc);
 324                                 return;
 325                         }
 326                 }
 327
 328                 default:
 329                         print("Incorrect parameters for ^2mv_download^7\n");
 330                 case CMD_REQUEST_USAGE:
 331                 {
 332                         print("\nUsage:^3 cl_cmd mv_download mapid\n");
 333                         print("  Where 'mapid' is the id number of the map to request an image of on the map vote selection menu.\n");
 334                         return;
 335                 }
 336         }
 337 }
 338
 339 void LocalCommand_sendcvar(int request, int argc)
 340 {
 341         switch(request)
 342         {
 343                 case CMD_REQUEST_COMMAND:
 344                 {
 345                         if(argv(1))
 346                         {
 347                                 // W_FixWeaponOrder will trash argv, so save what we need.
 348                                 string thiscvar = strzone(argv(1));
 349                                 string s = cvar_string(thiscvar);
 350
 351                                 if(thiscvar == "cl_weaponpriority")
 352                                         s = W_FixWeaponOrder(W_NumberWeaponOrder(s), 1);
 353                                 else if(substring(thiscvar, 0, 17) == "cl_weaponpriority" && strlen(thiscvar) == 18)
 354                                         s = W_FixWeaponOrder(W_NumberWeaponOrder(s), 0);
 355
 356                                 localcmd("cmd sentcvar ", thiscvar, " \"", s, "\"\n");
 357                                 strunzone(thiscvar);
 358                                 return;
 359                         }
 360                 }
 361
 362                 default:
 363                         print("Incorrect parameters for ^2sendcvar^7\n");
 364                 case CMD_REQUEST_USAGE:
 365                 {
 366                         print("\nUsage:^3 cl_cmd sendcvar <cvar>\n");
 367                         print("  Where 'cvar' is the cvar plus arguments to send to the server.\n");
 368                         return;
 369                 }
 370         }
 371 }
 372
 373 /* use this when creating a new command, making sure to place it in alphabetical order... also,
 374 ** ADD ALL NEW COMMANDS TO commands.cfg WITH PROPER ALIASES IN THE SAME FASHION!
 375 void LocalCommand_(int request)
 376 {
 377         switch(request)
 378         {
 379                 case CMD_REQUEST_COMMAND:
 380                 {
 381
 382                         return;
 383                 }
 384
 385                 default:
 386                 case CMD_REQUEST_USAGE:
 387                 {
 388                         print("\nUsage:^3 cl_cmd \n");
 389                         print("  No arguments required.\n");
 390                         return;
 391                 }
 392         }
 393 }
 394 */
 395
 396
 397 // ==================================
 398 //  Macro system for client commands
 399 // ==================================
 400
 401 // Normally do not hard code aliases for these, instead create them in commands.cfg... also: keep in alphabetical order, please ;)
 402 #define CLIENT_COMMANDS(request,arguments) \
 403         CLIENT_COMMAND("blurtest", LocalCommand_blurtest(request), "Feature for testing blur postprocessing") \
 404         CLIENT_COMMAND("boxparticles", LocalCommand_boxparticles(request, arguments), "Spawn particles manually") \
 405         CLIENT_COMMAND("create_scrshot_ent", LocalCommand_create_scrshot_ent(request), "Create an entity at this location for automatic screenshots") \
 406         CLIENT_COMMAND("debugmodel", LocalCommand_debugmodel(request, arguments), "Spawn a debug model manually") \
 407         CLIENT_COMMAND("handlevote", LocalCommand_handlevote(request, arguments), "System to handle selecting a vote or option") \
 408         CLIENT_COMMAND("hud", LocalCommand_hud(request, arguments), "Commands regarding/controlling the HUD system") \
 409         CLIENT_COMMAND("localprint", LocalCommand_localprint(request, arguments), "Create your own centerprint sent to yourself") \
 410         CLIENT_COMMAND("mv_download", LocalCommand_mv_download(request, arguments), "Retrieve mapshot picture from the server") \
 411         CLIENT_COMMAND("sendcvar", LocalCommand_sendcvar(request, arguments), "Send a cvar to the server (like weaponpriority)") \
 412         /* nothing */
 413
 414 void LocalCommand_macro_help()
 415 {
 416         #define CLIENT_COMMAND(name,function,description) \
 417                 { if(strtolower(description) != "") { print("  ^2", name, "^7: ", description, "\n"); } }
 418
 419         CLIENT_COMMANDS(0, 0);
 420         #undef CLIENT_COMMAND
 421
 422         return;
 423 }
 424
 425 bool LocalCommand_macro_command(int argc)
 426 {
 427         #define CLIENT_COMMAND(name,function,description) \
 428                 { if(name == strtolower(argv(0))) { function; return true; } }
 429
 430         CLIENT_COMMANDS(CMD_REQUEST_COMMAND, argc);
 431         #undef CLIENT_COMMAND
 432
 433         return false;
 434 }
 435
 436 bool LocalCommand_macro_usage(int argc)
 437 {
 438         #define CLIENT_COMMAND(name,function,description) \
 439                 { if(name == strtolower(argv(1))) { function; return true; } }
 440
 441         CLIENT_COMMANDS(CMD_REQUEST_USAGE, argc);
 442         #undef CLIENT_COMMAND
 443
 444         return false;
 445 }
 446
 447 void LocalCommand_macro_write_aliases(int fh)
 448 {
 449         #define CLIENT_COMMAND(name,function,description) \
 450                 { if(strtolower(description) != "") { CMD_Write_Alias("qc_cmd_cl", name, description); } }
 451
 452         CLIENT_COMMANDS(0, 0);
 453         #undef CLIENT_COMMAND
 454
 455         return;
 456 }
 457
 458
 459 // =========================================
 460 //  Main Function Called By Engine (cl_cmd)
 461 // =========================================
 462 // If this function exists, client code handles gamecommand instead of the engine code.
 463
 464 void GameCommand(string command)
 465 {
 466         int argc = tokenize_console(command);
 467
 468         // Guide for working with argc arguments by example:
 469         // argc:   1    - 2      - 3     - 4
 470         // argv:   0    - 1      - 2     - 3
 471         // cmd     vote - master - login - password
 472
 473         if(strtolower(argv(0)) == "help")
 474         {
 475                 if(argc == 1)
 476                 {
 477                         print("\nClient console commands:\n");
 478                         LocalCommand_macro_help();
 479
 480                         print("\nGeneric commands shared by all programs:\n");
 481                         GenericCommand_macro_help();
 482
 483                         print("\nUsage:^3 cl_cmd COMMAND...^7, where possible commands are listed above.\n");
 484                         print("For help about a specific command, type cl_cmd help COMMAND\n");
 485
 486                         return;
 487                 }
 488                 else if(GenericCommand_macro_usage(argc)) // Instead of trying to call a command, we're going to see detailed information about it
 489                 {
 490                         return;
 491                 }
 492                 else if(LocalCommand_macro_usage(argc)) // now try for normal commands too
 493                 {
 494                         return;
 495                 }
 496         }
 497         else if(GenericCommand(command))
 498         {
 499                 return; // handled by common/command/generic.qc
 500         }
 501         else if(LocalCommand_macro_command(argc)) // continue as usual and scan for normal commands
 502         {
 503                 return; // handled by one of the above LocalCommand_* functions
 504         }
 505
 506         // nothing above caught the command, must be invalid
 507         print(((command != "") ? strcat("Unknown client command \"", command, "\"") : "No command provided"), ". For a list of supported commands, try cl_cmd help.\n");
 508
 509         return;
 510 }
 511
 512
 513 // ===================================
 514 //  Macro system for console commands
 515 // ===================================
 516
 517 // These functions are here specifically to add special + - commands to the game, and are not really normal commands.
 518 // Please add client commands to the function above this, as this is only for special reasons.
 519 #define CONSOLE_COMMANDS_NORMAL() \
 520         CONSOLE_COMMAND("+showscores", { scoreboard_showscores = true; }) \
 521         CONSOLE_COMMAND("-showscores", { scoreboard_showscores = false; }) \
 522         CONSOLE_COMMAND("+showaccuracy", { scoreboard_showaccuracy = true; }) \
 523         CONSOLE_COMMAND("-showaccuracy", { scoreboard_showaccuracy = false; }) \
 524         /* nothing */
 525
 526 #define CONSOLE_COMMANDS_MOVEMENT() \
 527         CONSOLE_COMMAND("+forward", { ++camera_direction.x; }) \
 528         CONSOLE_COMMAND("-forward", { --camera_direction.x; }) \
 529         CONSOLE_COMMAND("+back", { --camera_direction.x; }) \
 530         CONSOLE_COMMAND("-back", { ++camera_direction.x; }) \
 531         CONSOLE_COMMAND("+moveup", { ++camera_direction.z; }) \
 532         CONSOLE_COMMAND("-moveup", { --camera_direction.z; }) \
 533         CONSOLE_COMMAND("+movedown", { --camera_direction.z; }) \
 534         CONSOLE_COMMAND("-movedown", { ++camera_direction.z; }) \
 535         CONSOLE_COMMAND("+moveright", { --camera_direction.y; }) \
 536         CONSOLE_COMMAND("-moveright", { ++camera_direction.y; }) \
 537         CONSOLE_COMMAND("+moveleft", { ++camera_direction.y; }) \
 538         CONSOLE_COMMAND("-moveleft", { --camera_direction.y; }) \
 539         CONSOLE_COMMAND("+roll_right", { ++camera_roll; }) \
 540         CONSOLE_COMMAND("-roll_right", { --camera_roll; }) \
 541         CONSOLE_COMMAND("+roll_left", { --camera_roll; }) \
 542         CONSOLE_COMMAND("-roll_left", { ++camera_roll; }) \
 543         /* nothing */
 544
 545 void ConsoleCommand_macro_init()
 546 {
 547         // first init normal commands
 548         #define CONSOLE_COMMAND(name,execution) \
 549                 { registercommand(name); }
 550
 551         CONSOLE_COMMANDS_NORMAL();
 552         #undef CONSOLE_COMMAND
 553
 554         // then init movement commands
 555         #ifndef CAMERATEST
 556         if(isdemo())
 557         {
 558         #endif
 559                 #define CONSOLE_COMMAND(name,execution) \
 560                         { registercommand(name); }
 561
 562                 CONSOLE_COMMANDS_MOVEMENT();
 563                 #undef CONSOLE_COMMAND
 564         #ifndef CAMERATEST
 565         }
 566         #endif
 567
 568         return;
 569 }
 570
 571 bool ConsoleCommand_macro_normal(int argc)
 572 {
 573         #define CONSOLE_COMMAND(name,execution) \
 574                 { if(name == strtolower(argv(0))) { { execution } return true; } }
 575
 576         CONSOLE_COMMANDS_NORMAL();
 577         #undef CONSOLE_COMMAND
 578
 579         return false;
 580 }
 581
 582 bool ConsoleCommand_macro_movement(int argc)
 583 {
 584         if(camera_active)
 585         {
 586                 #define CONSOLE_COMMAND(name,execution) \
 587                         { if(name == strtolower(argv(0))) { { execution } return true; } }
 588
 589                 CONSOLE_COMMANDS_MOVEMENT();
 590                 #undef CONSOLE_COMMAND
 591         }
 592
 593         return false;
 594 }
 595
 596
 597 // ======================================================
 598 //  Main Function Called By Engine (registered commands)
 599 // ======================================================
 600 // Used to parse commands in the console that have been registered with the "registercommand" function
 601
 602 bool CSQC_ConsoleCommand(string command)
 603 {
 604         int argc = tokenize_console(command);
 605
 606         if(ConsoleCommand_macro_normal(argc))
 607         {
 608                 return true;
 609         }
 610         else if(ConsoleCommand_macro_movement(argc))
 611         {
 612                 return true;
 613         }
 614
 615         // Return value should be 1 if CSQC handled the command, otherwise return 0 to have the engine handle it.
 616
 617         return false;
 618 }