qcsrc/client/hud/panel/infomessages.qc

   1 #include "infomessages.qh"
   2
   3 #include <common/ent_cs.qh>
   4 #include <common/mapinfo.qh>
   5
   6 // Info messages panel (#14)
   7
   8 float autocvar_hud_panel_infomessages_group_fadetime = 0.4;
   9 float autocvar_hud_panel_infomessages_group_time = 6;
  10 const int IMG_COUNT = 1; // number of InfoMessage Groups
  11 float img_fade[IMG_COUNT];
  12 int img_cur_msg[IMG_COUNT];
  13 float img_time[IMG_COUNT];
  14
  15 int img_select(int group_id)
  16 {
  17         float fadetime = max(0.001, autocvar_hud_panel_infomessages_group_fadetime);
  18         if(time > img_time[group_id])
  19         {
  20                 img_fade[group_id] = max(0, img_fade[group_id] - frametime / fadetime);
  21                 if(!img_fade[group_id])
  22                 {
  23                         ++img_cur_msg[group_id];
  24                         img_time[group_id] = floor(time) + autocvar_hud_panel_infomessages_group_time;
  25                 }
  26         }
  27         else
  28                 img_fade[group_id] = min(1, img_fade[group_id] + frametime / fadetime);
  29         return img_cur_msg[group_id];
  30 }
  31
  32 float stringwidth_colors(string s, vector theSize);
  33 vector InfoMessages_drawstring(string s, vector pos, vector sz, float a, vector fontsize)
  34 {
  35         getWrappedLine_remaining = s;
  36         float offset = 0;
  37         while(getWrappedLine_remaining)
  38         {
  39                 s = getWrappedLine(sz.x - offset, fontsize, stringwidth_colors);
  40                 if(autocvar_hud_panel_infomessages_flip)
  41                         offset = sz.x - stringwidth_colors(s, fontsize) - offset;
  42                 drawcolorcodedstring(pos + eX * offset, s, fontsize, a, DRAWFLAG_NORMAL);
  43                 pos.y += fontsize.y;
  44                 offset = fontsize.x;
  45         }
  46         return pos;
  47 }
  48
  49 #define InfoMessage(s) MACRO_BEGIN { \
  50         pos = InfoMessages_drawstring(s, pos, mySize, ((img_curr_group >= 0) ? panel_fg_alpha * img_fade[img_curr_group] : panel_fg_alpha), fontsize); \
  51         img_curr_group = -1; \
  52 } MACRO_END
  53
  54 void HUD_InfoMessages()
  55 {
  56         if(!autocvar__hud_configure)
  57         {
  58                 if(!autocvar_hud_panel_infomessages) return;
  59         }
  60
  61         HUD_Panel_UpdateCvars();
  62         vector pos, mySize;
  63         pos = panel_pos;
  64         mySize = panel_size;
  65
  66         if (autocvar_hud_panel_infomessages_dynamichud)
  67                 HUD_Scale_Enable();
  68         else
  69                 HUD_Scale_Disable();
  70         HUD_Panel_DrawBg(1);
  71         if(panel_bg_padding)
  72         {
  73                 pos += '1 1 0' * panel_bg_padding;
  74                 mySize -= '2 2 0' * panel_bg_padding;
  75         }
  76
  77         vector fontsize = '0.2 0.2 0' * mySize.y;
  78         string s;
  79         int img_curr_group = -1;
  80         if(!autocvar__hud_configure)
  81         {
  82                 if(spectatee_status)
  83                 {
  84                         if(spectatee_status == -1)
  85                                 s = _("^1Observing");
  86                         else
  87                                 s = sprintf(_("^1Spectating: ^7%s"), entcs_GetName(current_player));
  88                         InfoMessage(s);
  89
  90                         img_curr_group = 0;
  91                         switch(img_select(img_curr_group) % 3)
  92                         {
  93                                 default:
  94                                 case 0:
  95                                         if(spectatee_status == -1)
  96                                                 s = sprintf(_("^1Press ^3%s^1 to spectate"), getcommandkey(_("primary fire"), "+fire"));
  97                                         else
  98                                                 s = sprintf(_("^1Press ^3%s^1 or ^3%s^1 for next or previous player"), getcommandkey(_("next weapon"), "weapnext"), getcommandkey(_("previous weapon"), "weapprev"));
  99                                         break;
 100                                 case 1:
 101                                         if(spectatee_status == -1)
 102                                                 s = sprintf(_("^1Use ^3%s^1 or ^3%s^1 to change the speed"), getcommandkey(_("next weapon"), "weapnext"), getcommandkey(_("previous weapon"), "weapprev"));
 103                                         else
 104                                                 s = sprintf(_("^1Press ^3%s^1 to observe, ^3%s^1 to change camera mode"), getcommandkey(_("secondary fire"), "+fire2"), getcommandkey(_("drop weapon"), "dropweapon"));
 105                                         break;
 106                                 case 2:
 107                                         s = sprintf(_("^1Press ^3%s^1 for gamemode info"), getcommandkey(_("server info"), "+show_info"));
 108                                         break;
 109                         }
 110                         InfoMessage(s);
 111
 112                         if(gametype == MAPINFO_TYPE_LMS)
 113                         {
 114                                 entity sk;
 115                                 sk = playerslots[player_localnum];
 116                                 if(sk.(scores[ps_primary]) >= 666)
 117                                         s = _("^1Match has already begun");
 118                                 else if(sk.(scores[ps_primary]) > 0)
 119                                         s = _("^1You have no more lives left");
 120                                 else
 121                                         s = sprintf(_("^1Press ^3%s^1 to join"), getcommandkey(_("jump"), "+jump"));
 122                         }
 123                         else
 124                                 s = sprintf(_("^1Press ^3%s^1 to join"), getcommandkey(_("jump"), "+jump"));
 125                         InfoMessage(s);
 126                 }
 127
 128                 if (time < STAT(GAMESTARTTIME))
 129                 {
 130                         //we need to ceil, otherwise the countdown would be off by .5 when using round()
 131                         float countdown = ceil(STAT(GAMESTARTTIME) - time);
 132                         s = sprintf(_("^1Game starts in ^3%d^1 seconds"), countdown);
 133                         InfoMessage(s);
 134                 }
 135
 136                 if(warmup_stage)
 137                 {
 138                         s = _("^2Currently in ^1warmup^2 stage!");
 139                         InfoMessage(s);
 140                 }
 141
 142                 string blinkcolor;
 143                 if(time % 1 >= 0.5)
 144                         blinkcolor = "^1";
 145                 else
 146                         blinkcolor = "^3";
 147
 148                 if(ready_waiting && !spectatee_status)
 149                 {
 150                         if(ready_waiting_for_me)
 151                         {
 152                                 if(warmup_stage)
 153                                         s = sprintf(_("%sPress ^3%s%s to end warmup"), blinkcolor, getcommandkey(_("ready"), "ready"), blinkcolor);
 154                                 else
 155                                         s = sprintf(_("%sPress ^3%s%s once you are ready"), blinkcolor, getcommandkey(_("ready"), "ready"), blinkcolor);
 156                         }
 157                         else
 158                         {
 159                                 if(warmup_stage)
 160                                         s = _("^2Waiting for others to ready up to end warmup...");
 161                                 else
 162                                         s = _("^2Waiting for others to ready up...");
 163                         }
 164                         InfoMessage(s);
 165                 }
 166                 else if(warmup_stage && !spectatee_status)
 167                 {
 168                         s = sprintf(_("^2Press ^3%s^2 to end warmup"), getcommandkey(_("ready"), "ready"));
 169                         InfoMessage(s);
 170                 }
 171
 172                 if(teamplay && !spectatee_status && gametype != MAPINFO_TYPE_CA && teamnagger)
 173                 {
 174                         float ts_min = 0, ts_max = 0;
 175                         entity tm = teams.sort_next;
 176                         if (tm)
 177                         {
 178                                 for (; tm.sort_next; tm = tm.sort_next)
 179                                 {
 180                                         if(!tm.team_size || tm.team == NUM_SPECTATOR)
 181                                                 continue;
 182                                         if(!ts_min) ts_min = tm.team_size;
 183                                         else ts_min = min(ts_min, tm.team_size);
 184                                         if(!ts_max) ts_max = tm.team_size;
 185                                         else ts_max = max(ts_max, tm.team_size);
 186                                 }
 187                                 if ((ts_max - ts_min) > 1)
 188                                 {
 189                                         s = strcat(blinkcolor, _("Teamnumbers are unbalanced!"));
 190                                         tm = GetTeam(myteam, false);
 191                                         if (tm && tm.team != NUM_SPECTATOR && tm.team_size == ts_max)
 192                                                 s = strcat(s, sprintf(_(" Press ^3%s%s to adjust"), getcommandkey(_("team menu"), "menu_showteamselect"), blinkcolor));
 193                                         InfoMessage(s);
 194                                 }
 195                         }
 196                 }
 197         }
 198         else
 199         {
 200                 InfoMessage(_("^7Press ^3ESC ^7to show HUD options."));
 201                 InfoMessage(_("^3Doubleclick ^7a panel for panel-specific options."));
 202                 InfoMessage(_("^3CTRL ^7to disable collision testing, ^3SHIFT ^7and"));
 203                 InfoMessage(_("^3ALT ^7+ ^3ARROW KEYS ^7for fine adjustments."));
 204         }
 205 }