qcsrc/client/main.qc

   1 #include "main.qh"
   2
   3 #include <common/effects/qc/all.qh>
   4 #include "hud/all.qh"
   5 #include "mapvoting.qh"
   6 #include "mutators/events.qh"
   7 #include "quickmenu.qh"
   8 #include "scoreboard.qh"
   9 #include "shownames.qh"
  10 #include <common/t_items.qh>
  11 #include "wall.qh"
  12 #include "weapons/projectile.qh"
  13 #include <common/deathtypes/all.qh>
  14 #include <common/items/all.qh>
  15 #include <common/mapinfo.qh>
  16 #include <common/minigames/cl_minigames.qh>
  17 #include <common/minigames/cl_minigames_hud.qh>
  18 #include <common/net_notice.qh>
  19 #include <common/triggers/include.qh>
  20 #include <common/vehicles/all.qh>
  21 #include <lib/csqcmodel/cl_model.qh>
  22 #include <lib/csqcmodel/interpolate.qh>
  23 #include <lib/warpzone/client.qh>
  24
  25 // --------------------------------------------------------------------------
  26 // BEGIN REQUIRED CSQC FUNCTIONS
  27 //include "main.qh"
  28
  29 #define DP_CSQC_ENTITY_REMOVE_IS_B0RKED
  30
  31 void draw_cursor(vector pos, vector ofs, string img, vector col, float a)
  32 {
  33         ofs = eX * (ofs.x * SIZE_CURSOR.x) + eY * (ofs.y * SIZE_CURSOR.y);
  34         drawpic(pos - ofs, strcat(draw_currentSkin, img), SIZE_CURSOR, col, a, DRAWFLAG_NORMAL);
  35 }
  36
  37 void draw_cursor_normal(vector pos, vector col, float a)
  38 {
  39         draw_cursor(pos, OFFSET_CURSOR, "/cursor", col, a);
  40 }
  41
  42 void LoadMenuSkinValues()
  43 {
  44         int fh = -1;
  45         if(cvar_string("menu_skin") != "")
  46         {
  47                 draw_currentSkin = strcat("gfx/menu/", cvar_string("menu_skin"));
  48                 fh = fopen(strcat(draw_currentSkin, "/skinvalues.txt"), FILE_READ);
  49         }
  50         if(fh < 0 && cvar_defstring("menu_skin") != "")
  51         {
  52                 cvar_set("menu_skin", cvar_defstring("menu_skin"));
  53                 draw_currentSkin = strcat("gfx/menu/", cvar_string("menu_skin"));
  54                 fh = fopen(strcat(draw_currentSkin, "/skinvalues.txt"), FILE_READ);
  55         }
  56         if(fh < 0)
  57         {
  58                 draw_currentSkin = "gfx/menu/default";
  59                 fh = fopen(strcat(draw_currentSkin, "/skinvalues.txt"), FILE_READ);
  60         }
  61
  62         draw_currentSkin = strzone(draw_currentSkin);
  63
  64         if(fh >= 0)
  65         {
  66                 string s;
  67                 while((s = fgets(fh)))
  68                 {
  69                         int n = tokenize_console(s);
  70                         if (n < 2)
  71                                 continue;
  72                         if(substring(argv(0), 0, 2) == "//")
  73                                 continue;
  74                         if(argv(0) == "SIZE_CURSOR")
  75                                 SIZE_CURSOR = stov(substring(s, argv_start_index(1), argv_end_index(-1) - argv_start_index(1)));
  76                         else if(argv(0) == "OFFSET_CURSOR")
  77                                 OFFSET_CURSOR = stov(substring(s, argv_start_index(1), argv_end_index(-1) - argv_start_index(1)));
  78                 }
  79                 fclose(fh);
  80         }
  81 }
  82
  83 // CSQC_Init : Called every time the CSQC code is initialized (essentially at map load)
  84 // Useful for precaching things
  85
  86 void ConsoleCommand_macro_init();
  87 void CSQC_Init()
  88 {
  89         prvm_language = strzone(cvar_string("prvm_language"));
  90
  91 #ifdef WATERMARK
  92         LOG_INFOF("^4CSQC Build information: ^1%s\n", WATERMARK);
  93 #endif
  94
  95         {
  96                 int i = 0;
  97                 for ( ; i < 255; ++i)
  98                         if (getplayerkeyvalue(i, "viewentity") == "")
  99                                 break;
 100                 maxclients = i;
 101         }
 102
 103         // needs to be done so early because of the constants they create
 104         static_init();
 105         static_init_late();
 106         static_init_precache();
 107
 108         binddb = db_create();
 109         tempdb = db_create();
 110         ClientProgsDB = db_load("client.db");
 111         compressShortVector_init();
 112
 113         draw_endBoldFont();
 114
 115         //registercommand("hud_configure");
 116         //registercommand("hud_save");
 117         //registercommand("menu_action");
 118
 119         ConsoleCommand_macro_init();
 120
 121         registercvar("hud_usecsqc", "1");
 122         registercvar("scoreboard_columns", "default");
 123
 124         registercvar("cl_nade_type", "3");
 125         registercvar("cl_pokenade_type", "zombie");
 126
 127         registercvar("cl_jumpspeedcap_min", "");
 128         registercvar("cl_jumpspeedcap_max", "");
 129
 130         registercvar("cl_multijump", "0");
 131
 132         registercvar("cl_spawn_near_teammate", "1");
 133
 134         gametype = 0;
 135
 136         // hud_fields uses strunzone on the titles!
 137         for(int i = 0; i < MAX_HUD_FIELDS; ++i)
 138                 hud_title[i] = strzone("(null)");
 139
 140         Cmd_HUD_SetFields(0);
 141
 142         postinit = false;
 143
 144         calledhooks = 0;
 145
 146         teams = Sort_Spawn();
 147         players = Sort_Spawn();
 148
 149         GetTeam(NUM_SPECTATOR, true); // add specs first
 150
 151         // precaches
 152
 153         if(autocvar_cl_reticle)
 154         {
 155                 precache_pic("gfx/reticle_normal");
 156                 // weapon reticles are precached in weapon files
 157         }
 158
 159         {
 160                 get_mi_min_max_texcoords(1); // try the CLEVER way first
 161                 minimapname = strcat("gfx/", mi_shortname, "_radar.tga");
 162                 shortmapname = mi_shortname;
 163
 164                 if (precache_pic(minimapname) == "")
 165                 {
 166                         // but maybe we have a non-clever minimap
 167                         minimapname = strcat("gfx/", mi_shortname, "_mini.tga");
 168                         if (precache_pic(minimapname) == "")
 169                                 minimapname = ""; // FAIL
 170                         else
 171                                 get_mi_min_max_texcoords(0); // load new texcoords
 172                 }
 173
 174                 mi_center = (mi_min + mi_max) * 0.5;
 175                 mi_scale = mi_max - mi_min;
 176                 minimapname = strzone(minimapname);
 177         }
 178
 179         hud_skin_path = strzone(strcat("gfx/hud/", autocvar_hud_skin));
 180         LoadMenuSkinValues();
 181 }
 182
 183 // CSQC_Shutdown : Called every time the CSQC code is shutdown (changing maps, quitting, etc)
 184 void Shutdown()
 185 {
 186         WarpZone_Shutdown();
 187
 188         remove(teams);
 189         remove(players);
 190         db_close(binddb);
 191         db_close(tempdb);
 192         if(autocvar_cl_db_saveasdump)
 193                 db_dump(ClientProgsDB, "client.db");
 194         else
 195                 db_save(ClientProgsDB, "client.db");
 196         db_close(ClientProgsDB);
 197
 198         if(camera_active)
 199                 cvar_set("chase_active",ftos(chase_active_backup));
 200
 201         // unset the event chasecam's chase_active
 202         if(autocvar_chase_active < 0)
 203                 cvar_set("chase_active", "0");
 204
 205         cvar_set("slowmo", cvar_defstring("slowmo")); // reset it back to 'default'
 206
 207         if (!isdemo())
 208         {
 209                 if (!(calledhooks & HOOK_START))
 210                         localcmd("\n_cl_hook_gamestart nop\n");
 211                 if (!(calledhooks & HOOK_END))
 212                         localcmd("\ncl_hook_gameend\n");
 213         }
 214
 215         deactivate_minigame();
 216         HUD_MinigameMenu_Close();
 217 }
 218
 219 .float has_team;
 220 float SetTeam(entity o, int Team)
 221 {
 222         devassert_once(Team);
 223         entity tm;
 224         if(teamplay)
 225         {
 226                 switch(Team)
 227                 {
 228                         case -1:
 229                         case NUM_TEAM_1:
 230                         case NUM_TEAM_2:
 231                         case NUM_TEAM_3:
 232                         case NUM_TEAM_4:
 233                                 break;
 234                         default:
 235                                 if(GetTeam(Team, false) == world)
 236                                 {
 237                                         LOG_TRACEF("trying to switch to unsupported team %d\n", Team);
 238                                         Team = NUM_SPECTATOR;
 239                                 }
 240                                 break;
 241                 }
 242         }
 243         else
 244         {
 245                 switch(Team)
 246                 {
 247                         case -1:
 248                         case 0:
 249                                 break;
 250                         default:
 251                                 if(GetTeam(Team, false) == world)
 252                                 {
 253                                         LOG_TRACEF("trying to switch to unsupported team %d\n", Team);
 254                                         Team = NUM_SPECTATOR;
 255                                 }
 256                                 break;
 257                 }
 258         }
 259         if(Team == -1) // leave
 260         {
 261                 if(o.has_team)
 262                 {
 263                         tm = GetTeam(o.team, false);
 264                         tm.team_size -= 1;
 265                         o.has_team = 0;
 266                         return true;
 267                 }
 268         }
 269         else
 270         {
 271                 if (!o.has_team)
 272                 {
 273                         o.team = Team;
 274                         tm = GetTeam(Team, true);
 275                         tm.team_size += 1;
 276                         o.has_team = 1;
 277                         return true;
 278                 }
 279                 else if(Team != o.team)
 280                 {
 281                         tm = GetTeam(o.team, false);
 282                         tm.team_size -= 1;
 283                         o.team = Team;
 284                         tm = GetTeam(Team, true);
 285                         tm.team_size += 1;
 286                         return true;
 287                 }
 288         }
 289         return false;
 290 }
 291
 292 void Playerchecker_Think()
 293 {
 294         SELFPARAM();
 295     int i;
 296         entity e;
 297         for(i = 0; i < maxclients; ++i)
 298         {
 299                 e = playerslots[i];
 300                 if(entcs_GetName(i) == "")
 301                 {
 302                         if(e.sort_prev)
 303                         {
 304                                 // player disconnected
 305                                 SetTeam(e, -1);
 306                                 RemovePlayer(e);
 307                                 e.sort_prev = world;
 308                                 //e.gotscores = 0;
 309                         }
 310                 }
 311                 else
 312                 {
 313                         if (!e.sort_prev)
 314                         {
 315                                 // player connected
 316                                 if (!e)
 317                                 {
 318                                         playerslots[i] = e = new(playerslot);
 319                                         make_pure(e);
 320                                 }
 321                                 e.sv_entnum = i;
 322                                 e.ping = 0;
 323                                 e.ping_packetloss = 0;
 324                                 e.ping_movementloss = 0;
 325                                 //e.gotscores = 0; // we might already have the scores...
 326                                 int t = entcs_GetScoreTeam(i);
 327                                 if (t) SetTeam(e, t); // will not hurt; later updates come with HUD_UpdatePlayerTeams
 328                                 RegisterPlayer(e);
 329                                 HUD_UpdatePlayerPos(e);
 330                         }
 331                 }
 332         }
 333         this.nextthink = time + 0.2;
 334 }
 335
 336 void Porto_Init();
 337 void TrueAim_Init();
 338 void PostInit()
 339 {
 340         entity playerchecker = new(playerchecker);
 341         make_pure(playerchecker);
 342         playerchecker.think = Playerchecker_Think;
 343         playerchecker.nextthink = time + 0.2;
 344
 345         Porto_Init();
 346         TrueAim_Init();
 347
 348         postinit = true;
 349 }
 350
 351 // CSQC_InputEvent : Used to perform actions based on any key pressed, key released and mouse on the client.
 352 // Return value should be 1 if CSQC handled the input, otherwise return 0 to have the input passed to the engine.
 353 // All keys are in ascii.
 354 // bInputType = 0 is key pressed, 1 is key released, 2 and 3 are mouse input.
 355 // In the case of keyboard input, nPrimary is the ascii code, and nSecondary is 0.
 356 // In the case of mouse input, nPrimary is xdelta, nSecondary is ydelta.
 357 // In the case of mouse input after a setcursormode(1) call, nPrimary is xpos, nSecondary is ypos.
 358 float CSQC_InputEvent(float bInputType, float nPrimary, float nSecondary)
 359 {
 360         if (HUD_Panel_InputEvent(bInputType, nPrimary, nSecondary))
 361                 return true;
 362
 363         if (QuickMenu_InputEvent(bInputType, nPrimary, nSecondary))
 364                 return true;
 365
 366         if (HUD_Radar_InputEvent(bInputType, nPrimary, nSecondary))
 367                 return true;
 368
 369         if (MapVote_InputEvent(bInputType, nPrimary, nSecondary))
 370                 return true;
 371
 372         if (HUD_Minigame_InputEvent(bInputType, nPrimary, nSecondary))
 373                 return true;
 374
 375         return false;
 376 }
 377
 378 // END REQUIRED CSQC FUNCTIONS
 379 // --------------------------------------------------------------------------
 380
 381 // --------------------------------------------------------------------------
 382 // BEGIN OPTIONAL CSQC FUNCTIONS
 383
 384 .void(entity) predraw_qc;
 385 void PreDraw_self()
 386 {
 387         SELFPARAM();
 388         if (this.predraw_qc) this.predraw_qc(this);
 389 }
 390
 391 void setpredraw(entity this, void(entity) pdfunc)
 392 {
 393         this.predraw = PreDraw_self;
 394         this.predraw_qc = pdfunc;
 395 }
 396
 397 void Ent_Remove(entity this);
 398
 399 void Ent_RemovePlayerScore(entity this)
 400 {
 401         if(this.owner) {
 402                 SetTeam(this.owner, -1);
 403                 this.owner.gotscores = 0;
 404                 for(int i = 0; i < MAX_SCORE; ++i) {
 405                         this.owner.(scores[i]) = 0; // clear all scores
 406                 }
 407         }
 408 }
 409
 410 NET_HANDLE(ENT_CLIENT_SCORES, bool isnew)
 411 {
 412         make_pure(this);
 413         int i, n;
 414         bool isNew;
 415         entity o;
 416
 417         // damnit -.- don't want to go change every single .sv_entnum in hud.qc AGAIN
 418         // (no I've never heard of M-x replace-string, sed, or anything like that)
 419         isNew = !this.owner; // workaround for DP bug
 420         n = ReadByte()-1;
 421
 422 #ifdef DP_CSQC_ENTITY_REMOVE_IS_B0RKED
 423         if(!isNew && n != this.sv_entnum)
 424         {
 425                 //print("A CSQC entity changed its owner!\n");
 426                 LOG_INFOF("A CSQC entity changed its owner! (edict: %d, classname: %s)\n", etof(this), this.classname);
 427                 isNew = true;
 428                 Ent_Remove(this);
 429         }
 430 #endif
 431
 432         this.sv_entnum = n;
 433
 434         o = playerslots[this.sv_entnum];
 435         if (!o)
 436         {
 437                 o = playerslots[this.sv_entnum] = new(playerslot);
 438                 make_pure(o);
 439         }
 440         this.owner = o;
 441         o.sv_entnum = this.sv_entnum;
 442         o.gotscores = 1;
 443
 444         //if (!o.sort_prev)
 445         //      RegisterPlayer(o);
 446         //playerchecker will do this for us later, if it has not already done so
 447
 448     int sf, lf;
 449 #if MAX_SCORE <= 8
 450         sf = ReadByte();
 451         lf = ReadByte();
 452 #else
 453         sf = ReadShort();
 454         lf = ReadShort();
 455 #endif
 456     int p;
 457         for(i = 0, p = 1; i < MAX_SCORE; ++i, p *= 2)
 458                 if(sf & p)
 459                 {
 460                         if(lf & p)
 461                                 o.(scores[i]) = ReadInt24_t();
 462                         else
 463                                 o.(scores[i]) = ReadChar();
 464                 }
 465
 466         return = true;
 467
 468         if(o.sort_prev)
 469                 HUD_UpdatePlayerPos(o); // if not registered, we cannot do this yet!
 470
 471         this.entremove = Ent_RemovePlayerScore;
 472 }
 473
 474 NET_HANDLE(ENT_CLIENT_TEAMSCORES, bool isnew)
 475 {
 476         make_pure(this);
 477         int i;
 478         entity o;
 479
 480         this.team = ReadByte();
 481         o = this.owner = GetTeam(this.team, true); // these team numbers can always be trusted
 482
 483     int sf, lf;
 484 #if MAX_TEAMSCORE <= 8
 485         sf = ReadByte();
 486         lf = ReadByte();
 487 #else
 488         sf = ReadShort();
 489         lf = ReadShort();
 490 #endif
 491         int p;
 492         for(i = 0, p = 1; i < MAX_TEAMSCORE; ++i, p *= 2)
 493                 if(sf & p)
 494                 {
 495                         if(lf & p)
 496                                 o.(teamscores[i]) = ReadInt24_t();
 497                         else
 498                                 o.(teamscores[i]) = ReadChar();
 499                 }
 500
 501         return = true;
 502
 503         HUD_UpdateTeamPos(o);
 504 }
 505
 506 NET_HANDLE(ENT_CLIENT_CLIENTDATA, bool isnew)
 507 {
 508         make_pure(this);
 509         float newspectatee_status;
 510
 511     int f = ReadByte();
 512
 513         scoreboard_showscores_force = (f & 1);
 514
 515         if(f & 2)
 516         {
 517                 newspectatee_status = ReadByte();
 518                 if(newspectatee_status == player_localnum + 1)
 519                         newspectatee_status = -1; // observing
 520         }
 521         else
 522                 newspectatee_status = 0;
 523
 524         spectatorbutton_zoom = (f & 4);
 525
 526         if(f & 8)
 527         {
 528                 angles_held_status = 1;
 529                 angles_held.x = ReadAngle();
 530                 angles_held.y = ReadAngle();
 531                 angles_held.z = 0;
 532         }
 533         else
 534                 angles_held_status = 0;
 535
 536         return = true;
 537
 538         if(newspectatee_status != spectatee_status)
 539         {
 540                 // clear race stuff
 541                 race_laptime = 0;
 542                 race_checkpointtime = 0;
 543         }
 544         if (autocvar_hud_panel_healtharmor_progressbar_gfx)
 545         {
 546                 if ( (spectatee_status == -1 && newspectatee_status > 0) //before observing, now spectating
 547                   || (spectatee_status > 0 && newspectatee_status > 0 && spectatee_status != newspectatee_status) //changed spectated player
 548                 )
 549                         prev_p_health = -1;
 550                 else if(spectatee_status && !newspectatee_status) //before observing/spectating, now playing
 551                         prev_health = -1;
 552         }
 553         spectatee_status = newspectatee_status;
 554
 555         // we could get rid of spectatee_status, and derive it from player_localentnum and player_localnum
 556 }
 557
 558 NET_HANDLE(ENT_CLIENT_NAGGER, bool isnew)
 559 {
 560         make_pure(this);
 561     int i, j, b, f;
 562
 563     int nags = ReadByte(); // NAGS NAGS NAGS NAGS NAGS NAGS NADZ NAGS NAGS NAGS
 564
 565         if(!(nags & BIT(2)))
 566         {
 567                 if(vote_called_vote)
 568                         strunzone(vote_called_vote);
 569                 vote_called_vote = string_null;
 570                 vote_active = 0;
 571         }
 572         else
 573         {
 574                 vote_active = 1;
 575         }
 576
 577         if(nags & BIT(6))
 578         {
 579                 vote_yescount = ReadByte();
 580                 vote_nocount = ReadByte();
 581                 vote_needed = ReadByte();
 582                 vote_highlighted = ReadChar();
 583         }
 584
 585         if(nags & BIT(7))
 586         {
 587                 if(vote_called_vote)
 588                         strunzone(vote_called_vote);
 589                 vote_called_vote = strzone(ColorTranslateRGB(ReadString()));
 590         }
 591
 592         if(nags & 1)
 593         {
 594                 for(j = 0; j < maxclients; ++j)
 595                         if(playerslots[j])
 596                                 playerslots[j].ready = 1;
 597                 for(i = 1; i <= maxclients; i += 8)
 598                 {
 599                         f = ReadByte();
 600                         for(j = i-1, b = 1; b < 256; b *= 2, ++j)
 601                                 if (!(f & b))
 602                                         if(playerslots[j])
 603                                                 playerslots[j].ready = 0;
 604                 }
 605         }
 606
 607         return = true;
 608
 609         ready_waiting = (nags & BIT(0));
 610         ready_waiting_for_me = (nags & BIT(1));
 611         vote_waiting = (nags & BIT(2));
 612         vote_waiting_for_me = (nags & BIT(3));
 613         warmup_stage = (nags & BIT(4));
 614 }
 615
 616 NET_HANDLE(ENT_CLIENT_ELIMINATEDPLAYERS, bool isnew)
 617 {
 618         make_pure(this);
 619     int i, j, b, f;
 620
 621     int sf = ReadByte();
 622         if(sf & 1)
 623         {
 624                 for(j = 0; j < maxclients; ++j)
 625                         if(playerslots[j])
 626                                 playerslots[j].eliminated = 1;
 627                 for(i = 1; i <= maxclients; i += 8)
 628                 {
 629                         f = ReadByte();
 630                         for(j = i-1, b = 1; b < 256; b *= 2, ++j)
 631                                 if (!(f & b))
 632                                         if(playerslots[j])
 633                                                 playerslots[j].eliminated = 0;
 634                 }
 635         }
 636         return true;
 637 }
 638
 639 NET_HANDLE(ENT_CLIENT_RANDOMSEED, bool isnew)
 640 {
 641         make_pure(this);
 642         prandom_debug();
 643         float s = ReadShort();
 644         psrandom(s);
 645         return true;
 646 }
 647
 648 NET_HANDLE(ENT_CLIENT_ACCURACY, bool isnew)
 649 {
 650         make_pure(this);
 651     int sf = ReadInt24_t();
 652         if (sf == 0) {
 653                 for (int w = 0; w <= WEP_LAST - WEP_FIRST; ++w)
 654                         weapon_accuracy[w] = -1;
 655                 return true;
 656         }
 657
 658         int f = 1;
 659         for (int w = 0; w <= WEP_LAST - WEP_FIRST; ++w) {
 660                 if (sf & f) {
 661             int b = ReadByte();
 662                         if (b == 0)
 663                                 weapon_accuracy[w] = -1;
 664                         else if (b == 255)
 665                                 weapon_accuracy[w] = 1.0; // no better error handling yet, sorry
 666                         else
 667                                 weapon_accuracy[w] = (b - 1.0) / 100.0;
 668                 }
 669                 f = (f == 0x800000) ? 1 : f * 2;
 670         }
 671         return true;
 672 }
 673
 674 void Spawn_Draw(entity this)
 675 {
 676         __pointparticles(this.cnt, this.origin + '0 0 28', '0 0 2', bound(0, frametime, 0.1));
 677 }
 678
 679 NET_HANDLE(ENT_CLIENT_SPAWNPOINT, bool is_new)
 680 {
 681         float teamnum = (ReadByte() - 1);
 682         vector spn_origin;
 683         spn_origin.x = ReadShort();
 684         spn_origin.y = ReadShort();
 685         spn_origin.z = ReadShort();
 686
 687         //if(is_new)
 688         //{
 689                 this.origin = spn_origin;
 690                 setsize(this, PL_MIN_CONST, PL_MAX_CONST);
 691                 //droptofloor();
 692
 693                 /*if(autocvar_cl_spawn_point_model) // needs a model first
 694                 {
 695                         this.mdl = "models/spawnpoint.md3";
 696                         this.colormod = Team_ColorRGB(teamnum);
 697                         precache_model(this.mdl);
 698                         setmodel(this, this.mdl);
 699                         this.drawmask = MASK_NORMAL;
 700                         //this.movetype = MOVETYPE_NOCLIP;
 701                         //this.draw = Spawn_Draw;
 702                 }*/
 703                 if(autocvar_cl_spawn_point_particles)
 704                 {
 705                         if((serverflags & SERVERFLAG_TEAMPLAY))
 706                         {
 707                                 switch(teamnum)
 708                                 {
 709                                         case NUM_TEAM_1: this.cnt = particleeffectnum(EFFECT_SPAWNPOINT_RED); break;
 710                                         case NUM_TEAM_2: this.cnt = particleeffectnum(EFFECT_SPAWNPOINT_BLUE); break;
 711                                         case NUM_TEAM_3: this.cnt = particleeffectnum(EFFECT_SPAWNPOINT_YELLOW); break;
 712                                         case NUM_TEAM_4: this.cnt = particleeffectnum(EFFECT_SPAWNPOINT_PINK); break;
 713                                         default: this.cnt = particleeffectnum(EFFECT_SPAWNPOINT_NEUTRAL); break;
 714                                 }
 715                         }
 716                         else { this.cnt = particleeffectnum(EFFECT_SPAWNPOINT_NEUTRAL); }
 717
 718                         this.draw = Spawn_Draw;
 719                 }
 720         //}
 721
 722         //printf("Ent_ReadSpawnPoint(is_new = %d); origin = %s, team = %d, effect = %d\n", is_new, vtos(this.origin), teamnum, this.cnt);
 723         return true;
 724 }
 725
 726 NET_HANDLE(ENT_CLIENT_SPAWNEVENT, bool is_new)
 727 {
 728         // If entnum is 0, ONLY do the local spawn actions
 729         // this way the server can disable the sending of
 730         // spawn origin or such to clients if wanted.
 731         float entnum = ReadByte();
 732
 733         if(entnum)
 734         {
 735                 this.origin_x = ReadShort();
 736                 this.origin_y = ReadShort();
 737                 this.origin_z = ReadShort();
 738
 739                 if(is_new)
 740                 {
 741                         float teamnum = entcs_GetTeam(entnum - 1);
 742
 743                         if(autocvar_cl_spawn_event_particles)
 744                         {
 745                                 switch(teamnum)
 746                                 {
 747                                         case NUM_TEAM_1: pointparticles(EFFECT_SPAWN_RED, this.origin, '0 0 0', 1); break;
 748                                         case NUM_TEAM_2: pointparticles(EFFECT_SPAWN_BLUE, this.origin, '0 0 0', 1); break;
 749                                         case NUM_TEAM_3: pointparticles(EFFECT_SPAWN_YELLOW, this.origin, '0 0 0', 1); break;
 750                                         case NUM_TEAM_4: pointparticles(EFFECT_SPAWN_PINK, this.origin, '0 0 0', 1); break;
 751                                         default: pointparticles(EFFECT_SPAWN_NEUTRAL, this.origin, '0 0 0', 1); break;
 752                                 }
 753                         }
 754                         if(autocvar_cl_spawn_event_sound)
 755                         {
 756                                 sound(this, CH_TRIGGER, SND_SPAWN, VOL_BASE, ATTEN_NORM);
 757                         }
 758                 }
 759         }
 760         return = true;
 761
 762         // local spawn actions
 763         if(is_new && (!entnum || (entnum == player_localentnum)))
 764         {
 765                 zoomin_effect = 1;
 766                 current_viewzoom = (1 / bound(1, autocvar_cl_spawnzoom_factor, 16));
 767
 768                 if(autocvar_cl_unpress_zoom_on_spawn)
 769                 {
 770                         localcmd("-zoom\n");
 771                         button_zoom = false;
 772                 }
 773         }
 774         HUD_Radar_Hide_Maximized();
 775         //printf("Ent_ReadSpawnEvent(is_new = %d); origin = %s, entnum = %d, localentnum = %d\n", is_new, vtos(this.origin), entnum, player_localentnum);
 776 }
 777
 778 // CSQC_Ent_Update : Called every frame that the server has indicated an update to the SSQC / CSQC entity has occured.
 779 // The only parameter reflects if the entity is "new" to the client, meaning it just came into the client's PVS.
 780 void CSQC_Ent_Update(bool isnew)
 781 {
 782         SELFPARAM();
 783         this.sourceLoc = __FILE__ ":" STR(__LINE__);
 784         int t = ReadByte();
 785
 786         // set up the "time" global for received entities to be correct for interpolation purposes
 787         float savetime = time;
 788         if(servertime)
 789         {
 790                 time = servertime;
 791         }
 792         else
 793         {
 794                 serverprevtime = time;
 795                 serverdeltatime = STAT(MOVEVARS_TICRATE) * STAT(MOVEVARS_TIMESCALE);
 796                 time = serverprevtime + serverdeltatime;
 797         }
 798
 799 #ifdef DP_CSQC_ENTITY_REMOVE_IS_B0RKED
 800         if (this.enttype)
 801         {
 802                 if (t != this.enttype || isnew)
 803                 {
 804                         LOG_INFOF("A CSQC entity changed its type! (edict: %d, server: %d, type: %d -> %d)\n", etof(this), this.entnum, this.enttype, t);
 805                         Ent_Remove(this);
 806                         clearentity(this);
 807                         isnew = true;
 808                 }
 809         }
 810         else
 811         {
 812                 if (!isnew)
 813                 {
 814                         LOG_INFOF("A CSQC entity appeared out of nowhere! (edict: %d, server: %d, type: %d)\n", etof(this), this.entnum, t);
 815                         isnew = true;
 816                 }
 817         }
 818 #endif
 819         this.enttype = t;
 820         bool done = false;
 821         FOREACH(LinkedEntities, it.m_id == t, LAMBDA(
 822                 if (isnew) this.classname = it.netname;
 823                 if (autocvar_developer_csqcentities)
 824             LOG_INFOF("CSQC_Ent_Update(%d) at %f with this=%i {.entnum=%d, .enttype=%d} t=%s (%d)\n", isnew, savetime, this, this.entnum, this.enttype, this.classname, t);
 825                 done = it.m_read(this, NULL, isnew);
 826                 break;
 827         ));
 828         time = savetime;
 829         if (!done)
 830         {
 831                 LOG_FATALF("CSQC_Ent_Update(%d) at %f with this=%i {.entnum=%d, .enttype=%d} t=%s (%d)\n", isnew, savetime, this, this.entnum, this.enttype, this.classname, t);
 832         }
 833 }
 834
 835 // Destructor, but does NOT deallocate the entity by calling remove(). Also
 836 // used when an entity changes its type. For an entity that someone interacts
 837 // with others, make sure it can no longer do so.
 838 void Ent_Remove(entity this)
 839 {
 840         if(this.entremove) this.entremove(this);
 841
 842         if(this.skeletonindex)
 843         {
 844                 skel_delete(this.skeletonindex);
 845                 this.skeletonindex = 0;
 846         }
 847
 848         if(this.snd_looping > 0)
 849         {
 850                 sound(this, this.snd_looping, SND_Null, VOL_BASE, autocvar_g_jetpack_attenuation);
 851                 this.snd_looping = 0;
 852         }
 853
 854         this.enttype = 0;
 855         this.classname = "";
 856         this.draw = func_null;
 857         this.entremove = func_null;
 858         // TODO possibly set more stuff to defaults
 859 }
 860 // CSQC_Ent_Remove : Called when the server requests a SSQC / CSQC entity to be removed.  Essentially call remove(this) as well.
 861 void CSQC_Ent_Remove()
 862 {
 863         SELFPARAM();
 864         if (autocvar_developer_csqcentities) LOG_INFOF("CSQC_Ent_Remove() with this=%i {.entnum=%d, .enttype=%d}\n", this, this.entnum, this.enttype);
 865         if (wasfreed(this))
 866         {
 867                 LOG_WARNING("CSQC_Ent_Remove called for already removed entity. Packet loss?\n");
 868                 return;
 869         }
 870         if (this.enttype) Ent_Remove(this);
 871         remove(this);
 872 }
 873
 874 void Gamemode_Init()
 875 {
 876         if (!isdemo())
 877         {
 878                 if(!(calledhooks & HOOK_START))
 879                         localcmd("\n_cl_hook_gamestart ", MapInfo_Type_ToString(gametype), "\n");
 880                 calledhooks |= HOOK_START;
 881         }
 882 }
 883 // CSQC_Parse_StuffCmd : Provides the stuffcmd string in the first parameter that the server provided.  To execute standard behavior, simply execute localcmd with the string.
 884 void CSQC_Parse_StuffCmd(string strMessage)
 885 {
 886         if (autocvar_developer_csqcentities) LOG_INFOF("CSQC_Parse_StuffCmd(\"%s\")\n", strMessage);
 887         localcmd(strMessage);
 888 }
 889 // CSQC_Parse_Print : Provides the print string in the first parameter that the server provided.  To execute standard behavior, simply execute print with the string.
 890 void CSQC_Parse_Print(string strMessage)
 891 {
 892         if (autocvar_developer_csqcentities) LOG_INFOF("CSQC_Parse_Print(\"%s\")\n", strMessage);
 893         print(ColorTranslateRGB(strMessage));
 894 }
 895
 896 // CSQC_Parse_CenterPrint : Provides the centerprint_hud string in the first parameter that the server provided.
 897 void CSQC_Parse_CenterPrint(string strMessage)
 898 {
 899         if (autocvar_developer_csqcentities) LOG_INFOF("CSQC_Parse_CenterPrint(\"%s\")\n", strMessage);
 900         centerprint_hud(strMessage);
 901 }
 902
 903 // CSQC_Parse_TempEntity : Handles all temporary entity network data in the CSQC layer.
 904 // You must ALWAYS first acquire the temporary ID, which is sent as a byte.
 905 // Return value should be 1 if CSQC handled the temporary entity, otherwise return 0 to have the engine process the event.
 906 bool CSQC_Parse_TempEntity()
 907 {
 908         // Acquire TE ID
 909         int nTEID = ReadByte();
 910
 911         FOREACH(TempEntities, it.m_id == nTEID, LAMBDA(
 912                 if (autocvar_developer_csqcentities)
 913                         LOG_INFOF("CSQC_Parse_TempEntity() nTEID=%s (%d)\n", it.netname, nTEID);
 914                 return it.m_read(NULL, NULL, true);
 915         ));
 916
 917         if (autocvar_developer_csqcentities)
 918                 LOG_INFOF("CSQC_Parse_TempEntity() with nTEID=%d\n", nTEID);
 919
 920         // No special logic for this temporary entity; return 0 so the engine can handle it
 921         return false;
 922 }
 923
 924 /** TODO somehow thwart prvm_globalset client ... */
 925 string forcefog;
 926 void Fog_Force()
 927 {
 928         if (autocvar_cl_orthoview && autocvar_cl_orthoview_nofog)
 929                 localcmd("\nr_drawfog 0\n");
 930         else if (forcefog != "")
 931                 localcmd(sprintf("\nfog %s\nr_fog_exp2 0\nr_drawfog 1\n", forcefog));
 932 }
 933
 934 void Gamemode_Init();
 935 NET_HANDLE(ENT_CLIENT_SCORES_INFO, bool isnew)
 936 {
 937         make_pure(this);
 938         gametype = ReadInt24_t();
 939         HUD_ModIcons_SetFunc();
 940         for (int i = 0; i < MAX_SCORE; ++i)
 941         {
 942                 if (scores_label[i]) strunzone(scores_label[i]);
 943                 scores_label[i] = strzone(ReadString());
 944                 scores_flags[i] = ReadByte();
 945         }
 946         for (int i = 0; i < MAX_TEAMSCORE; ++i)
 947         {
 948                 if (teamscores_label[i]) strunzone(teamscores_label[i]);
 949                 teamscores_label[i] = strzone(ReadString());
 950                 teamscores_flags[i] = ReadByte();
 951         }
 952         return = true;
 953         HUD_InitScores();
 954         Gamemode_Init();
 955 }
 956
 957 NET_HANDLE(ENT_CLIENT_INIT, bool isnew)
 958 {
 959         nb_pb_period = ReadByte() / 32; //Accuracy of 1/32th
 960
 961         hook_shotorigin[0] = decompressShotOrigin(ReadInt24_t());
 962         hook_shotorigin[1] = decompressShotOrigin(ReadInt24_t());
 963         hook_shotorigin[2] = decompressShotOrigin(ReadInt24_t());
 964         hook_shotorigin[3] = decompressShotOrigin(ReadInt24_t());
 965         arc_shotorigin[0] = decompressShotOrigin(ReadInt24_t());
 966         arc_shotorigin[1] = decompressShotOrigin(ReadInt24_t());
 967         arc_shotorigin[2] = decompressShotOrigin(ReadInt24_t());
 968         arc_shotorigin[3] = decompressShotOrigin(ReadInt24_t());
 969
 970         if (forcefog) strunzone(forcefog);
 971         forcefog = strzone(ReadString());
 972
 973         armorblockpercent = ReadByte() / 255.0;
 974
 975         serverflags = ReadByte();
 976
 977         g_trueaim_minrange = ReadCoord();
 978
 979         return = true;
 980
 981         MUTATOR_CALLHOOK(Ent_Init);
 982
 983         if (!postinit) PostInit();
 984 }
 985
 986 NET_HANDLE(TE_CSQC_RACE, bool isNew)
 987 {
 988         int b = ReadByte();
 989
 990         switch (b)
 991         {
 992                 case RACE_NET_CHECKPOINT_HIT_QUALIFYING:
 993                         race_checkpoint = ReadByte();
 994                         race_time = ReadInt24_t();
 995                         race_previousbesttime = ReadInt24_t();
 996                         if(race_previousbestname)
 997                                 strunzone(race_previousbestname);
 998                         race_previousbestname = strzone(ColorTranslateRGB(ReadString()));
 999
1000                         race_checkpointtime = time;
1001
1002                         if(race_checkpoint == 0 || race_checkpoint == 254)
1003                         {
1004                                 race_penaltyaccumulator = 0;
1005                                 race_laptime = time; // valid
1006                         }
1007
1008                         break;
1009
1010                 case RACE_NET_CHECKPOINT_CLEAR:
1011                         race_laptime = 0;
1012                         race_checkpointtime = 0;
1013                         break;
1014
1015                 case RACE_NET_CHECKPOINT_NEXT_SPEC_QUALIFYING:
1016                         race_laptime = ReadCoord();
1017                         race_checkpointtime = -99999;
1018                         // fall through
1019                 case RACE_NET_CHECKPOINT_NEXT_QUALIFYING:
1020                         race_nextcheckpoint = ReadByte();
1021
1022                         race_nextbesttime = ReadInt24_t();
1023                         if(race_nextbestname)
1024                                 strunzone(race_nextbestname);
1025                         race_nextbestname = strzone(ColorTranslateRGB(ReadString()));
1026                         break;
1027
1028                 case RACE_NET_CHECKPOINT_HIT_RACE:
1029                         race_mycheckpoint = ReadByte();
1030                         race_mycheckpointtime = time;
1031                         race_mycheckpointdelta = ReadInt24_t();
1032                         race_mycheckpointlapsdelta = ReadByte();
1033                         if(race_mycheckpointlapsdelta >= 128)
1034                                 race_mycheckpointlapsdelta -= 256;
1035                         if(race_mycheckpointenemy)
1036                                 strunzone(race_mycheckpointenemy);
1037                         race_mycheckpointenemy = strzone(ColorTranslateRGB(ReadString()));
1038                         break;
1039
1040                 case RACE_NET_CHECKPOINT_HIT_RACE_BY_OPPONENT:
1041                         race_othercheckpoint = ReadByte();
1042                         race_othercheckpointtime = time;
1043                         race_othercheckpointdelta = ReadInt24_t();
1044                         race_othercheckpointlapsdelta = ReadByte();
1045                         if(race_othercheckpointlapsdelta >= 128)
1046                                 race_othercheckpointlapsdelta -= 256;
1047                         if(race_othercheckpointenemy)
1048                                 strunzone(race_othercheckpointenemy);
1049                         race_othercheckpointenemy = strzone(ColorTranslateRGB(ReadString()));
1050                         break;
1051
1052                 case RACE_NET_PENALTY_RACE:
1053                         race_penaltyeventtime = time;
1054                         race_penaltytime = ReadShort();
1055                         //race_penaltyaccumulator += race_penaltytime;
1056                         if(race_penaltyreason)
1057                                 strunzone(race_penaltyreason);
1058                         race_penaltyreason = strzone(ReadString());
1059                         break;
1060
1061                 case RACE_NET_PENALTY_QUALIFYING:
1062                         race_penaltyeventtime = time;
1063                         race_penaltytime = ReadShort();
1064                         race_penaltyaccumulator += race_penaltytime;
1065                         if(race_penaltyreason)
1066                                 strunzone(race_penaltyreason);
1067                         race_penaltyreason = strzone(ReadString());
1068                         break;
1069
1070                 case RACE_NET_SERVER_RECORD:
1071                         race_server_record = ReadInt24_t();
1072                         break;
1073                 case RACE_NET_SPEED_AWARD:
1074                         race_speedaward = ReadInt24_t();
1075                         if(race_speedaward_holder)
1076                                 strunzone(race_speedaward_holder);
1077                         race_speedaward_holder = strzone(ReadString());
1078                         break;
1079                 case RACE_NET_SPEED_AWARD_BEST:
1080                         race_speedaward_alltimebest = ReadInt24_t();
1081                         if(race_speedaward_alltimebest_holder)
1082                                 strunzone(race_speedaward_alltimebest_holder);
1083                         race_speedaward_alltimebest_holder = strzone(ReadString());
1084                         break;
1085                 case RACE_NET_SERVER_RANKINGS:
1086                         float prevpos, del;
1087             int pos = ReadShort();
1088                         prevpos = ReadShort();
1089                         del = ReadShort();
1090
1091                         // move other rankings out of the way
1092             int i;
1093                         if (prevpos) {
1094                                 for (i=prevpos-1;i>pos-1;--i) {
1095                                         grecordtime[i] = grecordtime[i-1];
1096                                         if(grecordholder[i])
1097                                                 strunzone(grecordholder[i]);
1098                                         grecordholder[i] = strzone(grecordholder[i-1]);
1099                                 }
1100                         } else if (del) { // a record has been deleted by the admin
1101                                 for (i=pos-1; i<= RANKINGS_CNT-1; ++i) {
1102                                         if (i == RANKINGS_CNT-1) { // clear out last record
1103                                                 grecordtime[i] = 0;
1104                                                 if (grecordholder[i])
1105                                                         strunzone(grecordholder[i]);
1106                                                 grecordholder[i] = string_null;
1107                                         }
1108                                         else {
1109                                                 grecordtime[i] = grecordtime[i+1];
1110                                                 if (grecordholder[i])
1111                                                         strunzone(grecordholder[i]);
1112                                                 grecordholder[i] = strzone(grecordholder[i+1]);
1113                                         }
1114                                 }
1115                         } else { // player has no ranked record yet
1116                                 for (i=RANKINGS_CNT-1;i>pos-1;--i) {
1117                                         grecordtime[i] = grecordtime[i-1];
1118                                         if(grecordholder[i])
1119                                                 strunzone(grecordholder[i]);
1120                                         grecordholder[i] = strzone(grecordholder[i-1]);
1121                                 }
1122                         }
1123
1124                         // store new ranking
1125                         if(grecordholder[pos-1] != "")
1126                                 strunzone(grecordholder[pos-1]);
1127                         grecordholder[pos-1] = strzone(ReadString());
1128                         grecordtime[pos-1] = ReadInt24_t();
1129                         if(grecordholder[pos-1] == entcs_GetName(player_localnum))
1130                                 race_myrank = pos;
1131                         break;
1132                 case RACE_NET_SERVER_STATUS:
1133                         race_status = ReadShort();
1134                         if(race_status_name)
1135                                 strunzone(race_status_name);
1136                         race_status_name = strzone(ReadString());
1137         }
1138         return true;
1139 }
1140
1141 NET_HANDLE(TE_CSQC_TEAMNAGGER, bool isNew)
1142 {
1143         teamnagger = 1;
1144         return true;
1145 }
1146
1147 NET_HANDLE(TE_CSQC_PINGPLREPORT, bool isNew)
1148 {
1149         int i = ReadByte();
1150         int pi = ReadShort();
1151         int pl = ReadByte();
1152         int ml = ReadByte();
1153         return = true;
1154         entity e = playerslots[i];
1155         if (!e) return;
1156         e.ping = pi;
1157         e.ping_packetloss = pl / 255.0;
1158         e.ping_movementloss = ml / 255.0;
1159 }
1160
1161 NET_HANDLE(TE_CSQC_WEAPONCOMPLAIN, bool isNew)
1162 {
1163         complain_weapon = ReadByte();
1164         complain_weapon_type = ReadByte();
1165         return = true;
1166
1167         complain_weapon_time = time;
1168         weapontime = time; // ping the weapon panel
1169
1170         switch(complain_weapon_type)
1171         {
1172                 case 0: Local_Notification(MSG_MULTI, ITEM_WEAPON_NOAMMO, complain_weapon); break;
1173                 case 1: Local_Notification(MSG_MULTI, ITEM_WEAPON_DONTHAVE, complain_weapon); break;
1174                 default: Local_Notification(MSG_MULTI, ITEM_WEAPON_UNAVAILABLE, complain_weapon); break;
1175         }
1176 }
1177
1178 string getcommandkey(string text, string command)
1179 {
1180         string keys;
1181         float n, j, k, l = 0;
1182
1183         if (!autocvar_hud_showbinds)
1184                 return text;
1185
1186         keys = db_get(binddb, command);
1187         if (keys == "")
1188         {
1189                 n = tokenize(findkeysforcommand(command, 0)); // uses '...' strings
1190                 for(j = 0; j < n; ++j)
1191                 {
1192                         k = stof(argv(j));
1193                         if(k != -1)
1194                         {
1195                                 if ("" == keys)
1196                                         keys = keynumtostring(k);
1197                                 else
1198                                         keys = strcat(keys, ", ", keynumtostring(k));
1199
1200                                 ++l;
1201                                 if (autocvar_hud_showbinds_limit > 0 && autocvar_hud_showbinds_limit <= l)
1202                                         break;
1203                         }
1204
1205                 }
1206                 if (keys == "")
1207                         keys = "NO_KEY";
1208                 db_put(binddb, command, keys);
1209         }
1210
1211         if (keys == "NO_KEY") {
1212                 if (autocvar_hud_showbinds > 1)
1213                         return sprintf(_("%s (not bound)"), text);
1214                 else
1215                         return text;
1216         }
1217         else if (autocvar_hud_showbinds > 1)
1218                 return sprintf("%s (%s)", text, keys);
1219         else
1220                 return keys;
1221 }