qcsrc/client/main.qc

   1 #include "main.qh"
   2
   3 #include <client/command/cl_cmd.qh>
   4 #include <client/draw.qh>
   5 #include <client/hud/_mod.qh>
   6 #include <client/hud/panel/centerprint.qh>
   7 #include <client/hud/panel/chat.qh>
   8 #include <client/hud/panel/quickmenu.qh>
   9 #include <client/hud/panel/scoreboard.qh>
  10 #include <client/items/items.qh>
  11 #include <client/mapvoting.qh>
  12 #include <client/mutators/_mod.qh>
  13 #include <client/shownames.qh>
  14 #include <client/view.qh>
  15 #include <client/weapons/projectile.qh>
  16 #include <common/deathtypes/all.qh>
  17 #include <common/effects/all.inc>
  18 #include <common/effects/all.qh>
  19 #include <common/effects/effect.qh>
  20 #include <common/effects/qc/_mod.qh>
  21 #include <common/ent_cs.qh>
  22 #include <common/gamemodes/gamemode/nexball/cl_nexball.qh>
  23 #include <common/items/_mod.qh>
  24 #include <common/mapinfo.qh>
  25 #include <common/mapobjects/_mod.qh>
  26 #include <common/minigames/cl_minigames.qh>
  27 #include <common/minigames/cl_minigames_hud.qh>
  28 #include <common/net_linked.qh>
  29 #include <common/net_notice.qh>
  30 #include <common/scores.qh>
  31 #include <common/vehicles/all.qh>
  32 #include <lib/csqcmodel/cl_model.qh>
  33 #include <lib/csqcmodel/interpolate.qh>
  34 #include <lib/warpzone/client.qh>
  35
  36 // --------------------------------------------------------------------------
  37 // BEGIN REQUIRED CSQC FUNCTIONS
  38 //include "main.qh"
  39
  40 #define DP_CSQC_ENTITY_REMOVE_IS_B0RKED
  41
  42 // CSQC_Init : Called every time the CSQC code is initialized (essentially at map load)
  43 // Useful for precaching things
  44
  45 void CSQC_Init()
  46 {
  47         prvm_language = strzone(cvar_string("prvm_language"));
  48
  49 #ifdef WATERMARK
  50         LOG_TRACEF("^4CSQC Build information: ^1%s", WATERMARK);
  51 #endif
  52
  53         {
  54                 int i = 0;
  55                 for ( ; i < 255; ++i)
  56                         if (getplayerkeyvalue(i, "viewentity") == "")
  57                                 break;
  58                 maxclients = i;
  59         }
  60
  61         // needs to be done so early because of the constants they create
  62         static_init();
  63         static_init_late();
  64         static_init_precache();
  65
  66         binddb = db_create();
  67         tempdb = db_create();
  68         ClientProgsDB = db_load("client.db");
  69
  70         draw_endBoldFont();
  71
  72         //registercommand("hud_configure");
  73         //registercommand("hud_save");
  74         //registercommand("menu_action");
  75
  76         ConsoleCommand_macro_init();
  77
  78         registercvar("hud_usecsqc", "1");
  79         registercvar("scoreboard_columns", "default");
  80
  81         registercvar("cl_nade_type", "3");
  82         registercvar("cl_pokenade_type", "zombie");
  83
  84         registercvar("cl_jumpspeedcap_min", "");
  85         registercvar("cl_jumpspeedcap_max", "");
  86
  87         registercvar("cl_shootfromfixedorigin", "");
  88
  89         registercvar("cl_multijump", "-1");
  90
  91         registercvar("cl_dodging", "0");
  92
  93         registercvar("cl_spawn_near_teammate", "1");
  94
  95         registercvar("cl_weapon_switch_reload", "1");
  96         registercvar("cl_weapon_switch_fallback_to_impulse", "1");
  97
  98         registercvar("cl_allow_uidranking", "1");
  99
 100         if(autocvar_cl_lockview)
 101                 cvar_set("cl_lockview", "0");
 102
 103         gametype = NULL;
 104
 105         postinit = false;
 106
 107         calledhooks = 0;
 108
 109         teams = Sort_Spawn();
 110         players = Sort_Spawn();
 111
 112         GetTeam(NUM_SPECTATOR, true); // add specs first
 113
 114         for (int w = 0; w <= WEP_LAST - WEP_FIRST; ++w)
 115                 weapon_accuracy[w] = -1;
 116
 117         // precaches
 118
 119         if(autocvar_cl_reticle)
 120         {
 121                 precache_pic("gfx/reticle_normal");
 122                 // weapon reticles are precached in weapon files
 123         }
 124
 125         {
 126                 get_mi_min_max_texcoords(1); // try the CLEVER way first
 127                 minimapname = strcat("gfx/", mi_shortname, "_radar");
 128                 shortmapname = mi_shortname;
 129
 130                 if (precache_pic(minimapname) == "")
 131                 {
 132                         // but maybe we have a non-clever minimap
 133                         minimapname = strcat("gfx/", mi_shortname, "_mini");
 134                         if (precache_pic(minimapname) == "")
 135                                 minimapname = ""; // FAIL
 136                         else
 137                                 get_mi_min_max_texcoords(0); // load new texcoords
 138                 }
 139
 140                 mi_center = (mi_min + mi_max) * 0.5;
 141                 mi_scale = mi_max - mi_min;
 142                 minimapname = strzone(minimapname);
 143         }
 144
 145         hud_skin_path = strzone(strcat("gfx/hud/", autocvar_hud_skin));
 146         LoadMenuSkinValues();
 147 }
 148
 149 // CSQC_Shutdown : Called every time the CSQC code is shutdown (changing maps, quitting, etc)
 150 void Shutdown()
 151 {
 152         WarpZone_Shutdown();
 153
 154         delete(teams);
 155         delete(players);
 156         db_close(binddb);
 157         db_close(tempdb);
 158         if(autocvar_cl_db_saveasdump)
 159                 db_dump(ClientProgsDB, "client.db");
 160         else
 161                 db_save(ClientProgsDB, "client.db");
 162         db_close(ClientProgsDB);
 163
 164         if(camera_active)
 165                 cvar_set("chase_active",ftos(chase_active_backup));
 166
 167         // unset the event chasecam's chase_active
 168         if(autocvar_chase_active < 0)
 169                 cvar_set("chase_active", "0");
 170
 171         if (autocvar_r_drawviewmodel < 0)
 172                 cvar_set("r_drawviewmodel", "0");
 173
 174         cvar_set("slowmo", cvar_defstring("slowmo")); // reset it back to 'default'
 175
 176         if (!isdemo())
 177         {
 178                 if (!(calledhooks & HOOK_START))
 179                         localcmd("\n_cl_hook_gamestart nop\n");
 180                 if (!(calledhooks & HOOK_END))
 181                 {
 182                         int gamecount = cvar("cl_matchcount");
 183                         localcmd("\ncl_hook_gameend\n");
 184                         // NOTE: using localcmd here to ensure it's executed AFTER cl_hook_gameend
 185                         // earlier versions of the game abuse the hook to set this cvar
 186                         localcmd(strcat("cl_matchcount ", itos(gamecount + 1), "\n"));
 187                         //cvar_set("cl_matchcount", itos(gamecount + 1));
 188                 }
 189         }
 190
 191         localcmd("\ncl_hook_shutdown\n");
 192
 193         localcmd("\n-button12\n");
 194
 195         deactivate_minigame();
 196         HUD_MinigameMenu_Close(NULL, NULL, NULL);
 197
 198         ReplicateVars(REPLICATEVARS_DESTROY);
 199 }
 200
 201 void AuditLists()
 202 {
 203         entity e;
 204         entity prev;
 205
 206         prev = players;
 207         for(e = prev.sort_next; e; prev = e, e = e.sort_next)
 208         {
 209                 if(prev != e.sort_prev)
 210                         error(strcat("sort list chain error\nplease submit the output of 'prvm_edicts client' to the developers"));
 211         }
 212
 213         prev = teams;
 214         for(e = prev.sort_next; e; prev = e, e = e.sort_next)
 215         {
 216                 if(prev != e.sort_prev)
 217                         error(strcat("sort list chain error\nplease submit the output of 'prvm_edicts client' to the developers"));
 218         }
 219 }
 220
 221 float RegisterPlayer(entity player)
 222 {
 223         entity pl;
 224         AuditLists();
 225         for(pl = players.sort_next; pl; pl = pl.sort_next)
 226                 if(pl == player)
 227                         error("Player already registered!");
 228         player.sort_next = players.sort_next;
 229         player.sort_prev = players;
 230         if(players.sort_next)
 231                 players.sort_next.sort_prev = player;
 232         players.sort_next = player;
 233         AuditLists();
 234         return true;
 235 }
 236
 237 void RemovePlayer(entity player)
 238 {
 239         entity pl, parent;
 240         AuditLists();
 241         parent = players;
 242         for(pl = players.sort_next; pl && pl != player; pl = pl.sort_next)
 243                 parent = pl;
 244
 245         if(!pl)
 246         {
 247                 error("Trying to remove a player which is not in the playerlist!");
 248                 return;
 249         }
 250         parent.sort_next = player.sort_next;
 251         if(player.sort_next)
 252                 player.sort_next.sort_prev = parent;
 253         AuditLists();
 254 }
 255
 256 void MoveToLast(entity e)
 257 {
 258         AuditLists();
 259         entity ent = e.sort_next;
 260         while(ent)
 261         {
 262                 SORT_SWAP(ent, e);
 263                 ent = e.sort_next;
 264         }
 265         AuditLists();
 266 }
 267
 268 float RegisterTeam(entity Team)
 269 {
 270         assert_once(Team.team, eprint(Team));
 271         entity tm;
 272         AuditLists();
 273         for(tm = teams.sort_next; tm; tm = tm.sort_next)
 274                 if(tm == Team)
 275                         error("Team already registered!");
 276         Team.sort_next = teams.sort_next;
 277         Team.sort_prev = teams;
 278         if(teams.sort_next)
 279                 teams.sort_next.sort_prev = Team;
 280         teams.sort_next = Team;
 281         if(Team.team && Team.team != NUM_SPECTATOR)
 282                 ++team_count;
 283         AuditLists();
 284         return true;
 285 }
 286
 287 void RemoveTeam(entity Team)
 288 {
 289         entity tm, parent;
 290         AuditLists();
 291         parent = teams;
 292         for(tm = teams.sort_next; tm && tm != Team; tm = tm.sort_next)
 293                 parent = tm;
 294
 295         if(!tm)
 296         {
 297                 LOG_INFO(_("Trying to remove a team which is not in the teamlist!"));
 298                 return;
 299         }
 300         parent.sort_next = Team.sort_next;
 301         if(Team.sort_next)
 302                 Team.sort_next.sort_prev = parent;
 303         if(Team.team && Team.team != NUM_SPECTATOR)
 304                 --team_count;
 305         AuditLists();
 306 }
 307
 308 entity GetTeam(int Team, bool add)
 309 {
 310         TC(int, Team); TC(bool, add);
 311         int num = (Team == NUM_SPECTATOR) ? 16 : Team;
 312         if(teamslots[num])
 313                 return teamslots[num];
 314         if (!add)
 315                 return NULL;
 316         entity tm = new_pure(team);
 317         tm.team = Team;
 318         teamslots[num] = tm;
 319         RegisterTeam(tm);
 320         return tm;
 321 }
 322
 323 .float has_team;
 324 bool SetTeam(entity o, int Team)
 325 {
 326         TC(int, Team);
 327         //devassert_once(Team);
 328         entity tm;
 329         if(teamplay)
 330         {
 331                 switch(Team)
 332                 {
 333                         case -1:
 334                         case NUM_TEAM_1:
 335                         case NUM_TEAM_2:
 336                         case NUM_TEAM_3:
 337                         case NUM_TEAM_4:
 338                                 break;
 339                         default:
 340                                 if(GetTeam(Team, false) == NULL)
 341                                 {
 342                                         LOG_TRACEF("trying to switch to unsupported team %d", Team);
 343                                         Team = NUM_SPECTATOR;
 344                                 }
 345                                 break;
 346                 }
 347         }
 348         else
 349         {
 350                 switch(Team)
 351                 {
 352                         case -1:
 353                         case 0:
 354                                 break;
 355                         default:
 356                                 if(GetTeam(Team, false) == NULL)
 357                                 {
 358                                         LOG_TRACEF("trying to switch to unsupported team %d", Team);
 359                                         Team = NUM_SPECTATOR;
 360                                 }
 361                                 break;
 362                 }
 363         }
 364         if(Team == -1) // leave
 365         {
 366                 if(o.has_team)
 367                 {
 368                         tm = GetTeam(o.team, false);
 369                         tm.team_size -= 1;
 370                         o.has_team = 0;
 371                         return true;
 372                 }
 373         }
 374         else
 375         {
 376                 if (!o.has_team)
 377                 {
 378                         o.team = Team;
 379                         tm = GetTeam(Team, true);
 380                         tm.team_size += 1;
 381                         o.has_team = 1;
 382                         return true;
 383                 }
 384                 else if(Team != o.team)
 385                 {
 386                         tm = GetTeam(o.team, false);
 387                         tm.team_size -= 1;
 388                         o.team = Team;
 389                         tm = GetTeam(Team, true);
 390                         tm.team_size += 1;
 391                         return true;
 392                 }
 393         }
 394         return false;
 395 }
 396
 397 void Playerchecker_Think(entity this)
 398 {
 399         int i;
 400         entity e;
 401         for(i = 0; i < maxclients; ++i)
 402         {
 403                 e = playerslots[i];
 404                 if(entcs_GetName(i) == "")
 405                 {
 406                         if(e.sort_prev)
 407                         {
 408                                 // player disconnected
 409                                 SetTeam(e, -1);
 410                                 RemovePlayer(e);
 411                                 e.sort_prev = NULL;
 412                                 //e.gotscores = 0;
 413                         }
 414                 }
 415                 else
 416                 {
 417                         if (!e.sort_prev)
 418                         {
 419                                 // player connected
 420                                 if (!e)
 421                                 {
 422                                         playerslots[i] = e = new_pure(playerslot);
 423                                 }
 424                                 e.sv_entnum = i;
 425                                 e.ping = 0;
 426                                 e.ping_packetloss = 0;
 427                                 e.ping_movementloss = 0;
 428                                 //e.gotscores = 0; // we might already have the scores...
 429                                 int t = entcs_GetScoreTeam(i);
 430                                 if (t) SetTeam(e, t); // will not hurt; later updates come with Scoreboard_UpdatePlayerTeams
 431                                 RegisterPlayer(e);
 432                                 Scoreboard_UpdatePlayerPos(e);
 433                         }
 434                 }
 435         }
 436         this.nextthink = time + 0.2;
 437 }
 438
 439 void PostInit()
 440 {
 441         entity playerchecker = new_pure(playerchecker);
 442         setthink(playerchecker, Playerchecker_Think);
 443         playerchecker.nextthink = time + 0.2;
 444
 445         TrueAim_Init();
 446
 447         // this can't be called in CSQC_Init as it'd send cvars too early
 448         ReplicateVars_Start();
 449
 450         postinit = true;
 451 }
 452
 453 void Release_Common_Keys()
 454 {
 455         localcmd("-fire\n");
 456         localcmd("-fire2\n");
 457         localcmd("-use\n");
 458         localcmd("-hook\n");
 459         localcmd("-jump\n");
 460 }
 461
 462 // CSQC_InputEvent : Used to perform actions based on any key pressed, key released and mouse on the client.
 463 // Return value should be 1 if CSQC handled the input, otherwise return 0 to have the input passed to the engine.
 464 // All keys are in ascii.
 465 // bInputType = 0 is key pressed, 1 is key released, 2 and 3 are mouse input.
 466 // In the case of keyboard input, nPrimary is the ascii code, and nSecondary is 0.
 467 // In the case of mouse input, nPrimary is xdelta, nSecondary is ydelta.
 468 // In the case of mouse input after a setcursormode(1) call, nPrimary is xpos, nSecondary is ypos.
 469 float CSQC_InputEvent(int bInputType, float nPrimary, float nSecondary)
 470 {
 471         TC(int, bInputType);
 472         bool override = false;
 473
 474         override |= HUD_Scoreboard_InputEvent(bInputType, nPrimary, nSecondary);
 475         if (override)
 476                 return true;
 477
 478         override |= HUD_Panel_InputEvent(bInputType, nPrimary, nSecondary);
 479         if (override)
 480                 return true;
 481
 482         override |= HUD_Panel_Chat_InputEvent(bInputType, nPrimary, nSecondary);
 483
 484         override |= QuickMenu_InputEvent(bInputType, nPrimary, nSecondary);
 485
 486         override |= HUD_Radar_InputEvent(bInputType, nPrimary, nSecondary);
 487
 488         override |= MapVote_InputEvent(bInputType, nPrimary, nSecondary);
 489
 490         override |= HUD_Minigame_InputEvent(bInputType, nPrimary, nSecondary);
 491
 492         if(override)
 493                 return true;
 494
 495         if(bInputType == 3 || bInputType == 2)
 496                 return false;
 497
 498         // at this point bInputType can only be 0 or 1 (key pressed or released)
 499         bool key_pressed = (bInputType == 0);
 500
 501         if(key_pressed) {
 502                 if(nPrimary == K_ALT) hudShiftState |= S_ALT;
 503                 if(nPrimary == K_CTRL) hudShiftState |= S_CTRL;
 504                 if(nPrimary == K_SHIFT) hudShiftState |= S_SHIFT;
 505                 if(nPrimary == K_TAB) hudShiftState |= S_TAB;
 506         }
 507         else {
 508                 if(nPrimary == K_ALT) hudShiftState -= (hudShiftState & S_ALT);
 509                 if(nPrimary == K_CTRL) hudShiftState -= (hudShiftState & S_CTRL);
 510                 if(nPrimary == K_SHIFT) hudShiftState -= (hudShiftState & S_SHIFT);
 511                 if(nPrimary == K_TAB) hudShiftState -= (hudShiftState & S_TAB);
 512         }
 513
 514         // NOTE: Shift-Escape must be filtered out because it's the hardcoded console shortcut
 515         if (nPrimary == K_ESCAPE && !(hudShiftState & S_SHIFT) && key_pressed)
 516         {
 517                 if (hudShiftState & S_TAB)
 518                 {
 519                         Scoreboard_UI_Enable(0);
 520                         return true;
 521                 }
 522                 if (!isdemo() && cvar("_menu_gamemenu_dialog_available"))
 523                 {
 524                         localcmd("\nmenu_showgamemenudialog\n");
 525                         return true;
 526                 }
 527         }
 528
 529         return false;
 530 }
 531
 532 // END REQUIRED CSQC FUNCTIONS
 533 // --------------------------------------------------------------------------
 534
 535 // --------------------------------------------------------------------------
 536 // BEGIN OPTIONAL CSQC FUNCTIONS
 537
 538 void Ent_RemovePlayerScore(entity this)
 539 {
 540         if(this.owner) {
 541                 SetTeam(this.owner, -1);
 542                 this.owner.gotscores = 0;
 543                 FOREACH(Scores, true, {
 544                         this.owner.(scores(it)) = 0; // clear all scores
 545                 });
 546         }
 547 }
 548
 549 NET_HANDLE(ENT_CLIENT_SCORES, bool isnew)
 550 {
 551         make_pure(this);
 552         entity o;
 553
 554         // damnit -.- don't want to go change every single .sv_entnum in hud.qc AGAIN
 555         // (no I've never heard of M-x replace-string, sed, or anything like that)
 556         bool isNew = !this.owner; // workaround for DP bug
 557         int n = ReadByte()-1;
 558
 559 #ifdef DP_CSQC_ENTITY_REMOVE_IS_B0RKED
 560         if(!isNew && n != this.sv_entnum)
 561         {
 562                 //print("A CSQC entity changed its owner!\n");
 563                 LOG_INFOF("A CSQC entity changed its owner! (edict: %d, classname: %s)", etof(this), this.classname);
 564                 isNew = true;
 565                 Ent_Remove(this);
 566         }
 567 #endif
 568
 569         this.sv_entnum = n;
 570
 571         o = playerslots[this.sv_entnum];
 572         if (!o)
 573         {
 574                 o = playerslots[this.sv_entnum] = new_pure(playerslot);
 575         }
 576         this.owner = o;
 577         o.sv_entnum = this.sv_entnum;
 578         o.gotscores = 1;
 579
 580         //if (!o.sort_prev)
 581         //      RegisterPlayer(o);
 582         //playerchecker will do this for us later, if it has not already done so
 583
 584         int sf = ReadShort();
 585         int lf = ReadShort();
 586         FOREACH(Scores, true, {
 587                 int p = 1 << (i % 16);
 588                 if (sf & p)
 589                 {
 590                         if (lf & p)
 591                                 o.(scores(it)) = ReadInt24_t();
 592                         else
 593                                 o.(scores(it)) = ReadChar();
 594                 }
 595         });
 596
 597         return = true;
 598
 599         if(o.sort_prev)
 600                 Scoreboard_UpdatePlayerPos(o); // if not registered, we cannot do this yet!
 601
 602         this.entremove = Ent_RemovePlayerScore;
 603 }
 604
 605 NET_HANDLE(ENT_CLIENT_TEAMSCORES, bool isnew)
 606 {
 607         make_pure(this);
 608         int i;
 609
 610         this.team = ReadByte();
 611         entity o = this.owner = GetTeam(this.team, true); // these team numbers can always be trusted
 612
 613 #if MAX_TEAMSCORE <= 8
 614         int sf = ReadByte();
 615         int lf = ReadByte();
 616 #else
 617         int sf = ReadShort();
 618         int lf = ReadShort();
 619 #endif
 620         for(i = 0; i < MAX_TEAMSCORE; ++i)
 621                 if(sf & BIT(i))
 622                 {
 623                         if(lf & BIT(i))
 624                                 o.(teamscores(i)) = ReadInt24_t();
 625                         else
 626                                 o.(teamscores(i)) = ReadChar();
 627                 }
 628
 629         return = true;
 630
 631         Scoreboard_UpdateTeamPos(o);
 632 }
 633
 634 NET_HANDLE(ENT_CLIENT_CLIENTDATA, bool isnew)
 635 {
 636         make_pure(this);
 637         float newspectatee_status;
 638
 639         int f = ReadByte();
 640
 641         scoreboard_showscores_force = (f & BIT(0));
 642
 643         if(f & BIT(1))
 644         {
 645                 newspectatee_status = ReadByte();
 646                 if(newspectatee_status == player_localnum + 1)
 647                         newspectatee_status = -1; // observing
 648         }
 649         else
 650                 newspectatee_status = 0;
 651
 652         spectatorbutton_zoom = (f & BIT(2));
 653
 654         if(f & BIT(4))
 655         {
 656                 num_spectators = ReadByte();
 657
 658                 float i, slot;
 659
 660                 for(i = 0; i < MAX_SPECTATORS; ++i)
 661                         spectatorlist[i] = 0; // reset list first
 662
 663                 int limit = min(num_spectators, MAX_SPECTATORS);
 664                 for(i = 0; i < limit; ++i)
 665                 {
 666                         slot = ReadByte();
 667                         spectatorlist[i] = slot - 1;
 668                 }
 669         }
 670         else
 671         {
 672                 for(int j = 0; j < MAX_SPECTATORS; ++j)
 673                         spectatorlist[j] = 0; // reset list if showspectators has been turned off
 674                 num_spectators = 0;
 675         }
 676
 677         return = true;
 678
 679         if(newspectatee_status != spectatee_status)
 680         {
 681                 // clear race stuff
 682                 race_laptime = 0;
 683                 race_checkpointtime = 0;
 684                 hud_dynamic_shake_factor = -1;
 685                 spectatee_status_changed_time = time;
 686         }
 687         if (autocvar_hud_panel_healtharmor_progressbar_gfx)
 688         {
 689                 if ( (spectatee_status == -1 && newspectatee_status > 0) //before observing, now spectating
 690                   || (spectatee_status > 0 && newspectatee_status > 0 && spectatee_status != newspectatee_status) //changed spectated player
 691                 )
 692                         prev_p_health = -1;
 693                 else if(spectatee_status && !newspectatee_status) //before observing/spectating, now playing
 694                         prev_health = -1;
 695         }
 696         spectatee_status = newspectatee_status;
 697
 698         // we could get rid of spectatee_status, and derive it from player_localentnum and player_localnum
 699 }
 700
 701 NET_HANDLE(ENT_CLIENT_NAGGER, bool isnew)
 702 {
 703         make_pure(this);
 704         int i, j, b, f;
 705
 706         int nags = ReadByte(); // NAGS NAGS NAGS NAGS NAGS NAGS NADZ NAGS NAGS NAGS
 707
 708         if(!(nags & BIT(2)))
 709         {
 710                 strfree(vote_called_vote);
 711                 vote_active = 0;
 712         }
 713         else
 714         {
 715                 vote_active = 1;
 716         }
 717
 718         if(nags & BIT(6))
 719         {
 720                 vote_yescount = ReadByte();
 721                 vote_nocount = ReadByte();
 722                 vote_needed = ReadByte();
 723                 vote_highlighted = ReadChar();
 724         }
 725
 726         if(nags & BIT(7))
 727         {
 728                 strcpy(vote_called_vote, ReadString());
 729         }
 730
 731         if(nags & 1)
 732         {
 733                 for(j = 0; j < maxclients; ++j)
 734                         if(playerslots[j])
 735                                 playerslots[j].ready = true;
 736                 for(i = 1; i <= maxclients; i += 8)
 737                 {
 738                         f = ReadByte();
 739                         for(j = i-1, b = BIT(0); b < BIT(8); b <<= 1, ++j)
 740                                 if (!(f & b))
 741                                         if(playerslots[j])
 742                                                 playerslots[j].ready = false;
 743                 }
 744         }
 745
 746         return = true;
 747
 748         ready_waiting = (nags & BIT(0));
 749         ready_waiting_for_me = (nags & BIT(1));
 750         vote_waiting = (nags & BIT(2));
 751         vote_waiting_for_me = (nags & BIT(3));
 752         warmup_stage = (nags & BIT(4));
 753 }
 754
 755 NET_HANDLE(ENT_CLIENT_ELIMINATEDPLAYERS, bool isnew)
 756 {
 757         make_pure(this);
 758         int sf = 0;
 759         serialize(byte, 0, sf);
 760         if (sf & 1) {
 761                 for (int j = 0; j < maxclients; ++j) {
 762                         if (playerslots[j]) {
 763                                 playerslots[j].eliminated = true;
 764                         }
 765                 }
 766                 for (int i = 1; i <= maxclients; i += 8) {
 767                         int f = 0;
 768                         serialize(byte, 0, f);
 769                         for (int b = 0; b < 8; ++b) {
 770                                 if (f & BIT(b)) continue;
 771                                 int j = i - 1 + b;
 772                                 if (playerslots[j]) {
 773                                         playerslots[j].eliminated = false;
 774                                 }
 775                         }
 776                 }
 777         }
 778         return true;
 779 }
 780
 781 NET_HANDLE(ENT_CLIENT_RANDOMSEED, bool isnew)
 782 {
 783         make_pure(this);
 784         prandom_debug();
 785         float s = ReadShort();
 786         psrandom(s);
 787         return true;
 788 }
 789
 790 NET_HANDLE(ENT_CLIENT_ACCURACY, bool isnew)
 791 {
 792         make_pure(this);
 793         int sf = ReadInt24_t();
 794         if (sf == 0) {
 795                 for (int w = 0; w <= WEP_LAST - WEP_FIRST; ++w)
 796                         weapon_accuracy[w] = -1;
 797                 return true;
 798         }
 799
 800         int f = 1;
 801         for (int w = 0; w <= WEP_LAST - WEP_FIRST; ++w) {
 802                 if (sf & f) {
 803                         int b = ReadByte();
 804                         if (b == 0)
 805                                 weapon_accuracy[w] = -1;
 806                         else if (b == 255)
 807                                 weapon_accuracy[w] = 1.0; // no better error handling yet, sorry
 808                         else
 809                                 weapon_accuracy[w] = (b - 1.0) / 100.0;
 810                 }
 811                 f = (f == 0x800000) ? 1 : f * 2;
 812         }
 813         return true;
 814 }
 815
 816 void Spawn_Draw(entity this)
 817 {
 818         bool dodraw = autocvar_cl_spawn_point_particles;
 819         if(dodraw && autocvar_cl_spawn_point_dist_max)
 820         {
 821                 vector org = getpropertyvec(VF_ORIGIN);
 822                 dodraw = vdist(org - this.origin, <, autocvar_cl_spawn_point_dist_max);
 823         }
 824
 825         if(dodraw)
 826                 pointparticles(((!teamplay) ? EFFECT_SPAWNPOINT_NEUTRAL : EFFECT_SPAWNPOINT(this.team - 1)), this.origin + '0 0 28', '0 0 2', bound(0, frametime, 0.1));
 827 }
 828
 829 NET_HANDLE(ENT_CLIENT_SPAWNPOINT, bool is_new)
 830 {
 831         float teamnum = (ReadByte() - 1);
 832         vector spn_origin = ReadVector();
 833
 834         this.team = (teamnum + 1);
 835
 836         //if(is_new)
 837         //{
 838                 this.origin = spn_origin;
 839                 setsize(this, PL_MIN_CONST, PL_MAX_CONST);
 840                 //droptofloor();
 841
 842                 /*if(autocvar_cl_spawn_point_model) // needs a model first
 843                 {
 844                         this.mdl = "models/spawnpoint.md3";
 845                         this.colormod = Team_ColorRGB(teamnum);
 846                         precache_model(this.mdl);
 847                         setmodel(this, this.mdl);
 848                         this.drawmask = MASK_NORMAL;
 849                         //this.move_movetype = MOVETYPE_NOCLIP;
 850                         //this.draw = Spawn_Draw;
 851                         IL_PUSH(g_drawables, this);
 852                 }*/
 853                 this.draw = Spawn_Draw;
 854                 if (is_new) IL_PUSH(g_drawables, this);
 855         //}
 856
 857         //printf("Ent_ReadSpawnPoint(is_new = %d); origin = %s, team = %d, effect = %d\n", is_new, vtos(this.origin), teamnum, this.cnt);
 858         return true;
 859 }
 860
 861 NET_HANDLE(ENT_CLIENT_SPAWNEVENT, bool is_new)
 862 {
 863         // If entnum is 0, ONLY do the local spawn actions
 864         // this way the server can disable the sending of
 865         // spawn origin or such to clients if wanted.
 866         float entnum = ReadByte();
 867
 868         if(entnum)
 869         {
 870                 this.origin = ReadVector();
 871
 872                 if(is_new)
 873                 {
 874                         float teamnum = entcs_GetTeam(entnum - 1);
 875
 876                         if(autocvar_cl_spawn_event_particles)
 877                         {
 878                                 switch(teamnum)
 879                                 {
 880                                         case NUM_TEAM_1: pointparticles(EFFECT_SPAWN_RED, this.origin, '0 0 0', 1); break;
 881                                         case NUM_TEAM_2: pointparticles(EFFECT_SPAWN_BLUE, this.origin, '0 0 0', 1); break;
 882                                         case NUM_TEAM_3: pointparticles(EFFECT_SPAWN_YELLOW, this.origin, '0 0 0', 1); break;
 883                                         case NUM_TEAM_4: pointparticles(EFFECT_SPAWN_PINK, this.origin, '0 0 0', 1); break;
 884                                         default: pointparticles(EFFECT_SPAWN_NEUTRAL, this.origin, '0 0 0', 1); break;
 885                                 }
 886                         }
 887                         if(autocvar_cl_spawn_event_sound)
 888                         {
 889                                 sound(this, CH_TRIGGER, SND_SPAWN, VOL_BASE, ATTEN_NORM);
 890                         }
 891                 }
 892         }
 893         return = true;
 894
 895         // local spawn actions
 896         if(is_new && (!entnum || (entnum == player_localentnum)))
 897         {
 898                 if(autocvar_cl_spawnzoom && !autocvar_cl_lockview)
 899                 {
 900                         zoomin_effect = 1;
 901                         current_viewzoom = (1 / bound(1, autocvar_cl_spawnzoom_factor, 16));
 902                 }
 903
 904                 if(autocvar_cl_unpress_zoom_on_spawn)
 905                 {
 906                         localcmd("-zoom\n");
 907                         button_zoom = false;
 908                 }
 909                 HUD_Radar_Hide_Maximized();
 910         }
 911         //printf("Ent_ReadSpawnEvent(is_new = %d); origin = %s, entnum = %d, localentnum = %d\n", is_new, vtos(this.origin), entnum, player_localentnum);
 912 }
 913
 914 // CSQC_Ent_Update : Called every frame that the server has indicated an update to the SSQC / CSQC entity has occured.
 915 // The parameter isnew reflects if the entity is "new" to the client, meaning it just came into the client's PVS.
 916 void CSQC_Ent_Update(entity this, bool isnew)
 917 {
 918         this.sourceLoc = __FILE__":"STR(__LINE__);
 919         int t = ReadByte();
 920
 921         // set up the "time" global for received entities to be correct for interpolation purposes
 922         float savetime = time;
 923         if(servertime)
 924         {
 925                 time = servertime;
 926         }
 927         else
 928         {
 929                 serverprevtime = time;
 930                 serverdeltatime = STAT(MOVEVARS_TICRATE) * STAT(MOVEVARS_TIMESCALE);
 931                 time = serverprevtime + serverdeltatime;
 932         }
 933
 934 #ifdef DP_CSQC_ENTITY_REMOVE_IS_B0RKED
 935         if (this.enttype)
 936         {
 937                 if (t != this.enttype || isnew)
 938                 {
 939                         LOG_INFOF("A CSQC entity changed its type! (edict: %d, server: %d, type: %d -> %d)", etof(this), this.entnum, this.enttype, t);
 940                         Ent_Remove(this);
 941                         ONREMOVE(this);
 942                         clearentity(this);
 943                         isnew = true;
 944                 }
 945         }
 946         else
 947         {
 948                 if (!isnew)
 949                 {
 950                         LOG_INFOF("A CSQC entity appeared out of nowhere! (edict: %d, server: %d, type: %d)", etof(this), this.entnum, t);
 951                         isnew = true;
 952                 }
 953         }
 954 #endif
 955         this.enttype = t;
 956         bool done = false;
 957         FOREACH(LinkedEntities, it.m_id == t, {
 958                 if (isnew) this.classname = it.netname;
 959                 if (autocvar_developer_csqcentities)
 960                         LOG_INFOF("CSQC_Ent_Update(%i, %d) at %f {.entnum=%d, .enttype=%d} t=%s (%d)", this, isnew, savetime, this.entnum, this.enttype, this.classname, t);
 961                 done = it.m_read(this, NULL, isnew);
 962                 MUTATOR_CALLHOOK(Ent_Update, this, isnew);
 963                 break;
 964         });
 965         time = savetime;
 966         if (!done)
 967         {
 968                 LOG_FATALF("CSQC_Ent_Update(%i, %d) at %f {.entnum=%d, .enttype=%d} t=%s (%d)", this, isnew, savetime, this.entnum, this.enttype, this.classname, t);
 969         }
 970 }
 971
 972 // Destructor, but does NOT deallocate the entity by calling remove(). Also
 973 // used when an entity changes its type. For an entity that someone interacts
 974 // with others, make sure it can no longer do so.
 975 void Ent_Remove(entity this)
 976 {
 977         if(this.entremove) this.entremove(this);
 978
 979         if(this.skeletonindex)
 980         {
 981                 skel_delete(this.skeletonindex);
 982                 this.skeletonindex = 0;
 983         }
 984
 985         if(this.snd_looping > 0)
 986         {
 987                 sound(this, this.snd_looping, SND_Null, VOL_BASE, autocvar_cl_jetpack_attenuation);
 988                 this.snd_looping = 0;
 989         }
 990
 991         this.enttype = 0;
 992         this.classname = "";
 993         this.draw = func_null;
 994         this.entremove = func_null;
 995         // TODO possibly set more stuff to defaults
 996 }
 997 // CSQC_Ent_Remove : Called when the server requests a SSQC / CSQC entity to be removed.  Essentially call remove(this) as well.
 998 void CSQC_Ent_Remove(entity this)
 999 {
1000         if (autocvar_developer_csqcentities) LOG_INFOF("CSQC_Ent_Remove() with this=%i {.entnum=%d, .enttype=%d}", this, this.entnum, this.enttype);
1001         if (wasfreed(this))
1002         {
1003                 LOG_WARN("CSQC_Ent_Remove called for already removed entity. Packet loss?");
1004                 return;
1005         }
1006         if (this.enttype) Ent_Remove(this);
1007         delete(this);
1008 }
1009
1010 void Gamemode_Init()
1011 {
1012         if (!isdemo())
1013         {
1014                 if(!(calledhooks & HOOK_START))
1015                         localcmd("\n_cl_hook_gamestart ", MapInfo_Type_ToString(gametype), "\n");
1016                 calledhooks |= HOOK_START;
1017         }
1018 }
1019 // CSQC_Parse_StuffCmd : Provides the stuffcmd string in the first parameter that the server provided.  To execute standard behavior, simply execute localcmd with the string.
1020 void CSQC_Parse_StuffCmd(string strMessage)
1021 {
1022         if (autocvar_developer_csqcentities) LOG_INFOF("CSQC_Parse_StuffCmd(\"%s\")", strMessage);
1023         localcmd(strMessage);
1024 }
1025 // CSQC_Parse_Print : Provides the print string in the first parameter that the server provided.  To execute standard behavior, simply execute print with the string.
1026 void CSQC_Parse_Print(string strMessage)
1027 {
1028         if (autocvar_developer_csqcentities) LOG_INFOF("CSQC_Parse_Print(\"%s\")", strMessage);
1029         print(ColorTranslateRGB(strMessage));
1030 }
1031
1032 // CSQC_Parse_CenterPrint : Provides the centerprint_AddStandard string in the first parameter that the server provided.
1033 void CSQC_Parse_CenterPrint(string strMessage)
1034 {
1035         if (autocvar_developer_csqcentities) LOG_INFOF("CSQC_Parse_CenterPrint(\"%s\")", strMessage);
1036         centerprint_AddStandard(strMessage);
1037 }
1038
1039 // CSQC_Parse_TempEntity : Handles all temporary entity network data in the CSQC layer.
1040 // You must ALWAYS first acquire the temporary ID, which is sent as a byte.
1041 // Return value should be 1 if CSQC handled the temporary entity, otherwise return 0 to have the engine process the event.
1042 bool CSQC_Parse_TempEntity()
1043 {
1044         // Acquire TE ID
1045         int nTEID = ReadByte();
1046
1047         FOREACH(TempEntities, it.m_id == nTEID, {
1048                 if (autocvar_developer_csqcentities)
1049                         LOG_INFOF("CSQC_Parse_TempEntity() nTEID=%s (%d)", it.netname, nTEID);
1050                 return it.m_read(NULL, NULL, true);
1051         });
1052
1053         if (autocvar_developer_csqcentities)
1054                 LOG_INFOF("CSQC_Parse_TempEntity() with nTEID=%d", nTEID);
1055
1056         // No special logic for this temporary entity; return 0 so the engine can handle it
1057         return false;
1058 }
1059
1060 string forcefog;
1061 void Fog_Force()
1062 {
1063         if (autocvar_cl_orthoview && autocvar_cl_orthoview_nofog)
1064                 localcmd("\nr_drawfog 0\n");
1065         else if (forcefog != "")
1066                 localcmd(sprintf("\nfog %s\nr_fog_exp2 0\nr_drawfog 1\n", forcefog));
1067 }
1068
1069 bool net_handle_ServerWelcome();
1070 NET_HANDLE(ENT_CLIENT_SCORES_INFO, bool isnew)
1071 {
1072         make_pure(this);
1073         gametype = ReadRegistered(Gametypes);
1074         teamplay = _MapInfo_GetTeamPlayBool(gametype);
1075         HUD_ModIcons_SetFunc();
1076         FOREACH(Scores, true, {
1077                 strcpy(scores_label(it), ReadString());
1078                 scores_flags(it) = ReadByte();
1079         });
1080         for (int i = 0; i < MAX_TEAMSCORE; ++i)
1081         {
1082                 strcpy(teamscores_label(i), ReadString());
1083                 teamscores_flags(i) = ReadByte();
1084         }
1085         bool welcome_msg_too = ReadByte();
1086         if (welcome_msg_too)
1087                 net_handle_ServerWelcome();
1088         return = true;
1089         Scoreboard_InitScores();
1090         Gamemode_Init();
1091 }
1092
1093 NET_HANDLE(ENT_CLIENT_INIT, bool isnew)
1094 {
1095         nb_pb_period = ReadByte() / 32; //Accuracy of 1/32th
1096
1097         hook_shotorigin[0] = decompressShotOrigin(ReadInt24_t());
1098         hook_shotorigin[1] = decompressShotOrigin(ReadInt24_t());
1099         hook_shotorigin[2] = decompressShotOrigin(ReadInt24_t());
1100         hook_shotorigin[3] = decompressShotOrigin(ReadInt24_t());
1101         arc_shotorigin[0] = decompressShotOrigin(ReadInt24_t());
1102         arc_shotorigin[1] = decompressShotOrigin(ReadInt24_t());
1103         arc_shotorigin[2] = decompressShotOrigin(ReadInt24_t());
1104         arc_shotorigin[3] = decompressShotOrigin(ReadInt24_t());
1105
1106         strcpy(forcefog, ReadString());
1107
1108         armorblockpercent = ReadByte() / 255.0;
1109         damagepush_speedfactor = ReadByte() / 255.0;
1110
1111         serverflags = ReadByte();
1112
1113         g_trueaim_minrange = ReadCoord();
1114
1115         return = true;
1116
1117         MUTATOR_CALLHOOK(Ent_Init);
1118
1119         if (!postinit) PostInit();
1120 }
1121
1122 float GetSpeedUnitFactor(int speed_unit)
1123 {
1124         switch(speed_unit)
1125         {
1126                 default:
1127                 case 1: return 1.0;
1128                 case 2: return 0.0254;
1129                 case 3: return 0.0254 * 3.6;
1130                 case 4: return 0.0254 * 3.6 * 0.6213711922;
1131                 case 5: return 0.0254 * 1.943844492; // 1 m/s = 1.943844492 knots, because 1 knot = 1.852 km/h
1132         }
1133 }
1134
1135 string GetSpeedUnit(int speed_unit)
1136 {
1137         switch(speed_unit)
1138         {
1139                 // translator-friendly strings without the initial space
1140                 default:
1141                 case 1: return strcat(" ", _("qu/s"));
1142                 case 2: return strcat(" ", _("m/s"));
1143                 case 3: return strcat(" ", _("km/h"));
1144                 case 4: return strcat(" ", _("mph"));
1145                 case 5: return strcat(" ", _("knots"));
1146         }
1147 }
1148
1149 NET_HANDLE(TE_CSQC_RACE, bool isNew)
1150 {
1151         int b = ReadByte();
1152
1153         switch (b)
1154         {
1155                 case RACE_NET_CHECKPOINT_HIT_QUALIFYING:
1156                         race_checkpoint = ReadByte();
1157                         race_time = ReadInt24_t();
1158                         race_previousbesttime = ReadInt24_t();
1159                         race_mypreviousbesttime = ReadInt24_t();
1160                         string pbestname = ReadString();
1161                         if(autocvar_cl_race_cptimes_onlyself)
1162                         {
1163                                 race_previousbesttime = race_mypreviousbesttime;
1164                                 race_mypreviousbesttime = 0;
1165                                 strcpy(race_previousbestname, "");
1166                         }
1167                         else
1168                                 strcpy(race_previousbestname, pbestname);
1169
1170                         race_checkpointtime = time;
1171
1172                         if(race_checkpoint == 0 || race_checkpoint == 254)
1173                         {
1174                                 race_penaltyaccumulator = 0;
1175                                 race_laptime = time; // valid
1176                         }
1177                         break;
1178
1179                 case RACE_NET_CHECKPOINT_CLEAR:
1180                         race_laptime = 0;
1181                         race_checkpointtime = 0;
1182                         break;
1183
1184                 case RACE_NET_CHECKPOINT_NEXT_SPEC_QUALIFYING:
1185                         race_laptime = ReadCoord();
1186                         race_checkpointtime = -99999;
1187                         // fall through
1188                 case RACE_NET_CHECKPOINT_NEXT_QUALIFYING:
1189                         race_nextcheckpoint = ReadByte();
1190
1191                         race_nextbesttime = ReadInt24_t();
1192                         if(b != RACE_NET_CHECKPOINT_NEXT_SPEC_QUALIFYING) // not while spectating (matches server)
1193                                 race_mybesttime = ReadInt24_t();
1194                         string newname = ReadString();
1195                         if(autocvar_cl_race_cptimes_onlyself && b != RACE_NET_CHECKPOINT_NEXT_SPEC_QUALIFYING)
1196                         {
1197                                 race_nextbesttime = race_mybesttime;
1198                                 race_mybesttime = 0;
1199                                 strcpy(race_nextbestname, "");
1200                         }
1201                         else
1202                                 strcpy(race_nextbestname, newname);
1203                         break;
1204
1205                 case RACE_NET_CHECKPOINT_HIT_RACE:
1206                         race_mycheckpoint = ReadByte();
1207                         race_mycheckpointtime = time;
1208                         race_mycheckpointdelta = ReadInt24_t();
1209                         race_mycheckpointlapsdelta = ReadByte();
1210                         if(race_mycheckpointlapsdelta >= 128)
1211                                 race_mycheckpointlapsdelta -= 256;
1212                         int who = ReadByte();
1213                         if(who)
1214                                 strcpy(race_mycheckpointenemy, entcs_GetName(who - 1));
1215                         else
1216                                 strcpy(race_mycheckpointenemy, ""); // TODO: maybe string_null works fine here?
1217                         break;
1218
1219                 case RACE_NET_CHECKPOINT_HIT_RACE_BY_OPPONENT:
1220                         race_othercheckpoint = ReadByte();
1221                         race_othercheckpointtime = time;
1222                         race_othercheckpointdelta = ReadInt24_t();
1223                         race_othercheckpointlapsdelta = ReadByte();
1224                         if(race_othercheckpointlapsdelta >= 128)
1225                                 race_othercheckpointlapsdelta -= 256;
1226                         int what = ReadByte();
1227                         if(what)
1228                                 strcpy(race_othercheckpointenemy, entcs_GetName(what - 1));
1229                         else
1230                                 strcpy(race_othercheckpointenemy, ""); // TODO: maybe string_null works fine here?
1231                         break;
1232
1233                 case RACE_NET_PENALTY_RACE:
1234                 case RACE_NET_PENALTY_QUALIFYING:
1235                         race_penaltyeventtime = time;
1236                         race_penaltytime = ReadShort();
1237                         string reason = ReadString();
1238                         if (reason == "missing a checkpoint")
1239                                 reason = _("missing a checkpoint");
1240                         strcpy(race_penaltyreason, reason);
1241                         if (b == RACE_NET_PENALTY_QUALIFYING)
1242                                 race_penaltyaccumulator += race_penaltytime;
1243                         break;
1244
1245                 case RACE_NET_SERVER_RECORD:
1246                         race_server_record = ReadInt24_t();
1247                         break;
1248                 case RACE_NET_SPEED_AWARD:
1249                         race_speedaward = ReadInt24_t() * GetSpeedUnitFactor(autocvar_hud_panel_physics_speed_unit);
1250                         strcpy(race_speedaward_holder, ReadString());
1251                         break;
1252                 case RACE_NET_SPEED_AWARD_BEST:
1253                         race_speedaward_alltimebest = ReadInt24_t() * GetSpeedUnitFactor(autocvar_hud_panel_physics_speed_unit);
1254                         strcpy(race_speedaward_alltimebest_holder, ReadString());
1255                         break;
1256                 case RACE_NET_RANKINGS_CNT:
1257                         RANKINGS_DISPLAY_CNT = ReadByte();
1258                         break;
1259                 case RACE_NET_SERVER_RANKINGS:
1260                         float prevpos, del;
1261                         int pos = ReadShort();
1262                         prevpos = ReadShort();
1263                         del = ReadShort();
1264
1265                         // move other rankings out of the way
1266                         int i;
1267                         if (prevpos) {
1268                                 int m = min(prevpos, RANKINGS_DISPLAY_CNT);
1269                                 for (i=m-1; i>pos-1; --i) {
1270                                         grecordtime[i] = grecordtime[i-1];
1271                                         strcpy(grecordholder[i], grecordholder[i-1]);
1272                                 }
1273                         } else if (del) { // a record has been deleted by the admin
1274                                 for (i=pos-1; i<= RANKINGS_DISPLAY_CNT-1; ++i) {
1275                                         if (i == RANKINGS_DISPLAY_CNT-1) { // clear out last record
1276                                                 grecordtime[i] = 0;
1277                                                 strfree(grecordholder[i]);
1278                                         }
1279                                         else {
1280                                                 grecordtime[i] = grecordtime[i+1];
1281                                                 strcpy(grecordholder[i], grecordholder[i+1]);
1282                                         }
1283                                 }
1284                         } else { // player has no ranked record yet
1285                                 for (i=RANKINGS_DISPLAY_CNT-1;i>pos-1;--i) {
1286                                         grecordtime[i] = grecordtime[i-1];
1287                                         strcpy(grecordholder[i], grecordholder[i-1]);
1288                                 }
1289                         }
1290
1291                         if (grecordtime[RANKINGS_DISPLAY_CNT]) {
1292                                 // kick off the player who fell from the last displayed position
1293                                 grecordtime[RANKINGS_DISPLAY_CNT] = 0;
1294                                 strfree(grecordholder[RANKINGS_DISPLAY_CNT]);
1295                         }
1296
1297                         // store new ranking
1298                         strcpy(grecordholder[pos-1], ReadString());
1299                         grecordtime[pos-1] = ReadInt24_t();
1300                         if(strdecolorize(grecordholder[pos-1]) == strdecolorize(entcs_GetName(player_localnum)))
1301                                 race_myrank = pos;
1302                         break;
1303                 case RACE_NET_SERVER_STATUS:
1304                         race_status = ReadShort();
1305                         strcpy(race_status_name, ReadString());
1306         }
1307         return true;
1308 }
1309
1310 NET_HANDLE(TE_CSQC_TEAMNAGGER, bool isNew)
1311 {
1312         teamnagger = 1;
1313         return true;
1314 }
1315
1316 NET_HANDLE(TE_CSQC_PINGPLREPORT, bool isNew)
1317 {
1318         int i = ReadByte();
1319         int pi = ReadShort();
1320         int pl = ReadByte();
1321         int ml = ReadByte();
1322         return = true;
1323         entity e = playerslots[i];
1324         if (!e) return;
1325         e.ping = pi;
1326         e.ping_packetloss = pl / 255.0;
1327         e.ping_movementloss = ml / 255.0;
1328 }
1329
1330 NET_HANDLE(TE_CSQC_WEAPONCOMPLAIN, bool isNew)
1331 {
1332         int weapon_id = ReadByte();
1333         complain_weapon = REGISTRY_GET(Weapons, weapon_id);
1334         complain_weapon_type = ReadByte();
1335         return = true;
1336
1337         complain_weapon_time = time;
1338         weapontime = time; // ping the weapon panel
1339
1340         switch(complain_weapon_type)
1341         {
1342                 case 0: Local_Notification(MSG_MULTI, ITEM_WEAPON_NOAMMO, weapon_id); break;
1343                 case 1: Local_Notification(MSG_MULTI, ITEM_WEAPON_DONTHAVE, weapon_id); break;
1344                 default: Local_Notification(MSG_MULTI, ITEM_WEAPON_UNAVAILABLE, weapon_id); break;
1345         }
1346 }
1347
1348 string translate_modifications(string s)
1349 {
1350         return build_mutator_list(s);
1351 }
1352
1353 string translate_weaponarena(string s)
1354 {
1355         if (s == "") return s;
1356         if (s == "All Weapons Arena") return _("All Weapons Arena");
1357         if (s == "All Available Weapons Arena") return _("All Available Weapons Arena");
1358         if (s == "Most Weapons Arena") return _("Most Weapons Arena");
1359         if (s == "Most Available Weapons Arena") return _("Most Available Weapons Arena");
1360         if (s == "Dev All Weapons Arena") return s; // development option, do not translate
1361         if (s == "Dev All Available Weapons Arena") return s; // development option, do not translate
1362         if (s == "No Weapons Arena") return _("No Weapons Arena");
1363
1364         int n = tokenizebyseparator(s, " & ");
1365         string wpn_list = "";
1366         for (int i = 0; i < n; i++)
1367         {
1368                 Weapon wep = Weapon_from_name(argv(i));
1369                 if (wep == WEP_Null)
1370                         LOG_INFO("^3Warning: ^7server sent an invalid weapon name\n");
1371                 wpn_list = cons_mid(wpn_list, " & ", wep.m_name);
1372         }
1373         if (wpn_list != "")
1374                 return sprintf(_("%s Arena"), wpn_list);
1375         else
1376                 return _("No Weapons Arena");
1377 }
1378
1379 string GetVersionMessage(string hostversion, bool version_mismatch, bool version_check)
1380 {
1381         string xonotic_hostversion = strcat("Xonotic ", hostversion);
1382         if (version_mismatch)
1383         {
1384                 if(!version_check)
1385                         return strcat(sprintf(_("This is %s"), xonotic_hostversion), "\n^3",
1386                                 _("Your client version is outdated."), "\n\n\n",
1387                                 _("### YOU WON'T BE ABLE TO PLAY ON THIS SERVER ###"), "\n\n\n",
1388                                 _("Please update!"));
1389                 else
1390                         return strcat(sprintf(_("This is %s"), xonotic_hostversion), "\n^3",
1391                                 _("This server is using an outdated Xonotic version."), "\n\n\n",
1392                                 _("### THIS SERVER IS INCOMPATIBLE AND THUS YOU CANNOT JOIN ###"));
1393         }
1394         return sprintf(_("Welcome to %s"), xonotic_hostversion);
1395 }
1396
1397 bool net_handle_ServerWelcome()
1398 {
1399         bool campaign = ReadByte();
1400         if (campaign)
1401         {
1402                 string campaign_title = ReadString();
1403                 int campaign_level = ReadByte();
1404                 string campaign_msg = ReadString();
1405                 string welcomedialog_args;
1406                 welcomedialog_args = strcat("HOSTNAME \"", campaign_title, "\"");
1407                 string key = getcommandkey(_("jump"), "+jump");
1408                 string msg = strcat(
1409                         CCR("^F1"), sprintf(_("Level %d:"), campaign_level),
1410                         sprintf(CCR(" ^BG%s\n^3\n"), campaign_msg),
1411                         sprintf(CCR(_("^BGPress ^F2%s^BG to enter the game")), key));
1412                 msg = MakeConsoleSafe(strreplace("\n", "\\n", msg));
1413                 welcomedialog_args = strcat(welcomedialog_args, " WELCOME \"", msg, "\"");
1414                 localcmd("\nmenu_cmd directmenu Welcome ", welcomedialog_args, "\n");
1415                 return true;
1416         }
1417
1418         strcpy(hostname, ReadString());
1419
1420         string hostversion = ReadString();
1421         bool version_mismatch = ReadByte();
1422         bool version_check = ReadByte();
1423         string ver = GetVersionMessage(hostversion, version_mismatch, version_check);
1424
1425         string modifications = translate_modifications(ReadString());
1426         string weaponarena_list = translate_weaponarena(ReadString());
1427         string cache_mutatormsg = ReadString();
1428         string motd = ReadString();
1429
1430         string msg = "";
1431         msg = strcat(msg, ver);
1432         msg = strcat(msg, "^8\n\n", strcat(_("Gametype:"), " ^1", MapInfo_Type_ToText(gametype)), "^8\n");
1433
1434         modifications = cons_mid(modifications, ", ", weaponarena_list);
1435         if(modifications != "")
1436                 msg = strcat(msg, "^8\n", _("Active modifications:"), " ^3", modifications, "^8\n");
1437
1438         if (cache_mutatormsg != "")
1439                 msg = strcat(msg, "\n\n^8", _("Special gameplay tips:"), " ^7", cache_mutatormsg);
1440         string mutator_msg = "";
1441         MUTATOR_CALLHOOK(BuildGameplayTipsString, mutator_msg);
1442         mutator_msg = M_ARGV(0, string);
1443         msg = strcat(msg, mutator_msg); // trust that the mutator will do proper formatting
1444
1445         if (motd != "")
1446                 msg = strcat(msg, "\n\n^8", _("MOTD:"), " ^7", motd);
1447
1448         strcpy(welcome_msg, msg);
1449         welcome_msg_menu_check_maxtime = time + 1; // wait for menu to load before showing the welcome dialog
1450         return true;
1451 }
1452
1453 void Welcome_Message_Show_Try()
1454 {
1455         if (!welcome_msg_menu_check_maxtime)
1456                 return;
1457
1458         // if want dialog check if menu is initialized but for a short time
1459         if (cvar("_menu_initialized") == 2 || time > welcome_msg_menu_check_maxtime)
1460         {
1461                 if (cvar("_menu_welcome_dialog_available"))
1462                 {
1463                         string welcomedialog_args = strcat("HOSTNAME \"", hostname, "\"");
1464                         string msg = MakeConsoleSafe(strreplace("\n", "\\n", welcome_msg));
1465                         welcomedialog_args = strcat(welcomedialog_args, " WELCOME \"", msg, "\"");
1466                         localcmd("\nmenu_cmd directmenu Welcome ", welcomedialog_args, "\n");
1467                         if (intermission || isdemo() || !autocvar_cl_welcome)
1468                                 // close it after it's been initialized so it can still be opened manually
1469                                 localcmd("\ntogglemenu 0\n");
1470                 }
1471
1472                 strfree(welcome_msg);
1473                 welcome_msg_menu_check_maxtime = 0;
1474         }
1475 }
1476
1477 NET_HANDLE(TE_CSQC_SERVERWELCOME, bool isNew)
1478 {
1479         return net_handle_ServerWelcome();
1480 }
1481
1482 string _getcommandkey(string cmd_name, string command, bool forcename)
1483 {
1484         string keys;
1485         float n, j, k, l = 0;
1486
1487         if (!autocvar_hud_showbinds)
1488                 return cmd_name;
1489
1490         keys = db_get(binddb, command);
1491         if (keys == "")
1492         {
1493                 bool joy_active = cvar("joy_active");
1494                 n = tokenize(findkeysforcommand(command, 0)); // uses '...' strings
1495                 for(j = 0; j < n; ++j)
1496                 {
1497                         k = stof(argv(j));
1498                         if(k != -1)
1499                         {
1500                                 string key = keynumtostring(k);
1501                                 if(!joy_active && substring(key, 0, 3) == "JOY")
1502                                         continue;
1503
1504                                 key = translate_key(key);
1505
1506                                 if (keys == "")
1507                                         keys = key;
1508                                 else
1509                                         keys = strcat(keys, ", ", key);
1510
1511                                 ++l;
1512                                 if (autocvar_hud_showbinds_limit > 0 && autocvar_hud_showbinds_limit <= l)
1513                                         break;
1514                         }
1515
1516                 }
1517                 if (keys == "")
1518                         keys = "NO_KEY";
1519                 db_put(binddb, command, keys);
1520         }
1521
1522         if (keys == "NO_KEY") {
1523                 if (autocvar_hud_showbinds > 1)
1524                         return sprintf(_("%s (not bound)"), cmd_name);
1525                 else
1526                         return cmd_name;
1527         }
1528         else if (autocvar_hud_showbinds > 1 || forcename)
1529                 return sprintf("%s (%s)", cmd_name, keys);
1530         else
1531                 return keys;
1532 }
1533
1534 /** engine callback */
1535 void URI_Get_Callback(int id, int status, string data)
1536 {
1537         TC(int, id); TC(int, status);
1538         if(url_URI_Get_Callback(id, status, data))
1539         {
1540                 // handled
1541         }
1542         else if (id == URI_GET_DISCARD)
1543         {
1544                 // discard
1545         }
1546         else if (id >= URI_GET_CURL && id <= URI_GET_CURL_END)
1547         {
1548                 // sv_cmd curl
1549                 Curl_URI_Get_Callback(id, status, data);
1550         }
1551         else
1552         {
1553                 LOG_INFOF("Received HTTP request data for an invalid id %d.", id);
1554         }
1555 }