qcsrc/client/main.qc

   1 #include "main.qh"
   2
   3 #include <client/command/cl_cmd.qh>
   4 #include <client/draw.qh>
   5 #include <client/hud/_mod.qh>
   6 #include <client/hud/panel/centerprint.qh>
   7 #include <client/hud/panel/quickmenu.qh>
   8 #include <client/hud/panel/scoreboard.qh>
   9 #include <client/items/items.qh>
  10 #include <client/mapvoting.qh>
  11 #include <client/mutators/_mod.qh>
  12 #include <client/shownames.qh>
  13 #include <client/view.qh>
  14 #include <client/weapons/projectile.qh>
  15 #include <common/deathtypes/all.qh>
  16 #include <common/effects/all.inc>
  17 #include <common/effects/all.qh>
  18 #include <common/effects/effect.qh>
  19 #include <common/effects/qc/_mod.qh>
  20 #include <common/ent_cs.qh>
  21 #include <common/gamemodes/gamemode/nexball/cl_nexball.qh>
  22 #include <common/items/_mod.qh>
  23 #include <common/mapinfo.qh>
  24 #include <common/mapobjects/_mod.qh>
  25 #include <common/minigames/cl_minigames.qh>
  26 #include <common/minigames/cl_minigames_hud.qh>
  27 #include <common/net_linked.qh>
  28 #include <common/net_notice.qh>
  29 #include <common/scores.qh>
  30 #include <common/vehicles/all.qh>
  31 #include <lib/csqcmodel/cl_model.qh>
  32 #include <lib/csqcmodel/interpolate.qh>
  33 #include <lib/warpzone/client.qh>
  34
  35 // --------------------------------------------------------------------------
  36 // BEGIN REQUIRED CSQC FUNCTIONS
  37 //include "main.qh"
  38
  39 #define DP_CSQC_ENTITY_REMOVE_IS_B0RKED
  40
  41 // CSQC_Init : Called every time the CSQC code is initialized (essentially at map load)
  42 // Useful for precaching things
  43
  44 void CSQC_Init()
  45 {
  46         prvm_language = strzone(cvar_string("prvm_language"));
  47
  48 #ifdef WATERMARK
  49         LOG_TRACEF("^4CSQC Build information: ^1%s", WATERMARK);
  50 #endif
  51
  52         {
  53                 int i = 0;
  54                 for ( ; i < 255; ++i)
  55                         if (getplayerkeyvalue(i, "viewentity") == "")
  56                                 break;
  57                 maxclients = i;
  58         }
  59
  60         // needs to be done so early because of the constants they create
  61         static_init();
  62         static_init_late();
  63         static_init_precache();
  64
  65         binddb = db_create();
  66         tempdb = db_create();
  67         ClientProgsDB = db_load("client.db");
  68
  69         draw_endBoldFont();
  70
  71         //registercommand("hud_configure");
  72         //registercommand("hud_save");
  73         //registercommand("menu_action");
  74
  75         ConsoleCommand_macro_init();
  76
  77         registercvar("hud_usecsqc", "1");
  78         registercvar("scoreboard_columns", "default");
  79
  80         registercvar("cl_nade_type", "3");
  81         registercvar("cl_pokenade_type", "zombie");
  82
  83         registercvar("cl_jumpspeedcap_min", "");
  84         registercvar("cl_jumpspeedcap_max", "");
  85
  86         registercvar("cl_shootfromfixedorigin", "");
  87
  88         registercvar("cl_multijump", "-1");
  89
  90         registercvar("cl_dodging", "0");
  91
  92         registercvar("cl_spawn_near_teammate", "1");
  93
  94         registercvar("cl_weapon_switch_reload", "1");
  95         registercvar("cl_weapon_switch_fallback_to_impulse", "1");
  96
  97         registercvar("cl_allow_uidranking", "1");
  98
  99         if(autocvar_cl_lockview)
 100                 cvar_set("cl_lockview", "0");
 101
 102         gametype = NULL;
 103
 104         postinit = false;
 105
 106         calledhooks = 0;
 107
 108         teams = Sort_Spawn();
 109         players = Sort_Spawn();
 110
 111         GetTeam(NUM_SPECTATOR, true); // add specs first
 112
 113         for (int w = 0; w <= WEP_LAST - WEP_FIRST; ++w)
 114                 weapon_accuracy[w] = -1;
 115
 116         // precaches
 117
 118         if(autocvar_cl_reticle)
 119         {
 120                 precache_pic("gfx/reticle_normal");
 121                 // weapon reticles are precached in weapon files
 122         }
 123
 124         {
 125                 get_mi_min_max_texcoords(1); // try the CLEVER way first
 126                 minimapname = strcat("gfx/", mi_shortname, "_radar");
 127                 shortmapname = mi_shortname;
 128
 129                 if (precache_pic(minimapname) == "")
 130                 {
 131                         // but maybe we have a non-clever minimap
 132                         minimapname = strcat("gfx/", mi_shortname, "_mini");
 133                         if (precache_pic(minimapname) == "")
 134                                 minimapname = ""; // FAIL
 135                         else
 136                                 get_mi_min_max_texcoords(0); // load new texcoords
 137                 }
 138
 139                 mi_center = (mi_min + mi_max) * 0.5;
 140                 mi_scale = mi_max - mi_min;
 141                 minimapname = strzone(minimapname);
 142         }
 143
 144         hud_skin_path = strzone(strcat("gfx/hud/", autocvar_hud_skin));
 145         LoadMenuSkinValues();
 146 }
 147
 148 // CSQC_Shutdown : Called every time the CSQC code is shutdown (changing maps, quitting, etc)
 149 void Shutdown()
 150 {
 151         WarpZone_Shutdown();
 152
 153         delete(teams);
 154         delete(players);
 155         db_close(binddb);
 156         db_close(tempdb);
 157         if(autocvar_cl_db_saveasdump)
 158                 db_dump(ClientProgsDB, "client.db");
 159         else
 160                 db_save(ClientProgsDB, "client.db");
 161         db_close(ClientProgsDB);
 162
 163         if(camera_active)
 164                 cvar_set("chase_active",ftos(chase_active_backup));
 165
 166         // unset the event chasecam's chase_active
 167         if(autocvar_chase_active < 0)
 168                 cvar_set("chase_active", "0");
 169
 170         if (autocvar_r_drawviewmodel < 0)
 171                 cvar_set("r_drawviewmodel", "0");
 172
 173         cvar_set("slowmo", cvar_defstring("slowmo")); // reset it back to 'default'
 174
 175         if (!isdemo())
 176         {
 177                 if (!(calledhooks & HOOK_START))
 178                         localcmd("\n_cl_hook_gamestart nop\n");
 179                 if (!(calledhooks & HOOK_END))
 180                         localcmd("\ncl_hook_gameend\n");
 181         }
 182
 183         localcmd("\ncl_hook_shutdown\n");
 184
 185         localcmd("\n-button12\n");
 186
 187         deactivate_minigame();
 188         HUD_MinigameMenu_Close(NULL, NULL, NULL);
 189
 190         ReplicateVars(true); // destroy
 191 }
 192
 193 void AuditLists()
 194 {
 195         entity e;
 196         entity prev;
 197
 198         prev = players;
 199         for(e = prev.sort_next; e; prev = e, e = e.sort_next)
 200         {
 201                 if(prev != e.sort_prev)
 202                         error(strcat("sort list chain error\nplease submit the output of 'prvm_edicts client' to the developers"));
 203         }
 204
 205         prev = teams;
 206         for(e = prev.sort_next; e; prev = e, e = e.sort_next)
 207         {
 208                 if(prev != e.sort_prev)
 209                         error(strcat("sort list chain error\nplease submit the output of 'prvm_edicts client' to the developers"));
 210         }
 211 }
 212
 213 float RegisterPlayer(entity player)
 214 {
 215         entity pl;
 216         AuditLists();
 217         for(pl = players.sort_next; pl; pl = pl.sort_next)
 218                 if(pl == player)
 219                         error("Player already registered!");
 220         player.sort_next = players.sort_next;
 221         player.sort_prev = players;
 222         if(players.sort_next)
 223                 players.sort_next.sort_prev = player;
 224         players.sort_next = player;
 225         AuditLists();
 226         return true;
 227 }
 228
 229 void RemovePlayer(entity player)
 230 {
 231         entity pl, parent;
 232         AuditLists();
 233         parent = players;
 234         for(pl = players.sort_next; pl && pl != player; pl = pl.sort_next)
 235                 parent = pl;
 236
 237         if(!pl)
 238         {
 239                 error("Trying to remove a player which is not in the playerlist!");
 240                 return;
 241         }
 242         parent.sort_next = player.sort_next;
 243         if(player.sort_next)
 244                 player.sort_next.sort_prev = parent;
 245         AuditLists();
 246 }
 247
 248 void MoveToLast(entity e)
 249 {
 250         AuditLists();
 251         entity ent = e.sort_next;
 252         while(ent)
 253         {
 254                 SORT_SWAP(ent, e);
 255                 ent = e.sort_next;
 256         }
 257         AuditLists();
 258 }
 259
 260 float RegisterTeam(entity Team)
 261 {
 262         assert_once(Team.team, eprint(Team));
 263         entity tm;
 264         AuditLists();
 265         for(tm = teams.sort_next; tm; tm = tm.sort_next)
 266                 if(tm == Team)
 267                         error("Team already registered!");
 268         Team.sort_next = teams.sort_next;
 269         Team.sort_prev = teams;
 270         if(teams.sort_next)
 271                 teams.sort_next.sort_prev = Team;
 272         teams.sort_next = Team;
 273         if(Team.team && Team.team != NUM_SPECTATOR)
 274                 ++team_count;
 275         AuditLists();
 276         return true;
 277 }
 278
 279 void RemoveTeam(entity Team)
 280 {
 281         entity tm, parent;
 282         AuditLists();
 283         parent = teams;
 284         for(tm = teams.sort_next; tm && tm != Team; tm = tm.sort_next)
 285                 parent = tm;
 286
 287         if(!tm)
 288         {
 289                 LOG_INFO(_("Trying to remove a team which is not in the teamlist!"));
 290                 return;
 291         }
 292         parent.sort_next = Team.sort_next;
 293         if(Team.sort_next)
 294                 Team.sort_next.sort_prev = parent;
 295         if(Team.team && Team.team != NUM_SPECTATOR)
 296                 --team_count;
 297         AuditLists();
 298 }
 299
 300 entity GetTeam(int Team, bool add)
 301 {
 302         TC(int, Team); TC(bool, add);
 303         int num = (Team == NUM_SPECTATOR) ? 16 : Team;
 304         if(teamslots[num])
 305                 return teamslots[num];
 306         if (!add)
 307                 return NULL;
 308         entity tm = new_pure(team);
 309         tm.team = Team;
 310         teamslots[num] = tm;
 311         RegisterTeam(tm);
 312         return tm;
 313 }
 314
 315 .float has_team;
 316 bool SetTeam(entity o, int Team)
 317 {
 318         TC(int, Team);
 319         //devassert_once(Team);
 320         entity tm;
 321         if(teamplay)
 322         {
 323                 switch(Team)
 324                 {
 325                         case -1:
 326                         case NUM_TEAM_1:
 327                         case NUM_TEAM_2:
 328                         case NUM_TEAM_3:
 329                         case NUM_TEAM_4:
 330                                 break;
 331                         default:
 332                                 if(GetTeam(Team, false) == NULL)
 333                                 {
 334                                         LOG_TRACEF("trying to switch to unsupported team %d", Team);
 335                                         Team = NUM_SPECTATOR;
 336                                 }
 337                                 break;
 338                 }
 339         }
 340         else
 341         {
 342                 switch(Team)
 343                 {
 344                         case -1:
 345                         case 0:
 346                                 break;
 347                         default:
 348                                 if(GetTeam(Team, false) == NULL)
 349                                 {
 350                                         LOG_TRACEF("trying to switch to unsupported team %d", Team);
 351                                         Team = NUM_SPECTATOR;
 352                                 }
 353                                 break;
 354                 }
 355         }
 356         if(Team == -1) // leave
 357         {
 358                 if(o.has_team)
 359                 {
 360                         tm = GetTeam(o.team, false);
 361                         tm.team_size -= 1;
 362                         o.has_team = 0;
 363                         return true;
 364                 }
 365         }
 366         else
 367         {
 368                 if (!o.has_team)
 369                 {
 370                         o.team = Team;
 371                         tm = GetTeam(Team, true);
 372                         tm.team_size += 1;
 373                         o.has_team = 1;
 374                         return true;
 375                 }
 376                 else if(Team != o.team)
 377                 {
 378                         tm = GetTeam(o.team, false);
 379                         tm.team_size -= 1;
 380                         o.team = Team;
 381                         tm = GetTeam(Team, true);
 382                         tm.team_size += 1;
 383                         return true;
 384                 }
 385         }
 386         return false;
 387 }
 388
 389 void Playerchecker_Think(entity this)
 390 {
 391         int i;
 392         entity e;
 393         for(i = 0; i < maxclients; ++i)
 394         {
 395                 e = playerslots[i];
 396                 if(entcs_GetName(i) == "")
 397                 {
 398                         if(e.sort_prev)
 399                         {
 400                                 // player disconnected
 401                                 SetTeam(e, -1);
 402                                 RemovePlayer(e);
 403                                 e.sort_prev = NULL;
 404                                 //e.gotscores = 0;
 405                         }
 406                 }
 407                 else
 408                 {
 409                         if (!e.sort_prev)
 410                         {
 411                                 // player connected
 412                                 if (!e)
 413                                 {
 414                                         playerslots[i] = e = new_pure(playerslot);
 415                                 }
 416                                 e.sv_entnum = i;
 417                                 e.ping = 0;
 418                                 e.ping_packetloss = 0;
 419                                 e.ping_movementloss = 0;
 420                                 //e.gotscores = 0; // we might already have the scores...
 421                                 int t = entcs_GetScoreTeam(i);
 422                                 if (t) SetTeam(e, t); // will not hurt; later updates come with Scoreboard_UpdatePlayerTeams
 423                                 RegisterPlayer(e);
 424                                 Scoreboard_UpdatePlayerPos(e);
 425                         }
 426                 }
 427         }
 428         this.nextthink = time + 0.2;
 429 }
 430
 431 void PostInit()
 432 {
 433         entity playerchecker = new_pure(playerchecker);
 434         setthink(playerchecker, Playerchecker_Think);
 435         playerchecker.nextthink = time + 0.2;
 436
 437         TrueAim_Init();
 438
 439         postinit = true;
 440 }
 441
 442 // CSQC_InputEvent : Used to perform actions based on any key pressed, key released and mouse on the client.
 443 // Return value should be 1 if CSQC handled the input, otherwise return 0 to have the input passed to the engine.
 444 // All keys are in ascii.
 445 // bInputType = 0 is key pressed, 1 is key released, 2 and 3 are mouse input.
 446 // In the case of keyboard input, nPrimary is the ascii code, and nSecondary is 0.
 447 // In the case of mouse input, nPrimary is xdelta, nSecondary is ydelta.
 448 // In the case of mouse input after a setcursormode(1) call, nPrimary is xpos, nSecondary is ypos.
 449 float CSQC_InputEvent(int bInputType, float nPrimary, float nSecondary)
 450 {
 451         TC(int, bInputType);
 452         bool override = false;
 453         override |= HUD_Scoreboard_InputEvent(bInputType, nPrimary, nSecondary);
 454         if (override)
 455                 return true;
 456
 457         override |= HUD_Panel_InputEvent(bInputType, nPrimary, nSecondary);
 458         if (override)
 459                 return true;
 460
 461         override |= QuickMenu_InputEvent(bInputType, nPrimary, nSecondary);
 462
 463         override |= HUD_Radar_InputEvent(bInputType, nPrimary, nSecondary);
 464
 465         override |= MapVote_InputEvent(bInputType, nPrimary, nSecondary);
 466
 467         override |= HUD_Minigame_InputEvent(bInputType, nPrimary, nSecondary);
 468
 469         if(override)
 470                 return true;
 471
 472         return false;
 473 }
 474
 475 // END REQUIRED CSQC FUNCTIONS
 476 // --------------------------------------------------------------------------
 477
 478 // --------------------------------------------------------------------------
 479 // BEGIN OPTIONAL CSQC FUNCTIONS
 480
 481 void Ent_RemovePlayerScore(entity this)
 482 {
 483         if(this.owner) {
 484                 SetTeam(this.owner, -1);
 485                 this.owner.gotscores = 0;
 486                 FOREACH(Scores, true, {
 487                         this.owner.(scores(it)) = 0; // clear all scores
 488                 });
 489         }
 490 }
 491
 492 NET_HANDLE(ENT_CLIENT_SCORES, bool isnew)
 493 {
 494         make_pure(this);
 495         entity o;
 496
 497         // damnit -.- don't want to go change every single .sv_entnum in hud.qc AGAIN
 498         // (no I've never heard of M-x replace-string, sed, or anything like that)
 499         bool isNew = !this.owner; // workaround for DP bug
 500         int n = ReadByte()-1;
 501
 502 #ifdef DP_CSQC_ENTITY_REMOVE_IS_B0RKED
 503         if(!isNew && n != this.sv_entnum)
 504         {
 505                 //print("A CSQC entity changed its owner!\n");
 506                 LOG_INFOF("A CSQC entity changed its owner! (edict: %d, classname: %s)", etof(this), this.classname);
 507                 isNew = true;
 508                 Ent_Remove(this);
 509         }
 510 #endif
 511
 512         this.sv_entnum = n;
 513
 514         o = playerslots[this.sv_entnum];
 515         if (!o)
 516         {
 517                 o = playerslots[this.sv_entnum] = new_pure(playerslot);
 518         }
 519         this.owner = o;
 520         o.sv_entnum = this.sv_entnum;
 521         o.gotscores = 1;
 522
 523         //if (!o.sort_prev)
 524         //      RegisterPlayer(o);
 525         //playerchecker will do this for us later, if it has not already done so
 526
 527         int sf = ReadShort();
 528         int lf = ReadShort();
 529         FOREACH(Scores, true, {
 530                 int p = 1 << (i % 16);
 531                 if (sf & p)
 532                 {
 533                         if (lf & p)
 534                                 o.(scores(it)) = ReadInt24_t();
 535                         else
 536                                 o.(scores(it)) = ReadChar();
 537                 }
 538         });
 539
 540         return = true;
 541
 542         if(o.sort_prev)
 543                 Scoreboard_UpdatePlayerPos(o); // if not registered, we cannot do this yet!
 544
 545         this.entremove = Ent_RemovePlayerScore;
 546 }
 547
 548 NET_HANDLE(ENT_CLIENT_TEAMSCORES, bool isnew)
 549 {
 550         make_pure(this);
 551         int i;
 552
 553         this.team = ReadByte();
 554         entity o = this.owner = GetTeam(this.team, true); // these team numbers can always be trusted
 555
 556 #if MAX_TEAMSCORE <= 8
 557         int sf = ReadByte();
 558         int lf = ReadByte();
 559 #else
 560         int sf = ReadShort();
 561         int lf = ReadShort();
 562 #endif
 563         for(i = 0; i < MAX_TEAMSCORE; ++i)
 564                 if(sf & BIT(i))
 565                 {
 566                         if(lf & BIT(i))
 567                                 o.(teamscores(i)) = ReadInt24_t();
 568                         else
 569                                 o.(teamscores(i)) = ReadChar();
 570                 }
 571
 572         return = true;
 573
 574         Scoreboard_UpdateTeamPos(o);
 575 }
 576
 577 NET_HANDLE(ENT_CLIENT_CLIENTDATA, bool isnew)
 578 {
 579         make_pure(this);
 580         float newspectatee_status;
 581
 582         int f = ReadByte();
 583
 584         scoreboard_showscores_force = (f & BIT(0));
 585
 586         if(f & BIT(1))
 587         {
 588                 newspectatee_status = ReadByte();
 589                 if(newspectatee_status == player_localnum + 1)
 590                         newspectatee_status = -1; // observing
 591         }
 592         else
 593                 newspectatee_status = 0;
 594
 595         spectatorbutton_zoom = (f & BIT(2));
 596
 597         if(f & BIT(4))
 598         {
 599                 num_spectators = ReadByte();
 600
 601                 float i, slot;
 602
 603                 for(i = 0; i < MAX_SPECTATORS; ++i)
 604                         spectatorlist[i] = 0; // reset list first
 605
 606                 int limit = min(num_spectators, MAX_SPECTATORS);
 607                 for(i = 0; i < limit; ++i)
 608                 {
 609                         slot = ReadByte();
 610                         spectatorlist[i] = slot - 1;
 611                 }
 612         }
 613         else
 614         {
 615                 for(int j = 0; j < MAX_SPECTATORS; ++j)
 616                         spectatorlist[j] = 0; // reset list if showspectators has been turned off
 617                 num_spectators = 0;
 618         }
 619
 620         return = true;
 621
 622         if(newspectatee_status != spectatee_status)
 623         {
 624                 // clear race stuff
 625                 race_laptime = 0;
 626                 race_checkpointtime = 0;
 627                 hud_dynamic_shake_factor = -1;
 628                 spectatee_status_changed_time = time;
 629         }
 630         if (autocvar_hud_panel_healtharmor_progressbar_gfx)
 631         {
 632                 if ( (spectatee_status == -1 && newspectatee_status > 0) //before observing, now spectating
 633                   || (spectatee_status > 0 && newspectatee_status > 0 && spectatee_status != newspectatee_status) //changed spectated player
 634                 )
 635                         prev_p_health = -1;
 636                 else if(spectatee_status && !newspectatee_status) //before observing/spectating, now playing
 637                         prev_health = -1;
 638         }
 639         spectatee_status = newspectatee_status;
 640
 641         // we could get rid of spectatee_status, and derive it from player_localentnum and player_localnum
 642 }
 643
 644 NET_HANDLE(ENT_CLIENT_NAGGER, bool isnew)
 645 {
 646         make_pure(this);
 647         int i, j, b, f;
 648
 649         int nags = ReadByte(); // NAGS NAGS NAGS NAGS NAGS NAGS NADZ NAGS NAGS NAGS
 650
 651         if(!(nags & BIT(2)))
 652         {
 653                 strfree(vote_called_vote);
 654                 vote_active = 0;
 655         }
 656         else
 657         {
 658                 vote_active = 1;
 659         }
 660
 661         if(nags & BIT(6))
 662         {
 663                 vote_yescount = ReadByte();
 664                 vote_nocount = ReadByte();
 665                 vote_needed = ReadByte();
 666                 vote_highlighted = ReadChar();
 667         }
 668
 669         if(nags & BIT(7))
 670         {
 671                 strcpy(vote_called_vote, ReadString());
 672         }
 673
 674         if(nags & 1)
 675         {
 676                 for(j = 0; j < maxclients; ++j)
 677                         if(playerslots[j])
 678                                 playerslots[j].ready = true;
 679                 for(i = 1; i <= maxclients; i += 8)
 680                 {
 681                         f = ReadByte();
 682                         for(j = i-1, b = BIT(0); b < BIT(8); b <<= 1, ++j)
 683                                 if (!(f & b))
 684                                         if(playerslots[j])
 685                                                 playerslots[j].ready = false;
 686                 }
 687         }
 688
 689         return = true;
 690
 691         ready_waiting = (nags & BIT(0));
 692         ready_waiting_for_me = (nags & BIT(1));
 693         vote_waiting = (nags & BIT(2));
 694         vote_waiting_for_me = (nags & BIT(3));
 695         warmup_stage = (nags & BIT(4));
 696 }
 697
 698 NET_HANDLE(ENT_CLIENT_ELIMINATEDPLAYERS, bool isnew)
 699 {
 700         make_pure(this);
 701         int sf = 0;
 702         serialize(byte, 0, sf);
 703         if (sf & 1) {
 704                 for (int j = 0; j < maxclients; ++j) {
 705                         if (playerslots[j]) {
 706                                 playerslots[j].eliminated = true;
 707                         }
 708                 }
 709                 for (int i = 1; i <= maxclients; i += 8) {
 710                         int f = 0;
 711                         serialize(byte, 0, f);
 712                         for (int b = 0; b < 8; ++b) {
 713                                 if (f & BIT(b)) continue;
 714                                 int j = i - 1 + b;
 715                                 if (playerslots[j]) {
 716                                         playerslots[j].eliminated = false;
 717                                 }
 718                         }
 719                 }
 720         }
 721         return true;
 722 }
 723
 724 NET_HANDLE(ENT_CLIENT_RANDOMSEED, bool isnew)
 725 {
 726         make_pure(this);
 727         prandom_debug();
 728         float s = ReadShort();
 729         psrandom(s);
 730         return true;
 731 }
 732
 733 NET_HANDLE(ENT_CLIENT_ACCURACY, bool isnew)
 734 {
 735         make_pure(this);
 736         int sf = ReadInt24_t();
 737         if (sf == 0) {
 738                 for (int w = 0; w <= WEP_LAST - WEP_FIRST; ++w)
 739                         weapon_accuracy[w] = -1;
 740                 return true;
 741         }
 742
 743         int f = 1;
 744         for (int w = 0; w <= WEP_LAST - WEP_FIRST; ++w) {
 745                 if (sf & f) {
 746                         int b = ReadByte();
 747                         if (b == 0)
 748                                 weapon_accuracy[w] = -1;
 749                         else if (b == 255)
 750                                 weapon_accuracy[w] = 1.0; // no better error handling yet, sorry
 751                         else
 752                                 weapon_accuracy[w] = (b - 1.0) / 100.0;
 753                 }
 754                 f = (f == 0x800000) ? 1 : f * 2;
 755         }
 756         return true;
 757 }
 758
 759 void Spawn_Draw(entity this)
 760 {
 761         bool dodraw = autocvar_cl_spawn_point_particles;
 762         if(dodraw && autocvar_cl_spawn_point_dist_max)
 763         {
 764                 vector org = getpropertyvec(VF_ORIGIN);
 765                 dodraw = vdist(org - this.origin, <, autocvar_cl_spawn_point_dist_max);
 766         }
 767
 768         if(dodraw)
 769                 pointparticles(((!teamplay) ? EFFECT_SPAWNPOINT_NEUTRAL : EFFECT_SPAWNPOINT(this.team - 1)), this.origin + '0 0 28', '0 0 2', bound(0, frametime, 0.1));
 770 }
 771
 772 NET_HANDLE(ENT_CLIENT_SPAWNPOINT, bool is_new)
 773 {
 774         float teamnum = (ReadByte() - 1);
 775         vector spn_origin = ReadVector();
 776
 777         this.team = (teamnum + 1);
 778
 779         //if(is_new)
 780         //{
 781                 this.origin = spn_origin;
 782                 setsize(this, PL_MIN_CONST, PL_MAX_CONST);
 783                 //droptofloor();
 784
 785                 /*if(autocvar_cl_spawn_point_model) // needs a model first
 786                 {
 787                         this.mdl = "models/spawnpoint.md3";
 788                         this.colormod = Team_ColorRGB(teamnum);
 789                         precache_model(this.mdl);
 790                         setmodel(this, this.mdl);
 791                         this.drawmask = MASK_NORMAL;
 792                         //this.move_movetype = MOVETYPE_NOCLIP;
 793                         //this.draw = Spawn_Draw;
 794                         IL_PUSH(g_drawables, this);
 795                 }*/
 796                 this.draw = Spawn_Draw;
 797                 if (is_new) IL_PUSH(g_drawables, this);
 798         //}
 799
 800         //printf("Ent_ReadSpawnPoint(is_new = %d); origin = %s, team = %d, effect = %d\n", is_new, vtos(this.origin), teamnum, this.cnt);
 801         return true;
 802 }
 803
 804 NET_HANDLE(ENT_CLIENT_SPAWNEVENT, bool is_new)
 805 {
 806         // If entnum is 0, ONLY do the local spawn actions
 807         // this way the server can disable the sending of
 808         // spawn origin or such to clients if wanted.
 809         float entnum = ReadByte();
 810
 811         if(entnum)
 812         {
 813                 this.origin = ReadVector();
 814
 815                 if(is_new)
 816                 {
 817                         float teamnum = entcs_GetTeam(entnum - 1);
 818
 819                         if(autocvar_cl_spawn_event_particles)
 820                         {
 821                                 switch(teamnum)
 822                                 {
 823                                         case NUM_TEAM_1: pointparticles(EFFECT_SPAWN_RED, this.origin, '0 0 0', 1); break;
 824                                         case NUM_TEAM_2: pointparticles(EFFECT_SPAWN_BLUE, this.origin, '0 0 0', 1); break;
 825                                         case NUM_TEAM_3: pointparticles(EFFECT_SPAWN_YELLOW, this.origin, '0 0 0', 1); break;
 826                                         case NUM_TEAM_4: pointparticles(EFFECT_SPAWN_PINK, this.origin, '0 0 0', 1); break;
 827                                         default: pointparticles(EFFECT_SPAWN_NEUTRAL, this.origin, '0 0 0', 1); break;
 828                                 }
 829                         }
 830                         if(autocvar_cl_spawn_event_sound)
 831                         {
 832                                 sound(this, CH_TRIGGER, SND_SPAWN, VOL_BASE, ATTEN_NORM);
 833                         }
 834                 }
 835         }
 836         return = true;
 837
 838         // local spawn actions
 839         if(is_new && (!entnum || (entnum == player_localentnum)))
 840         {
 841                 if(autocvar_cl_spawnzoom && !autocvar_cl_lockview)
 842                 {
 843                         zoomin_effect = 1;
 844                         current_viewzoom = (1 / bound(1, autocvar_cl_spawnzoom_factor, 16));
 845                 }
 846
 847                 if(autocvar_cl_unpress_zoom_on_spawn)
 848                 {
 849                         localcmd("-zoom\n");
 850                         button_zoom = false;
 851                 }
 852                 HUD_Radar_Hide_Maximized();
 853         }
 854         //printf("Ent_ReadSpawnEvent(is_new = %d); origin = %s, entnum = %d, localentnum = %d\n", is_new, vtos(this.origin), entnum, player_localentnum);
 855 }
 856
 857 // CSQC_Ent_Update : Called every frame that the server has indicated an update to the SSQC / CSQC entity has occured.
 858 // The parameter isnew reflects if the entity is "new" to the client, meaning it just came into the client's PVS.
 859 void CSQC_Ent_Update(entity this, bool isnew)
 860 {
 861         this.sourceLoc = __FILE__":"STR(__LINE__);
 862         int t = ReadByte();
 863
 864         // set up the "time" global for received entities to be correct for interpolation purposes
 865         float savetime = time;
 866         if(servertime)
 867         {
 868                 time = servertime;
 869         }
 870         else
 871         {
 872                 serverprevtime = time;
 873                 serverdeltatime = STAT(MOVEVARS_TICRATE) * STAT(MOVEVARS_TIMESCALE);
 874                 time = serverprevtime + serverdeltatime;
 875         }
 876
 877 #ifdef DP_CSQC_ENTITY_REMOVE_IS_B0RKED
 878         if (this.enttype)
 879         {
 880                 if (t != this.enttype || isnew)
 881                 {
 882                         LOG_INFOF("A CSQC entity changed its type! (edict: %d, server: %d, type: %d -> %d)", etof(this), this.entnum, this.enttype, t);
 883                         Ent_Remove(this);
 884                         ONREMOVE(this);
 885                         clearentity(this);
 886                         isnew = true;
 887                 }
 888         }
 889         else
 890         {
 891                 if (!isnew)
 892                 {
 893                         LOG_INFOF("A CSQC entity appeared out of nowhere! (edict: %d, server: %d, type: %d)", etof(this), this.entnum, t);
 894                         isnew = true;
 895                 }
 896         }
 897 #endif
 898         this.enttype = t;
 899         bool done = false;
 900         FOREACH(LinkedEntities, it.m_id == t, {
 901                 if (isnew) this.classname = it.netname;
 902                 if (autocvar_developer_csqcentities)
 903                         LOG_INFOF("CSQC_Ent_Update(%i, %d) at %f {.entnum=%d, .enttype=%d} t=%s (%d)", this, isnew, savetime, this.entnum, this.enttype, this.classname, t);
 904                 done = it.m_read(this, NULL, isnew);
 905                 MUTATOR_CALLHOOK(Ent_Update, this, isnew);
 906                 break;
 907         });
 908         time = savetime;
 909         if (!done)
 910         {
 911                 LOG_FATALF("CSQC_Ent_Update(%i, %d) at %f {.entnum=%d, .enttype=%d} t=%s (%d)", this, isnew, savetime, this.entnum, this.enttype, this.classname, t);
 912         }
 913 }
 914
 915 // Destructor, but does NOT deallocate the entity by calling remove(). Also
 916 // used when an entity changes its type. For an entity that someone interacts
 917 // with others, make sure it can no longer do so.
 918 void Ent_Remove(entity this)
 919 {
 920         if(this.entremove) this.entremove(this);
 921
 922         if(this.skeletonindex)
 923         {
 924                 skel_delete(this.skeletonindex);
 925                 this.skeletonindex = 0;
 926         }
 927
 928         if(this.snd_looping > 0)
 929         {
 930                 sound(this, this.snd_looping, SND_Null, VOL_BASE, autocvar_cl_jetpack_attenuation);
 931                 this.snd_looping = 0;
 932         }
 933
 934         this.enttype = 0;
 935         this.classname = "";
 936         this.draw = func_null;
 937         this.entremove = func_null;
 938         // TODO possibly set more stuff to defaults
 939 }
 940 // CSQC_Ent_Remove : Called when the server requests a SSQC / CSQC entity to be removed.  Essentially call remove(this) as well.
 941 void CSQC_Ent_Remove(entity this)
 942 {
 943         if (autocvar_developer_csqcentities) LOG_INFOF("CSQC_Ent_Remove() with this=%i {.entnum=%d, .enttype=%d}", this, this.entnum, this.enttype);
 944         if (wasfreed(this))
 945         {
 946                 LOG_WARN("CSQC_Ent_Remove called for already removed entity. Packet loss?");
 947                 return;
 948         }
 949         if (this.enttype) Ent_Remove(this);
 950         delete(this);
 951 }
 952
 953 void Gamemode_Init()
 954 {
 955         if (!isdemo())
 956         {
 957                 if(!(calledhooks & HOOK_START))
 958                         localcmd("\n_cl_hook_gamestart ", MapInfo_Type_ToString(gametype), "\n");
 959                 calledhooks |= HOOK_START;
 960         }
 961 }
 962 // CSQC_Parse_StuffCmd : Provides the stuffcmd string in the first parameter that the server provided.  To execute standard behavior, simply execute localcmd with the string.
 963 void CSQC_Parse_StuffCmd(string strMessage)
 964 {
 965         if (autocvar_developer_csqcentities) LOG_INFOF("CSQC_Parse_StuffCmd(\"%s\")", strMessage);
 966         localcmd(strMessage);
 967 }
 968 // CSQC_Parse_Print : Provides the print string in the first parameter that the server provided.  To execute standard behavior, simply execute print with the string.
 969 void CSQC_Parse_Print(string strMessage)
 970 {
 971         if (autocvar_developer_csqcentities) LOG_INFOF("CSQC_Parse_Print(\"%s\")", strMessage);
 972         print(ColorTranslateRGB(strMessage));
 973 }
 974
 975 // CSQC_Parse_CenterPrint : Provides the centerprint_AddStandard string in the first parameter that the server provided.
 976 void CSQC_Parse_CenterPrint(string strMessage)
 977 {
 978         if (autocvar_developer_csqcentities) LOG_INFOF("CSQC_Parse_CenterPrint(\"%s\")", strMessage);
 979         centerprint_AddStandard(strMessage);
 980 }
 981
 982 // CSQC_Parse_TempEntity : Handles all temporary entity network data in the CSQC layer.
 983 // You must ALWAYS first acquire the temporary ID, which is sent as a byte.
 984 // Return value should be 1 if CSQC handled the temporary entity, otherwise return 0 to have the engine process the event.
 985 bool CSQC_Parse_TempEntity()
 986 {
 987         // Acquire TE ID
 988         int nTEID = ReadByte();
 989
 990         FOREACH(TempEntities, it.m_id == nTEID, {
 991                 if (autocvar_developer_csqcentities)
 992                         LOG_INFOF("CSQC_Parse_TempEntity() nTEID=%s (%d)", it.netname, nTEID);
 993                 return it.m_read(NULL, NULL, true);
 994         });
 995
 996         if (autocvar_developer_csqcentities)
 997                 LOG_INFOF("CSQC_Parse_TempEntity() with nTEID=%d", nTEID);
 998
 999         // No special logic for this temporary entity; return 0 so the engine can handle it
1000         return false;
1001 }
1002
1003 string forcefog;
1004 void Fog_Force()
1005 {
1006         if (autocvar_cl_orthoview && autocvar_cl_orthoview_nofog)
1007                 localcmd("\nr_drawfog 0\n");
1008         else if (forcefog != "")
1009                 localcmd(sprintf("\nfog %s\nr_fog_exp2 0\nr_drawfog 1\n", forcefog));
1010 }
1011
1012 NET_HANDLE(ENT_CLIENT_SCORES_INFO, bool isnew)
1013 {
1014         make_pure(this);
1015         gametype = ReadRegistered(Gametypes);
1016         teamplay = _MapInfo_GetTeamPlayBool(gametype);
1017         HUD_ModIcons_SetFunc();
1018         FOREACH(Scores, true, {
1019                 strcpy(scores_label(it), ReadString());
1020                 scores_flags(it) = ReadByte();
1021         });
1022         for (int i = 0; i < MAX_TEAMSCORE; ++i)
1023         {
1024                 strcpy(teamscores_label(i), ReadString());
1025                 teamscores_flags(i) = ReadByte();
1026         }
1027         return = true;
1028         Scoreboard_InitScores();
1029         Gamemode_Init();
1030 }
1031
1032 NET_HANDLE(ENT_CLIENT_INIT, bool isnew)
1033 {
1034         nb_pb_period = ReadByte() / 32; //Accuracy of 1/32th
1035
1036         hook_shotorigin[0] = decompressShotOrigin(ReadInt24_t());
1037         hook_shotorigin[1] = decompressShotOrigin(ReadInt24_t());
1038         hook_shotorigin[2] = decompressShotOrigin(ReadInt24_t());
1039         hook_shotorigin[3] = decompressShotOrigin(ReadInt24_t());
1040         arc_shotorigin[0] = decompressShotOrigin(ReadInt24_t());
1041         arc_shotorigin[1] = decompressShotOrigin(ReadInt24_t());
1042         arc_shotorigin[2] = decompressShotOrigin(ReadInt24_t());
1043         arc_shotorigin[3] = decompressShotOrigin(ReadInt24_t());
1044
1045         strcpy(forcefog, ReadString());
1046
1047         armorblockpercent = ReadByte() / 255.0;
1048         damagepush_speedfactor = ReadByte() / 255.0;
1049
1050         serverflags = ReadByte();
1051
1052         g_trueaim_minrange = ReadCoord();
1053
1054         return = true;
1055
1056         MUTATOR_CALLHOOK(Ent_Init);
1057
1058         if (!postinit) PostInit();
1059 }
1060
1061 float GetSpeedUnitFactor(int speed_unit)
1062 {
1063         switch(speed_unit)
1064         {
1065                 default:
1066                 case 1: return 1.0;
1067                 case 2: return 0.0254;
1068                 case 3: return 0.0254 * 3.6;
1069                 case 4: return 0.0254 * 3.6 * 0.6213711922;
1070                 case 5: return 0.0254 * 1.943844492; // 1 m/s = 1.943844492 knots, because 1 knot = 1.852 km/h
1071         }
1072 }
1073
1074 string GetSpeedUnit(int speed_unit)
1075 {
1076         switch(speed_unit)
1077         {
1078                 // translator-friendly strings without the initial space
1079                 default:
1080                 case 1: return strcat(" ", _("qu/s"));
1081                 case 2: return strcat(" ", _("m/s"));
1082                 case 3: return strcat(" ", _("km/h"));
1083                 case 4: return strcat(" ", _("mph"));
1084                 case 5: return strcat(" ", _("knots"));
1085         }
1086 }
1087
1088 NET_HANDLE(TE_CSQC_RACE, bool isNew)
1089 {
1090         int b = ReadByte();
1091
1092         switch (b)
1093         {
1094                 case RACE_NET_CHECKPOINT_HIT_QUALIFYING:
1095                         race_checkpoint = ReadByte();
1096                         race_time = ReadInt24_t();
1097                         race_previousbesttime = ReadInt24_t();
1098                         race_mypreviousbesttime = ReadInt24_t();
1099                         string pbestname = ReadString();
1100                         if(autocvar_cl_race_cptimes_onlyself)
1101                         {
1102                                 race_previousbesttime = race_mypreviousbesttime;
1103                                 race_mypreviousbesttime = 0;
1104                                 strcpy(race_previousbestname, "");
1105                         }
1106                         else
1107                                 strcpy(race_previousbestname, pbestname);
1108
1109                         race_checkpointtime = time;
1110
1111                         if(race_checkpoint == 0 || race_checkpoint == 254)
1112                         {
1113                                 race_penaltyaccumulator = 0;
1114                                 race_laptime = time; // valid
1115                         }
1116                         break;
1117
1118                 case RACE_NET_CHECKPOINT_CLEAR:
1119                         race_laptime = 0;
1120                         race_checkpointtime = 0;
1121                         break;
1122
1123                 case RACE_NET_CHECKPOINT_NEXT_SPEC_QUALIFYING:
1124                         race_laptime = ReadCoord();
1125                         race_checkpointtime = -99999;
1126                         // fall through
1127                 case RACE_NET_CHECKPOINT_NEXT_QUALIFYING:
1128                         race_nextcheckpoint = ReadByte();
1129
1130                         race_nextbesttime = ReadInt24_t();
1131                         if(b != RACE_NET_CHECKPOINT_NEXT_SPEC_QUALIFYING) // not while spectating (matches server)
1132                                 race_mybesttime = ReadInt24_t();
1133                         string newname = ReadString();
1134                         if(autocvar_cl_race_cptimes_onlyself && b != RACE_NET_CHECKPOINT_NEXT_SPEC_QUALIFYING)
1135                         {
1136                                 race_nextbesttime = race_mybesttime;
1137                                 race_mybesttime = 0;
1138                                 strcpy(race_nextbestname, "");
1139                         }
1140                         else
1141                                 strcpy(race_nextbestname, newname);
1142                         break;
1143
1144                 case RACE_NET_CHECKPOINT_HIT_RACE:
1145                         race_mycheckpoint = ReadByte();
1146                         race_mycheckpointtime = time;
1147                         race_mycheckpointdelta = ReadInt24_t();
1148                         race_mycheckpointlapsdelta = ReadByte();
1149                         if(race_mycheckpointlapsdelta >= 128)
1150                                 race_mycheckpointlapsdelta -= 256;
1151                         int who = ReadByte();
1152                         if(who)
1153                                 strcpy(race_mycheckpointenemy, entcs_GetName(who - 1));
1154                         else
1155                                 strcpy(race_mycheckpointenemy, ""); // TODO: maybe string_null works fine here?
1156                         break;
1157
1158                 case RACE_NET_CHECKPOINT_HIT_RACE_BY_OPPONENT:
1159                         race_othercheckpoint = ReadByte();
1160                         race_othercheckpointtime = time;
1161                         race_othercheckpointdelta = ReadInt24_t();
1162                         race_othercheckpointlapsdelta = ReadByte();
1163                         if(race_othercheckpointlapsdelta >= 128)
1164                                 race_othercheckpointlapsdelta -= 256;
1165                         int what = ReadByte();
1166                         if(what)
1167                                 strcpy(race_othercheckpointenemy, entcs_GetName(what - 1));
1168                         else
1169                                 strcpy(race_othercheckpointenemy, ""); // TODO: maybe string_null works fine here?
1170                         break;
1171
1172                 case RACE_NET_PENALTY_RACE:
1173                 case RACE_NET_PENALTY_QUALIFYING:
1174                         race_penaltyeventtime = time;
1175                         race_penaltytime = ReadShort();
1176                         string reason = ReadString();
1177                         if (reason == "missing a checkpoint")
1178                                 reason = _("missing a checkpoint");
1179                         strcpy(race_penaltyreason, reason);
1180                         if (b == RACE_NET_PENALTY_QUALIFYING)
1181                                 race_penaltyaccumulator += race_penaltytime;
1182                         break;
1183
1184                 case RACE_NET_SERVER_RECORD:
1185                         race_server_record = ReadInt24_t();
1186                         break;
1187                 case RACE_NET_SPEED_AWARD:
1188                         race_speedaward = ReadInt24_t() * GetSpeedUnitFactor(autocvar_hud_panel_physics_speed_unit);
1189                         strcpy(race_speedaward_holder, ReadString());
1190                         break;
1191                 case RACE_NET_SPEED_AWARD_BEST:
1192                         race_speedaward_alltimebest = ReadInt24_t() * GetSpeedUnitFactor(autocvar_hud_panel_physics_speed_unit);
1193                         strcpy(race_speedaward_alltimebest_holder, ReadString());
1194                         break;
1195                 case RACE_NET_RANKINGS_CNT:
1196                         RANKINGS_DISPLAY_CNT = ReadByte();
1197                         break;
1198                 case RACE_NET_SERVER_RANKINGS:
1199                         float prevpos, del;
1200                         int pos = ReadShort();
1201                         prevpos = ReadShort();
1202                         del = ReadShort();
1203
1204                         // move other rankings out of the way
1205                         int i;
1206                         if (prevpos) {
1207                                 int m = min(prevpos, RANKINGS_DISPLAY_CNT);
1208                                 for (i=m-1; i>pos-1; --i) {
1209                                         grecordtime[i] = grecordtime[i-1];
1210                                         strcpy(grecordholder[i], grecordholder[i-1]);
1211                                 }
1212                         } else if (del) { // a record has been deleted by the admin
1213                                 for (i=pos-1; i<= RANKINGS_DISPLAY_CNT-1; ++i) {
1214                                         if (i == RANKINGS_DISPLAY_CNT-1) { // clear out last record
1215                                                 grecordtime[i] = 0;
1216                                                 strfree(grecordholder[i]);
1217                                         }
1218                                         else {
1219                                                 grecordtime[i] = grecordtime[i+1];
1220                                                 strcpy(grecordholder[i], grecordholder[i+1]);
1221                                         }
1222                                 }
1223                         } else { // player has no ranked record yet
1224                                 for (i=RANKINGS_DISPLAY_CNT-1;i>pos-1;--i) {
1225                                         grecordtime[i] = grecordtime[i-1];
1226                                         strcpy(grecordholder[i], grecordholder[i-1]);
1227                                 }
1228                         }
1229
1230                         if (grecordtime[RANKINGS_DISPLAY_CNT]) {
1231                                 // kick off the player who fell from the last displayed position
1232                                 grecordtime[RANKINGS_DISPLAY_CNT] = 0;
1233                                 strfree(grecordholder[RANKINGS_DISPLAY_CNT]);
1234                         }
1235
1236                         // store new ranking
1237                         strcpy(grecordholder[pos-1], ReadString());
1238                         grecordtime[pos-1] = ReadInt24_t();
1239                         if(strdecolorize(grecordholder[pos-1]) == strdecolorize(entcs_GetName(player_localnum)))
1240                                 race_myrank = pos;
1241                         break;
1242                 case RACE_NET_SERVER_STATUS:
1243                         race_status = ReadShort();
1244                         strcpy(race_status_name, ReadString());
1245         }
1246         return true;
1247 }
1248
1249 NET_HANDLE(TE_CSQC_TEAMNAGGER, bool isNew)
1250 {
1251         teamnagger = 1;
1252         return true;
1253 }
1254
1255 NET_HANDLE(TE_CSQC_PINGPLREPORT, bool isNew)
1256 {
1257         int i = ReadByte();
1258         int pi = ReadShort();
1259         int pl = ReadByte();
1260         int ml = ReadByte();
1261         return = true;
1262         entity e = playerslots[i];
1263         if (!e) return;
1264         e.ping = pi;
1265         e.ping_packetloss = pl / 255.0;
1266         e.ping_movementloss = ml / 255.0;
1267 }
1268
1269 NET_HANDLE(TE_CSQC_WEAPONCOMPLAIN, bool isNew)
1270 {
1271         int weapon_id = ReadByte();
1272         complain_weapon = REGISTRY_GET(Weapons, weapon_id);
1273         complain_weapon_type = ReadByte();
1274         return = true;
1275
1276         complain_weapon_time = time;
1277         weapontime = time; // ping the weapon panel
1278
1279         switch(complain_weapon_type)
1280         {
1281                 case 0: Local_Notification(MSG_MULTI, ITEM_WEAPON_NOAMMO, weapon_id); break;
1282                 case 1: Local_Notification(MSG_MULTI, ITEM_WEAPON_DONTHAVE, weapon_id); break;
1283                 default: Local_Notification(MSG_MULTI, ITEM_WEAPON_UNAVAILABLE, weapon_id); break;
1284         }
1285 }
1286
1287 string _getcommandkey(string cmd_name, string command, bool forcename)
1288 {
1289         string keys;
1290         float n, j, k, l = 0;
1291
1292         if (!autocvar_hud_showbinds)
1293                 return cmd_name;
1294
1295         keys = db_get(binddb, command);
1296         if (keys == "")
1297         {
1298                 bool joy_active = cvar("joy_active");
1299                 n = tokenize(findkeysforcommand(command, 0)); // uses '...' strings
1300                 for(j = 0; j < n; ++j)
1301                 {
1302                         k = stof(argv(j));
1303                         if(k != -1)
1304                         {
1305                                 string key = keynumtostring(k);
1306                                 if(!joy_active && substring(key, 0, 3) == "JOY")
1307                                         continue;
1308
1309                                 key = translate_key(key);
1310
1311                                 if (keys == "")
1312                                         keys = key;
1313                                 else
1314                                         keys = strcat(keys, ", ", key);
1315
1316                                 ++l;
1317                                 if (autocvar_hud_showbinds_limit > 0 && autocvar_hud_showbinds_limit <= l)
1318                                         break;
1319                         }
1320
1321                 }
1322                 if (keys == "")
1323                         keys = "NO_KEY";
1324                 db_put(binddb, command, keys);
1325         }
1326
1327         if (keys == "NO_KEY") {
1328                 if (autocvar_hud_showbinds > 1)
1329                         return sprintf(_("%s (not bound)"), cmd_name);
1330                 else
1331                         return cmd_name;
1332         }
1333         else if (autocvar_hud_showbinds > 1 || forcename)
1334                 return sprintf("%s (%s)", cmd_name, keys);
1335         else
1336                 return keys;
1337 }
1338
1339 /** engine callback */
1340 void URI_Get_Callback(int id, int status, string data)
1341 {
1342         TC(int, id); TC(int, status);
1343         if(url_URI_Get_Callback(id, status, data))
1344         {
1345                 // handled
1346         }
1347         else if (id == URI_GET_DISCARD)
1348         {
1349                 // discard
1350         }
1351         else if (id >= URI_GET_CURL && id <= URI_GET_CURL_END)
1352         {
1353                 // sv_cmd curl
1354                 Curl_URI_Get_Callback(id, status, data);
1355         }
1356         else
1357         {
1358                 LOG_INFOF("Received HTTP request data for an invalid id %d.", id);
1359         }
1360 }