qcsrc/client/main.qc

   1 #include "main.qh"
   2
   3 #include "casings.qh"
   4 #include "csqcmodel_hooks.qh"
   5 #include "damage.qh"
   6 #include "defs.qh"
   7 #include "effects.qh"
   8 #include "gibs.qh"
   9 #include "hook.qh"
  10 #include "hud.qh"
  11 #include "hud_config.qh"
  12 #include "laser.qh"
  13 #include "mapvoting.qh"
  14 #include "miscfunctions.qh"
  15 #include "modeleffects.qh"
  16 #include "particles.qh"
  17 #include "prandom.qh"
  18 #include "scoreboard.qh"
  19 #include "shownames.qh"
  20 #include "sortlist.qh"
  21 #include "target_music.qh"
  22 #include "tturrets.qh"
  23 #include "tuba.qh"
  24 #include "t_items.qh"
  25 #include "wall.qh"
  26 #include "waypointsprites.qh"
  27
  28 #include "vehicles/bumblebee.qh"
  29 #include "vehicles/vehicles.qh"
  30
  31 #include "weapons/projectile.qh"
  32
  33 #include "../common/buffs.qh"
  34 #include "../common/deathtypes.qh"
  35 #include "../common/mapinfo.qh"
  36 #include "../common/monsters/monsters.qh"
  37 #include "../common/nades.qh"
  38 #include "../common/net_notice.qh"
  39 #include "../common/notifications.qh"
  40 #include "../common/stats.qh"
  41 #include "../common/teams.qh"
  42
  43 #include "../common/weapons/weapons.qh"
  44
  45 #include "../csqcmodellib/cl_model.qh"
  46 #include "../csqcmodellib/interpolate.qh"
  47
  48 #include "../warpzonelib/client.qh"
  49
  50 // --------------------------------------------------------------------------
  51 // BEGIN REQUIRED CSQC FUNCTIONS
  52 //include "main.qh"
  53
  54 entity clearentity_ent;
  55 void clearentity(entity e)
  56 {
  57         if (!clearentity_ent)
  58         {
  59                 clearentity_ent = spawn();
  60                 clearentity_ent.classname = "clearentity";
  61         }
  62         int n = e.entnum;
  63         copyentity(clearentity_ent, e);
  64         e.entnum = n;
  65 }
  66
  67 #define DP_CSQC_ENTITY_REMOVE_IS_B0RKED
  68 void menu_show_error()
  69 {
  70         drawstring('0 200 0', _("ERROR - MENU IS VISIBLE BUT NO MENU WAS DEFINED!"), '8 8 0', '1 0 0', 1, 0);
  71 }
  72
  73 // CSQC_Init : Called every time the CSQC code is initialized (essentially at map load)
  74 // Useful for precaching things
  75
  76 void menu_sub_null()
  77 {
  78 }
  79
  80 string forcefog;
  81 void WaypointSprite_Load();
  82 void ConsoleCommand_macro_init();
  83 void CSQC_Init(void)
  84 {
  85         prvm_language = cvar_string("prvm_language");
  86
  87 #ifdef WATERMARK
  88         dprintf("^4CSQC Build information: ^1%s\n", WATERMARK);
  89 #endif
  90
  91         int i;
  92
  93         binddb = db_create();
  94         tempdb = db_create();
  95         ClientProgsDB = db_load("client.db");
  96         compressShortVector_init();
  97
  98         draw_endBoldFont();
  99         menu_visible = false;
 100         menu_show = menu_show_error;
 101         menu_action = func_null;
 102
 103         for(i = 0; i < 255; ++i)
 104                 if(getplayerkeyvalue(i, "viewentity") == "")
 105                         break;
 106         maxclients = i;
 107
 108         //registercommand("hud_configure");
 109         //registercommand("hud_save");
 110         //registercommand("menu_action");
 111
 112         ConsoleCommand_macro_init();
 113
 114         registercvar("hud_usecsqc", "1");
 115         registercvar("scoreboard_columns", "default");
 116
 117         registercvar("cl_nade_type", "3");
 118         registercvar("cl_pokenade_type", "zombie");
 119
 120         gametype = 0;
 121
 122         // hud_fields uses strunzone on the titles!
 123         for(i = 0; i < MAX_HUD_FIELDS; ++i)
 124                 hud_title[i] = strzone("(null)");
 125
 126         Cmd_HUD_SetFields(0);
 127
 128         postinit = false;
 129
 130         calledhooks = 0;
 131
 132         teams = Sort_Spawn();
 133         players = Sort_Spawn();
 134
 135         GetTeam(NUM_SPECTATOR, true); // add specs first
 136
 137         // needs to be done so early because of the constants they create
 138         CALL_ACCUMULATED_FUNCTION(RegisterWeapons);
 139         CALL_ACCUMULATED_FUNCTION(RegisterMonsters);
 140         CALL_ACCUMULATED_FUNCTION(RegisterGametypes);
 141         CALL_ACCUMULATED_FUNCTION(RegisterNotifications);
 142         CALL_ACCUMULATED_FUNCTION(RegisterDeathtypes);
 143         CALL_ACCUMULATED_FUNCTION(RegisterHUD_Panels);
 144         CALL_ACCUMULATED_FUNCTION(RegisterBuffs);
 145
 146         WaypointSprite_Load();
 147
 148         // precaches
 149         precache_model("null");
 150         precache_sound("misc/hit.wav");
 151         precache_sound("misc/typehit.wav");
 152
 153         Projectile_Precache();
 154         Hook_Precache();
 155         GibSplash_Precache();
 156         Casings_Precache();
 157         Vehicles_Precache();
 158         turrets_precache();
 159         Tuba_Precache();
 160         CSQCPlayer_Precache();
 161
 162         if(autocvar_cl_reticle)
 163         {
 164                 precache_pic("gfx/reticle_normal");
 165                 // weapon reticles are precached in weapon files
 166         }
 167
 168         get_mi_min_max_texcoords(1); // try the CLEVER way first
 169         minimapname = strcat("gfx/", mi_shortname, "_radar.tga");
 170         shortmapname = mi_shortname;
 171
 172         if(precache_pic(minimapname) == "")
 173         {
 174                 // but maybe we have a non-clever minimap
 175                 minimapname = strcat("gfx/", mi_shortname, "_mini.tga");
 176                 if(precache_pic(minimapname) == "")
 177                         minimapname = ""; // FAIL
 178                 else
 179                         get_mi_min_max_texcoords(0); // load new texcoords
 180         }
 181
 182         mi_center = (mi_min + mi_max) * 0.5;
 183         mi_scale = mi_max - mi_min;
 184         minimapname = strzone(minimapname);
 185
 186         WarpZone_Init();
 187
 188         hud_skin_path = strzone(strcat("gfx/hud/", autocvar_hud_skin));
 189         draw_currentSkin = strzone(strcat("gfx/menu/", cvar_string("menu_skin")));
 190 }
 191
 192 // CSQC_Shutdown : Called every time the CSQC code is shutdown (changing maps, quitting, etc)
 193 void Shutdown(void)
 194 {
 195         WarpZone_Shutdown();
 196
 197         remove(teams);
 198         remove(players);
 199         db_close(binddb);
 200         db_close(tempdb);
 201         if(autocvar_cl_db_saveasdump)
 202                 db_dump(ClientProgsDB, "client.db");
 203         else
 204                 db_save(ClientProgsDB, "client.db");
 205         db_close(ClientProgsDB);
 206
 207         if(camera_active)
 208                 cvar_set("chase_active",ftos(chase_active_backup));
 209
 210         // unset the event chasecam's chase_active
 211         if(autocvar_chase_active < 0)
 212                 cvar_set("chase_active", "0");
 213
 214         if (!isdemo())
 215         {
 216                 if (!(calledhooks & HOOK_START))
 217                         localcmd("\n_cl_hook_gamestart nop\n");
 218                 if (!(calledhooks & HOOK_END))
 219                         localcmd("\ncl_hook_gameend\n");
 220         }
 221 }
 222
 223 .float has_team;
 224 float SetTeam(entity o, int Team)
 225 {
 226         entity tm;
 227         if(teamplay)
 228         {
 229                 switch(Team)
 230                 {
 231                         case -1:
 232                         case NUM_TEAM_1:
 233                         case NUM_TEAM_2:
 234                         case NUM_TEAM_3:
 235                         case NUM_TEAM_4:
 236                                 break;
 237                         default:
 238                                 if(GetTeam(Team, false) == world)
 239                                 {
 240                                         dprintf("trying to switch to unsupported team %d\n", Team);
 241                                         Team = NUM_SPECTATOR;
 242                                 }
 243                                 break;
 244                 }
 245         }
 246         else
 247         {
 248                 switch(Team)
 249                 {
 250                         case -1:
 251                         case 0:
 252                                 break;
 253                         default:
 254                                 if(GetTeam(Team, false) == world)
 255                                 {
 256                                         dprintf("trying to switch to unsupported team %d\n", Team);
 257                                         Team = NUM_SPECTATOR;
 258                                 }
 259                                 break;
 260                 }
 261         }
 262         if(Team == -1) // leave
 263         {
 264                 if(o.has_team)
 265                 {
 266                         tm = GetTeam(o.team, false);
 267                         tm.team_size -= 1;
 268                         o.has_team = 0;
 269                         return true;
 270                 }
 271         }
 272         else
 273         {
 274                 if (!o.has_team)
 275                 {
 276                         o.team = Team;
 277                         tm = GetTeam(Team, true);
 278                         tm.team_size += 1;
 279                         o.has_team = 1;
 280                         return true;
 281                 }
 282                 else if(Team != o.team)
 283                 {
 284                         tm = GetTeam(o.team, false);
 285                         tm.team_size -= 1;
 286                         o.team = Team;
 287                         tm = GetTeam(Team, true);
 288                         tm.team_size += 1;
 289                         return true;
 290                 }
 291         }
 292         return false;
 293 }
 294
 295 void Playerchecker_Think()
 296 {
 297     int i;
 298         entity e;
 299         for(i = 0; i < maxclients; ++i)
 300         {
 301                 e = playerslots[i];
 302                 if(GetPlayerName(i) == "")
 303                 {
 304                         if(e.sort_prev)
 305                         {
 306                                 // player disconnected
 307                                 SetTeam(e, -1);
 308                                 RemovePlayer(e);
 309                                 e.sort_prev = world;
 310                                 //e.gotscores = 0;
 311                         }
 312                 }
 313                 else
 314                 {
 315                         if (!e.sort_prev)
 316                         {
 317                                 // player connected
 318                                 if (!e)
 319                                         playerslots[i] = e = spawn();
 320                                 e.sv_entnum = i;
 321                                 e.ping = 0;
 322                                 e.ping_packetloss = 0;
 323                                 e.ping_movementloss = 0;
 324                                 //e.gotscores = 0; // we might already have the scores...
 325                                 SetTeam(e, GetPlayerColor(i)); // will not hurt; later updates come with HUD_UpdatePlayerTeams
 326                                 RegisterPlayer(e);
 327                                 HUD_UpdatePlayerPos(e);
 328                         }
 329                 }
 330         }
 331         self.nextthink = time + 0.2;
 332 }
 333
 334 void Porto_Init();
 335 void TrueAim_Init();
 336 void PostInit(void)
 337 {
 338         entity playerchecker;
 339         playerchecker = spawn();
 340         playerchecker.think = Playerchecker_Think;
 341         playerchecker.nextthink = time + 0.2;
 342
 343         Porto_Init();
 344         TrueAim_Init();
 345
 346         postinit = true;
 347 }
 348
 349 // CSQC_InputEvent : Used to perform actions based on any key pressed, key released and mouse on the client.
 350 // Return value should be 1 if CSQC handled the input, otherwise return 0 to have the input passed to the engine.
 351 // All keys are in ascii.
 352 // bInputType = 0 is key pressed, 1 is key released, 2 and 3 are mouse input.
 353 // In the case of keyboard input, nPrimary is the ascii code, and nSecondary is 0.
 354 // In the case of mouse input, nPrimary is xdelta, nSecondary is ydelta.
 355 // In the case of mouse input after a setcursormode(1) call, nPrimary is xpos, nSecondary is ypos.
 356 float CSQC_InputEvent(float bInputType, float nPrimary, float nSecondary)
 357 {
 358         float bSkipKey;
 359         bSkipKey = false;
 360
 361         if (HUD_Panel_InputEvent(bInputType, nPrimary, nSecondary))
 362                 return true;
 363
 364         if (MapVote_InputEvent(bInputType, nPrimary, nSecondary))
 365                 return true;
 366
 367         if(menu_visible && menu_action)
 368                 if(menu_action(bInputType, nPrimary, nSecondary))
 369                         return true;
 370
 371         return bSkipKey;
 372 }
 373
 374 // END REQUIRED CSQC FUNCTIONS
 375 // --------------------------------------------------------------------------
 376
 377 // --------------------------------------------------------------------------
 378 // BEGIN OPTIONAL CSQC FUNCTIONS
 379 void Ent_RemoveEntCS()
 380 {
 381         entcs_receiver[self.sv_entnum] = world;
 382 }
 383 void Ent_ReadEntCS()
 384 {
 385     int sf;
 386         InterpolateOrigin_Undo();
 387
 388         self.classname = "entcs_receiver";
 389         sf = ReadByte();
 390
 391         if(sf & 1)
 392                 self.sv_entnum = ReadByte();
 393         if(sf & 2)
 394         {
 395                 self.origin_x = ReadShort();
 396                 self.origin_y = ReadShort();
 397                 self.origin_z = ReadShort();
 398                 setorigin(self, self.origin);
 399         }
 400         if(sf & 4)
 401         {
 402                 self.angles_y = ReadByte() * 360.0 / 256;
 403                 self.angles_x = self.angles_z = 0;
 404         }
 405         if(sf & 8)
 406                 self.healthvalue = ReadByte() * 10;
 407         if(sf & 16)
 408                 self.armorvalue = ReadByte() * 10;
 409
 410         entcs_receiver[self.sv_entnum] = self;
 411         self.entremove = Ent_RemoveEntCS;
 412         self.iflags |= IFLAG_ORIGIN;
 413
 414         InterpolateOrigin_Note();
 415 }
 416
 417 void Ent_Remove();
 418
 419 void Ent_RemovePlayerScore()
 420 {
 421         if(self.owner) {
 422                 SetTeam(self.owner, -1);
 423                 self.owner.gotscores = 0;
 424                 for(int i = 0; i < MAX_SCORE; ++i) {
 425                         self.owner.(scores[i]) = 0; // clear all scores
 426                 }
 427         }
 428 }
 429
 430 void Ent_ReadPlayerScore()
 431 {
 432         int i, n;
 433         bool isNew;
 434         entity o;
 435
 436         // damnit -.- don't want to go change every single .sv_entnum in hud.qc AGAIN
 437         // (no I've never heard of M-x replace-string, sed, or anything like that)
 438         isNew = !self.owner; // workaround for DP bug
 439         n = ReadByte()-1;
 440
 441 #ifdef DP_CSQC_ENTITY_REMOVE_IS_B0RKED
 442         if(!isNew && n != self.sv_entnum)
 443         {
 444                 //print("A CSQC entity changed its owner!\n");
 445                 printf("A CSQC entity changed its owner! (edict: %d, classname: %s)\n", num_for_edict(self), self.classname);
 446                 isNew = true;
 447                 Ent_Remove();
 448                 self.enttype = ENT_CLIENT_SCORES;
 449         }
 450 #endif
 451
 452         self.sv_entnum = n;
 453
 454         if (!(playerslots[self.sv_entnum]))
 455                 playerslots[self.sv_entnum] = spawn();
 456         o = self.owner = playerslots[self.sv_entnum];
 457         o.sv_entnum = self.sv_entnum;
 458         o.gotscores = 1;
 459
 460         //if (!o.sort_prev)
 461         //      RegisterPlayer(o);
 462         //playerchecker will do this for us later, if it has not already done so
 463
 464     int sf, lf;
 465 #if MAX_SCORE <= 8
 466         sf = ReadByte();
 467         lf = ReadByte();
 468 #else
 469         sf = ReadShort();
 470         lf = ReadShort();
 471 #endif
 472     int p;
 473         for(i = 0, p = 1; i < MAX_SCORE; ++i, p *= 2)
 474                 if(sf & p)
 475                 {
 476                         if(lf & p)
 477                                 o.(scores[i]) = ReadInt24_t();
 478                         else
 479                                 o.(scores[i]) = ReadChar();
 480                 }
 481
 482         if(o.sort_prev)
 483                 HUD_UpdatePlayerPos(o); // if not registered, we cannot do this yet!
 484
 485         self.entremove = Ent_RemovePlayerScore;
 486 }
 487
 488 void Ent_ReadTeamScore()
 489 {
 490         int i;
 491         entity o;
 492
 493         self.team = ReadByte();
 494         o = self.owner = GetTeam(self.team, true); // these team numbers can always be trusted
 495
 496     int sf, lf;
 497 #if MAX_TEAMSCORE <= 8
 498         sf = ReadByte();
 499         lf = ReadByte();
 500 #else
 501         sf = ReadShort();
 502         lf = ReadShort();
 503 #endif
 504         int p;
 505         for(i = 0, p = 1; i < MAX_TEAMSCORE; ++i, p *= 2)
 506                 if(sf & p)
 507                 {
 508                         if(lf & p)
 509                                 o.(teamscores[i]) = ReadInt24_t();
 510                         else
 511                                 o.(teamscores[i]) = ReadChar();
 512                 }
 513
 514         HUD_UpdateTeamPos(o);
 515 }
 516
 517 void Ent_ClientData()
 518 {
 519         float newspectatee_status;
 520
 521     int f = ReadByte();
 522
 523         scoreboard_showscores_force = (f & 1);
 524
 525         if(f & 2)
 526         {
 527                 newspectatee_status = ReadByte();
 528                 if(newspectatee_status == player_localnum + 1)
 529                         newspectatee_status = -1; // observing
 530         }
 531         else
 532                 newspectatee_status = 0;
 533
 534         spectatorbutton_zoom = (f & 4);
 535
 536         if(f & 8)
 537         {
 538                 angles_held_status = 1;
 539                 angles_held.x = ReadAngle();
 540                 angles_held.y = ReadAngle();
 541                 angles_held.z = 0;
 542         }
 543         else
 544                 angles_held_status = 0;
 545
 546         if(newspectatee_status != spectatee_status)
 547         {
 548                 // clear race stuff
 549                 race_laptime = 0;
 550                 race_checkpointtime = 0;
 551         }
 552         if (autocvar_hud_panel_healtharmor_progressbar_gfx)
 553         {
 554                 if ( (spectatee_status == -1 && newspectatee_status > 0) //before observing, now spectating
 555                   || (spectatee_status > 0 && newspectatee_status > 0 && spectatee_status != newspectatee_status) //changed spectated player
 556                 )
 557                         prev_p_health = -1;
 558                 else if(spectatee_status && !newspectatee_status) //before observing/spectating, now playing
 559                         prev_health = -1;
 560         }
 561         spectatee_status = newspectatee_status;
 562
 563         // we could get rid of spectatee_status, and derive it from player_localentnum and player_localnum
 564 }
 565
 566 void Ent_Nagger()
 567 {
 568     int i, j, b, f;
 569
 570     int nags = ReadByte(); // NAGS NAGS NAGS NAGS NAGS NAGS NADZ NAGS NAGS NAGS
 571
 572         if(!(nags & 4))
 573         {
 574                 if(vote_called_vote)
 575                         strunzone(vote_called_vote);
 576                 vote_called_vote = string_null;
 577                 vote_active = 0;
 578         }
 579         else
 580         {
 581                 vote_active = 1;
 582         }
 583
 584         if(nags & 64)
 585         {
 586                 vote_yescount = ReadByte();
 587                 vote_nocount = ReadByte();
 588                 vote_needed = ReadByte();
 589                 vote_highlighted = ReadChar();
 590         }
 591
 592         if(nags & 128)
 593         {
 594                 if(vote_called_vote)
 595                         strunzone(vote_called_vote);
 596                 vote_called_vote = strzone(ColorTranslateRGB(ReadString()));
 597         }
 598
 599         if(nags & 1)
 600         {
 601                 for(j = 0; j < maxclients; ++j)
 602                         if(playerslots[j])
 603                                 playerslots[j].ready = 1;
 604                 for(i = 1; i <= maxclients; i += 8)
 605                 {
 606                         f = ReadByte();
 607                         for(j = i-1, b = 1; b < 256; b *= 2, ++j)
 608                                 if (!(f & b))
 609                                         if(playerslots[j])
 610                                                 playerslots[j].ready = 0;
 611                 }
 612         }
 613
 614         ready_waiting = (nags & 1);
 615         ready_waiting_for_me = (nags & 2);
 616         vote_waiting = (nags & 4);
 617         vote_waiting_for_me = (nags & 8);
 618         warmup_stage = (nags & 16);
 619 }
 620
 621 void Ent_EliminatedPlayers()
 622 {
 623     int i, j, b, f;
 624
 625     int sf = ReadByte();
 626         if(sf & 1)
 627         {
 628                 for(j = 0; j < maxclients; ++j)
 629                         if(playerslots[j])
 630                                 playerslots[j].eliminated = 1;
 631                 for(i = 1; i <= maxclients; i += 8)
 632                 {
 633                         f = ReadByte();
 634                         for(j = i-1, b = 1; b < 256; b *= 2, ++j)
 635                                 if (!(f & b))
 636                                         if(playerslots[j])
 637                                                 playerslots[j].eliminated = 0;
 638                 }
 639         }
 640 }
 641
 642 void Ent_RandomSeed()
 643 {
 644         float s;
 645         prandom_debug();
 646         s = ReadShort();
 647         psrandom(s);
 648 }
 649
 650 void Ent_ReadAccuracy(void)
 651 {
 652     int f, w;
 653     int sf = ReadInt24_t();
 654         if(sf == 0)
 655         {
 656                 for(w = 0; w <= WEP_LAST - WEP_FIRST; ++w)
 657                         weapon_accuracy[w] = -1;
 658                 return;
 659         }
 660
 661         for(w = 0, f = 1; w <= WEP_LAST - WEP_FIRST; ++w)
 662         {
 663                 if(sf & f)
 664                 {
 665             int b = ReadByte();
 666                         if(b == 0)
 667                                 weapon_accuracy[w] = -1;
 668                         else if(b == 255)
 669                                 weapon_accuracy[w] = 1.0; // no better error handling yet, sorry
 670                         else
 671                                 weapon_accuracy[w] = (b - 1.0) / 100.0;
 672                 }
 673                 if(f == 0x800000)
 674                         f = 1;
 675                 else
 676                         f *= 2;
 677         }
 678 }
 679
 680 void Spawn_Draw(void)
 681 {
 682         pointparticles(self.cnt, self.origin + '0 0 28', '0 0 2', bound(0, frametime, 0.1));
 683 }
 684
 685 void Ent_ReadSpawnPoint(float is_new) // entity for spawnpoint
 686 {
 687         float teamnum = (ReadByte() - 1);
 688         vector spn_origin;
 689         spn_origin.x = ReadShort();
 690         spn_origin.y = ReadShort();
 691         spn_origin.z = ReadShort();
 692
 693         if(is_new)
 694         {
 695                 self.origin = spn_origin;
 696                 setsize(self, PL_MIN, PL_MAX);
 697                 droptofloor();
 698
 699                 /*if(autocvar_cl_spawn_point_model) // needs a model first
 700                 {
 701                         self.mdl = "models/spawnpoint.md3";
 702                         self.colormod = Team_ColorRGB(teamnum);
 703                         precache_model(self.mdl);
 704                         setmodel(self, self.mdl);
 705                         self.drawmask = MASK_NORMAL;
 706                         //self.movetype = MOVETYPE_NOCLIP;
 707                         //self.draw = Spawn_Draw;
 708                 }*/
 709                 if(autocvar_cl_spawn_point_particles)
 710                 {
 711                         if((serverflags & SERVERFLAG_TEAMPLAY))
 712                         {
 713                                 switch(teamnum)
 714                                 {
 715                                         case NUM_TEAM_1: self.cnt = particleeffectnum("spawn_point_red"); break;
 716                                         case NUM_TEAM_2: self.cnt = particleeffectnum("spawn_point_blue"); break;
 717                                         case NUM_TEAM_3: self.cnt = particleeffectnum("spawn_point_yellow"); break;
 718                                         case NUM_TEAM_4: self.cnt = particleeffectnum("spawn_point_pink"); break;
 719                                         default: self.cnt = particleeffectnum("spawn_point_neutral"); break;
 720                                 }
 721                         }
 722                         else { self.cnt = particleeffectnum("spawn_point_neutral"); }
 723
 724                         self.draw = Spawn_Draw;
 725                 }
 726         }
 727
 728         //printf("Ent_ReadSpawnPoint(is_new = %d); origin = %s, team = %d, effect = %d\n", is_new, vtos(self.origin), teamnum, self.cnt);
 729 }
 730
 731 void Ent_ReadSpawnEvent(float is_new)
 732 {
 733         // If entnum is 0, ONLY do the local spawn actions
 734         // this way the server can disable the sending of
 735         // spawn origin or such to clients if wanted.
 736         float entnum = ReadByte();
 737
 738         if(entnum)
 739         {
 740                 self.origin_x = ReadShort();
 741                 self.origin_y = ReadShort();
 742                 self.origin_z = ReadShort();
 743
 744                 if(is_new)
 745                 {
 746                         float teamnum = GetPlayerColor(entnum - 1);
 747
 748                         if(autocvar_cl_spawn_event_particles)
 749                         {
 750                                 switch(teamnum)
 751                                 {
 752                                         case NUM_TEAM_1: pointparticles(particleeffectnum("spawn_event_red"), self.origin, '0 0 0', 1); break;
 753                                         case NUM_TEAM_2: pointparticles(particleeffectnum("spawn_event_blue"), self.origin, '0 0 0', 1); break;
 754                                         case NUM_TEAM_3: pointparticles(particleeffectnum("spawn_event_yellow"), self.origin, '0 0 0', 1); break;
 755                                         case NUM_TEAM_4: pointparticles(particleeffectnum("spawn_event_pink"), self.origin, '0 0 0', 1); break;
 756                                         default: pointparticles(particleeffectnum("spawn_event_neutral"), self.origin, '0 0 0', 1); break;
 757                                 }
 758                         }
 759                         if(autocvar_cl_spawn_event_sound)
 760                         {
 761                                 sound(self, CH_TRIGGER, "misc/spawn.wav", VOL_BASE, ATTEN_NORM);
 762                         }
 763                 }
 764         }
 765
 766         // local spawn actions
 767         if(is_new && (!entnum || (entnum == player_localentnum)))
 768         {
 769                 zoomin_effect = 1;
 770                 current_viewzoom = (1 / bound(1, autocvar_cl_spawnzoom_factor, 16));
 771
 772                 if(autocvar_cl_unpress_zoom_on_spawn)
 773                 {
 774                         localcmd("-zoom\n");
 775                         button_zoom = false;
 776                 }
 777         }
 778
 779         //printf("Ent_ReadSpawnEvent(is_new = %d); origin = %s, entnum = %d, localentnum = %d\n", is_new, vtos(self.origin), entnum, player_localentnum);
 780 }
 781
 782 // CSQC_Ent_Update : Called every frame that the server has indicated an update to the SSQC / CSQC entity has occured.
 783 // The only parameter reflects if the entity is "new" to the client, meaning it just came into the client's PVS.
 784 void Ent_RadarLink();
 785 void Ent_Init();
 786 void Ent_ScoresInfo();
 787 void CSQC_Ent_Update(float bIsNewEntity)
 788 {
 789         float t;
 790         float savetime;
 791         t = ReadByte();
 792
 793         if(autocvar_developer_csqcentities)
 794                 printf("CSQC_Ent_Update(%d) with self=%i self.entnum=%d self.enttype=%d t=%d\n", bIsNewEntity, self, self.entnum, self.enttype, t);
 795
 796         // set up the "time" global for received entities to be correct for interpolation purposes
 797         savetime = time;
 798         if(servertime)
 799         {
 800                 time = servertime;
 801         }
 802         else
 803         {
 804                 serverprevtime = time;
 805                 serverdeltatime = getstatf(STAT_MOVEVARS_TICRATE) * getstatf(STAT_MOVEVARS_TIMESCALE);
 806                 time = serverprevtime + serverdeltatime;
 807         }
 808
 809 #ifdef DP_CSQC_ENTITY_REMOVE_IS_B0RKED
 810         if(self.enttype)
 811         {
 812                 if(t != self.enttype || bIsNewEntity)
 813                 {
 814                         //print("A CSQC entity changed its type!\n");
 815                         printf("A CSQC entity changed its type! (edict: %d, server: %d, type: %d -> %d)\n", num_for_edict(self), self.entnum, self.enttype, t);
 816                         Ent_Remove();
 817                         clearentity(self);
 818                         bIsNewEntity = 1;
 819                 }
 820         }
 821         else
 822         {
 823                 if(!bIsNewEntity)
 824                 {
 825                         printf("A CSQC entity appeared out of nowhere! (edict: %d, server: %d, type: %d)\n", num_for_edict(self), self.entnum, t);
 826                         bIsNewEntity = 1;
 827                 }
 828         }
 829 #endif
 830         self.enttype = t;
 831         switch(t)
 832         {
 833                 case ENT_CLIENT_ENTCS: Ent_ReadEntCS(); break;
 834                 case ENT_CLIENT_SCORES: Ent_ReadPlayerScore(); break;
 835                 case ENT_CLIENT_TEAMSCORES: Ent_ReadTeamScore(); break;
 836                 case ENT_CLIENT_POINTPARTICLES: Ent_PointParticles(); break;
 837                 case ENT_CLIENT_RAINSNOW: Ent_RainOrSnow(); break;
 838                 case ENT_CLIENT_LASER: Ent_Laser(); break;
 839                 case ENT_CLIENT_NAGGER: Ent_Nagger(); break;
 840                 case ENT_CLIENT_ELIMINATEDPLAYERS: Ent_EliminatedPlayers(); break;
 841                 case ENT_CLIENT_WAYPOINT: Ent_WaypointSprite(); break;
 842                 case ENT_CLIENT_RADARLINK: Ent_RadarLink(); break;
 843                 case ENT_CLIENT_PROJECTILE: Ent_Projectile(); break;
 844                 case ENT_CLIENT_GIBSPLASH: Ent_GibSplash(bIsNewEntity); break;
 845                 case ENT_CLIENT_DAMAGEINFO: Ent_DamageInfo(bIsNewEntity); break;
 846                 case ENT_CLIENT_CASING: Ent_Casing(bIsNewEntity); break;
 847                 case ENT_CLIENT_INIT: Ent_Init(); break;
 848                 case ENT_CLIENT_SCORES_INFO: Ent_ScoresInfo(); break;
 849                 case ENT_CLIENT_MAPVOTE: Ent_MapVote(); break;
 850                 case ENT_CLIENT_CLIENTDATA: Ent_ClientData(); break;
 851                 case ENT_CLIENT_RANDOMSEED: Ent_RandomSeed(); break;
 852                 case ENT_CLIENT_WALL: Ent_Wall(); break;
 853                 case ENT_CLIENT_MODELEFFECT: Ent_ModelEffect(bIsNewEntity); break;
 854                 case ENT_CLIENT_TUBANOTE: Ent_TubaNote(bIsNewEntity); break;
 855                 case ENT_CLIENT_WARPZONE: WarpZone_Read(bIsNewEntity); break;
 856                 case ENT_CLIENT_WARPZONE_CAMERA: WarpZone_Camera_Read(bIsNewEntity); break;
 857                 case ENT_CLIENT_WARPZONE_TELEPORTED: WarpZone_Teleported_Read(bIsNewEntity); break;
 858                 case ENT_CLIENT_TRIGGER_MUSIC: Ent_ReadTriggerMusic(); break;
 859                 case ENT_CLIENT_HOOK: Ent_ReadHook(bIsNewEntity, ENT_CLIENT_HOOK); break;
 860                 case ENT_CLIENT_ARC_BEAM: Ent_ReadArcBeam(bIsNewEntity); break;
 861                 case ENT_CLIENT_ACCURACY: Ent_ReadAccuracy(); break;
 862                 case ENT_CLIENT_AUXILIARYXHAIR: Net_AuXair2(bIsNewEntity); break;
 863                 case ENT_CLIENT_TURRET: ent_turret(); break;
 864                 case ENT_CLIENT_MODEL: CSQCModel_Read(bIsNewEntity); break;
 865                 case ENT_CLIENT_ITEM: ItemRead(bIsNewEntity); break;
 866                 case ENT_CLIENT_BUMBLE_RAYGUN: bumble_raygun_read(bIsNewEntity); break;
 867                 case ENT_CLIENT_SPAWNPOINT: Ent_ReadSpawnPoint(bIsNewEntity); break;
 868                 case ENT_CLIENT_SPAWNEVENT: Ent_ReadSpawnEvent(bIsNewEntity); break;
 869                 case ENT_CLIENT_NOTIFICATION: Read_Notification(bIsNewEntity); break;
 870                 case ENT_CLIENT_HEALING_ORB: ent_healer(); break;
 871
 872                 default:
 873                         //error(strcat(_("unknown entity type in CSQC_Ent_Update: %d\n"), self.enttype));
 874                         error(sprintf("Unknown entity type in CSQC_Ent_Update (enttype: %d, edict: %d, classname: %s)\n", self.enttype, num_for_edict(self), self.classname));
 875                         break;
 876         }
 877
 878         time = savetime;
 879 }
 880 // Destructor, but does NOT deallocate the entity by calling remove(). Also
 881 // used when an entity changes its type. For an entity that someone interacts
 882 // with others, make sure it can no longer do so.
 883 void Ent_Remove()
 884 {
 885         if(self.entremove)
 886                 self.entremove();
 887
 888         if(self.skeletonindex)
 889         {
 890                 skel_delete(self.skeletonindex);
 891                 self.skeletonindex = 0;
 892         }
 893
 894         if(self.snd_looping > 0)
 895         {
 896                 sound(self, self.snd_looping, "misc/null.wav", VOL_BASE, autocvar_g_jetpack_attenuation);
 897                 self.snd_looping = 0;
 898         }
 899
 900         self.enttype = 0;
 901         self.classname = "";
 902         self.draw = menu_sub_null;
 903         self.entremove = menu_sub_null;
 904         // TODO possibly set more stuff to defaults
 905 }
 906 // CSQC_Ent_Remove : Called when the server requests a SSQC / CSQC entity to be removed.  Essentially call remove(self) as well.
 907 void CSQC_Ent_Remove()
 908 {
 909         if(autocvar_developer_csqcentities)
 910                 printf("CSQC_Ent_Remove() with self=%i self.entnum=%d self.enttype=%d\n", self, self.entnum, self.enttype);
 911
 912         if(wasfreed(self))
 913         {
 914                 print("WARNING: CSQC_Ent_Remove called for already removed entity. Packet loss?\n");
 915                 return;
 916         }
 917         if(self.enttype)
 918                 Ent_Remove();
 919         remove(self);
 920 }
 921
 922 void Gamemode_Init()
 923 {
 924         if (!isdemo())
 925         {
 926                 if(!(calledhooks & HOOK_START))
 927                         localcmd("\n_cl_hook_gamestart ", MapInfo_Type_ToString(gametype), "\n");
 928                 calledhooks |= HOOK_START;
 929         }
 930 }
 931 // CSQC_Parse_StuffCmd : Provides the stuffcmd string in the first parameter that the server provided.  To execute standard behavior, simply execute localcmd with the string.
 932 void CSQC_Parse_StuffCmd(string strMessage)
 933 {
 934         if(autocvar_developer_csqcentities)
 935                 printf("CSQC_Parse_StuffCmd(\"%s\")\n", strMessage);
 936
 937         localcmd(strMessage);
 938 }
 939 // CSQC_Parse_Print : Provides the print string in the first parameter that the server provided.  To execute standard behavior, simply execute print with the string.
 940 void CSQC_Parse_Print(string strMessage)
 941 {
 942         if(autocvar_developer_csqcentities)
 943                 printf("CSQC_Parse_Print(\"%s\")\n", strMessage);
 944
 945         print(ColorTranslateRGB(strMessage));
 946 }
 947
 948 // CSQC_Parse_CenterPrint : Provides the centerprint_hud string in the first parameter that the server provided.
 949 void CSQC_Parse_CenterPrint(string strMessage)
 950 {
 951         if(autocvar_developer_csqcentities)
 952                 printf("CSQC_Parse_CenterPrint(\"%s\")\n", strMessage);
 953
 954         centerprint_hud(strMessage);
 955 }
 956
 957 string notranslate_fogcmd1 = "\nfog ";
 958 string notranslate_fogcmd2 = "\nr_fog_exp2 0\nr_drawfog 1\n";
 959 void Fog_Force()
 960 {
 961         // TODO somehow thwart prvm_globalset client ...
 962
 963         if(autocvar_cl_orthoview && autocvar_cl_orthoview_nofog)
 964                 { localcmd("\nr_drawfog 0\n"); }
 965         else if(forcefog != "")
 966                 { localcmd(strcat(notranslate_fogcmd1, forcefog, notranslate_fogcmd2)); }
 967 }
 968
 969 void Gamemode_Init();
 970 void Ent_ScoresInfo()
 971 {
 972     int i;
 973         self.classname = "ent_client_scores_info";
 974         gametype = ReadInt24_t();
 975         HUD_ModIcons_SetFunc();
 976         for(i = 0; i < MAX_SCORE; ++i)
 977         {
 978                 if(scores_label[i])
 979                         strunzone(scores_label[i]);
 980                 scores_label[i] = strzone(ReadString());
 981                 scores_flags[i] = ReadByte();
 982         }
 983         for(i = 0; i < MAX_TEAMSCORE; ++i)
 984         {
 985                 if(teamscores_label[i])
 986                         strunzone(teamscores_label[i]);
 987                 teamscores_label[i] = strzone(ReadString());
 988                 teamscores_flags[i] = ReadByte();
 989         }
 990         HUD_InitScores();
 991         Gamemode_Init();
 992 }
 993
 994 void Ent_Init()
 995 {
 996         self.classname = "ent_client_init";
 997
 998         nb_pb_period = ReadByte() / 32; //Accuracy of 1/32th
 999
1000         hook_shotorigin[0] = decompressShotOrigin(ReadInt24_t());
1001         hook_shotorigin[1] = decompressShotOrigin(ReadInt24_t());
1002         hook_shotorigin[2] = decompressShotOrigin(ReadInt24_t());
1003         hook_shotorigin[3] = decompressShotOrigin(ReadInt24_t());
1004         arc_shotorigin[0] = decompressShotOrigin(ReadInt24_t());
1005         arc_shotorigin[1] = decompressShotOrigin(ReadInt24_t());
1006         arc_shotorigin[2] = decompressShotOrigin(ReadInt24_t());
1007         arc_shotorigin[3] = decompressShotOrigin(ReadInt24_t());
1008
1009         if(forcefog)
1010                 strunzone(forcefog);
1011         forcefog = strzone(ReadString());
1012
1013         armorblockpercent = ReadByte() / 255.0;
1014
1015         g_balance_mortar_bouncefactor = ReadCoord();
1016         g_balance_mortar_bouncestop = ReadCoord();
1017         g_balance_electro_secondary_bouncefactor = ReadCoord();
1018         g_balance_electro_secondary_bouncestop = ReadCoord();
1019
1020         vortex_scope = !ReadByte();
1021         rifle_scope = !ReadByte();
1022
1023         serverflags = ReadByte();
1024
1025         minelayer_maxmines = ReadByte();
1026
1027         hagar_maxrockets = ReadByte();
1028
1029         g_trueaim_minrange = ReadCoord();
1030         g_balance_porto_secondary = ReadByte();
1031
1032         if(!postinit)
1033                 PostInit();
1034 }
1035
1036 void Net_ReadRace()
1037 {
1038         float b;
1039
1040         b = ReadByte();
1041
1042         switch(b)
1043         {
1044                 case RACE_NET_CHECKPOINT_HIT_QUALIFYING:
1045                         race_checkpoint = ReadByte();
1046                         race_time = ReadInt24_t();
1047                         race_previousbesttime = ReadInt24_t();
1048                         if(race_previousbestname)
1049                                 strunzone(race_previousbestname);
1050                         race_previousbestname = strzone(ColorTranslateRGB(ReadString()));
1051
1052                         race_checkpointtime = time;
1053
1054                         if(race_checkpoint == 0 || race_checkpoint == 254)
1055                         {
1056                                 race_penaltyaccumulator = 0;
1057                                 race_laptime = time; // valid
1058                         }
1059
1060                         break;
1061
1062                 case RACE_NET_CHECKPOINT_CLEAR:
1063                         race_laptime = 0;
1064                         race_checkpointtime = 0;
1065                         break;
1066
1067                 case RACE_NET_CHECKPOINT_NEXT_SPEC_QUALIFYING:
1068                         race_laptime = ReadCoord();
1069                         race_checkpointtime = -99999;
1070                         // fall through
1071                 case RACE_NET_CHECKPOINT_NEXT_QUALIFYING:
1072                         race_nextcheckpoint = ReadByte();
1073
1074                         race_nextbesttime = ReadInt24_t();
1075                         if(race_nextbestname)
1076                                 strunzone(race_nextbestname);
1077                         race_nextbestname = strzone(ColorTranslateRGB(ReadString()));
1078                         break;
1079
1080                 case RACE_NET_CHECKPOINT_HIT_RACE:
1081                         race_mycheckpoint = ReadByte();
1082                         race_mycheckpointtime = time;
1083                         race_mycheckpointdelta = ReadInt24_t();
1084                         race_mycheckpointlapsdelta = ReadByte();
1085                         if(race_mycheckpointlapsdelta >= 128)
1086                                 race_mycheckpointlapsdelta -= 256;
1087                         if(race_mycheckpointenemy)
1088                                 strunzone(race_mycheckpointenemy);
1089                         race_mycheckpointenemy = strzone(ColorTranslateRGB(ReadString()));
1090                         break;
1091
1092                 case RACE_NET_CHECKPOINT_HIT_RACE_BY_OPPONENT:
1093                         race_othercheckpoint = ReadByte();
1094                         race_othercheckpointtime = time;
1095                         race_othercheckpointdelta = ReadInt24_t();
1096                         race_othercheckpointlapsdelta = ReadByte();
1097                         if(race_othercheckpointlapsdelta >= 128)
1098                                 race_othercheckpointlapsdelta -= 256;
1099                         if(race_othercheckpointenemy)
1100                                 strunzone(race_othercheckpointenemy);
1101                         race_othercheckpointenemy = strzone(ColorTranslateRGB(ReadString()));
1102                         break;
1103
1104                 case RACE_NET_PENALTY_RACE:
1105                         race_penaltyeventtime = time;
1106                         race_penaltytime = ReadShort();
1107                         //race_penaltyaccumulator += race_penaltytime;
1108                         if(race_penaltyreason)
1109                                 strunzone(race_penaltyreason);
1110                         race_penaltyreason = strzone(ReadString());
1111                         break;
1112
1113                 case RACE_NET_PENALTY_QUALIFYING:
1114                         race_penaltyeventtime = time;
1115                         race_penaltytime = ReadShort();
1116                         race_penaltyaccumulator += race_penaltytime;
1117                         if(race_penaltyreason)
1118                                 strunzone(race_penaltyreason);
1119                         race_penaltyreason = strzone(ReadString());
1120                         break;
1121
1122                 case RACE_NET_SERVER_RECORD:
1123                         race_server_record = ReadInt24_t();
1124                         break;
1125                 case RACE_NET_SPEED_AWARD:
1126                         race_speedaward = ReadInt24_t();
1127                         if(race_speedaward_holder)
1128                                 strunzone(race_speedaward_holder);
1129                         race_speedaward_holder = strzone(ReadString());
1130                         break;
1131                 case RACE_NET_SPEED_AWARD_BEST:
1132                         race_speedaward_alltimebest = ReadInt24_t();
1133                         if(race_speedaward_alltimebest_holder)
1134                                 strunzone(race_speedaward_alltimebest_holder);
1135                         race_speedaward_alltimebest_holder = strzone(ReadString());
1136                         break;
1137                 case RACE_NET_SERVER_RANKINGS:
1138                         float prevpos, del;
1139             int pos = ReadShort();
1140                         prevpos = ReadShort();
1141                         del = ReadShort();
1142
1143                         // move other rankings out of the way
1144             int i;
1145                         if (prevpos) {
1146                                 for (i=prevpos-1;i>pos-1;--i) {
1147                                         grecordtime[i] = grecordtime[i-1];
1148                                         if(grecordholder[i])
1149                                                 strunzone(grecordholder[i]);
1150                                         grecordholder[i] = strzone(grecordholder[i-1]);
1151                                 }
1152                         } else if (del) { // a record has been deleted by the admin
1153                                 for (i=pos-1; i<= RANKINGS_CNT-1; ++i) {
1154                                         if (i == RANKINGS_CNT-1) { // clear out last record
1155                                                 grecordtime[i] = 0;
1156                                                 if (grecordholder[i])
1157                                                         strunzone(grecordholder[i]);
1158                                                 grecordholder[i] = string_null;
1159                                         }
1160                                         else {
1161                                                 grecordtime[i] = grecordtime[i+1];
1162                                                 if (grecordholder[i])
1163                                                         strunzone(grecordholder[i]);
1164                                                 grecordholder[i] = strzone(grecordholder[i+1]);
1165                                         }
1166                                 }
1167                         } else { // player has no ranked record yet
1168                                 for (i=RANKINGS_CNT-1;i>pos-1;--i) {
1169                                         grecordtime[i] = grecordtime[i-1];
1170                                         if(grecordholder[i])
1171                                                 strunzone(grecordholder[i]);
1172                                         grecordholder[i] = strzone(grecordholder[i-1]);
1173                                 }
1174                         }
1175
1176                         // store new ranking
1177                         if(grecordholder[pos-1] != "")
1178                                 strunzone(grecordholder[pos-1]);
1179                         grecordholder[pos-1] = strzone(ReadString());
1180                         grecordtime[pos-1] = ReadInt24_t();
1181                         if(grecordholder[pos-1] == GetPlayerName(player_localnum))
1182                                 race_myrank = pos;
1183                         break;
1184                 case RACE_NET_SERVER_STATUS:
1185                         race_status = ReadShort();
1186                         if(race_status_name)
1187                                 strunzone(race_status_name);
1188                         race_status_name = strzone(ReadString());
1189         }
1190 }
1191
1192 void Net_TeamNagger()
1193 {
1194         teamnagger = 1;
1195 }
1196
1197 void Net_ReadPingPLReport()
1198 {
1199         int e, pi, pl, ml;
1200         e = ReadByte();
1201         pi = ReadShort();
1202         pl = ReadByte();
1203         ml = ReadByte();
1204         if (!(playerslots[e]))
1205                 return;
1206         playerslots[e].ping = pi;
1207         playerslots[e].ping_packetloss = pl / 255.0;
1208         playerslots[e].ping_movementloss = ml / 255.0;
1209 }
1210
1211 void Net_WeaponComplain()
1212 {
1213         complain_weapon = ReadByte();
1214
1215         if(complain_weapon_name)
1216                 strunzone(complain_weapon_name);
1217         complain_weapon_name = strzone(WEP_NAME(complain_weapon));
1218
1219         complain_weapon_type = ReadByte();
1220
1221         complain_weapon_time = time;
1222         weapontime = time; // ping the weapon panel
1223
1224         switch(complain_weapon_type)
1225         {
1226                 case 0: Local_Notification(MSG_MULTI, ITEM_WEAPON_NOAMMO, complain_weapon); break;
1227                 case 1: Local_Notification(MSG_MULTI, ITEM_WEAPON_DONTHAVE, complain_weapon); break;
1228                 default: Local_Notification(MSG_MULTI, ITEM_WEAPON_UNAVAILABLE, complain_weapon); break;
1229         }
1230 }
1231
1232 // CSQC_Parse_TempEntity : Handles all temporary entity network data in the CSQC layer.
1233 // You must ALWAYS first acquire the temporary ID, which is sent as a byte.
1234 // Return value should be 1 if CSQC handled the temporary entity, otherwise return 0 to have the engine process the event.
1235 float CSQC_Parse_TempEntity()
1236 {
1237         float bHandled;
1238                 bHandled  = true;
1239         // Acquire TE ID
1240         float nTEID;
1241                 nTEID = ReadByte();
1242
1243         if(autocvar_developer_csqcentities)
1244                 printf("CSQC_Parse_TempEntity() with nTEID=%d\n", nTEID);
1245
1246                 // NOTE: Could just do return instead of break...
1247         switch(nTEID)
1248         {
1249                 case TE_CSQC_TARGET_MUSIC:
1250                         Net_TargetMusic();
1251                         bHandled = true;
1252                         break;
1253                 case TE_CSQC_PICTURE:
1254                         Net_MapVote_Picture();
1255                         bHandled = true;
1256                         break;
1257                 case TE_CSQC_RACE:
1258                         Net_ReadRace();
1259                         bHandled = true;
1260                         break;
1261                 case TE_CSQC_VORTEXBEAMPARTICLE:
1262                         Net_ReadVortexBeamParticle();
1263                         bHandled = true;
1264                         break;
1265                 case TE_CSQC_TEAMNAGGER:
1266                         Net_TeamNagger();
1267                         bHandled = true;
1268                         break;
1269                 case TE_CSQC_ARC:
1270                         Net_ReadArc();
1271                         bHandled = true;
1272                         break;
1273                 case TE_CSQC_PINGPLREPORT:
1274                         Net_ReadPingPLReport();
1275                         bHandled = true;
1276                         break;
1277                 case TE_CSQC_WEAPONCOMPLAIN:
1278                         Net_WeaponComplain();
1279                         bHandled = true;
1280                         break;
1281                 case TE_CSQC_VEHICLESETUP:
1282                         Net_VehicleSetup();
1283                         bHandled = true;
1284                         break;
1285                 case TE_CSQC_SVNOTICE:
1286                         cl_notice_read();
1287                         bHandled = true;
1288                         break;
1289                 case TE_CSQC_SHOCKWAVEPARTICLE:
1290                         Net_ReadShockwaveParticle();
1291                         bHandled = true;
1292                         break;
1293                 default:
1294                         // No special logic for this temporary entity; return 0 so the engine can handle it
1295                         bHandled = false;
1296                         break;
1297         }
1298
1299         return bHandled;
1300 }
1301
1302 string getcommandkey(string text, string command)
1303 {
1304         string keys;
1305         float n, j, k, l = 0;
1306
1307         if (!autocvar_hud_showbinds)
1308                 return text;
1309
1310         keys = db_get(binddb, command);
1311         if (keys == "")
1312         {
1313                 n = tokenize(findkeysforcommand(command, 0)); // uses '...' strings
1314                 for(j = 0; j < n; ++j)
1315                 {
1316                         k = stof(argv(j));
1317                         if(k != -1)
1318                         {
1319                                 if ("" == keys)
1320                                         keys = keynumtostring(k);
1321                                 else
1322                                         keys = strcat(keys, ", ", keynumtostring(k));
1323
1324                                 ++l;
1325                                 if (autocvar_hud_showbinds_limit > 0 && autocvar_hud_showbinds_limit <= l)
1326                                         break;
1327                         }
1328
1329                 }
1330                 if (keys == "")
1331                         keys = "NO_KEY";
1332                 db_put(binddb, command, keys);
1333         }
1334
1335         if (keys == "NO_KEY") {
1336                 if (autocvar_hud_showbinds > 1)
1337                         return sprintf(_("%s (not bound)"), text);
1338                 else
1339                         return text;
1340         }
1341         else if (autocvar_hud_showbinds > 1)
1342                 return sprintf("%s (%s)", text, keys);
1343         else
1344                 return keys;
1345 }