qcsrc/client/main.qc

   1 #include "main.qh"
   2
   3 #include "defs.qh"
   4 #include <common/ent_cs.qh>
   5 #include "miscfunctions.qh"
   6 #include <common/effects/effect.qh>
   7 #include <common/effects/qc/_mod.qh>
   8 #include <common/effects/all.qh>
   9 #include <common/effects/all.inc>
  10 #include "hud/_mod.qh"
  11 #include "mapvoting.qh"
  12 #include "mutators/events.qh"
  13 #include "hud/panel/scoreboard.qh"
  14 #include "hud/panel/quickmenu.qh"
  15 #include "shownames.qh"
  16 #include <common/t_items.qh>
  17 #include "wall.qh"
  18 #include "weapons/projectile.qh"
  19 #include <common/deathtypes/all.qh>
  20 #include <common/items/_mod.qh>
  21 #include <common/mapinfo.qh>
  22 #include <common/minigames/cl_minigames.qh>
  23 #include <common/minigames/cl_minigames_hud.qh>
  24 #include <common/net_linked.qh>
  25 #include <common/net_notice.qh>
  26 #include <common/scores.qh>
  27 #include <common/triggers/include.qh>
  28 #include <common/vehicles/all.qh>
  29 #include <lib/csqcmodel/cl_model.qh>
  30 #include <lib/csqcmodel/interpolate.qh>
  31 #include <lib/warpzone/client.qh>
  32
  33 // --------------------------------------------------------------------------
  34 // BEGIN REQUIRED CSQC FUNCTIONS
  35 //include "main.qh"
  36
  37 #define DP_CSQC_ENTITY_REMOVE_IS_B0RKED
  38
  39 void draw_cursor(vector pos, vector ofs, string img, vector col, float a)
  40 {
  41         ofs = vec2(ofs.x * SIZE_CURSOR.x, ofs.y * SIZE_CURSOR.y);
  42         drawpic(pos - ofs, strcat(draw_currentSkin, img), SIZE_CURSOR, col, a, DRAWFLAG_NORMAL);
  43 }
  44
  45 void draw_cursor_normal(vector pos, vector col, float a)
  46 {
  47         draw_cursor(pos, OFFSET_CURSOR, "/cursor", col, a);
  48 }
  49
  50 void LoadMenuSkinValues()
  51 {
  52         int fh = -1;
  53         if(cvar_string("menu_skin") != "")
  54         {
  55                 draw_currentSkin = strcat("gfx/menu/", cvar_string("menu_skin"));
  56                 fh = fopen(strcat(draw_currentSkin, "/skinvalues.txt"), FILE_READ);
  57         }
  58         if(fh < 0 && cvar_defstring("menu_skin") != "")
  59         {
  60                 cvar_set("menu_skin", cvar_defstring("menu_skin"));
  61                 draw_currentSkin = strcat("gfx/menu/", cvar_string("menu_skin"));
  62                 fh = fopen(strcat(draw_currentSkin, "/skinvalues.txt"), FILE_READ);
  63         }
  64         if(fh < 0)
  65         {
  66                 draw_currentSkin = "gfx/menu/default";
  67                 fh = fopen(strcat(draw_currentSkin, "/skinvalues.txt"), FILE_READ);
  68         }
  69
  70         draw_currentSkin = strzone(draw_currentSkin);
  71
  72         if(fh >= 0)
  73         {
  74                 string s;
  75                 while((s = fgets(fh)))
  76                 {
  77                         int n = tokenize_console(s);
  78                         if (n < 2)
  79                                 continue;
  80                         if(substring(argv(0), 0, 2) == "//")
  81                                 continue;
  82                         if(argv(0) == "SIZE_CURSOR")
  83                                 SIZE_CURSOR = stov(substring(s, argv_start_index(1), argv_end_index(-1) - argv_start_index(1)));
  84                         else if(argv(0) == "OFFSET_CURSOR")
  85                                 OFFSET_CURSOR = stov(substring(s, argv_start_index(1), argv_end_index(-1) - argv_start_index(1)));
  86                 }
  87                 fclose(fh);
  88         }
  89 }
  90
  91 // CSQC_Init : Called every time the CSQC code is initialized (essentially at map load)
  92 // Useful for precaching things
  93
  94 void ConsoleCommand_macro_init();
  95 void CSQC_Init()
  96 {
  97         prvm_language = strzone(cvar_string("prvm_language"));
  98
  99 #ifdef WATERMARK
 100         LOG_INFOF("^4CSQC Build information: ^1%s", WATERMARK);
 101 #endif
 102
 103         {
 104                 int i = 0;
 105                 for ( ; i < 255; ++i)
 106                         if (getplayerkeyvalue(i, "viewentity") == "")
 107                                 break;
 108                 maxclients = i;
 109         }
 110
 111         // needs to be done so early because of the constants they create
 112         static_init();
 113         static_init_late();
 114         static_init_precache();
 115
 116         binddb = db_create();
 117         tempdb = db_create();
 118         ClientProgsDB = db_load("client.db");
 119
 120         draw_endBoldFont();
 121
 122         //registercommand("hud_configure");
 123         //registercommand("hud_save");
 124         //registercommand("menu_action");
 125
 126         ConsoleCommand_macro_init();
 127
 128         registercvar("hud_usecsqc", "1");
 129         registercvar("scoreboard_columns", "default");
 130
 131         registercvar("cl_nade_type", "3");
 132         registercvar("cl_pokenade_type", "zombie");
 133
 134         registercvar("cl_jumpspeedcap_min", "");
 135         registercvar("cl_jumpspeedcap_max", "");
 136
 137         registercvar("cl_multijump", "1");
 138
 139         registercvar("cl_spawn_near_teammate", "1");
 140
 141         if(autocvar_cl_lockview)
 142                 cvar_set("cl_lockview", "0");
 143
 144         gametype = NULL;
 145
 146         postinit = false;
 147
 148         calledhooks = 0;
 149
 150         teams = Sort_Spawn();
 151         players = Sort_Spawn();
 152
 153         GetTeam(NUM_SPECTATOR, true); // add specs first
 154
 155         for (int w = 0; w <= WEP_LAST - WEP_FIRST; ++w)
 156                 weapon_accuracy[w] = -1;
 157
 158         // precaches
 159
 160         if(autocvar_cl_reticle)
 161         {
 162                 precache_pic("gfx/reticle_normal");
 163                 // weapon reticles are precached in weapon files
 164         }
 165
 166         {
 167                 get_mi_min_max_texcoords(1); // try the CLEVER way first
 168                 minimapname = strcat("gfx/", mi_shortname, "_radar.tga");
 169                 shortmapname = mi_shortname;
 170
 171                 if (precache_pic(minimapname) == "")
 172                 {
 173                         // but maybe we have a non-clever minimap
 174                         minimapname = strcat("gfx/", mi_shortname, "_mini.tga");
 175                         if (precache_pic(minimapname) == "")
 176                                 minimapname = ""; // FAIL
 177                         else
 178                                 get_mi_min_max_texcoords(0); // load new texcoords
 179                 }
 180
 181                 mi_center = (mi_min + mi_max) * 0.5;
 182                 mi_scale = mi_max - mi_min;
 183                 minimapname = strzone(minimapname);
 184         }
 185
 186         hud_skin_path = strzone(strcat("gfx/hud/", autocvar_hud_skin));
 187         LoadMenuSkinValues();
 188 }
 189
 190 // CSQC_Shutdown : Called every time the CSQC code is shutdown (changing maps, quitting, etc)
 191 void Shutdown()
 192 {
 193         WarpZone_Shutdown();
 194
 195         delete(teams);
 196         delete(players);
 197         db_close(binddb);
 198         db_close(tempdb);
 199         if(autocvar_cl_db_saveasdump)
 200                 db_dump(ClientProgsDB, "client.db");
 201         else
 202                 db_save(ClientProgsDB, "client.db");
 203         db_close(ClientProgsDB);
 204
 205         if(camera_active)
 206                 cvar_set("chase_active",ftos(chase_active_backup));
 207
 208         // unset the event chasecam's chase_active
 209         if(autocvar_chase_active < 0)
 210                 cvar_set("chase_active", "0");
 211
 212         cvar_set("slowmo", cvar_defstring("slowmo")); // reset it back to 'default'
 213
 214         if (!isdemo())
 215         {
 216                 if (!(calledhooks & HOOK_START))
 217                         localcmd("\n_cl_hook_gamestart nop\n");
 218                 if (!(calledhooks & HOOK_END))
 219                         localcmd("\ncl_hook_gameend\n");
 220         }
 221
 222         localcmd("\ncl_hook_shutdown\n");
 223
 224         deactivate_minigame();
 225         HUD_MinigameMenu_Close(NULL, NULL, NULL);
 226 }
 227
 228 .float has_team;
 229 float SetTeam(entity o, int Team)
 230 {
 231     TC(int, Team);
 232         devassert_once(Team);
 233         entity tm;
 234         if(teamplay)
 235         {
 236                 switch(Team)
 237                 {
 238                         case -1:
 239                         case NUM_TEAM_1:
 240                         case NUM_TEAM_2:
 241                         case NUM_TEAM_3:
 242                         case NUM_TEAM_4:
 243                                 break;
 244                         default:
 245                                 if(GetTeam(Team, false) == NULL)
 246                                 {
 247                                         LOG_TRACEF("trying to switch to unsupported team %d", Team);
 248                                         Team = NUM_SPECTATOR;
 249                                 }
 250                                 break;
 251                 }
 252         }
 253         else
 254         {
 255                 switch(Team)
 256                 {
 257                         case -1:
 258                         case 0:
 259                                 break;
 260                         default:
 261                                 if(GetTeam(Team, false) == NULL)
 262                                 {
 263                                         LOG_TRACEF("trying to switch to unsupported team %d", Team);
 264                                         Team = NUM_SPECTATOR;
 265                                 }
 266                                 break;
 267                 }
 268         }
 269         if(Team == -1) // leave
 270         {
 271                 if(o.has_team)
 272                 {
 273                         tm = GetTeam(o.team, false);
 274                         tm.team_size -= 1;
 275                         o.has_team = 0;
 276                         return true;
 277                 }
 278         }
 279         else
 280         {
 281                 if (!o.has_team)
 282                 {
 283                         o.team = Team;
 284                         tm = GetTeam(Team, true);
 285                         tm.team_size += 1;
 286                         o.has_team = 1;
 287                         return true;
 288                 }
 289                 else if(Team != o.team)
 290                 {
 291                         tm = GetTeam(o.team, false);
 292                         tm.team_size -= 1;
 293                         o.team = Team;
 294                         tm = GetTeam(Team, true);
 295                         tm.team_size += 1;
 296                         return true;
 297                 }
 298         }
 299         return false;
 300 }
 301
 302 void Playerchecker_Think(entity this)
 303 {
 304     int i;
 305         entity e;
 306         for(i = 0; i < maxclients; ++i)
 307         {
 308                 e = playerslots[i];
 309                 if(entcs_GetName(i) == "")
 310                 {
 311                         if(e.sort_prev)
 312                         {
 313                                 // player disconnected
 314                                 SetTeam(e, -1);
 315                                 RemovePlayer(e);
 316                                 e.sort_prev = NULL;
 317                                 //e.gotscores = 0;
 318                         }
 319                 }
 320                 else
 321                 {
 322                         if (!e.sort_prev)
 323                         {
 324                                 // player connected
 325                                 if (!e)
 326                                 {
 327                                         playerslots[i] = e = new_pure(playerslot);
 328                                 }
 329                                 e.sv_entnum = i;
 330                                 e.ping = 0;
 331                                 e.ping_packetloss = 0;
 332                                 e.ping_movementloss = 0;
 333                                 //e.gotscores = 0; // we might already have the scores...
 334                                 int t = entcs_GetScoreTeam(i);
 335                                 if (t) SetTeam(e, t); // will not hurt; later updates come with Scoreboard_UpdatePlayerTeams
 336                                 RegisterPlayer(e);
 337                                 Scoreboard_UpdatePlayerPos(e);
 338                         }
 339                 }
 340         }
 341         this.nextthink = time + 0.2;
 342 }
 343
 344 void TrueAim_Init();
 345 void PostInit()
 346 {
 347         entity playerchecker = new_pure(playerchecker);
 348         setthink(playerchecker, Playerchecker_Think);
 349         playerchecker.nextthink = time + 0.2;
 350
 351         TrueAim_Init();
 352
 353         postinit = true;
 354 }
 355
 356 // CSQC_InputEvent : Used to perform actions based on any key pressed, key released and mouse on the client.
 357 // Return value should be 1 if CSQC handled the input, otherwise return 0 to have the input passed to the engine.
 358 // All keys are in ascii.
 359 // bInputType = 0 is key pressed, 1 is key released, 2 and 3 are mouse input.
 360 // In the case of keyboard input, nPrimary is the ascii code, and nSecondary is 0.
 361 // In the case of mouse input, nPrimary is xdelta, nSecondary is ydelta.
 362 // In the case of mouse input after a setcursormode(1) call, nPrimary is xpos, nSecondary is ypos.
 363 float CSQC_InputEvent(int bInputType, float nPrimary, float nSecondary)
 364 {
 365     TC(int, bInputType);
 366         if (HUD_Panel_InputEvent(bInputType, nPrimary, nSecondary))
 367                 return true;
 368
 369         if (QuickMenu_InputEvent(bInputType, nPrimary, nSecondary))
 370                 return true;
 371
 372         if (HUD_Radar_InputEvent(bInputType, nPrimary, nSecondary))
 373                 return true;
 374
 375         if (MapVote_InputEvent(bInputType, nPrimary, nSecondary))
 376                 return true;
 377
 378         if (HUD_Minigame_InputEvent(bInputType, nPrimary, nSecondary))
 379                 return true;
 380
 381         return false;
 382 }
 383
 384 // END REQUIRED CSQC FUNCTIONS
 385 // --------------------------------------------------------------------------
 386
 387 // --------------------------------------------------------------------------
 388 // BEGIN OPTIONAL CSQC FUNCTIONS
 389
 390 void Ent_Remove(entity this);
 391
 392 void Ent_RemovePlayerScore(entity this)
 393 {
 394         if(this.owner) {
 395                 SetTeam(this.owner, -1);
 396                 this.owner.gotscores = 0;
 397                 FOREACH(Scores, true, {
 398                         this.owner.(scores(it)) = 0; // clear all scores
 399                 });
 400         }
 401 }
 402
 403 NET_HANDLE(ENT_CLIENT_SCORES, bool isnew)
 404 {
 405         make_pure(this);
 406         entity o;
 407
 408         // damnit -.- don't want to go change every single .sv_entnum in hud.qc AGAIN
 409         // (no I've never heard of M-x replace-string, sed, or anything like that)
 410         bool isNew = !this.owner; // workaround for DP bug
 411         int n = ReadByte()-1;
 412
 413 #ifdef DP_CSQC_ENTITY_REMOVE_IS_B0RKED
 414         if(!isNew && n != this.sv_entnum)
 415         {
 416                 //print("A CSQC entity changed its owner!\n");
 417                 LOG_INFOF("A CSQC entity changed its owner! (edict: %d, classname: %s)", etof(this), this.classname);
 418                 isNew = true;
 419                 Ent_Remove(this);
 420         }
 421 #endif
 422
 423         this.sv_entnum = n;
 424
 425         o = playerslots[this.sv_entnum];
 426         if (!o)
 427         {
 428                 o = playerslots[this.sv_entnum] = new_pure(playerslot);
 429         }
 430         this.owner = o;
 431         o.sv_entnum = this.sv_entnum;
 432         o.gotscores = 1;
 433
 434         //if (!o.sort_prev)
 435         //      RegisterPlayer(o);
 436         //playerchecker will do this for us later, if it has not already done so
 437
 438     int sf, lf;
 439         sf = ReadShort();
 440         lf = ReadShort();
 441         FOREACH(Scores, true, {
 442         int p = 1 << (i % 16);
 443                 if (sf & p)
 444                 {
 445                         if (lf & p)
 446                                 o.(scores(it)) = ReadInt24_t();
 447                         else
 448                                 o.(scores(it)) = ReadChar();
 449                 }
 450     });
 451
 452         return = true;
 453
 454         if(o.sort_prev)
 455                 Scoreboard_UpdatePlayerPos(o); // if not registered, we cannot do this yet!
 456
 457         this.entremove = Ent_RemovePlayerScore;
 458 }
 459
 460 NET_HANDLE(ENT_CLIENT_TEAMSCORES, bool isnew)
 461 {
 462         make_pure(this);
 463         int i;
 464         entity o;
 465
 466         this.team = ReadByte();
 467         o = this.owner = GetTeam(this.team, true); // these team numbers can always be trusted
 468
 469     int sf, lf;
 470 #if MAX_TEAMSCORE <= 8
 471         sf = ReadByte();
 472         lf = ReadByte();
 473 #else
 474         sf = ReadShort();
 475         lf = ReadShort();
 476 #endif
 477         int p;
 478         for(i = 0, p = 1; i < MAX_TEAMSCORE; ++i, p *= 2)
 479                 if(sf & p)
 480                 {
 481                         if(lf & p)
 482                                 o.(teamscores(i)) = ReadInt24_t();
 483                         else
 484                                 o.(teamscores(i)) = ReadChar();
 485                 }
 486
 487         return = true;
 488
 489         Scoreboard_UpdateTeamPos(o);
 490 }
 491
 492 NET_HANDLE(ENT_CLIENT_CLIENTDATA, bool isnew)
 493 {
 494         make_pure(this);
 495         float newspectatee_status;
 496
 497     int f = ReadByte();
 498
 499         scoreboard_showscores_force = (f & BIT(0));
 500
 501         if(f & BIT(1))
 502         {
 503                 newspectatee_status = ReadByte();
 504                 if(newspectatee_status == player_localnum + 1)
 505                         newspectatee_status = -1; // observing
 506         }
 507         else
 508                 newspectatee_status = 0;
 509
 510         spectatorbutton_zoom = (f & BIT(2));
 511
 512         if(f & BIT(4))
 513         {
 514                 num_spectators = ReadByte();
 515
 516                 float i, slot;
 517
 518                 for(i = 0; i < MAX_SPECTATORS; ++i)
 519                         spectatorlist[i] = 0; // reset list first
 520
 521                 for(i = 0; i < num_spectators; ++i)
 522                 {
 523                         slot = ReadByte();
 524                         spectatorlist[i] = slot - 1;
 525                 }
 526         }
 527
 528         return = true;
 529
 530         if(newspectatee_status != spectatee_status)
 531         {
 532                 // clear race stuff
 533                 race_laptime = 0;
 534                 race_checkpointtime = 0;
 535                 hud_dynamic_shake_factor = -1;
 536         }
 537         if (autocvar_hud_panel_healtharmor_progressbar_gfx)
 538         {
 539                 if ( (spectatee_status == -1 && newspectatee_status > 0) //before observing, now spectating
 540                   || (spectatee_status > 0 && newspectatee_status > 0 && spectatee_status != newspectatee_status) //changed spectated player
 541                 )
 542                         prev_p_health = -1;
 543                 else if(spectatee_status && !newspectatee_status) //before observing/spectating, now playing
 544                         prev_health = -1;
 545         }
 546         spectatee_status = newspectatee_status;
 547
 548         // we could get rid of spectatee_status, and derive it from player_localentnum and player_localnum
 549 }
 550
 551 NET_HANDLE(ENT_CLIENT_NAGGER, bool isnew)
 552 {
 553         make_pure(this);
 554     int i, j, b, f;
 555
 556     int nags = ReadByte(); // NAGS NAGS NAGS NAGS NAGS NAGS NADZ NAGS NAGS NAGS
 557
 558         if(!(nags & BIT(2)))
 559         {
 560                 if(vote_called_vote)
 561                         strunzone(vote_called_vote);
 562                 vote_called_vote = string_null;
 563                 vote_active = 0;
 564         }
 565         else
 566         {
 567                 vote_active = 1;
 568         }
 569
 570         if(nags & BIT(6))
 571         {
 572                 vote_yescount = ReadByte();
 573                 vote_nocount = ReadByte();
 574                 vote_needed = ReadByte();
 575                 vote_highlighted = ReadChar();
 576         }
 577
 578         if(nags & BIT(7))
 579         {
 580                 if(vote_called_vote)
 581                         strunzone(vote_called_vote);
 582                 vote_called_vote = strzone(ReadString());
 583         }
 584
 585         if(nags & 1)
 586         {
 587                 for(j = 0; j < maxclients; ++j)
 588                         if(playerslots[j])
 589                                 playerslots[j].ready = 1;
 590                 for(i = 1; i <= maxclients; i += 8)
 591                 {
 592                         f = ReadByte();
 593                         for(j = i-1, b = 1; b < 256; b *= 2, ++j)
 594                                 if (!(f & b))
 595                                         if(playerslots[j])
 596                                                 playerslots[j].ready = 0;
 597                 }
 598         }
 599
 600         return = true;
 601
 602         ready_waiting = (nags & BIT(0));
 603         ready_waiting_for_me = (nags & BIT(1));
 604         vote_waiting = (nags & BIT(2));
 605         vote_waiting_for_me = (nags & BIT(3));
 606         warmup_stage = (nags & BIT(4));
 607 }
 608
 609 NET_HANDLE(ENT_CLIENT_ELIMINATEDPLAYERS, bool isnew)
 610 {
 611         make_pure(this);
 612     int sf; serialize(byte, 0, sf);
 613         if (sf & 1) {
 614                 for (int j = 0; j < maxclients; ++j) {
 615                         if (playerslots[j]) {
 616                             playerslots[j].eliminated = 1;
 617                         }
 618         }
 619                 for (int i = 1; i <= maxclients; i += 8) {
 620                         int f = 0;
 621                         serialize(byte, 0, f);
 622                         for (int b = 0; b < 8; ++b) {
 623                                 if (f & BIT(b)) continue;
 624                 int j = i - 1 + b;
 625                 if (playerslots[j]) {
 626                     playerslots[j].eliminated = 0;
 627                 }
 628             }
 629                 }
 630         }
 631         return true;
 632 }
 633
 634 NET_HANDLE(ENT_CLIENT_RANDOMSEED, bool isnew)
 635 {
 636         make_pure(this);
 637         prandom_debug();
 638         float s = ReadShort();
 639         psrandom(s);
 640         return true;
 641 }
 642
 643 NET_HANDLE(ENT_CLIENT_ACCURACY, bool isnew)
 644 {
 645         make_pure(this);
 646     int sf = ReadInt24_t();
 647         if (sf == 0) {
 648                 for (int w = 0; w <= WEP_LAST - WEP_FIRST; ++w)
 649                         weapon_accuracy[w] = -1;
 650                 return true;
 651         }
 652
 653         int f = 1;
 654         for (int w = 0; w <= WEP_LAST - WEP_FIRST; ++w) {
 655                 if (sf & f) {
 656             int b = ReadByte();
 657                         if (b == 0)
 658                                 weapon_accuracy[w] = -1;
 659                         else if (b == 255)
 660                                 weapon_accuracy[w] = 1.0; // no better error handling yet, sorry
 661                         else
 662                                 weapon_accuracy[w] = (b - 1.0) / 100.0;
 663                 }
 664                 f = (f == 0x800000) ? 1 : f * 2;
 665         }
 666         return true;
 667 }
 668
 669 void Spawn_Draw(entity this)
 670 {
 671         if(this.alpha <= 0)
 672                 return;
 673
 674         __pointparticles(this.cnt, this.origin + '0 0 28', '0 0 2', bound(0, frametime, 0.1));
 675 }
 676
 677 void Spawn_PreDraw(entity this)
 678 {
 679         float alph;
 680         vector org = getpropertyvec(VF_ORIGIN);
 681         if(this.fade_start)
 682         {
 683                 if(vdist(org - this.origin, >, this.fade_end))
 684                         alph = 0; // save on some processing
 685                 else if(vdist(org - this.origin, <, this.fade_start))
 686                         alph = 1; // more processing saved
 687                 else
 688                         alph = bound(0, (this.fade_end - vlen(org - this.origin - 0.5 * (this.mins + this.maxs))) / (this.fade_end - this.fade_start), 1);
 689         }
 690         else
 691                 alph = 1;
 692         //printf("%v <-> %v\n", view_origin, this.origin + 0.5 * (this.mins + this.maxs));
 693         this.alpha = alph;
 694         if(alph <= 0)
 695                 this.drawmask = 0;
 696         else
 697                 this.drawmask = MASK_NORMAL;
 698 }
 699
 700 NET_HANDLE(ENT_CLIENT_SPAWNPOINT, bool is_new)
 701 {
 702         float teamnum = (ReadByte() - 1);
 703         vector spn_origin;
 704         spn_origin.x = ReadCoord();
 705         spn_origin.y = ReadCoord();
 706         spn_origin.z = ReadCoord();
 707
 708         this.team = (teamnum + 1);
 709
 710         //if(is_new)
 711         //{
 712                 this.origin = spn_origin;
 713                 setsize(this, PL_MIN_CONST, PL_MAX_CONST);
 714                 //droptofloor();
 715
 716                 /*if(autocvar_cl_spawn_point_model) // needs a model first
 717                 {
 718                         this.mdl = "models/spawnpoint.md3";
 719                         this.colormod = Team_ColorRGB(teamnum);
 720                         precache_model(this.mdl);
 721                         setmodel(this, this.mdl);
 722                         this.drawmask = MASK_NORMAL;
 723                         //this.move_movetype = MOVETYPE_NOCLIP;
 724                         //this.draw = Spawn_Draw;
 725                         IL_PUSH(g_drawables, this);
 726                 }*/
 727                 if(autocvar_cl_spawn_point_particles)
 728                 {
 729                         if(teamplay)
 730                         {
 731                                 switch(teamnum)
 732                                 {
 733                                         case NUM_TEAM_1: this.cnt = particleeffectnum(EFFECT_SPAWNPOINT_RED); break;
 734                                         case NUM_TEAM_2: this.cnt = particleeffectnum(EFFECT_SPAWNPOINT_BLUE); break;
 735                                         case NUM_TEAM_3: this.cnt = particleeffectnum(EFFECT_SPAWNPOINT_YELLOW); break;
 736                                         case NUM_TEAM_4: this.cnt = particleeffectnum(EFFECT_SPAWNPOINT_PINK); break;
 737                                         default: this.cnt = particleeffectnum(EFFECT_SPAWNPOINT_NEUTRAL); break;
 738                                 }
 739                         }
 740                         else { this.cnt = particleeffectnum(EFFECT_SPAWNPOINT_NEUTRAL); }
 741
 742                         this.draw = Spawn_Draw;
 743                         if (is_new) IL_PUSH(g_drawables, this);
 744                         setpredraw(this, Spawn_PreDraw);
 745                         this.fade_start = autocvar_cl_spawn_point_dist_min;
 746                         this.fade_end = autocvar_cl_spawn_point_dist_max;
 747                 }
 748         //}
 749
 750         //printf("Ent_ReadSpawnPoint(is_new = %d); origin = %s, team = %d, effect = %d\n", is_new, vtos(this.origin), teamnum, this.cnt);
 751         return true;
 752 }
 753
 754 NET_HANDLE(ENT_CLIENT_SPAWNEVENT, bool is_new)
 755 {
 756         // If entnum is 0, ONLY do the local spawn actions
 757         // this way the server can disable the sending of
 758         // spawn origin or such to clients if wanted.
 759         float entnum = ReadByte();
 760
 761         if(entnum)
 762         {
 763                 this.origin_x = ReadCoord();
 764                 this.origin_y = ReadCoord();
 765                 this.origin_z = ReadCoord();
 766
 767                 if(is_new)
 768                 {
 769                         float teamnum = entcs_GetTeam(entnum - 1);
 770
 771                         if(autocvar_cl_spawn_event_particles)
 772                         {
 773                                 switch(teamnum)
 774                                 {
 775                                         case NUM_TEAM_1: pointparticles(EFFECT_SPAWN_RED, this.origin, '0 0 0', 1); break;
 776                                         case NUM_TEAM_2: pointparticles(EFFECT_SPAWN_BLUE, this.origin, '0 0 0', 1); break;
 777                                         case NUM_TEAM_3: pointparticles(EFFECT_SPAWN_YELLOW, this.origin, '0 0 0', 1); break;
 778                                         case NUM_TEAM_4: pointparticles(EFFECT_SPAWN_PINK, this.origin, '0 0 0', 1); break;
 779                                         default: pointparticles(EFFECT_SPAWN_NEUTRAL, this.origin, '0 0 0', 1); break;
 780                                 }
 781                         }
 782                         if(autocvar_cl_spawn_event_sound)
 783                         {
 784                                 sound(this, CH_TRIGGER, SND_SPAWN, VOL_BASE, ATTEN_NORM);
 785                         }
 786                 }
 787         }
 788         return = true;
 789
 790         // local spawn actions
 791         if(is_new && (!entnum || (entnum == player_localentnum)))
 792         {
 793                 zoomin_effect = 1;
 794                 current_viewzoom = (1 / bound(1, autocvar_cl_spawnzoom_factor, 16));
 795
 796                 if(autocvar_cl_unpress_zoom_on_spawn)
 797                 {
 798                         localcmd("-zoom\n");
 799                         button_zoom = false;
 800                 }
 801                 HUD_Radar_Hide_Maximized();
 802         }
 803         //printf("Ent_ReadSpawnEvent(is_new = %d); origin = %s, entnum = %d, localentnum = %d\n", is_new, vtos(this.origin), entnum, player_localentnum);
 804 }
 805
 806 // CSQC_Ent_Update : Called every frame that the server has indicated an update to the SSQC / CSQC entity has occured.
 807 // The only parameter reflects if the entity is "new" to the client, meaning it just came into the client's PVS.
 808 void CSQC_Ent_Update(entity this, bool isnew)
 809 {
 810         this.sourceLoc = __FILE__ ":" STR(__LINE__);
 811         int t = ReadByte();
 812
 813         // set up the "time" global for received entities to be correct for interpolation purposes
 814         float savetime = time;
 815         if(servertime)
 816         {
 817                 time = servertime;
 818         }
 819         else
 820         {
 821                 serverprevtime = time;
 822                 serverdeltatime = STAT(MOVEVARS_TICRATE) * STAT(MOVEVARS_TIMESCALE);
 823                 time = serverprevtime + serverdeltatime;
 824         }
 825
 826 #ifdef DP_CSQC_ENTITY_REMOVE_IS_B0RKED
 827         if (this.enttype)
 828         {
 829                 if (t != this.enttype || isnew)
 830                 {
 831                         LOG_INFOF("A CSQC entity changed its type! (edict: %d, server: %d, type: %d -> %d)", etof(this), this.entnum, this.enttype, t);
 832                         Ent_Remove(this);
 833                         clearentity(this);
 834                         isnew = true;
 835                 }
 836         }
 837         else
 838         {
 839                 if (!isnew)
 840                 {
 841                         LOG_INFOF("A CSQC entity appeared out of nowhere! (edict: %d, server: %d, type: %d)", etof(this), this.entnum, t);
 842                         isnew = true;
 843                 }
 844         }
 845 #endif
 846         this.enttype = t;
 847         bool done = false;
 848         FOREACH(LinkedEntities, it.m_id == t, {
 849                 if (isnew) this.classname = it.netname;
 850                 if (autocvar_developer_csqcentities)
 851             LOG_INFOF("CSQC_Ent_Update(%d) at %f with this=%i {.entnum=%d, .enttype=%d} t=%s (%d)", isnew, savetime, this, this.entnum, this.enttype, this.classname, t);
 852                 done = it.m_read(this, NULL, isnew);
 853                 MUTATOR_CALLHOOK(Ent_Update, this, isnew);
 854                 break;
 855         });
 856         time = savetime;
 857         if (!done)
 858         {
 859                 LOG_FATALF("CSQC_Ent_Update(%d) at %f with this=%i {.entnum=%d, .enttype=%d} t=%s (%d)", isnew, savetime, this, this.entnum, this.enttype, this.classname, t);
 860         }
 861 }
 862
 863 // Destructor, but does NOT deallocate the entity by calling remove(). Also
 864 // used when an entity changes its type. For an entity that someone interacts
 865 // with others, make sure it can no longer do so.
 866 void Ent_Remove(entity this)
 867 {
 868         if(this.entremove) this.entremove(this);
 869
 870         if(this.skeletonindex)
 871         {
 872                 skel_delete(this.skeletonindex);
 873                 this.skeletonindex = 0;
 874         }
 875
 876         if(this.snd_looping > 0)
 877         {
 878                 sound(this, this.snd_looping, SND_Null, VOL_BASE, autocvar_cl_jetpack_attenuation);
 879                 this.snd_looping = 0;
 880         }
 881
 882         this.enttype = 0;
 883         this.classname = "";
 884         this.draw = func_null;
 885         this.entremove = func_null;
 886         // TODO possibly set more stuff to defaults
 887 }
 888 // CSQC_Ent_Remove : Called when the server requests a SSQC / CSQC entity to be removed.  Essentially call remove(this) as well.
 889 void CSQC_Ent_Remove(entity this)
 890 {
 891         if (autocvar_developer_csqcentities) LOG_INFOF("CSQC_Ent_Remove() with this=%i {.entnum=%d, .enttype=%d}", this, this.entnum, this.enttype);
 892         if (wasfreed(this))
 893         {
 894                 LOG_WARN("CSQC_Ent_Remove called for already removed entity. Packet loss?");
 895                 return;
 896         }
 897         if (this.enttype) Ent_Remove(this);
 898         delete(this);
 899 }
 900
 901 void Gamemode_Init()
 902 {
 903         if (!isdemo())
 904         {
 905                 if(!(calledhooks & HOOK_START))
 906                         localcmd("\n_cl_hook_gamestart ", MapInfo_Type_ToString(gametype), "\n");
 907                 calledhooks |= HOOK_START;
 908         }
 909 }
 910 // CSQC_Parse_StuffCmd : Provides the stuffcmd string in the first parameter that the server provided.  To execute standard behavior, simply execute localcmd with the string.
 911 void CSQC_Parse_StuffCmd(string strMessage)
 912 {
 913         if (autocvar_developer_csqcentities) LOG_INFOF("CSQC_Parse_StuffCmd(\"%s\")", strMessage);
 914         localcmd(strMessage);
 915 }
 916 // CSQC_Parse_Print : Provides the print string in the first parameter that the server provided.  To execute standard behavior, simply execute print with the string.
 917 void CSQC_Parse_Print(string strMessage)
 918 {
 919         if (autocvar_developer_csqcentities) LOG_INFOF("CSQC_Parse_Print(\"%s\")", strMessage);
 920         print(ColorTranslateRGB(strMessage));
 921 }
 922
 923 // CSQC_Parse_CenterPrint : Provides the centerprint_hud string in the first parameter that the server provided.
 924 void CSQC_Parse_CenterPrint(string strMessage)
 925 {
 926         if (autocvar_developer_csqcentities) LOG_INFOF("CSQC_Parse_CenterPrint(\"%s\")", strMessage);
 927         centerprint_hud(strMessage);
 928 }
 929
 930 // CSQC_Parse_TempEntity : Handles all temporary entity network data in the CSQC layer.
 931 // You must ALWAYS first acquire the temporary ID, which is sent as a byte.
 932 // Return value should be 1 if CSQC handled the temporary entity, otherwise return 0 to have the engine process the event.
 933 bool CSQC_Parse_TempEntity()
 934 {
 935         // Acquire TE ID
 936         int nTEID = ReadByte();
 937
 938         FOREACH(TempEntities, it.m_id == nTEID, {
 939                 if (autocvar_developer_csqcentities)
 940                         LOG_INFOF("CSQC_Parse_TempEntity() nTEID=%s (%d)", it.netname, nTEID);
 941                 return it.m_read(NULL, NULL, true);
 942         });
 943
 944         if (autocvar_developer_csqcentities)
 945                 LOG_INFOF("CSQC_Parse_TempEntity() with nTEID=%d", nTEID);
 946
 947         // No special logic for this temporary entity; return 0 so the engine can handle it
 948         return false;
 949 }
 950
 951 string forcefog;
 952 void Fog_Force()
 953 {
 954         if (autocvar_cl_orthoview && autocvar_cl_orthoview_nofog)
 955                 localcmd("\nr_drawfog 0\n");
 956         else if (forcefog != "")
 957                 localcmd(sprintf("\nfog %s\nr_fog_exp2 0\nr_drawfog 1\n", forcefog));
 958 }
 959
 960 void Gamemode_Init();
 961 NET_HANDLE(ENT_CLIENT_SCORES_INFO, bool isnew)
 962 {
 963         make_pure(this);
 964         gametype = ReadRegistered(Gametypes);
 965         teamplay = _MapInfo_GetTeamPlayBool(gametype);
 966         HUD_ModIcons_SetFunc();
 967         FOREACH(Scores, true, {
 968                 if (scores_label(it)) strunzone(scores_label(it));
 969                 scores_label(it) = strzone(ReadString());
 970                 scores_flags(it) = ReadByte();
 971         });
 972         for (int i = 0; i < MAX_TEAMSCORE; ++i)
 973         {
 974                 if (teamscores_label(i)) strunzone(teamscores_label(i));
 975                 teamscores_label(i) = strzone(ReadString());
 976                 teamscores_flags(i) = ReadByte();
 977         }
 978         return = true;
 979         Scoreboard_InitScores();
 980         Gamemode_Init();
 981 }
 982
 983 NET_HANDLE(ENT_CLIENT_INIT, bool isnew)
 984 {
 985         nb_pb_period = ReadByte() / 32; //Accuracy of 1/32th
 986
 987         hook_shotorigin[0] = decompressShotOrigin(ReadInt24_t());
 988         hook_shotorigin[1] = decompressShotOrigin(ReadInt24_t());
 989         hook_shotorigin[2] = decompressShotOrigin(ReadInt24_t());
 990         hook_shotorigin[3] = decompressShotOrigin(ReadInt24_t());
 991         arc_shotorigin[0] = decompressShotOrigin(ReadInt24_t());
 992         arc_shotorigin[1] = decompressShotOrigin(ReadInt24_t());
 993         arc_shotorigin[2] = decompressShotOrigin(ReadInt24_t());
 994         arc_shotorigin[3] = decompressShotOrigin(ReadInt24_t());
 995
 996         if (forcefog) strunzone(forcefog);
 997         forcefog = strzone(ReadString());
 998
 999         armorblockpercent = ReadByte() / 255.0;
1000         damagepush_speedfactor = ReadByte() / 255.0;
1001
1002         serverflags = ReadByte();
1003
1004         g_trueaim_minrange = ReadCoord();
1005
1006         return = true;
1007
1008         MUTATOR_CALLHOOK(Ent_Init);
1009
1010         if (!postinit) PostInit();
1011 }
1012
1013 float GetSpeedUnitFactor(int speed_unit)
1014 {
1015         switch(speed_unit)
1016         {
1017                 default:
1018                 case 1:
1019                         return 1.0;
1020                 case 2:
1021                         return 0.0254;
1022                 case 3:
1023                         return 0.0254 * 3.6;
1024                 case 4:
1025                         return 0.0254 * 3.6 * 0.6213711922;
1026                 case 5:
1027                         return 0.0254 * 1.943844492; // 1 m/s = 1.943844492 knots, because 1 knot = 1.852 km/h
1028         }
1029 }
1030
1031 string GetSpeedUnit(int speed_unit)
1032 {
1033         switch(speed_unit)
1034         {
1035                 default:
1036                 case 1:
1037                         return _(" qu/s");
1038                 case 2:
1039                         return _(" m/s");
1040                 case 3:
1041                         return _(" km/h");
1042                 case 4:
1043                         return _(" mph");
1044                 case 5:
1045                         return _(" knots");
1046         }
1047 }
1048
1049 NET_HANDLE(TE_CSQC_RACE, bool isNew)
1050 {
1051         int b = ReadByte();
1052
1053         switch (b)
1054         {
1055                 case RACE_NET_CHECKPOINT_HIT_QUALIFYING:
1056                         race_checkpoint = ReadByte();
1057                         race_time = ReadInt24_t();
1058                         race_previousbesttime = ReadInt24_t();
1059                         race_mypreviousbesttime = ReadInt24_t();
1060                         if(race_previousbestname)
1061                                 strunzone(race_previousbestname);
1062                         string pbestname = ReadString();
1063                         if(autocvar_cl_race_cptimes_onlyself)
1064                         {
1065                                 race_previousbesttime = race_mypreviousbesttime;
1066                                 race_mypreviousbesttime = 0;
1067                                 race_previousbestname = strzone("");
1068                         }
1069                         else
1070                                 race_previousbestname = strzone(pbestname);
1071
1072                         race_checkpointtime = time;
1073
1074                         if(race_checkpoint == 0 || race_checkpoint == 254)
1075                         {
1076                                 race_penaltyaccumulator = 0;
1077                                 race_laptime = time; // valid
1078                         }
1079                         break;
1080
1081                 case RACE_NET_CHECKPOINT_CLEAR:
1082                         race_laptime = 0;
1083                         race_checkpointtime = 0;
1084                         break;
1085
1086                 case RACE_NET_CHECKPOINT_NEXT_SPEC_QUALIFYING:
1087                         race_laptime = ReadCoord();
1088                         race_checkpointtime = -99999;
1089                         // fall through
1090                 case RACE_NET_CHECKPOINT_NEXT_QUALIFYING:
1091                         race_nextcheckpoint = ReadByte();
1092
1093                         race_nextbesttime = ReadInt24_t();
1094                         if(b != RACE_NET_CHECKPOINT_NEXT_SPEC_QUALIFYING) // not while spectating (matches server)
1095                                 race_mybesttime = ReadInt24_t();
1096                         if(race_nextbestname)
1097                                 strunzone(race_nextbestname);
1098                         string newname = ReadString();
1099                         if(autocvar_cl_race_cptimes_onlyself && b != RACE_NET_CHECKPOINT_NEXT_SPEC_QUALIFYING)
1100                         {
1101                                 race_nextbesttime = race_mybesttime;
1102                                 race_mybesttime = 0;
1103                                 race_nextbestname = strzone("");
1104                         }
1105                         else
1106                                 race_nextbestname = strzone(newname);
1107                         break;
1108
1109                 case RACE_NET_CHECKPOINT_HIT_RACE:
1110                         race_mycheckpoint = ReadByte();
1111                         race_mycheckpointtime = time;
1112                         race_mycheckpointdelta = ReadInt24_t();
1113                         race_mycheckpointlapsdelta = ReadByte();
1114                         if(race_mycheckpointlapsdelta >= 128)
1115                                 race_mycheckpointlapsdelta -= 256;
1116                         if(race_mycheckpointenemy)
1117                                 strunzone(race_mycheckpointenemy);
1118                         int who = ReadByte();
1119                         if(who)
1120                                 race_mycheckpointenemy = strzone(entcs_GetName(who - 1));
1121                         else
1122                                 race_mycheckpointenemy = strzone(""); // TODO: maybe string_null works fine here?
1123                         break;
1124
1125                 case RACE_NET_CHECKPOINT_HIT_RACE_BY_OPPONENT:
1126                         race_othercheckpoint = ReadByte();
1127                         race_othercheckpointtime = time;
1128                         race_othercheckpointdelta = ReadInt24_t();
1129                         race_othercheckpointlapsdelta = ReadByte();
1130                         if(race_othercheckpointlapsdelta >= 128)
1131                                 race_othercheckpointlapsdelta -= 256;
1132                         if(race_othercheckpointenemy)
1133                                 strunzone(race_othercheckpointenemy);
1134                         int what = ReadByte();
1135                         if(what)
1136                                 race_othercheckpointenemy = strzone(entcs_GetName(what - 1));
1137                         else
1138                                 race_othercheckpointenemy = strzone(""); // TODO: maybe string_null works fine here?
1139                         break;
1140
1141                 case RACE_NET_PENALTY_RACE:
1142                         race_penaltyeventtime = time;
1143                         race_penaltytime = ReadShort();
1144                         //race_penaltyaccumulator += race_penaltytime;
1145                         if(race_penaltyreason)
1146                                 strunzone(race_penaltyreason);
1147                         race_penaltyreason = strzone(ReadString());
1148                         break;
1149
1150                 case RACE_NET_PENALTY_QUALIFYING:
1151                         race_penaltyeventtime = time;
1152                         race_penaltytime = ReadShort();
1153                         race_penaltyaccumulator += race_penaltytime;
1154                         if(race_penaltyreason)
1155                                 strunzone(race_penaltyreason);
1156                         race_penaltyreason = strzone(ReadString());
1157                         break;
1158
1159                 case RACE_NET_SERVER_RECORD:
1160                         race_server_record = ReadInt24_t();
1161                         break;
1162                 case RACE_NET_SPEED_AWARD:
1163                         race_speedaward = ReadInt24_t() * GetSpeedUnitFactor(autocvar_hud_panel_physics_speed_unit);
1164                         if(race_speedaward_holder)
1165                                 strunzone(race_speedaward_holder);
1166                         race_speedaward_holder = strzone(ReadString());
1167                         if(race_speedaward_unit)
1168                                 strunzone(race_speedaward_unit);
1169                         race_speedaward_unit = strzone(GetSpeedUnit(autocvar_hud_panel_physics_speed_unit));
1170                         break;
1171                 case RACE_NET_SPEED_AWARD_BEST:
1172                         race_speedaward_alltimebest = ReadInt24_t() * GetSpeedUnitFactor(autocvar_hud_panel_physics_speed_unit);
1173                         if(race_speedaward_alltimebest_holder)
1174                                 strunzone(race_speedaward_alltimebest_holder);
1175                         race_speedaward_alltimebest_holder = strzone(ReadString());
1176                         if(race_speedaward_alltimebest_unit)
1177                                 strunzone(race_speedaward_alltimebest_unit);
1178                         race_speedaward_alltimebest_unit = strzone(GetSpeedUnit(autocvar_hud_panel_physics_speed_unit));
1179                         break;
1180                 case RACE_NET_SERVER_RANKINGS:
1181                         float prevpos, del;
1182             int pos = ReadShort();
1183                         prevpos = ReadShort();
1184                         del = ReadShort();
1185
1186                         // move other rankings out of the way
1187             int i;
1188                         if (prevpos) {
1189                                 for (i=prevpos-1;i>pos-1;--i) {
1190                                         grecordtime[i] = grecordtime[i-1];
1191                                         if(grecordholder[i])
1192                                                 strunzone(grecordholder[i]);
1193                                         grecordholder[i] = strzone(grecordholder[i-1]);
1194                                 }
1195                         } else if (del) { // a record has been deleted by the admin
1196                                 for (i=pos-1; i<= RANKINGS_CNT-1; ++i) {
1197                                         if (i == RANKINGS_CNT-1) { // clear out last record
1198                                                 grecordtime[i] = 0;
1199                                                 if (grecordholder[i])
1200                                                         strunzone(grecordholder[i]);
1201                                                 grecordholder[i] = string_null;
1202                                         }
1203                                         else {
1204                                                 grecordtime[i] = grecordtime[i+1];
1205                                                 if (grecordholder[i])
1206                                                         strunzone(grecordholder[i]);
1207                                                 grecordholder[i] = strzone(grecordholder[i+1]);
1208                                         }
1209                                 }
1210                         } else { // player has no ranked record yet
1211                                 for (i=RANKINGS_CNT-1;i>pos-1;--i) {
1212                                         grecordtime[i] = grecordtime[i-1];
1213                                         if(grecordholder[i])
1214                                                 strunzone(grecordholder[i]);
1215                                         grecordholder[i] = strzone(grecordholder[i-1]);
1216                                 }
1217                         }
1218
1219                         // store new ranking
1220                         if(grecordholder[pos-1] != "")
1221                                 strunzone(grecordholder[pos-1]);
1222                         grecordholder[pos-1] = strzone(ReadString());
1223                         grecordtime[pos-1] = ReadInt24_t();
1224                         if(strdecolorize(grecordholder[pos-1]) == strdecolorize(entcs_GetName(player_localnum)))
1225                                 race_myrank = pos;
1226                         break;
1227                 case RACE_NET_SERVER_STATUS:
1228                         race_status = ReadShort();
1229                         if(race_status_name)
1230                                 strunzone(race_status_name);
1231                         race_status_name = strzone(ReadString());
1232         }
1233         return true;
1234 }
1235
1236 NET_HANDLE(TE_CSQC_TEAMNAGGER, bool isNew)
1237 {
1238         teamnagger = 1;
1239         return true;
1240 }
1241
1242 NET_HANDLE(TE_CSQC_PINGPLREPORT, bool isNew)
1243 {
1244         int i = ReadByte();
1245         int pi = ReadShort();
1246         int pl = ReadByte();
1247         int ml = ReadByte();
1248         return = true;
1249         entity e = playerslots[i];
1250         if (!e) return;
1251         e.ping = pi;
1252         e.ping_packetloss = pl / 255.0;
1253         e.ping_movementloss = ml / 255.0;
1254 }
1255
1256 NET_HANDLE(TE_CSQC_WEAPONCOMPLAIN, bool isNew)
1257 {
1258         complain_weapon = ReadByte();
1259         complain_weapon_type = ReadByte();
1260         return = true;
1261
1262         complain_weapon_time = time;
1263         weapontime = time; // ping the weapon panel
1264
1265         switch(complain_weapon_type)
1266         {
1267                 case 0: Local_Notification(MSG_MULTI, ITEM_WEAPON_NOAMMO, complain_weapon); break;
1268                 case 1: Local_Notification(MSG_MULTI, ITEM_WEAPON_DONTHAVE, complain_weapon); break;
1269                 default: Local_Notification(MSG_MULTI, ITEM_WEAPON_UNAVAILABLE, complain_weapon); break;
1270         }
1271 }
1272
1273 string _getcommandkey(string cmd_name, string command, bool forcename)
1274 {
1275         string keys;
1276         float n, j, k, l = 0;
1277
1278         if (!autocvar_hud_showbinds)
1279                 return cmd_name;
1280
1281         keys = db_get(binddb, command);
1282         if (keys == "")
1283         {
1284                 bool joy_active = cvar("joy_active");
1285                 n = tokenize(findkeysforcommand(command, 0)); // uses '...' strings
1286                 for(j = 0; j < n; ++j)
1287                 {
1288                         k = stof(argv(j));
1289                         if(k != -1)
1290                         {
1291                                 string key = keynumtostring(k);
1292                                 if(!joy_active && substring(key, 0, 3) == "JOY")
1293                                         continue;
1294
1295                                 if (keys == "")
1296                                         keys = key;
1297                                 else
1298                                         keys = strcat(keys, ", ", key);
1299
1300                                 ++l;
1301                                 if (autocvar_hud_showbinds_limit > 0 && autocvar_hud_showbinds_limit <= l)
1302                                         break;
1303                         }
1304
1305                 }
1306                 if (keys == "")
1307                         keys = "NO_KEY";
1308                 db_put(binddb, command, keys);
1309         }
1310
1311         if (keys == "NO_KEY") {
1312                 if (autocvar_hud_showbinds > 1)
1313                         return sprintf(_("%s (not bound)"), cmd_name);
1314                 else
1315                         return cmd_name;
1316         }
1317         else if (autocvar_hud_showbinds > 1 || forcename)
1318                 return sprintf("%s (%s)", cmd_name, keys);
1319         else
1320                 return keys;
1321 }