qcsrc/client/main.qc

   1 #include "main.qh"
   2
   3 #include <client/command/cl_cmd.qh>
   4 #include <client/draw.qh>
   5 #include <client/hud/_mod.qh>
   6 #include <client/hud/panel/centerprint.qh>
   7 #include <client/hud/panel/chat.qh>
   8 #include <client/hud/panel/quickmenu.qh>
   9 #include <client/hud/panel/scoreboard.qh>
  10 #include <client/items/items.qh>
  11 #include <client/mapvoting.qh>
  12 #include <client/mutators/_mod.qh>
  13 #include <client/shownames.qh>
  14 #include <client/view.qh>
  15 #include <client/weapons/projectile.qh>
  16 #include <common/deathtypes/all.qh>
  17 #include <common/effects/all.inc>
  18 #include <common/effects/all.qh>
  19 #include <common/effects/effect.qh>
  20 #include <common/effects/qc/_mod.qh>
  21 #include <common/ent_cs.qh>
  22 #include <common/gamemodes/gamemode/nexball/cl_nexball.qh>
  23 #include <common/items/_mod.qh>
  24 #include <common/mapinfo.qh>
  25 #include <common/mapobjects/_mod.qh>
  26 #include <common/minigames/cl_minigames.qh>
  27 #include <common/minigames/cl_minigames_hud.qh>
  28 #include <common/net_linked.qh>
  29 #include <common/net_notice.qh>
  30 #include <common/scores.qh>
  31 #include <common/vehicles/all.qh>
  32 #include <lib/csqcmodel/cl_model.qh>
  33 #include <lib/csqcmodel/interpolate.qh>
  34 #include <lib/warpzone/client.qh>
  35
  36 // --------------------------------------------------------------------------
  37 // BEGIN REQUIRED CSQC FUNCTIONS
  38 //include "main.qh"
  39
  40 #define DP_CSQC_ENTITY_REMOVE_IS_B0RKED
  41
  42 // CSQC_Init : Called every time the CSQC code is initialized (essentially at map load)
  43 // Useful for precaching things
  44
  45 void CSQC_Init()
  46 {
  47         prvm_language = strzone(cvar_string("prvm_language"));
  48
  49 #ifdef WATERMARK
  50         LOG_TRACEF("^4CSQC Build information: ^1%s", WATERMARK);
  51 #endif
  52
  53         {
  54                 int i = 0;
  55                 for ( ; i < 255; ++i)
  56                         if (getplayerkeyvalue(i, "viewentity") == "")
  57                                 break;
  58                 maxclients = i;
  59         }
  60
  61         // needs to be done so early because of the constants they create
  62         static_init();
  63         static_init_late();
  64         static_init_precache();
  65
  66         binddb = db_create();
  67         tempdb = db_create();
  68         ClientProgsDB = db_load("client.db");
  69
  70         draw_endBoldFont();
  71
  72         //registercommand("hud_configure");
  73         //registercommand("hud_save");
  74         //registercommand("menu_action");
  75
  76         ConsoleCommand_macro_init();
  77
  78         registercvar("hud_usecsqc", "1");
  79         registercvar("scoreboard_columns", "default");
  80
  81         registercvar("cl_nade_type", "3");
  82         registercvar("cl_pokenade_type", "zombie");
  83
  84         registercvar("cl_jumpspeedcap_min", "");
  85         registercvar("cl_jumpspeedcap_max", "");
  86
  87         registercvar("cl_shootfromfixedorigin", "");
  88
  89         registercvar("cl_multijump", "-1");
  90
  91         registercvar("cl_dodging", "0");
  92
  93         registercvar("cl_spawn_near_teammate", "1");
  94
  95         registercvar("cl_weapon_switch_reload", "1");
  96         registercvar("cl_weapon_switch_fallback_to_impulse", "1");
  97
  98         registercvar("cl_allow_uidranking", "1");
  99
 100         if(autocvar_cl_lockview)
 101                 cvar_set("cl_lockview", "0");
 102
 103         if (cvar_type("_scoreboard_team_selection_available") & CVAR_TYPEFLAG_EXISTS)
 104                 cvar_settemp("_scoreboard_team_selection_available", "1");
 105         cvar_set("_scoreboard_team_selection", "0"); // in case it has been left set to 1
 106
 107         gametype = NULL;
 108
 109         postinit = false;
 110
 111         calledhooks = 0;
 112
 113         teams = Sort_Spawn();
 114         players = Sort_Spawn();
 115
 116         GetTeam(NUM_SPECTATOR, true); // add specs first
 117
 118         for (int w = 0; w <= WEP_LAST - WEP_FIRST; ++w)
 119                 weapon_accuracy[w] = -1;
 120
 121         // precaches
 122
 123         if(autocvar_cl_reticle)
 124         {
 125                 precache_pic("gfx/reticle_normal");
 126                 // weapon reticles are precached in weapon files
 127         }
 128
 129         {
 130                 get_mi_min_max_texcoords(1); // try the CLEVER way first
 131                 minimapname = strcat("gfx/", mi_shortname, "_radar");
 132
 133                 if (precache_pic(minimapname) == "")
 134                 {
 135                         // but maybe we have a non-clever minimap
 136                         minimapname = strcat("gfx/", mi_shortname, "_mini");
 137                         if (precache_pic(minimapname) == "")
 138                                 minimapname = ""; // FAIL
 139                         else
 140                                 get_mi_min_max_texcoords(0); // load new texcoords
 141                 }
 142
 143                 mi_center = (mi_min + mi_max) * 0.5;
 144                 mi_scale = mi_max - mi_min;
 145                 minimapname = strzone(minimapname);
 146         }
 147
 148         hud_skin_path = strzone(strcat("gfx/hud/", autocvar_hud_skin));
 149         LoadMenuSkinValues();
 150 }
 151
 152 // CSQC_Shutdown : Called every time the CSQC code is shutdown (changing maps, quitting, etc)
 153 void Shutdown()
 154 {
 155         WarpZone_Shutdown();
 156
 157         delete(teams);
 158         delete(players);
 159         db_close(binddb);
 160         db_close(tempdb);
 161         if(autocvar_cl_db_saveasdump)
 162                 db_dump(ClientProgsDB, "client.db");
 163         else
 164                 db_save(ClientProgsDB, "client.db");
 165         db_close(ClientProgsDB);
 166
 167         if(camera_active)
 168                 cvar_set("chase_active",ftos(chase_active_backup));
 169
 170         // unset the event chasecam's chase_active
 171         if(autocvar_chase_active < 0)
 172                 cvar_set("chase_active", "0");
 173
 174         if (autocvar_r_drawviewmodel < 0)
 175                 cvar_set("r_drawviewmodel", "0");
 176
 177         cvar_set("slowmo", cvar_defstring("slowmo")); // reset it back to 'default'
 178
 179         if (!isdemo())
 180         {
 181                 if (!(calledhooks & HOOK_START))
 182                         localcmd("\n_cl_hook_gamestart nop\n");
 183                 if (!(calledhooks & HOOK_END))
 184                 {
 185                         int gamecount = cvar("cl_matchcount");
 186                         localcmd("\ncl_hook_gameend\n");
 187                         // NOTE: using localcmd here to ensure it's executed AFTER cl_hook_gameend
 188                         // earlier versions of the game abuse the hook to set this cvar
 189                         localcmd(strcat("cl_matchcount ", itos(gamecount + 1), "\n"));
 190                         //cvar_set("cl_matchcount", itos(gamecount + 1));
 191                 }
 192         }
 193
 194         localcmd("\ncl_hook_shutdown\n");
 195
 196         localcmd("\n-button12\n");
 197
 198         deactivate_minigame();
 199         HUD_MinigameMenu_Close(NULL, NULL, NULL);
 200
 201         ReplicateVars(REPLICATEVARS_DESTROY);
 202 }
 203
 204 void AuditLists()
 205 {
 206         entity e;
 207         entity prev;
 208
 209         prev = players;
 210         for(e = prev.sort_next; e; prev = e, e = e.sort_next)
 211         {
 212                 if(prev != e.sort_prev)
 213                         error(strcat("sort list chain error\nplease submit the output of 'prvm_edicts client' to the developers"));
 214         }
 215
 216         prev = teams;
 217         for(e = prev.sort_next; e; prev = e, e = e.sort_next)
 218         {
 219                 if(prev != e.sort_prev)
 220                         error(strcat("sort list chain error\nplease submit the output of 'prvm_edicts client' to the developers"));
 221         }
 222 }
 223
 224 float RegisterPlayer(entity player)
 225 {
 226         entity pl;
 227         AuditLists();
 228         for(pl = players.sort_next; pl; pl = pl.sort_next)
 229                 if(pl == player)
 230                         error("Player already registered!");
 231         player.sort_next = players.sort_next;
 232         player.sort_prev = players;
 233         if(players.sort_next)
 234                 players.sort_next.sort_prev = player;
 235         players.sort_next = player;
 236         AuditLists();
 237         return true;
 238 }
 239
 240 void RemovePlayer(entity player)
 241 {
 242         entity pl, parent;
 243         AuditLists();
 244         parent = players;
 245         for(pl = players.sort_next; pl && pl != player; pl = pl.sort_next)
 246                 parent = pl;
 247
 248         if(!pl)
 249         {
 250                 error("Trying to remove a player which is not in the playerlist!");
 251                 return;
 252         }
 253         parent.sort_next = player.sort_next;
 254         if(player.sort_next)
 255                 player.sort_next.sort_prev = parent;
 256         AuditLists();
 257 }
 258
 259 void MoveToLast(entity e)
 260 {
 261         AuditLists();
 262         entity ent = e.sort_next;
 263         while(ent)
 264         {
 265                 SORT_SWAP(ent, e);
 266                 ent = e.sort_next;
 267         }
 268         AuditLists();
 269 }
 270
 271 float RegisterTeam(entity Team)
 272 {
 273         assert_once(Team.team, eprint(Team));
 274         entity tm;
 275         AuditLists();
 276         for(tm = teams.sort_next; tm; tm = tm.sort_next)
 277                 if(tm == Team)
 278                         error("Team already registered!");
 279         Team.sort_next = teams.sort_next;
 280         Team.sort_prev = teams;
 281         if(teams.sort_next)
 282                 teams.sort_next.sort_prev = Team;
 283         teams.sort_next = Team;
 284         if(Team.team && Team.team != NUM_SPECTATOR)
 285                 ++team_count;
 286         AuditLists();
 287         return true;
 288 }
 289
 290 void RemoveTeam(entity Team)
 291 {
 292         entity tm, parent;
 293         AuditLists();
 294         parent = teams;
 295         for(tm = teams.sort_next; tm && tm != Team; tm = tm.sort_next)
 296                 parent = tm;
 297
 298         if(!tm)
 299         {
 300                 LOG_INFO(_("Trying to remove a team which is not in the teamlist!"));
 301                 return;
 302         }
 303         parent.sort_next = Team.sort_next;
 304         if(Team.sort_next)
 305                 Team.sort_next.sort_prev = parent;
 306         if(Team.team && Team.team != NUM_SPECTATOR)
 307                 --team_count;
 308         AuditLists();
 309 }
 310
 311 entity GetTeam(int Team, bool add)
 312 {
 313         TC(int, Team); TC(bool, add);
 314         int num = (Team == NUM_SPECTATOR) ? 16 : Team;
 315         if(teamslots[num])
 316                 return teamslots[num];
 317         if (!add)
 318                 return NULL;
 319         entity tm = new_pure(team);
 320         tm.team = Team;
 321         teamslots[num] = tm;
 322         RegisterTeam(tm);
 323         return tm;
 324 }
 325
 326 .float has_team;
 327 bool SetTeam(entity o, int Team)
 328 {
 329         TC(int, Team);
 330         //devassert_once(Team);
 331         entity tm;
 332         if(teamplay)
 333         {
 334                 switch(Team)
 335                 {
 336                         case -1:
 337                         case NUM_TEAM_1:
 338                         case NUM_TEAM_2:
 339                         case NUM_TEAM_3:
 340                         case NUM_TEAM_4:
 341                                 break;
 342                         default:
 343                                 if(GetTeam(Team, false) == NULL)
 344                                 {
 345                                         LOG_TRACEF("trying to switch to unsupported team %d", Team);
 346                                         Team = NUM_SPECTATOR;
 347                                 }
 348                                 break;
 349                 }
 350         }
 351         else
 352         {
 353                 switch(Team)
 354                 {
 355                         case -1:
 356                         case 0:
 357                                 break;
 358                         default:
 359                                 if(GetTeam(Team, false) == NULL)
 360                                 {
 361                                         LOG_TRACEF("trying to switch to unsupported team %d", Team);
 362                                         Team = NUM_SPECTATOR;
 363                                 }
 364                                 break;
 365                 }
 366         }
 367         if(Team == -1) // leave
 368         {
 369                 if(o.has_team)
 370                 {
 371                         tm = GetTeam(o.team, false);
 372                         tm.team_size -= 1;
 373                         o.has_team = 0;
 374                         return true;
 375                 }
 376         }
 377         else
 378         {
 379                 if (!o.has_team)
 380                 {
 381                         o.team = Team;
 382                         tm = GetTeam(Team, true);
 383                         tm.team_size += 1;
 384                         o.has_team = 1;
 385                         return true;
 386                 }
 387                 else if(Team != o.team)
 388                 {
 389                         tm = GetTeam(o.team, false);
 390                         tm.team_size -= 1;
 391                         o.team = Team;
 392                         tm = GetTeam(Team, true);
 393                         tm.team_size += 1;
 394                         return true;
 395                 }
 396         }
 397         return false;
 398 }
 399
 400 void Playerchecker_Think(entity this)
 401 {
 402         int i;
 403         entity e;
 404         for(i = 0; i < maxclients; ++i)
 405         {
 406                 e = playerslots[i];
 407                 if(entcs_GetName(i) == "")
 408                 {
 409                         if(e.sort_prev)
 410                         {
 411                                 // player disconnected
 412                                 SetTeam(e, -1);
 413                                 RemovePlayer(e);
 414                                 e.sort_prev = NULL;
 415                                 //e.gotscores = 0;
 416                         }
 417                 }
 418                 else
 419                 {
 420                         if (!e.sort_prev)
 421                         {
 422                                 // player connected
 423                                 if (!e)
 424                                 {
 425                                         playerslots[i] = e = new_pure(playerslot);
 426                                 }
 427                                 e.sv_entnum = i;
 428                                 e.ping = 0;
 429                                 e.ping_packetloss = 0;
 430                                 e.ping_movementloss = 0;
 431                                 //e.gotscores = 0; // we might already have the scores...
 432                                 int t = entcs_GetScoreTeam(i);
 433                                 if (t) SetTeam(e, t); // will not hurt; later updates come with Scoreboard_UpdatePlayerTeams
 434                                 RegisterPlayer(e);
 435                                 Scoreboard_UpdatePlayerPos(e);
 436                         }
 437                 }
 438         }
 439         this.nextthink = time + 0.2;
 440 }
 441
 442 void PostInit()
 443 {
 444         entity playerchecker = new_pure(playerchecker);
 445         setthink(playerchecker, Playerchecker_Think);
 446         playerchecker.nextthink = time + 0.2;
 447
 448         TrueAim_Init();
 449
 450         // this can't be called in CSQC_Init as it'd send cvars too early
 451         ReplicateVars_Start();
 452
 453         postinit = true;
 454 }
 455
 456 void Release_Common_Keys()
 457 {
 458         localcmd("-fire\n");
 459         localcmd("-fire2\n");
 460         localcmd("-use\n");
 461         localcmd("-hook\n");
 462         localcmd("-jump\n");
 463         localcmd("-forward\n");
 464         localcmd("-back\n");
 465         localcmd("-moveleft\n");
 466         localcmd("-moveright\n");
 467 }
 468
 469 // CSQC_InputEvent : Used to perform actions based on any key pressed, key released and mouse on the client.
 470 // Return value should be 1 if CSQC handled the input, otherwise return 0 to have the input passed to the engine.
 471 // All keys are in ascii.
 472 // bInputType = 0 is key pressed, 1 is key released, 2 and 3 are mouse input.
 473 // In the case of keyboard input, nPrimary is the ascii code, and nSecondary is 0.
 474 // In the case of mouse input, nPrimary is xdelta, nSecondary is ydelta.
 475 // In the case of mouse input after a setcursormode(1) call, nPrimary is xpos, nSecondary is ypos.
 476 float CSQC_InputEvent(int bInputType, float nPrimary, float nSecondary)
 477 {
 478         TC(int, bInputType);
 479         bool override = false;
 480
 481         override |= HUD_Scoreboard_InputEvent(bInputType, nPrimary, nSecondary);
 482         if (override)
 483                 return true;
 484
 485         override |= HUD_Panel_InputEvent(bInputType, nPrimary, nSecondary);
 486         if (override)
 487                 return true;
 488
 489         override |= HUD_Panel_Chat_InputEvent(bInputType, nPrimary, nSecondary);
 490
 491         override |= QuickMenu_InputEvent(bInputType, nPrimary, nSecondary);
 492
 493         override |= HUD_Radar_InputEvent(bInputType, nPrimary, nSecondary);
 494
 495         override |= MapVote_InputEvent(bInputType, nPrimary, nSecondary);
 496
 497         override |= HUD_Minigame_InputEvent(bInputType, nPrimary, nSecondary);
 498
 499         if(override)
 500                 return true;
 501
 502         if(bInputType == 3 || bInputType == 2)
 503                 return false;
 504
 505         // at this point bInputType can only be 0 or 1 (key pressed or released)
 506         bool key_pressed = (bInputType == 0);
 507
 508         if(key_pressed) {
 509                 if(nPrimary == K_ALT) hudShiftState |= S_ALT;
 510                 if(nPrimary == K_CTRL) hudShiftState |= S_CTRL;
 511                 if(nPrimary == K_SHIFT) hudShiftState |= S_SHIFT;
 512                 if(nPrimary == K_TAB) hudShiftState |= S_TAB;
 513         }
 514         else {
 515                 if(nPrimary == K_ALT) hudShiftState -= (hudShiftState & S_ALT);
 516                 if(nPrimary == K_CTRL) hudShiftState -= (hudShiftState & S_CTRL);
 517                 if(nPrimary == K_SHIFT) hudShiftState -= (hudShiftState & S_SHIFT);
 518                 if(nPrimary == K_TAB) hudShiftState -= (hudShiftState & S_TAB);
 519         }
 520
 521         // NOTE: Shift-Escape must be filtered out because it's the hardcoded console shortcut
 522         if (nPrimary == K_ESCAPE && !(hudShiftState & S_SHIFT) && key_pressed)
 523         {
 524                 if (hudShiftState & S_TAB)
 525                 {
 526                         Scoreboard_UI_Enable(0);
 527                         return true;
 528                 }
 529                 if (autocvar_menu_gamemenu && !isdemo() && cvar("_menu_gamemenu_dialog_available"))
 530                 {
 531                         localcmd("\nmenu_showgamemenudialog\n");
 532                         return true;
 533                 }
 534         }
 535
 536         return false;
 537 }
 538
 539 // END REQUIRED CSQC FUNCTIONS
 540 // --------------------------------------------------------------------------
 541
 542 // --------------------------------------------------------------------------
 543 // BEGIN OPTIONAL CSQC FUNCTIONS
 544 .int survival_status;
 545 void Ent_RemovePlayerScore(entity this)
 546 {
 547         if(this.owner) {
 548                 SetTeam(this.owner, -1);
 549                 this.owner.gotscores = 0;
 550                 FOREACH(Scores, true, {
 551                         this.owner.(scores(it)) = 0; // clear all scores
 552                 });
 553                 this.owner.ready = 0;
 554                 this.owner.eliminated = 0;
 555                 this.owner.colormap = 0;
 556                 // TODO add a hook to reset this Survival field
 557                 this.owner.survival_status = 0;
 558         }
 559 }
 560
 561 NET_HANDLE(ENT_CLIENT_SCORES, bool isnew)
 562 {
 563         make_pure(this);
 564         entity o;
 565
 566         // damnit -.- don't want to go change every single .sv_entnum in hud.qc AGAIN
 567         // (no I've never heard of M-x replace-string, sed, or anything like that)
 568         bool isNew = !this.owner; // workaround for DP bug
 569         int n = ReadByte()-1;
 570
 571 #ifdef DP_CSQC_ENTITY_REMOVE_IS_B0RKED
 572         if(!isNew && n != this.sv_entnum)
 573         {
 574                 //print("A CSQC entity changed its owner!\n");
 575                 LOG_INFOF("A CSQC entity changed its owner! (edict: %d, classname: %s)", etof(this), this.classname);
 576                 isNew = true;
 577                 Ent_Remove(this);
 578         }
 579 #endif
 580
 581         this.sv_entnum = n;
 582
 583         o = playerslots[this.sv_entnum];
 584         if (!o)
 585         {
 586                 o = playerslots[this.sv_entnum] = new_pure(playerslot);
 587         }
 588         this.owner = o;
 589         o.sv_entnum = this.sv_entnum;
 590         o.gotscores = 1;
 591
 592         //if (!o.sort_prev)
 593         //      RegisterPlayer(o);
 594         //playerchecker will do this for us later, if it has not already done so
 595
 596         int sf = ReadShort();
 597         int lf = ReadShort();
 598         FOREACH(Scores, true, {
 599                 int p = 1 << (i % 16);
 600                 if (sf & p)
 601                 {
 602                         if (lf & p)
 603                                 o.(scores(it)) = ReadInt24_t();
 604                         else
 605                                 o.(scores(it)) = ReadChar();
 606                 }
 607         });
 608
 609         return = true;
 610
 611         if(o.sort_prev)
 612                 Scoreboard_UpdatePlayerPos(o); // if not registered, we cannot do this yet!
 613
 614         this.entremove = Ent_RemovePlayerScore;
 615 }
 616
 617 NET_HANDLE(ENT_CLIENT_TEAMSCORES, bool isnew)
 618 {
 619         make_pure(this);
 620         int i;
 621
 622         this.team = ReadByte();
 623         entity o = this.owner = GetTeam(this.team, true); // these team numbers can always be trusted
 624
 625 #if MAX_TEAMSCORE <= 8
 626         int sf = ReadByte();
 627         int lf = ReadByte();
 628 #else
 629         int sf = ReadShort();
 630         int lf = ReadShort();
 631 #endif
 632         for(i = 0; i < MAX_TEAMSCORE; ++i)
 633                 if(sf & BIT(i))
 634                 {
 635                         if(lf & BIT(i))
 636                                 o.(teamscores(i)) = ReadInt24_t();
 637                         else
 638                                 o.(teamscores(i)) = ReadChar();
 639                 }
 640
 641         return = true;
 642
 643         Scoreboard_UpdateTeamPos(o);
 644 }
 645
 646 NET_HANDLE(ENT_CLIENT_CLIENTDATA, bool isnew)
 647 {
 648         make_pure(this);
 649         float newspectatee_status;
 650
 651         int f = ReadByte();
 652
 653         scoreboard_showscores_force = (f & BIT(0));
 654
 655         if(f & BIT(1))
 656         {
 657                 newspectatee_status = ReadByte();
 658                 if(newspectatee_status == player_localnum + 1)
 659                         newspectatee_status = -1; // observing
 660         }
 661         else
 662                 newspectatee_status = 0;
 663
 664         spectatorbutton_zoom = (f & BIT(2));
 665         observe_blocked = (f & BIT(3));
 666
 667         if(f & BIT(4))
 668         {
 669                 num_spectators = ReadByte();
 670
 671                 float i, slot;
 672
 673                 for(i = 0; i < MAX_SPECTATORS; ++i)
 674                         spectatorlist[i] = 0; // reset list first
 675
 676                 int limit = min(num_spectators, MAX_SPECTATORS);
 677                 for(i = 0; i < limit; ++i)
 678                 {
 679                         slot = ReadByte();
 680                         spectatorlist[i] = slot - 1;
 681                 }
 682         }
 683         else
 684         {
 685                 for(int j = 0; j < MAX_SPECTATORS; ++j)
 686                         spectatorlist[j] = 0; // reset list if showspectators has been turned off
 687                 num_spectators = 0;
 688         }
 689
 690         return = true;
 691
 692         if(newspectatee_status != spectatee_status)
 693         {
 694                 // clear race stuff
 695                 race_laptime = 0;
 696                 race_checkpointtime = 0;
 697                 hud_dynamic_shake_factor = -1;
 698                 spectatee_status_changed_time = time;
 699         }
 700         if (autocvar_hud_panel_healtharmor_progressbar_gfx)
 701         {
 702                 if ( (spectatee_status == -1 && newspectatee_status > 0) //before observing, now spectating
 703                   || (spectatee_status > 0 && newspectatee_status > 0 && spectatee_status != newspectatee_status) //changed spectated player
 704                 )
 705                         prev_p_health = -1;
 706                 else if(spectatee_status && !newspectatee_status) //before observing/spectating, now playing
 707                         prev_health = -1;
 708         }
 709         spectatee_status = newspectatee_status;
 710
 711         // we could get rid of spectatee_status, and derive it from player_localentnum and player_localnum
 712 }
 713
 714 NET_HANDLE(ENT_CLIENT_NAGGER, bool isnew)
 715 {
 716         make_pure(this);
 717
 718         int nags = ReadByte(); // NAGS NAGS NAGS NAGS NAGS NAGS NADZ NAGS NAGS NAGS
 719
 720         if(!(nags & BIT(2)))
 721         {
 722                 strfree(vote_called_vote);
 723                 vote_active = 0;
 724         }
 725         else
 726         {
 727                 vote_active = 1;
 728         }
 729
 730         if(nags & BIT(6))
 731         {
 732                 vote_yescount = ReadByte();
 733                 vote_nocount = ReadByte();
 734                 vote_needed = ReadByte();
 735                 vote_highlighted = ReadChar();
 736         }
 737
 738         if(nags & BIT(7))
 739         {
 740                 strcpy(vote_called_vote, ReadString());
 741         }
 742
 743         if(nags & BIT(0))
 744                 for(int i = 0; i < maxclients;)
 745                         for(int f = ReadByte(), b = 0; b < 8 && i < maxclients; ++b, ++i)
 746                                 if(playerslots[i])
 747                                         playerslots[i].ready = f & BIT(b);
 748
 749         return = true;
 750
 751         ready_waiting = (nags & BIT(0));
 752         ready_waiting_for_me = (nags & BIT(1));
 753         vote_waiting = (nags & BIT(2));
 754         vote_waiting_for_me = (nags & BIT(3));
 755         warmup_stage = (nags & BIT(4));
 756 }
 757
 758 NET_HANDLE(ENT_CLIENT_ELIMINATEDPLAYERS, bool isnew)
 759 {
 760         make_pure(this);
 761         int sf = 0;
 762         serialize(byte, 0, sf);
 763         if (sf & 1) {
 764                 for (int j = 0; j < maxclients; ++j) {
 765                         if (playerslots[j]) {
 766                                 playerslots[j].eliminated = true;
 767                         }
 768                 }
 769                 for (int i = 1; i <= maxclients; i += 8) {
 770                         int f = 0;
 771                         serialize(byte, 0, f);
 772                         for (int b = 0; b < 8; ++b) {
 773                                 if (f & BIT(b)) continue;
 774                                 int j = i - 1 + b;
 775                                 if (playerslots[j]) {
 776                                         playerslots[j].eliminated = false;
 777                                 }
 778                         }
 779                 }
 780         }
 781         return true;
 782 }
 783
 784 NET_HANDLE(ENT_CLIENT_RANDOMSEED, bool isnew)
 785 {
 786         make_pure(this);
 787         prandom_debug();
 788         float s = ReadShort();
 789         psrandom(s);
 790         return true;
 791 }
 792
 793 NET_HANDLE(ENT_CLIENT_ACCURACY, bool isnew)
 794 {
 795         make_pure(this);
 796         int sf = ReadInt24_t();
 797         if (sf == 0) {
 798                 for (int w = 0; w <= WEP_LAST - WEP_FIRST; ++w)
 799                         weapon_accuracy[w] = -1;
 800                 return true;
 801         }
 802
 803         int f = 1;
 804         for (int w = 0; w <= WEP_LAST - WEP_FIRST; ++w) {
 805                 if (sf & f) {
 806                         int b = ReadByte();
 807                         if (b == 0)
 808                                 weapon_accuracy[w] = -1;
 809                         else if (b == 255)
 810                                 weapon_accuracy[w] = 1.0; // no better error handling yet, sorry
 811                         else
 812                                 weapon_accuracy[w] = (b - 1.0) / 100.0;
 813                 }
 814                 f = (f == 0x800000) ? 1 : f * 2;
 815         }
 816         return true;
 817 }
 818
 819 void Spawn_Draw(entity this)
 820 {
 821         bool dodraw = autocvar_cl_spawn_point_particles;
 822         if(dodraw && autocvar_cl_spawn_point_dist_max)
 823         {
 824                 vector org = getpropertyvec(VF_ORIGIN);
 825                 dodraw = vdist(org - this.origin, <, autocvar_cl_spawn_point_dist_max);
 826         }
 827
 828         if(dodraw)
 829                 pointparticles(((!teamplay) ? EFFECT_SPAWNPOINT_NEUTRAL : EFFECT_SPAWNPOINT(this.team - 1)), this.origin + '0 0 28', '0 0 2', bound(0, frametime, 0.1));
 830 }
 831
 832 NET_HANDLE(ENT_CLIENT_SPAWNPOINT, bool is_new)
 833 {
 834         float teamnum = (ReadByte() - 1);
 835         vector spn_origin = ReadVector();
 836
 837         this.team = (teamnum + 1);
 838
 839         //if(is_new)
 840         //{
 841                 this.origin = spn_origin;
 842                 setsize(this, PL_MIN_CONST, PL_MAX_CONST);
 843                 //droptofloor();
 844
 845                 /*if(autocvar_cl_spawn_point_model) // needs a model first
 846                 {
 847                         this.mdl = "models/spawnpoint.md3";
 848                         this.colormod = Team_ColorRGB(teamnum);
 849                         precache_model(this.mdl);
 850                         setmodel(this, this.mdl);
 851                         this.drawmask = MASK_NORMAL;
 852                         //this.move_movetype = MOVETYPE_NOCLIP;
 853                         //this.draw = Spawn_Draw;
 854                         IL_PUSH(g_drawables, this);
 855                 }*/
 856                 this.draw = Spawn_Draw;
 857                 if (is_new) IL_PUSH(g_drawables, this);
 858         //}
 859
 860         //printf("Ent_ReadSpawnPoint(is_new = %d); origin = %s, team = %d, effect = %d\n", is_new, vtos(this.origin), teamnum, this.cnt);
 861         return true;
 862 }
 863
 864 NET_HANDLE(ENT_CLIENT_SPAWNEVENT, bool is_new)
 865 {
 866         // If entnum is 0, ONLY do the local spawn actions
 867         // this way the server can disable the sending of
 868         // spawn origin or such to clients if wanted.
 869         float entnum = ReadByte();
 870
 871         if(entnum)
 872         {
 873                 this.origin = ReadVector();
 874
 875                 if(is_new)
 876                 {
 877                         float teamnum = entcs_GetTeam(entnum - 1);
 878
 879                         if(autocvar_cl_spawn_event_particles)
 880                         {
 881                                 switch(teamnum)
 882                                 {
 883                                         case NUM_TEAM_1: pointparticles(EFFECT_SPAWN_RED, this.origin, '0 0 0', 1); break;
 884                                         case NUM_TEAM_2: pointparticles(EFFECT_SPAWN_BLUE, this.origin, '0 0 0', 1); break;
 885                                         case NUM_TEAM_3: pointparticles(EFFECT_SPAWN_YELLOW, this.origin, '0 0 0', 1); break;
 886                                         case NUM_TEAM_4: pointparticles(EFFECT_SPAWN_PINK, this.origin, '0 0 0', 1); break;
 887                                         default: pointparticles(EFFECT_SPAWN_NEUTRAL, this.origin, '0 0 0', 1); break;
 888                                 }
 889                         }
 890                         if(autocvar_cl_spawn_event_sound)
 891                         {
 892                                 sound(this, CH_TRIGGER, SND_SPAWN, VOL_BASE, ATTEN_NORM);
 893                         }
 894                 }
 895         }
 896         return = true;
 897
 898         // local spawn actions
 899         if(is_new && (!entnum || (entnum == player_localentnum)))
 900         {
 901                 if(autocvar_cl_spawnzoom && !autocvar_cl_lockview)
 902                 {
 903                         zoomin_effect = 1;
 904                         current_viewzoom = (1 / bound(1, autocvar_cl_spawnzoom_factor, 16));
 905                 }
 906
 907                 if(autocvar_cl_unpress_zoom_on_spawn)
 908                 {
 909                         localcmd("-zoom\n");
 910                         button_zoom = false;
 911                 }
 912                 HUD_Radar_Hide_Maximized();
 913         }
 914         //printf("Ent_ReadSpawnEvent(is_new = %d); origin = %s, entnum = %d, localentnum = %d\n", is_new, vtos(this.origin), entnum, player_localentnum);
 915 }
 916
 917 // CSQC_Ent_Update : Called every frame that the server has indicated an update to the SSQC / CSQC entity has occured.
 918 // The parameter isnew reflects if the entity is "new" to the client, meaning it just came into the client's PVS.
 919 void CSQC_Ent_Update(entity this, bool isnew)
 920 {
 921         this.sourceLoc = __FILE__":"STR(__LINE__);
 922         int t = ReadByte();
 923
 924         // set up the "time" global for received entities to be correct for interpolation purposes
 925         float savetime = time;
 926         if(servertime)
 927         {
 928                 time = servertime;
 929         }
 930         else
 931         {
 932                 serverprevtime = time;
 933                 serverdeltatime = STAT(MOVEVARS_TICRATE) * STAT(MOVEVARS_TIMESCALE);
 934                 time = serverprevtime + serverdeltatime;
 935         }
 936
 937 #ifdef DP_CSQC_ENTITY_REMOVE_IS_B0RKED
 938         if (this.enttype)
 939         {
 940                 if (t != this.enttype || isnew)
 941                 {
 942                         LOG_INFOF("A CSQC entity changed its type! (edict: %d, server: %d, type: %d -> %d)", etof(this), this.entnum, this.enttype, t);
 943                         Ent_Remove(this);
 944                         ONREMOVE(this);
 945                         clearentity(this);
 946                         isnew = true;
 947                 }
 948         }
 949         else
 950         {
 951                 if (!isnew)
 952                 {
 953                         LOG_INFOF("A CSQC entity appeared out of nowhere! (edict: %d, server: %d, type: %d)", etof(this), this.entnum, t);
 954                         isnew = true;
 955                 }
 956         }
 957 #endif
 958         this.enttype = t;
 959         bool done = false;
 960         FOREACH(LinkedEntities, it.m_id == t, {
 961                 if (isnew) this.classname = it.netname;
 962                 if (autocvar_developer_csqcentities)
 963                         LOG_INFOF("CSQC_Ent_Update(%i, %d) at %f {.entnum=%d, .enttype=%d} t=%s (%d)", this, isnew, savetime, this.entnum, this.enttype, this.classname, t);
 964                 done = it.m_read(this, NULL, isnew);
 965                 MUTATOR_CALLHOOK(Ent_Update, this, isnew);
 966                 break;
 967         });
 968         time = savetime;
 969         if (!done)
 970         {
 971                 LOG_FATALF("CSQC_Ent_Update(%i, %d) at %f {.entnum=%d, .enttype=%d} t=%s (%d)", this, isnew, savetime, this.entnum, this.enttype, this.classname, t);
 972         }
 973 }
 974
 975 // Destructor, but does NOT deallocate the entity by calling remove(). Also
 976 // used when an entity changes its type. For an entity that someone interacts
 977 // with others, make sure it can no longer do so.
 978 void Ent_Remove(entity this)
 979 {
 980         if(this.entremove) this.entremove(this);
 981
 982         if(this.skeletonindex)
 983         {
 984                 skel_delete(this.skeletonindex);
 985                 this.skeletonindex = 0;
 986         }
 987
 988         if(this.snd_looping > 0)
 989         {
 990                 sound(this, this.snd_looping, SND_Null, VOL_BASE, autocvar_cl_jetpack_attenuation);
 991                 this.snd_looping = 0;
 992         }
 993
 994         this.enttype = 0;
 995         this.classname = "";
 996         this.draw = func_null;
 997         this.entremove = func_null;
 998         // TODO possibly set more stuff to defaults
 999 }
1000 // CSQC_Ent_Remove : Called when the server requests a SSQC / CSQC entity to be removed.  Essentially call remove(this) as well.
1001 void CSQC_Ent_Remove(entity this)
1002 {
1003         if (autocvar_developer_csqcentities) LOG_INFOF("CSQC_Ent_Remove() with this=%i {.entnum=%d, .enttype=%d}", this, this.entnum, this.enttype);
1004         if (wasfreed(this))
1005         {
1006                 LOG_WARN("CSQC_Ent_Remove called for already removed entity. Packet loss?");
1007                 return;
1008         }
1009         if (this.enttype) Ent_Remove(this);
1010         delete(this);
1011 }
1012
1013 void Gamemode_Init()
1014 {
1015         if (!isdemo())
1016         {
1017                 if(!(calledhooks & HOOK_START))
1018                         localcmd("\n_cl_hook_gamestart ", MapInfo_Type_ToString(gametype), "\n");
1019                 calledhooks |= HOOK_START;
1020         }
1021 }
1022 // CSQC_Parse_StuffCmd : Provides the stuffcmd string in the first parameter that the server provided.  To execute standard behavior, simply execute localcmd with the string.
1023 void CSQC_Parse_StuffCmd(string strMessage)
1024 {
1025         if (autocvar_developer_csqcentities) LOG_INFOF("CSQC_Parse_StuffCmd(\"%s\")", strMessage);
1026         localcmd(strMessage);
1027 }
1028 // CSQC_Parse_Print : Provides the print string in the first parameter that the server provided.  To execute standard behavior, simply execute print with the string.
1029 void CSQC_Parse_Print(string strMessage)
1030 {
1031         if (autocvar_developer_csqcentities) LOG_INFOF("CSQC_Parse_Print(\"%s\")", strMessage);
1032         print(ColorTranslateRGB(strMessage));
1033 }
1034
1035 // CSQC_Parse_CenterPrint : Provides the centerprint_AddStandard string in the first parameter that the server provided.
1036 void CSQC_Parse_CenterPrint(string strMessage)
1037 {
1038         if (autocvar_developer_csqcentities) LOG_INFOF("CSQC_Parse_CenterPrint(\"%s\")", strMessage);
1039         centerprint_AddStandard(strMessage);
1040 }
1041
1042 // CSQC_Parse_TempEntity : Handles all temporary entity network data in the CSQC layer.
1043 // You must ALWAYS first acquire the temporary ID, which is sent as a byte.
1044 // Return value should be 1 if CSQC handled the temporary entity, otherwise return 0 to have the engine process the event.
1045 bool CSQC_Parse_TempEntity()
1046 {
1047         // Acquire TE ID
1048         int nTEID = ReadByte();
1049
1050         FOREACH(TempEntities, it.m_id == nTEID, {
1051                 if (autocvar_developer_csqcentities)
1052                         LOG_INFOF("CSQC_Parse_TempEntity() nTEID=%s (%d)", it.netname, nTEID);
1053                 return it.m_read(NULL, NULL, true);
1054         });
1055
1056         if (autocvar_developer_csqcentities)
1057                 LOG_INFOF("CSQC_Parse_TempEntity() with nTEID=%d", nTEID);
1058
1059         // No special logic for this temporary entity; return 0 so the engine can handle it
1060         return false;
1061 }
1062
1063 bool autocvar_r_drawfog;
1064 bool autocvar_r_fog_exp2;
1065 string forcefog;
1066 void Fog_Force()
1067 {
1068         if (autocvar_cl_orthoview && autocvar_cl_orthoview_nofog)
1069         {
1070                 if (autocvar_r_drawfog)
1071                         cvar_set("r_drawfog", "0");
1072         }
1073         else if (forcefog != "")
1074         {
1075                 // using cvar_set as it's faster and safer than a command
1076                 if (!autocvar_r_drawfog)
1077                         cvar_set("r_drawfog", "1");
1078                 if (autocvar_r_fog_exp2)
1079                         cvar_set("r_fog_exp2", "0");
1080                 localcmd(sprintf("\nfog %s\n", forcefog));
1081         }
1082 }
1083
1084 bool net_handle_ServerWelcome();
1085 NET_HANDLE(ENT_CLIENT_SCORES_INFO, bool isnew)
1086 {
1087         make_pure(this);
1088         gametype = ReadRegistered(Gametypes);
1089         teamplay = _MapInfo_GetTeamPlayBool(gametype);
1090         HUD_ModIcons_SetFunc();
1091         FOREACH(Scores, true, {
1092                 strcpy(scores_label(it), ReadString());
1093                 scores_flags(it) = ReadByte();
1094         });
1095         for (int i = 0; i < MAX_TEAMSCORE; ++i)
1096         {
1097                 strcpy(teamscores_label(i), ReadString());
1098                 teamscores_flags(i) = ReadByte();
1099         }
1100         bool welcome_msg_too = ReadByte();
1101         if (welcome_msg_too)
1102                 net_handle_ServerWelcome();
1103         return = true;
1104         Scoreboard_InitScores();
1105         Gamemode_Init();
1106 }
1107
1108 NET_HANDLE(ENT_CLIENT_INIT, bool isnew)
1109 {
1110         nb_pb_period = ReadByte() / 32; //Accuracy of 1/32th
1111
1112         hook_shotorigin[0] = decompressShotOrigin(ReadInt24_t());
1113         hook_shotorigin[1] = decompressShotOrigin(ReadInt24_t());
1114         hook_shotorigin[2] = decompressShotOrigin(ReadInt24_t());
1115         hook_shotorigin[3] = decompressShotOrigin(ReadInt24_t());
1116         arc_shotorigin[0] = decompressShotOrigin(ReadInt24_t());
1117         arc_shotorigin[1] = decompressShotOrigin(ReadInt24_t());
1118         arc_shotorigin[2] = decompressShotOrigin(ReadInt24_t());
1119         arc_shotorigin[3] = decompressShotOrigin(ReadInt24_t());
1120
1121         strcpy(forcefog, ReadString());
1122
1123         armorblockpercent = ReadByte() / 255.0;
1124         damagepush_speedfactor = ReadByte() / 255.0;
1125
1126         serverflags = ReadByte();
1127
1128         g_trueaim_minrange = ReadCoord();
1129
1130         return = true;
1131
1132         MUTATOR_CALLHOOK(Ent_Init);
1133
1134         if (!postinit) PostInit();
1135 }
1136
1137 float GetSpeedUnitFactor(int speed_unit)
1138 {
1139         switch(speed_unit)
1140         {
1141                 default:
1142                 case 1: return 1.0;
1143                 case 2: return 0.0254;
1144                 case 3: return 0.0254 * 3.6;
1145                 case 4: return 0.0254 * 3.6 * 0.6213711922;
1146                 case 5: return 0.0254 * 1.943844492; // 1 m/s = 1.943844492 knots, because 1 knot = 1.852 km/h
1147         }
1148 }
1149
1150 string GetSpeedUnit(int speed_unit)
1151 {
1152         switch(speed_unit)
1153         {
1154                 // translator-friendly strings without the initial space
1155                 default:
1156                 case 1: return strcat(" ", _("qu/s"));
1157                 case 2: return strcat(" ", _("m/s"));
1158                 case 3: return strcat(" ", _("km/h"));
1159                 case 4: return strcat(" ", _("mph"));
1160                 case 5: return strcat(" ", _("knots"));
1161         }
1162 }
1163
1164 NET_HANDLE(TE_CSQC_RACE, bool isNew)
1165 {
1166         int b = ReadByte();
1167
1168         switch (b)
1169         {
1170                 case RACE_NET_CHECKPOINT_HIT_QUALIFYING:
1171                         race_checkpoint = ReadByte();
1172                         race_time = ReadInt24_t();
1173                         race_previousbesttime = ReadInt24_t();
1174                         race_mypreviousbesttime = ReadInt24_t();
1175                         string pbestname = ReadString();
1176                         if(autocvar_cl_race_cptimes_onlyself)
1177                         {
1178                                 race_previousbesttime = race_mypreviousbesttime;
1179                                 race_mypreviousbesttime = 0;
1180                                 strcpy(race_previousbestname, "");
1181                         }
1182                         else
1183                                 strcpy(race_previousbestname, pbestname);
1184
1185                         race_checkpointtime = time;
1186
1187                         if(race_checkpoint == 0 || race_checkpoint == 254)
1188                         {
1189                                 race_penaltyaccumulator = 0;
1190                                 race_laptime = time; // valid
1191                         }
1192                         break;
1193
1194                 case RACE_NET_CHECKPOINT_CLEAR:
1195                         race_laptime = 0;
1196                         race_checkpointtime = 0;
1197                         break;
1198
1199                 case RACE_NET_CHECKPOINT_NEXT_SPEC_QUALIFYING:
1200                         race_laptime = ReadCoord();
1201                         race_checkpointtime = -99999;
1202                         // fall through
1203                 case RACE_NET_CHECKPOINT_NEXT_QUALIFYING:
1204                         race_nextcheckpoint = ReadByte();
1205
1206                         race_nextbesttime = ReadInt24_t();
1207                         if(b != RACE_NET_CHECKPOINT_NEXT_SPEC_QUALIFYING) // not while spectating (matches server)
1208                                 race_mybesttime = ReadInt24_t();
1209                         string newname = ReadString();
1210                         if(autocvar_cl_race_cptimes_onlyself && b != RACE_NET_CHECKPOINT_NEXT_SPEC_QUALIFYING)
1211                         {
1212                                 race_nextbesttime = race_mybesttime;
1213                                 race_mybesttime = 0;
1214                                 strcpy(race_nextbestname, "");
1215                         }
1216                         else
1217                                 strcpy(race_nextbestname, newname);
1218                         break;
1219
1220                 case RACE_NET_CHECKPOINT_HIT_RACE:
1221                         race_mycheckpoint = ReadByte();
1222                         race_mycheckpointtime = time;
1223                         race_mycheckpointdelta = ReadInt24_t();
1224                         race_mycheckpointlapsdelta = ReadByte();
1225                         if(race_mycheckpointlapsdelta >= 128)
1226                                 race_mycheckpointlapsdelta -= 256;
1227                         int who = ReadByte();
1228                         if(who)
1229                                 strcpy(race_mycheckpointenemy, entcs_GetName(who - 1));
1230                         else
1231                                 strcpy(race_mycheckpointenemy, ""); // TODO: maybe string_null works fine here?
1232                         break;
1233
1234                 case RACE_NET_CHECKPOINT_HIT_RACE_BY_OPPONENT:
1235                         race_othercheckpoint = ReadByte();
1236                         race_othercheckpointtime = time;
1237                         race_othercheckpointdelta = ReadInt24_t();
1238                         race_othercheckpointlapsdelta = ReadByte();
1239                         if(race_othercheckpointlapsdelta >= 128)
1240                                 race_othercheckpointlapsdelta -= 256;
1241                         int what = ReadByte();
1242                         if(what)
1243                                 strcpy(race_othercheckpointenemy, entcs_GetName(what - 1));
1244                         else
1245                                 strcpy(race_othercheckpointenemy, ""); // TODO: maybe string_null works fine here?
1246                         break;
1247
1248                 case RACE_NET_PENALTY_RACE:
1249                 case RACE_NET_PENALTY_QUALIFYING:
1250                         race_penaltyeventtime = time;
1251                         race_penaltytime = ReadShort();
1252                         string reason = ReadString();
1253                         if (reason == "missing a checkpoint")
1254                                 reason = _("missing a checkpoint");
1255                         strcpy(race_penaltyreason, reason);
1256                         if (b == RACE_NET_PENALTY_QUALIFYING)
1257                                 race_penaltyaccumulator += race_penaltytime;
1258                         break;
1259
1260                 case RACE_NET_SERVER_RECORD:
1261                         race_server_record = ReadInt24_t();
1262                         break;
1263                 case RACE_NET_SPEED_AWARD:
1264                         race_speedaward = ReadInt24_t();
1265                         strcpy(race_speedaward_holder, ReadString());
1266                         break;
1267                 case RACE_NET_SPEED_AWARD_BEST:
1268                         race_speedaward_alltimebest = ReadInt24_t();
1269                         strcpy(race_speedaward_alltimebest_holder, ReadString());
1270                         break;
1271                 case RACE_NET_RANKINGS_CNT:
1272                         RANKINGS_DISPLAY_CNT = ReadByte();
1273                         break;
1274                 case RACE_NET_SERVER_RANKINGS:
1275                         float prevpos, del;
1276                         int pos = ReadShort();
1277                         prevpos = ReadShort();
1278                         del = ReadShort();
1279
1280                         // move other rankings out of the way
1281                         int i;
1282                         if (prevpos) {
1283                                 int m = min(prevpos, RANKINGS_DISPLAY_CNT);
1284                                 for (i=m-1; i>pos-1; --i) {
1285                                         grecordtime[i] = grecordtime[i-1];
1286                                         strcpy(grecordholder[i], grecordholder[i-1]);
1287                                 }
1288                         } else if (del) { // a record has been deleted by the admin
1289                                 for (i=pos-1; i<= RANKINGS_DISPLAY_CNT-1; ++i) {
1290                                         if (i == RANKINGS_DISPLAY_CNT-1) { // clear out last record
1291                                                 grecordtime[i] = 0;
1292                                                 strfree(grecordholder[i]);
1293                                         }
1294                                         else {
1295                                                 grecordtime[i] = grecordtime[i+1];
1296                                                 strcpy(grecordholder[i], grecordholder[i+1]);
1297                                         }
1298                                 }
1299                         } else { // player has no ranked record yet
1300                                 for (i=RANKINGS_DISPLAY_CNT-1;i>pos-1;--i) {
1301                                         grecordtime[i] = grecordtime[i-1];
1302                                         strcpy(grecordholder[i], grecordholder[i-1]);
1303                                 }
1304                         }
1305
1306                         if (grecordtime[RANKINGS_DISPLAY_CNT]) {
1307                                 // kick off the player who fell from the last displayed position
1308                                 grecordtime[RANKINGS_DISPLAY_CNT] = 0;
1309                                 strfree(grecordholder[RANKINGS_DISPLAY_CNT]);
1310                         }
1311
1312                         // store new ranking
1313                         strcpy(grecordholder[pos-1], ReadString());
1314                         grecordtime[pos-1] = ReadInt24_t();
1315                         if(strdecolorize(grecordholder[pos-1]) == strdecolorize(entcs_GetName(player_localnum)))
1316                                 race_myrank = pos;
1317                         break;
1318                 case RACE_NET_SERVER_STATUS:
1319                         race_status = ReadShort();
1320                         strcpy(race_status_name, ReadString());
1321         }
1322         return true;
1323 }
1324
1325 NET_HANDLE(TE_CSQC_TEAMNAGGER, bool isNew)
1326 {
1327         teamnagger = 1;
1328         return true;
1329 }
1330
1331 NET_HANDLE(TE_CSQC_PINGPLREPORT, bool isNew)
1332 {
1333         int i = ReadByte();
1334         int pi = ReadShort();
1335         int pl = ReadByte();
1336         int ml = ReadByte();
1337         return = true;
1338         entity e = playerslots[i];
1339         if (!e) return;
1340         e.ping = pi;
1341         e.ping_packetloss = pl / 255.0;
1342         e.ping_movementloss = ml / 255.0;
1343 }
1344
1345 NET_HANDLE(TE_CSQC_WEAPONCOMPLAIN, bool isNew)
1346 {
1347         int weapon_id = ReadByte();
1348         complain_weapon = REGISTRY_GET(Weapons, weapon_id);
1349         complain_weapon_type = ReadByte();
1350         return = true;
1351
1352         complain_weapon_time = time;
1353         weapontime = time; // ping the weapon panel
1354
1355         switch(complain_weapon_type)
1356         {
1357                 case 0: Local_Notification(MSG_MULTI, ITEM_WEAPON_NOAMMO, weapon_id); break;
1358                 case 1: Local_Notification(MSG_MULTI, ITEM_WEAPON_DONTHAVE, weapon_id); break;
1359                 default: Local_Notification(MSG_MULTI, ITEM_WEAPON_UNAVAILABLE, weapon_id); break;
1360         }
1361 }
1362
1363 string translate_modifications(string s)
1364 {
1365         return build_mutator_list(s);
1366 }
1367
1368 string translate_weaponarena(string s)
1369 {
1370         if (s == "") return s;
1371         if (s == "All Weapons Arena") return _("All Weapons Arena");
1372         if (s == "All Available Weapons Arena") return _("All Available Weapons Arena");
1373         if (s == "Most Weapons Arena") return _("Most Weapons Arena");
1374         if (s == "Most Available Weapons Arena") return _("Most Available Weapons Arena");
1375         if (s == "Dev All Weapons Arena") return s; // development option, do not translate
1376         if (s == "Dev All Available Weapons Arena") return s; // development option, do not translate
1377         if (s == "No Weapons Arena") return _("No Weapons Arena");
1378
1379         int n = tokenizebyseparator(s, " & ");
1380         string wpn_list = "";
1381         for (int i = 0; i < n; i++)
1382         {
1383                 Weapon wep = Weapon_from_name(argv(i));
1384                 if (wep == WEP_Null)
1385                         LOG_INFO("^3Warning: ^7server sent an invalid weapon name\n");
1386                 wpn_list = cons_mid(wpn_list, " & ", wep.m_name);
1387         }
1388         if (wpn_list != "")
1389                 return sprintf(_("%s Arena"), wpn_list);
1390         else
1391                 return _("No Weapons Arena");
1392 }
1393
1394 string GetVersionMessage(string hostversion, bool version_mismatch, bool version_check)
1395 {
1396         string xonotic_hostversion = strcat("Xonotic ", hostversion);
1397         if (version_mismatch)
1398         {
1399                 if(!version_check)
1400                         return strcat(sprintf(_("This is %s"), xonotic_hostversion), "\n^3",
1401                                 _("Your client version is outdated."), "\n\n\n",
1402                                 _("### YOU WON'T BE ABLE TO PLAY ON THIS SERVER ###"), "\n\n\n",
1403                                 _("Please update!"));
1404                 else
1405                         return strcat(sprintf(_("This is %s"), xonotic_hostversion), "\n^3",
1406                                 _("This server is using an outdated Xonotic version."), "\n\n\n",
1407                                 _("### THIS SERVER IS INCOMPATIBLE AND THUS YOU CANNOT JOIN ###"));
1408         }
1409         return sprintf(_("Welcome to %s"), xonotic_hostversion);
1410 }
1411
1412 bool net_handle_ServerWelcome()
1413 {
1414         campaign = ReadByte();
1415         if (campaign)
1416         {
1417                 int campaign_level = ReadByte();
1418                 // Menu can't build the whole campaign message because it lacks getcommandkey and CCR
1419                 // so we build part of the message here and let the menu insert the level description
1420                 // (that client doesn't know) by replacing the keyword _LEVEL_DESC
1421                 string key = getcommandkey(_("jump"), "+jump");
1422                 string msg = strcat(
1423                         CCR("^F1"), sprintf(_("Level %d:"), campaign_level),
1424                         sprintf(CCR(" ^BG%s\n\n"), "_LEVEL_DESC"),
1425                         sprintf(CCR(_("^BGPress ^F2%s^BG to enter the game")), key));
1426                 msg = MakeConsoleSafe(strreplace("\n", "\\n", msg));
1427                 string welcomedialog_args = strcat("CAMPAIGN ", itos(campaign_level), " \"", msg, "\"");
1428
1429                 localcmd("\nmenu_cmd directmenu Welcome ", welcomedialog_args, "\n");
1430                 return true;
1431         }
1432
1433         strcpy(hostname, ReadString());
1434         string hostversion = ReadString();
1435         bool version_mismatch = ReadByte();
1436         bool version_check = ReadByte();
1437         srv_minplayers = ReadByte();
1438         srv_maxplayers = ReadByte();
1439         string modifications = translate_modifications(ReadString());
1440         string weaponarena_list = translate_weaponarena(ReadString());
1441         string cache_mutatormsg = ReadString();
1442         string motd = ReadString();
1443
1444         string msg = GetVersionMessage(hostversion, version_mismatch, version_check);
1445
1446         msg = strcat(msg, "\n\n", _("Gametype:"), " ^1", MapInfo_Type_ToText(gametype), "\n");
1447
1448         msg = strcat(msg, "\n", _("Map:"), " ^2");
1449         if (world.message == "")
1450                 msg = strcat(msg, mi_shortname, "\n");
1451         else
1452         {
1453                 int i = strstrofs(world.message, " by ", 0); // matches _MapInfo_Generate()
1454                 string longname = i >= 0 ? substring(world.message, 0, i) : world.message;
1455                 msg = strcat(msg, (strcasecmp(longname, mi_shortname) ? strcat(mi_shortname, " ^7// ^2") : ""), longname, "\n");
1456         }
1457
1458         if (srv_minplayers || srv_maxplayers)
1459         {
1460                 msg = strcat(msg, "\n", _("This match supports"), " ^5");
1461                 if (srv_minplayers == srv_maxplayers)
1462                         msg = strcat(msg, sprintf(_("%d players"), srv_maxplayers), "\n");
1463                 else if (srv_minplayers && srv_maxplayers)
1464                         msg = strcat(msg, sprintf(_("%d to %d players"), srv_minplayers, srv_maxplayers), "\n");
1465                 else if (srv_maxplayers)
1466                         msg = strcat(msg, sprintf(_("%d players maximum"), srv_maxplayers), "\n");
1467                 else
1468                         msg = strcat(msg, sprintf(_("%d players minimum"), srv_minplayers), "\n");
1469         }
1470
1471         modifications = cons_mid(modifications, ", ", weaponarena_list);
1472         if(modifications != "")
1473                 msg = strcat(msg, "\n", _("Active modifications:"), " ^3", modifications, "\n");
1474
1475         if (cache_mutatormsg != "")
1476                 msg = strcat(msg, "\n", _("Special gameplay tips:"), " ^7", cache_mutatormsg, "\n");
1477         string mutator_msg = "";
1478         MUTATOR_CALLHOOK(BuildGameplayTipsString, mutator_msg);
1479         mutator_msg = M_ARGV(0, string);
1480         msg = strcat(msg, mutator_msg); // trust that the mutator will do proper formatting
1481
1482         if (motd != "")
1483                 msg = strcat(msg, "\n^9↓ ", _("Server's message"), " ↓\n", motd);
1484
1485         strcpy(welcome_msg, msg);
1486         welcome_msg_menu_check_maxtime = time + 1; // wait for menu to load before showing the welcome dialog
1487         return true;
1488 }
1489
1490 void Welcome_Message_Show_Try()
1491 {
1492         if (!welcome_msg_menu_check_maxtime)
1493                 return;
1494
1495         // if want dialog check if menu is initialized but for a short time
1496         if (cvar("_menu_initialized") == 2 || time > welcome_msg_menu_check_maxtime)
1497         {
1498                 if (cvar("_menu_welcome_dialog_available"))
1499                 {
1500                         string welcomedialog_args = strcat("HOSTNAME \"", hostname, "\"");
1501                         string msg = MakeConsoleSafe(strreplace("\n", "\\n", welcome_msg));
1502                         welcomedialog_args = strcat(welcomedialog_args, " WELCOME \"", msg, "\"");
1503
1504                         if (intermission || isdemo() || !autocvar_cl_welcome)
1505                         {
1506                                 if (cvar("_menu_cmd_closemenu_available"))
1507                                 {
1508                                         // initialize the dialog without opening it
1509                                         localcmd("\nmenu_cmd closemenu Welcome ", welcomedialog_args, "\n");
1510                                 }
1511                                 else
1512                                 {
1513                                         // legacy code for clients with old menus
1514                                         // since togglemenu 0 doesn't close the dialog but only hides it,
1515                                         // playing back a demo the Welcome dialog will pop up on the first ESC press
1516                                         localcmd("\nmenu_cmd directmenu Welcome ", welcomedialog_args, "\n");
1517                                         // close it after it's been initialized so it can still be opened manually
1518                                         localcmd("\ntogglemenu 0\n");
1519                                 }
1520                         }
1521                         else
1522                                 localcmd("\nmenu_cmd directmenu Welcome ", welcomedialog_args, "\n");
1523                 }
1524
1525                 strfree(welcome_msg);
1526                 welcome_msg_menu_check_maxtime = 0;
1527         }
1528 }
1529
1530 NET_HANDLE(TE_CSQC_SERVERWELCOME, bool isNew)
1531 {
1532         return net_handle_ServerWelcome();
1533 }
1534
1535 string _getcommandkey(string cmd_name, string command, bool forcename)
1536 {
1537         string keys;
1538         float n, j, k, l = 0;
1539
1540         if (!autocvar_hud_showbinds)
1541                 return cmd_name;
1542
1543         keys = db_get(binddb, command);
1544         if (keys == "")
1545         {
1546                 bool joy_active = cvar("joy_active");
1547                 n = tokenize(findkeysforcommand(command, 0)); // uses '...' strings
1548                 for(j = 0; j < n; ++j)
1549                 {
1550                         k = stof(argv(j));
1551                         if(k != -1)
1552                         {
1553                                 string key = keynumtostring(k);
1554                                 if(!joy_active && substring(key, 0, 3) == "JOY")
1555                                         continue;
1556
1557                                 key = translate_key(key);
1558
1559                                 if (keys == "")
1560                                         keys = key;
1561                                 else
1562                                         keys = strcat(keys, ", ", key);
1563
1564                                 ++l;
1565                                 if (autocvar_hud_showbinds_limit > 0 && autocvar_hud_showbinds_limit <= l)
1566                                         break;
1567                         }
1568
1569                 }
1570                 if (keys == "")
1571                         keys = "NO_KEY";
1572                 db_put(binddb, command, keys);
1573         }
1574
1575         if (keys == "NO_KEY") {
1576                 if (autocvar_hud_showbinds > 1)
1577                         return sprintf(_("%s (not bound)"), cmd_name);
1578                 else
1579                         return cmd_name;
1580         }
1581         else if (autocvar_hud_showbinds > 1 || forcename)
1582                 return sprintf("%s (%s)", cmd_name, keys);
1583         else
1584                 return keys;
1585 }
1586
1587 /** engine callback */
1588 void URI_Get_Callback(int id, int status, string data)
1589 {
1590         TC(int, id); TC(int, status);
1591         if(url_URI_Get_Callback(id, status, data))
1592         {
1593                 // handled
1594         }
1595         else if (id == URI_GET_DISCARD)
1596         {
1597                 // discard
1598         }
1599         else if (id >= URI_GET_CURL && id <= URI_GET_CURL_END)
1600         {
1601                 // sv_cmd curl
1602                 Curl_URI_Get_Callback(id, status, data);
1603         }
1604         else
1605         {
1606                 LOG_INFOF("Received HTTP request data for an invalid id %d.", id);
1607         }
1608 }