qcsrc/client/csqcmodel_hooks.qc

   1 .float isplayermodel;
   2
   3 // FEATURE: LOD
   4 .float lodmodelindex0;
   5 .float lodmodelindex1;
   6 .float lodmodelindex2;
   7 void CSQCPlayer_LOD_Apply(void)
   8 {
   9         // LOD model loading
  10         if(self.lodmodelindex0 != self.modelindex)
  11         {
  12                 string modelname = self.model;
  13                 string s;
  14
  15                 if(!fexists(modelname))
  16                 {
  17                         print(sprintf(_("Trying to use non existing model %s. "), modelname));
  18                         modelname = cvar_defstring("_cl_playermodel");
  19                         print(sprintf(_("Reverted to %s.\n"), modelname));
  20                 }
  21
  22                 // set modelindex
  23                 self.lodmodelindex0 = self.modelindex;
  24                 self.lodmodelindex1 = self.modelindex;
  25                 self.lodmodelindex2 = self.modelindex;
  26
  27                 // FIXME: this only supports 3-letter extensions
  28                 s = strcat(substring(modelname, 0, strlen(modelname)-4), "_lod1", substring(modelname, -4, 4));
  29                 if(fexists(s))
  30                 {
  31                         precache_model(s);
  32                         setmodel(self, s);
  33                         if(self.modelindex)
  34                                 self.lodmodelindex1 = self.modelindex;
  35                 }
  36
  37                 s = strcat(substring(modelname, 0, strlen(modelname)-4), "_lod2", substring(modelname, -4, 4));
  38                 if(fexists(s))
  39                 {
  40                         precache_model(s);
  41                         setmodel(self, s);
  42                         if(self.modelindex)
  43                                 self.lodmodelindex2 = self.modelindex;
  44                 }
  45
  46                 setmodel(self, modelname); // make everything normal again
  47         }
  48
  49         // apply LOD
  50         if(autocvar_cl_playerdetailreduction <= 0)
  51         {
  52                 if(autocvar_cl_playerdetailreduction <= -2)
  53                         self.modelindex = self.lodmodelindex2;
  54                 else if(autocvar_cl_playerdetailreduction <= -1)
  55                         self.modelindex = self.lodmodelindex1;
  56                 else
  57                         self.modelindex = self.lodmodelindex0;
  58         }
  59         else
  60         {
  61                 float distance = vlen(self.origin - other.origin);
  62                 float f = (distance + 100.0) * autocvar_cl_playerdetailreduction;
  63                 f *= 1.0 / bound(0.01, view_quality, 1);
  64                 if(f > autocvar_cl_loddistance2)
  65                         self.modelindex = self.lodmodelindex2;
  66                 else if(f > autocvar_cl_loddistance1)
  67                         self.modelindex = self.lodmodelindex1;
  68                 else
  69                         self.modelindex = self.lodmodelindex0;
  70         }
  71 }
  72
  73 // FEATURE: forcemodel (MUST be called BEFORE LOD!)
  74 string forceplayermodels_model;
  75 float forceplayermodels_modelindex;
  76 float forceplayermodels_skin;
  77
  78 string forceplayermodels_mymodel;
  79 float forceplayermodels_mymodelindex;
  80
  81 float forceplayermodels_attempted;
  82 .string forceplayermodels_savemodel;
  83 .float forceplayermodels_savemodelindex;
  84 .float forceplayermodels_saveskin;
  85 .float forceplayermodels_savecolormap;
  86 void CSQCPlayer_ForceModel_PreUpdate(void)
  87 {
  88         self.model = self.forceplayermodels_savemodel;
  89         self.modelindex = self.forceplayermodels_savemodelindex;
  90         self.skin = self.forceplayermodels_saveskin;
  91         self.colormap = self.forceplayermodels_savecolormap;
  92 }
  93 void CSQCPlayer_ForceModel_PostUpdate(void)
  94 {
  95         self.forceplayermodels_savemodel = self.model;
  96         self.forceplayermodels_savemodelindex = self.modelindex;
  97         self.forceplayermodels_saveskin = self.skin;
  98         self.forceplayermodels_savecolormap = self.colormap;
  99 }
 100 void CSQCPlayer_ForceModel_Apply(float islocalplayer)
 101 {
 102         // first, try finding it from the server
 103
 104         if(self.forceplayermodels_savemodelindex && self.forceplayermodels_savemodel != "null")
 105         {
 106                 if(islocalplayer)
 107                 {
 108                         // trust server's idea of "own player model"
 109                         forceplayermodels_model = self.model;
 110                         forceplayermodels_modelindex = self.modelindex;
 111                         forceplayermodels_skin = self.skin;
 112                         forceplayermodels_attempted = 1;
 113                 }
 114         }
 115
 116         // forcemodel finding
 117         if(!forceplayermodels_attempted)
 118         {
 119                 forceplayermodels_attempted = 1;
 120
 121                 // only if this failed, find it out on our own
 122                 entity e;
 123                 e = spawn();
 124                 setmodel(e, autocvar__cl_playermodel); // this is harmless, see below
 125                 forceplayermodels_model = e.model;
 126                 forceplayermodels_modelindex = e.modelindex;
 127                 forceplayermodels_skin = autocvar__cl_playerskin;
 128                 remove(e);
 129         }
 130
 131         if(autocvar_cl_forcemyplayermodel != "" && autocvar_cl_forcemyplayermodel != forceplayermodels_mymodel)
 132         {
 133                 entity e;
 134                 e = spawn();
 135                 setmodel(e, autocvar_cl_forcemyplayermodel); // this is harmless, see below
 136                 forceplayermodels_mymodel = e.model;
 137                 forceplayermodels_mymodelindex = e.modelindex;
 138                 remove(e);
 139         }
 140
 141         // apply it
 142         if(autocvar_cl_forcemyplayermodel != "" && forceplayermodels_mymodelindex && self.entnum == player_localnum + 1)
 143         {
 144                 self.model = forceplayermodels_mymodel;
 145                 self.modelindex = forceplayermodels_mymodelindex;
 146                 self.skin = autocvar_cl_forcemyplayerskin;
 147         }
 148         else if(autocvar_cl_forceplayermodels && forceplayermodels_modelindex)
 149         {
 150                 self.model = forceplayermodels_model;
 151                 self.modelindex = forceplayermodels_modelindex;
 152                 self.skin = forceplayermodels_skin;
 153         }
 154         else
 155         {
 156                 self.model = self.forceplayermodels_savemodel;
 157                 self.modelindex = self.forceplayermodels_savemodelindex;
 158                 self.skin = self.forceplayermodels_saveskin;
 159         }
 160
 161         // forceplayercolors too
 162         if(!teamplay)
 163         {
 164                 if(autocvar_cl_forcemyplayercolors && self.entnum == player_localnum + 1)
 165                         self.colormap = 1024 + autocvar_cl_forcemyplayercolors;
 166                 else if(autocvar_cl_forceplayercolors)
 167                         self.colormap = player_localnum + 1;
 168         }
 169 }
 170
 171 // FEATURE: fallback frames
 172 .float csqcmodel_saveframe;
 173 .float csqcmodel_saveframe2;
 174 .float csqcmodel_saveframe3;
 175 .float csqcmodel_saveframe4;
 176 .float csqcmodel_framecount;
 177 void CSQCPlayer_FallbackFrame_PreUpdate(void)
 178 {
 179         self.frame = self.csqcmodel_saveframe;
 180         self.frame2 = self.csqcmodel_saveframe2;
 181         self.frame3 = self.csqcmodel_saveframe3;
 182         self.frame4 = self.csqcmodel_saveframe4;
 183 }
 184 void CSQCPlayer_FallbackFrame_PostUpdate(float isnew)
 185 {
 186         self.csqcmodel_saveframe = self.frame;
 187         self.csqcmodel_saveframe2 = self.frame2;
 188         self.csqcmodel_saveframe3 = self.frame3;
 189         self.csqcmodel_saveframe4 = self.frame4;
 190
 191         // hack for death animations: set their frametime to zero in case a
 192         // player "pops in"
 193         if(isnew)
 194         {
 195 #define FIX_FRAMETIME(f,ft) \
 196                 switch(self.f) \
 197                 { \
 198                         case 0: \
 199                         case 1: \
 200                                 self.ft = 0; \
 201                                 break; \
 202                 }
 203                 FIX_FRAMETIME(frame, frame1time)
 204                 FIX_FRAMETIME(frame2, frame2time)
 205                 FIX_FRAMETIME(frame3, frame3time)
 206                 FIX_FRAMETIME(frame4, frame4time)
 207         }
 208 }
 209 float CSQCPlayer_FallbackFrame(float f)
 210 {
 211         if(frameduration(self.modelindex, f) > 0)
 212                 return f; // goooooood
 213         switch(f)
 214         {
 215                 case 23: return 11; // anim_melee -> anim_shoot
 216                 case 24: return 4; // anim_duckwalkbackwards -> anim_duckwalk
 217                 case 25: return 4; // anim_duckwalkstrafeleft -> anim_duckwalk
 218                 case 26: return 4; // anim_duckwalkstraferight -> anim_duckwalk
 219                 case 27: return 4; // anim_duckwalkforwardright -> anim_duckwalk
 220                 case 28: return 4; // anim_duckwalkforwardleft -> anim_duckwalk
 221                 case 29: return 4; // anim_duckwalkbackright -> anim_duckwalk
 222                 case 30: return 4; // anim_duckwalkbackleft -> anim_duckwalk
 223         }
 224         print(sprintf("Frame %d missing in model %s, and we have no fallback - FAIL!\n", f, self.model));
 225         return f;
 226 }
 227 void CSQCPlayer_FallbackFrame_Apply(void)
 228 {
 229         self.frame = CSQCPlayer_FallbackFrame(self.frame);
 230         self.frame2 = CSQCPlayer_FallbackFrame(self.frame2);
 231         self.frame3 = CSQCPlayer_FallbackFrame(self.frame3);
 232         self.frame4 = CSQCPlayer_FallbackFrame(self.frame4);
 233 }
 234
 235 // FEATURE: auto glowmod
 236 .vector glowmod;
 237 void CSQCPlayer_GlowMod_Apply(void)
 238 {
 239         if(self.colormap > 0)
 240                 self.glowmod = colormapPaletteColor(((self.colormap >= 1024) ? self.colormap : stof(getplayerkeyvalue(self.colormap - 1, "colors"))) & 0x0F, TRUE) * 2;
 241         else
 242                 self.glowmod = '1 1 1';
 243 }
 244
 245 // FEATURE: auto tag_index
 246 .entity tag_entity;
 247 .float tag_entity_lastmodelindex;
 248 .float tag_index;
 249 void CSQCModel_AutoTagIndex_Apply(void)
 250 {
 251         if(self.tag_entity && wasfreed(self.tag_entity))
 252                 self.tag_entity = world;
 253
 254         if(self.tag_networkentity)
 255         {
 256                 // we are ATTACHED!
 257                 float changed = 0;
 258                 if(self.tag_entity.entnum != self.tag_networkentity)
 259                 {
 260                         self.tag_entity = findfloat(world, entnum, self.tag_networkentity);
 261                         changed = 1;
 262                 }
 263                 if(self.tag_entity.modelindex != self.tag_entity_lastmodelindex)
 264                 {
 265                         self.tag_entity_lastmodelindex = self.tag_entity.modelindex;
 266                         changed = 1;
 267                 }
 268                 if(changed)
 269                 {
 270                         if(self.tag_entity)
 271                         {
 272                                 // the best part is: IT EXISTS
 273                                 if(substring(self.model, 0, 17) == "models/weapons/v_")
 274                                         if(substring(self.tag_entity.model, 0, 17) == "models/weapons/h_")
 275                                         {
 276                                                 self.tag_index = gettagindex(self.tag_entity, "weapon");
 277                                                 if(!self.tag_index)
 278                                                         self.tag_index = gettagindex(self.tag_entity, "tag_weapon");
 279                                                 if(!self.tag_index)
 280                                                 {
 281                                                         // we need to prevent this from 'appening
 282                                                         self.tag_entity = world;
 283                                                         self.drawmask = 0;
 284                                                         dprint("h_ model lacks weapon attachment, but v_ model is attached to it\n");
 285                                                 }
 286                                         }
 287
 288                                 if(substring(self.model, 0, 17) == "models/weapons/v_")
 289                                         if(substring(self.tag_entity.model, 0, 14) == "models/player/")
 290                                         {
 291                                                 self.tag_index = gettagindex(self.tag_entity, "tag_weapon");
 292                                                 if(!self.tag_index)
 293                                                         self.tag_index = gettagindex(self.tag_entity, "bip01 r hand");
 294                                         }
 295
 296                                 if(substring(self.tag_entity.model, 0, 17) == "models/weapons/v_")
 297                                 {
 298                                         self.tag_index = gettagindex(self.tag_entity, "shot");
 299                                         if(!self.tag_index)
 300                                                 self.tag_index = gettagindex(self.tag_entity, "tag_shot");
 301                                 }
 302                         }
 303                         else
 304                         {
 305                                 // damn, see you next frame
 306                                 self.drawmask = 0;
 307                         }
 308                 }
 309         }
 310 }
 311
 312 // FEATURE: EF_NODRAW workalike
 313 float EF_BRIGHTFIELD    = 1;
 314 float EF_BRIGHTLIGHT    = 4;
 315 float EF_DIMLIGHT       = 8;
 316 float EF_DOUBLESIDED = 32768;
 317 float EF_NOSELFSHADOW = 65536;
 318 float EF_DYNAMICMODELLIGHT = 131072;
 319 float MF_ROCKET  =   1; // leave a trail
 320 float MF_GRENADE =   2; // leave a trail
 321 float MF_GIB     =   4; // leave a trail
 322 float MF_ROTATE  =   8; // rotate (bonus items)
 323 float MF_TRACER  =  16; // green split trail
 324 float MF_ZOMGIB  =  32; // small blood trail
 325 float MF_TRACER2 =  64; // orange split trail
 326 float MF_TRACER3 = 128; // purple trail
 327 .float csqcmodel_effects;
 328 .float csqcmodel_modelflags;
 329 void CSQCModel_Effects_PreUpdate(void)
 330 {
 331         self.effects = self.csqcmodel_effects;
 332         self.modelflags = self.csqcmodel_modelflags;
 333 }
 334 void CSQCModel_Effects_PostUpdate(void)
 335 {
 336         self.csqcmodel_effects = self.effects;
 337         self.csqcmodel_modelflags = self.modelflags;
 338         self.effects = 0;
 339         self.modelflags = 0;
 340         if(self.csqcmodel_teleported)
 341                 Projectile_ResetTrail(self.origin);
 342 }
 343 void CSQCModel_Effects_Apply(void)
 344 {
 345         float eff = self.csqcmodel_effects;
 346         eff &~= CSQCMODEL_EF_INVISIBLE;
 347
 348         self.renderflags &~= (RF_DEPTHHACK | RF_ADDITIVE | RF_FULLBRIGHT | EF_NOSHADOW | RF_USEAXIS);
 349         self.effects = 0;
 350         self.traileffect = 0;
 351
 352         if(eff & EF_BRIGHTFIELD)
 353                 self.traileffect = particleeffectnum("TR_NEXUIZPLASMA");
 354         // ignoring EF_MUZZLEFLASH
 355         if(eff & EF_BRIGHTLIGHT)
 356                 adddynamiclight(self.origin, 400, '3 3 3');
 357         if(eff & EF_DIMLIGHT)
 358                 adddynamiclight(self.origin, 200, '1.5 1.5 1.5');
 359         if((eff & EF_NODRAW) || (self.csqcmodel_effects & CSQCMODEL_EF_INVISIBLE) || (self.alpha < 0))
 360                 self.drawmask = 0;
 361         if(eff & EF_ADDITIVE)
 362                 self.renderflags |= RF_ADDITIVE;
 363         if(eff & EF_BLUE)
 364                 adddynamiclight(self.origin, 200, '0.15 0.15 1.5');
 365         if(eff & EF_RED)
 366                 adddynamiclight(self.origin, 200, '1.5 0.15 0.15');
 367         // ignoring EF_NOGUNBOB
 368         if(eff & EF_FULLBRIGHT)
 369                 self.renderflags |= RF_FULLBRIGHT;
 370         if(eff & EF_FLAME)
 371                 pointparticles(particleeffectnum("EF_FLAME"), self.origin, '0 0 0', bound(0, frametime, 0.1));
 372         if(eff & EF_STARDUST)
 373                 pointparticles(particleeffectnum("EF_STARDUST"), self.origin, '0 0 0', bound(0, frametime, 0.1));
 374         if(eff & EF_NOSHADOW)
 375                 self.renderflags |= RF_NOSHADOW;
 376         if(eff & EF_NODEPTHTEST)
 377                 self.renderflags |= RF_DEPTHHACK;
 378         // ignoring EF_SELECTABLE
 379         if(eff & EF_DOUBLESIDED)
 380                 self.effects |= EF_DOUBLESIDED;
 381         if(eff & EF_NOSELFSHADOW)
 382                 self.effects |= EF_NOSELFSHADOW;
 383         if(eff & EF_DYNAMICMODELLIGHT)
 384                 self.renderflags |= RF_DYNAMICMODELLIGHT;
 385         // ignoring EF_UNUSED18, EF_UNUSED19, EF_RESTARTANIM_BIT, EF_TELEPORT_BIT, EF_LOWPRECISION
 386         if(self.csqcmodel_modelflags & MF_ROCKET)
 387                 self.traileffect = particleeffectnum("TR_ROCKET");
 388         if(self.csqcmodel_modelflags & MF_GRENADE)
 389                 self.traileffect = particleeffectnum("TR_GRENADE");
 390         if(self.csqcmodel_modelflags & MF_GIB)
 391                 self.traileffect = particleeffectnum("TR_BLOOD");
 392         if(self.csqcmodel_modelflags & MF_ROTATE)
 393         {
 394                 self.renderflags |= RF_USEAXIS;
 395                 makevectors(self.angles + '0 100 0' * fmod(time, 3.6));
 396         }
 397         if(self.csqcmodel_modelflags & MF_TRACER)
 398                 self.traileffect = particleeffectnum("TR_WIZSPIKE");
 399         if(self.csqcmodel_modelflags & MF_ZOMGIB)
 400                 self.traileffect = particleeffectnum("TR_SLIGHTBLOOD");
 401         if(self.csqcmodel_modelflags & MF_TRACER2)
 402                 self.traileffect = particleeffectnum("TR_KNIGHTSPIKE");
 403         if(self.csqcmodel_modelflags & MF_TRACER3)
 404                 self.traileffect = particleeffectnum("TR_VORESPIKE");
 405
 406         if(self.drawmask)
 407                 Projectile_DrawTrail(self.origin);
 408         else
 409                 Projectile_ResetTrail(self.origin);
 410 }
 411
 412 // general functions
 413 void CSQCModel_Hook_PreDraw(float isplayer, float islocalplayer)
 414 {
 415         if(!self.modelindex || self.model == "null")
 416         {
 417                 self.drawmask = 0;
 418                 return;
 419         }
 420         else
 421                 self.drawmask = MASK_NORMAL;
 422
 423         if(self.isplayermodel) // this checks if it's a player MODEL!
 424         {
 425                 CSQCPlayer_GlowMod_Apply();
 426                 CSQCPlayer_ForceModel_Apply(islocalplayer);
 427                 CSQCPlayer_LOD_Apply();
 428                 CSQCPlayer_FallbackFrame_Apply();
 429         }
 430
 431         if(!isplayer) // this checks if it's a player SLOT!
 432                 CSQCModel_AutoTagIndex_Apply();
 433
 434         CSQCModel_Effects_Apply();
 435 }
 436
 437 void CSQCModel_Hook_PreUpdate(float isnew, float isplayer, float islocalplayer)
 438 {
 439         // revert to values from server
 440         CSQCModel_Effects_PreUpdate();
 441         if(self.isplayermodel)
 442         {
 443                 CSQCPlayer_FallbackFrame_PreUpdate();
 444                 CSQCPlayer_ForceModel_PreUpdate();
 445         }
 446 }
 447
 448 void CSQCModel_Hook_PostUpdate(float isnew, float isplayer, float islocalplayer)
 449 {
 450         // is it a player model? (shared state)
 451         self.isplayermodel = (substring(self.model, 0, 14) == "models/player/");
 452
 453         // save values set by server
 454         if(self.isplayermodel)
 455         {
 456                 CSQCPlayer_ForceModel_PostUpdate();
 457                 CSQCPlayer_FallbackFrame_PostUpdate(isnew);
 458         }
 459         CSQCModel_Effects_PostUpdate();
 460 }