qcsrc/client/main.qc

   1 #include "main.qh"
   2
   3 #include <client/command/cl_cmd.qh>
   4 #include <client/draw.qh>
   5 #include <client/hud/_mod.qh>
   6 #include <client/hud/panel/centerprint.qh>
   7 #include <client/hud/panel/chat.qh>
   8 #include <client/hud/panel/quickmenu.qh>
   9 #include <client/hud/panel/scoreboard.qh>
  10 #include <client/items/items.qh>
  11 #include <client/mapvoting.qh>
  12 #include <client/mutators/_mod.qh>
  13 #include <client/shownames.qh>
  14 #include <client/view.qh>
  15 #include <client/weapons/projectile.qh>
  16 #include <common/deathtypes/all.qh>
  17 #include <common/effects/all.inc>
  18 #include <common/effects/all.qh>
  19 #include <common/effects/effect.qh>
  20 #include <common/effects/qc/_mod.qh>
  21 #include <common/ent_cs.qh>
  22 #include <common/gamemodes/gamemode/nexball/cl_nexball.qh>
  23 #include <common/items/_mod.qh>
  24 #include <common/mapinfo.qh>
  25 #include <common/mapobjects/_mod.qh>
  26 #include <common/minigames/cl_minigames.qh>
  27 #include <common/minigames/cl_minigames_hud.qh>
  28 #include <common/net_linked.qh>
  29 #include <common/net_notice.qh>
  30 #include <common/scores.qh>
  31 #include <common/vehicles/all.qh>
  32 #include <lib/csqcmodel/cl_model.qh>
  33 #include <lib/csqcmodel/interpolate.qh>
  34 #include <lib/warpzone/client.qh>
  35
  36 // --------------------------------------------------------------------------
  37 // BEGIN REQUIRED CSQC FUNCTIONS
  38 //include "main.qh"
  39
  40 #define DP_CSQC_ENTITY_REMOVE_IS_B0RKED
  41
  42 // CSQC_Init : Called every time the CSQC code is initialized (essentially at map load)
  43 // Useful for precaching things
  44
  45 void CSQC_Init()
  46 {
  47         prvm_language = strzone(cvar_string("prvm_language"));
  48
  49 #ifdef WATERMARK
  50         LOG_TRACEF("^4CSQC Build information: ^1%s", WATERMARK);
  51 #endif
  52
  53         {
  54                 int i = 0;
  55                 for ( ; i < 255; ++i)
  56                         if (getplayerkeyvalue(i, "viewentity") == "")
  57                                 break;
  58                 maxclients = i;
  59         }
  60
  61         // needs to be done so early because of the constants they create
  62         static_init();
  63         static_init_late();
  64         static_init_precache();
  65
  66         binddb = db_create();
  67         tempdb = db_create();
  68         ClientProgsDB = db_load("client.db");
  69
  70         draw_endBoldFont();
  71
  72         //registercommand("hud_configure");
  73         //registercommand("hud_save");
  74         //registercommand("menu_action");
  75
  76         ConsoleCommand_macro_init();
  77
  78         registercvar("hud_usecsqc", "1");
  79         registercvar("scoreboard_columns", "default");
  80
  81         registercvar("cl_nade_type", "3");
  82         registercvar("cl_pokenade_type", "zombie");
  83
  84         registercvar("cl_jumpspeedcap_min", "");
  85         registercvar("cl_jumpspeedcap_max", "");
  86
  87         registercvar("cl_shootfromfixedorigin", "");
  88
  89         registercvar("cl_multijump", "-1");
  90
  91         registercvar("cl_dodging", "0");
  92
  93         registercvar("cl_spawn_near_teammate", "1");
  94
  95         registercvar("cl_weapon_switch_reload", "1");
  96         registercvar("cl_weapon_switch_fallback_to_impulse", "1");
  97
  98         registercvar("cl_allow_uidranking", "1");
  99
 100         if(autocvar_cl_lockview)
 101                 cvar_set("cl_lockview", "0");
 102
 103         if (cvar_type("_scoreboard_team_selection_available") & CVAR_TYPEFLAG_EXISTS)
 104                 cvar_settemp("_scoreboard_team_selection_available", "1");
 105         cvar_set("_scoreboard_team_selection", "0"); // in case it has been left set to 1
 106
 107         gametype = NULL;
 108
 109         postinit = false;
 110
 111         calledhooks = 0;
 112
 113         teams = Sort_Spawn();
 114         players = Sort_Spawn();
 115
 116         GetTeam(NUM_SPECTATOR, true); // add specs first
 117
 118         for (int w = 0; w <= WEP_LAST - WEP_FIRST; ++w)
 119                 weapon_accuracy[w] = -1;
 120
 121         // precaches
 122
 123         if(autocvar_cl_reticle)
 124         {
 125                 precache_pic("gfx/reticle_normal");
 126                 // weapon reticles are precached in weapon files
 127         }
 128
 129         {
 130                 get_mi_min_max_texcoords(1); // try the CLEVER way first
 131                 minimapname = strcat("gfx/", mi_shortname, "_radar");
 132
 133                 if (precache_pic(minimapname) == "")
 134                 {
 135                         // but maybe we have a non-clever minimap
 136                         minimapname = strcat("gfx/", mi_shortname, "_mini");
 137                         if (precache_pic(minimapname) == "")
 138                                 minimapname = ""; // FAIL
 139                         else
 140                                 get_mi_min_max_texcoords(0); // load new texcoords
 141                 }
 142
 143                 mi_center = (mi_min + mi_max) * 0.5;
 144                 mi_scale = mi_max - mi_min;
 145                 minimapname = strzone(minimapname);
 146         }
 147
 148         hud_skin_path = strzone(strcat("gfx/hud/", autocvar_hud_skin));
 149         LoadMenuSkinValues();
 150 }
 151
 152 // CSQC_Shutdown : Called every time the CSQC code is shutdown (changing maps, quitting, etc)
 153 void Shutdown()
 154 {
 155         WarpZone_Shutdown();
 156
 157         delete(teams);
 158         delete(players);
 159         db_close(binddb);
 160         db_close(tempdb);
 161         if(autocvar_cl_db_saveasdump)
 162                 db_dump(ClientProgsDB, "client.db");
 163         else
 164                 db_save(ClientProgsDB, "client.db");
 165         db_close(ClientProgsDB);
 166
 167         if(camera_active)
 168                 cvar_set("chase_active",ftos(chase_active_backup));
 169
 170         // unset the event chasecam's chase_active
 171         if(autocvar_chase_active < 0)
 172                 cvar_set("chase_active", "0");
 173
 174         if (autocvar_r_drawviewmodel < 0)
 175                 cvar_set("r_drawviewmodel", "0");
 176
 177         cvar_set("slowmo", cvar_defstring("slowmo")); // reset it back to 'default'
 178
 179         if (!isdemo())
 180         {
 181                 if (!(calledhooks & HOOK_START))
 182                         localcmd("\n_cl_hook_gamestart nop\n");
 183                 if (!(calledhooks & HOOK_END))
 184                 {
 185                         int gamecount = cvar("cl_matchcount");
 186                         localcmd("\ncl_hook_gameend\n");
 187                         // NOTE: using localcmd here to ensure it's executed AFTER cl_hook_gameend
 188                         // earlier versions of the game abuse the hook to set this cvar
 189                         localcmd(strcat("cl_matchcount ", itos(gamecount + 1), "\n"));
 190                         //cvar_set("cl_matchcount", itos(gamecount + 1));
 191                 }
 192         }
 193
 194         localcmd("\ncl_hook_shutdown\n");
 195
 196         localcmd("\n-button12\n");
 197
 198         deactivate_minigame();
 199         HUD_MinigameMenu_Close(NULL, NULL, NULL);
 200
 201         ReplicateVars(REPLICATEVARS_DESTROY);
 202 }
 203
 204 void AuditLists()
 205 {
 206         entity e;
 207         entity prev;
 208
 209         prev = players;
 210         for(e = prev.sort_next; e; prev = e, e = e.sort_next)
 211         {
 212                 if(prev != e.sort_prev)
 213                         error(strcat("sort list chain error\nplease submit the output of 'prvm_edicts client' to the developers"));
 214         }
 215
 216         prev = teams;
 217         for(e = prev.sort_next; e; prev = e, e = e.sort_next)
 218         {
 219                 if(prev != e.sort_prev)
 220                         error(strcat("sort list chain error\nplease submit the output of 'prvm_edicts client' to the developers"));
 221         }
 222 }
 223
 224 float RegisterPlayer(entity player)
 225 {
 226         entity pl;
 227         AuditLists();
 228         for(pl = players.sort_next; pl; pl = pl.sort_next)
 229                 if(pl == player)
 230                         error("Player already registered!");
 231         player.sort_next = players.sort_next;
 232         player.sort_prev = players;
 233         if(players.sort_next)
 234                 players.sort_next.sort_prev = player;
 235         players.sort_next = player;
 236         AuditLists();
 237         return true;
 238 }
 239
 240 void RemovePlayer(entity player)
 241 {
 242         entity pl, parent;
 243         AuditLists();
 244         parent = players;
 245         for(pl = players.sort_next; pl && pl != player; pl = pl.sort_next)
 246                 parent = pl;
 247
 248         if(!pl)
 249         {
 250                 error("Trying to remove a player which is not in the playerlist!");
 251                 return;
 252         }
 253         parent.sort_next = player.sort_next;
 254         if(player.sort_next)
 255                 player.sort_next.sort_prev = parent;
 256         AuditLists();
 257 }
 258
 259 void MoveToLast(entity e)
 260 {
 261         AuditLists();
 262         entity ent = e.sort_next;
 263         while(ent)
 264         {
 265                 SORT_SWAP(ent, e);
 266                 ent = e.sort_next;
 267         }
 268         AuditLists();
 269 }
 270
 271 float RegisterTeam(entity Team)
 272 {
 273         assert_once(Team.team, eprint(Team));
 274         entity tm;
 275         AuditLists();
 276         for(tm = teams.sort_next; tm; tm = tm.sort_next)
 277                 if(tm == Team)
 278                         error("Team already registered!");
 279         Team.sort_next = teams.sort_next;
 280         Team.sort_prev = teams;
 281         if(teams.sort_next)
 282                 teams.sort_next.sort_prev = Team;
 283         teams.sort_next = Team;
 284         if(Team.team && Team.team != NUM_SPECTATOR)
 285                 ++team_count;
 286         AuditLists();
 287         return true;
 288 }
 289
 290 void RemoveTeam(entity Team)
 291 {
 292         entity tm, parent;
 293         AuditLists();
 294         parent = teams;
 295         for(tm = teams.sort_next; tm && tm != Team; tm = tm.sort_next)
 296                 parent = tm;
 297
 298         if(!tm)
 299         {
 300                 LOG_INFO(_("Trying to remove a team which is not in the teamlist!"));
 301                 return;
 302         }
 303         parent.sort_next = Team.sort_next;
 304         if(Team.sort_next)
 305                 Team.sort_next.sort_prev = parent;
 306         if(Team.team && Team.team != NUM_SPECTATOR)
 307                 --team_count;
 308         AuditLists();
 309 }
 310
 311 entity GetTeam(int Team, bool add)
 312 {
 313         TC(int, Team); TC(bool, add);
 314         int num = (Team == NUM_SPECTATOR) ? 16 : Team;
 315         if(teamslots[num])
 316                 return teamslots[num];
 317         if (!add)
 318                 return NULL;
 319         entity tm = new_pure(team);
 320         tm.team = Team;
 321         teamslots[num] = tm;
 322         RegisterTeam(tm);
 323         return tm;
 324 }
 325
 326 .float has_team;
 327 bool SetTeam(entity o, int Team)
 328 {
 329         TC(int, Team);
 330         //devassert_once(Team);
 331         entity tm;
 332         if(teamplay)
 333         {
 334                 switch(Team)
 335                 {
 336                         case -1:
 337                         case NUM_TEAM_1:
 338                         case NUM_TEAM_2:
 339                         case NUM_TEAM_3:
 340                         case NUM_TEAM_4:
 341                                 break;
 342                         default:
 343                                 if(GetTeam(Team, false) == NULL)
 344                                 {
 345                                         LOG_TRACEF("trying to switch to unsupported team %d", Team);
 346                                         Team = NUM_SPECTATOR;
 347                                 }
 348                                 break;
 349                 }
 350         }
 351         else
 352         {
 353                 switch(Team)
 354                 {
 355                         case -1:
 356                         case 0:
 357                                 break;
 358                         default:
 359                                 if(GetTeam(Team, false) == NULL)
 360                                 {
 361                                         LOG_TRACEF("trying to switch to unsupported team %d", Team);
 362                                         Team = NUM_SPECTATOR;
 363                                 }
 364                                 break;
 365                 }
 366         }
 367         if(Team == -1) // leave
 368         {
 369                 if(o.has_team)
 370                 {
 371                         tm = GetTeam(o.team, false);
 372                         tm.team_size -= 1;
 373                         o.has_team = 0;
 374                         return true;
 375                 }
 376         }
 377         else
 378         {
 379                 if (!o.has_team)
 380                 {
 381                         o.team = Team;
 382                         tm = GetTeam(Team, true);
 383                         tm.team_size += 1;
 384                         o.has_team = 1;
 385                         return true;
 386                 }
 387                 else if(Team != o.team)
 388                 {
 389                         tm = GetTeam(o.team, false);
 390                         tm.team_size -= 1;
 391                         o.team = Team;
 392                         tm = GetTeam(Team, true);
 393                         tm.team_size += 1;
 394                         return true;
 395                 }
 396         }
 397         return false;
 398 }
 399
 400 void Playerchecker_Think(entity this)
 401 {
 402         int i;
 403         entity e;
 404         for(i = 0; i < maxclients; ++i)
 405         {
 406                 e = playerslots[i];
 407                 if(entcs_GetName(i) == "")
 408                 {
 409                         if(e.sort_prev)
 410                         {
 411                                 // player disconnected
 412                                 SetTeam(e, -1);
 413                                 RemovePlayer(e);
 414                                 e.sort_prev = NULL;
 415                                 //e.gotscores = 0;
 416                         }
 417                 }
 418                 else
 419                 {
 420                         if (!e.sort_prev)
 421                         {
 422                                 // player connected
 423                                 if (!e)
 424                                 {
 425                                         playerslots[i] = e = new_pure(playerslot);
 426                                 }
 427                                 e.sv_entnum = i;
 428                                 e.ping = 0;
 429                                 e.ping_packetloss = 0;
 430                                 e.ping_movementloss = 0;
 431                                 //e.gotscores = 0; // we might already have the scores...
 432                                 int t = entcs_GetScoreTeam(i);
 433                                 if (t) SetTeam(e, t); // will not hurt; later updates come with Scoreboard_UpdatePlayerTeams
 434                                 RegisterPlayer(e);
 435                                 Scoreboard_UpdatePlayerPos(e);
 436                         }
 437                 }
 438         }
 439         this.nextthink = time + 0.2;
 440 }
 441
 442 void PostInit()
 443 {
 444         entity playerchecker = new_pure(playerchecker);
 445         setthink(playerchecker, Playerchecker_Think);
 446         playerchecker.nextthink = time + 0.2;
 447
 448         TrueAim_Init();
 449
 450         // this can't be called in CSQC_Init as it'd send cvars too early
 451         ReplicateVars_Start();
 452
 453         postinit = true;
 454 }
 455
 456 void Release_Common_Keys()
 457 {
 458         localcmd("-fire\n");
 459         localcmd("-fire2\n");
 460         localcmd("-use\n");
 461         localcmd("-hook\n");
 462         localcmd("-jump\n");
 463         localcmd("-forward\n");
 464         localcmd("-back\n");
 465         localcmd("-moveleft\n");
 466         localcmd("-moveright\n");
 467 }
 468
 469 // CSQC_InputEvent : Used to perform actions based on any key pressed, key released and mouse on the client.
 470 // Return value should be 1 if CSQC handled the input, otherwise return 0 to have the input passed to the engine.
 471 // All keys are in ascii.
 472 // bInputType = 0 is key pressed, 1 is key released, 2 and 3 are mouse input.
 473 // In the case of keyboard input, nPrimary is the ascii code, and nSecondary is 0.
 474 // In the case of mouse input, nPrimary is xdelta, nSecondary is ydelta.
 475 // In the case of mouse input after a setcursormode(1) call, nPrimary is xpos, nSecondary is ypos.
 476 float CSQC_InputEvent(int bInputType, float nPrimary, float nSecondary)
 477 {
 478         TC(int, bInputType);
 479         bool override = false;
 480
 481         override |= HUD_Scoreboard_InputEvent(bInputType, nPrimary, nSecondary);
 482         if (override)
 483                 return true;
 484
 485         override |= HUD_Panel_InputEvent(bInputType, nPrimary, nSecondary);
 486         if (override)
 487                 return true;
 488
 489         override |= HUD_Panel_Chat_InputEvent(bInputType, nPrimary, nSecondary);
 490
 491         override |= QuickMenu_InputEvent(bInputType, nPrimary, nSecondary);
 492
 493         override |= HUD_Radar_InputEvent(bInputType, nPrimary, nSecondary);
 494
 495         override |= MapVote_InputEvent(bInputType, nPrimary, nSecondary);
 496
 497         override |= HUD_Minigame_InputEvent(bInputType, nPrimary, nSecondary);
 498
 499         if(override)
 500                 return true;
 501
 502         if(bInputType == 3 || bInputType == 2)
 503                 return false;
 504
 505         // at this point bInputType can only be 0 or 1 (key pressed or released)
 506         bool key_pressed = (bInputType == 0);
 507
 508         if(key_pressed) {
 509                 if(nPrimary == K_ALT) hudShiftState |= S_ALT;
 510                 if(nPrimary == K_CTRL) hudShiftState |= S_CTRL;
 511                 if(nPrimary == K_SHIFT) hudShiftState |= S_SHIFT;
 512                 if(nPrimary == K_TAB) hudShiftState |= S_TAB;
 513         }
 514         else {
 515                 if(nPrimary == K_ALT) hudShiftState -= (hudShiftState & S_ALT);
 516                 if(nPrimary == K_CTRL) hudShiftState -= (hudShiftState & S_CTRL);
 517                 if(nPrimary == K_SHIFT) hudShiftState -= (hudShiftState & S_SHIFT);
 518                 if(nPrimary == K_TAB) hudShiftState -= (hudShiftState & S_TAB);
 519         }
 520
 521         // NOTE: Shift-Escape must be filtered out because it's the hardcoded console shortcut
 522         if (nPrimary == K_ESCAPE && !(hudShiftState & S_SHIFT) && key_pressed)
 523         {
 524                 if (hudShiftState & S_TAB)
 525                 {
 526                         Scoreboard_UI_Enable(0);
 527                         return true;
 528                 }
 529                 if (!isdemo() && cvar("_menu_gamemenu_dialog_available"))
 530                 {
 531                         localcmd("\nmenu_showgamemenudialog\n");
 532                         return true;
 533                 }
 534         }
 535
 536         return false;
 537 }
 538
 539 // END REQUIRED CSQC FUNCTIONS
 540 // --------------------------------------------------------------------------
 541
 542 // --------------------------------------------------------------------------
 543 // BEGIN OPTIONAL CSQC FUNCTIONS
 544
 545 void Ent_RemovePlayerScore(entity this)
 546 {
 547         if(this.owner) {
 548                 SetTeam(this.owner, -1);
 549                 this.owner.gotscores = 0;
 550                 FOREACH(Scores, true, {
 551                         this.owner.(scores(it)) = 0; // clear all scores
 552                 });
 553         }
 554 }
 555
 556 NET_HANDLE(ENT_CLIENT_SCORES, bool isnew)
 557 {
 558         make_pure(this);
 559         entity o;
 560
 561         // damnit -.- don't want to go change every single .sv_entnum in hud.qc AGAIN
 562         // (no I've never heard of M-x replace-string, sed, or anything like that)
 563         bool isNew = !this.owner; // workaround for DP bug
 564         int n = ReadByte()-1;
 565
 566 #ifdef DP_CSQC_ENTITY_REMOVE_IS_B0RKED
 567         if(!isNew && n != this.sv_entnum)
 568         {
 569                 //print("A CSQC entity changed its owner!\n");
 570                 LOG_INFOF("A CSQC entity changed its owner! (edict: %d, classname: %s)", etof(this), this.classname);
 571                 isNew = true;
 572                 Ent_Remove(this);
 573         }
 574 #endif
 575
 576         this.sv_entnum = n;
 577
 578         o = playerslots[this.sv_entnum];
 579         if (!o)
 580         {
 581                 o = playerslots[this.sv_entnum] = new_pure(playerslot);
 582         }
 583         this.owner = o;
 584         o.sv_entnum = this.sv_entnum;
 585         o.gotscores = 1;
 586
 587         //if (!o.sort_prev)
 588         //      RegisterPlayer(o);
 589         //playerchecker will do this for us later, if it has not already done so
 590
 591         int sf = ReadShort();
 592         int lf = ReadShort();
 593         FOREACH(Scores, true, {
 594                 int p = 1 << (i % 16);
 595                 if (sf & p)
 596                 {
 597                         if (lf & p)
 598                                 o.(scores(it)) = ReadInt24_t();
 599                         else
 600                                 o.(scores(it)) = ReadChar();
 601                 }
 602         });
 603
 604         return = true;
 605
 606         if(o.sort_prev)
 607                 Scoreboard_UpdatePlayerPos(o); // if not registered, we cannot do this yet!
 608
 609         this.entremove = Ent_RemovePlayerScore;
 610 }
 611
 612 NET_HANDLE(ENT_CLIENT_TEAMSCORES, bool isnew)
 613 {
 614         make_pure(this);
 615         int i;
 616
 617         this.team = ReadByte();
 618         entity o = this.owner = GetTeam(this.team, true); // these team numbers can always be trusted
 619
 620 #if MAX_TEAMSCORE <= 8
 621         int sf = ReadByte();
 622         int lf = ReadByte();
 623 #else
 624         int sf = ReadShort();
 625         int lf = ReadShort();
 626 #endif
 627         for(i = 0; i < MAX_TEAMSCORE; ++i)
 628                 if(sf & BIT(i))
 629                 {
 630                         if(lf & BIT(i))
 631                                 o.(teamscores(i)) = ReadInt24_t();
 632                         else
 633                                 o.(teamscores(i)) = ReadChar();
 634                 }
 635
 636         return = true;
 637
 638         Scoreboard_UpdateTeamPos(o);
 639 }
 640
 641 NET_HANDLE(ENT_CLIENT_CLIENTDATA, bool isnew)
 642 {
 643         make_pure(this);
 644         float newspectatee_status;
 645
 646         int f = ReadByte();
 647
 648         scoreboard_showscores_force = (f & BIT(0));
 649
 650         if(f & BIT(1))
 651         {
 652                 newspectatee_status = ReadByte();
 653                 if(newspectatee_status == player_localnum + 1)
 654                         newspectatee_status = -1; // observing
 655         }
 656         else
 657                 newspectatee_status = 0;
 658
 659         spectatorbutton_zoom = (f & BIT(2));
 660
 661         if(f & BIT(4))
 662         {
 663                 num_spectators = ReadByte();
 664
 665                 float i, slot;
 666
 667                 for(i = 0; i < MAX_SPECTATORS; ++i)
 668                         spectatorlist[i] = 0; // reset list first
 669
 670                 int limit = min(num_spectators, MAX_SPECTATORS);
 671                 for(i = 0; i < limit; ++i)
 672                 {
 673                         slot = ReadByte();
 674                         spectatorlist[i] = slot - 1;
 675                 }
 676         }
 677         else
 678         {
 679                 for(int j = 0; j < MAX_SPECTATORS; ++j)
 680                         spectatorlist[j] = 0; // reset list if showspectators has been turned off
 681                 num_spectators = 0;
 682         }
 683
 684         return = true;
 685
 686         if(newspectatee_status != spectatee_status)
 687         {
 688                 // clear race stuff
 689                 race_laptime = 0;
 690                 race_checkpointtime = 0;
 691                 hud_dynamic_shake_factor = -1;
 692                 spectatee_status_changed_time = time;
 693         }
 694         if (autocvar_hud_panel_healtharmor_progressbar_gfx)
 695         {
 696                 if ( (spectatee_status == -1 && newspectatee_status > 0) //before observing, now spectating
 697                   || (spectatee_status > 0 && newspectatee_status > 0 && spectatee_status != newspectatee_status) //changed spectated player
 698                 )
 699                         prev_p_health = -1;
 700                 else if(spectatee_status && !newspectatee_status) //before observing/spectating, now playing
 701                         prev_health = -1;
 702         }
 703         spectatee_status = newspectatee_status;
 704
 705         // we could get rid of spectatee_status, and derive it from player_localentnum and player_localnum
 706 }
 707
 708 NET_HANDLE(ENT_CLIENT_NAGGER, bool isnew)
 709 {
 710         make_pure(this);
 711         int i, j, b, f;
 712
 713         int nags = ReadByte(); // NAGS NAGS NAGS NAGS NAGS NAGS NADZ NAGS NAGS NAGS
 714
 715         if(!(nags & BIT(2)))
 716         {
 717                 strfree(vote_called_vote);
 718                 vote_active = 0;
 719         }
 720         else
 721         {
 722                 vote_active = 1;
 723         }
 724
 725         if(nags & BIT(6))
 726         {
 727                 vote_yescount = ReadByte();
 728                 vote_nocount = ReadByte();
 729                 vote_needed = ReadByte();
 730                 vote_highlighted = ReadChar();
 731         }
 732
 733         if(nags & BIT(7))
 734         {
 735                 strcpy(vote_called_vote, ReadString());
 736         }
 737
 738         if(nags & 1)
 739         {
 740                 for(j = 0; j < maxclients; ++j)
 741                         if(playerslots[j])
 742                                 playerslots[j].ready = true;
 743                 for(i = 1; i <= maxclients; i += 8)
 744                 {
 745                         f = ReadByte();
 746                         for(j = i-1, b = BIT(0); b < BIT(8); b <<= 1, ++j)
 747                                 if (!(f & b))
 748                                         if(playerslots[j])
 749                                                 playerslots[j].ready = false;
 750                 }
 751         }
 752
 753         return = true;
 754
 755         ready_waiting = (nags & BIT(0));
 756         ready_waiting_for_me = (nags & BIT(1));
 757         vote_waiting = (nags & BIT(2));
 758         vote_waiting_for_me = (nags & BIT(3));
 759         warmup_stage = (nags & BIT(4));
 760 }
 761
 762 NET_HANDLE(ENT_CLIENT_ELIMINATEDPLAYERS, bool isnew)
 763 {
 764         make_pure(this);
 765         int sf = 0;
 766         serialize(byte, 0, sf);
 767         if (sf & 1) {
 768                 for (int j = 0; j < maxclients; ++j) {
 769                         if (playerslots[j]) {
 770                                 playerslots[j].eliminated = true;
 771                         }
 772                 }
 773                 for (int i = 1; i <= maxclients; i += 8) {
 774                         int f = 0;
 775                         serialize(byte, 0, f);
 776                         for (int b = 0; b < 8; ++b) {
 777                                 if (f & BIT(b)) continue;
 778                                 int j = i - 1 + b;
 779                                 if (playerslots[j]) {
 780                                         playerslots[j].eliminated = false;
 781                                 }
 782                         }
 783                 }
 784         }
 785         return true;
 786 }
 787
 788 NET_HANDLE(ENT_CLIENT_RANDOMSEED, bool isnew)
 789 {
 790         make_pure(this);
 791         prandom_debug();
 792         float s = ReadShort();
 793         psrandom(s);
 794         return true;
 795 }
 796
 797 NET_HANDLE(ENT_CLIENT_ACCURACY, bool isnew)
 798 {
 799         make_pure(this);
 800         int sf = ReadInt24_t();
 801         if (sf == 0) {
 802                 for (int w = 0; w <= WEP_LAST - WEP_FIRST; ++w)
 803                         weapon_accuracy[w] = -1;
 804                 return true;
 805         }
 806
 807         int f = 1;
 808         for (int w = 0; w <= WEP_LAST - WEP_FIRST; ++w) {
 809                 if (sf & f) {
 810                         int b = ReadByte();
 811                         if (b == 0)
 812                                 weapon_accuracy[w] = -1;
 813                         else if (b == 255)
 814                                 weapon_accuracy[w] = 1.0; // no better error handling yet, sorry
 815                         else
 816                                 weapon_accuracy[w] = (b - 1.0) / 100.0;
 817                 }
 818                 f = (f == 0x800000) ? 1 : f * 2;
 819         }
 820         return true;
 821 }
 822
 823 void Spawn_Draw(entity this)
 824 {
 825         bool dodraw = autocvar_cl_spawn_point_particles;
 826         if(dodraw && autocvar_cl_spawn_point_dist_max)
 827         {
 828                 vector org = getpropertyvec(VF_ORIGIN);
 829                 dodraw = vdist(org - this.origin, <, autocvar_cl_spawn_point_dist_max);
 830         }
 831
 832         if(dodraw)
 833                 pointparticles(((!teamplay) ? EFFECT_SPAWNPOINT_NEUTRAL : EFFECT_SPAWNPOINT(this.team - 1)), this.origin + '0 0 28', '0 0 2', bound(0, frametime, 0.1));
 834 }
 835
 836 NET_HANDLE(ENT_CLIENT_SPAWNPOINT, bool is_new)
 837 {
 838         float teamnum = (ReadByte() - 1);
 839         vector spn_origin = ReadVector();
 840
 841         this.team = (teamnum + 1);
 842
 843         //if(is_new)
 844         //{
 845                 this.origin = spn_origin;
 846                 setsize(this, PL_MIN_CONST, PL_MAX_CONST);
 847                 //droptofloor();
 848
 849                 /*if(autocvar_cl_spawn_point_model) // needs a model first
 850                 {
 851                         this.mdl = "models/spawnpoint.md3";
 852                         this.colormod = Team_ColorRGB(teamnum);
 853                         precache_model(this.mdl);
 854                         setmodel(this, this.mdl);
 855                         this.drawmask = MASK_NORMAL;
 856                         //this.move_movetype = MOVETYPE_NOCLIP;
 857                         //this.draw = Spawn_Draw;
 858                         IL_PUSH(g_drawables, this);
 859                 }*/
 860                 this.draw = Spawn_Draw;
 861                 if (is_new) IL_PUSH(g_drawables, this);
 862         //}
 863
 864         //printf("Ent_ReadSpawnPoint(is_new = %d); origin = %s, team = %d, effect = %d\n", is_new, vtos(this.origin), teamnum, this.cnt);
 865         return true;
 866 }
 867
 868 NET_HANDLE(ENT_CLIENT_SPAWNEVENT, bool is_new)
 869 {
 870         // If entnum is 0, ONLY do the local spawn actions
 871         // this way the server can disable the sending of
 872         // spawn origin or such to clients if wanted.
 873         float entnum = ReadByte();
 874
 875         if(entnum)
 876         {
 877                 this.origin = ReadVector();
 878
 879                 if(is_new)
 880                 {
 881                         float teamnum = entcs_GetTeam(entnum - 1);
 882
 883                         if(autocvar_cl_spawn_event_particles)
 884                         {
 885                                 switch(teamnum)
 886                                 {
 887                                         case NUM_TEAM_1: pointparticles(EFFECT_SPAWN_RED, this.origin, '0 0 0', 1); break;
 888                                         case NUM_TEAM_2: pointparticles(EFFECT_SPAWN_BLUE, this.origin, '0 0 0', 1); break;
 889                                         case NUM_TEAM_3: pointparticles(EFFECT_SPAWN_YELLOW, this.origin, '0 0 0', 1); break;
 890                                         case NUM_TEAM_4: pointparticles(EFFECT_SPAWN_PINK, this.origin, '0 0 0', 1); break;
 891                                         default: pointparticles(EFFECT_SPAWN_NEUTRAL, this.origin, '0 0 0', 1); break;
 892                                 }
 893                         }
 894                         if(autocvar_cl_spawn_event_sound)
 895                         {
 896                                 sound(this, CH_TRIGGER, SND_SPAWN, VOL_BASE, ATTEN_NORM);
 897                         }
 898                 }
 899         }
 900         return = true;
 901
 902         // local spawn actions
 903         if(is_new && (!entnum || (entnum == player_localentnum)))
 904         {
 905                 if(autocvar_cl_spawnzoom && !autocvar_cl_lockview)
 906                 {
 907                         zoomin_effect = 1;
 908                         current_viewzoom = (1 / bound(1, autocvar_cl_spawnzoom_factor, 16));
 909                 }
 910
 911                 if(autocvar_cl_unpress_zoom_on_spawn)
 912                 {
 913                         localcmd("-zoom\n");
 914                         button_zoom = false;
 915                 }
 916                 HUD_Radar_Hide_Maximized();
 917         }
 918         //printf("Ent_ReadSpawnEvent(is_new = %d); origin = %s, entnum = %d, localentnum = %d\n", is_new, vtos(this.origin), entnum, player_localentnum);
 919 }
 920
 921 // CSQC_Ent_Update : Called every frame that the server has indicated an update to the SSQC / CSQC entity has occured.
 922 // The parameter isnew reflects if the entity is "new" to the client, meaning it just came into the client's PVS.
 923 void CSQC_Ent_Update(entity this, bool isnew)
 924 {
 925         this.sourceLoc = __FILE__":"STR(__LINE__);
 926         int t = ReadByte();
 927
 928         // set up the "time" global for received entities to be correct for interpolation purposes
 929         float savetime = time;
 930         if(servertime)
 931         {
 932                 time = servertime;
 933         }
 934         else
 935         {
 936                 serverprevtime = time;
 937                 serverdeltatime = STAT(MOVEVARS_TICRATE) * STAT(MOVEVARS_TIMESCALE);
 938                 time = serverprevtime + serverdeltatime;
 939         }
 940
 941 #ifdef DP_CSQC_ENTITY_REMOVE_IS_B0RKED
 942         if (this.enttype)
 943         {
 944                 if (t != this.enttype || isnew)
 945                 {
 946                         LOG_INFOF("A CSQC entity changed its type! (edict: %d, server: %d, type: %d -> %d)", etof(this), this.entnum, this.enttype, t);
 947                         Ent_Remove(this);
 948                         ONREMOVE(this);
 949                         clearentity(this);
 950                         isnew = true;
 951                 }
 952         }
 953         else
 954         {
 955                 if (!isnew)
 956                 {
 957                         LOG_INFOF("A CSQC entity appeared out of nowhere! (edict: %d, server: %d, type: %d)", etof(this), this.entnum, t);
 958                         isnew = true;
 959                 }
 960         }
 961 #endif
 962         this.enttype = t;
 963         bool done = false;
 964         FOREACH(LinkedEntities, it.m_id == t, {
 965                 if (isnew) this.classname = it.netname;
 966                 if (autocvar_developer_csqcentities)
 967                         LOG_INFOF("CSQC_Ent_Update(%i, %d) at %f {.entnum=%d, .enttype=%d} t=%s (%d)", this, isnew, savetime, this.entnum, this.enttype, this.classname, t);
 968                 done = it.m_read(this, NULL, isnew);
 969                 MUTATOR_CALLHOOK(Ent_Update, this, isnew);
 970                 break;
 971         });
 972         time = savetime;
 973         if (!done)
 974         {
 975                 LOG_FATALF("CSQC_Ent_Update(%i, %d) at %f {.entnum=%d, .enttype=%d} t=%s (%d)", this, isnew, savetime, this.entnum, this.enttype, this.classname, t);
 976         }
 977 }
 978
 979 // Destructor, but does NOT deallocate the entity by calling remove(). Also
 980 // used when an entity changes its type. For an entity that someone interacts
 981 // with others, make sure it can no longer do so.
 982 void Ent_Remove(entity this)
 983 {
 984         if(this.entremove) this.entremove(this);
 985
 986         if(this.skeletonindex)
 987         {
 988                 skel_delete(this.skeletonindex);
 989                 this.skeletonindex = 0;
 990         }
 991
 992         if(this.snd_looping > 0)
 993         {
 994                 sound(this, this.snd_looping, SND_Null, VOL_BASE, autocvar_cl_jetpack_attenuation);
 995                 this.snd_looping = 0;
 996         }
 997
 998         this.enttype = 0;
 999         this.classname = "";
1000         this.draw = func_null;
1001         this.entremove = func_null;
1002         // TODO possibly set more stuff to defaults
1003 }
1004 // CSQC_Ent_Remove : Called when the server requests a SSQC / CSQC entity to be removed.  Essentially call remove(this) as well.
1005 void CSQC_Ent_Remove(entity this)
1006 {
1007         if (autocvar_developer_csqcentities) LOG_INFOF("CSQC_Ent_Remove() with this=%i {.entnum=%d, .enttype=%d}", this, this.entnum, this.enttype);
1008         if (wasfreed(this))
1009         {
1010                 LOG_WARN("CSQC_Ent_Remove called for already removed entity. Packet loss?");
1011                 return;
1012         }
1013         if (this.enttype) Ent_Remove(this);
1014         delete(this);
1015 }
1016
1017 void Gamemode_Init()
1018 {
1019         if (!isdemo())
1020         {
1021                 if(!(calledhooks & HOOK_START))
1022                         localcmd("\n_cl_hook_gamestart ", MapInfo_Type_ToString(gametype), "\n");
1023                 calledhooks |= HOOK_START;
1024         }
1025 }
1026 // CSQC_Parse_StuffCmd : Provides the stuffcmd string in the first parameter that the server provided.  To execute standard behavior, simply execute localcmd with the string.
1027 void CSQC_Parse_StuffCmd(string strMessage)
1028 {
1029         if (autocvar_developer_csqcentities) LOG_INFOF("CSQC_Parse_StuffCmd(\"%s\")", strMessage);
1030         localcmd(strMessage);
1031 }
1032 // CSQC_Parse_Print : Provides the print string in the first parameter that the server provided.  To execute standard behavior, simply execute print with the string.
1033 void CSQC_Parse_Print(string strMessage)
1034 {
1035         if (autocvar_developer_csqcentities) LOG_INFOF("CSQC_Parse_Print(\"%s\")", strMessage);
1036         print(ColorTranslateRGB(strMessage));
1037 }
1038
1039 // CSQC_Parse_CenterPrint : Provides the centerprint_AddStandard string in the first parameter that the server provided.
1040 void CSQC_Parse_CenterPrint(string strMessage)
1041 {
1042         if (autocvar_developer_csqcentities) LOG_INFOF("CSQC_Parse_CenterPrint(\"%s\")", strMessage);
1043         centerprint_AddStandard(strMessage);
1044 }
1045
1046 // CSQC_Parse_TempEntity : Handles all temporary entity network data in the CSQC layer.
1047 // You must ALWAYS first acquire the temporary ID, which is sent as a byte.
1048 // Return value should be 1 if CSQC handled the temporary entity, otherwise return 0 to have the engine process the event.
1049 bool CSQC_Parse_TempEntity()
1050 {
1051         // Acquire TE ID
1052         int nTEID = ReadByte();
1053
1054         FOREACH(TempEntities, it.m_id == nTEID, {
1055                 if (autocvar_developer_csqcentities)
1056                         LOG_INFOF("CSQC_Parse_TempEntity() nTEID=%s (%d)", it.netname, nTEID);
1057                 return it.m_read(NULL, NULL, true);
1058         });
1059
1060         if (autocvar_developer_csqcentities)
1061                 LOG_INFOF("CSQC_Parse_TempEntity() with nTEID=%d", nTEID);
1062
1063         // No special logic for this temporary entity; return 0 so the engine can handle it
1064         return false;
1065 }
1066
1067 string forcefog;
1068 void Fog_Force()
1069 {
1070         if (autocvar_cl_orthoview && autocvar_cl_orthoview_nofog)
1071                 localcmd("\nr_drawfog 0\n");
1072         else if (forcefog != "")
1073                 localcmd(sprintf("\nfog %s\nr_fog_exp2 0\nr_drawfog 1\n", forcefog));
1074 }
1075
1076 bool net_handle_ServerWelcome();
1077 NET_HANDLE(ENT_CLIENT_SCORES_INFO, bool isnew)
1078 {
1079         make_pure(this);
1080         gametype = ReadRegistered(Gametypes);
1081         teamplay = _MapInfo_GetTeamPlayBool(gametype);
1082         HUD_ModIcons_SetFunc();
1083         FOREACH(Scores, true, {
1084                 strcpy(scores_label(it), ReadString());
1085                 scores_flags(it) = ReadByte();
1086         });
1087         for (int i = 0; i < MAX_TEAMSCORE; ++i)
1088         {
1089                 strcpy(teamscores_label(i), ReadString());
1090                 teamscores_flags(i) = ReadByte();
1091         }
1092         bool welcome_msg_too = ReadByte();
1093         if (welcome_msg_too)
1094                 net_handle_ServerWelcome();
1095         return = true;
1096         Scoreboard_InitScores();
1097         Gamemode_Init();
1098 }
1099
1100 NET_HANDLE(ENT_CLIENT_INIT, bool isnew)
1101 {
1102         nb_pb_period = ReadByte() / 32; //Accuracy of 1/32th
1103
1104         hook_shotorigin[0] = decompressShotOrigin(ReadInt24_t());
1105         hook_shotorigin[1] = decompressShotOrigin(ReadInt24_t());
1106         hook_shotorigin[2] = decompressShotOrigin(ReadInt24_t());
1107         hook_shotorigin[3] = decompressShotOrigin(ReadInt24_t());
1108         arc_shotorigin[0] = decompressShotOrigin(ReadInt24_t());
1109         arc_shotorigin[1] = decompressShotOrigin(ReadInt24_t());
1110         arc_shotorigin[2] = decompressShotOrigin(ReadInt24_t());
1111         arc_shotorigin[3] = decompressShotOrigin(ReadInt24_t());
1112
1113         strcpy(forcefog, ReadString());
1114
1115         armorblockpercent = ReadByte() / 255.0;
1116         damagepush_speedfactor = ReadByte() / 255.0;
1117
1118         serverflags = ReadByte();
1119
1120         g_trueaim_minrange = ReadCoord();
1121
1122         return = true;
1123
1124         MUTATOR_CALLHOOK(Ent_Init);
1125
1126         if (!postinit) PostInit();
1127 }
1128
1129 float GetSpeedUnitFactor(int speed_unit)
1130 {
1131         switch(speed_unit)
1132         {
1133                 default:
1134                 case 1: return 1.0;
1135                 case 2: return 0.0254;
1136                 case 3: return 0.0254 * 3.6;
1137                 case 4: return 0.0254 * 3.6 * 0.6213711922;
1138                 case 5: return 0.0254 * 1.943844492; // 1 m/s = 1.943844492 knots, because 1 knot = 1.852 km/h
1139         }
1140 }
1141
1142 string GetSpeedUnit(int speed_unit)
1143 {
1144         switch(speed_unit)
1145         {
1146                 // translator-friendly strings without the initial space
1147                 default:
1148                 case 1: return strcat(" ", _("qu/s"));
1149                 case 2: return strcat(" ", _("m/s"));
1150                 case 3: return strcat(" ", _("km/h"));
1151                 case 4: return strcat(" ", _("mph"));
1152                 case 5: return strcat(" ", _("knots"));
1153         }
1154 }
1155
1156 NET_HANDLE(TE_CSQC_RACE, bool isNew)
1157 {
1158         int b = ReadByte();
1159
1160         switch (b)
1161         {
1162                 case RACE_NET_CHECKPOINT_HIT_QUALIFYING:
1163                         race_checkpoint = ReadByte();
1164                         race_time = ReadInt24_t();
1165                         race_previousbesttime = ReadInt24_t();
1166                         race_mypreviousbesttime = ReadInt24_t();
1167                         string pbestname = ReadString();
1168                         if(autocvar_cl_race_cptimes_onlyself)
1169                         {
1170                                 race_previousbesttime = race_mypreviousbesttime;
1171                                 race_mypreviousbesttime = 0;
1172                                 strcpy(race_previousbestname, "");
1173                         }
1174                         else
1175                                 strcpy(race_previousbestname, pbestname);
1176
1177                         race_checkpointtime = time;
1178
1179                         if(race_checkpoint == 0 || race_checkpoint == 254)
1180                         {
1181                                 race_penaltyaccumulator = 0;
1182                                 race_laptime = time; // valid
1183                         }
1184                         break;
1185
1186                 case RACE_NET_CHECKPOINT_CLEAR:
1187                         race_laptime = 0;
1188                         race_checkpointtime = 0;
1189                         break;
1190
1191                 case RACE_NET_CHECKPOINT_NEXT_SPEC_QUALIFYING:
1192                         race_laptime = ReadCoord();
1193                         race_checkpointtime = -99999;
1194                         // fall through
1195                 case RACE_NET_CHECKPOINT_NEXT_QUALIFYING:
1196                         race_nextcheckpoint = ReadByte();
1197
1198                         race_nextbesttime = ReadInt24_t();
1199                         if(b != RACE_NET_CHECKPOINT_NEXT_SPEC_QUALIFYING) // not while spectating (matches server)
1200                                 race_mybesttime = ReadInt24_t();
1201                         string newname = ReadString();
1202                         if(autocvar_cl_race_cptimes_onlyself && b != RACE_NET_CHECKPOINT_NEXT_SPEC_QUALIFYING)
1203                         {
1204                                 race_nextbesttime = race_mybesttime;
1205                                 race_mybesttime = 0;
1206                                 strcpy(race_nextbestname, "");
1207                         }
1208                         else
1209                                 strcpy(race_nextbestname, newname);
1210                         break;
1211
1212                 case RACE_NET_CHECKPOINT_HIT_RACE:
1213                         race_mycheckpoint = ReadByte();
1214                         race_mycheckpointtime = time;
1215                         race_mycheckpointdelta = ReadInt24_t();
1216                         race_mycheckpointlapsdelta = ReadByte();
1217                         if(race_mycheckpointlapsdelta >= 128)
1218                                 race_mycheckpointlapsdelta -= 256;
1219                         int who = ReadByte();
1220                         if(who)
1221                                 strcpy(race_mycheckpointenemy, entcs_GetName(who - 1));
1222                         else
1223                                 strcpy(race_mycheckpointenemy, ""); // TODO: maybe string_null works fine here?
1224                         break;
1225
1226                 case RACE_NET_CHECKPOINT_HIT_RACE_BY_OPPONENT:
1227                         race_othercheckpoint = ReadByte();
1228                         race_othercheckpointtime = time;
1229                         race_othercheckpointdelta = ReadInt24_t();
1230                         race_othercheckpointlapsdelta = ReadByte();
1231                         if(race_othercheckpointlapsdelta >= 128)
1232                                 race_othercheckpointlapsdelta -= 256;
1233                         int what = ReadByte();
1234                         if(what)
1235                                 strcpy(race_othercheckpointenemy, entcs_GetName(what - 1));
1236                         else
1237                                 strcpy(race_othercheckpointenemy, ""); // TODO: maybe string_null works fine here?
1238                         break;
1239
1240                 case RACE_NET_PENALTY_RACE:
1241                 case RACE_NET_PENALTY_QUALIFYING:
1242                         race_penaltyeventtime = time;
1243                         race_penaltytime = ReadShort();
1244                         string reason = ReadString();
1245                         if (reason == "missing a checkpoint")
1246                                 reason = _("missing a checkpoint");
1247                         strcpy(race_penaltyreason, reason);
1248                         if (b == RACE_NET_PENALTY_QUALIFYING)
1249                                 race_penaltyaccumulator += race_penaltytime;
1250                         break;
1251
1252                 case RACE_NET_SERVER_RECORD:
1253                         race_server_record = ReadInt24_t();
1254                         break;
1255                 case RACE_NET_SPEED_AWARD:
1256                         race_speedaward = ReadInt24_t() * GetSpeedUnitFactor(autocvar_hud_panel_physics_speed_unit);
1257                         strcpy(race_speedaward_holder, ReadString());
1258                         break;
1259                 case RACE_NET_SPEED_AWARD_BEST:
1260                         race_speedaward_alltimebest = ReadInt24_t() * GetSpeedUnitFactor(autocvar_hud_panel_physics_speed_unit);
1261                         strcpy(race_speedaward_alltimebest_holder, ReadString());
1262                         break;
1263                 case RACE_NET_RANKINGS_CNT:
1264                         RANKINGS_DISPLAY_CNT = ReadByte();
1265                         break;
1266                 case RACE_NET_SERVER_RANKINGS:
1267                         float prevpos, del;
1268                         int pos = ReadShort();
1269                         prevpos = ReadShort();
1270                         del = ReadShort();
1271
1272                         // move other rankings out of the way
1273                         int i;
1274                         if (prevpos) {
1275                                 int m = min(prevpos, RANKINGS_DISPLAY_CNT);
1276                                 for (i=m-1; i>pos-1; --i) {
1277                                         grecordtime[i] = grecordtime[i-1];
1278                                         strcpy(grecordholder[i], grecordholder[i-1]);
1279                                 }
1280                         } else if (del) { // a record has been deleted by the admin
1281                                 for (i=pos-1; i<= RANKINGS_DISPLAY_CNT-1; ++i) {
1282                                         if (i == RANKINGS_DISPLAY_CNT-1) { // clear out last record
1283                                                 grecordtime[i] = 0;
1284                                                 strfree(grecordholder[i]);
1285                                         }
1286                                         else {
1287                                                 grecordtime[i] = grecordtime[i+1];
1288                                                 strcpy(grecordholder[i], grecordholder[i+1]);
1289                                         }
1290                                 }
1291                         } else { // player has no ranked record yet
1292                                 for (i=RANKINGS_DISPLAY_CNT-1;i>pos-1;--i) {
1293                                         grecordtime[i] = grecordtime[i-1];
1294                                         strcpy(grecordholder[i], grecordholder[i-1]);
1295                                 }
1296                         }
1297
1298                         if (grecordtime[RANKINGS_DISPLAY_CNT]) {
1299                                 // kick off the player who fell from the last displayed position
1300                                 grecordtime[RANKINGS_DISPLAY_CNT] = 0;
1301                                 strfree(grecordholder[RANKINGS_DISPLAY_CNT]);
1302                         }
1303
1304                         // store new ranking
1305                         strcpy(grecordholder[pos-1], ReadString());
1306                         grecordtime[pos-1] = ReadInt24_t();
1307                         if(strdecolorize(grecordholder[pos-1]) == strdecolorize(entcs_GetName(player_localnum)))
1308                                 race_myrank = pos;
1309                         break;
1310                 case RACE_NET_SERVER_STATUS:
1311                         race_status = ReadShort();
1312                         strcpy(race_status_name, ReadString());
1313         }
1314         return true;
1315 }
1316
1317 NET_HANDLE(TE_CSQC_TEAMNAGGER, bool isNew)
1318 {
1319         teamnagger = 1;
1320         return true;
1321 }
1322
1323 NET_HANDLE(TE_CSQC_PINGPLREPORT, bool isNew)
1324 {
1325         int i = ReadByte();
1326         int pi = ReadShort();
1327         int pl = ReadByte();
1328         int ml = ReadByte();
1329         return = true;
1330         entity e = playerslots[i];
1331         if (!e) return;
1332         e.ping = pi;
1333         e.ping_packetloss = pl / 255.0;
1334         e.ping_movementloss = ml / 255.0;
1335 }
1336
1337 NET_HANDLE(TE_CSQC_WEAPONCOMPLAIN, bool isNew)
1338 {
1339         int weapon_id = ReadByte();
1340         complain_weapon = REGISTRY_GET(Weapons, weapon_id);
1341         complain_weapon_type = ReadByte();
1342         return = true;
1343
1344         complain_weapon_time = time;
1345         weapontime = time; // ping the weapon panel
1346
1347         switch(complain_weapon_type)
1348         {
1349                 case 0: Local_Notification(MSG_MULTI, ITEM_WEAPON_NOAMMO, weapon_id); break;
1350                 case 1: Local_Notification(MSG_MULTI, ITEM_WEAPON_DONTHAVE, weapon_id); break;
1351                 default: Local_Notification(MSG_MULTI, ITEM_WEAPON_UNAVAILABLE, weapon_id); break;
1352         }
1353 }
1354
1355 string translate_modifications(string s)
1356 {
1357         return build_mutator_list(s);
1358 }
1359
1360 string translate_weaponarena(string s)
1361 {
1362         if (s == "") return s;
1363         if (s == "All Weapons Arena") return _("All Weapons Arena");
1364         if (s == "All Available Weapons Arena") return _("All Available Weapons Arena");
1365         if (s == "Most Weapons Arena") return _("Most Weapons Arena");
1366         if (s == "Most Available Weapons Arena") return _("Most Available Weapons Arena");
1367         if (s == "Dev All Weapons Arena") return s; // development option, do not translate
1368         if (s == "Dev All Available Weapons Arena") return s; // development option, do not translate
1369         if (s == "No Weapons Arena") return _("No Weapons Arena");
1370
1371         int n = tokenizebyseparator(s, " & ");
1372         string wpn_list = "";
1373         for (int i = 0; i < n; i++)
1374         {
1375                 Weapon wep = Weapon_from_name(argv(i));
1376                 if (wep == WEP_Null)
1377                         LOG_INFO("^3Warning: ^7server sent an invalid weapon name\n");
1378                 wpn_list = cons_mid(wpn_list, " & ", wep.m_name);
1379         }
1380         if (wpn_list != "")
1381                 return sprintf(_("%s Arena"), wpn_list);
1382         else
1383                 return _("No Weapons Arena");
1384 }
1385
1386 string GetVersionMessage(string hostversion, bool version_mismatch, bool version_check)
1387 {
1388         string xonotic_hostversion = strcat("Xonotic ", hostversion);
1389         if (version_mismatch)
1390         {
1391                 if(!version_check)
1392                         return strcat(sprintf(_("This is %s"), xonotic_hostversion), "\n^3",
1393                                 _("Your client version is outdated."), "\n\n\n",
1394                                 _("### YOU WON'T BE ABLE TO PLAY ON THIS SERVER ###"), "\n\n\n",
1395                                 _("Please update!"));
1396                 else
1397                         return strcat(sprintf(_("This is %s"), xonotic_hostversion), "\n^3",
1398                                 _("This server is using an outdated Xonotic version."), "\n\n\n",
1399                                 _("### THIS SERVER IS INCOMPATIBLE AND THUS YOU CANNOT JOIN ###"));
1400         }
1401         return sprintf(_("Welcome to %s"), xonotic_hostversion);
1402 }
1403
1404 bool net_handle_ServerWelcome()
1405 {
1406         bool campaign = ReadByte();
1407         if (campaign)
1408         {
1409                 string campaign_title = ReadString();
1410                 int campaign_level = ReadByte();
1411                 string campaign_msg = ReadString();
1412                 string welcomedialog_args;
1413                 welcomedialog_args = strcat("HOSTNAME \"", campaign_title, "\"");
1414                 string key = getcommandkey(_("jump"), "+jump");
1415                 string msg = strcat(
1416                         CCR("^F1"), sprintf(_("Level %d:"), campaign_level),
1417                         sprintf(CCR(" ^BG%s\n^3\n"), campaign_msg),
1418                         sprintf(CCR(_("^BGPress ^F2%s^BG to enter the game")), key));
1419                 msg = MakeConsoleSafe(strreplace("\n", "\\n", msg));
1420                 welcomedialog_args = strcat(welcomedialog_args, " WELCOME \"", msg, "\"");
1421                 localcmd("\nmenu_cmd directmenu Welcome ", welcomedialog_args, "\n");
1422                 return true;
1423         }
1424
1425         strcpy(hostname, ReadString());
1426         string hostversion = ReadString();
1427         bool version_mismatch = ReadByte();
1428         bool version_check = ReadByte();
1429         srv_minplayers = ReadByte();
1430         srv_maxplayers = ReadByte();
1431         string modifications = translate_modifications(ReadString());
1432         string weaponarena_list = translate_weaponarena(ReadString());
1433         string cache_mutatormsg = ReadString();
1434         string motd = ReadString();
1435
1436         string msg = GetVersionMessage(hostversion, version_mismatch, version_check);
1437
1438         msg = strcat(msg, "\n\n", _("Gametype:"), " ^1", MapInfo_Type_ToText(gametype), "\n");
1439
1440         msg = strcat(msg, "\n", _("Map:"), " ^2");
1441         if (world.message == "")
1442                 msg = strcat(msg, mi_shortname, "\n");
1443         else
1444         {
1445                 int i = strstrofs(world.message, " by ", 0); // matches _MapInfo_Generate()
1446                 string longname = i >= 0 ? substring(world.message, 0, i) : world.message;
1447                 msg = strcat(msg, (strcasecmp(longname, mi_shortname) ? strcat(mi_shortname, " ^7// ^2") : ""), longname, "\n");
1448         }
1449
1450         if (srv_minplayers || srv_maxplayers)
1451         {
1452                 msg = strcat(msg, "\n", _("This match supports"), " ^5");
1453                 if (srv_minplayers == srv_maxplayers)
1454                         msg = strcat(msg, sprintf(_("%d players"), srv_maxplayers), "\n");
1455                 else if (srv_minplayers && srv_maxplayers)
1456                         msg = strcat(msg, sprintf(_("%d to %d players"), srv_minplayers, srv_maxplayers), "\n");
1457                 else if (srv_maxplayers)
1458                         msg = strcat(msg, sprintf(_("%d players maximum"), srv_maxplayers), "\n");
1459                 else
1460                         msg = strcat(msg, sprintf(_("%d players minimum"), srv_minplayers), "\n");
1461         }
1462
1463         modifications = cons_mid(modifications, ", ", weaponarena_list);
1464         if(modifications != "")
1465                 msg = strcat(msg, "\n", _("Active modifications:"), " ^3", modifications, "\n");
1466
1467         if (cache_mutatormsg != "")
1468                 msg = strcat(msg, "\n", _("Special gameplay tips:"), " ^7", cache_mutatormsg, "\n");
1469         string mutator_msg = "";
1470         MUTATOR_CALLHOOK(BuildGameplayTipsString, mutator_msg);
1471         mutator_msg = M_ARGV(0, string);
1472         msg = strcat(msg, mutator_msg); // trust that the mutator will do proper formatting
1473
1474         if (motd != "")
1475                 msg = strcat(msg, "\n^9↓ ", _("Server's message"), " ↓\n", motd);
1476
1477         strcpy(welcome_msg, msg);
1478         welcome_msg_menu_check_maxtime = time + 1; // wait for menu to load before showing the welcome dialog
1479         return true;
1480 }
1481
1482 void Welcome_Message_Show_Try()
1483 {
1484         if (!welcome_msg_menu_check_maxtime)
1485                 return;
1486
1487         // if want dialog check if menu is initialized but for a short time
1488         if (cvar("_menu_initialized") == 2 || time > welcome_msg_menu_check_maxtime)
1489         {
1490                 if (cvar("_menu_welcome_dialog_available"))
1491                 {
1492                         string welcomedialog_args = strcat("HOSTNAME \"", hostname, "\"");
1493                         string msg = MakeConsoleSafe(strreplace("\n", "\\n", welcome_msg));
1494                         welcomedialog_args = strcat(welcomedialog_args, " WELCOME \"", msg, "\"");
1495
1496                         if (intermission || isdemo() || !autocvar_cl_welcome)
1497                         {
1498                                 if (cvar("_menu_cmd_closemenu_available"))
1499                                 {
1500                                         // initialize the dialog without opening it
1501                                         localcmd("\nmenu_cmd closemenu Welcome ", welcomedialog_args, "\n");
1502                                 }
1503                                 else
1504                                 {
1505                                         // legacy code for clients with old menus
1506                                         // since togglemenu 0 doesn't close the dialog but only hides it,
1507                                         // playing back a demo the Welcome dialog will pop up on the first ESC press
1508                                         localcmd("\nmenu_cmd directmenu Welcome ", welcomedialog_args, "\n");
1509                                         // close it after it's been initialized so it can still be opened manually
1510                                         localcmd("\ntogglemenu 0\n");
1511                                 }
1512                         }
1513                         else
1514                                 localcmd("\nmenu_cmd directmenu Welcome ", welcomedialog_args, "\n");
1515                 }
1516
1517                 strfree(welcome_msg);
1518                 welcome_msg_menu_check_maxtime = 0;
1519         }
1520 }
1521
1522 NET_HANDLE(TE_CSQC_SERVERWELCOME, bool isNew)
1523 {
1524         return net_handle_ServerWelcome();
1525 }
1526
1527 string _getcommandkey(string cmd_name, string command, bool forcename)
1528 {
1529         string keys;
1530         float n, j, k, l = 0;
1531
1532         if (!autocvar_hud_showbinds)
1533                 return cmd_name;
1534
1535         keys = db_get(binddb, command);
1536         if (keys == "")
1537         {
1538                 bool joy_active = cvar("joy_active");
1539                 n = tokenize(findkeysforcommand(command, 0)); // uses '...' strings
1540                 for(j = 0; j < n; ++j)
1541                 {
1542                         k = stof(argv(j));
1543                         if(k != -1)
1544                         {
1545                                 string key = keynumtostring(k);
1546                                 if(!joy_active && substring(key, 0, 3) == "JOY")
1547                                         continue;
1548
1549                                 key = translate_key(key);
1550
1551                                 if (keys == "")
1552                                         keys = key;
1553                                 else
1554                                         keys = strcat(keys, ", ", key);
1555
1556                                 ++l;
1557                                 if (autocvar_hud_showbinds_limit > 0 && autocvar_hud_showbinds_limit <= l)
1558                                         break;
1559                         }
1560
1561                 }
1562                 if (keys == "")
1563                         keys = "NO_KEY";
1564                 db_put(binddb, command, keys);
1565         }
1566
1567         if (keys == "NO_KEY") {
1568                 if (autocvar_hud_showbinds > 1)
1569                         return sprintf(_("%s (not bound)"), cmd_name);
1570                 else
1571                         return cmd_name;
1572         }
1573         else if (autocvar_hud_showbinds > 1 || forcename)
1574                 return sprintf("%s (%s)", cmd_name, keys);
1575         else
1576                 return keys;
1577 }
1578
1579 /** engine callback */
1580 void URI_Get_Callback(int id, int status, string data)
1581 {
1582         TC(int, id); TC(int, status);
1583         if(url_URI_Get_Callback(id, status, data))
1584         {
1585                 // handled
1586         }
1587         else if (id == URI_GET_DISCARD)
1588         {
1589                 // discard
1590         }
1591         else if (id >= URI_GET_CURL && id <= URI_GET_CURL_END)
1592         {
1593                 // sv_cmd curl
1594                 Curl_URI_Get_Callback(id, status, data);
1595         }
1596         else
1597         {
1598                 LOG_INFOF("Received HTTP request data for an invalid id %d.", id);
1599         }
1600 }