qcsrc/client/main.qc

   1 #include "mapvoting.qh"
   2 #include "modeleffects.qh"
   3 #include "particles.qh"
   4 #include "scoreboard.qh"
   5 #include "shownames.qh"
   6 #include "target_music.qh"
   7 #include "tturrets.qh"
   8 #include "tuba.qh"
   9 #include "wall.qh"
  10 #include "waypointsprites.qh"
  11
  12 #include "../common/vehicles/vehicles.qh"
  13 #include "../common/vehicles/cl_vehicles.qh"
  14
  15 #include "../common/net_notice.qh"
  16
  17 #include "../common/monsters/monsters.qh"
  18
  19 #include "../warpzonelib/client.qh"
  20
  21 // --------------------------------------------------------------------------
  22 // BEGIN REQUIRED CSQC FUNCTIONS
  23 //include "main.qh"
  24
  25 entity clearentity_ent;
  26 void clearentity(entity e)
  27 {
  28         if (!clearentity_ent)
  29         {
  30                 clearentity_ent = spawn();
  31                 clearentity_ent.classname = "clearentity";
  32         }
  33         int n = e.entnum;
  34         copyentity(clearentity_ent, e);
  35         e.entnum = n;
  36 }
  37
  38 #define DP_CSQC_ENTITY_REMOVE_IS_B0RKED
  39 void menu_show_error()
  40 {
  41         drawstring('0 200 0', _("ERROR - MENU IS VISIBLE BUT NO MENU WAS DEFINED!"), '8 8 0', '1 0 0', 1, 0);
  42 }
  43
  44 // CSQC_Init : Called every time the CSQC code is initialized (essentially at map load)
  45 // Useful for precaching things
  46
  47 void menu_sub_null()
  48 {
  49 }
  50
  51 string forcefog;
  52 void WaypointSprite_Load();
  53 void ConsoleCommand_macro_init();
  54 void CSQC_Init(void)
  55 {
  56         prvm_language = cvar_string("prvm_language");
  57
  58 #ifdef WATERMARK
  59         dprintf("^4CSQC Build information: ^1%s\n", WATERMARK);
  60 #endif
  61
  62         int i;
  63
  64         binddb = db_create();
  65         tempdb = db_create();
  66         ClientProgsDB = db_load("client.db");
  67         compressShortVector_init();
  68
  69         draw_endBoldFont();
  70         menu_visible = false;
  71         menu_show = menu_show_error;
  72         menu_action = func_null;
  73
  74         for(i = 0; i < 255; ++i)
  75                 if(getplayerkeyvalue(i, "viewentity") == "")
  76                         break;
  77         maxclients = i;
  78
  79         //registercommand("hud_configure");
  80         //registercommand("hud_save");
  81         //registercommand("menu_action");
  82
  83         ConsoleCommand_macro_init();
  84
  85         registercvar("hud_usecsqc", "1");
  86         registercvar("scoreboard_columns", "default");
  87
  88         registercvar("cl_nade_type", "3");
  89         registercvar("cl_pokenade_type", "zombie");
  90
  91         gametype = 0;
  92
  93         // hud_fields uses strunzone on the titles!
  94         for(i = 0; i < MAX_HUD_FIELDS; ++i)
  95                 hud_title[i] = strzone("(null)");
  96
  97         Cmd_HUD_SetFields(0);
  98
  99         postinit = false;
 100
 101         calledhooks = 0;
 102
 103         teams = Sort_Spawn();
 104         players = Sort_Spawn();
 105
 106         GetTeam(NUM_SPECTATOR, true); // add specs first
 107
 108         // needs to be done so early because of the constants they create
 109         CALL_ACCUMULATED_FUNCTION(RegisterWeapons);
 110         CALL_ACCUMULATED_FUNCTION(RegisterVehicles);
 111         CALL_ACCUMULATED_FUNCTION(RegisterMonsters);
 112         CALL_ACCUMULATED_FUNCTION(RegisterGametypes);
 113         CALL_ACCUMULATED_FUNCTION(RegisterNotifications);
 114         CALL_ACCUMULATED_FUNCTION(RegisterDeathtypes);
 115         CALL_ACCUMULATED_FUNCTION(RegisterHUD_Panels);
 116         CALL_ACCUMULATED_FUNCTION(RegisterBuffs);
 117
 118         WaypointSprite_Load();
 119
 120         // precaches
 121         precache_model("null");
 122         precache_sound("misc/hit.wav");
 123         precache_sound("misc/typehit.wav");
 124
 125         Projectile_Precache();
 126         Hook_Precache();
 127         GibSplash_Precache();
 128         Casings_Precache();
 129         turrets_precache();
 130         Tuba_Precache();
 131         CSQCPlayer_Precache();
 132
 133         if(autocvar_cl_reticle)
 134         {
 135                 precache_pic("gfx/reticle_normal");
 136                 // weapon reticles are precached in weapon files
 137         }
 138
 139         get_mi_min_max_texcoords(1); // try the CLEVER way first
 140         minimapname = strcat("gfx/", mi_shortname, "_radar.tga");
 141         shortmapname = mi_shortname;
 142
 143         if(precache_pic(minimapname) == "")
 144         {
 145                 // but maybe we have a non-clever minimap
 146                 minimapname = strcat("gfx/", mi_shortname, "_mini.tga");
 147                 if(precache_pic(minimapname) == "")
 148                         minimapname = ""; // FAIL
 149                 else
 150                         get_mi_min_max_texcoords(0); // load new texcoords
 151         }
 152
 153         mi_center = (mi_min + mi_max) * 0.5;
 154         mi_scale = mi_max - mi_min;
 155         minimapname = strzone(minimapname);
 156
 157         WarpZone_Init();
 158
 159         hud_skin_path = strzone(strcat("gfx/hud/", autocvar_hud_skin));
 160         hud_configure_prev = -1;
 161
 162         draw_currentSkin = strzone(strcat("gfx/menu/", cvar_string("menu_skin")));
 163 }
 164
 165 // CSQC_Shutdown : Called every time the CSQC code is shutdown (changing maps, quitting, etc)
 166 void Shutdown(void)
 167 {
 168         WarpZone_Shutdown();
 169
 170         remove(teams);
 171         remove(players);
 172         db_close(binddb);
 173         db_close(tempdb);
 174         if(autocvar_cl_db_saveasdump)
 175                 db_dump(ClientProgsDB, "client.db");
 176         else
 177                 db_save(ClientProgsDB, "client.db");
 178         db_close(ClientProgsDB);
 179
 180         if(camera_active)
 181                 cvar_set("chase_active",ftos(chase_active_backup));
 182
 183         // unset the event chasecam's chase_active
 184         if(autocvar_chase_active < 0)
 185                 cvar_set("chase_active", "0");
 186
 187         if (!isdemo())
 188         {
 189                 if (!(calledhooks & HOOK_START))
 190                         localcmd("\n_cl_hook_gamestart nop\n");
 191                 if (!(calledhooks & HOOK_END))
 192                         localcmd("\ncl_hook_gameend\n");
 193         }
 194 }
 195
 196 .float has_team;
 197 float SetTeam(entity o, int Team)
 198 {
 199         entity tm;
 200         if(teamplay)
 201         {
 202                 switch(Team)
 203                 {
 204                         case -1:
 205                         case NUM_TEAM_1:
 206                         case NUM_TEAM_2:
 207                         case NUM_TEAM_3:
 208                         case NUM_TEAM_4:
 209                                 break;
 210                         default:
 211                                 if(GetTeam(Team, false) == world)
 212                                 {
 213                                         dprintf("trying to switch to unsupported team %d\n", Team);
 214                                         Team = NUM_SPECTATOR;
 215                                 }
 216                                 break;
 217                 }
 218         }
 219         else
 220         {
 221                 switch(Team)
 222                 {
 223                         case -1:
 224                         case 0:
 225                                 break;
 226                         default:
 227                                 if(GetTeam(Team, false) == world)
 228                                 {
 229                                         dprintf("trying to switch to unsupported team %d\n", Team);
 230                                         Team = NUM_SPECTATOR;
 231                                 }
 232                                 break;
 233                 }
 234         }
 235         if(Team == -1) // leave
 236         {
 237                 if(o.has_team)
 238                 {
 239                         tm = GetTeam(o.team, false);
 240                         tm.team_size -= 1;
 241                         o.has_team = 0;
 242                         return true;
 243                 }
 244         }
 245         else
 246         {
 247                 if (!o.has_team)
 248                 {
 249                         o.team = Team;
 250                         tm = GetTeam(Team, true);
 251                         tm.team_size += 1;
 252                         o.has_team = 1;
 253                         return true;
 254                 }
 255                 else if(Team != o.team)
 256                 {
 257                         tm = GetTeam(o.team, false);
 258                         tm.team_size -= 1;
 259                         o.team = Team;
 260                         tm = GetTeam(Team, true);
 261                         tm.team_size += 1;
 262                         return true;
 263                 }
 264         }
 265         return false;
 266 }
 267
 268 void Playerchecker_Think()
 269 {
 270     int i;
 271         entity e;
 272         for(i = 0; i < maxclients; ++i)
 273         {
 274                 e = playerslots[i];
 275                 if(GetPlayerName(i) == "")
 276                 {
 277                         if(e.sort_prev)
 278                         {
 279                                 // player disconnected
 280                                 SetTeam(e, -1);
 281                                 RemovePlayer(e);
 282                                 e.sort_prev = world;
 283                                 //e.gotscores = 0;
 284                         }
 285                 }
 286                 else
 287                 {
 288                         if (!e.sort_prev)
 289                         {
 290                                 // player connected
 291                                 if (!e)
 292                                         playerslots[i] = e = spawn();
 293                                 e.sv_entnum = i;
 294                                 e.ping = 0;
 295                                 e.ping_packetloss = 0;
 296                                 e.ping_movementloss = 0;
 297                                 //e.gotscores = 0; // we might already have the scores...
 298                                 SetTeam(e, GetPlayerColor(i)); // will not hurt; later updates come with HUD_UpdatePlayerTeams
 299                                 RegisterPlayer(e);
 300                                 HUD_UpdatePlayerPos(e);
 301                         }
 302                 }
 303         }
 304         self.nextthink = time + 0.2;
 305 }
 306
 307 void Porto_Init();
 308 void TrueAim_Init();
 309 void PostInit(void)
 310 {
 311         entity playerchecker;
 312         playerchecker = spawn();
 313         playerchecker.think = Playerchecker_Think;
 314         playerchecker.nextthink = time + 0.2;
 315
 316         Porto_Init();
 317         TrueAim_Init();
 318
 319         postinit = true;
 320 }
 321
 322 // CSQC_InputEvent : Used to perform actions based on any key pressed, key released and mouse on the client.
 323 // Return value should be 1 if CSQC handled the input, otherwise return 0 to have the input passed to the engine.
 324 // All keys are in ascii.
 325 // bInputType = 0 is key pressed, 1 is key released, 2 and 3 are mouse input.
 326 // In the case of keyboard input, nPrimary is the ascii code, and nSecondary is 0.
 327 // In the case of mouse input, nPrimary is xdelta, nSecondary is ydelta.
 328 // In the case of mouse input after a setcursormode(1) call, nPrimary is xpos, nSecondary is ypos.
 329 float CSQC_InputEvent(float bInputType, float nPrimary, float nSecondary)
 330 {
 331         float bSkipKey;
 332         bSkipKey = false;
 333
 334         if (HUD_Panel_InputEvent(bInputType, nPrimary, nSecondary))
 335                 return true;
 336
 337         if (MapVote_InputEvent(bInputType, nPrimary, nSecondary))
 338                 return true;
 339
 340         if(menu_visible && menu_action)
 341                 if(menu_action(bInputType, nPrimary, nSecondary))
 342                         return true;
 343
 344         return bSkipKey;
 345 }
 346
 347 // END REQUIRED CSQC FUNCTIONS
 348 // --------------------------------------------------------------------------
 349
 350 // --------------------------------------------------------------------------
 351 // BEGIN OPTIONAL CSQC FUNCTIONS
 352 void Ent_RemoveEntCS()
 353 {
 354         entcs_receiver[self.sv_entnum] = world;
 355 }
 356 void Ent_ReadEntCS()
 357 {
 358     int sf;
 359         InterpolateOrigin_Undo();
 360
 361         self.classname = "entcs_receiver";
 362         sf = ReadByte();
 363
 364         if(sf & 1)
 365                 self.sv_entnum = ReadByte();
 366         if(sf & 2)
 367         {
 368                 self.origin_x = ReadShort();
 369                 self.origin_y = ReadShort();
 370                 self.origin_z = ReadShort();
 371                 setorigin(self, self.origin);
 372         }
 373         if(sf & 4)
 374         {
 375                 self.angles_y = ReadByte() * 360.0 / 256;
 376                 self.angles_x = self.angles_z = 0;
 377         }
 378         if(sf & 8)
 379                 self.healthvalue = ReadByte() * 10;
 380         if(sf & 16)
 381                 self.armorvalue = ReadByte() * 10;
 382
 383         entcs_receiver[self.sv_entnum] = self;
 384         self.entremove = Ent_RemoveEntCS;
 385         self.iflags |= IFLAG_ORIGIN;
 386
 387         InterpolateOrigin_Note();
 388 }
 389
 390 void Ent_Remove();
 391
 392 void Ent_RemovePlayerScore()
 393 {
 394         if(self.owner) {
 395                 SetTeam(self.owner, -1);
 396                 self.owner.gotscores = 0;
 397                 for(int i = 0; i < MAX_SCORE; ++i) {
 398                         self.owner.(scores[i]) = 0; // clear all scores
 399                 }
 400         }
 401 }
 402
 403 void Ent_ReadPlayerScore()
 404 {
 405         int i, n;
 406         bool isNew;
 407         entity o;
 408
 409         // damnit -.- don't want to go change every single .sv_entnum in hud.qc AGAIN
 410         // (no I've never heard of M-x replace-string, sed, or anything like that)
 411         isNew = !self.owner; // workaround for DP bug
 412         n = ReadByte()-1;
 413
 414 #ifdef DP_CSQC_ENTITY_REMOVE_IS_B0RKED
 415         if(!isNew && n != self.sv_entnum)
 416         {
 417                 //print("A CSQC entity changed its owner!\n");
 418                 printf("A CSQC entity changed its owner! (edict: %d, classname: %s)\n", num_for_edict(self), self.classname);
 419                 isNew = true;
 420                 Ent_Remove();
 421                 self.enttype = ENT_CLIENT_SCORES;
 422         }
 423 #endif
 424
 425         self.sv_entnum = n;
 426
 427         if (!(playerslots[self.sv_entnum]))
 428                 playerslots[self.sv_entnum] = spawn();
 429         o = self.owner = playerslots[self.sv_entnum];
 430         o.sv_entnum = self.sv_entnum;
 431         o.gotscores = 1;
 432
 433         //if (!o.sort_prev)
 434         //      RegisterPlayer(o);
 435         //playerchecker will do this for us later, if it has not already done so
 436
 437     int sf, lf;
 438 #if MAX_SCORE <= 8
 439         sf = ReadByte();
 440         lf = ReadByte();
 441 #else
 442         sf = ReadShort();
 443         lf = ReadShort();
 444 #endif
 445     int p;
 446         for(i = 0, p = 1; i < MAX_SCORE; ++i, p *= 2)
 447                 if(sf & p)
 448                 {
 449                         if(lf & p)
 450                                 o.(scores[i]) = ReadInt24_t();
 451                         else
 452                                 o.(scores[i]) = ReadChar();
 453                 }
 454
 455         if(o.sort_prev)
 456                 HUD_UpdatePlayerPos(o); // if not registered, we cannot do this yet!
 457
 458         self.entremove = Ent_RemovePlayerScore;
 459 }
 460
 461 void Ent_ReadTeamScore()
 462 {
 463         int i;
 464         entity o;
 465
 466         self.team = ReadByte();
 467         o = self.owner = GetTeam(self.team, true); // these team numbers can always be trusted
 468
 469     int sf, lf;
 470 #if MAX_TEAMSCORE <= 8
 471         sf = ReadByte();
 472         lf = ReadByte();
 473 #else
 474         sf = ReadShort();
 475         lf = ReadShort();
 476 #endif
 477         int p;
 478         for(i = 0, p = 1; i < MAX_TEAMSCORE; ++i, p *= 2)
 479                 if(sf & p)
 480                 {
 481                         if(lf & p)
 482                                 o.(teamscores[i]) = ReadInt24_t();
 483                         else
 484                                 o.(teamscores[i]) = ReadChar();
 485                 }
 486
 487         HUD_UpdateTeamPos(o);
 488 }
 489
 490 void Ent_ClientData()
 491 {
 492         float newspectatee_status;
 493
 494     int f = ReadByte();
 495
 496         scoreboard_showscores_force = (f & 1);
 497
 498         if(f & 2)
 499         {
 500                 newspectatee_status = ReadByte();
 501                 if(newspectatee_status == player_localnum + 1)
 502                         newspectatee_status = -1; // observing
 503         }
 504         else
 505                 newspectatee_status = 0;
 506
 507         spectatorbutton_zoom = (f & 4);
 508
 509         if(f & 8)
 510         {
 511                 angles_held_status = 1;
 512                 angles_held.x = ReadAngle();
 513                 angles_held.y = ReadAngle();
 514                 angles_held.z = 0;
 515         }
 516         else
 517                 angles_held_status = 0;
 518
 519         if(newspectatee_status != spectatee_status)
 520         {
 521                 // clear race stuff
 522                 race_laptime = 0;
 523                 race_checkpointtime = 0;
 524         }
 525         if (autocvar_hud_panel_healtharmor_progressbar_gfx)
 526         {
 527                 if ( (spectatee_status == -1 && newspectatee_status > 0) //before observing, now spectating
 528                   || (spectatee_status > 0 && newspectatee_status > 0 && spectatee_status != newspectatee_status) //changed spectated player
 529                 )
 530                         prev_p_health = -1;
 531                 else if(spectatee_status && !newspectatee_status) //before observing/spectating, now playing
 532                         prev_health = -1;
 533         }
 534         spectatee_status = newspectatee_status;
 535
 536         // we could get rid of spectatee_status, and derive it from player_localentnum and player_localnum
 537 }
 538
 539 void Ent_Nagger()
 540 {
 541     int i, j, b, f;
 542
 543     int nags = ReadByte(); // NAGS NAGS NAGS NAGS NAGS NAGS NADZ NAGS NAGS NAGS
 544
 545         if(!(nags & 4))
 546         {
 547                 if(vote_called_vote)
 548                         strunzone(vote_called_vote);
 549                 vote_called_vote = string_null;
 550                 vote_active = 0;
 551         }
 552         else
 553         {
 554                 vote_active = 1;
 555         }
 556
 557         if(nags & 64)
 558         {
 559                 vote_yescount = ReadByte();
 560                 vote_nocount = ReadByte();
 561                 vote_needed = ReadByte();
 562                 vote_highlighted = ReadChar();
 563         }
 564
 565         if(nags & 128)
 566         {
 567                 if(vote_called_vote)
 568                         strunzone(vote_called_vote);
 569                 vote_called_vote = strzone(ColorTranslateRGB(ReadString()));
 570         }
 571
 572         if(nags & 1)
 573         {
 574                 for(j = 0; j < maxclients; ++j)
 575                         if(playerslots[j])
 576                                 playerslots[j].ready = 1;
 577                 for(i = 1; i <= maxclients; i += 8)
 578                 {
 579                         f = ReadByte();
 580                         for(j = i-1, b = 1; b < 256; b *= 2, ++j)
 581                                 if (!(f & b))
 582                                         if(playerslots[j])
 583                                                 playerslots[j].ready = 0;
 584                 }
 585         }
 586
 587         ready_waiting = (nags & 1);
 588         ready_waiting_for_me = (nags & 2);
 589         vote_waiting = (nags & 4);
 590         vote_waiting_for_me = (nags & 8);
 591         warmup_stage = (nags & 16);
 592 }
 593
 594 void Ent_EliminatedPlayers()
 595 {
 596     int i, j, b, f;
 597
 598     int sf = ReadByte();
 599         if(sf & 1)
 600         {
 601                 for(j = 0; j < maxclients; ++j)
 602                         if(playerslots[j])
 603                                 playerslots[j].eliminated = 1;
 604                 for(i = 1; i <= maxclients; i += 8)
 605                 {
 606                         f = ReadByte();
 607                         for(j = i-1, b = 1; b < 256; b *= 2, ++j)
 608                                 if (!(f & b))
 609                                         if(playerslots[j])
 610                                                 playerslots[j].eliminated = 0;
 611                 }
 612         }
 613 }
 614
 615 void Ent_RandomSeed()
 616 {
 617         float s;
 618         prandom_debug();
 619         s = ReadShort();
 620         psrandom(s);
 621 }
 622
 623 void Ent_ReadAccuracy(void)
 624 {
 625     int f, w;
 626     int sf = ReadInt24_t();
 627         if(sf == 0)
 628         {
 629                 for(w = 0; w <= WEP_LAST - WEP_FIRST; ++w)
 630                         weapon_accuracy[w] = -1;
 631                 return;
 632         }
 633
 634         for(w = 0, f = 1; w <= WEP_LAST - WEP_FIRST; ++w)
 635         {
 636                 if(sf & f)
 637                 {
 638             int b = ReadByte();
 639                         if(b == 0)
 640                                 weapon_accuracy[w] = -1;
 641                         else if(b == 255)
 642                                 weapon_accuracy[w] = 1.0; // no better error handling yet, sorry
 643                         else
 644                                 weapon_accuracy[w] = (b - 1.0) / 100.0;
 645                 }
 646                 if(f == 0x800000)
 647                         f = 1;
 648                 else
 649                         f *= 2;
 650         }
 651 }
 652
 653 void Spawn_Draw(void)
 654 {
 655         pointparticles(self.cnt, self.origin + '0 0 28', '0 0 2', bound(0, frametime, 0.1));
 656 }
 657
 658 void Ent_ReadSpawnPoint(float is_new) // entity for spawnpoint
 659 {
 660         float teamnum = (ReadByte() - 1);
 661         vector spn_origin;
 662         spn_origin.x = ReadShort();
 663         spn_origin.y = ReadShort();
 664         spn_origin.z = ReadShort();
 665
 666         if(is_new)
 667         {
 668                 self.origin = spn_origin;
 669                 setsize(self, PL_MIN, PL_MAX);
 670                 droptofloor();
 671
 672                 /*if(autocvar_cl_spawn_point_model) // needs a model first
 673                 {
 674                         self.mdl = "models/spawnpoint.md3";
 675                         self.colormod = Team_ColorRGB(teamnum);
 676                         precache_model(self.mdl);
 677                         setmodel(self, self.mdl);
 678                         self.drawmask = MASK_NORMAL;
 679                         //self.movetype = MOVETYPE_NOCLIP;
 680                         //self.draw = Spawn_Draw;
 681                 }*/
 682                 if(autocvar_cl_spawn_point_particles)
 683                 {
 684                         if((serverflags & SERVERFLAG_TEAMPLAY))
 685                         {
 686                                 switch(teamnum)
 687                                 {
 688                                         case NUM_TEAM_1: self.cnt = particleeffectnum("spawn_point_red"); break;
 689                                         case NUM_TEAM_2: self.cnt = particleeffectnum("spawn_point_blue"); break;
 690                                         case NUM_TEAM_3: self.cnt = particleeffectnum("spawn_point_yellow"); break;
 691                                         case NUM_TEAM_4: self.cnt = particleeffectnum("spawn_point_pink"); break;
 692                                         default: self.cnt = particleeffectnum("spawn_point_neutral"); break;
 693                                 }
 694                         }
 695                         else { self.cnt = particleeffectnum("spawn_point_neutral"); }
 696
 697                         self.draw = Spawn_Draw;
 698                 }
 699         }
 700
 701         //printf("Ent_ReadSpawnPoint(is_new = %d); origin = %s, team = %d, effect = %d\n", is_new, vtos(self.origin), teamnum, self.cnt);
 702 }
 703
 704 void Ent_ReadSpawnEvent(float is_new)
 705 {
 706         // If entnum is 0, ONLY do the local spawn actions
 707         // this way the server can disable the sending of
 708         // spawn origin or such to clients if wanted.
 709         float entnum = ReadByte();
 710
 711         if(entnum)
 712         {
 713                 self.origin_x = ReadShort();
 714                 self.origin_y = ReadShort();
 715                 self.origin_z = ReadShort();
 716
 717                 if(is_new)
 718                 {
 719                         float teamnum = GetPlayerColor(entnum - 1);
 720
 721                         if(autocvar_cl_spawn_event_particles)
 722                         {
 723                                 switch(teamnum)
 724                                 {
 725                                         case NUM_TEAM_1: pointparticles(particleeffectnum("spawn_event_red"), self.origin, '0 0 0', 1); break;
 726                                         case NUM_TEAM_2: pointparticles(particleeffectnum("spawn_event_blue"), self.origin, '0 0 0', 1); break;
 727                                         case NUM_TEAM_3: pointparticles(particleeffectnum("spawn_event_yellow"), self.origin, '0 0 0', 1); break;
 728                                         case NUM_TEAM_4: pointparticles(particleeffectnum("spawn_event_pink"), self.origin, '0 0 0', 1); break;
 729                                         default: pointparticles(particleeffectnum("spawn_event_neutral"), self.origin, '0 0 0', 1); break;
 730                                 }
 731                         }
 732                         if(autocvar_cl_spawn_event_sound)
 733                         {
 734                                 sound(self, CH_TRIGGER, "misc/spawn.wav", VOL_BASE, ATTEN_NORM);
 735                         }
 736                 }
 737         }
 738
 739         // local spawn actions
 740         if(is_new && (!entnum || (entnum == player_localentnum)))
 741         {
 742                 zoomin_effect = 1;
 743                 current_viewzoom = (1 / bound(1, autocvar_cl_spawnzoom_factor, 16));
 744
 745                 if(autocvar_cl_unpress_zoom_on_spawn)
 746                 {
 747                         localcmd("-zoom\n");
 748                         button_zoom = false;
 749                 }
 750         }
 751
 752         //printf("Ent_ReadSpawnEvent(is_new = %d); origin = %s, entnum = %d, localentnum = %d\n", is_new, vtos(self.origin), entnum, player_localentnum);
 753 }
 754
 755 // CSQC_Ent_Update : Called every frame that the server has indicated an update to the SSQC / CSQC entity has occured.
 756 // The only parameter reflects if the entity is "new" to the client, meaning it just came into the client's PVS.
 757 void Ent_RadarLink();
 758 void Ent_Init();
 759 void Ent_ScoresInfo();
 760 void CSQC_Ent_Update(float bIsNewEntity)
 761 {
 762         float t;
 763         float savetime;
 764         t = ReadByte();
 765
 766         if(autocvar_developer_csqcentities)
 767                 printf("CSQC_Ent_Update(%d) with self=%i self.entnum=%d self.enttype=%d t=%d\n", bIsNewEntity, self, self.entnum, self.enttype, t);
 768
 769         // set up the "time" global for received entities to be correct for interpolation purposes
 770         savetime = time;
 771         if(servertime)
 772         {
 773                 time = servertime;
 774         }
 775         else
 776         {
 777                 serverprevtime = time;
 778                 serverdeltatime = getstatf(STAT_MOVEVARS_TICRATE) * getstatf(STAT_MOVEVARS_TIMESCALE);
 779                 time = serverprevtime + serverdeltatime;
 780         }
 781
 782 #ifdef DP_CSQC_ENTITY_REMOVE_IS_B0RKED
 783         if(self.enttype)
 784         {
 785                 if(t != self.enttype || bIsNewEntity)
 786                 {
 787                         //print("A CSQC entity changed its type!\n");
 788                         printf("A CSQC entity changed its type! (edict: %d, server: %d, type: %d -> %d)\n", num_for_edict(self), self.entnum, self.enttype, t);
 789                         Ent_Remove();
 790                         clearentity(self);
 791                         bIsNewEntity = 1;
 792                 }
 793         }
 794         else
 795         {
 796                 if(!bIsNewEntity)
 797                 {
 798                         printf("A CSQC entity appeared out of nowhere! (edict: %d, server: %d, type: %d)\n", num_for_edict(self), self.entnum, t);
 799                         bIsNewEntity = 1;
 800                 }
 801         }
 802 #endif
 803         self.enttype = t;
 804         switch(t)
 805         {
 806                 case ENT_CLIENT_ENTCS: Ent_ReadEntCS(); break;
 807                 case ENT_CLIENT_SCORES: Ent_ReadPlayerScore(); break;
 808                 case ENT_CLIENT_TEAMSCORES: Ent_ReadTeamScore(); break;
 809                 case ENT_CLIENT_POINTPARTICLES: Ent_PointParticles(); break;
 810                 case ENT_CLIENT_RAINSNOW: Ent_RainOrSnow(); break;
 811                 case ENT_CLIENT_LASER: Ent_Laser(); break;
 812                 case ENT_CLIENT_NAGGER: Ent_Nagger(); break;
 813                 case ENT_CLIENT_ELIMINATEDPLAYERS: Ent_EliminatedPlayers(); break;
 814                 case ENT_CLIENT_WAYPOINT: Ent_WaypointSprite(); break;
 815                 case ENT_CLIENT_RADARLINK: Ent_RadarLink(); break;
 816                 case ENT_CLIENT_PROJECTILE: Ent_Projectile(); break;
 817                 case ENT_CLIENT_GIBSPLASH: Ent_GibSplash(bIsNewEntity); break;
 818                 case ENT_CLIENT_DAMAGEINFO: Ent_DamageInfo(bIsNewEntity); break;
 819                 case ENT_CLIENT_CASING: Ent_Casing(bIsNewEntity); break;
 820                 case ENT_CLIENT_INIT: Ent_Init(); break;
 821                 case ENT_CLIENT_SCORES_INFO: Ent_ScoresInfo(); break;
 822                 case ENT_CLIENT_MAPVOTE: Ent_MapVote(); break;
 823                 case ENT_CLIENT_CLIENTDATA: Ent_ClientData(); break;
 824                 case ENT_CLIENT_RANDOMSEED: Ent_RandomSeed(); break;
 825                 case ENT_CLIENT_WALL: Ent_Wall(); break;
 826                 case ENT_CLIENT_MODELEFFECT: Ent_ModelEffect(bIsNewEntity); break;
 827                 case ENT_CLIENT_TUBANOTE: Ent_TubaNote(bIsNewEntity); break;
 828                 case ENT_CLIENT_WARPZONE: WarpZone_Read(bIsNewEntity); break;
 829                 case ENT_CLIENT_WARPZONE_CAMERA: WarpZone_Camera_Read(bIsNewEntity); break;
 830                 case ENT_CLIENT_WARPZONE_TELEPORTED: WarpZone_Teleported_Read(bIsNewEntity); break;
 831                 case ENT_CLIENT_TRIGGER_MUSIC: Ent_ReadTriggerMusic(); break;
 832                 case ENT_CLIENT_HOOK: Ent_ReadHook(bIsNewEntity, ENT_CLIENT_HOOK); break;
 833                 case ENT_CLIENT_ARC_BEAM: Ent_ReadArcBeam(bIsNewEntity); break;
 834                 case ENT_CLIENT_ACCURACY: Ent_ReadAccuracy(); break;
 835                 case ENT_CLIENT_AUXILIARYXHAIR: Net_AuXair2(bIsNewEntity); break;
 836                 case ENT_CLIENT_TURRET: ent_turret(); break;
 837                 case ENT_CLIENT_MODEL: CSQCModel_Read(bIsNewEntity); break;
 838                 case ENT_CLIENT_ITEM: ItemRead(bIsNewEntity); break;
 839                 case ENT_CLIENT_BUMBLE_RAYGUN: bumble_raygun_read(bIsNewEntity); break;
 840                 case ENT_CLIENT_SPAWNPOINT: Ent_ReadSpawnPoint(bIsNewEntity); break;
 841                 case ENT_CLIENT_SPAWNEVENT: Ent_ReadSpawnEvent(bIsNewEntity); break;
 842                 case ENT_CLIENT_NOTIFICATION: Read_Notification(bIsNewEntity); break;
 843                 case ENT_CLIENT_HEALING_ORB: ent_healer(); break;
 844
 845                 default:
 846                         //error(strcat(_("unknown entity type in CSQC_Ent_Update: %d\n"), self.enttype));
 847                         error(sprintf("Unknown entity type in CSQC_Ent_Update (enttype: %d, edict: %d, classname: %s)\n", self.enttype, num_for_edict(self), self.classname));
 848                         break;
 849         }
 850
 851         time = savetime;
 852 }
 853 // Destructor, but does NOT deallocate the entity by calling remove(). Also
 854 // used when an entity changes its type. For an entity that someone interacts
 855 // with others, make sure it can no longer do so.
 856 void Ent_Remove()
 857 {
 858         if(self.entremove)
 859                 self.entremove();
 860
 861         if(self.skeletonindex)
 862         {
 863                 skel_delete(self.skeletonindex);
 864                 self.skeletonindex = 0;
 865         }
 866
 867         if(self.snd_looping > 0)
 868         {
 869                 sound(self, self.snd_looping, "misc/null.wav", VOL_BASE, autocvar_g_jetpack_attenuation);
 870                 self.snd_looping = 0;
 871         }
 872
 873         self.enttype = 0;
 874         self.classname = "";
 875         self.draw = menu_sub_null;
 876         self.entremove = menu_sub_null;
 877         // TODO possibly set more stuff to defaults
 878 }
 879 // CSQC_Ent_Remove : Called when the server requests a SSQC / CSQC entity to be removed.  Essentially call remove(self) as well.
 880 void CSQC_Ent_Remove()
 881 {
 882         if(autocvar_developer_csqcentities)
 883                 printf("CSQC_Ent_Remove() with self=%i self.entnum=%d self.enttype=%d\n", self, self.entnum, self.enttype);
 884
 885         if(wasfreed(self))
 886         {
 887                 print("WARNING: CSQC_Ent_Remove called for already removed entity. Packet loss?\n");
 888                 return;
 889         }
 890         if(self.enttype)
 891                 Ent_Remove();
 892         remove(self);
 893 }
 894
 895 void Gamemode_Init()
 896 {
 897         if (!isdemo())
 898         {
 899                 if(!(calledhooks & HOOK_START))
 900                         localcmd("\n_cl_hook_gamestart ", MapInfo_Type_ToString(gametype), "\n");
 901                 calledhooks |= HOOK_START;
 902         }
 903 }
 904 // CSQC_Parse_StuffCmd : Provides the stuffcmd string in the first parameter that the server provided.  To execute standard behavior, simply execute localcmd with the string.
 905 void CSQC_Parse_StuffCmd(string strMessage)
 906 {
 907         if(autocvar_developer_csqcentities)
 908                 printf("CSQC_Parse_StuffCmd(\"%s\")\n", strMessage);
 909
 910         localcmd(strMessage);
 911 }
 912 // CSQC_Parse_Print : Provides the print string in the first parameter that the server provided.  To execute standard behavior, simply execute print with the string.
 913 void CSQC_Parse_Print(string strMessage)
 914 {
 915         if(autocvar_developer_csqcentities)
 916                 printf("CSQC_Parse_Print(\"%s\")\n", strMessage);
 917
 918         print(ColorTranslateRGB(strMessage));
 919 }
 920
 921 // CSQC_Parse_CenterPrint : Provides the centerprint_hud string in the first parameter that the server provided.
 922 void CSQC_Parse_CenterPrint(string strMessage)
 923 {
 924         if(autocvar_developer_csqcentities)
 925                 printf("CSQC_Parse_CenterPrint(\"%s\")\n", strMessage);
 926
 927         centerprint_hud(strMessage);
 928 }
 929
 930 string notranslate_fogcmd1 = "\nfog ";
 931 string notranslate_fogcmd2 = "\nr_fog_exp2 0\nr_drawfog 1\n";
 932 void Fog_Force()
 933 {
 934         // TODO somehow thwart prvm_globalset client ...
 935
 936         if(autocvar_cl_orthoview && autocvar_cl_orthoview_nofog)
 937                 { localcmd("\nr_drawfog 0\n"); }
 938         else if(forcefog != "")
 939                 { localcmd(strcat(notranslate_fogcmd1, forcefog, notranslate_fogcmd2)); }
 940 }
 941
 942 void Gamemode_Init();
 943 void Ent_ScoresInfo()
 944 {
 945     int i;
 946         self.classname = "ent_client_scores_info";
 947         gametype = ReadInt24_t();
 948         HUD_ModIcons_SetFunc();
 949         for(i = 0; i < MAX_SCORE; ++i)
 950         {
 951                 if(scores_label[i])
 952                         strunzone(scores_label[i]);
 953                 scores_label[i] = strzone(ReadString());
 954                 scores_flags[i] = ReadByte();
 955         }
 956         for(i = 0; i < MAX_TEAMSCORE; ++i)
 957         {
 958                 if(teamscores_label[i])
 959                         strunzone(teamscores_label[i]);
 960                 teamscores_label[i] = strzone(ReadString());
 961                 teamscores_flags[i] = ReadByte();
 962         }
 963         HUD_InitScores();
 964         Gamemode_Init();
 965 }
 966
 967 void Ent_Init()
 968 {
 969         self.classname = "ent_client_init";
 970
 971         nb_pb_period = ReadByte() / 32; //Accuracy of 1/32th
 972
 973         hook_shotorigin[0] = decompressShotOrigin(ReadInt24_t());
 974         hook_shotorigin[1] = decompressShotOrigin(ReadInt24_t());
 975         hook_shotorigin[2] = decompressShotOrigin(ReadInt24_t());
 976         hook_shotorigin[3] = decompressShotOrigin(ReadInt24_t());
 977         arc_shotorigin[0] = decompressShotOrigin(ReadInt24_t());
 978         arc_shotorigin[1] = decompressShotOrigin(ReadInt24_t());
 979         arc_shotorigin[2] = decompressShotOrigin(ReadInt24_t());
 980         arc_shotorigin[3] = decompressShotOrigin(ReadInt24_t());
 981
 982         if(forcefog)
 983                 strunzone(forcefog);
 984         forcefog = strzone(ReadString());
 985
 986         armorblockpercent = ReadByte() / 255.0;
 987
 988         g_balance_mortar_bouncefactor = ReadCoord();
 989         g_balance_mortar_bouncestop = ReadCoord();
 990         g_balance_electro_secondary_bouncefactor = ReadCoord();
 991         g_balance_electro_secondary_bouncestop = ReadCoord();
 992
 993         vortex_scope = !ReadByte();
 994         rifle_scope = !ReadByte();
 995
 996         serverflags = ReadByte();
 997
 998         minelayer_maxmines = ReadByte();
 999
1000         hagar_maxrockets = ReadByte();
1001
1002         g_trueaim_minrange = ReadCoord();
1003         g_balance_porto_secondary = ReadByte();
1004
1005         if(!postinit)
1006                 PostInit();
1007 }
1008
1009 void Net_ReadRace()
1010 {
1011         float b;
1012
1013         b = ReadByte();
1014
1015         switch(b)
1016         {
1017                 case RACE_NET_CHECKPOINT_HIT_QUALIFYING:
1018                         race_checkpoint = ReadByte();
1019                         race_time = ReadInt24_t();
1020                         race_previousbesttime = ReadInt24_t();
1021                         if(race_previousbestname)
1022                                 strunzone(race_previousbestname);
1023                         race_previousbestname = strzone(ColorTranslateRGB(ReadString()));
1024
1025                         race_checkpointtime = time;
1026
1027                         if(race_checkpoint == 0 || race_checkpoint == 254)
1028                         {
1029                                 race_penaltyaccumulator = 0;
1030                                 race_laptime = time; // valid
1031                         }
1032
1033                         break;
1034
1035                 case RACE_NET_CHECKPOINT_CLEAR:
1036                         race_laptime = 0;
1037                         race_checkpointtime = 0;
1038                         break;
1039
1040                 case RACE_NET_CHECKPOINT_NEXT_SPEC_QUALIFYING:
1041                         race_laptime = ReadCoord();
1042                         race_checkpointtime = -99999;
1043                         // fall through
1044                 case RACE_NET_CHECKPOINT_NEXT_QUALIFYING:
1045                         race_nextcheckpoint = ReadByte();
1046
1047                         race_nextbesttime = ReadInt24_t();
1048                         if(race_nextbestname)
1049                                 strunzone(race_nextbestname);
1050                         race_nextbestname = strzone(ColorTranslateRGB(ReadString()));
1051                         break;
1052
1053                 case RACE_NET_CHECKPOINT_HIT_RACE:
1054                         race_mycheckpoint = ReadByte();
1055                         race_mycheckpointtime = time;
1056                         race_mycheckpointdelta = ReadInt24_t();
1057                         race_mycheckpointlapsdelta = ReadByte();
1058                         if(race_mycheckpointlapsdelta >= 128)
1059                                 race_mycheckpointlapsdelta -= 256;
1060                         if(race_mycheckpointenemy)
1061                                 strunzone(race_mycheckpointenemy);
1062                         race_mycheckpointenemy = strzone(ColorTranslateRGB(ReadString()));
1063                         break;
1064
1065                 case RACE_NET_CHECKPOINT_HIT_RACE_BY_OPPONENT:
1066                         race_othercheckpoint = ReadByte();
1067                         race_othercheckpointtime = time;
1068                         race_othercheckpointdelta = ReadInt24_t();
1069                         race_othercheckpointlapsdelta = ReadByte();
1070                         if(race_othercheckpointlapsdelta >= 128)
1071                                 race_othercheckpointlapsdelta -= 256;
1072                         if(race_othercheckpointenemy)
1073                                 strunzone(race_othercheckpointenemy);
1074                         race_othercheckpointenemy = strzone(ColorTranslateRGB(ReadString()));
1075                         break;
1076
1077                 case RACE_NET_PENALTY_RACE:
1078                         race_penaltyeventtime = time;
1079                         race_penaltytime = ReadShort();
1080                         //race_penaltyaccumulator += race_penaltytime;
1081                         if(race_penaltyreason)
1082                                 strunzone(race_penaltyreason);
1083                         race_penaltyreason = strzone(ReadString());
1084                         break;
1085
1086                 case RACE_NET_PENALTY_QUALIFYING:
1087                         race_penaltyeventtime = time;
1088                         race_penaltytime = ReadShort();
1089                         race_penaltyaccumulator += race_penaltytime;
1090                         if(race_penaltyreason)
1091                                 strunzone(race_penaltyreason);
1092                         race_penaltyreason = strzone(ReadString());
1093                         break;
1094
1095                 case RACE_NET_SERVER_RECORD:
1096                         race_server_record = ReadInt24_t();
1097                         break;
1098                 case RACE_NET_SPEED_AWARD:
1099                         race_speedaward = ReadInt24_t();
1100                         if(race_speedaward_holder)
1101                                 strunzone(race_speedaward_holder);
1102                         race_speedaward_holder = strzone(ReadString());
1103                         break;
1104                 case RACE_NET_SPEED_AWARD_BEST:
1105                         race_speedaward_alltimebest = ReadInt24_t();
1106                         if(race_speedaward_alltimebest_holder)
1107                                 strunzone(race_speedaward_alltimebest_holder);
1108                         race_speedaward_alltimebest_holder = strzone(ReadString());
1109                         break;
1110                 case RACE_NET_SERVER_RANKINGS:
1111                         float prevpos, del;
1112             int pos = ReadShort();
1113                         prevpos = ReadShort();
1114                         del = ReadShort();
1115
1116                         // move other rankings out of the way
1117             int i;
1118                         if (prevpos) {
1119                                 for (i=prevpos-1;i>pos-1;--i) {
1120                                         grecordtime[i] = grecordtime[i-1];
1121                                         if(grecordholder[i])
1122                                                 strunzone(grecordholder[i]);
1123                                         grecordholder[i] = strzone(grecordholder[i-1]);
1124                                 }
1125                         } else if (del) { // a record has been deleted by the admin
1126                                 for (i=pos-1; i<= RANKINGS_CNT-1; ++i) {
1127                                         if (i == RANKINGS_CNT-1) { // clear out last record
1128                                                 grecordtime[i] = 0;
1129                                                 if (grecordholder[i])
1130                                                         strunzone(grecordholder[i]);
1131                                                 grecordholder[i] = string_null;
1132                                         }
1133                                         else {
1134                                                 grecordtime[i] = grecordtime[i+1];
1135                                                 if (grecordholder[i])
1136                                                         strunzone(grecordholder[i]);
1137                                                 grecordholder[i] = strzone(grecordholder[i+1]);
1138                                         }
1139                                 }
1140                         } else { // player has no ranked record yet
1141                                 for (i=RANKINGS_CNT-1;i>pos-1;--i) {
1142                                         grecordtime[i] = grecordtime[i-1];
1143                                         if(grecordholder[i])
1144                                                 strunzone(grecordholder[i]);
1145                                         grecordholder[i] = strzone(grecordholder[i-1]);
1146                                 }
1147                         }
1148
1149                         // store new ranking
1150                         if(grecordholder[pos-1] != "")
1151                                 strunzone(grecordholder[pos-1]);
1152                         grecordholder[pos-1] = strzone(ReadString());
1153                         grecordtime[pos-1] = ReadInt24_t();
1154                         if(grecordholder[pos-1] == GetPlayerName(player_localnum))
1155                                 race_myrank = pos;
1156                         break;
1157                 case RACE_NET_SERVER_STATUS:
1158                         race_status = ReadShort();
1159                         if(race_status_name)
1160                                 strunzone(race_status_name);
1161                         race_status_name = strzone(ReadString());
1162         }
1163 }
1164
1165 void Net_TeamNagger()
1166 {
1167         teamnagger = 1;
1168 }
1169
1170 void Net_ReadPingPLReport()
1171 {
1172         int e, pi, pl, ml;
1173         e = ReadByte();
1174         pi = ReadShort();
1175         pl = ReadByte();
1176         ml = ReadByte();
1177         if (!(playerslots[e]))
1178                 return;
1179         playerslots[e].ping = pi;
1180         playerslots[e].ping_packetloss = pl / 255.0;
1181         playerslots[e].ping_movementloss = ml / 255.0;
1182 }
1183
1184 void Net_WeaponComplain()
1185 {
1186         complain_weapon = ReadByte();
1187
1188         if(complain_weapon_name)
1189                 strunzone(complain_weapon_name);
1190         complain_weapon_name = strzone(WEP_NAME(complain_weapon));
1191
1192         complain_weapon_type = ReadByte();
1193
1194         complain_weapon_time = time;
1195         weapontime = time; // ping the weapon panel
1196
1197         switch(complain_weapon_type)
1198         {
1199                 case 0: Local_Notification(MSG_MULTI, ITEM_WEAPON_NOAMMO, complain_weapon); break;
1200                 case 1: Local_Notification(MSG_MULTI, ITEM_WEAPON_DONTHAVE, complain_weapon); break;
1201                 default: Local_Notification(MSG_MULTI, ITEM_WEAPON_UNAVAILABLE, complain_weapon); break;
1202         }
1203 }
1204
1205 // CSQC_Parse_TempEntity : Handles all temporary entity network data in the CSQC layer.
1206 // You must ALWAYS first acquire the temporary ID, which is sent as a byte.
1207 // Return value should be 1 if CSQC handled the temporary entity, otherwise return 0 to have the engine process the event.
1208 float CSQC_Parse_TempEntity()
1209 {
1210         float bHandled;
1211                 bHandled  = true;
1212         // Acquire TE ID
1213         float nTEID;
1214                 nTEID = ReadByte();
1215
1216         if(autocvar_developer_csqcentities)
1217                 printf("CSQC_Parse_TempEntity() with nTEID=%d\n", nTEID);
1218
1219                 // NOTE: Could just do return instead of break...
1220         switch(nTEID)
1221         {
1222                 case TE_CSQC_TARGET_MUSIC:
1223                         Net_TargetMusic();
1224                         bHandled = true;
1225                         break;
1226                 case TE_CSQC_PICTURE:
1227                         Net_MapVote_Picture();
1228                         bHandled = true;
1229                         break;
1230                 case TE_CSQC_RACE:
1231                         Net_ReadRace();
1232                         bHandled = true;
1233                         break;
1234                 case TE_CSQC_VORTEXBEAMPARTICLE:
1235                         Net_ReadVortexBeamParticle();
1236                         bHandled = true;
1237                         break;
1238                 case TE_CSQC_TEAMNAGGER:
1239                         Net_TeamNagger();
1240                         bHandled = true;
1241                         break;
1242                 case TE_CSQC_ARC:
1243                         Net_ReadArc();
1244                         bHandled = true;
1245                         break;
1246                 case TE_CSQC_PINGPLREPORT:
1247                         Net_ReadPingPLReport();
1248                         bHandled = true;
1249                         break;
1250                 case TE_CSQC_WEAPONCOMPLAIN:
1251                         Net_WeaponComplain();
1252                         bHandled = true;
1253                         break;
1254                 case TE_CSQC_VEHICLESETUP:
1255                         Net_VehicleSetup();
1256                         bHandled = true;
1257                         break;
1258                 case TE_CSQC_SVNOTICE:
1259                         cl_notice_read();
1260                         bHandled = true;
1261                         break;
1262                 case TE_CSQC_SHOCKWAVEPARTICLE:
1263                         Net_ReadShockwaveParticle();
1264                         bHandled = true;
1265                         break;
1266                 default:
1267                         // No special logic for this temporary entity; return 0 so the engine can handle it
1268                         bHandled = false;
1269                         break;
1270         }
1271
1272         return bHandled;
1273 }
1274
1275 string getcommandkey(string text, string command)
1276 {
1277         string keys;
1278         float n, j, k, l = 0;
1279
1280         if (!autocvar_hud_showbinds)
1281                 return text;
1282
1283         keys = db_get(binddb, command);
1284         if (keys == "")
1285         {
1286                 n = tokenize(findkeysforcommand(command, 0)); // uses '...' strings
1287                 for(j = 0; j < n; ++j)
1288                 {
1289                         k = stof(argv(j));
1290                         if(k != -1)
1291                         {
1292                                 if ("" == keys)
1293                                         keys = keynumtostring(k);
1294                                 else
1295                                         keys = strcat(keys, ", ", keynumtostring(k));
1296
1297                                 ++l;
1298                                 if (autocvar_hud_showbinds_limit > 0 && autocvar_hud_showbinds_limit <= l)
1299                                         break;
1300                         }
1301
1302                 }
1303                 if (keys == "")
1304                         keys = "NO_KEY";
1305                 db_put(binddb, command, keys);
1306         }
1307
1308         if (keys == "NO_KEY") {
1309                 if (autocvar_hud_showbinds > 1)
1310                         return sprintf(_("%s (not bound)"), text);
1311                 else
1312                         return text;
1313         }
1314         else if (autocvar_hud_showbinds > 1)
1315                 return sprintf("%s (%s)", text, keys);
1316         else
1317                 return keys;
1318 }