qcsrc/client/mapvoting.qc

   1 #include "mapvoting.qh"
   2
   3 #include "autocvars.qh"
   4 #include <client/draw.qh>
   5 #include "main.qh"
   6 #include "hud/_mod.qh"
   7 #include "hud/panel/scoreboard.qh"
   8
   9 #include <common/mapinfo.qh>
  10 #include <common/util.qh>
  11
  12 // MapVote (#21)
  13
  14 void MapVote_Draw_Export(int fh)
  15 {
  16         // allow saving cvars that aesthetically change the panel into hud skin files
  17         HUD_Write_Cvar("hud_panel_mapvote_highlight_border");
  18 }
  19
  20 int mv_num_maps;
  21
  22 string mv_maps[MAPVOTE_COUNT];
  23 string mv_pics[MAPVOTE_COUNT];
  24 string mv_pk3[MAPVOTE_COUNT]; // map pk3 name or gametype human readable name
  25 string mv_desc[MAPVOTE_COUNT];
  26 float mv_preview[MAPVOTE_COUNT];
  27 float mv_votes[MAPVOTE_COUNT];
  28 float mv_flags[MAPVOTE_COUNT];
  29 float mv_flags_start[MAPVOTE_COUNT];
  30 entity mv_pk3list;
  31 float mv_abstain;
  32 float mv_ownvote;
  33 float mv_detail;
  34 float mv_timeout;
  35 float mv_top2_time;
  36 float mv_top2_alpha;
  37
  38 int mv_selection;
  39 int mv_columns;
  40 int mv_mouse_selection;
  41 int mv_selection_keyboard;
  42
  43 float gametypevote;
  44 string mapvote_chosenmap;
  45 vector gtv_text_size;
  46 vector gtv_text_size_small;
  47
  48 const int NUM_SSDIRS = 4;
  49 string ssdirs[NUM_SSDIRS];
  50 int n_ssdirs;
  51
  52 bool PreviewExists(string name)
  53 {
  54         if(autocvar_cl_readpicture_force)
  55                 return false;
  56
  57         if (fexists(strcat(name, ".tga"))) return true;
  58         if (fexists(strcat(name, ".png"))) return true;
  59         if (fexists(strcat(name, ".jpg"))) return true;
  60         if (fexists(strcat(name, ".pcx"))) return true;
  61
  62         return false;
  63 }
  64
  65 string MapVote_FormatMapItem(int id, string map, float _count, float maxwidth, vector fontsize)
  66 {
  67         TC(int, id);
  68         string pre, post;
  69         pre = sprintf("%d. ", id+1);
  70         if(mv_detail)
  71         {
  72                 if(_count == 1)
  73                         post = _(" (1 vote)");
  74                 else if(_count >= 0 && (mv_flags[id] & GTV_AVAILABLE))
  75                         post = sprintf(_(" (%d votes)"), _count);
  76                 else
  77                         post = "";
  78         }
  79         else
  80                 post = "";
  81         maxwidth -= stringwidth(pre, false, fontsize) + stringwidth(post, false, fontsize);
  82         map = textShortenToWidth(map, maxwidth, fontsize, stringwidth_nocolors);
  83         return strcat(pre, map, post);
  84 }
  85
  86 vector MapVote_RGB(int id)
  87 {
  88         TC(int, id);
  89         if(!(mv_flags[id] & GTV_AVAILABLE))
  90                 return '1 1 1';
  91         if(id == mv_ownvote)
  92                 return '0 1 0';
  93         else if (id == mv_selection)
  94                 return '1 1 0';
  95         else
  96                 return '1 1 1';
  97 }
  98
  99 void GameTypeVote_DrawGameTypeItem(vector pos, float maxh, float tsize, string gtype, string pic, float _count, int id)
 100 {
 101         TC(int, id);
 102         // Find the correct alpha
 103         float alpha;
 104         if(!(mv_flags_start[id] & GTV_AVAILABLE))
 105                 alpha = 0.2; // The gametype isn't supported by the map
 106         else if ( !(mv_flags[id] & GTV_AVAILABLE) && mv_top2_alpha)
 107                 alpha = mv_top2_alpha; // Fade away if not one of the top 2 choice
 108         else
 109                 alpha = 1; // Normal, full alpha
 110         alpha *= panel_fg_alpha;
 111
 112         // Bounding box details
 113         float rect_margin = hud_fontsize.y / 2;
 114
 115         pos.x += rect_margin + autocvar_hud_panel_mapvote_highlight_border;
 116         pos.y += rect_margin + autocvar_hud_panel_mapvote_highlight_border;
 117         maxh -= 2 * (rect_margin + autocvar_hud_panel_mapvote_highlight_border);
 118         tsize -= 2 * (rect_margin + autocvar_hud_panel_mapvote_highlight_border);
 119
 120         vector rect_pos = pos - '0.5 0.5 0' * rect_margin;
 121         vector rect_size = '1 1 0';
 122         rect_size.x = tsize + rect_margin;
 123         rect_size.y = maxh + rect_margin;
 124
 125         // Highlight selected item
 126         if(id == mv_selection && (mv_flags[id] & GTV_AVAILABLE))
 127         {
 128                 drawfill(rect_pos, rect_size, '1 1 1', 0.1 * panel_fg_alpha, DRAWFLAG_NORMAL);
 129         }
 130
 131         // Highlight current vote
 132         vector rgb = MapVote_RGB(id);
 133         if(id == mv_ownvote)
 134         {
 135                 drawfill(rect_pos, rect_size, rgb, 0.1 * alpha, DRAWFLAG_NORMAL);
 136                 drawborderlines(autocvar_hud_panel_mapvote_highlight_border, rect_pos, rect_size, rgb, alpha, DRAWFLAG_NORMAL);
 137         }
 138
 139         vector offset = pos;
 140
 141         float title_gap = gtv_text_size.y * 1.4; // distance between the title and the description
 142         pos.y += title_gap;
 143         maxh -= title_gap;
 144
 145         // Evaluate the image size
 146         vector image_size = '1 1 0' * gtv_text_size.x * 3;
 147         if ( maxh < image_size.y )
 148                 image_size = '1 1 0' * maxh;
 149         image_size *= 0.8;
 150         float desc_padding = gtv_text_size.x * 0.6;
 151         pos.x += image_size.x + desc_padding;
 152         tsize -= image_size.x + desc_padding;
 153
 154         // Split the description into lines
 155         entity title;
 156         title = spawn();
 157         title.message = MapVote_FormatMapItem(id, mv_pk3[id], _count, tsize, gtv_text_size);
 158
 159         string thelabel = mv_desc[id], ts;
 160         entity last = title;
 161         entity next = NULL;
 162         float nlines = 0;
 163         if( thelabel != "")
 164         {
 165                 float i,n = tokenizebyseparator(thelabel, "\n");
 166                 for(i = 0; i < n && maxh > (nlines+1)*gtv_text_size_small.y; ++i)
 167                 {
 168                         getWrappedLine_remaining = argv(i);
 169                         while(getWrappedLine_remaining && maxh > (nlines+1)*gtv_text_size_small.y)
 170                         {
 171                                 ts = getWrappedLine(tsize, gtv_text_size_small, stringwidth_colors);
 172                                 if (ts != "")
 173                                 {
 174                                         next = spawn();
 175                                         next.message = ts;
 176                                         next.origin = pos-offset;
 177                                         last.chain = next;
 178                                         last = next;
 179                                         pos.y += gtv_text_size_small.y;
 180                                         nlines++;
 181                                 }
 182                         }
 183                 }
 184         }
 185
 186         // Center the contents in the bounding box
 187         maxh -= max(nlines*gtv_text_size_small.y,image_size.y);
 188         if ( maxh > 0 )
 189                 offset.y += maxh/2;
 190
 191         // Draw the title
 192         drawstring(offset, title.message, gtv_text_size, rgb, alpha, DRAWFLAG_NORMAL);
 193
 194         // Draw the icon
 195         if(pic != "")
 196                 drawpic('0 1 0'*title_gap+'0.5 0 0'*desc_padding+offset, pic, image_size, '1 1 1', alpha, DRAWFLAG_NORMAL);
 197
 198         // Draw the description
 199         for ( last = title.chain; last ; )
 200         {
 201                 drawstring(last.origin+offset, last.message, gtv_text_size_small, '1 1 1', alpha, DRAWFLAG_NORMAL);
 202                 next = last;
 203                 last = last.chain;
 204                 delete(next);
 205         }
 206
 207         // Cleanup
 208         delete(title);
 209 }
 210
 211 void MapVote_DrawMapItem(vector pos, float isize, float tsize, string map, string pic, float _count, int id)
 212 {
 213         TC(int, id);
 214         vector img_size = '0 0 0';
 215         string label;
 216         float text_size;
 217
 218         float rect_margin = hud_fontsize.y / 2;
 219
 220         pos.x += rect_margin + autocvar_hud_panel_mapvote_highlight_border;
 221         pos.y += rect_margin + autocvar_hud_panel_mapvote_highlight_border;
 222         isize -= 2 * (rect_margin + autocvar_hud_panel_mapvote_highlight_border);
 223         tsize -= 2 * (rect_margin + autocvar_hud_panel_mapvote_highlight_border);
 224
 225         vector rect_pos = pos - '0.5 0.5 0' * rect_margin;
 226         vector rect_size = '1 1 0';
 227         rect_size.x = tsize + rect_margin;
 228         rect_size.y = isize + rect_margin;
 229
 230         float img_ar = 4/3;
 231         img_size.x = min(tsize, isize * img_ar);
 232         img_size.y = img_size.x / img_ar;
 233         img_size.y -= hud_fontsize.y;
 234         img_size.x = img_size.y * img_ar;
 235
 236         pos.y += (isize - img_size.y - hud_fontsize.y) / 2;
 237
 238         label = MapVote_FormatMapItem(id, map, _count, tsize, hud_fontsize);
 239
 240         text_size = stringwidth(label, false, hud_fontsize);
 241
 242         float save_rect_sizex = rect_size.x;
 243         rect_size.x = max(img_size.x, text_size) + rect_margin;
 244         rect_pos.x += (save_rect_sizex - rect_size.x) / 2;
 245
 246         vector text_pos = '0 0 0';
 247         text_pos.x = pos.x + (tsize - text_size) / 2;
 248         text_pos.y = pos.y + img_size.y;
 249
 250         pos.x += (tsize - img_size.x) / 2;
 251
 252         float theAlpha;
 253         if (!(mv_flags[id] & GTV_AVAILABLE) && mv_top2_alpha)
 254                 theAlpha = mv_top2_alpha;
 255         else
 256                 theAlpha = 1;
 257         theAlpha *= panel_fg_alpha;
 258
 259         // Highlight selected item
 260         if(id == mv_selection && (mv_flags[id] & GTV_AVAILABLE))
 261                 drawfill(rect_pos, rect_size, '1 1 1', 0.1 * panel_fg_alpha, DRAWFLAG_NORMAL);
 262
 263         // Highlight current vote
 264         vector rgb = MapVote_RGB(id);
 265         if(id == mv_ownvote)
 266         {
 267                 drawfill(rect_pos, rect_size, rgb, 0.1 * theAlpha, DRAWFLAG_NORMAL);
 268                 drawborderlines(autocvar_hud_panel_mapvote_highlight_border, rect_pos, rect_size, rgb, theAlpha, DRAWFLAG_NORMAL);
 269         }
 270
 271         drawstring(text_pos, label, hud_fontsize, rgb, theAlpha, DRAWFLAG_NORMAL);
 272
 273         if(pic == "")
 274         {
 275                 drawfill(pos, img_size, '.5 .5 .5', .7 * theAlpha, DRAWFLAG_NORMAL);
 276         }
 277         else
 278         {
 279                 if(drawgetimagesize(pic) == '0 0 0')
 280                         drawpic(pos, draw_UseSkinFor("nopreview_map"), img_size, '1 1 1', theAlpha, DRAWFLAG_NORMAL);
 281                 else
 282                         drawpic(pos, pic, img_size, '1 1 1', theAlpha, DRAWFLAG_NORMAL);
 283         }
 284 }
 285
 286 void MapVote_DrawAbstain(vector pos, float isize, float tsize, float _count, int id)
 287 {
 288         TC(int, id);
 289         vector rgb;
 290         float text_size;
 291         string label;
 292
 293         rgb = MapVote_RGB(id);
 294
 295         label = MapVote_FormatMapItem(id, _("Don't care"), _count, tsize, hud_fontsize);
 296
 297         text_size = stringwidth(label, false, hud_fontsize);
 298
 299         pos.x -= text_size*0.5;
 300         drawstring(pos, label, hud_fontsize, rgb, panel_fg_alpha, DRAWFLAG_NORMAL);
 301 }
 302
 303 vector MapVote_GridVec(vector gridspec, int i, int m)
 304 {
 305         TC(int, i); TC(int, m);
 306         int r = i % m;
 307         return
 308                 '1 0 0' * (gridspec.x * r)
 309                 +
 310                 '0 1 0' * (gridspec.y * (i - r) / m);
 311 }
 312
 313 float MapVote_Selection(vector topleft, vector cellsize, float rows, float columns)
 314 {
 315
 316         float c, r;
 317
 318         mv_mouse_selection = -1;
 319
 320         for (r = 0; r < rows; ++r)
 321                 for (c = 0; c < columns; ++c)
 322                 {
 323                         if (mousepos.x >= topleft.x + cellsize.x *  c &&
 324                                 mousepos.x <= topleft.x + cellsize.x * (c + 1) &&
 325                                 mousepos.y >= topleft.y + cellsize.y *  r &&
 326                                 mousepos.y <= topleft.y + cellsize.y * (r + 1))
 327                         {
 328                                 mv_mouse_selection = r * columns + c;
 329                                 break;
 330                         }
 331                 }
 332
 333         if (mv_mouse_selection >= mv_num_maps)
 334                 mv_mouse_selection = -1;
 335
 336         if (mv_abstain && mv_mouse_selection < 0)
 337                 mv_mouse_selection = mv_num_maps;
 338
 339         if ( mv_selection_keyboard )
 340                 return mv_selection;
 341
 342         return mv_mouse_selection;
 343 }
 344
 345 vector prev_mousepos;
 346 // draws map vote or gametype vote
 347 void MapVote_Draw()
 348 {
 349         string map;
 350         int i;
 351         float tmp;
 352         vector pos;
 353         float center;
 354         float rows;
 355         vector dist = '0 0 0';
 356
 357         //if(intermission != 2) return;
 358         if(!mv_active)
 359                 return;
 360
 361         HUD_Panel_LoadCvars();
 362
 363         if (!autocvar_hud_cursormode)
 364         {
 365                 if (mousepos.x != prev_mousepos.x || mousepos.y != prev_mousepos.y)
 366                 {
 367                         mv_selection_keyboard = 0;
 368                         prev_mousepos = mousepos;
 369                 }
 370         }
 371
 372         center = (vid_conwidth - 1)/2;
 373         xmin = vid_conwidth * 0.08;
 374         xmax = vid_conwidth - xmin;
 375         ymin = 20;
 376         ymax = vid_conheight - ymin;
 377
 378         if(chat_posy + chat_sizey / 2 < vid_conheight / 2)
 379                 ymin += chat_sizey;
 380         else
 381                 ymax -= chat_sizey;
 382
 383         hud_fontsize = HUD_GetFontsize("hud_fontsize");
 384         if (gametypevote)
 385         {
 386                 gtv_text_size = hud_fontsize * 1.4;
 387                 gtv_text_size_small = hud_fontsize * 1.1;
 388         }
 389
 390         pos.y = ymin;
 391         pos.z = 0;
 392
 393         HUD_Scale_Disable();
 394         draw_beginBoldFont();
 395
 396         map = ((gametypevote) ? _("Decide the gametype") : _("Vote for a map"));
 397         pos.x = center - stringwidth(map, false, hud_fontsize * 2) * 0.5;
 398         drawstring(pos, map, hud_fontsize * 2, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
 399         pos.y += hud_fontsize.y * 2;
 400
 401         if( mapvote_chosenmap != "" )
 402         {
 403                 pos.y += hud_fontsize.y * 0.25;
 404                 pos.x = center - stringwidth(mapvote_chosenmap, false, hud_fontsize * 1.5) * 0.5;
 405                 drawstring(pos, mapvote_chosenmap, hud_fontsize * 1.5, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
 406                 pos.y += hud_fontsize.y * 1.5;
 407         }
 408         pos.y += hud_fontsize.y * 0.5;
 409
 410         draw_endBoldFont();
 411
 412         i = ceil(max(0, mv_timeout - time));
 413         map = sprintf(_("%d seconds left"), i);
 414         pos.x = center - stringwidth(map, false, hud_fontsize * 1.5) * 0.5;
 415         drawstring(pos, map, hud_fontsize * 1.5, '0 1 0', panel_fg_alpha, DRAWFLAG_NORMAL);
 416         pos.y += hud_fontsize.y * 1.5;
 417         pos.y += hud_fontsize.y * 0.5;
 418
 419         // base for multi-column stuff...
 420         pos.y += hud_fontsize.y;
 421         pos.x = xmin;
 422         ymin = pos.y;
 423         float abstain_spacing = panel_bg_border + hud_fontsize.y;
 424         if(mv_abstain)
 425         {
 426                 mv_num_maps -= 1;
 427                 ymax -= abstain_spacing;
 428         }
 429
 430         // higher than the image itself ratio for mapvote items to reserve space for long map names
 431         int item_aspect = (gametypevote) ? 3/1 : 5/3;
 432         vector table_size = HUD_GetTableSize_BestItemAR(mv_num_maps, vec2(xmax - xmin, ymax - ymin), item_aspect);
 433         mv_columns = table_size.x;
 434         rows = table_size.y;
 435
 436         dist.x = (xmax - xmin) / mv_columns;
 437         dist.y = (ymax - pos.y) / rows;
 438
 439         // reduce size of too wide items
 440         tmp = vid_conwidth / 3; // max width
 441         if(dist.x > tmp)
 442         {
 443                 dist.x = tmp;
 444                 dist.y = min(dist.y, dist.x / item_aspect);
 445         }
 446         tmp = vid_conheight / 3; // max height
 447         if(dist.y > tmp)
 448         {
 449                 dist.y = tmp;
 450                 dist.x = min(dist.x, dist.y * item_aspect);
 451         }
 452
 453         // reduce size to fix aspect ratio
 454         if(dist.x / dist.y > item_aspect)
 455                 dist.x = dist.y * item_aspect;
 456         else
 457                 dist.y = dist.x / item_aspect;
 458
 459         // adjust table pos and size according to the new size
 460         float offset;
 461         offset = ((xmax - pos.x) - dist.x * mv_columns) / 2;
 462         xmin = pos.x += offset;
 463         xmax -= offset;
 464         offset = ((ymax - pos.y) - dist.y * rows) / 2;
 465         ymax -= 2 * offset;
 466
 467         // override panel_pos and panel_size
 468         panel_pos.x = pos.x;
 469         panel_pos.y = pos.y;
 470         panel_size.x = xmax - xmin;
 471         panel_size.y = ymax - ymin;
 472         HUD_Panel_DrawBg();
 473
 474         if(panel_bg_padding)
 475         {
 476                 // FIXME item AR gets slightly changed here...
 477                 // it's rather hard to avoid it at this point
 478                 dist.x -= 2 * panel_bg_padding / mv_columns;
 479                 dist.y -= 2 * panel_bg_padding / rows;
 480                 xmin = pos.x += panel_bg_padding;
 481                 ymin = pos.y += panel_bg_padding;
 482                 xmax -= 2 * panel_bg_padding;
 483                 ymax -= 2 * panel_bg_padding;
 484         }
 485
 486         mv_selection = MapVote_Selection(pos, dist, rows, mv_columns);
 487
 488         if (mv_top2_time)
 489                 mv_top2_alpha = max(0.2, 1 - (time - mv_top2_time) ** 2);
 490
 491         void (vector, float, float, string, string, float, float) DrawItem;
 492
 493         if(gametypevote)
 494                 DrawItem = GameTypeVote_DrawGameTypeItem;
 495         else
 496                 DrawItem = MapVote_DrawMapItem;
 497
 498         for(i = 0; i < mv_num_maps; ++i)
 499         {
 500                 tmp = mv_votes[i]; // FTEQCC bug: too many array accesses in the function call screw it up
 501                 map = mv_maps[i];
 502                 if(mv_preview[i])
 503                         DrawItem(pos + MapVote_GridVec(dist, i, mv_columns), dist.y, dist.x, map, mv_pics[i], tmp, i);
 504                 else
 505                         DrawItem(pos + MapVote_GridVec(dist, i, mv_columns), dist.y, dist.x, map, "", tmp, i);
 506         }
 507
 508         if(mv_abstain)
 509                 ++mv_num_maps;
 510
 511         if(mv_abstain && i < mv_num_maps) {
 512                 tmp = mv_votes[i];
 513                 pos.y = ymax + abstain_spacing;
 514                 pos.x = (xmax+xmin)*0.5;
 515                 MapVote_DrawAbstain(pos, dist.x, xmax - xmin, tmp, i);
 516         }
 517 }
 518
 519 void Cmd_MapVote_MapDownload(int argc)
 520 {
 521         TC(int, argc);
 522         entity pak;
 523
 524         if(argc != 2 || !mv_pk3list)
 525         {
 526                 LOG_INFO(_("mv_mapdownload: ^3You're not supposed to use this command on your own!"));
 527                 return;
 528         }
 529
 530         int id = stof(argv(1));
 531         for(pak = mv_pk3list; pak; pak = pak.chain)
 532                 if(pak.sv_entnum == id)
 533                         break;
 534
 535         if(!pak || pak.sv_entnum != id) {
 536                 LOG_INFO(_("^1Error:^7 Couldn't find pak index."));
 537                 return;
 538         }
 539
 540         if(PreviewExists(pak.message))
 541         {
 542                 mv_preview[id] = true;
 543                 return;
 544         } else {
 545                 LOG_INFO(_("Requesting preview..."));
 546                 localcmd(strcat("\ncmd mv_getpicture ", ftos(id), "\n"));
 547         }
 548 }
 549
 550 void MapVote_CheckPK3(string pic, string pk3, int id)
 551 {
 552         TC(int, id);
 553         entity pak;
 554         pak = spawn();
 555         pak.netname = pk3;
 556         pak.message = pic;
 557         pak.sv_entnum = id;
 558
 559         pak.chain = mv_pk3list;
 560         mv_pk3list = pak;
 561
 562         if(pk3 != "")
 563         {
 564                 localcmd(strcat("\ncurl --pak ", pk3, "; wait; cl_cmd mv_download ", ftos(id), "\n"));
 565         }
 566         else
 567         {
 568                 Cmd_MapVote_MapDownload(tokenize_console(strcat("mv_download ", ftos(id))));
 569         }
 570 }
 571
 572 void MapVote_CheckPic(string pic, string pk3, int id)
 573 {
 574         TC(int, id);
 575         // never try to retrieve a pic for the "don't care" 'map'
 576         if(mv_abstain && id == mv_num_maps - 1)
 577                 return;
 578
 579         if(PreviewExists(pic))
 580         {
 581                 mv_preview[id] = true;
 582                 return;
 583         }
 584         MapVote_CheckPK3(pic, pk3, id);
 585 }
 586
 587 void MapVote_ReadMask()
 588 {
 589         int i;
 590         if ( mv_num_maps < 24 )
 591         {
 592                 int mask;
 593                 if(mv_num_maps < 8)
 594                         mask = ReadByte();
 595                 else if(mv_num_maps < 16)
 596                         mask = ReadShort();
 597                 else
 598                         mask = ReadLong();
 599
 600                 for(i = 0; i < mv_num_maps; ++i)
 601                 {
 602                         if (mask & BIT(i))
 603                                 mv_flags[i] |= GTV_AVAILABLE;
 604                         else
 605                                 mv_flags[i] &= ~GTV_AVAILABLE;
 606                 }
 607         }
 608         else
 609         {
 610                 for(i = 0; i < mv_num_maps; ++i )
 611                         mv_flags[i] = ReadByte();
 612         }
 613 }
 614
 615 void MapVote_ReadOption(int i)
 616 {
 617         TC(int, i);
 618         string map = strzone(ReadString());
 619         string pk3 = strzone(ReadString());
 620         int j = bound(0, ReadByte(), n_ssdirs - 1);
 621
 622         mv_maps[i] = map;
 623         mv_pk3[i] = pk3;
 624         mv_flags[i] = GTV_AVAILABLE;
 625
 626         string pic = strzone(strcat(ssdirs[j], "/", map));
 627         mv_pics[i] = pic;
 628         mv_preview[i] = false;
 629         MapVote_CheckPic(pic, pk3, i);
 630 }
 631
 632 void GameTypeVote_ReadOption(int i)
 633 {
 634         TC(int, i);
 635         string gt = strzone(ReadString());
 636
 637         mv_maps[i] = gt;
 638         mv_flags[i] = ReadByte();
 639
 640         string basetype = "";
 641
 642         if ( mv_flags[i] & GTV_CUSTOM )
 643         {
 644                 string name = ReadString();
 645                 if ( strlen(name) < 1 )
 646                         name = gt;
 647                 mv_pk3[i] = strzone(name);
 648                 mv_desc[i] = strzone(ReadString());
 649                 basetype = strzone(ReadString());
 650         }
 651         else
 652         {
 653                 Gametype type = MapInfo_Type_FromString(gt, false);
 654                 mv_pk3[i] = strzone(MapInfo_Type_ToText(type));
 655                 mv_desc[i] = MapInfo_Type_Description(type);
 656         }
 657
 658         string mv_picpath = sprintf("gfx/menu/%s/gametype_%s", autocvar_menu_skin, gt);
 659         if(precache_pic(mv_picpath) == "")
 660         {
 661                 mv_picpath = strcat("gfx/menu/default/gametype_", gt);
 662                 if(precache_pic(mv_picpath) == "")
 663                 {
 664                         mv_picpath = sprintf("gfx/menu/%s/gametype_%s", autocvar_menu_skin, basetype);
 665                         if(precache_pic(mv_picpath) == "")
 666                         {
 667                                 mv_picpath = strcat("gfx/menu/default/gametype_", basetype);
 668                         }
 669                 }
 670         }
 671         string pic = strzone(mv_picpath);
 672         mv_pics[i] = pic;
 673         mv_preview[i] = PreviewExists(pic);
 674 }
 675
 676 void MapVote_Init()
 677 {
 678         mv_active = 1;
 679         if(!autocvar_hud_cursormode) mousepos = '0.5 0 0' * vid_conwidth + '0 0.5 0' * vid_conheight;
 680         mv_selection = -1;
 681         mv_selection_keyboard = 0;
 682
 683         string s;
 684         for(n_ssdirs = 0; ; ++n_ssdirs)
 685         {
 686                 s = ReadString();
 687                 if(s == "")
 688                         break;
 689                 if(n_ssdirs < NUM_SSDIRS)
 690                         ssdirs[n_ssdirs] = s;
 691         }
 692         n_ssdirs = min(n_ssdirs, NUM_SSDIRS);
 693
 694         mv_num_maps = min(MAPVOTE_COUNT, ReadByte());
 695         mv_abstain = ReadByte();
 696         if(mv_abstain)
 697                 mv_abstain = 1; // must be 1 for bool-true, makes stuff easier
 698         mv_detail = ReadByte();
 699
 700         mv_ownvote = -1;
 701         mv_timeout = ReadCoord();
 702
 703         gametypevote = ReadByte();
 704
 705         if(gametypevote)
 706         {
 707                 mapvote_chosenmap = strzone(ReadString());
 708                 if ( gametypevote == 2 )
 709                         gametypevote = 0;
 710         }
 711
 712         MapVote_ReadMask();
 713         int i;
 714         for(i = 0; i < mv_num_maps; ++i )
 715                 mv_flags_start[i] = mv_flags[i];
 716
 717         // Assume mv_pk3list is NULL, there should only be 1 mapvote per round
 718         mv_pk3list = NULL; // I'm still paranoid!
 719
 720         for(i = 0; i < mv_num_maps; ++i)
 721         {
 722                 mv_votes[i] = 0;
 723
 724                 if ( gametypevote )
 725                         GameTypeVote_ReadOption(i);
 726                 else
 727                         MapVote_ReadOption(i);
 728         }
 729
 730         for(i = 0; i < n_ssdirs; ++i)
 731                 ssdirs[n_ssdirs] = string_null;
 732         n_ssdirs = 0;
 733 }
 734
 735 void MapVote_SendChoice(int index)
 736 {
 737         TC(int, index);
 738         localcmd(strcat("\nimpulse ", ftos(index+1), "\n"));
 739 }
 740
 741 int MapVote_MoveLeft(int pos)
 742 {
 743         TC(int, pos);
 744         int imp;
 745         if ( pos < 0 )
 746                 imp = mv_num_maps - 1;
 747         else
 748                 imp = pos < 1 ? mv_num_maps - 1 : pos - 1;
 749         if ( !(mv_flags[imp] & GTV_AVAILABLE) && imp != mv_ownvote )
 750                 imp = MapVote_MoveLeft(imp);
 751         return imp;
 752 }
 753 int MapVote_MoveRight(int pos)
 754 {
 755         TC(int, pos);
 756         int imp;
 757         if ( pos < 0 )
 758                 imp = 0;
 759         else
 760                 imp = pos >= mv_num_maps - 1 ? 0 : pos + 1;
 761         if ( !(mv_flags[imp] & GTV_AVAILABLE) && imp != mv_ownvote )
 762                 imp = MapVote_MoveRight(imp);
 763         return imp;
 764 }
 765 int MapVote_MoveUp(int pos)
 766 {
 767         TC(int, pos);
 768         int imp;
 769         if ( pos < 0 )
 770                 imp = mv_num_maps - 1;
 771         else
 772         {
 773                 imp = pos - mv_columns;
 774                 if ( imp < 0 )
 775                 {
 776                         imp = floor(mv_num_maps/mv_columns)*mv_columns + pos % mv_columns;
 777                         if ( imp >= mv_num_maps )
 778                                 imp -= mv_columns;
 779                 }
 780         }
 781         if ( !(mv_flags[imp] & GTV_AVAILABLE) && imp != mv_ownvote )
 782                 imp = MapVote_MoveUp(imp);
 783         return imp;
 784 }
 785 int MapVote_MoveDown(int pos)
 786 {
 787         TC(int, pos);
 788         int imp;
 789         if ( pos < 0 )
 790                 imp = 0;
 791         else
 792         {
 793                 imp = pos + mv_columns;
 794                 if ( imp >= mv_num_maps )
 795                         imp = imp % mv_columns;
 796         }
 797         if ( !(mv_flags[imp] & GTV_AVAILABLE) && imp != mv_ownvote )
 798                 imp = MapVote_MoveDown(imp);
 799         return imp;
 800 }
 801
 802 float MapVote_InputEvent(int bInputType, float nPrimary, float nSecondary)
 803 {
 804         TC(int, bInputType);
 805
 806         static int first_digit = 0;
 807         if (!mv_active)
 808                 return false;
 809
 810         if(bInputType == 3)
 811         {
 812                 mousepos.x = nPrimary;
 813                 mousepos.y = nSecondary;
 814                 mv_selection_keyboard = 0;
 815                 return true;
 816         }
 817
 818         if (bInputType == 0)
 819         {
 820                 if (nPrimary == K_ALT) hudShiftState |= S_ALT;
 821                 if (nPrimary == K_CTRL) hudShiftState |= S_CTRL;
 822                 if (nPrimary == K_SHIFT) hudShiftState |= S_SHIFT;
 823         }
 824         else if (bInputType == 1)
 825         {
 826                 if (nPrimary == K_ALT) hudShiftState -= (hudShiftState & S_ALT);
 827                 if (nPrimary == K_CTRL) hudShiftState -= (hudShiftState & S_CTRL);
 828                 if (nPrimary == K_SHIFT) hudShiftState -= (hudShiftState & S_SHIFT);
 829
 830                 if (nPrimary == K_CTRL)
 831                         first_digit = 0;
 832         }
 833
 834         if (bInputType != 0)
 835                 return false;
 836
 837         int imp = 0;
 838         switch(nPrimary)
 839         {
 840                 case K_RIGHTARROW:
 841                         mv_selection_keyboard = 1;
 842                         mv_selection = MapVote_MoveRight(mv_selection);
 843                         return true;
 844                 case K_LEFTARROW:
 845                         mv_selection_keyboard = 1;
 846                         mv_selection = MapVote_MoveLeft(mv_selection);
 847                         return true;
 848                 case K_DOWNARROW:
 849                         mv_selection_keyboard = 1;
 850                         mv_selection = MapVote_MoveDown(mv_selection);
 851                         return true;
 852                 case K_UPARROW:
 853                         mv_selection_keyboard = 1;
 854                         mv_selection = MapVote_MoveUp(mv_selection);
 855                         return true;
 856                 case K_KP_ENTER:
 857                 case K_ENTER:
 858                 case K_SPACE:
 859                         if ( mv_selection_keyboard )
 860                                 MapVote_SendChoice(mv_selection);
 861                         return true;
 862                 case '1': case K_KP_1: imp = 1; break;
 863                 case '2': case K_KP_2: imp = 2; break;
 864                 case '3': case K_KP_3: imp = 3; break;
 865                 case '4': case K_KP_4: imp = 4; break;
 866                 case '5': case K_KP_5: imp = 5; break;
 867                 case '6': case K_KP_6: imp = 6; break;
 868                 case '7': case K_KP_7: imp = 7; break;
 869                 case '8': case K_KP_8: imp = 8; break;
 870                 case '9': case K_KP_9: imp = 9; break;
 871                 case '0': case K_KP_0: imp = 10; break;
 872         }
 873
 874         if (imp && hudShiftState & S_CTRL)
 875         {
 876                 if (!first_digit)
 877                 {
 878                         first_digit = imp % 10;
 879                         return true;
 880                 }
 881                 else
 882                         imp = first_digit * 10 + (imp % 10);
 883         }
 884
 885         if (nPrimary == K_MOUSE1)
 886         {
 887                 mv_selection_keyboard = 0;
 888                 mv_selection = mv_mouse_selection;
 889                 if (mv_selection >= 0)
 890                         imp = min(mv_selection + 1, mv_num_maps);
 891         }
 892
 893         if (imp)
 894         {
 895                 if (imp <= mv_num_maps)
 896                         localcmd(strcat("\nimpulse ", ftos(imp), "\n"));
 897                 return true;
 898         }
 899
 900         return false;
 901 }
 902
 903 void MapVote_UpdateMask()
 904 {
 905         MapVote_ReadMask();
 906         mv_top2_time = time;
 907 }
 908
 909 void MapVote_UpdateVotes()
 910 {
 911         int i;
 912         for(i = 0; i < mv_num_maps; ++i)
 913         {
 914                 if(mv_flags[i] & GTV_AVAILABLE)
 915                 {
 916                         if(mv_detail)
 917                                 mv_votes[i] = ReadByte();
 918                         else
 919                                 mv_votes[i] = 0;
 920                 }
 921                 else
 922                         mv_votes[i] = -1;
 923         }
 924
 925         mv_ownvote = ReadByte()-1;
 926 }
 927
 928 NET_HANDLE(ENT_CLIENT_MAPVOTE, bool isnew)
 929 {
 930         make_pure(this);
 931         int sf = ReadByte();
 932         return = true;
 933
 934         if(sf & 1)
 935                 MapVote_Init();
 936
 937         if(sf & 2)
 938                 MapVote_UpdateMask();
 939
 940         if(sf & 4)
 941                 MapVote_UpdateVotes();
 942 }
 943
 944 NET_HANDLE(TE_CSQC_PICTURE, bool isNew)
 945 {
 946         Net_MapVote_Picture();
 947         return true;
 948 }
 949
 950 void Net_MapVote_Picture()
 951 {
 952         int type = ReadByte();
 953         mv_preview[type] = true;
 954         mv_pics[type] = strzone(ReadPicture());
 955 }