qcsrc/client/hud/panel/strafehud.qc

   1 // Author: Juhu
   2
   3 #include "strafehud.qh"
   4
   5 #include <client/autocvars.qh>
   6 #include <client/miscfunctions.qh>
   7 #include <client/resources.qh>
   8 #include <common/animdecide.qh>
   9 #include <common/ent_cs.qh>
  10 #include <common/mapinfo.qh>
  11 #include <common/physics/movetypes/movetypes.qh>
  12 #include <common/physics/player.qh>
  13 #include <lib/csqcmodel/cl_player.qh>
  14
  15 // StrafeHUD (#25)
  16
  17 void HUD_StrafeHUD_Export(int fh)
  18 {
  19     // allow saving cvars that aesthetically change the panel into hud skin files
  20 }
  21
  22 float hidden_width;
  23 int direction;
  24 float demo_angle = -37;
  25 float demo_direction = 1;
  26 float demo_time = 0;
  27 bool state_onground = false;
  28 float state_onground_time = 0;
  29 bool state_strafekeys = false;
  30 float state_strafekeys_time = 0;
  31 bool turn = false;
  32 float turnangle;
  33 bool fwd = true;
  34 bool state_fwd = true;
  35 bool state_fwd_prev = true;
  36 float state_fwd_time = 0;
  37 float starttime = 0;
  38 float startspeed = -1;
  39 float jumptime = 0;
  40 float jumpheight = -1;
  41 float jumpheight_persistent = -1;
  42 float jumpheight_prev = 0;
  43 float jumpspeed_prev = 0;
  44 bool  jumprestart = true;
  45
  46 // provide basic panel cvars to old clients
  47 // TODO remove them after a future release (0.8.2+)
  48 noref string autocvar_hud_panel_strafehud_pos = "0.320000 0.570000";
  49 noref string autocvar_hud_panel_strafehud_size = "0.360000 0.020000";
  50 noref string autocvar_hud_panel_strafehud_bg = "0";
  51 noref string autocvar_hud_panel_strafehud_bg_color = "";
  52 noref string autocvar_hud_panel_strafehud_bg_color_team = "";
  53 noref string autocvar_hud_panel_strafehud_bg_alpha = "0.7";
  54 noref string autocvar_hud_panel_strafehud_bg_border = "";
  55 noref string autocvar_hud_panel_strafehud_bg_padding = "";
  56
  57 void HUD_StrafeHUD()
  58 {
  59     entity strafeplayer;
  60     bool islocal;
  61
  62     // generic hud routines
  63     if(!autocvar__hud_configure)
  64     {
  65         if(!autocvar_hud_panel_strafehud ||
  66            (spectatee_status == -1 && (autocvar_hud_panel_strafehud == 1 || autocvar_hud_panel_strafehud == 3)) ||
  67            (autocvar_hud_panel_strafehud == 3 && !(ISGAMETYPE(RACE) || ISGAMETYPE(CTS)))) return;
  68     }
  69
  70     HUD_Panel_LoadCvars();
  71
  72     if(autocvar_hud_panel_strafehud_dynamichud)
  73     {
  74         HUD_Scale_Enable();
  75     }
  76     else
  77     {
  78         HUD_Scale_Disable();
  79     }
  80
  81     HUD_Panel_DrawBg();
  82
  83     if(panel_bg_padding)
  84     {
  85         panel_pos  += '1 1 0' * panel_bg_padding;
  86         panel_size -= '2 2 0' * panel_bg_padding;
  87     }
  88
  89     // find out whether the local csqcmodel entity is valid
  90     if(spectatee_status > 0 || isdemo())
  91     {
  92         islocal = false;
  93         strafeplayer = CSQCModel_server2csqc(player_localentnum - 1);
  94     }
  95     else
  96     {
  97         islocal = true;
  98         strafeplayer = csqcplayer;
  99     }
 100
 101     // draw strafehud
 102     if(csqcplayer && strafeplayer)
 103     {
 104         // physics
 105         bool   onground                      = islocal ? IS_ONGROUND(strafeplayer) : !(strafeplayer.anim_implicit_state & ANIMIMPLICITSTATE_INAIR);
 106         bool   strafekeys;
 107         bool   swimming                      = strafeplayer.waterlevel >= WATERLEVEL_SWIMMING;
 108         bool   spectating                    = entcs_GetSpecState(strafeplayer.sv_entnum) == ENTCS_SPEC_PURE;
 109         float  speed                         = !autocvar__hud_configure ? vlen(vec2(csqcplayer.velocity)) : 1337; // use local csqcmodel entity for this even when spectating, flickers too much otherwise
 110         float  maxspeed_crouch_mod           = IS_DUCKED(strafeplayer) && !swimming ? .5 : 1;
 111         float  maxspeed_water_mod            = swimming ? .7 : 1; // very simplified water physics, the hud will not work well (and is not supposed to) while swimming
 112         float  maxspeed_phys                 = onground ? PHYS_MAXSPEED(strafeplayer) : PHYS_MAXAIRSPEED(strafeplayer);
 113         float  maxspeed                      = !autocvar__hud_configure ? maxspeed_phys * maxspeed_crouch_mod * maxspeed_water_mod : 320;
 114         float  vel_angle                     = vectoangles(strafeplayer.velocity).y;
 115         float  view_angle                    = PHYS_INPUT_ANGLES(strafeplayer).y + 180;
 116         float  angle;
 117         vector movement                      = PHYS_INPUT_MOVEVALUES(strafeplayer);
 118         int    keys                          = STAT(PRESSED_KEYS);
 119         int    keys_fwd;
 120         float  wishangle                     = 0;
 121
 122         // HUD
 123         int    mode                          = autocvar_hud_panel_strafehud_mode >= 0 && autocvar_hud_panel_strafehud_mode <= 1 ? autocvar_hud_panel_strafehud_mode : 0;
 124         float  speed_conversion_factor       = GetSpeedUnitFactor(autocvar_hud_panel_strafehud_unit);
 125         float  length_conversion_factor      = GetLengthUnitFactor(autocvar_hud_panel_strafehud_unit);
 126         string speed_unit                    = GetSpeedUnit(autocvar_hud_panel_strafehud_unit);
 127         string length_unit                   = GetLengthUnit(autocvar_hud_panel_strafehud_unit);
 128         int    length_decimals               = autocvar_hud_panel_strafehud_unit >= 3 && autocvar_hud_panel_strafehud_unit <= 5 ? 6 : 2; // use more decimals when displaying km or miles
 129         float  antiflicker_angle             = bound(0, autocvar_hud_panel_strafehud_antiflicker_angle, 180);
 130         float  antiflicker_speed             = max(0, autocvar_hud_panel_strafehud_antiflicker_speed);
 131         float  minspeed;
 132         float  shift_offset                  = 0;
 133         bool   straight_overturn             = false;
 134         bool   immobile                      = speed <= (swimming ? antiflicker_speed : 0);
 135         float  hudangle;
 136         float  neutral_offset;
 137         float  neutral_width;
 138         vector currentangle_color            = autocvar_hud_panel_strafehud_angle_neutral_color;
 139         float  currentangle_offset;
 140         vector currentangle_size             = '0 0 0';
 141         float  bestangle;
 142         float  odd_bestangle;
 143         bool   bestangle_anywhere            = false;
 144         float  bestangle_offset;
 145         float  switch_bestangle_offset;
 146         bool   odd_angles                    = false;
 147         float  odd_bestangle_offset          = 0;
 148         float  switch_odd_bestangle_offset   = 0;
 149         float  bestangle_width;
 150         float  accelzone_left_offset;
 151         float  accelzone_right_offset;
 152         float  accelzone_width;
 153         float  overturn_offset;
 154         float  overturn_width;
 155         float  slickdetector_height;
 156         vector direction_size_vertical       = '0 0 0';
 157         vector direction_size_horizontal     = '0 0 0';
 158         float  range_minangle;
 159
 160         // determine whether the player is pressing forwards or backwards keys
 161         if(islocal) // if entity is local player
 162         {
 163             if(movement.x > 0)
 164             {
 165                 keys_fwd = 1;
 166             }
 167             else if(movement.x < 0)
 168             {
 169                 keys_fwd = -1;
 170             }
 171             else
 172             {
 173                 keys_fwd = 0;
 174             }
 175         }
 176         else // alternatively determine direction by querying pressed keys
 177         {
 178             if((keys & KEY_FORWARD) && !(keys & KEY_BACKWARD))
 179             {
 180                 keys_fwd = 1;
 181             }
 182             else if(!(keys & KEY_FORWARD) && (keys & KEY_BACKWARD))
 183             {
 184                 keys_fwd = -1;
 185             }
 186             else
 187             {
 188                 keys_fwd = 0;
 189             }
 190         }
 191
 192         // determine player wishdir
 193         if(islocal) // if entity is local player
 194         {
 195             if(movement.x == 0)
 196             {
 197                 if(movement.y < 0)
 198                 {
 199                     wishangle = -90;
 200                 }
 201                 else if(movement.y > 0)
 202                 {
 203                     wishangle = 90;
 204                 }
 205                 else
 206                 {
 207                     wishangle = 0;
 208                 }
 209             }
 210             else
 211             {
 212                 if(movement.y == 0)
 213                 {
 214                     wishangle = 0;
 215                 }
 216                 else
 217                 {
 218                     wishangle = RAD2DEG * atan2(movement.y, movement.x);
 219                     // wrap the wish angle if it exceeds ±90°
 220                     if(fabs(wishangle) > 90)
 221                     {
 222                         if(wishangle < 0) wishangle += 180;
 223                         else wishangle -= 180;
 224                         wishangle = -wishangle;
 225                     }
 226                 }
 227             }
 228         }
 229         else // alternatively calculate wishdir by querying pressed keys
 230         {
 231             if(keys & KEY_FORWARD || keys & KEY_BACKWARD)
 232             {
 233                 wishangle = 45;
 234             }
 235             else
 236             {
 237                 wishangle = 90;
 238             }
 239             if(keys & KEY_LEFT)
 240             {
 241                 wishangle *= -1;
 242             }
 243             else if(!(keys & KEY_RIGHT))
 244             {
 245                 wishangle = 0; // wraps at 180°
 246             }
 247         }
 248
 249         strafekeys = fabs(wishangle) == 90;
 250
 251         // determine minimum required angle to display full strafe range
 252         range_minangle = fabs(wishangle) % 90; // maximum range is 90 degree
 253         if(range_minangle > 45) // minimum angle range is 45
 254         {
 255             range_minangle = 45 - fabs(wishangle) % 45;
 256         }
 257         range_minangle = 90 - range_minangle; // calculate value which is never >90 or <45
 258         range_minangle *= 2; // multiply to accommodate for both sides of the hud
 259
 260         if(autocvar_hud_panel_strafehud_range == 0)
 261         {
 262             if(autocvar__hud_configure)
 263             {
 264                 hudangle = 90;
 265             }
 266             else
 267             {
 268                 hudangle = range_minangle; // use minimum angle required if dynamically setting hud angle
 269             }
 270         }
 271         else
 272         {
 273             hudangle = bound(0, fabs(autocvar_hud_panel_strafehud_range), 360); // limit HUD range to 360 degrees, higher values don't make sense
 274         }
 275
 276         // detect air strafe turning
 277         if(onground != state_onground)
 278         {
 279             state_onground_time = time;
 280         }
 281         state_onground = onground;
 282
 283         if(strafekeys != state_strafekeys)
 284         {
 285             state_strafekeys_time = time;
 286         }
 287         state_strafekeys = strafekeys;
 288
 289         if((keys & KEY_FORWARD) || (keys & KEY_BACKWARD) || swimming || autocvar__hud_configure)
 290         {
 291             turn = false;
 292         }
 293         else if(onground)
 294         {
 295             if((time - state_onground_time) >= autocvar_hud_panel_strafehud_timeout_ground) // timeout for strafe jumping in general
 296             {
 297                 turn = false;
 298             }
 299         }
 300         else // air strafe only
 301         {
 302             if(strafekeys)
 303             {
 304                 if(((time - state_onground_time) >= autocvar_hud_panel_strafehud_timeout_air) || (keys & KEY_JUMP)) // timeout for slick ramps
 305                 {
 306                     turn = true; // CPMA turning
 307                     turnangle = wishangle;
 308                 }
 309             }
 310             else if((time - state_strafekeys_time) >= autocvar_hud_panel_strafehud_timeout_turn) // timeout for jumping with strafe keys only
 311             {
 312                 turn = false;
 313             }
 314         }
 315         if(turn)
 316         {
 317             maxspeed = PHYS_MAXAIRSTRAFESPEED(strafeplayer); // no modifiers here because they don't affect air strafing
 318             wishangle = turnangle;
 319         }
 320
 321         minspeed = autocvar_hud_panel_strafehud_switch_minspeed < 0 ? maxspeed + antiflicker_speed : autocvar_hud_panel_strafehud_switch_minspeed;
 322
 323         // get current strafing angle ranging from -180° to +180°
 324         if(!autocvar__hud_configure)
 325         {
 326             if(speed > 0)
 327             {
 328                 // calculate view angle relative to the players current velocity direction
 329                 angle = vel_angle - view_angle;
 330
 331                 // if the angle goes above 180° or below -180° wrap it to the opposite side
 332                 if (angle > 180) angle -= 360;
 333                 else if(angle < -180) angle += 360;
 334
 335                 // shift the strafe angle by 180° for hud calculations
 336                 if(angle < 0) angle += 180;
 337                 else angle -= 180;
 338
 339                 // determine whether the player is strafing forwards or backwards
 340                 // if the player isn't strafe turning use forwards/backwards keys to determine direction
 341                 if(!strafekeys)
 342                 {
 343                     if(keys_fwd > 0)
 344                     {
 345                         state_fwd = true;
 346                     }
 347                     else if(keys_fwd < 0)
 348                     {
 349                         state_fwd = false;
 350                     }
 351                     else
 352                     {
 353                         state_fwd = fabs(angle) <= 90;
 354                     }
 355                 }
 356                 // otherwise determine by examining the strafe angle
 357                 else
 358                 {
 359                     if(wishangle < 0) // detect direction using wishangle since the direction is not yet set
 360                     {
 361                         state_fwd = angle <= -wishangle;
 362                     }
 363                     else
 364                     {
 365                         state_fwd = angle >= -wishangle;
 366                     }
 367                 }
 368
 369                 if(state_fwd_prev != state_fwd)
 370                 {
 371                     state_fwd_time = time;
 372                 }
 373                 state_fwd_prev = state_fwd;
 374
 375                 if((time - state_fwd_time) >= autocvar_hud_panel_strafehud_timeout_direction || speed < maxspeed || (strafekeys && mode == 0)) // timeout when changing between forwards and backwards movement
 376                 {
 377                     fwd = state_fwd;
 378                 }
 379
 380                 // shift the strafe angle by 180° when strafing backwards
 381                 if(!fwd)
 382                 {
 383                     if(angle < 0) angle += 180;
 384                     else angle -= 180;
 385                 }
 386
 387                 // don't make the angle indicator switch side too much at ±180° if anti flicker is turned on
 388                 if(angle > (180 - antiflicker_angle) || angle < (-180 + antiflicker_angle))
 389                 {
 390                     straight_overturn = true;
 391                 }
 392             }
 393             else
 394             {
 395                 angle = 0;
 396             }
 397         }
 398         else // simulate turning for HUD setup
 399         {
 400             fwd = true;
 401             if(autocvar__hud_panel_strafehud_demo && ((time - demo_time) >= .025))
 402             {
 403                 demo_time = time;
 404                 demo_angle += demo_direction;
 405                 if(fabs(demo_angle) >= 55)
 406                 {
 407                     demo_direction = -demo_direction;
 408                 }
 409             }
 410             angle = demo_angle;
 411             wishangle = 45 * (demo_angle > 0 ? 1 : -1);
 412         }
 413
 414         // invert the wish angle when strafing backwards
 415         if(!fwd)
 416         {
 417             wishangle = -wishangle;
 418         }
 419
 420         // flip angles if v_flipped is enabled
 421         if(autocvar_v_flipped)
 422         {
 423             angle = -angle;
 424             wishangle = -wishangle;
 425         }
 426
 427         // determine whether the player is strafing left or right
 428         if(wishangle != 0)
 429         {
 430             direction = wishangle > 0 ? 1 : -1;
 431         }
 432         else
 433         {
 434             direction = (angle > antiflicker_angle && angle < (180 - antiflicker_angle)) ? 1 : (angle < -antiflicker_angle && angle > (-180 + antiflicker_angle)) ? -1 : 0;
 435         }
 436
 437         // best angle to strafe at
 438         bestangle = (speed > maxspeed ? acos(maxspeed / speed) : 0) * RAD2DEG * (direction < 0 ? -1 : 1);
 439         odd_bestangle = -bestangle - wishangle;
 440         bestangle -= wishangle;
 441
 442         // various offsets and size calculations of hud indicator elements
 443         // how much is hidden by the current hud angle
 444         hidden_width = (360 - hudangle) / hudangle * panel_size.x;
 445         // current angle
 446         currentangle_size.x = max(panel_size.x * autocvar_hud_panel_strafehud_angle_width, 1);
 447         if(mode == 0)
 448         {
 449             currentangle_offset = angle/hudangle * panel_size.x;
 450         }
 451         else
 452         {
 453             currentangle_offset = bound(-hudangle/2, angle, hudangle/2)/hudangle * panel_size.x + panel_size.x/2;
 454         }
 455         currentangle_size.y = max(panel_size.y * min(autocvar_hud_panel_strafehud_angle_height, 2), 1);
 456         // best strafe acceleration angle
 457         bestangle_offset        =  bestangle/hudangle * panel_size.x + panel_size.x/2;
 458         switch_bestangle_offset = -bestangle/hudangle * panel_size.x + panel_size.x/2;
 459         bestangle_width = max(panel_size.x * autocvar_hud_panel_strafehud_switch_width, 1);
 460
 461         if(((angle > -wishangle && direction < 0) || (angle < -wishangle && direction > 0)) && (direction != 0))
 462         {
 463             odd_angles = true;
 464             odd_bestangle_offset = odd_bestangle/hudangle * panel_size.x + panel_size.x/2;
 465             switch_odd_bestangle_offset = (odd_bestangle+bestangle*2)/hudangle * panel_size.x + panel_size.x/2;
 466         }
 467         // direction indicator
 468         direction_size_vertical.x = max(panel_size.y * min(autocvar_hud_panel_strafehud_direction_width, .5), 1);
 469         direction_size_vertical.y = panel_size.y;
 470         direction_size_horizontal.x = max(panel_size.x * min(autocvar_hud_panel_strafehud_direction_length, .5), direction_size_vertical.x);
 471         direction_size_horizontal.y = direction_size_vertical.x;
 472         // overturn
 473         overturn_width = 180/hudangle * panel_size.x;
 474
 475         // the neutral zone fills the whole strafe bar
 476         if(immobile)
 477         {
 478             // draw neutral zone
 479             if(panel_size.x > 0 && panel_size.y > 0 && autocvar_hud_panel_strafehud_bar_neutral_alpha * panel_fg_alpha > 0)
 480             {
 481                 switch(autocvar_hud_panel_strafehud_style)
 482                 {
 483                     default:
 484                     case 0:
 485                         drawfill(panel_pos, panel_size, autocvar_hud_panel_strafehud_bar_neutral_color, autocvar_hud_panel_strafehud_bar_neutral_alpha * panel_fg_alpha, DRAWFLAG_NORMAL);
 486                         break;
 487
 488                     case 1:
 489                         HUD_Panel_DrawProgressBar(panel_pos, panel_size, "progressbar", 1, 0, 0, autocvar_hud_panel_strafehud_bar_neutral_color, autocvar_hud_panel_strafehud_bar_neutral_alpha * panel_fg_alpha, DRAWFLAG_NORMAL);
 490                 }
 491             }
 492         }
 493         else
 494         {
 495             // calculate various zones of the strafe-o-meter
 496             accelzone_width = overturn_offset = (90 - fabs(bestangle + wishangle))/hudangle * panel_size.x;
 497             accelzone_right_offset = 0;
 498             accelzone_left_offset = overturn_offset + overturn_width;
 499             neutral_width = 360/hudangle * panel_size.x - accelzone_width*2 - overturn_width;
 500             neutral_offset = direction < 0 ? accelzone_left_offset + accelzone_width : -neutral_width;
 501
 502             // remove switch indicator width from offset
 503             if(direction < 0)
 504             {
 505                 bestangle_offset -= bestangle_width;
 506                 switch_odd_bestangle_offset -= bestangle_width;
 507             }
 508             else
 509             {
 510                 switch_bestangle_offset -= bestangle_width;
 511                 odd_bestangle_offset -= bestangle_width;
 512             }
 513
 514             // shift hud if operating in view angle centered mode
 515             if(mode == 0)
 516             {
 517                 shift_offset = -currentangle_offset;
 518                 bestangle_offset += shift_offset;
 519                 switch_bestangle_offset += shift_offset;
 520                 odd_bestangle_offset += shift_offset;
 521                 switch_odd_bestangle_offset += shift_offset;
 522             }
 523             if(direction < 0) shift_offset += -360/hudangle * panel_size.x;
 524             // calculate how far off-center the strafe zones currently are
 525             shift_offset += (panel_size.x + neutral_width)/2 - wishangle/hudangle * panel_size.x;
 526             // shift strafe zones into correct place
 527             neutral_offset += shift_offset;
 528             accelzone_left_offset += shift_offset;
 529             accelzone_right_offset += shift_offset;
 530             overturn_offset += shift_offset;
 531
 532             // draw left acceleration zone
 533             HUD_Panel_DrawStrafeHUD(accelzone_left_offset, accelzone_width, autocvar_hud_panel_strafehud_bar_accel_color, autocvar_hud_panel_strafehud_bar_accel_alpha * panel_fg_alpha, autocvar_hud_panel_strafehud_style, 1);
 534
 535             // draw right acceleration zone
 536             HUD_Panel_DrawStrafeHUD(accelzone_right_offset, accelzone_width, autocvar_hud_panel_strafehud_bar_accel_color, autocvar_hud_panel_strafehud_bar_accel_alpha * panel_fg_alpha, autocvar_hud_panel_strafehud_style, 2);
 537
 538             // draw overturn zone
 539             HUD_Panel_DrawStrafeHUD(overturn_offset, overturn_width, autocvar_hud_panel_strafehud_bar_overturn_color, autocvar_hud_panel_strafehud_bar_overturn_alpha * panel_fg_alpha, autocvar_hud_panel_strafehud_style, 3);
 540
 541             // draw neutral zone
 542             HUD_Panel_DrawStrafeHUD(neutral_offset, neutral_width, autocvar_hud_panel_strafehud_bar_neutral_color, autocvar_hud_panel_strafehud_bar_neutral_alpha * panel_fg_alpha, autocvar_hud_panel_strafehud_style, 0);
 543
 544             if(direction != 0 && direction_size_vertical.x > 0 && autocvar_hud_panel_strafehud_direction_alpha * panel_fg_alpha > 0)
 545             {
 546                 bool indicator_direction = direction < 0;
 547                 // invert left/right when strafing backwards or when strafing towards the opposite side indicated by the direction variable
 548                 // if both conditions are true then it's inverted twice hence not inverted at all
 549                 if(!fwd != odd_angles)
 550                 {
 551                     indicator_direction = !indicator_direction;
 552                 }
 553                 // draw the direction indicator caps at the sides of the hud
 554                 // vertical line
 555                 if(direction_size_vertical.y > 0) drawfill(panel_pos + eX * (indicator_direction ? -direction_size_vertical.x : panel_size.x), direction_size_vertical, autocvar_hud_panel_strafehud_direction_color, autocvar_hud_panel_strafehud_direction_alpha * panel_fg_alpha, DRAWFLAG_NORMAL);
 556                 // top horizontal line
 557                 drawfill(panel_pos + eX * (indicator_direction ? -direction_size_vertical.x : panel_size.x - direction_size_horizontal.x + direction_size_vertical.x) - eY * direction_size_horizontal.y, direction_size_horizontal, autocvar_hud_panel_strafehud_direction_color, autocvar_hud_panel_strafehud_direction_alpha * panel_fg_alpha, DRAWFLAG_NORMAL);
 558                 // bottom horizontal line
 559                 drawfill(panel_pos + eX * (indicator_direction ? -direction_size_vertical.x : panel_size.x - direction_size_horizontal.x + direction_size_vertical.x) + eY * panel_size.y, direction_size_horizontal, autocvar_hud_panel_strafehud_direction_color, autocvar_hud_panel_strafehud_direction_alpha * panel_fg_alpha, DRAWFLAG_NORMAL);
 560             }
 561
 562             if(speed >= minspeed) // only draw indicators if minspeed is reached
 563             {
 564                 // draw best angles for acceleration
 565                 float offset = !odd_angles ? bestangle_offset : odd_bestangle_offset;
 566                 float switch_offset = !odd_angles ? switch_bestangle_offset : switch_odd_bestangle_offset;
 567                 // both indicators are inactive if no direction can be determined
 568                 vector switch_color = direction != 0 ? autocvar_hud_panel_strafehud_switch_active_color : autocvar_hud_panel_strafehud_switch_inactive_color;
 569                 float switch_alpha = direction != 0 ? autocvar_hud_panel_strafehud_switch_active_alpha : autocvar_hud_panel_strafehud_switch_inactive_alpha;
 570                 // draw the switch indicators
 571                 HUD_Panel_DrawStrafeHUD(switch_offset, bestangle_width, autocvar_hud_panel_strafehud_switch_inactive_color, autocvar_hud_panel_strafehud_switch_inactive_alpha * panel_fg_alpha, 0, 0);
 572                 HUD_Panel_DrawStrafeHUD(offset, bestangle_width, switch_color, switch_alpha * panel_fg_alpha, 0, 0);
 573             }
 574         }
 575
 576         // experimental: slick detector
 577         slickdetector_height = panel_size.y * bound(0, autocvar_hud_panel_strafehud_slickdetector_height, 0.5);
 578         if(autocvar_hud_panel_strafehud_slickdetector_range > 0 && autocvar_hud_panel_strafehud_slickdetector_alpha > 0 && slickdetector_height > 0 && panel_size.x > 0) // dunno if slick detection works in spectate
 579         {
 580             float slicksteps = 90 / pow(2, bound(0, autocvar_hud_panel_strafehud_slickdetector_granularity, 4));
 581             bool slickdetected = false;
 582
 583             slickdetected = IS_ONSLICK(strafeplayer); // don't need to traceline if already touching slick
 584
 585             // traceline into every direction
 586             trace_dphitq3surfaceflags = 0;
 587             for(float i = 0; i < 360 && !slickdetected; i += slicksteps)
 588             {
 589                 vector slickoffset;
 590                 float slickrotate;
 591                 slickoffset.z = -cos(i * DEG2RAD) * autocvar_hud_panel_strafehud_slickdetector_range;
 592                 slickrotate = sin(i * DEG2RAD) * autocvar_hud_panel_strafehud_slickdetector_range;
 593                 if(i != 0 && i != 180)
 594                 {
 595                     for(float j = 0; j < 180 && !slickdetected; j += slicksteps)
 596                     {
 597                         slickoffset.x = sin(j * DEG2RAD) * slickrotate;
 598                         slickoffset.y = cos(j * DEG2RAD) * slickrotate;
 599
 600                         traceline(strafeplayer.origin, strafeplayer.origin + slickoffset, MOVE_WORLDONLY, NULL);
 601                         if(trace_dphitq3surfaceflags & Q3SURFACEFLAG_SLICK) slickdetected = true;
 602                     }
 603                 }
 604                 else
 605                 {
 606                     slickoffset.x = slickoffset.y = 0;
 607                     traceline(strafeplayer.origin, strafeplayer.origin + slickoffset, MOVE_WORLDONLY, NULL);
 608                     if(trace_dphitq3surfaceflags & Q3SURFACEFLAG_SLICK) slickdetected = true;
 609                 }
 610             }
 611
 612             // if a traceline hit a slick surface
 613             if(slickdetected)
 614             {
 615                 vector slickdetector_size = panel_size;
 616                 slickdetector_size.y = slickdetector_height;
 617                 // top horizontal line
 618                 drawfill(panel_pos - eY * slickdetector_size.y, slickdetector_size, autocvar_hud_panel_strafehud_slickdetector_color, autocvar_hud_panel_strafehud_slickdetector_alpha * panel_fg_alpha, DRAWFLAG_NORMAL);
 619                 // bottom horizontal line
 620                 drawfill(panel_pos + eY * panel_size.y, slickdetector_size, autocvar_hud_panel_strafehud_slickdetector_color, autocvar_hud_panel_strafehud_slickdetector_alpha * panel_fg_alpha, DRAWFLAG_NORMAL);
 621             }
 622         }
 623
 624         draw_beginBoldFont();
 625         // show speed when crossing the start trigger
 626         if(autocvar_hud_panel_strafehud_startspeed_fade > 0)
 627         {
 628             float text_alpha = 0;
 629             if(race_checkpoint == 254) // checkpoint 254 is the start trigger
 630             {
 631                 if(starttime != race_checkpointtime)
 632                 {
 633                     starttime = race_checkpointtime;
 634                     startspeed = speed;
 635                 }
 636             }
 637             if(startspeed >= 0)
 638             {
 639                 text_alpha = cos(((time - starttime) / autocvar_hud_panel_strafehud_startspeed_fade) * 90 * DEG2RAD); // fade non-linear like the physics panel does
 640                 if((time - starttime) > autocvar_hud_panel_strafehud_startspeed_fade)
 641                 {
 642                     startspeed = -1;
 643                 }
 644             }
 645             if(startspeed >= 0 && text_alpha > 0 && autocvar_hud_panel_strafehud_startspeed_size > 0)
 646             {
 647                 vector startspeed_size = panel_size;
 648                 startspeed_size.y = panel_size.y * min(autocvar_hud_panel_strafehud_startspeed_size, 5);
 649                 drawstring_aspect(panel_pos + eY * panel_size.y, strcat(ftos_decimals(startspeed * speed_conversion_factor, 2), autocvar_hud_panel_strafehud_unit_show ? speed_unit : ""), startspeed_size, autocvar_hud_panel_strafehud_startspeed_color, text_alpha * panel_fg_alpha, DRAWFLAG_NORMAL);
 650             }
 651         }
 652         else
 653         {
 654             starttime = 0;
 655             startspeed = -1;
 656         }
 657
 658         // experimental: show height achieved by a single jump (doesn't work in low gravity and may not be 100% accurate)
 659         if(autocvar_hud_panel_strafehud_jumpheight_fade > 0)
 660         {
 661             float text_alpha = 0;
 662             float jumpheight_min = max(autocvar_hud_panel_strafehud_jumpheight_min, 0);
 663             float jumpheight_current = strafeplayer.origin.z;
 664             float jumpspeed_current = strafeplayer.velocity.z;
 665             if(jumpspeed_prev <= jumpspeed_current || jumpheight_prev > jumpheight_current || IS_ONGROUND(strafeplayer) || swimming || IS_DEAD(strafeplayer) || spectating)
 666             {
 667                 // tries to catch kill and spectate but those are not reliable, should just hook to kill/spectate/teleport and reset jump height there
 668                 jumprestart = true;
 669             }
 670             else
 671             {
 672                 if(jumpheight < 0 || jumprestart)
 673                 {
 674                     jumprestart = false;
 675                     jumpheight = 0;
 676                 }
 677                 else
 678                 {
 679                     jumpheight += jumpheight_current - jumpheight_prev;
 680                 }
 681                 if((jumpheight * length_conversion_factor) > jumpheight_min && jumpheight > jumpheight_persistent)
 682                 {
 683                     jumptime = time;
 684                     jumpheight_persistent = jumpheight;
 685                 }
 686             }
 687             jumpheight_prev = jumpheight_current;
 688             jumpspeed_prev = jumpspeed_current;
 689             if(jumpheight_persistent > 0)
 690             {
 691                 text_alpha = cos(((time - jumptime) / autocvar_hud_panel_strafehud_jumpheight_fade) * 90 * DEG2RAD); // fade non-linear like the physics panel does
 692                 if((time - jumptime) > autocvar_hud_panel_strafehud_jumpheight_fade)
 693                 {
 694                     jumpheight_persistent = -1;
 695                 }
 696             }
 697             if(jumpheight_persistent > 0 && text_alpha > 0 && autocvar_hud_panel_strafehud_jumpheight_size > 0)
 698             {
 699                 vector jumpheight_size = panel_size;
 700                 jumpheight_size.y = panel_size.y * min(autocvar_hud_panel_strafehud_jumpheight_size, 5);
 701                 drawstring_aspect(panel_pos - eY * jumpheight_size.y, strcat(ftos_decimals(jumpheight_persistent * length_conversion_factor, length_decimals), autocvar_hud_panel_strafehud_unit_show ? length_unit : ""), jumpheight_size, autocvar_hud_panel_strafehud_jumpheight_color, text_alpha * panel_fg_alpha, DRAWFLAG_NORMAL);
 702             }
 703         }
 704         else
 705         {
 706             jumpheight_prev = jumpspeed_prev = 0;
 707             jumpheight = jumpheight_persistent = -1;
 708         }
 709         draw_endBoldFont();
 710
 711         if(speed < (maxspeed + antiflicker_speed) && !immobile)
 712         {
 713             bestangle_anywhere = true; // moving forward should suffice to gain speed
 714         }
 715
 716         // draw the actual strafe angle
 717         if(!bestangle_anywhere && !immobile) // player gains speed with strafing
 718         {
 719             if((direction > 0 && (angle >= bestangle || angle <= -(bestangle + wishangle*2))) ||
 720                (direction < 0 && (angle <= bestangle || angle >= -(bestangle + wishangle*2))))
 721             currentangle_color = autocvar_hud_panel_strafehud_angle_accel_color;
 722         }
 723
 724         if(fabs(angle + wishangle) > 90) // player is overturning
 725         {
 726             currentangle_color = autocvar_hud_panel_strafehud_angle_overturn_color;
 727         }
 728         else if(bestangle_anywhere) // player gains speed without strafing
 729         {
 730             currentangle_color = autocvar_hud_panel_strafehud_angle_accel_color;
 731         }
 732
 733         if(mode == 0 || straight_overturn)
 734         {
 735             currentangle_offset = panel_size.x/2;
 736         }
 737
 738         if(autocvar_hud_panel_strafehud_style == 2 && !immobile)
 739         {
 740             float moveangle = angle + wishangle;
 741             float strafeangle = (bestangle + wishangle) * (direction < 0 ? -1 : 1);
 742             float strafe_ratio = 0;
 743             if(fabs(moveangle) > 90)
 744             {
 745                 strafe_ratio = -((fabs(moveangle) - 90) / 90);
 746                 if(strafe_ratio < -1) strafe_ratio = -2 - strafe_ratio;
 747             }
 748             else
 749             {
 750                 if(moveangle >= strafeangle)
 751                 {
 752                     strafe_ratio = 1 - (moveangle - strafeangle) / (90 - strafeangle);
 753                 }
 754                 else if(moveangle <= -strafeangle)
 755                 {
 756                     strafe_ratio = 1 - (moveangle + strafeangle) / (-90 + strafeangle);
 757                 }
 758             }
 759             if(strafe_ratio < 0)
 760             {
 761                 currentangle_color = StrafeHUD_mixColors(autocvar_hud_panel_strafehud_angle_neutral_color, autocvar_hud_panel_strafehud_angle_overturn_color, -strafe_ratio);
 762             }
 763             else
 764             {
 765                 currentangle_color = StrafeHUD_mixColors(autocvar_hud_panel_strafehud_angle_neutral_color, autocvar_hud_panel_strafehud_angle_accel_color, strafe_ratio);
 766             }
 767         }
 768
 769         if(currentangle_size.x > 0 && currentangle_size.y > 0 && autocvar_hud_panel_strafehud_angle_alpha * panel_fg_alpha > 0)
 770         {
 771             drawfill(panel_pos - eY * ((currentangle_size.y - panel_size.y) / 2) + eX * (currentangle_offset - currentangle_size.x/2), currentangle_size, currentangle_color, autocvar_hud_panel_strafehud_angle_alpha * panel_fg_alpha, DRAWFLAG_NORMAL);
 772         }
 773     }
 774 }
 775
 776 // functions to make hud elements align perfectly in the hud area
 777 void HUD_Panel_DrawStrafeHUD(float offset, float width, vector color, float alpha, int type, int gradientType)
 778 {
 779     float mirror_offset, mirror_width;
 780     vector size = panel_size;
 781     vector mirror_size = panel_size;
 782
 783     float original_width = width;
 784     float hiddencolor_width;
 785
 786     if(alpha <= 0 && type != 2 || width <= 0) return;
 787
 788     if(type == 2 && gradientType == 0) type = 0;
 789
 790     if(offset < 0)
 791     {
 792         mirror_width = min(fabs(offset), width);
 793         mirror_offset = panel_size.x + hidden_width - fabs(offset);
 794         width += offset;
 795         offset = 0;
 796     }
 797     else
 798     {
 799         mirror_width = min(offset + width - panel_size.x - hidden_width, width);
 800         mirror_offset = max(offset - panel_size.x - hidden_width, 0);
 801     }
 802     if((offset + width) > panel_size.x)
 803     {
 804         width = panel_size.x - offset;
 805     }
 806     if(mirror_offset < 0)
 807     {
 808         mirror_width += mirror_offset;
 809         mirror_offset = 0;
 810     }
 811     if((mirror_offset + mirror_width) > panel_size.x)
 812     {
 813         mirror_width = panel_size.x - mirror_offset;
 814     }
 815
 816     if(width < 0) width = 0;
 817     if(mirror_width < 0) mirror_width = 0;
 818     hiddencolor_width = original_width - width - mirror_width;
 819
 820     if(direction < 0) // swap mirror and non-mirror values if direction points left
 821     {
 822         offset += mirror_offset;
 823         mirror_offset = offset - mirror_offset;
 824         offset -= mirror_offset;
 825
 826         width += mirror_width;
 827         mirror_width = width - mirror_width;
 828         width -= mirror_width;
 829     }
 830
 831     size.x = width;
 832     mirror_size.x = mirror_width;
 833
 834     switch(type)
 835     {
 836         default:
 837         case 0: // no styling (drawfill)
 838             if(mirror_size.x > 0 && mirror_size.y > 0) drawfill(panel_pos + eX * mirror_offset, mirror_size, color, alpha, DRAWFLAG_NORMAL);
 839             if(size.x > 0 && size.y > 0) drawfill(panel_pos + eX * offset, size, color, alpha, DRAWFLAG_NORMAL);
 840             break;
 841
 842         case 1: // progress bar style
 843             if(mirror_size.x > 0 && mirror_size.y > 0) HUD_Panel_DrawProgressBar(panel_pos + eX * mirror_offset, mirror_size, "progressbar", 1, 0, 0, color, alpha, DRAWFLAG_NORMAL);
 844             if(size.x > 0 && size.y > 0) HUD_Panel_DrawProgressBar(panel_pos + eX * offset, size, "progressbar", 1, 0, 0, color, alpha, DRAWFLAG_NORMAL);
 845             break;
 846
 847         case 2: // gradient style (types: 1 = left, 2 = right, 3 = both)
 848             StrafeHUD_drawGradient(color, autocvar_hud_panel_strafehud_bar_neutral_color, mirror_size, original_width, mirror_offset, alpha, width + (mirror_offset == 0 ? hiddencolor_width : 0), gradientType);
 849             StrafeHUD_drawGradient(color, autocvar_hud_panel_strafehud_bar_neutral_color, size, original_width, offset, alpha, (offset == 0 ? hiddencolor_width : 0), gradientType);
 850     }
 851 }
 852
 853 vector StrafeHUD_mixColors(vector color1, vector color2, float ratio)
 854 {
 855     vector mixedColor;
 856     if(ratio <= 0) return color1;
 857     if(ratio >= 1) return color2;
 858     mixedColor.x = color1.x + (color2.x - color1.x) * ratio;
 859     mixedColor.y = color1.y + (color2.y - color1.y) * ratio;
 860     mixedColor.z = color1.z + (color2.z - color1.z) * ratio;
 861     return mixedColor;
 862 }
 863
 864 void StrafeHUD_drawGradient(vector color1, vector color2, vector size, float original_width, float offset, float alpha, float gradientOffset, int gradientType)
 865 {
 866     float color_ratio, alpha1, alpha2;
 867     vector gradient_size = size;
 868     alpha1 = bound(0, alpha, 1);
 869     alpha2 = bound(0, autocvar_hud_panel_strafehud_bar_neutral_alpha, 1);
 870     if((alpha1+alpha2) == 0) return;
 871     color_ratio = alpha1/(alpha1+alpha2);
 872     for(int i = 0; i < size.x; ++i)
 873     {
 874         float ratio, alpha_ratio, combine_ratio1, combine_ratio2;
 875         gradient_size.x = size.x - i < 1 ? size.x - i : 1;
 876         ratio = (i + gradientOffset) / original_width * (gradientType == 3 ? 2 : 1);
 877         if(ratio > 1) ratio = 2 - ratio;
 878         if(gradientType != 2) ratio = 1 - ratio;
 879         alpha_ratio = alpha1 - (alpha1 - alpha2) * ratio;
 880         combine_ratio1 = ratio*(1-color_ratio);
 881         combine_ratio2 = (1-ratio)*color_ratio;
 882         ratio = (combine_ratio1 + combine_ratio2) == 0 ? 1 : combine_ratio1/(combine_ratio1 + combine_ratio2);
 883         if(alpha_ratio > 0) drawfill(panel_pos + eX * (offset + i), gradient_size, StrafeHUD_mixColors(color1, color2, ratio), alpha_ratio, DRAWFLAG_NORMAL);
 884     }
 885 }
 886
 887 // length unit conversion (km and miles are only included to match the GetSpeedUnit* functions)
 888 float GetLengthUnitFactor(int length_unit)
 889 {
 890         switch(length_unit)
 891         {
 892                 default:
 893                 case 1: return 1.0;
 894                 case 2: return 0.0254;
 895                 case 3: return 0.0254 * 0.001;
 896                 case 4: return 0.0254 * 0.001 * 0.6213711922;
 897                 case 5: return 0.0254 * 0.001 * 0.5399568035;
 898         }
 899 }
 900
 901 string GetLengthUnit(int length_unit)
 902 {
 903         switch(length_unit)
 904         {
 905                 // translator-friendly strings without the initial space
 906                 default:
 907                 case 1: return strcat(" ", _("qu"));
 908                 case 2: return strcat(" ", _("m"));
 909                 case 3: return strcat(" ", _("km"));
 910                 case 4: return strcat(" ", _("mi"));
 911                 case 5: return strcat(" ", _("nmi"));
 912         }
 913 }