qcsrc/client/main.qc

   1 #include "main.qh"
   2 #include "_all.qh"
   3
   4 #include "casings.qh"
   5 #include "controlpoint.qh"
   6 #include "csqcmodel_hooks.qh"
   7 #include "damage.qh"
   8 #include "effects.qh"
   9 #include "generator.qh"
  10 #include "gibs.qh"
  11 #include "hook.qh"
  12 #include "hud.qh"
  13 #include "hud_config.qh"
  14 #include "laser.qh"
  15 #include "mapvoting.qh"
  16 #include "modeleffects.qh"
  17 #include "particles.qh"
  18 #include "prandom.qh"
  19 #include "scoreboard.qh"
  20 #include "shownames.qh"
  21 #include "sortlist.qh"
  22 #include "tuba.qh"
  23 #include "t_items.qh"
  24 #include "wall.qh"
  25 #include "waypointsprites.qh"
  26
  27 #include "../common/vehicles/all.qh"
  28
  29 #include "mutators/events.qh"
  30
  31 #include "weapons/projectile.qh"
  32
  33 #include "../common/buffs.qh"
  34 #include "../common/deathtypes.qh"
  35 #include "../common/effects.qh"
  36 #include "../common/mapinfo.qh"
  37 #include "../common/monsters/all.qh"
  38 #include "../common/nades.qh"
  39 #include "../common/net_notice.qh"
  40 #include "../common/notifications.qh"
  41 #include "../common/stats.qh"
  42 #include "../common/teams.qh"
  43
  44 #include "../common/items/all.qh"
  45
  46 #include "../common/mutators/base.qh"
  47
  48 #include "../common/weapons/all.qh"
  49
  50 #include "../csqcmodellib/cl_model.qh"
  51 #include "../csqcmodellib/interpolate.qh"
  52
  53 #include "../common/triggers/include.qh"
  54
  55 #include "../common/turrets/cl_turrets.qh"
  56 #include "../common/turrets/turrets.qh"
  57
  58 #include "../warpzonelib/client.qh"
  59
  60 // --------------------------------------------------------------------------
  61 // BEGIN REQUIRED CSQC FUNCTIONS
  62 //include "main.qh"
  63
  64 entity clearentity_ent;
  65 void clearentity(entity e)
  66 {
  67         if (!clearentity_ent)
  68         {
  69                 clearentity_ent = spawn();
  70                 clearentity_ent.classname = "clearentity";
  71         }
  72         int n = e.entnum;
  73         copyentity(clearentity_ent, e);
  74         e.entnum = n;
  75 }
  76
  77 #define DP_CSQC_ENTITY_REMOVE_IS_B0RKED
  78 void menu_show_error()
  79 {
  80         drawstring('0 200 0', _("ERROR - MENU IS VISIBLE BUT NO MENU WAS DEFINED!"), '8 8 0', '1 0 0', 1, 0);
  81 }
  82
  83 // CSQC_Init : Called every time the CSQC code is initialized (essentially at map load)
  84 // Useful for precaching things
  85
  86 void menu_sub_null()
  87 {
  88 }
  89
  90 string forcefog;
  91 void WaypointSprite_Load();
  92 void ConsoleCommand_macro_init();
  93 void CSQC_Init(void)
  94 {
  95         prvm_language = cvar_string("prvm_language");
  96
  97 #ifdef WATERMARK
  98         dprintf("^4CSQC Build information: ^1%s\n", WATERMARK);
  99 #endif
 100
 101         int i;
 102
 103         binddb = db_create();
 104         tempdb = db_create();
 105         ClientProgsDB = db_load("client.db");
 106         compressShortVector_init();
 107
 108         draw_endBoldFont();
 109         menu_visible = false;
 110         menu_show = menu_show_error;
 111         menu_action = func_null;
 112
 113         for(i = 0; i < 255; ++i)
 114                 if(getplayerkeyvalue(i, "viewentity") == "")
 115                         break;
 116         maxclients = i;
 117
 118         //registercommand("hud_configure");
 119         //registercommand("hud_save");
 120         //registercommand("menu_action");
 121
 122         ConsoleCommand_macro_init();
 123
 124         registercvar("hud_usecsqc", "1");
 125         registercvar("scoreboard_columns", "default");
 126
 127         registercvar("cl_nade_type", "3");
 128         registercvar("cl_pokenade_type", "zombie");
 129
 130         registercvar("cl_jumpspeedcap_min", "");
 131         registercvar("cl_jumpspeedcap_max", "");
 132
 133         gametype = 0;
 134
 135         // hud_fields uses strunzone on the titles!
 136         for(i = 0; i < MAX_HUD_FIELDS; ++i)
 137                 hud_title[i] = strzone("(null)");
 138
 139         Cmd_HUD_SetFields(0);
 140
 141         postinit = false;
 142
 143         calledhooks = 0;
 144
 145         teams = Sort_Spawn();
 146         players = Sort_Spawn();
 147
 148         GetTeam(NUM_SPECTATOR, true); // add specs first
 149
 150         // needs to be done so early because of the constants they create
 151         static_init();
 152         CALL_ACCUMULATED_FUNCTION(RegisterTurrets);
 153         CALL_ACCUMULATED_FUNCTION(RegisterNotifications);
 154         CALL_ACCUMULATED_FUNCTION(RegisterDeathtypes);
 155         CALL_ACCUMULATED_FUNCTION(RegisterHUD_Panels);
 156         CALL_ACCUMULATED_FUNCTION(RegisterEffects);
 157
 158         initialize_minigames();
 159
 160         WaypointSprite_Load();
 161
 162         // precaches
 163         precache_model("null");
 164         precache_sound("misc/hit.wav");
 165         precache_sound("misc/typehit.wav");
 166
 167         generator_precache();
 168         Projectile_Precache();
 169         Hook_Precache();
 170         GibSplash_Precache();
 171         Casings_Precache();
 172         Tuba_Precache();
 173         CSQCPlayer_Precache();
 174
 175         if(autocvar_cl_reticle)
 176         {
 177                 precache_pic("gfx/reticle_normal");
 178                 // weapon reticles are precached in weapon files
 179         }
 180
 181         get_mi_min_max_texcoords(1); // try the CLEVER way first
 182         minimapname = strcat("gfx/", mi_shortname, "_radar.tga");
 183         shortmapname = mi_shortname;
 184
 185         if(precache_pic(minimapname) == "")
 186         {
 187                 // but maybe we have a non-clever minimap
 188                 minimapname = strcat("gfx/", mi_shortname, "_mini.tga");
 189                 if(precache_pic(minimapname) == "")
 190                         minimapname = ""; // FAIL
 191                 else
 192                         get_mi_min_max_texcoords(0); // load new texcoords
 193         }
 194
 195         mi_center = (mi_min + mi_max) * 0.5;
 196         mi_scale = mi_max - mi_min;
 197         minimapname = strzone(minimapname);
 198
 199         WarpZone_Init();
 200
 201         hud_skin_path = strzone(strcat("gfx/hud/", autocvar_hud_skin));
 202         draw_currentSkin = strzone(strcat("gfx/menu/", cvar_string("menu_skin")));
 203 }
 204
 205 // CSQC_Shutdown : Called every time the CSQC code is shutdown (changing maps, quitting, etc)
 206 void Shutdown(void)
 207 {
 208         WarpZone_Shutdown();
 209
 210         remove(teams);
 211         remove(players);
 212         db_close(binddb);
 213         db_close(tempdb);
 214         if(autocvar_cl_db_saveasdump)
 215                 db_dump(ClientProgsDB, "client.db");
 216         else
 217                 db_save(ClientProgsDB, "client.db");
 218         db_close(ClientProgsDB);
 219
 220         if(camera_active)
 221                 cvar_set("chase_active",ftos(chase_active_backup));
 222
 223         // unset the event chasecam's chase_active
 224         if(autocvar_chase_active < 0)
 225                 cvar_set("chase_active", "0");
 226
 227         if (!isdemo())
 228         {
 229                 if (!(calledhooks & HOOK_START))
 230                         localcmd("\n_cl_hook_gamestart nop\n");
 231                 if (!(calledhooks & HOOK_END))
 232                         localcmd("\ncl_hook_gameend\n");
 233         }
 234
 235         deactivate_minigame();
 236         HUD_MinigameMenu_Close();
 237 }
 238
 239 .float has_team;
 240 float SetTeam(entity o, int Team)
 241 {
 242         entity tm;
 243         if(teamplay)
 244         {
 245                 switch(Team)
 246                 {
 247                         case -1:
 248                         case NUM_TEAM_1:
 249                         case NUM_TEAM_2:
 250                         case NUM_TEAM_3:
 251                         case NUM_TEAM_4:
 252                                 break;
 253                         default:
 254                                 if(GetTeam(Team, false) == world)
 255                                 {
 256                                         dprintf("trying to switch to unsupported team %d\n", Team);
 257                                         Team = NUM_SPECTATOR;
 258                                 }
 259                                 break;
 260                 }
 261         }
 262         else
 263         {
 264                 switch(Team)
 265                 {
 266                         case -1:
 267                         case 0:
 268                                 break;
 269                         default:
 270                                 if(GetTeam(Team, false) == world)
 271                                 {
 272                                         dprintf("trying to switch to unsupported team %d\n", Team);
 273                                         Team = NUM_SPECTATOR;
 274                                 }
 275                                 break;
 276                 }
 277         }
 278         if(Team == -1) // leave
 279         {
 280                 if(o.has_team)
 281                 {
 282                         tm = GetTeam(o.team, false);
 283                         tm.team_size -= 1;
 284                         o.has_team = 0;
 285                         return true;
 286                 }
 287         }
 288         else
 289         {
 290                 if (!o.has_team)
 291                 {
 292                         o.team = Team;
 293                         tm = GetTeam(Team, true);
 294                         tm.team_size += 1;
 295                         o.has_team = 1;
 296                         return true;
 297                 }
 298                 else if(Team != o.team)
 299                 {
 300                         tm = GetTeam(o.team, false);
 301                         tm.team_size -= 1;
 302                         o.team = Team;
 303                         tm = GetTeam(Team, true);
 304                         tm.team_size += 1;
 305                         return true;
 306                 }
 307         }
 308         return false;
 309 }
 310
 311 void Playerchecker_Think()
 312 {
 313     int i;
 314         entity e;
 315         for(i = 0; i < maxclients; ++i)
 316         {
 317                 e = playerslots[i];
 318                 if(GetPlayerName(i) == "")
 319                 {
 320                         if(e.sort_prev)
 321                         {
 322                                 // player disconnected
 323                                 SetTeam(e, -1);
 324                                 RemovePlayer(e);
 325                                 e.sort_prev = world;
 326                                 //e.gotscores = 0;
 327                         }
 328                 }
 329                 else
 330                 {
 331                         if (!e.sort_prev)
 332                         {
 333                                 // player connected
 334                                 if (!e)
 335                                         playerslots[i] = e = spawn();
 336                                 e.sv_entnum = i;
 337                                 e.ping = 0;
 338                                 e.ping_packetloss = 0;
 339                                 e.ping_movementloss = 0;
 340                                 //e.gotscores = 0; // we might already have the scores...
 341                                 SetTeam(e, GetPlayerColor(i)); // will not hurt; later updates come with HUD_UpdatePlayerTeams
 342                                 RegisterPlayer(e);
 343                                 HUD_UpdatePlayerPos(e);
 344                         }
 345                 }
 346         }
 347         self.nextthink = time + 0.2;
 348 }
 349
 350 void Porto_Init();
 351 void TrueAim_Init();
 352 void PostInit(void)
 353 {
 354         entity playerchecker;
 355         playerchecker = spawn();
 356         playerchecker.think = Playerchecker_Think;
 357         playerchecker.nextthink = time + 0.2;
 358
 359         Porto_Init();
 360         TrueAim_Init();
 361
 362         postinit = true;
 363 }
 364
 365 // CSQC_InputEvent : Used to perform actions based on any key pressed, key released and mouse on the client.
 366 // Return value should be 1 if CSQC handled the input, otherwise return 0 to have the input passed to the engine.
 367 // All keys are in ascii.
 368 // bInputType = 0 is key pressed, 1 is key released, 2 and 3 are mouse input.
 369 // In the case of keyboard input, nPrimary is the ascii code, and nSecondary is 0.
 370 // In the case of mouse input, nPrimary is xdelta, nSecondary is ydelta.
 371 // In the case of mouse input after a setcursormode(1) call, nPrimary is xpos, nSecondary is ypos.
 372 float CSQC_InputEvent(float bInputType, float nPrimary, float nSecondary)
 373 {
 374         float bSkipKey;
 375         bSkipKey = false;
 376
 377         if (HUD_Panel_InputEvent(bInputType, nPrimary, nSecondary))
 378                 return true;
 379
 380         if ( HUD_Radar_InputEvent(bInputType, nPrimary, nSecondary) )
 381                 return true;
 382
 383         if (MapVote_InputEvent(bInputType, nPrimary, nSecondary))
 384                 return true;
 385
 386         if (HUD_Minigame_InputEvent(bInputType, nPrimary, nSecondary))
 387                 return true;
 388
 389         if(menu_visible && menu_action)
 390                 if(menu_action(bInputType, nPrimary, nSecondary))
 391                         return true;
 392
 393         return bSkipKey;
 394 }
 395
 396 // END REQUIRED CSQC FUNCTIONS
 397 // --------------------------------------------------------------------------
 398
 399 // --------------------------------------------------------------------------
 400 // BEGIN OPTIONAL CSQC FUNCTIONS
 401
 402 void Ent_RemoveEntCS()
 403 {
 404         entcs_receiver[self.sv_entnum] = world;
 405 }
 406 void Ent_ReadEntCS()
 407 {
 408     int sf;
 409         InterpolateOrigin_Undo();
 410
 411         self.classname = "entcs_receiver";
 412         sf = ReadByte();
 413
 414         if(sf & 1)
 415                 self.sv_entnum = ReadByte();
 416         if(sf & 2)
 417         {
 418                 self.origin_x = ReadShort();
 419                 self.origin_y = ReadShort();
 420                 self.origin_z = ReadShort();
 421                 setorigin(self, self.origin);
 422         }
 423         if(sf & 4)
 424         {
 425                 self.angles_y = ReadByte() * 360.0 / 256;
 426                 self.angles_x = self.angles_z = 0;
 427         }
 428         if(sf & 8)
 429                 self.healthvalue = ReadByte() * 10;
 430         if(sf & 16)
 431                 self.armorvalue = ReadByte() * 10;
 432
 433         entcs_receiver[self.sv_entnum] = self;
 434         self.entremove = Ent_RemoveEntCS;
 435         self.iflags |= IFLAG_ORIGIN;
 436
 437         InterpolateOrigin_Note();
 438 }
 439
 440 void Ent_Remove();
 441
 442 void Ent_RemovePlayerScore()
 443 {
 444         if(self.owner) {
 445                 SetTeam(self.owner, -1);
 446                 self.owner.gotscores = 0;
 447                 for(int i = 0; i < MAX_SCORE; ++i) {
 448                         self.owner.(scores[i]) = 0; // clear all scores
 449                 }
 450         }
 451 }
 452
 453 void Ent_ReadPlayerScore()
 454 {
 455         int i, n;
 456         bool isNew;
 457         entity o;
 458
 459         // damnit -.- don't want to go change every single .sv_entnum in hud.qc AGAIN
 460         // (no I've never heard of M-x replace-string, sed, or anything like that)
 461         isNew = !self.owner; // workaround for DP bug
 462         n = ReadByte()-1;
 463
 464 #ifdef DP_CSQC_ENTITY_REMOVE_IS_B0RKED
 465         if(!isNew && n != self.sv_entnum)
 466         {
 467                 //print("A CSQC entity changed its owner!\n");
 468                 printf("A CSQC entity changed its owner! (edict: %d, classname: %s)\n", num_for_edict(self), self.classname);
 469                 isNew = true;
 470                 Ent_Remove();
 471                 self.enttype = ENT_CLIENT_SCORES;
 472         }
 473 #endif
 474
 475         self.sv_entnum = n;
 476
 477         if (!(playerslots[self.sv_entnum]))
 478                 playerslots[self.sv_entnum] = spawn();
 479         o = self.owner = playerslots[self.sv_entnum];
 480         o.sv_entnum = self.sv_entnum;
 481         o.gotscores = 1;
 482
 483         //if (!o.sort_prev)
 484         //      RegisterPlayer(o);
 485         //playerchecker will do this for us later, if it has not already done so
 486
 487     int sf, lf;
 488 #if MAX_SCORE <= 8
 489         sf = ReadByte();
 490         lf = ReadByte();
 491 #else
 492         sf = ReadShort();
 493         lf = ReadShort();
 494 #endif
 495     int p;
 496         for(i = 0, p = 1; i < MAX_SCORE; ++i, p *= 2)
 497                 if(sf & p)
 498                 {
 499                         if(lf & p)
 500                                 o.(scores[i]) = ReadInt24_t();
 501                         else
 502                                 o.(scores[i]) = ReadChar();
 503                 }
 504
 505         if(o.sort_prev)
 506                 HUD_UpdatePlayerPos(o); // if not registered, we cannot do this yet!
 507
 508         self.entremove = Ent_RemovePlayerScore;
 509 }
 510
 511 void Ent_ReadTeamScore()
 512 {
 513         int i;
 514         entity o;
 515
 516         self.team = ReadByte();
 517         o = self.owner = GetTeam(self.team, true); // these team numbers can always be trusted
 518
 519     int sf, lf;
 520 #if MAX_TEAMSCORE <= 8
 521         sf = ReadByte();
 522         lf = ReadByte();
 523 #else
 524         sf = ReadShort();
 525         lf = ReadShort();
 526 #endif
 527         int p;
 528         for(i = 0, p = 1; i < MAX_TEAMSCORE; ++i, p *= 2)
 529                 if(sf & p)
 530                 {
 531                         if(lf & p)
 532                                 o.(teamscores[i]) = ReadInt24_t();
 533                         else
 534                                 o.(teamscores[i]) = ReadChar();
 535                 }
 536
 537         HUD_UpdateTeamPos(o);
 538 }
 539
 540 void Ent_ClientData()
 541 {
 542         float newspectatee_status;
 543
 544     int f = ReadByte();
 545
 546         scoreboard_showscores_force = (f & 1);
 547
 548         if(f & 2)
 549         {
 550                 newspectatee_status = ReadByte();
 551                 if(newspectatee_status == player_localnum + 1)
 552                         newspectatee_status = -1; // observing
 553         }
 554         else
 555                 newspectatee_status = 0;
 556
 557         spectatorbutton_zoom = (f & 4);
 558
 559         if(f & 8)
 560         {
 561                 angles_held_status = 1;
 562                 angles_held.x = ReadAngle();
 563                 angles_held.y = ReadAngle();
 564                 angles_held.z = 0;
 565         }
 566         else
 567                 angles_held_status = 0;
 568
 569         if(newspectatee_status != spectatee_status)
 570         {
 571                 // clear race stuff
 572                 race_laptime = 0;
 573                 race_checkpointtime = 0;
 574         }
 575         if (autocvar_hud_panel_healtharmor_progressbar_gfx)
 576         {
 577                 if ( (spectatee_status == -1 && newspectatee_status > 0) //before observing, now spectating
 578                   || (spectatee_status > 0 && newspectatee_status > 0 && spectatee_status != newspectatee_status) //changed spectated player
 579                 )
 580                         prev_p_health = -1;
 581                 else if(spectatee_status && !newspectatee_status) //before observing/spectating, now playing
 582                         prev_health = -1;
 583         }
 584         spectatee_status = newspectatee_status;
 585
 586         // we could get rid of spectatee_status, and derive it from player_localentnum and player_localnum
 587 }
 588
 589 void Ent_Nagger()
 590 {
 591     int i, j, b, f;
 592
 593     int nags = ReadByte(); // NAGS NAGS NAGS NAGS NAGS NAGS NADZ NAGS NAGS NAGS
 594
 595         if(!(nags & 4))
 596         {
 597                 if(vote_called_vote)
 598                         strunzone(vote_called_vote);
 599                 vote_called_vote = string_null;
 600                 vote_active = 0;
 601         }
 602         else
 603         {
 604                 vote_active = 1;
 605         }
 606
 607         if(nags & 64)
 608         {
 609                 vote_yescount = ReadByte();
 610                 vote_nocount = ReadByte();
 611                 vote_needed = ReadByte();
 612                 vote_highlighted = ReadChar();
 613         }
 614
 615         if(nags & 128)
 616         {
 617                 if(vote_called_vote)
 618                         strunzone(vote_called_vote);
 619                 vote_called_vote = strzone(ColorTranslateRGB(ReadString()));
 620         }
 621
 622         if(nags & 1)
 623         {
 624                 for(j = 0; j < maxclients; ++j)
 625                         if(playerslots[j])
 626                                 playerslots[j].ready = 1;
 627                 for(i = 1; i <= maxclients; i += 8)
 628                 {
 629                         f = ReadByte();
 630                         for(j = i-1, b = 1; b < 256; b *= 2, ++j)
 631                                 if (!(f & b))
 632                                         if(playerslots[j])
 633                                                 playerslots[j].ready = 0;
 634                 }
 635         }
 636
 637         ready_waiting = (nags & 1);
 638         ready_waiting_for_me = (nags & 2);
 639         vote_waiting = (nags & 4);
 640         vote_waiting_for_me = (nags & 8);
 641         warmup_stage = (nags & 16);
 642 }
 643
 644 void Ent_EliminatedPlayers()
 645 {
 646     int i, j, b, f;
 647
 648     int sf = ReadByte();
 649         if(sf & 1)
 650         {
 651                 for(j = 0; j < maxclients; ++j)
 652                         if(playerslots[j])
 653                                 playerslots[j].eliminated = 1;
 654                 for(i = 1; i <= maxclients; i += 8)
 655                 {
 656                         f = ReadByte();
 657                         for(j = i-1, b = 1; b < 256; b *= 2, ++j)
 658                                 if (!(f & b))
 659                                         if(playerslots[j])
 660                                                 playerslots[j].eliminated = 0;
 661                 }
 662         }
 663 }
 664
 665 void Ent_RandomSeed()
 666 {
 667         float s;
 668         prandom_debug();
 669         s = ReadShort();
 670         psrandom(s);
 671 }
 672
 673 void Ent_ReadAccuracy(void)
 674 {
 675     int f, w;
 676     int sf = ReadInt24_t();
 677         if(sf == 0)
 678         {
 679                 for(w = 0; w <= WEP_LAST - WEP_FIRST; ++w)
 680                         weapon_accuracy[w] = -1;
 681                 return;
 682         }
 683
 684         for(w = 0, f = 1; w <= WEP_LAST - WEP_FIRST; ++w)
 685         {
 686                 if(sf & f)
 687                 {
 688             int b = ReadByte();
 689                         if(b == 0)
 690                                 weapon_accuracy[w] = -1;
 691                         else if(b == 255)
 692                                 weapon_accuracy[w] = 1.0; // no better error handling yet, sorry
 693                         else
 694                                 weapon_accuracy[w] = (b - 1.0) / 100.0;
 695                 }
 696                 if(f == 0x800000)
 697                         f = 1;
 698                 else
 699                         f *= 2;
 700         }
 701 }
 702
 703 void Spawn_Draw(void)
 704 {
 705         pointparticles(self.cnt, self.origin + '0 0 28', '0 0 2', bound(0, frametime, 0.1));
 706 }
 707
 708 void Ent_ReadSpawnPoint(float is_new) // entity for spawnpoint
 709 {
 710         float teamnum = (ReadByte() - 1);
 711         vector spn_origin;
 712         spn_origin.x = ReadShort();
 713         spn_origin.y = ReadShort();
 714         spn_origin.z = ReadShort();
 715
 716         if(is_new)
 717         {
 718                 self.origin = spn_origin;
 719                 setsize(self, PL_MIN_CONST, PL_MAX_CONST);
 720                 droptofloor();
 721
 722                 /*if(autocvar_cl_spawn_point_model) // needs a model first
 723                 {
 724                         self.mdl = "models/spawnpoint.md3";
 725                         self.colormod = Team_ColorRGB(teamnum);
 726                         precache_model(self.mdl);
 727                         setmodel(self, self.mdl);
 728                         self.drawmask = MASK_NORMAL;
 729                         //self.movetype = MOVETYPE_NOCLIP;
 730                         //self.draw = Spawn_Draw;
 731                 }*/
 732                 if(autocvar_cl_spawn_point_particles)
 733                 {
 734                         if((serverflags & SERVERFLAG_TEAMPLAY))
 735                         {
 736                                 switch(teamnum)
 737                                 {
 738                                         case NUM_TEAM_1: self.cnt = particleeffectnum("spawn_point_red"); break;
 739                                         case NUM_TEAM_2: self.cnt = particleeffectnum("spawn_point_blue"); break;
 740                                         case NUM_TEAM_3: self.cnt = particleeffectnum("spawn_point_yellow"); break;
 741                                         case NUM_TEAM_4: self.cnt = particleeffectnum("spawn_point_pink"); break;
 742                                         default: self.cnt = particleeffectnum("spawn_point_neutral"); break;
 743                                 }
 744                         }
 745                         else { self.cnt = particleeffectnum("spawn_point_neutral"); }
 746
 747                         self.draw = Spawn_Draw;
 748                 }
 749         }
 750
 751         //printf("Ent_ReadSpawnPoint(is_new = %d); origin = %s, team = %d, effect = %d\n", is_new, vtos(self.origin), teamnum, self.cnt);
 752 }
 753
 754 void Ent_ReadSpawnEvent(float is_new)
 755 {
 756         // If entnum is 0, ONLY do the local spawn actions
 757         // this way the server can disable the sending of
 758         // spawn origin or such to clients if wanted.
 759         float entnum = ReadByte();
 760
 761         if(entnum)
 762         {
 763                 self.origin_x = ReadShort();
 764                 self.origin_y = ReadShort();
 765                 self.origin_z = ReadShort();
 766
 767                 if(is_new)
 768                 {
 769                         float teamnum = GetPlayerColor(entnum - 1);
 770
 771                         if(autocvar_cl_spawn_event_particles)
 772                         {
 773                                 switch(teamnum)
 774                                 {
 775                                         case NUM_TEAM_1: pointparticles(particleeffectnum("spawn_event_red"), self.origin, '0 0 0', 1); break;
 776                                         case NUM_TEAM_2: pointparticles(particleeffectnum("spawn_event_blue"), self.origin, '0 0 0', 1); break;
 777                                         case NUM_TEAM_3: pointparticles(particleeffectnum("spawn_event_yellow"), self.origin, '0 0 0', 1); break;
 778                                         case NUM_TEAM_4: pointparticles(particleeffectnum("spawn_event_pink"), self.origin, '0 0 0', 1); break;
 779                                         default: pointparticles(particleeffectnum("spawn_event_neutral"), self.origin, '0 0 0', 1); break;
 780                                 }
 781                         }
 782                         if(autocvar_cl_spawn_event_sound)
 783                         {
 784                                 sound(self, CH_TRIGGER, "misc/spawn.wav", VOL_BASE, ATTEN_NORM);
 785                         }
 786                 }
 787         }
 788
 789         // local spawn actions
 790         if(is_new && (!entnum || (entnum == player_localentnum)))
 791         {
 792                 zoomin_effect = 1;
 793                 current_viewzoom = (1 / bound(1, autocvar_cl_spawnzoom_factor, 16));
 794
 795                 if(autocvar_cl_unpress_zoom_on_spawn)
 796                 {
 797                         localcmd("-zoom\n");
 798                         button_zoom = false;
 799                 }
 800         }
 801         HUD_Radar_Hide_Maximized();
 802         //printf("Ent_ReadSpawnEvent(is_new = %d); origin = %s, entnum = %d, localentnum = %d\n", is_new, vtos(self.origin), entnum, player_localentnum);
 803 }
 804
 805 // CSQC_Ent_Update : Called every frame that the server has indicated an update to the SSQC / CSQC entity has occured.
 806 // The only parameter reflects if the entity is "new" to the client, meaning it just came into the client's PVS.
 807 void Ent_RadarLink();
 808 void Ent_Init();
 809 void Ent_ScoresInfo();
 810 void CSQC_Ent_Update(float bIsNewEntity)
 811 {
 812         float t;
 813         float savetime;
 814         t = ReadByte();
 815
 816         if(autocvar_developer_csqcentities)
 817                 printf("CSQC_Ent_Update(%d) with self=%i self.entnum=%d self.enttype=%d t=%d\n", bIsNewEntity, self, self.entnum, self.enttype, t);
 818
 819         // set up the "time" global for received entities to be correct for interpolation purposes
 820         savetime = time;
 821         if(servertime)
 822         {
 823                 time = servertime;
 824         }
 825         else
 826         {
 827                 serverprevtime = time;
 828                 serverdeltatime = getstatf(STAT_MOVEVARS_TICRATE) * getstatf(STAT_MOVEVARS_TIMESCALE);
 829                 time = serverprevtime + serverdeltatime;
 830         }
 831
 832 #ifdef DP_CSQC_ENTITY_REMOVE_IS_B0RKED
 833         if(self.enttype)
 834         {
 835                 if(t != self.enttype || bIsNewEntity)
 836                 {
 837                         //print("A CSQC entity changed its type!\n");
 838                         printf("A CSQC entity changed its type! (edict: %d, server: %d, type: %d -> %d)\n", num_for_edict(self), self.entnum, self.enttype, t);
 839                         Ent_Remove();
 840                         clearentity(self);
 841                         bIsNewEntity = 1;
 842                 }
 843         }
 844         else
 845         {
 846                 if(!bIsNewEntity)
 847                 {
 848                         printf("A CSQC entity appeared out of nowhere! (edict: %d, server: %d, type: %d)\n", num_for_edict(self), self.entnum, t);
 849                         bIsNewEntity = 1;
 850                 }
 851         }
 852 #endif
 853         self.enttype = t;
 854         switch(t)
 855         {
 856                 case ENT_CLIENT_MUTATOR: {
 857                         int mutID = ReadMutator();
 858                         if (!MUTATOR_CALLHOOK(CSQC_Ent_Update, mutID, bIsNewEntity))
 859                         error(sprintf("Unknown mutator type in CSQC_Ent_Update (mutID: %d, edict: %d, classname: %s)\n", mutID, num_for_edict(self), self.classname));
 860                         break;
 861                 }
 862                 case ENT_CLIENT_ENTCS: Ent_ReadEntCS(); break;
 863                 case ENT_CLIENT_SCORES: Ent_ReadPlayerScore(); break;
 864                 case ENT_CLIENT_TEAMSCORES: Ent_ReadTeamScore(); break;
 865                 case ENT_CLIENT_POINTPARTICLES: Ent_PointParticles(); break;
 866                 case ENT_CLIENT_RAINSNOW: Ent_RainOrSnow(); break;
 867                 case ENT_CLIENT_LASER: Ent_Laser(); break;
 868                 case ENT_CLIENT_NAGGER: Ent_Nagger(); break;
 869                 case ENT_CLIENT_ELIMINATEDPLAYERS: Ent_EliminatedPlayers(); break;
 870                 case ENT_CLIENT_RADARLINK: Ent_RadarLink(); break;
 871                 case ENT_CLIENT_PROJECTILE: Ent_Projectile(); break;
 872                 case ENT_CLIENT_GIBSPLASH: Ent_GibSplash(bIsNewEntity); break;
 873                 case ENT_CLIENT_DAMAGEINFO: Ent_DamageInfo(bIsNewEntity); break;
 874                 case ENT_CLIENT_CASING: Ent_Casing(bIsNewEntity); break;
 875                 case ENT_CLIENT_INIT: Ent_Init(); break;
 876                 case ENT_CLIENT_SCORES_INFO: Ent_ScoresInfo(); break;
 877                 case ENT_CLIENT_MAPVOTE: Ent_MapVote(); break;
 878                 case ENT_CLIENT_CLIENTDATA: Ent_ClientData(); break;
 879                 case ENT_CLIENT_RANDOMSEED: Ent_RandomSeed(); break;
 880                 case ENT_CLIENT_WALL: Ent_Wall(); break;
 881                 case ENT_CLIENT_MODELEFFECT: Ent_ModelEffect(bIsNewEntity); break;
 882                 case ENT_CLIENT_TUBANOTE: Ent_TubaNote(bIsNewEntity); break;
 883                 case ENT_CLIENT_WARPZONE: WarpZone_Read(bIsNewEntity); break;
 884                 case ENT_CLIENT_WARPZONE_CAMERA: WarpZone_Camera_Read(bIsNewEntity); break;
 885                 case ENT_CLIENT_WARPZONE_TELEPORTED: WarpZone_Teleported_Read(bIsNewEntity); break;
 886                 case ENT_CLIENT_TRIGGER_MUSIC: Ent_ReadTriggerMusic(); break;
 887                 case ENT_CLIENT_HOOK: Ent_ReadHook(bIsNewEntity, ENT_CLIENT_HOOK); break;
 888                 case ENT_CLIENT_INVENTORY: Inventory_Read(self); break;
 889                 case ENT_CLIENT_ARC_BEAM: Ent_ReadArcBeam(bIsNewEntity); break;
 890                 case ENT_CLIENT_ACCURACY: Ent_ReadAccuracy(); break;
 891                 case ENT_CLIENT_AUXILIARYXHAIR: Net_AuXair2(bIsNewEntity); break;
 892                 case ENT_CLIENT_TURRET: ent_turret(); break;
 893                 case ENT_CLIENT_GENERATOR: ent_generator(); break;
 894                 case ENT_CLIENT_CONTROLPOINT_ICON: ent_cpicon(); break;
 895                 case ENT_CLIENT_MODEL: CSQCModel_Read(bIsNewEntity); break;
 896                 case ENT_CLIENT_ITEM: ItemRead(bIsNewEntity); break;
 897                 case ENT_CLIENT_BUMBLE_RAYGUN: bumble_raygun_read(bIsNewEntity); break;
 898                 case ENT_CLIENT_SPAWNPOINT: Ent_ReadSpawnPoint(bIsNewEntity); break;
 899                 case ENT_CLIENT_SPAWNEVENT: Ent_ReadSpawnEvent(bIsNewEntity); break;
 900                 case ENT_CLIENT_NOTIFICATION: Read_Notification(bIsNewEntity); break;
 901                 case ENT_CLIENT_HEALING_ORB: ent_healer(); break;
 902                 case ENT_CLIENT_MINIGAME: ent_read_minigame(); break;
 903                 case ENT_CLIENT_VIEWLOC: ent_viewloc(); break;
 904                 case ENT_CLIENT_VIEWLOC_TRIGGER: ent_viewloc_trigger(); break;
 905                 case ENT_CLIENT_LADDER: ent_func_ladder(); break;
 906                 case ENT_CLIENT_TRIGGER_PUSH: ent_trigger_push(); break;
 907                 case ENT_CLIENT_TARGET_PUSH: ent_target_push(); break;
 908                 case ENT_CLIENT_CONVEYOR: ent_conveyor(); break;
 909                 case ENT_CLIENT_DOOR: ent_door(); break;
 910                 case ENT_CLIENT_PLAT: ent_plat(); break;
 911                 case ENT_CLIENT_SWAMP: ent_swamp(); break;
 912                 case ENT_CLIENT_CORNER: ent_corner(); break;
 913                 case ENT_CLIENT_KEYLOCK: ent_keylock(); break;
 914                 case ENT_CLIENT_TRAIN: ent_train(); break;
 915                 case ENT_CLIENT_TRIGGER_IMPULSE: ent_trigger_impulse(); break;
 916                 case ENT_CLIENT_EFFECT: Read_Effect(bIsNewEntity); break;
 917
 918                 default:
 919                         //error(strcat(_("unknown entity type in CSQC_Ent_Update: %d\n"), self.enttype));
 920                         error(sprintf("Unknown entity type in CSQC_Ent_Update (enttype: %d, edict: %d, classname: %s)\n", self.enttype, num_for_edict(self), self.classname));
 921                         break;
 922         }
 923
 924         time = savetime;
 925 }
 926 // Destructor, but does NOT deallocate the entity by calling remove(). Also
 927 // used when an entity changes its type. For an entity that someone interacts
 928 // with others, make sure it can no longer do so.
 929 void Ent_Remove()
 930 {
 931         if(self.entremove)
 932                 self.entremove();
 933
 934         if(self.skeletonindex)
 935         {
 936                 skel_delete(self.skeletonindex);
 937                 self.skeletonindex = 0;
 938         }
 939
 940         if(self.snd_looping > 0)
 941         {
 942                 sound(self, self.snd_looping, "misc/null.wav", VOL_BASE, autocvar_g_jetpack_attenuation);
 943                 self.snd_looping = 0;
 944         }
 945
 946         self.enttype = 0;
 947         self.classname = "";
 948         self.draw = menu_sub_null;
 949         self.entremove = menu_sub_null;
 950         // TODO possibly set more stuff to defaults
 951 }
 952 // CSQC_Ent_Remove : Called when the server requests a SSQC / CSQC entity to be removed.  Essentially call remove(self) as well.
 953 void CSQC_Ent_Remove()
 954 {
 955         if(autocvar_developer_csqcentities)
 956                 printf("CSQC_Ent_Remove() with self=%i self.entnum=%d self.enttype=%d\n", self, self.entnum, self.enttype);
 957
 958         if(wasfreed(self))
 959         {
 960                 print("WARNING: CSQC_Ent_Remove called for already removed entity. Packet loss?\n");
 961                 return;
 962         }
 963         if(self.enttype)
 964                 Ent_Remove();
 965         remove(self);
 966 }
 967
 968 void Gamemode_Init()
 969 {
 970         if (!isdemo())
 971         {
 972                 if(!(calledhooks & HOOK_START))
 973                         localcmd("\n_cl_hook_gamestart ", MapInfo_Type_ToString(gametype), "\n");
 974                 calledhooks |= HOOK_START;
 975         }
 976 }
 977 // CSQC_Parse_StuffCmd : Provides the stuffcmd string in the first parameter that the server provided.  To execute standard behavior, simply execute localcmd with the string.
 978 void CSQC_Parse_StuffCmd(string strMessage)
 979 {
 980         if(autocvar_developer_csqcentities)
 981                 printf("CSQC_Parse_StuffCmd(\"%s\")\n", strMessage);
 982
 983         localcmd(strMessage);
 984 }
 985 // CSQC_Parse_Print : Provides the print string in the first parameter that the server provided.  To execute standard behavior, simply execute print with the string.
 986 void CSQC_Parse_Print(string strMessage)
 987 {
 988         if(autocvar_developer_csqcentities)
 989                 printf("CSQC_Parse_Print(\"%s\")\n", strMessage);
 990
 991         print(ColorTranslateRGB(strMessage));
 992 }
 993
 994 // CSQC_Parse_CenterPrint : Provides the centerprint_hud string in the first parameter that the server provided.
 995 void CSQC_Parse_CenterPrint(string strMessage)
 996 {
 997         if(autocvar_developer_csqcentities)
 998                 printf("CSQC_Parse_CenterPrint(\"%s\")\n", strMessage);
 999
1000         centerprint_hud(strMessage);
1001 }
1002
1003 string notranslate_fogcmd1 = "\nfog ";
1004 string notranslate_fogcmd2 = "\nr_fog_exp2 0\nr_drawfog 1\n";
1005 void Fog_Force()
1006 {
1007         // TODO somehow thwart prvm_globalset client ...
1008
1009         if(autocvar_cl_orthoview && autocvar_cl_orthoview_nofog)
1010                 { localcmd("\nr_drawfog 0\n"); }
1011         else if(forcefog != "")
1012                 { localcmd(strcat(notranslate_fogcmd1, forcefog, notranslate_fogcmd2)); }
1013 }
1014
1015 void Gamemode_Init();
1016 void Ent_ScoresInfo()
1017 {
1018     int i;
1019         self.classname = "ent_client_scores_info";
1020         gametype = ReadInt24_t();
1021         HUD_ModIcons_SetFunc();
1022         for(i = 0; i < MAX_SCORE; ++i)
1023         {
1024                 if(scores_label[i])
1025                         strunzone(scores_label[i]);
1026                 scores_label[i] = strzone(ReadString());
1027                 scores_flags[i] = ReadByte();
1028         }
1029         for(i = 0; i < MAX_TEAMSCORE; ++i)
1030         {
1031                 if(teamscores_label[i])
1032                         strunzone(teamscores_label[i]);
1033                 teamscores_label[i] = strzone(ReadString());
1034                 teamscores_flags[i] = ReadByte();
1035         }
1036         HUD_InitScores();
1037         Gamemode_Init();
1038 }
1039
1040 void Ent_Init()
1041 {
1042         self.classname = "ent_client_init";
1043
1044         nb_pb_period = ReadByte() / 32; //Accuracy of 1/32th
1045
1046         hook_shotorigin[0] = decompressShotOrigin(ReadInt24_t());
1047         hook_shotorigin[1] = decompressShotOrigin(ReadInt24_t());
1048         hook_shotorigin[2] = decompressShotOrigin(ReadInt24_t());
1049         hook_shotorigin[3] = decompressShotOrigin(ReadInt24_t());
1050         arc_shotorigin[0] = decompressShotOrigin(ReadInt24_t());
1051         arc_shotorigin[1] = decompressShotOrigin(ReadInt24_t());
1052         arc_shotorigin[2] = decompressShotOrigin(ReadInt24_t());
1053         arc_shotorigin[3] = decompressShotOrigin(ReadInt24_t());
1054
1055         if(forcefog)
1056                 strunzone(forcefog);
1057         forcefog = strzone(ReadString());
1058
1059         armorblockpercent = ReadByte() / 255.0;
1060
1061         g_balance_mortar_bouncefactor = ReadCoord();
1062         g_balance_mortar_bouncestop = ReadCoord();
1063         g_balance_electro_secondary_bouncefactor = ReadCoord();
1064         g_balance_electro_secondary_bouncestop = ReadCoord();
1065
1066         vortex_scope = !ReadByte();
1067         rifle_scope = !ReadByte();
1068
1069         serverflags = ReadByte();
1070
1071         minelayer_maxmines = ReadByte();
1072
1073         hagar_maxrockets = ReadByte();
1074
1075         g_trueaim_minrange = ReadCoord();
1076         g_balance_porto_secondary = ReadByte();
1077
1078         if(!postinit)
1079                 PostInit();
1080 }
1081
1082 void Net_ReadRace()
1083 {
1084         float b;
1085
1086         b = ReadByte();
1087
1088         switch(b)
1089         {
1090                 case RACE_NET_CHECKPOINT_HIT_QUALIFYING:
1091                         race_checkpoint = ReadByte();
1092                         race_time = ReadInt24_t();
1093                         race_previousbesttime = ReadInt24_t();
1094                         if(race_previousbestname)
1095                                 strunzone(race_previousbestname);
1096                         race_previousbestname = strzone(ColorTranslateRGB(ReadString()));
1097
1098                         race_checkpointtime = time;
1099
1100                         if(race_checkpoint == 0 || race_checkpoint == 254)
1101                         {
1102                                 race_penaltyaccumulator = 0;
1103                                 race_laptime = time; // valid
1104                         }
1105
1106                         break;
1107
1108                 case RACE_NET_CHECKPOINT_CLEAR:
1109                         race_laptime = 0;
1110                         race_checkpointtime = 0;
1111                         break;
1112
1113                 case RACE_NET_CHECKPOINT_NEXT_SPEC_QUALIFYING:
1114                         race_laptime = ReadCoord();
1115                         race_checkpointtime = -99999;
1116                         // fall through
1117                 case RACE_NET_CHECKPOINT_NEXT_QUALIFYING:
1118                         race_nextcheckpoint = ReadByte();
1119
1120                         race_nextbesttime = ReadInt24_t();
1121                         if(race_nextbestname)
1122                                 strunzone(race_nextbestname);
1123                         race_nextbestname = strzone(ColorTranslateRGB(ReadString()));
1124                         break;
1125
1126                 case RACE_NET_CHECKPOINT_HIT_RACE:
1127                         race_mycheckpoint = ReadByte();
1128                         race_mycheckpointtime = time;
1129                         race_mycheckpointdelta = ReadInt24_t();
1130                         race_mycheckpointlapsdelta = ReadByte();
1131                         if(race_mycheckpointlapsdelta >= 128)
1132                                 race_mycheckpointlapsdelta -= 256;
1133                         if(race_mycheckpointenemy)
1134                                 strunzone(race_mycheckpointenemy);
1135                         race_mycheckpointenemy = strzone(ColorTranslateRGB(ReadString()));
1136                         break;
1137
1138                 case RACE_NET_CHECKPOINT_HIT_RACE_BY_OPPONENT:
1139                         race_othercheckpoint = ReadByte();
1140                         race_othercheckpointtime = time;
1141                         race_othercheckpointdelta = ReadInt24_t();
1142                         race_othercheckpointlapsdelta = ReadByte();
1143                         if(race_othercheckpointlapsdelta >= 128)
1144                                 race_othercheckpointlapsdelta -= 256;
1145                         if(race_othercheckpointenemy)
1146                                 strunzone(race_othercheckpointenemy);
1147                         race_othercheckpointenemy = strzone(ColorTranslateRGB(ReadString()));
1148                         break;
1149
1150                 case RACE_NET_PENALTY_RACE:
1151                         race_penaltyeventtime = time;
1152                         race_penaltytime = ReadShort();
1153                         //race_penaltyaccumulator += race_penaltytime;
1154                         if(race_penaltyreason)
1155                                 strunzone(race_penaltyreason);
1156                         race_penaltyreason = strzone(ReadString());
1157                         break;
1158
1159                 case RACE_NET_PENALTY_QUALIFYING:
1160                         race_penaltyeventtime = time;
1161                         race_penaltytime = ReadShort();
1162                         race_penaltyaccumulator += race_penaltytime;
1163                         if(race_penaltyreason)
1164                                 strunzone(race_penaltyreason);
1165                         race_penaltyreason = strzone(ReadString());
1166                         break;
1167
1168                 case RACE_NET_SERVER_RECORD:
1169                         race_server_record = ReadInt24_t();
1170                         break;
1171                 case RACE_NET_SPEED_AWARD:
1172                         race_speedaward = ReadInt24_t();
1173                         if(race_speedaward_holder)
1174                                 strunzone(race_speedaward_holder);
1175                         race_speedaward_holder = strzone(ReadString());
1176                         break;
1177                 case RACE_NET_SPEED_AWARD_BEST:
1178                         race_speedaward_alltimebest = ReadInt24_t();
1179                         if(race_speedaward_alltimebest_holder)
1180                                 strunzone(race_speedaward_alltimebest_holder);
1181                         race_speedaward_alltimebest_holder = strzone(ReadString());
1182                         break;
1183                 case RACE_NET_SERVER_RANKINGS:
1184                         float prevpos, del;
1185             int pos = ReadShort();
1186                         prevpos = ReadShort();
1187                         del = ReadShort();
1188
1189                         // move other rankings out of the way
1190             int i;
1191                         if (prevpos) {
1192                                 for (i=prevpos-1;i>pos-1;--i) {
1193                                         grecordtime[i] = grecordtime[i-1];
1194                                         if(grecordholder[i])
1195                                                 strunzone(grecordholder[i]);
1196                                         grecordholder[i] = strzone(grecordholder[i-1]);
1197                                 }
1198                         } else if (del) { // a record has been deleted by the admin
1199                                 for (i=pos-1; i<= RANKINGS_CNT-1; ++i) {
1200                                         if (i == RANKINGS_CNT-1) { // clear out last record
1201                                                 grecordtime[i] = 0;
1202                                                 if (grecordholder[i])
1203                                                         strunzone(grecordholder[i]);
1204                                                 grecordholder[i] = string_null;
1205                                         }
1206                                         else {
1207                                                 grecordtime[i] = grecordtime[i+1];
1208                                                 if (grecordholder[i])
1209                                                         strunzone(grecordholder[i]);
1210                                                 grecordholder[i] = strzone(grecordholder[i+1]);
1211                                         }
1212                                 }
1213                         } else { // player has no ranked record yet
1214                                 for (i=RANKINGS_CNT-1;i>pos-1;--i) {
1215                                         grecordtime[i] = grecordtime[i-1];
1216                                         if(grecordholder[i])
1217                                                 strunzone(grecordholder[i]);
1218                                         grecordholder[i] = strzone(grecordholder[i-1]);
1219                                 }
1220                         }
1221
1222                         // store new ranking
1223                         if(grecordholder[pos-1] != "")
1224                                 strunzone(grecordholder[pos-1]);
1225                         grecordholder[pos-1] = strzone(ReadString());
1226                         grecordtime[pos-1] = ReadInt24_t();
1227                         if(grecordholder[pos-1] == GetPlayerName(player_localnum))
1228                                 race_myrank = pos;
1229                         break;
1230                 case RACE_NET_SERVER_STATUS:
1231                         race_status = ReadShort();
1232                         if(race_status_name)
1233                                 strunzone(race_status_name);
1234                         race_status_name = strzone(ReadString());
1235         }
1236 }
1237
1238 void Net_TeamNagger()
1239 {
1240         teamnagger = 1;
1241 }
1242
1243 void Net_ReadPingPLReport()
1244 {
1245         int e, pi, pl, ml;
1246         e = ReadByte();
1247         pi = ReadShort();
1248         pl = ReadByte();
1249         ml = ReadByte();
1250         if (!(playerslots[e]))
1251                 return;
1252         playerslots[e].ping = pi;
1253         playerslots[e].ping_packetloss = pl / 255.0;
1254         playerslots[e].ping_movementloss = ml / 255.0;
1255 }
1256
1257 void Net_WeaponComplain()
1258 {
1259         complain_weapon = ReadByte();
1260
1261         if(complain_weapon_name)
1262                 strunzone(complain_weapon_name);
1263         complain_weapon_name = strzone(WEP_NAME(complain_weapon));
1264
1265         complain_weapon_type = ReadByte();
1266
1267         complain_weapon_time = time;
1268         weapontime = time; // ping the weapon panel
1269
1270         switch(complain_weapon_type)
1271         {
1272                 case 0: Local_Notification(MSG_MULTI, ITEM_WEAPON_NOAMMO, complain_weapon); break;
1273                 case 1: Local_Notification(MSG_MULTI, ITEM_WEAPON_DONTHAVE, complain_weapon); break;
1274                 default: Local_Notification(MSG_MULTI, ITEM_WEAPON_UNAVAILABLE, complain_weapon); break;
1275         }
1276 }
1277
1278 // CSQC_Parse_TempEntity : Handles all temporary entity network data in the CSQC layer.
1279 // You must ALWAYS first acquire the temporary ID, which is sent as a byte.
1280 // Return value should be 1 if CSQC handled the temporary entity, otherwise return 0 to have the engine process the event.
1281 float CSQC_Parse_TempEntity()
1282 {
1283         // Acquire TE ID
1284         int nTEID = ReadByte();
1285
1286         if (autocvar_developer_csqcentities)
1287                 printf("CSQC_Parse_TempEntity() with nTEID=%d\n", nTEID);
1288
1289         switch (nTEID)
1290         {
1291                 case TE_CSQC_MUTATOR:
1292                         int mutID = ReadMutator();
1293                         if (MUTATOR_CALLHOOK(CSQC_Parse_TempEntity, mutID))
1294                         return true;
1295                 case TE_CSQC_TARGET_MUSIC:
1296                         Net_TargetMusic();
1297                         return true;
1298                 case TE_CSQC_PICTURE:
1299                         Net_MapVote_Picture();
1300                         return true;
1301                 case TE_CSQC_RACE:
1302                         Net_ReadRace();
1303                         return true;
1304                 case TE_CSQC_VORTEXBEAMPARTICLE:
1305                         Net_ReadVortexBeamParticle();
1306                         return true;
1307                 case TE_CSQC_TEAMNAGGER:
1308                         Net_TeamNagger();
1309                         return true;
1310                 case TE_CSQC_ARC:
1311                         Net_ReadArc();
1312                         return true;
1313                 case TE_CSQC_PINGPLREPORT:
1314                         Net_ReadPingPLReport();
1315                         return true;
1316                 case TE_CSQC_WEAPONCOMPLAIN:
1317                         Net_WeaponComplain();
1318                         return true;
1319                 case TE_CSQC_VEHICLESETUP:
1320                         Net_VehicleSetup();
1321                         return true;
1322                 case TE_CSQC_SVNOTICE:
1323                         cl_notice_read();
1324                         return true;
1325                 case TE_CSQC_SHOCKWAVEPARTICLE:
1326                         Net_ReadShockwaveParticle();
1327                         return true;
1328                 default:
1329                         // No special logic for this temporary entity; return 0 so the engine can handle it
1330                         return false;
1331         }
1332 }
1333
1334 string getcommandkey(string text, string command)
1335 {
1336         string keys;
1337         float n, j, k, l = 0;
1338
1339         if (!autocvar_hud_showbinds)
1340                 return text;
1341
1342         keys = db_get(binddb, command);
1343         if (keys == "")
1344         {
1345                 n = tokenize(findkeysforcommand(command, 0)); // uses '...' strings
1346                 for(j = 0; j < n; ++j)
1347                 {
1348                         k = stof(argv(j));
1349                         if(k != -1)
1350                         {
1351                                 if ("" == keys)
1352                                         keys = keynumtostring(k);
1353                                 else
1354                                         keys = strcat(keys, ", ", keynumtostring(k));
1355
1356                                 ++l;
1357                                 if (autocvar_hud_showbinds_limit > 0 && autocvar_hud_showbinds_limit <= l)
1358                                         break;
1359                         }
1360
1361                 }
1362                 if (keys == "")
1363                         keys = "NO_KEY";
1364                 db_put(binddb, command, keys);
1365         }
1366
1367         if (keys == "NO_KEY") {
1368                 if (autocvar_hud_showbinds > 1)
1369                         return sprintf(_("%s (not bound)"), text);
1370                 else
1371                         return text;
1372         }
1373         else if (autocvar_hud_showbinds > 1)
1374                 return sprintf("%s (%s)", text, keys);
1375         else
1376                 return keys;
1377 }