qcsrc/client/main.qc

   1 #include "main.qh"
   2
   3 #include <client/command/cl_cmd.qh>
   4 #include <client/draw.qh>
   5 #include <client/hud/_mod.qh>
   6 #include <client/hud/panel/centerprint.qh>
   7 #include <client/hud/panel/chat.qh>
   8 #include <client/hud/panel/quickmenu.qh>
   9 #include <client/hud/panel/scoreboard.qh>
  10 #include <client/items/items.qh>
  11 #include <client/mapvoting.qh>
  12 #include <client/mutators/_mod.qh>
  13 #include <client/shownames.qh>
  14 #include <client/view.qh>
  15 #include <client/weapons/projectile.qh>
  16 #include <common/deathtypes/all.qh>
  17 #include <common/effects/all.inc>
  18 #include <common/effects/all.qh>
  19 #include <common/effects/effect.qh>
  20 #include <common/effects/qc/_mod.qh>
  21 #include <common/ent_cs.qh>
  22 #include <common/gamemodes/gamemode/nexball/cl_nexball.qh>
  23 #include <common/items/_mod.qh>
  24 #include <common/mapinfo.qh>
  25 #include <common/mapobjects/_mod.qh>
  26 #include <common/minigames/cl_minigames.qh>
  27 #include <common/minigames/cl_minigames_hud.qh>
  28 #include <common/net_linked.qh>
  29 #include <common/net_notice.qh>
  30 #include <common/scores.qh>
  31 #include <common/vehicles/all.qh>
  32 #include <lib/csqcmodel/cl_model.qh>
  33 #include <lib/csqcmodel/interpolate.qh>
  34 #include <lib/warpzone/client.qh>
  35
  36 // --------------------------------------------------------------------------
  37 // BEGIN REQUIRED CSQC FUNCTIONS
  38 //include "main.qh"
  39
  40 #define DP_CSQC_ENTITY_REMOVE_IS_B0RKED
  41
  42 // CSQC_Init : Called every time the CSQC code is initialized (essentially at map load)
  43 // Useful for precaching things
  44
  45 void CSQC_Init()
  46 {
  47         prvm_language = strzone(cvar_string("prvm_language"));
  48
  49 #ifdef WATERMARK
  50         LOG_TRACEF("^4CSQC Build information: ^1%s", WATERMARK);
  51 #endif
  52
  53         {
  54                 int i = 0;
  55                 for ( ; i < 255; ++i)
  56                         if (getplayerkeyvalue(i, "viewentity") == "")
  57                                 break;
  58                 maxclients = i;
  59         }
  60
  61         // needs to be done so early because of the constants they create
  62         static_init();
  63         static_init_late();
  64         static_init_precache();
  65
  66         binddb = db_create();
  67         tempdb = db_create();
  68         ClientProgsDB = db_load("client.db");
  69
  70         draw_endBoldFont();
  71
  72         //registercommand("hud_configure");
  73         //registercommand("hud_save");
  74         //registercommand("menu_action");
  75
  76         ConsoleCommand_macro_init();
  77
  78         registercvar("hud_usecsqc", "1");
  79         registercvar("scoreboard_columns", "default");
  80
  81         registercvar("cl_nade_type", "3");
  82         registercvar("cl_pokenade_type", "zombie");
  83
  84         registercvar("cl_jumpspeedcap_min", "");
  85         registercvar("cl_jumpspeedcap_max", "");
  86
  87         registercvar("cl_shootfromfixedorigin", "");
  88
  89         registercvar("cl_multijump", "-1");
  90
  91         registercvar("cl_dodging", "0");
  92
  93         registercvar("cl_spawn_near_teammate", "1");
  94
  95         registercvar("cl_weapon_switch_reload", "1");
  96         registercvar("cl_weapon_switch_fallback_to_impulse", "1");
  97
  98         registercvar("cl_allow_uidranking", "1");
  99
 100         if(autocvar_cl_lockview)
 101                 cvar_set("cl_lockview", "0");
 102
 103         if (cvar_type("_scoreboard_team_selection_available") & CVAR_TYPEFLAG_EXISTS)
 104                 cvar_settemp("_scoreboard_team_selection_available", "1");
 105         cvar_set("_scoreboard_team_selection", "0"); // in case it has been left set to 1
 106
 107         gametype = NULL;
 108
 109         postinit = false;
 110
 111         calledhooks = 0;
 112
 113         teams = Sort_Spawn();
 114         players = Sort_Spawn();
 115
 116         GetTeam(NUM_SPECTATOR, true); // add specs first
 117
 118         for (int w = 0; w <= WEP_LAST - WEP_FIRST; ++w)
 119                 weapon_accuracy[w] = -1;
 120
 121         // precaches
 122
 123         if(autocvar_cl_reticle)
 124         {
 125                 precache_pic("gfx/reticle_normal");
 126                 // weapon reticles are precached in weapon files
 127         }
 128
 129         {
 130                 get_mi_min_max_texcoords(1); // try the CLEVER way first
 131                 minimapname = strcat("gfx/", mi_shortname, "_radar");
 132
 133                 if (precache_pic(minimapname) == "")
 134                 {
 135                         // but maybe we have a non-clever minimap
 136                         minimapname = strcat("gfx/", mi_shortname, "_mini");
 137                         if (precache_pic(minimapname) == "")
 138                                 minimapname = ""; // FAIL
 139                         else
 140                                 get_mi_min_max_texcoords(0); // load new texcoords
 141                 }
 142
 143                 mi_center = (mi_min + mi_max) * 0.5;
 144                 mi_scale = mi_max - mi_min;
 145                 minimapname = strzone(minimapname);
 146         }
 147
 148         hud_skin_path = strzone(strcat("gfx/hud/", autocvar_hud_skin));
 149         LoadMenuSkinValues();
 150 }
 151
 152 // CSQC_Shutdown : Called every time the CSQC code is shutdown (changing maps, quitting, etc)
 153 void Shutdown()
 154 {
 155         WarpZone_Shutdown();
 156
 157         delete(teams);
 158         delete(players);
 159         db_close(binddb);
 160         db_close(tempdb);
 161         if(autocvar_cl_db_saveasdump)
 162                 db_dump(ClientProgsDB, "client.db");
 163         else
 164                 db_save(ClientProgsDB, "client.db");
 165         db_close(ClientProgsDB);
 166
 167         if(camera_active)
 168                 cvar_set("chase_active",ftos(chase_active_backup));
 169
 170         // unset the event chasecam's chase_active
 171         if(autocvar_chase_active < 0)
 172                 cvar_set("chase_active", "0");
 173
 174         if (autocvar_r_drawviewmodel < 0)
 175                 cvar_set("r_drawviewmodel", "0");
 176
 177         cvar_set("slowmo", cvar_defstring("slowmo")); // reset it back to 'default'
 178
 179         if (!isdemo())
 180         {
 181                 if (!(calledhooks & HOOK_START))
 182                         localcmd("\n_cl_hook_gamestart nop\n");
 183                 if (!(calledhooks & HOOK_END))
 184                 {
 185                         int gamecount = cvar("cl_matchcount");
 186                         localcmd("\ncl_hook_gameend\n");
 187                         // NOTE: using localcmd here to ensure it's executed AFTER cl_hook_gameend
 188                         // earlier versions of the game abuse the hook to set this cvar
 189                         localcmd(strcat("cl_matchcount ", itos(gamecount + 1), "\n"));
 190                         //cvar_set("cl_matchcount", itos(gamecount + 1));
 191                 }
 192         }
 193
 194         localcmd("\ncl_hook_shutdown\n");
 195
 196         localcmd("\n-button12\n");
 197
 198         deactivate_minigame();
 199         HUD_MinigameMenu_Close(NULL, NULL, NULL);
 200
 201         ReplicateVars(REPLICATEVARS_DESTROY);
 202 }
 203
 204 void AuditLists()
 205 {
 206         entity e;
 207         entity prev;
 208
 209         prev = players;
 210         for(e = prev.sort_next; e; prev = e, e = e.sort_next)
 211         {
 212                 if(prev != e.sort_prev)
 213                         error(strcat("sort list chain error\nplease submit the output of 'prvm_edicts client' to the developers"));
 214         }
 215
 216         prev = teams;
 217         for(e = prev.sort_next; e; prev = e, e = e.sort_next)
 218         {
 219                 if(prev != e.sort_prev)
 220                         error(strcat("sort list chain error\nplease submit the output of 'prvm_edicts client' to the developers"));
 221         }
 222 }
 223
 224 float RegisterPlayer(entity player)
 225 {
 226         entity pl;
 227         AuditLists();
 228         for(pl = players.sort_next; pl; pl = pl.sort_next)
 229                 if(pl == player)
 230                         error("Player already registered!");
 231         player.sort_next = players.sort_next;
 232         player.sort_prev = players;
 233         if(players.sort_next)
 234                 players.sort_next.sort_prev = player;
 235         players.sort_next = player;
 236         AuditLists();
 237         return true;
 238 }
 239
 240 void RemovePlayer(entity player)
 241 {
 242         entity pl, parent;
 243         AuditLists();
 244         parent = players;
 245         for(pl = players.sort_next; pl && pl != player; pl = pl.sort_next)
 246                 parent = pl;
 247
 248         if(!pl)
 249         {
 250                 error("Trying to remove a player which is not in the playerlist!");
 251                 return;
 252         }
 253         parent.sort_next = player.sort_next;
 254         if(player.sort_next)
 255                 player.sort_next.sort_prev = parent;
 256         AuditLists();
 257 }
 258
 259 void MoveToLast(entity e)
 260 {
 261         AuditLists();
 262         entity ent = e.sort_next;
 263         while(ent)
 264         {
 265                 SORT_SWAP(ent, e);
 266                 ent = e.sort_next;
 267         }
 268         AuditLists();
 269 }
 270
 271 float RegisterTeam(entity Team)
 272 {
 273         assert_once(Team.team, eprint(Team));
 274         entity tm;
 275         AuditLists();
 276         for(tm = teams.sort_next; tm; tm = tm.sort_next)
 277                 if(tm == Team)
 278                         error("Team already registered!");
 279         Team.sort_next = teams.sort_next;
 280         Team.sort_prev = teams;
 281         if(teams.sort_next)
 282                 teams.sort_next.sort_prev = Team;
 283         teams.sort_next = Team;
 284         if(Team.team && Team.team != NUM_SPECTATOR)
 285                 ++team_count;
 286         AuditLists();
 287         return true;
 288 }
 289
 290 void RemoveTeam(entity Team)
 291 {
 292         entity tm, parent;
 293         AuditLists();
 294         parent = teams;
 295         for(tm = teams.sort_next; tm && tm != Team; tm = tm.sort_next)
 296                 parent = tm;
 297
 298         if(!tm)
 299         {
 300                 LOG_INFO(_("Trying to remove a team which is not in the teamlist!"));
 301                 return;
 302         }
 303         parent.sort_next = Team.sort_next;
 304         if(Team.sort_next)
 305                 Team.sort_next.sort_prev = parent;
 306         if(Team.team && Team.team != NUM_SPECTATOR)
 307                 --team_count;
 308         AuditLists();
 309 }
 310
 311 entity GetTeam(int Team, bool add)
 312 {
 313         TC(int, Team); TC(bool, add);
 314         int num = (Team == NUM_SPECTATOR) ? 16 : Team;
 315         if(teamslots[num])
 316                 return teamslots[num];
 317         if (!add)
 318                 return NULL;
 319         entity tm = new_pure(team);
 320         tm.team = Team;
 321         teamslots[num] = tm;
 322         RegisterTeam(tm);
 323         return tm;
 324 }
 325
 326 .float has_team;
 327 bool SetTeam(entity o, int Team)
 328 {
 329         TC(int, Team);
 330         //devassert_once(Team);
 331         entity tm;
 332         if(teamplay)
 333         {
 334                 switch(Team)
 335                 {
 336                         case -1:
 337                         case NUM_TEAM_1:
 338                         case NUM_TEAM_2:
 339                         case NUM_TEAM_3:
 340                         case NUM_TEAM_4:
 341                                 break;
 342                         default:
 343                                 if(GetTeam(Team, false) == NULL)
 344                                 {
 345                                         LOG_TRACEF("trying to switch to unsupported team %d", Team);
 346                                         Team = NUM_SPECTATOR;
 347                                 }
 348                                 break;
 349                 }
 350         }
 351         else
 352         {
 353                 switch(Team)
 354                 {
 355                         case -1:
 356                         case 0:
 357                                 break;
 358                         default:
 359                                 if(GetTeam(Team, false) == NULL)
 360                                 {
 361                                         LOG_TRACEF("trying to switch to unsupported team %d", Team);
 362                                         Team = NUM_SPECTATOR;
 363                                 }
 364                                 break;
 365                 }
 366         }
 367         if(Team == -1) // leave
 368         {
 369                 if(o.has_team)
 370                 {
 371                         tm = GetTeam(o.team, false);
 372                         tm.team_size -= 1;
 373                         o.has_team = 0;
 374                         return true;
 375                 }
 376         }
 377         else
 378         {
 379                 if (!o.has_team)
 380                 {
 381                         o.team = Team;
 382                         tm = GetTeam(Team, true);
 383                         tm.team_size += 1;
 384                         o.has_team = 1;
 385                         return true;
 386                 }
 387                 else if(Team != o.team)
 388                 {
 389                         tm = GetTeam(o.team, false);
 390                         tm.team_size -= 1;
 391                         o.team = Team;
 392                         tm = GetTeam(Team, true);
 393                         tm.team_size += 1;
 394                         return true;
 395                 }
 396         }
 397         return false;
 398 }
 399
 400 void Playerchecker_Think(entity this)
 401 {
 402         int i;
 403         entity e;
 404         for(i = 0; i < maxclients; ++i)
 405         {
 406                 e = playerslots[i];
 407                 if(entcs_GetName(i) == "")
 408                 {
 409                         if(e.sort_prev)
 410                         {
 411                                 // player disconnected
 412                                 SetTeam(e, -1);
 413                                 RemovePlayer(e);
 414                                 e.sort_prev = NULL;
 415                                 //e.gotscores = 0;
 416                         }
 417                 }
 418                 else
 419                 {
 420                         if (!e.sort_prev)
 421                         {
 422                                 // player connected
 423                                 if (!e)
 424                                 {
 425                                         playerslots[i] = e = new_pure(playerslot);
 426                                 }
 427                                 e.sv_entnum = i;
 428                                 e.ping = 0;
 429                                 e.ping_packetloss = 0;
 430                                 e.ping_movementloss = 0;
 431                                 //e.gotscores = 0; // we might already have the scores...
 432                                 int t = entcs_GetScoreTeam(i);
 433                                 if (t) SetTeam(e, t); // will not hurt; later updates come with Scoreboard_UpdatePlayerTeams
 434                                 RegisterPlayer(e);
 435                                 Scoreboard_UpdatePlayerPos(e);
 436                         }
 437                 }
 438         }
 439         this.nextthink = time + 0.2;
 440 }
 441
 442 void PostInit()
 443 {
 444         entity playerchecker = new_pure(playerchecker);
 445         setthink(playerchecker, Playerchecker_Think);
 446         playerchecker.nextthink = time + 0.2;
 447
 448         TrueAim_Init();
 449
 450         // this can't be called in CSQC_Init as it'd send cvars too early
 451         ReplicateVars_Start();
 452
 453         postinit = true;
 454 }
 455
 456 void Release_Common_Keys()
 457 {
 458         localcmd("-fire\n");
 459         localcmd("-fire2\n");
 460         localcmd("-use\n");
 461         localcmd("-hook\n");
 462         localcmd("-jump\n");
 463         localcmd("-forward\n");
 464         localcmd("-back\n");
 465         localcmd("-moveleft\n");
 466         localcmd("-moveright\n");
 467 }
 468
 469 // CSQC_InputEvent : Used to perform actions based on any key pressed, key released and mouse on the client.
 470 // Return value should be 1 if CSQC handled the input, otherwise return 0 to have the input passed to the engine.
 471 // All keys are in ascii.
 472 // bInputType = 0 is key pressed, 1 is key released, 2 and 3 are mouse input.
 473 // In the case of keyboard input, nPrimary is the ascii code, and nSecondary is 0.
 474 // In the case of mouse input, nPrimary is xdelta, nSecondary is ydelta.
 475 // In the case of mouse input after a setcursormode(1) call, nPrimary is xpos, nSecondary is ypos.
 476 float CSQC_InputEvent(int bInputType, float nPrimary, float nSecondary)
 477 {
 478         TC(int, bInputType);
 479         bool override = false;
 480
 481         override |= HUD_Scoreboard_InputEvent(bInputType, nPrimary, nSecondary);
 482         if (override)
 483                 return true;
 484
 485         override |= HUD_Panel_InputEvent(bInputType, nPrimary, nSecondary);
 486         if (override)
 487                 return true;
 488
 489         override |= HUD_Panel_Chat_InputEvent(bInputType, nPrimary, nSecondary);
 490
 491         override |= QuickMenu_InputEvent(bInputType, nPrimary, nSecondary);
 492
 493         override |= HUD_Radar_InputEvent(bInputType, nPrimary, nSecondary);
 494
 495         override |= MapVote_InputEvent(bInputType, nPrimary, nSecondary);
 496
 497         override |= HUD_Minigame_InputEvent(bInputType, nPrimary, nSecondary);
 498
 499         if(override)
 500                 return true;
 501
 502         if(bInputType == 3 || bInputType == 2)
 503                 return false;
 504
 505         // at this point bInputType can only be 0 or 1 (key pressed or released)
 506         bool key_pressed = (bInputType == 0);
 507
 508         if(key_pressed) {
 509                 if(nPrimary == K_ALT) hudShiftState |= S_ALT;
 510                 if(nPrimary == K_CTRL) hudShiftState |= S_CTRL;
 511                 if(nPrimary == K_SHIFT) hudShiftState |= S_SHIFT;
 512                 if(nPrimary == K_TAB) hudShiftState |= S_TAB;
 513         }
 514         else {
 515                 if(nPrimary == K_ALT) hudShiftState -= (hudShiftState & S_ALT);
 516                 if(nPrimary == K_CTRL) hudShiftState -= (hudShiftState & S_CTRL);
 517                 if(nPrimary == K_SHIFT) hudShiftState -= (hudShiftState & S_SHIFT);
 518                 if(nPrimary == K_TAB) hudShiftState -= (hudShiftState & S_TAB);
 519         }
 520
 521         // NOTE: Shift-Escape must be filtered out because it's the hardcoded console shortcut
 522         if (nPrimary == K_ESCAPE && !(hudShiftState & S_SHIFT) && key_pressed)
 523         {
 524                 if (hudShiftState & S_TAB)
 525                 {
 526                         Scoreboard_UI_Enable(0);
 527                         return true;
 528                 }
 529                 if (autocvar_menu_gamemenu && !isdemo() && cvar("_menu_gamemenu_dialog_available"))
 530                 {
 531                         localcmd("\nmenu_showgamemenudialog\n");
 532                         return true;
 533                 }
 534         }
 535
 536         return false;
 537 }
 538
 539 // END REQUIRED CSQC FUNCTIONS
 540 // --------------------------------------------------------------------------
 541
 542 // --------------------------------------------------------------------------
 543 // BEGIN OPTIONAL CSQC FUNCTIONS
 544 .int survival_status;
 545 void Ent_RemovePlayerScore(entity this)
 546 {
 547         if(this.owner) {
 548                 SetTeam(this.owner, -1);
 549                 this.owner.gotscores = 0;
 550                 FOREACH(Scores, true, {
 551                         this.owner.(scores(it)) = 0; // clear all scores
 552                 });
 553                 this.owner.colormap = 0;
 554                 // TODO add a hook to reset this Survival field
 555                 this.owner.survival_status = 0;
 556         }
 557 }
 558
 559 NET_HANDLE(ENT_CLIENT_SCORES, bool isnew)
 560 {
 561         make_pure(this);
 562         entity o;
 563
 564         // damnit -.- don't want to go change every single .sv_entnum in hud.qc AGAIN
 565         // (no I've never heard of M-x replace-string, sed, or anything like that)
 566         bool isNew = !this.owner; // workaround for DP bug
 567         int n = ReadByte()-1;
 568
 569 #ifdef DP_CSQC_ENTITY_REMOVE_IS_B0RKED
 570         if(!isNew && n != this.sv_entnum)
 571         {
 572                 //print("A CSQC entity changed its owner!\n");
 573                 LOG_INFOF("A CSQC entity changed its owner! (edict: %d, classname: %s)", etof(this), this.classname);
 574                 isNew = true;
 575                 Ent_Remove(this);
 576         }
 577 #endif
 578
 579         this.sv_entnum = n;
 580
 581         o = playerslots[this.sv_entnum];
 582         if (!o)
 583         {
 584                 o = playerslots[this.sv_entnum] = new_pure(playerslot);
 585         }
 586         this.owner = o;
 587         o.sv_entnum = this.sv_entnum;
 588         o.gotscores = 1;
 589
 590         //if (!o.sort_prev)
 591         //      RegisterPlayer(o);
 592         //playerchecker will do this for us later, if it has not already done so
 593
 594         int sf = ReadShort();
 595         int lf = ReadShort();
 596         FOREACH(Scores, true, {
 597                 int p = 1 << (i % 16);
 598                 if (sf & p)
 599                 {
 600                         if (lf & p)
 601                                 o.(scores(it)) = ReadInt24_t();
 602                         else
 603                                 o.(scores(it)) = ReadChar();
 604                 }
 605         });
 606
 607         return = true;
 608
 609         if(o.sort_prev)
 610                 Scoreboard_UpdatePlayerPos(o); // if not registered, we cannot do this yet!
 611
 612         this.entremove = Ent_RemovePlayerScore;
 613 }
 614
 615 NET_HANDLE(ENT_CLIENT_TEAMSCORES, bool isnew)
 616 {
 617         make_pure(this);
 618         int i;
 619
 620         this.team = ReadByte();
 621         entity o = this.owner = GetTeam(this.team, true); // these team numbers can always be trusted
 622
 623 #if MAX_TEAMSCORE <= 8
 624         int sf = ReadByte();
 625         int lf = ReadByte();
 626 #else
 627         int sf = ReadShort();
 628         int lf = ReadShort();
 629 #endif
 630         for(i = 0; i < MAX_TEAMSCORE; ++i)
 631                 if(sf & BIT(i))
 632                 {
 633                         if(lf & BIT(i))
 634                                 o.(teamscores(i)) = ReadInt24_t();
 635                         else
 636                                 o.(teamscores(i)) = ReadChar();
 637                 }
 638
 639         return = true;
 640
 641         Scoreboard_UpdateTeamPos(o);
 642 }
 643
 644 NET_HANDLE(ENT_CLIENT_CLIENTDATA, bool isnew)
 645 {
 646         make_pure(this);
 647         float newspectatee_status;
 648
 649         int f = ReadByte();
 650
 651         scoreboard_showscores_force = (f & BIT(0));
 652
 653         if(f & BIT(1))
 654         {
 655                 newspectatee_status = ReadByte();
 656                 if(newspectatee_status == player_localnum + 1)
 657                         newspectatee_status = -1; // observing
 658         }
 659         else
 660                 newspectatee_status = 0;
 661
 662         spectatorbutton_zoom = (f & BIT(2));
 663         observe_blocked = (f & BIT(3));
 664
 665         if(f & BIT(4))
 666         {
 667                 num_spectators = ReadByte();
 668
 669                 float i, slot;
 670
 671                 for(i = 0; i < MAX_SPECTATORS; ++i)
 672                         spectatorlist[i] = 0; // reset list first
 673
 674                 int limit = min(num_spectators, MAX_SPECTATORS);
 675                 for(i = 0; i < limit; ++i)
 676                 {
 677                         slot = ReadByte();
 678                         spectatorlist[i] = slot - 1;
 679                 }
 680         }
 681         else
 682         {
 683                 for(int j = 0; j < MAX_SPECTATORS; ++j)
 684                         spectatorlist[j] = 0; // reset list if showspectators has been turned off
 685                 num_spectators = 0;
 686         }
 687
 688         return = true;
 689
 690         if(newspectatee_status != spectatee_status)
 691         {
 692                 // clear race stuff
 693                 race_laptime = 0;
 694                 race_checkpointtime = 0;
 695                 hud_dynamic_shake_factor = -1;
 696                 spectatee_status_changed_time = time;
 697         }
 698         if (autocvar_hud_panel_healtharmor_progressbar_gfx)
 699         {
 700                 if ( (spectatee_status == -1 && newspectatee_status > 0) //before observing, now spectating
 701                   || (spectatee_status > 0 && newspectatee_status > 0 && spectatee_status != newspectatee_status) //changed spectated player
 702                 )
 703                         prev_p_health = -1;
 704                 else if(spectatee_status && !newspectatee_status) //before observing/spectating, now playing
 705                         prev_health = -1;
 706         }
 707         spectatee_status = newspectatee_status;
 708
 709         // we could get rid of spectatee_status, and derive it from player_localentnum and player_localnum
 710 }
 711
 712 NET_HANDLE(ENT_CLIENT_NAGGER, bool isnew)
 713 {
 714         make_pure(this);
 715
 716         int nags = ReadByte(); // NAGS NAGS NAGS NAGS NAGS NAGS NADZ NAGS NAGS NAGS
 717
 718         if(!(nags & BIT(2)))
 719         {
 720                 strfree(vote_called_vote);
 721                 vote_active = 0;
 722         }
 723         else
 724         {
 725                 vote_active = 1;
 726         }
 727
 728         if(nags & BIT(6))
 729         {
 730                 vote_yescount = ReadByte();
 731                 vote_nocount = ReadByte();
 732                 vote_needed = ReadByte();
 733                 vote_highlighted = ReadChar();
 734         }
 735
 736         if(nags & BIT(7))
 737         {
 738                 strcpy(vote_called_vote, ReadString());
 739         }
 740
 741         if(nags & BIT(0))
 742                 for(int i = 0; i < maxclients;)
 743                         for(int f = ReadByte(), b = 0; b < 8 && i < maxclients; ++b, ++i)
 744                                 if(playerslots[i])
 745                                         playerslots[i].ready = f & BIT(b);
 746
 747         return = true;
 748
 749         ready_waiting = (nags & BIT(0));
 750         ready_waiting_for_me = (nags & BIT(1));
 751         vote_waiting = (nags & BIT(2));
 752         vote_waiting_for_me = (nags & BIT(3));
 753         warmup_stage = (nags & BIT(4));
 754 }
 755
 756 NET_HANDLE(ENT_CLIENT_ELIMINATEDPLAYERS, bool isnew)
 757 {
 758         make_pure(this);
 759         int sf = 0;
 760         serialize(byte, 0, sf);
 761         if (sf & 1) {
 762                 for (int j = 0; j < maxclients; ++j) {
 763                         if (playerslots[j]) {
 764                                 playerslots[j].eliminated = true;
 765                         }
 766                 }
 767                 for (int i = 1; i <= maxclients; i += 8) {
 768                         int f = 0;
 769                         serialize(byte, 0, f);
 770                         for (int b = 0; b < 8; ++b) {
 771                                 if (f & BIT(b)) continue;
 772                                 int j = i - 1 + b;
 773                                 if (playerslots[j]) {
 774                                         playerslots[j].eliminated = false;
 775                                 }
 776                         }
 777                 }
 778         }
 779         return true;
 780 }
 781
 782 NET_HANDLE(ENT_CLIENT_RANDOMSEED, bool isnew)
 783 {
 784         make_pure(this);
 785         prandom_debug();
 786         float s = ReadShort();
 787         psrandom(s);
 788         return true;
 789 }
 790
 791 NET_HANDLE(ENT_CLIENT_ACCURACY, bool isnew)
 792 {
 793         make_pure(this);
 794         int sf = ReadInt24_t();
 795         if (sf == 0) {
 796                 for (int w = 0; w <= WEP_LAST - WEP_FIRST; ++w)
 797                         weapon_accuracy[w] = -1;
 798                 return true;
 799         }
 800
 801         int f = 1;
 802         for (int w = 0; w <= WEP_LAST - WEP_FIRST; ++w) {
 803                 if (sf & f) {
 804                         int b = ReadByte();
 805                         if (b == 0)
 806                                 weapon_accuracy[w] = -1;
 807                         else if (b == 255)
 808                                 weapon_accuracy[w] = 1.0; // no better error handling yet, sorry
 809                         else
 810                                 weapon_accuracy[w] = (b - 1.0) / 100.0;
 811                 }
 812                 f = (f == 0x800000) ? 1 : f * 2;
 813         }
 814         return true;
 815 }
 816
 817 void Spawn_Draw(entity this)
 818 {
 819         bool dodraw = autocvar_cl_spawn_point_particles;
 820         if(dodraw && autocvar_cl_spawn_point_dist_max)
 821         {
 822                 vector org = getpropertyvec(VF_ORIGIN);
 823                 dodraw = vdist(org - this.origin, <, autocvar_cl_spawn_point_dist_max);
 824         }
 825
 826         if(dodraw)
 827                 pointparticles(((!teamplay) ? EFFECT_SPAWNPOINT_NEUTRAL : EFFECT_SPAWNPOINT(this.team - 1)), this.origin + '0 0 28', '0 0 2', bound(0, frametime, 0.1));
 828 }
 829
 830 NET_HANDLE(ENT_CLIENT_SPAWNPOINT, bool is_new)
 831 {
 832         float teamnum = (ReadByte() - 1);
 833         vector spn_origin = ReadVector();
 834
 835         this.team = (teamnum + 1);
 836
 837         //if(is_new)
 838         //{
 839                 this.origin = spn_origin;
 840                 setsize(this, PL_MIN_CONST, PL_MAX_CONST);
 841                 //droptofloor();
 842
 843                 /*if(autocvar_cl_spawn_point_model) // needs a model first
 844                 {
 845                         this.mdl = "models/spawnpoint.md3";
 846                         this.colormod = Team_ColorRGB(teamnum);
 847                         precache_model(this.mdl);
 848                         setmodel(this, this.mdl);
 849                         this.drawmask = MASK_NORMAL;
 850                         //this.move_movetype = MOVETYPE_NOCLIP;
 851                         //this.draw = Spawn_Draw;
 852                         IL_PUSH(g_drawables, this);
 853                 }*/
 854                 this.draw = Spawn_Draw;
 855                 if (is_new) IL_PUSH(g_drawables, this);
 856         //}
 857
 858         //printf("Ent_ReadSpawnPoint(is_new = %d); origin = %s, team = %d, effect = %d\n", is_new, vtos(this.origin), teamnum, this.cnt);
 859         return true;
 860 }
 861
 862 NET_HANDLE(ENT_CLIENT_SPAWNEVENT, bool is_new)
 863 {
 864         // If entnum is 0, ONLY do the local spawn actions
 865         // this way the server can disable the sending of
 866         // spawn origin or such to clients if wanted.
 867         float entnum = ReadByte();
 868
 869         if(entnum)
 870         {
 871                 this.origin = ReadVector();
 872
 873                 if(is_new)
 874                 {
 875                         float teamnum = entcs_GetTeam(entnum - 1);
 876
 877                         if(autocvar_cl_spawn_event_particles)
 878                         {
 879                                 switch(teamnum)
 880                                 {
 881                                         case NUM_TEAM_1: pointparticles(EFFECT_SPAWN_RED, this.origin, '0 0 0', 1); break;
 882                                         case NUM_TEAM_2: pointparticles(EFFECT_SPAWN_BLUE, this.origin, '0 0 0', 1); break;
 883                                         case NUM_TEAM_3: pointparticles(EFFECT_SPAWN_YELLOW, this.origin, '0 0 0', 1); break;
 884                                         case NUM_TEAM_4: pointparticles(EFFECT_SPAWN_PINK, this.origin, '0 0 0', 1); break;
 885                                         default: pointparticles(EFFECT_SPAWN_NEUTRAL, this.origin, '0 0 0', 1); break;
 886                                 }
 887                         }
 888                         if(autocvar_cl_spawn_event_sound)
 889                         {
 890                                 sound(this, CH_TRIGGER, SND_SPAWN, VOL_BASE, ATTEN_NORM);
 891                         }
 892                 }
 893         }
 894         return = true;
 895
 896         // local spawn actions
 897         if(is_new && (!entnum || (entnum == player_localentnum)))
 898         {
 899                 if(autocvar_cl_spawnzoom && !autocvar_cl_lockview)
 900                 {
 901                         zoomin_effect = 1;
 902                         current_viewzoom = (1 / bound(1, autocvar_cl_spawnzoom_factor, 16));
 903                 }
 904
 905                 if(autocvar_cl_unpress_zoom_on_spawn)
 906                 {
 907                         localcmd("-zoom\n");
 908                         button_zoom = false;
 909                 }
 910                 HUD_Radar_Hide_Maximized();
 911         }
 912         //printf("Ent_ReadSpawnEvent(is_new = %d); origin = %s, entnum = %d, localentnum = %d\n", is_new, vtos(this.origin), entnum, player_localentnum);
 913 }
 914
 915 // CSQC_Ent_Update : Called every frame that the server has indicated an update to the SSQC / CSQC entity has occured.
 916 // The parameter isnew reflects if the entity is "new" to the client, meaning it just came into the client's PVS.
 917 void CSQC_Ent_Update(entity this, bool isnew)
 918 {
 919         this.sourceLoc = __FILE__":"STR(__LINE__);
 920         int t = ReadByte();
 921
 922         // set up the "time" global for received entities to be correct for interpolation purposes
 923         float savetime = time;
 924         if(servertime)
 925         {
 926                 time = servertime;
 927         }
 928         else
 929         {
 930                 serverprevtime = time;
 931                 serverdeltatime = STAT(MOVEVARS_TICRATE) * STAT(MOVEVARS_TIMESCALE);
 932                 time = serverprevtime + serverdeltatime;
 933         }
 934
 935 #ifdef DP_CSQC_ENTITY_REMOVE_IS_B0RKED
 936         if (this.enttype)
 937         {
 938                 if (t != this.enttype || isnew)
 939                 {
 940                         LOG_INFOF("A CSQC entity changed its type! (edict: %d, server: %d, type: %d -> %d)", etof(this), this.entnum, this.enttype, t);
 941                         Ent_Remove(this);
 942                         ONREMOVE(this);
 943                         clearentity(this);
 944                         isnew = true;
 945                 }
 946         }
 947         else
 948         {
 949                 if (!isnew)
 950                 {
 951                         LOG_INFOF("A CSQC entity appeared out of nowhere! (edict: %d, server: %d, type: %d)", etof(this), this.entnum, t);
 952                         isnew = true;
 953                 }
 954         }
 955 #endif
 956         this.enttype = t;
 957         bool done = false;
 958         FOREACH(LinkedEntities, it.m_id == t, {
 959                 if (isnew) this.classname = it.netname;
 960                 if (autocvar_developer_csqcentities)
 961                         LOG_INFOF("CSQC_Ent_Update(%i, %d) at %f {.entnum=%d, .enttype=%d} t=%s (%d)", this, isnew, savetime, this.entnum, this.enttype, this.classname, t);
 962                 done = it.m_read(this, NULL, isnew);
 963                 MUTATOR_CALLHOOK(Ent_Update, this, isnew);
 964                 break;
 965         });
 966         time = savetime;
 967         if (!done)
 968         {
 969                 LOG_FATALF("CSQC_Ent_Update(%i, %d) at %f {.entnum=%d, .enttype=%d} t=%s (%d)", this, isnew, savetime, this.entnum, this.enttype, this.classname, t);
 970         }
 971 }
 972
 973 // Destructor, but does NOT deallocate the entity by calling remove(). Also
 974 // used when an entity changes its type. For an entity that someone interacts
 975 // with others, make sure it can no longer do so.
 976 void Ent_Remove(entity this)
 977 {
 978         if(this.entremove) this.entremove(this);
 979
 980         if(this.skeletonindex)
 981         {
 982                 skel_delete(this.skeletonindex);
 983                 this.skeletonindex = 0;
 984         }
 985
 986         if(this.snd_looping > 0)
 987         {
 988                 sound(this, this.snd_looping, SND_Null, VOL_BASE, autocvar_cl_jetpack_attenuation);
 989                 this.snd_looping = 0;
 990         }
 991
 992         this.enttype = 0;
 993         this.classname = "";
 994         this.draw = func_null;
 995         this.entremove = func_null;
 996         // TODO possibly set more stuff to defaults
 997 }
 998 // CSQC_Ent_Remove : Called when the server requests a SSQC / CSQC entity to be removed.  Essentially call remove(this) as well.
 999 void CSQC_Ent_Remove(entity this)
1000 {
1001         if (autocvar_developer_csqcentities) LOG_INFOF("CSQC_Ent_Remove() with this=%i {.entnum=%d, .enttype=%d}", this, this.entnum, this.enttype);
1002         if (wasfreed(this))
1003         {
1004                 LOG_WARN("CSQC_Ent_Remove called for already removed entity. Packet loss?");
1005                 return;
1006         }
1007         if (this.enttype) Ent_Remove(this);
1008         delete(this);
1009 }
1010
1011 void Gamemode_Init()
1012 {
1013         if (!isdemo())
1014         {
1015                 if(!(calledhooks & HOOK_START))
1016                         localcmd("\n_cl_hook_gamestart ", MapInfo_Type_ToString(gametype), "\n");
1017                 calledhooks |= HOOK_START;
1018         }
1019 }
1020 // CSQC_Parse_StuffCmd : Provides the stuffcmd string in the first parameter that the server provided.  To execute standard behavior, simply execute localcmd with the string.
1021 void CSQC_Parse_StuffCmd(string strMessage)
1022 {
1023         if (autocvar_developer_csqcentities) LOG_INFOF("CSQC_Parse_StuffCmd(\"%s\")", strMessage);
1024         localcmd(strMessage);
1025 }
1026 // CSQC_Parse_Print : Provides the print string in the first parameter that the server provided.  To execute standard behavior, simply execute print with the string.
1027 void CSQC_Parse_Print(string strMessage)
1028 {
1029         if (autocvar_developer_csqcentities) LOG_INFOF("CSQC_Parse_Print(\"%s\")", strMessage);
1030         print(ColorTranslateRGB(strMessage));
1031 }
1032
1033 // CSQC_Parse_CenterPrint : Provides the centerprint_AddStandard string in the first parameter that the server provided.
1034 void CSQC_Parse_CenterPrint(string strMessage)
1035 {
1036         if (autocvar_developer_csqcentities) LOG_INFOF("CSQC_Parse_CenterPrint(\"%s\")", strMessage);
1037         centerprint_AddStandard(strMessage);
1038 }
1039
1040 // CSQC_Parse_TempEntity : Handles all temporary entity network data in the CSQC layer.
1041 // You must ALWAYS first acquire the temporary ID, which is sent as a byte.
1042 // Return value should be 1 if CSQC handled the temporary entity, otherwise return 0 to have the engine process the event.
1043 bool CSQC_Parse_TempEntity()
1044 {
1045         // Acquire TE ID
1046         int nTEID = ReadByte();
1047
1048         FOREACH(TempEntities, it.m_id == nTEID, {
1049                 if (autocvar_developer_csqcentities)
1050                         LOG_INFOF("CSQC_Parse_TempEntity() nTEID=%s (%d)", it.netname, nTEID);
1051                 return it.m_read(NULL, NULL, true);
1052         });
1053
1054         if (autocvar_developer_csqcentities)
1055                 LOG_INFOF("CSQC_Parse_TempEntity() with nTEID=%d", nTEID);
1056
1057         // No special logic for this temporary entity; return 0 so the engine can handle it
1058         return false;
1059 }
1060
1061 string forcefog;
1062 void Fog_Force()
1063 {
1064         if (autocvar_cl_orthoview && autocvar_cl_orthoview_nofog)
1065                 localcmd("\nr_drawfog 0\n");
1066         else if (forcefog != "")
1067                 localcmd(sprintf("\nfog %s\nr_fog_exp2 0\nr_drawfog 1\n", forcefog));
1068 }
1069
1070 bool net_handle_ServerWelcome();
1071 NET_HANDLE(ENT_CLIENT_SCORES_INFO, bool isnew)
1072 {
1073         make_pure(this);
1074         gametype = ReadRegistered(Gametypes);
1075         teamplay = _MapInfo_GetTeamPlayBool(gametype);
1076         HUD_ModIcons_SetFunc();
1077         FOREACH(Scores, true, {
1078                 strcpy(scores_label(it), ReadString());
1079                 scores_flags(it) = ReadByte();
1080         });
1081         for (int i = 0; i < MAX_TEAMSCORE; ++i)
1082         {
1083                 strcpy(teamscores_label(i), ReadString());
1084                 teamscores_flags(i) = ReadByte();
1085         }
1086         bool welcome_msg_too = ReadByte();
1087         if (welcome_msg_too)
1088                 net_handle_ServerWelcome();
1089         return = true;
1090         Scoreboard_InitScores();
1091         Gamemode_Init();
1092 }
1093
1094 NET_HANDLE(ENT_CLIENT_INIT, bool isnew)
1095 {
1096         nb_pb_period = ReadByte() / 32; //Accuracy of 1/32th
1097
1098         hook_shotorigin[0] = decompressShotOrigin(ReadInt24_t());
1099         hook_shotorigin[1] = decompressShotOrigin(ReadInt24_t());
1100         hook_shotorigin[2] = decompressShotOrigin(ReadInt24_t());
1101         hook_shotorigin[3] = decompressShotOrigin(ReadInt24_t());
1102         arc_shotorigin[0] = decompressShotOrigin(ReadInt24_t());
1103         arc_shotorigin[1] = decompressShotOrigin(ReadInt24_t());
1104         arc_shotorigin[2] = decompressShotOrigin(ReadInt24_t());
1105         arc_shotorigin[3] = decompressShotOrigin(ReadInt24_t());
1106
1107         strcpy(forcefog, ReadString());
1108
1109         armorblockpercent = ReadByte() / 255.0;
1110         damagepush_speedfactor = ReadByte() / 255.0;
1111
1112         serverflags = ReadByte();
1113
1114         g_trueaim_minrange = ReadCoord();
1115
1116         return = true;
1117
1118         MUTATOR_CALLHOOK(Ent_Init);
1119
1120         if (!postinit) PostInit();
1121 }
1122
1123 float GetSpeedUnitFactor(int speed_unit)
1124 {
1125         switch(speed_unit)
1126         {
1127                 default:
1128                 case 1: return 1.0;
1129                 case 2: return 0.0254;
1130                 case 3: return 0.0254 * 3.6;
1131                 case 4: return 0.0254 * 3.6 * 0.6213711922;
1132                 case 5: return 0.0254 * 1.943844492; // 1 m/s = 1.943844492 knots, because 1 knot = 1.852 km/h
1133         }
1134 }
1135
1136 string GetSpeedUnit(int speed_unit)
1137 {
1138         switch(speed_unit)
1139         {
1140                 // translator-friendly strings without the initial space
1141                 default:
1142                 case 1: return strcat(" ", _("qu/s"));
1143                 case 2: return strcat(" ", _("m/s"));
1144                 case 3: return strcat(" ", _("km/h"));
1145                 case 4: return strcat(" ", _("mph"));
1146                 case 5: return strcat(" ", _("knots"));
1147         }
1148 }
1149
1150 NET_HANDLE(TE_CSQC_RACE, bool isNew)
1151 {
1152         int b = ReadByte();
1153
1154         switch (b)
1155         {
1156                 case RACE_NET_CHECKPOINT_HIT_QUALIFYING:
1157                         race_checkpoint = ReadByte();
1158                         race_time = ReadInt24_t();
1159                         race_previousbesttime = ReadInt24_t();
1160                         race_mypreviousbesttime = ReadInt24_t();
1161                         string pbestname = ReadString();
1162                         if(autocvar_cl_race_cptimes_onlyself)
1163                         {
1164                                 race_previousbesttime = race_mypreviousbesttime;
1165                                 race_mypreviousbesttime = 0;
1166                                 strcpy(race_previousbestname, "");
1167                         }
1168                         else
1169                                 strcpy(race_previousbestname, pbestname);
1170
1171                         race_checkpointtime = time;
1172
1173                         if(race_checkpoint == 0 || race_checkpoint == 254)
1174                         {
1175                                 race_penaltyaccumulator = 0;
1176                                 race_laptime = time; // valid
1177                         }
1178                         break;
1179
1180                 case RACE_NET_CHECKPOINT_CLEAR:
1181                         race_laptime = 0;
1182                         race_checkpointtime = 0;
1183                         break;
1184
1185                 case RACE_NET_CHECKPOINT_NEXT_SPEC_QUALIFYING:
1186                         race_laptime = ReadCoord();
1187                         race_checkpointtime = -99999;
1188                         // fall through
1189                 case RACE_NET_CHECKPOINT_NEXT_QUALIFYING:
1190                         race_nextcheckpoint = ReadByte();
1191
1192                         race_nextbesttime = ReadInt24_t();
1193                         if(b != RACE_NET_CHECKPOINT_NEXT_SPEC_QUALIFYING) // not while spectating (matches server)
1194                                 race_mybesttime = ReadInt24_t();
1195                         string newname = ReadString();
1196                         if(autocvar_cl_race_cptimes_onlyself && b != RACE_NET_CHECKPOINT_NEXT_SPEC_QUALIFYING)
1197                         {
1198                                 race_nextbesttime = race_mybesttime;
1199                                 race_mybesttime = 0;
1200                                 strcpy(race_nextbestname, "");
1201                         }
1202                         else
1203                                 strcpy(race_nextbestname, newname);
1204                         break;
1205
1206                 case RACE_NET_CHECKPOINT_HIT_RACE:
1207                         race_mycheckpoint = ReadByte();
1208                         race_mycheckpointtime = time;
1209                         race_mycheckpointdelta = ReadInt24_t();
1210                         race_mycheckpointlapsdelta = ReadByte();
1211                         if(race_mycheckpointlapsdelta >= 128)
1212                                 race_mycheckpointlapsdelta -= 256;
1213                         int who = ReadByte();
1214                         if(who)
1215                                 strcpy(race_mycheckpointenemy, entcs_GetName(who - 1));
1216                         else
1217                                 strcpy(race_mycheckpointenemy, ""); // TODO: maybe string_null works fine here?
1218                         break;
1219
1220                 case RACE_NET_CHECKPOINT_HIT_RACE_BY_OPPONENT:
1221                         race_othercheckpoint = ReadByte();
1222                         race_othercheckpointtime = time;
1223                         race_othercheckpointdelta = ReadInt24_t();
1224                         race_othercheckpointlapsdelta = ReadByte();
1225                         if(race_othercheckpointlapsdelta >= 128)
1226                                 race_othercheckpointlapsdelta -= 256;
1227                         int what = ReadByte();
1228                         if(what)
1229                                 strcpy(race_othercheckpointenemy, entcs_GetName(what - 1));
1230                         else
1231                                 strcpy(race_othercheckpointenemy, ""); // TODO: maybe string_null works fine here?
1232                         break;
1233
1234                 case RACE_NET_PENALTY_RACE:
1235                 case RACE_NET_PENALTY_QUALIFYING:
1236                         race_penaltyeventtime = time;
1237                         race_penaltytime = ReadShort();
1238                         string reason = ReadString();
1239                         if (reason == "missing a checkpoint")
1240                                 reason = _("missing a checkpoint");
1241                         strcpy(race_penaltyreason, reason);
1242                         if (b == RACE_NET_PENALTY_QUALIFYING)
1243                                 race_penaltyaccumulator += race_penaltytime;
1244                         break;
1245
1246                 case RACE_NET_SERVER_RECORD:
1247                         race_server_record = ReadInt24_t();
1248                         break;
1249                 case RACE_NET_SPEED_AWARD:
1250                         race_speedaward = ReadInt24_t();
1251                         strcpy(race_speedaward_holder, ReadString());
1252                         break;
1253                 case RACE_NET_SPEED_AWARD_BEST:
1254                         race_speedaward_alltimebest = ReadInt24_t();
1255                         strcpy(race_speedaward_alltimebest_holder, ReadString());
1256                         break;
1257                 case RACE_NET_RANKINGS_CNT:
1258                         RANKINGS_DISPLAY_CNT = ReadByte();
1259                         break;
1260                 case RACE_NET_SERVER_RANKINGS:
1261                         float prevpos, del;
1262                         int pos = ReadShort();
1263                         prevpos = ReadShort();
1264                         del = ReadShort();
1265
1266                         // move other rankings out of the way
1267                         int i;
1268                         if (prevpos) {
1269                                 int m = min(prevpos, RANKINGS_DISPLAY_CNT);
1270                                 for (i=m-1; i>pos-1; --i) {
1271                                         grecordtime[i] = grecordtime[i-1];
1272                                         strcpy(grecordholder[i], grecordholder[i-1]);
1273                                 }
1274                         } else if (del) { // a record has been deleted by the admin
1275                                 for (i=pos-1; i<= RANKINGS_DISPLAY_CNT-1; ++i) {
1276                                         if (i == RANKINGS_DISPLAY_CNT-1) { // clear out last record
1277                                                 grecordtime[i] = 0;
1278                                                 strfree(grecordholder[i]);
1279                                         }
1280                                         else {
1281                                                 grecordtime[i] = grecordtime[i+1];
1282                                                 strcpy(grecordholder[i], grecordholder[i+1]);
1283                                         }
1284                                 }
1285                         } else { // player has no ranked record yet
1286                                 for (i=RANKINGS_DISPLAY_CNT-1;i>pos-1;--i) {
1287                                         grecordtime[i] = grecordtime[i-1];
1288                                         strcpy(grecordholder[i], grecordholder[i-1]);
1289                                 }
1290                         }
1291
1292                         if (grecordtime[RANKINGS_DISPLAY_CNT]) {
1293                                 // kick off the player who fell from the last displayed position
1294                                 grecordtime[RANKINGS_DISPLAY_CNT] = 0;
1295                                 strfree(grecordholder[RANKINGS_DISPLAY_CNT]);
1296                         }
1297
1298                         // store new ranking
1299                         strcpy(grecordholder[pos-1], ReadString());
1300                         grecordtime[pos-1] = ReadInt24_t();
1301                         if(strdecolorize(grecordholder[pos-1]) == strdecolorize(entcs_GetName(player_localnum)))
1302                                 race_myrank = pos;
1303                         break;
1304                 case RACE_NET_SERVER_STATUS:
1305                         race_status = ReadShort();
1306                         strcpy(race_status_name, ReadString());
1307         }
1308         return true;
1309 }
1310
1311 NET_HANDLE(TE_CSQC_TEAMNAGGER, bool isNew)
1312 {
1313         teamnagger = 1;
1314         return true;
1315 }
1316
1317 NET_HANDLE(TE_CSQC_PINGPLREPORT, bool isNew)
1318 {
1319         int i = ReadByte();
1320         int pi = ReadShort();
1321         int pl = ReadByte();
1322         int ml = ReadByte();
1323         return = true;
1324         entity e = playerslots[i];
1325         if (!e) return;
1326         e.ping = pi;
1327         e.ping_packetloss = pl / 255.0;
1328         e.ping_movementloss = ml / 255.0;
1329 }
1330
1331 NET_HANDLE(TE_CSQC_WEAPONCOMPLAIN, bool isNew)
1332 {
1333         int weapon_id = ReadByte();
1334         complain_weapon = REGISTRY_GET(Weapons, weapon_id);
1335         complain_weapon_type = ReadByte();
1336         return = true;
1337
1338         complain_weapon_time = time;
1339         weapontime = time; // ping the weapon panel
1340
1341         switch(complain_weapon_type)
1342         {
1343                 case 0: Local_Notification(MSG_MULTI, ITEM_WEAPON_NOAMMO, weapon_id); break;
1344                 case 1: Local_Notification(MSG_MULTI, ITEM_WEAPON_DONTHAVE, weapon_id); break;
1345                 default: Local_Notification(MSG_MULTI, ITEM_WEAPON_UNAVAILABLE, weapon_id); break;
1346         }
1347 }
1348
1349 string translate_modifications(string s)
1350 {
1351         return build_mutator_list(s);
1352 }
1353
1354 string translate_weaponarena(string s)
1355 {
1356         if (s == "") return s;
1357         if (s == "All Weapons Arena") return _("All Weapons Arena");
1358         if (s == "All Available Weapons Arena") return _("All Available Weapons Arena");
1359         if (s == "Most Weapons Arena") return _("Most Weapons Arena");
1360         if (s == "Most Available Weapons Arena") return _("Most Available Weapons Arena");
1361         if (s == "Dev All Weapons Arena") return s; // development option, do not translate
1362         if (s == "Dev All Available Weapons Arena") return s; // development option, do not translate
1363         if (s == "No Weapons Arena") return _("No Weapons Arena");
1364
1365         int n = tokenizebyseparator(s, " & ");
1366         string wpn_list = "";
1367         for (int i = 0; i < n; i++)
1368         {
1369                 Weapon wep = Weapon_from_name(argv(i));
1370                 if (wep == WEP_Null)
1371                         LOG_INFO("^3Warning: ^7server sent an invalid weapon name\n");
1372                 wpn_list = cons_mid(wpn_list, " & ", wep.m_name);
1373         }
1374         if (wpn_list != "")
1375                 return sprintf(_("%s Arena"), wpn_list);
1376         else
1377                 return _("No Weapons Arena");
1378 }
1379
1380 string GetVersionMessage(string hostversion, bool version_mismatch, bool version_check)
1381 {
1382         string xonotic_hostversion = strcat("Xonotic ", hostversion);
1383         if (version_mismatch)
1384         {
1385                 if(!version_check)
1386                         return strcat(sprintf(_("This is %s"), xonotic_hostversion), "\n^3",
1387                                 _("Your client version is outdated."), "\n\n\n",
1388                                 _("### YOU WON'T BE ABLE TO PLAY ON THIS SERVER ###"), "\n\n\n",
1389                                 _("Please update!"));
1390                 else
1391                         return strcat(sprintf(_("This is %s"), xonotic_hostversion), "\n^3",
1392                                 _("This server is using an outdated Xonotic version."), "\n\n\n",
1393                                 _("### THIS SERVER IS INCOMPATIBLE AND THUS YOU CANNOT JOIN ###"));
1394         }
1395         return sprintf(_("Welcome to %s"), xonotic_hostversion);
1396 }
1397
1398 bool net_handle_ServerWelcome()
1399 {
1400         campaign = ReadByte();
1401         if (campaign)
1402         {
1403                 string campaign_title = ReadString();
1404                 int campaign_level = ReadByte();
1405                 string campaign_msg = ReadString();
1406                 string welcomedialog_args;
1407                 welcomedialog_args = strcat("HOSTNAME \"", campaign_title, "\"");
1408                 string key = getcommandkey(_("jump"), "+jump");
1409                 string msg = strcat(
1410                         CCR("^F1"), sprintf(_("Level %d:"), campaign_level),
1411                         sprintf(CCR(" ^BG%s\n^3\n"), campaign_msg),
1412                         sprintf(CCR(_("^BGPress ^F2%s^BG to enter the game")), key));
1413                 msg = MakeConsoleSafe(strreplace("\n", "\\n", msg));
1414                 welcomedialog_args = strcat(welcomedialog_args, " WELCOME \"", msg, "\"");
1415                 localcmd("\nmenu_cmd directmenu Welcome ", welcomedialog_args, "\n");
1416                 return true;
1417         }
1418
1419         strcpy(hostname, ReadString());
1420         string hostversion = ReadString();
1421         bool version_mismatch = ReadByte();
1422         bool version_check = ReadByte();
1423         srv_minplayers = ReadByte();
1424         srv_maxplayers = ReadByte();
1425         string modifications = translate_modifications(ReadString());
1426         string weaponarena_list = translate_weaponarena(ReadString());
1427         string cache_mutatormsg = ReadString();
1428         string motd = ReadString();
1429
1430         string msg = GetVersionMessage(hostversion, version_mismatch, version_check);
1431
1432         msg = strcat(msg, "\n\n", _("Gametype:"), " ^1", MapInfo_Type_ToText(gametype), "\n");
1433
1434         msg = strcat(msg, "\n", _("Map:"), " ^2");
1435         if (world.message == "")
1436                 msg = strcat(msg, mi_shortname, "\n");
1437         else
1438         {
1439                 int i = strstrofs(world.message, " by ", 0); // matches _MapInfo_Generate()
1440                 string longname = i >= 0 ? substring(world.message, 0, i) : world.message;
1441                 msg = strcat(msg, (strcasecmp(longname, mi_shortname) ? strcat(mi_shortname, " ^7// ^2") : ""), longname, "\n");
1442         }
1443
1444         if (srv_minplayers || srv_maxplayers)
1445         {
1446                 msg = strcat(msg, "\n", _("This match supports"), " ^5");
1447                 if (srv_minplayers == srv_maxplayers)
1448                         msg = strcat(msg, sprintf(_("%d players"), srv_maxplayers), "\n");
1449                 else if (srv_minplayers && srv_maxplayers)
1450                         msg = strcat(msg, sprintf(_("%d to %d players"), srv_minplayers, srv_maxplayers), "\n");
1451                 else if (srv_maxplayers)
1452                         msg = strcat(msg, sprintf(_("%d players maximum"), srv_maxplayers), "\n");
1453                 else
1454                         msg = strcat(msg, sprintf(_("%d players minimum"), srv_minplayers), "\n");
1455         }
1456
1457         modifications = cons_mid(modifications, ", ", weaponarena_list);
1458         if(modifications != "")
1459                 msg = strcat(msg, "\n", _("Active modifications:"), " ^3", modifications, "\n");
1460
1461         if (cache_mutatormsg != "")
1462                 msg = strcat(msg, "\n", _("Special gameplay tips:"), " ^7", cache_mutatormsg, "\n");
1463         string mutator_msg = "";
1464         MUTATOR_CALLHOOK(BuildGameplayTipsString, mutator_msg);
1465         mutator_msg = M_ARGV(0, string);
1466         msg = strcat(msg, mutator_msg); // trust that the mutator will do proper formatting
1467
1468         if (motd != "")
1469                 msg = strcat(msg, "\n^9↓ ", _("Server's message"), " ↓\n", motd);
1470
1471         strcpy(welcome_msg, msg);
1472         welcome_msg_menu_check_maxtime = time + 1; // wait for menu to load before showing the welcome dialog
1473         return true;
1474 }
1475
1476 void Welcome_Message_Show_Try()
1477 {
1478         if (!welcome_msg_menu_check_maxtime)
1479                 return;
1480
1481         // if want dialog check if menu is initialized but for a short time
1482         if (cvar("_menu_initialized") == 2 || time > welcome_msg_menu_check_maxtime)
1483         {
1484                 if (cvar("_menu_welcome_dialog_available"))
1485                 {
1486                         string welcomedialog_args = strcat("HOSTNAME \"", hostname, "\"");
1487                         string msg = MakeConsoleSafe(strreplace("\n", "\\n", welcome_msg));
1488                         welcomedialog_args = strcat(welcomedialog_args, " WELCOME \"", msg, "\"");
1489
1490                         if (intermission || isdemo() || !autocvar_cl_welcome)
1491                         {
1492                                 if (cvar("_menu_cmd_closemenu_available"))
1493                                 {
1494                                         // initialize the dialog without opening it
1495                                         localcmd("\nmenu_cmd closemenu Welcome ", welcomedialog_args, "\n");
1496                                 }
1497                                 else
1498                                 {
1499                                         // legacy code for clients with old menus
1500                                         // since togglemenu 0 doesn't close the dialog but only hides it,
1501                                         // playing back a demo the Welcome dialog will pop up on the first ESC press
1502                                         localcmd("\nmenu_cmd directmenu Welcome ", welcomedialog_args, "\n");
1503                                         // close it after it's been initialized so it can still be opened manually
1504                                         localcmd("\ntogglemenu 0\n");
1505                                 }
1506                         }
1507                         else
1508                                 localcmd("\nmenu_cmd directmenu Welcome ", welcomedialog_args, "\n");
1509                 }
1510
1511                 strfree(welcome_msg);
1512                 welcome_msg_menu_check_maxtime = 0;
1513         }
1514 }
1515
1516 NET_HANDLE(TE_CSQC_SERVERWELCOME, bool isNew)
1517 {
1518         return net_handle_ServerWelcome();
1519 }
1520
1521 string _getcommandkey(string cmd_name, string command, bool forcename)
1522 {
1523         string keys;
1524         float n, j, k, l = 0;
1525
1526         if (!autocvar_hud_showbinds)
1527                 return cmd_name;
1528
1529         keys = db_get(binddb, command);
1530         if (keys == "")
1531         {
1532                 bool joy_active = cvar("joy_active");
1533                 n = tokenize(findkeysforcommand(command, 0)); // uses '...' strings
1534                 for(j = 0; j < n; ++j)
1535                 {
1536                         k = stof(argv(j));
1537                         if(k != -1)
1538                         {
1539                                 string key = keynumtostring(k);
1540                                 if(!joy_active && substring(key, 0, 3) == "JOY")
1541                                         continue;
1542
1543                                 key = translate_key(key);
1544
1545                                 if (keys == "")
1546                                         keys = key;
1547                                 else
1548                                         keys = strcat(keys, ", ", key);
1549
1550                                 ++l;
1551                                 if (autocvar_hud_showbinds_limit > 0 && autocvar_hud_showbinds_limit <= l)
1552                                         break;
1553                         }
1554
1555                 }
1556                 if (keys == "")
1557                         keys = "NO_KEY";
1558                 db_put(binddb, command, keys);
1559         }
1560
1561         if (keys == "NO_KEY") {
1562                 if (autocvar_hud_showbinds > 1)
1563                         return sprintf(_("%s (not bound)"), cmd_name);
1564                 else
1565                         return cmd_name;
1566         }
1567         else if (autocvar_hud_showbinds > 1 || forcename)
1568                 return sprintf("%s (%s)", cmd_name, keys);
1569         else
1570                 return keys;
1571 }
1572
1573 /** engine callback */
1574 void URI_Get_Callback(int id, int status, string data)
1575 {
1576         TC(int, id); TC(int, status);
1577         if(url_URI_Get_Callback(id, status, data))
1578         {
1579                 // handled
1580         }
1581         else if (id == URI_GET_DISCARD)
1582         {
1583                 // discard
1584         }
1585         else if (id >= URI_GET_CURL && id <= URI_GET_CURL_END)
1586         {
1587                 // sv_cmd curl
1588                 Curl_URI_Get_Callback(id, status, data);
1589         }
1590         else
1591         {
1592                 LOG_INFOF("Received HTTP request data for an invalid id %d.", id);
1593         }
1594 }