qcsrc/client/main.qc

   1 #include "main.qh"
   2 #include "_all.qh"
   3
   4 #include "controlpoint.qh"
   5 #include "damage.qh"
   6 #include "effects.qh"
   7 #include "generator.qh"
   8 #include "gibs.qh"
   9 #include "hook.qh"
  10 #include "hud.qh"
  11 #include "hud_config.qh"
  12 #include "laser.qh"
  13 #include "mapvoting.qh"
  14 #include "modeleffects.qh"
  15 #include "particles.qh"
  16 #include "scoreboard.qh"
  17 #include "shownames.qh"
  18 #include "tuba.qh"
  19 #include "t_items.qh"
  20 #include "wall.qh"
  21
  22 #include "../common/vehicles/all.qh"
  23
  24 #include "mutators/events.qh"
  25
  26 #include "weapons/projectile.qh"
  27
  28 #include "../common/buffs.qh"
  29 #include "../common/deathtypes.qh"
  30 #include "../common/effects/effects.qh"
  31 #include "../common/mapinfo.qh"
  32 #include "../common/monsters/all.qh"
  33 #include "../common/nades.qh"
  34 #include "../common/net_notice.qh"
  35 #include "../common/notifications.qh"
  36 #include "../common/stats.qh"
  37 #include "../common/teams.qh"
  38
  39 #include "../common/items/all.qh"
  40
  41 #include "../common/mutators/base.qh"
  42
  43 #include "../common/weapons/all.qh"
  44
  45 #include "../csqcmodellib/cl_model.qh"
  46 #include "../csqcmodellib/interpolate.qh"
  47
  48 #include "../common/triggers/include.qh"
  49
  50 #include "../common/turrets/cl_turrets.qh"
  51
  52 #include "../warpzonelib/client.qh"
  53
  54 // --------------------------------------------------------------------------
  55 // BEGIN REQUIRED CSQC FUNCTIONS
  56 //include "main.qh"
  57
  58 entity clearentity_ent;
  59 void clearentity(entity e)
  60 {
  61         if (!clearentity_ent)
  62         {
  63                 clearentity_ent = spawn();
  64                 clearentity_ent.classname = "clearentity";
  65         }
  66         int n = e.entnum;
  67         copyentity(clearentity_ent, e);
  68         e.entnum = n;
  69 }
  70
  71 #define DP_CSQC_ENTITY_REMOVE_IS_B0RKED
  72 void menu_show_error()
  73 {
  74         drawstring('0 200 0', _("ERROR - MENU IS VISIBLE BUT NO MENU WAS DEFINED!"), '8 8 0', '1 0 0', 1, 0);
  75 }
  76
  77 // CSQC_Init : Called every time the CSQC code is initialized (essentially at map load)
  78 // Useful for precaching things
  79
  80 void menu_sub_null()
  81 {
  82 }
  83
  84 string forcefog;
  85 void ConsoleCommand_macro_init();
  86 void CSQC_Init(void)
  87 {
  88         prvm_language = strzone(cvar_string("prvm_language"));
  89
  90 #ifdef WATERMARK
  91         LOG_TRACEF("^4CSQC Build information: ^1%s\n", WATERMARK);
  92 #endif
  93
  94         int i;
  95
  96         binddb = db_create();
  97         tempdb = db_create();
  98         ClientProgsDB = db_load("client.db");
  99         compressShortVector_init();
 100
 101         draw_endBoldFont();
 102         menu_visible = false;
 103         menu_show = menu_show_error;
 104         menu_action = func_null;
 105
 106         for(i = 0; i < 255; ++i)
 107                 if(getplayerkeyvalue(i, "viewentity") == "")
 108                         break;
 109         maxclients = i;
 110
 111         //registercommand("hud_configure");
 112         //registercommand("hud_save");
 113         //registercommand("menu_action");
 114
 115         ConsoleCommand_macro_init();
 116
 117         registercvar("hud_usecsqc", "1");
 118         registercvar("scoreboard_columns", "default");
 119
 120         registercvar("cl_nade_type", "3");
 121         registercvar("cl_pokenade_type", "zombie");
 122
 123         registercvar("cl_jumpspeedcap_min", "");
 124         registercvar("cl_jumpspeedcap_max", "");
 125
 126         registercvar("cl_multijump", "0");
 127
 128         registercvar("cl_spawn_near_teammate", "1");
 129
 130         gametype = 0;
 131
 132         // hud_fields uses strunzone on the titles!
 133         for(i = 0; i < MAX_HUD_FIELDS; ++i)
 134                 hud_title[i] = strzone("(null)");
 135
 136         Cmd_HUD_SetFields(0);
 137
 138         postinit = false;
 139
 140         calledhooks = 0;
 141
 142         teams = Sort_Spawn();
 143         players = Sort_Spawn();
 144
 145         GetTeam(NUM_SPECTATOR, true); // add specs first
 146
 147         // needs to be done so early because of the constants they create
 148         static_init();
 149         CALL_ACCUMULATED_FUNCTION(RegisterNotifications);
 150         CALL_ACCUMULATED_FUNCTION(RegisterDeathtypes);
 151         CALL_ACCUMULATED_FUNCTION(RegisterHUD_Panels);
 152
 153         // precaches
 154
 155         Projectile_Precache();
 156         Tuba_Precache();
 157
 158         if(autocvar_cl_reticle)
 159         {
 160                 precache_pic("gfx/reticle_normal");
 161                 // weapon reticles are precached in weapon files
 162         }
 163
 164         get_mi_min_max_texcoords(1); // try the CLEVER way first
 165         minimapname = strcat("gfx/", mi_shortname, "_radar.tga");
 166         shortmapname = mi_shortname;
 167
 168         if(precache_pic(minimapname) == "")
 169         {
 170                 // but maybe we have a non-clever minimap
 171                 minimapname = strcat("gfx/", mi_shortname, "_mini.tga");
 172                 if(precache_pic(minimapname) == "")
 173                         minimapname = ""; // FAIL
 174                 else
 175                         get_mi_min_max_texcoords(0); // load new texcoords
 176         }
 177
 178         mi_center = (mi_min + mi_max) * 0.5;
 179         mi_scale = mi_max - mi_min;
 180         minimapname = strzone(minimapname);
 181
 182         WarpZone_Init();
 183
 184         hud_skin_path = strzone(strcat("gfx/hud/", autocvar_hud_skin));
 185         draw_currentSkin = strzone(strcat("gfx/menu/", cvar_string("menu_skin")));
 186 }
 187
 188 // CSQC_Shutdown : Called every time the CSQC code is shutdown (changing maps, quitting, etc)
 189 void Shutdown(void)
 190 {
 191         WarpZone_Shutdown();
 192
 193         remove(teams);
 194         remove(players);
 195         db_close(binddb);
 196         db_close(tempdb);
 197         if(autocvar_cl_db_saveasdump)
 198                 db_dump(ClientProgsDB, "client.db");
 199         else
 200                 db_save(ClientProgsDB, "client.db");
 201         db_close(ClientProgsDB);
 202
 203         if(camera_active)
 204                 cvar_set("chase_active",ftos(chase_active_backup));
 205
 206         // unset the event chasecam's chase_active
 207         if(autocvar_chase_active < 0)
 208                 cvar_set("chase_active", "0");
 209
 210         if (!isdemo())
 211         {
 212                 if (!(calledhooks & HOOK_START))
 213                         localcmd("\n_cl_hook_gamestart nop\n");
 214                 if (!(calledhooks & HOOK_END))
 215                         localcmd("\ncl_hook_gameend\n");
 216         }
 217
 218         deactivate_minigame();
 219         HUD_MinigameMenu_Close();
 220 }
 221
 222 .float has_team;
 223 float SetTeam(entity o, int Team)
 224 {
 225         entity tm;
 226         if(teamplay)
 227         {
 228                 switch(Team)
 229                 {
 230                         case -1:
 231                         case NUM_TEAM_1:
 232                         case NUM_TEAM_2:
 233                         case NUM_TEAM_3:
 234                         case NUM_TEAM_4:
 235                                 break;
 236                         default:
 237                                 if(GetTeam(Team, false) == world)
 238                                 {
 239                                         LOG_TRACEF("trying to switch to unsupported team %d\n", Team);
 240                                         Team = NUM_SPECTATOR;
 241                                 }
 242                                 break;
 243                 }
 244         }
 245         else
 246         {
 247                 switch(Team)
 248                 {
 249                         case -1:
 250                         case 0:
 251                                 break;
 252                         default:
 253                                 if(GetTeam(Team, false) == world)
 254                                 {
 255                                         LOG_TRACEF("trying to switch to unsupported team %d\n", Team);
 256                                         Team = NUM_SPECTATOR;
 257                                 }
 258                                 break;
 259                 }
 260         }
 261         if(Team == -1) // leave
 262         {
 263                 if(o.has_team)
 264                 {
 265                         tm = GetTeam(o.team, false);
 266                         tm.team_size -= 1;
 267                         o.has_team = 0;
 268                         return true;
 269                 }
 270         }
 271         else
 272         {
 273                 if (!o.has_team)
 274                 {
 275                         o.team = Team;
 276                         tm = GetTeam(Team, true);
 277                         tm.team_size += 1;
 278                         o.has_team = 1;
 279                         return true;
 280                 }
 281                 else if(Team != o.team)
 282                 {
 283                         tm = GetTeam(o.team, false);
 284                         tm.team_size -= 1;
 285                         o.team = Team;
 286                         tm = GetTeam(Team, true);
 287                         tm.team_size += 1;
 288                         return true;
 289                 }
 290         }
 291         return false;
 292 }
 293
 294 void Playerchecker_Think()
 295 {SELFPARAM();
 296     int i;
 297         entity e;
 298         for(i = 0; i < maxclients; ++i)
 299         {
 300                 e = playerslots[i];
 301                 if(GetPlayerName(i) == "")
 302                 {
 303                         if(e.sort_prev)
 304                         {
 305                                 // player disconnected
 306                                 SetTeam(e, -1);
 307                                 RemovePlayer(e);
 308                                 e.sort_prev = world;
 309                                 //e.gotscores = 0;
 310                         }
 311                 }
 312                 else
 313                 {
 314                         if (!e.sort_prev)
 315                         {
 316                                 // player connected
 317                                 if (!e)
 318                                         playerslots[i] = e = spawn();
 319                                 e.sv_entnum = i;
 320                                 e.ping = 0;
 321                                 e.ping_packetloss = 0;
 322                                 e.ping_movementloss = 0;
 323                                 //e.gotscores = 0; // we might already have the scores...
 324                                 SetTeam(e, GetPlayerColor(i)); // will not hurt; later updates come with HUD_UpdatePlayerTeams
 325                                 RegisterPlayer(e);
 326                                 HUD_UpdatePlayerPos(e);
 327                         }
 328                 }
 329         }
 330         self.nextthink = time + 0.2;
 331 }
 332
 333 void Porto_Init();
 334 void TrueAim_Init();
 335 void PostInit(void)
 336 {
 337         entity playerchecker;
 338         playerchecker = spawn();
 339         playerchecker.think = Playerchecker_Think;
 340         playerchecker.nextthink = time + 0.2;
 341
 342         Porto_Init();
 343         TrueAim_Init();
 344
 345         postinit = true;
 346 }
 347
 348 // CSQC_InputEvent : Used to perform actions based on any key pressed, key released and mouse on the client.
 349 // Return value should be 1 if CSQC handled the input, otherwise return 0 to have the input passed to the engine.
 350 // All keys are in ascii.
 351 // bInputType = 0 is key pressed, 1 is key released, 2 and 3 are mouse input.
 352 // In the case of keyboard input, nPrimary is the ascii code, and nSecondary is 0.
 353 // In the case of mouse input, nPrimary is xdelta, nSecondary is ydelta.
 354 // In the case of mouse input after a setcursormode(1) call, nPrimary is xpos, nSecondary is ypos.
 355 float CSQC_InputEvent(float bInputType, float nPrimary, float nSecondary)
 356 {
 357         float bSkipKey;
 358         bSkipKey = false;
 359
 360         if (HUD_Panel_InputEvent(bInputType, nPrimary, nSecondary))
 361                 return true;
 362
 363         if (QuickMenu_InputEvent(bInputType, nPrimary, nSecondary))
 364                 return true;
 365
 366         if ( HUD_Radar_InputEvent(bInputType, nPrimary, nSecondary) )
 367                 return true;
 368
 369         if (MapVote_InputEvent(bInputType, nPrimary, nSecondary))
 370                 return true;
 371
 372         if (HUD_Minigame_InputEvent(bInputType, nPrimary, nSecondary))
 373                 return true;
 374
 375         if(menu_visible && menu_action)
 376                 if(menu_action(bInputType, nPrimary, nSecondary))
 377                         return true;
 378
 379         return bSkipKey;
 380 }
 381
 382 // END REQUIRED CSQC FUNCTIONS
 383 // --------------------------------------------------------------------------
 384
 385 // --------------------------------------------------------------------------
 386 // BEGIN OPTIONAL CSQC FUNCTIONS
 387
 388 void Ent_RemoveEntCS()
 389 {SELFPARAM();
 390         entcs_receiver[self.sv_entnum] = world;
 391 }
 392 void Ent_ReadEntCS()
 393 {SELFPARAM();
 394     int sf;
 395         InterpolateOrigin_Undo();
 396
 397         self.classname = "entcs_receiver";
 398         sf = ReadByte();
 399
 400         if(sf & 1)
 401                 self.sv_entnum = ReadByte();
 402         if(sf & 2)
 403         {
 404                 self.origin_x = ReadShort();
 405                 self.origin_y = ReadShort();
 406                 self.origin_z = ReadShort();
 407                 setorigin(self, self.origin);
 408         }
 409         if(sf & 4)
 410         {
 411                 self.angles_y = ReadByte() * 360.0 / 256;
 412                 self.angles_x = self.angles_z = 0;
 413         }
 414         if(sf & 8)
 415                 self.healthvalue = ReadByte() * 10;
 416         if(sf & 16)
 417                 self.armorvalue = ReadByte() * 10;
 418
 419         entcs_receiver[self.sv_entnum] = self;
 420         self.entremove = Ent_RemoveEntCS;
 421         self.iflags |= IFLAG_ORIGIN;
 422
 423         InterpolateOrigin_Note();
 424 }
 425
 426 void Ent_Remove();
 427
 428 void Ent_RemovePlayerScore()
 429 {SELFPARAM();
 430         if(self.owner) {
 431                 SetTeam(self.owner, -1);
 432                 self.owner.gotscores = 0;
 433                 for(int i = 0; i < MAX_SCORE; ++i) {
 434                         self.owner.(scores[i]) = 0; // clear all scores
 435                 }
 436         }
 437 }
 438
 439 void Ent_ReadPlayerScore()
 440 {SELFPARAM();
 441         int i, n;
 442         bool isNew;
 443         entity o;
 444
 445         // damnit -.- don't want to go change every single .sv_entnum in hud.qc AGAIN
 446         // (no I've never heard of M-x replace-string, sed, or anything like that)
 447         isNew = !self.owner; // workaround for DP bug
 448         n = ReadByte()-1;
 449
 450 #ifdef DP_CSQC_ENTITY_REMOVE_IS_B0RKED
 451         if(!isNew && n != self.sv_entnum)
 452         {
 453                 //print("A CSQC entity changed its owner!\n");
 454                 LOG_INFOF("A CSQC entity changed its owner! (edict: %d, classname: %s)\n", num_for_edict(self), self.classname);
 455                 isNew = true;
 456                 Ent_Remove();
 457                 self.enttype = ENT_CLIENT_SCORES;
 458         }
 459 #endif
 460
 461         self.sv_entnum = n;
 462
 463         if (!(playerslots[self.sv_entnum]))
 464                 playerslots[self.sv_entnum] = spawn();
 465         o = self.owner = playerslots[self.sv_entnum];
 466         o.sv_entnum = self.sv_entnum;
 467         o.gotscores = 1;
 468
 469         //if (!o.sort_prev)
 470         //      RegisterPlayer(o);
 471         //playerchecker will do this for us later, if it has not already done so
 472
 473     int sf, lf;
 474 #if MAX_SCORE <= 8
 475         sf = ReadByte();
 476         lf = ReadByte();
 477 #else
 478         sf = ReadShort();
 479         lf = ReadShort();
 480 #endif
 481     int p;
 482         for(i = 0, p = 1; i < MAX_SCORE; ++i, p *= 2)
 483                 if(sf & p)
 484                 {
 485                         if(lf & p)
 486                                 o.(scores[i]) = ReadInt24_t();
 487                         else
 488                                 o.(scores[i]) = ReadChar();
 489                 }
 490
 491         if(o.sort_prev)
 492                 HUD_UpdatePlayerPos(o); // if not registered, we cannot do this yet!
 493
 494         self.entremove = Ent_RemovePlayerScore;
 495 }
 496
 497 void Ent_ReadTeamScore()
 498 {SELFPARAM();
 499         int i;
 500         entity o;
 501
 502         self.team = ReadByte();
 503         o = self.owner = GetTeam(self.team, true); // these team numbers can always be trusted
 504
 505     int sf, lf;
 506 #if MAX_TEAMSCORE <= 8
 507         sf = ReadByte();
 508         lf = ReadByte();
 509 #else
 510         sf = ReadShort();
 511         lf = ReadShort();
 512 #endif
 513         int p;
 514         for(i = 0, p = 1; i < MAX_TEAMSCORE; ++i, p *= 2)
 515                 if(sf & p)
 516                 {
 517                         if(lf & p)
 518                                 o.(teamscores[i]) = ReadInt24_t();
 519                         else
 520                                 o.(teamscores[i]) = ReadChar();
 521                 }
 522
 523         HUD_UpdateTeamPos(o);
 524 }
 525
 526 void Ent_ClientData()
 527 {
 528         float newspectatee_status;
 529
 530     int f = ReadByte();
 531
 532         scoreboard_showscores_force = (f & 1);
 533
 534         if(f & 2)
 535         {
 536                 newspectatee_status = ReadByte();
 537                 if(newspectatee_status == player_localnum + 1)
 538                         newspectatee_status = -1; // observing
 539         }
 540         else
 541                 newspectatee_status = 0;
 542
 543         spectatorbutton_zoom = (f & 4);
 544
 545         if(f & 8)
 546         {
 547                 angles_held_status = 1;
 548                 angles_held.x = ReadAngle();
 549                 angles_held.y = ReadAngle();
 550                 angles_held.z = 0;
 551         }
 552         else
 553                 angles_held_status = 0;
 554
 555         if(newspectatee_status != spectatee_status)
 556         {
 557                 // clear race stuff
 558                 race_laptime = 0;
 559                 race_checkpointtime = 0;
 560         }
 561         if (autocvar_hud_panel_healtharmor_progressbar_gfx)
 562         {
 563                 if ( (spectatee_status == -1 && newspectatee_status > 0) //before observing, now spectating
 564                   || (spectatee_status > 0 && newspectatee_status > 0 && spectatee_status != newspectatee_status) //changed spectated player
 565                 )
 566                         prev_p_health = -1;
 567                 else if(spectatee_status && !newspectatee_status) //before observing/spectating, now playing
 568                         prev_health = -1;
 569         }
 570         spectatee_status = newspectatee_status;
 571
 572         // we could get rid of spectatee_status, and derive it from player_localentnum and player_localnum
 573 }
 574
 575 void Ent_Nagger()
 576 {
 577     int i, j, b, f;
 578
 579     int nags = ReadByte(); // NAGS NAGS NAGS NAGS NAGS NAGS NADZ NAGS NAGS NAGS
 580
 581         if(!(nags & 4))
 582         {
 583                 if(vote_called_vote)
 584                         strunzone(vote_called_vote);
 585                 vote_called_vote = string_null;
 586                 vote_active = 0;
 587         }
 588         else
 589         {
 590                 vote_active = 1;
 591         }
 592
 593         if(nags & 64)
 594         {
 595                 vote_yescount = ReadByte();
 596                 vote_nocount = ReadByte();
 597                 vote_needed = ReadByte();
 598                 vote_highlighted = ReadChar();
 599         }
 600
 601         if(nags & 128)
 602         {
 603                 if(vote_called_vote)
 604                         strunzone(vote_called_vote);
 605                 vote_called_vote = strzone(ColorTranslateRGB(ReadString()));
 606         }
 607
 608         if(nags & 1)
 609         {
 610                 for(j = 0; j < maxclients; ++j)
 611                         if(playerslots[j])
 612                                 playerslots[j].ready = 1;
 613                 for(i = 1; i <= maxclients; i += 8)
 614                 {
 615                         f = ReadByte();
 616                         for(j = i-1, b = 1; b < 256; b *= 2, ++j)
 617                                 if (!(f & b))
 618                                         if(playerslots[j])
 619                                                 playerslots[j].ready = 0;
 620                 }
 621         }
 622
 623         ready_waiting = (nags & 1);
 624         ready_waiting_for_me = (nags & 2);
 625         vote_waiting = (nags & 4);
 626         vote_waiting_for_me = (nags & 8);
 627         warmup_stage = (nags & 16);
 628 }
 629
 630 void Ent_EliminatedPlayers()
 631 {
 632     int i, j, b, f;
 633
 634     int sf = ReadByte();
 635         if(sf & 1)
 636         {
 637                 for(j = 0; j < maxclients; ++j)
 638                         if(playerslots[j])
 639                                 playerslots[j].eliminated = 1;
 640                 for(i = 1; i <= maxclients; i += 8)
 641                 {
 642                         f = ReadByte();
 643                         for(j = i-1, b = 1; b < 256; b *= 2, ++j)
 644                                 if (!(f & b))
 645                                         if(playerslots[j])
 646                                                 playerslots[j].eliminated = 0;
 647                 }
 648         }
 649 }
 650
 651 void Ent_RandomSeed()
 652 {
 653         float s;
 654         prandom_debug();
 655         s = ReadShort();
 656         psrandom(s);
 657 }
 658
 659 void Ent_ReadAccuracy(void)
 660 {
 661     int f, w;
 662     int sf = ReadInt24_t();
 663         if(sf == 0)
 664         {
 665                 for(w = 0; w <= WEP_LAST - WEP_FIRST; ++w)
 666                         weapon_accuracy[w] = -1;
 667                 return;
 668         }
 669
 670         for(w = 0, f = 1; w <= WEP_LAST - WEP_FIRST; ++w)
 671         {
 672                 if(sf & f)
 673                 {
 674             int b = ReadByte();
 675                         if(b == 0)
 676                                 weapon_accuracy[w] = -1;
 677                         else if(b == 255)
 678                                 weapon_accuracy[w] = 1.0; // no better error handling yet, sorry
 679                         else
 680                                 weapon_accuracy[w] = (b - 1.0) / 100.0;
 681                 }
 682                 if(f == 0x800000)
 683                         f = 1;
 684                 else
 685                         f *= 2;
 686         }
 687 }
 688
 689 void Spawn_Draw(void)
 690 {SELFPARAM();
 691         pointparticles(self.cnt, self.origin + '0 0 28', '0 0 2', bound(0, frametime, 0.1));
 692 }
 693
 694 void Ent_ReadSpawnPoint(float is_new) // entity for spawnpoint
 695 {SELFPARAM();
 696         float teamnum = (ReadByte() - 1);
 697         vector spn_origin;
 698         spn_origin.x = ReadShort();
 699         spn_origin.y = ReadShort();
 700         spn_origin.z = ReadShort();
 701
 702         if(is_new)
 703         {
 704                 self.origin = spn_origin;
 705                 setsize(self, PL_MIN_CONST, PL_MAX_CONST);
 706                 droptofloor();
 707
 708                 /*if(autocvar_cl_spawn_point_model) // needs a model first
 709                 {
 710                         self.mdl = "models/spawnpoint.md3";
 711                         self.colormod = Team_ColorRGB(teamnum);
 712                         precache_model(self.mdl);
 713                         setmodel(self, self.mdl);
 714                         self.drawmask = MASK_NORMAL;
 715                         //self.movetype = MOVETYPE_NOCLIP;
 716                         //self.draw = Spawn_Draw;
 717                 }*/
 718                 if(autocvar_cl_spawn_point_particles)
 719                 {
 720                         if((serverflags & SERVERFLAG_TEAMPLAY))
 721                         {
 722                                 switch(teamnum)
 723                                 {
 724                                         case NUM_TEAM_1: self.cnt = particleeffectnum(EFFECT_SPAWNPOINT_RED); break;
 725                                         case NUM_TEAM_2: self.cnt = particleeffectnum(EFFECT_SPAWNPOINT_BLUE); break;
 726                                         case NUM_TEAM_3: self.cnt = particleeffectnum(EFFECT_SPAWNPOINT_YELLOW); break;
 727                                         case NUM_TEAM_4: self.cnt = particleeffectnum(EFFECT_SPAWNPOINT_PINK); break;
 728                                         default: self.cnt = particleeffectnum(EFFECT_SPAWNPOINT_NEUTRAL); break;
 729                                 }
 730                         }
 731                         else { self.cnt = particleeffectnum(EFFECT_SPAWNPOINT_NEUTRAL); }
 732
 733                         self.draw = Spawn_Draw;
 734                 }
 735         }
 736
 737         //printf("Ent_ReadSpawnPoint(is_new = %d); origin = %s, team = %d, effect = %d\n", is_new, vtos(self.origin), teamnum, self.cnt);
 738 }
 739
 740 void Ent_ReadSpawnEvent(float is_new)
 741 {SELFPARAM();
 742         // If entnum is 0, ONLY do the local spawn actions
 743         // this way the server can disable the sending of
 744         // spawn origin or such to clients if wanted.
 745         float entnum = ReadByte();
 746
 747         if(entnum)
 748         {
 749                 self.origin_x = ReadShort();
 750                 self.origin_y = ReadShort();
 751                 self.origin_z = ReadShort();
 752
 753                 if(is_new)
 754                 {
 755                         float teamnum = GetPlayerColor(entnum - 1);
 756
 757                         if(autocvar_cl_spawn_event_particles)
 758                         {
 759                                 switch(teamnum)
 760                                 {
 761                                         case NUM_TEAM_1: pointparticles(particleeffectnum(EFFECT_SPAWN_RED), self.origin, '0 0 0', 1); break;
 762                                         case NUM_TEAM_2: pointparticles(particleeffectnum(EFFECT_SPAWN_BLUE), self.origin, '0 0 0', 1); break;
 763                                         case NUM_TEAM_3: pointparticles(particleeffectnum(EFFECT_SPAWN_YELLOW), self.origin, '0 0 0', 1); break;
 764                                         case NUM_TEAM_4: pointparticles(particleeffectnum(EFFECT_SPAWN_PINK), self.origin, '0 0 0', 1); break;
 765                                         default: pointparticles(particleeffectnum(EFFECT_SPAWN_NEUTRAL), self.origin, '0 0 0', 1); break;
 766                                 }
 767                         }
 768                         if(autocvar_cl_spawn_event_sound)
 769                         {
 770                                 sound(self, CH_TRIGGER, SND_SPAWN, VOL_BASE, ATTEN_NORM);
 771                         }
 772                 }
 773         }
 774
 775         // local spawn actions
 776         if(is_new && (!entnum || (entnum == player_localentnum)))
 777         {
 778                 zoomin_effect = 1;
 779                 current_viewzoom = (1 / bound(1, autocvar_cl_spawnzoom_factor, 16));
 780
 781                 if(autocvar_cl_unpress_zoom_on_spawn)
 782                 {
 783                         localcmd("-zoom\n");
 784                         button_zoom = false;
 785                 }
 786         }
 787         HUD_Radar_Hide_Maximized();
 788         //printf("Ent_ReadSpawnEvent(is_new = %d); origin = %s, entnum = %d, localentnum = %d\n", is_new, vtos(self.origin), entnum, player_localentnum);
 789 }
 790
 791 // CSQC_Ent_Update : Called every frame that the server has indicated an update to the SSQC / CSQC entity has occured.
 792 // The only parameter reflects if the entity is "new" to the client, meaning it just came into the client's PVS.
 793 void Ent_RadarLink();
 794 void Ent_Init();
 795 void Ent_ScoresInfo();
 796 void CSQC_Ent_Update(float bIsNewEntity)
 797 {SELFPARAM();
 798         float t;
 799         float savetime;
 800         t = ReadByte();
 801
 802         if(autocvar_developer_csqcentities)
 803                 LOG_INFOF("CSQC_Ent_Update(%d) with self=%i self.entnum=%d self.enttype=%d t=%d\n", bIsNewEntity, self, self.entnum, self.enttype, t);
 804
 805         // set up the "time" global for received entities to be correct for interpolation purposes
 806         savetime = time;
 807         if(servertime)
 808         {
 809                 time = servertime;
 810         }
 811         else
 812         {
 813                 serverprevtime = time;
 814                 serverdeltatime = getstatf(STAT_MOVEVARS_TICRATE) * getstatf(STAT_MOVEVARS_TIMESCALE);
 815                 time = serverprevtime + serverdeltatime;
 816         }
 817
 818 #ifdef DP_CSQC_ENTITY_REMOVE_IS_B0RKED
 819         if(self.enttype)
 820         {
 821                 if(t != self.enttype || bIsNewEntity)
 822                 {
 823                         //print("A CSQC entity changed its type!\n");
 824                         LOG_INFOF("A CSQC entity changed its type! (edict: %d, server: %d, type: %d -> %d)\n", num_for_edict(self), self.entnum, self.enttype, t);
 825                         Ent_Remove();
 826                         clearentity(self);
 827                         bIsNewEntity = 1;
 828                 }
 829         }
 830         else
 831         {
 832                 if(!bIsNewEntity)
 833                 {
 834                         LOG_INFOF("A CSQC entity appeared out of nowhere! (edict: %d, server: %d, type: %d)\n", num_for_edict(self), self.entnum, t);
 835                         bIsNewEntity = 1;
 836                 }
 837         }
 838 #endif
 839         self.enttype = t;
 840         switch(t)
 841         {
 842                 case ENT_CLIENT_MUTATOR: {
 843                         int mutID = ReadMutator();
 844                         if (!MUTATOR_CALLHOOK(CSQC_Ent_Update, mutID, bIsNewEntity))
 845                         error(sprintf("Unknown mutator type in CSQC_Ent_Update (mutID: %d, edict: %d, classname: %s)\n", mutID, num_for_edict(self), self.classname));
 846                         break;
 847                 }
 848                 case ENT_CLIENT_ENTCS: Ent_ReadEntCS(); break;
 849                 case ENT_CLIENT_SCORES: Ent_ReadPlayerScore(); break;
 850                 case ENT_CLIENT_TEAMSCORES: Ent_ReadTeamScore(); break;
 851                 case ENT_CLIENT_POINTPARTICLES: Ent_PointParticles(); break;
 852                 case ENT_CLIENT_RAINSNOW: Ent_RainOrSnow(); break;
 853                 case ENT_CLIENT_LASER: Ent_Laser(); break;
 854                 case ENT_CLIENT_NAGGER: Ent_Nagger(); break;
 855                 case ENT_CLIENT_ELIMINATEDPLAYERS: Ent_EliminatedPlayers(); break;
 856                 case ENT_CLIENT_RADARLINK: Ent_RadarLink(); break;
 857                 case ENT_CLIENT_PROJECTILE: Ent_Projectile(); break;
 858                 case ENT_CLIENT_GIBSPLASH: Ent_GibSplash(bIsNewEntity); break;
 859                 case ENT_CLIENT_DAMAGEINFO: Ent_DamageInfo(bIsNewEntity); break;
 860                 case ENT_CLIENT_INIT: Ent_Init(); break;
 861                 case ENT_CLIENT_SCORES_INFO: Ent_ScoresInfo(); break;
 862                 case ENT_CLIENT_MAPVOTE: Ent_MapVote(); break;
 863                 case ENT_CLIENT_CLIENTDATA: Ent_ClientData(); break;
 864                 case ENT_CLIENT_RANDOMSEED: Ent_RandomSeed(); break;
 865                 case ENT_CLIENT_WALL: Ent_Wall(); break;
 866                 case ENT_CLIENT_MODELEFFECT: Ent_ModelEffect(bIsNewEntity); break;
 867                 case ENT_CLIENT_TUBANOTE: Ent_TubaNote(bIsNewEntity); break;
 868                 case ENT_CLIENT_WARPZONE: WarpZone_Read(bIsNewEntity); break;
 869                 case ENT_CLIENT_WARPZONE_CAMERA: WarpZone_Camera_Read(bIsNewEntity); break;
 870                 case ENT_CLIENT_WARPZONE_TELEPORTED: WarpZone_Teleported_Read(bIsNewEntity); break;
 871                 case ENT_CLIENT_TRIGGER_MUSIC: Ent_ReadTriggerMusic(); break;
 872                 case ENT_CLIENT_HOOK: Ent_ReadHook(bIsNewEntity, ENT_CLIENT_HOOK); break;
 873                 case ENT_CLIENT_INVENTORY: Inventory_Read(self); break;
 874                 case ENT_CLIENT_ARC_BEAM: Ent_ReadArcBeam(bIsNewEntity); break;
 875                 case ENT_CLIENT_ACCURACY: Ent_ReadAccuracy(); break;
 876                 case ENT_CLIENT_AUXILIARYXHAIR: Net_AuXair2(bIsNewEntity); break;
 877                 case ENT_CLIENT_TURRET: ent_turret(); break;
 878                 case ENT_CLIENT_GENERATOR: ent_generator(); break;
 879                 case ENT_CLIENT_CONTROLPOINT_ICON: ent_cpicon(); break;
 880                 case ENT_CLIENT_MODEL: CSQCModel_Read(bIsNewEntity); break;
 881                 case ENT_CLIENT_ITEM: ItemRead(bIsNewEntity); break;
 882                 case ENT_CLIENT_BUMBLE_RAYGUN: bumble_raygun_read(bIsNewEntity); break;
 883                 case ENT_CLIENT_SPAWNPOINT: Ent_ReadSpawnPoint(bIsNewEntity); break;
 884                 case ENT_CLIENT_SPAWNEVENT: Ent_ReadSpawnEvent(bIsNewEntity); break;
 885                 case ENT_CLIENT_NOTIFICATION: Read_Notification(bIsNewEntity); break;
 886                 case ENT_CLIENT_HEALING_ORB: ent_healer(); break;
 887                 case ENT_CLIENT_MINIGAME: ent_read_minigame(); break;
 888                 case ENT_CLIENT_VIEWLOC: ent_viewloc(); break;
 889                 case ENT_CLIENT_VIEWLOC_TRIGGER: ent_viewloc_trigger(); break;
 890                 case ENT_CLIENT_LADDER: ent_func_ladder(); break;
 891                 case ENT_CLIENT_TRIGGER_PUSH: ent_trigger_push(); break;
 892                 case ENT_CLIENT_TARGET_PUSH: ent_target_push(); break;
 893                 case ENT_CLIENT_CONVEYOR: ent_conveyor(); break;
 894                 case ENT_CLIENT_DOOR: ent_door(); break;
 895                 case ENT_CLIENT_PLAT: ent_plat(); break;
 896                 case ENT_CLIENT_SWAMP: ent_swamp(); break;
 897                 case ENT_CLIENT_CORNER: ent_corner(); break;
 898                 case ENT_CLIENT_KEYLOCK: ent_keylock(); break;
 899                 case ENT_CLIENT_TRAIN: ent_train(); break;
 900                 case ENT_CLIENT_TRIGGER_IMPULSE: ent_trigger_impulse(); break;
 901                 case ENT_CLIENT_EFFECT: Read_Effect(bIsNewEntity); break;
 902
 903                 default:
 904                         //error(strcat(_("unknown entity type in CSQC_Ent_Update: %d\n"), self.enttype));
 905                         error(sprintf("Unknown entity type in CSQC_Ent_Update (enttype: %d, edict: %d, classname: %s)\n", self.enttype, num_for_edict(self), self.classname));
 906                         break;
 907         }
 908
 909         time = savetime;
 910 }
 911 // Destructor, but does NOT deallocate the entity by calling remove(). Also
 912 // used when an entity changes its type. For an entity that someone interacts
 913 // with others, make sure it can no longer do so.
 914 void Ent_Remove()
 915 {SELFPARAM();
 916         if(self.entremove)
 917                 self.entremove();
 918
 919         if(self.skeletonindex)
 920         {
 921                 skel_delete(self.skeletonindex);
 922                 self.skeletonindex = 0;
 923         }
 924
 925         if(self.snd_looping > 0)
 926         {
 927                 sound(self, self.snd_looping, SND_Null, VOL_BASE, autocvar_g_jetpack_attenuation);
 928                 self.snd_looping = 0;
 929         }
 930
 931         self.enttype = 0;
 932         self.classname = "";
 933         self.draw = menu_sub_null;
 934         self.entremove = menu_sub_null;
 935         // TODO possibly set more stuff to defaults
 936 }
 937 // CSQC_Ent_Remove : Called when the server requests a SSQC / CSQC entity to be removed.  Essentially call remove(self) as well.
 938 void CSQC_Ent_Remove()
 939 {SELFPARAM();
 940         if(autocvar_developer_csqcentities)
 941                 LOG_INFOF("CSQC_Ent_Remove() with self=%i self.entnum=%d self.enttype=%d\n", self, self.entnum, self.enttype);
 942
 943         if(wasfreed(self))
 944         {
 945                 LOG_INFO("WARNING: CSQC_Ent_Remove called for already removed entity. Packet loss?\n");
 946                 return;
 947         }
 948         if(self.enttype)
 949                 Ent_Remove();
 950         remove(self);
 951 }
 952
 953 void Gamemode_Init()
 954 {
 955         if (!isdemo())
 956         {
 957                 if(!(calledhooks & HOOK_START))
 958                         localcmd("\n_cl_hook_gamestart ", MapInfo_Type_ToString(gametype), "\n");
 959                 calledhooks |= HOOK_START;
 960         }
 961 }
 962 // CSQC_Parse_StuffCmd : Provides the stuffcmd string in the first parameter that the server provided.  To execute standard behavior, simply execute localcmd with the string.
 963 void CSQC_Parse_StuffCmd(string strMessage)
 964 {
 965         if(autocvar_developer_csqcentities)
 966                 LOG_INFOF("CSQC_Parse_StuffCmd(\"%s\")\n", strMessage);
 967
 968         localcmd(strMessage);
 969 }
 970 // CSQC_Parse_Print : Provides the print string in the first parameter that the server provided.  To execute standard behavior, simply execute print with the string.
 971 void CSQC_Parse_Print(string strMessage)
 972 {
 973         if(autocvar_developer_csqcentities)
 974                 LOG_INFOF("CSQC_Parse_Print(\"%s\")\n", strMessage);
 975
 976         print(ColorTranslateRGB(strMessage));
 977 }
 978
 979 // CSQC_Parse_CenterPrint : Provides the centerprint_hud string in the first parameter that the server provided.
 980 void CSQC_Parse_CenterPrint(string strMessage)
 981 {
 982         if(autocvar_developer_csqcentities)
 983                 LOG_INFOF("CSQC_Parse_CenterPrint(\"%s\")\n", strMessage);
 984
 985         centerprint_hud(strMessage);
 986 }
 987
 988 string notranslate_fogcmd1 = "\nfog ";
 989 string notranslate_fogcmd2 = "\nr_fog_exp2 0\nr_drawfog 1\n";
 990 void Fog_Force()
 991 {
 992         // TODO somehow thwart prvm_globalset client ...
 993
 994         if(autocvar_cl_orthoview && autocvar_cl_orthoview_nofog)
 995                 { localcmd("\nr_drawfog 0\n"); }
 996         else if(forcefog != "")
 997                 { localcmd(strcat(notranslate_fogcmd1, forcefog, notranslate_fogcmd2)); }
 998 }
 999
1000 void Gamemode_Init();
1001 void Ent_ScoresInfo()
1002 {SELFPARAM();
1003     int i;
1004         self.classname = "ent_client_scores_info";
1005         gametype = ReadInt24_t();
1006         HUD_ModIcons_SetFunc();
1007         for(i = 0; i < MAX_SCORE; ++i)
1008         {
1009                 if(scores_label[i])
1010                         strunzone(scores_label[i]);
1011                 scores_label[i] = strzone(ReadString());
1012                 scores_flags[i] = ReadByte();
1013         }
1014         for(i = 0; i < MAX_TEAMSCORE; ++i)
1015         {
1016                 if(teamscores_label[i])
1017                         strunzone(teamscores_label[i]);
1018                 teamscores_label[i] = strzone(ReadString());
1019                 teamscores_flags[i] = ReadByte();
1020         }
1021         HUD_InitScores();
1022         Gamemode_Init();
1023 }
1024
1025 void Ent_Init()
1026 {SELFPARAM();
1027         self.classname = "ent_client_init";
1028
1029         nb_pb_period = ReadByte() / 32; //Accuracy of 1/32th
1030
1031         hook_shotorigin[0] = decompressShotOrigin(ReadInt24_t());
1032         hook_shotorigin[1] = decompressShotOrigin(ReadInt24_t());
1033         hook_shotorigin[2] = decompressShotOrigin(ReadInt24_t());
1034         hook_shotorigin[3] = decompressShotOrigin(ReadInt24_t());
1035         arc_shotorigin[0] = decompressShotOrigin(ReadInt24_t());
1036         arc_shotorigin[1] = decompressShotOrigin(ReadInt24_t());
1037         arc_shotorigin[2] = decompressShotOrigin(ReadInt24_t());
1038         arc_shotorigin[3] = decompressShotOrigin(ReadInt24_t());
1039
1040         if(forcefog)
1041                 strunzone(forcefog);
1042         forcefog = strzone(ReadString());
1043
1044         armorblockpercent = ReadByte() / 255.0;
1045
1046         g_balance_mortar_bouncefactor = ReadCoord();
1047         g_balance_mortar_bouncestop = ReadCoord();
1048         g_balance_electro_secondary_bouncefactor = ReadCoord();
1049         g_balance_electro_secondary_bouncestop = ReadCoord();
1050
1051         vortex_scope = !ReadByte();
1052         rifle_scope = !ReadByte();
1053
1054         serverflags = ReadByte();
1055
1056         minelayer_maxmines = ReadByte();
1057
1058         hagar_maxrockets = ReadByte();
1059
1060         g_trueaim_minrange = ReadCoord();
1061         g_balance_porto_secondary = ReadByte();
1062
1063         if(!postinit)
1064                 PostInit();
1065 }
1066
1067 void Net_ReadRace()
1068 {
1069         float b;
1070
1071         b = ReadByte();
1072
1073         switch(b)
1074         {
1075                 case RACE_NET_CHECKPOINT_HIT_QUALIFYING:
1076                         race_checkpoint = ReadByte();
1077                         race_time = ReadInt24_t();
1078                         race_previousbesttime = ReadInt24_t();
1079                         if(race_previousbestname)
1080                                 strunzone(race_previousbestname);
1081                         race_previousbestname = strzone(ColorTranslateRGB(ReadString()));
1082
1083                         race_checkpointtime = time;
1084
1085                         if(race_checkpoint == 0 || race_checkpoint == 254)
1086                         {
1087                                 race_penaltyaccumulator = 0;
1088                                 race_laptime = time; // valid
1089                         }
1090
1091                         break;
1092
1093                 case RACE_NET_CHECKPOINT_CLEAR:
1094                         race_laptime = 0;
1095                         race_checkpointtime = 0;
1096                         break;
1097
1098                 case RACE_NET_CHECKPOINT_NEXT_SPEC_QUALIFYING:
1099                         race_laptime = ReadCoord();
1100                         race_checkpointtime = -99999;
1101                         // fall through
1102                 case RACE_NET_CHECKPOINT_NEXT_QUALIFYING:
1103                         race_nextcheckpoint = ReadByte();
1104
1105                         race_nextbesttime = ReadInt24_t();
1106                         if(race_nextbestname)
1107                                 strunzone(race_nextbestname);
1108                         race_nextbestname = strzone(ColorTranslateRGB(ReadString()));
1109                         break;
1110
1111                 case RACE_NET_CHECKPOINT_HIT_RACE:
1112                         race_mycheckpoint = ReadByte();
1113                         race_mycheckpointtime = time;
1114                         race_mycheckpointdelta = ReadInt24_t();
1115                         race_mycheckpointlapsdelta = ReadByte();
1116                         if(race_mycheckpointlapsdelta >= 128)
1117                                 race_mycheckpointlapsdelta -= 256;
1118                         if(race_mycheckpointenemy)
1119                                 strunzone(race_mycheckpointenemy);
1120                         race_mycheckpointenemy = strzone(ColorTranslateRGB(ReadString()));
1121                         break;
1122
1123                 case RACE_NET_CHECKPOINT_HIT_RACE_BY_OPPONENT:
1124                         race_othercheckpoint = ReadByte();
1125                         race_othercheckpointtime = time;
1126                         race_othercheckpointdelta = ReadInt24_t();
1127                         race_othercheckpointlapsdelta = ReadByte();
1128                         if(race_othercheckpointlapsdelta >= 128)
1129                                 race_othercheckpointlapsdelta -= 256;
1130                         if(race_othercheckpointenemy)
1131                                 strunzone(race_othercheckpointenemy);
1132                         race_othercheckpointenemy = strzone(ColorTranslateRGB(ReadString()));
1133                         break;
1134
1135                 case RACE_NET_PENALTY_RACE:
1136                         race_penaltyeventtime = time;
1137                         race_penaltytime = ReadShort();
1138                         //race_penaltyaccumulator += race_penaltytime;
1139                         if(race_penaltyreason)
1140                                 strunzone(race_penaltyreason);
1141                         race_penaltyreason = strzone(ReadString());
1142                         break;
1143
1144                 case RACE_NET_PENALTY_QUALIFYING:
1145                         race_penaltyeventtime = time;
1146                         race_penaltytime = ReadShort();
1147                         race_penaltyaccumulator += race_penaltytime;
1148                         if(race_penaltyreason)
1149                                 strunzone(race_penaltyreason);
1150                         race_penaltyreason = strzone(ReadString());
1151                         break;
1152
1153                 case RACE_NET_SERVER_RECORD:
1154                         race_server_record = ReadInt24_t();
1155                         break;
1156                 case RACE_NET_SPEED_AWARD:
1157                         race_speedaward = ReadInt24_t();
1158                         if(race_speedaward_holder)
1159                                 strunzone(race_speedaward_holder);
1160                         race_speedaward_holder = strzone(ReadString());
1161                         break;
1162                 case RACE_NET_SPEED_AWARD_BEST:
1163                         race_speedaward_alltimebest = ReadInt24_t();
1164                         if(race_speedaward_alltimebest_holder)
1165                                 strunzone(race_speedaward_alltimebest_holder);
1166                         race_speedaward_alltimebest_holder = strzone(ReadString());
1167                         break;
1168                 case RACE_NET_SERVER_RANKINGS:
1169                         float prevpos, del;
1170             int pos = ReadShort();
1171                         prevpos = ReadShort();
1172                         del = ReadShort();
1173
1174                         // move other rankings out of the way
1175             int i;
1176                         if (prevpos) {
1177                                 for (i=prevpos-1;i>pos-1;--i) {
1178                                         grecordtime[i] = grecordtime[i-1];
1179                                         if(grecordholder[i])
1180                                                 strunzone(grecordholder[i]);
1181                                         grecordholder[i] = strzone(grecordholder[i-1]);
1182                                 }
1183                         } else if (del) { // a record has been deleted by the admin
1184                                 for (i=pos-1; i<= RANKINGS_CNT-1; ++i) {
1185                                         if (i == RANKINGS_CNT-1) { // clear out last record
1186                                                 grecordtime[i] = 0;
1187                                                 if (grecordholder[i])
1188                                                         strunzone(grecordholder[i]);
1189                                                 grecordholder[i] = string_null;
1190                                         }
1191                                         else {
1192                                                 grecordtime[i] = grecordtime[i+1];
1193                                                 if (grecordholder[i])
1194                                                         strunzone(grecordholder[i]);
1195                                                 grecordholder[i] = strzone(grecordholder[i+1]);
1196                                         }
1197                                 }
1198                         } else { // player has no ranked record yet
1199                                 for (i=RANKINGS_CNT-1;i>pos-1;--i) {
1200                                         grecordtime[i] = grecordtime[i-1];
1201                                         if(grecordholder[i])
1202                                                 strunzone(grecordholder[i]);
1203                                         grecordholder[i] = strzone(grecordholder[i-1]);
1204                                 }
1205                         }
1206
1207                         // store new ranking
1208                         if(grecordholder[pos-1] != "")
1209                                 strunzone(grecordholder[pos-1]);
1210                         grecordholder[pos-1] = strzone(ReadString());
1211                         grecordtime[pos-1] = ReadInt24_t();
1212                         if(grecordholder[pos-1] == GetPlayerName(player_localnum))
1213                                 race_myrank = pos;
1214                         break;
1215                 case RACE_NET_SERVER_STATUS:
1216                         race_status = ReadShort();
1217                         if(race_status_name)
1218                                 strunzone(race_status_name);
1219                         race_status_name = strzone(ReadString());
1220         }
1221 }
1222
1223 void Net_TeamNagger()
1224 {
1225         teamnagger = 1;
1226 }
1227
1228 void Net_ReadPingPLReport()
1229 {
1230         int e, pi, pl, ml;
1231         e = ReadByte();
1232         pi = ReadShort();
1233         pl = ReadByte();
1234         ml = ReadByte();
1235         if (!(playerslots[e]))
1236                 return;
1237         playerslots[e].ping = pi;
1238         playerslots[e].ping_packetloss = pl / 255.0;
1239         playerslots[e].ping_movementloss = ml / 255.0;
1240 }
1241
1242 void Net_WeaponComplain()
1243 {
1244         complain_weapon = ReadByte();
1245
1246         if(complain_weapon_name)
1247                 strunzone(complain_weapon_name);
1248         complain_weapon_name = strzone(WEP_NAME(complain_weapon));
1249
1250         complain_weapon_type = ReadByte();
1251
1252         complain_weapon_time = time;
1253         weapontime = time; // ping the weapon panel
1254
1255         switch(complain_weapon_type)
1256         {
1257                 case 0: Local_Notification(MSG_MULTI, ITEM_WEAPON_NOAMMO, complain_weapon); break;
1258                 case 1: Local_Notification(MSG_MULTI, ITEM_WEAPON_DONTHAVE, complain_weapon); break;
1259                 default: Local_Notification(MSG_MULTI, ITEM_WEAPON_UNAVAILABLE, complain_weapon); break;
1260         }
1261 }
1262
1263 // CSQC_Parse_TempEntity : Handles all temporary entity network data in the CSQC layer.
1264 // You must ALWAYS first acquire the temporary ID, which is sent as a byte.
1265 // Return value should be 1 if CSQC handled the temporary entity, otherwise return 0 to have the engine process the event.
1266 float CSQC_Parse_TempEntity()
1267 {
1268         // Acquire TE ID
1269         int nTEID = ReadByte();
1270
1271         if (autocvar_developer_csqcentities)
1272                 LOG_INFOF("CSQC_Parse_TempEntity() with nTEID=%d\n", nTEID);
1273
1274         switch (nTEID)
1275         {
1276                 case TE_CSQC_MUTATOR:
1277                         int mutID = ReadMutator();
1278                         if (MUTATOR_CALLHOOK(CSQC_Parse_TempEntity, mutID))
1279                         return true;
1280                 case TE_CSQC_TARGET_MUSIC:
1281                         Net_TargetMusic();
1282                         return true;
1283                 case TE_CSQC_PICTURE:
1284                         Net_MapVote_Picture();
1285                         return true;
1286                 case TE_CSQC_RACE:
1287                         Net_ReadRace();
1288                         return true;
1289                 case TE_CSQC_VORTEXBEAMPARTICLE:
1290                         Net_ReadVortexBeamParticle();
1291                         return true;
1292                 case TE_CSQC_TEAMNAGGER:
1293                         Net_TeamNagger();
1294                         return true;
1295                 case TE_CSQC_ARC:
1296                         Net_ReadArc();
1297                         return true;
1298                 case TE_CSQC_PINGPLREPORT:
1299                         Net_ReadPingPLReport();
1300                         return true;
1301                 case TE_CSQC_WEAPONCOMPLAIN:
1302                         Net_WeaponComplain();
1303                         return true;
1304                 case TE_CSQC_VEHICLESETUP:
1305                         Net_VehicleSetup();
1306                         return true;
1307                 case TE_CSQC_SVNOTICE:
1308                         cl_notice_read();
1309                         return true;
1310                 case TE_CSQC_SHOCKWAVEPARTICLE:
1311                         Net_ReadShockwaveParticle();
1312                         return true;
1313                 default:
1314                         // No special logic for this temporary entity; return 0 so the engine can handle it
1315                         return false;
1316         }
1317 }
1318
1319 string getcommandkey(string text, string command)
1320 {
1321         string keys;
1322         float n, j, k, l = 0;
1323
1324         if (!autocvar_hud_showbinds)
1325                 return text;
1326
1327         keys = db_get(binddb, command);
1328         if (keys == "")
1329         {
1330                 n = tokenize(findkeysforcommand(command, 0)); // uses '...' strings
1331                 for(j = 0; j < n; ++j)
1332                 {
1333                         k = stof(argv(j));
1334                         if(k != -1)
1335                         {
1336                                 if ("" == keys)
1337                                         keys = keynumtostring(k);
1338                                 else
1339                                         keys = strcat(keys, ", ", keynumtostring(k));
1340
1341                                 ++l;
1342                                 if (autocvar_hud_showbinds_limit > 0 && autocvar_hud_showbinds_limit <= l)
1343                                         break;
1344                         }
1345
1346                 }
1347                 if (keys == "")
1348                         keys = "NO_KEY";
1349                 db_put(binddb, command, keys);
1350         }
1351
1352         if (keys == "NO_KEY") {
1353                 if (autocvar_hud_showbinds > 1)
1354                         return sprintf(_("%s (not bound)"), text);
1355                 else
1356                         return text;
1357         }
1358         else if (autocvar_hud_showbinds > 1)
1359                 return sprintf("%s (%s)", text, keys);
1360         else
1361                 return keys;
1362 }