qcsrc/client/main.qc

   1 #include "main.qh"
   2
   3 #include <client/command/cl_cmd.qh>
   4 #include <client/draw.qh>
   5 #include <client/hud/_mod.qh>
   6 #include <client/hud/panel/centerprint.qh>
   7 #include <client/hud/panel/chat.qh>
   8 #include <client/hud/panel/quickmenu.qh>
   9 #include <client/hud/panel/scoreboard.qh>
  10 #include <client/items/items.qh>
  11 #include <client/mapvoting.qh>
  12 #include <client/mutators/_mod.qh>
  13 #include <client/shownames.qh>
  14 #include <client/view.qh>
  15 #include <client/weapons/projectile.qh>
  16 #include <common/deathtypes/all.qh>
  17 #include <common/effects/all.inc>
  18 #include <common/effects/all.qh>
  19 #include <common/effects/effect.qh>
  20 #include <common/effects/qc/_mod.qh>
  21 #include <common/ent_cs.qh>
  22 #include <common/gamemodes/gamemode/nexball/cl_nexball.qh>
  23 #include <common/items/_mod.qh>
  24 #include <common/mapinfo.qh>
  25 #include <common/mapobjects/_mod.qh>
  26 #include <common/minigames/cl_minigames.qh>
  27 #include <common/minigames/cl_minigames_hud.qh>
  28 #include <common/net_linked.qh>
  29 #include <common/net_notice.qh>
  30 #include <common/scores.qh>
  31 #include <common/vehicles/all.qh>
  32 #include <lib/csqcmodel/cl_model.qh>
  33 #include <lib/csqcmodel/interpolate.qh>
  34 #include <lib/warpzone/client.qh>
  35
  36 // --------------------------------------------------------------------------
  37 // BEGIN REQUIRED CSQC FUNCTIONS
  38 //include "main.qh"
  39
  40 #define DP_CSQC_ENTITY_REMOVE_IS_B0RKED
  41
  42 // CSQC_Init : Called every time the CSQC code is initialized (essentially at map load)
  43 // Useful for precaching things
  44
  45 void CSQC_Init()
  46 {
  47         prvm_language = strzone(cvar_string("prvm_language"));
  48
  49 #ifdef WATERMARK
  50         LOG_TRACEF("^4CSQC Build information: ^1%s", WATERMARK);
  51 #endif
  52
  53         {
  54                 int i = 0;
  55                 for ( ; i < 255; ++i)
  56                         if (getplayerkeyvalue(i, "viewentity") == "")
  57                                 break;
  58                 maxclients = i;
  59         }
  60
  61         // needs to be done so early because of the constants they create
  62         static_init();
  63         static_init_late();
  64         static_init_precache();
  65
  66         binddb = db_create();
  67         tempdb = db_create();
  68         ClientProgsDB = db_load("client.db");
  69
  70         draw_endBoldFont();
  71
  72         //registercommand("hud_configure");
  73         //registercommand("hud_save");
  74         //registercommand("menu_action");
  75
  76         ConsoleCommand_macro_init();
  77
  78         registercvar("hud_usecsqc", "1");
  79         registercvar("scoreboard_columns", "default");
  80
  81         registercvar("cl_nade_type", "3");
  82         registercvar("cl_pokenade_type", "zombie");
  83
  84         registercvar("cl_jumpspeedcap_min", "");
  85         registercvar("cl_jumpspeedcap_max", "");
  86
  87         registercvar("cl_shootfromfixedorigin", "");
  88
  89         registercvar("cl_multijump", "-1");
  90
  91         registercvar("cl_dodging", "0");
  92
  93         registercvar("cl_spawn_near_teammate", "1");
  94
  95         registercvar("cl_weapon_switch_reload", "1");
  96         registercvar("cl_weapon_switch_fallback_to_impulse", "1");
  97
  98         registercvar("cl_allow_uidranking", "1");
  99
 100         if(autocvar_cl_lockview)
 101                 cvar_set("cl_lockview", "0");
 102
 103         if (cvar_type("_scoreboard_team_selection_available") & CVAR_TYPEFLAG_EXISTS)
 104                 cvar_settemp("_scoreboard_team_selection_available", "1");
 105         cvar_set("_scoreboard_team_selection", "0"); // in case it has been left set to 1
 106
 107         gametype = NULL;
 108
 109         postinit = false;
 110
 111         calledhooks = 0;
 112
 113         teams = Sort_Spawn();
 114         players = Sort_Spawn();
 115
 116         GetTeam(NUM_SPECTATOR, true); // add specs first
 117
 118         for (int w = 0; w <= WEP_LAST - WEP_FIRST; ++w)
 119                 weapon_accuracy[w] = -1;
 120
 121         // precaches
 122
 123         if(autocvar_cl_reticle)
 124         {
 125                 precache_pic("gfx/reticle_normal");
 126                 // weapon reticles are precached in weapon files
 127         }
 128
 129         {
 130                 get_mi_min_max_texcoords(1); // try the CLEVER way first
 131                 minimapname = strcat("gfx/", mi_shortname, "_radar");
 132
 133                 if (precache_pic(minimapname) == "")
 134                 {
 135                         // but maybe we have a non-clever minimap
 136                         minimapname = strcat("gfx/", mi_shortname, "_mini");
 137                         if (precache_pic(minimapname) == "")
 138                                 minimapname = ""; // FAIL
 139                         else
 140                                 get_mi_min_max_texcoords(0); // load new texcoords
 141                 }
 142
 143                 mi_center = (mi_min + mi_max) * 0.5;
 144                 mi_scale = mi_max - mi_min;
 145                 minimapname = strzone(minimapname);
 146         }
 147
 148         hud_skin_path = strzone(strcat("gfx/hud/", autocvar_hud_skin));
 149         LoadMenuSkinValues();
 150 }
 151
 152 // CSQC_Shutdown : Called every time the CSQC code is shutdown (changing maps, quitting, etc)
 153 void Shutdown()
 154 {
 155         WarpZone_Shutdown();
 156
 157         delete(teams);
 158         delete(players);
 159         db_close(binddb);
 160         db_close(tempdb);
 161         if(autocvar_cl_db_saveasdump)
 162                 db_dump(ClientProgsDB, "client.db");
 163         else
 164                 db_save(ClientProgsDB, "client.db");
 165         db_close(ClientProgsDB);
 166
 167         if(camera_active)
 168                 cvar_set("chase_active",ftos(chase_active_backup));
 169
 170         // unset the event chasecam's chase_active
 171         if(autocvar_chase_active < 0)
 172                 cvar_set("chase_active", "0");
 173
 174         if (autocvar_r_drawviewmodel < 0)
 175                 cvar_set("r_drawviewmodel", "0");
 176
 177         cvar_set("slowmo", cvar_defstring("slowmo")); // reset it back to 'default'
 178
 179         if (!isdemo())
 180         {
 181                 if (!(calledhooks & HOOK_START))
 182                         localcmd("\n_cl_hook_gamestart nop\n");
 183                 if (!(calledhooks & HOOK_END))
 184                 {
 185                         int gamecount = cvar("cl_matchcount");
 186                         localcmd("\ncl_hook_gameend\n");
 187                         // NOTE: using localcmd here to ensure it's executed AFTER cl_hook_gameend
 188                         // earlier versions of the game abuse the hook to set this cvar
 189                         localcmd(strcat("cl_matchcount ", itos(gamecount + 1), "\n"));
 190                         //cvar_set("cl_matchcount", itos(gamecount + 1));
 191                 }
 192         }
 193
 194         localcmd("\ncl_hook_shutdown\n");
 195
 196         localcmd("\n-button12\n");
 197
 198         deactivate_minigame();
 199         HUD_MinigameMenu_Close(NULL, NULL, NULL);
 200
 201         ReplicateVars(REPLICATEVARS_DESTROY);
 202 }
 203
 204 void AuditLists()
 205 {
 206         entity e;
 207         entity prev;
 208
 209         prev = players;
 210         for(e = prev.sort_next; e; prev = e, e = e.sort_next)
 211         {
 212                 if(prev != e.sort_prev)
 213                         error(strcat("sort list chain error\nplease submit the output of 'prvm_edicts client' to the developers"));
 214         }
 215
 216         prev = teams;
 217         for(e = prev.sort_next; e; prev = e, e = e.sort_next)
 218         {
 219                 if(prev != e.sort_prev)
 220                         error(strcat("sort list chain error\nplease submit the output of 'prvm_edicts client' to the developers"));
 221         }
 222 }
 223
 224 float RegisterPlayer(entity player)
 225 {
 226         entity pl;
 227         AuditLists();
 228         for(pl = players.sort_next; pl; pl = pl.sort_next)
 229                 if(pl == player)
 230                         error("Player already registered!");
 231         player.sort_next = players.sort_next;
 232         player.sort_prev = players;
 233         if(players.sort_next)
 234                 players.sort_next.sort_prev = player;
 235         players.sort_next = player;
 236         AuditLists();
 237         return true;
 238 }
 239
 240 void RemovePlayer(entity player)
 241 {
 242         entity pl, parent;
 243         AuditLists();
 244         parent = players;
 245         for(pl = players.sort_next; pl && pl != player; pl = pl.sort_next)
 246                 parent = pl;
 247
 248         if(!pl)
 249         {
 250                 error("Trying to remove a player which is not in the playerlist!");
 251                 return;
 252         }
 253         parent.sort_next = player.sort_next;
 254         if(player.sort_next)
 255                 player.sort_next.sort_prev = parent;
 256         AuditLists();
 257 }
 258
 259 void MoveToLast(entity e)
 260 {
 261         AuditLists();
 262         entity ent = e.sort_next;
 263         while(ent)
 264         {
 265                 SORT_SWAP(ent, e);
 266                 ent = e.sort_next;
 267         }
 268         AuditLists();
 269 }
 270
 271 float RegisterTeam(entity Team)
 272 {
 273         assert_once(Team.team, eprint(Team));
 274         entity tm;
 275         AuditLists();
 276         for(tm = teams.sort_next; tm; tm = tm.sort_next)
 277                 if(tm == Team)
 278                         error("Team already registered!");
 279         Team.sort_next = teams.sort_next;
 280         Team.sort_prev = teams;
 281         if(teams.sort_next)
 282                 teams.sort_next.sort_prev = Team;
 283         teams.sort_next = Team;
 284         if(Team.team && Team.team != NUM_SPECTATOR)
 285                 ++team_count;
 286         AuditLists();
 287         return true;
 288 }
 289
 290 void RemoveTeam(entity Team)
 291 {
 292         entity tm, parent;
 293         AuditLists();
 294         parent = teams;
 295         for(tm = teams.sort_next; tm && tm != Team; tm = tm.sort_next)
 296                 parent = tm;
 297
 298         if(!tm)
 299         {
 300                 LOG_INFO(_("Trying to remove a team which is not in the teamlist!"));
 301                 return;
 302         }
 303         parent.sort_next = Team.sort_next;
 304         if(Team.sort_next)
 305                 Team.sort_next.sort_prev = parent;
 306         if(Team.team && Team.team != NUM_SPECTATOR)
 307                 --team_count;
 308         AuditLists();
 309 }
 310
 311 entity GetTeam(int Team, bool add)
 312 {
 313         TC(int, Team); TC(bool, add);
 314         int num = (Team == NUM_SPECTATOR) ? 16 : Team;
 315         if(teamslots[num])
 316                 return teamslots[num];
 317         if (!add)
 318                 return NULL;
 319         entity tm = new_pure(team);
 320         tm.team = Team;
 321         teamslots[num] = tm;
 322         RegisterTeam(tm);
 323         return tm;
 324 }
 325
 326 .float has_team;
 327 bool SetTeam(entity o, int Team)
 328 {
 329         TC(int, Team);
 330         //devassert_once(Team);
 331         entity tm;
 332         if(teamplay)
 333         {
 334                 switch(Team)
 335                 {
 336                         case -1:
 337                         case NUM_TEAM_1:
 338                         case NUM_TEAM_2:
 339                         case NUM_TEAM_3:
 340                         case NUM_TEAM_4:
 341                                 break;
 342                         default:
 343                                 if(GetTeam(Team, false) == NULL)
 344                                 {
 345                                         LOG_TRACEF("trying to switch to unsupported team %d", Team);
 346                                         Team = NUM_SPECTATOR;
 347                                 }
 348                                 break;
 349                 }
 350         }
 351         else
 352         {
 353                 switch(Team)
 354                 {
 355                         case -1:
 356                         case 0:
 357                                 break;
 358                         default:
 359                                 if(GetTeam(Team, false) == NULL)
 360                                 {
 361                                         LOG_TRACEF("trying to switch to unsupported team %d", Team);
 362                                         Team = NUM_SPECTATOR;
 363                                 }
 364                                 break;
 365                 }
 366         }
 367         if(Team == -1) // leave
 368         {
 369                 if(o.has_team)
 370                 {
 371                         tm = GetTeam(o.team, false);
 372                         tm.team_size -= 1;
 373                         o.has_team = 0;
 374                         return true;
 375                 }
 376         }
 377         else
 378         {
 379                 if (!o.has_team)
 380                 {
 381                         o.team = Team;
 382                         tm = GetTeam(Team, true);
 383                         tm.team_size += 1;
 384                         o.has_team = 1;
 385                         return true;
 386                 }
 387                 else if(Team != o.team)
 388                 {
 389                         tm = GetTeam(o.team, false);
 390                         tm.team_size -= 1;
 391                         o.team = Team;
 392                         tm = GetTeam(Team, true);
 393                         tm.team_size += 1;
 394                         return true;
 395                 }
 396         }
 397         return false;
 398 }
 399
 400 void Playerchecker_Think(entity this)
 401 {
 402         int i;
 403         entity e;
 404         for(i = 0; i < maxclients; ++i)
 405         {
 406                 e = playerslots[i];
 407                 if(entcs_GetName(i) == "")
 408                 {
 409                         if(e.sort_prev)
 410                         {
 411                                 // player disconnected
 412                                 SetTeam(e, -1);
 413                                 RemovePlayer(e);
 414                                 e.sort_prev = NULL;
 415                                 //e.gotscores = 0;
 416                         }
 417                 }
 418                 else
 419                 {
 420                         if (!e.sort_prev)
 421                         {
 422                                 // player connected
 423                                 if (!e)
 424                                 {
 425                                         playerslots[i] = e = new_pure(playerslot);
 426                                 }
 427                                 e.sv_entnum = i;
 428                                 e.ping = 0;
 429                                 e.ping_packetloss = 0;
 430                                 e.ping_movementloss = 0;
 431                                 //e.gotscores = 0; // we might already have the scores...
 432                                 int t = entcs_GetScoreTeam(i);
 433                                 if (t) SetTeam(e, t); // will not hurt; later updates come with Scoreboard_UpdatePlayerTeams
 434                                 RegisterPlayer(e);
 435                                 Scoreboard_UpdatePlayerPos(e);
 436                         }
 437                 }
 438         }
 439         this.nextthink = time + 0.2;
 440 }
 441
 442 void PostInit()
 443 {
 444         entity playerchecker = new_pure(playerchecker);
 445         setthink(playerchecker, Playerchecker_Think);
 446         playerchecker.nextthink = time + 0.2;
 447
 448         TrueAim_Init();
 449
 450         // this can't be called in CSQC_Init as it'd send cvars too early
 451         ReplicateVars_Start();
 452
 453         postinit = true;
 454 }
 455
 456 void Release_Common_Keys()
 457 {
 458         localcmd("-fire\n");
 459         localcmd("-fire2\n");
 460         localcmd("-use\n");
 461         localcmd("-hook\n");
 462         localcmd("-jump\n");
 463         localcmd("-forward\n");
 464         localcmd("-back\n");
 465         localcmd("-moveleft\n");
 466         localcmd("-moveright\n");
 467 }
 468
 469 // CSQC_InputEvent : Used to perform actions based on any key pressed, key released and mouse on the client.
 470 // Return value should be 1 if CSQC handled the input, otherwise return 0 to have the input passed to the engine.
 471 // All keys are in ascii.
 472 // bInputType = 0 is key pressed, 1 is key released, 2 and 3 are mouse input.
 473 // In the case of keyboard input, nPrimary is the ascii code, and nSecondary is 0.
 474 // In the case of mouse input, nPrimary is xdelta, nSecondary is ydelta.
 475 // In the case of mouse input after a setcursormode(1) call, nPrimary is xpos, nSecondary is ypos.
 476 float CSQC_InputEvent(int bInputType, float nPrimary, float nSecondary)
 477 {
 478         TC(int, bInputType);
 479         bool override = false;
 480
 481         override |= HUD_Scoreboard_InputEvent(bInputType, nPrimary, nSecondary);
 482         if (override)
 483                 return true;
 484
 485         override |= HUD_Panel_InputEvent(bInputType, nPrimary, nSecondary);
 486         if (override)
 487                 return true;
 488
 489         override |= HUD_Panel_Chat_InputEvent(bInputType, nPrimary, nSecondary);
 490
 491         override |= QuickMenu_InputEvent(bInputType, nPrimary, nSecondary);
 492
 493         override |= HUD_Radar_InputEvent(bInputType, nPrimary, nSecondary);
 494
 495         override |= MapVote_InputEvent(bInputType, nPrimary, nSecondary);
 496
 497         override |= HUD_Minigame_InputEvent(bInputType, nPrimary, nSecondary);
 498
 499         if(override)
 500                 return true;
 501
 502         if(bInputType == 3 || bInputType == 2)
 503                 return false;
 504
 505         // at this point bInputType can only be 0 or 1 (key pressed or released)
 506         bool key_pressed = (bInputType == 0);
 507
 508         if(key_pressed) {
 509                 if(nPrimary == K_ALT) hudShiftState |= S_ALT;
 510                 if(nPrimary == K_CTRL) hudShiftState |= S_CTRL;
 511                 if(nPrimary == K_SHIFT) hudShiftState |= S_SHIFT;
 512                 if(nPrimary == K_TAB) hudShiftState |= S_TAB;
 513         }
 514         else {
 515                 if(nPrimary == K_ALT) hudShiftState -= (hudShiftState & S_ALT);
 516                 if(nPrimary == K_CTRL) hudShiftState -= (hudShiftState & S_CTRL);
 517                 if(nPrimary == K_SHIFT) hudShiftState -= (hudShiftState & S_SHIFT);
 518                 if(nPrimary == K_TAB) hudShiftState -= (hudShiftState & S_TAB);
 519         }
 520
 521         // NOTE: Shift-Escape must be filtered out because it's the hardcoded console shortcut
 522         if (nPrimary == K_ESCAPE && !(hudShiftState & S_SHIFT) && key_pressed)
 523         {
 524                 if (hudShiftState & S_TAB)
 525                 {
 526                         Scoreboard_UI_Enable(0);
 527                         return true;
 528                 }
 529                 if (autocvar_menu_gamemenu && !isdemo() && cvar("_menu_gamemenu_dialog_available"))
 530                 {
 531                         localcmd("\nmenu_showgamemenudialog\n");
 532                         return true;
 533                 }
 534         }
 535
 536         return false;
 537 }
 538
 539 // END REQUIRED CSQC FUNCTIONS
 540 // --------------------------------------------------------------------------
 541
 542 // --------------------------------------------------------------------------
 543 // BEGIN OPTIONAL CSQC FUNCTIONS
 544
 545 void Ent_RemovePlayerScore(entity this)
 546 {
 547         if(this.owner) {
 548                 SetTeam(this.owner, -1);
 549                 this.owner.gotscores = 0;
 550                 FOREACH(Scores, true, {
 551                         this.owner.(scores(it)) = 0; // clear all scores
 552                 });
 553         }
 554 }
 555
 556 NET_HANDLE(ENT_CLIENT_SCORES, bool isnew)
 557 {
 558         make_pure(this);
 559         entity o;
 560
 561         // damnit -.- don't want to go change every single .sv_entnum in hud.qc AGAIN
 562         // (no I've never heard of M-x replace-string, sed, or anything like that)
 563         bool isNew = !this.owner; // workaround for DP bug
 564         int n = ReadByte()-1;
 565
 566 #ifdef DP_CSQC_ENTITY_REMOVE_IS_B0RKED
 567         if(!isNew && n != this.sv_entnum)
 568         {
 569                 //print("A CSQC entity changed its owner!\n");
 570                 LOG_INFOF("A CSQC entity changed its owner! (edict: %d, classname: %s)", etof(this), this.classname);
 571                 isNew = true;
 572                 Ent_Remove(this);
 573         }
 574 #endif
 575
 576         this.sv_entnum = n;
 577
 578         o = playerslots[this.sv_entnum];
 579         if (!o)
 580         {
 581                 o = playerslots[this.sv_entnum] = new_pure(playerslot);
 582         }
 583         this.owner = o;
 584         o.sv_entnum = this.sv_entnum;
 585         o.gotscores = 1;
 586
 587         //if (!o.sort_prev)
 588         //      RegisterPlayer(o);
 589         //playerchecker will do this for us later, if it has not already done so
 590
 591         int sf = ReadShort();
 592         int lf = ReadShort();
 593         FOREACH(Scores, true, {
 594                 int p = 1 << (i % 16);
 595                 if (sf & p)
 596                 {
 597                         if (lf & p)
 598                                 o.(scores(it)) = ReadInt24_t();
 599                         else
 600                                 o.(scores(it)) = ReadChar();
 601                 }
 602         });
 603
 604         return = true;
 605
 606         if(o.sort_prev)
 607                 Scoreboard_UpdatePlayerPos(o); // if not registered, we cannot do this yet!
 608
 609         this.entremove = Ent_RemovePlayerScore;
 610 }
 611
 612 NET_HANDLE(ENT_CLIENT_TEAMSCORES, bool isnew)
 613 {
 614         make_pure(this);
 615         int i;
 616
 617         this.team = ReadByte();
 618         entity o = this.owner = GetTeam(this.team, true); // these team numbers can always be trusted
 619
 620 #if MAX_TEAMSCORE <= 8
 621         int sf = ReadByte();
 622         int lf = ReadByte();
 623 #else
 624         int sf = ReadShort();
 625         int lf = ReadShort();
 626 #endif
 627         for(i = 0; i < MAX_TEAMSCORE; ++i)
 628                 if(sf & BIT(i))
 629                 {
 630                         if(lf & BIT(i))
 631                                 o.(teamscores(i)) = ReadInt24_t();
 632                         else
 633                                 o.(teamscores(i)) = ReadChar();
 634                 }
 635
 636         return = true;
 637
 638         Scoreboard_UpdateTeamPos(o);
 639 }
 640
 641 NET_HANDLE(ENT_CLIENT_CLIENTDATA, bool isnew)
 642 {
 643         make_pure(this);
 644         float newspectatee_status;
 645
 646         int f = ReadByte();
 647
 648         scoreboard_showscores_force = (f & BIT(0));
 649
 650         if(f & BIT(1))
 651         {
 652                 newspectatee_status = ReadByte();
 653                 if(newspectatee_status == player_localnum + 1)
 654                         newspectatee_status = -1; // observing
 655         }
 656         else
 657                 newspectatee_status = 0;
 658
 659         spectatorbutton_zoom = (f & BIT(2));
 660         observe_blocked = (f & BIT(3));
 661
 662         if(f & BIT(4))
 663         {
 664                 num_spectators = ReadByte();
 665
 666                 float i, slot;
 667
 668                 for(i = 0; i < MAX_SPECTATORS; ++i)
 669                         spectatorlist[i] = 0; // reset list first
 670
 671                 int limit = min(num_spectators, MAX_SPECTATORS);
 672                 for(i = 0; i < limit; ++i)
 673                 {
 674                         slot = ReadByte();
 675                         spectatorlist[i] = slot - 1;
 676                 }
 677         }
 678         else
 679         {
 680                 for(int j = 0; j < MAX_SPECTATORS; ++j)
 681                         spectatorlist[j] = 0; // reset list if showspectators has been turned off
 682                 num_spectators = 0;
 683         }
 684
 685         return = true;
 686
 687         if(newspectatee_status != spectatee_status)
 688         {
 689                 // clear race stuff
 690                 race_laptime = 0;
 691                 race_checkpointtime = 0;
 692                 hud_dynamic_shake_factor = -1;
 693                 spectatee_status_changed_time = time;
 694         }
 695         if (autocvar_hud_panel_healtharmor_progressbar_gfx)
 696         {
 697                 if ( (spectatee_status == -1 && newspectatee_status > 0) //before observing, now spectating
 698                   || (spectatee_status > 0 && newspectatee_status > 0 && spectatee_status != newspectatee_status) //changed spectated player
 699                 )
 700                         prev_p_health = -1;
 701                 else if(spectatee_status && !newspectatee_status) //before observing/spectating, now playing
 702                         prev_health = -1;
 703         }
 704         spectatee_status = newspectatee_status;
 705
 706         // we could get rid of spectatee_status, and derive it from player_localentnum and player_localnum
 707 }
 708
 709 NET_HANDLE(ENT_CLIENT_NAGGER, bool isnew)
 710 {
 711         make_pure(this);
 712
 713         int nags = ReadByte(); // NAGS NAGS NAGS NAGS NAGS NAGS NADZ NAGS NAGS NAGS
 714
 715         if(!(nags & BIT(2)))
 716         {
 717                 strfree(vote_called_vote);
 718                 vote_active = 0;
 719         }
 720         else
 721         {
 722                 vote_active = 1;
 723         }
 724
 725         if(nags & BIT(6))
 726         {
 727                 vote_yescount = ReadByte();
 728                 vote_nocount = ReadByte();
 729                 vote_needed = ReadByte();
 730                 vote_highlighted = ReadChar();
 731         }
 732
 733         if(nags & BIT(7))
 734         {
 735                 strcpy(vote_called_vote, ReadString());
 736         }
 737
 738         if(nags & BIT(0))
 739                 for(int i = 0; i < maxclients;)
 740                         for(int f = ReadByte(), b = 0; b < 8 && i < maxclients; ++b, ++i)
 741                                 if(playerslots[i])
 742                                         playerslots[i].ready = f & BIT(b);
 743
 744         return = true;
 745
 746         ready_waiting = (nags & BIT(0));
 747         ready_waiting_for_me = (nags & BIT(1));
 748         vote_waiting = (nags & BIT(2));
 749         vote_waiting_for_me = (nags & BIT(3));
 750         warmup_stage = (nags & BIT(4));
 751 }
 752
 753 NET_HANDLE(ENT_CLIENT_ELIMINATEDPLAYERS, bool isnew)
 754 {
 755         make_pure(this);
 756         int sf = 0;
 757         serialize(byte, 0, sf);
 758         if (sf & 1) {
 759                 for (int j = 0; j < maxclients; ++j) {
 760                         if (playerslots[j]) {
 761                                 playerslots[j].eliminated = true;
 762                         }
 763                 }
 764                 for (int i = 1; i <= maxclients; i += 8) {
 765                         int f = 0;
 766                         serialize(byte, 0, f);
 767                         for (int b = 0; b < 8; ++b) {
 768                                 if (f & BIT(b)) continue;
 769                                 int j = i - 1 + b;
 770                                 if (playerslots[j]) {
 771                                         playerslots[j].eliminated = false;
 772                                 }
 773                         }
 774                 }
 775         }
 776         return true;
 777 }
 778
 779 NET_HANDLE(ENT_CLIENT_RANDOMSEED, bool isnew)
 780 {
 781         make_pure(this);
 782         prandom_debug();
 783         float s = ReadShort();
 784         psrandom(s);
 785         return true;
 786 }
 787
 788 NET_HANDLE(ENT_CLIENT_ACCURACY, bool isnew)
 789 {
 790         make_pure(this);
 791         int sf = ReadInt24_t();
 792         if (sf == 0) {
 793                 for (int w = 0; w <= WEP_LAST - WEP_FIRST; ++w)
 794                         weapon_accuracy[w] = -1;
 795                 return true;
 796         }
 797
 798         int f = 1;
 799         for (int w = 0; w <= WEP_LAST - WEP_FIRST; ++w) {
 800                 if (sf & f) {
 801                         int b = ReadByte();
 802                         if (b == 0)
 803                                 weapon_accuracy[w] = -1;
 804                         else if (b == 255)
 805                                 weapon_accuracy[w] = 1.0; // no better error handling yet, sorry
 806                         else
 807                                 weapon_accuracy[w] = (b - 1.0) / 100.0;
 808                 }
 809                 f = (f == 0x800000) ? 1 : f * 2;
 810         }
 811         return true;
 812 }
 813
 814 void Spawn_Draw(entity this)
 815 {
 816         bool dodraw = autocvar_cl_spawn_point_particles;
 817         if(dodraw && autocvar_cl_spawn_point_dist_max)
 818         {
 819                 vector org = getpropertyvec(VF_ORIGIN);
 820                 dodraw = vdist(org - this.origin, <, autocvar_cl_spawn_point_dist_max);
 821         }
 822
 823         if(dodraw)
 824                 pointparticles(((!teamplay) ? EFFECT_SPAWNPOINT_NEUTRAL : EFFECT_SPAWNPOINT(this.team - 1)), this.origin + '0 0 28', '0 0 2', bound(0, frametime, 0.1));
 825 }
 826
 827 NET_HANDLE(ENT_CLIENT_SPAWNPOINT, bool is_new)
 828 {
 829         float teamnum = (ReadByte() - 1);
 830         vector spn_origin = ReadVector();
 831
 832         this.team = (teamnum + 1);
 833
 834         //if(is_new)
 835         //{
 836                 this.origin = spn_origin;
 837                 setsize(this, PL_MIN_CONST, PL_MAX_CONST);
 838                 //droptofloor();
 839
 840                 /*if(autocvar_cl_spawn_point_model) // needs a model first
 841                 {
 842                         this.mdl = "models/spawnpoint.md3";
 843                         this.colormod = Team_ColorRGB(teamnum);
 844                         precache_model(this.mdl);
 845                         setmodel(this, this.mdl);
 846                         this.drawmask = MASK_NORMAL;
 847                         //this.move_movetype = MOVETYPE_NOCLIP;
 848                         //this.draw = Spawn_Draw;
 849                         IL_PUSH(g_drawables, this);
 850                 }*/
 851                 this.draw = Spawn_Draw;
 852                 if (is_new) IL_PUSH(g_drawables, this);
 853         //}
 854
 855         //printf("Ent_ReadSpawnPoint(is_new = %d); origin = %s, team = %d, effect = %d\n", is_new, vtos(this.origin), teamnum, this.cnt);
 856         return true;
 857 }
 858
 859 NET_HANDLE(ENT_CLIENT_SPAWNEVENT, bool is_new)
 860 {
 861         // If entnum is 0, ONLY do the local spawn actions
 862         // this way the server can disable the sending of
 863         // spawn origin or such to clients if wanted.
 864         float entnum = ReadByte();
 865
 866         if(entnum)
 867         {
 868                 this.origin = ReadVector();
 869
 870                 if(is_new)
 871                 {
 872                         float teamnum = entcs_GetTeam(entnum - 1);
 873
 874                         if(autocvar_cl_spawn_event_particles)
 875                         {
 876                                 switch(teamnum)
 877                                 {
 878                                         case NUM_TEAM_1: pointparticles(EFFECT_SPAWN_RED, this.origin, '0 0 0', 1); break;
 879                                         case NUM_TEAM_2: pointparticles(EFFECT_SPAWN_BLUE, this.origin, '0 0 0', 1); break;
 880                                         case NUM_TEAM_3: pointparticles(EFFECT_SPAWN_YELLOW, this.origin, '0 0 0', 1); break;
 881                                         case NUM_TEAM_4: pointparticles(EFFECT_SPAWN_PINK, this.origin, '0 0 0', 1); break;
 882                                         default: pointparticles(EFFECT_SPAWN_NEUTRAL, this.origin, '0 0 0', 1); break;
 883                                 }
 884                         }
 885                         if(autocvar_cl_spawn_event_sound)
 886                         {
 887                                 sound(this, CH_TRIGGER, SND_SPAWN, VOL_BASE, ATTEN_NORM);
 888                         }
 889                 }
 890         }
 891         return = true;
 892
 893         // local spawn actions
 894         if(is_new && (!entnum || (entnum == player_localentnum)))
 895         {
 896                 if(autocvar_cl_spawnzoom && !autocvar_cl_lockview)
 897                 {
 898                         zoomin_effect = 1;
 899                         current_viewzoom = (1 / bound(1, autocvar_cl_spawnzoom_factor, 16));
 900                 }
 901
 902                 if(autocvar_cl_unpress_zoom_on_spawn)
 903                 {
 904                         localcmd("-zoom\n");
 905                         button_zoom = false;
 906                 }
 907                 HUD_Radar_Hide_Maximized();
 908         }
 909         //printf("Ent_ReadSpawnEvent(is_new = %d); origin = %s, entnum = %d, localentnum = %d\n", is_new, vtos(this.origin), entnum, player_localentnum);
 910 }
 911
 912 // CSQC_Ent_Update : Called every frame that the server has indicated an update to the SSQC / CSQC entity has occured.
 913 // The parameter isnew reflects if the entity is "new" to the client, meaning it just came into the client's PVS.
 914 void CSQC_Ent_Update(entity this, bool isnew)
 915 {
 916         this.sourceLoc = __FILE__":"STR(__LINE__);
 917         int t = ReadByte();
 918
 919         // set up the "time" global for received entities to be correct for interpolation purposes
 920         float savetime = time;
 921         if(servertime)
 922         {
 923                 time = servertime;
 924         }
 925         else
 926         {
 927                 serverprevtime = time;
 928                 serverdeltatime = STAT(MOVEVARS_TICRATE) * STAT(MOVEVARS_TIMESCALE);
 929                 time = serverprevtime + serverdeltatime;
 930         }
 931
 932 #ifdef DP_CSQC_ENTITY_REMOVE_IS_B0RKED
 933         if (this.enttype)
 934         {
 935                 if (t != this.enttype || isnew)
 936                 {
 937                         LOG_INFOF("A CSQC entity changed its type! (edict: %d, server: %d, type: %d -> %d)", etof(this), this.entnum, this.enttype, t);
 938                         Ent_Remove(this);
 939                         ONREMOVE(this);
 940                         clearentity(this);
 941                         isnew = true;
 942                 }
 943         }
 944         else
 945         {
 946                 if (!isnew)
 947                 {
 948                         LOG_INFOF("A CSQC entity appeared out of nowhere! (edict: %d, server: %d, type: %d)", etof(this), this.entnum, t);
 949                         isnew = true;
 950                 }
 951         }
 952 #endif
 953         this.enttype = t;
 954         bool done = false;
 955         FOREACH(LinkedEntities, it.m_id == t, {
 956                 if (isnew) this.classname = it.netname;
 957                 if (autocvar_developer_csqcentities)
 958                         LOG_INFOF("CSQC_Ent_Update(%i, %d) at %f {.entnum=%d, .enttype=%d} t=%s (%d)", this, isnew, savetime, this.entnum, this.enttype, this.classname, t);
 959                 done = it.m_read(this, NULL, isnew);
 960                 MUTATOR_CALLHOOK(Ent_Update, this, isnew);
 961                 break;
 962         });
 963         time = savetime;
 964         if (!done)
 965         {
 966                 LOG_FATALF("CSQC_Ent_Update(%i, %d) at %f {.entnum=%d, .enttype=%d} t=%s (%d)", this, isnew, savetime, this.entnum, this.enttype, this.classname, t);
 967         }
 968 }
 969
 970 // Destructor, but does NOT deallocate the entity by calling remove(). Also
 971 // used when an entity changes its type. For an entity that someone interacts
 972 // with others, make sure it can no longer do so.
 973 void Ent_Remove(entity this)
 974 {
 975         if(this.entremove) this.entremove(this);
 976
 977         if(this.skeletonindex)
 978         {
 979                 skel_delete(this.skeletonindex);
 980                 this.skeletonindex = 0;
 981         }
 982
 983         if(this.snd_looping > 0)
 984         {
 985                 sound(this, this.snd_looping, SND_Null, VOL_BASE, autocvar_cl_jetpack_attenuation);
 986                 this.snd_looping = 0;
 987         }
 988
 989         this.enttype = 0;
 990         this.classname = "";
 991         this.draw = func_null;
 992         this.entremove = func_null;
 993         // TODO possibly set more stuff to defaults
 994 }
 995 // CSQC_Ent_Remove : Called when the server requests a SSQC / CSQC entity to be removed.  Essentially call remove(this) as well.
 996 void CSQC_Ent_Remove(entity this)
 997 {
 998         if (autocvar_developer_csqcentities) LOG_INFOF("CSQC_Ent_Remove() with this=%i {.entnum=%d, .enttype=%d}", this, this.entnum, this.enttype);
 999         if (wasfreed(this))
1000         {
1001                 LOG_WARN("CSQC_Ent_Remove called for already removed entity. Packet loss?");
1002                 return;
1003         }
1004         if (this.enttype) Ent_Remove(this);
1005         delete(this);
1006 }
1007
1008 void Gamemode_Init()
1009 {
1010         if (!isdemo())
1011         {
1012                 if(!(calledhooks & HOOK_START))
1013                         localcmd("\n_cl_hook_gamestart ", MapInfo_Type_ToString(gametype), "\n");
1014                 calledhooks |= HOOK_START;
1015         }
1016 }
1017 // CSQC_Parse_StuffCmd : Provides the stuffcmd string in the first parameter that the server provided.  To execute standard behavior, simply execute localcmd with the string.
1018 void CSQC_Parse_StuffCmd(string strMessage)
1019 {
1020         if (autocvar_developer_csqcentities) LOG_INFOF("CSQC_Parse_StuffCmd(\"%s\")", strMessage);
1021         localcmd(strMessage);
1022 }
1023 // CSQC_Parse_Print : Provides the print string in the first parameter that the server provided.  To execute standard behavior, simply execute print with the string.
1024 void CSQC_Parse_Print(string strMessage)
1025 {
1026         if (autocvar_developer_csqcentities) LOG_INFOF("CSQC_Parse_Print(\"%s\")", strMessage);
1027         print(ColorTranslateRGB(strMessage));
1028 }
1029
1030 // CSQC_Parse_CenterPrint : Provides the centerprint_AddStandard string in the first parameter that the server provided.
1031 void CSQC_Parse_CenterPrint(string strMessage)
1032 {
1033         if (autocvar_developer_csqcentities) LOG_INFOF("CSQC_Parse_CenterPrint(\"%s\")", strMessage);
1034         centerprint_AddStandard(strMessage);
1035 }
1036
1037 // CSQC_Parse_TempEntity : Handles all temporary entity network data in the CSQC layer.
1038 // You must ALWAYS first acquire the temporary ID, which is sent as a byte.
1039 // Return value should be 1 if CSQC handled the temporary entity, otherwise return 0 to have the engine process the event.
1040 bool CSQC_Parse_TempEntity()
1041 {
1042         // Acquire TE ID
1043         int nTEID = ReadByte();
1044
1045         FOREACH(TempEntities, it.m_id == nTEID, {
1046                 if (autocvar_developer_csqcentities)
1047                         LOG_INFOF("CSQC_Parse_TempEntity() nTEID=%s (%d)", it.netname, nTEID);
1048                 return it.m_read(NULL, NULL, true);
1049         });
1050
1051         if (autocvar_developer_csqcentities)
1052                 LOG_INFOF("CSQC_Parse_TempEntity() with nTEID=%d", nTEID);
1053
1054         // No special logic for this temporary entity; return 0 so the engine can handle it
1055         return false;
1056 }
1057
1058 string forcefog;
1059 void Fog_Force()
1060 {
1061         if (autocvar_cl_orthoview && autocvar_cl_orthoview_nofog)
1062                 localcmd("\nr_drawfog 0\n");
1063         else if (forcefog != "")
1064                 localcmd(sprintf("\nfog %s\nr_fog_exp2 0\nr_drawfog 1\n", forcefog));
1065 }
1066
1067 bool net_handle_ServerWelcome();
1068 NET_HANDLE(ENT_CLIENT_SCORES_INFO, bool isnew)
1069 {
1070         make_pure(this);
1071         gametype = ReadRegistered(Gametypes);
1072         teamplay = _MapInfo_GetTeamPlayBool(gametype);
1073         HUD_ModIcons_SetFunc();
1074         FOREACH(Scores, true, {
1075                 strcpy(scores_label(it), ReadString());
1076                 scores_flags(it) = ReadByte();
1077         });
1078         for (int i = 0; i < MAX_TEAMSCORE; ++i)
1079         {
1080                 strcpy(teamscores_label(i), ReadString());
1081                 teamscores_flags(i) = ReadByte();
1082         }
1083         bool welcome_msg_too = ReadByte();
1084         if (welcome_msg_too)
1085                 net_handle_ServerWelcome();
1086         return = true;
1087         Scoreboard_InitScores();
1088         Gamemode_Init();
1089 }
1090
1091 NET_HANDLE(ENT_CLIENT_INIT, bool isnew)
1092 {
1093         nb_pb_period = ReadByte() / 32; //Accuracy of 1/32th
1094
1095         hook_shotorigin[0] = decompressShotOrigin(ReadInt24_t());
1096         hook_shotorigin[1] = decompressShotOrigin(ReadInt24_t());
1097         hook_shotorigin[2] = decompressShotOrigin(ReadInt24_t());
1098         hook_shotorigin[3] = decompressShotOrigin(ReadInt24_t());
1099         arc_shotorigin[0] = decompressShotOrigin(ReadInt24_t());
1100         arc_shotorigin[1] = decompressShotOrigin(ReadInt24_t());
1101         arc_shotorigin[2] = decompressShotOrigin(ReadInt24_t());
1102         arc_shotorigin[3] = decompressShotOrigin(ReadInt24_t());
1103
1104         strcpy(forcefog, ReadString());
1105
1106         armorblockpercent = ReadByte() / 255.0;
1107         damagepush_speedfactor = ReadByte() / 255.0;
1108
1109         serverflags = ReadByte();
1110
1111         g_trueaim_minrange = ReadCoord();
1112
1113         return = true;
1114
1115         MUTATOR_CALLHOOK(Ent_Init);
1116
1117         if (!postinit) PostInit();
1118 }
1119
1120 float GetSpeedUnitFactor(int speed_unit)
1121 {
1122         switch(speed_unit)
1123         {
1124                 default:
1125                 case 1: return 1.0;
1126                 case 2: return 0.0254;
1127                 case 3: return 0.0254 * 3.6;
1128                 case 4: return 0.0254 * 3.6 * 0.6213711922;
1129                 case 5: return 0.0254 * 1.943844492; // 1 m/s = 1.943844492 knots, because 1 knot = 1.852 km/h
1130         }
1131 }
1132
1133 string GetSpeedUnit(int speed_unit)
1134 {
1135         switch(speed_unit)
1136         {
1137                 // translator-friendly strings without the initial space
1138                 default:
1139                 case 1: return strcat(" ", _("qu/s"));
1140                 case 2: return strcat(" ", _("m/s"));
1141                 case 3: return strcat(" ", _("km/h"));
1142                 case 4: return strcat(" ", _("mph"));
1143                 case 5: return strcat(" ", _("knots"));
1144         }
1145 }
1146
1147 NET_HANDLE(TE_CSQC_RACE, bool isNew)
1148 {
1149         int b = ReadByte();
1150
1151         switch (b)
1152         {
1153                 case RACE_NET_CHECKPOINT_HIT_QUALIFYING:
1154                         race_checkpoint = ReadByte();
1155                         race_time = ReadInt24_t();
1156                         race_previousbesttime = ReadInt24_t();
1157                         race_mypreviousbesttime = ReadInt24_t();
1158                         string pbestname = ReadString();
1159                         if(autocvar_cl_race_cptimes_onlyself)
1160                         {
1161                                 race_previousbesttime = race_mypreviousbesttime;
1162                                 race_mypreviousbesttime = 0;
1163                                 strcpy(race_previousbestname, "");
1164                         }
1165                         else
1166                                 strcpy(race_previousbestname, pbestname);
1167
1168                         race_checkpointtime = time;
1169
1170                         if(race_checkpoint == 0 || race_checkpoint == 254)
1171                         {
1172                                 race_penaltyaccumulator = 0;
1173                                 race_laptime = time; // valid
1174                         }
1175                         break;
1176
1177                 case RACE_NET_CHECKPOINT_CLEAR:
1178                         race_laptime = 0;
1179                         race_checkpointtime = 0;
1180                         break;
1181
1182                 case RACE_NET_CHECKPOINT_NEXT_SPEC_QUALIFYING:
1183                         race_laptime = ReadCoord();
1184                         race_checkpointtime = -99999;
1185                         // fall through
1186                 case RACE_NET_CHECKPOINT_NEXT_QUALIFYING:
1187                         race_nextcheckpoint = ReadByte();
1188
1189                         race_nextbesttime = ReadInt24_t();
1190                         if(b != RACE_NET_CHECKPOINT_NEXT_SPEC_QUALIFYING) // not while spectating (matches server)
1191                                 race_mybesttime = ReadInt24_t();
1192                         string newname = ReadString();
1193                         if(autocvar_cl_race_cptimes_onlyself && b != RACE_NET_CHECKPOINT_NEXT_SPEC_QUALIFYING)
1194                         {
1195                                 race_nextbesttime = race_mybesttime;
1196                                 race_mybesttime = 0;
1197                                 strcpy(race_nextbestname, "");
1198                         }
1199                         else
1200                                 strcpy(race_nextbestname, newname);
1201                         break;
1202
1203                 case RACE_NET_CHECKPOINT_HIT_RACE:
1204                         race_mycheckpoint = ReadByte();
1205                         race_mycheckpointtime = time;
1206                         race_mycheckpointdelta = ReadInt24_t();
1207                         race_mycheckpointlapsdelta = ReadByte();
1208                         if(race_mycheckpointlapsdelta >= 128)
1209                                 race_mycheckpointlapsdelta -= 256;
1210                         int who = ReadByte();
1211                         if(who)
1212                                 strcpy(race_mycheckpointenemy, entcs_GetName(who - 1));
1213                         else
1214                                 strcpy(race_mycheckpointenemy, ""); // TODO: maybe string_null works fine here?
1215                         break;
1216
1217                 case RACE_NET_CHECKPOINT_HIT_RACE_BY_OPPONENT:
1218                         race_othercheckpoint = ReadByte();
1219                         race_othercheckpointtime = time;
1220                         race_othercheckpointdelta = ReadInt24_t();
1221                         race_othercheckpointlapsdelta = ReadByte();
1222                         if(race_othercheckpointlapsdelta >= 128)
1223                                 race_othercheckpointlapsdelta -= 256;
1224                         int what = ReadByte();
1225                         if(what)
1226                                 strcpy(race_othercheckpointenemy, entcs_GetName(what - 1));
1227                         else
1228                                 strcpy(race_othercheckpointenemy, ""); // TODO: maybe string_null works fine here?
1229                         break;
1230
1231                 case RACE_NET_PENALTY_RACE:
1232                 case RACE_NET_PENALTY_QUALIFYING:
1233                         race_penaltyeventtime = time;
1234                         race_penaltytime = ReadShort();
1235                         string reason = ReadString();
1236                         if (reason == "missing a checkpoint")
1237                                 reason = _("missing a checkpoint");
1238                         strcpy(race_penaltyreason, reason);
1239                         if (b == RACE_NET_PENALTY_QUALIFYING)
1240                                 race_penaltyaccumulator += race_penaltytime;
1241                         break;
1242
1243                 case RACE_NET_SERVER_RECORD:
1244                         race_server_record = ReadInt24_t();
1245                         break;
1246                 case RACE_NET_SPEED_AWARD:
1247                         race_speedaward = ReadInt24_t() * GetSpeedUnitFactor(autocvar_hud_panel_physics_speed_unit);
1248                         strcpy(race_speedaward_holder, ReadString());
1249                         break;
1250                 case RACE_NET_SPEED_AWARD_BEST:
1251                         race_speedaward_alltimebest = ReadInt24_t() * GetSpeedUnitFactor(autocvar_hud_panel_physics_speed_unit);
1252                         strcpy(race_speedaward_alltimebest_holder, ReadString());
1253                         break;
1254                 case RACE_NET_RANKINGS_CNT:
1255                         RANKINGS_DISPLAY_CNT = ReadByte();
1256                         break;
1257                 case RACE_NET_SERVER_RANKINGS:
1258                         float prevpos, del;
1259                         int pos = ReadShort();
1260                         prevpos = ReadShort();
1261                         del = ReadShort();
1262
1263                         // move other rankings out of the way
1264                         int i;
1265                         if (prevpos) {
1266                                 int m = min(prevpos, RANKINGS_DISPLAY_CNT);
1267                                 for (i=m-1; i>pos-1; --i) {
1268                                         grecordtime[i] = grecordtime[i-1];
1269                                         strcpy(grecordholder[i], grecordholder[i-1]);
1270                                 }
1271                         } else if (del) { // a record has been deleted by the admin
1272                                 for (i=pos-1; i<= RANKINGS_DISPLAY_CNT-1; ++i) {
1273                                         if (i == RANKINGS_DISPLAY_CNT-1) { // clear out last record
1274                                                 grecordtime[i] = 0;
1275                                                 strfree(grecordholder[i]);
1276                                         }
1277                                         else {
1278                                                 grecordtime[i] = grecordtime[i+1];
1279                                                 strcpy(grecordholder[i], grecordholder[i+1]);
1280                                         }
1281                                 }
1282                         } else { // player has no ranked record yet
1283                                 for (i=RANKINGS_DISPLAY_CNT-1;i>pos-1;--i) {
1284                                         grecordtime[i] = grecordtime[i-1];
1285                                         strcpy(grecordholder[i], grecordholder[i-1]);
1286                                 }
1287                         }
1288
1289                         if (grecordtime[RANKINGS_DISPLAY_CNT]) {
1290                                 // kick off the player who fell from the last displayed position
1291                                 grecordtime[RANKINGS_DISPLAY_CNT] = 0;
1292                                 strfree(grecordholder[RANKINGS_DISPLAY_CNT]);
1293                         }
1294
1295                         // store new ranking
1296                         strcpy(grecordholder[pos-1], ReadString());
1297                         grecordtime[pos-1] = ReadInt24_t();
1298                         if(strdecolorize(grecordholder[pos-1]) == strdecolorize(entcs_GetName(player_localnum)))
1299                                 race_myrank = pos;
1300                         break;
1301                 case RACE_NET_SERVER_STATUS:
1302                         race_status = ReadShort();
1303                         strcpy(race_status_name, ReadString());
1304         }
1305         return true;
1306 }
1307
1308 NET_HANDLE(TE_CSQC_TEAMNAGGER, bool isNew)
1309 {
1310         teamnagger = 1;
1311         return true;
1312 }
1313
1314 NET_HANDLE(TE_CSQC_PINGPLREPORT, bool isNew)
1315 {
1316         int i = ReadByte();
1317         int pi = ReadShort();
1318         int pl = ReadByte();
1319         int ml = ReadByte();
1320         return = true;
1321         entity e = playerslots[i];
1322         if (!e) return;
1323         e.ping = pi;
1324         e.ping_packetloss = pl / 255.0;
1325         e.ping_movementloss = ml / 255.0;
1326 }
1327
1328 NET_HANDLE(TE_CSQC_WEAPONCOMPLAIN, bool isNew)
1329 {
1330         int weapon_id = ReadByte();
1331         complain_weapon = REGISTRY_GET(Weapons, weapon_id);
1332         complain_weapon_type = ReadByte();
1333         return = true;
1334
1335         complain_weapon_time = time;
1336         weapontime = time; // ping the weapon panel
1337
1338         switch(complain_weapon_type)
1339         {
1340                 case 0: Local_Notification(MSG_MULTI, ITEM_WEAPON_NOAMMO, weapon_id); break;
1341                 case 1: Local_Notification(MSG_MULTI, ITEM_WEAPON_DONTHAVE, weapon_id); break;
1342                 default: Local_Notification(MSG_MULTI, ITEM_WEAPON_UNAVAILABLE, weapon_id); break;
1343         }
1344 }
1345
1346 string translate_modifications(string s)
1347 {
1348         return build_mutator_list(s);
1349 }
1350
1351 string translate_weaponarena(string s)
1352 {
1353         if (s == "") return s;
1354         if (s == "All Weapons Arena") return _("All Weapons Arena");
1355         if (s == "All Available Weapons Arena") return _("All Available Weapons Arena");
1356         if (s == "Most Weapons Arena") return _("Most Weapons Arena");
1357         if (s == "Most Available Weapons Arena") return _("Most Available Weapons Arena");
1358         if (s == "Dev All Weapons Arena") return s; // development option, do not translate
1359         if (s == "Dev All Available Weapons Arena") return s; // development option, do not translate
1360         if (s == "No Weapons Arena") return _("No Weapons Arena");
1361
1362         int n = tokenizebyseparator(s, " & ");
1363         string wpn_list = "";
1364         for (int i = 0; i < n; i++)
1365         {
1366                 Weapon wep = Weapon_from_name(argv(i));
1367                 if (wep == WEP_Null)
1368                         LOG_INFO("^3Warning: ^7server sent an invalid weapon name\n");
1369                 wpn_list = cons_mid(wpn_list, " & ", wep.m_name);
1370         }
1371         if (wpn_list != "")
1372                 return sprintf(_("%s Arena"), wpn_list);
1373         else
1374                 return _("No Weapons Arena");
1375 }
1376
1377 string GetVersionMessage(string hostversion, bool version_mismatch, bool version_check)
1378 {
1379         string xonotic_hostversion = strcat("Xonotic ", hostversion);
1380         if (version_mismatch)
1381         {
1382                 if(!version_check)
1383                         return strcat(sprintf(_("This is %s"), xonotic_hostversion), "\n^3",
1384                                 _("Your client version is outdated."), "\n\n\n",
1385                                 _("### YOU WON'T BE ABLE TO PLAY ON THIS SERVER ###"), "\n\n\n",
1386                                 _("Please update!"));
1387                 else
1388                         return strcat(sprintf(_("This is %s"), xonotic_hostversion), "\n^3",
1389                                 _("This server is using an outdated Xonotic version."), "\n\n\n",
1390                                 _("### THIS SERVER IS INCOMPATIBLE AND THUS YOU CANNOT JOIN ###"));
1391         }
1392         return sprintf(_("Welcome to %s"), xonotic_hostversion);
1393 }
1394
1395 bool net_handle_ServerWelcome()
1396 {
1397         campaign = ReadByte();
1398         if (campaign)
1399         {
1400                 string campaign_title = ReadString();
1401                 int campaign_level = ReadByte();
1402                 string campaign_msg = ReadString();
1403                 string welcomedialog_args;
1404                 welcomedialog_args = strcat("HOSTNAME \"", campaign_title, "\"");
1405                 string key = getcommandkey(_("jump"), "+jump");
1406                 string msg = strcat(
1407                         CCR("^F1"), sprintf(_("Level %d:"), campaign_level),
1408                         sprintf(CCR(" ^BG%s\n^3\n"), campaign_msg),
1409                         sprintf(CCR(_("^BGPress ^F2%s^BG to enter the game")), key));
1410                 msg = MakeConsoleSafe(strreplace("\n", "\\n", msg));
1411                 welcomedialog_args = strcat(welcomedialog_args, " WELCOME \"", msg, "\"");
1412                 localcmd("\nmenu_cmd directmenu Welcome ", welcomedialog_args, "\n");
1413                 return true;
1414         }
1415
1416         strcpy(hostname, ReadString());
1417         string hostversion = ReadString();
1418         bool version_mismatch = ReadByte();
1419         bool version_check = ReadByte();
1420         srv_minplayers = ReadByte();
1421         srv_maxplayers = ReadByte();
1422         string modifications = translate_modifications(ReadString());
1423         string weaponarena_list = translate_weaponarena(ReadString());
1424         string cache_mutatormsg = ReadString();
1425         string motd = ReadString();
1426
1427         string msg = GetVersionMessage(hostversion, version_mismatch, version_check);
1428
1429         msg = strcat(msg, "\n\n", _("Gametype:"), " ^1", MapInfo_Type_ToText(gametype), "\n");
1430
1431         msg = strcat(msg, "\n", _("Map:"), " ^2");
1432         if (world.message == "")
1433                 msg = strcat(msg, mi_shortname, "\n");
1434         else
1435         {
1436                 int i = strstrofs(world.message, " by ", 0); // matches _MapInfo_Generate()
1437                 string longname = i >= 0 ? substring(world.message, 0, i) : world.message;
1438                 msg = strcat(msg, (strcasecmp(longname, mi_shortname) ? strcat(mi_shortname, " ^7// ^2") : ""), longname, "\n");
1439         }
1440
1441         if (srv_minplayers || srv_maxplayers)
1442         {
1443                 msg = strcat(msg, "\n", _("This match supports"), " ^5");
1444                 if (srv_minplayers == srv_maxplayers)
1445                         msg = strcat(msg, sprintf(_("%d players"), srv_maxplayers), "\n");
1446                 else if (srv_minplayers && srv_maxplayers)
1447                         msg = strcat(msg, sprintf(_("%d to %d players"), srv_minplayers, srv_maxplayers), "\n");
1448                 else if (srv_maxplayers)
1449                         msg = strcat(msg, sprintf(_("%d players maximum"), srv_maxplayers), "\n");
1450                 else
1451                         msg = strcat(msg, sprintf(_("%d players minimum"), srv_minplayers), "\n");
1452         }
1453
1454         modifications = cons_mid(modifications, ", ", weaponarena_list);
1455         if(modifications != "")
1456                 msg = strcat(msg, "\n", _("Active modifications:"), " ^3", modifications, "\n");
1457
1458         if (cache_mutatormsg != "")
1459                 msg = strcat(msg, "\n", _("Special gameplay tips:"), " ^7", cache_mutatormsg, "\n");
1460         string mutator_msg = "";
1461         MUTATOR_CALLHOOK(BuildGameplayTipsString, mutator_msg);
1462         mutator_msg = M_ARGV(0, string);
1463         msg = strcat(msg, mutator_msg); // trust that the mutator will do proper formatting
1464
1465         if (motd != "")
1466                 msg = strcat(msg, "\n^9↓ ", _("Server's message"), " ↓\n", motd);
1467
1468         strcpy(welcome_msg, msg);
1469         welcome_msg_menu_check_maxtime = time + 1; // wait for menu to load before showing the welcome dialog
1470         return true;
1471 }
1472
1473 void Welcome_Message_Show_Try()
1474 {
1475         if (!welcome_msg_menu_check_maxtime)
1476                 return;
1477
1478         // if want dialog check if menu is initialized but for a short time
1479         if (cvar("_menu_initialized") == 2 || time > welcome_msg_menu_check_maxtime)
1480         {
1481                 if (cvar("_menu_welcome_dialog_available"))
1482                 {
1483                         string welcomedialog_args = strcat("HOSTNAME \"", hostname, "\"");
1484                         string msg = MakeConsoleSafe(strreplace("\n", "\\n", welcome_msg));
1485                         welcomedialog_args = strcat(welcomedialog_args, " WELCOME \"", msg, "\"");
1486
1487                         if (intermission || isdemo() || !autocvar_cl_welcome)
1488                         {
1489                                 if (cvar("_menu_cmd_closemenu_available"))
1490                                 {
1491                                         // initialize the dialog without opening it
1492                                         localcmd("\nmenu_cmd closemenu Welcome ", welcomedialog_args, "\n");
1493                                 }
1494                                 else
1495                                 {
1496                                         // legacy code for clients with old menus
1497                                         // since togglemenu 0 doesn't close the dialog but only hides it,
1498                                         // playing back a demo the Welcome dialog will pop up on the first ESC press
1499                                         localcmd("\nmenu_cmd directmenu Welcome ", welcomedialog_args, "\n");
1500                                         // close it after it's been initialized so it can still be opened manually
1501                                         localcmd("\ntogglemenu 0\n");
1502                                 }
1503                         }
1504                         else
1505                                 localcmd("\nmenu_cmd directmenu Welcome ", welcomedialog_args, "\n");
1506                 }
1507
1508                 strfree(welcome_msg);
1509                 welcome_msg_menu_check_maxtime = 0;
1510         }
1511 }
1512
1513 NET_HANDLE(TE_CSQC_SERVERWELCOME, bool isNew)
1514 {
1515         return net_handle_ServerWelcome();
1516 }
1517
1518 string _getcommandkey(string cmd_name, string command, bool forcename)
1519 {
1520         string keys;
1521         float n, j, k, l = 0;
1522
1523         if (!autocvar_hud_showbinds)
1524                 return cmd_name;
1525
1526         keys = db_get(binddb, command);
1527         if (keys == "")
1528         {
1529                 bool joy_active = cvar("joy_active");
1530                 n = tokenize(findkeysforcommand(command, 0)); // uses '...' strings
1531                 for(j = 0; j < n; ++j)
1532                 {
1533                         k = stof(argv(j));
1534                         if(k != -1)
1535                         {
1536                                 string key = keynumtostring(k);
1537                                 if(!joy_active && substring(key, 0, 3) == "JOY")
1538                                         continue;
1539
1540                                 key = translate_key(key);
1541
1542                                 if (keys == "")
1543                                         keys = key;
1544                                 else
1545                                         keys = strcat(keys, ", ", key);
1546
1547                                 ++l;
1548                                 if (autocvar_hud_showbinds_limit > 0 && autocvar_hud_showbinds_limit <= l)
1549                                         break;
1550                         }
1551
1552                 }
1553                 if (keys == "")
1554                         keys = "NO_KEY";
1555                 db_put(binddb, command, keys);
1556         }
1557
1558         if (keys == "NO_KEY") {
1559                 if (autocvar_hud_showbinds > 1)
1560                         return sprintf(_("%s (not bound)"), cmd_name);
1561                 else
1562                         return cmd_name;
1563         }
1564         else if (autocvar_hud_showbinds > 1 || forcename)
1565                 return sprintf("%s (%s)", cmd_name, keys);
1566         else
1567                 return keys;
1568 }
1569
1570 /** engine callback */
1571 void URI_Get_Callback(int id, int status, string data)
1572 {
1573         TC(int, id); TC(int, status);
1574         if(url_URI_Get_Callback(id, status, data))
1575         {
1576                 // handled
1577         }
1578         else if (id == URI_GET_DISCARD)
1579         {
1580                 // discard
1581         }
1582         else if (id >= URI_GET_CURL && id <= URI_GET_CURL_END)
1583         {
1584                 // sv_cmd curl
1585                 Curl_URI_Get_Callback(id, status, data);
1586         }
1587         else
1588         {
1589                 LOG_INFOF("Received HTTP request data for an invalid id %d.", id);
1590         }
1591 }