qcsrc/client/main.qc

   1 #include "main.qh"
   2
   3 #include <client/command/cl_cmd.qh>
   4 #include <client/draw.qh>
   5 #include <client/hud/_mod.qh>
   6 #include <client/hud/panel/centerprint.qh>
   7 #include <client/hud/panel/chat.qh>
   8 #include <client/hud/panel/quickmenu.qh>
   9 #include <client/hud/panel/scoreboard.qh>
  10 #include <client/items/items.qh>
  11 #include <client/mapvoting.qh>
  12 #include <client/mutators/_mod.qh>
  13 #include <client/shownames.qh>
  14 #include <client/view.qh>
  15 #include <client/weapons/projectile.qh>
  16 #include <common/checkextension.qh>
  17 #include <common/deathtypes/all.qh>
  18 #include <common/effects/all.inc>
  19 #include <common/effects/all.qh>
  20 #include <common/effects/effect.qh>
  21 #include <common/effects/qc/_mod.qh>
  22 #include <common/ent_cs.qh>
  23 #include <common/gamemodes/gamemode/nexball/cl_nexball.qh>
  24 #include <common/items/_mod.qh>
  25 #include <common/mapinfo.qh>
  26 #include <common/mapobjects/_mod.qh>
  27 #include <common/minigames/cl_minigames.qh>
  28 #include <common/minigames/cl_minigames_hud.qh>
  29 #include <common/net_linked.qh>
  30 #include <common/net_notice.qh>
  31 #include <common/scores.qh>
  32 #include <common/vehicles/all.qh>
  33 #include <lib/csqcmodel/cl_model.qh>
  34 #include <lib/csqcmodel/interpolate.qh>
  35 #include <lib/warpzone/client.qh>
  36
  37 // --------------------------------------------------------------------------
  38 // BEGIN REQUIRED CSQC FUNCTIONS
  39 //include "main.qh"
  40
  41 #define DP_CSQC_ENTITY_REMOVE_IS_B0RKED
  42
  43 // CSQC_Init : Called every time the CSQC code is initialized (essentially at map load)
  44 // Useful for precaching things
  45
  46 void CSQC_Init()
  47 {
  48         prvm_language = strzone(cvar_string("prvm_language"));
  49
  50 #ifdef WATERMARK
  51         LOG_TRACEF("^4CSQC Build information: ^1%s", WATERMARK);
  52 #endif
  53
  54         CheckEngineExtensions();
  55
  56         {
  57                 int i = 0;
  58                 for ( ; i < 255; ++i)
  59                         if (getplayerkeyvalue(i, "viewentity") == "")
  60                                 break;
  61                 maxclients = i;
  62         }
  63
  64         // needs to be done so early because of the constants they create
  65         static_init();
  66         static_init_late();
  67         static_init_precache();
  68
  69         binddb = db_create();
  70         tempdb = db_create();
  71         ClientProgsDB = db_load("client.db");
  72
  73         draw_endBoldFont();
  74
  75         //registercommand("hud_configure");
  76         //registercommand("hud_save");
  77         //registercommand("menu_action");
  78
  79         ConsoleCommand_macro_init();
  80
  81         registercvar("hud_usecsqc", "1");
  82         registercvar("scoreboard_columns", "default");
  83
  84         registercvar("cl_nade_type", "3");
  85         registercvar("cl_pokenade_type", "zombie");
  86
  87         registercvar("cl_jumpspeedcap_min", "");
  88         registercvar("cl_jumpspeedcap_max", "");
  89
  90         registercvar("cl_shootfromfixedorigin", "");
  91
  92         registercvar("cl_multijump", "-1");
  93
  94         registercvar("cl_dodging", "0");
  95
  96         registercvar("cl_spawn_near_teammate", "1");
  97
  98         registercvar("cl_weapon_switch_reload", "1");
  99         registercvar("cl_weapon_switch_fallback_to_impulse", "1");
 100
 101         registercvar("cl_allow_uidranking", "1");
 102
 103         if(autocvar_cl_lockview)
 104                 cvar_set("cl_lockview", "0");
 105
 106         if (cvar_type("_scoreboard_team_selection_available") & CVAR_TYPEFLAG_EXISTS)
 107                 cvar_settemp("_scoreboard_team_selection_available", "1");
 108         cvar_set("_scoreboard_team_selection", "0"); // in case it has been left set to 1
 109
 110         gametype = NULL;
 111
 112         postinit = false;
 113
 114         calledhooks = 0;
 115
 116         teams = Sort_Spawn();
 117         players = Sort_Spawn();
 118
 119         GetTeam(NUM_SPECTATOR, true); // add specs first
 120
 121         for (int w = 0; w <= WEP_LAST - WEP_FIRST; ++w)
 122                 weapon_accuracy[w] = -1;
 123
 124         // precaches
 125
 126         if(autocvar_cl_reticle)
 127         {
 128                 precache_pic("gfx/reticle_normal");
 129                 // weapon reticles are precached in weapon files
 130         }
 131
 132         {
 133                 get_mi_min_max_texcoords(1); // try the CLEVER way first
 134                 minimapname = strcat("gfx/", mi_shortname, "_radar");
 135
 136                 if (precache_pic(minimapname) == "")
 137                 {
 138                         // but maybe we have a non-clever minimap
 139                         minimapname = strcat("gfx/", mi_shortname, "_mini");
 140                         if (precache_pic(minimapname) == "")
 141                                 minimapname = ""; // FAIL
 142                         else
 143                                 get_mi_min_max_texcoords(0); // load new texcoords
 144                 }
 145
 146                 mi_center = (mi_min + mi_max) * 0.5;
 147                 mi_scale = mi_max - mi_min;
 148                 minimapname = strzone(minimapname);
 149         }
 150
 151         hud_skin_path = strzone(strcat("gfx/hud/", autocvar_hud_skin));
 152         LoadMenuSkinValues();
 153 }
 154
 155 // CSQC_Shutdown : Called every time the CSQC code is shutdown (changing maps, quitting, etc)
 156 void Shutdown()
 157 {
 158         WarpZone_Shutdown();
 159
 160         delete(teams);
 161         delete(players);
 162         db_close(binddb);
 163         db_close(tempdb);
 164         if(autocvar_cl_db_saveasdump)
 165                 db_dump(ClientProgsDB, "client.db");
 166         else
 167                 db_save(ClientProgsDB, "client.db");
 168         db_close(ClientProgsDB);
 169
 170         if(camera_active)
 171                 cvar_set("chase_active",ftos(chase_active_backup));
 172
 173         // unset the event chasecam's chase_active
 174         if(autocvar_chase_active < 0)
 175                 cvar_set("chase_active", "0");
 176
 177         if (autocvar_r_drawviewmodel < 0)
 178                 cvar_set("r_drawviewmodel", "0");
 179
 180         cvar_set("slowmo", cvar_defstring("slowmo")); // reset it back to 'default'
 181
 182         if (!isdemo())
 183         {
 184                 if (!(calledhooks & HOOK_START))
 185                         localcmd("\n_cl_hook_gamestart nop\n");
 186                 if (!(calledhooks & HOOK_END))
 187                 {
 188                         int gamecount = cvar("cl_matchcount");
 189                         localcmd("\ncl_hook_gameend\n");
 190                         // NOTE: using localcmd here to ensure it's executed AFTER cl_hook_gameend
 191                         // earlier versions of the game abuse the hook to set this cvar
 192                         localcmd(strcat("cl_matchcount ", itos(gamecount + 1), "\n"));
 193                         //cvar_set("cl_matchcount", itos(gamecount + 1));
 194                 }
 195         }
 196
 197         localcmd("\ncl_hook_shutdown\n");
 198
 199         localcmd("\n-button12\n");
 200
 201         deactivate_minigame();
 202         HUD_MinigameMenu_Close(NULL, NULL, NULL);
 203
 204         ReplicateVars(REPLICATEVARS_DESTROY);
 205 }
 206
 207 void AuditLists()
 208 {
 209         entity e;
 210         entity prev;
 211
 212         prev = players;
 213         for(e = prev.sort_next; e; prev = e, e = e.sort_next)
 214         {
 215                 if(prev != e.sort_prev)
 216                         error(strcat("sort list chain error\nplease submit the output of 'prvm_edicts client' to the developers"));
 217         }
 218
 219         prev = teams;
 220         for(e = prev.sort_next; e; prev = e, e = e.sort_next)
 221         {
 222                 if(prev != e.sort_prev)
 223                         error(strcat("sort list chain error\nplease submit the output of 'prvm_edicts client' to the developers"));
 224         }
 225 }
 226
 227 float RegisterPlayer(entity player)
 228 {
 229         entity pl;
 230         AuditLists();
 231         for(pl = players.sort_next; pl; pl = pl.sort_next)
 232                 if(pl == player)
 233                         error("Player already registered!");
 234         player.sort_next = players.sort_next;
 235         player.sort_prev = players;
 236         if(players.sort_next)
 237                 players.sort_next.sort_prev = player;
 238         players.sort_next = player;
 239         AuditLists();
 240         return true;
 241 }
 242
 243 void RemovePlayer(entity player)
 244 {
 245         entity pl, parent;
 246         AuditLists();
 247         parent = players;
 248         for(pl = players.sort_next; pl && pl != player; pl = pl.sort_next)
 249                 parent = pl;
 250
 251         if(!pl)
 252         {
 253                 error("Trying to remove a player which is not in the playerlist!");
 254                 return;
 255         }
 256         parent.sort_next = player.sort_next;
 257         if(player.sort_next)
 258                 player.sort_next.sort_prev = parent;
 259         AuditLists();
 260 }
 261
 262 void MoveToLast(entity e)
 263 {
 264         AuditLists();
 265         entity ent = e.sort_next;
 266         while(ent)
 267         {
 268                 SORT_SWAP(ent, e);
 269                 ent = e.sort_next;
 270         }
 271         AuditLists();
 272 }
 273
 274 float RegisterTeam(entity Team)
 275 {
 276         assert_once(Team.team, eprint(Team));
 277         entity tm;
 278         AuditLists();
 279         for(tm = teams.sort_next; tm; tm = tm.sort_next)
 280                 if(tm == Team)
 281                         error("Team already registered!");
 282         Team.sort_next = teams.sort_next;
 283         Team.sort_prev = teams;
 284         if(teams.sort_next)
 285                 teams.sort_next.sort_prev = Team;
 286         teams.sort_next = Team;
 287         if(Team.team && Team.team != NUM_SPECTATOR)
 288                 ++team_count;
 289         AuditLists();
 290         return true;
 291 }
 292
 293 void RemoveTeam(entity Team)
 294 {
 295         entity tm, parent;
 296         AuditLists();
 297         parent = teams;
 298         for(tm = teams.sort_next; tm && tm != Team; tm = tm.sort_next)
 299                 parent = tm;
 300
 301         if(!tm)
 302         {
 303                 LOG_INFO(_("Trying to remove a team which is not in the teamlist!"));
 304                 return;
 305         }
 306         parent.sort_next = Team.sort_next;
 307         if(Team.sort_next)
 308                 Team.sort_next.sort_prev = parent;
 309         if(Team.team && Team.team != NUM_SPECTATOR)
 310                 --team_count;
 311         AuditLists();
 312 }
 313
 314 entity GetTeam(int Team, bool add)
 315 {
 316         TC(int, Team); TC(bool, add);
 317         int num = (Team == NUM_SPECTATOR) ? 16 : Team;
 318         if(teamslots[num])
 319                 return teamslots[num];
 320         if (!add)
 321                 return NULL;
 322         entity tm = new_pure(team);
 323         tm.team = Team;
 324         teamslots[num] = tm;
 325         RegisterTeam(tm);
 326         return tm;
 327 }
 328
 329 .float has_team;
 330 bool SetTeam(entity o, int Team)
 331 {
 332         TC(int, Team);
 333         //devassert_once(Team);
 334         entity tm;
 335         if(teamplay)
 336         {
 337                 switch(Team)
 338                 {
 339                         case -1:
 340                         case NUM_TEAM_1:
 341                         case NUM_TEAM_2:
 342                         case NUM_TEAM_3:
 343                         case NUM_TEAM_4:
 344                                 break;
 345                         default:
 346                                 if(GetTeam(Team, false) == NULL)
 347                                 {
 348                                         LOG_TRACEF("trying to switch to unsupported team %d", Team);
 349                                         Team = NUM_SPECTATOR;
 350                                 }
 351                                 break;
 352                 }
 353         }
 354         else
 355         {
 356                 switch(Team)
 357                 {
 358                         case -1:
 359                         case 0:
 360                                 break;
 361                         default:
 362                                 if(GetTeam(Team, false) == NULL)
 363                                 {
 364                                         LOG_TRACEF("trying to switch to unsupported team %d", Team);
 365                                         Team = NUM_SPECTATOR;
 366                                 }
 367                                 break;
 368                 }
 369         }
 370         if(Team == -1) // leave
 371         {
 372                 if(o.has_team)
 373                 {
 374                         tm = GetTeam(o.team, false);
 375                         tm.team_size -= 1;
 376                         o.has_team = 0;
 377                         return true;
 378                 }
 379         }
 380         else
 381         {
 382                 if (!o.has_team)
 383                 {
 384                         o.team = Team;
 385                         tm = GetTeam(Team, true);
 386                         tm.team_size += 1;
 387                         o.has_team = 1;
 388                         return true;
 389                 }
 390                 else if(Team != o.team)
 391                 {
 392                         tm = GetTeam(o.team, false);
 393                         tm.team_size -= 1;
 394                         o.team = Team;
 395                         tm = GetTeam(Team, true);
 396                         tm.team_size += 1;
 397                         return true;
 398                 }
 399         }
 400         return false;
 401 }
 402
 403 void Playerchecker_Think(entity this)
 404 {
 405         int i;
 406         entity e;
 407         for(i = 0; i < maxclients; ++i)
 408         {
 409                 e = playerslots[i];
 410                 if(entcs_GetName(i) == "")
 411                 {
 412                         if(e.sort_prev)
 413                         {
 414                                 // player disconnected
 415                                 SetTeam(e, -1);
 416                                 RemovePlayer(e);
 417                                 e.sort_prev = NULL;
 418                                 //e.gotscores = 0;
 419                         }
 420                 }
 421                 else
 422                 {
 423                         if (!e.sort_prev)
 424                         {
 425                                 // player connected
 426                                 if (!e)
 427                                 {
 428                                         playerslots[i] = e = new_pure(playerslot);
 429                                 }
 430                                 e.sv_entnum = i;
 431                                 e.ping = 0;
 432                                 e.ping_packetloss = 0;
 433                                 e.ping_movementloss = 0;
 434                                 //e.gotscores = 0; // we might already have the scores...
 435                                 int t = entcs_GetScoreTeam(i);
 436                                 if (t) SetTeam(e, t); // will not hurt; later updates come with Scoreboard_UpdatePlayerTeams
 437                                 RegisterPlayer(e);
 438                                 Scoreboard_UpdatePlayerPos(e);
 439                         }
 440                 }
 441         }
 442         this.nextthink = time + 0.2;
 443 }
 444
 445 void PostInit()
 446 {
 447         entity playerchecker = new_pure(playerchecker);
 448         setthink(playerchecker, Playerchecker_Think);
 449         playerchecker.nextthink = time + 0.2;
 450
 451         TrueAim_Init();
 452
 453         // this can't be called in CSQC_Init as it'd send cvars too early
 454         ReplicateVars_Start();
 455
 456         postinit = true;
 457 }
 458
 459 void Release_Common_Keys()
 460 {
 461         localcmd("-fire\n");
 462         localcmd("-fire2\n");
 463         localcmd("-use\n");
 464         localcmd("-hook\n");
 465         localcmd("-jump\n");
 466         localcmd("-forward\n");
 467         localcmd("-back\n");
 468         localcmd("-moveleft\n");
 469         localcmd("-moveright\n");
 470 }
 471
 472 // CSQC_InputEvent : Used to perform actions based on any key pressed, key released and mouse on the client.
 473 // Return value should be 1 if CSQC handled the input, otherwise return 0 to have the input passed to the engine.
 474 // All keys are in ascii.
 475 // bInputType = 0 is key pressed, 1 is key released, 2 and 3 are mouse input.
 476 // In the case of keyboard input, nPrimary is the ascii code, and nSecondary is 0.
 477 // In the case of mouse input, nPrimary is xdelta, nSecondary is ydelta.
 478 // In the case of mouse input after a setcursormode(1) call, nPrimary is xpos, nSecondary is ypos.
 479 float CSQC_InputEvent(int bInputType, float nPrimary, float nSecondary)
 480 {
 481         TC(int, bInputType);
 482         bool override = false;
 483
 484         override |= HUD_Scoreboard_InputEvent(bInputType, nPrimary, nSecondary);
 485         if (override)
 486                 return true;
 487
 488         override |= HUD_Panel_InputEvent(bInputType, nPrimary, nSecondary);
 489         if (override)
 490                 return true;
 491
 492         override |= HUD_Panel_Chat_InputEvent(bInputType, nPrimary, nSecondary);
 493
 494         override |= QuickMenu_InputEvent(bInputType, nPrimary, nSecondary);
 495
 496         override |= HUD_Radar_InputEvent(bInputType, nPrimary, nSecondary);
 497
 498         override |= MapVote_InputEvent(bInputType, nPrimary, nSecondary);
 499
 500         override |= HUD_Minigame_InputEvent(bInputType, nPrimary, nSecondary);
 501
 502         if(override)
 503                 return true;
 504
 505         if(bInputType == 3 || bInputType == 2)
 506                 return false;
 507
 508         // at this point bInputType can only be 0 or 1 (key pressed or released)
 509         bool key_pressed = (bInputType == 0);
 510
 511         if(key_pressed) {
 512                 if(nPrimary == K_ALT) hudShiftState |= S_ALT;
 513                 if(nPrimary == K_CTRL) hudShiftState |= S_CTRL;
 514                 if(nPrimary == K_SHIFT) hudShiftState |= S_SHIFT;
 515                 if(nPrimary == K_TAB) hudShiftState |= S_TAB;
 516         }
 517         else {
 518                 if(nPrimary == K_ALT) hudShiftState -= (hudShiftState & S_ALT);
 519                 if(nPrimary == K_CTRL) hudShiftState -= (hudShiftState & S_CTRL);
 520                 if(nPrimary == K_SHIFT) hudShiftState -= (hudShiftState & S_SHIFT);
 521                 if(nPrimary == K_TAB) hudShiftState -= (hudShiftState & S_TAB);
 522         }
 523
 524         // NOTE: Shift-Escape must be filtered out because it's the hardcoded console shortcut
 525         if (nPrimary == K_ESCAPE && !(hudShiftState & S_SHIFT) && key_pressed)
 526         {
 527                 if (hudShiftState & S_TAB)
 528                 {
 529                         Scoreboard_UI_Enable(0);
 530                         return true;
 531                 }
 532                 if (autocvar_menu_gamemenu && !isdemo() && cvar("_menu_gamemenu_dialog_available"))
 533                 {
 534                         localcmd("\nmenu_showgamemenudialog\n");
 535                         return true;
 536                 }
 537         }
 538
 539         return false;
 540 }
 541
 542 // END REQUIRED CSQC FUNCTIONS
 543 // --------------------------------------------------------------------------
 544
 545 // --------------------------------------------------------------------------
 546 // BEGIN OPTIONAL CSQC FUNCTIONS
 547 .int survival_status;
 548 void Ent_RemovePlayerScore(entity this)
 549 {
 550         if(this.owner) {
 551                 SetTeam(this.owner, -1);
 552                 this.owner.gotscores = 0;
 553                 FOREACH(Scores, true, {
 554                         this.owner.(scores(it)) = 0; // clear all scores
 555                 });
 556                 this.owner.ready = 0;
 557                 this.owner.eliminated = 0;
 558                 this.owner.colormap = 0;
 559                 // TODO add a hook to reset this Survival field
 560                 this.owner.survival_status = 0;
 561         }
 562 }
 563
 564 NET_HANDLE(ENT_CLIENT_SCORES, bool isnew)
 565 {
 566         make_pure(this);
 567         entity o;
 568
 569         // damnit -.- don't want to go change every single .sv_entnum in hud.qc AGAIN
 570         // (no I've never heard of M-x replace-string, sed, or anything like that)
 571         bool isNew = !this.owner; // workaround for DP bug
 572         int n = ReadByte()-1;
 573
 574 #ifdef DP_CSQC_ENTITY_REMOVE_IS_B0RKED
 575         if(!isNew && n != this.sv_entnum)
 576         {
 577                 //print("A CSQC entity changed its owner!\n");
 578                 LOG_INFOF("A CSQC entity changed its owner! (edict: %d, classname: %s)", etof(this), this.classname);
 579                 isNew = true;
 580                 Ent_Remove(this);
 581         }
 582 #endif
 583
 584         this.sv_entnum = n;
 585
 586         o = playerslots[this.sv_entnum];
 587         if (!o)
 588         {
 589                 o = playerslots[this.sv_entnum] = new_pure(playerslot);
 590         }
 591         this.owner = o;
 592         o.sv_entnum = this.sv_entnum;
 593         o.gotscores = 1;
 594
 595         //if (!o.sort_prev)
 596         //      RegisterPlayer(o);
 597         //playerchecker will do this for us later, if it has not already done so
 598
 599         int sf = ReadShort();
 600         int lf = ReadShort();
 601         FOREACH(Scores, true, {
 602                 int p = 1 << (i % 16);
 603                 if (sf & p)
 604                 {
 605                         if (lf & p)
 606                                 o.(scores(it)) = ReadInt24_t();
 607                         else
 608                                 o.(scores(it)) = ReadChar();
 609                 }
 610         });
 611
 612         return = true;
 613
 614         if(o.sort_prev)
 615                 Scoreboard_UpdatePlayerPos(o); // if not registered, we cannot do this yet!
 616
 617         this.entremove = Ent_RemovePlayerScore;
 618 }
 619
 620 NET_HANDLE(ENT_CLIENT_TEAMSCORES, bool isnew)
 621 {
 622         make_pure(this);
 623         int i;
 624
 625         this.team = ReadByte();
 626         entity o = this.owner = GetTeam(this.team, true); // these team numbers can always be trusted
 627
 628 #if MAX_TEAMSCORE <= 8
 629         int sf = ReadByte();
 630         int lf = ReadByte();
 631 #else
 632         int sf = ReadShort();
 633         int lf = ReadShort();
 634 #endif
 635         for(i = 0; i < MAX_TEAMSCORE; ++i)
 636                 if(sf & BIT(i))
 637                 {
 638                         if(lf & BIT(i))
 639                                 o.(teamscores(i)) = ReadInt24_t();
 640                         else
 641                                 o.(teamscores(i)) = ReadChar();
 642                 }
 643
 644         return = true;
 645
 646         Scoreboard_UpdateTeamPos(o);
 647 }
 648
 649 NET_HANDLE(ENT_CLIENT_CLIENTDATA, bool isnew)
 650 {
 651         make_pure(this);
 652         float newspectatee_status;
 653
 654         int f = ReadByte();
 655
 656         scoreboard_showscores_force = (f & BIT(0));
 657
 658         if(f & BIT(1))
 659         {
 660                 newspectatee_status = ReadByte();
 661                 if(newspectatee_status == player_localnum + 1)
 662                         newspectatee_status = -1; // observing
 663         }
 664         else
 665                 newspectatee_status = 0;
 666
 667         spectatorbutton_zoom = (f & BIT(2));
 668         observe_blocked = (f & BIT(3));
 669
 670         if(f & BIT(4))
 671         {
 672                 num_spectators = ReadByte();
 673
 674                 float i, slot;
 675
 676                 for(i = 0; i < MAX_SPECTATORS; ++i)
 677                         spectatorlist[i] = 0; // reset list first
 678
 679                 int limit = min(num_spectators, MAX_SPECTATORS);
 680                 for(i = 0; i < limit; ++i)
 681                 {
 682                         slot = ReadByte();
 683                         spectatorlist[i] = slot - 1;
 684                 }
 685         }
 686         else
 687         {
 688                 for(int j = 0; j < MAX_SPECTATORS; ++j)
 689                         spectatorlist[j] = 0; // reset list if showspectators has been turned off
 690                 num_spectators = 0;
 691         }
 692
 693         return = true;
 694
 695         if(newspectatee_status != spectatee_status)
 696         {
 697                 // clear race stuff
 698                 race_laptime = 0;
 699                 race_checkpointtime = 0;
 700                 hud_dynamic_shake_factor = -1;
 701                 spectatee_status_changed_time = time;
 702         }
 703         if (autocvar_hud_panel_healtharmor_progressbar_gfx)
 704         {
 705                 if ( (spectatee_status == -1 && newspectatee_status > 0) //before observing, now spectating
 706                   || (spectatee_status > 0 && newspectatee_status > 0 && spectatee_status != newspectatee_status) //changed spectated player
 707                 )
 708                         prev_p_health = -1;
 709                 else if(spectatee_status && !newspectatee_status) //before observing/spectating, now playing
 710                         prev_health = -1;
 711         }
 712         spectatee_status = newspectatee_status;
 713
 714         // we could get rid of spectatee_status, and derive it from player_localentnum and player_localnum
 715 }
 716
 717 NET_HANDLE(ENT_CLIENT_NAGGER, bool isnew)
 718 {
 719         make_pure(this);
 720
 721         int nags = ReadByte(); // NAGS NAGS NAGS NAGS NAGS NAGS NADZ NAGS NAGS NAGS
 722
 723         if(!(nags & BIT(2)))
 724         {
 725                 strfree(vote_called_vote);
 726                 vote_active = 0;
 727         }
 728         else
 729         {
 730                 vote_active = 1;
 731         }
 732
 733         if(nags & BIT(6))
 734         {
 735                 vote_yescount = ReadByte();
 736                 vote_nocount = ReadByte();
 737                 vote_needed = ReadByte();
 738                 vote_highlighted = ReadChar();
 739         }
 740
 741         if(nags & BIT(7))
 742         {
 743                 strcpy(vote_called_vote, ReadString());
 744         }
 745
 746         if(nags & BIT(0))
 747                 for(int i = 0; i < maxclients;)
 748                         for(int f = ReadByte(), b = 0; b < 8 && i < maxclients; ++b, ++i)
 749                                 if(playerslots[i])
 750                                         playerslots[i].ready = f & BIT(b);
 751
 752         return = true;
 753
 754         ready_waiting = (nags & BIT(0));
 755         ready_waiting_for_me = (nags & BIT(1));
 756         vote_waiting = (nags & BIT(2));
 757         vote_waiting_for_me = (nags & BIT(3));
 758         warmup_stage = (nags & BIT(4));
 759 }
 760
 761 NET_HANDLE(ENT_CLIENT_ELIMINATEDPLAYERS, bool isnew)
 762 {
 763         make_pure(this);
 764         int sf = 0;
 765         serialize(byte, 0, sf);
 766         if (sf & 1) {
 767                 for (int j = 0; j < maxclients; ++j) {
 768                         if (playerslots[j]) {
 769                                 playerslots[j].eliminated = true;
 770                         }
 771                 }
 772                 for (int i = 1; i <= maxclients; i += 8) {
 773                         int f = 0;
 774                         serialize(byte, 0, f);
 775                         for (int b = 0; b < 8; ++b) {
 776                                 if (f & BIT(b)) continue;
 777                                 int j = i - 1 + b;
 778                                 if (playerslots[j]) {
 779                                         playerslots[j].eliminated = false;
 780                                 }
 781                         }
 782                 }
 783         }
 784         return true;
 785 }
 786
 787 NET_HANDLE(ENT_CLIENT_RANDOMSEED, bool isnew)
 788 {
 789         make_pure(this);
 790         prandom_debug();
 791         float s = ReadShort();
 792         psrandom(s);
 793         return true;
 794 }
 795
 796 NET_HANDLE(ENT_CLIENT_ACCURACY, bool isnew)
 797 {
 798         make_pure(this);
 799         int sf = ReadInt24_t();
 800         if (sf == 0) {
 801                 for (int w = 0; w <= WEP_LAST - WEP_FIRST; ++w)
 802                         weapon_accuracy[w] = -1;
 803                 return true;
 804         }
 805
 806         int f = 1;
 807         for (int w = 0; w <= WEP_LAST - WEP_FIRST; ++w) {
 808                 if (sf & f) {
 809                         int b = ReadByte();
 810                         if (b == 0)
 811                                 weapon_accuracy[w] = -1;
 812                         else if (b == 255)
 813                                 weapon_accuracy[w] = 1.0; // no better error handling yet, sorry
 814                         else
 815                                 weapon_accuracy[w] = (b - 1.0) / 100.0;
 816                 }
 817                 f = (f == 0x800000) ? 1 : f * 2;
 818         }
 819         return true;
 820 }
 821
 822 void Spawn_Draw(entity this)
 823 {
 824         bool dodraw = autocvar_cl_spawn_point_particles;
 825         if(dodraw && autocvar_cl_spawn_point_dist_max)
 826         {
 827                 vector org = getpropertyvec(VF_ORIGIN);
 828                 dodraw = vdist(org - this.origin, <, autocvar_cl_spawn_point_dist_max);
 829         }
 830
 831         if(dodraw)
 832                 pointparticles(((!teamplay) ? EFFECT_SPAWNPOINT_NEUTRAL : EFFECT_SPAWNPOINT(this.team - 1)), this.origin + '0 0 28', '0 0 2', bound(0, frametime, 0.1));
 833 }
 834
 835 NET_HANDLE(ENT_CLIENT_SPAWNPOINT, bool is_new)
 836 {
 837         float teamnum = (ReadByte() - 1);
 838         vector spn_origin = ReadVector();
 839
 840         this.team = (teamnum + 1);
 841
 842         //if(is_new)
 843         //{
 844                 this.origin = spn_origin;
 845                 setsize(this, PL_MIN_CONST, PL_MAX_CONST);
 846                 //droptofloor();
 847
 848                 /*if(autocvar_cl_spawn_point_model) // needs a model first
 849                 {
 850                         this.mdl = "models/spawnpoint.md3";
 851                         this.colormod = Team_ColorRGB(teamnum);
 852                         precache_model(this.mdl);
 853                         setmodel(this, this.mdl);
 854                         this.drawmask = MASK_NORMAL;
 855                         //this.move_movetype = MOVETYPE_NOCLIP;
 856                         //this.draw = Spawn_Draw;
 857                         IL_PUSH(g_drawables, this);
 858                 }*/
 859                 this.draw = Spawn_Draw;
 860                 if (is_new) IL_PUSH(g_drawables, this);
 861         //}
 862
 863         //printf("Ent_ReadSpawnPoint(is_new = %d); origin = %s, team = %d, effect = %d\n", is_new, vtos(this.origin), teamnum, this.cnt);
 864         return true;
 865 }
 866
 867 NET_HANDLE(ENT_CLIENT_SPAWNEVENT, bool is_new)
 868 {
 869         // If entnum is 0, ONLY do the local spawn actions
 870         // this way the server can disable the sending of
 871         // spawn origin or such to clients if wanted.
 872         float entnum = ReadByte();
 873
 874         if(entnum)
 875         {
 876                 this.origin = ReadVector();
 877
 878                 if(is_new)
 879                 {
 880                         float teamnum = entcs_GetTeam(entnum - 1);
 881
 882                         if(autocvar_cl_spawn_event_particles)
 883                         {
 884                                 switch(teamnum)
 885                                 {
 886                                         case NUM_TEAM_1: pointparticles(EFFECT_SPAWN_RED, this.origin, '0 0 0', 1); break;
 887                                         case NUM_TEAM_2: pointparticles(EFFECT_SPAWN_BLUE, this.origin, '0 0 0', 1); break;
 888                                         case NUM_TEAM_3: pointparticles(EFFECT_SPAWN_YELLOW, this.origin, '0 0 0', 1); break;
 889                                         case NUM_TEAM_4: pointparticles(EFFECT_SPAWN_PINK, this.origin, '0 0 0', 1); break;
 890                                         default: pointparticles(EFFECT_SPAWN_NEUTRAL, this.origin, '0 0 0', 1); break;
 891                                 }
 892                         }
 893                         if(autocvar_cl_spawn_event_sound)
 894                         {
 895                                 sound(this, CH_TRIGGER, SND_SPAWN, VOL_BASE, ATTEN_NORM);
 896                         }
 897                 }
 898         }
 899         return = true;
 900
 901         // local spawn actions
 902         if(is_new && (!entnum || (entnum == player_localentnum)))
 903         {
 904                 if(autocvar_cl_spawnzoom && !autocvar_cl_lockview)
 905                 {
 906                         zoomin_effect = 1;
 907                         current_viewzoom = (1 / bound(1, autocvar_cl_spawnzoom_factor, 16));
 908                 }
 909
 910                 if(autocvar_cl_unpress_zoom_on_spawn)
 911                 {
 912                         localcmd("-zoom\n");
 913                         button_zoom = false;
 914                 }
 915                 HUD_Radar_Hide_Maximized();
 916         }
 917         //printf("Ent_ReadSpawnEvent(is_new = %d); origin = %s, entnum = %d, localentnum = %d\n", is_new, vtos(this.origin), entnum, player_localentnum);
 918 }
 919
 920 // CSQC_Ent_Update : Called every frame that the server has indicated an update to the SSQC / CSQC entity has occured.
 921 // The parameter isnew reflects if the entity is "new" to the client, meaning it just came into the client's PVS.
 922 void CSQC_Ent_Update(entity this, bool isnew)
 923 {
 924         this.sourceLoc = __FILE__":"STR(__LINE__);
 925         int t = ReadByte();
 926
 927         // set up the "time" global for received entities to be correct for interpolation purposes
 928         float savetime = time;
 929         if(servertime)
 930         {
 931                 time = servertime;
 932         }
 933         else
 934         {
 935                 serverprevtime = time;
 936                 serverdeltatime = STAT(MOVEVARS_TICRATE) * STAT(MOVEVARS_TIMESCALE);
 937                 time = serverprevtime + serverdeltatime;
 938         }
 939
 940 #ifdef DP_CSQC_ENTITY_REMOVE_IS_B0RKED
 941         if (this.enttype)
 942         {
 943                 if (t != this.enttype || isnew)
 944                 {
 945                         LOG_INFOF("A CSQC entity changed its type! (edict: %d, server: %d, type: %d -> %d)", etof(this), this.entnum, this.enttype, t);
 946                         Ent_Remove(this);
 947                         ONREMOVE(this);
 948                         clearentity(this);
 949                         isnew = true;
 950                 }
 951         }
 952         else
 953         {
 954                 if (!isnew)
 955                 {
 956                         LOG_INFOF("A CSQC entity appeared out of nowhere! (edict: %d, server: %d, type: %d)", etof(this), this.entnum, t);
 957                         isnew = true;
 958                 }
 959         }
 960 #endif
 961         this.enttype = t;
 962         bool done = false;
 963         FOREACH(LinkedEntities, it.m_id == t, {
 964                 if (isnew) this.classname = it.netname;
 965                 if (autocvar_developer_csqcentities)
 966                         LOG_INFOF("CSQC_Ent_Update(%i, %d) at %f {.entnum=%d, .enttype=%d} t=%s (%d)", this, isnew, savetime, this.entnum, this.enttype, this.classname, t);
 967                 done = it.m_read(this, NULL, isnew);
 968                 MUTATOR_CALLHOOK(Ent_Update, this, isnew);
 969                 break;
 970         });
 971         time = savetime;
 972         if (!done)
 973         {
 974                 LOG_FATALF("CSQC_Ent_Update(%i, %d) at %f {.entnum=%d, .enttype=%d} t=%s (%d)", this, isnew, savetime, this.entnum, this.enttype, this.classname, t);
 975         }
 976 }
 977
 978 // Destructor, but does NOT deallocate the entity by calling remove(). Also
 979 // used when an entity changes its type. For an entity that someone interacts
 980 // with others, make sure it can no longer do so.
 981 void Ent_Remove(entity this)
 982 {
 983         if(this.entremove) this.entremove(this);
 984
 985         if(this.skeletonindex)
 986         {
 987                 skel_delete(this.skeletonindex);
 988                 this.skeletonindex = 0;
 989         }
 990
 991         if(this.snd_looping > 0)
 992         {
 993                 sound(this, this.snd_looping, SND_Null, VOL_BASE, autocvar_cl_jetpack_attenuation);
 994                 this.snd_looping = 0;
 995         }
 996
 997         this.enttype = 0;
 998         this.classname = "";
 999         this.draw = func_null;
1000         this.entremove = func_null;
1001         // TODO possibly set more stuff to defaults
1002 }
1003 // CSQC_Ent_Remove : Called when the server requests a SSQC / CSQC entity to be removed.  Essentially call remove(this) as well.
1004 void CSQC_Ent_Remove(entity this)
1005 {
1006         if (autocvar_developer_csqcentities) LOG_INFOF("CSQC_Ent_Remove() with this=%i {.entnum=%d, .enttype=%d}", this, this.entnum, this.enttype);
1007         if (wasfreed(this))
1008         {
1009                 LOG_WARN("CSQC_Ent_Remove called for already removed entity. Packet loss?");
1010                 return;
1011         }
1012         if (this.enttype) Ent_Remove(this);
1013         delete(this);
1014 }
1015
1016 void Gamemode_Init()
1017 {
1018         if (!isdemo())
1019         {
1020                 if(!(calledhooks & HOOK_START))
1021                         localcmd("\n_cl_hook_gamestart ", MapInfo_Type_ToString(gametype), "\n");
1022                 calledhooks |= HOOK_START;
1023         }
1024 }
1025 // CSQC_Parse_StuffCmd : Provides the stuffcmd string in the first parameter that the server provided.  To execute standard behavior, simply execute localcmd with the string.
1026 void CSQC_Parse_StuffCmd(string strMessage)
1027 {
1028         if (autocvar_developer_csqcentities) LOG_INFOF("CSQC_Parse_StuffCmd(\"%s\")", strMessage);
1029         localcmd(strMessage);
1030 }
1031 // CSQC_Parse_Print : Provides the print string in the first parameter that the server provided.  To execute standard behavior, simply execute print with the string.
1032 void CSQC_Parse_Print(string strMessage)
1033 {
1034         if (autocvar_developer_csqcentities) LOG_INFOF("CSQC_Parse_Print(\"%s\")", strMessage);
1035         print(ColorTranslateRGB(strMessage));
1036 }
1037
1038 // CSQC_Parse_CenterPrint : Provides the centerprint_AddStandard string in the first parameter that the server provided.
1039 void CSQC_Parse_CenterPrint(string strMessage)
1040 {
1041         if (autocvar_developer_csqcentities) LOG_INFOF("CSQC_Parse_CenterPrint(\"%s\")", strMessage);
1042         centerprint_AddStandard(strMessage);
1043 }
1044
1045 // CSQC_Parse_TempEntity : Handles all temporary entity network data in the CSQC layer.
1046 // You must ALWAYS first acquire the temporary ID, which is sent as a byte.
1047 // Return value should be 1 if CSQC handled the temporary entity, otherwise return 0 to have the engine process the event.
1048 bool CSQC_Parse_TempEntity()
1049 {
1050         // Acquire TE ID
1051         int nTEID = ReadByte();
1052
1053         FOREACH(TempEntities, it.m_id == nTEID, {
1054                 if (autocvar_developer_csqcentities)
1055                         LOG_INFOF("CSQC_Parse_TempEntity() nTEID=%s (%d)", it.netname, nTEID);
1056                 return it.m_read(NULL, NULL, true);
1057         });
1058
1059         if (autocvar_developer_csqcentities)
1060                 LOG_INFOF("CSQC_Parse_TempEntity() with nTEID=%d", nTEID);
1061
1062         // No special logic for this temporary entity; return 0 so the engine can handle it
1063         return false;
1064 }
1065
1066 bool autocvar_r_drawfog;
1067 bool autocvar_r_fog_exp2;
1068 string forcefog;
1069 void Fog_Force()
1070 {
1071         if (autocvar_cl_orthoview && autocvar_cl_orthoview_nofog)
1072         {
1073                 if (autocvar_r_drawfog)
1074                         cvar_set("r_drawfog", "0");
1075         }
1076         else if (forcefog != "")
1077         {
1078                 // using cvar_set as it's faster and safer than a command
1079                 if (!autocvar_r_drawfog)
1080                         cvar_set("r_drawfog", "1");
1081                 if (autocvar_r_fog_exp2)
1082                         cvar_set("r_fog_exp2", "0");
1083                 localcmd(sprintf("\nfog %s\n", forcefog));
1084         }
1085 }
1086
1087 bool net_handle_ServerWelcome();
1088 NET_HANDLE(ENT_CLIENT_SCORES_INFO, bool isnew)
1089 {
1090         make_pure(this);
1091         gametype = ReadRegistered(Gametypes);
1092         teamplay = _MapInfo_GetTeamPlayBool(gametype);
1093         HUD_ModIcons_SetFunc();
1094         FOREACH(Scores, true, {
1095                 strcpy(scores_label(it), ReadString());
1096                 scores_flags(it) = ReadByte();
1097         });
1098         for (int i = 0; i < MAX_TEAMSCORE; ++i)
1099         {
1100                 strcpy(teamscores_label(i), ReadString());
1101                 teamscores_flags(i) = ReadByte();
1102         }
1103         bool welcome_msg_too = ReadByte();
1104         if (welcome_msg_too)
1105                 net_handle_ServerWelcome();
1106         return = true;
1107         Scoreboard_InitScores();
1108         Gamemode_Init();
1109 }
1110
1111 NET_HANDLE(ENT_CLIENT_INIT, bool isnew)
1112 {
1113         nb_pb_period = ReadByte() / 32; //Accuracy of 1/32th
1114
1115         hook_shotorigin[0] = decompressShotOrigin(ReadInt24_t());
1116         hook_shotorigin[1] = decompressShotOrigin(ReadInt24_t());
1117         hook_shotorigin[2] = decompressShotOrigin(ReadInt24_t());
1118         hook_shotorigin[3] = decompressShotOrigin(ReadInt24_t());
1119         arc_shotorigin[0] = decompressShotOrigin(ReadInt24_t());
1120         arc_shotorigin[1] = decompressShotOrigin(ReadInt24_t());
1121         arc_shotorigin[2] = decompressShotOrigin(ReadInt24_t());
1122         arc_shotorigin[3] = decompressShotOrigin(ReadInt24_t());
1123
1124         strcpy(forcefog, ReadString());
1125
1126         armorblockpercent = ReadByte() / 255.0;
1127         damagepush_speedfactor = ReadByte() / 255.0;
1128
1129         serverflags = ReadByte();
1130
1131         g_trueaim_minrange = ReadCoord();
1132
1133         return = true;
1134
1135         MUTATOR_CALLHOOK(Ent_Init);
1136
1137         if (!postinit) PostInit();
1138 }
1139
1140 float GetSpeedUnitFactor(int speed_unit)
1141 {
1142         switch(speed_unit)
1143         {
1144                 default:
1145                 case 1: return 1.0;
1146                 case 2: return 0.0254;
1147                 case 3: return 0.0254 * 3.6;
1148                 case 4: return 0.0254 * 3.6 * 0.6213711922;
1149                 case 5: return 0.0254 * 1.943844492; // 1 m/s = 1.943844492 knots, because 1 knot = 1.852 km/h
1150         }
1151 }
1152
1153 string GetSpeedUnit(int speed_unit)
1154 {
1155         switch(speed_unit)
1156         {
1157                 // translator-friendly strings without the initial space
1158                 default:
1159                 case 1: return strcat(" ", _("qu/s"));
1160                 case 2: return strcat(" ", _("m/s"));
1161                 case 3: return strcat(" ", _("km/h"));
1162                 case 4: return strcat(" ", _("mph"));
1163                 case 5: return strcat(" ", _("knots"));
1164         }
1165 }
1166
1167 NET_HANDLE(TE_CSQC_RACE, bool isNew)
1168 {
1169         int b = ReadByte();
1170
1171         switch (b)
1172         {
1173                 case RACE_NET_CHECKPOINT_HIT_QUALIFYING:
1174                         race_checkpoint = ReadByte();
1175                         race_time = ReadInt24_t();
1176                         race_previousbesttime = ReadInt24_t();
1177                         race_mypreviousbesttime = ReadInt24_t();
1178                         string pbestname = ReadString();
1179                         if(autocvar_cl_race_cptimes_onlyself)
1180                         {
1181                                 race_previousbesttime = race_mypreviousbesttime;
1182                                 race_mypreviousbesttime = 0;
1183                                 strcpy(race_previousbestname, "");
1184                         }
1185                         else
1186                                 strcpy(race_previousbestname, pbestname);
1187
1188                         race_checkpointtime = time;
1189
1190                         if(race_checkpoint == 0 || race_checkpoint == 254)
1191                         {
1192                                 race_penaltyaccumulator = 0;
1193                                 race_laptime = time; // valid
1194                         }
1195                         break;
1196
1197                 case RACE_NET_CHECKPOINT_CLEAR:
1198                         race_laptime = 0;
1199                         race_checkpointtime = 0;
1200                         break;
1201
1202                 case RACE_NET_CHECKPOINT_NEXT_SPEC_QUALIFYING:
1203                         race_laptime = ReadCoord();
1204                         race_checkpointtime = -99999;
1205                         // fall through
1206                 case RACE_NET_CHECKPOINT_NEXT_QUALIFYING:
1207                         race_nextcheckpoint = ReadByte();
1208
1209                         race_nextbesttime = ReadInt24_t();
1210                         if(b != RACE_NET_CHECKPOINT_NEXT_SPEC_QUALIFYING) // not while spectating (matches server)
1211                                 race_mybesttime = ReadInt24_t();
1212                         string newname = ReadString();
1213                         if(autocvar_cl_race_cptimes_onlyself && b != RACE_NET_CHECKPOINT_NEXT_SPEC_QUALIFYING)
1214                         {
1215                                 race_nextbesttime = race_mybesttime;
1216                                 race_mybesttime = 0;
1217                                 strcpy(race_nextbestname, "");
1218                         }
1219                         else
1220                                 strcpy(race_nextbestname, newname);
1221                         break;
1222
1223                 case RACE_NET_CHECKPOINT_HIT_RACE:
1224                         race_mycheckpoint = ReadByte();
1225                         race_mycheckpointtime = time;
1226                         race_mycheckpointdelta = ReadInt24_t();
1227                         race_mycheckpointlapsdelta = ReadByte();
1228                         if(race_mycheckpointlapsdelta >= 128)
1229                                 race_mycheckpointlapsdelta -= 256;
1230                         int who = ReadByte();
1231                         if(who)
1232                                 strcpy(race_mycheckpointenemy, entcs_GetName(who - 1));
1233                         else
1234                                 strcpy(race_mycheckpointenemy, ""); // TODO: maybe string_null works fine here?
1235                         break;
1236
1237                 case RACE_NET_CHECKPOINT_HIT_RACE_BY_OPPONENT:
1238                         race_othercheckpoint = ReadByte();
1239                         race_othercheckpointtime = time;
1240                         race_othercheckpointdelta = ReadInt24_t();
1241                         race_othercheckpointlapsdelta = ReadByte();
1242                         if(race_othercheckpointlapsdelta >= 128)
1243                                 race_othercheckpointlapsdelta -= 256;
1244                         int what = ReadByte();
1245                         if(what)
1246                                 strcpy(race_othercheckpointenemy, entcs_GetName(what - 1));
1247                         else
1248                                 strcpy(race_othercheckpointenemy, ""); // TODO: maybe string_null works fine here?
1249                         break;
1250
1251                 case RACE_NET_PENALTY_RACE:
1252                 case RACE_NET_PENALTY_QUALIFYING:
1253                         race_penaltyeventtime = time;
1254                         race_penaltytime = ReadShort();
1255                         string reason = ReadString();
1256                         if (reason == "missing a checkpoint")
1257                                 reason = _("missing a checkpoint");
1258                         strcpy(race_penaltyreason, reason);
1259                         if (b == RACE_NET_PENALTY_QUALIFYING)
1260                                 race_penaltyaccumulator += race_penaltytime;
1261                         break;
1262
1263                 case RACE_NET_SERVER_RECORD:
1264                         race_server_record = ReadInt24_t();
1265                         break;
1266                 case RACE_NET_SPEED_AWARD:
1267                         race_speedaward = ReadInt24_t();
1268                         strcpy(race_speedaward_holder, ReadString());
1269                         break;
1270                 case RACE_NET_SPEED_AWARD_BEST:
1271                         race_speedaward_alltimebest = ReadInt24_t();
1272                         strcpy(race_speedaward_alltimebest_holder, ReadString());
1273                         break;
1274                 case RACE_NET_RANKINGS_CNT:
1275                         RANKINGS_DISPLAY_CNT = ReadByte();
1276                         break;
1277                 case RACE_NET_SERVER_RANKINGS:
1278                         float prevpos, del;
1279                         int pos = ReadShort();
1280                         prevpos = ReadShort();
1281                         del = ReadShort();
1282
1283                         // move other rankings out of the way
1284                         int i;
1285                         if (prevpos) {
1286                                 int m = min(prevpos, RANKINGS_DISPLAY_CNT);
1287                                 for (i=m-1; i>pos-1; --i) {
1288                                         grecordtime[i] = grecordtime[i-1];
1289                                         strcpy(grecordholder[i], grecordholder[i-1]);
1290                                 }
1291                         } else if (del) { // a record has been deleted by the admin
1292                                 for (i=pos-1; i<= RANKINGS_DISPLAY_CNT-1; ++i) {
1293                                         if (i == RANKINGS_DISPLAY_CNT-1) { // clear out last record
1294                                                 grecordtime[i] = 0;
1295                                                 strfree(grecordholder[i]);
1296                                         }
1297                                         else {
1298                                                 grecordtime[i] = grecordtime[i+1];
1299                                                 strcpy(grecordholder[i], grecordholder[i+1]);
1300                                         }
1301                                 }
1302                         } else { // player has no ranked record yet
1303                                 for (i=RANKINGS_DISPLAY_CNT-1;i>pos-1;--i) {
1304                                         grecordtime[i] = grecordtime[i-1];
1305                                         strcpy(grecordholder[i], grecordholder[i-1]);
1306                                 }
1307                         }
1308
1309                         if (grecordtime[RANKINGS_DISPLAY_CNT]) {
1310                                 // kick off the player who fell from the last displayed position
1311                                 grecordtime[RANKINGS_DISPLAY_CNT] = 0;
1312                                 strfree(grecordholder[RANKINGS_DISPLAY_CNT]);
1313                         }
1314
1315                         // store new ranking
1316                         strcpy(grecordholder[pos-1], ReadString());
1317                         grecordtime[pos-1] = ReadInt24_t();
1318                         if(strdecolorize(grecordholder[pos-1]) == strdecolorize(entcs_GetName(player_localnum)))
1319                                 race_myrank = pos;
1320                         break;
1321                 case RACE_NET_SERVER_STATUS:
1322                         race_status = ReadShort();
1323                         strcpy(race_status_name, ReadString());
1324         }
1325         return true;
1326 }
1327
1328 NET_HANDLE(TE_CSQC_TEAMNAGGER, bool isNew)
1329 {
1330         teamnagger = 1;
1331         return true;
1332 }
1333
1334 NET_HANDLE(TE_CSQC_PINGPLREPORT, bool isNew)
1335 {
1336         int i = ReadByte();
1337         int pi = ReadShort();
1338         int pl = ReadByte();
1339         int ml = ReadByte();
1340         return = true;
1341         entity e = playerslots[i];
1342         if (!e) return;
1343         e.ping = pi;
1344         e.ping_packetloss = pl / 255.0;
1345         e.ping_movementloss = ml / 255.0;
1346 }
1347
1348 NET_HANDLE(TE_CSQC_WEAPONCOMPLAIN, bool isNew)
1349 {
1350         int weapon_id = ReadByte();
1351         complain_weapon = REGISTRY_GET(Weapons, weapon_id);
1352         complain_weapon_type = ReadByte();
1353         return = true;
1354
1355         complain_weapon_time = time;
1356         weapontime = time; // ping the weapon panel
1357
1358         switch(complain_weapon_type)
1359         {
1360                 case 0: Local_Notification(MSG_MULTI, ITEM_WEAPON_NOAMMO, weapon_id); break;
1361                 case 1: Local_Notification(MSG_MULTI, ITEM_WEAPON_DONTHAVE, weapon_id); break;
1362                 default: Local_Notification(MSG_MULTI, ITEM_WEAPON_UNAVAILABLE, weapon_id); break;
1363         }
1364 }
1365
1366 string translate_modifications(string s)
1367 {
1368         return build_mutator_list(s);
1369 }
1370
1371 string translate_weaponarena(string s)
1372 {
1373         if (s == "") return s;
1374         if (s == "All Weapons Arena") return _("All Weapons Arena");
1375         if (s == "All Available Weapons Arena") return _("All Available Weapons Arena");
1376         if (s == "Most Weapons Arena") return _("Most Weapons Arena");
1377         if (s == "Most Available Weapons Arena") return _("Most Available Weapons Arena");
1378         if (s == "Dev All Weapons Arena") return s; // development option, do not translate
1379         if (s == "Dev All Available Weapons Arena") return s; // development option, do not translate
1380         if (s == "No Weapons Arena") return _("No Weapons Arena");
1381
1382         int n = tokenizebyseparator(s, " & ");
1383         string wpn_list = "";
1384         for (int i = 0; i < n; i++)
1385         {
1386                 Weapon wep = Weapon_from_name(argv(i));
1387                 if (wep == WEP_Null)
1388                         LOG_INFO("^3Warning: ^7server sent an invalid weapon name\n");
1389                 wpn_list = cons_mid(wpn_list, " & ", wep.m_name);
1390         }
1391         if (wpn_list != "")
1392                 return sprintf(_("%s Arena"), wpn_list);
1393         else
1394                 return _("No Weapons Arena");
1395 }
1396
1397 string GetVersionMessage(string hostversion, bool version_mismatch, bool version_check)
1398 {
1399         string xonotic_hostversion = strcat("Xonotic ", hostversion);
1400         if (version_mismatch)
1401         {
1402                 if(!version_check)
1403                         return strcat(sprintf(_("This is %s"), xonotic_hostversion), "\n^3",
1404                                 _("Your client version is outdated."), "\n\n\n",
1405                                 _("### YOU WON'T BE ABLE TO PLAY ON THIS SERVER ###"), "\n\n\n",
1406                                 _("Please update!"));
1407                 else
1408                         return strcat(sprintf(_("This is %s"), xonotic_hostversion), "\n^3",
1409                                 _("This server is using an outdated Xonotic version."), "\n\n\n",
1410                                 _("### THIS SERVER IS INCOMPATIBLE AND THUS YOU CANNOT JOIN ###"));
1411         }
1412         return sprintf(_("Welcome to %s"), xonotic_hostversion);
1413 }
1414
1415 bool net_handle_ServerWelcome()
1416 {
1417         campaign = ReadByte();
1418         if (campaign)
1419         {
1420                 int campaign_level = ReadByte();
1421                 // Menu can't build the whole campaign message because it lacks getcommandkey and CCR
1422                 // so we build part of the message here and let the menu insert the level description
1423                 // (that client doesn't know) by replacing the keyword _LEVEL_DESC
1424                 string key = getcommandkey(_("jump"), "+jump");
1425                 string msg = strcat(
1426                         CCR("^F1"), sprintf(_("Level %d:"), campaign_level),
1427                         sprintf(CCR(" ^BG%s\n\n"), "_LEVEL_DESC"),
1428                         sprintf(CCR(_("^BGPress ^F2%s^BG to enter the game")), key));
1429                 msg = MakeConsoleSafe(strreplace("\n", "\\n", msg));
1430                 string welcomedialog_args = strcat("CAMPAIGN ", itos(campaign_level), " \"", msg, "\"");
1431
1432                 localcmd("\nmenu_cmd directmenu Welcome ", welcomedialog_args, "\n");
1433                 return true;
1434         }
1435
1436         strcpy(hostname, ReadString());
1437         string hostversion = ReadString();
1438         bool version_mismatch = ReadByte();
1439         bool version_check = ReadByte();
1440         srv_minplayers = ReadByte();
1441         srv_maxplayers = ReadByte();
1442         string modifications = translate_modifications(ReadString());
1443         string weaponarena_list = translate_weaponarena(ReadString());
1444         string cache_mutatormsg = ReadString();
1445         string motd = ReadString();
1446
1447         string msg = GetVersionMessage(hostversion, version_mismatch, version_check);
1448
1449         msg = strcat(msg, "\n\n", _("Gametype:"), " ^1", MapInfo_Type_ToText(gametype), "\n");
1450
1451         msg = strcat(msg, "\n", _("Map:"), " ^2");
1452         if (world.message == "")
1453                 msg = strcat(msg, mi_shortname, "\n");
1454         else
1455         {
1456                 int i = strstrofs(world.message, " by ", 0); // matches _MapInfo_Generate()
1457                 string longname = i >= 0 ? substring(world.message, 0, i) : world.message;
1458                 msg = strcat(msg, (strcasecmp(longname, mi_shortname) ? strcat(mi_shortname, " ^7// ^2") : ""), longname, "\n");
1459         }
1460
1461         if (srv_minplayers || srv_maxplayers)
1462         {
1463                 msg = strcat(msg, "\n", _("This match supports"), " ^5");
1464                 if (srv_minplayers == srv_maxplayers)
1465                         msg = strcat(msg, sprintf(_("%d players"), srv_maxplayers), "\n");
1466                 else if (srv_minplayers && srv_maxplayers)
1467                         msg = strcat(msg, sprintf(_("%d to %d players"), srv_minplayers, srv_maxplayers), "\n");
1468                 else if (srv_maxplayers)
1469                         msg = strcat(msg, sprintf(_("%d players maximum"), srv_maxplayers), "\n");
1470                 else
1471                         msg = strcat(msg, sprintf(_("%d players minimum"), srv_minplayers), "\n");
1472         }
1473
1474         modifications = cons_mid(modifications, ", ", weaponarena_list);
1475         if(modifications != "")
1476                 msg = strcat(msg, "\n", _("Active modifications:"), " ^3", modifications, "\n");
1477
1478         if (cache_mutatormsg != "")
1479                 msg = strcat(msg, "\n", _("Special gameplay tips:"), " ^7", cache_mutatormsg, "\n");
1480         string mutator_msg = "";
1481         MUTATOR_CALLHOOK(BuildGameplayTipsString, mutator_msg);
1482         mutator_msg = M_ARGV(0, string);
1483         msg = strcat(msg, mutator_msg); // trust that the mutator will do proper formatting
1484
1485         if (motd != "")
1486                 msg = strcat(msg, "\n^9↓ ", _("Server's message"), " ↓\n", motd);
1487
1488         strcpy(welcome_msg, msg);
1489         welcome_msg_menu_check_maxtime = time + 1; // wait for menu to load before showing the welcome dialog
1490         return true;
1491 }
1492
1493 void Welcome_Message_Show_Try()
1494 {
1495         if (!welcome_msg_menu_check_maxtime)
1496                 return;
1497
1498         // if want dialog check if menu is initialized but for a short time
1499         if (cvar("_menu_initialized") == 2 || time > welcome_msg_menu_check_maxtime)
1500         {
1501                 if (cvar("_menu_welcome_dialog_available"))
1502                 {
1503                         string welcomedialog_args = strcat("HOSTNAME \"", hostname, "\"");
1504                         string msg = MakeConsoleSafe(strreplace("\n", "\\n", welcome_msg));
1505                         welcomedialog_args = strcat(welcomedialog_args, " WELCOME \"", msg, "\"");
1506
1507                         if (intermission || isdemo() || !autocvar_cl_welcome)
1508                         {
1509                                 if (cvar("_menu_cmd_closemenu_available"))
1510                                 {
1511                                         // initialize the dialog without opening it
1512                                         localcmd("\nmenu_cmd closemenu Welcome ", welcomedialog_args, "\n");
1513                                 }
1514                                 else
1515                                 {
1516                                         // legacy code for clients with old menus
1517                                         // since togglemenu 0 doesn't close the dialog but only hides it,
1518                                         // playing back a demo the Welcome dialog will pop up on the first ESC press
1519                                         localcmd("\nmenu_cmd directmenu Welcome ", welcomedialog_args, "\n");
1520                                         // close it after it's been initialized so it can still be opened manually
1521                                         localcmd("\ntogglemenu 0\n");
1522                                 }
1523                         }
1524                         else
1525                                 localcmd("\nmenu_cmd directmenu Welcome ", welcomedialog_args, "\n");
1526                 }
1527
1528                 strfree(welcome_msg);
1529                 welcome_msg_menu_check_maxtime = 0;
1530         }
1531 }
1532
1533 NET_HANDLE(TE_CSQC_SERVERWELCOME, bool isNew)
1534 {
1535         return net_handle_ServerWelcome();
1536 }
1537
1538 string _getcommandkey(string cmd_name, string command, bool forcename)
1539 {
1540         string keys;
1541         float n, j, k, l = 0;
1542
1543         if (!autocvar_hud_showbinds)
1544                 return cmd_name;
1545
1546         keys = db_get(binddb, command);
1547         if (keys == "")
1548         {
1549                 bool joy_active = cvar("joy_active");
1550                 n = tokenize(findkeysforcommand(command, 0)); // uses '...' strings
1551                 for(j = 0; j < n; ++j)
1552                 {
1553                         k = stof(argv(j));
1554                         if(k != -1)
1555                         {
1556                                 string key = keynumtostring(k);
1557                                 if(!joy_active && substring(key, 0, 3) == "JOY")
1558                                         continue;
1559
1560                                 key = translate_key(key);
1561
1562                                 if (keys == "")
1563                                         keys = key;
1564                                 else
1565                                         keys = strcat(keys, ", ", key);
1566
1567                                 ++l;
1568                                 if (autocvar_hud_showbinds_limit > 0 && autocvar_hud_showbinds_limit <= l)
1569                                         break;
1570                         }
1571
1572                 }
1573                 if (keys == "")
1574                         keys = "NO_KEY";
1575                 db_put(binddb, command, keys);
1576         }
1577
1578         if (keys == "NO_KEY") {
1579                 if (autocvar_hud_showbinds > 1)
1580                         return sprintf(_("%s (not bound)"), cmd_name);
1581                 else
1582                         return cmd_name;
1583         }
1584         else if (autocvar_hud_showbinds > 1 || forcename)
1585                 return sprintf("%s (%s)", cmd_name, keys);
1586         else
1587                 return keys;
1588 }
1589
1590 /** engine callback */
1591 void URI_Get_Callback(int id, int status, string data)
1592 {
1593         TC(int, id); TC(int, status);
1594         if(url_URI_Get_Callback(id, status, data))
1595         {
1596                 // handled
1597         }
1598         else if (id == URI_GET_DISCARD)
1599         {
1600                 // discard
1601         }
1602         else if (id >= URI_GET_CURL && id <= URI_GET_CURL_END)
1603         {
1604                 // sv_cmd curl
1605                 Curl_URI_Get_Callback(id, status, data);
1606         }
1607         else
1608         {
1609                 LOG_INFOF("Received HTTP request data for an invalid id %d.", id);
1610         }
1611 }