qcsrc/client/csqcmodel_hooks.qc

   1 void CSQCModel_Hook_PreDraw();
   2
   3 .float isplayermodel;
   4
   5 // FEATURE: LOD
   6 .float lodmodelindex0;
   7 .float lodmodelindex1;
   8 .float lodmodelindex2;
   9 void CSQCPlayer_LOD_Apply(void)
  10 {
  11         // LOD model loading
  12         if(self.lodmodelindex0 != self.modelindex)
  13         {
  14                 string modelname = self.model;
  15                 string s;
  16
  17                 // set modelindex
  18                 self.lodmodelindex0 = self.modelindex;
  19                 self.lodmodelindex1 = self.modelindex;
  20                 self.lodmodelindex2 = self.modelindex;
  21
  22                 // FIXME: this only supports 3-letter extensions
  23                 s = strcat(substring(modelname, 0, strlen(modelname)-4), "_lod1", substring(modelname, -4, 4));
  24                 if(fexists(s))
  25                 {
  26                         precache_model(s);
  27                         setmodel(self, s);
  28                         if(self.modelindex)
  29                                 self.lodmodelindex1 = self.modelindex;
  30                 }
  31
  32                 s = strcat(substring(modelname, 0, strlen(modelname)-4), "_lod2", substring(modelname, -4, 4));
  33                 if(fexists(s))
  34                 {
  35                         precache_model(s);
  36                         setmodel(self, s);
  37                         if(self.modelindex)
  38                                 self.lodmodelindex2 = self.modelindex;
  39                 }
  40
  41                 setmodel(self, modelname); // make everything normal again
  42         }
  43
  44         // apply LOD
  45         if(autocvar_cl_playerdetailreduction <= 0)
  46         {
  47                 if(autocvar_cl_playerdetailreduction <= -2)
  48                         self.modelindex = self.lodmodelindex2;
  49                 else if(autocvar_cl_playerdetailreduction <= -1)
  50                         self.modelindex = self.lodmodelindex1;
  51                 else
  52                         self.modelindex = self.lodmodelindex0;
  53         }
  54         else
  55         {
  56                 float distance = vlen(self.origin - other.origin);
  57                 float f = (distance + 100.0) * autocvar_cl_playerdetailreduction;
  58                 f *= 1.0 / bound(0.01, view_quality, 1);
  59                 if(f > autocvar_cl_loddistance2)
  60                         self.modelindex = self.lodmodelindex2;
  61                 else if(f > autocvar_cl_loddistance1)
  62                         self.modelindex = self.lodmodelindex1;
  63                 else
  64                         self.modelindex = self.lodmodelindex0;
  65         }
  66 }
  67
  68 // FEATURE: forcemodel (MUST be called BEFORE LOD!)
  69 string forceplayermodels_model;
  70 float forceplayermodels_modelisgoodmodel;
  71 float forceplayermodels_modelindex;
  72 float forceplayermodels_skin;
  73
  74 string forceplayermodels_mymodel;
  75 float forceplayermodels_myisgoodmodel;
  76 float forceplayermodels_mymodelindex;
  77
  78 float forceplayermodels_attempted;
  79
  80 .string forceplayermodels_savemodel;
  81 .float forceplayermodels_savemodelindex;
  82 .float forceplayermodels_saveskin;
  83 .float forceplayermodels_savecolormap;
  84
  85 .string forceplayermodels_isgoodmodel_mdl;
  86 .float forceplayermodels_isgoodmodel;
  87
  88 string forceplayermodels_goodmodel;
  89 float forceplayermodels_goodmodelindex;
  90
  91 void CSQCPlayer_ForceModel_PreUpdate(void)
  92 {
  93         self.model = self.forceplayermodels_savemodel;
  94         self.modelindex = self.forceplayermodels_savemodelindex;
  95         self.skin = self.forceplayermodels_saveskin;
  96         self.colormap = self.forceplayermodels_savecolormap;
  97 }
  98 void CSQCPlayer_ForceModel_PostUpdate(void)
  99 {
 100         self.forceplayermodels_savemodel = self.model;
 101         self.forceplayermodels_savemodelindex = self.modelindex;
 102         self.forceplayermodels_saveskin = self.skin;
 103         self.forceplayermodels_savecolormap = self.colormap;
 104
 105         if(self.forceplayermodels_savemodel != self.forceplayermodels_isgoodmodel_mdl)
 106         {
 107                 self.forceplayermodels_isgoodmodel = fexists(self.forceplayermodels_savemodel);
 108                 self.forceplayermodels_isgoodmodel_mdl = self.forceplayermodels_savemodel;
 109                 if(!self.forceplayermodels_isgoodmodel)
 110                         print(sprintf("Warning: missing model %s has been used\n", self.forceplayermodels_savemodel));
 111         }
 112 }
 113 void CSQCPlayer_ForceModel_Apply(float islocalplayer)
 114 {
 115         // which one is ALWAYS good?
 116         if not(forceplayermodels_goodmodel)
 117         {
 118                 entity e;
 119                 e = spawn();
 120                 precache_model(cvar_defstring("_cl_playermodel"));
 121                 setmodel(e, cvar_defstring("_cl_playermodel"));
 122                 forceplayermodels_goodmodel = e.model;
 123                 forceplayermodels_goodmodelindex = e.modelindex;
 124                 remove(e);
 125         }
 126
 127         // first, try finding it from the server
 128         if(self.forceplayermodels_savemodelindex && self.forceplayermodels_savemodel != "null")
 129         {
 130                 if(islocalplayer)
 131                 {
 132                         // trust server's idea of "own player model"
 133                         forceplayermodels_modelisgoodmodel = self.forceplayermodels_isgoodmodel;
 134                         forceplayermodels_model = self.forceplayermodels_savemodel;
 135                         forceplayermodels_modelindex = self.forceplayermodels_savemodelindex;
 136                         forceplayermodels_skin = self.forceplayermodels_saveskin;
 137                         forceplayermodels_attempted = 1;
 138                 }
 139         }
 140
 141         // forcemodel finding
 142         if(!forceplayermodels_attempted)
 143         {
 144                 forceplayermodels_attempted = 1;
 145
 146                 // only if this failed, find it out on our own
 147                 entity e;
 148                 e = spawn();
 149                 setmodel(e, autocvar__cl_playermodel); // this is harmless, see below
 150                 forceplayermodels_modelisgoodmodel = fexists(e.model);
 151                 forceplayermodels_model = e.model;
 152                 forceplayermodels_modelindex = e.modelindex;
 153                 forceplayermodels_skin = autocvar__cl_playerskin;
 154                 remove(e);
 155         }
 156
 157         if(autocvar_cl_forcemyplayermodel != "" && autocvar_cl_forcemyplayermodel != forceplayermodels_mymodel)
 158         {
 159                 entity e;
 160                 e = spawn();
 161                 setmodel(e, autocvar_cl_forcemyplayermodel); // this is harmless, see below
 162                 forceplayermodels_myisgoodmodel = fexists(e.model);
 163                 forceplayermodels_mymodel = e.model;
 164                 forceplayermodels_mymodelindex = e.modelindex;
 165                 remove(e);
 166         }
 167
 168         // apply it
 169         if(autocvar_cl_forcemyplayermodel != "" && forceplayermodels_myisgoodmodel && islocalplayer)
 170         {
 171                 self.model = forceplayermodels_mymodel;
 172                 self.modelindex = forceplayermodels_mymodelindex;
 173                 self.skin = autocvar_cl_forcemyplayerskin;
 174         }
 175         else if(autocvar_cl_forceplayermodels && forceplayermodels_modelisgoodmodel)
 176         {
 177                 self.model = forceplayermodels_model;
 178                 self.modelindex = forceplayermodels_modelindex;
 179                 self.skin = forceplayermodels_skin;
 180         }
 181         else if(self.forceplayermodels_isgoodmodel)
 182         {
 183                 self.model = self.forceplayermodels_savemodel;
 184                 self.modelindex = self.forceplayermodels_savemodelindex;
 185                 self.skin = self.forceplayermodels_saveskin;
 186         }
 187         else
 188         {
 189                 self.model = forceplayermodels_goodmodel;
 190                 self.modelindex = forceplayermodels_goodmodelindex;
 191                 self.skin = self.forceplayermodels_saveskin;
 192         }
 193
 194         // forceplayercolors too
 195         if(!teamplay)
 196         {
 197                 if(autocvar_cl_forcemyplayercolors && islocalplayer)
 198                         self.colormap = 1024 + autocvar_cl_forcemyplayercolors;
 199                 else if(autocvar_cl_forceplayercolors)
 200                         self.colormap = player_localnum + 1;
 201         }
 202 }
 203
 204 // FEATURE: fallback frames
 205 .float csqcmodel_saveframe;
 206 .float csqcmodel_saveframe2;
 207 .float csqcmodel_saveframe3;
 208 .float csqcmodel_saveframe4;
 209 .float csqcmodel_framecount;
 210
 211 #define IS_DEAD_FRAME(f) ((f) == 0 || (f) == 1)
 212 void CSQCPlayer_FallbackFrame_PreUpdate(void)
 213 {
 214         self.frame = self.csqcmodel_saveframe;
 215         self.frame2 = self.csqcmodel_saveframe2;
 216         self.frame3 = self.csqcmodel_saveframe3;
 217         self.frame4 = self.csqcmodel_saveframe4;
 218 }
 219 void CSQCPlayer_FallbackFrame_PostUpdate(float isnew)
 220 {
 221         self.csqcmodel_saveframe = self.frame;
 222         self.csqcmodel_saveframe2 = self.frame2;
 223         self.csqcmodel_saveframe3 = self.frame3;
 224         self.csqcmodel_saveframe4 = self.frame4;
 225
 226         // hack for death animations: set their frametime to zero in case a
 227         // player "pops in"
 228         if(isnew)
 229         {
 230 #define FIX_FRAMETIME(f,ft) \
 231                 if(IS_DEAD_FRAME(self.f) && self.ft != 0 && self.death_time != 0) \
 232                 { \
 233                         self.ft = self.death_time; \
 234                 }
 235                 FIX_FRAMETIME(frame, frame1time)
 236                 FIX_FRAMETIME(frame2, frame2time)
 237                 FIX_FRAMETIME(frame3, frame3time)
 238                 FIX_FRAMETIME(frame4, frame4time)
 239         }
 240         self.csqcmodel_isdead = IS_DEAD_FRAME(self.frame);
 241 }
 242 float CSQCPlayer_FallbackFrame(float f)
 243 {
 244         if(frameduration(self.modelindex, f) > 0)
 245                 return f; // goooooood
 246         switch(f)
 247         {
 248                 case 23: return 11; // anim_melee -> anim_shoot
 249                 case 24: return 4; // anim_duckwalkbackwards -> anim_duckwalk
 250                 case 25: return 4; // anim_duckwalkstrafeleft -> anim_duckwalk
 251                 case 26: return 4; // anim_duckwalkstraferight -> anim_duckwalk
 252                 case 27: return 4; // anim_duckwalkforwardright -> anim_duckwalk
 253                 case 28: return 4; // anim_duckwalkforwardleft -> anim_duckwalk
 254                 case 29: return 4; // anim_duckwalkbackright -> anim_duckwalk
 255                 case 30: return 4; // anim_duckwalkbackleft -> anim_duckwalk
 256         }
 257         print(sprintf("Frame %d missing in model %s, and we have no fallback - FAIL!\n", f, self.model));
 258         return f;
 259 }
 260 void CSQCPlayer_FallbackFrame_Apply(void)
 261 {
 262         self.frame = CSQCPlayer_FallbackFrame(self.frame);
 263         self.frame2 = CSQCPlayer_FallbackFrame(self.frame2);
 264         self.frame3 = CSQCPlayer_FallbackFrame(self.frame3);
 265         self.frame4 = CSQCPlayer_FallbackFrame(self.frame4);
 266 }
 267
 268 // FEATURE: auto tag_index
 269 .entity tag_entity;
 270 .float tag_entity_lastmodelindex;
 271 .float tag_index;
 272 void CSQCModel_AutoTagIndex_Apply(void)
 273 {
 274         if(self.tag_entity && wasfreed(self.tag_entity))
 275                 self.tag_entity = world;
 276
 277         if(self.tag_networkentity)
 278         {
 279                 // we are ATTACHED!
 280                 float changed = 0;
 281                 if(self.tag_entity.entnum != self.tag_networkentity)
 282                 {
 283                         self.tag_entity = findfloat(world, entnum, self.tag_networkentity);
 284                         changed = 1;
 285                 }
 286
 287                 // recursive predraw call to fix issues with forcemodels and LOD if bone indexes mismatch
 288                 {
 289                         entity oldself = self;
 290                         self = self.tag_entity;
 291                         CSQCModel_Hook_PreDraw();
 292                         self = oldself;
 293                 }
 294
 295                 if(self.tag_entity.modelindex != self.tag_entity_lastmodelindex)
 296                 {
 297                         self.tag_entity_lastmodelindex = self.tag_entity.modelindex;
 298                         changed = 1;
 299                 }
 300                 if(changed)
 301                 {
 302                         if(self.tag_entity)
 303                         {
 304                                 // the best part is: IT EXISTS
 305                                 if(substring(self.model, 0, 17) == "models/weapons/v_")
 306                                         if(substring(self.tag_entity.model, 0, 17) == "models/weapons/h_")
 307                                         {
 308                                                 self.tag_index = gettagindex(self.tag_entity, "weapon");
 309                                                 if(!self.tag_index)
 310                                                         self.tag_index = gettagindex(self.tag_entity, "tag_weapon");
 311                                                 if(!self.tag_index)
 312                                                 {
 313                                                         // we need to prevent this from 'appening
 314                                                         self.tag_entity = world;
 315                                                         self.drawmask = 0;
 316                                                         dprint("h_ model lacks weapon attachment, but v_ model is attached to it\n");
 317                                                 }
 318                                         }
 319
 320                                 if(substring(self.model, 0, 17) == "models/weapons/v_")
 321                                         if(substring(self.tag_entity.model, 0, 14) == "models/player/")
 322                                         {
 323                                                 self.tag_index = gettagindex(self.tag_entity, "tag_weapon");
 324                                                 if(!self.tag_index)
 325                                                         self.tag_index = gettagindex(self.tag_entity, "bip01 r hand");
 326                                         }
 327
 328                                 if(substring(self.tag_entity.model, 0, 17) == "models/weapons/v_")
 329                                 {
 330                                         self.tag_index = gettagindex(self.tag_entity, "shot");
 331                                         if(!self.tag_index)
 332                                                 self.tag_index = gettagindex(self.tag_entity, "tag_shot");
 333                                 }
 334                         }
 335                         else
 336                         {
 337                                 // damn, see you next frame
 338                                 self.drawmask = 0;
 339                         }
 340                 }
 341         }
 342 }
 343
 344 // FEATURE: EF_NODRAW workalike
 345 float EF_BRIGHTFIELD    = 1;
 346 float EF_BRIGHTLIGHT    = 4;
 347 float EF_DIMLIGHT       = 8;
 348 float EF_DOUBLESIDED = 32768;
 349 float EF_NOSELFSHADOW = 65536;
 350 float EF_DYNAMICMODELLIGHT = 131072;
 351 float MF_ROCKET  =   1; // leave a trail
 352 float MF_GRENADE =   2; // leave a trail
 353 float MF_GIB     =   4; // leave a trail
 354 float MF_ROTATE  =   8; // rotate (bonus items)
 355 float MF_TRACER  =  16; // green split trail
 356 float MF_ZOMGIB  =  32; // small blood trail
 357 float MF_TRACER2 =  64; // orange split trail
 358 float MF_TRACER3 = 128; // purple trail
 359 .float csqcmodel_effects;
 360 .float csqcmodel_modelflags;
 361 void CSQCModel_Effects_PreUpdate(void)
 362 {
 363         self.effects = self.csqcmodel_effects;
 364         self.modelflags = self.csqcmodel_modelflags;
 365 }
 366 void CSQCModel_Effects_PostUpdate(void)
 367 {
 368         self.csqcmodel_effects = self.effects;
 369         self.csqcmodel_modelflags = self.modelflags;
 370         self.effects = 0;
 371         self.modelflags = 0;
 372         if(self.csqcmodel_teleported)
 373                 Projectile_ResetTrail(self.origin);
 374 }
 375 void CSQCModel_Effects_Apply(void)
 376 {
 377         float eff = self.csqcmodel_effects;
 378         eff &~= CSQCMODEL_EF_RESPAWNGHOST;
 379
 380         self.renderflags &~= (RF_DEPTHHACK | RF_ADDITIVE | RF_FULLBRIGHT | EF_NOSHADOW | RF_USEAXIS);
 381         self.effects = 0;
 382         self.traileffect = 0;
 383
 384         if(eff & EF_BRIGHTFIELD)
 385                 self.traileffect = particleeffectnum("TR_NEXUIZPLASMA");
 386         // ignoring EF_MUZZLEFLASH
 387         if(eff & EF_BRIGHTLIGHT)
 388                 adddynamiclight(self.origin, 400, '3 3 3');
 389         if(eff & EF_DIMLIGHT)
 390                 adddynamiclight(self.origin, 200, '1.5 1.5 1.5');
 391         if((eff & EF_NODRAW) || (self.alpha < 0))
 392                 self.drawmask = 0;
 393         if(eff & EF_ADDITIVE)
 394                 self.renderflags |= RF_ADDITIVE;
 395         if(eff & EF_BLUE)
 396                 adddynamiclight(self.origin, 200, '0.15 0.15 1.5');
 397         if(eff & EF_RED)
 398                 adddynamiclight(self.origin, 200, '1.5 0.15 0.15');
 399         // ignoring EF_NOGUNBOB
 400         if(eff & EF_FULLBRIGHT)
 401                 self.renderflags |= RF_FULLBRIGHT;
 402         if(eff & EF_FLAME)
 403                 pointparticles(particleeffectnum("EF_FLAME"), self.origin, '0 0 0', bound(0, frametime, 0.1));
 404         if(eff & EF_STARDUST)
 405                 pointparticles(particleeffectnum("EF_STARDUST"), self.origin, '0 0 0', bound(0, frametime, 0.1));
 406         if(eff & EF_NOSHADOW)
 407                 self.renderflags |= RF_NOSHADOW;
 408         if(eff & EF_NODEPTHTEST)
 409                 self.renderflags |= RF_DEPTHHACK;
 410         // ignoring EF_SELECTABLE
 411         if(eff & EF_DOUBLESIDED)
 412                 self.effects |= EF_DOUBLESIDED;
 413         if(eff & EF_NOSELFSHADOW)
 414                 self.effects |= EF_NOSELFSHADOW;
 415         if(eff & EF_DYNAMICMODELLIGHT)
 416                 self.renderflags |= RF_DYNAMICMODELLIGHT;
 417         // ignoring EF_UNUSED18, EF_UNUSED19, EF_RESTARTANIM_BIT, EF_TELEPORT_BIT, EF_LOWPRECISION
 418         if(self.csqcmodel_modelflags & MF_ROCKET)
 419                 self.traileffect = particleeffectnum("TR_ROCKET");
 420         if(self.csqcmodel_modelflags & MF_GRENADE)
 421                 self.traileffect = particleeffectnum("TR_GRENADE");
 422         if(self.csqcmodel_modelflags & MF_GIB)
 423                 self.traileffect = particleeffectnum("TR_BLOOD");
 424         if(self.csqcmodel_modelflags & MF_ROTATE)
 425         {
 426                 self.renderflags |= RF_USEAXIS;
 427                 makevectors(self.angles + '0 100 0' * fmod(time, 3.6));
 428         }
 429         if(self.csqcmodel_modelflags & MF_TRACER)
 430                 self.traileffect = particleeffectnum("TR_WIZSPIKE");
 431         if(self.csqcmodel_modelflags & MF_ZOMGIB)
 432                 self.traileffect = particleeffectnum("TR_SLIGHTBLOOD");
 433         if(self.csqcmodel_modelflags & MF_TRACER2)
 434                 self.traileffect = particleeffectnum("TR_KNIGHTSPIKE");
 435         if(self.csqcmodel_modelflags & MF_TRACER3)
 436                 self.traileffect = particleeffectnum("TR_VORESPIKE");
 437
 438         if(self.drawmask)
 439                 Projectile_DrawTrail(self.origin);
 440         else
 441                 Projectile_ResetTrail(self.origin);
 442
 443         if(self.csqcmodel_effects & CSQCMODEL_EF_RESPAWNGHOST)
 444                 self.renderflags |= RF_ADDITIVE;
 445                 // also special in CSQCPlayer_GlowMod_Apply
 446 }
 447
 448 // FEATURE: auto glowmod
 449 .vector glowmod;
 450 void CSQCPlayer_GlowMod_Apply(void)
 451 {
 452         float cm = self.colormap;
 453
 454         if(self.csqcmodel_effects & CSQCMODEL_EF_RESPAWNGHOST)
 455                 cm = 1024;
 456
 457         if(self.colormap > 0)
 458                 self.glowmod = colormapPaletteColor(((self.colormap >= 1024) ? self.colormap : stof(getplayerkeyvalue(self.colormap - 1, "colors"))) & 0x0F, TRUE) * 2;
 459         else
 460                 self.glowmod = '1 1 1';
 461
 462         if(autocvar_cl_deathglow > 0)
 463                 if(self.csqcmodel_isdead)
 464                 {
 465                         self.glowmod = self.glowmod * bound(0, 1 - (time - self.death_time) / autocvar_cl_deathglow, 1);
 466                         // prevent the zero vector
 467                         self.glowmod_x = max(self.glowmod_x, 0.0001);
 468                         self.glowmod_y = max(self.glowmod_y, 0.0001);
 469                         self.glowmod_z = max(self.glowmod_z, 0.0001);
 470                 }
 471 }
 472
 473 // general functions
 474 .float csqcmodel_predraw_run;
 475 void CSQCModel_Hook_PreDraw()
 476 {
 477         if(self.csqcmodel_predraw_run == framecount)
 478                 return;
 479         self.csqcmodel_predraw_run = framecount;
 480
 481         if(!self.modelindex || self.model == "null")
 482         {
 483                 self.drawmask = 0;
 484                 return;
 485         }
 486         else
 487                 self.drawmask = MASK_NORMAL;
 488
 489         if(self.isplayermodel) // this checks if it's a player MODEL!
 490         {
 491                 CSQCPlayer_ForceModel_Apply(self.entnum == player_localnum + 1);
 492                 CSQCPlayer_GlowMod_Apply();
 493                 CSQCPlayer_LOD_Apply();
 494                 CSQCPlayer_FallbackFrame_Apply();
 495         }
 496
 497         CSQCModel_AutoTagIndex_Apply();
 498
 499         CSQCModel_Effects_Apply();
 500 }
 501
 502 void CSQCModel_Hook_PreUpdate(float isnew, float isplayer, float islocalplayer)
 503 {
 504         // revert to values from server
 505         CSQCModel_Effects_PreUpdate();
 506         if(self.isplayermodel)
 507         {
 508                 CSQCPlayer_FallbackFrame_PreUpdate();
 509                 CSQCPlayer_ForceModel_PreUpdate();
 510         }
 511 }
 512
 513 void CSQCModel_Hook_PostUpdate(float isnew, float isplayer, float islocalplayer)
 514 {
 515         // is it a player model? (shared state)
 516         self.isplayermodel = (substring(self.model, 0, 14) == "models/player/");
 517
 518         // save values set by server
 519         if(self.isplayermodel)
 520         {
 521                 CSQCPlayer_ForceModel_PostUpdate();
 522                 CSQCPlayer_FallbackFrame_PostUpdate(isnew);
 523         }
 524         CSQCModel_Effects_PostUpdate();
 525 }