qcsrc/client/hud/panel/engineinfo.qc

   1 // Engine info panel (#13)
   2
   3 float prevfps;
   4 float prevfps_time;
   5 int framecounter;
   6
   7 float frametimeavg;
   8 float frametimeavg1; // 1 frame ago
   9 float frametimeavg2; // 2 frames ago
  10 float autocvar_hud_panel_engineinfo_framecounter_exponentialmovingaverage;
  11 float autocvar_hud_panel_engineinfo_framecounter_exponentialmovingaverage_new_weight;
  12 float autocvar_hud_panel_engineinfo_framecounter_exponentialmovingaverage_instantupdate_change_threshold;
  13 void HUD_EngineInfo()
  14 {
  15         if(!autocvar__hud_configure)
  16         {
  17                 if(!autocvar_hud_panel_engineinfo) return;
  18         }
  19
  20         HUD_Panel_UpdateCvars();
  21         vector pos, mySize;
  22         pos = panel_pos;
  23         mySize = panel_size;
  24
  25         HUD_Panel_DrawBg(1);
  26         if(panel_bg_padding)
  27         {
  28                 pos += '1 1 0' * panel_bg_padding;
  29                 mySize -= '2 2 0' * panel_bg_padding;
  30         }
  31
  32         float currentTime = gettime(GETTIME_REALTIME);
  33         if(autocvar_hud_panel_engineinfo_framecounter_exponentialmovingaverage)
  34         {
  35                 float currentframetime = currentTime - prevfps_time;
  36                 frametimeavg = (frametimeavg + frametimeavg1 + frametimeavg2 + currentframetime)/4; // average three frametimes into framecounter for slightly more stable fps readings :P
  37                 frametimeavg2 = frametimeavg1;
  38                 frametimeavg1 = frametimeavg;
  39
  40                 float weight;
  41                 weight = autocvar_hud_panel_engineinfo_framecounter_exponentialmovingaverage_new_weight;
  42                 if(currentframetime > 0.0001) // filter out insane values which sometimes seem to occur and throw off the average? If you are getting 10,000 fps or more, then you don't need a framerate counter.
  43                 {
  44                         if(fabs(prevfps - (1/frametimeavg)) > prevfps * autocvar_hud_panel_engineinfo_framecounter_exponentialmovingaverage_instantupdate_change_threshold) // if there was a big jump in fps, just force prevfps at current (1/currentframetime) to make big updates instant
  45                                 prevfps = (1/currentframetime);
  46                         prevfps = (1 - weight) * prevfps + weight * (1/frametimeavg); // framecounter just used so there's no need for a new variable, think of it as "frametime average"
  47                 }
  48                 prevfps_time = currentTime;
  49         }
  50         else
  51         {
  52                 framecounter += 1;
  53                 if(currentTime - prevfps_time > autocvar_hud_panel_engineinfo_framecounter_time)
  54                 {
  55                         prevfps = framecounter/(currentTime - prevfps_time);
  56                         framecounter = 0;
  57                         prevfps_time = currentTime;
  58                 }
  59         }
  60
  61         vector color;
  62         color = HUD_Get_Num_Color (prevfps, 100);
  63         drawstring_aspect(pos, sprintf(_("FPS: %.*f"), autocvar_hud_panel_engineinfo_framecounter_decimals, prevfps), mySize, color, panel_fg_alpha, DRAWFLAG_NORMAL);
  64 }