qcsrc/client/main.qc

   1 #include "main.qh"
   2
   3 #include <client/command/cl_cmd.qh>
   4 #include <client/draw.qh>
   5 #include <client/hud/_mod.qh>
   6 #include <client/hud/panel/centerprint.qh>
   7 #include <client/hud/panel/chat.qh>
   8 #include <client/hud/panel/quickmenu.qh>
   9 #include <client/hud/panel/scoreboard.qh>
  10 #include <client/items/items.qh>
  11 #include <client/mapvoting.qh>
  12 #include <client/mutators/_mod.qh>
  13 #include <client/shownames.qh>
  14 #include <client/view.qh>
  15 #include <client/weapons/projectile.qh>
  16 #include <common/deathtypes/all.qh>
  17 #include <common/effects/all.inc>
  18 #include <common/effects/all.qh>
  19 #include <common/effects/effect.qh>
  20 #include <common/effects/qc/_mod.qh>
  21 #include <common/ent_cs.qh>
  22 #include <common/gamemodes/gamemode/nexball/cl_nexball.qh>
  23 #include <common/items/_mod.qh>
  24 #include <common/mapinfo.qh>
  25 #include <common/mapobjects/_mod.qh>
  26 #include <common/minigames/cl_minigames.qh>
  27 #include <common/minigames/cl_minigames_hud.qh>
  28 #include <common/net_linked.qh>
  29 #include <common/net_notice.qh>
  30 #include <common/scores.qh>
  31 #include <common/vehicles/all.qh>
  32 #include <lib/csqcmodel/cl_model.qh>
  33 #include <lib/csqcmodel/interpolate.qh>
  34 #include <lib/warpzone/client.qh>
  35
  36 // --------------------------------------------------------------------------
  37 // BEGIN REQUIRED CSQC FUNCTIONS
  38 //include "main.qh"
  39
  40 #define DP_CSQC_ENTITY_REMOVE_IS_B0RKED
  41
  42 // CSQC_Init : Called every time the CSQC code is initialized (essentially at map load)
  43 // Useful for precaching things
  44
  45 void CSQC_Init()
  46 {
  47         prvm_language = strzone(cvar_string("prvm_language"));
  48
  49 #ifdef WATERMARK
  50         LOG_TRACEF("^4CSQC Build information: ^1%s", WATERMARK);
  51 #endif
  52
  53         {
  54                 int i = 0;
  55                 for ( ; i < 255; ++i)
  56                         if (getplayerkeyvalue(i, "viewentity") == "")
  57                                 break;
  58                 maxclients = i;
  59         }
  60
  61         // needs to be done so early because of the constants they create
  62         static_init();
  63         static_init_late();
  64         static_init_precache();
  65
  66         binddb = db_create();
  67         tempdb = db_create();
  68         ClientProgsDB = db_load("client.db");
  69
  70         draw_endBoldFont();
  71
  72         //registercommand("hud_configure");
  73         //registercommand("hud_save");
  74         //registercommand("menu_action");
  75
  76         ConsoleCommand_macro_init();
  77
  78         registercvar("hud_usecsqc", "1");
  79         registercvar("scoreboard_columns", "default");
  80
  81         registercvar("cl_nade_type", "3");
  82         registercvar("cl_pokenade_type", "zombie");
  83
  84         registercvar("cl_jumpspeedcap_min", "");
  85         registercvar("cl_jumpspeedcap_max", "");
  86
  87         registercvar("cl_shootfromfixedorigin", "");
  88
  89         registercvar("cl_multijump", "-1");
  90
  91         registercvar("cl_dodging", "0");
  92
  93         registercvar("cl_spawn_near_teammate", "1");
  94
  95         registercvar("cl_weapon_switch_reload", "1");
  96         registercvar("cl_weapon_switch_fallback_to_impulse", "1");
  97
  98         registercvar("cl_allow_uidranking", "1");
  99
 100         if(autocvar_cl_lockview)
 101                 cvar_set("cl_lockview", "0");
 102
 103         gametype = NULL;
 104
 105         postinit = false;
 106
 107         calledhooks = 0;
 108
 109         teams = Sort_Spawn();
 110         players = Sort_Spawn();
 111
 112         GetTeam(NUM_SPECTATOR, true); // add specs first
 113
 114         for (int w = 0; w <= WEP_LAST - WEP_FIRST; ++w)
 115                 weapon_accuracy[w] = -1;
 116
 117         // precaches
 118
 119         if(autocvar_cl_reticle)
 120         {
 121                 precache_pic("gfx/reticle_normal");
 122                 // weapon reticles are precached in weapon files
 123         }
 124
 125         {
 126                 get_mi_min_max_texcoords(1); // try the CLEVER way first
 127                 minimapname = strcat("gfx/", mi_shortname, "_radar");
 128                 shortmapname = mi_shortname;
 129
 130                 if (precache_pic(minimapname) == "")
 131                 {
 132                         // but maybe we have a non-clever minimap
 133                         minimapname = strcat("gfx/", mi_shortname, "_mini");
 134                         if (precache_pic(minimapname) == "")
 135                                 minimapname = ""; // FAIL
 136                         else
 137                                 get_mi_min_max_texcoords(0); // load new texcoords
 138                 }
 139
 140                 mi_center = (mi_min + mi_max) * 0.5;
 141                 mi_scale = mi_max - mi_min;
 142                 minimapname = strzone(minimapname);
 143         }
 144
 145         hud_skin_path = strzone(strcat("gfx/hud/", autocvar_hud_skin));
 146         LoadMenuSkinValues();
 147 }
 148
 149 // CSQC_Shutdown : Called every time the CSQC code is shutdown (changing maps, quitting, etc)
 150 void Shutdown()
 151 {
 152         WarpZone_Shutdown();
 153
 154         delete(teams);
 155         delete(players);
 156         db_close(binddb);
 157         db_close(tempdb);
 158         if(autocvar_cl_db_saveasdump)
 159                 db_dump(ClientProgsDB, "client.db");
 160         else
 161                 db_save(ClientProgsDB, "client.db");
 162         db_close(ClientProgsDB);
 163
 164         if(camera_active)
 165                 cvar_set("chase_active",ftos(chase_active_backup));
 166
 167         // unset the event chasecam's chase_active
 168         if(autocvar_chase_active < 0)
 169                 cvar_set("chase_active", "0");
 170
 171         if (autocvar_r_drawviewmodel < 0)
 172                 cvar_set("r_drawviewmodel", "0");
 173
 174         cvar_set("slowmo", cvar_defstring("slowmo")); // reset it back to 'default'
 175
 176         if (!isdemo())
 177         {
 178                 if (!(calledhooks & HOOK_START))
 179                         localcmd("\n_cl_hook_gamestart nop\n");
 180                 if (!(calledhooks & HOOK_END))
 181                         localcmd("\ncl_hook_gameend\n");
 182         }
 183
 184         localcmd("\ncl_hook_shutdown\n");
 185
 186         localcmd("\n-button12\n");
 187
 188         deactivate_minigame();
 189         HUD_MinigameMenu_Close(NULL, NULL, NULL);
 190
 191         ReplicateVars(REPLICATEVARS_DESTROY);
 192 }
 193
 194 void AuditLists()
 195 {
 196         entity e;
 197         entity prev;
 198
 199         prev = players;
 200         for(e = prev.sort_next; e; prev = e, e = e.sort_next)
 201         {
 202                 if(prev != e.sort_prev)
 203                         error(strcat("sort list chain error\nplease submit the output of 'prvm_edicts client' to the developers"));
 204         }
 205
 206         prev = teams;
 207         for(e = prev.sort_next; e; prev = e, e = e.sort_next)
 208         {
 209                 if(prev != e.sort_prev)
 210                         error(strcat("sort list chain error\nplease submit the output of 'prvm_edicts client' to the developers"));
 211         }
 212 }
 213
 214 float RegisterPlayer(entity player)
 215 {
 216         entity pl;
 217         AuditLists();
 218         for(pl = players.sort_next; pl; pl = pl.sort_next)
 219                 if(pl == player)
 220                         error("Player already registered!");
 221         player.sort_next = players.sort_next;
 222         player.sort_prev = players;
 223         if(players.sort_next)
 224                 players.sort_next.sort_prev = player;
 225         players.sort_next = player;
 226         AuditLists();
 227         return true;
 228 }
 229
 230 void RemovePlayer(entity player)
 231 {
 232         entity pl, parent;
 233         AuditLists();
 234         parent = players;
 235         for(pl = players.sort_next; pl && pl != player; pl = pl.sort_next)
 236                 parent = pl;
 237
 238         if(!pl)
 239         {
 240                 error("Trying to remove a player which is not in the playerlist!");
 241                 return;
 242         }
 243         parent.sort_next = player.sort_next;
 244         if(player.sort_next)
 245                 player.sort_next.sort_prev = parent;
 246         AuditLists();
 247 }
 248
 249 void MoveToLast(entity e)
 250 {
 251         AuditLists();
 252         entity ent = e.sort_next;
 253         while(ent)
 254         {
 255                 SORT_SWAP(ent, e);
 256                 ent = e.sort_next;
 257         }
 258         AuditLists();
 259 }
 260
 261 float RegisterTeam(entity Team)
 262 {
 263         assert_once(Team.team, eprint(Team));
 264         entity tm;
 265         AuditLists();
 266         for(tm = teams.sort_next; tm; tm = tm.sort_next)
 267                 if(tm == Team)
 268                         error("Team already registered!");
 269         Team.sort_next = teams.sort_next;
 270         Team.sort_prev = teams;
 271         if(teams.sort_next)
 272                 teams.sort_next.sort_prev = Team;
 273         teams.sort_next = Team;
 274         if(Team.team && Team.team != NUM_SPECTATOR)
 275                 ++team_count;
 276         AuditLists();
 277         return true;
 278 }
 279
 280 void RemoveTeam(entity Team)
 281 {
 282         entity tm, parent;
 283         AuditLists();
 284         parent = teams;
 285         for(tm = teams.sort_next; tm && tm != Team; tm = tm.sort_next)
 286                 parent = tm;
 287
 288         if(!tm)
 289         {
 290                 LOG_INFO(_("Trying to remove a team which is not in the teamlist!"));
 291                 return;
 292         }
 293         parent.sort_next = Team.sort_next;
 294         if(Team.sort_next)
 295                 Team.sort_next.sort_prev = parent;
 296         if(Team.team && Team.team != NUM_SPECTATOR)
 297                 --team_count;
 298         AuditLists();
 299 }
 300
 301 entity GetTeam(int Team, bool add)
 302 {
 303         TC(int, Team); TC(bool, add);
 304         int num = (Team == NUM_SPECTATOR) ? 16 : Team;
 305         if(teamslots[num])
 306                 return teamslots[num];
 307         if (!add)
 308                 return NULL;
 309         entity tm = new_pure(team);
 310         tm.team = Team;
 311         teamslots[num] = tm;
 312         RegisterTeam(tm);
 313         return tm;
 314 }
 315
 316 .float has_team;
 317 bool SetTeam(entity o, int Team)
 318 {
 319         TC(int, Team);
 320         //devassert_once(Team);
 321         entity tm;
 322         if(teamplay)
 323         {
 324                 switch(Team)
 325                 {
 326                         case -1:
 327                         case NUM_TEAM_1:
 328                         case NUM_TEAM_2:
 329                         case NUM_TEAM_3:
 330                         case NUM_TEAM_4:
 331                                 break;
 332                         default:
 333                                 if(GetTeam(Team, false) == NULL)
 334                                 {
 335                                         LOG_TRACEF("trying to switch to unsupported team %d", Team);
 336                                         Team = NUM_SPECTATOR;
 337                                 }
 338                                 break;
 339                 }
 340         }
 341         else
 342         {
 343                 switch(Team)
 344                 {
 345                         case -1:
 346                         case 0:
 347                                 break;
 348                         default:
 349                                 if(GetTeam(Team, false) == NULL)
 350                                 {
 351                                         LOG_TRACEF("trying to switch to unsupported team %d", Team);
 352                                         Team = NUM_SPECTATOR;
 353                                 }
 354                                 break;
 355                 }
 356         }
 357         if(Team == -1) // leave
 358         {
 359                 if(o.has_team)
 360                 {
 361                         tm = GetTeam(o.team, false);
 362                         tm.team_size -= 1;
 363                         o.has_team = 0;
 364                         return true;
 365                 }
 366         }
 367         else
 368         {
 369                 if (!o.has_team)
 370                 {
 371                         o.team = Team;
 372                         tm = GetTeam(Team, true);
 373                         tm.team_size += 1;
 374                         o.has_team = 1;
 375                         return true;
 376                 }
 377                 else if(Team != o.team)
 378                 {
 379                         tm = GetTeam(o.team, false);
 380                         tm.team_size -= 1;
 381                         o.team = Team;
 382                         tm = GetTeam(Team, true);
 383                         tm.team_size += 1;
 384                         return true;
 385                 }
 386         }
 387         return false;
 388 }
 389
 390 void Playerchecker_Think(entity this)
 391 {
 392         int i;
 393         entity e;
 394         for(i = 0; i < maxclients; ++i)
 395         {
 396                 e = playerslots[i];
 397                 if(entcs_GetName(i) == "")
 398                 {
 399                         if(e.sort_prev)
 400                         {
 401                                 // player disconnected
 402                                 SetTeam(e, -1);
 403                                 RemovePlayer(e);
 404                                 e.sort_prev = NULL;
 405                                 //e.gotscores = 0;
 406                         }
 407                 }
 408                 else
 409                 {
 410                         if (!e.sort_prev)
 411                         {
 412                                 // player connected
 413                                 if (!e)
 414                                 {
 415                                         playerslots[i] = e = new_pure(playerslot);
 416                                 }
 417                                 e.sv_entnum = i;
 418                                 e.ping = 0;
 419                                 e.ping_packetloss = 0;
 420                                 e.ping_movementloss = 0;
 421                                 //e.gotscores = 0; // we might already have the scores...
 422                                 int t = entcs_GetScoreTeam(i);
 423                                 if (t) SetTeam(e, t); // will not hurt; later updates come with Scoreboard_UpdatePlayerTeams
 424                                 RegisterPlayer(e);
 425                                 Scoreboard_UpdatePlayerPos(e);
 426                         }
 427                 }
 428         }
 429         this.nextthink = time + 0.2;
 430 }
 431
 432 void PostInit()
 433 {
 434         entity playerchecker = new_pure(playerchecker);
 435         setthink(playerchecker, Playerchecker_Think);
 436         playerchecker.nextthink = time + 0.2;
 437
 438         TrueAim_Init();
 439
 440         // this can't be called in CSQC_Init as it'd send cvars too early
 441         ReplicateVars_Start();
 442
 443         postinit = true;
 444 }
 445
 446 // CSQC_InputEvent : Used to perform actions based on any key pressed, key released and mouse on the client.
 447 // Return value should be 1 if CSQC handled the input, otherwise return 0 to have the input passed to the engine.
 448 // All keys are in ascii.
 449 // bInputType = 0 is key pressed, 1 is key released, 2 and 3 are mouse input.
 450 // In the case of keyboard input, nPrimary is the ascii code, and nSecondary is 0.
 451 // In the case of mouse input, nPrimary is xdelta, nSecondary is ydelta.
 452 // In the case of mouse input after a setcursormode(1) call, nPrimary is xpos, nSecondary is ypos.
 453 float CSQC_InputEvent(int bInputType, float nPrimary, float nSecondary)
 454 {
 455         TC(int, bInputType);
 456         bool override = false;
 457
 458         override |= HUD_Scoreboard_InputEvent(bInputType, nPrimary, nSecondary);
 459         if (override)
 460                 return true;
 461
 462         override |= HUD_Panel_InputEvent(bInputType, nPrimary, nSecondary);
 463         if (override)
 464                 return true;
 465
 466         override |= HUD_Panel_Chat_InputEvent(bInputType, nPrimary, nSecondary);
 467
 468         override |= QuickMenu_InputEvent(bInputType, nPrimary, nSecondary);
 469
 470         override |= HUD_Radar_InputEvent(bInputType, nPrimary, nSecondary);
 471
 472         override |= MapVote_InputEvent(bInputType, nPrimary, nSecondary);
 473
 474         override |= HUD_Minigame_InputEvent(bInputType, nPrimary, nSecondary);
 475
 476         if(override)
 477                 return true;
 478
 479         if(bInputType == 3 || bInputType == 2)
 480                 return false;
 481
 482         // at this point bInputType can only be 0 or 1 (key pressed or released)
 483         bool key_pressed = (bInputType == 0);
 484
 485         if(key_pressed) {
 486                 if(nPrimary == K_ALT) hudShiftState |= S_ALT;
 487                 if(nPrimary == K_CTRL) hudShiftState |= S_CTRL;
 488                 if(nPrimary == K_SHIFT) hudShiftState |= S_SHIFT;
 489         }
 490         else {
 491                 if(nPrimary == K_ALT) hudShiftState -= (hudShiftState & S_ALT);
 492                 if(nPrimary == K_CTRL) hudShiftState -= (hudShiftState & S_CTRL);
 493                 if(nPrimary == K_SHIFT) hudShiftState -= (hudShiftState & S_SHIFT);
 494         }
 495
 496         if (nPrimary == K_ESCAPE && !(hudShiftState & S_SHIFT) && key_pressed)
 497         {
 498                 if (!isdemo() && cvar("_menu_gamemenu_dialog_available"))
 499                 {
 500                         localcmd("\nmenu_showgamemenudialog\n");
 501                         return true;
 502                 }
 503         }
 504
 505         return false;
 506 }
 507
 508 // END REQUIRED CSQC FUNCTIONS
 509 // --------------------------------------------------------------------------
 510
 511 // --------------------------------------------------------------------------
 512 // BEGIN OPTIONAL CSQC FUNCTIONS
 513
 514 void Ent_RemovePlayerScore(entity this)
 515 {
 516         if(this.owner) {
 517                 SetTeam(this.owner, -1);
 518                 this.owner.gotscores = 0;
 519                 FOREACH(Scores, true, {
 520                         this.owner.(scores(it)) = 0; // clear all scores
 521                 });
 522         }
 523 }
 524
 525 NET_HANDLE(ENT_CLIENT_SCORES, bool isnew)
 526 {
 527         make_pure(this);
 528         entity o;
 529
 530         // damnit -.- don't want to go change every single .sv_entnum in hud.qc AGAIN
 531         // (no I've never heard of M-x replace-string, sed, or anything like that)
 532         bool isNew = !this.owner; // workaround for DP bug
 533         int n = ReadByte()-1;
 534
 535 #ifdef DP_CSQC_ENTITY_REMOVE_IS_B0RKED
 536         if(!isNew && n != this.sv_entnum)
 537         {
 538                 //print("A CSQC entity changed its owner!\n");
 539                 LOG_INFOF("A CSQC entity changed its owner! (edict: %d, classname: %s)", etof(this), this.classname);
 540                 isNew = true;
 541                 Ent_Remove(this);
 542         }
 543 #endif
 544
 545         this.sv_entnum = n;
 546
 547         o = playerslots[this.sv_entnum];
 548         if (!o)
 549         {
 550                 o = playerslots[this.sv_entnum] = new_pure(playerslot);
 551         }
 552         this.owner = o;
 553         o.sv_entnum = this.sv_entnum;
 554         o.gotscores = 1;
 555
 556         //if (!o.sort_prev)
 557         //      RegisterPlayer(o);
 558         //playerchecker will do this for us later, if it has not already done so
 559
 560         int sf = ReadShort();
 561         int lf = ReadShort();
 562         FOREACH(Scores, true, {
 563                 int p = 1 << (i % 16);
 564                 if (sf & p)
 565                 {
 566                         if (lf & p)
 567                                 o.(scores(it)) = ReadInt24_t();
 568                         else
 569                                 o.(scores(it)) = ReadChar();
 570                 }
 571         });
 572
 573         return = true;
 574
 575         if(o.sort_prev)
 576                 Scoreboard_UpdatePlayerPos(o); // if not registered, we cannot do this yet!
 577
 578         this.entremove = Ent_RemovePlayerScore;
 579 }
 580
 581 NET_HANDLE(ENT_CLIENT_TEAMSCORES, bool isnew)
 582 {
 583         make_pure(this);
 584         int i;
 585
 586         this.team = ReadByte();
 587         entity o = this.owner = GetTeam(this.team, true); // these team numbers can always be trusted
 588
 589 #if MAX_TEAMSCORE <= 8
 590         int sf = ReadByte();
 591         int lf = ReadByte();
 592 #else
 593         int sf = ReadShort();
 594         int lf = ReadShort();
 595 #endif
 596         for(i = 0; i < MAX_TEAMSCORE; ++i)
 597                 if(sf & BIT(i))
 598                 {
 599                         if(lf & BIT(i))
 600                                 o.(teamscores(i)) = ReadInt24_t();
 601                         else
 602                                 o.(teamscores(i)) = ReadChar();
 603                 }
 604
 605         return = true;
 606
 607         Scoreboard_UpdateTeamPos(o);
 608 }
 609
 610 NET_HANDLE(ENT_CLIENT_CLIENTDATA, bool isnew)
 611 {
 612         make_pure(this);
 613         float newspectatee_status;
 614
 615         int f = ReadByte();
 616
 617         scoreboard_showscores_force = (f & BIT(0));
 618
 619         if(f & BIT(1))
 620         {
 621                 newspectatee_status = ReadByte();
 622                 if(newspectatee_status == player_localnum + 1)
 623                         newspectatee_status = -1; // observing
 624         }
 625         else
 626                 newspectatee_status = 0;
 627
 628         spectatorbutton_zoom = (f & BIT(2));
 629
 630         if(f & BIT(4))
 631         {
 632                 num_spectators = ReadByte();
 633
 634                 float i, slot;
 635
 636                 for(i = 0; i < MAX_SPECTATORS; ++i)
 637                         spectatorlist[i] = 0; // reset list first
 638
 639                 int limit = min(num_spectators, MAX_SPECTATORS);
 640                 for(i = 0; i < limit; ++i)
 641                 {
 642                         slot = ReadByte();
 643                         spectatorlist[i] = slot - 1;
 644                 }
 645         }
 646         else
 647         {
 648                 for(int j = 0; j < MAX_SPECTATORS; ++j)
 649                         spectatorlist[j] = 0; // reset list if showspectators has been turned off
 650                 num_spectators = 0;
 651         }
 652
 653         return = true;
 654
 655         if(newspectatee_status != spectatee_status)
 656         {
 657                 // clear race stuff
 658                 race_laptime = 0;
 659                 race_checkpointtime = 0;
 660                 hud_dynamic_shake_factor = -1;
 661                 spectatee_status_changed_time = time;
 662         }
 663         if (autocvar_hud_panel_healtharmor_progressbar_gfx)
 664         {
 665                 if ( (spectatee_status == -1 && newspectatee_status > 0) //before observing, now spectating
 666                   || (spectatee_status > 0 && newspectatee_status > 0 && spectatee_status != newspectatee_status) //changed spectated player
 667                 )
 668                         prev_p_health = -1;
 669                 else if(spectatee_status && !newspectatee_status) //before observing/spectating, now playing
 670                         prev_health = -1;
 671         }
 672         spectatee_status = newspectatee_status;
 673
 674         // we could get rid of spectatee_status, and derive it from player_localentnum and player_localnum
 675 }
 676
 677 NET_HANDLE(ENT_CLIENT_NAGGER, bool isnew)
 678 {
 679         make_pure(this);
 680         int i, j, b, f;
 681
 682         int nags = ReadByte(); // NAGS NAGS NAGS NAGS NAGS NAGS NADZ NAGS NAGS NAGS
 683
 684         if(!(nags & BIT(2)))
 685         {
 686                 strfree(vote_called_vote);
 687                 vote_active = 0;
 688         }
 689         else
 690         {
 691                 vote_active = 1;
 692         }
 693
 694         if(nags & BIT(6))
 695         {
 696                 vote_yescount = ReadByte();
 697                 vote_nocount = ReadByte();
 698                 vote_needed = ReadByte();
 699                 vote_highlighted = ReadChar();
 700         }
 701
 702         if(nags & BIT(7))
 703         {
 704                 strcpy(vote_called_vote, ReadString());
 705         }
 706
 707         if(nags & 1)
 708         {
 709                 for(j = 0; j < maxclients; ++j)
 710                         if(playerslots[j])
 711                                 playerslots[j].ready = true;
 712                 for(i = 1; i <= maxclients; i += 8)
 713                 {
 714                         f = ReadByte();
 715                         for(j = i-1, b = BIT(0); b < BIT(8); b <<= 1, ++j)
 716                                 if (!(f & b))
 717                                         if(playerslots[j])
 718                                                 playerslots[j].ready = false;
 719                 }
 720         }
 721
 722         return = true;
 723
 724         ready_waiting = (nags & BIT(0));
 725         ready_waiting_for_me = (nags & BIT(1));
 726         vote_waiting = (nags & BIT(2));
 727         vote_waiting_for_me = (nags & BIT(3));
 728         warmup_stage = (nags & BIT(4));
 729 }
 730
 731 NET_HANDLE(ENT_CLIENT_ELIMINATEDPLAYERS, bool isnew)
 732 {
 733         make_pure(this);
 734         int sf = 0;
 735         serialize(byte, 0, sf);
 736         if (sf & 1) {
 737                 for (int j = 0; j < maxclients; ++j) {
 738                         if (playerslots[j]) {
 739                                 playerslots[j].eliminated = true;
 740                         }
 741                 }
 742                 for (int i = 1; i <= maxclients; i += 8) {
 743                         int f = 0;
 744                         serialize(byte, 0, f);
 745                         for (int b = 0; b < 8; ++b) {
 746                                 if (f & BIT(b)) continue;
 747                                 int j = i - 1 + b;
 748                                 if (playerslots[j]) {
 749                                         playerslots[j].eliminated = false;
 750                                 }
 751                         }
 752                 }
 753         }
 754         return true;
 755 }
 756
 757 NET_HANDLE(ENT_CLIENT_RANDOMSEED, bool isnew)
 758 {
 759         make_pure(this);
 760         prandom_debug();
 761         float s = ReadShort();
 762         psrandom(s);
 763         return true;
 764 }
 765
 766 NET_HANDLE(ENT_CLIENT_ACCURACY, bool isnew)
 767 {
 768         make_pure(this);
 769         int sf = ReadInt24_t();
 770         if (sf == 0) {
 771                 for (int w = 0; w <= WEP_LAST - WEP_FIRST; ++w)
 772                         weapon_accuracy[w] = -1;
 773                 return true;
 774         }
 775
 776         int f = 1;
 777         for (int w = 0; w <= WEP_LAST - WEP_FIRST; ++w) {
 778                 if (sf & f) {
 779                         int b = ReadByte();
 780                         if (b == 0)
 781                                 weapon_accuracy[w] = -1;
 782                         else if (b == 255)
 783                                 weapon_accuracy[w] = 1.0; // no better error handling yet, sorry
 784                         else
 785                                 weapon_accuracy[w] = (b - 1.0) / 100.0;
 786                 }
 787                 f = (f == 0x800000) ? 1 : f * 2;
 788         }
 789         return true;
 790 }
 791
 792 void Spawn_Draw(entity this)
 793 {
 794         bool dodraw = autocvar_cl_spawn_point_particles;
 795         if(dodraw && autocvar_cl_spawn_point_dist_max)
 796         {
 797                 vector org = getpropertyvec(VF_ORIGIN);
 798                 dodraw = vdist(org - this.origin, <, autocvar_cl_spawn_point_dist_max);
 799         }
 800
 801         if(dodraw)
 802                 pointparticles(((!teamplay) ? EFFECT_SPAWNPOINT_NEUTRAL : EFFECT_SPAWNPOINT(this.team - 1)), this.origin + '0 0 28', '0 0 2', bound(0, frametime, 0.1));
 803 }
 804
 805 NET_HANDLE(ENT_CLIENT_SPAWNPOINT, bool is_new)
 806 {
 807         float teamnum = (ReadByte() - 1);
 808         vector spn_origin = ReadVector();
 809
 810         this.team = (teamnum + 1);
 811
 812         //if(is_new)
 813         //{
 814                 this.origin = spn_origin;
 815                 setsize(this, PL_MIN_CONST, PL_MAX_CONST);
 816                 //droptofloor();
 817
 818                 /*if(autocvar_cl_spawn_point_model) // needs a model first
 819                 {
 820                         this.mdl = "models/spawnpoint.md3";
 821                         this.colormod = Team_ColorRGB(teamnum);
 822                         precache_model(this.mdl);
 823                         setmodel(this, this.mdl);
 824                         this.drawmask = MASK_NORMAL;
 825                         //this.move_movetype = MOVETYPE_NOCLIP;
 826                         //this.draw = Spawn_Draw;
 827                         IL_PUSH(g_drawables, this);
 828                 }*/
 829                 this.draw = Spawn_Draw;
 830                 if (is_new) IL_PUSH(g_drawables, this);
 831         //}
 832
 833         //printf("Ent_ReadSpawnPoint(is_new = %d); origin = %s, team = %d, effect = %d\n", is_new, vtos(this.origin), teamnum, this.cnt);
 834         return true;
 835 }
 836
 837 NET_HANDLE(ENT_CLIENT_SPAWNEVENT, bool is_new)
 838 {
 839         // If entnum is 0, ONLY do the local spawn actions
 840         // this way the server can disable the sending of
 841         // spawn origin or such to clients if wanted.
 842         float entnum = ReadByte();
 843
 844         if(entnum)
 845         {
 846                 this.origin = ReadVector();
 847
 848                 if(is_new)
 849                 {
 850                         float teamnum = entcs_GetTeam(entnum - 1);
 851
 852                         if(autocvar_cl_spawn_event_particles)
 853                         {
 854                                 switch(teamnum)
 855                                 {
 856                                         case NUM_TEAM_1: pointparticles(EFFECT_SPAWN_RED, this.origin, '0 0 0', 1); break;
 857                                         case NUM_TEAM_2: pointparticles(EFFECT_SPAWN_BLUE, this.origin, '0 0 0', 1); break;
 858                                         case NUM_TEAM_3: pointparticles(EFFECT_SPAWN_YELLOW, this.origin, '0 0 0', 1); break;
 859                                         case NUM_TEAM_4: pointparticles(EFFECT_SPAWN_PINK, this.origin, '0 0 0', 1); break;
 860                                         default: pointparticles(EFFECT_SPAWN_NEUTRAL, this.origin, '0 0 0', 1); break;
 861                                 }
 862                         }
 863                         if(autocvar_cl_spawn_event_sound)
 864                         {
 865                                 sound(this, CH_TRIGGER, SND_SPAWN, VOL_BASE, ATTEN_NORM);
 866                         }
 867                 }
 868         }
 869         return = true;
 870
 871         // local spawn actions
 872         if(is_new && (!entnum || (entnum == player_localentnum)))
 873         {
 874                 if(autocvar_cl_spawnzoom && !autocvar_cl_lockview)
 875                 {
 876                         zoomin_effect = 1;
 877                         current_viewzoom = (1 / bound(1, autocvar_cl_spawnzoom_factor, 16));
 878                 }
 879
 880                 if(autocvar_cl_unpress_zoom_on_spawn)
 881                 {
 882                         localcmd("-zoom\n");
 883                         button_zoom = false;
 884                 }
 885                 HUD_Radar_Hide_Maximized();
 886         }
 887         //printf("Ent_ReadSpawnEvent(is_new = %d); origin = %s, entnum = %d, localentnum = %d\n", is_new, vtos(this.origin), entnum, player_localentnum);
 888 }
 889
 890 // CSQC_Ent_Update : Called every frame that the server has indicated an update to the SSQC / CSQC entity has occured.
 891 // The parameter isnew reflects if the entity is "new" to the client, meaning it just came into the client's PVS.
 892 void CSQC_Ent_Update(entity this, bool isnew)
 893 {
 894         this.sourceLoc = __FILE__":"STR(__LINE__);
 895         int t = ReadByte();
 896
 897         // set up the "time" global for received entities to be correct for interpolation purposes
 898         float savetime = time;
 899         if(servertime)
 900         {
 901                 time = servertime;
 902         }
 903         else
 904         {
 905                 serverprevtime = time;
 906                 serverdeltatime = STAT(MOVEVARS_TICRATE) * STAT(MOVEVARS_TIMESCALE);
 907                 time = serverprevtime + serverdeltatime;
 908         }
 909
 910 #ifdef DP_CSQC_ENTITY_REMOVE_IS_B0RKED
 911         if (this.enttype)
 912         {
 913                 if (t != this.enttype || isnew)
 914                 {
 915                         LOG_INFOF("A CSQC entity changed its type! (edict: %d, server: %d, type: %d -> %d)", etof(this), this.entnum, this.enttype, t);
 916                         Ent_Remove(this);
 917                         ONREMOVE(this);
 918                         clearentity(this);
 919                         isnew = true;
 920                 }
 921         }
 922         else
 923         {
 924                 if (!isnew)
 925                 {
 926                         LOG_INFOF("A CSQC entity appeared out of nowhere! (edict: %d, server: %d, type: %d)", etof(this), this.entnum, t);
 927                         isnew = true;
 928                 }
 929         }
 930 #endif
 931         this.enttype = t;
 932         bool done = false;
 933         FOREACH(LinkedEntities, it.m_id == t, {
 934                 if (isnew) this.classname = it.netname;
 935                 if (autocvar_developer_csqcentities)
 936                         LOG_INFOF("CSQC_Ent_Update(%i, %d) at %f {.entnum=%d, .enttype=%d} t=%s (%d)", this, isnew, savetime, this.entnum, this.enttype, this.classname, t);
 937                 done = it.m_read(this, NULL, isnew);
 938                 MUTATOR_CALLHOOK(Ent_Update, this, isnew);
 939                 break;
 940         });
 941         time = savetime;
 942         if (!done)
 943         {
 944                 LOG_FATALF("CSQC_Ent_Update(%i, %d) at %f {.entnum=%d, .enttype=%d} t=%s (%d)", this, isnew, savetime, this.entnum, this.enttype, this.classname, t);
 945         }
 946 }
 947
 948 // Destructor, but does NOT deallocate the entity by calling remove(). Also
 949 // used when an entity changes its type. For an entity that someone interacts
 950 // with others, make sure it can no longer do so.
 951 void Ent_Remove(entity this)
 952 {
 953         if(this.entremove) this.entremove(this);
 954
 955         if(this.skeletonindex)
 956         {
 957                 skel_delete(this.skeletonindex);
 958                 this.skeletonindex = 0;
 959         }
 960
 961         if(this.snd_looping > 0)
 962         {
 963                 sound(this, this.snd_looping, SND_Null, VOL_BASE, autocvar_cl_jetpack_attenuation);
 964                 this.snd_looping = 0;
 965         }
 966
 967         this.enttype = 0;
 968         this.classname = "";
 969         this.draw = func_null;
 970         this.entremove = func_null;
 971         // TODO possibly set more stuff to defaults
 972 }
 973 // CSQC_Ent_Remove : Called when the server requests a SSQC / CSQC entity to be removed.  Essentially call remove(this) as well.
 974 void CSQC_Ent_Remove(entity this)
 975 {
 976         if (autocvar_developer_csqcentities) LOG_INFOF("CSQC_Ent_Remove() with this=%i {.entnum=%d, .enttype=%d}", this, this.entnum, this.enttype);
 977         if (wasfreed(this))
 978         {
 979                 LOG_WARN("CSQC_Ent_Remove called for already removed entity. Packet loss?");
 980                 return;
 981         }
 982         if (this.enttype) Ent_Remove(this);
 983         delete(this);
 984 }
 985
 986 void Gamemode_Init()
 987 {
 988         if (!isdemo())
 989         {
 990                 if(!(calledhooks & HOOK_START))
 991                         localcmd("\n_cl_hook_gamestart ", MapInfo_Type_ToString(gametype), "\n");
 992                 calledhooks |= HOOK_START;
 993         }
 994 }
 995 // CSQC_Parse_StuffCmd : Provides the stuffcmd string in the first parameter that the server provided.  To execute standard behavior, simply execute localcmd with the string.
 996 void CSQC_Parse_StuffCmd(string strMessage)
 997 {
 998         if (autocvar_developer_csqcentities) LOG_INFOF("CSQC_Parse_StuffCmd(\"%s\")", strMessage);
 999         localcmd(strMessage);
1000 }
1001 // CSQC_Parse_Print : Provides the print string in the first parameter that the server provided.  To execute standard behavior, simply execute print with the string.
1002 void CSQC_Parse_Print(string strMessage)
1003 {
1004         if (autocvar_developer_csqcentities) LOG_INFOF("CSQC_Parse_Print(\"%s\")", strMessage);
1005         print(ColorTranslateRGB(strMessage));
1006 }
1007
1008 // CSQC_Parse_CenterPrint : Provides the centerprint_AddStandard string in the first parameter that the server provided.
1009 void CSQC_Parse_CenterPrint(string strMessage)
1010 {
1011         if (autocvar_developer_csqcentities) LOG_INFOF("CSQC_Parse_CenterPrint(\"%s\")", strMessage);
1012         centerprint_AddStandard(strMessage);
1013 }
1014
1015 // CSQC_Parse_TempEntity : Handles all temporary entity network data in the CSQC layer.
1016 // You must ALWAYS first acquire the temporary ID, which is sent as a byte.
1017 // Return value should be 1 if CSQC handled the temporary entity, otherwise return 0 to have the engine process the event.
1018 bool CSQC_Parse_TempEntity()
1019 {
1020         // Acquire TE ID
1021         int nTEID = ReadByte();
1022
1023         FOREACH(TempEntities, it.m_id == nTEID, {
1024                 if (autocvar_developer_csqcentities)
1025                         LOG_INFOF("CSQC_Parse_TempEntity() nTEID=%s (%d)", it.netname, nTEID);
1026                 return it.m_read(NULL, NULL, true);
1027         });
1028
1029         if (autocvar_developer_csqcentities)
1030                 LOG_INFOF("CSQC_Parse_TempEntity() with nTEID=%d", nTEID);
1031
1032         // No special logic for this temporary entity; return 0 so the engine can handle it
1033         return false;
1034 }
1035
1036 string forcefog;
1037 void Fog_Force()
1038 {
1039         if (autocvar_cl_orthoview && autocvar_cl_orthoview_nofog)
1040                 localcmd("\nr_drawfog 0\n");
1041         else if (forcefog != "")
1042                 localcmd(sprintf("\nfog %s\nr_fog_exp2 0\nr_drawfog 1\n", forcefog));
1043 }
1044
1045 bool net_handle_ServerWelcome();
1046 NET_HANDLE(ENT_CLIENT_SCORES_INFO, bool isnew)
1047 {
1048         make_pure(this);
1049         gametype = ReadRegistered(Gametypes);
1050         teamplay = _MapInfo_GetTeamPlayBool(gametype);
1051         HUD_ModIcons_SetFunc();
1052         FOREACH(Scores, true, {
1053                 strcpy(scores_label(it), ReadString());
1054                 scores_flags(it) = ReadByte();
1055         });
1056         for (int i = 0; i < MAX_TEAMSCORE; ++i)
1057         {
1058                 strcpy(teamscores_label(i), ReadString());
1059                 teamscores_flags(i) = ReadByte();
1060         }
1061         bool welcome_msg_too = ReadByte();
1062         if (welcome_msg_too)
1063                 net_handle_ServerWelcome();
1064         return = true;
1065         Scoreboard_InitScores();
1066         Gamemode_Init();
1067 }
1068
1069 NET_HANDLE(ENT_CLIENT_INIT, bool isnew)
1070 {
1071         nb_pb_period = ReadByte() / 32; //Accuracy of 1/32th
1072
1073         hook_shotorigin[0] = decompressShotOrigin(ReadInt24_t());
1074         hook_shotorigin[1] = decompressShotOrigin(ReadInt24_t());
1075         hook_shotorigin[2] = decompressShotOrigin(ReadInt24_t());
1076         hook_shotorigin[3] = decompressShotOrigin(ReadInt24_t());
1077         arc_shotorigin[0] = decompressShotOrigin(ReadInt24_t());
1078         arc_shotorigin[1] = decompressShotOrigin(ReadInt24_t());
1079         arc_shotorigin[2] = decompressShotOrigin(ReadInt24_t());
1080         arc_shotorigin[3] = decompressShotOrigin(ReadInt24_t());
1081
1082         strcpy(forcefog, ReadString());
1083
1084         armorblockpercent = ReadByte() / 255.0;
1085         damagepush_speedfactor = ReadByte() / 255.0;
1086
1087         serverflags = ReadByte();
1088
1089         g_trueaim_minrange = ReadCoord();
1090
1091         return = true;
1092
1093         MUTATOR_CALLHOOK(Ent_Init);
1094
1095         if (!postinit) PostInit();
1096 }
1097
1098 float GetSpeedUnitFactor(int speed_unit)
1099 {
1100         switch(speed_unit)
1101         {
1102                 default:
1103                 case 1: return 1.0;
1104                 case 2: return 0.0254;
1105                 case 3: return 0.0254 * 3.6;
1106                 case 4: return 0.0254 * 3.6 * 0.6213711922;
1107                 case 5: return 0.0254 * 1.943844492; // 1 m/s = 1.943844492 knots, because 1 knot = 1.852 km/h
1108         }
1109 }
1110
1111 string GetSpeedUnit(int speed_unit)
1112 {
1113         switch(speed_unit)
1114         {
1115                 // translator-friendly strings without the initial space
1116                 default:
1117                 case 1: return strcat(" ", _("qu/s"));
1118                 case 2: return strcat(" ", _("m/s"));
1119                 case 3: return strcat(" ", _("km/h"));
1120                 case 4: return strcat(" ", _("mph"));
1121                 case 5: return strcat(" ", _("knots"));
1122         }
1123 }
1124
1125 NET_HANDLE(TE_CSQC_RACE, bool isNew)
1126 {
1127         int b = ReadByte();
1128
1129         switch (b)
1130         {
1131                 case RACE_NET_CHECKPOINT_HIT_QUALIFYING:
1132                         race_checkpoint = ReadByte();
1133                         race_time = ReadInt24_t();
1134                         race_previousbesttime = ReadInt24_t();
1135                         race_mypreviousbesttime = ReadInt24_t();
1136                         string pbestname = ReadString();
1137                         if(autocvar_cl_race_cptimes_onlyself)
1138                         {
1139                                 race_previousbesttime = race_mypreviousbesttime;
1140                                 race_mypreviousbesttime = 0;
1141                                 strcpy(race_previousbestname, "");
1142                         }
1143                         else
1144                                 strcpy(race_previousbestname, pbestname);
1145
1146                         race_checkpointtime = time;
1147
1148                         if(race_checkpoint == 0 || race_checkpoint == 254)
1149                         {
1150                                 race_penaltyaccumulator = 0;
1151                                 race_laptime = time; // valid
1152                         }
1153                         break;
1154
1155                 case RACE_NET_CHECKPOINT_CLEAR:
1156                         race_laptime = 0;
1157                         race_checkpointtime = 0;
1158                         break;
1159
1160                 case RACE_NET_CHECKPOINT_NEXT_SPEC_QUALIFYING:
1161                         race_laptime = ReadCoord();
1162                         race_checkpointtime = -99999;
1163                         // fall through
1164                 case RACE_NET_CHECKPOINT_NEXT_QUALIFYING:
1165                         race_nextcheckpoint = ReadByte();
1166
1167                         race_nextbesttime = ReadInt24_t();
1168                         if(b != RACE_NET_CHECKPOINT_NEXT_SPEC_QUALIFYING) // not while spectating (matches server)
1169                                 race_mybesttime = ReadInt24_t();
1170                         string newname = ReadString();
1171                         if(autocvar_cl_race_cptimes_onlyself && b != RACE_NET_CHECKPOINT_NEXT_SPEC_QUALIFYING)
1172                         {
1173                                 race_nextbesttime = race_mybesttime;
1174                                 race_mybesttime = 0;
1175                                 strcpy(race_nextbestname, "");
1176                         }
1177                         else
1178                                 strcpy(race_nextbestname, newname);
1179                         break;
1180
1181                 case RACE_NET_CHECKPOINT_HIT_RACE:
1182                         race_mycheckpoint = ReadByte();
1183                         race_mycheckpointtime = time;
1184                         race_mycheckpointdelta = ReadInt24_t();
1185                         race_mycheckpointlapsdelta = ReadByte();
1186                         if(race_mycheckpointlapsdelta >= 128)
1187                                 race_mycheckpointlapsdelta -= 256;
1188                         int who = ReadByte();
1189                         if(who)
1190                                 strcpy(race_mycheckpointenemy, entcs_GetName(who - 1));
1191                         else
1192                                 strcpy(race_mycheckpointenemy, ""); // TODO: maybe string_null works fine here?
1193                         break;
1194
1195                 case RACE_NET_CHECKPOINT_HIT_RACE_BY_OPPONENT:
1196                         race_othercheckpoint = ReadByte();
1197                         race_othercheckpointtime = time;
1198                         race_othercheckpointdelta = ReadInt24_t();
1199                         race_othercheckpointlapsdelta = ReadByte();
1200                         if(race_othercheckpointlapsdelta >= 128)
1201                                 race_othercheckpointlapsdelta -= 256;
1202                         int what = ReadByte();
1203                         if(what)
1204                                 strcpy(race_othercheckpointenemy, entcs_GetName(what - 1));
1205                         else
1206                                 strcpy(race_othercheckpointenemy, ""); // TODO: maybe string_null works fine here?
1207                         break;
1208
1209                 case RACE_NET_PENALTY_RACE:
1210                 case RACE_NET_PENALTY_QUALIFYING:
1211                         race_penaltyeventtime = time;
1212                         race_penaltytime = ReadShort();
1213                         string reason = ReadString();
1214                         if (reason == "missing a checkpoint")
1215                                 reason = _("missing a checkpoint");
1216                         strcpy(race_penaltyreason, reason);
1217                         if (b == RACE_NET_PENALTY_QUALIFYING)
1218                                 race_penaltyaccumulator += race_penaltytime;
1219                         break;
1220
1221                 case RACE_NET_SERVER_RECORD:
1222                         race_server_record = ReadInt24_t();
1223                         break;
1224                 case RACE_NET_SPEED_AWARD:
1225                         race_speedaward = ReadInt24_t() * GetSpeedUnitFactor(autocvar_hud_panel_physics_speed_unit);
1226                         strcpy(race_speedaward_holder, ReadString());
1227                         break;
1228                 case RACE_NET_SPEED_AWARD_BEST:
1229                         race_speedaward_alltimebest = ReadInt24_t() * GetSpeedUnitFactor(autocvar_hud_panel_physics_speed_unit);
1230                         strcpy(race_speedaward_alltimebest_holder, ReadString());
1231                         break;
1232                 case RACE_NET_RANKINGS_CNT:
1233                         RANKINGS_DISPLAY_CNT = ReadByte();
1234                         break;
1235                 case RACE_NET_SERVER_RANKINGS:
1236                         float prevpos, del;
1237                         int pos = ReadShort();
1238                         prevpos = ReadShort();
1239                         del = ReadShort();
1240
1241                         // move other rankings out of the way
1242                         int i;
1243                         if (prevpos) {
1244                                 int m = min(prevpos, RANKINGS_DISPLAY_CNT);
1245                                 for (i=m-1; i>pos-1; --i) {
1246                                         grecordtime[i] = grecordtime[i-1];
1247                                         strcpy(grecordholder[i], grecordholder[i-1]);
1248                                 }
1249                         } else if (del) { // a record has been deleted by the admin
1250                                 for (i=pos-1; i<= RANKINGS_DISPLAY_CNT-1; ++i) {
1251                                         if (i == RANKINGS_DISPLAY_CNT-1) { // clear out last record
1252                                                 grecordtime[i] = 0;
1253                                                 strfree(grecordholder[i]);
1254                                         }
1255                                         else {
1256                                                 grecordtime[i] = grecordtime[i+1];
1257                                                 strcpy(grecordholder[i], grecordholder[i+1]);
1258                                         }
1259                                 }
1260                         } else { // player has no ranked record yet
1261                                 for (i=RANKINGS_DISPLAY_CNT-1;i>pos-1;--i) {
1262                                         grecordtime[i] = grecordtime[i-1];
1263                                         strcpy(grecordholder[i], grecordholder[i-1]);
1264                                 }
1265                         }
1266
1267                         if (grecordtime[RANKINGS_DISPLAY_CNT]) {
1268                                 // kick off the player who fell from the last displayed position
1269                                 grecordtime[RANKINGS_DISPLAY_CNT] = 0;
1270                                 strfree(grecordholder[RANKINGS_DISPLAY_CNT]);
1271                         }
1272
1273                         // store new ranking
1274                         strcpy(grecordholder[pos-1], ReadString());
1275                         grecordtime[pos-1] = ReadInt24_t();
1276                         if(strdecolorize(grecordholder[pos-1]) == strdecolorize(entcs_GetName(player_localnum)))
1277                                 race_myrank = pos;
1278                         break;
1279                 case RACE_NET_SERVER_STATUS:
1280                         race_status = ReadShort();
1281                         strcpy(race_status_name, ReadString());
1282         }
1283         return true;
1284 }
1285
1286 NET_HANDLE(TE_CSQC_TEAMNAGGER, bool isNew)
1287 {
1288         teamnagger = 1;
1289         return true;
1290 }
1291
1292 NET_HANDLE(TE_CSQC_PINGPLREPORT, bool isNew)
1293 {
1294         int i = ReadByte();
1295         int pi = ReadShort();
1296         int pl = ReadByte();
1297         int ml = ReadByte();
1298         return = true;
1299         entity e = playerslots[i];
1300         if (!e) return;
1301         e.ping = pi;
1302         e.ping_packetloss = pl / 255.0;
1303         e.ping_movementloss = ml / 255.0;
1304 }
1305
1306 NET_HANDLE(TE_CSQC_WEAPONCOMPLAIN, bool isNew)
1307 {
1308         int weapon_id = ReadByte();
1309         complain_weapon = REGISTRY_GET(Weapons, weapon_id);
1310         complain_weapon_type = ReadByte();
1311         return = true;
1312
1313         complain_weapon_time = time;
1314         weapontime = time; // ping the weapon panel
1315
1316         switch(complain_weapon_type)
1317         {
1318                 case 0: Local_Notification(MSG_MULTI, ITEM_WEAPON_NOAMMO, weapon_id); break;
1319                 case 1: Local_Notification(MSG_MULTI, ITEM_WEAPON_DONTHAVE, weapon_id); break;
1320                 default: Local_Notification(MSG_MULTI, ITEM_WEAPON_UNAVAILABLE, weapon_id); break;
1321         }
1322 }
1323
1324 string translate_modifications(string s)
1325 {
1326         return build_mutator_list(s);
1327 }
1328
1329 string translate_weaponarena(string s)
1330 {
1331         if (s == "") return s;
1332         if (s == "All Weapons Arena") return _("All Weapons Arena");
1333         if (s == "All Available Weapons Arena") return _("All Available Weapons Arena");
1334         if (s == "Most Weapons Arena") return _("Most Weapons Arena");
1335         if (s == "Most Available Weapons Arena") return _("Most Available Weapons Arena");
1336         if (s == "Dev All Weapons Arena") return s; // development option, do not translate
1337         if (s == "Dev All Available Weapons Arena") return s; // development option, do not translate
1338         if (s == "No Weapons Arena") return _("No Weapons Arena");
1339
1340         int n = tokenizebyseparator(s, " & ");
1341         string wpn_list = "";
1342         for (int i = 0; i < n; i++)
1343         {
1344                 Weapon wep = Weapon_from_name(argv(i));
1345                 if (wep == WEP_Null)
1346                         LOG_INFO("^3Warning: ^7server sent an invalid weapon name\n");
1347                 wpn_list = cons_mid(wpn_list, " & ", wep.m_name);
1348         }
1349         if (wpn_list != "")
1350                 return sprintf(_("%s Arena"), wpn_list);
1351         else
1352                 return _("No Weapons Arena");
1353 }
1354
1355 string GetVersionMessage(string hostversion, bool version_mismatch, bool version_check)
1356 {
1357         string xonotic_hostversion = strcat("Xonotic ", hostversion);
1358         if (version_mismatch)
1359         {
1360                 if(!version_check)
1361                         return strcat(sprintf(_("This is %s"), xonotic_hostversion), "\n^3",
1362                                 _("Your client version is outdated."), "\n\n\n",
1363                                 _("### YOU WON'T BE ABLE TO PLAY ON THIS SERVER ###"), "\n\n\n",
1364                                 _("Please update!"));
1365                 else
1366                         return strcat(sprintf(_("This is %s"), xonotic_hostversion), "\n^3",
1367                                 _("This server is using an outdated Xonotic version."), "\n\n\n",
1368                                 _("### THIS SERVER IS INCOMPATIBLE AND THUS YOU CANNOT JOIN ###"));
1369         }
1370         return sprintf(_("Welcome to %s"), xonotic_hostversion);
1371 }
1372
1373 bool net_handle_ServerWelcome()
1374 {
1375         bool campaign = ReadByte();
1376         if (campaign)
1377         {
1378                 string campaign_title = ReadString();
1379                 int campaign_level = ReadByte();
1380                 string campaign_msg = ReadString();
1381                 string welcomedialog_args;
1382                 welcomedialog_args = strcat("HOSTNAME \"", campaign_title, "\"");
1383                 string key = getcommandkey(_("jump"), "+jump");
1384                 string msg = strcat(
1385                         CCR("^F1"), sprintf(_("Level %d:"), campaign_level),
1386                         sprintf(CCR(" ^BG%s\n^3\n"), campaign_msg),
1387                         sprintf(CCR(_("^BGPress ^F2%s^BG to enter the game")), key));
1388                 msg = MakeConsoleSafe(strreplace("\n", "\\n", msg));
1389                 welcomedialog_args = strcat(welcomedialog_args, " WELCOME \"", msg, "\"");
1390                 localcmd("\nmenu_cmd directmenu Welcome ", welcomedialog_args, "\n");
1391                 return true;
1392         }
1393
1394         welcome_msg_force_centerprint = ReadByte();
1395         strcpy(hostname, ReadString());
1396
1397         string hostversion = ReadString();
1398         bool version_mismatch = ReadByte();
1399         bool version_check = ReadByte();
1400         string ver = GetVersionMessage(hostversion, version_mismatch, version_check);
1401
1402         string modifications = translate_modifications(ReadString());
1403         string weaponarena_list = translate_weaponarena(ReadString());
1404         string cache_mutatormsg = ReadString();
1405         string motd = ReadString();
1406
1407         string msg = "";
1408         msg = strcat(msg, ver);
1409         msg = strcat(msg, "^8\n\n", strcat(_("Gametype:"), " ^1", MapInfo_Type_ToText(gametype)), "^8\n");
1410
1411         modifications = cons_mid(modifications, ", ", weaponarena_list);
1412         if(modifications != "")
1413                 msg = strcat(msg, "^8\n", _("Active modifications:"), " ^3", modifications, "^8\n");
1414
1415         if (cache_mutatormsg != "")
1416                 msg = strcat(msg, "\n\n^8", _("Special gameplay tips:"), " ^7", cache_mutatormsg);
1417         string mutator_msg = "";
1418         MUTATOR_CALLHOOK(BuildGameplayTipsString, mutator_msg);
1419         mutator_msg = M_ARGV(0, string);
1420         msg = strcat(msg, mutator_msg); // trust that the mutator will do proper formatting
1421
1422         if (motd != "")
1423                 msg = strcat(msg, "\n\n^8", _("MOTD:"), " ^7", motd);
1424
1425         strcpy(welcome_msg, msg);
1426         welcome_msg_menu_check_maxtime = time + 1; // wait for menu to load before showing the welcome dialog
1427         return true;
1428 }
1429
1430 void Welcome_Message_Show_Try()
1431 {
1432         if (!welcome_msg_menu_check_maxtime)
1433                 return;
1434
1435         bool want_dialog = (!welcome_msg_force_centerprint && !isdemo() && autocvar_cl_welcome_in_menu_dialog);
1436         // if want dialog check if menu is initialized but for a short time
1437         if (!want_dialog || cvar("_menu_initialized") == 2 || time > welcome_msg_menu_check_maxtime)
1438         {
1439                 if (want_dialog && cvar("_menu_welcome_dialog_available"))
1440                 {
1441                         string welcomedialog_args = strcat("HOSTNAME \"", hostname, "\"");
1442                         string msg = MakeConsoleSafe(strreplace("\n", "\\n", welcome_msg));
1443                         welcomedialog_args = strcat(welcomedialog_args, " WELCOME \"", msg, "\"");
1444                         localcmd("\nmenu_cmd directmenu Welcome ", welcomedialog_args, "\n");
1445                 }
1446                 else
1447                         centerprint_Add(ORDINAL(CPID_MOTD), strcat(hostname, "\n\n\n", welcome_msg), -1, 0);
1448
1449                 strfree(welcome_msg);
1450                 welcome_msg_menu_check_maxtime = 0;
1451         }
1452 }
1453
1454 NET_HANDLE(TE_CSQC_SERVERWELCOME, bool isNew)
1455 {
1456         return net_handle_ServerWelcome();
1457 }
1458
1459 string _getcommandkey(string cmd_name, string command, bool forcename)
1460 {
1461         string keys;
1462         float n, j, k, l = 0;
1463
1464         if (!autocvar_hud_showbinds)
1465                 return cmd_name;
1466
1467         keys = db_get(binddb, command);
1468         if (keys == "")
1469         {
1470                 bool joy_active = cvar("joy_active");
1471                 n = tokenize(findkeysforcommand(command, 0)); // uses '...' strings
1472                 for(j = 0; j < n; ++j)
1473                 {
1474                         k = stof(argv(j));
1475                         if(k != -1)
1476                         {
1477                                 string key = keynumtostring(k);
1478                                 if(!joy_active && substring(key, 0, 3) == "JOY")
1479                                         continue;
1480
1481                                 key = translate_key(key);
1482
1483                                 if (keys == "")
1484                                         keys = key;
1485                                 else
1486                                         keys = strcat(keys, ", ", key);
1487
1488                                 ++l;
1489                                 if (autocvar_hud_showbinds_limit > 0 && autocvar_hud_showbinds_limit <= l)
1490                                         break;
1491                         }
1492
1493                 }
1494                 if (keys == "")
1495                         keys = "NO_KEY";
1496                 db_put(binddb, command, keys);
1497         }
1498
1499         if (keys == "NO_KEY") {
1500                 if (autocvar_hud_showbinds > 1)
1501                         return sprintf(_("%s (not bound)"), cmd_name);
1502                 else
1503                         return cmd_name;
1504         }
1505         else if (autocvar_hud_showbinds > 1 || forcename)
1506                 return sprintf("%s (%s)", cmd_name, keys);
1507         else
1508                 return keys;
1509 }
1510
1511 /** engine callback */
1512 void URI_Get_Callback(int id, int status, string data)
1513 {
1514         TC(int, id); TC(int, status);
1515         if(url_URI_Get_Callback(id, status, data))
1516         {
1517                 // handled
1518         }
1519         else if (id == URI_GET_DISCARD)
1520         {
1521                 // discard
1522         }
1523         else if (id >= URI_GET_CURL && id <= URI_GET_CURL_END)
1524         {
1525                 // sv_cmd curl
1526                 Curl_URI_Get_Callback(id, status, data);
1527         }
1528         else
1529         {
1530                 LOG_INFOF("Received HTTP request data for an invalid id %d.", id);
1531         }
1532 }