qcsrc/client/hud/panel/centerprint.qc

   1 #include "centerprint.qh"
   2
   3 #include <client/draw.qh>
   4 #include <client/hud/panel/scoreboard.qh>
   5 #include <common/notifications/all.qh>
   6
   7 // CenterPrint (#16)
   8
   9 void HUD_CenterPrint_Export(int fh)
  10 {
  11         // allow saving cvars that aesthetically change the panel into hud skin files
  12         HUD_Write_Cvar("hud_panel_centerprint_align");
  13         HUD_Write_Cvar("hud_panel_centerprint_flip");
  14         HUD_Write_Cvar("hud_panel_centerprint_fontscale");
  15         HUD_Write_Cvar("hud_panel_centerprint_fontscale_bold");
  16         HUD_Write_Cvar("hud_panel_centerprint_time");
  17         HUD_Write_Cvar("hud_panel_centerprint_fade_in");
  18         HUD_Write_Cvar("hud_panel_centerprint_fade_out");
  19         HUD_Write_Cvar("hud_panel_centerprint_fade_subsequent");
  20         HUD_Write_Cvar("hud_panel_centerprint_fade_subsequent_passone");
  21         HUD_Write_Cvar("hud_panel_centerprint_fade_subsequent_passone_minalpha");
  22         HUD_Write_Cvar("hud_panel_centerprint_fade_subsequent_passtwo");
  23         HUD_Write_Cvar("hud_panel_centerprint_fade_subsequent_passtwo_minalpha");
  24         HUD_Write_Cvar("hud_panel_centerprint_fade_subsequent_minfontsize");
  25         HUD_Write_Cvar("hud_panel_centerprint_fade_minfontsize");
  26 }
  27
  28 // These are the functions that draw the text at the center of the screen (e.g. frag messages and server MOTD).
  29 // centerprint_Add parses a message and puts it in the circular buffer centerprint_messages
  30 // centerprint_Add is usually called by Local_Notification_centerprint_Add, which is called
  31 // by Local_Notification.
  32 // HUD_CenterPrint draws all the messages on screen
  33
  34 const int CENTERPRINT_MAX_MSGS = 10;
  35 const int CENTERPRINT_MAX_ENTRIES = 50;
  36 const float CENTERPRINT_SPACING = 0.5;
  37 const float CENTERPRINT_TITLE_SPACING = 0.8;
  38 int cpm_index;
  39 string centerprint_messages[CENTERPRINT_MAX_MSGS];
  40 int centerprint_msgID[CENTERPRINT_MAX_MSGS];
  41 float centerprint_time[CENTERPRINT_MAX_MSGS];
  42 float centerprint_start_time[CENTERPRINT_MAX_MSGS];
  43 float centerprint_expire_time[CENTERPRINT_MAX_MSGS];
  44 int centerprint_countdown_num[CENTERPRINT_MAX_MSGS];
  45 bool centerprint_showing;
  46
  47 bool centerprint_title_show;
  48 string centerprint_title;
  49
  50 void centerprint_Add(int new_id, string strMessage, float duration, int countdown_num)
  51 {
  52         TC(int, new_id); TC(int, countdown_num);
  53         //LOG_INFOF("centerprint_Add: ^2id: %d ^3dur: %d ^5countdown: %d\n'%s'", new_id, duration, countdown_num, strreplace("\n", "^7\\n^7", strMessage));
  54         int i, j;
  55
  56         if(strMessage == "" && new_id == 0)
  57                 return;
  58
  59         // strip trailing newlines
  60         j = strlen(strMessage) - 1;
  61         while(substring(strMessage, j, 1) == "\n" && j >= 0)
  62                 --j;
  63         if (j < strlen(strMessage) - 1)
  64                 strMessage = substring(strMessage, 0, j + 1);
  65
  66         if(strMessage == "" && new_id == 0)
  67                 return;
  68
  69         // strip leading newlines
  70         j = 0;
  71         while(substring(strMessage, j, 1) == "\n" && j < strlen(strMessage))
  72                 ++j;
  73         if (j > 0)
  74                 strMessage = substring(strMessage, j, strlen(strMessage) - j);
  75
  76         if(strMessage == "" && new_id == 0)
  77                 return;
  78
  79         if (!centerprint_showing)
  80                 centerprint_showing = true;
  81
  82         for (i=0, j=cpm_index; i<CENTERPRINT_MAX_MSGS; ++i, ++j)
  83         {
  84                 if (j == CENTERPRINT_MAX_MSGS)
  85                         j = 0;
  86                 if (new_id && new_id == centerprint_msgID[j])
  87                 {
  88                         if (strMessage == "" && centerprint_messages[j] != "" && centerprint_countdown_num[j] == 0)
  89                         {
  90                                 // fade out the current msg (duration and countdown_num are ignored)
  91                                 centerprint_time[j] = min(5, autocvar_hud_panel_centerprint_fade_out);
  92                                 centerprint_expire_time[j] = -1; // don't use the variable time here!
  93                                 return;
  94                         }
  95                         break; // found a msg with the same id, at position j
  96                 }
  97         }
  98
  99         if (strMessage == "")
 100                 return;
 101
 102         if (i == CENTERPRINT_MAX_MSGS)
 103         {
 104                 // a msg with the same id was not found, add the msg at the next position
 105                 --cpm_index;
 106                 if (cpm_index == -1)
 107                         cpm_index = CENTERPRINT_MAX_MSGS - 1;
 108                 j = cpm_index;
 109         }
 110         strcpy(centerprint_messages[j], strMessage);
 111         centerprint_start_time[j] = time;
 112         centerprint_msgID[j] = new_id;
 113         if (duration < 0)
 114         {
 115                 centerprint_time[j] = -1;
 116                 centerprint_expire_time[j] = -1; // don't use the variable time here!
 117         }
 118         else
 119         {
 120                 if(duration == 0)
 121                         duration = max(1, autocvar_hud_panel_centerprint_time);
 122                 centerprint_time[j] = duration;
 123                 centerprint_expire_time[j] = -1; // don't use the variable time here!
 124         }
 125         centerprint_countdown_num[j] = countdown_num;
 126 }
 127
 128 void centerprint_Kill(int id)
 129 {
 130         TC(int, id);
 131         centerprint_Add(id, "", 0, 0);
 132 }
 133
 134 void centerprint_AddStandard(string strMessage)
 135 {
 136         centerprint_Add(0, strMessage, autocvar_hud_panel_centerprint_time, 0);
 137 }
 138
 139 void centerprint_KillAll()
 140 {
 141         for (int i=0; i<CENTERPRINT_MAX_MSGS; ++i)
 142         {
 143                 centerprint_start_time[i] = 0;
 144                 centerprint_expire_time[i] = 0;
 145                 centerprint_time[i] = 1;
 146                 centerprint_msgID[i] = 0;
 147                 strfree(centerprint_messages[i]);
 148         }
 149 }
 150
 151 void centerprint_ClearTitle()
 152 {
 153         strfree(centerprint_title);
 154         centerprint_title_show = false;
 155 }
 156
 157 void centerprint_SetTitle(string title)
 158 {
 159         if(title != centerprint_title) {
 160                 if(centerprint_title)
 161                         strfree(centerprint_title);
 162
 163                 centerprint_title = strzone(title);
 164                 centerprint_title_show = true;
 165         }
 166 }
 167
 168 float hud_configure_cp_generation_time;
 169 void HUD_CenterPrint()
 170 {
 171         if(!autocvar__hud_configure)
 172         {
 173                 if(!autocvar_hud_panel_centerprint) return;
 174
 175                 if(hud_configure_prev) {
 176                         centerprint_ClearTitle();
 177                         centerprint_KillAll();
 178                 }
 179         }
 180         else
 181         {
 182                 if(!hud_configure_prev)
 183                 {
 184                         centerprint_KillAll();
 185                         hud_configure_cp_generation_time = time; // show a message immediately
 186                 }
 187                 if (time > hud_configure_cp_generation_time)
 188                 {
 189                         if(highlightedPanel == HUD_PANEL(CENTERPRINT))
 190                         {
 191                                 centerprint_SetTitle(strcat("test", ftos(hud_configure_cp_generation_time)));
 192
 193                                 float r;
 194                                 r = random();
 195                                 if (r > 0.8)
 196                                         centerprint_Add(floor(r*1000), sprintf(_("^3Countdown message at time %s, seconds left: ^COUNT"), seconds_tostring(time)), 1, 10);
 197                                 else if (r > 0.55)
 198                                         centerprint_Add(0, sprintf(_("^1Multiline message at time %s that\n^BOLDlasts longer than normal"), seconds_tostring(time)), 20, 0);
 199                                 else
 200                                         centerprint_AddStandard(sprintf(_("Message at time %s"), seconds_tostring(time)));
 201                                 //hud_configure_cp_generation_time = time + 1 + random()*4;
 202                                 hud_configure_cp_generation_time = time + 1;
 203                         }
 204                         else
 205                         {
 206                                 centerprint_Add(0, _("Generic message"), 10, 0);
 207                                 hud_configure_cp_generation_time = time + 10 - random()*3;
 208                         }
 209                 }
 210         }
 211
 212         HUD_Panel_LoadCvars();
 213
 214         if ( HUD_Radar_Clickable() )
 215         {
 216                 if (hud_panel_radar_bottom >= vid_conheight)
 217                         return;
 218
 219                 panel_pos.x = 0.5 * (vid_conwidth - panel_size.x);
 220                 panel_pos.y = hud_panel_radar_bottom;
 221                 panel_size.y = min(panel_size.y, vid_conheight - hud_panel_radar_bottom);
 222         }
 223         else if(!autocvar__hud_configure && scoreboard_fade_alpha)
 224         {
 225                 vector target_pos = vec2(0.5 * (vid_conwidth - panel_size.x), scoreboard_bottom);
 226                 if(target_pos.y > panel_pos.y)
 227                 {
 228                         panel_pos = panel_pos + (target_pos - panel_pos) * sqrt(scoreboard_fade_alpha);
 229                         panel_size.y = min(panel_size.y, vid_conheight - scoreboard_bottom);
 230                 }
 231
 232                 // move the panel below the scoreboard
 233                 if (panel_pos.y >= vid_conheight)
 234                         return;
 235         }
 236
 237         if (autocvar_hud_panel_centerprint_dynamichud)
 238                 HUD_Scale_Enable();
 239         else
 240                 HUD_Scale_Disable();
 241         HUD_Panel_DrawBg();
 242
 243         if (!centerprint_showing)
 244                 return;
 245
 246         if(panel_bg_padding)
 247         {
 248                 panel_pos += '1 1 0' * panel_bg_padding;
 249                 panel_size -= '2 2 0' * panel_bg_padding;
 250         }
 251
 252         int i, j, k, n, g;
 253         float a = 1, sz, align, current_msg_posY = 0, msg_size;
 254         vector pos;
 255         string ts = "";
 256         bool all_messages_expired = true;
 257
 258         pos = panel_pos;
 259         if (autocvar_hud_panel_centerprint_flip)
 260                 pos.y += panel_size.y;
 261         align = bound(0, autocvar_hud_panel_centerprint_align, 1);
 262
 263         // Show title if available
 264         if(centerprint_title_show) {
 265                 vector fontsize = hud_fontsize * 1.5 * autocvar_hud_panel_centerprint_fontscale_title;
 266                 float width = stringwidth(centerprint_title, true, fontsize);
 267
 268                 pos.x = panel_pos.x + (panel_size.x - width) * align;
 269                 drawcolorcodedstring(pos, centerprint_title, fontsize, 1, DRAWFLAG_NORMAL);
 270
 271                 if (autocvar_hud_panel_centerprint_flip)
 272                         pos.y -= fontsize.y + (hud_fontsize.y * CENTERPRINT_TITLE_SPACING / 2);
 273                 else
 274                         pos.y += fontsize.y + (hud_fontsize.y * CENTERPRINT_TITLE_SPACING / 2);
 275
 276                 drawfill(pos, vec2(width, 1), '1 1 1', 1, DRAWFLAG_NORMAL);
 277
 278                 if (autocvar_hud_panel_centerprint_flip)
 279                         pos.y -= hud_fontsize.y * 1.5 * (CENTERPRINT_TITLE_SPACING / 2);
 280                 else
 281                         pos.y += hud_fontsize.y * 1.5 * (CENTERPRINT_TITLE_SPACING / 2);
 282
 283                 all_messages_expired = false;
 284         }
 285
 286         for (g=0, i=0, j=cpm_index; i<CENTERPRINT_MAX_MSGS; ++i, ++j)
 287         {
 288                 if (j == CENTERPRINT_MAX_MSGS)
 289                         j = 0;
 290                 if (centerprint_expire_time[j] == -1)
 291                 {
 292                         // here we are sure the time variable is not altered by CSQC_Ent_Update
 293                         centerprint_expire_time[j] = time;
 294                         if (centerprint_time[j] > 0)
 295                                 centerprint_expire_time[j] += centerprint_time[j];
 296                 }
 297                 if (centerprint_expire_time[j] <= time)
 298                 {
 299                         if (centerprint_countdown_num[j] && centerprint_time[j] > 0)
 300                         {
 301                                 centerprint_countdown_num[j] = centerprint_countdown_num[j] - 1;
 302                                 if (centerprint_countdown_num[j] == 0)
 303                                         continue;
 304                                 centerprint_expire_time[j] = centerprint_expire_time[j] + centerprint_time[j];
 305                         }
 306                         else if(centerprint_time[j] != -1)
 307                                 continue;
 308                 }
 309
 310                 all_messages_expired = false;
 311
 312                 if (time < centerprint_start_time[j]) continue;
 313
 314                 float fade_in_time = autocvar_hud_panel_centerprint_fade_in;
 315                 float fade_out_time = autocvar_hud_panel_centerprint_fade_out;
 316
 317                 if (centerprint_countdown_num[j]) {
 318                         fade_in_time = autocvar_hud_panel_centerprint_fade_in_short;
 319                         fade_out_time = 0;
 320                 }
 321
 322                 // fade
 323                 if(fade_in_time && centerprint_start_time[j] && time < centerprint_start_time[j] + fade_in_time) // Fade in
 324                         a = (time - centerprint_start_time[j]) / fade_in_time;
 325                 else if(time < centerprint_expire_time[j] - fade_out_time || centerprint_time[j] < 0) // Regularily printed or forced
 326                         a = 1;
 327                 else if(fade_out_time) // Expiring soon, so fade it out.
 328                         a = (centerprint_expire_time[j] - time) / fade_out_time;
 329
 330                 if(centerprint_msgID[j] == ORDINAL(CPID_TIMEIN))
 331                         a = 1;
 332
 333                 // while counting down show it anyway in order to hold the current message position
 334                 if (a <= 0.5/255.0 && centerprint_countdown_num[j] == 0)  // Guaranteed invisible - don't show.
 335                         continue;
 336
 337                 // set the size from fading in/out before subsequent fading
 338                 sz = autocvar_hud_panel_centerprint_fade_minfontsize + a * (1 - autocvar_hud_panel_centerprint_fade_minfontsize);
 339
 340                 // also fade it based on positioning
 341                 if(autocvar_hud_panel_centerprint_fade_subsequent)
 342                 {
 343                         // pass one: all messages after the first have half alpha
 344                         a = a * bound(autocvar_hud_panel_centerprint_fade_subsequent_passone_minalpha, (1 - (g / max(1, autocvar_hud_panel_centerprint_fade_subsequent_passone))), 1);
 345                         // pass two: after that, gradually lower alpha even more for each message
 346                         a = a * bound(autocvar_hud_panel_centerprint_fade_subsequent_passtwo_minalpha, (1 - (g / max(1, autocvar_hud_panel_centerprint_fade_subsequent_passtwo))), 1);
 347                 }
 348                 a *= panel_fg_alpha;
 349
 350                 // finally set the size based on the new alpha from subsequent fading
 351                 // TODO: Apply this only if subsequent, otherwise it fucks it up
 352                 if(g)
 353                         sz = sz * (autocvar_hud_panel_centerprint_fade_subsequent_minfontsize + a * (1 - autocvar_hud_panel_centerprint_fade_subsequent_minfontsize));
 354                 drawfontscale = hud_scale * sz;
 355
 356                 if (centerprint_countdown_num[j])
 357                         n = tokenizebyseparator(strreplace("^COUNT", ftos(centerprint_countdown_num[j]), centerprint_messages[j]), "\n");
 358                 else
 359                         n = tokenizebyseparator(centerprint_messages[j], "\n");
 360
 361                 if (autocvar_hud_panel_centerprint_flip)
 362                 {
 363                         // check if the message can be entirely shown
 364                         for(k = 0; k < n; ++k)
 365                         {
 366                                 getWrappedLine_remaining = argv(k);
 367                                 while(getWrappedLine_remaining)
 368                                 {
 369                                         bool is_bold = (substring(getWrappedLine_remaining, 0, 5) == BOLD_OPERATOR);
 370                                         vector fontsize = hud_fontsize * 1.5 * (is_bold ? autocvar_hud_panel_centerprint_fontscale_bold : autocvar_hud_panel_centerprint_fontscale);
 371
 372                                         ts = getWrappedLine(panel_size.x * hud_scale.x * sz, fontsize, stringwidth_colors);
 373                                         if (ts != "")
 374                                                 pos.y -= fontsize.y;
 375                                         else
 376                                                 pos.y -= fontsize.y * CENTERPRINT_SPACING/2;
 377                                 }
 378                         }
 379                         current_msg_posY = pos.y; // save starting pos (first line) of the current message
 380                 }
 381
 382                 msg_size = pos.y;
 383                 for(k = 0; k < n; ++k)
 384                 {
 385                         getWrappedLine_remaining = argv(k);
 386
 387                         bool is_bold = (substring(getWrappedLine_remaining, 0, 5) == BOLD_OPERATOR);
 388                         vector fontsize = hud_fontsize * 1.5 * (is_bold ? autocvar_hud_panel_centerprint_fontscale_bold : autocvar_hud_panel_centerprint_fontscale);
 389                         if (is_bold)
 390                                 getWrappedLine_remaining = substring(getWrappedLine_remaining, 5, -1);
 391
 392                         while(getWrappedLine_remaining)
 393                         {
 394                                 ts = getWrappedLine(panel_size.x * hud_scale.x * sz, fontsize, stringwidth_colors);
 395                                 if (ts != "")
 396                                 {
 397                                         if (align)
 398                                                 pos.x = panel_pos.x + (panel_size.x - stringwidth(ts, true, fontsize) * sz) * align;
 399                                         if (a > 0.5/255.0)  // Otherwise guaranteed invisible - don't show. This is checked a second time after some multiplications with other factors were done so temporary changes of these cannot cause flicker.
 400                                                 if (is_bold) draw_beginBoldFont();
 401                                                 drawcolorcodedstring(pos + eY * 0.5 * (1 - sz * hud_scale.x) * fontsize.y, ts, fontsize, a, DRAWFLAG_NORMAL);
 402                                                 if (is_bold) draw_endBoldFont();
 403                                         pos.y += fontsize.y;
 404                                 }
 405                                 else
 406                                         pos.y += fontsize.y * CENTERPRINT_SPACING/2;
 407                         }
 408                 }
 409
 410                 ++g; // move next position number up
 411
 412                 msg_size = pos.y - msg_size;
 413
 414                 if (autocvar_hud_panel_centerprint_flip)
 415                 {
 416                         pos.y -= msg_size + CENTERPRINT_SPACING * hud_fontsize.y;
 417                         if (a < 1 && centerprint_msgID[j] == 0) // messages with id can be replaced just after they are faded out, so never move over them the next messages
 418                                 pos.y += (1 - sqrt(a));
 419
 420                         if (pos.y < panel_pos.y) // check if the next message can be shown
 421                         {
 422                                 drawfontscale = hud_scale;
 423                                 return;
 424                         }
 425                 }
 426                 else
 427                 {
 428                         pos.y += CENTERPRINT_SPACING * hud_fontsize.y;
 429                         if (a < 1 && centerprint_msgID[j] == 0) // messages with id can be replaced just after they are faded out, so never move over them the next messages
 430                                 pos.y -= (1 - sqrt(a));
 431
 432                         if(pos.y > panel_pos.y + panel_size.y - hud_fontsize.y) // check if the next message can be shown
 433                         {
 434                                 drawfontscale = hud_scale;
 435                                 return;
 436                         }
 437                 }
 438         }
 439
 440         drawfontscale = hud_scale;
 441         if (all_messages_expired)
 442         {
 443                 centerprint_showing = false;
 444                 centerprint_KillAll();
 445         }
 446 }