qcsrc/client/commands/cl_cmd.qc

   1 // ==============================================
   2 //  CSQC client commands code, written by Samual
   3 //  Last updated: December 28th, 2011
   4 // ==============================================
   5
   6 #include "../../common/command/command.qh"
   7 #include "cl_cmd.qh"
   8
   9 #include "../autocvars.qh"
  10 #include "../defs.qh"
  11 #include "../hud.qh"
  12 #include "../hud_config.qh"
  13 #include "../main.qh"
  14 #include "../mapvoting.qh"
  15 #include "../miscfunctions.qh"
  16
  17 #include "../mutators/events.qh"
  18
  19 #include "../../common/mapinfo.qh"
  20
  21 #include "../../common/command/generic.qh"
  22
  23 void DrawDebugModel(entity this)
  24 {
  25         if(time - floor(time) > 0.5)
  26         {
  27                 PolyDrawModel(self);
  28                 self.drawmask = 0;
  29         }
  30         else
  31         {
  32                 self.renderflags = 0;
  33                 self.drawmask = MASK_NORMAL;
  34         }
  35 }
  36
  37
  38 // =======================
  39 //  Command Sub-Functions
  40 // =======================
  41
  42 void LocalCommand_blurtest(int request)
  43 {
  44         // Simple command to work with postprocessing temporarily... possibly completely pointless, the glsl shader is used for a real feature now...
  45         // Anyway, to enable it, just compile the client with -DBLURTEST and then you can use the command.
  46
  47         #ifdef BLURTEST
  48         switch(request)
  49         {
  50                 case CMD_REQUEST_COMMAND:
  51                 {
  52                         blurtest_time0 = time;
  53                         blurtest_time1 = time + stof(argv(1));
  54                         blurtest_radius = stof(argv(2));
  55                         blurtest_power = stof(argv(3));
  56                         LOG_INFO("Enabled blurtest\n");
  57                         return;
  58                 }
  59
  60                 default:
  61                 case CMD_REQUEST_USAGE:
  62                 {
  63                         LOG_INFO("\nUsage:^3 cl_cmd blurtest\n");
  64                         LOG_INFO("  No arguments required.\n");
  65                         return;
  66                 }
  67         }
  68         #else
  69         if(request)
  70         {
  71                 LOG_INFO("Blurtest is not enabled on this client.\n");
  72                 return;
  73         }
  74         #endif
  75 }
  76
  77 void LocalCommand_boxparticles(int request, int argc)
  78 {
  79         switch(request)
  80         {
  81                 case CMD_REQUEST_COMMAND:
  82                 {
  83                         if (argc == 9)
  84                         {
  85                                 int effect = _particleeffectnum(argv(1));
  86                                 if (effect >= 0)
  87                                 {
  88                                         int index = stoi(argv(2));
  89                                         entity own;
  90                                         if(index <= 0)
  91                                                 own = entitybyindex(-index);
  92                                         else
  93                                                 own = findfloat(world, entnum, index);
  94                                         vector org_from = stov(argv(3));
  95                                         vector org_to = stov(argv(4));
  96                                         vector dir_from = stov(argv(5));
  97                                         vector dir_to = stov(argv(6));
  98                                         int countmultiplier = stoi(argv(7));
  99                                         int flags = stoi(argv(8));
 100                                         boxparticles(effect, own, org_from, org_to, dir_from, dir_to, countmultiplier, flags);
 101                                         return;
 102                                 }
 103                         }
 104                 }
 105
 106                 default:
 107                         LOG_INFO("Incorrect parameters for ^2boxparticles^7\n");
 108                 case CMD_REQUEST_USAGE:
 109                 {
 110                         LOG_INFO("\nUsage:^3 lv_cmd boxparticles effectname own org_from org_to, dir_from, dir_to, countmultiplier, flags\n");
 111                         LOG_INFO("  'effectname' is the name of a particle effect in effectinfo.txt\n");
 112                         LOG_INFO("  'own' is the entity number of the owner (negative for csqc ent, positive for svqc ent)\n");
 113                         LOG_INFO("  'org_from' is the starting origin of the box\n");
 114                         LOG_INFO("  'org_to' is the ending origin of the box\n");
 115                         LOG_INFO("  'dir_from' is the minimum velocity\n");
 116                         LOG_INFO("  'dir_to' is the maximum velocity\n");
 117                         LOG_INFO("  'countmultiplier' defines a multiplier for the particle count (affects count only, not countabsolute or trailspacing)\n");
 118                         LOG_INFO("  'flags' can contain:\n");
 119                         LOG_INFO("    1 to respect globals particles_alphamin, particles_alphamax (set right before via prvm_globalset client)\n");
 120                         LOG_INFO("    2 to respect globals particles_colormin, particles_colormax (set right before via prvm_globalset client)\n");
 121                         LOG_INFO("    4 to respect globals particles_fade (set right before via prvm_globalset client)\n");
 122                         LOG_INFO("    128 to draw a trail, not a box\n");
 123                         return;
 124                 }
 125         }
 126 }
 127
 128 void LocalCommand_create_scrshot_ent(int request)
 129 {
 130         switch(request)
 131         {
 132                 case CMD_REQUEST_COMMAND:
 133                 {
 134                         string filename = strcat(MapInfo_Map_bspname, "_scrshot_ent.txt");
 135                         int fh = fopen(filename, FILE_WRITE);
 136
 137                         if(fh >= 0)
 138                         {
 139                                 fputs(fh, "{\n");
 140                                 fputs(fh, strcat("\"classname\" \"info_autoscreenshot\"\n"));
 141                                 fputs(fh, strcat("\"origin\" \"", strcat(ftos(view_origin.x), " ", ftos(view_origin.y), " ", ftos(view_origin.z)), "\"\n"));
 142                                 fputs(fh, strcat("\"angles\" \"", strcat(ftos(view_angles.x), " ", ftos(view_angles.y), " ", ftos(view_angles.z)), "\"\n"));
 143                                 fputs(fh, "}\n");
 144
 145                                 LOG_INFO("Completed screenshot entity dump in ^2data/data/", MapInfo_Map_bspname, "_scrshot_ent.txt^7.\n");
 146
 147                                 fclose(fh);
 148                         }
 149                         else
 150                         {
 151                                 LOG_INFO("^1Error: ^7Could not dump to file!\n");
 152                         }
 153                         return;
 154                 }
 155
 156                 default:
 157                 case CMD_REQUEST_USAGE:
 158                 {
 159                         LOG_INFO("\nUsage:^3 cl_cmd create_scrshot_ent\n");
 160                         LOG_INFO("  No arguments required.\n");
 161                         return;
 162                 }
 163         }
 164 }
 165
 166 void LocalCommand_debugmodel(int request, int argc)
 167 {
 168         switch(request)
 169         {
 170                 case CMD_REQUEST_COMMAND:
 171                 {
 172                         string modelname = argv(1);
 173                         entity debugmodel_entity;
 174
 175                         debugmodel_entity = spawn();
 176                         precache_model(modelname);
 177                         _setmodel(debugmodel_entity, modelname);
 178                         setorigin(debugmodel_entity, view_origin);
 179                         debugmodel_entity.angles = view_angles;
 180                         debugmodel_entity.draw = DrawDebugModel;
 181                         debugmodel_entity.classname = "debugmodel";
 182
 183                         return;
 184                 }
 185
 186                 default:
 187                 case CMD_REQUEST_USAGE:
 188                 {
 189                         LOG_INFO("\nUsage:^3 cl_cmd debugmodel model\n");
 190                         LOG_INFO("  Where 'model' is a string of the model name to use for the debug model.\n");
 191                         return;
 192                 }
 193         }
 194 }
 195
 196 void LocalCommand_handlevote(int request, int argc)
 197 {
 198         switch(request)
 199         {
 200                 case CMD_REQUEST_COMMAND:
 201                 {
 202                         int vote_selection;
 203                         string vote_string;
 204
 205                         if(InterpretBoolean(argv(1)))
 206                         {
 207                                 vote_selection = 2;
 208                                 vote_string = "yes";
 209                         }
 210                         else
 211                         {
 212                                 vote_selection = 1;
 213                                 vote_string = "no";
 214                         }
 215
 216                         if(vote_selection)
 217                         {
 218                                 if(uid2name_dialog) // handled by "uid2name" option
 219                                 {
 220                                         vote_active = 0;
 221                                         vote_prev = 0;
 222                                         vote_change = -9999;
 223                                         localcmd(strcat("setreport cl_allow_uid2name ", ftos(vote_selection - 1), "\n"));
 224                                         uid2name_dialog = 0;
 225                                 }
 226                                 else { localcmd(strcat("cmd vote ", vote_string, "\n")); }
 227
 228                                 return;
 229                         }
 230                 }
 231
 232                 default:
 233                         LOG_INFO("Incorrect parameters for ^2handlevote^7\n");
 234                 case CMD_REQUEST_USAGE:
 235                 {
 236                         LOG_INFO("\nUsage:^3 cl_cmd handlevote vote\n");
 237                         LOG_INFO("  Where 'vote' is the selection for either the current poll or uid2name.\n");
 238                         return;
 239                 }
 240         }
 241 }
 242
 243 bool QuickMenu_IsOpened();
 244 void QuickMenu_Close();
 245 bool QuickMenu_Open(string mode, string submenu);
 246
 247 bool HUD_MinigameMenu_IsOpened();
 248 void HUD_MinigameMenu_Close();
 249 void HUD_MinigameMenu_Open();
 250
 251 void HUD_Radar_Show_Maximized(bool doshow, bool clickable);
 252
 253 void LocalCommand_hud(int request, int argc)
 254 {
 255         switch(request)
 256         {
 257                 case CMD_REQUEST_COMMAND:
 258                 {
 259                         switch(argv(1))
 260                         {
 261                                 case "configure":
 262                                 {
 263                                         cvar_set("_hud_configure", ftos(!autocvar__hud_configure));
 264                                         return;
 265                                 }
 266
 267                                 case "quickmenu":
 268                                 {
 269                                         if(QuickMenu_IsOpened())
 270                                                 QuickMenu_Close();
 271                                         else
 272                                                 QuickMenu_Open(argv(2), argv(3)); // mode, submenu
 273                                         return;
 274                                 }
 275
 276                                 case "minigame":
 277                                 {
 278                                         if(HUD_MinigameMenu_IsOpened())
 279                                                 HUD_MinigameMenu_Close();
 280                                         else
 281                                                 HUD_MinigameMenu_Open();
 282                                         return;
 283                                 }
 284
 285                                 case "save":
 286                                 {
 287                                         if(argv(2))
 288                                         {
 289                                                 HUD_Panel_ExportCfg(argv(2));
 290                                                 return;
 291                                         }
 292                                         else
 293                                         {
 294                                                 break; // go to usage, we're missing the paramater needed here.
 295                                         }
 296                                 }
 297
 298                                 case "scoreboard_columns_set":
 299                                 {
 300                                         Cmd_HUD_SetFields(argc);
 301                                         return;
 302                                 }
 303
 304                                 case "scoreboard_columns_help":
 305                                 {
 306                                         Cmd_HUD_Help();
 307                                         return;
 308                                 }
 309
 310                                 case "radar":
 311                                 {
 312                                         if(argv(2))
 313                                                 HUD_Radar_Show_Maximized(InterpretBoolean(argv(2)),0);
 314                                         else
 315                                                 HUD_Radar_Show_Maximized(!hud_panel_radar_maximized,0);
 316                                         return;
 317                                 }
 318
 319                                 case "clickradar":
 320                                 {
 321                                         HUD_Radar_Show_Maximized(!hud_panel_radar_mouse,1);
 322                                         return;
 323                                 }
 324                         }
 325                 }
 326
 327                 default:
 328                         LOG_INFO("Incorrect parameters for ^2hud^7\n");
 329                 case CMD_REQUEST_USAGE:
 330                 {
 331                         LOG_INFO("\nUsage:^3 cl_cmd hud action [configname | radartoggle | layout]\n");
 332                         LOG_INFO("  Where 'action' is the command to complete,\n");
 333                         LOG_INFO("  'configname' is the name to save to for \"save\" action,\n");
 334                         LOG_INFO("  'radartoggle' is to control hud_panel_radar_maximized for \"radar\" action,\n");
 335                         LOG_INFO("  and 'layout' is how to organize the scoreboard columns for the set action.\n");
 336                         LOG_INFO("  quickmenu [[default | file | \"\"] submenu]\n");
 337                         LOG_INFO("    Called without options (or with "") loads either the default quickmenu or a quickmenu file if hud_panel_quickmenu_file is set to a valid filename.\n");
 338                         LOG_INFO("    Submenu option allows to open quickmenu directly in a submenu, it requires to specify 'default', 'file' or '\"\"' option.\n");
 339                         LOG_INFO("  Full list of commands here: \"configure, minigame, save, scoreboard_columns_help, scoreboard_columns_set, radar.\"\n");
 340                         return;
 341                 }
 342         }
 343 }
 344
 345 void LocalCommand_localprint(int request, int argc)
 346 {
 347         switch(request)
 348         {
 349                 case CMD_REQUEST_COMMAND:
 350                 {
 351                         if(argv(1))
 352                         {
 353                                 centerprint_hud(argv(1));
 354                                 return;
 355                         }
 356                 }
 357
 358                 default:
 359                         LOG_INFO("Incorrect parameters for ^2localprint^7\n");
 360                 case CMD_REQUEST_USAGE:
 361                 {
 362                         LOG_INFO("\nUsage:^3 cl_cmd localprint \"message\"\n");
 363                         LOG_INFO("  'message' is the centerprint message to send to yourself.\n");
 364                         return;
 365                 }
 366         }
 367 }
 368
 369 void LocalCommand_mv_download(int request, int argc)
 370 {
 371         switch(request)
 372         {
 373                 case CMD_REQUEST_COMMAND:
 374                 {
 375                         if(argv(1))
 376                         {
 377                                 Cmd_MapVote_MapDownload(argc);
 378                                 return;
 379                         }
 380                 }
 381
 382                 default:
 383                         LOG_INFO("Incorrect parameters for ^2mv_download^7\n");
 384                 case CMD_REQUEST_USAGE:
 385                 {
 386                         LOG_INFO("\nUsage:^3 cl_cmd mv_download mapid\n");
 387                         LOG_INFO("  Where 'mapid' is the id number of the map to request an image of on the map vote selection menu.\n");
 388                         return;
 389                 }
 390         }
 391 }
 392
 393 void LocalCommand_find(int request, int argc)
 394 {
 395         switch(request)
 396         {
 397                 case CMD_REQUEST_COMMAND:
 398                 {
 399                         entity client;
 400
 401                         for(client = world; (client = find(client, classname, argv(1))); )
 402                                 LOG_INFO(etos(client), "\n");
 403
 404                         return;
 405                 }
 406
 407                 default:
 408                         LOG_INFO("Incorrect parameters for ^2find^7\n");
 409                 case CMD_REQUEST_USAGE:
 410                 {
 411                         LOG_INFO("\nUsage:^3 cl_cmd find classname\n");
 412                         LOG_INFO("  Where 'classname' is the classname to search for.\n");
 413                         return;
 414                 }
 415         }
 416 }
 417
 418 void LocalCommand_sendcvar(int request, int argc)
 419 {
 420         switch(request)
 421         {
 422                 case CMD_REQUEST_COMMAND:
 423                 {
 424                         if(argv(1))
 425                         {
 426                                 // W_FixWeaponOrder will trash argv, so save what we need.
 427                                 string thiscvar = strzone(argv(1));
 428                                 string s = cvar_string(thiscvar);
 429
 430                                 if(thiscvar == "cl_weaponpriority")
 431                                         s = W_FixWeaponOrder(W_NumberWeaponOrder(s), 1);
 432                                 else if(substring(thiscvar, 0, 17) == "cl_weaponpriority" && strlen(thiscvar) == 18)
 433                                         s = W_FixWeaponOrder(W_NumberWeaponOrder(s), 0);
 434
 435                                 localcmd("cmd sentcvar ", thiscvar, " \"", s, "\"\n");
 436                                 strunzone(thiscvar);
 437                                 return;
 438                         }
 439                 }
 440
 441                 default:
 442                         LOG_INFO("Incorrect parameters for ^2sendcvar^7\n");
 443                 case CMD_REQUEST_USAGE:
 444                 {
 445                         LOG_INFO("\nUsage:^3 cl_cmd sendcvar <cvar>\n");
 446                         LOG_INFO("  Where 'cvar' is the cvar plus arguments to send to the server.\n");
 447                         return;
 448                 }
 449         }
 450 }
 451
 452 /* use this when creating a new command, making sure to place it in alphabetical order... also,
 453 ** ADD ALL NEW COMMANDS TO commands.cfg WITH PROPER ALIASES IN THE SAME FASHION!
 454 void LocalCommand_(int request)
 455 {
 456         switch(request)
 457         {
 458                 case CMD_REQUEST_COMMAND:
 459                 {
 460
 461                         return;
 462                 }
 463
 464                 default:
 465                 case CMD_REQUEST_USAGE:
 466                 {
 467                         print("\nUsage:^3 cl_cmd \n");
 468                         print("  No arguments required.\n");
 469                         return;
 470                 }
 471         }
 472 }
 473 */
 474
 475
 476 // ==================================
 477 //  Macro system for client commands
 478 // ==================================
 479
 480 // Normally do not hard code aliases for these, instead create them in commands.cfg... also: keep in alphabetical order, please ;)
 481 #define CLIENT_COMMANDS(request,arguments) \
 482         CLIENT_COMMAND("blurtest", LocalCommand_blurtest(request), "Feature for testing blur postprocessing") \
 483         CLIENT_COMMAND("boxparticles", LocalCommand_boxparticles(request, arguments), "Spawn particles manually") \
 484         CLIENT_COMMAND("create_scrshot_ent", LocalCommand_create_scrshot_ent(request), "Create an entity at this location for automatic screenshots") \
 485         CLIENT_COMMAND("debugmodel", LocalCommand_debugmodel(request, arguments), "Spawn a debug model manually") \
 486         CLIENT_COMMAND("handlevote", LocalCommand_handlevote(request, arguments), "System to handle selecting a vote or option") \
 487         CLIENT_COMMAND("hud", LocalCommand_hud(request, arguments), "Commands regarding/controlling the HUD system") \
 488         CLIENT_COMMAND("localprint", LocalCommand_localprint(request, arguments), "Create your own centerprint sent to yourself") \
 489         CLIENT_COMMAND("find", LocalCommand_find(request, arguments), "Search through entities for matching classname") \
 490         CLIENT_COMMAND("mv_download", LocalCommand_mv_download(request, arguments), "Retrieve mapshot picture from the server") \
 491         CLIENT_COMMAND("sendcvar", LocalCommand_sendcvar(request, arguments), "Send a cvar to the server (like weaponpriority)") \
 492         /* nothing */
 493
 494 void LocalCommand_macro_help()
 495 {
 496         #define CLIENT_COMMAND(name,function,description) \
 497                 { if(strtolower(description) != "") { LOG_INFO("  ^2", name, "^7: ", description, "\n"); } }
 498
 499         CLIENT_COMMANDS(0, 0);
 500         #undef CLIENT_COMMAND
 501
 502         return;
 503 }
 504
 505 bool LocalCommand_macro_command(int argc)
 506 {
 507         #define CLIENT_COMMAND(name,function,description) \
 508                 { if(name == strtolower(argv(0))) { function; return true; } }
 509
 510         CLIENT_COMMANDS(CMD_REQUEST_COMMAND, argc);
 511         #undef CLIENT_COMMAND
 512
 513         return false;
 514 }
 515
 516 bool LocalCommand_macro_usage(int argc)
 517 {
 518         #define CLIENT_COMMAND(name,function,description) \
 519                 { if(name == strtolower(argv(1))) { function; return true; } }
 520
 521         CLIENT_COMMANDS(CMD_REQUEST_USAGE, argc);
 522         #undef CLIENT_COMMAND
 523
 524         return false;
 525 }
 526
 527 void LocalCommand_macro_write_aliases(int fh)
 528 {
 529         #define CLIENT_COMMAND(name,function,description) \
 530                 { if(strtolower(description) != "") { CMD_Write_Alias("qc_cmd_cl", name, description); } }
 531
 532         CLIENT_COMMANDS(0, 0);
 533         #undef CLIENT_COMMAND
 534
 535         return;
 536 }
 537
 538
 539 // =========================================
 540 //  Main Function Called By Engine (cl_cmd)
 541 // =========================================
 542 // If this function exists, client code handles gamecommand instead of the engine code.
 543
 544 void GameCommand(string command)
 545 {
 546         int argc = tokenize_console(command);
 547
 548         // Guide for working with argc arguments by example:
 549         // argc:   1    - 2      - 3     - 4
 550         // argv:   0    - 1      - 2     - 3
 551         // cmd     vote - master - login - password
 552         string s = strtolower(argv(0));
 553         if (s == "help")
 554         {
 555                 if(argc == 1)
 556                 {
 557                         LOG_INFO("\nClient console commands:\n");
 558                         LocalCommand_macro_help();
 559
 560                         LOG_INFO("\nGeneric commands shared by all programs:\n");
 561                         GenericCommand_macro_help();
 562
 563                         LOG_INFO("\nUsage:^3 cl_cmd COMMAND...^7, where possible commands are listed above.\n");
 564                         LOG_INFO("For help about a specific command, type cl_cmd help COMMAND\n");
 565
 566                         return;
 567                 }
 568                 else if(GenericCommand_macro_usage(argc)) // Instead of trying to call a command, we're going to see detailed information about it
 569                 {
 570                         return;
 571                 }
 572                 else if(LocalCommand_macro_usage(argc)) // now try for normal commands too
 573                 {
 574                         return;
 575                 }
 576         }
 577         // continue as usual and scan for normal commands
 578         if (GenericCommand(command)// handled by common/command/generic.qc
 579         || LocalCommand_macro_command(argc) // handled by one of the above LocalCommand_* functions
 580         || MUTATOR_CALLHOOK(CSQC_ConsoleCommand, s, argc, command) // handled by a mutator
 581         ) return;
 582
 583         // nothing above caught the command, must be invalid
 584         LOG_INFO(((command != "") ? strcat("Unknown client command \"", command, "\"") : "No command provided"), ". For a list of supported commands, try cl_cmd help.\n");
 585
 586         return;
 587 }
 588
 589
 590 // ===================================
 591 //  Macro system for console commands
 592 // ===================================
 593
 594 // These functions are here specifically to add special + - commands to the game, and are not really normal commands.
 595 // Please add client commands to the function above this, as this is only for special reasons.
 596 #define CONSOLE_COMMANDS_NORMAL() \
 597         CONSOLE_COMMAND("+showscores", { scoreboard_showscores = true; }) \
 598         CONSOLE_COMMAND("-showscores", { scoreboard_showscores = false; }) \
 599         CONSOLE_COMMAND("+showaccuracy", { scoreboard_showaccuracy = true; }) \
 600         CONSOLE_COMMAND("-showaccuracy", { scoreboard_showaccuracy = false; }) \
 601         /* nothing */
 602
 603 #define CONSOLE_COMMANDS_MOVEMENT() \
 604         CONSOLE_COMMAND("+forward", { ++camera_direction.x; }) \
 605         CONSOLE_COMMAND("-forward", { --camera_direction.x; }) \
 606         CONSOLE_COMMAND("+back", { --camera_direction.x; }) \
 607         CONSOLE_COMMAND("-back", { ++camera_direction.x; }) \
 608         CONSOLE_COMMAND("+moveup", { ++camera_direction.z; }) \
 609         CONSOLE_COMMAND("-moveup", { --camera_direction.z; }) \
 610         CONSOLE_COMMAND("+movedown", { --camera_direction.z; }) \
 611         CONSOLE_COMMAND("-movedown", { ++camera_direction.z; }) \
 612         CONSOLE_COMMAND("+moveright", { --camera_direction.y; }) \
 613         CONSOLE_COMMAND("-moveright", { ++camera_direction.y; }) \
 614         CONSOLE_COMMAND("+moveleft", { ++camera_direction.y; }) \
 615         CONSOLE_COMMAND("-moveleft", { --camera_direction.y; }) \
 616         CONSOLE_COMMAND("+roll_right", { ++camera_roll; }) \
 617         CONSOLE_COMMAND("-roll_right", { --camera_roll; }) \
 618         CONSOLE_COMMAND("+roll_left", { --camera_roll; }) \
 619         CONSOLE_COMMAND("-roll_left", { ++camera_roll; }) \
 620         /* nothing */
 621
 622 void ConsoleCommand_macro_init()
 623 {
 624         // first init normal commands
 625         #define CONSOLE_COMMAND(name,execution) \
 626                 { registercommand(name); }
 627
 628         CONSOLE_COMMANDS_NORMAL();
 629         #undef CONSOLE_COMMAND
 630
 631         // then init movement commands
 632         #ifndef CAMERATEST
 633         if(isdemo())
 634         {
 635         #endif
 636                 #define CONSOLE_COMMAND(name,execution) \
 637                         { registercommand(name); }
 638
 639                 CONSOLE_COMMANDS_MOVEMENT();
 640                 #undef CONSOLE_COMMAND
 641         #ifndef CAMERATEST
 642         }
 643         #endif
 644 }
 645
 646 bool ConsoleCommand_macro_normal(string s, int argc)
 647 {
 648         #define CONSOLE_COMMAND(name,execution) \
 649                 { if (name == s) { { execution } return true; } }
 650
 651         CONSOLE_COMMANDS_NORMAL();
 652         #undef CONSOLE_COMMAND
 653
 654         return false;
 655 }
 656
 657 bool ConsoleCommand_macro_movement(string s, int argc)
 658 {
 659         if(camera_active)
 660         {
 661                 #define CONSOLE_COMMAND(name,execution) \
 662                         { if (name == s) { { execution } return true; } }
 663
 664                 CONSOLE_COMMANDS_MOVEMENT();
 665                 #undef CONSOLE_COMMAND
 666         }
 667
 668         return false;
 669 }
 670
 671
 672 // ======================================================
 673 //  Main Function Called By Engine (registered commands)
 674 // ======================================================
 675 // Used to parse commands in the console that have been registered with the "registercommand" function
 676
 677 bool CSQC_ConsoleCommand(string command)
 678 {
 679         int argc = tokenize_console(command);
 680         string s = strtolower(argv(0));
 681         // Return value should be true if CSQC handled the command, otherwise return false to have the engine handle it.
 682         return (ConsoleCommand_macro_normal(s, argc)
 683         || ConsoleCommand_macro_movement(s, argc)
 684         );
 685 }