qcsrc/client/main.qc

   1 #include "main.qh"
   2
   3 #include <common/effects/qc/all.qh>
   4 #include "hud/all.qh"
   5 #include "mapvoting.qh"
   6 #include "mutators/events.qh"
   7 #include "hud/panel/quickmenu.qh"
   8 #include "scoreboard.qh"
   9 #include "shownames.qh"
  10 #include <common/t_items.qh>
  11 #include "wall.qh"
  12 #include "weapons/projectile.qh"
  13 #include <common/deathtypes/all.qh>
  14 #include <common/items/all.qh>
  15 #include <common/mapinfo.qh>
  16 #include <common/minigames/cl_minigames.qh>
  17 #include <common/minigames/cl_minigames_hud.qh>
  18 #include <common/net_notice.qh>
  19 #include <common/triggers/include.qh>
  20 #include <common/vehicles/all.qh>
  21 #include <lib/csqcmodel/cl_model.qh>
  22 #include <lib/csqcmodel/interpolate.qh>
  23 #include <lib/warpzone/client.qh>
  24
  25 // --------------------------------------------------------------------------
  26 // BEGIN REQUIRED CSQC FUNCTIONS
  27 //include "main.qh"
  28
  29 #define DP_CSQC_ENTITY_REMOVE_IS_B0RKED
  30
  31 void draw_cursor(vector pos, vector ofs, string img, vector col, float a)
  32 {
  33         ofs = eX * (ofs.x * SIZE_CURSOR.x) + eY * (ofs.y * SIZE_CURSOR.y);
  34         drawpic(pos - ofs, strcat(draw_currentSkin, img), SIZE_CURSOR, col, a, DRAWFLAG_NORMAL);
  35 }
  36
  37 void draw_cursor_normal(vector pos, vector col, float a)
  38 {
  39         draw_cursor(pos, OFFSET_CURSOR, "/cursor", col, a);
  40 }
  41
  42 void LoadMenuSkinValues()
  43 {
  44         int fh = -1;
  45         if(cvar_string("menu_skin") != "")
  46         {
  47                 draw_currentSkin = strcat("gfx/menu/", cvar_string("menu_skin"));
  48                 fh = fopen(strcat(draw_currentSkin, "/skinvalues.txt"), FILE_READ);
  49         }
  50         if(fh < 0 && cvar_defstring("menu_skin") != "")
  51         {
  52                 cvar_set("menu_skin", cvar_defstring("menu_skin"));
  53                 draw_currentSkin = strcat("gfx/menu/", cvar_string("menu_skin"));
  54                 fh = fopen(strcat(draw_currentSkin, "/skinvalues.txt"), FILE_READ);
  55         }
  56         if(fh < 0)
  57         {
  58                 draw_currentSkin = "gfx/menu/default";
  59                 fh = fopen(strcat(draw_currentSkin, "/skinvalues.txt"), FILE_READ);
  60         }
  61
  62         draw_currentSkin = strzone(draw_currentSkin);
  63
  64         if(fh >= 0)
  65         {
  66                 string s;
  67                 while((s = fgets(fh)))
  68                 {
  69                         int n = tokenize_console(s);
  70                         if (n < 2)
  71                                 continue;
  72                         if(substring(argv(0), 0, 2) == "//")
  73                                 continue;
  74                         if(argv(0) == "SIZE_CURSOR")
  75                                 SIZE_CURSOR = stov(substring(s, argv_start_index(1), argv_end_index(-1) - argv_start_index(1)));
  76                         else if(argv(0) == "OFFSET_CURSOR")
  77                                 OFFSET_CURSOR = stov(substring(s, argv_start_index(1), argv_end_index(-1) - argv_start_index(1)));
  78                 }
  79                 fclose(fh);
  80         }
  81 }
  82
  83 // CSQC_Init : Called every time the CSQC code is initialized (essentially at map load)
  84 // Useful for precaching things
  85
  86 void ConsoleCommand_macro_init();
  87 void CSQC_Init()
  88 {
  89         prvm_language = strzone(cvar_string("prvm_language"));
  90
  91 #ifdef WATERMARK
  92         LOG_INFOF("^4CSQC Build information: ^1%s\n", WATERMARK);
  93 #endif
  94
  95         {
  96                 int i = 0;
  97                 for ( ; i < 255; ++i)
  98                         if (getplayerkeyvalue(i, "viewentity") == "")
  99                                 break;
 100                 maxclients = i;
 101         }
 102
 103         // needs to be done so early because of the constants they create
 104         static_init();
 105         static_init_late();
 106         static_init_precache();
 107
 108         binddb = db_create();
 109         tempdb = db_create();
 110         ClientProgsDB = db_load("client.db");
 111         compressShortVector_init();
 112
 113         draw_endBoldFont();
 114
 115         //registercommand("hud_configure");
 116         //registercommand("hud_save");
 117         //registercommand("menu_action");
 118
 119         ConsoleCommand_macro_init();
 120
 121         registercvar("hud_usecsqc", "1");
 122         registercvar("scoreboard_columns", "default");
 123
 124         registercvar("cl_nade_type", "3");
 125         registercvar("cl_pokenade_type", "zombie");
 126
 127         registercvar("cl_jumpspeedcap_min", "");
 128         registercvar("cl_jumpspeedcap_max", "");
 129
 130         registercvar("cl_multijump", "1");
 131
 132         registercvar("cl_spawn_near_teammate", "1");
 133
 134         gametype = 0;
 135
 136         // hud_fields uses strunzone on the titles!
 137         for(int i = 0; i < MAX_HUD_FIELDS; ++i)
 138                 hud_title[i] = strzone("(null)");
 139
 140         Cmd_HUD_SetFields(0);
 141
 142         postinit = false;
 143
 144         calledhooks = 0;
 145
 146         teams = Sort_Spawn();
 147         players = Sort_Spawn();
 148
 149         GetTeam(NUM_SPECTATOR, true); // add specs first
 150
 151         // precaches
 152
 153         if(autocvar_cl_reticle)
 154         {
 155                 precache_pic("gfx/reticle_normal");
 156                 // weapon reticles are precached in weapon files
 157         }
 158
 159         {
 160                 get_mi_min_max_texcoords(1); // try the CLEVER way first
 161                 minimapname = strcat("gfx/", mi_shortname, "_radar.tga");
 162                 shortmapname = mi_shortname;
 163
 164                 if (precache_pic(minimapname) == "")
 165                 {
 166                         // but maybe we have a non-clever minimap
 167                         minimapname = strcat("gfx/", mi_shortname, "_mini.tga");
 168                         if (precache_pic(minimapname) == "")
 169                                 minimapname = ""; // FAIL
 170                         else
 171                                 get_mi_min_max_texcoords(0); // load new texcoords
 172                 }
 173
 174                 mi_center = (mi_min + mi_max) * 0.5;
 175                 mi_scale = mi_max - mi_min;
 176                 minimapname = strzone(minimapname);
 177         }
 178
 179         hud_skin_path = strzone(strcat("gfx/hud/", autocvar_hud_skin));
 180         LoadMenuSkinValues();
 181 }
 182
 183 // CSQC_Shutdown : Called every time the CSQC code is shutdown (changing maps, quitting, etc)
 184 void Shutdown()
 185 {
 186         WarpZone_Shutdown();
 187
 188         remove(teams);
 189         remove(players);
 190         db_close(binddb);
 191         db_close(tempdb);
 192         if(autocvar_cl_db_saveasdump)
 193                 db_dump(ClientProgsDB, "client.db");
 194         else
 195                 db_save(ClientProgsDB, "client.db");
 196         db_close(ClientProgsDB);
 197
 198         if(camera_active)
 199                 cvar_set("chase_active",ftos(chase_active_backup));
 200
 201         // unset the event chasecam's chase_active
 202         if(autocvar_chase_active < 0)
 203                 cvar_set("chase_active", "0");
 204
 205         cvar_set("slowmo", cvar_defstring("slowmo")); // reset it back to 'default'
 206
 207         if (!isdemo())
 208         {
 209                 if (!(calledhooks & HOOK_START))
 210                         localcmd("\n_cl_hook_gamestart nop\n");
 211                 if (!(calledhooks & HOOK_END))
 212                         localcmd("\ncl_hook_gameend\n");
 213         }
 214
 215         deactivate_minigame();
 216         HUD_MinigameMenu_Close(NULL, NULL, NULL);
 217 }
 218
 219 .float has_team;
 220 float SetTeam(entity o, int Team)
 221 {
 222     TC(int, Team);
 223         devassert_once(Team);
 224         entity tm;
 225         if(teamplay)
 226         {
 227                 switch(Team)
 228                 {
 229                         case -1:
 230                         case NUM_TEAM_1:
 231                         case NUM_TEAM_2:
 232                         case NUM_TEAM_3:
 233                         case NUM_TEAM_4:
 234                                 break;
 235                         default:
 236                                 if(GetTeam(Team, false) == world)
 237                                 {
 238                                         LOG_TRACEF("trying to switch to unsupported team %d\n", Team);
 239                                         Team = NUM_SPECTATOR;
 240                                 }
 241                                 break;
 242                 }
 243         }
 244         else
 245         {
 246                 switch(Team)
 247                 {
 248                         case -1:
 249                         case 0:
 250                                 break;
 251                         default:
 252                                 if(GetTeam(Team, false) == world)
 253                                 {
 254                                         LOG_TRACEF("trying to switch to unsupported team %d\n", Team);
 255                                         Team = NUM_SPECTATOR;
 256                                 }
 257                                 break;
 258                 }
 259         }
 260         if(Team == -1) // leave
 261         {
 262                 if(o.has_team)
 263                 {
 264                         tm = GetTeam(o.team, false);
 265                         tm.team_size -= 1;
 266                         o.has_team = 0;
 267                         return true;
 268                 }
 269         }
 270         else
 271         {
 272                 if (!o.has_team)
 273                 {
 274                         o.team = Team;
 275                         tm = GetTeam(Team, true);
 276                         tm.team_size += 1;
 277                         o.has_team = 1;
 278                         return true;
 279                 }
 280                 else if(Team != o.team)
 281                 {
 282                         tm = GetTeam(o.team, false);
 283                         tm.team_size -= 1;
 284                         o.team = Team;
 285                         tm = GetTeam(Team, true);
 286                         tm.team_size += 1;
 287                         return true;
 288                 }
 289         }
 290         return false;
 291 }
 292
 293 void Playerchecker_Think(entity this)
 294 {
 295     int i;
 296         entity e;
 297         for(i = 0; i < maxclients; ++i)
 298         {
 299                 e = playerslots[i];
 300                 if(entcs_GetName(i) == "")
 301                 {
 302                         if(e.sort_prev)
 303                         {
 304                                 // player disconnected
 305                                 SetTeam(e, -1);
 306                                 RemovePlayer(e);
 307                                 e.sort_prev = world;
 308                                 //e.gotscores = 0;
 309                         }
 310                 }
 311                 else
 312                 {
 313                         if (!e.sort_prev)
 314                         {
 315                                 // player connected
 316                                 if (!e)
 317                                 {
 318                                         playerslots[i] = e = new_pure(playerslot);
 319                                 }
 320                                 e.sv_entnum = i;
 321                                 e.ping = 0;
 322                                 e.ping_packetloss = 0;
 323                                 e.ping_movementloss = 0;
 324                                 //e.gotscores = 0; // we might already have the scores...
 325                                 int t = entcs_GetScoreTeam(i);
 326                                 if (t) SetTeam(e, t); // will not hurt; later updates come with HUD_UpdatePlayerTeams
 327                                 RegisterPlayer(e);
 328                                 HUD_UpdatePlayerPos(e);
 329                         }
 330                 }
 331         }
 332         this.nextthink = time + 0.2;
 333 }
 334
 335 void TrueAim_Init();
 336 void PostInit()
 337 {
 338         entity playerchecker = new_pure(playerchecker);
 339         setthink(playerchecker, Playerchecker_Think);
 340         playerchecker.nextthink = time + 0.2;
 341
 342         TrueAim_Init();
 343
 344         postinit = true;
 345 }
 346
 347 // CSQC_InputEvent : Used to perform actions based on any key pressed, key released and mouse on the client.
 348 // Return value should be 1 if CSQC handled the input, otherwise return 0 to have the input passed to the engine.
 349 // All keys are in ascii.
 350 // bInputType = 0 is key pressed, 1 is key released, 2 and 3 are mouse input.
 351 // In the case of keyboard input, nPrimary is the ascii code, and nSecondary is 0.
 352 // In the case of mouse input, nPrimary is xdelta, nSecondary is ydelta.
 353 // In the case of mouse input after a setcursormode(1) call, nPrimary is xpos, nSecondary is ypos.
 354 float CSQC_InputEvent(int bInputType, float nPrimary, float nSecondary)
 355 {
 356     TC(int, bInputType);
 357         if (HUD_Panel_InputEvent(bInputType, nPrimary, nSecondary))
 358                 return true;
 359
 360         if (QuickMenu_InputEvent(bInputType, nPrimary, nSecondary))
 361                 return true;
 362
 363         if (HUD_Radar_InputEvent(bInputType, nPrimary, nSecondary))
 364                 return true;
 365
 366         if (MapVote_InputEvent(bInputType, nPrimary, nSecondary))
 367                 return true;
 368
 369         if (HUD_Minigame_InputEvent(bInputType, nPrimary, nSecondary))
 370                 return true;
 371
 372         return false;
 373 }
 374
 375 // END REQUIRED CSQC FUNCTIONS
 376 // --------------------------------------------------------------------------
 377
 378 // --------------------------------------------------------------------------
 379 // BEGIN OPTIONAL CSQC FUNCTIONS
 380
 381 void Ent_Remove(entity this);
 382
 383 void Ent_RemovePlayerScore(entity this)
 384 {
 385         if(this.owner) {
 386                 SetTeam(this.owner, -1);
 387                 this.owner.gotscores = 0;
 388                 for(int i = 0; i < MAX_SCORE; ++i) {
 389                         this.owner.(scores[i]) = 0; // clear all scores
 390                 }
 391         }
 392 }
 393
 394 NET_HANDLE(ENT_CLIENT_SCORES, bool isnew)
 395 {
 396         make_pure(this);
 397         int i, n;
 398         bool isNew;
 399         entity o;
 400
 401         // damnit -.- don't want to go change every single .sv_entnum in hud.qc AGAIN
 402         // (no I've never heard of M-x replace-string, sed, or anything like that)
 403         isNew = !this.owner; // workaround for DP bug
 404         n = ReadByte()-1;
 405
 406 #ifdef DP_CSQC_ENTITY_REMOVE_IS_B0RKED
 407         if(!isNew && n != this.sv_entnum)
 408         {
 409                 //print("A CSQC entity changed its owner!\n");
 410                 LOG_INFOF("A CSQC entity changed its owner! (edict: %d, classname: %s)\n", etof(this), this.classname);
 411                 isNew = true;
 412                 Ent_Remove(this);
 413         }
 414 #endif
 415
 416         this.sv_entnum = n;
 417
 418         o = playerslots[this.sv_entnum];
 419         if (!o)
 420         {
 421                 o = playerslots[this.sv_entnum] = new_pure(playerslot);
 422         }
 423         this.owner = o;
 424         o.sv_entnum = this.sv_entnum;
 425         o.gotscores = 1;
 426
 427         //if (!o.sort_prev)
 428         //      RegisterPlayer(o);
 429         //playerchecker will do this for us later, if it has not already done so
 430
 431     int sf, lf;
 432 #if MAX_SCORE <= 8
 433         sf = ReadByte();
 434         lf = ReadByte();
 435 #else
 436         sf = ReadShort();
 437         lf = ReadShort();
 438 #endif
 439     int p;
 440         for(i = 0, p = 1; i < MAX_SCORE; ++i, p *= 2)
 441                 if(sf & p)
 442                 {
 443                         if(lf & p)
 444                                 o.(scores[i]) = ReadInt24_t();
 445                         else
 446                                 o.(scores[i]) = ReadChar();
 447                 }
 448
 449         return = true;
 450
 451         if(o.sort_prev)
 452                 HUD_UpdatePlayerPos(o); // if not registered, we cannot do this yet!
 453
 454         this.entremove = Ent_RemovePlayerScore;
 455 }
 456
 457 NET_HANDLE(ENT_CLIENT_TEAMSCORES, bool isnew)
 458 {
 459         make_pure(this);
 460         int i;
 461         entity o;
 462
 463         this.team = ReadByte();
 464         o = this.owner = GetTeam(this.team, true); // these team numbers can always be trusted
 465
 466     int sf, lf;
 467 #if MAX_TEAMSCORE <= 8
 468         sf = ReadByte();
 469         lf = ReadByte();
 470 #else
 471         sf = ReadShort();
 472         lf = ReadShort();
 473 #endif
 474         int p;
 475         for(i = 0, p = 1; i < MAX_TEAMSCORE; ++i, p *= 2)
 476                 if(sf & p)
 477                 {
 478                         if(lf & p)
 479                                 o.(teamscores[i]) = ReadInt24_t();
 480                         else
 481                                 o.(teamscores[i]) = ReadChar();
 482                 }
 483
 484         return = true;
 485
 486         HUD_UpdateTeamPos(o);
 487 }
 488
 489 NET_HANDLE(ENT_CLIENT_CLIENTDATA, bool isnew)
 490 {
 491         make_pure(this);
 492         float newspectatee_status;
 493
 494     int f = ReadByte();
 495
 496         scoreboard_showscores_force = (f & 1);
 497
 498         if(f & 2)
 499         {
 500                 newspectatee_status = ReadByte();
 501                 if(newspectatee_status == player_localnum + 1)
 502                         newspectatee_status = -1; // observing
 503         }
 504         else
 505                 newspectatee_status = 0;
 506
 507         spectatorbutton_zoom = (f & 4);
 508
 509         if(f & 8)
 510         {
 511                 angles_held_status = 1;
 512                 angles_held.x = ReadAngle();
 513                 angles_held.y = ReadAngle();
 514                 angles_held.z = 0;
 515         }
 516         else
 517                 angles_held_status = 0;
 518
 519         return = true;
 520
 521         if(newspectatee_status != spectatee_status)
 522         {
 523                 // clear race stuff
 524                 race_laptime = 0;
 525                 race_checkpointtime = 0;
 526         }
 527         if (autocvar_hud_panel_healtharmor_progressbar_gfx)
 528         {
 529                 if ( (spectatee_status == -1 && newspectatee_status > 0) //before observing, now spectating
 530                   || (spectatee_status > 0 && newspectatee_status > 0 && spectatee_status != newspectatee_status) //changed spectated player
 531                 )
 532                         prev_p_health = -1;
 533                 else if(spectatee_status && !newspectatee_status) //before observing/spectating, now playing
 534                         prev_health = -1;
 535         }
 536         spectatee_status = newspectatee_status;
 537
 538         // we could get rid of spectatee_status, and derive it from player_localentnum and player_localnum
 539 }
 540
 541 NET_HANDLE(ENT_CLIENT_NAGGER, bool isnew)
 542 {
 543         make_pure(this);
 544     int i, j, b, f;
 545
 546     int nags = ReadByte(); // NAGS NAGS NAGS NAGS NAGS NAGS NADZ NAGS NAGS NAGS
 547
 548         if(!(nags & BIT(2)))
 549         {
 550                 if(vote_called_vote)
 551                         strunzone(vote_called_vote);
 552                 vote_called_vote = string_null;
 553                 vote_active = 0;
 554         }
 555         else
 556         {
 557                 vote_active = 1;
 558         }
 559
 560         if(nags & BIT(6))
 561         {
 562                 vote_yescount = ReadByte();
 563                 vote_nocount = ReadByte();
 564                 vote_needed = ReadByte();
 565                 vote_highlighted = ReadChar();
 566         }
 567
 568         if(nags & BIT(7))
 569         {
 570                 if(vote_called_vote)
 571                         strunzone(vote_called_vote);
 572                 vote_called_vote = strzone(ColorTranslateRGB(ReadString()));
 573         }
 574
 575         if(nags & 1)
 576         {
 577                 for(j = 0; j < maxclients; ++j)
 578                         if(playerslots[j])
 579                                 playerslots[j].ready = 1;
 580                 for(i = 1; i <= maxclients; i += 8)
 581                 {
 582                         f = ReadByte();
 583                         for(j = i-1, b = 1; b < 256; b *= 2, ++j)
 584                                 if (!(f & b))
 585                                         if(playerslots[j])
 586                                                 playerslots[j].ready = 0;
 587                 }
 588         }
 589
 590         return = true;
 591
 592         ready_waiting = (nags & BIT(0));
 593         ready_waiting_for_me = (nags & BIT(1));
 594         vote_waiting = (nags & BIT(2));
 595         vote_waiting_for_me = (nags & BIT(3));
 596         warmup_stage = (nags & BIT(4));
 597 }
 598
 599 NET_HANDLE(ENT_CLIENT_ELIMINATEDPLAYERS, bool isnew)
 600 {
 601         make_pure(this);
 602     int i, j, b, f;
 603
 604     int sf = ReadByte();
 605         if(sf & 1)
 606         {
 607                 for(j = 0; j < maxclients; ++j)
 608                         if(playerslots[j])
 609                                 playerslots[j].eliminated = 1;
 610                 for(i = 1; i <= maxclients; i += 8)
 611                 {
 612                         f = ReadByte();
 613                         for(j = i-1, b = 1; b < 256; b *= 2, ++j)
 614                                 if (!(f & b))
 615                                         if(playerslots[j])
 616                                                 playerslots[j].eliminated = 0;
 617                 }
 618         }
 619         return true;
 620 }
 621
 622 NET_HANDLE(ENT_CLIENT_RANDOMSEED, bool isnew)
 623 {
 624         make_pure(this);
 625         prandom_debug();
 626         float s = ReadShort();
 627         psrandom(s);
 628         return true;
 629 }
 630
 631 NET_HANDLE(ENT_CLIENT_ACCURACY, bool isnew)
 632 {
 633         make_pure(this);
 634     int sf = ReadInt24_t();
 635         if (sf == 0) {
 636                 for (int w = 0; w <= WEP_LAST - WEP_FIRST; ++w)
 637                         weapon_accuracy[w] = -1;
 638                 return true;
 639         }
 640
 641         int f = 1;
 642         for (int w = 0; w <= WEP_LAST - WEP_FIRST; ++w) {
 643                 if (sf & f) {
 644             int b = ReadByte();
 645                         if (b == 0)
 646                                 weapon_accuracy[w] = -1;
 647                         else if (b == 255)
 648                                 weapon_accuracy[w] = 1.0; // no better error handling yet, sorry
 649                         else
 650                                 weapon_accuracy[w] = (b - 1.0) / 100.0;
 651                 }
 652                 f = (f == 0x800000) ? 1 : f * 2;
 653         }
 654         return true;
 655 }
 656
 657 void Spawn_Draw(entity this)
 658 {
 659         __pointparticles(this.cnt, this.origin + '0 0 28', '0 0 2', bound(0, frametime, 0.1));
 660 }
 661
 662 void Spawn_PreDraw(entity this)
 663 {
 664         float alph;
 665         vector org = getpropertyvec(VF_ORIGIN);
 666         if(this.fade_start)
 667                 alph = bound(0, (this.fade_end - vlen(org - this.origin - 0.5 * (this.mins + this.maxs))) / (this.fade_end - this.fade_start), 1);
 668         else
 669                 alph = 1;
 670         //printf("%v <-> %v\n", view_origin, this.origin + 0.5 * (this.mins + this.maxs));
 671         this.alpha = alph;
 672         if(alph <= 0)
 673                 this.drawmask = 0;
 674         else
 675                 this.drawmask = MASK_NORMAL;
 676 }
 677
 678 NET_HANDLE(ENT_CLIENT_SPAWNPOINT, bool is_new)
 679 {
 680         float teamnum = (ReadByte() - 1);
 681         vector spn_origin;
 682         spn_origin.x = ReadCoord();
 683         spn_origin.y = ReadCoord();
 684         spn_origin.z = ReadCoord();
 685
 686         //if(is_new)
 687         //{
 688                 this.origin = spn_origin;
 689                 setsize(this, PL_MIN_CONST, PL_MAX_CONST);
 690                 //droptofloor();
 691
 692                 /*if(autocvar_cl_spawn_point_model) // needs a model first
 693                 {
 694                         this.mdl = "models/spawnpoint.md3";
 695                         this.colormod = Team_ColorRGB(teamnum);
 696                         precache_model(this.mdl);
 697                         setmodel(this, this.mdl);
 698                         this.drawmask = MASK_NORMAL;
 699                         //this.movetype = MOVETYPE_NOCLIP;
 700                         //this.draw = Spawn_Draw;
 701                 }*/
 702                 if(autocvar_cl_spawn_point_particles)
 703                 {
 704                         if((serverflags & SERVERFLAG_TEAMPLAY))
 705                         {
 706                                 switch(teamnum)
 707                                 {
 708                                         case NUM_TEAM_1: this.cnt = particleeffectnum(EFFECT_SPAWNPOINT_RED); break;
 709                                         case NUM_TEAM_2: this.cnt = particleeffectnum(EFFECT_SPAWNPOINT_BLUE); break;
 710                                         case NUM_TEAM_3: this.cnt = particleeffectnum(EFFECT_SPAWNPOINT_YELLOW); break;
 711                                         case NUM_TEAM_4: this.cnt = particleeffectnum(EFFECT_SPAWNPOINT_PINK); break;
 712                                         default: this.cnt = particleeffectnum(EFFECT_SPAWNPOINT_NEUTRAL); break;
 713                                 }
 714                         }
 715                         else { this.cnt = particleeffectnum(EFFECT_SPAWNPOINT_NEUTRAL); }
 716
 717                         this.draw = Spawn_Draw;
 718                         setpredraw(this, Spawn_PreDraw);
 719                         this.fade_start = autocvar_cl_spawn_point_dist_min;
 720                         this.fade_end = autocvar_cl_spawn_point_dist_max;
 721                 }
 722         //}
 723
 724         //printf("Ent_ReadSpawnPoint(is_new = %d); origin = %s, team = %d, effect = %d\n", is_new, vtos(this.origin), teamnum, this.cnt);
 725         return true;
 726 }
 727
 728 NET_HANDLE(ENT_CLIENT_SPAWNEVENT, bool is_new)
 729 {
 730         // If entnum is 0, ONLY do the local spawn actions
 731         // this way the server can disable the sending of
 732         // spawn origin or such to clients if wanted.
 733         float entnum = ReadByte();
 734
 735         if(entnum)
 736         {
 737                 this.origin_x = ReadCoord();
 738                 this.origin_y = ReadCoord();
 739                 this.origin_z = ReadCoord();
 740
 741                 if(is_new)
 742                 {
 743                         float teamnum = entcs_GetTeam(entnum - 1);
 744
 745                         if(autocvar_cl_spawn_event_particles)
 746                         {
 747                                 switch(teamnum)
 748                                 {
 749                                         case NUM_TEAM_1: pointparticles(EFFECT_SPAWN_RED, this.origin, '0 0 0', 1); break;
 750                                         case NUM_TEAM_2: pointparticles(EFFECT_SPAWN_BLUE, this.origin, '0 0 0', 1); break;
 751                                         case NUM_TEAM_3: pointparticles(EFFECT_SPAWN_YELLOW, this.origin, '0 0 0', 1); break;
 752                                         case NUM_TEAM_4: pointparticles(EFFECT_SPAWN_PINK, this.origin, '0 0 0', 1); break;
 753                                         default: pointparticles(EFFECT_SPAWN_NEUTRAL, this.origin, '0 0 0', 1); break;
 754                                 }
 755                         }
 756                         if(autocvar_cl_spawn_event_sound)
 757                         {
 758                                 sound(this, CH_TRIGGER, SND_SPAWN, VOL_BASE, ATTEN_NORM);
 759                         }
 760                 }
 761         }
 762         return = true;
 763
 764         // local spawn actions
 765         if(is_new && (!entnum || (entnum == player_localentnum)))
 766         {
 767                 zoomin_effect = 1;
 768                 current_viewzoom = (1 / bound(1, autocvar_cl_spawnzoom_factor, 16));
 769
 770                 if(autocvar_cl_unpress_zoom_on_spawn)
 771                 {
 772                         localcmd("-zoom\n");
 773                         button_zoom = false;
 774                 }
 775         }
 776         HUD_Radar_Hide_Maximized();
 777         //printf("Ent_ReadSpawnEvent(is_new = %d); origin = %s, entnum = %d, localentnum = %d\n", is_new, vtos(this.origin), entnum, player_localentnum);
 778 }
 779
 780 // CSQC_Ent_Update : Called every frame that the server has indicated an update to the SSQC / CSQC entity has occured.
 781 // The only parameter reflects if the entity is "new" to the client, meaning it just came into the client's PVS.
 782 void CSQC_Ent_Update(bool isnew)
 783 {
 784         SELFPARAM();
 785         this.sourceLoc = __FILE__ ":" STR(__LINE__);
 786         int t = ReadByte();
 787
 788         // set up the "time" global for received entities to be correct for interpolation purposes
 789         float savetime = time;
 790         if(servertime)
 791         {
 792                 time = servertime;
 793         }
 794         else
 795         {
 796                 serverprevtime = time;
 797                 serverdeltatime = STAT(MOVEVARS_TICRATE) * STAT(MOVEVARS_TIMESCALE);
 798                 time = serverprevtime + serverdeltatime;
 799         }
 800
 801 #ifdef DP_CSQC_ENTITY_REMOVE_IS_B0RKED
 802         if (this.enttype)
 803         {
 804                 if (t != this.enttype || isnew)
 805                 {
 806                         LOG_INFOF("A CSQC entity changed its type! (edict: %d, server: %d, type: %d -> %d)\n", etof(this), this.entnum, this.enttype, t);
 807                         Ent_Remove(this);
 808                         clearentity(this);
 809                         isnew = true;
 810                 }
 811         }
 812         else
 813         {
 814                 if (!isnew)
 815                 {
 816                         LOG_INFOF("A CSQC entity appeared out of nowhere! (edict: %d, server: %d, type: %d)\n", etof(this), this.entnum, t);
 817                         isnew = true;
 818                 }
 819         }
 820 #endif
 821         this.enttype = t;
 822         bool done = false;
 823         FOREACH(LinkedEntities, it.m_id == t, {
 824                 if (isnew) this.classname = it.netname;
 825                 if (autocvar_developer_csqcentities)
 826             LOG_INFOF("CSQC_Ent_Update(%d) at %f with this=%i {.entnum=%d, .enttype=%d} t=%s (%d)\n", isnew, savetime, this, this.entnum, this.enttype, this.classname, t);
 827                 done = it.m_read(this, NULL, isnew);
 828                 break;
 829         });
 830         time = savetime;
 831         if (!done)
 832         {
 833                 LOG_FATALF("CSQC_Ent_Update(%d) at %f with this=%i {.entnum=%d, .enttype=%d} t=%s (%d)\n", isnew, savetime, this, this.entnum, this.enttype, this.classname, t);
 834         }
 835 }
 836
 837 // Destructor, but does NOT deallocate the entity by calling remove(). Also
 838 // used when an entity changes its type. For an entity that someone interacts
 839 // with others, make sure it can no longer do so.
 840 void Ent_Remove(entity this)
 841 {
 842         if(this.entremove) this.entremove(this);
 843
 844         if(this.skeletonindex)
 845         {
 846                 skel_delete(this.skeletonindex);
 847                 this.skeletonindex = 0;
 848         }
 849
 850         if(this.snd_looping > 0)
 851         {
 852                 sound(this, this.snd_looping, SND_Null, VOL_BASE, autocvar_g_jetpack_attenuation);
 853                 this.snd_looping = 0;
 854         }
 855
 856         this.enttype = 0;
 857         this.classname = "";
 858         this.draw = func_null;
 859         this.entremove = func_null;
 860         // TODO possibly set more stuff to defaults
 861 }
 862 // CSQC_Ent_Remove : Called when the server requests a SSQC / CSQC entity to be removed.  Essentially call remove(this) as well.
 863 void CSQC_Ent_Remove()
 864 {
 865         SELFPARAM();
 866         if (autocvar_developer_csqcentities) LOG_INFOF("CSQC_Ent_Remove() with this=%i {.entnum=%d, .enttype=%d}\n", this, this.entnum, this.enttype);
 867         if (wasfreed(this))
 868         {
 869                 LOG_WARNING("CSQC_Ent_Remove called for already removed entity. Packet loss?\n");
 870                 return;
 871         }
 872         if (this.enttype) Ent_Remove(this);
 873         remove(this);
 874 }
 875
 876 void Gamemode_Init()
 877 {
 878         if (!isdemo())
 879         {
 880                 if(!(calledhooks & HOOK_START))
 881                         localcmd("\n_cl_hook_gamestart ", MapInfo_Type_ToString(gametype), "\n");
 882                 calledhooks |= HOOK_START;
 883         }
 884 }
 885 // CSQC_Parse_StuffCmd : Provides the stuffcmd string in the first parameter that the server provided.  To execute standard behavior, simply execute localcmd with the string.
 886 void CSQC_Parse_StuffCmd(string strMessage)
 887 {
 888         if (autocvar_developer_csqcentities) LOG_INFOF("CSQC_Parse_StuffCmd(\"%s\")\n", strMessage);
 889         localcmd(strMessage);
 890 }
 891 // CSQC_Parse_Print : Provides the print string in the first parameter that the server provided.  To execute standard behavior, simply execute print with the string.
 892 void CSQC_Parse_Print(string strMessage)
 893 {
 894         if (autocvar_developer_csqcentities) LOG_INFOF("CSQC_Parse_Print(\"%s\")\n", strMessage);
 895         print(ColorTranslateRGB(strMessage));
 896 }
 897
 898 // CSQC_Parse_CenterPrint : Provides the centerprint_hud string in the first parameter that the server provided.
 899 void CSQC_Parse_CenterPrint(string strMessage)
 900 {
 901         if (autocvar_developer_csqcentities) LOG_INFOF("CSQC_Parse_CenterPrint(\"%s\")\n", strMessage);
 902         centerprint_hud(strMessage);
 903 }
 904
 905 // CSQC_Parse_TempEntity : Handles all temporary entity network data in the CSQC layer.
 906 // You must ALWAYS first acquire the temporary ID, which is sent as a byte.
 907 // Return value should be 1 if CSQC handled the temporary entity, otherwise return 0 to have the engine process the event.
 908 bool CSQC_Parse_TempEntity()
 909 {
 910         // Acquire TE ID
 911         int nTEID = ReadByte();
 912
 913         FOREACH(TempEntities, it.m_id == nTEID, {
 914                 if (autocvar_developer_csqcentities)
 915                         LOG_INFOF("CSQC_Parse_TempEntity() nTEID=%s (%d)\n", it.netname, nTEID);
 916                 return it.m_read(NULL, NULL, true);
 917         });
 918
 919         if (autocvar_developer_csqcentities)
 920                 LOG_INFOF("CSQC_Parse_TempEntity() with nTEID=%d\n", nTEID);
 921
 922         // No special logic for this temporary entity; return 0 so the engine can handle it
 923         return false;
 924 }
 925
 926 string forcefog;
 927 void Fog_Force()
 928 {
 929         if (autocvar_cl_orthoview && autocvar_cl_orthoview_nofog)
 930                 localcmd("\nr_drawfog 0\n");
 931         else if (forcefog != "")
 932                 localcmd(sprintf("\nfog %s\nr_fog_exp2 0\nr_drawfog 1\n", forcefog));
 933 }
 934
 935 void Gamemode_Init();
 936 NET_HANDLE(ENT_CLIENT_SCORES_INFO, bool isnew)
 937 {
 938         make_pure(this);
 939         gametype = ReadInt24_t();
 940         HUD_ModIcons_SetFunc();
 941         for (int i = 0; i < MAX_SCORE; ++i)
 942         {
 943                 if (scores_label[i]) strunzone(scores_label[i]);
 944                 scores_label[i] = strzone(ReadString());
 945                 scores_flags[i] = ReadByte();
 946         }
 947         for (int i = 0; i < MAX_TEAMSCORE; ++i)
 948         {
 949                 if (teamscores_label[i]) strunzone(teamscores_label[i]);
 950                 teamscores_label[i] = strzone(ReadString());
 951                 teamscores_flags[i] = ReadByte();
 952         }
 953         return = true;
 954         HUD_InitScores();
 955         Gamemode_Init();
 956 }
 957
 958 NET_HANDLE(ENT_CLIENT_INIT, bool isnew)
 959 {
 960         nb_pb_period = ReadByte() / 32; //Accuracy of 1/32th
 961
 962         hook_shotorigin[0] = decompressShotOrigin(ReadInt24_t());
 963         hook_shotorigin[1] = decompressShotOrigin(ReadInt24_t());
 964         hook_shotorigin[2] = decompressShotOrigin(ReadInt24_t());
 965         hook_shotorigin[3] = decompressShotOrigin(ReadInt24_t());
 966         arc_shotorigin[0] = decompressShotOrigin(ReadInt24_t());
 967         arc_shotorigin[1] = decompressShotOrigin(ReadInt24_t());
 968         arc_shotorigin[2] = decompressShotOrigin(ReadInt24_t());
 969         arc_shotorigin[3] = decompressShotOrigin(ReadInt24_t());
 970
 971         if (forcefog) strunzone(forcefog);
 972         forcefog = strzone(ReadString());
 973
 974         armorblockpercent = ReadByte() / 255.0;
 975
 976         serverflags = ReadByte();
 977
 978         g_trueaim_minrange = ReadCoord();
 979
 980         return = true;
 981
 982         MUTATOR_CALLHOOK(Ent_Init);
 983
 984         if (!postinit) PostInit();
 985 }
 986
 987 NET_HANDLE(TE_CSQC_RACE, bool isNew)
 988 {
 989         int b = ReadByte();
 990
 991         switch (b)
 992         {
 993                 case RACE_NET_CHECKPOINT_HIT_QUALIFYING:
 994                         race_checkpoint = ReadByte();
 995                         race_time = ReadInt24_t();
 996                         race_previousbesttime = ReadInt24_t();
 997                         if(race_previousbestname)
 998                                 strunzone(race_previousbestname);
 999                         race_previousbestname = strzone(ColorTranslateRGB(ReadString()));
1000
1001                         race_checkpointtime = time;
1002
1003                         if(race_checkpoint == 0 || race_checkpoint == 254)
1004                         {
1005                                 race_penaltyaccumulator = 0;
1006                                 race_laptime = time; // valid
1007                         }
1008
1009                         break;
1010
1011                 case RACE_NET_CHECKPOINT_CLEAR:
1012                         race_laptime = 0;
1013                         race_checkpointtime = 0;
1014                         break;
1015
1016                 case RACE_NET_CHECKPOINT_NEXT_SPEC_QUALIFYING:
1017                         race_laptime = ReadCoord();
1018                         race_checkpointtime = -99999;
1019                         // fall through
1020                 case RACE_NET_CHECKPOINT_NEXT_QUALIFYING:
1021                         race_nextcheckpoint = ReadByte();
1022
1023                         race_nextbesttime = ReadInt24_t();
1024                         if(race_nextbestname)
1025                                 strunzone(race_nextbestname);
1026                         race_nextbestname = strzone(ColorTranslateRGB(ReadString()));
1027                         break;
1028
1029                 case RACE_NET_CHECKPOINT_HIT_RACE:
1030                         race_mycheckpoint = ReadByte();
1031                         race_mycheckpointtime = time;
1032                         race_mycheckpointdelta = ReadInt24_t();
1033                         race_mycheckpointlapsdelta = ReadByte();
1034                         if(race_mycheckpointlapsdelta >= 128)
1035                                 race_mycheckpointlapsdelta -= 256;
1036                         if(race_mycheckpointenemy)
1037                                 strunzone(race_mycheckpointenemy);
1038                         race_mycheckpointenemy = strzone(ColorTranslateRGB(ReadString()));
1039                         break;
1040
1041                 case RACE_NET_CHECKPOINT_HIT_RACE_BY_OPPONENT:
1042                         race_othercheckpoint = ReadByte();
1043                         race_othercheckpointtime = time;
1044                         race_othercheckpointdelta = ReadInt24_t();
1045                         race_othercheckpointlapsdelta = ReadByte();
1046                         if(race_othercheckpointlapsdelta >= 128)
1047                                 race_othercheckpointlapsdelta -= 256;
1048                         if(race_othercheckpointenemy)
1049                                 strunzone(race_othercheckpointenemy);
1050                         race_othercheckpointenemy = strzone(ColorTranslateRGB(ReadString()));
1051                         break;
1052
1053                 case RACE_NET_PENALTY_RACE:
1054                         race_penaltyeventtime = time;
1055                         race_penaltytime = ReadShort();
1056                         //race_penaltyaccumulator += race_penaltytime;
1057                         if(race_penaltyreason)
1058                                 strunzone(race_penaltyreason);
1059                         race_penaltyreason = strzone(ReadString());
1060                         break;
1061
1062                 case RACE_NET_PENALTY_QUALIFYING:
1063                         race_penaltyeventtime = time;
1064                         race_penaltytime = ReadShort();
1065                         race_penaltyaccumulator += race_penaltytime;
1066                         if(race_penaltyreason)
1067                                 strunzone(race_penaltyreason);
1068                         race_penaltyreason = strzone(ReadString());
1069                         break;
1070
1071                 case RACE_NET_SERVER_RECORD:
1072                         race_server_record = ReadInt24_t();
1073                         break;
1074                 case RACE_NET_SPEED_AWARD:
1075                         race_speedaward = ReadInt24_t();
1076                         if(race_speedaward_holder)
1077                                 strunzone(race_speedaward_holder);
1078                         race_speedaward_holder = strzone(ReadString());
1079                         break;
1080                 case RACE_NET_SPEED_AWARD_BEST:
1081                         race_speedaward_alltimebest = ReadInt24_t();
1082                         if(race_speedaward_alltimebest_holder)
1083                                 strunzone(race_speedaward_alltimebest_holder);
1084                         race_speedaward_alltimebest_holder = strzone(ReadString());
1085                         break;
1086                 case RACE_NET_SERVER_RANKINGS:
1087                         float prevpos, del;
1088             int pos = ReadShort();
1089                         prevpos = ReadShort();
1090                         del = ReadShort();
1091
1092                         // move other rankings out of the way
1093             int i;
1094                         if (prevpos) {
1095                                 for (i=prevpos-1;i>pos-1;--i) {
1096                                         grecordtime[i] = grecordtime[i-1];
1097                                         if(grecordholder[i])
1098                                                 strunzone(grecordholder[i]);
1099                                         grecordholder[i] = strzone(grecordholder[i-1]);
1100                                 }
1101                         } else if (del) { // a record has been deleted by the admin
1102                                 for (i=pos-1; i<= RANKINGS_CNT-1; ++i) {
1103                                         if (i == RANKINGS_CNT-1) { // clear out last record
1104                                                 grecordtime[i] = 0;
1105                                                 if (grecordholder[i])
1106                                                         strunzone(grecordholder[i]);
1107                                                 grecordholder[i] = string_null;
1108                                         }
1109                                         else {
1110                                                 grecordtime[i] = grecordtime[i+1];
1111                                                 if (grecordholder[i])
1112                                                         strunzone(grecordholder[i]);
1113                                                 grecordholder[i] = strzone(grecordholder[i+1]);
1114                                         }
1115                                 }
1116                         } else { // player has no ranked record yet
1117                                 for (i=RANKINGS_CNT-1;i>pos-1;--i) {
1118                                         grecordtime[i] = grecordtime[i-1];
1119                                         if(grecordholder[i])
1120                                                 strunzone(grecordholder[i]);
1121                                         grecordholder[i] = strzone(grecordholder[i-1]);
1122                                 }
1123                         }
1124
1125                         // store new ranking
1126                         if(grecordholder[pos-1] != "")
1127                                 strunzone(grecordholder[pos-1]);
1128                         grecordholder[pos-1] = strzone(ReadString());
1129                         grecordtime[pos-1] = ReadInt24_t();
1130                         if(grecordholder[pos-1] == entcs_GetName(player_localnum))
1131                                 race_myrank = pos;
1132                         break;
1133                 case RACE_NET_SERVER_STATUS:
1134                         race_status = ReadShort();
1135                         if(race_status_name)
1136                                 strunzone(race_status_name);
1137                         race_status_name = strzone(ReadString());
1138         }
1139         return true;
1140 }
1141
1142 NET_HANDLE(TE_CSQC_TEAMNAGGER, bool isNew)
1143 {
1144         teamnagger = 1;
1145         return true;
1146 }
1147
1148 NET_HANDLE(TE_CSQC_PINGPLREPORT, bool isNew)
1149 {
1150         int i = ReadByte();
1151         int pi = ReadShort();
1152         int pl = ReadByte();
1153         int ml = ReadByte();
1154         return = true;
1155         entity e = playerslots[i];
1156         if (!e) return;
1157         e.ping = pi;
1158         e.ping_packetloss = pl / 255.0;
1159         e.ping_movementloss = ml / 255.0;
1160 }
1161
1162 NET_HANDLE(TE_CSQC_WEAPONCOMPLAIN, bool isNew)
1163 {
1164         complain_weapon = ReadByte();
1165         complain_weapon_type = ReadByte();
1166         return = true;
1167
1168         complain_weapon_time = time;
1169         weapontime = time; // ping the weapon panel
1170
1171         switch(complain_weapon_type)
1172         {
1173                 case 0: Local_Notification(MSG_MULTI, ITEM_WEAPON_NOAMMO, complain_weapon); break;
1174                 case 1: Local_Notification(MSG_MULTI, ITEM_WEAPON_DONTHAVE, complain_weapon); break;
1175                 default: Local_Notification(MSG_MULTI, ITEM_WEAPON_UNAVAILABLE, complain_weapon); break;
1176         }
1177 }
1178
1179 string getcommandkey(string text, string command)
1180 {
1181         string keys;
1182         float n, j, k, l = 0;
1183
1184         if (!autocvar_hud_showbinds)
1185                 return text;
1186
1187         keys = db_get(binddb, command);
1188         if (keys == "")
1189         {
1190                 bool joy_detected = cvar("joy_detected");
1191                 n = tokenize(findkeysforcommand(command, 0)); // uses '...' strings
1192                 for(j = 0; j < n; ++j)
1193                 {
1194                         k = stof(argv(j));
1195                         if(k != -1)
1196                         {
1197                                 string key = keynumtostring(k);
1198                                 if(!joy_detected && substring(key, 0, 3) == "JOY")
1199                                         continue;
1200
1201                                 if (keys == "")
1202                                         keys = key;
1203                                 else
1204                                         keys = strcat(keys, ", ", key);
1205
1206                                 ++l;
1207                                 if (autocvar_hud_showbinds_limit > 0 && autocvar_hud_showbinds_limit <= l)
1208                                         break;
1209                         }
1210
1211                 }
1212                 if (keys == "")
1213                         keys = "NO_KEY";
1214                 db_put(binddb, command, keys);
1215         }
1216
1217         if (keys == "NO_KEY") {
1218                 if (autocvar_hud_showbinds > 1)
1219                         return sprintf(_("%s (not bound)"), text);
1220                 else
1221                         return text;
1222         }
1223         else if (autocvar_hud_showbinds > 1)
1224                 return sprintf("%s (%s)", text, keys);
1225         else
1226                 return keys;
1227 }