qcsrc/client/csqcmodel_hooks.qc

   1 void CSQCModel_Hook_PreDraw();
   2
   3 .float isplayermodel;
   4
   5 // FEATURE: LOD
   6 .float lodmodelindex0;
   7 .float lodmodelindex1;
   8 .float lodmodelindex2;
   9 void CSQCPlayer_LOD_Apply(void)
  10 {
  11         // LOD model loading
  12         if(self.lodmodelindex0 != self.modelindex)
  13         {
  14                 string modelname = self.model;
  15                 string s;
  16
  17                 // set modelindex
  18                 self.lodmodelindex0 = self.modelindex;
  19                 self.lodmodelindex1 = self.modelindex;
  20                 self.lodmodelindex2 = self.modelindex;
  21
  22                 // FIXME: this only supports 3-letter extensions
  23                 s = strcat(substring(modelname, 0, strlen(modelname)-4), "_lod1", substring(modelname, -4, 4));
  24                 if(fexists(s))
  25                 {
  26                         precache_model(s);
  27                         setmodel(self, s);
  28                         if(self.modelindex)
  29                                 self.lodmodelindex1 = self.modelindex;
  30                 }
  31
  32                 s = strcat(substring(modelname, 0, strlen(modelname)-4), "_lod2", substring(modelname, -4, 4));
  33                 if(fexists(s))
  34                 {
  35                         precache_model(s);
  36                         setmodel(self, s);
  37                         if(self.modelindex)
  38                                 self.lodmodelindex2 = self.modelindex;
  39                 }
  40
  41                 setmodel(self, modelname); // make everything normal again
  42         }
  43
  44         // apply LOD
  45         if(autocvar_cl_playerdetailreduction <= 0)
  46         {
  47                 if(autocvar_cl_playerdetailreduction <= -2)
  48                         self.modelindex = self.lodmodelindex2;
  49                 else if(autocvar_cl_playerdetailreduction <= -1)
  50                         self.modelindex = self.lodmodelindex1;
  51                 else
  52                         self.modelindex = self.lodmodelindex0;
  53         }
  54         else
  55         {
  56                 float distance = vlen(self.origin - other.origin);
  57                 float f = (distance + 100.0) * autocvar_cl_playerdetailreduction;
  58                 f *= 1.0 / bound(0.01, view_quality, 1);
  59                 if(f > autocvar_cl_loddistance2)
  60                         self.modelindex = self.lodmodelindex2;
  61                 else if(f > autocvar_cl_loddistance1)
  62                         self.modelindex = self.lodmodelindex1;
  63                 else
  64                         self.modelindex = self.lodmodelindex0;
  65         }
  66 }
  67
  68 // FEATURE: forcemodel (MUST be called BEFORE LOD!)
  69 string forceplayermodels_model;
  70 float forceplayermodels_modelisgoodmodel;
  71 float forceplayermodels_modelindex;
  72 float forceplayermodels_skin;
  73
  74 string forceplayermodels_mymodel;
  75 float forceplayermodels_myisgoodmodel;
  76 float forceplayermodels_mymodelindex;
  77
  78 float forceplayermodels_attempted;
  79
  80 .string forceplayermodels_savemodel;
  81 .float forceplayermodels_savemodelindex;
  82 .float forceplayermodels_saveskin;
  83 .float forceplayermodels_savecolormap;
  84
  85 .string forceplayermodels_isgoodmodel_mdl;
  86 .float forceplayermodels_isgoodmodel;
  87
  88 string forceplayermodels_goodmodel;
  89 float forceplayermodels_goodmodelindex;
  90
  91 void CSQCPlayer_ForceModel_PreUpdate(void)
  92 {
  93         self.model = self.forceplayermodels_savemodel;
  94         self.modelindex = self.forceplayermodels_savemodelindex;
  95         self.skin = self.forceplayermodels_saveskin;
  96         self.colormap = self.forceplayermodels_savecolormap;
  97 }
  98 void CSQCPlayer_ForceModel_PostUpdate(void)
  99 {
 100         self.forceplayermodels_savemodel = self.model;
 101         self.forceplayermodels_savemodelindex = self.modelindex;
 102         self.forceplayermodels_saveskin = self.skin;
 103         self.forceplayermodels_savecolormap = self.colormap;
 104
 105         if(self.forceplayermodels_savemodel != self.forceplayermodels_isgoodmodel_mdl)
 106         {
 107                 self.forceplayermodels_isgoodmodel = fexists(self.forceplayermodels_savemodel);
 108                 self.forceplayermodels_isgoodmodel_mdl = self.forceplayermodels_savemodel;
 109                 if(!self.forceplayermodels_isgoodmodel)
 110                         print(sprintf("Warning: missing model %s has been used\n", self.forceplayermodels_savemodel));
 111         }
 112 }
 113 void CSQCPlayer_ForceModel_Apply(float islocalplayer)
 114 {
 115         // which one is ALWAYS good?
 116         if not(forceplayermodels_goodmodel)
 117         {
 118                 entity e;
 119                 e = spawn();
 120                 setmodel(e, cvar_defstring("_cl_playermodel"));
 121                 forceplayermodels_goodmodel = e.model;
 122                 forceplayermodels_goodmodelindex = e.modelindex;
 123                 remove(e);
 124         }
 125
 126         // first, try finding it from the server
 127         if(self.forceplayermodels_savemodelindex && self.forceplayermodels_savemodel != "null")
 128         {
 129                 if(islocalplayer)
 130                 {
 131                         // trust server's idea of "own player model"
 132                         forceplayermodels_modelisgoodmodel = self.forceplayermodels_isgoodmodel;
 133                         forceplayermodels_model = self.forceplayermodels_savemodel;
 134                         forceplayermodels_modelindex = self.forceplayermodels_savemodelindex;
 135                         forceplayermodels_skin = self.forceplayermodels_saveskin;
 136                         forceplayermodels_attempted = 1;
 137                 }
 138         }
 139
 140         // forcemodel finding
 141         if(!forceplayermodels_attempted)
 142         {
 143                 forceplayermodels_attempted = 1;
 144
 145                 // only if this failed, find it out on our own
 146                 entity e;
 147                 e = spawn();
 148                 setmodel(e, autocvar__cl_playermodel); // this is harmless, see below
 149                 forceplayermodels_modelisgoodmodel = fexists(e.model);
 150                 forceplayermodels_model = e.model;
 151                 forceplayermodels_modelindex = e.modelindex;
 152                 forceplayermodels_skin = autocvar__cl_playerskin;
 153                 remove(e);
 154         }
 155
 156         if(autocvar_cl_forcemyplayermodel != "" && autocvar_cl_forcemyplayermodel != forceplayermodels_mymodel)
 157         {
 158                 entity e;
 159                 e = spawn();
 160                 setmodel(e, autocvar_cl_forcemyplayermodel); // this is harmless, see below
 161                 forceplayermodels_myisgoodmodel = fexists(e.model);
 162                 forceplayermodels_mymodel = e.model;
 163                 forceplayermodels_mymodelindex = e.modelindex;
 164                 remove(e);
 165         }
 166
 167         // apply it
 168         if(autocvar_cl_forcemyplayermodel != "" && forceplayermodels_myisgoodmodel && islocalplayer)
 169         {
 170                 self.model = forceplayermodels_mymodel;
 171                 self.modelindex = forceplayermodels_mymodelindex;
 172                 self.skin = autocvar_cl_forcemyplayerskin;
 173         }
 174         else if(autocvar_cl_forceplayermodels && forceplayermodels_modelisgoodmodel)
 175         {
 176                 self.model = forceplayermodels_model;
 177                 self.modelindex = forceplayermodels_modelindex;
 178                 self.skin = forceplayermodels_skin;
 179         }
 180         else if(self.forceplayermodels_isgoodmodel)
 181         {
 182                 self.model = self.forceplayermodels_savemodel;
 183                 self.modelindex = self.forceplayermodels_savemodelindex;
 184                 self.skin = self.forceplayermodels_saveskin;
 185         }
 186         else
 187         {
 188                 self.model = forceplayermodels_goodmodel;
 189                 self.modelindex = forceplayermodels_goodmodelindex;
 190                 self.skin = self.forceplayermodels_saveskin;
 191         }
 192
 193         // forceplayercolors too
 194         if(!teamplay)
 195         {
 196                 if(autocvar_cl_forcemyplayercolors && islocalplayer)
 197                         self.colormap = 1024 + autocvar_cl_forcemyplayercolors;
 198                 else if(autocvar_cl_forceplayercolors)
 199                         self.colormap = player_localnum + 1;
 200         }
 201 }
 202
 203 // FEATURE: fallback frames
 204 .float csqcmodel_saveframe;
 205 .float csqcmodel_saveframe2;
 206 .float csqcmodel_saveframe3;
 207 .float csqcmodel_saveframe4;
 208 .float csqcmodel_framecount;
 209
 210 .float csqcmodel_isdead; // for utility code
 211
 212 #define IS_DEAD_FRAME(f) ((f) == 0 || (f) == 1)
 213 void CSQCPlayer_FallbackFrame_PreUpdate(void)
 214 {
 215         self.frame = self.csqcmodel_saveframe;
 216         self.frame2 = self.csqcmodel_saveframe2;
 217         self.frame3 = self.csqcmodel_saveframe3;
 218         self.frame4 = self.csqcmodel_saveframe4;
 219 }
 220 void CSQCPlayer_FallbackFrame_PostUpdate(float isnew)
 221 {
 222         self.csqcmodel_saveframe = self.frame;
 223         self.csqcmodel_saveframe2 = self.frame2;
 224         self.csqcmodel_saveframe3 = self.frame3;
 225         self.csqcmodel_saveframe4 = self.frame4;
 226
 227         // hack for death animations: set their frametime to zero in case a
 228         // player "pops in"
 229         if(isnew)
 230         {
 231 #define FIX_FRAMETIME(f,ft) \
 232                 if(IS_DEAD_FRAME(self.f)) \
 233                 { \
 234                         self.ft = self.death_time; \
 235                 }
 236                 FIX_FRAMETIME(frame, frame1time)
 237                 FIX_FRAMETIME(frame2, frame2time)
 238                 FIX_FRAMETIME(frame3, frame3time)
 239                 FIX_FRAMETIME(frame4, frame4time)
 240         }
 241         self.csqcmodel_isdead = IS_DEAD_FRAME(self.frame);
 242 }
 243 float CSQCPlayer_FallbackFrame(float f)
 244 {
 245         if(frameduration(self.modelindex, f) > 0)
 246                 return f; // goooooood
 247         switch(f)
 248         {
 249                 case 23: return 11; // anim_melee -> anim_shoot
 250                 case 24: return 4; // anim_duckwalkbackwards -> anim_duckwalk
 251                 case 25: return 4; // anim_duckwalkstrafeleft -> anim_duckwalk
 252                 case 26: return 4; // anim_duckwalkstraferight -> anim_duckwalk
 253                 case 27: return 4; // anim_duckwalkforwardright -> anim_duckwalk
 254                 case 28: return 4; // anim_duckwalkforwardleft -> anim_duckwalk
 255                 case 29: return 4; // anim_duckwalkbackright -> anim_duckwalk
 256                 case 30: return 4; // anim_duckwalkbackleft -> anim_duckwalk
 257         }
 258         print(sprintf("Frame %d missing in model %s, and we have no fallback - FAIL!\n", f, self.model));
 259         return f;
 260 }
 261 void CSQCPlayer_FallbackFrame_Apply(void)
 262 {
 263         self.frame = CSQCPlayer_FallbackFrame(self.frame);
 264         self.frame2 = CSQCPlayer_FallbackFrame(self.frame2);
 265         self.frame3 = CSQCPlayer_FallbackFrame(self.frame3);
 266         self.frame4 = CSQCPlayer_FallbackFrame(self.frame4);
 267 }
 268
 269 // FEATURE: auto glowmod
 270 .vector glowmod;
 271 void CSQCPlayer_GlowMod_Apply(void)
 272 {
 273         if(self.colormap > 0)
 274                 self.glowmod = colormapPaletteColor(((self.colormap >= 1024) ? self.colormap : stof(getplayerkeyvalue(self.colormap - 1, "colors"))) & 0x0F, TRUE) * 2;
 275         else
 276                 self.glowmod = '1 1 1';
 277 }
 278
 279 // FEATURE: auto tag_index
 280 .entity tag_entity;
 281 .float tag_entity_lastmodelindex;
 282 .float tag_index;
 283 void CSQCModel_AutoTagIndex_Apply(void)
 284 {
 285         if(self.tag_entity && wasfreed(self.tag_entity))
 286                 self.tag_entity = world;
 287
 288         if(self.tag_networkentity)
 289         {
 290                 // we are ATTACHED!
 291                 float changed = 0;
 292                 if(self.tag_entity.entnum != self.tag_networkentity)
 293                 {
 294                         self.tag_entity = findfloat(world, entnum, self.tag_networkentity);
 295                         changed = 1;
 296                 }
 297
 298                 // recursive predraw call to fix issues with forcemodels and LOD if bone indexes mismatch
 299                 {
 300                         entity oldself = self;
 301                         self = self.tag_entity;
 302                         CSQCModel_Hook_PreDraw();
 303                         self = oldself;
 304                 }
 305
 306                 if(self.tag_entity.modelindex != self.tag_entity_lastmodelindex)
 307                 {
 308                         self.tag_entity_lastmodelindex = self.tag_entity.modelindex;
 309                         changed = 1;
 310                 }
 311                 if(changed)
 312                 {
 313                         if(self.tag_entity)
 314                         {
 315                                 // the best part is: IT EXISTS
 316                                 if(substring(self.model, 0, 17) == "models/weapons/v_")
 317                                         if(substring(self.tag_entity.model, 0, 17) == "models/weapons/h_")
 318                                         {
 319                                                 self.tag_index = gettagindex(self.tag_entity, "weapon");
 320                                                 if(!self.tag_index)
 321                                                         self.tag_index = gettagindex(self.tag_entity, "tag_weapon");
 322                                                 if(!self.tag_index)
 323                                                 {
 324                                                         // we need to prevent this from 'appening
 325                                                         self.tag_entity = world;
 326                                                         self.drawmask = 0;
 327                                                         dprint("h_ model lacks weapon attachment, but v_ model is attached to it\n");
 328                                                 }
 329                                         }
 330
 331                                 if(substring(self.model, 0, 17) == "models/weapons/v_")
 332                                         if(substring(self.tag_entity.model, 0, 14) == "models/player/")
 333                                         {
 334                                                 self.tag_index = gettagindex(self.tag_entity, "tag_weapon");
 335                                                 if(!self.tag_index)
 336                                                         self.tag_index = gettagindex(self.tag_entity, "bip01 r hand");
 337                                         }
 338
 339                                 if(substring(self.tag_entity.model, 0, 17) == "models/weapons/v_")
 340                                 {
 341                                         self.tag_index = gettagindex(self.tag_entity, "shot");
 342                                         if(!self.tag_index)
 343                                                 self.tag_index = gettagindex(self.tag_entity, "tag_shot");
 344                                 }
 345                         }
 346                         else
 347                         {
 348                                 // damn, see you next frame
 349                                 self.drawmask = 0;
 350                         }
 351                 }
 352         }
 353 }
 354
 355 // FEATURE: EF_NODRAW workalike
 356 float EF_BRIGHTFIELD    = 1;
 357 float EF_BRIGHTLIGHT    = 4;
 358 float EF_DIMLIGHT       = 8;
 359 float EF_DOUBLESIDED = 32768;
 360 float EF_NOSELFSHADOW = 65536;
 361 float EF_DYNAMICMODELLIGHT = 131072;
 362 float MF_ROCKET  =   1; // leave a trail
 363 float MF_GRENADE =   2; // leave a trail
 364 float MF_GIB     =   4; // leave a trail
 365 float MF_ROTATE  =   8; // rotate (bonus items)
 366 float MF_TRACER  =  16; // green split trail
 367 float MF_ZOMGIB  =  32; // small blood trail
 368 float MF_TRACER2 =  64; // orange split trail
 369 float MF_TRACER3 = 128; // purple trail
 370 .float csqcmodel_effects;
 371 .float csqcmodel_modelflags;
 372 void CSQCModel_Effects_PreUpdate(void)
 373 {
 374         self.effects = self.csqcmodel_effects;
 375         self.modelflags = self.csqcmodel_modelflags;
 376 }
 377 void CSQCModel_Effects_PostUpdate(void)
 378 {
 379         self.csqcmodel_effects = self.effects;
 380         self.csqcmodel_modelflags = self.modelflags;
 381         self.effects = 0;
 382         self.modelflags = 0;
 383         if(self.csqcmodel_teleported)
 384                 Projectile_ResetTrail(self.origin);
 385 }
 386 void CSQCModel_Effects_Apply(void)
 387 {
 388         float eff = self.csqcmodel_effects;
 389         eff &~= CSQCMODEL_EF_INVISIBLE;
 390
 391         self.renderflags &~= (RF_DEPTHHACK | RF_ADDITIVE | RF_FULLBRIGHT | EF_NOSHADOW | RF_USEAXIS);
 392         self.effects = 0;
 393         self.traileffect = 0;
 394
 395         if(eff & EF_BRIGHTFIELD)
 396                 self.traileffect = particleeffectnum("TR_NEXUIZPLASMA");
 397         // ignoring EF_MUZZLEFLASH
 398         if(eff & EF_BRIGHTLIGHT)
 399                 adddynamiclight(self.origin, 400, '3 3 3');
 400         if(eff & EF_DIMLIGHT)
 401                 adddynamiclight(self.origin, 200, '1.5 1.5 1.5');
 402         if((eff & EF_NODRAW) || (self.csqcmodel_effects & CSQCMODEL_EF_INVISIBLE) || (self.alpha < 0))
 403                 self.drawmask = 0;
 404         if(eff & EF_ADDITIVE)
 405                 self.renderflags |= RF_ADDITIVE;
 406         if(eff & EF_BLUE)
 407                 adddynamiclight(self.origin, 200, '0.15 0.15 1.5');
 408         if(eff & EF_RED)
 409                 adddynamiclight(self.origin, 200, '1.5 0.15 0.15');
 410         // ignoring EF_NOGUNBOB
 411         if(eff & EF_FULLBRIGHT)
 412                 self.renderflags |= RF_FULLBRIGHT;
 413         if(eff & EF_FLAME)
 414                 pointparticles(particleeffectnum("EF_FLAME"), self.origin, '0 0 0', bound(0, frametime, 0.1));
 415         if(eff & EF_STARDUST)
 416                 pointparticles(particleeffectnum("EF_STARDUST"), self.origin, '0 0 0', bound(0, frametime, 0.1));
 417         if(eff & EF_NOSHADOW)
 418                 self.renderflags |= RF_NOSHADOW;
 419         if(eff & EF_NODEPTHTEST)
 420                 self.renderflags |= RF_DEPTHHACK;
 421         // ignoring EF_SELECTABLE
 422         if(eff & EF_DOUBLESIDED)
 423                 self.effects |= EF_DOUBLESIDED;
 424         if(eff & EF_NOSELFSHADOW)
 425                 self.effects |= EF_NOSELFSHADOW;
 426         if(eff & EF_DYNAMICMODELLIGHT)
 427                 self.renderflags |= RF_DYNAMICMODELLIGHT;
 428         // ignoring EF_UNUSED18, EF_UNUSED19, EF_RESTARTANIM_BIT, EF_TELEPORT_BIT, EF_LOWPRECISION
 429         if(self.csqcmodel_modelflags & MF_ROCKET)
 430                 self.traileffect = particleeffectnum("TR_ROCKET");
 431         if(self.csqcmodel_modelflags & MF_GRENADE)
 432                 self.traileffect = particleeffectnum("TR_GRENADE");
 433         if(self.csqcmodel_modelflags & MF_GIB)
 434                 self.traileffect = particleeffectnum("TR_BLOOD");
 435         if(self.csqcmodel_modelflags & MF_ROTATE)
 436         {
 437                 self.renderflags |= RF_USEAXIS;
 438                 makevectors(self.angles + '0 100 0' * fmod(time, 3.6));
 439         }
 440         if(self.csqcmodel_modelflags & MF_TRACER)
 441                 self.traileffect = particleeffectnum("TR_WIZSPIKE");
 442         if(self.csqcmodel_modelflags & MF_ZOMGIB)
 443                 self.traileffect = particleeffectnum("TR_SLIGHTBLOOD");
 444         if(self.csqcmodel_modelflags & MF_TRACER2)
 445                 self.traileffect = particleeffectnum("TR_KNIGHTSPIKE");
 446         if(self.csqcmodel_modelflags & MF_TRACER3)
 447                 self.traileffect = particleeffectnum("TR_VORESPIKE");
 448
 449         if(self.drawmask)
 450                 Projectile_DrawTrail(self.origin);
 451         else
 452                 Projectile_ResetTrail(self.origin);
 453 }
 454
 455 // general functions
 456 .float csqcmodel_predraw_run;
 457 void CSQCModel_Hook_PreDraw()
 458 {
 459         if(self.csqcmodel_predraw_run == framecount)
 460                 return;
 461         self.csqcmodel_predraw_run = framecount;
 462
 463         if(!self.modelindex || self.model == "null")
 464         {
 465                 self.drawmask = 0;
 466                 return;
 467         }
 468         else
 469                 self.drawmask = MASK_NORMAL;
 470
 471         if(self.isplayermodel) // this checks if it's a player MODEL!
 472         {
 473                 CSQCPlayer_ForceModel_Apply(self.entnum == player_localnum + 1);
 474                 CSQCPlayer_GlowMod_Apply();
 475                 CSQCPlayer_LOD_Apply();
 476                 CSQCPlayer_FallbackFrame_Apply();
 477         }
 478
 479         CSQCModel_AutoTagIndex_Apply();
 480
 481         CSQCModel_Effects_Apply();
 482 }
 483
 484 void CSQCModel_Hook_PreUpdate(float isnew, float isplayer, float islocalplayer)
 485 {
 486         // revert to values from server
 487         CSQCModel_Effects_PreUpdate();
 488         if(self.isplayermodel)
 489         {
 490                 CSQCPlayer_FallbackFrame_PreUpdate();
 491                 CSQCPlayer_ForceModel_PreUpdate();
 492         }
 493 }
 494
 495 void CSQCModel_Hook_PostUpdate(float isnew, float isplayer, float islocalplayer)
 496 {
 497         // is it a player model? (shared state)
 498         self.isplayermodel = (substring(self.model, 0, 14) == "models/player/");
 499
 500         // save values set by server
 501         if(self.isplayermodel)
 502         {
 503                 CSQCPlayer_ForceModel_PostUpdate();
 504                 CSQCPlayer_FallbackFrame_PostUpdate(isnew);
 505         }
 506         CSQCModel_Effects_PostUpdate();
 507 }