qcsrc/client/main.qc

   1 #include "main.qh"
   2 #include "_all.qh"
   3
   4 #include "controlpoint.qh"
   5 #include "damage.qh"
   6 #include "effects.qh"
   7 #include "generator.qh"
   8 #include "gibs.qh"
   9 #include "hook.qh"
  10 #include "hud.qh"
  11 #include "hud_config.qh"
  12 #include "laser.qh"
  13 #include "mapvoting.qh"
  14 #include "modeleffects.qh"
  15 #include "particles.qh"
  16 #include "scoreboard.qh"
  17 #include "shownames.qh"
  18 #include "tuba.qh"
  19 #include "t_items.qh"
  20 #include "wall.qh"
  21
  22 #include "../common/vehicles/all.qh"
  23
  24 #include "mutators/events.qh"
  25
  26 #include "weapons/projectile.qh"
  27
  28 #include "../common/buffs/all.qh"
  29 #include "../common/deathtypes.qh"
  30 #include "../common/effects/effects.qh"
  31 #include "../common/mapinfo.qh"
  32 #include "../common/monsters/all.qh"
  33 #include "../common/nades/all.qh"
  34 #include "../common/net_notice.qh"
  35 #include "../common/notifications.qh"
  36 #include "../common/stats.qh"
  37 #include "../common/teams.qh"
  38
  39 #include "../common/items/all.qh"
  40
  41 #include "../common/mutators/base.qh"
  42
  43 #include "../common/weapons/all.qh"
  44
  45 #include "../csqcmodellib/cl_model.qh"
  46 #include "../csqcmodellib/interpolate.qh"
  47
  48 #include "../common/triggers/include.qh"
  49
  50 #include "../common/turrets/cl_turrets.qh"
  51
  52 #include "../warpzonelib/client.qh"
  53
  54 // --------------------------------------------------------------------------
  55 // BEGIN REQUIRED CSQC FUNCTIONS
  56 //include "main.qh"
  57
  58 entity clearentity_ent;
  59 void clearentity(entity e)
  60 {
  61         if (!clearentity_ent)
  62         {
  63                 clearentity_ent = spawn();
  64                 clearentity_ent.classname = "clearentity";
  65         }
  66         int n = e.entnum;
  67         copyentity(clearentity_ent, e);
  68         e.entnum = n;
  69 }
  70
  71 #define DP_CSQC_ENTITY_REMOVE_IS_B0RKED
  72 void menu_show_error()
  73 {
  74         drawstring('0 200 0', _("ERROR - MENU IS VISIBLE BUT NO MENU WAS DEFINED!"), '8 8 0', '1 0 0', 1, 0);
  75 }
  76
  77 // CSQC_Init : Called every time the CSQC code is initialized (essentially at map load)
  78 // Useful for precaching things
  79
  80 void menu_sub_null()
  81 {
  82 }
  83
  84 void draw_null(entity this) { }
  85
  86 string forcefog;
  87 void ConsoleCommand_macro_init();
  88 void CSQC_Init(void)
  89 {
  90         prvm_language = strzone(cvar_string("prvm_language"));
  91
  92 #ifdef WATERMARK
  93         LOG_TRACEF("^4CSQC Build information: ^1%s\n", WATERMARK);
  94 #endif
  95
  96         int i;
  97
  98         binddb = db_create();
  99         tempdb = db_create();
 100         ClientProgsDB = db_load("client.db");
 101         compressShortVector_init();
 102
 103         draw_endBoldFont();
 104         menu_visible = false;
 105         menu_show = menu_show_error;
 106         menu_action = func_null;
 107
 108         for(i = 0; i < 255; ++i)
 109                 if(getplayerkeyvalue(i, "viewentity") == "")
 110                         break;
 111         maxclients = i;
 112
 113         //registercommand("hud_configure");
 114         //registercommand("hud_save");
 115         //registercommand("menu_action");
 116
 117         ConsoleCommand_macro_init();
 118
 119         registercvar("hud_usecsqc", "1");
 120         registercvar("scoreboard_columns", "default");
 121
 122         registercvar("cl_nade_type", "3");
 123         registercvar("cl_pokenade_type", "zombie");
 124
 125         registercvar("cl_jumpspeedcap_min", "");
 126         registercvar("cl_jumpspeedcap_max", "");
 127
 128         registercvar("cl_multijump", "0");
 129
 130         registercvar("cl_spawn_near_teammate", "1");
 131
 132         gametype = 0;
 133
 134         // hud_fields uses strunzone on the titles!
 135         for(i = 0; i < MAX_HUD_FIELDS; ++i)
 136                 hud_title[i] = strzone("(null)");
 137
 138         Cmd_HUD_SetFields(0);
 139
 140         postinit = false;
 141
 142         calledhooks = 0;
 143
 144         teams = Sort_Spawn();
 145         players = Sort_Spawn();
 146
 147         GetTeam(NUM_SPECTATOR, true); // add specs first
 148
 149         // needs to be done so early because of the constants they create
 150         static_init();
 151         CALL_ACCUMULATED_FUNCTION(RegisterNotifications);
 152         CALL_ACCUMULATED_FUNCTION(RegisterDeathtypes);
 153
 154         // precaches
 155
 156         Projectile_Precache();
 157         Tuba_Precache();
 158
 159         if(autocvar_cl_reticle)
 160         {
 161                 precache_pic("gfx/reticle_normal");
 162                 // weapon reticles are precached in weapon files
 163         }
 164
 165         get_mi_min_max_texcoords(1); // try the CLEVER way first
 166         minimapname = strcat("gfx/", mi_shortname, "_radar.tga");
 167         shortmapname = mi_shortname;
 168
 169         if(precache_pic(minimapname) == "")
 170         {
 171                 // but maybe we have a non-clever minimap
 172                 minimapname = strcat("gfx/", mi_shortname, "_mini.tga");
 173                 if(precache_pic(minimapname) == "")
 174                         minimapname = ""; // FAIL
 175                 else
 176                         get_mi_min_max_texcoords(0); // load new texcoords
 177         }
 178
 179         mi_center = (mi_min + mi_max) * 0.5;
 180         mi_scale = mi_max - mi_min;
 181         minimapname = strzone(minimapname);
 182
 183         WarpZone_Init();
 184
 185         hud_skin_path = strzone(strcat("gfx/hud/", autocvar_hud_skin));
 186         draw_currentSkin = strzone(strcat("gfx/menu/", cvar_string("menu_skin")));
 187 }
 188
 189 // CSQC_Shutdown : Called every time the CSQC code is shutdown (changing maps, quitting, etc)
 190 void Shutdown(void)
 191 {
 192         WarpZone_Shutdown();
 193
 194         remove(teams);
 195         remove(players);
 196         db_close(binddb);
 197         db_close(tempdb);
 198         if(autocvar_cl_db_saveasdump)
 199                 db_dump(ClientProgsDB, "client.db");
 200         else
 201                 db_save(ClientProgsDB, "client.db");
 202         db_close(ClientProgsDB);
 203
 204         if(camera_active)
 205                 cvar_set("chase_active",ftos(chase_active_backup));
 206
 207         // unset the event chasecam's chase_active
 208         if(autocvar_chase_active < 0)
 209                 cvar_set("chase_active", "0");
 210
 211         if (!isdemo())
 212         {
 213                 if (!(calledhooks & HOOK_START))
 214                         localcmd("\n_cl_hook_gamestart nop\n");
 215                 if (!(calledhooks & HOOK_END))
 216                         localcmd("\ncl_hook_gameend\n");
 217         }
 218
 219         deactivate_minigame();
 220         HUD_MinigameMenu_Close();
 221 }
 222
 223 .float has_team;
 224 float SetTeam(entity o, int Team)
 225 {
 226         entity tm;
 227         if(teamplay)
 228         {
 229                 switch(Team)
 230                 {
 231                         case -1:
 232                         case NUM_TEAM_1:
 233                         case NUM_TEAM_2:
 234                         case NUM_TEAM_3:
 235                         case NUM_TEAM_4:
 236                                 break;
 237                         default:
 238                                 if(GetTeam(Team, false) == world)
 239                                 {
 240                                         LOG_TRACEF("trying to switch to unsupported team %d\n", Team);
 241                                         Team = NUM_SPECTATOR;
 242                                 }
 243                                 break;
 244                 }
 245         }
 246         else
 247         {
 248                 switch(Team)
 249                 {
 250                         case -1:
 251                         case 0:
 252                                 break;
 253                         default:
 254                                 if(GetTeam(Team, false) == world)
 255                                 {
 256                                         LOG_TRACEF("trying to switch to unsupported team %d\n", Team);
 257                                         Team = NUM_SPECTATOR;
 258                                 }
 259                                 break;
 260                 }
 261         }
 262         if(Team == -1) // leave
 263         {
 264                 if(o.has_team)
 265                 {
 266                         tm = GetTeam(o.team, false);
 267                         tm.team_size -= 1;
 268                         o.has_team = 0;
 269                         return true;
 270                 }
 271         }
 272         else
 273         {
 274                 if (!o.has_team)
 275                 {
 276                         o.team = Team;
 277                         tm = GetTeam(Team, true);
 278                         tm.team_size += 1;
 279                         o.has_team = 1;
 280                         return true;
 281                 }
 282                 else if(Team != o.team)
 283                 {
 284                         tm = GetTeam(o.team, false);
 285                         tm.team_size -= 1;
 286                         o.team = Team;
 287                         tm = GetTeam(Team, true);
 288                         tm.team_size += 1;
 289                         return true;
 290                 }
 291         }
 292         return false;
 293 }
 294
 295 void Playerchecker_Think()
 296 {SELFPARAM();
 297     int i;
 298         entity e;
 299         for(i = 0; i < maxclients; ++i)
 300         {
 301                 e = playerslots[i];
 302                 if(GetPlayerName(i) == "")
 303                 {
 304                         if(e.sort_prev)
 305                         {
 306                                 // player disconnected
 307                                 SetTeam(e, -1);
 308                                 RemovePlayer(e);
 309                                 e.sort_prev = world;
 310                                 //e.gotscores = 0;
 311                         }
 312                 }
 313                 else
 314                 {
 315                         if (!e.sort_prev)
 316                         {
 317                                 // player connected
 318                                 if (!e)
 319                                         playerslots[i] = e = spawn();
 320                                 e.sv_entnum = i;
 321                                 e.ping = 0;
 322                                 e.ping_packetloss = 0;
 323                                 e.ping_movementloss = 0;
 324                                 //e.gotscores = 0; // we might already have the scores...
 325                                 SetTeam(e, GetPlayerColor(i)); // will not hurt; later updates come with HUD_UpdatePlayerTeams
 326                                 RegisterPlayer(e);
 327                                 HUD_UpdatePlayerPos(e);
 328                         }
 329                 }
 330         }
 331         self.nextthink = time + 0.2;
 332 }
 333
 334 void Porto_Init();
 335 void TrueAim_Init();
 336 void PostInit(void)
 337 {
 338         entity playerchecker;
 339         playerchecker = spawn();
 340         playerchecker.think = Playerchecker_Think;
 341         playerchecker.nextthink = time + 0.2;
 342
 343         Porto_Init();
 344         TrueAim_Init();
 345
 346         postinit = true;
 347 }
 348
 349 // CSQC_InputEvent : Used to perform actions based on any key pressed, key released and mouse on the client.
 350 // Return value should be 1 if CSQC handled the input, otherwise return 0 to have the input passed to the engine.
 351 // All keys are in ascii.
 352 // bInputType = 0 is key pressed, 1 is key released, 2 and 3 are mouse input.
 353 // In the case of keyboard input, nPrimary is the ascii code, and nSecondary is 0.
 354 // In the case of mouse input, nPrimary is xdelta, nSecondary is ydelta.
 355 // In the case of mouse input after a setcursormode(1) call, nPrimary is xpos, nSecondary is ypos.
 356 float CSQC_InputEvent(float bInputType, float nPrimary, float nSecondary)
 357 {
 358         float bSkipKey;
 359         bSkipKey = false;
 360
 361         if (HUD_Panel_InputEvent(bInputType, nPrimary, nSecondary))
 362                 return true;
 363
 364         if (QuickMenu_InputEvent(bInputType, nPrimary, nSecondary))
 365                 return true;
 366
 367         if ( HUD_Radar_InputEvent(bInputType, nPrimary, nSecondary) )
 368                 return true;
 369
 370         if (MapVote_InputEvent(bInputType, nPrimary, nSecondary))
 371                 return true;
 372
 373         if (HUD_Minigame_InputEvent(bInputType, nPrimary, nSecondary))
 374                 return true;
 375
 376         if(menu_visible && menu_action)
 377                 if(menu_action(bInputType, nPrimary, nSecondary))
 378                         return true;
 379
 380         return bSkipKey;
 381 }
 382
 383 // END REQUIRED CSQC FUNCTIONS
 384 // --------------------------------------------------------------------------
 385
 386 // --------------------------------------------------------------------------
 387 // BEGIN OPTIONAL CSQC FUNCTIONS
 388
 389 void Ent_RemoveEntCS()
 390 {SELFPARAM();
 391         entcs_receiver[self.sv_entnum] = NULL;
 392 }
 393 void Ent_ReadEntCS()
 394 {SELFPARAM();
 395         InterpolateOrigin_Undo();
 396         self.classname = "entcs_receiver";
 397         int sf = ReadByte();
 398
 399         if(sf & BIT(0))
 400                 self.sv_entnum = ReadByte();
 401         if (sf & BIT(1))
 402         {
 403                 self.origin_x = ReadShort();
 404                 self.origin_y = ReadShort();
 405                 self.origin_z = ReadShort();
 406                 setorigin(self, self.origin);
 407         }
 408         if (sf & BIT(2))
 409         {
 410                 self.angles_y = ReadByte() * 360.0 / 256;
 411                 self.angles_x = self.angles_z = 0;
 412         }
 413         if (sf & BIT(3))
 414                 self.healthvalue = ReadByte() * 10;
 415         if (sf & BIT(4))
 416                 self.armorvalue = ReadByte() * 10;
 417
 418         entcs_receiver[self.sv_entnum] = self;
 419         self.entremove = Ent_RemoveEntCS;
 420         self.iflags |= IFLAG_ORIGIN;
 421
 422         InterpolateOrigin_Note();
 423 }
 424
 425 void Ent_Remove();
 426
 427 void Ent_RemovePlayerScore()
 428 {SELFPARAM();
 429         if(self.owner) {
 430                 SetTeam(self.owner, -1);
 431                 self.owner.gotscores = 0;
 432                 for(int i = 0; i < MAX_SCORE; ++i) {
 433                         self.owner.(scores[i]) = 0; // clear all scores
 434                 }
 435         }
 436 }
 437
 438 void Ent_ReadPlayerScore()
 439 {SELFPARAM();
 440         int i, n;
 441         bool isNew;
 442         entity o;
 443
 444         // damnit -.- don't want to go change every single .sv_entnum in hud.qc AGAIN
 445         // (no I've never heard of M-x replace-string, sed, or anything like that)
 446         isNew = !self.owner; // workaround for DP bug
 447         n = ReadByte()-1;
 448
 449 #ifdef DP_CSQC_ENTITY_REMOVE_IS_B0RKED
 450         if(!isNew && n != self.sv_entnum)
 451         {
 452                 //print("A CSQC entity changed its owner!\n");
 453                 LOG_INFOF("A CSQC entity changed its owner! (edict: %d, classname: %s)\n", num_for_edict(self), self.classname);
 454                 isNew = true;
 455                 Ent_Remove();
 456                 self.enttype = ENT_CLIENT_SCORES;
 457         }
 458 #endif
 459
 460         self.sv_entnum = n;
 461
 462         if (!(playerslots[self.sv_entnum]))
 463                 playerslots[self.sv_entnum] = spawn();
 464         o = self.owner = playerslots[self.sv_entnum];
 465         o.sv_entnum = self.sv_entnum;
 466         o.gotscores = 1;
 467
 468         //if (!o.sort_prev)
 469         //      RegisterPlayer(o);
 470         //playerchecker will do this for us later, if it has not already done so
 471
 472     int sf, lf;
 473 #if MAX_SCORE <= 8
 474         sf = ReadByte();
 475         lf = ReadByte();
 476 #else
 477         sf = ReadShort();
 478         lf = ReadShort();
 479 #endif
 480     int p;
 481         for(i = 0, p = 1; i < MAX_SCORE; ++i, p *= 2)
 482                 if(sf & p)
 483                 {
 484                         if(lf & p)
 485                                 o.(scores[i]) = ReadInt24_t();
 486                         else
 487                                 o.(scores[i]) = ReadChar();
 488                 }
 489
 490         if(o.sort_prev)
 491                 HUD_UpdatePlayerPos(o); // if not registered, we cannot do this yet!
 492
 493         self.entremove = Ent_RemovePlayerScore;
 494 }
 495
 496 void Ent_ReadTeamScore()
 497 {SELFPARAM();
 498         int i;
 499         entity o;
 500
 501         self.team = ReadByte();
 502         o = self.owner = GetTeam(self.team, true); // these team numbers can always be trusted
 503
 504     int sf, lf;
 505 #if MAX_TEAMSCORE <= 8
 506         sf = ReadByte();
 507         lf = ReadByte();
 508 #else
 509         sf = ReadShort();
 510         lf = ReadShort();
 511 #endif
 512         int p;
 513         for(i = 0, p = 1; i < MAX_TEAMSCORE; ++i, p *= 2)
 514                 if(sf & p)
 515                 {
 516                         if(lf & p)
 517                                 o.(teamscores[i]) = ReadInt24_t();
 518                         else
 519                                 o.(teamscores[i]) = ReadChar();
 520                 }
 521
 522         HUD_UpdateTeamPos(o);
 523 }
 524
 525 void Ent_ClientData()
 526 {
 527         float newspectatee_status;
 528
 529     int f = ReadByte();
 530
 531         scoreboard_showscores_force = (f & 1);
 532
 533         if(f & 2)
 534         {
 535                 newspectatee_status = ReadByte();
 536                 if(newspectatee_status == player_localnum + 1)
 537                         newspectatee_status = -1; // observing
 538         }
 539         else
 540                 newspectatee_status = 0;
 541
 542         spectatorbutton_zoom = (f & 4);
 543
 544         if(f & 8)
 545         {
 546                 angles_held_status = 1;
 547                 angles_held.x = ReadAngle();
 548                 angles_held.y = ReadAngle();
 549                 angles_held.z = 0;
 550         }
 551         else
 552                 angles_held_status = 0;
 553
 554         if(newspectatee_status != spectatee_status)
 555         {
 556                 // clear race stuff
 557                 race_laptime = 0;
 558                 race_checkpointtime = 0;
 559         }
 560         if (autocvar_hud_panel_healtharmor_progressbar_gfx)
 561         {
 562                 if ( (spectatee_status == -1 && newspectatee_status > 0) //before observing, now spectating
 563                   || (spectatee_status > 0 && newspectatee_status > 0 && spectatee_status != newspectatee_status) //changed spectated player
 564                 )
 565                         prev_p_health = -1;
 566                 else if(spectatee_status && !newspectatee_status) //before observing/spectating, now playing
 567                         prev_health = -1;
 568         }
 569         spectatee_status = newspectatee_status;
 570
 571         // we could get rid of spectatee_status, and derive it from player_localentnum and player_localnum
 572 }
 573
 574 void Ent_Nagger()
 575 {
 576     int i, j, b, f;
 577
 578     int nags = ReadByte(); // NAGS NAGS NAGS NAGS NAGS NAGS NADZ NAGS NAGS NAGS
 579
 580         if(!(nags & 4))
 581         {
 582                 if(vote_called_vote)
 583                         strunzone(vote_called_vote);
 584                 vote_called_vote = string_null;
 585                 vote_active = 0;
 586         }
 587         else
 588         {
 589                 vote_active = 1;
 590         }
 591
 592         if(nags & 64)
 593         {
 594                 vote_yescount = ReadByte();
 595                 vote_nocount = ReadByte();
 596                 vote_needed = ReadByte();
 597                 vote_highlighted = ReadChar();
 598         }
 599
 600         if(nags & 128)
 601         {
 602                 if(vote_called_vote)
 603                         strunzone(vote_called_vote);
 604                 vote_called_vote = strzone(ColorTranslateRGB(ReadString()));
 605         }
 606
 607         if(nags & 1)
 608         {
 609                 for(j = 0; j < maxclients; ++j)
 610                         if(playerslots[j])
 611                                 playerslots[j].ready = 1;
 612                 for(i = 1; i <= maxclients; i += 8)
 613                 {
 614                         f = ReadByte();
 615                         for(j = i-1, b = 1; b < 256; b *= 2, ++j)
 616                                 if (!(f & b))
 617                                         if(playerslots[j])
 618                                                 playerslots[j].ready = 0;
 619                 }
 620         }
 621
 622         ready_waiting = (nags & 1);
 623         ready_waiting_for_me = (nags & 2);
 624         vote_waiting = (nags & 4);
 625         vote_waiting_for_me = (nags & 8);
 626         warmup_stage = (nags & 16);
 627 }
 628
 629 void Ent_EliminatedPlayers()
 630 {
 631     int i, j, b, f;
 632
 633     int sf = ReadByte();
 634         if(sf & 1)
 635         {
 636                 for(j = 0; j < maxclients; ++j)
 637                         if(playerslots[j])
 638                                 playerslots[j].eliminated = 1;
 639                 for(i = 1; i <= maxclients; i += 8)
 640                 {
 641                         f = ReadByte();
 642                         for(j = i-1, b = 1; b < 256; b *= 2, ++j)
 643                                 if (!(f & b))
 644                                         if(playerslots[j])
 645                                                 playerslots[j].eliminated = 0;
 646                 }
 647         }
 648 }
 649
 650 void Ent_RandomSeed()
 651 {
 652         float s;
 653         prandom_debug();
 654         s = ReadShort();
 655         psrandom(s);
 656 }
 657
 658 void Ent_ReadAccuracy(void)
 659 {
 660     int f, w;
 661     int sf = ReadInt24_t();
 662         if(sf == 0)
 663         {
 664                 for(w = 0; w <= WEP_LAST - WEP_FIRST; ++w)
 665                         weapon_accuracy[w] = -1;
 666                 return;
 667         }
 668
 669         for(w = 0, f = 1; w <= WEP_LAST - WEP_FIRST; ++w)
 670         {
 671                 if(sf & f)
 672                 {
 673             int b = ReadByte();
 674                         if(b == 0)
 675                                 weapon_accuracy[w] = -1;
 676                         else if(b == 255)
 677                                 weapon_accuracy[w] = 1.0; // no better error handling yet, sorry
 678                         else
 679                                 weapon_accuracy[w] = (b - 1.0) / 100.0;
 680                 }
 681                 if(f == 0x800000)
 682                         f = 1;
 683                 else
 684                         f *= 2;
 685         }
 686 }
 687
 688 void Spawn_Draw(entity this)
 689 {
 690         pointparticles(this.cnt, this.origin + '0 0 28', '0 0 2', bound(0, frametime, 0.1));
 691 }
 692
 693 void Ent_ReadSpawnPoint(float is_new) // entity for spawnpoint
 694 {SELFPARAM();
 695         float teamnum = (ReadByte() - 1);
 696         vector spn_origin;
 697         spn_origin.x = ReadShort();
 698         spn_origin.y = ReadShort();
 699         spn_origin.z = ReadShort();
 700
 701         if(is_new)
 702         {
 703                 self.origin = spn_origin;
 704                 setsize(self, PL_MIN_CONST, PL_MAX_CONST);
 705                 droptofloor();
 706
 707                 /*if(autocvar_cl_spawn_point_model) // needs a model first
 708                 {
 709                         self.mdl = "models/spawnpoint.md3";
 710                         self.colormod = Team_ColorRGB(teamnum);
 711                         precache_model(self.mdl);
 712                         setmodel(self, self.mdl);
 713                         self.drawmask = MASK_NORMAL;
 714                         //self.movetype = MOVETYPE_NOCLIP;
 715                         //self.draw = Spawn_Draw;
 716                 }*/
 717                 if(autocvar_cl_spawn_point_particles)
 718                 {
 719                         if((serverflags & SERVERFLAG_TEAMPLAY))
 720                         {
 721                                 switch(teamnum)
 722                                 {
 723                                         case NUM_TEAM_1: self.cnt = particleeffectnum(EFFECT_SPAWNPOINT_RED); break;
 724                                         case NUM_TEAM_2: self.cnt = particleeffectnum(EFFECT_SPAWNPOINT_BLUE); break;
 725                                         case NUM_TEAM_3: self.cnt = particleeffectnum(EFFECT_SPAWNPOINT_YELLOW); break;
 726                                         case NUM_TEAM_4: self.cnt = particleeffectnum(EFFECT_SPAWNPOINT_PINK); break;
 727                                         default: self.cnt = particleeffectnum(EFFECT_SPAWNPOINT_NEUTRAL); break;
 728                                 }
 729                         }
 730                         else { self.cnt = particleeffectnum(EFFECT_SPAWNPOINT_NEUTRAL); }
 731
 732                         self.draw = Spawn_Draw;
 733                 }
 734         }
 735
 736         //printf("Ent_ReadSpawnPoint(is_new = %d); origin = %s, team = %d, effect = %d\n", is_new, vtos(self.origin), teamnum, self.cnt);
 737 }
 738
 739 void Ent_ReadSpawnEvent(float is_new)
 740 {SELFPARAM();
 741         // If entnum is 0, ONLY do the local spawn actions
 742         // this way the server can disable the sending of
 743         // spawn origin or such to clients if wanted.
 744         float entnum = ReadByte();
 745
 746         if(entnum)
 747         {
 748                 self.origin_x = ReadShort();
 749                 self.origin_y = ReadShort();
 750                 self.origin_z = ReadShort();
 751
 752                 if(is_new)
 753                 {
 754                         float teamnum = GetPlayerColor(entnum - 1);
 755
 756                         if(autocvar_cl_spawn_event_particles)
 757                         {
 758                                 switch(teamnum)
 759                                 {
 760                                         case NUM_TEAM_1: pointparticles(particleeffectnum(EFFECT_SPAWN_RED), self.origin, '0 0 0', 1); break;
 761                                         case NUM_TEAM_2: pointparticles(particleeffectnum(EFFECT_SPAWN_BLUE), self.origin, '0 0 0', 1); break;
 762                                         case NUM_TEAM_3: pointparticles(particleeffectnum(EFFECT_SPAWN_YELLOW), self.origin, '0 0 0', 1); break;
 763                                         case NUM_TEAM_4: pointparticles(particleeffectnum(EFFECT_SPAWN_PINK), self.origin, '0 0 0', 1); break;
 764                                         default: pointparticles(particleeffectnum(EFFECT_SPAWN_NEUTRAL), self.origin, '0 0 0', 1); break;
 765                                 }
 766                         }
 767                         if(autocvar_cl_spawn_event_sound)
 768                         {
 769                                 sound(self, CH_TRIGGER, SND_SPAWN, VOL_BASE, ATTEN_NORM);
 770                         }
 771                 }
 772         }
 773
 774         // local spawn actions
 775         if(is_new && (!entnum || (entnum == player_localentnum)))
 776         {
 777                 zoomin_effect = 1;
 778                 current_viewzoom = (1 / bound(1, autocvar_cl_spawnzoom_factor, 16));
 779
 780                 if(autocvar_cl_unpress_zoom_on_spawn)
 781                 {
 782                         localcmd("-zoom\n");
 783                         button_zoom = false;
 784                 }
 785         }
 786         HUD_Radar_Hide_Maximized();
 787         //printf("Ent_ReadSpawnEvent(is_new = %d); origin = %s, entnum = %d, localentnum = %d\n", is_new, vtos(self.origin), entnum, player_localentnum);
 788 }
 789
 790 // CSQC_Ent_Update : Called every frame that the server has indicated an update to the SSQC / CSQC entity has occured.
 791 // The only parameter reflects if the entity is "new" to the client, meaning it just came into the client's PVS.
 792 void Ent_RadarLink();
 793 void Ent_Init();
 794 void Ent_ScoresInfo();
 795 void CSQC_Ent_Update(float bIsNewEntity)
 796 {SELFPARAM();
 797         int t = ReadByte();
 798
 799         if(autocvar_developer_csqcentities)
 800                 LOG_INFOF("CSQC_Ent_Update(%d) with self=%i self.entnum=%d self.enttype=%d t=%d\n", bIsNewEntity, self, self.entnum, self.enttype, t);
 801
 802         // set up the "time" global for received entities to be correct for interpolation purposes
 803         float savetime = time;
 804         if(servertime)
 805         {
 806                 time = servertime;
 807         }
 808         else
 809         {
 810                 serverprevtime = time;
 811                 serverdeltatime = getstatf(STAT_MOVEVARS_TICRATE) * getstatf(STAT_MOVEVARS_TIMESCALE);
 812                 time = serverprevtime + serverdeltatime;
 813         }
 814
 815 #ifdef DP_CSQC_ENTITY_REMOVE_IS_B0RKED
 816         if(self.enttype)
 817         {
 818                 if(t != self.enttype || bIsNewEntity)
 819                 {
 820                         LOG_INFOF("A CSQC entity changed its type! (edict: %d, server: %d, type: %d -> %d)\n", num_for_edict(self), self.entnum, self.enttype, t);
 821                         Ent_Remove();
 822                         clearentity(self);
 823                         bIsNewEntity = 1;
 824                 }
 825         }
 826         else
 827         {
 828                 if(!bIsNewEntity)
 829                 {
 830                         LOG_INFOF("A CSQC entity appeared out of nowhere! (edict: %d, server: %d, type: %d)\n", num_for_edict(self), self.entnum, t);
 831                         bIsNewEntity = 1;
 832                 }
 833         }
 834 #endif
 835         self.enttype = t;
 836         bool done = false;
 837         FOREACH(LinkedEntities, it.m_id == t, LAMBDA(
 838                 it.m_read(self, bIsNewEntity);
 839                 done = true;
 840                 break;
 841         ));
 842         if (!done)
 843         switch(t)
 844         {
 845                 case ENT_CLIENT_MUTATOR: {
 846                         int mutID = ReadMutator();
 847                         if (!MUTATOR_CALLHOOK(CSQC_Ent_Update, mutID, bIsNewEntity))
 848                         error(sprintf("Unknown mutator type in CSQC_Ent_Update (mutID: %d, edict: %d, classname: %s)\n", mutID, num_for_edict(self), self.classname));
 849                         break;
 850                 }
 851                 case ENT_CLIENT_ENTCS: Ent_ReadEntCS(); break;
 852                 case ENT_CLIENT_SCORES: Ent_ReadPlayerScore(); break;
 853                 case ENT_CLIENT_TEAMSCORES: Ent_ReadTeamScore(); break;
 854                 case ENT_CLIENT_POINTPARTICLES: Ent_PointParticles(); break;
 855                 case ENT_CLIENT_RAINSNOW: Ent_RainOrSnow(); break;
 856                 case ENT_CLIENT_LASER: Ent_Laser(); break;
 857                 case ENT_CLIENT_NAGGER: Ent_Nagger(); break;
 858                 case ENT_CLIENT_ELIMINATEDPLAYERS: Ent_EliminatedPlayers(); break;
 859                 case ENT_CLIENT_RADARLINK: Ent_RadarLink(); break;
 860                 case ENT_CLIENT_PROJECTILE: Ent_Projectile(); break;
 861                 case ENT_CLIENT_GIBSPLASH: Ent_GibSplash(bIsNewEntity); break;
 862                 case ENT_CLIENT_DAMAGEINFO: Ent_DamageInfo(bIsNewEntity); break;
 863                 case ENT_CLIENT_INIT: Ent_Init(); break;
 864                 case ENT_CLIENT_SCORES_INFO: Ent_ScoresInfo(); break;
 865                 case ENT_CLIENT_MAPVOTE: Ent_MapVote(); break;
 866                 case ENT_CLIENT_CLIENTDATA: Ent_ClientData(); break;
 867                 case ENT_CLIENT_RANDOMSEED: Ent_RandomSeed(); break;
 868                 case ENT_CLIENT_WALL: Ent_Wall(); break;
 869                 case ENT_CLIENT_MODELEFFECT: Ent_ModelEffect(bIsNewEntity); break;
 870                 case ENT_CLIENT_TUBANOTE: Ent_TubaNote(bIsNewEntity); break;
 871                 case ENT_CLIENT_WARPZONE: WarpZone_Read(bIsNewEntity); break;
 872                 case ENT_CLIENT_WARPZONE_CAMERA: WarpZone_Camera_Read(bIsNewEntity); break;
 873                 case ENT_CLIENT_WARPZONE_TELEPORTED: WarpZone_Teleported_Read(bIsNewEntity); break;
 874                 case ENT_CLIENT_TRIGGER_MUSIC: Ent_ReadTriggerMusic(); break;
 875                 case ENT_CLIENT_HOOK: Ent_ReadHook(bIsNewEntity, ENT_CLIENT_HOOK); break;
 876                 case ENT_CLIENT_INVENTORY: Inventory_Read(self); break;
 877                 case ENT_CLIENT_ARC_BEAM: Ent_ReadArcBeam(bIsNewEntity); break;
 878                 case ENT_CLIENT_ACCURACY: Ent_ReadAccuracy(); break;
 879                 case ENT_CLIENT_AUXILIARYXHAIR: Net_AuXair2(bIsNewEntity); break;
 880                 case ENT_CLIENT_TURRET: ent_turret(); break;
 881                 case ENT_CLIENT_GENERATOR: ent_generator(); break;
 882                 case ENT_CLIENT_CONTROLPOINT_ICON: ent_cpicon(this); break;
 883                 case ENT_CLIENT_MODEL: CSQCModel_Read(bIsNewEntity); break;
 884                 case ENT_CLIENT_ITEM: ItemRead(bIsNewEntity); break;
 885                 case ENT_CLIENT_BUMBLE_RAYGUN: bumble_raygun_read(bIsNewEntity); break;
 886                 case ENT_CLIENT_SPAWNPOINT: Ent_ReadSpawnPoint(bIsNewEntity); break;
 887                 case ENT_CLIENT_SPAWNEVENT: Ent_ReadSpawnEvent(bIsNewEntity); break;
 888                 case ENT_CLIENT_NOTIFICATION: Read_Notification(bIsNewEntity); break;
 889                 case ENT_CLIENT_MINIGAME: ent_read_minigame(); break;
 890                 case ENT_CLIENT_VIEWLOC: ent_viewloc(); break;
 891                 case ENT_CLIENT_VIEWLOC_TRIGGER: ent_viewloc_trigger(); break;
 892                 case ENT_CLIENT_LADDER: ent_func_ladder(); break;
 893                 case ENT_CLIENT_TRIGGER_PUSH: ent_trigger_push(); break;
 894                 case ENT_CLIENT_TARGET_PUSH: ent_target_push(); break;
 895                 case ENT_CLIENT_CONVEYOR: ent_conveyor(); break;
 896                 case ENT_CLIENT_DOOR: ent_door(); break;
 897                 case ENT_CLIENT_PLAT: ent_plat(); break;
 898                 case ENT_CLIENT_SWAMP: ent_swamp(); break;
 899                 case ENT_CLIENT_CORNER: ent_corner(); break;
 900                 case ENT_CLIENT_KEYLOCK: ent_keylock(); break;
 901                 case ENT_CLIENT_TRAIN: ent_train(); break;
 902                 case ENT_CLIENT_TRIGGER_IMPULSE: ent_trigger_impulse(); break;
 903                 case ENT_CLIENT_EFFECT: Read_Effect(bIsNewEntity); break;
 904
 905                 default:
 906                         //error(strcat(_("unknown entity type in CSQC_Ent_Update: %d\n"), self.enttype));
 907                         error(sprintf("Unknown entity type in CSQC_Ent_Update (enttype: %d, edict: %d, classname: %s)\n", self.enttype, num_for_edict(self), self.classname));
 908                         break;
 909         }
 910
 911         time = savetime;
 912 }
 913 // Destructor, but does NOT deallocate the entity by calling remove(). Also
 914 // used when an entity changes its type. For an entity that someone interacts
 915 // with others, make sure it can no longer do so.
 916 void Ent_Remove()
 917 {SELFPARAM();
 918         if(self.entremove)
 919                 self.entremove();
 920
 921         if(self.skeletonindex)
 922         {
 923                 skel_delete(self.skeletonindex);
 924                 self.skeletonindex = 0;
 925         }
 926
 927         if(self.snd_looping > 0)
 928         {
 929                 sound(self, self.snd_looping, SND_Null, VOL_BASE, autocvar_g_jetpack_attenuation);
 930                 self.snd_looping = 0;
 931         }
 932
 933         self.enttype = 0;
 934         self.classname = "";
 935         self.draw = draw_null;
 936         self.entremove = menu_sub_null;
 937         // TODO possibly set more stuff to defaults
 938 }
 939 // CSQC_Ent_Remove : Called when the server requests a SSQC / CSQC entity to be removed.  Essentially call remove(self) as well.
 940 void CSQC_Ent_Remove()
 941 {SELFPARAM();
 942         if(autocvar_developer_csqcentities)
 943                 LOG_INFOF("CSQC_Ent_Remove() with self=%i self.entnum=%d self.enttype=%d\n", self, self.entnum, self.enttype);
 944
 945         if(wasfreed(self))
 946         {
 947                 LOG_INFO("WARNING: CSQC_Ent_Remove called for already removed entity. Packet loss?\n");
 948                 return;
 949         }
 950         if(self.enttype)
 951                 Ent_Remove();
 952         remove(self);
 953 }
 954
 955 void Gamemode_Init()
 956 {
 957         if (!isdemo())
 958         {
 959                 if(!(calledhooks & HOOK_START))
 960                         localcmd("\n_cl_hook_gamestart ", MapInfo_Type_ToString(gametype), "\n");
 961                 calledhooks |= HOOK_START;
 962         }
 963 }
 964 // CSQC_Parse_StuffCmd : Provides the stuffcmd string in the first parameter that the server provided.  To execute standard behavior, simply execute localcmd with the string.
 965 void CSQC_Parse_StuffCmd(string strMessage)
 966 {
 967         if(autocvar_developer_csqcentities)
 968                 LOG_INFOF("CSQC_Parse_StuffCmd(\"%s\")\n", strMessage);
 969
 970         localcmd(strMessage);
 971 }
 972 // CSQC_Parse_Print : Provides the print string in the first parameter that the server provided.  To execute standard behavior, simply execute print with the string.
 973 void CSQC_Parse_Print(string strMessage)
 974 {
 975         if(autocvar_developer_csqcentities)
 976                 LOG_INFOF("CSQC_Parse_Print(\"%s\")\n", strMessage);
 977
 978         print(ColorTranslateRGB(strMessage));
 979 }
 980
 981 // CSQC_Parse_CenterPrint : Provides the centerprint_hud string in the first parameter that the server provided.
 982 void CSQC_Parse_CenterPrint(string strMessage)
 983 {
 984         if(autocvar_developer_csqcentities)
 985                 LOG_INFOF("CSQC_Parse_CenterPrint(\"%s\")\n", strMessage);
 986
 987         centerprint_hud(strMessage);
 988 }
 989
 990 string notranslate_fogcmd1 = "\nfog ";
 991 string notranslate_fogcmd2 = "\nr_fog_exp2 0\nr_drawfog 1\n";
 992 void Fog_Force()
 993 {
 994         // TODO somehow thwart prvm_globalset client ...
 995
 996         if(autocvar_cl_orthoview && autocvar_cl_orthoview_nofog)
 997                 { localcmd("\nr_drawfog 0\n"); }
 998         else if(forcefog != "")
 999                 { localcmd(strcat(notranslate_fogcmd1, forcefog, notranslate_fogcmd2)); }
1000 }
1001
1002 void Gamemode_Init();
1003 void Ent_ScoresInfo()
1004 {SELFPARAM();
1005     int i;
1006         self.classname = "ent_client_scores_info";
1007         gametype = ReadInt24_t();
1008         HUD_ModIcons_SetFunc();
1009         for(i = 0; i < MAX_SCORE; ++i)
1010         {
1011                 if(scores_label[i])
1012                         strunzone(scores_label[i]);
1013                 scores_label[i] = strzone(ReadString());
1014                 scores_flags[i] = ReadByte();
1015         }
1016         for(i = 0; i < MAX_TEAMSCORE; ++i)
1017         {
1018                 if(teamscores_label[i])
1019                         strunzone(teamscores_label[i]);
1020                 teamscores_label[i] = strzone(ReadString());
1021                 teamscores_flags[i] = ReadByte();
1022         }
1023         HUD_InitScores();
1024         Gamemode_Init();
1025 }
1026
1027 void Ent_Init()
1028 {SELFPARAM();
1029         self.classname = "ent_client_init";
1030
1031         nb_pb_period = ReadByte() / 32; //Accuracy of 1/32th
1032
1033         hook_shotorigin[0] = decompressShotOrigin(ReadInt24_t());
1034         hook_shotorigin[1] = decompressShotOrigin(ReadInt24_t());
1035         hook_shotorigin[2] = decompressShotOrigin(ReadInt24_t());
1036         hook_shotorigin[3] = decompressShotOrigin(ReadInt24_t());
1037         arc_shotorigin[0] = decompressShotOrigin(ReadInt24_t());
1038         arc_shotorigin[1] = decompressShotOrigin(ReadInt24_t());
1039         arc_shotorigin[2] = decompressShotOrigin(ReadInt24_t());
1040         arc_shotorigin[3] = decompressShotOrigin(ReadInt24_t());
1041
1042         if(forcefog)
1043                 strunzone(forcefog);
1044         forcefog = strzone(ReadString());
1045
1046         armorblockpercent = ReadByte() / 255.0;
1047
1048         g_balance_mortar_bouncefactor = ReadCoord();
1049         g_balance_mortar_bouncestop = ReadCoord();
1050         g_balance_electro_secondary_bouncefactor = ReadCoord();
1051         g_balance_electro_secondary_bouncestop = ReadCoord();
1052
1053         vortex_scope = !ReadByte();
1054         rifle_scope = !ReadByte();
1055
1056         serverflags = ReadByte();
1057
1058         minelayer_maxmines = ReadByte();
1059
1060         hagar_maxrockets = ReadByte();
1061
1062         g_trueaim_minrange = ReadCoord();
1063         g_balance_porto_secondary = ReadByte();
1064
1065         if(!postinit)
1066                 PostInit();
1067 }
1068
1069 void Net_ReadRace()
1070 {
1071         float b;
1072
1073         b = ReadByte();
1074
1075         switch(b)
1076         {
1077                 case RACE_NET_CHECKPOINT_HIT_QUALIFYING:
1078                         race_checkpoint = ReadByte();
1079                         race_time = ReadInt24_t();
1080                         race_previousbesttime = ReadInt24_t();
1081                         if(race_previousbestname)
1082                                 strunzone(race_previousbestname);
1083                         race_previousbestname = strzone(ColorTranslateRGB(ReadString()));
1084
1085                         race_checkpointtime = time;
1086
1087                         if(race_checkpoint == 0 || race_checkpoint == 254)
1088                         {
1089                                 race_penaltyaccumulator = 0;
1090                                 race_laptime = time; // valid
1091                         }
1092
1093                         break;
1094
1095                 case RACE_NET_CHECKPOINT_CLEAR:
1096                         race_laptime = 0;
1097                         race_checkpointtime = 0;
1098                         break;
1099
1100                 case RACE_NET_CHECKPOINT_NEXT_SPEC_QUALIFYING:
1101                         race_laptime = ReadCoord();
1102                         race_checkpointtime = -99999;
1103                         // fall through
1104                 case RACE_NET_CHECKPOINT_NEXT_QUALIFYING:
1105                         race_nextcheckpoint = ReadByte();
1106
1107                         race_nextbesttime = ReadInt24_t();
1108                         if(race_nextbestname)
1109                                 strunzone(race_nextbestname);
1110                         race_nextbestname = strzone(ColorTranslateRGB(ReadString()));
1111                         break;
1112
1113                 case RACE_NET_CHECKPOINT_HIT_RACE:
1114                         race_mycheckpoint = ReadByte();
1115                         race_mycheckpointtime = time;
1116                         race_mycheckpointdelta = ReadInt24_t();
1117                         race_mycheckpointlapsdelta = ReadByte();
1118                         if(race_mycheckpointlapsdelta >= 128)
1119                                 race_mycheckpointlapsdelta -= 256;
1120                         if(race_mycheckpointenemy)
1121                                 strunzone(race_mycheckpointenemy);
1122                         race_mycheckpointenemy = strzone(ColorTranslateRGB(ReadString()));
1123                         break;
1124
1125                 case RACE_NET_CHECKPOINT_HIT_RACE_BY_OPPONENT:
1126                         race_othercheckpoint = ReadByte();
1127                         race_othercheckpointtime = time;
1128                         race_othercheckpointdelta = ReadInt24_t();
1129                         race_othercheckpointlapsdelta = ReadByte();
1130                         if(race_othercheckpointlapsdelta >= 128)
1131                                 race_othercheckpointlapsdelta -= 256;
1132                         if(race_othercheckpointenemy)
1133                                 strunzone(race_othercheckpointenemy);
1134                         race_othercheckpointenemy = strzone(ColorTranslateRGB(ReadString()));
1135                         break;
1136
1137                 case RACE_NET_PENALTY_RACE:
1138                         race_penaltyeventtime = time;
1139                         race_penaltytime = ReadShort();
1140                         //race_penaltyaccumulator += race_penaltytime;
1141                         if(race_penaltyreason)
1142                                 strunzone(race_penaltyreason);
1143                         race_penaltyreason = strzone(ReadString());
1144                         break;
1145
1146                 case RACE_NET_PENALTY_QUALIFYING:
1147                         race_penaltyeventtime = time;
1148                         race_penaltytime = ReadShort();
1149                         race_penaltyaccumulator += race_penaltytime;
1150                         if(race_penaltyreason)
1151                                 strunzone(race_penaltyreason);
1152                         race_penaltyreason = strzone(ReadString());
1153                         break;
1154
1155                 case RACE_NET_SERVER_RECORD:
1156                         race_server_record = ReadInt24_t();
1157                         break;
1158                 case RACE_NET_SPEED_AWARD:
1159                         race_speedaward = ReadInt24_t();
1160                         if(race_speedaward_holder)
1161                                 strunzone(race_speedaward_holder);
1162                         race_speedaward_holder = strzone(ReadString());
1163                         break;
1164                 case RACE_NET_SPEED_AWARD_BEST:
1165                         race_speedaward_alltimebest = ReadInt24_t();
1166                         if(race_speedaward_alltimebest_holder)
1167                                 strunzone(race_speedaward_alltimebest_holder);
1168                         race_speedaward_alltimebest_holder = strzone(ReadString());
1169                         break;
1170                 case RACE_NET_SERVER_RANKINGS:
1171                         float prevpos, del;
1172             int pos = ReadShort();
1173                         prevpos = ReadShort();
1174                         del = ReadShort();
1175
1176                         // move other rankings out of the way
1177             int i;
1178                         if (prevpos) {
1179                                 for (i=prevpos-1;i>pos-1;--i) {
1180                                         grecordtime[i] = grecordtime[i-1];
1181                                         if(grecordholder[i])
1182                                                 strunzone(grecordholder[i]);
1183                                         grecordholder[i] = strzone(grecordholder[i-1]);
1184                                 }
1185                         } else if (del) { // a record has been deleted by the admin
1186                                 for (i=pos-1; i<= RANKINGS_CNT-1; ++i) {
1187                                         if (i == RANKINGS_CNT-1) { // clear out last record
1188                                                 grecordtime[i] = 0;
1189                                                 if (grecordholder[i])
1190                                                         strunzone(grecordholder[i]);
1191                                                 grecordholder[i] = string_null;
1192                                         }
1193                                         else {
1194                                                 grecordtime[i] = grecordtime[i+1];
1195                                                 if (grecordholder[i])
1196                                                         strunzone(grecordholder[i]);
1197                                                 grecordholder[i] = strzone(grecordholder[i+1]);
1198                                         }
1199                                 }
1200                         } else { // player has no ranked record yet
1201                                 for (i=RANKINGS_CNT-1;i>pos-1;--i) {
1202                                         grecordtime[i] = grecordtime[i-1];
1203                                         if(grecordholder[i])
1204                                                 strunzone(grecordholder[i]);
1205                                         grecordholder[i] = strzone(grecordholder[i-1]);
1206                                 }
1207                         }
1208
1209                         // store new ranking
1210                         if(grecordholder[pos-1] != "")
1211                                 strunzone(grecordholder[pos-1]);
1212                         grecordholder[pos-1] = strzone(ReadString());
1213                         grecordtime[pos-1] = ReadInt24_t();
1214                         if(grecordholder[pos-1] == GetPlayerName(player_localnum))
1215                                 race_myrank = pos;
1216                         break;
1217                 case RACE_NET_SERVER_STATUS:
1218                         race_status = ReadShort();
1219                         if(race_status_name)
1220                                 strunzone(race_status_name);
1221                         race_status_name = strzone(ReadString());
1222         }
1223 }
1224
1225 void Net_TeamNagger()
1226 {
1227         teamnagger = 1;
1228 }
1229
1230 void Net_ReadPingPLReport()
1231 {
1232         int e, pi, pl, ml;
1233         e = ReadByte();
1234         pi = ReadShort();
1235         pl = ReadByte();
1236         ml = ReadByte();
1237         if (!(playerslots[e]))
1238                 return;
1239         playerslots[e].ping = pi;
1240         playerslots[e].ping_packetloss = pl / 255.0;
1241         playerslots[e].ping_movementloss = ml / 255.0;
1242 }
1243
1244 void Net_WeaponComplain()
1245 {
1246         complain_weapon = ReadByte();
1247
1248         if(complain_weapon_name)
1249                 strunzone(complain_weapon_name);
1250         complain_weapon_name = strzone(WEP_NAME(complain_weapon));
1251
1252         complain_weapon_type = ReadByte();
1253
1254         complain_weapon_time = time;
1255         weapontime = time; // ping the weapon panel
1256
1257         switch(complain_weapon_type)
1258         {
1259                 case 0: Local_Notification(MSG_MULTI, ITEM_WEAPON_NOAMMO, complain_weapon); break;
1260                 case 1: Local_Notification(MSG_MULTI, ITEM_WEAPON_DONTHAVE, complain_weapon); break;
1261                 default: Local_Notification(MSG_MULTI, ITEM_WEAPON_UNAVAILABLE, complain_weapon); break;
1262         }
1263 }
1264
1265 // CSQC_Parse_TempEntity : Handles all temporary entity network data in the CSQC layer.
1266 // You must ALWAYS first acquire the temporary ID, which is sent as a byte.
1267 // Return value should be 1 if CSQC handled the temporary entity, otherwise return 0 to have the engine process the event.
1268 bool CSQC_Parse_TempEntity()
1269 {
1270         // Acquire TE ID
1271         int nTEID = ReadByte();
1272
1273         if (autocvar_developer_csqcentities)
1274                 LOG_INFOF("CSQC_Parse_TempEntity() with nTEID=%d\n", nTEID);
1275
1276         FOREACH(TempEntities, it.m_id == nTEID, LAMBDA(
1277                 it.m_read(NULL, true);
1278                 return true;
1279         ));
1280         switch (nTEID)
1281         {
1282                 case TE_CSQC_MUTATOR:
1283                         int mutID = ReadMutator();
1284                         if (MUTATOR_CALLHOOK(CSQC_Parse_TempEntity, mutID))
1285                         return true;
1286                 case TE_CSQC_TARGET_MUSIC:
1287                         Net_TargetMusic();
1288                         return true;
1289                 case TE_CSQC_PICTURE:
1290                         Net_MapVote_Picture();
1291                         return true;
1292                 case TE_CSQC_RACE:
1293                         Net_ReadRace();
1294                         return true;
1295                 case TE_CSQC_VORTEXBEAMPARTICLE:
1296                         Net_ReadVortexBeamParticle();
1297                         return true;
1298                 case TE_CSQC_TEAMNAGGER:
1299                         Net_TeamNagger();
1300                         return true;
1301                 case TE_CSQC_ARC:
1302                         Net_ReadArc();
1303                         return true;
1304                 case TE_CSQC_PINGPLREPORT:
1305                         Net_ReadPingPLReport();
1306                         return true;
1307                 case TE_CSQC_WEAPONCOMPLAIN:
1308                         Net_WeaponComplain();
1309                         return true;
1310                 case TE_CSQC_VEHICLESETUP:
1311                         Net_VehicleSetup();
1312                         return true;
1313                 case TE_CSQC_SVNOTICE:
1314                         cl_notice_read();
1315                         return true;
1316                 case TE_CSQC_SHOCKWAVEPARTICLE:
1317                         Net_ReadShockwaveParticle();
1318                         return true;
1319                 default:
1320                         // No special logic for this temporary entity; return 0 so the engine can handle it
1321                         return false;
1322         }
1323 }
1324
1325 string getcommandkey(string text, string command)
1326 {
1327         string keys;
1328         float n, j, k, l = 0;
1329
1330         if (!autocvar_hud_showbinds)
1331                 return text;
1332
1333         keys = db_get(binddb, command);
1334         if (keys == "")
1335         {
1336                 n = tokenize(findkeysforcommand(command, 0)); // uses '...' strings
1337                 for(j = 0; j < n; ++j)
1338                 {
1339                         k = stof(argv(j));
1340                         if(k != -1)
1341                         {
1342                                 if ("" == keys)
1343                                         keys = keynumtostring(k);
1344                                 else
1345                                         keys = strcat(keys, ", ", keynumtostring(k));
1346
1347                                 ++l;
1348                                 if (autocvar_hud_showbinds_limit > 0 && autocvar_hud_showbinds_limit <= l)
1349                                         break;
1350                         }
1351
1352                 }
1353                 if (keys == "")
1354                         keys = "NO_KEY";
1355                 db_put(binddb, command, keys);
1356         }
1357
1358         if (keys == "NO_KEY") {
1359                 if (autocvar_hud_showbinds > 1)
1360                         return sprintf(_("%s (not bound)"), text);
1361                 else
1362                         return text;
1363         }
1364         else if (autocvar_hud_showbinds > 1)
1365                 return sprintf("%s (%s)", text, keys);
1366         else
1367                 return keys;
1368 }