qcsrc/client/hud.qc

   1 #include "scoreboard.qh"
   2 #include "teamradar.qh"
   3 #include "../common/buffs.qh"
   4 #include "../common/counting.qh"
   5 #include "../common/mapinfo.qh"
   6 #include "../common/nades.qh"
   7 #include "../server/t_items.qh"
   8
   9 /*
  10 ==================
  11 Misc HUD functions
  12 ==================
  13 */
  14
  15 // a border picture is a texture containing nine parts:
  16 //   1/4 width: left part
  17 //   1/2 width: middle part (stretched)
  18 //   1/4 width: right part
  19 // divided into
  20 //   1/4 height: top part
  21 //   1/2 height: middle part (stretched)
  22 //   1/4 height: bottom part
  23 void draw_BorderPicture(vector theOrigin, string pic, vector theSize, vector theColor, float theAlpha, vector theBorderSize)
  24 {
  25     if (theBorderSize.x < 0 && theBorderSize.y < 0) // draw whole image as it is
  26     {
  27                 drawpic(theOrigin, pic, theSize, theColor, theAlpha, 0);
  28                 return;
  29     }
  30         if (theBorderSize.x == 0 && theBorderSize.y == 0) // no border
  31         {
  32                 // draw only the central part
  33                 drawsubpic(theOrigin, theSize, pic, '0.25 0.25 0', '0.5 0.5 0', theColor, theAlpha, 0);
  34                 return;
  35         }
  36
  37         vector dX, dY;
  38         vector width, height;
  39         vector bW, bH;
  40         //pic = draw_UseSkinFor(pic);
  41         width = eX * theSize.x;
  42         height = eY * theSize.y;
  43         if(theSize.x <= theBorderSize.x * 2)
  44         {
  45                 // not wide enough... draw just left and right then
  46                 bW = eX * (0.25 * theSize.x / (theBorderSize.x * 2));
  47                 if(theSize.y <= theBorderSize.y * 2)
  48                 {
  49                         // not high enough... draw just corners
  50                         bH = eY * (0.25 * theSize.y / (theBorderSize.y * 2));
  51                         drawsubpic(theOrigin,                 width * 0.5 + height * 0.5, pic, '0 0 0',           bW + bH, theColor, theAlpha, 0);
  52                         drawsubpic(theOrigin + width   * 0.5, width * 0.5 + height * 0.5, pic, eX - bW,           bW + bH, theColor, theAlpha, 0);
  53                         drawsubpic(theOrigin + height  * 0.5, width * 0.5 + height * 0.5, pic, eY - bH,           bW + bH, theColor, theAlpha, 0);
  54                         drawsubpic(theOrigin + theSize * 0.5, width * 0.5 + height * 0.5, pic, eX + eY - bW - bH, bW + bH, theColor, theAlpha, 0);
  55                 }
  56                 else
  57                 {
  58                         dY = theBorderSize.x * eY;
  59                         drawsubpic(theOrigin,                             width * 0.5          +     dY, pic, '0 0    0',           '0 0.25 0' + bW, theColor, theAlpha, 0);
  60                         drawsubpic(theOrigin + width * 0.5,               width * 0.5          +     dY, pic, '0 0    0' + eX - bW, '0 0.25 0' + bW, theColor, theAlpha, 0);
  61                         drawsubpic(theOrigin                        + dY, width * 0.5 + height - 2 * dY, pic, '0 0.25 0',           '0 0.5  0' + bW, theColor, theAlpha, 0);
  62                         drawsubpic(theOrigin + width * 0.5          + dY, width * 0.5 + height - 2 * dY, pic, '0 0.25 0' + eX - bW, '0 0.5  0' + bW, theColor, theAlpha, 0);
  63                         drawsubpic(theOrigin               + height - dY, width * 0.5          +     dY, pic, '0 0.75 0',           '0 0.25 0' + bW, theColor, theAlpha, 0);
  64                         drawsubpic(theOrigin + width * 0.5 + height - dY, width * 0.5          +     dY, pic, '0 0.75 0' + eX - bW, '0 0.25 0' + bW, theColor, theAlpha, 0);
  65                 }
  66         }
  67         else
  68         {
  69                 if(theSize.y <= theBorderSize.y * 2)
  70                 {
  71                         // not high enough... draw just top and bottom then
  72                         bH = eY * (0.25 * theSize.y / (theBorderSize.y * 2));
  73                         dX = theBorderSize.x * eX;
  74                         drawsubpic(theOrigin,                                         dX + height * 0.5, pic, '0    0 0',           '0.25 0 0' + bH, theColor, theAlpha, 0);
  75                         drawsubpic(theOrigin + dX,                        width - 2 * dX + height * 0.5, pic, '0.25 0 0',           '0.5  0 0' + bH, theColor, theAlpha, 0);
  76                         drawsubpic(theOrigin + width - dX,                            dX + height * 0.5, pic, '0.75 0 0',           '0.25 0 0' + bH, theColor, theAlpha, 0);
  77                         drawsubpic(theOrigin              + height * 0.5,             dX + height * 0.5, pic, '0    0 0' + eY - bH, '0.25 0 0' + bH, theColor, theAlpha, 0);
  78                         drawsubpic(theOrigin + dX         + height * 0.5, width - 2 * dX + height * 0.5, pic, '0.25 0 0' + eY - bH, '0.5  0 0' + bH, theColor, theAlpha, 0);
  79                         drawsubpic(theOrigin + width - dX + height * 0.5,             dX + height * 0.5, pic, '0.75 0 0' + eY - bH, '0.25 0 0' + bH, theColor, theAlpha, 0);
  80                 }
  81                 else
  82                 {
  83                         dX = theBorderSize.x * eX;
  84                         dY = theBorderSize.x * eY;
  85                         drawsubpic(theOrigin,                                        dX          +     dY, pic, '0    0    0', '0.25 0.25 0', theColor, theAlpha, 0);
  86                         drawsubpic(theOrigin                  + dX,      width - 2 * dX          +     dY, pic, '0.25 0    0', '0.5  0.25 0', theColor, theAlpha, 0);
  87                         drawsubpic(theOrigin          + width - dX,                  dX          +     dY, pic, '0.75 0    0', '0.25 0.25 0', theColor, theAlpha, 0);
  88                         drawsubpic(theOrigin          + dY,                          dX + height - 2 * dY, pic, '0    0.25 0', '0.25 0.5  0', theColor, theAlpha, 0);
  89                         drawsubpic(theOrigin          + dY         + dX, width - 2 * dX + height - 2 * dY, pic, '0.25 0.25 0', '0.5  0.5  0', theColor, theAlpha, 0);
  90                         drawsubpic(theOrigin          + dY + width - dX,             dX + height - 2 * dY, pic, '0.75 0.25 0', '0.25 0.5  0', theColor, theAlpha, 0);
  91                         drawsubpic(theOrigin + height - dY,                          dX          +     dY, pic, '0    0.75 0', '0.25 0.25 0', theColor, theAlpha, 0);
  92                         drawsubpic(theOrigin + height - dY         + dX, width - 2 * dX          +     dY, pic, '0.25 0.75 0', '0.5  0.25 0', theColor, theAlpha, 0);
  93                         drawsubpic(theOrigin + height - dY + width - dX,             dX          +     dY, pic, '0.75 0.75 0', '0.25 0.25 0', theColor, theAlpha, 0);
  94                 }
  95         }
  96 }
  97
  98 vector HUD_Get_Num_Color (float x, float maxvalue)
  99 {
 100         float blinkingamt;
 101         vector color;
 102         if(x >= maxvalue) {
 103                 color.x = sin(2*M_PI*time);
 104                 color.y = 1;
 105                 color.z = sin(2*M_PI*time);
 106         }
 107         else if(x > maxvalue * 0.75) {
 108                 color.x = 0.4 - (x-150)*0.02 * 0.4; //red value between 0.4 -> 0
 109                 color.y = 0.9 + (x-150)*0.02 * 0.1; // green value between 0.9 -> 1
 110                 color.z = 0;
 111         }
 112         else if(x > maxvalue * 0.5) {
 113                 color.x = 1 - (x-100)*0.02 * 0.6; //red value between 1 -> 0.4
 114                 color.y = 1 - (x-100)*0.02 * 0.1; // green value between 1 -> 0.9
 115                 color.z = 1 - (x-100)*0.02; // blue value between 1 -> 0
 116         }
 117         else if(x > maxvalue * 0.25) {
 118                 color.x = 1;
 119                 color.y = 1;
 120                 color.z = 0.2 + (x-50)*0.02 * 0.8; // blue value between 0.2 -> 1
 121         }
 122         else if(x > maxvalue * 0.1) {
 123                 color.x = 1;
 124                 color.y = (x-20)*90/27/100; // green value between 0 -> 1
 125                 color.z = (x-20)*90/27/100 * 0.2; // blue value between 0 -> 0.2
 126         }
 127         else {
 128                 color.x = 1;
 129                 color.y = 0;
 130                 color.z = 0;
 131         }
 132
 133         blinkingamt = (1 - x/maxvalue/0.25);
 134         if(blinkingamt > 0)
 135         {
 136                 color.x = color.x - color.x * blinkingamt * sin(2*M_PI*time);
 137                 color.y = color.y - color.y * blinkingamt * sin(2*M_PI*time);
 138                 color.z = color.z - color.z * blinkingamt * sin(2*M_PI*time);
 139         }
 140         return color;
 141 }
 142
 143 float HUD_GetRowCount(float item_count, vector size, float item_aspect)
 144 {
 145         float aspect = size_y / size_x;
 146         return bound(1, floor((sqrt(4 * item_aspect * aspect * item_count + aspect * aspect) + aspect + 0.5) / 2), item_count);
 147 }
 148
 149 float stringwidth_colors(string s, vector theSize)
 150 {
 151         return stringwidth(s, true, theSize);
 152 }
 153
 154 float stringwidth_nocolors(string s, vector theSize)
 155 {
 156         return stringwidth(s, false, theSize);
 157 }
 158
 159 void drawstringright(vector position, string text, vector theScale, vector rgb, float theAlpha, float flag)
 160 {
 161         position.x -= 2 / 3 * strlen(text) * theScale.x;
 162         drawstring(position, text, theScale, rgb, theAlpha, flag);
 163 }
 164
 165 void drawstringcenter(vector position, string text, vector theScale, vector rgb, float theAlpha, float flag)
 166 {
 167         position.x = 0.5 * (vid_conwidth - 0.6025 * strlen(text) * theScale.x);
 168         drawstring(position, text, theScale, rgb, theAlpha, flag);
 169 }
 170
 171 // return the string of the onscreen race timer
 172 string MakeRaceString(float cp, float mytime, float histime, float lapdelta, string hisname)
 173 {
 174         string col;
 175         string timestr;
 176         string cpname;
 177         string lapstr;
 178         lapstr = "";
 179
 180         if(histime == 0) // goal hit
 181         {
 182                 if(mytime > 0)
 183                 {
 184                         timestr = strcat("+", ftos_decimals(+mytime, TIME_DECIMALS));
 185                         col = "^1";
 186                 }
 187                 else if(mytime == 0)
 188                 {
 189                         timestr = "+0.0";
 190                         col = "^3";
 191                 }
 192                 else
 193                 {
 194                         timestr = strcat("-", ftos_decimals(-mytime, TIME_DECIMALS));
 195                         col = "^2";
 196                 }
 197
 198                 if(lapdelta > 0)
 199                 {
 200                         lapstr = sprintf(_(" (-%dL)"), lapdelta);
 201                         col = "^2";
 202                 }
 203                 else if(lapdelta < 0)
 204                 {
 205                         lapstr = sprintf(_(" (+%dL)"), -lapdelta);
 206                         col = "^1";
 207                 }
 208         }
 209         else if(histime > 0) // anticipation
 210         {
 211                 if(mytime >= histime)
 212                         timestr = strcat("+", ftos_decimals(mytime - histime, TIME_DECIMALS));
 213                 else
 214                         timestr = TIME_ENCODED_TOSTRING(TIME_ENCODE(histime));
 215                 col = "^3";
 216         }
 217         else
 218         {
 219                 col = "^7";
 220                 timestr = "";
 221         }
 222
 223         if(cp == 254)
 224                 cpname = _("Start line");
 225         else if(cp == 255)
 226                 cpname = _("Finish line");
 227         else if(cp)
 228                 cpname = sprintf(_("Intermediate %d"), cp);
 229         else
 230                 cpname = _("Finish line");
 231
 232         if(histime < 0)
 233                 return strcat(col, cpname);
 234         else if(hisname == "")
 235                 return strcat(col, sprintf("%s (%s)", cpname, timestr));
 236         else
 237                 return strcat(col, sprintf("%s (%s %s)", cpname, timestr, strcat(hisname, col, lapstr)));
 238 }
 239
 240 // Check if the given name already exist in race rankings? In that case, where? (otherwise return 0)
 241 float race_CheckName(string net_name) {
 242         float i;
 243         for (i=RANKINGS_CNT-1;i>=0;--i)
 244                 if(grecordholder[i] == net_name)
 245                         return i+1;
 246         return 0;
 247 }
 248
 249 float GetPlayerColorForce(int i)
 250 {
 251         if(!teamplay)
 252                 return 0;
 253         else
 254                 return stof(getplayerkeyvalue(i, "colors")) & 15;
 255 }
 256
 257 float GetPlayerColor(int i)
 258 {
 259         if(!playerslots[i].gotscores) // unconnected
 260                 return NUM_SPECTATOR;
 261         else if(stof(getplayerkeyvalue(i, "frags")) == FRAGS_SPECTATOR)
 262                 return NUM_SPECTATOR;
 263         else
 264                 return GetPlayerColorForce(i);
 265 }
 266
 267 string GetPlayerName(int i)
 268 {
 269         return ColorTranslateRGB(getplayerkeyvalue(i, "name"));
 270 }
 271
 272
 273 /*
 274 ==================
 275 HUD panels
 276 ==================
 277 */
 278
 279 // draw the background/borders
 280 #define HUD_Panel_DrawBg(theAlpha) do {                                                                                                                                                         \
 281         if(panel.current_panel_bg != "0" && panel.current_panel_bg != "")                                                                                               \
 282                 draw_BorderPicture(panel_pos - '1 1 0' * panel_bg_border, panel.current_panel_bg, panel_size + '1 1 0' * 2 * panel_bg_border, panel_bg_color, panel_bg_alpha * theAlpha, '1 1 0' * (panel_bg_border/BORDER_MULTIPLIER));\
 283 } while(0)
 284
 285 //basically the same code of draw_ButtonPicture and draw_VertButtonPicture for the menu
 286 void HUD_Panel_DrawProgressBar(vector theOrigin, vector theSize, string pic, float length_ratio, float vertical, float baralign, vector theColor, float theAlpha, float drawflag)
 287 {
 288         if(!length_ratio || !theAlpha)
 289                 return;
 290         if(length_ratio > 1)
 291                 length_ratio = 1;
 292         if (baralign == 3)
 293         {
 294                 if(length_ratio < -1)
 295                         length_ratio = -1;
 296         }
 297         else if(length_ratio < 0)
 298                 return;
 299
 300         vector square;
 301         vector width, height;
 302         if(vertical) {
 303                 pic = strcat(hud_skin_path, "/", pic, "_vertical");
 304                 if(precache_pic(pic) == "") {
 305                         pic = "gfx/hud/default/progressbar_vertical";
 306                 }
 307
 308         if (baralign == 1) // bottom align
 309                         theOrigin.y += (1 - length_ratio) * theSize.y;
 310         else if (baralign == 2) // center align
 311             theOrigin.y += 0.5 * (1 - length_ratio) * theSize.y;
 312         else if (baralign == 3) // center align, positive values down, negative up
 313                 {
 314                         theSize.y *= 0.5;
 315                         if (length_ratio > 0)
 316                                 theOrigin.y += theSize.y;
 317                         else
 318                         {
 319                                 theOrigin.y += (1 + length_ratio) * theSize.y;
 320                                 length_ratio = -length_ratio;
 321                         }
 322                 }
 323                 theSize.y *= length_ratio;
 324
 325                 vector bH;
 326                 width = eX * theSize.x;
 327                 height = eY * theSize.y;
 328                 if(theSize.y <= theSize.x * 2)
 329                 {
 330                         // button not high enough
 331                         // draw just upper and lower part then
 332                         square = eY * theSize.y * 0.5;
 333                         bH = eY * (0.25 * theSize.y / (theSize.x * 2));
 334                         drawsubpic(theOrigin,          square + width, pic, '0 0 0', eX + bH, theColor, theAlpha, drawflag);
 335                         drawsubpic(theOrigin + square, square + width, pic, eY - bH, eX + bH, theColor, theAlpha, drawflag);
 336                 }
 337                 else
 338                 {
 339                         square = eY * theSize.x;
 340                         drawsubpic(theOrigin,                   width   +     square, pic, '0 0    0', '1 0.25 0', theColor, theAlpha, drawflag);
 341                         drawsubpic(theOrigin +          square, theSize - 2 * square, pic, '0 0.25 0', '1 0.5  0', theColor, theAlpha, drawflag);
 342                         drawsubpic(theOrigin + height - square, width   +     square, pic, '0 0.75 0', '1 0.25 0', theColor, theAlpha, drawflag);
 343                 }
 344         } else {
 345                 pic = strcat(hud_skin_path, "/", pic);
 346                 if(precache_pic(pic) == "") {
 347                         pic = "gfx/hud/default/progressbar";
 348                 }
 349
 350                 if (baralign == 1) // right align
 351                         theOrigin.x += (1 - length_ratio) * theSize.x;
 352         else if (baralign == 2) // center align
 353             theOrigin.x += 0.5 * (1 - length_ratio) * theSize.x;
 354         else if (baralign == 3) // center align, positive values on the right, negative on the left
 355                 {
 356                         theSize.x *= 0.5;
 357                         if (length_ratio > 0)
 358                                 theOrigin.x += theSize.x;
 359                         else
 360                         {
 361                                 theOrigin.x += (1 + length_ratio) * theSize.x;
 362                                 length_ratio = -length_ratio;
 363                         }
 364                 }
 365                 theSize.x *= length_ratio;
 366
 367                 vector bW;
 368                 width = eX * theSize.x;
 369                 height = eY * theSize.y;
 370                 if(theSize.x <= theSize.y * 2)
 371                 {
 372                         // button not wide enough
 373                         // draw just left and right part then
 374                         square = eX * theSize.x * 0.5;
 375                         bW = eX * (0.25 * theSize.x / (theSize.y * 2));
 376                         drawsubpic(theOrigin,          square + height, pic, '0 0 0', eY + bW, theColor, theAlpha, drawflag);
 377                         drawsubpic(theOrigin + square, square + height, pic, eX - bW, eY + bW, theColor, theAlpha, drawflag);
 378                 }
 379                 else
 380                 {
 381                         square = eX * theSize.y;
 382                         drawsubpic(theOrigin,                  height  +     square, pic, '0    0 0', '0.25 1 0', theColor, theAlpha, drawflag);
 383                         drawsubpic(theOrigin +         square, theSize - 2 * square, pic, '0.25 0 0', '0.5  1 0', theColor, theAlpha, drawflag);
 384                         drawsubpic(theOrigin + width - square, height  +     square, pic, '0.75 0 0', '0.25 1 0', theColor, theAlpha, drawflag);
 385                 }
 386         }
 387 }
 388
 389 void HUD_Panel_DrawHighlight(vector pos, vector mySize, vector color, float theAlpha, float drawflag)
 390 {
 391         if(!theAlpha)
 392                 return;
 393
 394         string pic;
 395         pic = strcat(hud_skin_path, "/num_leading");
 396         if(precache_pic(pic) == "") {
 397                 pic = "gfx/hud/default/num_leading";
 398         }
 399
 400         drawsubpic(pos, eX * min(mySize.x * 0.5, mySize.y) + eY * mySize.y, pic, '0 0 0', '0.25 1 0', color, theAlpha, drawflag);
 401         if(mySize.x/mySize.y > 2)
 402                 drawsubpic(pos + eX * mySize.y, eX * (mySize.x - 2 * mySize.y) + eY * mySize.y, pic, '0.25 0 0', '0.5 1 0', color, theAlpha, drawflag);
 403         drawsubpic(pos + eX * mySize.x - eX * min(mySize.x * 0.5, mySize.y), eX * min(mySize.x * 0.5, mySize.y) + eY * mySize.y, pic, '0.75 0 0', '0.25 1 0', color, theAlpha, drawflag);
 404 }
 405
 406 // Weapon icons (#0)
 407 //
 408 entity weaponorder[WEP_MAXCOUNT];
 409 void weaponorder_swap(int i, int j, entity pass)
 410 {
 411         entity h = weaponorder[i];
 412         weaponorder[i] = weaponorder[j];
 413         weaponorder[j] = h;
 414 }
 415
 416 string weaponorder_cmp_str;
 417 float weaponorder_cmp(float i, float j, entity pass)
 418 {
 419         float ai, aj;
 420         ai = strstrofs(weaponorder_cmp_str, sprintf(" %d ", weaponorder[i].weapon), 0);
 421         aj = strstrofs(weaponorder_cmp_str, sprintf(" %d ", weaponorder[j].weapon), 0);
 422         return aj - ai; // the string is in REVERSE order (higher prio at the right is what we want, but higher prio first is the string)
 423 }
 424
 425 void HUD_Weapons(void)
 426 {
 427         // declarations
 428         WepSet weapons_stat = WepSet_GetFromStat();
 429         float i, f, a;
 430         float screen_ar;
 431         vector center = '0 0 0';
 432         float weapon_count, weapon_id;
 433         float row, column, rows = 0, columns;
 434         float aspect = autocvar_hud_panel_weapons_aspect;
 435
 436         float timeout = autocvar_hud_panel_weapons_timeout;
 437         float timein_effect_length = autocvar_hud_panel_weapons_timeout_speed_in; //? 0.375 : 0);
 438         float timeout_effect_length = autocvar_hud_panel_weapons_timeout_speed_out; //? 0.75 : 0);
 439
 440         vector barsize = '0 0 0', baroffset = '0 0 0';
 441         vector ammo_color = '1 0 1';
 442         float ammo_alpha = 1;
 443
 444         float when = max(1, autocvar_hud_panel_weapons_complainbubble_time);
 445         float fadetime = max(0, autocvar_hud_panel_weapons_complainbubble_fadetime);
 446
 447         vector weapon_pos, weapon_size = '0 0 0';
 448         vector color;
 449
 450         // check to see if we want to continue
 451         if(hud != HUD_NORMAL) { return; }
 452
 453         if(!autocvar__hud_configure)
 454         {
 455                 if((!autocvar_hud_panel_weapons) || (spectatee_status == -1))
 456                         return;
 457                 if(timeout && time >= weapontime + timeout + timeout_effect_length)
 458                 if(autocvar_hud_panel_weapons_timeout_effect == 3 || (autocvar_hud_panel_weapons_timeout_effect == 1 && !(autocvar_hud_panel_weapons_timeout_fadebgmin + autocvar_hud_panel_weapons_timeout_fadefgmin)))
 459                 {
 460                         weaponprevtime = time;
 461                         return;
 462                 }
 463         }
 464
 465         // update generic hud functions
 466         HUD_Panel_UpdateCvars();
 467
 468         draw_beginBoldFont();
 469
 470         // figure out weapon order (how the weapons are sorted) // TODO make this configurable
 471         if(weaponorder_bypriority != autocvar_cl_weaponpriority || !weaponorder[0])
 472         {
 473                 int weapon_cnt;
 474                 if(weaponorder_bypriority)
 475                         strunzone(weaponorder_bypriority);
 476                 if(weaponorder_byimpulse)
 477                         strunzone(weaponorder_byimpulse);
 478
 479                 weaponorder_bypriority = strzone(autocvar_cl_weaponpriority);
 480                 weaponorder_byimpulse = strzone(W_FixWeaponOrder_BuildImpulseList(W_FixWeaponOrder_ForceComplete(W_NumberWeaponOrder(weaponorder_bypriority))));
 481                 weaponorder_cmp_str = strcat(" ", weaponorder_byimpulse, " ");
 482
 483                 weapon_cnt = 0;
 484                 for(i = WEP_FIRST; i <= WEP_LAST; ++i)
 485                 {
 486                         self = get_weaponinfo(i);
 487                         if(self.impulse >= 0)
 488                         {
 489                                 weaponorder[weapon_cnt] = self;
 490                                 ++weapon_cnt;
 491                         }
 492                 }
 493                 for(i = weapon_cnt; i < WEP_MAXCOUNT; ++i)
 494                         weaponorder[i] = world;
 495                 heapsort(weapon_cnt, weaponorder_swap, weaponorder_cmp, world);
 496
 497                 weaponorder_cmp_str = string_null;
 498         }
 499
 500         if(!autocvar_hud_panel_weapons_complainbubble || autocvar__hud_configure || time - complain_weapon_time >= when + fadetime)
 501                 complain_weapon = 0;
 502
 503         if(autocvar__hud_configure)
 504         {
 505                 if(!weapons_stat)
 506                         for(i = WEP_FIRST; i <= WEP_LAST; i += floor((WEP_LAST-WEP_FIRST)/5))
 507                                 weapons_stat |= WepSet_FromWeapon(i);
 508         }
 509
 510         // determine which weapons are going to be shown
 511         if (autocvar_hud_panel_weapons_onlyowned)
 512         {
 513                 if(autocvar__hud_configure)
 514                 {
 515                         if(menu_enabled != 2)
 516                                 HUD_Panel_DrawBg(1); // also draw the bg of the entire panel
 517                 }
 518
 519                 // do we own this weapon?
 520                 weapon_count = 0;
 521                 for(i = 0; i <= WEP_LAST-WEP_FIRST; ++i)
 522                         if((weapons_stat & WepSet_FromWeapon(weaponorder[i].weapon)) || (weaponorder[i].weapon == complain_weapon))
 523                                 ++weapon_count;
 524
 525                 // might as well commit suicide now, no reason to live ;)
 526                 if (weapon_count == 0)
 527                 {
 528                         draw_endBoldFont();
 529                         return;
 530                 }
 531
 532                 vector old_panel_size = panel_size;
 533                 if(panel_bg_padding)
 534                         old_panel_size -= '2 2 0' * panel_bg_padding;
 535
 536                 // NOTE: the goal is to use the all-weapons layout and remove unneeded cells
 537                 // this way weapon icons always have the same size regardless of owned weapon count
 538
 539                 // get the all-weapons layout
 540                 rows = HUD_GetRowCount(WEP_COUNT, old_panel_size, aspect);
 541                 columns = ceil(WEP_COUNT/rows);
 542                 weapon_size.x = old_panel_size.x / columns;
 543                 weapon_size.y = old_panel_size.y / rows;
 544
 545                 // reduce rows and columns as needed
 546                 columns = ceil(weapon_count / rows);
 547                 rows = ceil(weapon_count / columns);
 548
 549                 // NOTE: although weapons should aways look the same even if onlyowned is disabled,
 550                 // we enlarge them a bit when possible to better match the desired aspect ratio
 551                 // as they look much better
 552                 weapon_size.x = min(old_panel_size.x / columns, aspect * weapon_size.y);
 553                 weapon_size.y = min(old_panel_size.y / rows, weapon_size.x / aspect);
 554
 555                 // reduce size of the panel
 556                 panel_size.x = columns * weapon_size.x;
 557                 panel_size.y = rows * weapon_size.y;
 558                 panel_pos.x += (old_panel_size.x - panel_size.x) / 2;
 559                 panel_pos.y += (old_panel_size.y - panel_size.y) / 2;
 560                 if(panel_bg_padding)
 561                         panel_size += '2 2 0' * panel_bg_padding;
 562         }
 563         else
 564                 weapon_count = WEP_COUNT;
 565
 566         // animation for fading in/out the panel respectively when not in use
 567         if(!autocvar__hud_configure)
 568         {
 569                 if (timeout && time >= weapontime + timeout) // apply timeout effect if needed
 570                 {
 571                         f = bound(0, (time - (weapontime + timeout)) / timeout_effect_length, 1);
 572
 573                         // fade the panel alpha
 574                         if(autocvar_hud_panel_weapons_timeout_effect == 1)
 575                         {
 576                                 panel_bg_alpha *= (autocvar_hud_panel_weapons_timeout_fadebgmin * f + (1 - f));
 577                                 panel_fg_alpha *= (autocvar_hud_panel_weapons_timeout_fadefgmin * f + (1 - f));
 578                         }
 579                         else if(autocvar_hud_panel_weapons_timeout_effect == 3)
 580                         {
 581                                 panel_bg_alpha *= (1 - f);
 582                                 panel_fg_alpha *= (1 - f);
 583                         }
 584
 585                         // move the panel off the screen
 586                         if (autocvar_hud_panel_weapons_timeout_effect == 2 || autocvar_hud_panel_weapons_timeout_effect == 3)
 587                         {
 588                                 f *= f; // for a cooler movement
 589                                 center.x = panel_pos.x + panel_size.x/2;
 590                                 center.y = panel_pos.y + panel_size.y/2;
 591                                 screen_ar = vid_conwidth/vid_conheight;
 592                                 if (center.x/center.y < screen_ar) //bottom left
 593                                 {
 594                                         if ((vid_conwidth - center.x)/center.y < screen_ar) //bottom
 595                                                 panel_pos.y += f * (vid_conheight - panel_pos.y);
 596                                         else //left
 597                                                 panel_pos.x -= f * (panel_pos.x + panel_size.x);
 598                                 }
 599                                 else //top right
 600                                 {
 601                                         if ((vid_conwidth - center.x)/center.y < screen_ar) //right
 602                                                 panel_pos.x += f * (vid_conwidth - panel_pos.x);
 603                                         else //top
 604                                                 panel_pos.y -= f * (panel_pos.y + panel_size.y);
 605                                 }
 606                                 if(f == 1)
 607                                         center.x = -1; // mark the panel as off screen
 608                         }
 609                         weaponprevtime = time - (1 - f) * timein_effect_length;
 610                 }
 611                 else if (timeout && time < weaponprevtime + timein_effect_length) // apply timein effect if needed
 612                 {
 613                         f = bound(0, (time - weaponprevtime) / timein_effect_length, 1);
 614
 615                         // fade the panel alpha
 616                         if(autocvar_hud_panel_weapons_timeout_effect == 1)
 617                         {
 618                                 panel_bg_alpha *= (autocvar_hud_panel_weapons_timeout_fadebgmin * (1 - f) + f);
 619                                 panel_fg_alpha *= (autocvar_hud_panel_weapons_timeout_fadefgmin * (1 - f) + f);
 620                         }
 621                         else if(autocvar_hud_panel_weapons_timeout_effect == 3)
 622                         {
 623                                 panel_bg_alpha *= (f);
 624                                 panel_fg_alpha *= (f);
 625                         }
 626
 627                         // move the panel back on screen
 628                         if (autocvar_hud_panel_weapons_timeout_effect == 2 || autocvar_hud_panel_weapons_timeout_effect == 3)
 629                         {
 630                                 f *= f; // for a cooler movement
 631                                 f = 1 - f;
 632                                 center.x = panel_pos.x + panel_size.x/2;
 633                                 center.y = panel_pos.y + panel_size.y/2;
 634                                 screen_ar = vid_conwidth/vid_conheight;
 635                                 if (center.x/center.y < screen_ar) //bottom left
 636                                 {
 637                                         if ((vid_conwidth - center.x)/center.y < screen_ar) //bottom
 638                                                 panel_pos.y += f * (vid_conheight - panel_pos.y);
 639                                         else //left
 640                                                 panel_pos.x -= f * (panel_pos.x + panel_size.x);
 641                                 }
 642                                 else //top right
 643                                 {
 644                                         if ((vid_conwidth - center.x)/center.y < screen_ar) //right
 645                                                 panel_pos.x += f * (vid_conwidth - panel_pos.x);
 646                                         else //top
 647                                                 panel_pos.y -= f * (panel_pos.y + panel_size.y);
 648                                 }
 649                         }
 650                 }
 651         }
 652
 653         // draw the background, then change the virtual size of it to better fit other items inside
 654         HUD_Panel_DrawBg(1);
 655
 656         if(center.x == -1)
 657         {
 658                 draw_endBoldFont();
 659                 return;
 660         }
 661
 662         if(panel_bg_padding)
 663         {
 664                 panel_pos += '1 1 0' * panel_bg_padding;
 665                 panel_size -= '2 2 0' * panel_bg_padding;
 666         }
 667
 668         // after the sizing and animations are done, update the other values
 669
 670         if(!rows) // if rows is > 0 onlyowned code has already updated these vars
 671         {
 672                 rows = HUD_GetRowCount(weapon_count, panel_size, aspect);
 673                 columns = ceil(weapon_count/rows);
 674                 weapon_size = eX * panel_size.x*(1/columns) + eY * panel_size.y*(1/rows);
 675         }
 676
 677         // calculate position/size for visual bar displaying ammount of ammo status
 678         if (autocvar_hud_panel_weapons_ammo)
 679         {
 680                 ammo_color = stov(autocvar_hud_panel_weapons_ammo_color);
 681                 ammo_alpha = panel_fg_alpha * autocvar_hud_panel_weapons_ammo_alpha;
 682
 683                 if(weapon_size.x/weapon_size.y > aspect)
 684                 {
 685                         barsize.x = aspect * weapon_size.y;
 686                         barsize.y = weapon_size.y;
 687                         baroffset.x = (weapon_size.x - barsize.x) / 2;
 688                 }
 689                 else
 690                 {
 691                         barsize.y = 1/aspect * weapon_size.x;
 692                         barsize.x = weapon_size.x;
 693                         baroffset.y = (weapon_size.y - barsize.y) / 2;
 694                 }
 695         }
 696         if(autocvar_hud_panel_weapons_accuracy)
 697                 Accuracy_LoadColors();
 698
 699         // draw items
 700         row = column = 0;
 701         vector label_size = '1 1 0' * min(weapon_size.x, weapon_size.y) * bound(0, autocvar_hud_panel_weapons_label_scale, 1);
 702         for(i = 0; i <= WEP_LAST-WEP_FIRST; ++i)
 703         {
 704                 // retrieve information about the current weapon to be drawn
 705                 self = weaponorder[i];
 706                 weapon_id = self.impulse;
 707
 708                 // skip if this weapon doesn't exist
 709                 if(!self || weapon_id < 0) { continue; }
 710
 711                 // skip this weapon if we don't own it (and onlyowned is enabled)-- or if weapons_complainbubble is showing for this weapon
 712                 if(autocvar_hud_panel_weapons_onlyowned)
 713                 if (!((weapons_stat & WepSet_FromWeapon(self.weapon)) || (self.weapon == complain_weapon)))
 714                         continue;
 715
 716                 // figure out the drawing position of weapon
 717                 weapon_pos = (panel_pos
 718                         + eX * column * weapon_size.x
 719                         + eY * row * weapon_size.y);
 720
 721                 // draw background behind currently selected weapon
 722                 if(self.weapon == switchweapon)
 723                         drawpic_aspect_skin(weapon_pos, "weapon_current_bg", weapon_size, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
 724
 725                 // draw the weapon accuracy
 726                 if(autocvar_hud_panel_weapons_accuracy)
 727                 {
 728                         float panel_weapon_accuracy = weapon_accuracy[self.weapon-WEP_FIRST];
 729                         if(panel_weapon_accuracy >= 0)
 730                         {
 731                                 color = Accuracy_GetColor(panel_weapon_accuracy);
 732                                 drawpic_aspect_skin(weapon_pos, "weapon_accuracy", weapon_size, color, panel_fg_alpha, DRAWFLAG_NORMAL);
 733                         }
 734                 }
 735
 736                 // drawing all the weapon items
 737                 if(weapons_stat & WepSet_FromWeapon(self.weapon))
 738                 {
 739                         // draw the weapon image
 740                         drawpic_aspect_skin(weapon_pos, self.model2, weapon_size, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
 741
 742                         // draw weapon label string
 743                         switch(autocvar_hud_panel_weapons_label)
 744                         {
 745                                 case 1: // weapon number
 746                                         drawstring(weapon_pos, ftos(weapon_id), label_size, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
 747                                         break;
 748
 749                                 case 2: // bind
 750                                         drawstring(weapon_pos, getcommandkey(ftos(weapon_id), strcat("weapon_group_", ftos(weapon_id))), label_size, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
 751                                         break;
 752
 753                                 case 3: // weapon name
 754                                         drawstring(weapon_pos, strtolower(self.message), label_size, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
 755                                         break;
 756
 757                                 default: // nothing
 758                                         break;
 759                         }
 760
 761                         // draw ammo status bar
 762                         if(autocvar_hud_panel_weapons_ammo && (self.ammo_field != ammo_none))
 763                         {
 764                                 float ammo_full;
 765                                 a = getstati(GetAmmoStat(self.ammo_field)); // how much ammo do we have?
 766
 767                                 if(a > 0)
 768                                 {
 769                                         switch(self.ammo_field)
 770                                         {
 771                                                 case ammo_shells:  ammo_full = autocvar_hud_panel_weapons_ammo_full_shells;  break;
 772                                                 case ammo_nails:   ammo_full = autocvar_hud_panel_weapons_ammo_full_nails;   break;
 773                                                 case ammo_rockets: ammo_full = autocvar_hud_panel_weapons_ammo_full_rockets; break;
 774                                                 case ammo_cells:   ammo_full = autocvar_hud_panel_weapons_ammo_full_cells;   break;
 775                                                 case ammo_plasma:  ammo_full = autocvar_hud_panel_weapons_ammo_full_plasma;  break;
 776                                                 case ammo_fuel:    ammo_full = autocvar_hud_panel_weapons_ammo_full_fuel;    break;
 777                                                 default: ammo_full = 60;
 778                                         }
 779
 780                                         drawsetcliparea(
 781                                                 weapon_pos.x + baroffset.x,
 782                                                 weapon_pos.y + baroffset.y,
 783                                                 barsize.x * bound(0, a/ammo_full, 1),
 784                                                 barsize.y
 785                                         );
 786
 787                                         drawpic_aspect_skin(
 788                                                 weapon_pos,
 789                                                 "weapon_ammo",
 790                                                 weapon_size,
 791                                                 ammo_color,
 792                                                 ammo_alpha,
 793                                                 DRAWFLAG_NORMAL
 794                                         );
 795
 796                                         drawresetcliparea();
 797                                 }
 798                         }
 799                 }
 800                 else // draw a "ghost weapon icon" if you don't have the weapon
 801                 {
 802                         drawpic_aspect_skin(weapon_pos, self.model2, weapon_size, '0 0 0', panel_fg_alpha * 0.5, DRAWFLAG_NORMAL);
 803                 }
 804
 805                 // draw the complain message
 806                 if(self.weapon == complain_weapon)
 807                 {
 808                         if(fadetime)
 809                                 a = ((complain_weapon_time + when > time) ? 1 : bound(0, (complain_weapon_time + when + fadetime - time) / fadetime, 1));
 810                         else
 811                                 a = ((complain_weapon_time + when > time) ? 1 : 0);
 812
 813                         string s;
 814                         if(complain_weapon_type == 0) {
 815                                 s = _("Out of ammo");
 816                                 color = stov(autocvar_hud_panel_weapons_complainbubble_color_outofammo);
 817                         }
 818                         else if(complain_weapon_type == 1) {
 819                                 s = _("Don't have");
 820                                 color = stov(autocvar_hud_panel_weapons_complainbubble_color_donthave);
 821                         }
 822                         else {
 823                                 s = _("Unavailable");
 824                                 color = stov(autocvar_hud_panel_weapons_complainbubble_color_unavailable);
 825                         }
 826                         float padding = autocvar_hud_panel_weapons_complainbubble_padding;
 827                         drawpic_aspect_skin(weapon_pos + '1 1 0' * padding, "weapon_complainbubble", weapon_size - '2 2 0' * padding, color, a * panel_fg_alpha, DRAWFLAG_NORMAL);
 828                         drawstring_aspect(weapon_pos + '1 1 0' * padding, s, weapon_size - '2 2 0' * padding, '1 1 1', panel_fg_alpha * a, DRAWFLAG_NORMAL);
 829                 }
 830
 831                 // continue with new position for the next weapon
 832                 ++row;
 833                 if(row >= rows)
 834                 {
 835                         row = 0;
 836                         ++column;
 837                 }
 838         }
 839
 840         draw_endBoldFont();
 841 }
 842
 843 // Ammo (#1)
 844 void DrawNadeScoreBar(vector myPos, vector mySize, vector color)
 845 {
 846
 847         HUD_Panel_DrawProgressBar(
 848                 myPos + eX * autocvar_hud_panel_ammo_progressbar_xoffset * mySize.x,
 849                 mySize - eX * autocvar_hud_panel_ammo_progressbar_xoffset * mySize.x,
 850                 autocvar_hud_panel_ammo_progressbar_name,
 851                 getstatf(STAT_NADE_BONUS_SCORE), 0, 0, color,
 852                 autocvar_hud_progressbar_alpha * panel_fg_alpha, DRAWFLAG_NORMAL);
 853
 854 }
 855
 856 void DrawAmmoNades(vector myPos, vector mySize, float draw_expanding, float expand_time)
 857 {
 858         float theAlpha = 1, a, b;
 859         vector nade_color, picpos, numpos;
 860
 861         nade_color = Nade_Color(getstati(STAT_NADE_BONUS_TYPE));
 862
 863         a = getstatf(STAT_NADE_BONUS);
 864         b = getstatf(STAT_NADE_BONUS_SCORE);
 865
 866         if(autocvar_hud_panel_ammo_iconalign)
 867         {
 868                 numpos = myPos;
 869                 picpos = myPos + eX * 2 * mySize.y;
 870         }
 871         else
 872         {
 873                 numpos = myPos + eX * mySize.y;
 874                 picpos = myPos;
 875         }
 876
 877         DrawNadeScoreBar(myPos, mySize, nade_color);
 878
 879         if(b > 0 || a > 0)
 880         {
 881                 if(autocvar_hud_panel_ammo_text)
 882                         drawstring_aspect(numpos, ftos(a), eX * (2/3) * mySize.x + eY * mySize.y, '1 1 1', panel_fg_alpha * theAlpha, DRAWFLAG_NORMAL);
 883
 884                 if(draw_expanding)
 885                         drawpic_aspect_skin_expanding(picpos, "nade_nbg", '1 1 0' * mySize.y, '1 1 1', panel_fg_alpha * theAlpha, DRAWFLAG_NORMAL, expand_time);
 886
 887                 drawpic_aspect_skin(picpos, "nade_bg" , '1 1 0' * mySize.y, '1 1 1', panel_fg_alpha * theAlpha, DRAWFLAG_NORMAL);
 888                 drawpic_aspect_skin(picpos, "nade_nbg" , '1 1 0' * mySize.y, nade_color, panel_fg_alpha * theAlpha, DRAWFLAG_NORMAL);
 889         }
 890 }
 891
 892 void DrawAmmoItem(vector myPos, vector mySize, .float ammoType, float isCurrent, float isInfinite)
 893 {
 894         if(ammoType == ammo_none)
 895                 return;
 896
 897         // Initialize variables
 898
 899         float ammo;
 900         if(autocvar__hud_configure)
 901         {
 902                 isCurrent = (ammoType == ammo_rockets); // Rockets always current
 903                 ammo = 60;
 904         }
 905         else
 906                 ammo = getstati(GetAmmoStat(ammoType));
 907
 908         if(!isCurrent)
 909         {
 910                 float scale = bound(0, autocvar_hud_panel_ammo_noncurrent_scale, 1);
 911                 myPos = myPos + (mySize - mySize * scale) * 0.5;
 912                 mySize = mySize * scale;
 913         }
 914
 915         vector iconPos, textPos;
 916         if(autocvar_hud_panel_ammo_iconalign)
 917         {
 918                 iconPos = myPos + eX * 2 * mySize.y;
 919                 textPos = myPos;
 920         }
 921         else
 922         {
 923                 iconPos = myPos;
 924                 textPos = myPos + eX * mySize.y;
 925         }
 926
 927         float isShadowed = (ammo <= 0 && !isCurrent && !isInfinite);
 928
 929         vector iconColor = isShadowed ? '0 0 0' : '1 1 1';
 930         vector textColor;
 931         if(isInfinite)
 932                 textColor = '0.2 0.95 0';
 933         else if(isShadowed)
 934                 textColor = '0 0 0';
 935         else if(ammo < 10)
 936                 textColor = '0.8 0.04 0';
 937         else
 938                 textColor = '1 1 1';
 939
 940         float alpha;
 941         if(isCurrent)
 942                 alpha = panel_fg_alpha;
 943         else if(isShadowed)
 944                 alpha = panel_fg_alpha * bound(0, autocvar_hud_panel_ammo_noncurrent_alpha, 1) * 0.5;
 945         else
 946                 alpha = panel_fg_alpha * bound(0, autocvar_hud_panel_ammo_noncurrent_alpha, 1);
 947
 948         string text = isInfinite ? "\xE2\x88\x9E" : ftos(ammo); // Use infinity symbol (U+221E)
 949
 950         // Draw item
 951
 952         if(isCurrent)
 953                 drawpic_aspect_skin(myPos, "ammo_current_bg", mySize, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
 954
 955         if(ammo > 0 && autocvar_hud_panel_ammo_progressbar)
 956                 HUD_Panel_DrawProgressBar(myPos + eX * autocvar_hud_panel_ammo_progressbar_xoffset * mySize.x, mySize - eX * autocvar_hud_panel_ammo_progressbar_xoffset * mySize.x, autocvar_hud_panel_ammo_progressbar_name, ammo/autocvar_hud_panel_ammo_maxammo, 0, 0, textColor, autocvar_hud_progressbar_alpha * alpha, DRAWFLAG_NORMAL);
 957
 958         if(autocvar_hud_panel_ammo_text)
 959                 drawstring_aspect(textPos, text, eX * (2/3) * mySize.x + eY * mySize.y, textColor, alpha, DRAWFLAG_NORMAL);
 960
 961         drawpic_aspect_skin(iconPos, GetAmmoPicture(ammoType), '1 1 0' * mySize.y, iconColor, alpha, DRAWFLAG_NORMAL);
 962 }
 963
 964 float nade_prevstatus;
 965 float nade_prevframe;
 966 float nade_statuschange_time;
 967 void HUD_Ammo(void)
 968 {
 969         if(hud != HUD_NORMAL) return;
 970         if(!autocvar__hud_configure)
 971         {
 972                 if(!autocvar_hud_panel_ammo) return;
 973                 if(spectatee_status == -1) return;
 974         }
 975
 976         HUD_Panel_UpdateCvars();
 977
 978         draw_beginBoldFont();
 979
 980         vector pos, mySize;
 981         pos = panel_pos;
 982         mySize = panel_size;
 983
 984         HUD_Panel_DrawBg(1);
 985         if(panel_bg_padding)
 986         {
 987                 pos += '1 1 0' * panel_bg_padding;
 988                 mySize -= '2 2 0' * panel_bg_padding;
 989         }
 990
 991         float rows = 0, columns, row, column;
 992         float nade_cnt = getstatf(STAT_NADE_BONUS), nade_score = getstatf(STAT_NADE_BONUS_SCORE);
 993         float draw_nades = (nade_cnt > 0 || nade_score > 0), nade_statuschange_elapsedtime;
 994         float total_ammo_count;
 995
 996         vector ammo_size;
 997         if (autocvar_hud_panel_ammo_onlycurrent)
 998                 total_ammo_count = 1;
 999         else
1000                 total_ammo_count = AMMO_COUNT;
1001
1002         if(draw_nades)
1003         {
1004                 ++total_ammo_count;
1005                 if (nade_cnt != nade_prevframe)
1006                 {
1007                         nade_statuschange_time = time;
1008                         nade_prevstatus = nade_prevframe;
1009                         nade_prevframe = nade_cnt;
1010                 }
1011         }
1012         else
1013                 nade_prevstatus = nade_prevframe = nade_statuschange_time = 0;
1014
1015         rows = HUD_GetRowCount(total_ammo_count, mySize, 3);
1016         columns = ceil((total_ammo_count)/rows);
1017         ammo_size = eX * mySize.x*(1/columns) + eY * mySize.y*(1/rows);
1018
1019         vector offset = '0 0 0'; // fteqcc sucks
1020         float newSize;
1021         if(ammo_size.x/ammo_size.y > 3)
1022         {
1023                 newSize = 3 * ammo_size.y;
1024                 offset.x = ammo_size.x - newSize;
1025                 pos.x += offset.x/2;
1026                 ammo_size.x = newSize;
1027         }
1028         else
1029         {
1030                 newSize = 1/3 * ammo_size.x;
1031                 offset.y = ammo_size.y - newSize;
1032                 pos.y += offset.y/2;
1033                 ammo_size.y = newSize;
1034         }
1035
1036         float i;
1037         float infinite_ammo = (getstati(STAT_ITEMS, 0, 24) & IT_UNLIMITED_WEAPON_AMMO);
1038         row = column = 0;
1039         if(autocvar_hud_panel_ammo_onlycurrent)
1040         {
1041                 if(autocvar__hud_configure)
1042                 {
1043                         DrawAmmoItem(pos, ammo_size, ammo_rockets, true, false);
1044                 }
1045                 else
1046                 {
1047                         DrawAmmoItem(
1048                                 pos,
1049                                 ammo_size,
1050                                 (get_weaponinfo(switchweapon)).ammo_field,
1051                                 true,
1052                                 infinite_ammo
1053                         );
1054                 }
1055
1056                 ++row;
1057                 if(row >= rows)
1058                 {
1059                         row = 0;
1060                         column = column + 1;
1061                 }
1062         }
1063         else
1064         {
1065                 .float ammotype;
1066                 row = column = 0;
1067                 for(i = 0; i < AMMO_COUNT; ++i)
1068                 {
1069                         ammotype = GetAmmoFieldFromNum(i);
1070                         DrawAmmoItem(
1071                                 pos + eX * column * (ammo_size.x + offset.x) + eY * row * (ammo_size.y + offset.y),
1072                                 ammo_size,
1073                                 ammotype,
1074                                 ((get_weaponinfo(switchweapon)).ammo_field == ammotype),
1075                                 infinite_ammo
1076                         );
1077
1078                         ++row;
1079                         if(row >= rows)
1080                         {
1081                                 row = 0;
1082                                 column = column + 1;
1083                         }
1084                 }
1085         }
1086
1087         if (draw_nades)
1088         {
1089                 nade_statuschange_elapsedtime = time - nade_statuschange_time;
1090
1091                 float f = bound(0, nade_statuschange_elapsedtime*2, 1);
1092
1093                 DrawAmmoNades(pos + eX * column * (ammo_size.x + offset.x) + eY * row * (ammo_size.y + offset.y), ammo_size, nade_prevstatus < nade_cnt && nade_cnt != 0 && f < 1, f);
1094         }
1095
1096         draw_endBoldFont();
1097 }
1098
1099 void DrawNumIcon_expanding(vector myPos, vector mySize, float x, string icon, float vertical, float icon_right_align, vector color, float theAlpha, float fadelerp)
1100 {
1101         vector newPos = '0 0 0', newSize = '0 0 0';
1102         vector picpos, numpos;
1103
1104         if (vertical)
1105         {
1106                 if(mySize.y/mySize.x > 2)
1107                 {
1108                         newSize.y = 2 * mySize.x;
1109                         newSize.x = mySize.x;
1110
1111                         newPos.y = myPos.y + (mySize.y - newSize.y) / 2;
1112                         newPos.x = myPos.x;
1113                 }
1114                 else
1115                 {
1116                         newSize.x = 1/2 * mySize.y;
1117                         newSize.y = mySize.y;
1118
1119                         newPos.x = myPos.x + (mySize.x - newSize.x) / 2;
1120                         newPos.y = myPos.y;
1121                 }
1122
1123                 if(icon_right_align)
1124                 {
1125                         numpos = newPos;
1126                         picpos = newPos + eY * newSize.x;
1127                 }
1128                 else
1129                 {
1130                         picpos = newPos;
1131                         numpos = newPos + eY * newSize.x;
1132                 }
1133
1134                 newSize.y /= 2;
1135                 drawpic_aspect_skin(picpos, icon, newSize, '1 1 1', panel_fg_alpha * theAlpha, DRAWFLAG_NORMAL);
1136                 // make number smaller than icon, it looks better
1137                 // reduce only y to draw numbers with different number of digits with the same y size
1138                 numpos.y += newSize.y * ((1 - 0.7) / 2);
1139                 newSize.y *= 0.7;
1140                 drawstring_aspect(numpos, ftos(x), newSize, color, panel_fg_alpha * theAlpha, DRAWFLAG_NORMAL);
1141                 return;
1142         }
1143
1144         if(mySize.x/mySize.y > 3)
1145         {
1146                 newSize.x = 3 * mySize.y;
1147                 newSize.y = mySize.y;
1148
1149                 newPos.x = myPos.x + (mySize.x - newSize.x) / 2;
1150                 newPos.y = myPos.y;
1151         }
1152         else
1153         {
1154                 newSize.y = 1/3 * mySize.x;
1155                 newSize.x = mySize.x;
1156
1157                 newPos.y = myPos.y + (mySize.y - newSize.y) / 2;
1158                 newPos.x = myPos.x;
1159         }
1160
1161         if(icon_right_align) // right align
1162         {
1163                 numpos = newPos;
1164                 picpos = newPos + eX * 2 * newSize.y;
1165         }
1166         else // left align
1167         {
1168                 numpos = newPos + eX * newSize.y;
1169                 picpos = newPos;
1170         }
1171
1172         // NOTE: newSize_x is always equal to 3 * mySize_y so we can use
1173         // '2 1 0' * newSize_y instead of eX * (2/3) * newSize_x + eY * newSize_y
1174         drawstring_aspect_expanding(numpos, ftos(x), '2 1 0' * newSize.y, color, panel_fg_alpha * theAlpha, DRAWFLAG_NORMAL, fadelerp);
1175         drawpic_aspect_skin_expanding(picpos, icon, '1 1 0' * newSize.y, '1 1 1', panel_fg_alpha * theAlpha, DRAWFLAG_NORMAL, fadelerp);
1176 }
1177
1178 void DrawNumIcon(vector myPos, vector mySize, float x, string icon, float vertical, float icon_right_align, vector color, float theAlpha)
1179 {
1180         DrawNumIcon_expanding(myPos, mySize, x, icon, vertical, icon_right_align, color, theAlpha, 0);
1181 }
1182
1183 // Powerups (#2)
1184 //
1185 void HUD_Powerups(void)
1186 {
1187         float strength_time, shield_time, superweapons_time;
1188         if(!autocvar__hud_configure)
1189         {
1190                 if(!autocvar_hud_panel_powerups) return;
1191                 if(spectatee_status == -1) return;
1192                 if(!(getstati(STAT_ITEMS, 0, 24) & (IT_STRENGTH | IT_INVINCIBLE | IT_SUPERWEAPON))) return;
1193                 if (getstati(STAT_HEALTH) <= 0) return;
1194
1195                 strength_time = bound(0, getstatf(STAT_STRENGTH_FINISHED) - time, 99);
1196                 shield_time = bound(0, getstatf(STAT_INVINCIBLE_FINISHED) - time, 99);
1197                 superweapons_time = bound(0, getstatf(STAT_SUPERWEAPONS_FINISHED) - time, 99);
1198
1199                 if (getstati(STAT_ITEMS, 0, 24) & IT_UNLIMITED_SUPERWEAPONS)
1200                         superweapons_time = 99; // force max
1201
1202                 // prevent stuff to show up on mismatch that will be fixed next frame
1203                 if (!(getstati(STAT_ITEMS, 0, 24) & IT_SUPERWEAPON))
1204                         superweapons_time = 0;
1205         }
1206         else
1207         {
1208                 strength_time = 15;
1209                 shield_time = 27;
1210                 superweapons_time = 13;
1211         }
1212
1213         HUD_Panel_UpdateCvars();
1214
1215         draw_beginBoldFont();
1216
1217         vector pos, mySize;
1218         pos = panel_pos;
1219         mySize = panel_size;
1220
1221         HUD_Panel_DrawBg(bound(0, max(strength_time, shield_time, superweapons_time), 1));
1222         if(panel_bg_padding)
1223         {
1224                 pos += '1 1 0' * panel_bg_padding;
1225                 mySize -= '2 2 0' * panel_bg_padding;
1226         }
1227
1228         float panel_ar = mySize.x/mySize.y;
1229         float is_vertical = (panel_ar < 1);
1230         vector shield_offset = '0 0 0', strength_offset = '0 0 0', superweapons_offset = '0 0 0';
1231
1232         float superweapons_is = -1;
1233
1234         if(superweapons_time)
1235         {
1236                 if(strength_time)
1237                 {
1238                         if(shield_time)
1239                                 superweapons_is = 0;
1240                         else
1241                                 superweapons_is = 2;
1242                 }
1243                 else
1244                 {
1245                         if(shield_time)
1246                                 superweapons_is = 1;
1247                         else
1248                                 superweapons_is = 2;
1249                 }
1250         }
1251
1252         // FIXME handle superweapons here
1253         if(superweapons_is == 0)
1254         {
1255                 if (panel_ar >= 4 || (panel_ar >= 1/4 && panel_ar < 1))
1256                 {
1257                         mySize.x *= (1.0 / 3.0);
1258                         superweapons_offset.x = mySize.x;
1259                         if (autocvar_hud_panel_powerups_flip)
1260                                 shield_offset.x = 2*mySize.x;
1261                         else
1262                                 strength_offset.x = 2*mySize.x;
1263                 }
1264                 else
1265                 {
1266                         mySize.y *= (1.0 / 3.0);
1267                         superweapons_offset.y = mySize.y;
1268                         if (autocvar_hud_panel_powerups_flip)
1269                                 shield_offset.y = 2*mySize.y;
1270                         else
1271                                 strength_offset.y = 2*mySize.y;
1272                 }
1273         }
1274         else
1275         {
1276                 if (panel_ar >= 4 || (panel_ar >= 1/4 && panel_ar < 1))
1277                 {
1278                         mySize.x *= 0.5;
1279                         if (autocvar_hud_panel_powerups_flip)
1280                                 shield_offset.x = mySize.x;
1281                         else
1282                                 strength_offset.x = mySize.x;
1283                 }
1284                 else
1285                 {
1286                         mySize.y *= 0.5;
1287                         if (autocvar_hud_panel_powerups_flip)
1288                                 shield_offset.y = mySize.y;
1289                         else
1290                                 strength_offset.y = mySize.y;
1291                 }
1292         }
1293
1294         float shield_baralign, strength_baralign, superweapons_baralign;
1295         float shield_iconalign, strength_iconalign, superweapons_iconalign;
1296
1297         if (autocvar_hud_panel_powerups_flip)
1298         {
1299                 strength_baralign = (autocvar_hud_panel_powerups_baralign == 2 || autocvar_hud_panel_powerups_baralign == 1);
1300                 shield_baralign = (autocvar_hud_panel_powerups_baralign == 3 || autocvar_hud_panel_powerups_baralign == 1);
1301                 strength_iconalign = (autocvar_hud_panel_powerups_iconalign == 2 || autocvar_hud_panel_powerups_iconalign == 1);
1302                 shield_iconalign = (autocvar_hud_panel_powerups_iconalign == 3 || autocvar_hud_panel_powerups_iconalign == 1);
1303         }
1304         else
1305         {
1306                 shield_baralign = (autocvar_hud_panel_powerups_baralign == 2 || autocvar_hud_panel_powerups_baralign == 1);
1307                 strength_baralign = (autocvar_hud_panel_powerups_baralign == 3 || autocvar_hud_panel_powerups_baralign == 1);
1308                 shield_iconalign = (autocvar_hud_panel_powerups_iconalign == 2 || autocvar_hud_panel_powerups_iconalign == 1);
1309                 strength_iconalign = (autocvar_hud_panel_powerups_iconalign == 3 || autocvar_hud_panel_powerups_iconalign == 1);
1310         }
1311
1312         if(superweapons_is == 0)
1313         {
1314                 superweapons_iconalign = strength_iconalign;
1315                 superweapons_baralign = 2;
1316         }
1317         else if(superweapons_is == 1)
1318         {
1319                 superweapons_offset = strength_offset;
1320                 superweapons_iconalign = strength_iconalign;
1321                 superweapons_baralign = strength_baralign;
1322         }
1323         else // if(superweapons_is == 2)
1324         {
1325                 superweapons_offset = shield_offset;
1326                 superweapons_iconalign = shield_iconalign;
1327                 superweapons_baralign = shield_baralign;
1328         }
1329
1330         if(shield_time)
1331         {
1332                 const float maxshield = 30;
1333                 float shield = ceil(shield_time);
1334                 if(autocvar_hud_panel_powerups_progressbar)
1335                         HUD_Panel_DrawProgressBar(pos + shield_offset, mySize, autocvar_hud_panel_powerups_progressbar_shield, shield/maxshield, is_vertical, shield_baralign, autocvar_hud_progressbar_shield_color, autocvar_hud_progressbar_alpha * panel_fg_alpha, DRAWFLAG_NORMAL);
1336                 if(autocvar_hud_panel_powerups_text)
1337                 {
1338                         if(shield > 1)
1339                                 DrawNumIcon(pos + shield_offset, mySize, shield, "shield", is_vertical, shield_iconalign, '1 1 1', 1);
1340                         if(shield <= 5)
1341                                 DrawNumIcon_expanding(pos + shield_offset, mySize, shield, "shield", is_vertical, shield_iconalign, '1 1 1', 1, bound(0, (shield - shield_time) / 0.5, 1));
1342                 }
1343         }
1344
1345         if(strength_time)
1346         {
1347                 const float maxstrength = 30;
1348                 float strength = ceil(strength_time);
1349                 if(autocvar_hud_panel_powerups_progressbar)
1350                         HUD_Panel_DrawProgressBar(pos + strength_offset, mySize, autocvar_hud_panel_powerups_progressbar_strength, strength/maxstrength, is_vertical, strength_baralign, autocvar_hud_progressbar_strength_color, autocvar_hud_progressbar_alpha * panel_fg_alpha, DRAWFLAG_NORMAL);
1351                 if(autocvar_hud_panel_powerups_text)
1352                 {
1353                         if(strength > 1)
1354                                 DrawNumIcon(pos + strength_offset, mySize, strength, "strength", is_vertical, strength_iconalign, '1 1 1', 1);
1355                         if(strength <= 5)
1356                                 DrawNumIcon_expanding(pos + strength_offset, mySize, strength, "strength", is_vertical, strength_iconalign, '1 1 1', 1, bound(0, (strength - strength_time) / 0.5, 1));
1357                 }
1358         }
1359
1360         if(superweapons_time)
1361         {
1362                 const float maxsuperweapons = 30;
1363                 float superweapons = ceil(superweapons_time);
1364                 if(autocvar_hud_panel_powerups_progressbar)
1365                         HUD_Panel_DrawProgressBar(pos + superweapons_offset, mySize, autocvar_hud_panel_powerups_progressbar_superweapons, superweapons/maxsuperweapons, is_vertical, superweapons_baralign, autocvar_hud_progressbar_superweapons_color, autocvar_hud_progressbar_alpha * panel_fg_alpha, DRAWFLAG_NORMAL);
1366                 if(autocvar_hud_panel_powerups_text)
1367                 {
1368                         if(superweapons > 1)
1369                                 DrawNumIcon(pos + superweapons_offset, mySize, superweapons, "superweapons", is_vertical, superweapons_iconalign, '1 1 1', 1);
1370                         if(superweapons <= 5)
1371                                 DrawNumIcon_expanding(pos + superweapons_offset, mySize, superweapons, "superweapons", is_vertical, superweapons_iconalign, '1 1 1', 1, bound(0, (superweapons - superweapons_time) / 0.5, 1));
1372                 }
1373         }
1374
1375         draw_endBoldFont();
1376 }
1377
1378 // Health/armor (#3)
1379 //
1380
1381 // prev_* vars contain the health/armor at the previous FRAME
1382 // set to -1 when player is dead or was not playing
1383 float prev_health, prev_armor;
1384 float health_damagetime, armor_damagetime;
1385 float health_beforedamage, armor_beforedamage;
1386 // old_p_* vars keep track of previous values when smoothing value changes of the progressbar
1387 float old_p_health, old_p_armor;
1388 float old_p_healthtime, old_p_armortime;
1389 // prev_p_* vars contain the health/armor progressbar value at the previous FRAME
1390 // set to -1 to forcedly stop effects when we switch spectated player (e.g. from playerX: 70h to playerY: 50h)
1391 float prev_p_health, prev_p_armor;
1392
1393 void HUD_HealthArmor(void)
1394 {
1395         float armor, health, fuel;
1396         if(!autocvar__hud_configure)
1397         {
1398                 if(!autocvar_hud_panel_healtharmor) return;
1399                 if(hud != HUD_NORMAL) return;
1400                 if(spectatee_status == -1) return;
1401
1402                 health = getstati(STAT_HEALTH);
1403                 if(health <= 0)
1404                 {
1405                         prev_health = -1;
1406                         return;
1407                 }
1408                 armor = getstati(STAT_ARMOR);
1409
1410                 // code to check for spectatee_status changes is in Ent_ClientData()
1411                 // prev_p_health and prev_health can be set to -1 there
1412
1413                 if (prev_p_health == -1)
1414                 {
1415                         // no effect
1416                         health_beforedamage = 0;
1417                         armor_beforedamage = 0;
1418                         health_damagetime = 0;
1419                         armor_damagetime = 0;
1420                         prev_health = health;
1421                         prev_armor = armor;
1422                         old_p_health = health;
1423                         old_p_armor = armor;
1424                         prev_p_health = health;
1425                         prev_p_armor = armor;
1426                 }
1427                 else if (prev_health == -1)
1428                 {
1429                         //start the load effect
1430                         health_damagetime = 0;
1431                         armor_damagetime = 0;
1432                         prev_health = 0;
1433                         prev_armor = 0;
1434                 }
1435                 fuel = getstati(STAT_FUEL);
1436         }
1437         else
1438         {
1439                 health = 150;
1440                 armor = 75;
1441                 fuel = 20;
1442         }
1443
1444         HUD_Panel_UpdateCvars();
1445         vector pos, mySize;
1446         pos = panel_pos;
1447         mySize = panel_size;
1448
1449         HUD_Panel_DrawBg(1);
1450         if(panel_bg_padding)
1451         {
1452                 pos += '1 1 0' * panel_bg_padding;
1453                 mySize -= '2 2 0' * panel_bg_padding;
1454         }
1455
1456         float baralign = autocvar_hud_panel_healtharmor_baralign;
1457         float iconalign = autocvar_hud_panel_healtharmor_iconalign;
1458
1459     float maxhealth = autocvar_hud_panel_healtharmor_maxhealth;
1460     float maxarmor = autocvar_hud_panel_healtharmor_maxarmor;
1461         if(autocvar_hud_panel_healtharmor == 2) // combined health and armor display
1462         {
1463                 vector v;
1464                 v = healtharmor_maxdamage(health, armor, armorblockpercent, DEATH_WEAPON);
1465
1466                 float x;
1467                 x = floor(v.x + 1);
1468
1469         float maxtotal = maxhealth + maxarmor;
1470                 string biggercount;
1471                 if(v.z) // NOT fully armored
1472                 {
1473                         biggercount = "health";
1474                         if(autocvar_hud_panel_healtharmor_progressbar)
1475                                 HUD_Panel_DrawProgressBar(pos, mySize, autocvar_hud_panel_healtharmor_progressbar_health, x/maxtotal, 0, (baralign == 1 || baralign == 2), autocvar_hud_progressbar_health_color, autocvar_hud_progressbar_alpha * panel_fg_alpha, DRAWFLAG_NORMAL);
1476                         if(armor)
1477             if(autocvar_hud_panel_healtharmor_text)
1478                                 drawpic_aspect_skin(pos + eX * mySize.x - eX * 0.5 * mySize.y, "armor", '0.5 0.5 0' * mySize.y, '1 1 1', panel_fg_alpha * armor / health, DRAWFLAG_NORMAL);
1479                 }
1480                 else
1481                 {
1482                         biggercount = "armor";
1483                         if(autocvar_hud_panel_healtharmor_progressbar)
1484                                 HUD_Panel_DrawProgressBar(pos, mySize, autocvar_hud_panel_healtharmor_progressbar_armor, x/maxtotal, 0, (baralign == 1 || baralign == 2), autocvar_hud_progressbar_armor_color, autocvar_hud_progressbar_alpha * panel_fg_alpha, DRAWFLAG_NORMAL);
1485                         if(health)
1486             if(autocvar_hud_panel_healtharmor_text)
1487                                 drawpic_aspect_skin(pos + eX * mySize.x - eX * 0.5 * mySize.y, "health", '0.5 0.5 0' * mySize.y, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
1488                 }
1489         if(autocvar_hud_panel_healtharmor_text)
1490                         DrawNumIcon(pos, mySize, x, biggercount, 0, iconalign, HUD_Get_Num_Color(x, maxtotal), 1);
1491
1492                 if(fuel)
1493                         HUD_Panel_DrawProgressBar(pos, eX * mySize.x + eY * 0.2 * mySize.y, "progressbar", fuel/100, 0, (baralign == 1 || baralign == 3), autocvar_hud_progressbar_fuel_color, panel_fg_alpha * 0.8, DRAWFLAG_NORMAL);
1494         }
1495         else
1496         {
1497                 float panel_ar = mySize.x/mySize.y;
1498                 float is_vertical = (panel_ar < 1);
1499                 vector health_offset = '0 0 0', armor_offset = '0 0 0';
1500                 if (panel_ar >= 4 || (panel_ar >= 1/4 && panel_ar < 1))
1501                 {
1502                         mySize.x *= 0.5;
1503                         if (autocvar_hud_panel_healtharmor_flip)
1504                                 health_offset.x = mySize.x;
1505                         else
1506                                 armor_offset.x = mySize.x;
1507                 }
1508                 else
1509                 {
1510                         mySize.y *= 0.5;
1511                         if (autocvar_hud_panel_healtharmor_flip)
1512                                 health_offset.y = mySize.y;
1513                         else
1514                                 armor_offset.y = mySize.y;
1515                 }
1516
1517                 float health_baralign, armor_baralign, fuel_baralign;
1518                 float health_iconalign, armor_iconalign;
1519                 if (autocvar_hud_panel_healtharmor_flip)
1520                 {
1521                         armor_baralign = (autocvar_hud_panel_healtharmor_baralign == 2 || autocvar_hud_panel_healtharmor_baralign == 1);
1522                         health_baralign = (autocvar_hud_panel_healtharmor_baralign == 3 || autocvar_hud_panel_healtharmor_baralign == 1);
1523                         fuel_baralign = health_baralign;
1524                         armor_iconalign = (autocvar_hud_panel_healtharmor_iconalign == 2 || autocvar_hud_panel_healtharmor_iconalign == 1);
1525                         health_iconalign = (autocvar_hud_panel_healtharmor_iconalign == 3 || autocvar_hud_panel_healtharmor_iconalign == 1);
1526                 }
1527                 else
1528                 {
1529                         health_baralign = (autocvar_hud_panel_healtharmor_baralign == 2 || autocvar_hud_panel_healtharmor_baralign == 1);
1530                         armor_baralign = (autocvar_hud_panel_healtharmor_baralign == 3 || autocvar_hud_panel_healtharmor_baralign == 1);
1531                         fuel_baralign = armor_baralign;
1532                         health_iconalign = (autocvar_hud_panel_healtharmor_iconalign == 2 || autocvar_hud_panel_healtharmor_iconalign == 1);
1533                         armor_iconalign = (autocvar_hud_panel_healtharmor_iconalign == 3 || autocvar_hud_panel_healtharmor_iconalign == 1);
1534                 }
1535
1536                 //if(health)
1537                 {
1538                         if(autocvar_hud_panel_healtharmor_progressbar)
1539                         {
1540                                 float p_health, pain_health_alpha;
1541                                 p_health = health;
1542                                 pain_health_alpha = 1;
1543                                 if (autocvar_hud_panel_healtharmor_progressbar_gfx)
1544                                 {
1545                                         if (autocvar_hud_panel_healtharmor_progressbar_gfx_smooth > 0)
1546                                         {
1547                                                 if (fabs(prev_health - health) >= autocvar_hud_panel_healtharmor_progressbar_gfx_smooth)
1548                                                 {
1549                                                         if (time - old_p_healthtime < 1)
1550                                                                 old_p_health = prev_p_health;
1551                                                         else
1552                                                                 old_p_health = prev_health;
1553                                                         old_p_healthtime = time;
1554                                                 }
1555                                                 if (time - old_p_healthtime < 1)
1556                                                 {
1557                                                         p_health += (old_p_health - health) * (1 - (time - old_p_healthtime));
1558                                                         prev_p_health = p_health;
1559                                                 }
1560                                         }
1561                                         if (autocvar_hud_panel_healtharmor_progressbar_gfx_damage > 0)
1562                                         {
1563                                                 if (prev_health - health >= autocvar_hud_panel_healtharmor_progressbar_gfx_damage)
1564                                                 {
1565                                                         if (time - health_damagetime >= 1)
1566                                                                 health_beforedamage = prev_health;
1567                                                         health_damagetime = time;
1568                                                 }
1569                                                 if (time - health_damagetime < 1)
1570                                                 {
1571                                                         float health_damagealpha = 1 - (time - health_damagetime)*(time - health_damagetime);
1572                                                         HUD_Panel_DrawProgressBar(pos + health_offset, mySize, autocvar_hud_panel_healtharmor_progressbar_health, health_beforedamage/maxhealth, is_vertical, health_baralign, autocvar_hud_progressbar_health_color, autocvar_hud_progressbar_alpha * panel_fg_alpha * health_damagealpha, DRAWFLAG_NORMAL);
1573                                                 }
1574                                         }
1575                                         prev_health = health;
1576
1577                                         if (health <= autocvar_hud_panel_healtharmor_progressbar_gfx_lowhealth)
1578                                         {
1579                                                 float BLINK_FACTOR = 0.15;
1580                                                 float BLINK_BASE = 0.85;
1581                                                 float BLINK_FREQ = 9;
1582                                                 pain_health_alpha = BLINK_BASE + BLINK_FACTOR * cos(time * BLINK_FREQ);
1583                                         }
1584                                 }
1585                                 HUD_Panel_DrawProgressBar(pos + health_offset, mySize, autocvar_hud_panel_healtharmor_progressbar_health, p_health/maxhealth, is_vertical, health_baralign, autocvar_hud_progressbar_health_color, autocvar_hud_progressbar_alpha * panel_fg_alpha * pain_health_alpha, DRAWFLAG_NORMAL);
1586                         }
1587                         if(autocvar_hud_panel_healtharmor_text)
1588                                 DrawNumIcon(pos + health_offset, mySize, health, "health", is_vertical, health_iconalign, HUD_Get_Num_Color(health, maxhealth), 1);
1589                 }
1590
1591                 if(armor)
1592                 {
1593                         if(autocvar_hud_panel_healtharmor_progressbar)
1594                         {
1595                                 float p_armor;
1596                                 p_armor = armor;
1597                                 if (autocvar_hud_panel_healtharmor_progressbar_gfx)
1598                                 {
1599                                         if (autocvar_hud_panel_healtharmor_progressbar_gfx_smooth > 0)
1600                                         {
1601                                                 if (fabs(prev_armor - armor) >= autocvar_hud_panel_healtharmor_progressbar_gfx_smooth)
1602                                                 {
1603                                                         if (time - old_p_armortime < 1)
1604                                                                 old_p_armor = prev_p_armor;
1605                                                         else
1606                                                                 old_p_armor = prev_armor;
1607                                                         old_p_armortime = time;
1608                                                 }
1609                                                 if (time - old_p_armortime < 1)
1610                                                 {
1611                                                         p_armor += (old_p_armor - armor) * (1 - (time - old_p_armortime));
1612                                                         prev_p_armor = p_armor;
1613                                                 }
1614                                         }
1615                                         if (autocvar_hud_panel_healtharmor_progressbar_gfx_damage > 0)
1616                                         {
1617                                                 if (prev_armor - armor >= autocvar_hud_panel_healtharmor_progressbar_gfx_damage)
1618                                                 {
1619                                                         if (time - armor_damagetime >= 1)
1620                                                                 armor_beforedamage = prev_armor;
1621                                                         armor_damagetime = time;
1622                                                 }
1623                                                 if (time - armor_damagetime < 1)
1624                                                 {
1625                                                         float armor_damagealpha = 1 - (time - armor_damagetime)*(time - armor_damagetime);
1626                                                         HUD_Panel_DrawProgressBar(pos + armor_offset, mySize, autocvar_hud_panel_healtharmor_progressbar_armor, armor_beforedamage/maxarmor, is_vertical, armor_baralign, autocvar_hud_progressbar_armor_color, autocvar_hud_progressbar_alpha * panel_fg_alpha * armor_damagealpha, DRAWFLAG_NORMAL);
1627                                                 }
1628                                         }
1629                                         prev_armor = armor;
1630                                 }
1631                                 HUD_Panel_DrawProgressBar(pos + armor_offset, mySize, autocvar_hud_panel_healtharmor_progressbar_armor, p_armor/maxarmor, is_vertical, armor_baralign, autocvar_hud_progressbar_armor_color, autocvar_hud_progressbar_alpha * panel_fg_alpha, DRAWFLAG_NORMAL);
1632                         }
1633                         if(autocvar_hud_panel_healtharmor_text)
1634                                 DrawNumIcon(pos + armor_offset, mySize, armor, "armor", is_vertical, armor_iconalign, HUD_Get_Num_Color(armor, maxarmor), 1);
1635                 }
1636
1637                 if(fuel)
1638                 {
1639                         if (is_vertical)
1640                                 mySize.x *= 0.2 / 2; //if vertical always halve x to not cover too much numbers with 3 digits
1641                         else
1642                                 mySize.y *= 0.2;
1643                         if (panel_ar >= 4)
1644                                 mySize.x *= 2; //restore full panel size
1645                         else if (panel_ar < 1/4)
1646                                 mySize.y *= 2; //restore full panel size
1647                         HUD_Panel_DrawProgressBar(pos, mySize, "progressbar", fuel/100, is_vertical, fuel_baralign, autocvar_hud_progressbar_fuel_color, panel_fg_alpha * 0.8, DRAWFLAG_NORMAL);
1648                 }
1649         }
1650 }
1651
1652 // Notification area (#4)
1653 //
1654
1655 void HUD_Notify_Push(string icon, string attacker, string victim)
1656 {
1657         if (icon == "")
1658                 return;
1659
1660         ++notify_count;
1661         --notify_index;
1662
1663         if (notify_index == -1)
1664                 notify_index = NOTIFY_MAX_ENTRIES-1;
1665
1666         // Free old strings
1667         if (notify_attackers[notify_index])
1668                 strunzone(notify_attackers[notify_index]);
1669
1670         if (notify_victims[notify_index])
1671                 strunzone(notify_victims[notify_index]);
1672
1673         if (notify_icons[notify_index])
1674                 strunzone(notify_icons[notify_index]);
1675
1676         // Allocate new strings
1677         if (victim != "")
1678         {
1679                 notify_attackers[notify_index] = strzone(attacker);
1680                 notify_victims[notify_index] = strzone(victim);
1681         }
1682         else
1683         {
1684                 // In case of a notification without a victim, the attacker
1685                 // is displayed on the victim's side. Instead of special
1686                 // treatment later on, we can simply switch them here.
1687                 notify_attackers[notify_index] = string_null;
1688                 notify_victims[notify_index] = strzone(attacker);
1689         }
1690
1691         notify_icons[notify_index] = strzone(icon);
1692         notify_times[notify_index] = time;
1693 }
1694
1695 void HUD_Notify(void)
1696 {
1697         if (!autocvar__hud_configure)
1698                 if (!autocvar_hud_panel_notify)
1699                         return;
1700
1701         HUD_Panel_UpdateCvars();
1702         HUD_Panel_DrawBg(1);
1703
1704         if (!autocvar__hud_configure)
1705                 if (notify_count == 0)
1706                         return;
1707
1708         vector pos, size;
1709         pos  = panel_pos;
1710         size = panel_size;
1711
1712         if (panel_bg_padding)
1713         {
1714                 pos  += '1 1 0' * panel_bg_padding;
1715                 size -= '2 2 0' * panel_bg_padding;
1716         }
1717
1718         float fade_start = max(0, autocvar_hud_panel_notify_time);
1719         float fade_time = max(0, autocvar_hud_panel_notify_fadetime);
1720         float icon_aspect = max(1, autocvar_hud_panel_notify_icon_aspect);
1721
1722         float entry_count = bound(1, floor(NOTIFY_MAX_ENTRIES * size.y / size.x), NOTIFY_MAX_ENTRIES);
1723         float entry_height = size.y / entry_count;
1724
1725         float panel_width_half = size.x * 0.5;
1726         float icon_width_half = entry_height * icon_aspect / 2;
1727         float name_maxwidth = panel_width_half - icon_width_half - size.x * NOTIFY_ICON_MARGIN;
1728
1729         vector font_size = '0.5 0.5 0' * entry_height * autocvar_hud_panel_notify_fontsize;
1730         vector icon_size = (eX * icon_aspect + eY) * entry_height;
1731         vector icon_left = eX * (panel_width_half - icon_width_half);
1732         vector attacker_right = eX * name_maxwidth;
1733         vector victim_left = eX * (size.x - name_maxwidth);
1734
1735         vector attacker_pos, victim_pos, icon_pos;
1736         string attacker, victim, icon;
1737         float i, j, count, step, limit, alpha;
1738
1739         if (autocvar_hud_panel_notify_flip)
1740         {
1741                 // Order items from the top down
1742                 i = 0;
1743                 step = +1;
1744                 limit = entry_count;
1745         }
1746         else
1747         {
1748                 // Order items from the bottom up
1749                 i = entry_count - 1;
1750                 step = -1;
1751                 limit = -1;
1752         }
1753
1754         for (j = notify_index, count = 0; i != limit; i += step, ++j, ++count)
1755         {
1756                 if(autocvar__hud_configure)
1757                 {
1758                         attacker = sprintf(_("Player %d"), count + 1);
1759                         victim = sprintf(_("Player %d"), count + 2);
1760                         icon = get_weaponinfo(min(WEP_FIRST + count * 2, WEP_LAST)).model2;
1761                         alpha = bound(0, 1.2 - count / entry_count, 1);
1762                 }
1763                 else
1764                 {
1765                         if (j == NOTIFY_MAX_ENTRIES)
1766                                 j = 0;
1767
1768                         if (notify_times[j] + fade_start > time)
1769                                 alpha = 1;
1770                         else if (fade_time != 0)
1771                         {
1772                                 alpha = bound(0, (notify_times[j] + fade_start + fade_time - time) / fade_time, 1);
1773                                 if (alpha == 0)
1774                                         break;
1775                         }
1776                         else
1777                                 break;
1778
1779                         attacker = notify_attackers[j];
1780                         victim = notify_victims[j];
1781                         icon = notify_icons[j];
1782                 }
1783
1784                 if (icon != "" && victim != "")
1785                 {
1786                         vector name_top = eY * (i * entry_height + 0.5 * (entry_height - font_size.y));
1787
1788                         icon_pos = pos + icon_left + eY * i * entry_height;
1789                         drawpic_aspect_skin(icon_pos, icon, icon_size, '1 1 1', panel_fg_alpha * alpha, DRAWFLAG_NORMAL);
1790
1791                         victim = textShortenToWidth(victim, name_maxwidth, font_size, stringwidth_colors);
1792                         victim_pos = pos + victim_left + name_top;
1793                         drawcolorcodedstring(victim_pos, victim, font_size, panel_fg_alpha * alpha, DRAWFLAG_NORMAL);
1794
1795                         if (attacker != "")
1796                         {
1797                                 attacker = textShortenToWidth(attacker, name_maxwidth, font_size, stringwidth_colors);
1798                                 attacker_pos = pos + attacker_right - eX * stringwidth(attacker, true, font_size) + name_top;
1799                                 drawcolorcodedstring(attacker_pos, attacker, font_size, panel_fg_alpha * alpha, DRAWFLAG_NORMAL);
1800                         }
1801                 }
1802         }
1803
1804         notify_count = count;
1805 }
1806
1807 // Timer (#5)
1808 //
1809 // TODO: macro
1810 string seconds_tostring(float sec)
1811 {
1812         float minutes;
1813         minutes = floor(sec / 60);
1814
1815         sec -= minutes * 60;
1816         return sprintf("%d:%02d", minutes, sec);
1817 }
1818
1819 void HUD_Timer(void)
1820 {
1821         if(!autocvar__hud_configure)
1822         {
1823                 if(!autocvar_hud_panel_timer) return;
1824         }
1825
1826         HUD_Panel_UpdateCvars();
1827
1828         draw_beginBoldFont();
1829
1830         vector pos, mySize;
1831         pos = panel_pos;
1832         mySize = panel_size;
1833
1834         HUD_Panel_DrawBg(1);
1835         if(panel_bg_padding)
1836         {
1837                 pos += '1 1 0' * panel_bg_padding;
1838                 mySize -= '2 2 0' * panel_bg_padding;
1839         }
1840
1841         string timer;
1842         float timelimit, elapsedTime, timeleft, minutesLeft;
1843
1844         timelimit = getstatf(STAT_TIMELIMIT);
1845
1846         timeleft = max(0, timelimit * 60 + getstatf(STAT_GAMESTARTTIME) - time);
1847         timeleft = ceil(timeleft);
1848
1849         minutesLeft = floor(timeleft / 60);
1850
1851         vector timer_color;
1852         if(minutesLeft >= 5 || warmup_stage || timelimit == 0) //don't use red or yellow in warmup or when there is no timelimit
1853                 timer_color = '1 1 1'; //white
1854         else if(minutesLeft >= 1)
1855                 timer_color = '1 1 0'; //yellow
1856         else
1857                 timer_color = '1 0 0'; //red
1858
1859         if (autocvar_hud_panel_timer_increment || timelimit == 0 || warmup_stage) {
1860                 if (time < getstatf(STAT_GAMESTARTTIME)) {
1861                         //while restart is still active, show 00:00
1862                         timer = seconds_tostring(0);
1863                 } else {
1864                         elapsedTime = floor(time - getstatf(STAT_GAMESTARTTIME)); //127
1865                         timer = seconds_tostring(elapsedTime);
1866                 }
1867         } else {
1868                 timer = seconds_tostring(timeleft);
1869         }
1870
1871         drawstring_aspect(pos, timer, mySize, timer_color, panel_fg_alpha, DRAWFLAG_NORMAL);
1872
1873         draw_endBoldFont();
1874 }
1875
1876 // Radar (#6)
1877 //
1878 void HUD_Radar(void)
1879 {
1880         if (!autocvar__hud_configure)
1881         {
1882                 if (hud_panel_radar_maximized)
1883                 {
1884                         if (!hud_draw_maximized) return;
1885                 }
1886                 else
1887                 {
1888                         if (autocvar_hud_panel_radar == 0) return;
1889                         if (autocvar_hud_panel_radar != 2 && !teamplay) return;
1890                         if(radar_panel_modified)
1891                         {
1892                                 panel.update_time = time; // forces reload of panel attributes
1893                                 radar_panel_modified = false;
1894                         }
1895                 }
1896         }
1897
1898         HUD_Panel_UpdateCvars();
1899
1900         float f = 0;
1901
1902         if (hud_panel_radar_maximized && !autocvar__hud_configure)
1903         {
1904                 panel_size = autocvar_hud_panel_radar_maximized_size;
1905                 panel_size.x = bound(0.2, panel_size.x, 1) * vid_conwidth;
1906                 panel_size.y = bound(0.2, panel_size.y, 1) * vid_conheight;
1907                 panel_pos.x = (vid_conwidth - panel_size.x) / 2;
1908                 panel_pos.y = (vid_conheight - panel_size.y) / 2;
1909
1910                 string panel_bg;
1911                 panel_bg = strcat(hud_skin_path, "/border_default"); // always use the default border when maximized
1912                 if(precache_pic(panel_bg) == "")
1913                         panel_bg = "gfx/hud/default/border_default"; // fallback
1914                 if(!radar_panel_modified && panel_bg != panel.current_panel_bg)
1915                         radar_panel_modified = true;
1916                 if(panel.current_panel_bg)
1917                         strunzone(panel.current_panel_bg);
1918                 panel.current_panel_bg = strzone(panel_bg);
1919
1920                 switch(hud_panel_radar_maximized_zoommode)
1921                 {
1922                         default:
1923                         case 0:
1924                                 f = current_zoomfraction;
1925                                 break;
1926                         case 1:
1927                                 f = 1 - current_zoomfraction;
1928                                 break;
1929                         case 2:
1930                                 f = 0;
1931                                 break;
1932                         case 3:
1933                                 f = 1;
1934                                 break;
1935                 }
1936
1937                 switch(hud_panel_radar_maximized_rotation)
1938                 {
1939                         case 0:
1940                                 teamradar_angle = view_angles.y - 90;
1941                                 break;
1942                         default:
1943                                 teamradar_angle = 90 * hud_panel_radar_maximized_rotation;
1944                                 break;
1945                 }
1946         }
1947         if (!hud_panel_radar_maximized && !autocvar__hud_configure)
1948         {
1949                 switch(hud_panel_radar_zoommode)
1950                 {
1951                         default:
1952                         case 0:
1953                                 f = current_zoomfraction;
1954                                 break;
1955                         case 1:
1956                                 f = 1 - current_zoomfraction;
1957                                 break;
1958                         case 2:
1959                                 f = 0;
1960                                 break;
1961                         case 3:
1962                                 f = 1;
1963                                 break;
1964                 }
1965
1966                 switch(hud_panel_radar_rotation)
1967                 {
1968                         case 0:
1969                                 teamradar_angle = view_angles.y - 90;
1970                                 break;
1971                         default:
1972                                 teamradar_angle = 90 * hud_panel_radar_rotation;
1973                                 break;
1974                 }
1975         }
1976
1977         vector pos, mySize;
1978         pos = panel_pos;
1979         mySize = panel_size;
1980
1981         HUD_Panel_DrawBg(1);
1982         if(panel_bg_padding)
1983         {
1984                 pos += '1 1 0' * panel_bg_padding;
1985                 mySize -= '2 2 0' * panel_bg_padding;
1986         }
1987
1988         float color2;
1989         entity tm;
1990         float scale2d, normalsize, bigsize;
1991
1992         teamradar_origin2d = pos + 0.5 * mySize;
1993         teamradar_size2d = mySize;
1994
1995         if(minimapname == "")
1996                 return;
1997
1998         teamradar_loadcvars();
1999
2000         scale2d = vlen_maxnorm2d(mi_picmax - mi_picmin);
2001         teamradar_size2d = mySize;
2002
2003         teamradar_extraclip_mins = teamradar_extraclip_maxs = '0 0 0'; // we always center
2004
2005         // pixels per world qu to match the teamradar_size2d_x range in the longest dimension
2006         if((hud_panel_radar_rotation == 0 && !hud_panel_radar_maximized) || (hud_panel_radar_maximized_rotation == 0 && hud_panel_radar_maximized))
2007         {
2008                 // max-min distance must fit the radar in any rotation
2009                 bigsize = vlen_minnorm2d(teamradar_size2d) * scale2d / (1.05 * vlen2d(mi_scale));
2010         }
2011         else
2012         {
2013                 vector c0, c1, c2, c3, span;
2014                 c0 = rotate(mi_min, teamradar_angle * DEG2RAD);
2015                 c1 = rotate(mi_max, teamradar_angle * DEG2RAD);
2016                 c2 = rotate('1 0 0' * mi_min.x + '0 1 0' * mi_max.y, teamradar_angle * DEG2RAD);
2017                 c3 = rotate('1 0 0' * mi_max.x + '0 1 0' * mi_min.y, teamradar_angle * DEG2RAD);
2018                 span = '0 0 0';
2019                 span.x = max(c0_x, c1_x, c2_x, c3_x) - min(c0_x, c1_x, c2_x, c3_x);
2020                 span.y = max(c0_y, c1_y, c2_y, c3_y) - min(c0_y, c1_y, c2_y, c3_y);
2021
2022                 // max-min distance must fit the radar in x=x, y=y
2023                 bigsize = min(
2024                         teamradar_size2d.x * scale2d / (1.05 * span.x),
2025                         teamradar_size2d.y * scale2d / (1.05 * span.y)
2026                 );
2027         }
2028
2029         normalsize = vlen_maxnorm2d(teamradar_size2d) * scale2d / hud_panel_radar_scale;
2030         if(bigsize > normalsize)
2031                 normalsize = bigsize;
2032
2033         teamradar_size =
2034                   f * bigsize
2035                 + (1 - f) * normalsize;
2036         teamradar_origin3d_in_texcoord = teamradar_3dcoord_to_texcoord(
2037                   f * mi_center
2038                 + (1 - f) * view_origin);
2039
2040         drawsetcliparea(
2041                 pos.x,
2042                 pos.y,
2043                 mySize.x,
2044                 mySize.y
2045         );
2046
2047         draw_teamradar_background(hud_panel_radar_foreground_alpha);
2048
2049         for(tm = world; (tm = find(tm, classname, "radarlink")); )
2050                 draw_teamradar_link(tm.origin, tm.velocity, tm.team);
2051         for(tm = world; (tm = findflags(tm, teamradar_icon, 0xFFFFFF)); )
2052                 draw_teamradar_icon(tm.origin, tm.teamradar_icon, tm, tm.teamradar_color, panel_fg_alpha);
2053         for(tm = world; (tm = find(tm, classname, "entcs_receiver")); )
2054         {
2055                 color2 = GetPlayerColor(tm.sv_entnum);
2056                 //if(color == NUM_SPECTATOR || color == color2)
2057                         draw_teamradar_player(tm.origin, tm.angles, Team_ColorRGB(color2));
2058         }
2059         draw_teamradar_player(view_origin, view_angles, '1 1 1');
2060
2061         drawresetcliparea();
2062 }
2063
2064 // Score (#7)
2065 //
2066 void HUD_UpdatePlayerTeams();
2067 void HUD_Score_Rankings(vector pos, vector mySize, entity me)
2068 {
2069         float score;
2070         entity tm = world, pl;
2071         float SCOREPANEL_MAX_ENTRIES = 6;
2072         float SCOREPANEL_ASPECTRATIO = 2;
2073         float entries = bound(1, floor(SCOREPANEL_MAX_ENTRIES * mySize.y/mySize.x * SCOREPANEL_ASPECTRATIO), SCOREPANEL_MAX_ENTRIES);
2074         vector fontsize = '1 1 0' * (mySize.y/entries);
2075
2076         vector rgb, score_color;
2077         rgb = '1 1 1';
2078         score_color = '1 1 1';
2079
2080         float name_size = mySize.x*0.75;
2081         float spacing_size = mySize.x*0.04;
2082         const float highlight_alpha = 0.2;
2083         float i = 0, me_printed = 0, first_pl = 0;
2084         string s;
2085         if (autocvar__hud_configure)
2086         {
2087                 float players_per_team = 0;
2088                 if (team_count)
2089                 {
2090                         // show team scores in the first line
2091                         float score_size = mySize.x / team_count;
2092                         players_per_team = max(2, ceil((entries - 1) / team_count));
2093                         for(i=0; i<team_count; ++i) {
2094                                 if (i == floor((entries - 2) / players_per_team) || (entries == 1 && i == 0))
2095                                         HUD_Panel_DrawHighlight(pos + eX * score_size * i, eX * score_size + eY * fontsize.y, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
2096                                 drawstring_aspect(pos + eX * score_size * i, ftos(175 - 23*i), eX * score_size + eY * fontsize.y, Team_ColorRGB(ColorByTeam(i)) * 0.8, panel_fg_alpha, DRAWFLAG_NORMAL);
2097                         }
2098                         first_pl = 1;
2099                         pos.y += fontsize.y;
2100                 }
2101                 score = 10 + SCOREPANEL_MAX_ENTRIES * 3;
2102                 for (i=first_pl; i<entries; ++i)
2103                 {
2104                         //simulate my score is lower than all displayed players,
2105                         //so that I don't appear at all showing pure rankings.
2106                         //This is to better show the difference between the 2 ranking views
2107                         if (i == entries-1 && autocvar_hud_panel_score_rankings == 1)
2108                         {
2109                                 rgb = '1 1 0';
2110                                 drawfill(pos, eX * mySize.x + eY * fontsize.y, rgb, highlight_alpha * panel_fg_alpha, DRAWFLAG_NORMAL);
2111                                 s = GetPlayerName(player_localnum);
2112                                 score = 7;
2113                         }
2114                         else
2115                         {
2116                                 s = sprintf(_("Player %d"), i + 1 - first_pl);
2117                                 score -= 3;
2118                         }
2119
2120                         if (team_count)
2121                                 score_color = Team_ColorRGB(ColorByTeam(floor((i - first_pl) / players_per_team))) * 0.8;
2122                         s = textShortenToWidth(s, name_size, fontsize, stringwidth_colors);
2123                         drawcolorcodedstring(pos + eX * (name_size - stringwidth(s, true, fontsize)), s, fontsize, panel_fg_alpha, DRAWFLAG_NORMAL);
2124                         drawstring(pos + eX * (name_size + spacing_size), ftos(score), fontsize, score_color, panel_fg_alpha, DRAWFLAG_NORMAL);
2125                         pos.y += fontsize.y;
2126                 }
2127                 return;
2128         }
2129
2130         if (!scoreboard_fade_alpha) // the scoreboard too calls HUD_UpdatePlayerTeams
2131                 HUD_UpdatePlayerTeams();
2132         if (team_count)
2133         {
2134                 // show team scores in the first line
2135                 float score_size = mySize.x / team_count;
2136                 for(tm = teams.sort_next; tm; tm = tm.sort_next) {
2137                         if(tm.team == NUM_SPECTATOR)
2138                                 continue;
2139                         if (tm.team == myteam)
2140                                 drawfill(pos + eX * score_size * i, eX * score_size + eY * fontsize.y, '1 1 1', highlight_alpha * panel_fg_alpha, DRAWFLAG_NORMAL);
2141                         drawstring_aspect(pos + eX * score_size * i, ftos(tm.(teamscores[ts_primary])), eX * score_size + eY * fontsize.y, Team_ColorRGB(tm.team) * 0.8, panel_fg_alpha, DRAWFLAG_NORMAL);
2142                         ++i;
2143                 }
2144                 first_pl = 1;
2145                 pos.y += fontsize.y;
2146                 tm = teams.sort_next;
2147         }
2148         i = first_pl;
2149
2150         do
2151         for (pl = players.sort_next; pl && i<entries; pl = pl.sort_next)
2152         {
2153                 if ((team_count && pl.team != tm.team) || pl.team == NUM_SPECTATOR)
2154                         continue;
2155
2156                 if (i == entries-1 && !me_printed && pl != me)
2157                 if (autocvar_hud_panel_score_rankings == 1 && spectatee_status != -1)
2158                 {
2159                         for (pl = me.sort_next; pl; pl = pl.sort_next)
2160                                 if (pl.team != NUM_SPECTATOR)
2161                                         break;
2162
2163                         if (pl)
2164                                 rgb = '1 1 0'; //not last but not among the leading players: yellow
2165                         else
2166                                 rgb = '1 0 0'; //last: red
2167                         pl = me;
2168                 }
2169
2170                 if (pl == me)
2171                 {
2172                         if (i == first_pl)
2173                                 rgb = '0 1 0'; //first: green
2174                         me_printed = 1;
2175                         drawfill(pos, eX * mySize.x + eY * fontsize.y, rgb, highlight_alpha * panel_fg_alpha, DRAWFLAG_NORMAL);
2176                 }
2177                 if (team_count)
2178                         score_color = Team_ColorRGB(pl.team) * 0.8;
2179                 s = textShortenToWidth(GetPlayerName(pl.sv_entnum), name_size, fontsize, stringwidth_colors);
2180                 drawcolorcodedstring(pos + eX * (name_size - stringwidth(s, true, fontsize)), s, fontsize, panel_fg_alpha, DRAWFLAG_NORMAL);
2181                 drawstring(pos + eX * (name_size + spacing_size), ftos(pl.(scores[ps_primary])), fontsize, score_color, panel_fg_alpha, DRAWFLAG_NORMAL);
2182                 pos.y += fontsize.y;
2183                 ++i;
2184         }
2185         while (i<entries && team_count && (tm = tm.sort_next) && (tm.team != NUM_SPECTATOR || (tm = tm.sort_next)));
2186 }
2187
2188 void HUD_Score(void)
2189 {
2190         if(!autocvar__hud_configure)
2191         {
2192                 if(!autocvar_hud_panel_score) return;
2193                 if(spectatee_status == -1 && (gametype == MAPINFO_TYPE_RACE || gametype == MAPINFO_TYPE_CTS)) return;
2194         }
2195
2196         HUD_Panel_UpdateCvars();
2197         vector pos, mySize;
2198         pos = panel_pos;
2199         mySize = panel_size;
2200
2201         HUD_Panel_DrawBg(1);
2202         if(panel_bg_padding)
2203         {
2204                 pos += '1 1 0' * panel_bg_padding;
2205                 mySize -= '2 2 0' * panel_bg_padding;
2206         }
2207
2208         float score, distribution = 0;
2209         string sign;
2210         vector distribution_color;
2211         entity tm, pl, me;
2212
2213         me = playerslots[player_localentnum - 1];
2214
2215         if((scores_flags[ps_primary] & SFL_TIME) && !teamplay) { // race/cts record display on HUD
2216                 string timer, distrtimer;
2217
2218                 pl = players.sort_next;
2219                 if(pl == me)
2220                         pl = pl.sort_next;
2221                 if(scores_flags[ps_primary] & SFL_ZERO_IS_WORST)
2222                         if(pl.scores[ps_primary] == 0)
2223                                 pl = world;
2224
2225                 score = me.(scores[ps_primary]);
2226                 timer = TIME_ENCODED_TOSTRING(score);
2227
2228                 draw_beginBoldFont();
2229                 if (pl && ((!(scores_flags[ps_primary] & SFL_ZERO_IS_WORST)) || score)) {
2230                         // distribution display
2231                         distribution = me.(scores[ps_primary]) - pl.(scores[ps_primary]);
2232
2233                         distrtimer = ftos_decimals(fabs(distribution/pow(10, TIME_DECIMALS)), TIME_DECIMALS);
2234
2235                         if (distribution <= 0) {
2236                                 distribution_color = '0 1 0';
2237                                 sign = "-";
2238                         }
2239                         else {
2240                                 distribution_color = '1 0 0';
2241                                 sign = "+";
2242                         }
2243                         drawstring_aspect(pos + eX * 0.75 * mySize.x, strcat(sign, distrtimer), eX * 0.25 * mySize.x + eY * (1/3) * mySize.y, distribution_color, panel_fg_alpha, DRAWFLAG_NORMAL);
2244                 }
2245                 // race record display
2246                 if (distribution <= 0)
2247                         HUD_Panel_DrawHighlight(pos, eX * 0.75 * mySize.x + eY * mySize.y, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
2248                 drawstring_aspect(pos, timer, eX * 0.75 * mySize.x + eY * mySize.y, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
2249                 draw_endBoldFont();
2250         } else if (!teamplay) { // non-teamgames
2251                 if ((spectatee_status == -1 && !autocvar__hud_configure) || autocvar_hud_panel_score_rankings)
2252                 {
2253                         HUD_Score_Rankings(pos, mySize, me);
2254                         return;
2255                 }
2256                 // me vector := [team/connected frags id]
2257                 pl = players.sort_next;
2258                 if(pl == me)
2259                         pl = pl.sort_next;
2260
2261                 if(autocvar__hud_configure)
2262                         distribution = 42;
2263                 else if(pl)
2264                         distribution = me.(scores[ps_primary]) - pl.(scores[ps_primary]);
2265                 else
2266                         distribution = 0;
2267
2268                 score = me.(scores[ps_primary]);
2269                 if(autocvar__hud_configure)
2270                         score = 123;
2271
2272                 if(distribution >= 5)
2273                         distribution_color = eY;
2274                 else if(distribution >= 0)
2275                         distribution_color = '1 1 1';
2276                 else if(distribution >= -5)
2277                         distribution_color = '1 1 0';
2278                 else
2279                         distribution_color = eX;
2280
2281                 string distribution_str;
2282                 distribution_str = ftos(distribution);
2283                 draw_beginBoldFont();
2284                 if (distribution >= 0)
2285                 {
2286                         if (distribution > 0)
2287                                 distribution_str = strcat("+", distribution_str);
2288                         HUD_Panel_DrawHighlight(pos, eX * 0.75 * mySize.x + eY * mySize.y, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
2289                 }
2290                 drawstring_aspect(pos, ftos(score), eX * 0.75 * mySize.x + eY * mySize.y, distribution_color, panel_fg_alpha, DRAWFLAG_NORMAL);
2291                 drawstring_aspect(pos + eX * 0.75 * mySize.x, distribution_str, eX * 0.25 * mySize.x + eY * (1/3) * mySize.y, distribution_color, panel_fg_alpha, DRAWFLAG_NORMAL);
2292                 draw_endBoldFont();
2293         } else { // teamgames
2294                 float row, column, rows = 0, columns = 0;
2295                 vector offset = '0 0 0';
2296                 vector score_pos, score_size; //for scores other than myteam
2297                 if(autocvar_hud_panel_score_rankings)
2298                 {
2299                         HUD_Score_Rankings(pos, mySize, me);
2300                         return;
2301                 }
2302                 if(spectatee_status == -1)
2303                 {
2304                         rows = HUD_GetRowCount(team_count, mySize, 3);
2305                         columns = ceil(team_count/rows);
2306                         score_size = eX * mySize.x*(1/columns) + eY * mySize.y*(1/rows);
2307
2308                         float newSize;
2309                         if(score_size.x/score_size.y > 3)
2310                         {
2311                                 newSize = 3 * score_size.y;
2312                                 offset.x = score_size.x - newSize;
2313                                 pos.x += offset.x/2;
2314                                 score_size.x = newSize;
2315                         }
2316                         else
2317                         {
2318                                 newSize = 1/3 * score_size.x;
2319                                 offset.y = score_size.y - newSize;
2320                                 pos.y += offset.y/2;
2321                                 score_size.y = newSize;
2322                         }
2323                 }
2324                 else
2325                         score_size = eX * mySize.x*(1/4) + eY * mySize.y*(1/3);
2326
2327                 float max_fragcount;
2328                 max_fragcount = -99;
2329                 draw_beginBoldFont();
2330                 row = column = 0;
2331                 for(tm = teams.sort_next; tm; tm = tm.sort_next) {
2332                         if(tm.team == NUM_SPECTATOR)
2333                                 continue;
2334                         score = tm.(teamscores[ts_primary]);
2335                         if(autocvar__hud_configure)
2336                                 score = 123;
2337
2338                         if (score > max_fragcount)
2339                                 max_fragcount = score;
2340
2341                         if (spectatee_status == -1)
2342                         {
2343                                 score_pos = pos + eX * column * (score_size.x + offset.x) + eY * row * (score_size.y + offset.y);
2344                                 if (max_fragcount == score)
2345                                         HUD_Panel_DrawHighlight(score_pos, score_size, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
2346                                 drawstring_aspect(score_pos, ftos(score), score_size, Team_ColorRGB(tm.team) * 0.8, panel_fg_alpha, DRAWFLAG_NORMAL);
2347                                 ++row;
2348                                 if(row >= rows)
2349                                 {
2350                                         row = 0;
2351                                         ++column;
2352                                 }
2353                         }
2354                         else if(tm.team == myteam) {
2355                                 if (max_fragcount == score)
2356                                         HUD_Panel_DrawHighlight(pos, eX * 0.75 * mySize.x + eY * mySize.y, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
2357                                 drawstring_aspect(pos, ftos(score), eX * 0.75 * mySize.x + eY * mySize.y, Team_ColorRGB(tm.team) * 0.8, panel_fg_alpha, DRAWFLAG_NORMAL);
2358                         } else {
2359                                 if (max_fragcount == score)
2360                                         HUD_Panel_DrawHighlight(pos + eX * 0.75 * mySize.x + eY * (1/3) * rows * mySize.y, score_size, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
2361                                 drawstring_aspect(pos + eX * 0.75 * mySize.x + eY * (1/3) * rows * mySize.y, ftos(score), score_size, Team_ColorRGB(tm.team) * 0.8, panel_fg_alpha, DRAWFLAG_NORMAL);
2362                                 ++rows;
2363                         }
2364                 }
2365                 draw_endBoldFont();
2366         }
2367 }
2368
2369 // Race timer (#8)
2370 //
2371 void HUD_RaceTimer (void)
2372 {
2373         if(!autocvar__hud_configure)
2374         {
2375                 if(!autocvar_hud_panel_racetimer) return;
2376                 if(!(gametype == MAPINFO_TYPE_RACE || gametype == MAPINFO_TYPE_CTS)) return;
2377                 if(spectatee_status == -1) return;
2378         }
2379
2380         HUD_Panel_UpdateCvars();
2381
2382         draw_beginBoldFont();
2383
2384         vector pos, mySize;
2385         pos = panel_pos;
2386         mySize = panel_size;
2387
2388         HUD_Panel_DrawBg(1);
2389         if(panel_bg_padding)
2390         {
2391                 pos += '1 1 0' * panel_bg_padding;
2392                 mySize -= '2 2 0' * panel_bg_padding;
2393         }
2394
2395         // always force 4:1 aspect
2396         vector newSize = '0 0 0';
2397         if(mySize.x/mySize.y > 4)
2398         {
2399                 newSize.x = 4 * mySize.y;
2400                 newSize.y = mySize.y;
2401
2402                 pos.x = pos.x + (mySize.x - newSize.x) / 2;
2403         }
2404         else
2405         {
2406                 newSize.y = 1/4 * mySize.x;
2407                 newSize.x = mySize.x;
2408
2409                 pos.y = pos.y + (mySize.y - newSize.y) / 2;
2410         }
2411         mySize = newSize;
2412
2413         float a, t;
2414         string s, forcetime;
2415
2416         if(autocvar__hud_configure)
2417         {
2418                 s = "0:13:37";
2419                 drawstring(pos + eX * 0.5 * mySize.x - '0.5 0 0' * stringwidth(s, false, '0.60 0.60 0' * mySize.y), s, '0.60 0.60 0' * mySize.y, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
2420                 s = _("^1Intermediate 1 (+15.42)");
2421                 drawcolorcodedstring(pos + eX * 0.5 * mySize.x - '0.5 0 0' * stringwidth(s, true, '1 1 0' * 0.20 * mySize.y) + eY * 0.60 * mySize.y, s, '1 1 0' * 0.20 * mySize.y, panel_fg_alpha, DRAWFLAG_NORMAL);
2422                 s = sprintf(_("^1PENALTY: %.1f (%s)"), 2, "missing a checkpoint");
2423                 drawcolorcodedstring(pos + eX * 0.5 * mySize.x - '0.5 0 0' * stringwidth(s, true, '1 1 0' * 0.20 * mySize.y) + eY * 0.80 * mySize.y, s, '1 1 0' * 0.20 * mySize.y, panel_fg_alpha, DRAWFLAG_NORMAL);
2424         }
2425         else if(race_checkpointtime)
2426         {
2427                 a = bound(0, 2 - (time - race_checkpointtime), 1);
2428                 s = "";
2429                 forcetime = "";
2430                 if(a > 0) // just hit a checkpoint?
2431                 {
2432                         if(race_checkpoint != 254)
2433                         {
2434                                 if(race_time && race_previousbesttime)
2435                                         s = MakeRaceString(race_checkpoint, TIME_DECODE(race_time) - TIME_DECODE(race_previousbesttime), 0, 0, race_previousbestname);
2436                                 else
2437                                         s = MakeRaceString(race_checkpoint, 0, -1, 0, race_previousbestname);
2438                                 if(race_time)
2439                                         forcetime = TIME_ENCODED_TOSTRING(race_time);
2440                         }
2441                 }
2442                 else
2443                 {
2444                         if(race_laptime && race_nextbesttime && race_nextcheckpoint != 254)
2445                         {
2446                                 a = bound(0, 2 - ((race_laptime + TIME_DECODE(race_nextbesttime)) - (time + TIME_DECODE(race_penaltyaccumulator))), 1);
2447                                 if(a > 0) // next one?
2448                                 {
2449                                         s = MakeRaceString(race_nextcheckpoint, (time + TIME_DECODE(race_penaltyaccumulator)) - race_laptime, TIME_DECODE(race_nextbesttime), 0, race_nextbestname);
2450                                 }
2451                         }
2452                 }
2453
2454                 if(s != "" && a > 0)
2455                 {
2456                         drawcolorcodedstring(pos + eX * 0.5 * mySize.x - '0.5 0 0' * stringwidth(s, true, '1 1 0' * 0.2 * mySize.y) + eY * 0.6 * mySize.y, s, '1 1 0' * 0.2 * mySize.y, panel_fg_alpha * a, DRAWFLAG_NORMAL);
2457                 }
2458
2459                 if(race_penaltytime)
2460                 {
2461                         a = bound(0, 2 - (time - race_penaltyeventtime), 1);
2462                         if(a > 0)
2463                         {
2464                                 s = sprintf(_("^1PENALTY: %.1f (%s)"), race_penaltytime * 0.1, race_penaltyreason);
2465                                 drawcolorcodedstring(pos + eX * 0.5 * mySize.x - '0.5 0 0' * stringwidth(s, true, '1 1 0' * 0.2 * mySize.y) + eY * 0.8 * mySize.y, s, '1 1 0' * 0.2 * mySize.y, panel_fg_alpha * a, DRAWFLAG_NORMAL);
2466                         }
2467                 }
2468
2469                 if(forcetime != "")
2470                 {
2471                         a = bound(0, (time - race_checkpointtime) / 0.5, 1);
2472                         drawstring_expanding(pos + eX * 0.5 * mySize.x - '0.5 0 0' * stringwidth(forcetime, false, '1 1 0' * 0.6 * mySize.y), forcetime, '1 1 0' * 0.6 * mySize.y, '1 1 1', panel_fg_alpha, 0, a);
2473                 }
2474                 else
2475                         a = 1;
2476
2477                 if(race_laptime && race_checkpoint != 255)
2478                 {
2479                         s = TIME_ENCODED_TOSTRING(TIME_ENCODE(time + TIME_DECODE(race_penaltyaccumulator) - race_laptime));
2480                         drawstring(pos + eX * 0.5 * mySize.x - '0.5 0 0' * stringwidth(s, false, '0.6 0.6 0' * mySize.y), s, '0.6 0.6 0' * mySize.y, '1 1 1', panel_fg_alpha * a, DRAWFLAG_NORMAL);
2481                 }
2482         }
2483         else
2484         {
2485                 if(race_mycheckpointtime)
2486                 {
2487                         a = bound(0, 2 - (time - race_mycheckpointtime), 1);
2488                         s = MakeRaceString(race_mycheckpoint, TIME_DECODE(race_mycheckpointdelta), -(race_mycheckpointenemy == ""), race_mycheckpointlapsdelta, race_mycheckpointenemy);
2489                         drawcolorcodedstring(pos + eX * 0.5 * mySize.x - '0.5 0 0' * stringwidth(s, true, '1 1 0' * 0.2 * mySize.y) + eY * 0.6 * mySize.y, s, '1 1 0' * 0.2 * mySize.y, panel_fg_alpha * a, DRAWFLAG_NORMAL);
2490                 }
2491                 if(race_othercheckpointtime && race_othercheckpointenemy != "")
2492                 {
2493                         a = bound(0, 2 - (time - race_othercheckpointtime), 1);
2494                         s = MakeRaceString(race_othercheckpoint, -TIME_DECODE(race_othercheckpointdelta), -(race_othercheckpointenemy == ""), race_othercheckpointlapsdelta, race_othercheckpointenemy);
2495                         drawcolorcodedstring(pos + eX * 0.5 * mySize.x - '0.5 0 0' * stringwidth(s, true, '1 1 0' * 0.2 * mySize.y) + eY * 0.6 * mySize.y, s, '1 1 0' * 0.2 * mySize.y, panel_fg_alpha * a, DRAWFLAG_NORMAL);
2496                 }
2497
2498                 if(race_penaltytime && !race_penaltyaccumulator)
2499                 {
2500                         t = race_penaltytime * 0.1 + race_penaltyeventtime;
2501                         a = bound(0, (1 + t - time), 1);
2502                         if(a > 0)
2503                         {
2504                                 if(time < t)
2505                                         s = sprintf(_("^1PENALTY: %.1f (%s)"), (t - time) * 0.1, race_penaltyreason);
2506                                 else
2507                                         s = sprintf(_("^2PENALTY: %.1f (%s)"), 0, race_penaltyreason);
2508                                 drawcolorcodedstring(pos + eX * 0.5 * mySize.x - '0.5 0 0' * stringwidth(s, true, '1 1 0' * 0.2 * mySize.y) + eY * 0.6 * mySize.y, s, '1 1 0' * 0.2 * mySize.y, panel_fg_alpha * a, DRAWFLAG_NORMAL);
2509                         }
2510                 }
2511         }
2512
2513         draw_endBoldFont();
2514 }
2515
2516 // Vote window (#9)
2517 //
2518 float vote_yescount;
2519 float vote_nocount;
2520 float vote_needed;
2521 float vote_highlighted; // currently selected vote
2522
2523 float vote_active; // is there an active vote?
2524 float vote_prev; // previous state of vote_active to check for a change
2525 float vote_alpha;
2526 float vote_change; // "time" when vote_active changed
2527
2528 void HUD_Vote(void)
2529 {
2530         if(autocvar_cl_allow_uid2name == -1 && (gametype == MAPINFO_TYPE_CTS || gametype == MAPINFO_TYPE_RACE || (serverflags & SERVERFLAG_PLAYERSTATS)))
2531         {
2532                 vote_active = 1;
2533                 if (autocvar__hud_configure)
2534                 {
2535                         vote_yescount = 0;
2536                         vote_nocount = 0;
2537                         print(_("^1You must answer before entering hud configure mode\n"));
2538                         cvar_set("_hud_configure", "0");
2539                 }
2540                 if(vote_called_vote)
2541                         strunzone(vote_called_vote);
2542                 vote_called_vote = strzone(_("^2Name ^7instead of \"^1Anonymous player^7\" in stats"));
2543                 uid2name_dialog = 1;
2544         }
2545
2546         if(!autocvar__hud_configure)
2547         {
2548                 if(!autocvar_hud_panel_vote) return;
2549
2550                 panel_fg_alpha = autocvar_hud_panel_fg_alpha;
2551                 panel_bg_alpha_str = autocvar_hud_panel_vote_bg_alpha;
2552
2553                 if(panel_bg_alpha_str == "") {
2554                         panel_bg_alpha_str = ftos(autocvar_hud_panel_bg_alpha);
2555                 }
2556                 panel_bg_alpha = stof(panel_bg_alpha_str);
2557         }
2558         else
2559         {
2560                 vote_yescount = 3;
2561                 vote_nocount = 2;
2562                 vote_needed = 4;
2563         }
2564
2565         string s;
2566         float a;
2567         if(vote_active != vote_prev) {
2568                 vote_change = time;
2569                 vote_prev = vote_active;
2570         }
2571
2572         if(vote_active || autocvar__hud_configure)
2573                 vote_alpha = bound(0, (time - vote_change) * 2, 1);
2574         else
2575                 vote_alpha = bound(0, 1 - (time - vote_change) * 2, 1);
2576
2577         if(!vote_alpha)
2578                 return;
2579
2580         HUD_Panel_UpdateCvars();
2581
2582         if(uid2name_dialog)
2583         {
2584                 panel_pos = eX * 0.3 * vid_conwidth + eY * 0.1 * vid_conheight;
2585                 panel_size = eX * 0.4 * vid_conwidth + eY * 0.3 * vid_conheight;
2586         }
2587
2588     // these must be below above block
2589         vector pos, mySize;
2590         pos = panel_pos;
2591         mySize = panel_size;
2592
2593         a = vote_alpha * (vote_highlighted ? autocvar_hud_panel_vote_alreadyvoted_alpha : 1);
2594         HUD_Panel_DrawBg(a);
2595         a = panel_fg_alpha * a;
2596
2597         if(panel_bg_padding)
2598         {
2599                 pos += '1 1 0' * panel_bg_padding;
2600                 mySize -= '2 2 0' * panel_bg_padding;
2601         }
2602
2603         // always force 3:1 aspect
2604         vector newSize = '0 0 0';
2605         if(mySize.x/mySize.y > 3)
2606         {
2607                 newSize.x = 3 * mySize.y;
2608                 newSize.y = mySize.y;
2609
2610                 pos.x = pos.x + (mySize.x - newSize.x) / 2;
2611         }
2612         else
2613         {
2614                 newSize.y = 1/3 * mySize.x;
2615                 newSize.x = mySize.x;
2616
2617                 pos.y = pos.y + (mySize.y - newSize.y) / 2;
2618         }
2619         mySize = newSize;
2620
2621         s = _("A vote has been called for:");
2622         if(uid2name_dialog)
2623                 s = _("Allow servers to store and display your name?");
2624         drawstring_aspect(pos, s, eX * mySize.x + eY * (2/8) * mySize.y, '1 1 1', a, DRAWFLAG_NORMAL);
2625         s = textShortenToWidth(vote_called_vote, mySize.x, '1 1 0' * mySize.y * (1/8), stringwidth_colors);
2626         if(autocvar__hud_configure)
2627                 s = _("^1Configure the HUD");
2628         drawcolorcodedstring_aspect(pos + eY * (2/8) * mySize.y, s, eX * mySize.x + eY * (1.75/8) * mySize.y, a, DRAWFLAG_NORMAL);
2629
2630         // print the yes/no counts
2631     s = sprintf(_("Yes (%s): %d"), getcommandkey("vyes", "vyes"), vote_yescount);
2632         drawstring_aspect(pos + eY * (4/8) * mySize.y, s, eX * 0.5 * mySize.x + eY * (1.5/8) * mySize.y, '0 1 0', a, DRAWFLAG_NORMAL);
2633     s = sprintf(_("No (%s): %d"), getcommandkey("vno", "vno"), vote_nocount);
2634         drawstring_aspect(pos + eX * 0.5 * mySize.x + eY * (4/8) * mySize.y, s, eX * 0.5 * mySize.x + eY * (1.5/8) * mySize.y, '1 0 0', a, DRAWFLAG_NORMAL);
2635
2636         // draw the progress bar backgrounds
2637         drawpic_skin(pos + eY * (5/8) * mySize.y, "voteprogress_back", eX * mySize.x + eY * (3/8) * mySize.y, '1 1 1', a, DRAWFLAG_NORMAL);
2638
2639         // draw the highlights
2640         if(vote_highlighted == 1) {
2641                 drawsetcliparea(pos.x, pos.y, mySize.x * 0.5, mySize.y);
2642                 drawpic_skin(pos + eY * (5/8) * mySize.y, "voteprogress_voted", eX * mySize.x + eY * (3/8) * mySize.y, '1 1 1', a, DRAWFLAG_NORMAL);
2643         }
2644         else if(vote_highlighted == -1) {
2645                 drawsetcliparea(pos.x + 0.5 * mySize.x, pos.y, mySize.x * 0.5, mySize.y);
2646                 drawpic_skin(pos + eY * (5/8) * mySize.y, "voteprogress_voted", eX * mySize.x + eY * (3/8) * mySize.y, '1 1 1', a, DRAWFLAG_NORMAL);
2647         }
2648
2649         // draw the progress bars
2650         if(vote_yescount && vote_needed)
2651         {
2652                 drawsetcliparea(pos.x, pos.y, mySize.x * 0.5 * (vote_yescount/vote_needed), mySize.y);
2653                 drawpic_skin(pos + eY * (5/8) * mySize.y, "voteprogress_prog", eX * mySize.x + eY * (3/8) * mySize.y, '1 1 1', a, DRAWFLAG_NORMAL);
2654         }
2655
2656         if(vote_nocount && vote_needed)
2657         {
2658                 drawsetcliparea(pos.x + mySize.x - mySize.x * 0.5 * (vote_nocount/vote_needed), pos.y, mySize.x * 0.5, mySize.y);
2659                 drawpic_skin(pos + eY * (5/8) * mySize.y, "voteprogress_prog", eX * mySize.x + eY * (3/8) * mySize.y, '1 1 1', a, DRAWFLAG_NORMAL);
2660         }
2661
2662         drawresetcliparea();
2663 }
2664
2665 // Mod icons panel (#10)
2666 //
2667
2668 float mod_active; // is there any active mod icon?
2669
2670 void DrawCAItem(vector myPos, vector mySize, float aspect_ratio, int layout, float i)
2671 {
2672         float stat = -1;
2673         string pic = "";
2674         vector color = '0 0 0';
2675         switch(i)
2676         {
2677                 case 0:
2678                         stat = getstati(STAT_REDALIVE);
2679                         pic = "player_red.tga";
2680                         color = '1 0 0';
2681                         break;
2682                 case 1:
2683                         stat = getstati(STAT_BLUEALIVE);
2684                         pic = "player_blue.tga";
2685                         color = '0 0 1';
2686                         break;
2687                 case 2:
2688                         stat = getstati(STAT_YELLOWALIVE);
2689                         pic = "player_yellow.tga";
2690                         color = '1 1 0';
2691                         break;
2692                 default:
2693                 case 3:
2694                         stat = getstati(STAT_PINKALIVE);
2695                         pic = "player_pink.tga";
2696                         color = '1 0 1';
2697                         break;
2698         }
2699
2700         if(mySize.x/mySize.y > aspect_ratio)
2701         {
2702                 i = aspect_ratio * mySize.y;
2703                 myPos.x = myPos.x + (mySize.x - i) / 2;
2704                 mySize.x = i;
2705         }
2706         else
2707         {
2708                 i = 1/aspect_ratio * mySize.x;
2709                 myPos.y = myPos.y + (mySize.y - i) / 2;
2710                 mySize.y = i;
2711         }
2712
2713         if(layout)
2714         {
2715                 drawpic_aspect_skin(myPos, pic, eX * 0.7 * mySize.x + eY * mySize.y, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
2716                 drawstring_aspect(myPos + eX * 0.7 * mySize.x, ftos(stat), eX * 0.3 * mySize.x + eY * mySize.y, color, panel_fg_alpha, DRAWFLAG_NORMAL);
2717         }
2718         else
2719                 drawstring_aspect(myPos, ftos(stat), mySize, color, panel_fg_alpha, DRAWFLAG_NORMAL);
2720 }
2721
2722 // Clan Arena and Freeze Tag HUD modicons
2723 void HUD_Mod_CA(vector myPos, vector mySize)
2724 {
2725         mod_active = 1; // required in each mod function that always shows something
2726
2727         int layout;
2728         if(gametype == MAPINFO_TYPE_CA)
2729                 layout = autocvar_hud_panel_modicons_ca_layout;
2730         else //if(gametype == MAPINFO_TYPE_FREEZETAG)
2731                 layout = autocvar_hud_panel_modicons_freezetag_layout;
2732         float rows, columns, aspect_ratio;
2733         aspect_ratio = (layout) ? 2 : 1;
2734         rows = HUD_GetRowCount(team_count, mySize, aspect_ratio);
2735         columns = ceil(team_count/rows);
2736
2737         int i;
2738         float row = 0, column = 0;
2739         vector pos, itemSize;
2740         itemSize = eX * mySize.x*(1/columns) + eY * mySize.y*(1/rows);
2741         for(i=0; i<team_count; ++i)
2742         {
2743                 pos = myPos + eX * column * itemSize.x + eY * row * itemSize.y;
2744
2745                 DrawCAItem(pos, itemSize, aspect_ratio, layout, i);
2746
2747                 ++row;
2748                 if(row >= rows)
2749                 {
2750                         row = 0;
2751                         ++column;
2752                 }
2753         }
2754 }
2755
2756 // CTF HUD modicon section
2757 float redflag_prevframe, blueflag_prevframe; // status during previous frame
2758 float redflag_prevstatus, blueflag_prevstatus; // last remembered status
2759 float redflag_statuschange_time, blueflag_statuschange_time; // time when the status changed
2760
2761 void HUD_Mod_CTF_Reset(void)
2762 {
2763         redflag_prevstatus = blueflag_prevstatus = redflag_prevframe = blueflag_prevframe = redflag_statuschange_time = blueflag_statuschange_time = 0;
2764 }
2765
2766 void HUD_Mod_CTF(vector pos, vector mySize)
2767 {
2768         vector redflag_pos, blueflag_pos;
2769         vector flag_size;
2770         float f; // every function should have that
2771
2772         float redflag, blueflag; // current status
2773         float redflag_statuschange_elapsedtime, blueflag_statuschange_elapsedtime; // time since the status changed
2774         float stat_items;
2775
2776         stat_items = getstati(STAT_ITEMS, 0, 24);
2777         redflag = (stat_items/IT_RED_FLAG_TAKEN) & 3;
2778         blueflag = (stat_items/IT_BLUE_FLAG_TAKEN) & 3;
2779
2780         if(redflag || blueflag)
2781                 mod_active = 1;
2782         else
2783                 mod_active = 0;
2784
2785         if(autocvar__hud_configure)
2786         {
2787                 redflag = 1;
2788                 blueflag = 2;
2789         }
2790
2791         // when status CHANGES, set old status into prevstatus and current status into status
2792         if (redflag != redflag_prevframe)
2793         {
2794                 redflag_statuschange_time = time;
2795                 redflag_prevstatus = redflag_prevframe;
2796                 redflag_prevframe = redflag;
2797         }
2798
2799         if (blueflag != blueflag_prevframe)
2800         {
2801                 blueflag_statuschange_time = time;
2802                 blueflag_prevstatus = blueflag_prevframe;
2803                 blueflag_prevframe = blueflag;
2804         }
2805
2806         redflag_statuschange_elapsedtime = time - redflag_statuschange_time;
2807         blueflag_statuschange_elapsedtime = time - blueflag_statuschange_time;
2808
2809         float BLINK_FACTOR = 0.15;
2810         float BLINK_BASE = 0.85;
2811         // note:
2812         //   RMS = sqrt(BLINK_BASE^2 + 0.5 * BLINK_FACTOR^2)
2813         // thus
2814         //   BLINK_BASE = sqrt(RMS^2 - 0.5 * BLINK_FACTOR^2)
2815         // ensure RMS == 1
2816         float BLINK_FREQ = 5; // circle frequency, = 2*pi*frequency in hertz
2817
2818         string red_icon, red_icon_prevstatus;
2819         float red_alpha, red_alpha_prevstatus;
2820         red_alpha = red_alpha_prevstatus = 1;
2821         switch(redflag) {
2822                 case 1: red_icon = "flag_red_taken"; break;
2823                 case 2: red_icon = "flag_red_lost"; break;
2824                 case 3: red_icon = "flag_red_carrying"; red_alpha = BLINK_BASE + BLINK_FACTOR * cos(time * BLINK_FREQ); break;
2825                 default:
2826                         if((stat_items & IT_CTF_SHIELDED) && (myteam == NUM_TEAM_2))
2827                                 red_icon = "flag_red_shielded";
2828                         else
2829                                 red_icon = string_null;
2830                         break;
2831         }
2832         switch(redflag_prevstatus) {
2833                 case 1: red_icon_prevstatus = "flag_red_taken"; break;
2834                 case 2: red_icon_prevstatus = "flag_red_lost"; break;
2835                 case 3: red_icon_prevstatus = "flag_red_carrying"; red_alpha_prevstatus = BLINK_BASE + BLINK_FACTOR * cos(time * BLINK_FREQ); break;
2836                 default:
2837                         if(redflag == 3)
2838                                 red_icon_prevstatus = "flag_red_carrying"; // make it more visible
2839                         else if((stat_items & IT_CTF_SHIELDED) && (myteam == NUM_TEAM_2))
2840                                 red_icon_prevstatus = "flag_red_shielded";
2841                         else
2842                                 red_icon_prevstatus = string_null;
2843                         break;
2844         }
2845
2846         string blue_icon, blue_icon_prevstatus;
2847         float blue_alpha, blue_alpha_prevstatus;
2848         blue_alpha = blue_alpha_prevstatus = 1;
2849         switch(blueflag) {
2850                 case 1: blue_icon = "flag_blue_taken"; break;
2851                 case 2: blue_icon = "flag_blue_lost"; break;
2852                 case 3: blue_icon = "flag_blue_carrying"; blue_alpha = BLINK_BASE + BLINK_FACTOR * cos(time * BLINK_FREQ); break;
2853                 default:
2854                         if((stat_items & IT_CTF_SHIELDED) && (myteam == NUM_TEAM_1))
2855                                 blue_icon = "flag_blue_shielded";
2856                         else
2857                                 blue_icon = string_null;
2858                         break;
2859         }
2860         switch(blueflag_prevstatus) {
2861                 case 1: blue_icon_prevstatus = "flag_blue_taken"; break;
2862                 case 2: blue_icon_prevstatus = "flag_blue_lost"; break;
2863                 case 3: blue_icon_prevstatus = "flag_blue_carrying"; blue_alpha_prevstatus = BLINK_BASE + BLINK_FACTOR * cos(time * BLINK_FREQ); break;
2864                 default:
2865                         if(blueflag == 3)
2866                                 blue_icon_prevstatus = "flag_blue_carrying"; // make it more visible
2867                         else if((stat_items & IT_CTF_SHIELDED) && (myteam == NUM_TEAM_1))
2868                                 blue_icon_prevstatus = "flag_blue_shielded";
2869                         else
2870                                 blue_icon_prevstatus = string_null;
2871                         break;
2872         }
2873
2874         if(mySize.x > mySize.y) {
2875                 if (myteam == NUM_TEAM_1) { // always draw own flag on left
2876                         redflag_pos = pos;
2877                         blueflag_pos = pos + eX * 0.5 * mySize.x;
2878                 } else {
2879                         blueflag_pos = pos;
2880                         redflag_pos = pos + eX * 0.5 * mySize.x;
2881                 }
2882                 flag_size = eX * 0.5 * mySize.x + eY * mySize.y;
2883         } else {
2884                 if (myteam == NUM_TEAM_1) { // always draw own flag on left
2885                         redflag_pos = pos;
2886                         blueflag_pos = pos + eY * 0.5 * mySize.y;
2887                 } else {
2888                         blueflag_pos = pos;
2889                         redflag_pos = pos + eY * 0.5 * mySize.y;
2890                 }
2891                 flag_size = eY * 0.5 * mySize.y + eX * mySize.x;
2892         }
2893
2894         f = bound(0, redflag_statuschange_elapsedtime*2, 1);
2895         if(red_icon_prevstatus && f < 1)
2896                 drawpic_aspect_skin_expanding(redflag_pos, red_icon_prevstatus, flag_size, '1 1 1', panel_fg_alpha * red_alpha_prevstatus, DRAWFLAG_NORMAL, f);
2897         if(red_icon)
2898                 drawpic_aspect_skin(redflag_pos, red_icon, flag_size, '1 1 1', panel_fg_alpha * red_alpha * f, DRAWFLAG_NORMAL);
2899
2900         f = bound(0, blueflag_statuschange_elapsedtime*2, 1);
2901         if(blue_icon_prevstatus && f < 1)
2902                 drawpic_aspect_skin_expanding(blueflag_pos, blue_icon_prevstatus, flag_size, '1 1 1', panel_fg_alpha * blue_alpha_prevstatus, DRAWFLAG_NORMAL, f);
2903         if(blue_icon)
2904                 drawpic_aspect_skin(blueflag_pos, blue_icon, flag_size, '1 1 1', panel_fg_alpha * blue_alpha * f, DRAWFLAG_NORMAL);
2905 }
2906
2907 // Keyhunt HUD modicon section
2908 vector KH_SLOTS[4];
2909
2910 void HUD_Mod_KH(vector pos, vector mySize)
2911 {
2912         mod_active = 1; // keyhunt should never hide the mod icons panel
2913
2914         // Read current state
2915
2916         float state = getstati(STAT_KH_KEYS);
2917         float i, key_state;
2918         float all_keys, team1_keys, team2_keys, team3_keys, team4_keys, dropped_keys, carrying_keys;
2919         all_keys = team1_keys = team2_keys = team3_keys = team4_keys = dropped_keys = carrying_keys = 0;
2920
2921         for(i = 0; i < 4; ++i)
2922         {
2923                 key_state = (bitshift(state, i * -5) & 31) - 1;
2924
2925                 if(key_state == -1)
2926                         continue;
2927
2928                 if(key_state == 30)
2929                 {
2930                         ++carrying_keys;
2931                         key_state = myteam;
2932                 }
2933
2934                 switch(key_state)
2935                 {
2936                         case NUM_TEAM_1: ++team1_keys; break;
2937                         case NUM_TEAM_2: ++team2_keys; break;
2938                         case NUM_TEAM_3: ++team3_keys; break;
2939                         case NUM_TEAM_4: ++team4_keys; break;
2940                         case 29: ++dropped_keys; break;
2941                 }
2942
2943                 ++all_keys;
2944         }
2945
2946         // Calculate slot measurements
2947
2948         vector slot_size;
2949
2950         if(all_keys == 4 && mySize.x * 0.5 < mySize.y && mySize.y * 0.5 < mySize.x)
2951         {
2952                 // Quadratic arrangement
2953                 slot_size = eX * mySize.x * 0.5 + eY * mySize.y * 0.5;
2954                 KH_SLOTS[0] = pos;
2955                 KH_SLOTS[1] = pos + eX * slot_size.x;
2956                 KH_SLOTS[2] = pos + eY * slot_size.y;
2957                 KH_SLOTS[3] = pos + eX * slot_size.x + eY * slot_size.y;
2958         }
2959         else
2960         {
2961                 if(mySize.x > mySize.y)
2962                 {
2963                         // Horizontal arrangement
2964                         slot_size = eX * mySize.x / all_keys + eY * mySize.y;
2965                         for(i = 0; i < all_keys; ++i)
2966                                 KH_SLOTS[i] = pos + eX * slot_size.x * i;
2967                 }
2968                 else
2969                 {
2970                         // Vertical arrangement
2971                         slot_size = eX * mySize.x + eY * mySize.y / all_keys;
2972                         for(i = 0; i < all_keys; ++i)
2973                                 KH_SLOTS[i] = pos + eY * slot_size.y * i;
2974                 }
2975         }
2976
2977         // Make icons blink in case of RUN HERE
2978
2979         float blink = 0.6 + sin(2*M_PI*time) / 2.5; // Oscillate between 0.2 and 1
2980         float alpha;
2981         alpha = 1;
2982
2983         if(carrying_keys)
2984                 switch(myteam)
2985                 {
2986                         case NUM_TEAM_1: if(team1_keys == all_keys) alpha = blink; break;
2987                         case NUM_TEAM_2: if(team2_keys == all_keys) alpha = blink; break;
2988                         case NUM_TEAM_3: if(team3_keys == all_keys) alpha = blink; break;
2989                         case NUM_TEAM_4: if(team4_keys == all_keys) alpha = blink; break;
2990                 }
2991
2992         // Draw icons
2993
2994         i = 0;
2995
2996         while(team1_keys--)
2997                 if(myteam == NUM_TEAM_1 && carrying_keys)
2998                 {
2999                         drawpic_aspect_skin(KH_SLOTS[i++], "kh_red_carrying", slot_size, '1 1 1', alpha, DRAWFLAG_NORMAL);
3000                         --carrying_keys;
3001                 }
3002                 else
3003                         drawpic_aspect_skin(KH_SLOTS[i++], "kh_red_taken", slot_size, '1 1 1', alpha, DRAWFLAG_NORMAL);
3004
3005         while(team2_keys--)
3006                 if(myteam == NUM_TEAM_2 && carrying_keys)
3007                 {
3008                         drawpic_aspect_skin(KH_SLOTS[i++], "kh_blue_carrying", slot_size, '1 1 1', alpha, DRAWFLAG_NORMAL);
3009                         --carrying_keys;
3010                 }
3011                 else
3012                         drawpic_aspect_skin(KH_SLOTS[i++], "kh_blue_taken", slot_size, '1 1 1', alpha, DRAWFLAG_NORMAL);
3013
3014         while(team3_keys--)
3015                 if(myteam == NUM_TEAM_3 && carrying_keys)
3016                 {
3017                         drawpic_aspect_skin(KH_SLOTS[i++], "kh_yellow_carrying", slot_size, '1 1 1', alpha, DRAWFLAG_NORMAL);
3018                         --carrying_keys;
3019                 }
3020                 else
3021                         drawpic_aspect_skin(KH_SLOTS[i++], "kh_yellow_taken", slot_size, '1 1 1', alpha, DRAWFLAG_NORMAL);
3022
3023         while(team4_keys--)
3024                 if(myteam == NUM_TEAM_4 && carrying_keys)
3025                 {
3026                         drawpic_aspect_skin(KH_SLOTS[i++], "kh_pink_carrying", slot_size, '1 1 1', alpha, DRAWFLAG_NORMAL);
3027                         --carrying_keys;
3028                 }
3029                 else
3030                         drawpic_aspect_skin(KH_SLOTS[i++], "kh_pink_taken", slot_size, '1 1 1', alpha, DRAWFLAG_NORMAL);
3031
3032         while(dropped_keys--)
3033                 drawpic_aspect_skin(KH_SLOTS[i++], "kh_dropped", slot_size, '1 1 1', alpha, DRAWFLAG_NORMAL);
3034 }
3035
3036 // Keepaway HUD mod icon
3037 float kaball_prevstatus; // last remembered status
3038 float kaball_statuschange_time; // time when the status changed
3039
3040 // we don't need to reset for keepaway since it immediately
3041 // autocorrects prevstatus as to if the player has the ball or not
3042
3043 void HUD_Mod_Keepaway(vector pos, vector mySize)
3044 {
3045         mod_active = 1; // keepaway should always show the mod HUD
3046
3047         float BLINK_FACTOR = 0.15;
3048         float BLINK_BASE = 0.85;
3049         float BLINK_FREQ = 5;
3050         float kaball_alpha = BLINK_BASE + BLINK_FACTOR * cos(time * BLINK_FREQ);
3051
3052         float stat_items = getstati(STAT_ITEMS, 0, 24);
3053         float kaball = (stat_items/IT_KEY1) & 1;
3054
3055         if(kaball != kaball_prevstatus)
3056         {
3057                 kaball_statuschange_time = time;
3058                 kaball_prevstatus = kaball;
3059         }
3060
3061         vector kaball_pos, kaball_size;
3062
3063         if(mySize.x > mySize.y) {
3064                 kaball_pos = pos + eX * 0.25 * mySize.x;
3065                 kaball_size = eX * 0.5 * mySize.x + eY * mySize.y;
3066         } else {
3067                 kaball_pos = pos + eY * 0.25 * mySize.y;
3068                 kaball_size = eY * 0.5 * mySize.y + eX * mySize.x;
3069         }
3070
3071         float kaball_statuschange_elapsedtime = time - kaball_statuschange_time;
3072         float f = bound(0, kaball_statuschange_elapsedtime*2, 1);
3073
3074         if(kaball_prevstatus && f < 1)
3075                 drawpic_aspect_skin_expanding(kaball_pos, "keepawayball_carrying", kaball_size, '1 1 1', panel_fg_alpha * kaball_alpha, DRAWFLAG_NORMAL, f);
3076
3077         if(kaball)
3078                 drawpic_aspect_skin(pos, "keepawayball_carrying", eX * mySize.x + eY * mySize.y, '1 1 1', panel_fg_alpha * kaball_alpha * f, DRAWFLAG_NORMAL);
3079 }
3080
3081
3082 // Nexball HUD mod icon
3083 void HUD_Mod_NexBall(vector pos, vector mySize)
3084 {
3085         float stat_items, nb_pb_starttime, dt, p;
3086
3087         stat_items = getstati(STAT_ITEMS, 0, 24);
3088         nb_pb_starttime = getstatf(STAT_NB_METERSTART);
3089
3090         if (stat_items & IT_KEY1)
3091                 mod_active = 1;
3092         else
3093                 mod_active = 0;
3094
3095         //Manage the progress bar if any
3096         if (nb_pb_starttime > 0)
3097         {
3098                 dt = (time - nb_pb_starttime) % nb_pb_period;
3099                 // one period of positive triangle
3100                 p = 2 * dt / nb_pb_period;
3101                 if (p > 1)
3102                         p = 2 - p;
3103
3104                 HUD_Panel_DrawProgressBar(pos, mySize, "progressbar", p, (mySize.x <= mySize.y), 0, autocvar_hud_progressbar_nexball_color, autocvar_hud_progressbar_alpha * panel_fg_alpha, DRAWFLAG_NORMAL);
3105         }
3106
3107         if (stat_items & IT_KEY1)
3108                 drawpic_aspect_skin(pos, "nexball_carrying", eX * mySize.x + eY * mySize.y, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
3109 }
3110
3111 // Race/CTS HUD mod icons
3112 float crecordtime_prev; // last remembered crecordtime
3113 float crecordtime_change_time; // time when crecordtime last changed
3114 float srecordtime_prev; // last remembered srecordtime
3115 float srecordtime_change_time; // time when srecordtime last changed
3116
3117 float race_status_time;
3118 float race_status_prev;
3119 string race_status_name_prev;
3120 void HUD_Mod_Race(vector pos, vector mySize)
3121 {
3122         mod_active = 1; // race should never hide the mod icons panel
3123         entity me;
3124         me = playerslots[player_localnum];
3125         float t, score;
3126         float f; // yet another function has this
3127         score = me.(scores[ps_primary]);
3128
3129         if(!(scores_flags[ps_primary] & SFL_TIME) || teamplay) // race/cts record display on HUD
3130                 return; // no records in the actual race
3131
3132         // clientside personal record
3133         string rr;
3134         if(gametype == MAPINFO_TYPE_CTS)
3135                 rr = CTS_RECORD;
3136         else
3137                 rr = RACE_RECORD;
3138         t = stof(db_get(ClientProgsDB, strcat(shortmapname, rr, "time")));
3139
3140         if(score && (score < t || !t)) {
3141                 db_put(ClientProgsDB, strcat(shortmapname, rr, "time"), ftos(score));
3142                 if(autocvar_cl_autodemo_delete_keeprecords)
3143                 {
3144                         f = autocvar_cl_autodemo_delete;
3145                         f &= ~1;
3146                         cvar_set("cl_autodemo_delete", ftos(f)); // don't delete demo with new record!
3147                 }
3148         }
3149
3150         if(t != crecordtime_prev) {
3151                 crecordtime_prev = t;
3152                 crecordtime_change_time = time;
3153         }
3154
3155         vector textPos, medalPos;
3156         float squareSize;
3157         if(mySize.x > mySize.y) {
3158                 // text on left side
3159                 squareSize = min(mySize.y, mySize.x/2);
3160                 textPos = pos + eX * 0.5 * max(0, mySize.x/2 - squareSize) + eY * 0.5 * (mySize.y - squareSize);
3161                 medalPos = pos + eX * 0.5 * max(0, mySize.x/2 - squareSize) + eX * 0.5 * mySize.x + eY * 0.5 * (mySize.y - squareSize);
3162         } else {
3163                 // text on top
3164                 squareSize = min(mySize.x, mySize.y/2);
3165                 textPos = pos + eY * 0.5 * max(0, mySize.y/2 - squareSize) + eX * 0.5 * (mySize.x - squareSize);
3166                 medalPos = pos + eY * 0.5 * max(0, mySize.y/2 - squareSize) + eY * 0.5 * mySize.y + eX * 0.5 * (mySize.x - squareSize);
3167         }
3168
3169         f = time - crecordtime_change_time;
3170
3171         if (f > 1) {
3172                 drawstring_aspect(textPos, _("Personal best"), eX * squareSize + eY * 0.25 * squareSize, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
3173                 drawstring_aspect(textPos + eY * 0.25 * squareSize, TIME_ENCODED_TOSTRING(t), eX * squareSize + eY * 0.25 * squareSize, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
3174         } else {
3175                 drawstring_aspect(textPos, _("Personal best"), eX * squareSize + eY * 0.25 * squareSize, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
3176                 drawstring_aspect(textPos + eY * 0.25 * squareSize, TIME_ENCODED_TOSTRING(t), eX * squareSize + eY * 0.25 * squareSize, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
3177                 drawstring_aspect_expanding(pos, _("Personal best"), eX * squareSize + eY * 0.25 * squareSize, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL, f);
3178                 drawstring_aspect_expanding(pos + eY * 0.25 * squareSize, TIME_ENCODED_TOSTRING(t), eX * squareSize + eY * 0.25 * squareSize, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL, f);
3179         }
3180
3181         // server record
3182         t = race_server_record;
3183         if(t != srecordtime_prev) {
3184                 srecordtime_prev = t;
3185                 srecordtime_change_time = time;
3186         }
3187         f = time - srecordtime_change_time;
3188
3189         if (f > 1) {
3190                 drawstring_aspect(textPos + eY * 0.5 * squareSize, _("Server best"), eX * squareSize + eY * 0.25 * squareSize, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
3191                 drawstring_aspect(textPos + eY * 0.75 * squareSize, TIME_ENCODED_TOSTRING(t), eX * squareSize + eY * 0.25 * squareSize, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
3192         } else {
3193                 drawstring_aspect(textPos + eY * 0.5 * squareSize, _("Server best"), eX * squareSize + eY * 0.25 * squareSize, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
3194                 drawstring_aspect(textPos + eY * 0.75 * squareSize, TIME_ENCODED_TOSTRING(t), eX * squareSize + eY * 0.25 * squareSize, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
3195                 drawstring_aspect_expanding(textPos + eY * 0.5 * squareSize, _("Server best"), eX * squareSize + eY * 0.25 * squareSize, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL, f);
3196                 drawstring_aspect_expanding(textPos + eY * 0.75 * squareSize, TIME_ENCODED_TOSTRING(t), eX * squareSize + eY * 0.25 * squareSize, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL, f);
3197         }
3198
3199         if (race_status != race_status_prev || race_status_name != race_status_name_prev) {
3200                 race_status_time = time + 5;
3201                 race_status_prev = race_status;
3202                 if (race_status_name_prev)
3203                         strunzone(race_status_name_prev);
3204                 race_status_name_prev = strzone(race_status_name);
3205         }
3206
3207         // race "awards"
3208         float a;
3209         a = bound(0, race_status_time - time, 1);
3210
3211         string s;
3212         s = textShortenToWidth(race_status_name, squareSize, '1 1 0' * 0.1 * squareSize, stringwidth_colors);
3213
3214         float rank;
3215         if(race_status > 0)
3216                 rank = race_CheckName(race_status_name);
3217         else
3218                 rank = 0;
3219         string rankname;
3220         rankname = count_ordinal(rank);
3221
3222         vector namepos;
3223         namepos = medalPos + '0 0.8 0' * squareSize;
3224         vector rankpos;
3225         rankpos = medalPos + '0 0.15 0' * squareSize;
3226
3227         if(race_status == 0)
3228                 drawpic_aspect_skin(medalPos, "race_newfail", '1 1 0' * squareSize, '1 1 1', panel_fg_alpha * a, DRAWFLAG_NORMAL);
3229         else if(race_status == 1) {
3230                 drawpic_aspect_skin(medalPos + '0.1 0 0' * squareSize, "race_newtime", '1 1 0' * 0.8 * squareSize, '1 1 1', panel_fg_alpha * a, DRAWFLAG_NORMAL);
3231                 drawcolorcodedstring_aspect(namepos, s, '1 0.2 0' * squareSize, panel_fg_alpha * a, DRAWFLAG_NORMAL);
3232                 drawstring_aspect(rankpos, rankname, '1 0.15 0' * squareSize, '1 1 1', panel_fg_alpha * a, DRAWFLAG_NORMAL);
3233         } else if(race_status == 2) {
3234                 if(race_status_name == GetPlayerName(player_localnum) || !race_myrank || race_myrank < rank)
3235                         drawpic_aspect_skin(medalPos + '0.1 0 0' * squareSize, "race_newrankgreen", '1 1 0' * 0.8 * squareSize, '1 1 1', panel_fg_alpha * a, DRAWFLAG_NORMAL);
3236                 else
3237                         drawpic_aspect_skin(medalPos + '0.1 0 0' * squareSize, "race_newrankyellow", '1 1 0' * 0.8 * squareSize, '1 1 1', panel_fg_alpha * a, DRAWFLAG_NORMAL);
3238                 drawcolorcodedstring_aspect(namepos, s, '1 0.2 0' * squareSize, panel_fg_alpha * a, DRAWFLAG_NORMAL);
3239                 drawstring_aspect(rankpos, rankname, '1 0.15 0' * squareSize, '1 1 1', panel_fg_alpha * a, DRAWFLAG_NORMAL);
3240         } else if(race_status == 3) {
3241                 drawpic_aspect_skin(medalPos + '0.1 0 0' * squareSize, "race_newrecordserver", '1 1 0' * 0.8 * squareSize, '1 1 1', panel_fg_alpha * a, DRAWFLAG_NORMAL);
3242                 drawcolorcodedstring_aspect(namepos, s, '1 0.2 0' * squareSize, panel_fg_alpha * a, DRAWFLAG_NORMAL);
3243                 drawstring_aspect(rankpos, rankname, '1 0.15 0' * squareSize, '1 1 1', panel_fg_alpha * a, DRAWFLAG_NORMAL);
3244         }
3245
3246         if (race_status_time - time <= 0) {
3247                 race_status_prev = -1;
3248                 race_status = -1;
3249                 if(race_status_name)
3250                         strunzone(race_status_name);
3251                 race_status_name = string_null;
3252                 if(race_status_name_prev)
3253                         strunzone(race_status_name_prev);
3254                 race_status_name_prev = string_null;
3255         }
3256 }
3257
3258 void DrawDomItem(vector myPos, vector mySize, float aspect_ratio, int layout, float i)
3259 {
3260         float stat = -1;
3261         string pic = "";
3262         vector color = '0 0 0';
3263         switch(i)
3264         {
3265                 case 0:
3266                         stat = getstatf(STAT_DOM_PPS_RED);
3267                         pic = "dom_icon_red";
3268                         color = '1 0 0';
3269                         break;
3270                 case 1:
3271                         stat = getstatf(STAT_DOM_PPS_BLUE);
3272                         pic = "dom_icon_blue";
3273                         color = '0 0 1';
3274                         break;
3275                 case 2:
3276                         stat = getstatf(STAT_DOM_PPS_YELLOW);
3277                         pic = "dom_icon_yellow";
3278                         color = '1 1 0';
3279                         break;
3280                 default:
3281                 case 3:
3282                         stat = getstatf(STAT_DOM_PPS_PINK);
3283                         pic = "dom_icon_pink";
3284                         color = '1 0 1';
3285                         break;
3286         }
3287         float pps_ratio = stat / getstatf(STAT_DOM_TOTAL_PPS);
3288
3289         if(mySize.x/mySize.y > aspect_ratio)
3290         {
3291                 i = aspect_ratio * mySize.y;
3292                 myPos.x = myPos.x + (mySize.x - i) / 2;
3293                 mySize.x = i;
3294         }
3295         else
3296         {
3297                 i = 1/aspect_ratio * mySize.x;
3298                 myPos.y = myPos.y + (mySize.y - i) / 2;
3299                 mySize.y = i;
3300         }
3301
3302         if (layout) // show text too
3303         {
3304                 //draw the text
3305                 color *= 0.5 + pps_ratio * (1 - 0.5); // half saturated color at min, full saturated at max
3306                 if (layout == 2) // average pps
3307                         drawstring_aspect(myPos + eX * mySize.y, ftos_decimals(stat, 2), eX * (2/3) * mySize.x + eY * mySize.y, color, panel_fg_alpha, DRAWFLAG_NORMAL);
3308                 else // percentage of average pps
3309                         drawstring_aspect(myPos + eX * mySize.y, strcat( ftos(floor(pps_ratio*100 + 0.5)), "%" ), eX * (2/3) * mySize.x + eY * mySize.y, color, panel_fg_alpha, DRAWFLAG_NORMAL);
3310         }
3311
3312         //draw the icon
3313         drawpic_aspect_skin(myPos, pic, '1 1 0' * mySize.y, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
3314         if (stat > 0)
3315         {
3316                 drawsetcliparea(myPos.x, myPos.y + mySize.y * (1 - pps_ratio), mySize.y, mySize.y * pps_ratio);
3317                 drawpic_aspect_skin(myPos, strcat(pic, "-highlighted"), '1 1 0' * mySize.y, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
3318                 drawresetcliparea();
3319         }
3320 }
3321
3322 void HUD_Mod_Dom(vector myPos, vector mySize)
3323 {
3324         mod_active = 1; // required in each mod function that always shows something
3325
3326         int layout = autocvar_hud_panel_modicons_dom_layout;
3327         float rows, columns, aspect_ratio;
3328         aspect_ratio = (layout) ? 3 : 1;
3329         rows = HUD_GetRowCount(team_count, mySize, aspect_ratio);
3330         columns = ceil(team_count/rows);
3331
3332         int i;
3333         float row = 0, column = 0;
3334         vector pos, itemSize;
3335         itemSize = eX * mySize.x*(1/columns) + eY * mySize.y*(1/rows);
3336         for(i=0; i<team_count; ++i)
3337         {
3338                 pos = myPos + eX * column * itemSize.x + eY * row * itemSize.y;
3339
3340                 DrawDomItem(pos, itemSize, aspect_ratio, layout, i);
3341
3342                 ++row;
3343                 if(row >= rows)
3344                 {
3345                         row = 0;
3346                         ++column;
3347                 }
3348         }
3349 }
3350
3351 void HUD_ModIcons_SetFunc()
3352 {
3353         switch(gametype)
3354         {
3355                 case MAPINFO_TYPE_KEYHUNT:              HUD_ModIcons_GameType = HUD_Mod_KH; break;
3356                 case MAPINFO_TYPE_CTF:                  HUD_ModIcons_GameType = HUD_Mod_CTF; break;
3357                 case MAPINFO_TYPE_NEXBALL:              HUD_ModIcons_GameType = HUD_Mod_NexBall; break;
3358                 case MAPINFO_TYPE_CTS:
3359                 case MAPINFO_TYPE_RACE:         HUD_ModIcons_GameType = HUD_Mod_Race; break;
3360                 case MAPINFO_TYPE_CA:
3361                 case MAPINFO_TYPE_FREEZETAG:    HUD_ModIcons_GameType = HUD_Mod_CA; break;
3362                 case MAPINFO_TYPE_DOMINATION:   HUD_ModIcons_GameType = HUD_Mod_Dom; break;
3363                 case MAPINFO_TYPE_KEEPAWAY:     HUD_ModIcons_GameType = HUD_Mod_Keepaway; break;
3364         }
3365 }
3366
3367 float mod_prev; // previous state of mod_active to check for a change
3368 float mod_alpha;
3369 float mod_change; // "time" when mod_active changed
3370
3371 void HUD_ModIcons(void)
3372 {
3373         if(!autocvar__hud_configure)
3374         {
3375                 if(!autocvar_hud_panel_modicons) return;
3376                 if(!HUD_ModIcons_GameType) return;
3377         }
3378
3379         HUD_Panel_UpdateCvars();
3380
3381         draw_beginBoldFont();
3382
3383         if(mod_active != mod_prev) {
3384                 mod_change = time;
3385                 mod_prev = mod_active;
3386         }
3387
3388         if(mod_active || autocvar__hud_configure)
3389                 mod_alpha = bound(0, (time - mod_change) * 2, 1);
3390         else
3391                 mod_alpha = bound(0, 1 - (time - mod_change) * 2, 1);
3392
3393         if(mod_alpha)
3394                 HUD_Panel_DrawBg(mod_alpha);
3395
3396         if(panel_bg_padding)
3397         {
3398                 panel_pos += '1 1 0' * panel_bg_padding;
3399                 panel_size -= '2 2 0' * panel_bg_padding;
3400         }
3401
3402         if(autocvar__hud_configure)
3403                 HUD_Mod_CTF(panel_pos, panel_size);
3404         else
3405                 HUD_ModIcons_GameType(panel_pos, panel_size);
3406
3407         draw_endBoldFont();
3408 }
3409
3410 // Draw pressed keys (#11)
3411 //
3412 void HUD_PressedKeys(void)
3413 {
3414         if(!autocvar__hud_configure)
3415         {
3416                 if(!autocvar_hud_panel_pressedkeys) return;
3417                 if(spectatee_status <= 0 && autocvar_hud_panel_pressedkeys < 2) return;
3418         }
3419
3420         HUD_Panel_UpdateCvars();
3421         vector pos, mySize;
3422         pos = panel_pos;
3423         mySize = panel_size;
3424
3425         HUD_Panel_DrawBg(1);
3426         if(panel_bg_padding)
3427         {
3428                 pos += '1 1 0' * panel_bg_padding;
3429                 mySize -= '2 2 0' * panel_bg_padding;
3430         }
3431
3432         // force custom aspect
3433         float aspect = autocvar_hud_panel_pressedkeys_aspect;
3434         if(aspect)
3435         {
3436                 vector newSize = '0 0 0';
3437                 if(mySize.x/mySize.y > aspect)
3438                 {
3439                         newSize.x = aspect * mySize.y;
3440                         newSize.y = mySize.y;
3441
3442                         pos.x = pos.x + (mySize.x - newSize.x) / 2;
3443                 }
3444                 else
3445                 {
3446                         newSize.y = 1/aspect * mySize.x;
3447                         newSize.x = mySize.x;
3448
3449                         pos.y = pos.y + (mySize.y - newSize.y) / 2;
3450                 }
3451                 mySize = newSize;
3452         }
3453
3454         vector keysize;
3455         keysize = eX * mySize.x * (1/3.0) + eY * mySize.y * (1/(3.0 - !autocvar_hud_panel_pressedkeys_attack));
3456         float pressedkeys;
3457         pressedkeys = getstatf(STAT_PRESSED_KEYS);
3458
3459         if(autocvar_hud_panel_pressedkeys_attack)
3460         {
3461                 drawpic_aspect_skin(pos + eX * keysize.x * 0.5, ((pressedkeys & KEY_ATCK) ? "key_atck_inv.tga" : "key_atck.tga"), keysize, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
3462                 drawpic_aspect_skin(pos + eX * keysize.x * 1.5, ((pressedkeys & KEY_ATCK2) ? "key_atck_inv.tga" : "key_atck.tga"), keysize, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
3463                 pos.y += keysize.y;
3464         }
3465
3466         drawpic_aspect_skin(pos, ((pressedkeys & KEY_CROUCH) ? "key_crouch_inv.tga" : "key_crouch.tga"), keysize, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
3467         drawpic_aspect_skin(pos + eX * keysize.x, ((pressedkeys & KEY_FORWARD) ? "key_forward_inv.tga" : "key_forward.tga"), keysize, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
3468         drawpic_aspect_skin(pos + eX * keysize.x * 2, ((pressedkeys & KEY_JUMP) ? "key_jump_inv.tga" : "key_jump.tga"), keysize, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
3469         pos.y += keysize.y;
3470         drawpic_aspect_skin(pos, ((pressedkeys & KEY_LEFT) ? "key_left_inv.tga" : "key_left.tga"), keysize, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
3471         drawpic_aspect_skin(pos + eX * keysize.x, ((pressedkeys & KEY_BACKWARD) ? "key_backward_inv.tga" : "key_backward.tga"), keysize, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
3472         drawpic_aspect_skin(pos + eX * keysize.x * 2, ((pressedkeys & KEY_RIGHT) ? "key_right_inv.tga" : "key_right.tga"), keysize, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
3473 }
3474
3475 // Handle chat as a panel (#12)
3476 //
3477 void HUD_Chat(void)
3478 {
3479         if(!autocvar__hud_configure)
3480         {
3481                 if (!autocvar_hud_panel_chat)
3482                 {
3483                         if (!autocvar_con_chatrect)
3484                                 cvar_set("con_chatrect", "0");
3485                         return;
3486                 }
3487                 if(autocvar__con_chat_maximized)
3488                 {
3489                         if(!hud_draw_maximized) return;
3490                 }
3491                 else if(chat_panel_modified)
3492                 {
3493                         panel.update_time = time; // forces reload of panel attributes
3494                         chat_panel_modified = false;
3495                 }
3496         }
3497
3498         HUD_Panel_UpdateCvars();
3499
3500         if(autocvar__con_chat_maximized && !autocvar__hud_configure) // draw at full screen height if maximized
3501         {
3502                 panel_pos.y = panel_bg_border;
3503                 panel_size.y = vid_conheight - panel_bg_border * 2;
3504                 if(panel.current_panel_bg == "0") // force a border when maximized
3505                 {
3506                         string panel_bg;
3507                         panel_bg = strcat(hud_skin_path, "/border_default");
3508                         if(precache_pic(panel_bg) == "")
3509                                 panel_bg = "gfx/hud/default/border_default";
3510                         if(panel.current_panel_bg)
3511                                 strunzone(panel.current_panel_bg);
3512                         panel.current_panel_bg = strzone(panel_bg);
3513                         chat_panel_modified = true;
3514                 }
3515                 panel_bg_alpha = max(0.75, panel_bg_alpha); // force an theAlpha of at least 0.75
3516         }
3517
3518         vector pos, mySize;
3519         pos = panel_pos;
3520         mySize = panel_size;
3521
3522         HUD_Panel_DrawBg(1);
3523
3524         if(panel_bg_padding)
3525         {
3526                 pos += '1 1 0' * panel_bg_padding;
3527                 mySize -= '2 2 0' * panel_bg_padding;
3528         }
3529
3530         if (!autocvar_con_chatrect)
3531                 cvar_set("con_chatrect", "1");
3532
3533         cvar_set("con_chatrect_x", ftos(pos.x/vid_conwidth));
3534         cvar_set("con_chatrect_y", ftos(pos.y/vid_conheight));
3535
3536         cvar_set("con_chatwidth", ftos(mySize.x/vid_conwidth));
3537         cvar_set("con_chat", ftos(floor(mySize.y/autocvar_con_chatsize - 0.5)));
3538
3539         if(autocvar__hud_configure)
3540         {
3541                 vector chatsize;
3542                 chatsize = '1 1 0' * autocvar_con_chatsize;
3543                 cvar_set("con_chatrect_x", "9001"); // over 9000, we'll fake it instead for more control over theAlpha and such
3544                 float i, a;
3545                 for(i = 0; i < autocvar_con_chat; ++i)
3546                 {
3547                         if(i == autocvar_con_chat - 1)
3548                                 a = panel_fg_alpha;
3549                         else
3550                                 a = panel_fg_alpha * floor(((i + 1) * 7 + autocvar_con_chattime)/45);
3551                         drawcolorcodedstring(pos, textShortenToWidth(_("^3Player^7: This is the chat area."), mySize.x, chatsize, stringwidth_colors), chatsize, a, DRAWFLAG_NORMAL);
3552                         pos.y += chatsize.y;
3553                 }
3554         }
3555 }
3556
3557 // Engine info panel (#13)
3558 //
3559 float prevfps;
3560 float prevfps_time;
3561 float framecounter;
3562
3563 float frametimeavg;
3564 float frametimeavg1; // 1 frame ago
3565 float frametimeavg2; // 2 frames ago
3566 void HUD_EngineInfo(void)
3567 {
3568         if(!autocvar__hud_configure)
3569         {
3570                 if(!autocvar_hud_panel_engineinfo) return;
3571         }
3572
3573         HUD_Panel_UpdateCvars();
3574         vector pos, mySize;
3575         pos = panel_pos;
3576         mySize = panel_size;
3577
3578         HUD_Panel_DrawBg(1);
3579         if(panel_bg_padding)
3580         {
3581                 pos += '1 1 0' * panel_bg_padding;
3582                 mySize -= '2 2 0' * panel_bg_padding;
3583         }
3584
3585         float currentTime = gettime(GETTIME_REALTIME);
3586         if(cvar("hud_panel_engineinfo_framecounter_exponentialmovingaverage"))
3587         {
3588                 float currentframetime = currentTime - prevfps_time;
3589                 frametimeavg = (frametimeavg + frametimeavg1 + frametimeavg2 + currentframetime)/4; // average three frametimes into framecounter for slightly more stable fps readings :P
3590                 frametimeavg2 = frametimeavg1;
3591                 frametimeavg1 = frametimeavg;
3592
3593                 float weight;
3594                 weight = cvar("hud_panel_engineinfo_framecounter_exponentialmovingaverage_new_weight");
3595                 if(currentframetime > 0.0001) // filter out insane values which sometimes seem to occur and throw off the average? If you are getting 10,000 fps or more, then you don't need a framerate counter.
3596                 {
3597                         if(fabs(prevfps - (1/frametimeavg)) > prevfps * cvar("hud_panel_engineinfo_framecounter_exponentialmovingaverage_instantupdate_change_threshold")) // if there was a big jump in fps, just force prevfps at current (1/currentframetime) to make big updates instant
3598                                 prevfps = (1/currentframetime);
3599                         prevfps = (1 - weight) * prevfps + weight * (1/frametimeavg); // framecounter just used so there's no need for a new variable, think of it as "frametime average"
3600                 }
3601                 prevfps_time = currentTime;
3602         }
3603         else
3604         {
3605                 framecounter += 1;
3606                 if(currentTime - prevfps_time > autocvar_hud_panel_engineinfo_framecounter_time)
3607                 {
3608                         prevfps = framecounter/(currentTime - prevfps_time);
3609                         framecounter = 0;
3610                         prevfps_time = currentTime;
3611                 }
3612         }
3613
3614         vector color;
3615         color = HUD_Get_Num_Color (prevfps, 100);
3616         drawstring_aspect(pos, sprintf(_("FPS: %.*f"), autocvar_hud_panel_engineinfo_framecounter_decimals, prevfps), mySize, color, panel_fg_alpha, DRAWFLAG_NORMAL);
3617 }
3618
3619 // Info messages panel (#14)
3620 //
3621 #define drawInfoMessage(s) do {                                                                                                                                                                         \
3622         if(autocvar_hud_panel_infomessages_flip)                                                                                                                                                \
3623                 o.x = pos.x + mySize.x - stringwidth(s, true, fontsize);                                                                                                        \
3624         drawcolorcodedstring(o, s, fontsize, a, DRAWFLAG_NORMAL);                                                                                                               \
3625         o.y += fontsize.y;                                                                                                                                                                                              \
3626 } while(0)
3627 void HUD_InfoMessages(void)
3628 {
3629         if(!autocvar__hud_configure)
3630         {
3631                 if(!autocvar_hud_panel_infomessages) return;
3632         }
3633
3634         HUD_Panel_UpdateCvars();
3635         vector pos, mySize;
3636         pos = panel_pos;
3637         mySize = panel_size;
3638
3639         HUD_Panel_DrawBg(1);
3640         if(panel_bg_padding)
3641         {
3642                 pos += '1 1 0' * panel_bg_padding;
3643                 mySize -= '2 2 0' * panel_bg_padding;
3644         }
3645
3646         // always force 5:1 aspect
3647         vector newSize = '0 0 0';
3648         if(mySize.x/mySize.y > 5)
3649         {
3650                 newSize.x = 5 * mySize.y;
3651                 newSize.y = mySize.y;
3652
3653                 pos.x = pos.x + (mySize.x - newSize.x) / 2;
3654         }
3655         else
3656         {
3657                 newSize.y = 1/5 * mySize.x;
3658                 newSize.x = mySize.x;
3659
3660                 pos.y = pos.y + (mySize.y - newSize.y) / 2;
3661         }
3662
3663         mySize = newSize;
3664         entity tm;
3665         vector o;
3666         o = pos;
3667
3668         vector fontsize;
3669         fontsize = '0.20 0.20 0' * mySize.y;
3670
3671         float a;
3672         a = panel_fg_alpha;
3673
3674         string s;
3675         if(!autocvar__hud_configure)
3676         {
3677                 if(spectatee_status && !intermission)
3678                 {
3679                         a = 1;
3680                         if(spectatee_status == -1)
3681                                 s = _("^1Observing");
3682                         else
3683                                 s = sprintf(_("^1Spectating: ^7%s"), GetPlayerName(player_localentnum - 1));
3684                         drawInfoMessage(s);
3685
3686                         if(spectatee_status == -1)
3687                                 s = sprintf(_("^1Press ^3%s^1 to spectate"), getcommandkey("primary fire", "+fire"));
3688                         else
3689                                 s = sprintf(_("^1Press ^3%s^1 or ^3%s^1 for next or previous player"), getcommandkey("next weapon", "weapnext"), getcommandkey("previous weapon", "weapprev"));
3690                         drawInfoMessage(s);
3691
3692                         if(spectatee_status == -1)
3693                                 s = sprintf(_("^1Use ^3%s^1 or ^3%s^1 to change the speed"), getcommandkey("next weapon", "weapnext"), getcommandkey("previous weapon", "weapprev"));
3694                         else
3695                                 s = sprintf(_("^1Press ^3%s^1 to observe"), getcommandkey("secondary fire", "+fire2"));
3696                         drawInfoMessage(s);
3697
3698                         s = sprintf(_("^1Press ^3%s^1 for gamemode info"), getcommandkey("server info", "+show_info"));
3699                         drawInfoMessage(s);
3700
3701                         if(gametype == MAPINFO_TYPE_LMS)
3702                         {
3703                                 entity sk;
3704                                 sk = playerslots[player_localnum];
3705                                 if(sk.(scores[ps_primary]) >= 666)
3706                                         s = _("^1Match has already begun");
3707                                 else if(sk.(scores[ps_primary]) > 0)
3708                                         s = _("^1You have no more lives left");
3709                                 else
3710                                         s = sprintf(_("^1Press ^3%s^1 to join"), getcommandkey("jump", "+jump"));
3711                         }
3712                         else
3713                                 s = sprintf(_("^1Press ^3%s^1 to join"), getcommandkey("jump", "+jump"));
3714                         drawInfoMessage(s);
3715
3716                         //show restart countdown:
3717                         if (time < getstatf(STAT_GAMESTARTTIME)) {
3718                                 float countdown;
3719                                 //we need to ceil, otherwise the countdown would be off by .5 when using round()
3720                                 countdown = ceil(getstatf(STAT_GAMESTARTTIME) - time);
3721                                 s = sprintf(_("^1Game starts in ^3%d^1 seconds"), countdown);
3722                                 drawcolorcodedstring(o, s, fontsize, a, DRAWFLAG_NORMAL);
3723                                 o.y += fontsize.y;
3724                         }
3725                 }
3726                 if(warmup_stage && !intermission)
3727                 {
3728                         s = _("^2Currently in ^1warmup^2 stage!");
3729                         drawInfoMessage(s);
3730                 }
3731
3732                 string blinkcolor;
3733                 if(time % 1 >= 0.5)
3734                         blinkcolor = "^1";
3735                 else
3736                         blinkcolor = "^3";
3737
3738                 if(ready_waiting && !intermission && !spectatee_status)
3739                 {
3740                         if(ready_waiting_for_me)
3741                         {
3742                                 if(warmup_stage)
3743                                         s = sprintf(_("%sPress ^3%s%s to end warmup"), blinkcolor, getcommandkey("ready", "ready"), blinkcolor);
3744                                 else
3745                                         s = sprintf(_("%sPress ^3%s%s once you are ready"), blinkcolor, getcommandkey("ready", "ready"), blinkcolor);
3746                         }
3747                         else
3748                         {
3749                                 if(warmup_stage)
3750                                         s = _("^2Waiting for others to ready up to end warmup...");
3751                                 else
3752                                         s = _("^2Waiting for others to ready up...");
3753                         }
3754                         drawInfoMessage(s);
3755                 }
3756                 else if(warmup_stage && !intermission && !spectatee_status)
3757                 {
3758                         s = sprintf(_("^2Press ^3%s^2 to end warmup"), getcommandkey("ready", "ready"));
3759                         drawInfoMessage(s);
3760                 }
3761
3762                 if(teamplay && !intermission && !spectatee_status && gametype != MAPINFO_TYPE_CA && teamnagger)
3763                 {
3764                         float ts_min = 0, ts_max = 0;
3765                         tm = teams.sort_next;
3766                         if (tm)
3767                         {
3768                                 for (; tm.sort_next; tm = tm.sort_next)
3769                                 {
3770                                         if(!tm.team_size || tm.team == NUM_SPECTATOR)
3771                                                 continue;
3772                                         if(!ts_min) ts_min = tm.team_size;
3773                                         else ts_min = min(ts_min, tm.team_size);
3774                                         if(!ts_max) ts_max = tm.team_size;
3775                                         else ts_max = max(ts_max, tm.team_size);
3776                                 }
3777                                 if ((ts_max - ts_min) > 1)
3778                                 {
3779                                         s = strcat(blinkcolor, _("Teamnumbers are unbalanced!"));
3780                                         tm = GetTeam(myteam, false);
3781                                         if (tm)
3782                                         if (tm.team != NUM_SPECTATOR)
3783                                         if (tm.team_size == ts_max)
3784                                                 s = strcat(s, sprintf(_(" Press ^3%s%s to adjust"), getcommandkey("team menu", "menu_showteamselect"), blinkcolor));
3785                                         drawInfoMessage(s);
3786                                 }
3787                         }
3788                 }
3789         }
3790         else
3791         {
3792                 s = _("^7Press ^3ESC ^7to show HUD options.");
3793                 drawInfoMessage(s);
3794                 s = _("^3Doubleclick ^7a panel for panel-specific options.");
3795                 drawInfoMessage(s);
3796                 s = _("^3CTRL ^7to disable collision testing, ^3SHIFT ^7and");
3797                 drawInfoMessage(s);
3798                 s = _("^3ALT ^7+ ^3ARROW KEYS ^7for fine adjustments.");
3799                 drawInfoMessage(s);
3800         }
3801 }
3802
3803 // Physics panel (#15)
3804 //
3805 vector acc_prevspeed;
3806 float acc_prevtime, acc_avg, top_speed, top_speed_time;
3807 void HUD_Physics(void)
3808 {
3809         if(!autocvar__hud_configure)
3810         {
3811                 if(!autocvar_hud_panel_physics) return;
3812                 if(spectatee_status == -1 && (autocvar_hud_panel_physics == 1 || autocvar_hud_panel_physics == 3)) return;
3813                 if(autocvar_hud_panel_physics == 3 && !(gametype == MAPINFO_TYPE_RACE || gametype == MAPINFO_TYPE_CTS)) return;
3814         }
3815
3816         HUD_Panel_UpdateCvars();
3817
3818         draw_beginBoldFont();
3819
3820         HUD_Panel_DrawBg(1);
3821         if(panel_bg_padding)
3822         {
3823                 panel_pos += '1 1 0' * panel_bg_padding;
3824                 panel_size -= '2 2 0' * panel_bg_padding;
3825         }
3826
3827         float acceleration_progressbar_scale = 0;
3828         if(autocvar_hud_panel_physics_progressbar && autocvar_hud_panel_physics_acceleration_progressbar_scale > 1)
3829                 acceleration_progressbar_scale = autocvar_hud_panel_physics_acceleration_progressbar_scale;
3830
3831         float text_scale;
3832         if (autocvar_hud_panel_physics_text_scale <= 0)
3833                 text_scale = 1;
3834         else
3835                 text_scale = min(autocvar_hud_panel_physics_text_scale, 1);
3836
3837         //compute speed
3838         float speed, conversion_factor;
3839         string unit;
3840
3841         switch(autocvar_hud_panel_physics_speed_unit)
3842         {
3843                 default:
3844                 case 1:
3845                         unit = _(" qu/s");
3846                         conversion_factor = 1.0;
3847                         break;
3848                 case 2:
3849                         unit = _(" m/s");
3850                         conversion_factor = 0.0254;
3851                         break;
3852                 case 3:
3853                         unit = _(" km/h");
3854                         conversion_factor = 0.0254 * 3.6;
3855                         break;
3856                 case 4:
3857                         unit = _(" mph");
3858                         conversion_factor = 0.0254 * 3.6 * 0.6213711922;
3859                         break;
3860                 case 5:
3861                         unit = _(" knots");
3862                         conversion_factor = 0.0254 * 1.943844492; // 1 m/s = 1.943844492 knots, because 1 knot = 1.852 km/h
3863                         break;
3864         }
3865
3866         vector vel = (csqcplayer ? csqcplayer.velocity : pmove_vel);
3867
3868         float max_speed = floor( autocvar_hud_panel_physics_speed_max * conversion_factor + 0.5 );
3869         if (autocvar__hud_configure)
3870                 speed = floor( max_speed * 0.65 + 0.5 );
3871         else if(autocvar_hud_panel_physics_speed_vertical)
3872                 speed = floor( vlen(vel) * conversion_factor + 0.5 );
3873         else
3874                 speed = floor( vlen(vel - vel.z * '0 0 1') * conversion_factor + 0.5 );
3875
3876         //compute acceleration
3877         float acceleration, f;
3878         if (autocvar__hud_configure)
3879                 acceleration = autocvar_hud_panel_physics_acceleration_max * 0.3;
3880         else
3881         {
3882                 // 1 m/s = 0.0254 qu/s; 1 g = 9.80665 m/s^2
3883                 f = time - acc_prevtime;
3884                 if(autocvar_hud_panel_physics_acceleration_vertical)
3885                         acceleration = (vlen(vel) - vlen(acc_prevspeed));
3886                 else
3887                         acceleration = (vlen(vel - '0 0 1' * vel.z) - vlen(acc_prevspeed - '0 0 1' * acc_prevspeed.z));
3888
3889                 acceleration = acceleration * (1 / max(0.0001, f)) * (0.0254 / 9.80665);
3890
3891                 acc_prevspeed = vel;
3892                 acc_prevtime = time;
3893
3894                 f = bound(0, f * 10, 1);
3895                 acc_avg = acc_avg * (1 - f) + acceleration * f;
3896         }
3897
3898         //compute layout
3899         float panel_ar = panel_size.x/panel_size.y;
3900         vector speed_offset = '0 0 0', acceleration_offset = '0 0 0';
3901         if (panel_ar >= 5 && !acceleration_progressbar_scale)
3902         {
3903                 panel_size.x *= 0.5;
3904                 if (autocvar_hud_panel_physics_flip)
3905                         speed_offset.x = panel_size.x;
3906                 else
3907                         acceleration_offset.x = panel_size.x;
3908         }
3909         else
3910         {
3911                 panel_size.y *= 0.5;
3912                 if (autocvar_hud_panel_physics_flip)
3913                         speed_offset.y = panel_size.y;
3914                 else
3915                         acceleration_offset.y = panel_size.y;
3916         }
3917         float speed_baralign, acceleration_baralign;
3918         if (autocvar_hud_panel_physics_baralign == 1)
3919                 acceleration_baralign = speed_baralign = 1;
3920     else if(autocvar_hud_panel_physics_baralign == 4)
3921                 acceleration_baralign = speed_baralign = 2;
3922         else if (autocvar_hud_panel_physics_flip)
3923         {
3924                 acceleration_baralign = (autocvar_hud_panel_physics_baralign == 2);
3925                 speed_baralign = (autocvar_hud_panel_physics_baralign == 3);
3926         }
3927         else
3928         {
3929                 speed_baralign = (autocvar_hud_panel_physics_baralign == 2);
3930                 acceleration_baralign = (autocvar_hud_panel_physics_baralign == 3);
3931         }
3932         if (autocvar_hud_panel_physics_acceleration_progressbar_mode == 0)
3933                 acceleration_baralign = 3; //override hud_panel_physics_baralign value for acceleration
3934
3935         //draw speed
3936         if(speed)
3937         if(autocvar_hud_panel_physics_progressbar == 1 || autocvar_hud_panel_physics_progressbar == 2)
3938                 HUD_Panel_DrawProgressBar(panel_pos + speed_offset, panel_size, "progressbar", speed/max_speed, 0, speed_baralign, autocvar_hud_progressbar_speed_color, autocvar_hud_progressbar_alpha * panel_fg_alpha, DRAWFLAG_NORMAL);
3939         vector tmp_offset = '0 0 0', tmp_size = '0 0 0';
3940         if (autocvar_hud_panel_physics_text == 1 || autocvar_hud_panel_physics_text == 2)
3941         {
3942                 tmp_size.x = panel_size.x * 0.75;
3943                 tmp_size.y = panel_size.y * text_scale;
3944                 if (speed_baralign)
3945                         tmp_offset.x = panel_size.x - tmp_size.x;
3946                 //else
3947                         //tmp_offset_x = 0;
3948                 tmp_offset.y = (panel_size.y - tmp_size.y) / 2;
3949                 drawstring_aspect(panel_pos + speed_offset + tmp_offset, ftos(speed), tmp_size, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
3950
3951                 //draw speed unit
3952                 if (speed_baralign)
3953                         tmp_offset.x = 0;
3954                 else
3955                         tmp_offset.x = tmp_size.x;
3956                 if (autocvar_hud_panel_physics_speed_unit_show)
3957                 {
3958                         //tmp_offset_y = 0;
3959                         tmp_size.x = panel_size.x * (1 - 0.75);
3960                         tmp_size.y = panel_size.y * 0.4 * text_scale;
3961                         tmp_offset.y = (panel_size.y * 0.4 - tmp_size.y) / 2;
3962                         drawstring_aspect(panel_pos + speed_offset + tmp_offset, unit, tmp_size, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
3963                 }
3964         }
3965
3966         //compute and draw top speed
3967         if (autocvar_hud_panel_physics_topspeed)
3968         if (autocvar_hud_panel_physics_text == 1 || autocvar_hud_panel_physics_text == 2)
3969         {
3970                 if (autocvar__hud_configure)
3971                 {
3972                         top_speed = floor( max_speed * 0.75 + 0.5 );
3973                         f = 1;
3974                 }
3975                 else
3976                 {
3977                         if (speed >= top_speed)
3978                         {
3979                                 top_speed = speed;
3980                                 top_speed_time = time;
3981                         }
3982                         if (top_speed != 0)
3983                         {
3984                                 f = max(1, autocvar_hud_panel_physics_topspeed_time);
3985                                 // divide by f to make it start from 1
3986                                 f = cos( ((time - top_speed_time) / f) * PI/2 );
3987                         }
3988             else //hide top speed 0, it would be stupid
3989                                 f = 0;
3990                 }
3991                 if (f > 0)
3992                 {
3993                         //top speed progressbar peak
3994                         if(speed < top_speed)
3995                         if(autocvar_hud_panel_physics_progressbar == 1 || autocvar_hud_panel_physics_progressbar == 2)
3996                         {
3997                                 float peak_offsetX;
3998                                 vector peak_size = '0 0 0';
3999                                 if (speed_baralign == 0)
4000                                         peak_offsetX = min(top_speed, max_speed)/max_speed * panel_size.x;
4001                 else if (speed_baralign == 1)
4002                                         peak_offsetX = (1 - min(top_speed, max_speed)/max_speed) * panel_size.x;
4003                 else // if (speed_baralign == 2)
4004                     peak_offsetX = min(top_speed, max_speed)/max_speed * panel_size.x * 0.5;
4005                                 peak_size.x = floor(panel_size.x * 0.01 + 1.5);
4006                 peak_size.y = panel_size.y;
4007                 if (speed_baralign == 2) // draw two peaks, on both sides
4008                 {
4009                     drawfill(panel_pos + speed_offset + eX * (0.5 * panel_size.x + peak_offsetX - peak_size.x), peak_size, autocvar_hud_progressbar_speed_color, f * autocvar_hud_progressbar_alpha * panel_fg_alpha, DRAWFLAG_NORMAL);
4010                     drawfill(panel_pos + speed_offset + eX * (0.5 * panel_size.x - peak_offsetX + peak_size.x), peak_size, autocvar_hud_progressbar_speed_color, f * autocvar_hud_progressbar_alpha * panel_fg_alpha, DRAWFLAG_NORMAL);
4011                 }
4012                 else
4013                     drawfill(panel_pos + speed_offset + eX * (peak_offsetX - peak_size.x), peak_size, autocvar_hud_progressbar_speed_color, f * autocvar_hud_progressbar_alpha * panel_fg_alpha, DRAWFLAG_NORMAL);
4014                         }
4015
4016                         //top speed
4017                         tmp_offset.y = panel_size.y * 0.4;
4018                         tmp_size.x = panel_size.x * (1 - 0.75);
4019                         tmp_size.y = (panel_size.y - tmp_offset.y) * text_scale;
4020                         tmp_offset.y += (panel_size.y - tmp_offset.y - tmp_size.y) / 2;
4021                         drawstring_aspect(panel_pos + speed_offset + tmp_offset, ftos(top_speed), tmp_size, '1 0 0', f * panel_fg_alpha, DRAWFLAG_NORMAL);
4022                 }
4023                 else
4024                         top_speed = 0;
4025         }
4026
4027         //draw acceleration
4028         if(acceleration)
4029         if(autocvar_hud_panel_physics_progressbar == 1 || autocvar_hud_panel_physics_progressbar == 3)
4030         {
4031                 vector progressbar_color;
4032                 if(acceleration < 0)
4033                         progressbar_color = autocvar_hud_progressbar_acceleration_neg_color;
4034                 else
4035                         progressbar_color = autocvar_hud_progressbar_acceleration_color;
4036
4037                 f = acceleration/autocvar_hud_panel_physics_acceleration_max;
4038                 if (autocvar_hud_panel_physics_acceleration_progressbar_nonlinear)
4039                         f = sqrt(f);
4040
4041                 if (acceleration_progressbar_scale) // allow progressbar to go out of panel bounds
4042                 {
4043                         tmp_size = acceleration_progressbar_scale * panel_size.x * eX + panel_size.y * eY;
4044
4045                         if (acceleration_baralign == 1)
4046                                 tmp_offset.x = panel_size.x - tmp_size.x;
4047                         else if (acceleration_baralign == 2 || acceleration_baralign == 3)
4048                                 tmp_offset.x = (panel_size.x - tmp_size.x) / 2;
4049                         else
4050                                 tmp_offset.x = 0;
4051                         tmp_offset.y = 0;
4052                 }
4053                 else
4054                 {
4055                         tmp_size = panel_size;
4056                         tmp_offset = '0 0 0';
4057                 }
4058
4059                 HUD_Panel_DrawProgressBar(panel_pos + acceleration_offset + tmp_offset, tmp_size, "accelbar", f, 0, acceleration_baralign, progressbar_color, autocvar_hud_progressbar_alpha * panel_fg_alpha, DRAWFLAG_NORMAL);
4060         }
4061         tmp_size.x = panel_size.x;
4062         tmp_size.y = panel_size.y * text_scale;
4063         tmp_offset.x = 0;
4064         tmp_offset.y = (panel_size.y - tmp_size.y) / 2;
4065         if (autocvar_hud_panel_physics_text == 1 || autocvar_hud_panel_physics_text == 3)
4066                 drawstring_aspect(panel_pos + acceleration_offset + tmp_offset, strcat(ftos_decimals(acceleration, 2), "g"), tmp_size, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
4067
4068         draw_endBoldFont();
4069 }
4070
4071 // CenterPrint (#16)
4072 //
4073 const float CENTERPRINT_MAX_MSGS = 10;
4074 const float CENTERPRINT_MAX_ENTRIES = 50;
4075 const float CENTERPRINT_SPACING = 0.7;
4076 float cpm_index;
4077 string centerprint_messages[CENTERPRINT_MAX_MSGS];
4078 float centerprint_msgID[CENTERPRINT_MAX_MSGS];
4079 float centerprint_time[CENTERPRINT_MAX_MSGS];
4080 float centerprint_expire_time[CENTERPRINT_MAX_MSGS];
4081 float centerprint_countdown_num[CENTERPRINT_MAX_MSGS];
4082 float centerprint_showing;
4083
4084 void centerprint_generic(float new_id, string strMessage, float duration, float countdown_num)
4085 {
4086         //printf("centerprint_generic(%d, '%s^7', %d, %d);\n", new_id, strMessage, duration, countdown_num);
4087         float i, j;
4088
4089         if(strMessage == "" && new_id == 0)
4090                 return;
4091
4092         // strip trailing newlines
4093         j = strlen(strMessage) - 1;
4094         while(substring(strMessage, j, 1) == "\n" && j >= 0)
4095                 --j;
4096         if (j < strlen(strMessage) - 1)
4097                 strMessage = substring(strMessage, 0, j + 1);
4098
4099         if(strMessage == "" && new_id == 0)
4100                 return;
4101
4102         // strip leading newlines
4103         j = 0;
4104         while(substring(strMessage, j, 1) == "\n" && j < strlen(strMessage))
4105                 ++j;
4106         if (j > 0)
4107                 strMessage = substring(strMessage, j, strlen(strMessage) - j);
4108
4109         if(strMessage == "" && new_id == 0)
4110                 return;
4111
4112         if (!centerprint_showing)
4113                 centerprint_showing = true;
4114
4115         for (i=0, j=cpm_index; i<CENTERPRINT_MAX_MSGS; ++i, ++j)
4116         {
4117                 if (j == CENTERPRINT_MAX_MSGS)
4118                         j = 0;
4119                 if (new_id && new_id == centerprint_msgID[j])
4120                 {
4121                         if (strMessage == "" && centerprint_messages[j] != "" && centerprint_countdown_num[j] == 0)
4122                         {
4123                                 // fade out the current msg (duration and countdown_num are ignored)
4124                                 centerprint_time[j] = min(5, autocvar_hud_panel_centerprint_fade_out);
4125                                 if (centerprint_expire_time[j] > time + min(5, autocvar_hud_panel_centerprint_fade_out) || centerprint_expire_time[j] < time)
4126                                         centerprint_expire_time[j] = time + min(5, autocvar_hud_panel_centerprint_fade_out);
4127                                 return;
4128                         }
4129                         break; // found a msg with the same id, at position j
4130                 }
4131         }
4132
4133         if (i == CENTERPRINT_MAX_MSGS)
4134         {
4135                 // a msg with the same id was not found, add the msg at the next position
4136                 --cpm_index;
4137                 if (cpm_index == -1)
4138                         cpm_index = CENTERPRINT_MAX_MSGS - 1;
4139                 j = cpm_index;
4140         }
4141         if(centerprint_messages[j])
4142                 strunzone(centerprint_messages[j]);
4143         centerprint_messages[j] = strzone(strMessage);
4144         centerprint_msgID[j] = new_id;
4145         if (duration < 0)
4146         {
4147                 centerprint_time[j] = -1;
4148                 centerprint_expire_time[j] = time;
4149         }
4150         else
4151         {
4152                 if(duration == 0)
4153                         duration = max(1, autocvar_hud_panel_centerprint_time);
4154                 centerprint_time[j] = duration;
4155                 centerprint_expire_time[j] = time + duration;
4156         }
4157         centerprint_countdown_num[j] = countdown_num;
4158 }
4159
4160 void centerprint_hud(string strMessage)
4161 {
4162         centerprint_generic(0, strMessage, autocvar_hud_panel_centerprint_time, 0);
4163 }
4164
4165 void reset_centerprint_messages(void)
4166 {
4167         float i;
4168         for (i=0; i<CENTERPRINT_MAX_MSGS; ++i)
4169         {
4170                 centerprint_expire_time[i] = 0;
4171                 centerprint_time[i] = 1;
4172                 centerprint_msgID[i] = 0;
4173                 if(centerprint_messages[i])
4174                         strunzone(centerprint_messages[i]);
4175                 centerprint_messages[i] = string_null;
4176         }
4177 }
4178 float hud_configure_cp_generation_time;
4179 void HUD_CenterPrint (void)
4180 {
4181         if(!autocvar__hud_configure)
4182         {
4183                 if(!autocvar_hud_panel_centerprint) return;
4184
4185                 if (hud_configure_prev && hud_configure_prev != -1)
4186                         reset_centerprint_messages();
4187         }
4188         else
4189         {
4190                 if (!hud_configure_prev)
4191                         reset_centerprint_messages();
4192                 if (time > hud_configure_cp_generation_time)
4193                 {
4194                         float r;
4195                         r = random();
4196                         if (r > 0.75)
4197                                 centerprint_generic(floor(r*1000), strcat(sprintf("^3Countdown message at time %s", seconds_tostring(time)), ", seconds left: ^COUNT"), 1, 10);
4198                         else if (r > 0.5)
4199                                 centerprint_generic(0, sprintf("^1Multiline message at time %s that\n^1lasts longer than normal", seconds_tostring(time)), 20, 0);
4200                         else
4201                                 centerprint_hud(sprintf("Message at time %s", seconds_tostring(time)));
4202                         hud_configure_cp_generation_time = time + 1 + random()*4;
4203                 }
4204         }
4205
4206         // this panel fades only when the menu does
4207         float hud_fade_alpha_save = 0;
4208         if(scoreboard_fade_alpha)
4209         {
4210                 hud_fade_alpha_save = hud_fade_alpha;
4211                 hud_fade_alpha = 1 - autocvar__menu_alpha;
4212         }
4213         HUD_Panel_UpdateCvars();
4214
4215         if(scoreboard_fade_alpha)
4216         {
4217                 hud_fade_alpha = hud_fade_alpha_save;
4218
4219                 // move the panel below the scoreboard
4220                 if (scoreboard_bottom >= 0.96 * vid_conheight)
4221                         return;
4222                 vector target_pos;
4223
4224                 target_pos = eY * scoreboard_bottom + eX * 0.5 * (vid_conwidth - panel_size.x);
4225
4226                 if(target_pos.y > panel_pos.y)
4227                 {
4228                         panel_pos = panel_pos + (target_pos - panel_pos) * sqrt(scoreboard_fade_alpha);
4229                         panel_size.y = min(panel_size.y, vid_conheight - scoreboard_bottom);
4230                 }
4231         }
4232
4233         HUD_Panel_DrawBg(1);
4234
4235         if (!centerprint_showing)
4236                 return;
4237
4238         if(panel_bg_padding)
4239         {
4240                 panel_pos += '1 1 0' * panel_bg_padding;
4241                 panel_size -= '2 2 0' * panel_bg_padding;
4242         }
4243
4244         float entries, height;
4245         vector fontsize;
4246         // entries = bound(1, floor(CENTERPRINT_MAX_ENTRIES * 4 * panel_size_y/panel_size_x), CENTERPRINT_MAX_ENTRIES);
4247         // height = panel_size_y/entries;
4248         // fontsize = '1 1 0' * height;
4249         height = vid_conheight/50 * autocvar_hud_panel_centerprint_fontscale;
4250         fontsize = '1 1 0' * height;
4251         entries = bound(1, floor(panel_size.y/height), CENTERPRINT_MAX_ENTRIES);
4252
4253         float i, j, k, n, g;
4254         float a, sz, align, current_msg_posY = 0, msg_size;
4255         vector pos;
4256         string ts;
4257         float all_messages_expired = true;
4258
4259         pos = panel_pos;
4260         if (autocvar_hud_panel_centerprint_flip)
4261                 pos.y += panel_size.y;
4262         align = bound(0, autocvar_hud_panel_centerprint_align, 1);
4263         for (g=0, i=0, j=cpm_index; i<CENTERPRINT_MAX_MSGS; ++i, ++j)
4264         {
4265                 if (j == CENTERPRINT_MAX_MSGS)
4266                         j = 0;
4267                 if (centerprint_expire_time[j] <= time)
4268                 {
4269                         if (centerprint_countdown_num[j] && centerprint_time[j] > 0)
4270                         {
4271                                 centerprint_countdown_num[j] = centerprint_countdown_num[j] - 1;
4272                                 if (centerprint_countdown_num[j] == 0)
4273                                         continue;
4274                                 centerprint_expire_time[j] = centerprint_expire_time[j] + centerprint_time[j];
4275                         }
4276                         else if(centerprint_time[j] != -1)
4277                                 continue;
4278                 }
4279
4280                 all_messages_expired = false;
4281
4282                 // fade the centerprint_hud in/out
4283                 if(centerprint_time[j] < 0)  // Expired but forced. Expire time is the fade-in time.
4284                         a = (time - centerprint_expire_time[j]) / max(0.0001, autocvar_hud_panel_centerprint_fade_in);
4285                 else if(centerprint_expire_time[j] - autocvar_hud_panel_centerprint_fade_out > time)  // Regularily printed. Not fading out yet.
4286                         a = (time - (centerprint_expire_time[j] - centerprint_time[j])) / max(0.0001, autocvar_hud_panel_centerprint_fade_in);
4287                 else // Expiring soon, so fade it out.
4288                         a = (centerprint_expire_time[j] - time) / max(0.0001, autocvar_hud_panel_centerprint_fade_out);
4289
4290                 // while counting down show it anyway in order to hold the current message position
4291                 if (a <= 0.5/255.0 && centerprint_countdown_num[j] == 0)  // Guaranteed invisible - don't show.
4292                         continue;
4293                 if (a > 1)
4294                         a = 1;
4295
4296                 // set the size from fading in/out before subsequent fading
4297                 sz = autocvar_hud_panel_centerprint_fade_minfontsize + a * (1 - autocvar_hud_panel_centerprint_fade_minfontsize);
4298
4299                 // also fade it based on positioning
4300                 if(autocvar_hud_panel_centerprint_fade_subsequent)
4301                 {
4302                         a = a * bound(autocvar_hud_panel_centerprint_fade_subsequent_passone_minalpha, (1 - (g / max(1, autocvar_hud_panel_centerprint_fade_subsequent_passone))), 1); // pass one: all messages after the first have half theAlpha
4303                         a = a * bound(autocvar_hud_panel_centerprint_fade_subsequent_passtwo_minalpha, (1 - (g / max(1, autocvar_hud_panel_centerprint_fade_subsequent_passtwo))), 1); // pass two: after that, gradually lower theAlpha even more for each message
4304                 }
4305                 a *= panel_fg_alpha;
4306
4307                 // finally set the size based on the new theAlpha from subsequent fading
4308                 sz = sz * (autocvar_hud_panel_centerprint_fade_subsequent_minfontsize + a * (1 - autocvar_hud_panel_centerprint_fade_subsequent_minfontsize));
4309                 drawfontscale = sz * '1 1 0';
4310
4311                 if (centerprint_countdown_num[j])
4312                         n = tokenizebyseparator(strreplace("^COUNT", count_seconds(centerprint_countdown_num[j]), centerprint_messages[j]), "\n");
4313                 else
4314                         n = tokenizebyseparator(centerprint_messages[j], "\n");
4315
4316                 if (autocvar_hud_panel_centerprint_flip)
4317                 {
4318                         // check if the message can be entirely shown
4319                         for(k = 0; k < n; ++k)
4320                         {
4321                                 getWrappedLine_remaining = argv(k);
4322                                 while(getWrappedLine_remaining)
4323                                 {
4324                                         ts = getWrappedLine(panel_size.x * sz, fontsize, stringwidth_colors);
4325                                         if (ts != "")
4326                                                 pos.y -= fontsize.y;
4327                                         else
4328                                                 pos.y -= fontsize.y * CENTERPRINT_SPACING/2;
4329                                 }
4330                         }
4331                         current_msg_posY = pos.y; // save starting pos (first line) of the current message
4332                 }
4333
4334                 msg_size = pos.y;
4335                 for(k = 0; k < n; ++k)
4336                 {
4337                         getWrappedLine_remaining = argv(k);
4338                         while(getWrappedLine_remaining)
4339                         {
4340                                 ts = getWrappedLine(panel_size.x * sz, fontsize, stringwidth_colors);
4341                                 if (ts != "")
4342                                 {
4343                                         if (align)
4344                                                 pos.x = panel_pos.x + (panel_size.x - stringwidth(ts, true, fontsize)) * align;
4345                                         if (a > 0.5/255.0)  // Otherwise guaranteed invisible - don't show. This is checked a second time after some multiplications with other factors were done so temporary changes of these cannot cause flicker.
4346                                                 drawcolorcodedstring(pos + eY * 0.5 * (1 - sz) * fontsize.y, ts, fontsize, a, DRAWFLAG_NORMAL);
4347                                         pos.y += fontsize.y;
4348                                 }
4349                                 else
4350                                         pos.y += fontsize.y * CENTERPRINT_SPACING/2;
4351                         }
4352                 }
4353
4354                 ++g; // move next position number up
4355
4356                 msg_size = pos.y - msg_size;
4357                 if (autocvar_hud_panel_centerprint_flip)
4358                 {
4359                         pos.y = current_msg_posY - CENTERPRINT_SPACING * fontsize.y;
4360                         if (a < 1 && centerprint_msgID[j] == 0) // messages with id can be replaced just after they are faded out, so never move over them the next messages
4361                                 pos.y += (msg_size + CENTERPRINT_SPACING * fontsize.y) * (1 - sqrt(sz));
4362
4363                         if (pos.y < panel_pos.y) // check if the next message can be shown
4364                         {
4365                                 drawfontscale = '1 1 0';
4366                                 return;
4367                         }
4368                 }
4369                 else
4370                 {
4371                         pos.y += CENTERPRINT_SPACING * fontsize.y;
4372                         if (a < 1 && centerprint_msgID[j] == 0) // messages with id can be replaced just after they are faded out, so never move over them the next messages
4373                                 pos.y -= (msg_size + CENTERPRINT_SPACING * fontsize.y) * (1 - sqrt(sz));
4374
4375                         if(pos.y > panel_pos.y + panel_size.y - fontsize.y) // check if the next message can be shown
4376                         {
4377                                 drawfontscale = '1 1 0';
4378                                 return;
4379                         }
4380                 }
4381         }
4382         drawfontscale = '1 1 0';
4383         if (all_messages_expired)
4384         {
4385                 centerprint_showing = false;
4386                 reset_centerprint_messages();
4387         }
4388 }
4389
4390 // Buffs (#18)
4391 //
4392 void HUD_Buffs(void)
4393 {
4394         float buffs = getstati(STAT_BUFFS, 0, 24);
4395         if(!autocvar__hud_configure)
4396         {
4397                 if(!autocvar_hud_panel_buffs) return;
4398                 if(spectatee_status == -1) return;
4399                 if(getstati(STAT_HEALTH) <= 0) return;
4400                 if(!buffs) return;
4401         }
4402         else
4403         {
4404                 buffs = Buff_Type_first.items; // force first buff
4405         }
4406
4407         float b = 0; // counter to tell other functions that we have buffs
4408         entity e;
4409         string s = "";
4410         for(e = Buff_Type_first; e; e = e.enemy) if(buffs & e.items)
4411         {
4412                 ++b;
4413                 string o = strcat(rgb_to_hexcolor(Buff_Color(e.items)), Buff_PrettyName(e.items));
4414                 if(s == "")
4415                         s = o;
4416                 else
4417                         s = strcat(s, " ", o);
4418         }
4419
4420         HUD_Panel_UpdateCvars();
4421
4422         draw_beginBoldFont();
4423
4424         vector pos, mySize;
4425         pos = panel_pos;
4426         mySize = panel_size;
4427
4428         HUD_Panel_DrawBg(bound(0, b, 1));
4429         if(panel_bg_padding)
4430         {
4431                 pos += '1 1 0' * panel_bg_padding;
4432                 mySize -= '2 2 0' * panel_bg_padding;
4433         }
4434
4435         //float panel_ar = mySize_x/mySize_y;
4436         //float is_vertical = (panel_ar < 1);
4437         //float buff_iconalign = autocvar_hud_panel_buffs_iconalign;
4438         vector buff_offset = '0 0 0';
4439
4440         for(e = Buff_Type_first; e; e = e.enemy) if(buffs & e.items)
4441         {
4442                 //DrawNumIcon(pos + buff_offset, mySize, shield, "shield", is_vertical, buff_iconalign, '1 1 1', 1);
4443                 drawcolorcodedstring_aspect(pos + buff_offset, s, mySize, panel_fg_alpha * 0.5, DRAWFLAG_NORMAL);
4444         }
4445
4446         draw_endBoldFont();
4447 }
4448
4449
4450 // Minigame
4451 //
4452 #include "../common/minigames/cl_minigames_hud.qc"
4453
4454 /*
4455 ==================
4456 Main HUD system
4457 ==================
4458 */
4459
4460 bool HUD_Panel_CheckFlags(int showflags)
4461 {
4462         if ( HUD_Minigame_Showpanels() )
4463                 return showflags & PANEL_SHOW_MINIGAME;
4464         return showflags & PANEL_SHOW_MAINGAME;
4465 }
4466
4467 void HUD_Panel_Draw(entity panent)
4468 {
4469         panel = panent;
4470         if ( HUD_Panel_CheckFlags(panel.panel_showflags) )
4471                 panel.panel_draw();
4472 }
4473
4474 void HUD_Reset (void)
4475 {
4476         // reset gametype specific icons
4477         if(gametype == MAPINFO_TYPE_CTF)
4478                 HUD_Mod_CTF_Reset();
4479 }
4480
4481 void HUD_Main (void)
4482 {
4483         int i;
4484         // global hud theAlpha fade
4485         if(menu_enabled == 1)
4486                 hud_fade_alpha = 1;
4487         else
4488                 hud_fade_alpha = (1 - autocvar__menu_alpha);
4489
4490         if(scoreboard_fade_alpha)
4491                 hud_fade_alpha = (1 - scoreboard_fade_alpha);
4492
4493         HUD_Configure_Frame();
4494
4495         if(intermission == 2) // no hud during mapvote
4496                 hud_fade_alpha = 0;
4497
4498         // panels that we want to be active together with the scoreboard
4499         // they must fade only when the menu does
4500         if(scoreboard_fade_alpha == 1)
4501         {
4502                 HUD_Panel_Draw(HUD_PANEL(CENTERPRINT));
4503                 return;
4504         }
4505
4506         if(!autocvar__hud_configure && !hud_fade_alpha)
4507         {
4508                 hud_fade_alpha = 1;
4509                 HUD_Panel_Draw(HUD_PANEL(VOTE));
4510                 hud_fade_alpha = 0;
4511                 return;
4512         }
4513
4514         // Drawing stuff
4515         if (hud_skin_prev != autocvar_hud_skin)
4516         {
4517                 if (hud_skin_path)
4518                         strunzone(hud_skin_path);
4519                 hud_skin_path = strzone(strcat("gfx/hud/", autocvar_hud_skin));
4520                 if (hud_skin_prev)
4521                         strunzone(hud_skin_prev);
4522                 hud_skin_prev = strzone(autocvar_hud_skin);
4523         }
4524
4525     current_player = player_localentnum;
4526
4527         // draw the dock
4528         if(autocvar_hud_dock != "" && autocvar_hud_dock != "0")
4529         {
4530                 float f;
4531                 vector color;
4532                 float hud_dock_color_team = autocvar_hud_dock_color_team;
4533                 if((teamplay) && hud_dock_color_team) {
4534                         if(autocvar__hud_configure && myteam == NUM_SPECTATOR)
4535                                 color = '1 0 0' * hud_dock_color_team;
4536                         else
4537                                 color = myteamcolors * hud_dock_color_team;
4538                 }
4539                 else if(autocvar_hud_configure_teamcolorforced && autocvar__hud_configure && hud_dock_color_team) {
4540                         color = '1 0 0' * hud_dock_color_team;
4541                 }
4542                 else
4543                 {
4544                         string hud_dock_color = autocvar_hud_dock_color;
4545                         if(hud_dock_color == "shirt") {
4546                                 f = stof(getplayerkeyvalue(current_player - 1, "colors"));
4547                                 color = colormapPaletteColor(floor(f / 16), 0);
4548                         }
4549                         else if(hud_dock_color == "pants") {
4550                                 f = stof(getplayerkeyvalue(current_player - 1, "colors"));
4551                                 color = colormapPaletteColor(f % 16, 1);
4552                         }
4553                         else
4554                                 color = stov(hud_dock_color);
4555                 }
4556
4557                 string pic;
4558                 pic = strcat(hud_skin_path, "/", autocvar_hud_dock);
4559                 if(precache_pic(pic) == "") {
4560                         pic = strcat(hud_skin_path, "/dock_medium");
4561                         if(precache_pic(pic) == "") {
4562                                 pic = "gfx/hud/default/dock_medium";
4563                         }
4564                 }
4565                 drawpic('0 0 0', pic, eX * vid_conwidth + eY * vid_conheight, color, autocvar_hud_dock_alpha * hud_fade_alpha, DRAWFLAG_NORMAL); // no aspect ratio forcing on dock...
4566         }
4567
4568         // cache the panel order into the panel_order array
4569         if(autocvar__hud_panelorder != hud_panelorder_prev) {
4570                 for(i = 0; i < HUD_PANEL_NUM; ++i)
4571                         panel_order[i] = -1;
4572                 string s = "";
4573                 float p_num, warning = false;
4574                 float argc = tokenize_console(autocvar__hud_panelorder);
4575                 if (argc > HUD_PANEL_NUM)
4576                         warning = true;
4577                 //first detect wrong/missing panel numbers
4578                 for(i = 0; i < HUD_PANEL_NUM; ++i) {
4579                         p_num = stof(argv(i));
4580                         if (p_num >= 0 && p_num < HUD_PANEL_NUM) { //correct panel number?
4581                                 if (panel_order[p_num] == -1) //found for the first time?
4582                                         s = strcat(s, ftos(p_num), " ");
4583                                 panel_order[p_num] = 1; //mark as found
4584                         }
4585                         else
4586                                 warning = true;
4587                 }
4588                 for(i = 0; i < HUD_PANEL_NUM; ++i) {
4589                         if (panel_order[i] == -1) {
4590                                 warning = true;
4591                                 s = strcat(s, ftos(i), " "); //add missing panel number
4592                         }
4593                 }
4594                 if (warning)
4595                         dprint("Automatically fixed wrong/missing panel numbers in _hud_panelorder\n");
4596
4597                 cvar_set("_hud_panelorder", s);
4598                 if(hud_panelorder_prev)
4599                         strunzone(hud_panelorder_prev);
4600                 hud_panelorder_prev = strzone(s);
4601
4602                 //now properly set panel_order
4603                 tokenize_console(s);
4604                 for(i = 0; i < HUD_PANEL_NUM; ++i) {
4605                         panel_order[i] = stof(argv(i));
4606                 }
4607         }
4608
4609         hud_draw_maximized = 0;
4610         // draw panels in order specified by panel_order array
4611         for(i = HUD_PANEL_NUM - 1; i >= 0; --i)
4612                 HUD_Panel_Draw(hud_panel[panel_order[i]]);
4613
4614         hud_draw_maximized = 1; // panels that may be maximized must check this var
4615         // draw maximized panels on top
4616         if(hud_panel_radar_maximized)
4617                 HUD_Panel_Draw(HUD_PANEL(RADAR));
4618         if(autocvar__con_chat_maximized)
4619                 HUD_Panel_Draw(HUD_PANEL(CHAT));
4620
4621         HUD_Configure_PostDraw();
4622
4623         hud_configure_prev = autocvar__hud_configure;
4624 }