qcsrc/client/main.qc

   1 #include "controlpoint.qh"
   2 #include "generator.qh"
   3 #include "mapvoting.qh"
   4 #include "modeleffects.qh"
   5 #include "particles.qh"
   6 #include "scoreboard.qh"
   7 #include "shownames.qh"
   8 #include "target_music.qh"
   9 #include "tturrets.qh"
  10 #include "tuba.qh"
  11 #include "wall.qh"
  12 #include "waypointsprites.qh"
  13
  14 #include "vehicles/vehicles.qh"
  15
  16 #include "../server/vehicles/bumblebee.qh"
  17
  18 #include "../common/net_notice.qh"
  19
  20 #include "../common/monsters/monsters.qh"
  21
  22 #include "../warpzonelib/client.qh"
  23
  24 // --------------------------------------------------------------------------
  25 // BEGIN REQUIRED CSQC FUNCTIONS
  26 //include "main.qh"
  27
  28 entity clearentity_ent;
  29 void clearentity(entity e)
  30 {
  31         if (!clearentity_ent)
  32         {
  33                 clearentity_ent = spawn();
  34                 clearentity_ent.classname = "clearentity";
  35         }
  36         int n = e.entnum;
  37         copyentity(clearentity_ent, e);
  38         e.entnum = n;
  39 }
  40
  41 #define DP_CSQC_ENTITY_REMOVE_IS_B0RKED
  42 void menu_show_error()
  43 {
  44         drawstring('0 200 0', _("ERROR - MENU IS VISIBLE BUT NO MENU WAS DEFINED!"), '8 8 0', '1 0 0', 1, 0);
  45 }
  46
  47 // CSQC_Init : Called every time the CSQC code is initialized (essentially at map load)
  48 // Useful for precaching things
  49
  50 void menu_sub_null()
  51 {
  52 }
  53
  54 string forcefog;
  55 void WaypointSprite_Load();
  56 void ConsoleCommand_macro_init();
  57 void CSQC_Init(void)
  58 {
  59         prvm_language = cvar_string("prvm_language");
  60
  61 #ifdef WATERMARK
  62         dprintf("^4CSQC Build information: ^1%s\n", WATERMARK);
  63 #endif
  64
  65         int i;
  66
  67         binddb = db_create();
  68         tempdb = db_create();
  69         ClientProgsDB = db_load("client.db");
  70         compressShortVector_init();
  71
  72         draw_endBoldFont();
  73         menu_visible = false;
  74         menu_show = menu_show_error;
  75         menu_action = func_null;
  76
  77         for(i = 0; i < 255; ++i)
  78                 if(getplayerkeyvalue(i, "viewentity") == "")
  79                         break;
  80         maxclients = i;
  81
  82         //registercommand("hud_configure");
  83         //registercommand("hud_save");
  84         //registercommand("menu_action");
  85
  86         ConsoleCommand_macro_init();
  87
  88         registercvar("hud_usecsqc", "1");
  89         registercvar("scoreboard_columns", "default");
  90
  91         registercvar("cl_nade_type", "3");
  92         registercvar("cl_pokenade_type", "zombie");
  93
  94         gametype = 0;
  95
  96         // hud_fields uses strunzone on the titles!
  97         for(i = 0; i < MAX_HUD_FIELDS; ++i)
  98                 hud_title[i] = strzone("(null)");
  99
 100         Cmd_HUD_SetFields(0);
 101
 102         postinit = false;
 103
 104         calledhooks = 0;
 105
 106         teams = Sort_Spawn();
 107         players = Sort_Spawn();
 108
 109         GetTeam(NUM_SPECTATOR, true); // add specs first
 110
 111         // needs to be done so early because of the constants they create
 112         CALL_ACCUMULATED_FUNCTION(RegisterWeapons);
 113         CALL_ACCUMULATED_FUNCTION(RegisterMonsters);
 114         CALL_ACCUMULATED_FUNCTION(RegisterGametypes);
 115         CALL_ACCUMULATED_FUNCTION(RegisterNotifications);
 116         CALL_ACCUMULATED_FUNCTION(RegisterDeathtypes);
 117         CALL_ACCUMULATED_FUNCTION(RegisterHUD_Panels);
 118         CALL_ACCUMULATED_FUNCTION(RegisterBuffs);
 119
 120         WaypointSprite_Load();
 121
 122         // precaches
 123         precache_model("null");
 124         precache_sound("misc/hit.wav");
 125         precache_sound("misc/typehit.wav");
 126
 127         generator_precache();
 128         Projectile_Precache();
 129         Hook_Precache();
 130         GibSplash_Precache();
 131         Casings_Precache();
 132         Vehicles_Precache();
 133         turrets_precache();
 134         Tuba_Precache();
 135         CSQCPlayer_Precache();
 136
 137         if(autocvar_cl_reticle)
 138         {
 139                 precache_pic("gfx/reticle_normal");
 140                 // weapon reticles are precached in weapon files
 141         }
 142
 143         get_mi_min_max_texcoords(1); // try the CLEVER way first
 144         minimapname = strcat("gfx/", mi_shortname, "_radar.tga");
 145         shortmapname = mi_shortname;
 146
 147         if(precache_pic(minimapname) == "")
 148         {
 149                 // but maybe we have a non-clever minimap
 150                 minimapname = strcat("gfx/", mi_shortname, "_mini.tga");
 151                 if(precache_pic(minimapname) == "")
 152                         minimapname = ""; // FAIL
 153                 else
 154                         get_mi_min_max_texcoords(0); // load new texcoords
 155         }
 156
 157         mi_center = (mi_min + mi_max) * 0.5;
 158         mi_scale = mi_max - mi_min;
 159         minimapname = strzone(minimapname);
 160
 161         WarpZone_Init();
 162
 163         hud_skin_path = strzone(strcat("gfx/hud/", autocvar_hud_skin));
 164         draw_currentSkin = strzone(strcat("gfx/menu/", cvar_string("menu_skin")));
 165 }
 166
 167 // CSQC_Shutdown : Called every time the CSQC code is shutdown (changing maps, quitting, etc)
 168 void Shutdown(void)
 169 {
 170         WarpZone_Shutdown();
 171
 172         remove(teams);
 173         remove(players);
 174         db_close(binddb);
 175         db_close(tempdb);
 176         if(autocvar_cl_db_saveasdump)
 177                 db_dump(ClientProgsDB, "client.db");
 178         else
 179                 db_save(ClientProgsDB, "client.db");
 180         db_close(ClientProgsDB);
 181
 182         if(camera_active)
 183                 cvar_set("chase_active",ftos(chase_active_backup));
 184
 185         // unset the event chasecam's chase_active
 186         if(autocvar_chase_active < 0)
 187                 cvar_set("chase_active", "0");
 188
 189         if (!isdemo())
 190         {
 191                 if (!(calledhooks & HOOK_START))
 192                         localcmd("\n_cl_hook_gamestart nop\n");
 193                 if (!(calledhooks & HOOK_END))
 194                         localcmd("\ncl_hook_gameend\n");
 195         }
 196 }
 197
 198 .float has_team;
 199 float SetTeam(entity o, int Team)
 200 {
 201         entity tm;
 202         if(teamplay)
 203         {
 204                 switch(Team)
 205                 {
 206                         case -1:
 207                         case NUM_TEAM_1:
 208                         case NUM_TEAM_2:
 209                         case NUM_TEAM_3:
 210                         case NUM_TEAM_4:
 211                                 break;
 212                         default:
 213                                 if(GetTeam(Team, false) == world)
 214                                 {
 215                                         dprintf("trying to switch to unsupported team %d\n", Team);
 216                                         Team = NUM_SPECTATOR;
 217                                 }
 218                                 break;
 219                 }
 220         }
 221         else
 222         {
 223                 switch(Team)
 224                 {
 225                         case -1:
 226                         case 0:
 227                                 break;
 228                         default:
 229                                 if(GetTeam(Team, false) == world)
 230                                 {
 231                                         dprintf("trying to switch to unsupported team %d\n", Team);
 232                                         Team = NUM_SPECTATOR;
 233                                 }
 234                                 break;
 235                 }
 236         }
 237         if(Team == -1) // leave
 238         {
 239                 if(o.has_team)
 240                 {
 241                         tm = GetTeam(o.team, false);
 242                         tm.team_size -= 1;
 243                         o.has_team = 0;
 244                         return true;
 245                 }
 246         }
 247         else
 248         {
 249                 if (!o.has_team)
 250                 {
 251                         o.team = Team;
 252                         tm = GetTeam(Team, true);
 253                         tm.team_size += 1;
 254                         o.has_team = 1;
 255                         return true;
 256                 }
 257                 else if(Team != o.team)
 258                 {
 259                         tm = GetTeam(o.team, false);
 260                         tm.team_size -= 1;
 261                         o.team = Team;
 262                         tm = GetTeam(Team, true);
 263                         tm.team_size += 1;
 264                         return true;
 265                 }
 266         }
 267         return false;
 268 }
 269
 270 void Playerchecker_Think()
 271 {
 272     int i;
 273         entity e;
 274         for(i = 0; i < maxclients; ++i)
 275         {
 276                 e = playerslots[i];
 277                 if(GetPlayerName(i) == "")
 278                 {
 279                         if(e.sort_prev)
 280                         {
 281                                 // player disconnected
 282                                 SetTeam(e, -1);
 283                                 RemovePlayer(e);
 284                                 e.sort_prev = world;
 285                                 //e.gotscores = 0;
 286                         }
 287                 }
 288                 else
 289                 {
 290                         if (!e.sort_prev)
 291                         {
 292                                 // player connected
 293                                 if (!e)
 294                                         playerslots[i] = e = spawn();
 295                                 e.sv_entnum = i;
 296                                 e.ping = 0;
 297                                 e.ping_packetloss = 0;
 298                                 e.ping_movementloss = 0;
 299                                 //e.gotscores = 0; // we might already have the scores...
 300                                 SetTeam(e, GetPlayerColor(i)); // will not hurt; later updates come with HUD_UpdatePlayerTeams
 301                                 RegisterPlayer(e);
 302                                 HUD_UpdatePlayerPos(e);
 303                         }
 304                 }
 305         }
 306         self.nextthink = time + 0.2;
 307 }
 308
 309 void Porto_Init();
 310 void TrueAim_Init();
 311 void PostInit(void)
 312 {
 313         entity playerchecker;
 314         playerchecker = spawn();
 315         playerchecker.think = Playerchecker_Think;
 316         playerchecker.nextthink = time + 0.2;
 317
 318         Porto_Init();
 319         TrueAim_Init();
 320
 321         postinit = true;
 322 }
 323
 324 // CSQC_InputEvent : Used to perform actions based on any key pressed, key released and mouse on the client.
 325 // Return value should be 1 if CSQC handled the input, otherwise return 0 to have the input passed to the engine.
 326 // All keys are in ascii.
 327 // bInputType = 0 is key pressed, 1 is key released, 2 and 3 are mouse input.
 328 // In the case of keyboard input, nPrimary is the ascii code, and nSecondary is 0.
 329 // In the case of mouse input, nPrimary is xdelta, nSecondary is ydelta.
 330 // In the case of mouse input after a setcursormode(1) call, nPrimary is xpos, nSecondary is ypos.
 331 float CSQC_InputEvent(float bInputType, float nPrimary, float nSecondary)
 332 {
 333         float bSkipKey;
 334         bSkipKey = false;
 335
 336         if (HUD_Panel_InputEvent(bInputType, nPrimary, nSecondary))
 337                 return true;
 338
 339         if ( HUD_Radar_InputEvent(bInputType, nPrimary, nSecondary) )
 340                 return true;
 341
 342         if (MapVote_InputEvent(bInputType, nPrimary, nSecondary))
 343                 return true;
 344
 345         if(menu_visible && menu_action)
 346                 if(menu_action(bInputType, nPrimary, nSecondary))
 347                         return true;
 348
 349         return bSkipKey;
 350 }
 351
 352 // END REQUIRED CSQC FUNCTIONS
 353 // --------------------------------------------------------------------------
 354
 355 // --------------------------------------------------------------------------
 356 // BEGIN OPTIONAL CSQC FUNCTIONS
 357 void Ent_RemoveEntCS()
 358 {
 359         entcs_receiver[self.sv_entnum] = world;
 360 }
 361 void Ent_ReadEntCS()
 362 {
 363     int sf;
 364         InterpolateOrigin_Undo();
 365
 366         self.classname = "entcs_receiver";
 367         sf = ReadByte();
 368
 369         if(sf & 1)
 370                 self.sv_entnum = ReadByte();
 371         if(sf & 2)
 372         {
 373                 self.origin_x = ReadShort();
 374                 self.origin_y = ReadShort();
 375                 self.origin_z = ReadShort();
 376                 setorigin(self, self.origin);
 377         }
 378         if(sf & 4)
 379         {
 380                 self.angles_y = ReadByte() * 360.0 / 256;
 381                 self.angles_x = self.angles_z = 0;
 382         }
 383         if(sf & 8)
 384                 self.healthvalue = ReadByte() * 10;
 385         if(sf & 16)
 386                 self.armorvalue = ReadByte() * 10;
 387
 388         entcs_receiver[self.sv_entnum] = self;
 389         self.entremove = Ent_RemoveEntCS;
 390         self.iflags |= IFLAG_ORIGIN;
 391
 392         InterpolateOrigin_Note();
 393 }
 394
 395 void Ent_Remove();
 396
 397 void Ent_RemovePlayerScore()
 398 {
 399         if(self.owner) {
 400                 SetTeam(self.owner, -1);
 401                 self.owner.gotscores = 0;
 402                 for(int i = 0; i < MAX_SCORE; ++i) {
 403                         self.owner.(scores[i]) = 0; // clear all scores
 404                 }
 405         }
 406 }
 407
 408 void Ent_ReadPlayerScore()
 409 {
 410         int i, n;
 411         bool isNew;
 412         entity o;
 413
 414         // damnit -.- don't want to go change every single .sv_entnum in hud.qc AGAIN
 415         // (no I've never heard of M-x replace-string, sed, or anything like that)
 416         isNew = !self.owner; // workaround for DP bug
 417         n = ReadByte()-1;
 418
 419 #ifdef DP_CSQC_ENTITY_REMOVE_IS_B0RKED
 420         if(!isNew && n != self.sv_entnum)
 421         {
 422                 //print("A CSQC entity changed its owner!\n");
 423                 printf("A CSQC entity changed its owner! (edict: %d, classname: %s)\n", num_for_edict(self), self.classname);
 424                 isNew = true;
 425                 Ent_Remove();
 426                 self.enttype = ENT_CLIENT_SCORES;
 427         }
 428 #endif
 429
 430         self.sv_entnum = n;
 431
 432         if (!(playerslots[self.sv_entnum]))
 433                 playerslots[self.sv_entnum] = spawn();
 434         o = self.owner = playerslots[self.sv_entnum];
 435         o.sv_entnum = self.sv_entnum;
 436         o.gotscores = 1;
 437
 438         //if (!o.sort_prev)
 439         //      RegisterPlayer(o);
 440         //playerchecker will do this for us later, if it has not already done so
 441
 442     int sf, lf;
 443 #if MAX_SCORE <= 8
 444         sf = ReadByte();
 445         lf = ReadByte();
 446 #else
 447         sf = ReadShort();
 448         lf = ReadShort();
 449 #endif
 450     int p;
 451         for(i = 0, p = 1; i < MAX_SCORE; ++i, p *= 2)
 452                 if(sf & p)
 453                 {
 454                         if(lf & p)
 455                                 o.(scores[i]) = ReadInt24_t();
 456                         else
 457                                 o.(scores[i]) = ReadChar();
 458                 }
 459
 460         if(o.sort_prev)
 461                 HUD_UpdatePlayerPos(o); // if not registered, we cannot do this yet!
 462
 463         self.entremove = Ent_RemovePlayerScore;
 464 }
 465
 466 void Ent_ReadTeamScore()
 467 {
 468         int i;
 469         entity o;
 470
 471         self.team = ReadByte();
 472         o = self.owner = GetTeam(self.team, true); // these team numbers can always be trusted
 473
 474     int sf, lf;
 475 #if MAX_TEAMSCORE <= 8
 476         sf = ReadByte();
 477         lf = ReadByte();
 478 #else
 479         sf = ReadShort();
 480         lf = ReadShort();
 481 #endif
 482         int p;
 483         for(i = 0, p = 1; i < MAX_TEAMSCORE; ++i, p *= 2)
 484                 if(sf & p)
 485                 {
 486                         if(lf & p)
 487                                 o.(teamscores[i]) = ReadInt24_t();
 488                         else
 489                                 o.(teamscores[i]) = ReadChar();
 490                 }
 491
 492         HUD_UpdateTeamPos(o);
 493 }
 494
 495 void Ent_ClientData()
 496 {
 497         float newspectatee_status;
 498
 499     int f = ReadByte();
 500
 501         scoreboard_showscores_force = (f & 1);
 502
 503         if(f & 2)
 504         {
 505                 newspectatee_status = ReadByte();
 506                 if(newspectatee_status == player_localnum + 1)
 507                         newspectatee_status = -1; // observing
 508         }
 509         else
 510                 newspectatee_status = 0;
 511
 512         spectatorbutton_zoom = (f & 4);
 513
 514         if(f & 8)
 515         {
 516                 angles_held_status = 1;
 517                 angles_held.x = ReadAngle();
 518                 angles_held.y = ReadAngle();
 519                 angles_held.z = 0;
 520         }
 521         else
 522                 angles_held_status = 0;
 523
 524         if(newspectatee_status != spectatee_status)
 525         {
 526                 // clear race stuff
 527                 race_laptime = 0;
 528                 race_checkpointtime = 0;
 529         }
 530         if (autocvar_hud_panel_healtharmor_progressbar_gfx)
 531         {
 532                 if ( (spectatee_status == -1 && newspectatee_status > 0) //before observing, now spectating
 533                   || (spectatee_status > 0 && newspectatee_status > 0 && spectatee_status != newspectatee_status) //changed spectated player
 534                 )
 535                         prev_p_health = -1;
 536                 else if(spectatee_status && !newspectatee_status) //before observing/spectating, now playing
 537                         prev_health = -1;
 538         }
 539         spectatee_status = newspectatee_status;
 540
 541         // we could get rid of spectatee_status, and derive it from player_localentnum and player_localnum
 542 }
 543
 544 void Ent_Nagger()
 545 {
 546     int i, j, b, f;
 547
 548     int nags = ReadByte(); // NAGS NAGS NAGS NAGS NAGS NAGS NADZ NAGS NAGS NAGS
 549
 550         if(!(nags & 4))
 551         {
 552                 if(vote_called_vote)
 553                         strunzone(vote_called_vote);
 554                 vote_called_vote = string_null;
 555                 vote_active = 0;
 556         }
 557         else
 558         {
 559                 vote_active = 1;
 560         }
 561
 562         if(nags & 64)
 563         {
 564                 vote_yescount = ReadByte();
 565                 vote_nocount = ReadByte();
 566                 vote_needed = ReadByte();
 567                 vote_highlighted = ReadChar();
 568         }
 569
 570         if(nags & 128)
 571         {
 572                 if(vote_called_vote)
 573                         strunzone(vote_called_vote);
 574                 vote_called_vote = strzone(ColorTranslateRGB(ReadString()));
 575         }
 576
 577         if(nags & 1)
 578         {
 579                 for(j = 0; j < maxclients; ++j)
 580                         if(playerslots[j])
 581                                 playerslots[j].ready = 1;
 582                 for(i = 1; i <= maxclients; i += 8)
 583                 {
 584                         f = ReadByte();
 585                         for(j = i-1, b = 1; b < 256; b *= 2, ++j)
 586                                 if (!(f & b))
 587                                         if(playerslots[j])
 588                                                 playerslots[j].ready = 0;
 589                 }
 590         }
 591
 592         ready_waiting = (nags & 1);
 593         ready_waiting_for_me = (nags & 2);
 594         vote_waiting = (nags & 4);
 595         vote_waiting_for_me = (nags & 8);
 596         warmup_stage = (nags & 16);
 597 }
 598
 599 void Ent_EliminatedPlayers()
 600 {
 601     int i, j, b, f;
 602
 603     int sf = ReadByte();
 604         if(sf & 1)
 605         {
 606                 for(j = 0; j < maxclients; ++j)
 607                         if(playerslots[j])
 608                                 playerslots[j].eliminated = 1;
 609                 for(i = 1; i <= maxclients; i += 8)
 610                 {
 611                         f = ReadByte();
 612                         for(j = i-1, b = 1; b < 256; b *= 2, ++j)
 613                                 if (!(f & b))
 614                                         if(playerslots[j])
 615                                                 playerslots[j].eliminated = 0;
 616                 }
 617         }
 618 }
 619
 620 void Ent_RandomSeed()
 621 {
 622         float s;
 623         prandom_debug();
 624         s = ReadShort();
 625         psrandom(s);
 626 }
 627
 628 void Ent_ReadAccuracy(void)
 629 {
 630     int f, w;
 631     int sf = ReadInt24_t();
 632         if(sf == 0)
 633         {
 634                 for(w = 0; w <= WEP_LAST - WEP_FIRST; ++w)
 635                         weapon_accuracy[w] = -1;
 636                 return;
 637         }
 638
 639         for(w = 0, f = 1; w <= WEP_LAST - WEP_FIRST; ++w)
 640         {
 641                 if(sf & f)
 642                 {
 643             int b = ReadByte();
 644                         if(b == 0)
 645                                 weapon_accuracy[w] = -1;
 646                         else if(b == 255)
 647                                 weapon_accuracy[w] = 1.0; // no better error handling yet, sorry
 648                         else
 649                                 weapon_accuracy[w] = (b - 1.0) / 100.0;
 650                 }
 651                 if(f == 0x800000)
 652                         f = 1;
 653                 else
 654                         f *= 2;
 655         }
 656 }
 657
 658 void Spawn_Draw(void)
 659 {
 660         pointparticles(self.cnt, self.origin + '0 0 28', '0 0 2', bound(0, frametime, 0.1));
 661 }
 662
 663 void Ent_ReadSpawnPoint(float is_new) // entity for spawnpoint
 664 {
 665         float teamnum = (ReadByte() - 1);
 666         vector spn_origin;
 667         spn_origin.x = ReadShort();
 668         spn_origin.y = ReadShort();
 669         spn_origin.z = ReadShort();
 670
 671         if(is_new)
 672         {
 673                 self.origin = spn_origin;
 674                 setsize(self, PL_MIN, PL_MAX);
 675                 droptofloor();
 676
 677                 /*if(autocvar_cl_spawn_point_model) // needs a model first
 678                 {
 679                         self.mdl = "models/spawnpoint.md3";
 680                         self.colormod = Team_ColorRGB(teamnum);
 681                         precache_model(self.mdl);
 682                         setmodel(self, self.mdl);
 683                         self.drawmask = MASK_NORMAL;
 684                         //self.movetype = MOVETYPE_NOCLIP;
 685                         //self.draw = Spawn_Draw;
 686                 }*/
 687                 if(autocvar_cl_spawn_point_particles)
 688                 {
 689                         if((serverflags & SERVERFLAG_TEAMPLAY))
 690                         {
 691                                 switch(teamnum)
 692                                 {
 693                                         case NUM_TEAM_1: self.cnt = particleeffectnum("spawn_point_red"); break;
 694                                         case NUM_TEAM_2: self.cnt = particleeffectnum("spawn_point_blue"); break;
 695                                         case NUM_TEAM_3: self.cnt = particleeffectnum("spawn_point_yellow"); break;
 696                                         case NUM_TEAM_4: self.cnt = particleeffectnum("spawn_point_pink"); break;
 697                                         default: self.cnt = particleeffectnum("spawn_point_neutral"); break;
 698                                 }
 699                         }
 700                         else { self.cnt = particleeffectnum("spawn_point_neutral"); }
 701
 702                         self.draw = Spawn_Draw;
 703                 }
 704         }
 705
 706         //printf("Ent_ReadSpawnPoint(is_new = %d); origin = %s, team = %d, effect = %d\n", is_new, vtos(self.origin), teamnum, self.cnt);
 707 }
 708
 709 void Ent_ReadSpawnEvent(float is_new)
 710 {
 711         // If entnum is 0, ONLY do the local spawn actions
 712         // this way the server can disable the sending of
 713         // spawn origin or such to clients if wanted.
 714         float entnum = ReadByte();
 715
 716         if(entnum)
 717         {
 718                 self.origin_x = ReadShort();
 719                 self.origin_y = ReadShort();
 720                 self.origin_z = ReadShort();
 721
 722                 if(is_new)
 723                 {
 724                         float teamnum = GetPlayerColor(entnum - 1);
 725
 726                         if(autocvar_cl_spawn_event_particles)
 727                         {
 728                                 switch(teamnum)
 729                                 {
 730                                         case NUM_TEAM_1: pointparticles(particleeffectnum("spawn_event_red"), self.origin, '0 0 0', 1); break;
 731                                         case NUM_TEAM_2: pointparticles(particleeffectnum("spawn_event_blue"), self.origin, '0 0 0', 1); break;
 732                                         case NUM_TEAM_3: pointparticles(particleeffectnum("spawn_event_yellow"), self.origin, '0 0 0', 1); break;
 733                                         case NUM_TEAM_4: pointparticles(particleeffectnum("spawn_event_pink"), self.origin, '0 0 0', 1); break;
 734                                         default: pointparticles(particleeffectnum("spawn_event_neutral"), self.origin, '0 0 0', 1); break;
 735                                 }
 736                         }
 737                         if(autocvar_cl_spawn_event_sound)
 738                         {
 739                                 sound(self, CH_TRIGGER, "misc/spawn.wav", VOL_BASE, ATTEN_NORM);
 740                         }
 741                 }
 742         }
 743
 744         // local spawn actions
 745         if(is_new && (!entnum || (entnum == player_localentnum)))
 746         {
 747                 zoomin_effect = 1;
 748                 current_viewzoom = (1 / bound(1, autocvar_cl_spawnzoom_factor, 16));
 749
 750                 if(autocvar_cl_unpress_zoom_on_spawn)
 751                 {
 752                         localcmd("-zoom\n");
 753                         button_zoom = false;
 754                 }
 755         }
 756         HUD_Radar_Hide_Maximized();
 757         //printf("Ent_ReadSpawnEvent(is_new = %d); origin = %s, entnum = %d, localentnum = %d\n", is_new, vtos(self.origin), entnum, player_localentnum);
 758 }
 759
 760 // CSQC_Ent_Update : Called every frame that the server has indicated an update to the SSQC / CSQC entity has occured.
 761 // The only parameter reflects if the entity is "new" to the client, meaning it just came into the client's PVS.
 762 void Ent_RadarLink();
 763 void Ent_Init();
 764 void Ent_ScoresInfo();
 765 void CSQC_Ent_Update(float bIsNewEntity)
 766 {
 767         float t;
 768         float savetime;
 769         t = ReadByte();
 770
 771         if(autocvar_developer_csqcentities)
 772                 printf("CSQC_Ent_Update(%d) with self=%i self.entnum=%d self.enttype=%d t=%d\n", bIsNewEntity, self, self.entnum, self.enttype, t);
 773
 774         // set up the "time" global for received entities to be correct for interpolation purposes
 775         savetime = time;
 776         if(servertime)
 777         {
 778                 time = servertime;
 779         }
 780         else
 781         {
 782                 serverprevtime = time;
 783                 serverdeltatime = getstatf(STAT_MOVEVARS_TICRATE) * getstatf(STAT_MOVEVARS_TIMESCALE);
 784                 time = serverprevtime + serverdeltatime;
 785         }
 786
 787 #ifdef DP_CSQC_ENTITY_REMOVE_IS_B0RKED
 788         if(self.enttype)
 789         {
 790                 if(t != self.enttype || bIsNewEntity)
 791                 {
 792                         //print("A CSQC entity changed its type!\n");
 793                         printf("A CSQC entity changed its type! (edict: %d, server: %d, type: %d -> %d)\n", num_for_edict(self), self.entnum, self.enttype, t);
 794                         Ent_Remove();
 795                         clearentity(self);
 796                         bIsNewEntity = 1;
 797                 }
 798         }
 799         else
 800         {
 801                 if(!bIsNewEntity)
 802                 {
 803                         printf("A CSQC entity appeared out of nowhere! (edict: %d, server: %d, type: %d)\n", num_for_edict(self), self.entnum, t);
 804                         bIsNewEntity = 1;
 805                 }
 806         }
 807 #endif
 808         self.enttype = t;
 809         switch(t)
 810         {
 811                 case ENT_CLIENT_ENTCS: Ent_ReadEntCS(); break;
 812                 case ENT_CLIENT_SCORES: Ent_ReadPlayerScore(); break;
 813                 case ENT_CLIENT_TEAMSCORES: Ent_ReadTeamScore(); break;
 814                 case ENT_CLIENT_POINTPARTICLES: Ent_PointParticles(); break;
 815                 case ENT_CLIENT_RAINSNOW: Ent_RainOrSnow(); break;
 816                 case ENT_CLIENT_LASER: Ent_Laser(); break;
 817                 case ENT_CLIENT_NAGGER: Ent_Nagger(); break;
 818                 case ENT_CLIENT_ELIMINATEDPLAYERS: Ent_EliminatedPlayers(); break;
 819                 case ENT_CLIENT_WAYPOINT: Ent_WaypointSprite(); break;
 820                 case ENT_CLIENT_RADARLINK: Ent_RadarLink(); break;
 821                 case ENT_CLIENT_PROJECTILE: Ent_Projectile(); break;
 822                 case ENT_CLIENT_GIBSPLASH: Ent_GibSplash(bIsNewEntity); break;
 823                 case ENT_CLIENT_DAMAGEINFO: Ent_DamageInfo(bIsNewEntity); break;
 824                 case ENT_CLIENT_CASING: Ent_Casing(bIsNewEntity); break;
 825                 case ENT_CLIENT_INIT: Ent_Init(); break;
 826                 case ENT_CLIENT_SCORES_INFO: Ent_ScoresInfo(); break;
 827                 case ENT_CLIENT_MAPVOTE: Ent_MapVote(); break;
 828                 case ENT_CLIENT_CLIENTDATA: Ent_ClientData(); break;
 829                 case ENT_CLIENT_RANDOMSEED: Ent_RandomSeed(); break;
 830                 case ENT_CLIENT_WALL: Ent_Wall(); break;
 831                 case ENT_CLIENT_MODELEFFECT: Ent_ModelEffect(bIsNewEntity); break;
 832                 case ENT_CLIENT_TUBANOTE: Ent_TubaNote(bIsNewEntity); break;
 833                 case ENT_CLIENT_WARPZONE: WarpZone_Read(bIsNewEntity); break;
 834                 case ENT_CLIENT_WARPZONE_CAMERA: WarpZone_Camera_Read(bIsNewEntity); break;
 835                 case ENT_CLIENT_WARPZONE_TELEPORTED: WarpZone_Teleported_Read(bIsNewEntity); break;
 836                 case ENT_CLIENT_TRIGGER_MUSIC: Ent_ReadTriggerMusic(); break;
 837                 case ENT_CLIENT_HOOK: Ent_ReadHook(bIsNewEntity, ENT_CLIENT_HOOK); break;
 838                 case ENT_CLIENT_ARC_BEAM: Ent_ReadArcBeam(bIsNewEntity); break;
 839                 case ENT_CLIENT_ACCURACY: Ent_ReadAccuracy(); break;
 840                 case ENT_CLIENT_AUXILIARYXHAIR: Net_AuXair2(bIsNewEntity); break;
 841                 case ENT_CLIENT_TURRET: ent_turret(); break;
 842                 case ENT_CLIENT_GENERATOR: ent_generator(); break;
 843                 case ENT_CLIENT_CONTROLPOINT_ICON: ent_cpicon(); break;
 844                 case ENT_CLIENT_MODEL: CSQCModel_Read(bIsNewEntity); break;
 845                 case ENT_CLIENT_ITEM: ItemRead(bIsNewEntity); break;
 846                 case ENT_CLIENT_BUMBLE_RAYGUN: bumble_raygun_read(bIsNewEntity); break;
 847                 case ENT_CLIENT_SPAWNPOINT: Ent_ReadSpawnPoint(bIsNewEntity); break;
 848                 case ENT_CLIENT_SPAWNEVENT: Ent_ReadSpawnEvent(bIsNewEntity); break;
 849                 case ENT_CLIENT_NOTIFICATION: Read_Notification(bIsNewEntity); break;
 850                 case ENT_CLIENT_HEALING_ORB: ent_healer(); break;
 851
 852                 default:
 853                         //error(strcat(_("unknown entity type in CSQC_Ent_Update: %d\n"), self.enttype));
 854                         error(sprintf("Unknown entity type in CSQC_Ent_Update (enttype: %d, edict: %d, classname: %s)\n", self.enttype, num_for_edict(self), self.classname));
 855                         break;
 856         }
 857
 858         time = savetime;
 859 }
 860 // Destructor, but does NOT deallocate the entity by calling remove(). Also
 861 // used when an entity changes its type. For an entity that someone interacts
 862 // with others, make sure it can no longer do so.
 863 void Ent_Remove()
 864 {
 865         if(self.entremove)
 866                 self.entremove();
 867
 868         if(self.skeletonindex)
 869         {
 870                 skel_delete(self.skeletonindex);
 871                 self.skeletonindex = 0;
 872         }
 873
 874         if(self.snd_looping > 0)
 875         {
 876                 sound(self, self.snd_looping, "misc/null.wav", VOL_BASE, autocvar_g_jetpack_attenuation);
 877                 self.snd_looping = 0;
 878         }
 879
 880         self.enttype = 0;
 881         self.classname = "";
 882         self.draw = menu_sub_null;
 883         self.entremove = menu_sub_null;
 884         // TODO possibly set more stuff to defaults
 885 }
 886 // CSQC_Ent_Remove : Called when the server requests a SSQC / CSQC entity to be removed.  Essentially call remove(self) as well.
 887 void CSQC_Ent_Remove()
 888 {
 889         if(autocvar_developer_csqcentities)
 890                 printf("CSQC_Ent_Remove() with self=%i self.entnum=%d self.enttype=%d\n", self, self.entnum, self.enttype);
 891
 892         if(wasfreed(self))
 893         {
 894                 print("WARNING: CSQC_Ent_Remove called for already removed entity. Packet loss?\n");
 895                 return;
 896         }
 897         if(self.enttype)
 898                 Ent_Remove();
 899         remove(self);
 900 }
 901
 902 void Gamemode_Init()
 903 {
 904         if (!isdemo())
 905         {
 906                 if(!(calledhooks & HOOK_START))
 907                         localcmd("\n_cl_hook_gamestart ", MapInfo_Type_ToString(gametype), "\n");
 908                 calledhooks |= HOOK_START;
 909         }
 910 }
 911 // CSQC_Parse_StuffCmd : Provides the stuffcmd string in the first parameter that the server provided.  To execute standard behavior, simply execute localcmd with the string.
 912 void CSQC_Parse_StuffCmd(string strMessage)
 913 {
 914         if(autocvar_developer_csqcentities)
 915                 printf("CSQC_Parse_StuffCmd(\"%s\")\n", strMessage);
 916
 917         localcmd(strMessage);
 918 }
 919 // CSQC_Parse_Print : Provides the print string in the first parameter that the server provided.  To execute standard behavior, simply execute print with the string.
 920 void CSQC_Parse_Print(string strMessage)
 921 {
 922         if(autocvar_developer_csqcentities)
 923                 printf("CSQC_Parse_Print(\"%s\")\n", strMessage);
 924
 925         print(ColorTranslateRGB(strMessage));
 926 }
 927
 928 // CSQC_Parse_CenterPrint : Provides the centerprint_hud string in the first parameter that the server provided.
 929 void CSQC_Parse_CenterPrint(string strMessage)
 930 {
 931         if(autocvar_developer_csqcentities)
 932                 printf("CSQC_Parse_CenterPrint(\"%s\")\n", strMessage);
 933
 934         centerprint_hud(strMessage);
 935 }
 936
 937 string notranslate_fogcmd1 = "\nfog ";
 938 string notranslate_fogcmd2 = "\nr_fog_exp2 0\nr_drawfog 1\n";
 939 void Fog_Force()
 940 {
 941         // TODO somehow thwart prvm_globalset client ...
 942
 943         if(autocvar_cl_orthoview && autocvar_cl_orthoview_nofog)
 944                 { localcmd("\nr_drawfog 0\n"); }
 945         else if(forcefog != "")
 946                 { localcmd(strcat(notranslate_fogcmd1, forcefog, notranslate_fogcmd2)); }
 947 }
 948
 949 void Gamemode_Init();
 950 void Ent_ScoresInfo()
 951 {
 952     int i;
 953         self.classname = "ent_client_scores_info";
 954         gametype = ReadInt24_t();
 955         HUD_ModIcons_SetFunc();
 956         for(i = 0; i < MAX_SCORE; ++i)
 957         {
 958                 if(scores_label[i])
 959                         strunzone(scores_label[i]);
 960                 scores_label[i] = strzone(ReadString());
 961                 scores_flags[i] = ReadByte();
 962         }
 963         for(i = 0; i < MAX_TEAMSCORE; ++i)
 964         {
 965                 if(teamscores_label[i])
 966                         strunzone(teamscores_label[i]);
 967                 teamscores_label[i] = strzone(ReadString());
 968                 teamscores_flags[i] = ReadByte();
 969         }
 970         HUD_InitScores();
 971         Gamemode_Init();
 972 }
 973
 974 void Ent_Init()
 975 {
 976         self.classname = "ent_client_init";
 977
 978         nb_pb_period = ReadByte() / 32; //Accuracy of 1/32th
 979
 980         hook_shotorigin[0] = decompressShotOrigin(ReadInt24_t());
 981         hook_shotorigin[1] = decompressShotOrigin(ReadInt24_t());
 982         hook_shotorigin[2] = decompressShotOrigin(ReadInt24_t());
 983         hook_shotorigin[3] = decompressShotOrigin(ReadInt24_t());
 984         arc_shotorigin[0] = decompressShotOrigin(ReadInt24_t());
 985         arc_shotorigin[1] = decompressShotOrigin(ReadInt24_t());
 986         arc_shotorigin[2] = decompressShotOrigin(ReadInt24_t());
 987         arc_shotorigin[3] = decompressShotOrigin(ReadInt24_t());
 988
 989         if(forcefog)
 990                 strunzone(forcefog);
 991         forcefog = strzone(ReadString());
 992
 993         armorblockpercent = ReadByte() / 255.0;
 994
 995         g_balance_mortar_bouncefactor = ReadCoord();
 996         g_balance_mortar_bouncestop = ReadCoord();
 997         g_balance_electro_secondary_bouncefactor = ReadCoord();
 998         g_balance_electro_secondary_bouncestop = ReadCoord();
 999
1000         vortex_scope = !ReadByte();
1001         rifle_scope = !ReadByte();
1002
1003         serverflags = ReadByte();
1004
1005         minelayer_maxmines = ReadByte();
1006
1007         hagar_maxrockets = ReadByte();
1008
1009         g_trueaim_minrange = ReadCoord();
1010         g_balance_porto_secondary = ReadByte();
1011
1012         if(!postinit)
1013                 PostInit();
1014 }
1015
1016 void Net_ReadRace()
1017 {
1018         float b;
1019
1020         b = ReadByte();
1021
1022         switch(b)
1023         {
1024                 case RACE_NET_CHECKPOINT_HIT_QUALIFYING:
1025                         race_checkpoint = ReadByte();
1026                         race_time = ReadInt24_t();
1027                         race_previousbesttime = ReadInt24_t();
1028                         if(race_previousbestname)
1029                                 strunzone(race_previousbestname);
1030                         race_previousbestname = strzone(ColorTranslateRGB(ReadString()));
1031
1032                         race_checkpointtime = time;
1033
1034                         if(race_checkpoint == 0 || race_checkpoint == 254)
1035                         {
1036                                 race_penaltyaccumulator = 0;
1037                                 race_laptime = time; // valid
1038                         }
1039
1040                         break;
1041
1042                 case RACE_NET_CHECKPOINT_CLEAR:
1043                         race_laptime = 0;
1044                         race_checkpointtime = 0;
1045                         break;
1046
1047                 case RACE_NET_CHECKPOINT_NEXT_SPEC_QUALIFYING:
1048                         race_laptime = ReadCoord();
1049                         race_checkpointtime = -99999;
1050                         // fall through
1051                 case RACE_NET_CHECKPOINT_NEXT_QUALIFYING:
1052                         race_nextcheckpoint = ReadByte();
1053
1054                         race_nextbesttime = ReadInt24_t();
1055                         if(race_nextbestname)
1056                                 strunzone(race_nextbestname);
1057                         race_nextbestname = strzone(ColorTranslateRGB(ReadString()));
1058                         break;
1059
1060                 case RACE_NET_CHECKPOINT_HIT_RACE:
1061                         race_mycheckpoint = ReadByte();
1062                         race_mycheckpointtime = time;
1063                         race_mycheckpointdelta = ReadInt24_t();
1064                         race_mycheckpointlapsdelta = ReadByte();
1065                         if(race_mycheckpointlapsdelta >= 128)
1066                                 race_mycheckpointlapsdelta -= 256;
1067                         if(race_mycheckpointenemy)
1068                                 strunzone(race_mycheckpointenemy);
1069                         race_mycheckpointenemy = strzone(ColorTranslateRGB(ReadString()));
1070                         break;
1071
1072                 case RACE_NET_CHECKPOINT_HIT_RACE_BY_OPPONENT:
1073                         race_othercheckpoint = ReadByte();
1074                         race_othercheckpointtime = time;
1075                         race_othercheckpointdelta = ReadInt24_t();
1076                         race_othercheckpointlapsdelta = ReadByte();
1077                         if(race_othercheckpointlapsdelta >= 128)
1078                                 race_othercheckpointlapsdelta -= 256;
1079                         if(race_othercheckpointenemy)
1080                                 strunzone(race_othercheckpointenemy);
1081                         race_othercheckpointenemy = strzone(ColorTranslateRGB(ReadString()));
1082                         break;
1083
1084                 case RACE_NET_PENALTY_RACE:
1085                         race_penaltyeventtime = time;
1086                         race_penaltytime = ReadShort();
1087                         //race_penaltyaccumulator += race_penaltytime;
1088                         if(race_penaltyreason)
1089                                 strunzone(race_penaltyreason);
1090                         race_penaltyreason = strzone(ReadString());
1091                         break;
1092
1093                 case RACE_NET_PENALTY_QUALIFYING:
1094                         race_penaltyeventtime = time;
1095                         race_penaltytime = ReadShort();
1096                         race_penaltyaccumulator += race_penaltytime;
1097                         if(race_penaltyreason)
1098                                 strunzone(race_penaltyreason);
1099                         race_penaltyreason = strzone(ReadString());
1100                         break;
1101
1102                 case RACE_NET_SERVER_RECORD:
1103                         race_server_record = ReadInt24_t();
1104                         break;
1105                 case RACE_NET_SPEED_AWARD:
1106                         race_speedaward = ReadInt24_t();
1107                         if(race_speedaward_holder)
1108                                 strunzone(race_speedaward_holder);
1109                         race_speedaward_holder = strzone(ReadString());
1110                         break;
1111                 case RACE_NET_SPEED_AWARD_BEST:
1112                         race_speedaward_alltimebest = ReadInt24_t();
1113                         if(race_speedaward_alltimebest_holder)
1114                                 strunzone(race_speedaward_alltimebest_holder);
1115                         race_speedaward_alltimebest_holder = strzone(ReadString());
1116                         break;
1117                 case RACE_NET_SERVER_RANKINGS:
1118                         float prevpos, del;
1119             int pos = ReadShort();
1120                         prevpos = ReadShort();
1121                         del = ReadShort();
1122
1123                         // move other rankings out of the way
1124             int i;
1125                         if (prevpos) {
1126                                 for (i=prevpos-1;i>pos-1;--i) {
1127                                         grecordtime[i] = grecordtime[i-1];
1128                                         if(grecordholder[i])
1129                                                 strunzone(grecordholder[i]);
1130                                         grecordholder[i] = strzone(grecordholder[i-1]);
1131                                 }
1132                         } else if (del) { // a record has been deleted by the admin
1133                                 for (i=pos-1; i<= RANKINGS_CNT-1; ++i) {
1134                                         if (i == RANKINGS_CNT-1) { // clear out last record
1135                                                 grecordtime[i] = 0;
1136                                                 if (grecordholder[i])
1137                                                         strunzone(grecordholder[i]);
1138                                                 grecordholder[i] = string_null;
1139                                         }
1140                                         else {
1141                                                 grecordtime[i] = grecordtime[i+1];
1142                                                 if (grecordholder[i])
1143                                                         strunzone(grecordholder[i]);
1144                                                 grecordholder[i] = strzone(grecordholder[i+1]);
1145                                         }
1146                                 }
1147                         } else { // player has no ranked record yet
1148                                 for (i=RANKINGS_CNT-1;i>pos-1;--i) {
1149                                         grecordtime[i] = grecordtime[i-1];
1150                                         if(grecordholder[i])
1151                                                 strunzone(grecordholder[i]);
1152                                         grecordholder[i] = strzone(grecordholder[i-1]);
1153                                 }
1154                         }
1155
1156                         // store new ranking
1157                         if(grecordholder[pos-1] != "")
1158                                 strunzone(grecordholder[pos-1]);
1159                         grecordholder[pos-1] = strzone(ReadString());
1160                         grecordtime[pos-1] = ReadInt24_t();
1161                         if(grecordholder[pos-1] == GetPlayerName(player_localnum))
1162                                 race_myrank = pos;
1163                         break;
1164                 case RACE_NET_SERVER_STATUS:
1165                         race_status = ReadShort();
1166                         if(race_status_name)
1167                                 strunzone(race_status_name);
1168                         race_status_name = strzone(ReadString());
1169         }
1170 }
1171
1172 void Net_TeamNagger()
1173 {
1174         teamnagger = 1;
1175 }
1176
1177 void Net_ReadPingPLReport()
1178 {
1179         int e, pi, pl, ml;
1180         e = ReadByte();
1181         pi = ReadShort();
1182         pl = ReadByte();
1183         ml = ReadByte();
1184         if (!(playerslots[e]))
1185                 return;
1186         playerslots[e].ping = pi;
1187         playerslots[e].ping_packetloss = pl / 255.0;
1188         playerslots[e].ping_movementloss = ml / 255.0;
1189 }
1190
1191 void Net_WeaponComplain()
1192 {
1193         complain_weapon = ReadByte();
1194
1195         if(complain_weapon_name)
1196                 strunzone(complain_weapon_name);
1197         complain_weapon_name = strzone(WEP_NAME(complain_weapon));
1198
1199         complain_weapon_type = ReadByte();
1200
1201         complain_weapon_time = time;
1202         weapontime = time; // ping the weapon panel
1203
1204         switch(complain_weapon_type)
1205         {
1206                 case 0: Local_Notification(MSG_MULTI, ITEM_WEAPON_NOAMMO, complain_weapon); break;
1207                 case 1: Local_Notification(MSG_MULTI, ITEM_WEAPON_DONTHAVE, complain_weapon); break;
1208                 default: Local_Notification(MSG_MULTI, ITEM_WEAPON_UNAVAILABLE, complain_weapon); break;
1209         }
1210 }
1211
1212 // CSQC_Parse_TempEntity : Handles all temporary entity network data in the CSQC layer.
1213 // You must ALWAYS first acquire the temporary ID, which is sent as a byte.
1214 // Return value should be 1 if CSQC handled the temporary entity, otherwise return 0 to have the engine process the event.
1215 float CSQC_Parse_TempEntity()
1216 {
1217         float bHandled;
1218                 bHandled  = true;
1219         // Acquire TE ID
1220         float nTEID;
1221                 nTEID = ReadByte();
1222
1223         if(autocvar_developer_csqcentities)
1224                 printf("CSQC_Parse_TempEntity() with nTEID=%d\n", nTEID);
1225
1226                 // NOTE: Could just do return instead of break...
1227         switch(nTEID)
1228         {
1229                 case TE_CSQC_TARGET_MUSIC:
1230                         Net_TargetMusic();
1231                         bHandled = true;
1232                         break;
1233                 case TE_CSQC_PICTURE:
1234                         Net_MapVote_Picture();
1235                         bHandled = true;
1236                         break;
1237                 case TE_CSQC_RACE:
1238                         Net_ReadRace();
1239                         bHandled = true;
1240                         break;
1241                 case TE_CSQC_VORTEXBEAMPARTICLE:
1242                         Net_ReadVortexBeamParticle();
1243                         bHandled = true;
1244                         break;
1245                 case TE_CSQC_TEAMNAGGER:
1246                         Net_TeamNagger();
1247                         bHandled = true;
1248                         break;
1249                 case TE_CSQC_ARC:
1250                         Net_ReadArc();
1251                         bHandled = true;
1252                         break;
1253                 case TE_CSQC_PINGPLREPORT:
1254                         Net_ReadPingPLReport();
1255                         bHandled = true;
1256                         break;
1257                 case TE_CSQC_WEAPONCOMPLAIN:
1258                         Net_WeaponComplain();
1259                         bHandled = true;
1260                         break;
1261                 case TE_CSQC_VEHICLESETUP:
1262                         Net_VehicleSetup();
1263                         bHandled = true;
1264                         break;
1265                 case TE_CSQC_SVNOTICE:
1266                         cl_notice_read();
1267                         bHandled = true;
1268                         break;
1269                 case TE_CSQC_SHOCKWAVEPARTICLE:
1270                         Net_ReadShockwaveParticle();
1271                         bHandled = true;
1272                         break;
1273                 default:
1274                         // No special logic for this temporary entity; return 0 so the engine can handle it
1275                         bHandled = false;
1276                         break;
1277         }
1278
1279         return bHandled;
1280 }
1281
1282 string getcommandkey(string text, string command)
1283 {
1284         string keys;
1285         float n, j, k, l = 0;
1286
1287         if (!autocvar_hud_showbinds)
1288                 return text;
1289
1290         keys = db_get(binddb, command);
1291         if (keys == "")
1292         {
1293                 n = tokenize(findkeysforcommand(command, 0)); // uses '...' strings
1294                 for(j = 0; j < n; ++j)
1295                 {
1296                         k = stof(argv(j));
1297                         if(k != -1)
1298                         {
1299                                 if ("" == keys)
1300                                         keys = keynumtostring(k);
1301                                 else
1302                                         keys = strcat(keys, ", ", keynumtostring(k));
1303
1304                                 ++l;
1305                                 if (autocvar_hud_showbinds_limit > 0 && autocvar_hud_showbinds_limit <= l)
1306                                         break;
1307                         }
1308
1309                 }
1310                 if (keys == "")
1311                         keys = "NO_KEY";
1312                 db_put(binddb, command, keys);
1313         }
1314
1315         if (keys == "NO_KEY") {
1316                 if (autocvar_hud_showbinds > 1)
1317                         return sprintf(_("%s (not bound)"), text);
1318                 else
1319                         return text;
1320         }
1321         else if (autocvar_hud_showbinds > 1)
1322                 return sprintf("%s (%s)", text, keys);
1323         else
1324                 return keys;
1325 }