51324e1c5e09aa320895b35d1725ba572d21382d
[xonotic/xonotic-data.pk3dir.git] / qcsrc / client / main.qc
1 #include "main.qh"
2
3 #include "defs.qh"
4 #include <common/ent_cs.qh>
5 #include "miscfunctions.qh"
6 #include <common/effects/effect.qh>
7 #include <common/effects/qc/_mod.qh>
8 #include <common/effects/all.qh>
9 #include <common/effects/all.inc>
10 #include "hud/_mod.qh"
11 #include "commands/cl_cmd.qh"
12 #include "mapvoting.qh"
13 #include <client/mutators/_mod.qh>
14 #include "hud/panel/scoreboard.qh"
15 #include "hud/panel/quickmenu.qh"
16 #include "shownames.qh"
17 #include "view.qh"
18 #include <common/t_items.qh>
19 #include "weapons/projectile.qh"
20 #include <common/deathtypes/all.qh>
21 #include <common/items/_mod.qh>
22 #include <common/mapinfo.qh>
23 #include <common/minigames/cl_minigames.qh>
24 #include <common/minigames/cl_minigames_hud.qh>
25 #include <common/net_linked.qh>
26 #include <common/net_notice.qh>
27 #include <common/scores.qh>
28 #include <common/mapobjects/_mod.qh>
29 #include <common/vehicles/all.qh>
30 #include <lib/csqcmodel/cl_model.qh>
31 #include <lib/csqcmodel/interpolate.qh>
32 #include <lib/warpzone/client.qh>
33
34 // --------------------------------------------------------------------------
35 // BEGIN REQUIRED CSQC FUNCTIONS
36 //include "main.qh"
37
38 #define DP_CSQC_ENTITY_REMOVE_IS_B0RKED
39
40 void draw_cursor(vector pos, vector ofs, string img, vector col, float a)
41 {
42         ofs = vec2(ofs.x * SIZE_CURSOR.x, ofs.y * SIZE_CURSOR.y);
43         drawpic(pos - ofs, strcat(draw_currentSkin, img), SIZE_CURSOR, col, a, DRAWFLAG_NORMAL);
44 }
45
46 void draw_cursor_normal(vector pos, vector col, float a)
47 {
48         draw_cursor(pos, OFFSET_CURSOR, "/cursor", col, a);
49 }
50
51 void LoadMenuSkinValues()
52 {
53         int fh = -1;
54         if(cvar_string("menu_skin") != "")
55         {
56                 draw_currentSkin = strcat("gfx/menu/", cvar_string("menu_skin"));
57                 fh = fopen(strcat(draw_currentSkin, "/skinvalues.txt"), FILE_READ);
58         }
59         if(fh < 0 && cvar_defstring("menu_skin") != "")
60         {
61                 cvar_set("menu_skin", cvar_defstring("menu_skin"));
62                 draw_currentSkin = strcat("gfx/menu/", cvar_string("menu_skin"));
63                 fh = fopen(strcat(draw_currentSkin, "/skinvalues.txt"), FILE_READ);
64         }
65         if(fh < 0)
66         {
67                 draw_currentSkin = "gfx/menu/default";
68                 fh = fopen(strcat(draw_currentSkin, "/skinvalues.txt"), FILE_READ);
69         }
70
71         draw_currentSkin = strzone(draw_currentSkin);
72
73         if(fh >= 0)
74         {
75                 string s;
76                 while((s = fgets(fh)))
77                 {
78                         int n = tokenize_console(s);
79                         if (n < 2)
80                                 continue;
81                         if(substring(argv(0), 0, 2) == "//")
82                                 continue;
83                         if(argv(0) == "SIZE_CURSOR")
84                                 SIZE_CURSOR = stov(substring(s, argv_start_index(1), argv_end_index(-1) - argv_start_index(1)));
85                         else if(argv(0) == "OFFSET_CURSOR")
86                                 OFFSET_CURSOR = stov(substring(s, argv_start_index(1), argv_end_index(-1) - argv_start_index(1)));
87                 }
88                 fclose(fh);
89         }
90 }
91
92 // CSQC_Init : Called every time the CSQC code is initialized (essentially at map load)
93 // Useful for precaching things
94
95 void CSQC_Init()
96 {
97         prvm_language = strzone(cvar_string("prvm_language"));
98
99 #ifdef WATERMARK
100         LOG_INFOF("^4CSQC Build information: ^1%s", WATERMARK);
101 #endif
102
103         {
104                 int i = 0;
105                 for ( ; i < 255; ++i)
106                         if (getplayerkeyvalue(i, "viewentity") == "")
107                                 break;
108                 maxclients = i;
109         }
110
111         // needs to be done so early because of the constants they create
112         static_init();
113         static_init_late();
114         static_init_precache();
115
116         binddb = db_create();
117         tempdb = db_create();
118         ClientProgsDB = db_load("client.db");
119
120         draw_endBoldFont();
121
122         //registercommand("hud_configure");
123         //registercommand("hud_save");
124         //registercommand("menu_action");
125
126         ConsoleCommand_macro_init();
127
128         registercvar("hud_usecsqc", "1");
129         registercvar("scoreboard_columns", "default");
130
131         registercvar("cl_nade_type", "3");
132         registercvar("cl_pokenade_type", "zombie");
133
134         registercvar("cl_jumpspeedcap_min", "");
135         registercvar("cl_jumpspeedcap_max", "");
136
137         registercvar("cl_shootfromfixedorigin", "");
138
139         registercvar("cl_multijump", "1");
140
141         registercvar("cl_spawn_near_teammate", "1");
142
143         if(autocvar_cl_lockview)
144                 cvar_set("cl_lockview", "0");
145
146         gametype = NULL;
147
148         postinit = false;
149
150         calledhooks = 0;
151
152         teams = Sort_Spawn();
153         players = Sort_Spawn();
154
155         GetTeam(NUM_SPECTATOR, true); // add specs first
156
157         for (int w = 0; w <= WEP_LAST - WEP_FIRST; ++w)
158                 weapon_accuracy[w] = -1;
159
160         // precaches
161
162         if(autocvar_cl_reticle)
163         {
164                 precache_pic("gfx/reticle_normal");
165                 // weapon reticles are precached in weapon files
166         }
167
168         {
169                 get_mi_min_max_texcoords(1); // try the CLEVER way first
170                 minimapname = strcat("gfx/", mi_shortname, "_radar.tga");
171                 shortmapname = mi_shortname;
172
173                 if (precache_pic(minimapname) == "")
174                 {
175                         // but maybe we have a non-clever minimap
176                         minimapname = strcat("gfx/", mi_shortname, "_mini.tga");
177                         if (precache_pic(minimapname) == "")
178                                 minimapname = ""; // FAIL
179                         else
180                                 get_mi_min_max_texcoords(0); // load new texcoords
181                 }
182
183                 mi_center = (mi_min + mi_max) * 0.5;
184                 mi_scale = mi_max - mi_min;
185                 minimapname = strzone(minimapname);
186         }
187
188         hud_skin_path = strzone(strcat("gfx/hud/", autocvar_hud_skin));
189         LoadMenuSkinValues();
190 }
191
192 // CSQC_Shutdown : Called every time the CSQC code is shutdown (changing maps, quitting, etc)
193 void Shutdown()
194 {
195         WarpZone_Shutdown();
196
197         delete(teams);
198         delete(players);
199         db_close(binddb);
200         db_close(tempdb);
201         if(autocvar_cl_db_saveasdump)
202                 db_dump(ClientProgsDB, "client.db");
203         else
204                 db_save(ClientProgsDB, "client.db");
205         db_close(ClientProgsDB);
206
207         if(camera_active)
208                 cvar_set("chase_active",ftos(chase_active_backup));
209
210         // unset the event chasecam's chase_active
211         if(autocvar_chase_active < 0)
212                 cvar_set("chase_active", "0");
213
214         cvar_set("slowmo", cvar_defstring("slowmo")); // reset it back to 'default'
215
216         if (!isdemo())
217         {
218                 if (!(calledhooks & HOOK_START))
219                         localcmd("\n_cl_hook_gamestart nop\n");
220                 if (!(calledhooks & HOOK_END))
221                         localcmd("\ncl_hook_gameend\n");
222         }
223
224         localcmd("\ncl_hook_shutdown\n");
225
226         localcmd("\n-button14\n");
227
228         deactivate_minigame();
229         HUD_MinigameMenu_Close(NULL, NULL, NULL);
230 }
231
232 .float has_team;
233 bool SetTeam(entity o, int Team)
234 {
235         TC(int, Team);
236         devassert_once(Team);
237         entity tm;
238         if(teamplay)
239         {
240                 switch(Team)
241                 {
242                         case -1:
243                         case NUM_TEAM_1:
244                         case NUM_TEAM_2:
245                         case NUM_TEAM_3:
246                         case NUM_TEAM_4:
247                                 break;
248                         default:
249                                 if(GetTeam(Team, false) == NULL)
250                                 {
251                                         LOG_TRACEF("trying to switch to unsupported team %d", Team);
252                                         Team = NUM_SPECTATOR;
253                                 }
254                                 break;
255                 }
256         }
257         else
258         {
259                 switch(Team)
260                 {
261                         case -1:
262                         case 0:
263                                 break;
264                         default:
265                                 if(GetTeam(Team, false) == NULL)
266                                 {
267                                         LOG_TRACEF("trying to switch to unsupported team %d", Team);
268                                         Team = NUM_SPECTATOR;
269                                 }
270                                 break;
271                 }
272         }
273         if(Team == -1) // leave
274         {
275                 if(o.has_team)
276                 {
277                         tm = GetTeam(o.team, false);
278                         tm.team_size -= 1;
279                         o.has_team = 0;
280                         return true;
281                 }
282         }
283         else
284         {
285                 if (!o.has_team)
286                 {
287                         o.team = Team;
288                         tm = GetTeam(Team, true);
289                         tm.team_size += 1;
290                         o.has_team = 1;
291                         return true;
292                 }
293                 else if(Team != o.team)
294                 {
295                         tm = GetTeam(o.team, false);
296                         tm.team_size -= 1;
297                         o.team = Team;
298                         tm = GetTeam(Team, true);
299                         tm.team_size += 1;
300                         return true;
301                 }
302         }
303         return false;
304 }
305
306 void Playerchecker_Think(entity this)
307 {
308     int i;
309         entity e;
310         for(i = 0; i < maxclients; ++i)
311         {
312                 e = playerslots[i];
313                 if(entcs_GetName(i) == "")
314                 {
315                         if(e.sort_prev)
316                         {
317                                 // player disconnected
318                                 SetTeam(e, -1);
319                                 RemovePlayer(e);
320                                 e.sort_prev = NULL;
321                                 //e.gotscores = 0;
322                         }
323                 }
324                 else
325                 {
326                         if (!e.sort_prev)
327                         {
328                                 // player connected
329                                 if (!e)
330                                 {
331                                         playerslots[i] = e = new_pure(playerslot);
332                                 }
333                                 e.sv_entnum = i;
334                                 e.ping = 0;
335                                 e.ping_packetloss = 0;
336                                 e.ping_movementloss = 0;
337                                 //e.gotscores = 0; // we might already have the scores...
338                                 int t = entcs_GetScoreTeam(i);
339                                 if (t) SetTeam(e, t); // will not hurt; later updates come with Scoreboard_UpdatePlayerTeams
340                                 RegisterPlayer(e);
341                                 Scoreboard_UpdatePlayerPos(e);
342                         }
343                 }
344         }
345         this.nextthink = time + 0.2;
346 }
347
348 void PostInit()
349 {
350         entity playerchecker = new_pure(playerchecker);
351         setthink(playerchecker, Playerchecker_Think);
352         playerchecker.nextthink = time + 0.2;
353
354         TrueAim_Init();
355
356         postinit = true;
357 }
358
359 // CSQC_InputEvent : Used to perform actions based on any key pressed, key released and mouse on the client.
360 // Return value should be 1 if CSQC handled the input, otherwise return 0 to have the input passed to the engine.
361 // All keys are in ascii.
362 // bInputType = 0 is key pressed, 1 is key released, 2 and 3 are mouse input.
363 // In the case of keyboard input, nPrimary is the ascii code, and nSecondary is 0.
364 // In the case of mouse input, nPrimary is xdelta, nSecondary is ydelta.
365 // In the case of mouse input after a setcursormode(1) call, nPrimary is xpos, nSecondary is ypos.
366 float CSQC_InputEvent(int bInputType, float nPrimary, float nSecondary)
367 {
368         TC(int, bInputType);
369         bool override = false;
370         override |= HUD_Panel_InputEvent(bInputType, nPrimary, nSecondary);
371         if (override)
372                 return true;
373
374         override |= QuickMenu_InputEvent(bInputType, nPrimary, nSecondary);
375
376         override |= HUD_Radar_InputEvent(bInputType, nPrimary, nSecondary);
377
378         override |= MapVote_InputEvent(bInputType, nPrimary, nSecondary);
379
380         override |= HUD_Minigame_InputEvent(bInputType, nPrimary, nSecondary);
381
382         if(override)
383                 return true;
384
385         return false;
386 }
387
388 // END REQUIRED CSQC FUNCTIONS
389 // --------------------------------------------------------------------------
390
391 // --------------------------------------------------------------------------
392 // BEGIN OPTIONAL CSQC FUNCTIONS
393
394 void Ent_RemovePlayerScore(entity this)
395 {
396         if(this.owner) {
397                 SetTeam(this.owner, -1);
398                 this.owner.gotscores = 0;
399                 FOREACH(Scores, true, {
400                         this.owner.(scores(it)) = 0; // clear all scores
401                 });
402         }
403 }
404
405 NET_HANDLE(ENT_CLIENT_SCORES, bool isnew)
406 {
407         make_pure(this);
408         entity o;
409
410         // damnit -.- don't want to go change every single .sv_entnum in hud.qc AGAIN
411         // (no I've never heard of M-x replace-string, sed, or anything like that)
412         bool isNew = !this.owner; // workaround for DP bug
413         int n = ReadByte()-1;
414
415 #ifdef DP_CSQC_ENTITY_REMOVE_IS_B0RKED
416         if(!isNew && n != this.sv_entnum)
417         {
418                 //print("A CSQC entity changed its owner!\n");
419                 LOG_INFOF("A CSQC entity changed its owner! (edict: %d, classname: %s)", etof(this), this.classname);
420                 isNew = true;
421                 Ent_Remove(this);
422         }
423 #endif
424
425         this.sv_entnum = n;
426
427         o = playerslots[this.sv_entnum];
428         if (!o)
429         {
430                 o = playerslots[this.sv_entnum] = new_pure(playerslot);
431         }
432         this.owner = o;
433         o.sv_entnum = this.sv_entnum;
434         o.gotscores = 1;
435
436         //if (!o.sort_prev)
437         //      RegisterPlayer(o);
438         //playerchecker will do this for us later, if it has not already done so
439
440         int sf = ReadShort();
441         int lf = ReadShort();
442         FOREACH(Scores, true, {
443                 int p = 1 << (i % 16);
444                 if (sf & p)
445                 {
446                         if (lf & p)
447                                 o.(scores(it)) = ReadInt24_t();
448                         else
449                                 o.(scores(it)) = ReadChar();
450                 }
451         });
452
453         return = true;
454
455         if(o.sort_prev)
456                 Scoreboard_UpdatePlayerPos(o); // if not registered, we cannot do this yet!
457
458         this.entremove = Ent_RemovePlayerScore;
459 }
460
461 NET_HANDLE(ENT_CLIENT_TEAMSCORES, bool isnew)
462 {
463         make_pure(this);
464         int i;
465
466         this.team = ReadByte();
467         entity o = this.owner = GetTeam(this.team, true); // these team numbers can always be trusted
468
469 #if MAX_TEAMSCORE <= 8
470         int sf = ReadByte();
471         int lf = ReadByte();
472 #else
473         int sf = ReadShort();
474         int lf = ReadShort();
475 #endif
476         for(i = 0; i < MAX_TEAMSCORE; ++i)
477                 if(sf & BIT(i))
478                 {
479                         if(lf & BIT(i))
480                                 o.(teamscores(i)) = ReadInt24_t();
481                         else
482                                 o.(teamscores(i)) = ReadChar();
483                 }
484
485         return = true;
486
487         Scoreboard_UpdateTeamPos(o);
488 }
489
490 NET_HANDLE(ENT_CLIENT_CLIENTDATA, bool isnew)
491 {
492         make_pure(this);
493         float newspectatee_status;
494
495         int f = ReadByte();
496
497         scoreboard_showscores_force = (f & BIT(0));
498
499         if(f & BIT(1))
500         {
501                 newspectatee_status = ReadByte();
502                 if(newspectatee_status == player_localnum + 1)
503                         newspectatee_status = -1; // observing
504         }
505         else
506                 newspectatee_status = 0;
507
508         spectatorbutton_zoom = (f & BIT(2));
509
510         if(f & BIT(4))
511         {
512                 num_spectators = ReadByte();
513
514                 float i, slot;
515
516                 for(i = 0; i < MAX_SPECTATORS; ++i)
517                         spectatorlist[i] = 0; // reset list first
518
519                 for(i = 0; i < num_spectators; ++i)
520                 {
521                         slot = ReadByte();
522                         spectatorlist[i] = slot - 1;
523                 }
524         }
525
526         return = true;
527
528         if(newspectatee_status != spectatee_status)
529         {
530                 // clear race stuff
531                 race_laptime = 0;
532                 race_checkpointtime = 0;
533                 hud_dynamic_shake_factor = -1;
534                 spectatee_status_changed_time = time;
535         }
536         if (autocvar_hud_panel_healtharmor_progressbar_gfx)
537         {
538                 if ( (spectatee_status == -1 && newspectatee_status > 0) //before observing, now spectating
539                   || (spectatee_status > 0 && newspectatee_status > 0 && spectatee_status != newspectatee_status) //changed spectated player
540                 )
541                         prev_p_health = -1;
542                 else if(spectatee_status && !newspectatee_status) //before observing/spectating, now playing
543                         prev_health = -1;
544         }
545         spectatee_status = newspectatee_status;
546
547         // we could get rid of spectatee_status, and derive it from player_localentnum and player_localnum
548 }
549
550 NET_HANDLE(ENT_CLIENT_NAGGER, bool isnew)
551 {
552         make_pure(this);
553         int i, j, b, f;
554
555         int nags = ReadByte(); // NAGS NAGS NAGS NAGS NAGS NAGS NADZ NAGS NAGS NAGS
556
557         if(!(nags & BIT(2)))
558         {
559                 strfree(vote_called_vote);
560                 vote_active = 0;
561         }
562         else
563         {
564                 vote_active = 1;
565         }
566
567         if(nags & BIT(6))
568         {
569                 vote_yescount = ReadByte();
570                 vote_nocount = ReadByte();
571                 vote_needed = ReadByte();
572                 vote_highlighted = ReadChar();
573         }
574
575         if(nags & BIT(7))
576         {
577                 strcpy(vote_called_vote, ReadString());
578         }
579
580         if(nags & 1)
581         {
582                 for(j = 0; j < maxclients; ++j)
583                         if(playerslots[j])
584                                 playerslots[j].ready = true;
585                 for(i = 1; i <= maxclients; i += 8)
586                 {
587                         f = ReadByte();
588                         for(j = i-1, b = BIT(0); b < BIT(8); b <<= 1, ++j)
589                                 if (!(f & b))
590                                         if(playerslots[j])
591                                                 playerslots[j].ready = false;
592                 }
593         }
594
595         return = true;
596
597         ready_waiting = (nags & BIT(0));
598         ready_waiting_for_me = (nags & BIT(1));
599         vote_waiting = (nags & BIT(2));
600         vote_waiting_for_me = (nags & BIT(3));
601         warmup_stage = (nags & BIT(4));
602 }
603
604 NET_HANDLE(ENT_CLIENT_ELIMINATEDPLAYERS, bool isnew)
605 {
606         make_pure(this);
607         int sf = 0;
608         serialize(byte, 0, sf);
609         if (sf & 1) {
610                 for (int j = 0; j < maxclients; ++j) {
611                         if (playerslots[j]) {
612                                 playerslots[j].eliminated = true;
613                         }
614                 }
615                 for (int i = 1; i <= maxclients; i += 8) {
616                         int f = 0;
617                         serialize(byte, 0, f);
618                         for (int b = 0; b < 8; ++b) {
619                                 if (f & BIT(b)) continue;
620                                 int j = i - 1 + b;
621                                 if (playerslots[j]) {
622                                         playerslots[j].eliminated = false;
623                                 }
624                         }
625                 }
626         }
627         return true;
628 }
629
630 NET_HANDLE(ENT_CLIENT_RANDOMSEED, bool isnew)
631 {
632         make_pure(this);
633         prandom_debug();
634         float s = ReadShort();
635         psrandom(s);
636         return true;
637 }
638
639 NET_HANDLE(ENT_CLIENT_ACCURACY, bool isnew)
640 {
641         make_pure(this);
642         int sf = ReadInt24_t();
643         if (sf == 0) {
644                 for (int w = 0; w <= WEP_LAST - WEP_FIRST; ++w)
645                         weapon_accuracy[w] = -1;
646                 return true;
647         }
648
649         int f = 1;
650         for (int w = 0; w <= WEP_LAST - WEP_FIRST; ++w) {
651                 if (sf & f) {
652                         int b = ReadByte();
653                         if (b == 0)
654                                 weapon_accuracy[w] = -1;
655                         else if (b == 255)
656                                 weapon_accuracy[w] = 1.0; // no better error handling yet, sorry
657                         else
658                                 weapon_accuracy[w] = (b - 1.0) / 100.0;
659                 }
660                 f = (f == 0x800000) ? 1 : f * 2;
661         }
662         return true;
663 }
664
665 void Spawn_Draw(entity this)
666 {
667         if(this.alpha <= 0)
668                 return;
669
670         __pointparticles(this.cnt, this.origin + '0 0 28', '0 0 2', bound(0, frametime, 0.1));
671 }
672
673 void Spawn_PreDraw(entity this)
674 {
675         float alph;
676         vector org = getpropertyvec(VF_ORIGIN);
677         if(this.fade_start)
678         {
679                 if(vdist(org - this.origin, >, this.fade_end))
680                         alph = 0; // save on some processing
681                 else if(vdist(org - this.origin, <, this.fade_start))
682                         alph = 1; // more processing saved
683                 else
684                         alph = bound(0, (this.fade_end - vlen(org - this.origin - 0.5 * (this.mins + this.maxs))) / (this.fade_end - this.fade_start), 1);
685         }
686         else
687                 alph = 1;
688         //printf("%v <-> %v\n", view_origin, this.origin + 0.5 * (this.mins + this.maxs));
689         this.alpha = alph;
690         if(alph <= 0)
691                 this.drawmask = 0;
692         else
693                 this.drawmask = MASK_NORMAL;
694 }
695
696 NET_HANDLE(ENT_CLIENT_SPAWNPOINT, bool is_new)
697 {
698         float teamnum = (ReadByte() - 1);
699         vector spn_origin = ReadVector();
700
701         this.team = (teamnum + 1);
702
703         //if(is_new)
704         //{
705                 this.origin = spn_origin;
706                 setsize(this, PL_MIN_CONST, PL_MAX_CONST);
707                 //droptofloor();
708
709                 /*if(autocvar_cl_spawn_point_model) // needs a model first
710                 {
711                         this.mdl = "models/spawnpoint.md3";
712                         this.colormod = Team_ColorRGB(teamnum);
713                         precache_model(this.mdl);
714                         setmodel(this, this.mdl);
715                         this.drawmask = MASK_NORMAL;
716                         //this.move_movetype = MOVETYPE_NOCLIP;
717                         //this.draw = Spawn_Draw;
718                         IL_PUSH(g_drawables, this);
719                 }*/
720                 if(autocvar_cl_spawn_point_particles)
721                 {
722                         if(teamplay)
723                         {
724                                 switch(teamnum)
725                                 {
726                                         case NUM_TEAM_1: this.cnt = particleeffectnum(EFFECT_SPAWNPOINT_RED); break;
727                                         case NUM_TEAM_2: this.cnt = particleeffectnum(EFFECT_SPAWNPOINT_BLUE); break;
728                                         case NUM_TEAM_3: this.cnt = particleeffectnum(EFFECT_SPAWNPOINT_YELLOW); break;
729                                         case NUM_TEAM_4: this.cnt = particleeffectnum(EFFECT_SPAWNPOINT_PINK); break;
730                                         default: this.cnt = particleeffectnum(EFFECT_SPAWNPOINT_NEUTRAL); break;
731                                 }
732                         }
733                         else { this.cnt = particleeffectnum(EFFECT_SPAWNPOINT_NEUTRAL); }
734
735                         this.draw = Spawn_Draw;
736                         if (is_new) IL_PUSH(g_drawables, this);
737                         setpredraw(this, Spawn_PreDraw);
738                         this.fade_start = autocvar_cl_spawn_point_dist_min;
739                         this.fade_end = autocvar_cl_spawn_point_dist_max;
740                 }
741         //}
742
743         //printf("Ent_ReadSpawnPoint(is_new = %d); origin = %s, team = %d, effect = %d\n", is_new, vtos(this.origin), teamnum, this.cnt);
744         return true;
745 }
746
747 NET_HANDLE(ENT_CLIENT_SPAWNEVENT, bool is_new)
748 {
749         // If entnum is 0, ONLY do the local spawn actions
750         // this way the server can disable the sending of
751         // spawn origin or such to clients if wanted.
752         float entnum = ReadByte();
753
754         if(entnum)
755         {
756                 this.origin = ReadVector();
757
758                 if(is_new)
759                 {
760                         float teamnum = entcs_GetTeam(entnum - 1);
761
762                         if(autocvar_cl_spawn_event_particles)
763                         {
764                                 switch(teamnum)
765                                 {
766                                         case NUM_TEAM_1: pointparticles(EFFECT_SPAWN_RED, this.origin, '0 0 0', 1); break;
767                                         case NUM_TEAM_2: pointparticles(EFFECT_SPAWN_BLUE, this.origin, '0 0 0', 1); break;
768                                         case NUM_TEAM_3: pointparticles(EFFECT_SPAWN_YELLOW, this.origin, '0 0 0', 1); break;
769                                         case NUM_TEAM_4: pointparticles(EFFECT_SPAWN_PINK, this.origin, '0 0 0', 1); break;
770                                         default: pointparticles(EFFECT_SPAWN_NEUTRAL, this.origin, '0 0 0', 1); break;
771                                 }
772                         }
773                         if(autocvar_cl_spawn_event_sound)
774                         {
775                                 sound(this, CH_TRIGGER, SND_SPAWN, VOL_BASE, ATTEN_NORM);
776                         }
777                 }
778         }
779         return = true;
780
781         // local spawn actions
782         if(is_new && (!entnum || (entnum == player_localentnum)))
783         {
784                 zoomin_effect = 1;
785                 current_viewzoom = (1 / bound(1, autocvar_cl_spawnzoom_factor, 16));
786
787                 if(autocvar_cl_unpress_zoom_on_spawn)
788                 {
789                         localcmd("-zoom\n");
790                         button_zoom = false;
791                 }
792                 HUD_Radar_Hide_Maximized();
793         }
794         //printf("Ent_ReadSpawnEvent(is_new = %d); origin = %s, entnum = %d, localentnum = %d\n", is_new, vtos(this.origin), entnum, player_localentnum);
795 }
796
797 // CSQC_Ent_Update : Called every frame that the server has indicated an update to the SSQC / CSQC entity has occured.
798 // The only parameter reflects if the entity is "new" to the client, meaning it just came into the client's PVS.
799 void CSQC_Ent_Update(entity this, bool isnew)
800 {
801         this.sourceLoc = __FILE__ ":" STR(__LINE__);
802         int t = ReadByte();
803
804         // set up the "time" global for received entities to be correct for interpolation purposes
805         float savetime = time;
806         if(servertime)
807         {
808                 time = servertime;
809         }
810         else
811         {
812                 serverprevtime = time;
813                 serverdeltatime = STAT(MOVEVARS_TICRATE) * STAT(MOVEVARS_TIMESCALE);
814                 time = serverprevtime + serverdeltatime;
815         }
816
817 #ifdef DP_CSQC_ENTITY_REMOVE_IS_B0RKED
818         if (this.enttype)
819         {
820                 if (t != this.enttype || isnew)
821                 {
822                         LOG_INFOF("A CSQC entity changed its type! (edict: %d, server: %d, type: %d -> %d)", etof(this), this.entnum, this.enttype, t);
823                         Ent_Remove(this);
824                         clearentity(this);
825                         isnew = true;
826                 }
827         }
828         else
829         {
830                 if (!isnew)
831                 {
832                         LOG_INFOF("A CSQC entity appeared out of nowhere! (edict: %d, server: %d, type: %d)", etof(this), this.entnum, t);
833                         isnew = true;
834                 }
835         }
836 #endif
837         this.enttype = t;
838         bool done = false;
839         FOREACH(LinkedEntities, it.m_id == t, {
840                 if (isnew) this.classname = it.netname;
841                 if (autocvar_developer_csqcentities)
842             LOG_INFOF("CSQC_Ent_Update(%d) at %f with this=%i {.entnum=%d, .enttype=%d} t=%s (%d)", isnew, savetime, this, this.entnum, this.enttype, this.classname, t);
843                 done = it.m_read(this, NULL, isnew);
844                 MUTATOR_CALLHOOK(Ent_Update, this, isnew);
845                 break;
846         });
847         time = savetime;
848         if (!done)
849         {
850                 LOG_FATALF("CSQC_Ent_Update(%d) at %f with this=%i {.entnum=%d, .enttype=%d} t=%s (%d)", isnew, savetime, this, this.entnum, this.enttype, this.classname, t);
851         }
852 }
853
854 // Destructor, but does NOT deallocate the entity by calling remove(). Also
855 // used when an entity changes its type. For an entity that someone interacts
856 // with others, make sure it can no longer do so.
857 void Ent_Remove(entity this)
858 {
859         if(this.entremove) this.entremove(this);
860
861         if(this.skeletonindex)
862         {
863                 skel_delete(this.skeletonindex);
864                 this.skeletonindex = 0;
865         }
866
867         if(this.snd_looping > 0)
868         {
869                 sound(this, this.snd_looping, SND_Null, VOL_BASE, autocvar_cl_jetpack_attenuation);
870                 this.snd_looping = 0;
871         }
872
873         this.enttype = 0;
874         this.classname = "";
875         this.draw = func_null;
876         this.entremove = func_null;
877         // TODO possibly set more stuff to defaults
878 }
879 // CSQC_Ent_Remove : Called when the server requests a SSQC / CSQC entity to be removed.  Essentially call remove(this) as well.
880 void CSQC_Ent_Remove(entity this)
881 {
882         if (autocvar_developer_csqcentities) LOG_INFOF("CSQC_Ent_Remove() with this=%i {.entnum=%d, .enttype=%d}", this, this.entnum, this.enttype);
883         if (wasfreed(this))
884         {
885                 LOG_WARN("CSQC_Ent_Remove called for already removed entity. Packet loss?");
886                 return;
887         }
888         if (this.enttype) Ent_Remove(this);
889         delete(this);
890 }
891
892 void Gamemode_Init()
893 {
894         if (!isdemo())
895         {
896                 if(!(calledhooks & HOOK_START))
897                         localcmd("\n_cl_hook_gamestart ", MapInfo_Type_ToString(gametype), "\n");
898                 calledhooks |= HOOK_START;
899         }
900 }
901 // CSQC_Parse_StuffCmd : Provides the stuffcmd string in the first parameter that the server provided.  To execute standard behavior, simply execute localcmd with the string.
902 void CSQC_Parse_StuffCmd(string strMessage)
903 {
904         if (autocvar_developer_csqcentities) LOG_INFOF("CSQC_Parse_StuffCmd(\"%s\")", strMessage);
905         localcmd(strMessage);
906 }
907 // CSQC_Parse_Print : Provides the print string in the first parameter that the server provided.  To execute standard behavior, simply execute print with the string.
908 void CSQC_Parse_Print(string strMessage)
909 {
910         if (autocvar_developer_csqcentities) LOG_INFOF("CSQC_Parse_Print(\"%s\")", strMessage);
911         print(ColorTranslateRGB(strMessage));
912 }
913
914 // CSQC_Parse_CenterPrint : Provides the centerprint_hud string in the first parameter that the server provided.
915 void CSQC_Parse_CenterPrint(string strMessage)
916 {
917         if (autocvar_developer_csqcentities) LOG_INFOF("CSQC_Parse_CenterPrint(\"%s\")", strMessage);
918         centerprint_hud(strMessage);
919 }
920
921 // CSQC_Parse_TempEntity : Handles all temporary entity network data in the CSQC layer.
922 // You must ALWAYS first acquire the temporary ID, which is sent as a byte.
923 // Return value should be 1 if CSQC handled the temporary entity, otherwise return 0 to have the engine process the event.
924 bool CSQC_Parse_TempEntity()
925 {
926         // Acquire TE ID
927         int nTEID = ReadByte();
928
929         FOREACH(TempEntities, it.m_id == nTEID, {
930                 if (autocvar_developer_csqcentities)
931                         LOG_INFOF("CSQC_Parse_TempEntity() nTEID=%s (%d)", it.netname, nTEID);
932                 return it.m_read(NULL, NULL, true);
933         });
934
935         if (autocvar_developer_csqcentities)
936                 LOG_INFOF("CSQC_Parse_TempEntity() with nTEID=%d", nTEID);
937
938         // No special logic for this temporary entity; return 0 so the engine can handle it
939         return false;
940 }
941
942 string forcefog;
943 void Fog_Force()
944 {
945         if (autocvar_cl_orthoview && autocvar_cl_orthoview_nofog)
946                 localcmd("\nr_drawfog 0\n");
947         else if (forcefog != "")
948                 localcmd(sprintf("\nfog %s\nr_fog_exp2 0\nr_drawfog 1\n", forcefog));
949 }
950
951 NET_HANDLE(ENT_CLIENT_SCORES_INFO, bool isnew)
952 {
953         make_pure(this);
954         gametype = ReadRegistered(Gametypes);
955         teamplay = _MapInfo_GetTeamPlayBool(gametype);
956         HUD_ModIcons_SetFunc();
957         FOREACH(Scores, true, {
958                 strcpy(scores_label(it), ReadString());
959                 scores_flags(it) = ReadByte();
960         });
961         for (int i = 0; i < MAX_TEAMSCORE; ++i)
962         {
963                 strcpy(teamscores_label(i), ReadString());
964                 teamscores_flags(i) = ReadByte();
965         }
966         return = true;
967         Scoreboard_InitScores();
968         Gamemode_Init();
969 }
970
971 NET_HANDLE(ENT_CLIENT_INIT, bool isnew)
972 {
973         nb_pb_period = ReadByte() / 32; //Accuracy of 1/32th
974
975         hook_shotorigin[0] = decompressShotOrigin(ReadInt24_t());
976         hook_shotorigin[1] = decompressShotOrigin(ReadInt24_t());
977         hook_shotorigin[2] = decompressShotOrigin(ReadInt24_t());
978         hook_shotorigin[3] = decompressShotOrigin(ReadInt24_t());
979         arc_shotorigin[0] = decompressShotOrigin(ReadInt24_t());
980         arc_shotorigin[1] = decompressShotOrigin(ReadInt24_t());
981         arc_shotorigin[2] = decompressShotOrigin(ReadInt24_t());
982         arc_shotorigin[3] = decompressShotOrigin(ReadInt24_t());
983
984         strcpy(forcefog, ReadString());
985
986         armorblockpercent = ReadByte() / 255.0;
987         damagepush_speedfactor = ReadByte() / 255.0;
988
989         serverflags = ReadByte();
990
991         g_trueaim_minrange = ReadCoord();
992
993         return = true;
994
995         MUTATOR_CALLHOOK(Ent_Init);
996
997         if (!postinit) PostInit();
998 }
999
1000 float GetSpeedUnitFactor(int speed_unit)
1001 {
1002         switch(speed_unit)
1003         {
1004                 default:
1005                 case 1:
1006                         return 1.0;
1007                 case 2:
1008                         return 0.0254;
1009                 case 3:
1010                         return 0.0254 * 3.6;
1011                 case 4:
1012                         return 0.0254 * 3.6 * 0.6213711922;
1013                 case 5:
1014                         return 0.0254 * 1.943844492; // 1 m/s = 1.943844492 knots, because 1 knot = 1.852 km/h
1015         }
1016 }
1017
1018 string GetSpeedUnit(int speed_unit)
1019 {
1020         switch(speed_unit)
1021         {
1022                 default:
1023                 case 1:
1024                         return _(" qu/s");
1025                 case 2:
1026                         return _(" m/s");
1027                 case 3:
1028                         return _(" km/h");
1029                 case 4:
1030                         return _(" mph");
1031                 case 5:
1032                         return _(" knots");
1033         }
1034 }
1035
1036 NET_HANDLE(TE_CSQC_RACE, bool isNew)
1037 {
1038         int b = ReadByte();
1039
1040         switch (b)
1041         {
1042                 case RACE_NET_CHECKPOINT_HIT_QUALIFYING:
1043                         race_checkpoint = ReadByte();
1044                         race_time = ReadInt24_t();
1045                         race_previousbesttime = ReadInt24_t();
1046                         race_mypreviousbesttime = ReadInt24_t();
1047                         string pbestname = ReadString();
1048                         if(autocvar_cl_race_cptimes_onlyself)
1049                         {
1050                                 race_previousbesttime = race_mypreviousbesttime;
1051                                 race_mypreviousbesttime = 0;
1052                                 strcpy(race_previousbestname, "");
1053                         }
1054                         else
1055                                 strcpy(race_previousbestname, pbestname);
1056
1057                         race_checkpointtime = time;
1058
1059                         if(race_checkpoint == 0 || race_checkpoint == 254)
1060                         {
1061                                 race_penaltyaccumulator = 0;
1062                                 race_laptime = time; // valid
1063                         }
1064                         break;
1065
1066                 case RACE_NET_CHECKPOINT_CLEAR:
1067                         race_laptime = 0;
1068                         race_checkpointtime = 0;
1069                         break;
1070
1071                 case RACE_NET_CHECKPOINT_NEXT_SPEC_QUALIFYING:
1072                         race_laptime = ReadCoord();
1073                         race_checkpointtime = -99999;
1074                         // fall through
1075                 case RACE_NET_CHECKPOINT_NEXT_QUALIFYING:
1076                         race_nextcheckpoint = ReadByte();
1077
1078                         race_nextbesttime = ReadInt24_t();
1079                         if(b != RACE_NET_CHECKPOINT_NEXT_SPEC_QUALIFYING) // not while spectating (matches server)
1080                                 race_mybesttime = ReadInt24_t();
1081                         string newname = ReadString();
1082                         if(autocvar_cl_race_cptimes_onlyself && b != RACE_NET_CHECKPOINT_NEXT_SPEC_QUALIFYING)
1083                         {
1084                                 race_nextbesttime = race_mybesttime;
1085                                 race_mybesttime = 0;
1086                                 strcpy(race_nextbestname, "");
1087                         }
1088                         else
1089                                 strcpy(race_nextbestname, newname);
1090                         break;
1091
1092                 case RACE_NET_CHECKPOINT_HIT_RACE:
1093                         race_mycheckpoint = ReadByte();
1094                         race_mycheckpointtime = time;
1095                         race_mycheckpointdelta = ReadInt24_t();
1096                         race_mycheckpointlapsdelta = ReadByte();
1097                         if(race_mycheckpointlapsdelta >= 128)
1098                                 race_mycheckpointlapsdelta -= 256;
1099                         int who = ReadByte();
1100                         if(who)
1101                                 strcpy(race_mycheckpointenemy, entcs_GetName(who - 1));
1102                         else
1103                                 strcpy(race_mycheckpointenemy, ""); // TODO: maybe string_null works fine here?
1104                         break;
1105
1106                 case RACE_NET_CHECKPOINT_HIT_RACE_BY_OPPONENT:
1107                         race_othercheckpoint = ReadByte();
1108                         race_othercheckpointtime = time;
1109                         race_othercheckpointdelta = ReadInt24_t();
1110                         race_othercheckpointlapsdelta = ReadByte();
1111                         if(race_othercheckpointlapsdelta >= 128)
1112                                 race_othercheckpointlapsdelta -= 256;
1113                         int what = ReadByte();
1114                         if(what)
1115                                 strcpy(race_othercheckpointenemy, entcs_GetName(what - 1));
1116                         else
1117                                 strcpy(race_othercheckpointenemy, ""); // TODO: maybe string_null works fine here?
1118                         break;
1119
1120                 case RACE_NET_PENALTY_RACE:
1121                         race_penaltyeventtime = time;
1122                         race_penaltytime = ReadShort();
1123                         //race_penaltyaccumulator += race_penaltytime;
1124                         strcpy(race_penaltyreason, ReadString());
1125                         break;
1126
1127                 case RACE_NET_PENALTY_QUALIFYING:
1128                         race_penaltyeventtime = time;
1129                         race_penaltytime = ReadShort();
1130                         race_penaltyaccumulator += race_penaltytime;
1131                         strcpy(race_penaltyreason, ReadString());
1132                         break;
1133
1134                 case RACE_NET_SERVER_RECORD:
1135                         race_server_record = ReadInt24_t();
1136                         break;
1137                 case RACE_NET_SPEED_AWARD:
1138                         race_speedaward = ReadInt24_t() * GetSpeedUnitFactor(autocvar_hud_panel_physics_speed_unit);
1139                         strcpy(race_speedaward_holder, ReadString());
1140                         strcpy(race_speedaward_unit, GetSpeedUnit(autocvar_hud_panel_physics_speed_unit));
1141                         break;
1142                 case RACE_NET_SPEED_AWARD_BEST:
1143                         race_speedaward_alltimebest = ReadInt24_t() * GetSpeedUnitFactor(autocvar_hud_panel_physics_speed_unit);
1144                         strcpy(race_speedaward_alltimebest_holder, ReadString());
1145                         strcpy(race_speedaward_alltimebest_unit, GetSpeedUnit(autocvar_hud_panel_physics_speed_unit));
1146                         break;
1147                 case RACE_NET_RANKINGS_CNT:
1148                         RANKINGS_DISPLAY_CNT = ReadByte();
1149                         break;
1150                 case RACE_NET_SERVER_RANKINGS:
1151                         float prevpos, del;
1152             int pos = ReadShort();
1153                         prevpos = ReadShort();
1154                         del = ReadShort();
1155
1156                         // move other rankings out of the way
1157             int i;
1158                         if (prevpos) {
1159                                 int m = min(prevpos, RANKINGS_DISPLAY_CNT);
1160                                 for (i=m-1; i>pos-1; --i) {
1161                                         grecordtime[i] = grecordtime[i-1];
1162                                         strcpy(grecordholder[i], grecordholder[i-1]);
1163                                 }
1164                         } else if (del) { // a record has been deleted by the admin
1165                                 for (i=pos-1; i<= RANKINGS_DISPLAY_CNT-1; ++i) {
1166                                         if (i == RANKINGS_DISPLAY_CNT-1) { // clear out last record
1167                                                 grecordtime[i] = 0;
1168                                                 strfree(grecordholder[i]);
1169                                         }
1170                                         else {
1171                                                 grecordtime[i] = grecordtime[i+1];
1172                                                 strcpy(grecordholder[i], grecordholder[i+1]);
1173                                         }
1174                                 }
1175                         } else { // player has no ranked record yet
1176                                 for (i=RANKINGS_DISPLAY_CNT-1;i>pos-1;--i) {
1177                                         grecordtime[i] = grecordtime[i-1];
1178                                         strcpy(grecordholder[i], grecordholder[i-1]);
1179                                 }
1180                         }
1181
1182                         if (grecordtime[RANKINGS_DISPLAY_CNT]) {
1183                                 // kick off the player who fell from the last displayed position
1184                                 grecordtime[RANKINGS_DISPLAY_CNT] = 0;
1185                                 strfree(grecordholder[RANKINGS_DISPLAY_CNT]);
1186                         }
1187
1188                         // store new ranking
1189                         strcpy(grecordholder[pos-1], ReadString());
1190                         grecordtime[pos-1] = ReadInt24_t();
1191                         if(strdecolorize(grecordholder[pos-1]) == strdecolorize(entcs_GetName(player_localnum)))
1192                                 race_myrank = pos;
1193                         break;
1194                 case RACE_NET_SERVER_STATUS:
1195                         race_status = ReadShort();
1196                         strcpy(race_status_name, ReadString());
1197         }
1198         return true;
1199 }
1200
1201 NET_HANDLE(TE_CSQC_TEAMNAGGER, bool isNew)
1202 {
1203         teamnagger = 1;
1204         return true;
1205 }
1206
1207 NET_HANDLE(TE_CSQC_PINGPLREPORT, bool isNew)
1208 {
1209         int i = ReadByte();
1210         int pi = ReadShort();
1211         int pl = ReadByte();
1212         int ml = ReadByte();
1213         return = true;
1214         entity e = playerslots[i];
1215         if (!e) return;
1216         e.ping = pi;
1217         e.ping_packetloss = pl / 255.0;
1218         e.ping_movementloss = ml / 255.0;
1219 }
1220
1221 NET_HANDLE(TE_CSQC_WEAPONCOMPLAIN, bool isNew)
1222 {
1223         int weapon_id = ReadByte();
1224         complain_weapon = Weapons_from(weapon_id);
1225         complain_weapon_type = ReadByte();
1226         return = true;
1227
1228         complain_weapon_time = time;
1229         weapontime = time; // ping the weapon panel
1230
1231         switch(complain_weapon_type)
1232         {
1233                 case 0: Local_Notification(MSG_MULTI, ITEM_WEAPON_NOAMMO, weapon_id); break;
1234                 case 1: Local_Notification(MSG_MULTI, ITEM_WEAPON_DONTHAVE, weapon_id); break;
1235                 default: Local_Notification(MSG_MULTI, ITEM_WEAPON_UNAVAILABLE, weapon_id); break;
1236         }
1237 }
1238
1239 string _getcommandkey(string cmd_name, string command, bool forcename)
1240 {
1241         string keys;
1242         float n, j, k, l = 0;
1243
1244         if (!autocvar_hud_showbinds)
1245                 return cmd_name;
1246
1247         keys = db_get(binddb, command);
1248         if (keys == "")
1249         {
1250                 bool joy_active = cvar("joy_active");
1251                 n = tokenize(findkeysforcommand(command, 0)); // uses '...' strings
1252                 for(j = 0; j < n; ++j)
1253                 {
1254                         k = stof(argv(j));
1255                         if(k != -1)
1256                         {
1257                                 string key = keynumtostring(k);
1258                                 if(!joy_active && substring(key, 0, 3) == "JOY")
1259                                         continue;
1260
1261                                 if (keys == "")
1262                                         keys = key;
1263                                 else
1264                                         keys = strcat(keys, ", ", key);
1265
1266                                 ++l;
1267                                 if (autocvar_hud_showbinds_limit > 0 && autocvar_hud_showbinds_limit <= l)
1268                                         break;
1269                         }
1270
1271                 }
1272                 if (keys == "")
1273                         keys = "NO_KEY";
1274                 db_put(binddb, command, keys);
1275         }
1276
1277         if (keys == "NO_KEY") {
1278                 if (autocvar_hud_showbinds > 1)
1279                         return sprintf(_("%s (not bound)"), cmd_name);
1280                 else
1281                         return cmd_name;
1282         }
1283         else if (autocvar_hud_showbinds > 1 || forcename)
1284                 return sprintf("%s (%s)", cmd_name, keys);
1285         else
1286                 return keys;
1287 }