qcsrc/client/hud/panel/strafehud.qc

   1 // Author: Juhu
   2
   3 #include "strafehud.qh"
   4
   5 #include <client/autocvars.qh>
   6 #include <client/miscfunctions.qh>
   7 #include <common/animdecide.qh>
   8 #include <common/ent_cs.qh>
   9 #include <common/mapinfo.qh>
  10 #include <common/physics/movetypes/movetypes.qh>
  11 #include <common/physics/player.qh>
  12 #include <lib/csqcmodel/cl_player.qh>
  13
  14 // StrafeHUD (#25)
  15
  16 void HUD_StrafeHUD_Export(int fh)
  17 {
  18     // allow saving cvars that aesthetically change the panel into hud skin files
  19 }
  20
  21 float hidden_width;
  22 int direction;
  23 float demo_angle = -37;
  24 float demo_direction = 1;
  25 float demo_time = 0;
  26 bool state_onground = false;
  27 float state_onground_time = 0;
  28 bool state_strafekeys = false;
  29 float state_strafekeys_time = 0;
  30 bool turn = false;
  31 float turnangle;
  32 bool fwd = true;
  33 bool state_fwd = true;
  34 bool state_fwd_prev = true;
  35 float state_fwd_time = 0;
  36
  37 // provide basic panel cvars to old clients
  38 // TODO remove them after a future release (0.8.2+)
  39 noref string autocvar_hud_panel_strafehud_pos = "0.320000 0.570000";
  40 noref string autocvar_hud_panel_strafehud_size = "0.360000 0.020000";
  41 noref string autocvar_hud_panel_strafehud_bg = "0";
  42 noref string autocvar_hud_panel_strafehud_bg_color = "";
  43 noref string autocvar_hud_panel_strafehud_bg_color_team = "";
  44 noref string autocvar_hud_panel_strafehud_bg_alpha = "0.7";
  45 noref string autocvar_hud_panel_strafehud_bg_border = "";
  46 noref string autocvar_hud_panel_strafehud_bg_padding = "";
  47
  48 void HUD_StrafeHUD()
  49 {
  50     entity strafeplayer;
  51     bool islocal;
  52
  53     // generic hud routines
  54     if(!autocvar__hud_configure)
  55     {
  56         if(!autocvar_hud_panel_strafehud ||
  57            (spectatee_status == -1 && (autocvar_hud_panel_strafehud == 1 || autocvar_hud_panel_strafehud == 3)) ||
  58            (autocvar_hud_panel_strafehud == 3 && !(ISGAMETYPE(RACE) || ISGAMETYPE(CTS)))) return;
  59     }
  60
  61     HUD_Panel_LoadCvars();
  62
  63     if(autocvar_hud_panel_strafehud_dynamichud)
  64     {
  65         HUD_Scale_Enable();
  66     }
  67     else
  68     {
  69         HUD_Scale_Disable();
  70     }
  71
  72     HUD_Panel_DrawBg();
  73
  74     if(panel_bg_padding)
  75     {
  76         panel_pos  += '1 1 0' * panel_bg_padding;
  77         panel_size -= '2 2 0' * panel_bg_padding;
  78     }
  79
  80     // find out whether the local csqcmodel entity is valid
  81     if(spectatee_status > 0 || isdemo())
  82     {
  83         islocal = false;
  84         strafeplayer = CSQCModel_server2csqc(player_localentnum - 1);
  85     }
  86     else
  87     {
  88         islocal = true;
  89         strafeplayer = csqcplayer;
  90     }
  91
  92     // draw strafehud
  93     if(csqcplayer && strafeplayer)
  94     {
  95         // physics
  96         bool   onground                      = islocal ? IS_ONGROUND(strafeplayer) : !(strafeplayer.anim_implicit_state & ANIMIMPLICITSTATE_INAIR);
  97         bool   strafekeys;
  98         bool   swimming                      = strafeplayer.waterlevel >= WATERLEVEL_SWIMMING;
  99         float  speed                         = !autocvar__hud_configure ? vlen(vec2(csqcplayer.velocity)) : 1337; // use local csqcmodel entity for this even when spectating, flickers too much otherwise
 100         float  maxspeed_crouch_mod           = IS_DUCKED(strafeplayer) && !swimming ? .5 : 1;
 101         float  maxspeed_water_mod            = swimming ? .7 : 1; // very simplified water physics, the hud will not work well (and is not supposed to) while swimming
 102         float  maxspeed_phys                 = onground ? PHYS_MAXSPEED(strafeplayer) : PHYS_MAXAIRSPEED(strafeplayer);
 103         float  maxspeed                      = !autocvar__hud_configure ? maxspeed_phys * maxspeed_crouch_mod * maxspeed_water_mod : 320;
 104         float  vel_angle                     = vectoangles(strafeplayer.velocity).y;
 105         float  view_angle                    = view_angles.y + 180;
 106         float  angle;
 107         vector movement                      = PHYS_INPUT_MOVEVALUES(strafeplayer);
 108         int    keys                          = STAT(PRESSED_KEYS);
 109         int    keys_fwd;
 110         float  wishangle                     = 0;
 111
 112         // HUD
 113         int    mode                          = autocvar_hud_panel_strafehud_mode >= 0 && autocvar_hud_panel_strafehud_mode <= 1 ? autocvar_hud_panel_strafehud_mode : 0;
 114         float  antiflicker_angle             = bound(0, autocvar_hud_panel_strafehud_antiflicker_angle, 180);
 115         float  antiflicker_speed             = max(0, autocvar_hud_panel_strafehud_antiflicker_speed);
 116         float  minspeed;
 117         float  shift_offset                  = 0;
 118         bool   straight_overturn             = false;
 119         bool   immobile                      = speed <= (swimming ? antiflicker_speed : 0);
 120         float  hudangle;
 121         float  neutral_offset;
 122         float  neutral_width;
 123         vector currentangle_color            = autocvar_hud_panel_strafehud_angle_neutral_color;
 124         float  currentangle_offset;
 125         vector currentangle_size             = '0 0 0';
 126         float  bestangle;
 127         float  odd_bestangle;
 128         bool   bestangle_anywhere            = false;
 129         float  bestangle_offset;
 130         float  switch_bestangle_offset;
 131         bool   odd_angles                    = false;
 132         float  odd_bestangle_offset          = 0;
 133         float  switch_odd_bestangle_offset   = 0;
 134         float  bestangle_width;
 135         float  accelzone_left_offset;
 136         float  accelzone_right_offset;
 137         float  accelzone_width;
 138         float  overturn_offset;
 139         float  overturn_width;
 140         vector direction_size_vertical       = '0 0 0';
 141         vector direction_size_horizontal     = '0 0 0';
 142         float  range_minangle;
 143
 144         // determine whether the player is pressing forwards or backwards keys
 145         if(islocal) // if entity is local player
 146         {
 147             if(movement.x > 0)
 148             {
 149                 keys_fwd = 1;
 150             }
 151             else if(movement.x < 0)
 152             {
 153                 keys_fwd = -1;
 154             }
 155             else
 156             {
 157                 keys_fwd = 0;
 158             }
 159         }
 160         else // alternatively determine direction by querying pressed keys
 161         {
 162             if((keys & KEY_FORWARD) && !(keys & KEY_BACKWARD))
 163             {
 164                 keys_fwd = 1;
 165             }
 166             else if(!(keys & KEY_FORWARD) && (keys & KEY_BACKWARD))
 167             {
 168                 keys_fwd = -1;
 169             }
 170             else
 171             {
 172                 keys_fwd = 0;
 173             }
 174         }
 175
 176         // determine player wishdir
 177         if(islocal) // if entity is local player
 178         {
 179             if(movement.x == 0)
 180             {
 181                 if(movement.y < 0)
 182                 {
 183                     wishangle = -90;
 184                 }
 185                 else if(movement.y > 0)
 186                 {
 187                     wishangle = 90;
 188                 }
 189                 else
 190                 {
 191                     wishangle = 0;
 192                 }
 193             }
 194             else
 195             {
 196                 if(movement.y == 0)
 197                 {
 198                     wishangle = 0;
 199                 }
 200                 else
 201                 {
 202                     wishangle = RAD2DEG * atan2(movement.y, movement.x);
 203                     // wrap the wish angle if it exceeds ±90°
 204                     if(fabs(wishangle) > 90)
 205                     {
 206                         if(wishangle < 0) wishangle += 180;
 207                         else wishangle -= 180;
 208                         wishangle = -wishangle;
 209                     }
 210                 }
 211             }
 212         }
 213         else // alternatively calculate wishdir by querying pressed keys
 214         {
 215             if(keys & KEY_FORWARD || keys & KEY_BACKWARD)
 216             {
 217                 wishangle = 45;
 218             }
 219             else
 220             {
 221                 wishangle = 90;
 222             }
 223             if(keys & KEY_LEFT)
 224             {
 225                 wishangle *= -1;
 226             }
 227             else if(!(keys & KEY_RIGHT))
 228             {
 229                 wishangle = 0; // wraps at 180°
 230             }
 231         }
 232
 233         strafekeys = fabs(wishangle) == 90;
 234
 235         // determine minimum required angle to display full strafe range
 236         range_minangle = fabs(wishangle) % 90; // maximum range is 90 degree
 237         if(range_minangle > 45) // minimum angle range is 45
 238         {
 239             range_minangle = 45 - fabs(wishangle) % 45;
 240         }
 241         range_minangle = 90 - range_minangle; // calculate value which is never >90 or <45
 242         range_minangle *= 2; // multiply to accommodate for both sides of the hud
 243
 244         if(autocvar_hud_panel_strafehud_range == 0)
 245         {
 246             if(autocvar__hud_configure)
 247             {
 248                 hudangle = 90;
 249             }
 250             else
 251             {
 252                 hudangle = range_minangle; // use minimum angle required if dynamically setting hud angle
 253             }
 254         }
 255         else
 256         {
 257             hudangle = bound(0, fabs(autocvar_hud_panel_strafehud_range), 360); // limit HUD range to 360 degrees, higher values don't make sense
 258         }
 259
 260         // detect air strafe turning
 261         if(onground != state_onground)
 262         {
 263             state_onground_time = time;
 264         }
 265         state_onground = onground;
 266
 267         if(strafekeys != state_strafekeys)
 268         {
 269             state_strafekeys_time = time;
 270         }
 271         state_strafekeys = strafekeys;
 272
 273         if((keys & KEY_FORWARD) || (keys & KEY_BACKWARD) || swimming || autocvar__hud_configure)
 274         {
 275             turn = false;
 276         }
 277         else if(onground)
 278         {
 279             if((time - state_onground_time) >= autocvar_hud_panel_strafehud_timeout_ground) // timeout for strafe jumping in general
 280             {
 281                 turn = false;
 282             }
 283         }
 284         else // air strafe only
 285         {
 286             if(strafekeys)
 287             {
 288                 if(((time - state_onground_time) >= autocvar_hud_panel_strafehud_timeout_air) || (keys & KEY_JUMP)) // timeout for slick ramps
 289                 {
 290                     turn = true; // CPMA turning
 291                     turnangle = wishangle;
 292                 }
 293             }
 294             else if((time - state_strafekeys_time) >= autocvar_hud_panel_strafehud_timeout_turn) // timeout for jumping with strafe keys only
 295             {
 296                 turn = false;
 297             }
 298         }
 299         if(turn)
 300         {
 301             maxspeed = PHYS_MAXAIRSTRAFESPEED(strafeplayer); // no modifiers here because they don't affect air strafing
 302             wishangle = turnangle;
 303         }
 304
 305         minspeed = autocvar_hud_panel_strafehud_switch_minspeed < 0 ? maxspeed + antiflicker_speed : autocvar_hud_panel_strafehud_switch_minspeed;
 306
 307         // get current strafing angle ranging from -180° to +180°
 308         if(!autocvar__hud_configure)
 309         {
 310             if(speed > 0)
 311             {
 312                 // calculate view angle relative to the players current velocity direction
 313                 angle = vel_angle - view_angle;
 314
 315                 // if the angle goes above 180° or below -180° wrap it to the opposite side
 316                 if (angle > 180) angle -= 360;
 317                 else if(angle < -180) angle += 360;
 318
 319                 // shift the strafe angle by 180° for hud calculations
 320                 if(angle < 0) angle += 180;
 321                 else angle -= 180;
 322
 323                 // determine whether the player is strafing forwards or backwards
 324                 // if the player isn't strafe turning use forwards/backwards keys to determine direction
 325                 if(!strafekeys)
 326                 {
 327                     if(keys_fwd > 0)
 328                     {
 329                         state_fwd = true;
 330                     }
 331                     else if(keys_fwd < 0)
 332                     {
 333                         state_fwd = false;
 334                     }
 335                     else
 336                     {
 337                         state_fwd = fabs(angle) <= 90;
 338                     }
 339                 }
 340                 // otherwise determine by examining the strafe angle
 341                 else
 342                 {
 343                     if(wishangle < 0) // detect direction using wishangle since the direction is not yet set
 344                     {
 345                         state_fwd = angle <= -wishangle;
 346                     }
 347                     else
 348                     {
 349                         state_fwd = angle >= -wishangle;
 350                     }
 351                 }
 352
 353                 if(state_fwd_prev != state_fwd)
 354                 {
 355                     state_fwd_time = time;
 356                 }
 357                 state_fwd_prev = state_fwd;
 358
 359                 if((time - state_fwd_time) >= autocvar_hud_panel_strafehud_timeout_direction || speed < maxspeed || (strafekeys && mode == 0)) // timeout when changing between forwards and backwards movement
 360                 {
 361                     fwd = state_fwd;
 362                 }
 363
 364                 // shift the strafe angle by 180° when strafing backwards
 365                 if(!fwd)
 366                 {
 367                     if(angle < 0) angle += 180;
 368                     else angle -= 180;
 369                 }
 370
 371                 // don't make the angle indicator switch side too much at ±180° if anti flicker is turned on
 372                 if(angle > (180 - antiflicker_angle) || angle < (-180 + antiflicker_angle))
 373                 {
 374                     straight_overturn = true;
 375                 }
 376             }
 377             else
 378             {
 379                 angle = 0;
 380             }
 381         }
 382         else // simulate turning for HUD setup
 383         {
 384             if(autocvar__hud_panel_strafehud_demo && ((time - demo_time) >= .025))
 385             {
 386                 demo_time = time;
 387                 demo_angle += demo_direction;
 388                 if(fabs(demo_angle) >= 55)
 389                 {
 390                     demo_direction = -demo_direction;
 391                 }
 392             }
 393             angle = demo_angle;
 394             wishangle = 45 * (demo_angle > 0 ? 1 : -1);
 395         }
 396
 397         // invert the wish angle when strafing backwards
 398         if(!fwd)
 399         {
 400             wishangle = -wishangle;
 401         }
 402
 403         // flip angles if v_flipped is enabled
 404         if(autocvar_v_flipped)
 405         {
 406             angle = -angle;
 407             wishangle = -wishangle;
 408         }
 409
 410         // determine whether the player is strafing left or right
 411         if(wishangle != 0)
 412         {
 413             direction = wishangle > 0 ? 1 : -1;
 414         }
 415         else
 416         {
 417             direction = (angle > antiflicker_angle && angle < (180 - antiflicker_angle)) ? 1 : (angle < -antiflicker_angle && angle > (-180 + antiflicker_angle)) ? -1 : 0;
 418         }
 419
 420         // best angle to strafe at
 421         bestangle = (speed > maxspeed ? acos(maxspeed / speed) : 0) * RAD2DEG * (direction < 0 ? -1 : 1);
 422         odd_bestangle = -bestangle - wishangle;
 423         bestangle -= wishangle;
 424
 425         // various offsets and size calculations of hud indicator elements
 426         // how much is hidden by the current hud angle
 427         hidden_width = (360 - hudangle) / hudangle * panel_size.x;
 428         // current angle
 429         currentangle_size.x = max(panel_size.x * autocvar_hud_panel_strafehud_angle_width, 1);
 430         if(mode == 0)
 431         {
 432             currentangle_offset = angle/hudangle * panel_size.x;
 433         }
 434         else
 435         {
 436             currentangle_offset = bound(-hudangle/2, angle, hudangle/2)/hudangle * panel_size.x + panel_size.x/2;
 437         }
 438         currentangle_size.y = max(panel_size.y * min(autocvar_hud_panel_strafehud_angle_height, 2), 1);
 439         // best strafe acceleration angle
 440         bestangle_offset        =  bestangle/hudangle * panel_size.x + panel_size.x/2;
 441         switch_bestangle_offset = -bestangle/hudangle * panel_size.x + panel_size.x/2;
 442         bestangle_width = max(panel_size.x * autocvar_hud_panel_strafehud_switch_width, 1);
 443
 444         if(((angle > -wishangle && direction < 0) || (angle < -wishangle && direction > 0)) && (direction != 0))
 445         {
 446             odd_angles = true;
 447             odd_bestangle_offset = odd_bestangle/hudangle * panel_size.x + panel_size.x/2;
 448             switch_odd_bestangle_offset = (odd_bestangle+bestangle*2)/hudangle * panel_size.x + panel_size.x/2;
 449         }
 450         // direction indicator
 451         direction_size_vertical.x = max(panel_size.y * min(autocvar_hud_panel_strafehud_direction_width, .5), 1);
 452         direction_size_vertical.y = panel_size.y;
 453         direction_size_horizontal.x = max(panel_size.x * min(autocvar_hud_panel_strafehud_direction_length, .5), direction_size_vertical.x);
 454         direction_size_horizontal.y = direction_size_vertical.x;
 455         // overturn
 456         overturn_width = 180/hudangle * panel_size.x;
 457
 458         // the neutral zone fills the whole strafe bar
 459         if(immobile)
 460         {
 461             // draw neutral zone
 462             if(panel_size.x > 0 && panel_size.y > 0 && autocvar_hud_panel_strafehud_bar_neutral_alpha * panel_fg_alpha > 0)
 463             {
 464                 switch(autocvar_hud_panel_strafehud_style)
 465                 {
 466                     default:
 467                     case 0:
 468                         drawfill(panel_pos, panel_size, autocvar_hud_panel_strafehud_bar_neutral_color, autocvar_hud_panel_strafehud_bar_neutral_alpha * panel_fg_alpha, DRAWFLAG_NORMAL);
 469                         break;
 470
 471                     case 1:
 472                         HUD_Panel_DrawProgressBar(panel_pos, panel_size, "progressbar", 1, 0, 0, autocvar_hud_panel_strafehud_bar_neutral_color, autocvar_hud_panel_strafehud_bar_neutral_alpha * panel_fg_alpha, DRAWFLAG_NORMAL);
 473                 }
 474             }
 475         }
 476         else
 477         {
 478             // calculate various zones of the strafe-o-meter
 479             accelzone_width = overturn_offset = (90 - fabs(bestangle + wishangle))/hudangle * panel_size.x;
 480             accelzone_right_offset = 0;
 481             accelzone_left_offset = overturn_offset + overturn_width;
 482             neutral_width = 360/hudangle * panel_size.x - accelzone_width*2 - overturn_width;
 483             neutral_offset = direction < 0 ? accelzone_left_offset + accelzone_width : -neutral_width;
 484
 485             // remove switch indicator width from offset
 486             if(direction < 0)
 487             {
 488                 bestangle_offset -= bestangle_width;
 489                 switch_odd_bestangle_offset -= bestangle_width;
 490             }
 491             else
 492             {
 493                 switch_bestangle_offset -= bestangle_width;
 494                 odd_bestangle_offset -= bestangle_width;
 495             }
 496
 497             // shift hud if operating in view angle centered mode
 498             if(mode == 0)
 499             {
 500                 shift_offset = -currentangle_offset;
 501                 bestangle_offset += shift_offset;
 502                 switch_bestangle_offset += shift_offset;
 503                 odd_bestangle_offset += shift_offset;
 504                 switch_odd_bestangle_offset += shift_offset;
 505             }
 506             if(direction < 0) shift_offset += -360/hudangle * panel_size.x;
 507             // calculate how far off-center the strafe zones currently are
 508             shift_offset += (panel_size.x + neutral_width)/2 - wishangle/hudangle * panel_size.x;
 509             // shift strafe zones into correct place
 510             neutral_offset += shift_offset;
 511             accelzone_left_offset += shift_offset;
 512             accelzone_right_offset += shift_offset;
 513             overturn_offset += shift_offset;
 514
 515             // draw left acceleration zone
 516             HUD_Panel_DrawStrafeHUD(accelzone_left_offset, accelzone_width, autocvar_hud_panel_strafehud_bar_accel_color, autocvar_hud_panel_strafehud_bar_accel_alpha * panel_fg_alpha, autocvar_hud_panel_strafehud_style, 1);
 517
 518             // draw right acceleration zone
 519             HUD_Panel_DrawStrafeHUD(accelzone_right_offset, accelzone_width, autocvar_hud_panel_strafehud_bar_accel_color, autocvar_hud_panel_strafehud_bar_accel_alpha * panel_fg_alpha, autocvar_hud_panel_strafehud_style, 2);
 520
 521             // draw overturn zone
 522             HUD_Panel_DrawStrafeHUD(overturn_offset, overturn_width, autocvar_hud_panel_strafehud_bar_overturn_color, autocvar_hud_panel_strafehud_bar_overturn_alpha * panel_fg_alpha, autocvar_hud_panel_strafehud_style, 3);
 523
 524             // draw neutral zone
 525             HUD_Panel_DrawStrafeHUD(neutral_offset, neutral_width, autocvar_hud_panel_strafehud_bar_neutral_color, autocvar_hud_panel_strafehud_bar_neutral_alpha * panel_fg_alpha, autocvar_hud_panel_strafehud_style, 0);
 526
 527             if(direction != 0 && direction_size_vertical.x > 0 && autocvar_hud_panel_strafehud_direction_alpha * panel_fg_alpha > 0)
 528             {
 529                 bool indicator_direction = direction < 0;
 530                 // invert left/right when strafing backwards or when strafing towards the opposite side indicated by the direction variable
 531                 // if both conditions are true then it's inverted twice hence not inverted at all
 532                 if(!fwd != odd_angles)
 533                 {
 534                     indicator_direction = !indicator_direction;
 535                 }
 536                 // draw the direction indicator caps at the sides of the hud
 537                 // vertical line
 538                 if(direction_size_vertical.y > 0) drawfill(panel_pos + eX * (indicator_direction ? -direction_size_vertical.x : panel_size.x), direction_size_vertical, autocvar_hud_panel_strafehud_direction_color, autocvar_hud_panel_strafehud_direction_alpha * panel_fg_alpha, DRAWFLAG_NORMAL);
 539                 // top horizontal line
 540                 drawfill(panel_pos + eX * (indicator_direction ? -direction_size_vertical.x : panel_size.x - direction_size_horizontal.x + direction_size_vertical.x) - eY * direction_size_horizontal.y, direction_size_horizontal, autocvar_hud_panel_strafehud_direction_color, autocvar_hud_panel_strafehud_direction_alpha * panel_fg_alpha, DRAWFLAG_NORMAL);
 541                 // bottom horizontal line
 542                 drawfill(panel_pos + eX * (indicator_direction ? -direction_size_vertical.x : panel_size.x - direction_size_horizontal.x + direction_size_vertical.x) + eY * panel_size.y, direction_size_horizontal, autocvar_hud_panel_strafehud_direction_color, autocvar_hud_panel_strafehud_direction_alpha * panel_fg_alpha, DRAWFLAG_NORMAL);
 543             }
 544
 545             if(speed >= minspeed) // only draw indicators if minspeed is reached
 546             {
 547                 // draw best angles for acceleration
 548                 float offset = !odd_angles ? bestangle_offset : odd_bestangle_offset;
 549                 float switch_offset = !odd_angles ? switch_bestangle_offset : switch_odd_bestangle_offset;
 550                 // both indicators are inactive if no direction can be determined
 551                 vector switch_color = direction != 0 ? autocvar_hud_panel_strafehud_switch_active_color : autocvar_hud_panel_strafehud_switch_inactive_color;
 552                 float switch_alpha = direction != 0 ? autocvar_hud_panel_strafehud_switch_active_alpha : autocvar_hud_panel_strafehud_switch_inactive_alpha;
 553                 // draw the switch indicators
 554                 HUD_Panel_DrawStrafeHUD(switch_offset, bestangle_width, autocvar_hud_panel_strafehud_switch_inactive_color, autocvar_hud_panel_strafehud_switch_inactive_alpha * panel_fg_alpha, 0, 0);
 555                 HUD_Panel_DrawStrafeHUD(offset, bestangle_width, switch_color, switch_alpha * panel_fg_alpha, 0, 0);
 556             }
 557         }
 558
 559         if(speed < (maxspeed + antiflicker_speed) && !immobile)
 560         {
 561             bestangle_anywhere = true; // moving forward should suffice to gain speed
 562         }
 563
 564         // draw the actual strafe angle
 565         if(!bestangle_anywhere && !immobile) // player gains speed with strafing
 566         {
 567             if((direction > 0 && (angle >= bestangle || angle <= -(bestangle + wishangle*2))) ||
 568                (direction < 0 && (angle <= bestangle || angle >= -(bestangle + wishangle*2))))
 569             currentangle_color = autocvar_hud_panel_strafehud_angle_accel_color;
 570         }
 571
 572         if(fabs(angle + wishangle) > 90) // player is overturning
 573         {
 574             currentangle_color = autocvar_hud_panel_strafehud_angle_overturn_color;
 575         }
 576         else if(bestangle_anywhere) // player gains speed without strafing
 577         {
 578             currentangle_color = autocvar_hud_panel_strafehud_angle_accel_color;
 579         }
 580
 581         if(mode == 0 || straight_overturn)
 582         {
 583             currentangle_offset = panel_size.x/2;
 584         }
 585
 586         if(autocvar_hud_panel_strafehud_style == 2 && !immobile)
 587         {
 588             float moveangle = angle + wishangle;
 589             float strafeangle = (bestangle + wishangle) * (direction < 0 ? -1 : 1);
 590             float strafe_ratio = 0;
 591             if(fabs(moveangle) > 90)
 592             {
 593                 strafe_ratio = -((fabs(moveangle) - 90) / 90);
 594                 if(strafe_ratio < -1) strafe_ratio = -1 - strafe_ratio%1;
 595             }
 596             else
 597             {
 598                 if(moveangle >= strafeangle)
 599                 {
 600                     strafe_ratio = 1 - (moveangle - strafeangle) / (90 - strafeangle);
 601                 }
 602                 else if(moveangle <= -strafeangle)
 603                 {
 604                     strafe_ratio = 1 - (moveangle + strafeangle) / (-90 + strafeangle);
 605                 }
 606             }
 607             if(strafe_ratio < 0)
 608             {
 609                 currentangle_color = StrafeHUD_mixColors(autocvar_hud_panel_strafehud_angle_neutral_color, autocvar_hud_panel_strafehud_angle_overturn_color, -strafe_ratio);
 610             }
 611             else
 612             {
 613                 currentangle_color = StrafeHUD_mixColors(autocvar_hud_panel_strafehud_angle_neutral_color, autocvar_hud_panel_strafehud_angle_accel_color, strafe_ratio);
 614             }
 615         }
 616
 617         if(currentangle_size.x > 0 && currentangle_size.y > 0 && autocvar_hud_panel_strafehud_angle_alpha * panel_fg_alpha > 0)
 618         {
 619             drawfill(panel_pos - eY * ((currentangle_size.y - panel_size.y) / 2) + eX * (currentangle_offset - currentangle_size.x/2), currentangle_size, currentangle_color, autocvar_hud_panel_strafehud_angle_alpha * panel_fg_alpha, DRAWFLAG_NORMAL);
 620         }
 621     }
 622 }
 623
 624 // functions to make hud elements align perfectly in the hud area
 625 void HUD_Panel_DrawStrafeHUD(float offset, float width, vector color, float alpha, int type, int gradientType)
 626 {
 627     float mirror_offset, mirror_width;
 628     vector size = panel_size;
 629     vector mirror_size = panel_size;
 630
 631     float original_width = width;
 632     float hiddencolor_width;
 633
 634     if(alpha <= 0 || width <= 0) return;
 635
 636     if(type == 2 && gradientType == 0) type = 0;
 637
 638     if(offset < 0)
 639     {
 640         mirror_width = min(fabs(offset), width);
 641         mirror_offset = panel_size.x + hidden_width - fabs(offset);
 642         width += offset;
 643         offset = 0;
 644     }
 645     else
 646     {
 647         mirror_width = min(offset + width - panel_size.x - hidden_width, width);
 648         mirror_offset = max(offset - panel_size.x - hidden_width, 0);
 649     }
 650     if((offset + width) > panel_size.x)
 651     {
 652         width = panel_size.x - offset;
 653     }
 654     if(mirror_offset < 0)
 655     {
 656         mirror_width += mirror_offset;
 657         mirror_offset = 0;
 658     }
 659     if((mirror_offset + mirror_width) > panel_size.x)
 660     {
 661         mirror_width = panel_size.x - mirror_offset;
 662     }
 663
 664     if(width < 0) width = 0;
 665     if(mirror_width < 0) mirror_width = 0;
 666     hiddencolor_width = original_width - width - mirror_width;
 667
 668     if(direction < 0) // swap mirror and non-mirror values if direction points left
 669     {
 670         offset += mirror_offset;
 671         mirror_offset = offset - mirror_offset;
 672         offset -= mirror_offset;
 673
 674         width += mirror_width;
 675         mirror_width = width - mirror_width;
 676         width -= mirror_width;
 677     }
 678
 679     size.x = width;
 680     mirror_size.x = mirror_width;
 681
 682     switch(type)
 683     {
 684         default:
 685         case 0: // no styling (drawfill)
 686             if(mirror_size.x > 0 && mirror_size.y > 0) drawfill(panel_pos + eX * mirror_offset, mirror_size, color, alpha, DRAWFLAG_NORMAL);
 687             if(size.x > 0 && size.y > 0) drawfill(panel_pos + eX * offset, size, color, alpha, DRAWFLAG_NORMAL);
 688             break;
 689
 690         case 1: // progress bar style
 691             if(mirror_size.x > 0 && mirror_size.y > 0) HUD_Panel_DrawProgressBar(panel_pos + eX * mirror_offset, mirror_size, "progressbar", 1, 0, 0, color, alpha, DRAWFLAG_NORMAL);
 692             if(size.x > 0 && size.y > 0) HUD_Panel_DrawProgressBar(panel_pos + eX * offset, size, "progressbar", 1, 0, 0, color, alpha, DRAWFLAG_NORMAL);
 693             break;
 694
 695         case 2: // gradient style (types: 1 = left, 2 = right, 3 = both)
 696             StrafeHUD_drawGradient(color, autocvar_hud_panel_strafehud_bar_neutral_color, mirror_size, original_width, mirror_offset, alpha, width + (mirror_offset == 0 ? hiddencolor_width : 0), gradientType);
 697             StrafeHUD_drawGradient(color, autocvar_hud_panel_strafehud_bar_neutral_color, size, original_width, offset, alpha, (offset == 0 ? hiddencolor_width : 0), gradientType);
 698     }
 699 }
 700
 701 vector StrafeHUD_mixColors(vector color1, vector color2, float ratio)
 702 {
 703     vector mixedColor;
 704     if(ratio <= 0) return color1;
 705     if(ratio >= 1) return color2;
 706     mixedColor.x = color1.x + (color2.x - color1.x) * ratio;
 707     mixedColor.y = color1.y + (color2.y - color1.y) * ratio;
 708     mixedColor.z = color1.z + (color2.z - color1.z) * ratio;
 709     return mixedColor;
 710 }
 711
 712 void StrafeHUD_drawGradient(vector color1, vector color2, vector size, float original_width, float offset, float alpha, float gradientOffset, int gradientType)
 713 {
 714     float ratio, alpha_ratio;
 715     vector gradient_size = size;
 716     float color_ratio1 = autocvar_hud_panel_strafehud_bar_neutral_alpha == 0 ? 1 : min(min(alpha, 1)/min(autocvar_hud_panel_strafehud_bar_neutral_alpha, 1), 1);
 717     float color_ratio2 = alpha == 0 ? 1 : min(min(autocvar_hud_panel_strafehud_bar_neutral_alpha, 1)/min(alpha, 1), 1);
 718     vector gradient_color1 = gradientType == 2 ? StrafeHUD_mixColors(color2, color1, color_ratio1) : StrafeHUD_mixColors(color1, color2, color_ratio2);
 719     vector gradient_color2 = gradientType == 2 ? StrafeHUD_mixColors(color1, color2, color_ratio2) : StrafeHUD_mixColors(color2, color1, color_ratio1);
 720     for(int i = 0; i < size.x; ++i)
 721     {
 722         gradient_size.x = size.x - i < 1 ? size.x - i : 1;
 723         ratio = (i + gradientOffset) / original_width * (gradientType == 3 ? 2 : 1);
 724         if(ratio > 1) ratio = 2 - ratio;
 725         alpha_ratio = ratio;
 726         if(gradientType != 2) alpha_ratio = 1 - alpha_ratio;
 727         drawfill(panel_pos + eX * (offset + i), gradient_size, StrafeHUD_mixColors(gradient_color1, gradient_color2, ratio), alpha - (alpha - autocvar_hud_panel_strafehud_bar_neutral_alpha) * alpha_ratio, DRAWFLAG_NORMAL);
 728     }
 729 }