qcsrc/client/damage.qc

   1 void DamageEffect(vector hitorg, float dmg, float type, float specnum1, float entnumber);
   2 void Ent_DamageInfo(float isNew)
   3 {
   4         float dmg, rad, edge, thisdmg, forcemul, species;
   5         vector force, thisforce;
   6         entity oldself;
   7
   8         oldself = self;
   9
  10         w_deathtype = ReadShort();
  11         w_issilent = (w_deathtype & 0x8000);
  12         w_deathtype = (w_deathtype & 0x7FFF);
  13
  14         w_org_x = ReadCoord();
  15         w_org_y = ReadCoord();
  16         w_org_z = ReadCoord();
  17
  18         dmg = ReadByte();
  19         rad = ReadByte();
  20         edge = ReadByte();
  21         force = decompressShortVector(ReadShort());
  22         species = ReadByte();
  23
  24         if not(isNew)
  25                 return;
  26
  27         if(rad < 0)
  28         {
  29                 rad = -rad;
  30                 forcemul = -1;
  31         }
  32         else
  33                 forcemul = 1;
  34
  35         for(self = findradius(w_org, rad + MAX_DAMAGEEXTRARADIUS); self; self = self.chain)
  36         {
  37                 vector nearest = NearestPointOnBox(self, w_org);
  38                 if(rad)
  39                 {
  40                         thisdmg = ((vlen (nearest - w_org) - bound(MIN_DAMAGEEXTRARADIUS, self.damageextraradius, MAX_DAMAGEEXTRARADIUS)) / rad);
  41                         if(thisdmg >= 1)
  42                                 continue;
  43                         if(dmg)
  44                         {
  45                                 thisdmg = dmg + (edge - dmg) * thisdmg;
  46                                 thisforce = forcemul * vlen(force) * (thisdmg / dmg) * normalize(self.origin - w_org);
  47                         }
  48                         else
  49                         {
  50                                 thisdmg = 0;
  51                                 thisforce = forcemul * vlen(force) * normalize(self.origin - w_org);
  52                         }
  53                 }
  54                 else
  55                 {
  56                         if(vlen(nearest - w_org) > bound(MIN_DAMAGEEXTRARADIUS, self.damageextraradius, MAX_DAMAGEEXTRARADIUS))
  57                                 continue;
  58
  59                         thisdmg = dmg;
  60                         thisforce = forcemul * force;
  61                 }
  62
  63                 if(self.damageforcescale)
  64                         if(vlen(thisforce))
  65                         {
  66                                 self.move_velocity = self.move_velocity + damage_explosion_calcpush(self.damageforcescale * thisforce, self.move_velocity, autocvar_g_balance_damagepush_speedfactor);
  67                                 self.move_flags &~= FL_ONGROUND;
  68                         }
  69
  70                 if(w_issilent)
  71                         self.silent = 1;
  72
  73                 if(self.event_damage)
  74                         self.event_damage(thisdmg, w_deathtype, w_org, thisforce);
  75
  76                 DamageEffect(w_org, thisdmg, w_deathtype, species, self.entnum - 1);
  77         }
  78
  79         self = oldself;
  80
  81         if(DEATH_ISVEHICLE(w_deathtype))
  82         {
  83             traceline(w_org - normalize(force) * 16, w_org + normalize(force) * 16, MOVE_NOMONSTERS, world);
  84             if(trace_plane_normal != '0 0 0')
  85             w_backoff = trace_plane_normal;
  86         else
  87             w_backoff = -1 * normalize(w_org - (w_org + normalize(force) * 16));
  88
  89             setorigin(self, w_org + w_backoff * 2); // for sound() calls
  90
  91             switch(w_deathtype)
  92             {
  93             case DEATH_VHCRUSH:
  94                 break;
  95
  96             case DEATH_SBMINIGUN:
  97                 string _snd;
  98                 _snd = strcat("weapons/ric", ftos(1 + rint(random() * 2)), ".waw");
  99                 sound(self, CH_SHOTS, _snd, VOL_BASE, ATTN_NORM);
 100                 pointparticles(particleeffectnum("spiderbot_minigun_impact"), self.origin, w_backoff * 1000, 1);
 101                 break;
 102             case DEATH_SBROCKET:
 103                 sound(self, CH_SHOTS, "weapons/rocket_impact.wav", VOL_BASE, ATTN_NORM);
 104                 pointparticles(particleeffectnum("spiderbot_rocket_explode"), self.origin, w_backoff * 1000, 1);
 105                 break;
 106             case DEATH_SBBLOWUP:
 107                 sound(self, CH_SHOTS, "weapons/rocket_impact.wav", VOL_BASE, ATTN_MIN);
 108                 pointparticles(particleeffectnum("explosion_big"), self.origin, w_backoff * 1000, 1);
 109                 break;
 110
 111             case DEATH_WAKIGUN:
 112                 sound(self, CH_SHOTS, "weapons/laserimpact.wav", VOL_BASE, ATTN_NORM);
 113                 pointparticles(particleeffectnum("wakizashi_gun_impact"), self.origin, w_backoff * 1000, 1);
 114                 break;
 115             case DEATH_WAKIROCKET:
 116                 sound(self, CH_SHOTS, "weapons/rocket_impact.wav", VOL_BASE, ATTN_NORM);
 117                 pointparticles(particleeffectnum("wakizashi_rocket_explode"), self.origin, w_backoff * 1000, 1);
 118                 break;
 119             case DEATH_WAKIBLOWUP:
 120                 sound(self, CH_SHOTS, "weapons/rocket_impact.wav", VOL_BASE, ATTN_MIN);
 121                 pointparticles(particleeffectnum("explosion_big"), self.origin, w_backoff * 1000, 1);
 122                 break;
 123
 124             case DEATH_RAPTOR_CANNON:
 125                 sound(self, CH_SHOTS, "weapons/laserimpact.wav", VOL_BASE, ATTN_NORM);
 126                 pointparticles(particleeffectnum("raptor_cannon_impact"), self.origin, w_backoff * 1000, 1);
 127                 break;
 128             case DEATH_RAPTOR_BOMB_SPLIT:
 129                 float i;
 130                 vector ang, vel;
 131                 for(i = 1; i < 4; ++i)
 132                 {
 133                     vel = normalize(w_org - (w_org + normalize(force) * 16)) + randomvec() * 128;
 134                     ang = vectoangles(vel);
 135                     RaptorCBShellfragToss(w_org, vel, ang + '0 0 1' * (120 * i));
 136                 }
 137
 138
 139                 sound(self, CH_SHOTS, "weapons/rocket_impact.wav", VOL_BASE, ATTN_NORM);
 140                 pointparticles(particleeffectnum("raptor_bomb_spread"), self.origin, w_backoff * 1000, 1);
 141                 break;
 142             case DEATH_RAPTOR_BOMB:
 143                 sound(self, CH_SHOTS, "weapons/rocket_impact.wav", VOL_BASE, ATTN_NORM);
 144                 pointparticles(particleeffectnum("raptor_bomb_impact"), self.origin, w_backoff * 1000, 1);
 145                 break;
 146             case DEATH_RAPTOR_DEATH:
 147                 sound(self, CH_SHOTS, "weapons/laserimpact.wav", VOL_BASE, ATTN_MIN);
 148                 pointparticles(particleeffectnum("explosion_big"), self.origin, w_backoff * 1000, 1);
 149                 break;
 150             }
 151         }
 152
 153
 154         if(DEATH_ISTURRET(w_deathtype))
 155         {
 156             string _snd;
 157             traceline(w_org - normalize(force) * 16, w_org + normalize(force) * 16, MOVE_NOMONSTERS, world);
 158             if(trace_plane_normal != '0 0 0')
 159             w_backoff = trace_plane_normal;
 160         else
 161             w_backoff = -1 * normalize(w_org - (w_org + normalize(force) * 16));
 162
 163             setorigin(self, w_org + w_backoff * 2); // for sound() calls
 164
 165             switch(w_deathtype)
 166             {
 167              case DEATH_TURRET_EWHEEL:
 168                 sound(self, CH_SHOTS, "weapons/laserimpact.wav", VOL_BASE, ATTN_MIN);
 169                 pointparticles(particleeffectnum("laser_impact"), self.origin, w_backoff * 1000, 1);
 170                 break;
 171
 172              case DEATH_TURRET_FLAC:
 173                 pointparticles(particleeffectnum("hagar_explode"), w_org, '0 0 0', 1);
 174                 _snd = strcat("weapons/hagexp", ftos(1 + rint(random() * 2)), ".waw");
 175                 sound(self, CH_SHOTS, _snd, VOL_BASE, ATTN_NORM);
 176                 break;
 177
 178              case DEATH_TURRET_MLRS:
 179              case DEATH_TURRET_HK:
 180              case DEATH_TURRET_WALKER_ROCKET:
 181              case DEATH_TURRET_HELLION:
 182                 sound(self, CH_SHOTS, "weapons/rocket_impact.wav", VOL_BASE, ATTN_MIN);
 183                 pointparticles(particleeffectnum("rocket_explode"), self.origin, w_backoff * 1000, 1);
 184                 break;
 185
 186              case DEATH_TURRET_MACHINEGUN:
 187              case DEATH_TURRET_WALKER_GUN:
 188                 _snd = strcat("weapons/ric", ftos(1 + rint(random() * 2)), ".waw");
 189                 sound(self, CH_SHOTS, _snd, VOL_BASE, ATTN_NORM);
 190                 pointparticles(particleeffectnum("machinegun_impact"), self.origin, w_backoff * 1000, 1);
 191                 break;
 192
 193              case DEATH_TURRET_PLASMA:
 194                 sound(self, CH_SHOTS, "weapons/electro_impact.wav", VOL_BASE, ATTN_MIN);
 195                 pointparticles(particleeffectnum("electro_impact"), self.origin, w_backoff * 1000, 1);
 196                 break;
 197
 198              case DEATH_TURRET_WALKER_MEELE:
 199                 sound(self, CH_SHOTS, "weapons/ric1.wav", VOL_BASE, ATTN_MIN);
 200                 pointparticles(particleeffectnum("TE_SPARK"), self.origin, w_backoff * 1000, 1);
 201                 break;
 202
 203              case DEATH_TURRET_PHASER:
 204                 break;
 205
 206              case DEATH_TURRET_TESLA:
 207                 te_smallflash(self.origin);
 208                 break;
 209
 210         }
 211         }
 212
 213         // TODO spawn particle effects and sounds based on w_deathtype
 214         if(!DEATH_ISSPECIAL(w_deathtype))
 215         {
 216                 float hitwep;
 217
 218                 hitwep = DEATH_WEAPONOFWEAPONDEATH(w_deathtype);
 219                 w_random = prandom();
 220
 221                 traceline(w_org - normalize(force) * 16, w_org + normalize(force) * 16, MOVE_NOMONSTERS, world);
 222                 if(trace_fraction < 1 && hitwep != WEP_NEX && hitwep != WEP_MINSTANEX)
 223                         w_backoff = trace_plane_normal;
 224                 else
 225                         w_backoff = -1 * normalize(force);
 226                 setorigin(self, w_org + w_backoff * 2); // for sound() calls
 227
 228                 (get_weaponinfo(hitwep)).weapon_func(WR_IMPACTEFFECT);
 229         }
 230 }
 231
 232 void DamageInfo_Precache()
 233 {
 234         float i;
 235         for(i = WEP_FIRST; i <= WEP_LAST; ++i)
 236                 (get_weaponinfo(i)).weapon_func(WR_PRECACHE);
 237 }
 238
 239 // damage effect
 240
 241 .entity dmgent;
 242 .float dmgpartnum, dmgtime;
 243 .float lifetime;
 244
 245 void DamageEffect_Think()
 246 {
 247         self.nextthink = time;
 248         vector org;
 249
 250         if(time >= self.lifetime || !self.owner.drawmask) // time is up or the player got gibbed / disconnected
 251         {
 252                 remove(self);
 253                 self = world;
 254                 return;
 255         }
 256         if(self.dmgtime > time)
 257                 return;
 258         if(!autocvar_cl_damageeffect)
 259                 return; // don't show effects on the invisible dead body if gibs exist
 260         if(self.team == player_localentnum - 1 && !autocvar_chase_active)
 261                 return; // if we aren't in third person mode, hide own damage effect
 262
 263         // Now apply the effect to the player
 264         org = gettaginfo(self, 0);
 265         pointparticles(self.dmgpartnum, org, '0 0 0', 1);
 266         self.dmgtime = time + autocvar_cl_damageeffect;
 267 }
 268
 269 void DamageEffect(vector hitorg, float dmg, float type, float specnum, float entnumber)
 270 {
 271         float life, i;
 272         string specstr, effectnum;
 273         entity e;
 274
 275         if(!autocvar_cl_damageeffect || autocvar_cl_gentle || autocvar_cl_gentle_damage)
 276                 return;
 277         if(self.model == "" || !self.model || !self.drawmask)
 278                 return;
 279
 280         // return if we reached our damage effect count limit
 281         for(e = world; (e = find(e, classname, "damageeffect")); )
 282                 if(e.team == entnumber)
 283                         i += 1;
 284         if(self.isplayermodel && i >= autocvar_cl_damageeffect_limit)
 285                 return; // allow multiple damage effects on players
 286         if(!self.isplayermodel && i)
 287                 return; // allow a single damage effect on objects
 288
 289         specstr = species_prefix(specnum);
 290         life = bound(autocvar_cl_damageeffect_lifetime_min, dmg * autocvar_cl_damageeffect_lifetime, autocvar_cl_damageeffect_lifetime_max);
 291         type = DEATH_WEAPONOF(type);
 292         e = get_weaponinfo(type);
 293
 294         effectnum = strcat("weapondamage_", e.netname);
 295         // if the weapon is a bullet weapon, its damage effect is blood
 296         // since blood is species dependent, use the species tag in this effect
 297         if(type == WEP_SHOTGUN || type == WEP_UZI || type == WEP_RIFLE)
 298         {
 299                 if(self.isplayermodel && specstr != "")
 300                 {
 301                         effectnum = strcat(effectnum, "_", specstr);
 302                         effectnum = substring(effectnum, 0, strlen(effectnum) - 1); // remove the _ symbol at the end of the species tag
 303                 }
 304                 else
 305                         return; // objects can't bleed
 306         }
 307
 308         // if this is a player, damage effects will show on the limb the player was damaged on
 309         if(self.isplayermodel)
 310         {
 311                 float closest;
 312                 FOR_EACH_TAG(self)
 313                 {
 314                         // go through all tags on the player model, and choose the one closest to the damage origin
 315                         if(!closest || vlen(hitorg - gettaginfo(self, tagnum)) <= vlen(hitorg - gettaginfo(self, closest)))
 316                                 closest = tagnum;
 317                 }
 318                 gettaginfo(self, closest); // set gettaginfo_name
 319         }
 320         else
 321                 gettaginfo(self, 0);
 322
 323         e = spawn();
 324         setmodel(e, "models/null.md3");
 325         setattachment(e, self, gettaginfo_name);
 326         e.owner = self;
 327         e.team = entnumber;
 328         e.lifetime = time + life;
 329         e.classname = "damageeffect";
 330         e.dmgpartnum = particleeffectnum(effectnum);
 331         e.think = DamageEffect_Think;
 332         e.nextthink = time;
 333 }