qcsrc/client/hud/hud_config.qc

   1 #include "hud_config.qh"
   2
   3 #include "hud.qh"
   4 #include "panel/scoreboard.qh"
   5
   6 #define HUD_Write(s) fputs(fh, s)
   7 #define HUD_Write_Cvar(cvar) HUD_Write(strcat("seta ", cvar, " \"", cvar_string(cvar), "\"\n"))
   8 #define HUD_Write_PanelCvar(cvar_suf) HUD_Write_Cvar(strcat("hud_panel_", panel.panel_name, cvar_suf))
   9 // Save the config
  10 void HUD_Panel_ExportCfg(string cfgname)
  11 {
  12         float fh;
  13         string filename = strcat("hud_", autocvar_hud_skin, "_", cfgname, ".cfg");
  14         fh = fopen(filename, FILE_WRITE);
  15         if(fh >= 0)
  16         {
  17                 HUD_Write("//title \n");
  18                 HUD_Write("//author \n");
  19                 HUD_Write("\n");
  20                 HUD_Write_Cvar("hud_skin");
  21                 HUD_Write_Cvar("hud_panel_bg");
  22                 HUD_Write_Cvar("hud_panel_bg_color");
  23                 HUD_Write_Cvar("hud_panel_bg_color_team");
  24                 HUD_Write_Cvar("hud_panel_bg_alpha");
  25                 HUD_Write_Cvar("hud_panel_bg_border");
  26                 HUD_Write_Cvar("hud_panel_bg_padding");
  27                 HUD_Write_Cvar("hud_panel_fg_alpha");
  28                 HUD_Write("\n");
  29
  30                 HUD_Write_Cvar("hud_dock");
  31                 HUD_Write_Cvar("hud_dock_color");
  32                 HUD_Write_Cvar("hud_dock_color_team");
  33                 HUD_Write_Cvar("hud_dock_alpha");
  34                 HUD_Write("\n");
  35
  36                 HUD_Write_Cvar("hud_progressbar_alpha");
  37                 HUD_Write_Cvar("hud_progressbar_strength_color");
  38                 HUD_Write_Cvar("hud_progressbar_superweapons_color");
  39                 HUD_Write_Cvar("hud_progressbar_shield_color");
  40                 HUD_Write_Cvar("hud_progressbar_health_color");
  41                 HUD_Write_Cvar("hud_progressbar_armor_color");
  42                 HUD_Write_Cvar("hud_progressbar_fuel_color");
  43                 HUD_Write_Cvar("hud_progressbar_nexball_color");
  44                 HUD_Write_Cvar("hud_progressbar_speed_color");
  45                 HUD_Write_Cvar("hud_progressbar_acceleration_color");
  46                 HUD_Write_Cvar("hud_progressbar_acceleration_neg_color");
  47                 HUD_Write_Cvar("hud_progressbar_vehicles_ammo1_color");
  48                 HUD_Write_Cvar("hud_progressbar_vehicles_ammo2_color");
  49                 HUD_Write("\n");
  50
  51                 HUD_Write_Cvar("_hud_panelorder");
  52                 HUD_Write("\n");
  53
  54                 HUD_Write_Cvar("hud_configure_grid");
  55                 HUD_Write_Cvar("hud_configure_grid_xsize");
  56                 HUD_Write_Cvar("hud_configure_grid_ysize");
  57                 HUD_Write("\n");
  58
  59                 // common cvars for all panels
  60                 for (int i = 0; i < hud_panels_COUNT; ++i)
  61                 {
  62                         panel = hud_panels_from(i);
  63
  64                         HUD_Write_PanelCvar("_pos");
  65                         HUD_Write_PanelCvar("_size");
  66                         HUD_Write_PanelCvar("_bg");
  67                         HUD_Write_PanelCvar("_bg_color");
  68                         HUD_Write_PanelCvar("_bg_color_team");
  69                         HUD_Write_PanelCvar("_bg_alpha");
  70                         HUD_Write_PanelCvar("_bg_border");
  71                         HUD_Write_PanelCvar("_bg_padding");
  72                         switch(panel) {
  73                                 case HUD_PANEL_WEAPONS:
  74                                         HUD_Write_PanelCvar("_accuracy");
  75                                         HUD_Write_PanelCvar("_label");
  76                                         HUD_Write_PanelCvar("_label_scale");
  77                                         HUD_Write_PanelCvar("_complainbubble");
  78                                         HUD_Write_PanelCvar("_complainbubble_padding");
  79                                         HUD_Write_PanelCvar("_complainbubble_time");
  80                                         HUD_Write_PanelCvar("_complainbubble_fadetime");
  81                                         HUD_Write_PanelCvar("_complainbubble_color_outofammo");
  82                                         HUD_Write_PanelCvar("_complainbubble_color_donthave");
  83                                         HUD_Write_PanelCvar("_complainbubble_color_unavailable");
  84                                         HUD_Write_PanelCvar("_ammo");
  85                                         HUD_Write_PanelCvar("_ammo_color");
  86                                         HUD_Write_PanelCvar("_ammo_alpha");
  87                                         HUD_Write_PanelCvar("_aspect");
  88                                         HUD_Write_PanelCvar("_timeout");
  89                                         HUD_Write_PanelCvar("_timeout_effect");
  90                                         HUD_Write_PanelCvar("_timeout_fadebgmin");
  91                                         HUD_Write_PanelCvar("_timeout_fadefgmin");
  92                                         HUD_Write_PanelCvar("_timeout_speed_in");
  93                                         HUD_Write_PanelCvar("_timeout_speed_out");
  94                                         HUD_Write_PanelCvar("_onlyowned");
  95                                         HUD_Write_PanelCvar("_noncurrent_alpha");
  96                                         HUD_Write_PanelCvar("_noncurrent_scale");
  97                                         break;
  98                                 case HUD_PANEL_AMMO:
  99                                         HUD_Write_PanelCvar("_onlycurrent");
 100                                         HUD_Write_PanelCvar("_noncurrent_alpha");
 101                                         HUD_Write_PanelCvar("_noncurrent_scale");
 102                                         HUD_Write_PanelCvar("_iconalign");
 103                                         HUD_Write_PanelCvar("_progressbar");
 104                                         HUD_Write_PanelCvar("_progressbar_name");
 105                                         HUD_Write_PanelCvar("_progressbar_xoffset");
 106                                         HUD_Write_PanelCvar("_text");
 107                                         break;
 108                                 case HUD_PANEL_POWERUPS:
 109                                         HUD_Write_PanelCvar("_iconalign");
 110                                         HUD_Write_PanelCvar("_baralign");
 111                                         HUD_Write_PanelCvar("_progressbar");
 112                                         HUD_Write_PanelCvar("_text");
 113                                         break;
 114                                 case HUD_PANEL_HEALTHARMOR:
 115                                         HUD_Write_PanelCvar("_flip");
 116                                         HUD_Write_PanelCvar("_iconalign");
 117                                         HUD_Write_PanelCvar("_baralign");
 118                                         HUD_Write_PanelCvar("_progressbar");
 119                                         HUD_Write_PanelCvar("_progressbar_health");
 120                                         HUD_Write_PanelCvar("_progressbar_armor");
 121                                         HUD_Write_PanelCvar("_progressbar_gfx");
 122                                         HUD_Write_PanelCvar("_progressbar_gfx_smooth");
 123                                         HUD_Write_PanelCvar("_combined");
 124                                         HUD_Write_PanelCvar("_text");
 125                                         break;
 126                                 case HUD_PANEL_NOTIFY:
 127                                         HUD_Write_PanelCvar("_flip");
 128                                         HUD_Write_PanelCvar("_fontsize");
 129                                         HUD_Write_PanelCvar("_time");
 130                                         HUD_Write_PanelCvar("_fadetime");
 131                                         HUD_Write_PanelCvar("_icon_aspect");
 132                                         break;
 133                                 case HUD_PANEL_TIMER:
 134                                         break;
 135                                 case HUD_PANEL_RADAR:
 136                                         HUD_Write_PanelCvar("_foreground_alpha");
 137                                         HUD_Write_PanelCvar("_rotation");
 138                                         HUD_Write_PanelCvar("_zoommode");
 139                                         HUD_Write_PanelCvar("_scale");
 140                                         HUD_Write_PanelCvar("_maximized_scale");
 141                                         HUD_Write_PanelCvar("_maximized_size");
 142                                         HUD_Write_PanelCvar("_maximized_rotation");
 143                                         HUD_Write_PanelCvar("_maximized_zoommode");
 144                                         break;
 145                                 case HUD_PANEL_SCORE:
 146                                         HUD_Write_PanelCvar("_rankings");
 147                                         break;
 148                                 case HUD_PANEL_VOTE:
 149                                         HUD_Write_PanelCvar("_alreadyvoted_alpha");
 150                                         break;
 151                                 case HUD_PANEL_MODICONS:
 152                                         HUD_Write_PanelCvar("_ca_layout");
 153                                         HUD_Write_PanelCvar("_dom_layout");
 154                                         HUD_Write_PanelCvar("_freezetag_layout");
 155                                         break;
 156                                 case HUD_PANEL_PRESSEDKEYS:
 157                                         HUD_Write_PanelCvar("_aspect");
 158                                         HUD_Write_PanelCvar("_attack");
 159                                         break;
 160                                 case HUD_PANEL_ENGINEINFO:
 161                                         HUD_Write_PanelCvar("_framecounter_time");
 162                                         HUD_Write_PanelCvar("_framecounter_decimals");
 163                                         break;
 164                                 case HUD_PANEL_INFOMESSAGES:
 165                                         HUD_Write_PanelCvar("_flip");
 166                                         break;
 167                                 case HUD_PANEL_PHYSICS:
 168                                         HUD_Write_PanelCvar("_speed_unit_show");
 169                                         HUD_Write_PanelCvar("_speed_max");
 170                                         HUD_Write_PanelCvar("_speed_vertical");
 171                                         HUD_Write_PanelCvar("_topspeed");
 172                                         HUD_Write_PanelCvar("_topspeed_time");
 173                                         HUD_Write_PanelCvar("_acceleration_max");
 174                                         HUD_Write_PanelCvar("_acceleration_vertical");
 175                                         HUD_Write_PanelCvar("_flip");
 176                                         HUD_Write_PanelCvar("_baralign");
 177                                         HUD_Write_PanelCvar("_progressbar");
 178                                         HUD_Write_PanelCvar("_acceleration_progressbar_mode");
 179                                         HUD_Write_PanelCvar("_acceleration_progressbar_scale");
 180                                         HUD_Write_PanelCvar("_acceleration_progressbar_nonlinear");
 181                                         HUD_Write_PanelCvar("_text");
 182                                         HUD_Write_PanelCvar("_text_scale");
 183                                         break;
 184                                 case HUD_PANEL_CENTERPRINT:
 185                                         HUD_Write_PanelCvar("_align");
 186                                         HUD_Write_PanelCvar("_flip");
 187                                         HUD_Write_PanelCvar("_fontscale");
 188                                         HUD_Write_PanelCvar("_time");
 189                                         HUD_Write_PanelCvar("_fade_in");
 190                                         HUD_Write_PanelCvar("_fade_out");
 191                                         HUD_Write_PanelCvar("_fade_subsequent");
 192                                         HUD_Write_PanelCvar("_fade_subsequent_passone");
 193                                         HUD_Write_PanelCvar("_fade_subsequent_passone_minalpha");
 194                                         HUD_Write_PanelCvar("_fade_subsequent_passtwo");
 195                                         HUD_Write_PanelCvar("_fade_subsequent_passtwo_minalpha");
 196                                         HUD_Write_PanelCvar("_fade_subsequent_minfontsize");
 197                                         HUD_Write_PanelCvar("_fade_minfontsize");
 198                                         break;
 199                                 case HUD_PANEL_ITEMSTIME:
 200                                         HUD_Write_PanelCvar("_iconalign");
 201                                         HUD_Write_PanelCvar("_progressbar");
 202                                         HUD_Write_PanelCvar("_progressbar_name");
 203                                         HUD_Write_PanelCvar("_progressbar_reduced");
 204                                         HUD_Write_PanelCvar("_text");
 205                                         HUD_Write_PanelCvar("_ratio");
 206                                         HUD_Write_PanelCvar("_dynamicsize");
 207                                         break;
 208                                 case HUD_PANEL_QUICKMENU:
 209                                         HUD_Write_PanelCvar("_align");
 210                                         break;
 211                         }
 212                         HUD_Write("\n");
 213                 }
 214                 HUD_Write("menu_sync\n"); // force the menu to reread the cvars, so that the dialogs are updated
 215
 216                 LOG_INFOF(_("^2Successfully exported to %s! (Note: It's saved in data/data/)\n"), filename);
 217                 fclose(fh);
 218         }
 219         else
 220                 LOG_INFOF(_("^1Couldn't write to %s\n"), filename);
 221 }
 222
 223 void HUD_Configure_Exit_Force()
 224 {
 225         if (menu_enabled)
 226         {
 227                 menu_enabled = 0;
 228                 localcmd("togglemenu\n");
 229         }
 230         cvar_set("_hud_configure", "0");
 231 }
 232
 233 // check if move will result in panel being moved into another panel. If so, return snapped vector, otherwise return the given vector
 234 vector HUD_Panel_CheckMove(vector myPos, vector mySize)
 235 {
 236         vector myCenter, targCenter;
 237         vector myTarget = myPos;
 238         int i;
 239         for (i = 0; i < hud_panels_COUNT; ++i) {
 240                 panel = hud_panels_from(i);
 241                 if(!(panel.panel_configflags & PANEL_CONFIG_MAIN)) continue;
 242                 if(panel == highlightedPanel) continue;
 243                 HUD_Panel_UpdatePosSize();
 244                 if(!panel_enabled) continue;
 245
 246                 panel_pos -= '1 1 0' * panel_bg_border;
 247                 panel_size += '2 2 0' * panel_bg_border;
 248
 249                 if(myPos.y + mySize.y < panel_pos.y)
 250                         continue;
 251                 if(myPos.y > panel_pos.y + panel_size.y)
 252                         continue;
 253
 254                 if(myPos.x + mySize.x < panel_pos.x)
 255                         continue;
 256                 if(myPos.x > panel_pos.x + panel_size.x)
 257                         continue;
 258
 259                 // OK, there IS a collision.
 260
 261                 myCenter.x = myPos.x + 0.5 * mySize.x;
 262                 myCenter.y = myPos.y + 0.5 * mySize.y;
 263
 264                 targCenter.x = panel_pos.x + 0.5 * panel_size.x;
 265                 targCenter.y = panel_pos.y + 0.5 * panel_size.y;
 266
 267                 if(myCenter.x < targCenter.x && myCenter.y < targCenter.y) // top left (of the target panel)
 268                 {
 269                         if(myPos.x + mySize.x - panel_pos.x < myPos.y + mySize.y - panel_pos.y) // push it to the side
 270                                 myTarget.x = panel_pos.x - mySize.x;
 271                         else // push it upwards
 272                                 myTarget.y = panel_pos.y - mySize.y;
 273                 }
 274                 else if(myCenter.x > targCenter.x && myCenter.y < targCenter.y) // top right
 275                 {
 276                         if(panel_pos.x + panel_size.x - myPos.x < myPos.y + mySize.y - panel_pos.y) // push it to the side
 277                                 myTarget.x = panel_pos.x + panel_size.x;
 278                         else // push it upwards
 279                                 myTarget.y = panel_pos.y - mySize.y;
 280                 }
 281                 else if(myCenter.x < targCenter.x && myCenter.y > targCenter.y) // bottom left
 282                 {
 283                         if(myPos.x + mySize.x - panel_pos.x < panel_pos.y + panel_size.y - myPos.y) // push it to the side
 284                                 myTarget.x = panel_pos.x - mySize.x;
 285                         else // push it downwards
 286                                 myTarget.y = panel_pos.y + panel_size.y;
 287                 }
 288                 else if(myCenter.x > targCenter.x && myCenter.y > targCenter.y) // bottom right
 289                 {
 290                         if(panel_pos.x + panel_size.x - myPos.x < panel_pos.y + panel_size.y - myPos.y) // push it to the side
 291                                 myTarget.x = panel_pos.x + panel_size.x;
 292                         else // push it downwards
 293                                 myTarget.y = panel_pos.y + panel_size.y;
 294                 }
 295                 //if(cvar("hud_configure_checkcollisions_debug"))
 296                         //drawfill(panel_pos, panel_size, '1 1 0', .3, DRAWFLAG_NORMAL);
 297         }
 298
 299         return myTarget;
 300 }
 301
 302 void HUD_Panel_SetPos(vector pos)
 303 {
 304         panel = highlightedPanel;
 305         HUD_Panel_UpdatePosSize();
 306         vector mySize;
 307         mySize = panel_size;
 308
 309         //if(cvar("hud_configure_checkcollisions_debug"))
 310                 //drawfill(pos, mySize, '1 1 1', .2, DRAWFLAG_NORMAL);
 311
 312         if(autocvar_hud_configure_grid)
 313         {
 314                 pos.x = floor((pos.x/vid_conwidth)/hud_configure_gridSize.x + 0.5) * hud_configure_realGridSize.x;
 315                 pos.y = floor((pos.y/vid_conheight)/hud_configure_gridSize.y + 0.5) * hud_configure_realGridSize.y;
 316         }
 317
 318         if(hud_configure_checkcollisions)
 319                 pos = HUD_Panel_CheckMove(pos, mySize);
 320
 321         pos.x = bound(0, pos.x, vid_conwidth - mySize.x);
 322         pos.y = bound(0, pos.y, vid_conheight - mySize.y);
 323
 324         string s;
 325         s = strcat(ftos(pos.x/vid_conwidth), " ", ftos(pos.y/vid_conheight));
 326
 327         cvar_set(strcat("hud_panel_", highlightedPanel.panel_name, "_pos"), s);
 328 }
 329
 330 // check if resize will result in panel being moved into another panel. If so, return snapped vector, otherwise return the given vector
 331 vector HUD_Panel_CheckResize(vector mySize, vector resizeorigin) {
 332         vector targEndPos;
 333         vector dist;
 334         float ratio = mySize.x/mySize.y;
 335         int i;
 336         for (i = 0; i < hud_panels_COUNT; ++i) {
 337                 panel = hud_panels_from(i);
 338                 if(!(panel.panel_configflags & PANEL_CONFIG_MAIN)) continue;
 339                 if(panel == highlightedPanel) continue;
 340                 HUD_Panel_UpdatePosSize();
 341                 if(!panel_enabled) continue;
 342
 343                 panel_pos -= '1 1 0' * panel_bg_border;
 344                 panel_size += '2 2 0' * panel_bg_border;
 345
 346                 targEndPos = panel_pos + panel_size;
 347
 348                 // resizeorigin is WITHIN target panel, just abort any collision testing against that particular panel to produce expected behaviour!
 349                 if(resizeorigin.x > panel_pos.x && resizeorigin.x < targEndPos.x && resizeorigin.y > panel_pos.y && resizeorigin.y < targEndPos.y)
 350                         continue;
 351
 352                 if (resizeCorner == 1)
 353                 {
 354                         // check if this panel is on our way
 355                         if (resizeorigin.x <= panel_pos.x)
 356                                 continue;
 357                         if (resizeorigin.y <= panel_pos.y)
 358                                 continue;
 359                         if (targEndPos.x <= resizeorigin.x - mySize.x)
 360                                 continue;
 361                         if (targEndPos.y <= resizeorigin.y - mySize.y)
 362                                 continue;
 363
 364                         // there is a collision:
 365                         // detect which side of the panel we are facing is actually limiting the resizing
 366                         // (which side the resize direction finds for first) and reduce the size up to there
 367                         //
 368                         // dist is the distance between resizeorigin and the "analogous" point of the panel
 369                         // in this case between resizeorigin (bottom-right point) and the bottom-right point of the panel
 370                         dist.x = resizeorigin.x - targEndPos.x;
 371                         dist.y = resizeorigin.y - targEndPos.y;
 372                         if (dist.y <= 0 || dist.x / dist.y > ratio)
 373                                 mySize.x = min(mySize.x, dist.x);
 374                         else
 375                                 mySize.y = min(mySize.y, dist.y);
 376                 }
 377                 else if (resizeCorner == 2)
 378                 {
 379                         if (resizeorigin.x >= targEndPos.x)
 380                                 continue;
 381                         if (resizeorigin.y <= panel_pos.y)
 382                                 continue;
 383                         if (panel_pos.x >= resizeorigin.x + mySize.x)
 384                                 continue;
 385                         if (targEndPos.y <= resizeorigin.y - mySize.y)
 386                                 continue;
 387
 388                         dist.x = panel_pos.x - resizeorigin.x;
 389                         dist.y = resizeorigin.y - targEndPos.y;
 390                         if (dist.y <= 0 || dist.x / dist.y > ratio)
 391                                 mySize.x = min(mySize.x, dist.x);
 392                         else
 393                                 mySize.y = min(mySize.y, dist.y);
 394                 }
 395                 else if (resizeCorner == 3)
 396                 {
 397                         if (resizeorigin.x <= panel_pos.x)
 398                                 continue;
 399                         if (resizeorigin.y >= targEndPos.y)
 400                                 continue;
 401                         if (targEndPos.x <= resizeorigin.x - mySize.x)
 402                                 continue;
 403                         if (panel_pos.y >= resizeorigin.y + mySize.y)
 404                                 continue;
 405
 406                         dist.x = resizeorigin.x - targEndPos.x;
 407                         dist.y = panel_pos.y - resizeorigin.y;
 408                         if (dist.y <= 0 || dist.x / dist.y > ratio)
 409                                 mySize.x = min(mySize.x, dist.x);
 410                         else
 411                                 mySize.y = min(mySize.y, dist.y);
 412                 }
 413                 else if (resizeCorner == 4)
 414                 {
 415                         if (resizeorigin.x >= targEndPos.x)
 416                                 continue;
 417                         if (resizeorigin.y >= targEndPos.y)
 418                                 continue;
 419                         if (panel_pos.x >= resizeorigin.x + mySize.x)
 420                                 continue;
 421                         if (panel_pos.y >= resizeorigin.y + mySize.y)
 422                                 continue;
 423
 424                         dist.x = panel_pos.x - resizeorigin.x;
 425                         dist.y = panel_pos.y - resizeorigin.y;
 426                         if (dist.y <= 0 || dist.x / dist.y > ratio)
 427                                 mySize.x = min(mySize.x, dist.x);
 428                         else
 429                                 mySize.y = min(mySize.y, dist.y);
 430                 }
 431                 //if(cvar("hud_configure_checkcollisions_debug"))
 432                         //drawfill(panel_pos, panel_size, '1 1 0', .3, DRAWFLAG_NORMAL);
 433         }
 434
 435         return mySize;
 436 }
 437
 438 void HUD_Panel_SetPosSize(vector mySize)
 439 {
 440         panel = highlightedPanel;
 441         HUD_Panel_UpdatePosSize();
 442         vector resizeorigin = panel_click_resizeorigin;
 443         vector myPos;
 444
 445         // minimum panel size cap
 446         mySize.x = max(0.025 * vid_conwidth, mySize.x);
 447         mySize.y = max(0.025 * vid_conheight, mySize.y);
 448
 449         if(highlightedPanel == HUD_PANEL(CHAT)) // some panels have their own restrictions, like the chat panel (which actually only moves the engine chat print around). Looks bad if it's too small.
 450         {
 451                 mySize.x = max(17 * autocvar_con_chatsize, mySize.x);
 452                 mySize.y = max(2 * autocvar_con_chatsize + 2 * panel_bg_padding, mySize.y);
 453         }
 454
 455         // collision testing|
 456         // -----------------+
 457
 458         // we need to know pos at this stage, but it might still change later if we hit a screen edge/other panel (?)
 459         if(resizeCorner == 1) {
 460                 myPos.x = resizeorigin.x - mySize.x;
 461                 myPos.y = resizeorigin.y - mySize.y;
 462         } else if(resizeCorner == 2) {
 463                 myPos.x = resizeorigin.x;
 464                 myPos.y = resizeorigin.y - mySize.y;
 465         } else if(resizeCorner == 3) {
 466                 myPos.x = resizeorigin.x - mySize.x;
 467                 myPos.y = resizeorigin.y;
 468         } else { // resizeCorner == 4
 469                 myPos.x = resizeorigin.x;
 470                 myPos.y = resizeorigin.y;
 471         }
 472
 473         // left/top screen edges
 474         if(myPos.x < 0)
 475                 mySize.x = mySize.x + myPos.x;
 476         if(myPos.y < 0)
 477                 mySize.y = mySize.y + myPos.y;
 478
 479         // bottom/right screen edges
 480         if(myPos.x + mySize.x > vid_conwidth)
 481                 mySize.x = vid_conwidth - myPos.x;
 482         if(myPos.y + mySize.y > vid_conheight)
 483                 mySize.y = vid_conheight - myPos.y;
 484
 485         //if(cvar("hud_configure_checkcollisions_debug"))
 486                 //drawfill(myPos, mySize, '1 1 1', .2, DRAWFLAG_NORMAL);
 487
 488         // before checkresize, otherwise panel can be snapped partially inside another panel or panel aspect ratio can be broken
 489         if(autocvar_hud_configure_grid)
 490         {
 491                 mySize.x = floor((mySize.x/vid_conwidth)/hud_configure_gridSize.x + 0.5) * hud_configure_realGridSize.x;
 492                 mySize.y = floor((mySize.y/vid_conheight)/hud_configure_gridSize.y + 0.5) * hud_configure_realGridSize.y;
 493         }
 494
 495         if(hud_configure_checkcollisions)
 496                 mySize = HUD_Panel_CheckResize(mySize, resizeorigin);
 497
 498         // minimum panel size cap, do this once more so we NEVER EVER EVER have a panel smaller than this, JUST IN CASE above code still makes the panel eg negative (impossible to resize back without changing cvars manually then)
 499         mySize.x = max(0.025 * vid_conwidth, mySize.x);
 500         mySize.y = max(0.025 * vid_conheight, mySize.y);
 501
 502         // do another pos check, as size might have changed by now
 503         if(resizeCorner == 1) {
 504                 myPos.x = resizeorigin.x - mySize.x;
 505                 myPos.y = resizeorigin.y - mySize.y;
 506         } else if(resizeCorner == 2) {
 507                 myPos.x = resizeorigin.x;
 508                 myPos.y = resizeorigin.y - mySize.y;
 509         } else if(resizeCorner == 3) {
 510                 myPos.x = resizeorigin.x - mySize.x;
 511                 myPos.y = resizeorigin.y;
 512         } else { // resizeCorner == 4
 513                 myPos.x = resizeorigin.x;
 514                 myPos.y = resizeorigin.y;
 515         }
 516
 517         //if(cvar("hud_configure_checkcollisions_debug"))
 518                 //drawfill(myPos, mySize, '0 1 0', .3, DRAWFLAG_NORMAL);
 519
 520         string s;
 521         s = strcat(ftos(mySize.x/vid_conwidth), " ", ftos(mySize.y/vid_conheight));
 522         cvar_set(strcat("hud_panel_", highlightedPanel.panel_name, "_size"), s);
 523
 524         s = strcat(ftos(myPos.x/vid_conwidth), " ", ftos(myPos.y/vid_conheight));
 525         cvar_set(strcat("hud_panel_", highlightedPanel.panel_name, "_pos"), s);
 526 }
 527
 528 float pressed_key_time;
 529 vector highlightedPanel_initial_pos, highlightedPanel_initial_size;
 530 void HUD_Panel_Arrow_Action(float nPrimary)
 531 {
 532         if(!highlightedPanel)
 533                 return;
 534
 535         hud_configure_checkcollisions = (!(hudShiftState & S_CTRL) && autocvar_hud_configure_checkcollisions);
 536
 537         float step;
 538         if(autocvar_hud_configure_grid)
 539         {
 540                 if (nPrimary == K_UPARROW || nPrimary == K_DOWNARROW)
 541                 {
 542                         if (hudShiftState & S_SHIFT)
 543                                 step = hud_configure_realGridSize.y;
 544                         else
 545                                 step = 2 * hud_configure_realGridSize.y;
 546                 }
 547                 else
 548                 {
 549                         if (hudShiftState & S_SHIFT)
 550                                 step = hud_configure_realGridSize.x;
 551                         else
 552                                 step = 2 * hud_configure_realGridSize.x;
 553                 }
 554         }
 555         else
 556         {
 557                 if (nPrimary == K_UPARROW || nPrimary == K_DOWNARROW)
 558                         step = vid_conheight;
 559                 else
 560                         step = vid_conwidth;
 561                 if (hudShiftState & S_SHIFT)
 562                         step = (step / 256); // more precision
 563                 else
 564                         step = (step / 64) * (1 + 2 * (time - pressed_key_time));
 565         }
 566
 567         panel = highlightedPanel;
 568         HUD_Panel_UpdatePosSize();
 569
 570         highlightedPanel_initial_pos = panel_pos;
 571         highlightedPanel_initial_size = panel_size;
 572
 573         if (hudShiftState & S_ALT) // resize
 574         {
 575                 if(nPrimary == K_UPARROW)
 576                         resizeCorner = 1;
 577                 else if(nPrimary == K_RIGHTARROW)
 578                         resizeCorner = 2;
 579                 else if(nPrimary == K_LEFTARROW)
 580                         resizeCorner = 3;
 581                 else // if(nPrimary == K_DOWNARROW)
 582                         resizeCorner = 4;
 583
 584                 // ctrl+arrow reduces the size, instead of increasing it
 585                 // Note that ctrl disables collisions check too, but it's fine
 586                 // since we don't collide with anything reducing the size
 587                 if (hudShiftState & S_CTRL) {
 588                         step = -step;
 589                         resizeCorner = 5 - resizeCorner;
 590                 }
 591
 592                 vector mySize;
 593                 mySize = panel_size;
 594                 panel_click_resizeorigin = panel_pos;
 595                 if(resizeCorner == 1) {
 596                         panel_click_resizeorigin += mySize;
 597                         mySize.y += step;
 598                 } else if(resizeCorner == 2) {
 599                         panel_click_resizeorigin.y += mySize.y;
 600                         mySize.x += step;
 601                 } else if(resizeCorner == 3) {
 602                         panel_click_resizeorigin.x += mySize.x;
 603                         mySize.x += step;
 604                 } else { // resizeCorner == 4
 605                         mySize.y += step;
 606                 }
 607                 HUD_Panel_SetPosSize(mySize);
 608         }
 609         else // move
 610         {
 611                 vector pos;
 612                 pos = panel_pos;
 613                 if(nPrimary == K_UPARROW)
 614                         pos.y -= step;
 615                 else if(nPrimary == K_DOWNARROW)
 616                         pos.y += step;
 617                 else if(nPrimary == K_LEFTARROW)
 618                         pos.x -= step;
 619                 else // if(nPrimary == K_RIGHTARROW)
 620                         pos.x += step;
 621
 622                 HUD_Panel_SetPos(pos);
 623         }
 624
 625         panel = highlightedPanel;
 626         HUD_Panel_UpdatePosSize();
 627
 628         if (highlightedPanel_initial_pos != panel_pos || highlightedPanel_initial_size != panel_size)
 629         {
 630                 // backup!
 631                 panel_pos_backup = highlightedPanel_initial_pos;
 632                 panel_size_backup = highlightedPanel_initial_size;
 633                 highlightedPanel_backup = highlightedPanel;
 634         }
 635 }
 636
 637 void HUD_Panel_EnableMenu();
 638 entity tab_panels[hud_panels_MAX];
 639 entity tab_panel;
 640 vector tab_panel_pos;
 641 float tab_backward;
 642 void HUD_Panel_FirstInDrawQ(float id);
 643 void reset_tab_panels()
 644 {
 645         for (int i = 0; i < hud_panels_COUNT; ++i)
 646                 tab_panels[i] = NULL;
 647 }
 648 float HUD_Panel_InputEvent(float bInputType, float nPrimary, float nSecondary)
 649 {
 650         string s;
 651
 652         if(bInputType == 2)
 653                 return false;
 654
 655         if(!autocvar__hud_configure)
 656                 return false;
 657
 658         if(bInputType == 3)
 659         {
 660                 mousepos.x = nPrimary;
 661                 mousepos.y = nSecondary;
 662                 return true;
 663         }
 664
 665         // block any input while a menu dialog is fading
 666         // don't block mousepos read as it leads to cursor jumps in the interaction with the menu
 667         if(autocvar__menu_alpha)
 668         {
 669                 hudShiftState = 0;
 670                 mouseClicked = 0;
 671                 return true;
 672         }
 673
 674         // allow console bind to work
 675         string con_keys = findkeysforcommand("toggleconsole", 0);
 676         int keys = tokenize(con_keys); // findkeysforcommand returns data for this
 677
 678         bool hit_con_bind = false;
 679         int i;
 680         for (i = 0; i < keys; ++i)
 681         {
 682                 if(nPrimary == stof(argv(i)))
 683                         hit_con_bind = true;
 684         }
 685
 686         if(bInputType == 0) {
 687                 if(nPrimary == K_ALT) hudShiftState |= S_ALT;
 688                 if(nPrimary == K_CTRL) hudShiftState |= S_CTRL;
 689                 if(nPrimary == K_SHIFT) hudShiftState |= S_SHIFT;
 690         }
 691         else if(bInputType == 1) {
 692                 if(nPrimary == K_ALT) hudShiftState -= (hudShiftState & S_ALT);
 693                 if(nPrimary == K_CTRL) hudShiftState -= (hudShiftState & S_CTRL);
 694                 if(nPrimary == K_SHIFT) hudShiftState -= (hudShiftState & S_SHIFT);
 695         }
 696
 697         if(nPrimary == K_CTRL)
 698         {
 699                 if (bInputType == 1) //ctrl has been released
 700                 {
 701                         if (tab_panel)
 702                         {
 703                                 //switch to selected panel
 704                                 highlightedPanel = tab_panel;
 705                                 highlightedAction = 0;
 706                                 HUD_Panel_FirstInDrawQ(highlightedPanel.panel_id);
 707                         }
 708                         tab_panel = NULL;
 709                         reset_tab_panels();
 710                 }
 711         }
 712
 713         if(nPrimary == K_MOUSE1)
 714         {
 715                 if(bInputType == 0) // key pressed
 716                         mouseClicked |= S_MOUSE1;
 717                 else if(bInputType == 1) // key released
 718                         mouseClicked -= (mouseClicked & S_MOUSE1);
 719         }
 720         else if(nPrimary == K_MOUSE2)
 721         {
 722                 if(bInputType == 0) // key pressed
 723                         mouseClicked |= S_MOUSE2;
 724                 else if(bInputType == 1) // key released
 725                         mouseClicked -= (mouseClicked & S_MOUSE2);
 726         }
 727         else if(nPrimary == K_ESCAPE)
 728         {
 729                 if (bInputType == 1)
 730                         return true;
 731                 menu_enabled = 1;
 732                 localcmd("menu_showhudexit\n");
 733         }
 734         else if(nPrimary == K_BACKSPACE && hudShiftState & S_CTRL)
 735         {
 736                 if (bInputType == 1)
 737                         return true;
 738                 if (!menu_enabled)
 739                         cvar_set("_hud_configure", "0");
 740         }
 741         else if(nPrimary == K_TAB && hudShiftState & S_CTRL) // switch panel
 742         {
 743                 if (bInputType == 1 || mouseClicked)
 744                         return true;
 745
 746                 // FIXME minor bug: if a panel is highlighted, has the same pos_x and
 747                 // lays in the same level of another panel then the next consecutive
 748                 // CTRL TAB presses will reselect once more the highlighted panel
 749
 750                 entity starting_panel;
 751                 entity old_tab_panel = tab_panel;
 752                 if (!tab_panel) //first press of TAB
 753                 {
 754                         if (highlightedPanel)
 755                         {
 756                                 panel = highlightedPanel;
 757                                 HUD_Panel_UpdatePosSize();
 758                         }
 759                         else
 760                                 panel_pos = '0 0 0';
 761                         starting_panel = highlightedPanel;
 762                         tab_panel_pos = panel_pos; //to compute level
 763                 }
 764                 else
 765                 {
 766                         if ( ((!tab_backward) && (hudShiftState & S_SHIFT)) || (tab_backward && !(hudShiftState & S_SHIFT)) ) //tab direction changed?
 767                                 reset_tab_panels();
 768                         starting_panel = tab_panel;
 769                 }
 770                 tab_backward = (hudShiftState & S_SHIFT);
 771
 772                 float k, level = 0, start_posX;
 773                 vector candidate_pos = '0 0 0';
 774                 const float LEVELS_NUM = 4;
 775                 float level_height = vid_conheight / LEVELS_NUM;
 776 LABEL(find_tab_panel)
 777                 level = floor(tab_panel_pos.y / level_height) * level_height; //starting level
 778                 candidate_pos.x = (!tab_backward) ? vid_conwidth : 0;
 779                 start_posX = tab_panel_pos.x;
 780                 tab_panel = NULL;
 781                 k=0;
 782                 while(++k)
 783                 {
 784                         for(i = 0; i < hud_panels_COUNT; ++i)
 785                         {
 786                                 panel = hud_panels_from(i);
 787                                 if(!(panel.panel_configflags & PANEL_CONFIG_MAIN))
 788                                         continue;
 789                                 if (panel == tab_panels[i] || panel == starting_panel)
 790                                         continue;
 791                                 HUD_Panel_UpdatePosSize();
 792                                 if (panel_pos.y >= level && (panel_pos.y - level) < level_height)
 793                                 if (  ( !tab_backward && panel_pos.x >= start_posX && (panel_pos.x < candidate_pos.x || (panel_pos.x == candidate_pos.x && panel_pos.y <= candidate_pos.y)) )
 794                                         || ( tab_backward && panel_pos.x <= start_posX && (panel_pos.x > candidate_pos.x || (panel_pos.x == candidate_pos.x && panel_pos.y >= candidate_pos.y)) )  )
 795                                 {
 796                                         tab_panel = panel;
 797                                         tab_panel_pos = candidate_pos = panel_pos;
 798                                 }
 799                         }
 800                         if (tab_panel)
 801                                 break;
 802                         if (k == LEVELS_NUM) //tab_panel not found
 803                         {
 804                                 reset_tab_panels();
 805                                 if (!old_tab_panel)
 806                                 {
 807                                         tab_panel = NULL;
 808                                         return true;
 809                                 }
 810                                 starting_panel = old_tab_panel;
 811                                 old_tab_panel = NULL;
 812                                 goto find_tab_panel; //u must find tab_panel!
 813                         }
 814                         if (!tab_backward)
 815                         {
 816                                 level = (level + level_height) % vid_conheight;
 817                                 start_posX = 0;
 818                                 candidate_pos.x = vid_conwidth;
 819                         }
 820                         else
 821                         {
 822                                 level = (level - level_height) % vid_conheight;
 823                                 start_posX = vid_conwidth;
 824                                 candidate_pos.x = 0;
 825                         }
 826                 }
 827
 828                 tab_panels[tab_panel.panel_id] = tab_panel;
 829         }
 830         else if(nPrimary == K_SPACE && hudShiftState & S_CTRL) // enable/disable highlighted panel or dock
 831         {
 832                 if (bInputType == 1 || mouseClicked)
 833                         return true;
 834
 835                 if (highlightedPanel)
 836                         cvar_set(strcat("hud_panel_", highlightedPanel.panel_name), ftos(!cvar(strcat("hud_panel_", highlightedPanel.panel_name))));
 837                 else
 838                         cvar_set(strcat("hud_dock"), (autocvar_hud_dock == "") ? "dock" : "");
 839         }
 840         else if(nPrimary == 'c' && hudShiftState & S_CTRL) // copy highlighted panel size
 841         {
 842                 if (bInputType == 1 || mouseClicked)
 843                         return true;
 844
 845                 if (highlightedPanel)
 846                 {
 847                         panel = highlightedPanel;
 848                         HUD_Panel_UpdatePosSize();
 849                         panel_size_copied = panel_size;
 850                 }
 851         }
 852         else if(nPrimary == 'v' && hudShiftState & S_CTRL) // past copied size on the highlighted panel
 853         {
 854                 if (bInputType == 1 || mouseClicked)
 855                         return true;
 856
 857                 if (panel_size_copied == '0 0 0' || !highlightedPanel)
 858                         return true;
 859
 860                 panel = highlightedPanel;
 861                 HUD_Panel_UpdatePosSize();
 862
 863                 // reduce size if it'd go beyond screen boundaries
 864                 vector tmp_size = panel_size_copied;
 865                 if (panel_pos.x + panel_size_copied.x > vid_conwidth)
 866                         tmp_size.x = vid_conwidth - panel_pos.x;
 867                 if (panel_pos.y + panel_size_copied.y > vid_conheight)
 868                         tmp_size.y = vid_conheight - panel_pos.y;
 869
 870                 if (panel_size == tmp_size)
 871                         return true;
 872
 873                 // backup first!
 874                 panel_pos_backup = panel_pos;
 875                 panel_size_backup = panel_size;
 876                 highlightedPanel_backup = highlightedPanel;
 877
 878                 s = strcat(ftos(tmp_size.x/vid_conwidth), " ", ftos(tmp_size.y/vid_conheight));
 879                 cvar_set(strcat("hud_panel_", highlightedPanel.panel_name, "_size"), s);
 880         }
 881         else if(nPrimary == 'z' && hudShiftState & S_CTRL) // undo last action
 882         {
 883                 if (bInputType == 1 || mouseClicked)
 884                         return true;
 885                 //restore previous values
 886                 if (highlightedPanel_backup)
 887                 {
 888                         s = strcat(ftos(panel_pos_backup.x/vid_conwidth), " ", ftos(panel_pos_backup.y/vid_conheight));
 889                         cvar_set(strcat("hud_panel_", highlightedPanel_backup.panel_name, "_pos"), s);
 890                         s = strcat(ftos(panel_size_backup.x/vid_conwidth), " ", ftos(panel_size_backup.y/vid_conheight));
 891                         cvar_set(strcat("hud_panel_", highlightedPanel_backup.panel_name, "_size"), s);
 892                         highlightedPanel_backup = NULL;
 893                 }
 894         }
 895         else if(nPrimary == 's' && hudShiftState & S_CTRL) // save config
 896         {
 897                 if (bInputType == 1 || mouseClicked)
 898                         return true;
 899                 localcmd("hud save myconfig\n");
 900         }
 901         else if(nPrimary == K_UPARROW || nPrimary == K_DOWNARROW || nPrimary == K_LEFTARROW || nPrimary == K_RIGHTARROW)
 902         {
 903                 if (bInputType == 1)
 904                 {
 905                         pressed_key_time = 0;
 906                         return true;
 907                 }
 908                 else if (pressed_key_time == 0)
 909                         pressed_key_time = time;
 910
 911                 if (!mouseClicked)
 912                         HUD_Panel_Arrow_Action(nPrimary); //move or resize panel
 913         }
 914         else if(nPrimary == K_ENTER || nPrimary == K_SPACE || nPrimary == K_KP_ENTER)
 915         {
 916                 if (bInputType == 1)
 917                         return true;
 918                 if (highlightedPanel)
 919                         HUD_Panel_EnableMenu();
 920         }
 921         else if(hit_con_bind || nPrimary == K_PAUSE)
 922                 return false;
 923
 924         return true;
 925 }
 926
 927 float HUD_Panel_Check_Mouse_Pos(float allow_move)
 928 {
 929         int i, j = 0;
 930         while(j < hud_panels_COUNT)
 931         {
 932                 i = panel_order[j];
 933                 j += 1;
 934
 935                 panel = hud_panels_from(i);
 936                 if(!(panel.panel_configflags & PANEL_CONFIG_MAIN)) continue;
 937                 HUD_Panel_UpdatePosSize();
 938
 939                 float border = max(8, panel_bg_border); // FORCED border so a small border size doesn't mean you can't resize
 940
 941                 // move
 942                 if(allow_move && mousepos.x > panel_pos.x && mousepos.y > panel_pos.y && mousepos.x < panel_pos.x + panel_size.x && mousepos.y < panel_pos.y + panel_size.y)
 943                 {
 944                         return 1;
 945                 }
 946                 // resize from topleft border
 947                 else if(mousepos.x >= panel_pos.x - border && mousepos.y >= panel_pos.y - border && mousepos.x <= panel_pos.x + 0.5 * panel_size.x && mousepos.y <= panel_pos.y + 0.5 * panel_size.y)
 948                 {
 949                         return 2;
 950                 }
 951                 // resize from topright border
 952                 else if(mousepos.x >= panel_pos.x + 0.5 * panel_size.x && mousepos.y >= panel_pos.y - border && mousepos.x <= panel_pos.x + panel_size.x + border && mousepos.y <= panel_pos.y + 0.5 * panel_size.y)
 953                 {
 954                         return 3;
 955                 }
 956                 // resize from bottomleft border
 957                 else if(mousepos.x >= panel_pos.x - border && mousepos.y >= panel_pos.y + 0.5 * panel_size.y && mousepos.x <= panel_pos.x + 0.5 * panel_size.x && mousepos.y <= panel_pos.y + panel_size.y + border)
 958                 {
 959                         return 3;
 960                 }
 961                 // resize from bottomright border
 962                 else if(mousepos.x >= panel_pos.x + 0.5 * panel_size.x && mousepos.y >= panel_pos.y + 0.5 * panel_size.y && mousepos.x <= panel_pos.x + panel_size.x + border && mousepos.y <= panel_pos.y + panel_size.y + border)
 963                 {
 964                         return 2;
 965                 }
 966         }
 967         return 0;
 968 }
 969
 970 // move a panel to the beginning of the panel order array (which means it gets drawn last, on top of everything else)
 971 void HUD_Panel_FirstInDrawQ(float id)
 972 {
 973         int i;
 974         int place = -1;
 975         // find out where in the array our current id is, save into place
 976         for(i = 0; i < hud_panels_COUNT; ++i)
 977         {
 978                 if(panel_order[i] == id)
 979                 {
 980                         place = i;
 981                         break;
 982                 }
 983         }
 984         // place last if we didn't find a place for it yet (probably new panel, or screwed up cvar)
 985         if(place == -1)
 986                 place = hud_panels_COUNT - 1;
 987
 988         // move all ids up by one step in the array until "place"
 989         for(i = place; i > 0; --i)
 990         {
 991                 panel_order[i] = panel_order[i-1];
 992         }
 993         // now save the new top id
 994         panel_order[0] = id;
 995
 996         // let's save them into the cvar by some strcat trickery
 997         string s = "";
 998         for(i = 0; i < hud_panels_COUNT; ++i)
 999         {
1000                 s = strcat(s, ftos(panel_order[i]), " ");
1001         }
1002         cvar_set("_hud_panelorder", s);
1003         if(hud_panelorder_prev)
1004                 strunzone(hud_panelorder_prev);
1005         hud_panelorder_prev = strzone(autocvar__hud_panelorder); // prevent HUD_Main from doing useless update, we already updated here
1006 }
1007
1008 void HUD_Panel_Highlight(float allow_move)
1009 {
1010         int i, j = 0;
1011
1012         while(j < hud_panels_COUNT)
1013         {
1014                 i = panel_order[j];
1015                 j += 1;
1016
1017                 panel = hud_panels_from(i);
1018                 if(!(panel.panel_configflags & PANEL_CONFIG_MAIN))
1019                         continue;
1020                 HUD_Panel_UpdatePosSize();
1021
1022                 float border = max(8, panel_bg_border); // FORCED border so a small border size doesn't mean you can't resize
1023
1024                 // move
1025                 if(allow_move && mousepos.x > panel_pos.x && mousepos.y > panel_pos.y && mousepos.x < panel_pos.x + panel_size.x && mousepos.y < panel_pos.y + panel_size.y)
1026                 {
1027                         highlightedPanel = hud_panels_from(i);
1028                         HUD_Panel_FirstInDrawQ(i);
1029                         highlightedAction = 1;
1030                         panel_click_distance = mousepos - panel_pos;
1031                         return;
1032                 }
1033                 // resize from topleft border
1034                 else if(mousepos.x >= panel_pos.x - border && mousepos.y >= panel_pos.y - border && mousepos.x <= panel_pos.x + 0.5 * panel_size.x && mousepos.y <= panel_pos.y + 0.5 * panel_size.y)
1035                 {
1036                         highlightedPanel = hud_panels_from(i);
1037                         HUD_Panel_FirstInDrawQ(i);
1038                         highlightedAction = 2;
1039                         resizeCorner = 1;
1040                         panel_click_distance = mousepos - panel_pos;
1041                         panel_click_resizeorigin = panel_pos + panel_size;
1042                         return;
1043                 }
1044                 // resize from topright border
1045                 else if(mousepos.x >= panel_pos.x + 0.5 * panel_size.x && mousepos.y >= panel_pos.y - border && mousepos.x <= panel_pos.x + panel_size.x + border && mousepos.y <= panel_pos.y + 0.5 * panel_size.y)
1046                 {
1047                         highlightedPanel = hud_panels_from(i);
1048                         HUD_Panel_FirstInDrawQ(i);
1049                         highlightedAction = 2;
1050                         resizeCorner = 2;
1051                         panel_click_distance.x = panel_size.x - mousepos.x + panel_pos.x;
1052                         panel_click_distance.y = mousepos.y - panel_pos.y;
1053                         panel_click_resizeorigin = panel_pos + eY * panel_size.y;
1054                         return;
1055                 }
1056                 // resize from bottomleft border
1057                 else if(mousepos.x >= panel_pos.x - border && mousepos.y >= panel_pos.y + 0.5 * panel_size.y && mousepos.x <= panel_pos.x + 0.5 * panel_size.x && mousepos.y <= panel_pos.y + panel_size.y + border)
1058                 {
1059                         highlightedPanel = hud_panels_from(i);
1060                         HUD_Panel_FirstInDrawQ(i);
1061                         highlightedAction = 2;
1062                         resizeCorner = 3;
1063                         panel_click_distance.x = mousepos.x - panel_pos.x;
1064                         panel_click_distance.y = panel_size.y - mousepos.y + panel_pos.y;
1065                         panel_click_resizeorigin = panel_pos + eX * panel_size.x;
1066                         return;
1067                 }
1068                 // resize from bottomright border
1069                 else if(mousepos.x >= panel_pos.x + 0.5 * panel_size.x && mousepos.y >= panel_pos.y + 0.5 * panel_size.y && mousepos.x <= panel_pos.x + panel_size.x + border && mousepos.y <= panel_pos.y + panel_size.y + border)
1070                 {
1071                         highlightedPanel = hud_panels_from(i);
1072                         HUD_Panel_FirstInDrawQ(i);
1073                         highlightedAction = 2;
1074                         resizeCorner = 4;
1075                         panel_click_distance = panel_size - mousepos + panel_pos;
1076                         panel_click_resizeorigin = panel_pos;
1077                         return;
1078                 }
1079         }
1080         highlightedPanel = NULL;
1081         highlightedAction = 0;
1082 }
1083
1084 void HUD_Panel_EnableMenu()
1085 {
1086         menu_enabled = 2;
1087         localcmd("menu_showhudoptions ", highlightedPanel.panel_name, "\n");
1088 }
1089 float mouse_over_panel;
1090 void HUD_Panel_Mouse()
1091 {
1092         if(autocvar__menu_alpha == 1)
1093                 return;
1094
1095         if (!autocvar_hud_cursormode)
1096         {
1097                 mousepos = mousepos + getmousepos() * autocvar_menu_mouse_speed;
1098
1099                 mousepos.x = bound(0, mousepos.x, vid_conwidth);
1100                 mousepos.y = bound(0, mousepos.y, vid_conheight);
1101         }
1102
1103         if(mouseClicked)
1104         {
1105                 if(prevMouseClicked == 0)
1106                 {
1107                         if (tab_panel)
1108                         {
1109                                 //stop ctrl-tab selection
1110                                 tab_panel = NULL;
1111                                 reset_tab_panels();
1112                         }
1113                         HUD_Panel_Highlight(mouseClicked & S_MOUSE1); // sets highlightedPanel, highlightedAction, panel_click_distance, panel_click_resizeorigin
1114                                                                         // and calls HUD_Panel_UpdatePosSize() for the highlighted panel
1115                         if (highlightedPanel)
1116                         {
1117                                 highlightedPanel_initial_pos = panel_pos;
1118                                 highlightedPanel_initial_size = panel_size;
1119                         }
1120                         // doubleclick check
1121                         if ((mouseClicked & S_MOUSE1) && time - prevMouseClickedTime < 0.4 && highlightedPanel && prevMouseClickedPos == mousepos)
1122                         {
1123                                 mouseClicked = 0; // to prevent spam, I guess.
1124                                 HUD_Panel_EnableMenu();
1125                         }
1126                         else
1127                         {
1128                                 if (mouseClicked & S_MOUSE1)
1129                                 {
1130                                         prevMouseClickedTime = time;
1131                                         prevMouseClickedPos = mousepos;
1132                                 }
1133                                 mouse_over_panel = HUD_Panel_Check_Mouse_Pos(mouseClicked & S_MOUSE1);
1134                         }
1135                 }
1136                 else
1137                 {
1138                         panel = highlightedPanel;
1139                         HUD_Panel_UpdatePosSize();
1140                 }
1141
1142                 if (highlightedPanel)
1143                 {
1144                         drawfill(panel_pos - '1 1 0' * panel_bg_border, panel_size + '2 2 0' * panel_bg_border, '1 1 1', .1, DRAWFLAG_NORMAL);
1145                         if (highlightedPanel_initial_pos != panel_pos || highlightedPanel_initial_size != panel_size)
1146                         {
1147                                 hud_configure_checkcollisions = (!(hudShiftState & S_CTRL) && autocvar_hud_configure_checkcollisions);
1148                                 // backup!
1149                                 panel_pos_backup = highlightedPanel_initial_pos;
1150                                 panel_size_backup = highlightedPanel_initial_size;
1151                                 highlightedPanel_backup = highlightedPanel;
1152                         }
1153                         else
1154                                 // in case the clicked panel is inside another panel and we aren't
1155                                 // moving it, avoid the immediate "fix" of its position/size
1156                                 // (often unwanted and hateful) by disabling collisions check
1157                                 hud_configure_checkcollisions = false;
1158                 }
1159
1160                 if(highlightedAction == 1)
1161                         HUD_Panel_SetPos(mousepos - panel_click_distance);
1162                 else if(highlightedAction == 2)
1163                 {
1164                         vector mySize = '0 0 0';
1165                         if(resizeCorner == 1) {
1166                                 mySize.x = panel_click_resizeorigin.x - (mousepos.x - panel_click_distance.x);
1167                                 mySize.y = panel_click_resizeorigin.y - (mousepos.y - panel_click_distance.y);
1168                         } else if(resizeCorner == 2) {
1169                                 mySize.x = mousepos.x + panel_click_distance.x - panel_click_resizeorigin.x;
1170                                 mySize.y = panel_click_distance.y + panel_click_resizeorigin.y - mousepos.y;
1171                         } else if(resizeCorner == 3) {
1172                                 mySize.x = panel_click_resizeorigin.x + panel_click_distance.x - mousepos.x;
1173                                 mySize.y = mousepos.y + panel_click_distance.y - panel_click_resizeorigin.y;
1174                         } else { // resizeCorner == 4
1175                                 mySize.x = mousepos.x - (panel_click_resizeorigin.x - panel_click_distance.x);
1176                                 mySize.y = mousepos.y - (panel_click_resizeorigin.y - panel_click_distance.y);
1177                         }
1178                         HUD_Panel_SetPosSize(mySize);
1179                 }
1180         }
1181         else
1182         {
1183                 if(prevMouseClicked)
1184                         highlightedAction = 0;
1185                 if(menu_enabled == 2)
1186                         mouse_over_panel = 0;
1187                 else
1188                         mouse_over_panel = HUD_Panel_Check_Mouse_Pos(true);
1189                 if (mouse_over_panel && !tab_panel)
1190                         drawfill(panel_pos - '1 1 0' * panel_bg_border, panel_size + '2 2 0' * panel_bg_border, '1 1 1', .1, DRAWFLAG_NORMAL);
1191         }
1192         // draw cursor after performing move/resize to have the panel pos/size updated before mouse_over_panel
1193         float cursor_alpha = 1 - autocvar__menu_alpha;
1194
1195         if(!mouse_over_panel)
1196                 draw_cursor_normal(mousepos, '1 1 1', cursor_alpha);
1197         else if(mouse_over_panel == 1)
1198                 draw_cursor(mousepos, '0.5 0.5 0', "/cursor_move", '1 1 1', cursor_alpha);
1199         else if(mouse_over_panel == 2)
1200                 draw_cursor(mousepos, '0.5 0.5 0', "/cursor_resize", '1 1 1', cursor_alpha);
1201         else
1202                 draw_cursor(mousepos, '0.5 0.5 0', "/cursor_resize2", '1 1 1', cursor_alpha);
1203
1204         prevMouseClicked = mouseClicked;
1205 }
1206 void HUD_Configure_DrawGrid()
1207 {
1208         float i;
1209         if(autocvar_hud_configure_grid && autocvar_hud_configure_grid_alpha)
1210         {
1211                 hud_configure_gridSize.x = bound(0.005, cvar("hud_configure_grid_xsize"), 0.2);
1212                 hud_configure_gridSize.y = bound(0.005, cvar("hud_configure_grid_ysize"), 0.2);
1213                 hud_configure_realGridSize.x = hud_configure_gridSize.x * vid_conwidth;
1214                 hud_configure_realGridSize.y = hud_configure_gridSize.y * vid_conheight;
1215                 vector s;
1216                 // x-axis
1217                 s = eX + eY * vid_conheight;
1218                 for(i = 1; i < 1/hud_configure_gridSize.x; ++i)
1219                         drawfill(eX * i * hud_configure_realGridSize.x, s, '0.5 0.5 0.5', autocvar_hud_configure_grid_alpha, DRAWFLAG_NORMAL);
1220                 // y-axis
1221                 s = eY + eX * vid_conwidth;
1222                 for(i = 1; i < 1/hud_configure_gridSize.y; ++i)
1223                         drawfill(eY * i * hud_configure_realGridSize.y, s, '0.5 0.5 0.5', autocvar_hud_configure_grid_alpha, DRAWFLAG_NORMAL);
1224         }
1225 }
1226
1227 float _menu_alpha_prev;
1228 void HUD_Configure_Frame()
1229 {
1230         int i;
1231         if(autocvar__hud_configure)
1232         {
1233                 if(isdemo() || intermission == 2 || scoreboard_active)
1234                 {
1235                         HUD_Configure_Exit_Force();
1236                         return;
1237                 }
1238
1239                 if(!hud_configure_prev)
1240                 {
1241                         if(autocvar_hud_cursormode)
1242                                 setcursormode(1);
1243                         hudShiftState = 0;
1244                         for(i = hud_panels_COUNT - 1; i >= 0; --i)
1245                                 hud_panels_from(panel_order[i]).update_time = time;
1246                 }
1247
1248                 // NOTE this check is necessary because _menu_alpha isn't updated the frame the menu gets enabled
1249                 if(autocvar__menu_alpha != _menu_alpha_prev)
1250                 {
1251                         if(autocvar__menu_alpha == 0)
1252                                 menu_enabled = 0;
1253                         _menu_alpha_prev = autocvar__menu_alpha;
1254                 }
1255
1256                 HUD_Configure_DrawGrid();
1257         }
1258         else if(hud_configure_prev)
1259         {
1260                 if(menu_enabled)
1261                         menu_enabled = 0;
1262                 if(autocvar_hud_cursormode)
1263                         setcursormode(0);
1264                 hud_dynamic_shake_factor = -1;
1265         }
1266 }
1267
1268 const float hlBorderSize = 2;
1269 const string hlBorder = "gfx/hud/default/border_highlighted";
1270 const string hlBorder2 = "gfx/hud/default/border_highlighted2";
1271 void HUD_Panel_HlBorder(float myBorder, vector color, float theAlpha)
1272 {
1273         drawfill(panel_pos - '1 1 0' * myBorder, panel_size + '2 2 0' * myBorder, '0 0.5 1', .5 * theAlpha, DRAWFLAG_NORMAL);
1274         drawpic_tiled(panel_pos - '1 1 0' * myBorder, hlBorder, '8 1 0' * hlBorderSize, eX * (panel_size.x + 2 * myBorder) + eY * hlBorderSize, color, theAlpha, DRAWFLAG_NORMAL);
1275         drawpic_tiled(panel_pos - '1 1 0' * myBorder + eY * (panel_size.y + 2 * myBorder - hlBorderSize), hlBorder, '8 1 0' * hlBorderSize, eX * (panel_size.x + 2 * myBorder) + eY * hlBorderSize, color, theAlpha, DRAWFLAG_NORMAL);
1276         drawpic_tiled(panel_pos - '1 1 0' * myBorder + eY * hlBorderSize, hlBorder2, '1 8 0' * hlBorderSize, eY * (panel_size.y + 2 * myBorder - 2 * hlBorderSize) + eX * hlBorderSize, color, theAlpha, DRAWFLAG_NORMAL);
1277         drawpic_tiled(panel_pos - '1 1 0' * myBorder + eY * hlBorderSize + eX * (panel_size.x + 2 * myBorder - hlBorderSize), hlBorder2, '1 8 0' * hlBorderSize, eY * (panel_size.y + 2 * myBorder - 2 * hlBorderSize) + eX * hlBorderSize, color, theAlpha, DRAWFLAG_NORMAL);
1278 }
1279
1280 void HUD_Configure_PostDraw()
1281 {
1282         if(autocvar__hud_configure)
1283         {
1284                 if(tab_panel)
1285                 {
1286                         panel = tab_panel;
1287                         HUD_Panel_UpdatePosSize();
1288                         drawfill(panel_pos - '1 1 0' * panel_bg_border, panel_size + '2 2 0' * panel_bg_border, '1 1 1', .2, DRAWFLAG_NORMAL);
1289                 }
1290                 if(highlightedPanel)
1291                 {
1292                         panel = highlightedPanel;
1293                         HUD_Panel_UpdatePosSize();
1294                         HUD_Panel_HlBorder(panel_bg_border * hlBorderSize, '0 0.5 1', 0.4 * (1 - autocvar__menu_alpha));
1295                 }
1296         }
1297 }