qcsrc/client/mapvoting.qc

   1 #include "mapvoting.qh"
   2 #include "_all.qh"
   3
   4 #include "hud.qh"
   5 #include "scoreboard.qh"
   6
   7 #include "../common/mapinfo.qh"
   8 #include "../common/util.qh"
   9
  10
  11 int mv_num_maps;
  12
  13 string mv_maps[MAPVOTE_COUNT];
  14 string mv_pics[MAPVOTE_COUNT];
  15 string mv_pk3[MAPVOTE_COUNT]; // map pk3 name or gametype human readable name
  16 string mv_desc[MAPVOTE_COUNT];
  17 float mv_preview[MAPVOTE_COUNT];
  18 float mv_votes[MAPVOTE_COUNT];
  19 float mv_flags[MAPVOTE_COUNT];
  20 float mv_flags_start[MAPVOTE_COUNT];
  21 entity mv_pk3list;
  22 float mv_abstain;
  23 float mv_ownvote;
  24 float mv_detail;
  25 float mv_timeout;
  26 float mv_top2_time;
  27 float mv_top2_alpha;
  28
  29 vector mv_mousepos;
  30 int mv_selection;
  31 int mv_columns;
  32 int mv_mouse_selection;
  33 int mv_selection_keyboard;
  34
  35 float gametypevote;
  36 string mapvote_chosenmap;
  37 vector gtv_text_size;
  38 vector gtv_text_size_small;
  39
  40 const int NUM_SSDIRS = 4;
  41 string ssdirs[NUM_SSDIRS];
  42 int n_ssdirs;
  43
  44 string MapVote_FormatMapItem(int id, string map, float _count, float maxwidth, vector fontsize)
  45 {
  46         string pre, post;
  47         pre = sprintf("%d. ", id+1);
  48         if(mv_detail)
  49         {
  50                 if(_count == 1)
  51                         post = _(" (1 vote)");
  52                 else if(_count >= 0 && (mv_flags[id] & GTV_AVAILABLE))
  53                         post = sprintf(_(" (%d votes)"), _count);
  54                 else
  55                         post = "";
  56         }
  57         else
  58                 post = "";
  59         maxwidth -= stringwidth(pre, false, fontsize) + stringwidth(post, false, fontsize);
  60         map = textShortenToWidth(map, maxwidth, fontsize, stringwidth_nocolors);
  61         return strcat(pre, map, post);
  62 }
  63
  64 vector MapVote_RGB(int id)
  65 {
  66         if(!(mv_flags[id] & GTV_AVAILABLE))
  67                 return '1 1 1';
  68         if(id == mv_ownvote)
  69                 return '0 1 0';
  70         else if (id == mv_selection)
  71                 return '1 1 0';
  72         else
  73                 return '1 1 1';
  74 }
  75
  76 void GameTypeVote_DrawGameTypeItem(vector pos, float maxh, float tsize, string gtype, string pic, float _count, int id)
  77 {
  78         // Find the correct alpha
  79         float alpha;
  80         if(!(mv_flags_start[id] & GTV_AVAILABLE))
  81                 alpha = 0.2; // The gametype isn't supported by the map
  82         else if ( !(mv_flags[id] & GTV_AVAILABLE) && mv_top2_alpha)
  83                 alpha = mv_top2_alpha; // Fade away if not one of the top 2 choice
  84         else
  85                 alpha = 1; // Normal, full alpha
  86
  87         // Bounding box details
  88         float rect_margin = hud_fontsize.y / 2;
  89
  90         pos.x += rect_margin + autocvar_scoreboard_border_thickness;
  91         pos.y += rect_margin + autocvar_scoreboard_border_thickness;
  92         maxh -= 2 * (rect_margin + autocvar_scoreboard_border_thickness);
  93         tsize -= 2 * (rect_margin + autocvar_scoreboard_border_thickness);
  94
  95         vector rect_pos = pos - '0.5 0.5 0' * rect_margin;
  96         vector rect_size = '1 1 0';
  97         rect_size.x = tsize + rect_margin;
  98         rect_size.y = maxh + rect_margin;
  99
 100         // Highlight selected item
 101         if(id == mv_selection && (mv_flags[id] & GTV_AVAILABLE))
 102         {
 103                 drawfill(rect_pos, rect_size, '1 1 1', 0.1, DRAWFLAG_NORMAL);
 104         }
 105
 106         // Highlight current vote
 107         vector rgb = MapVote_RGB(id);
 108         if(id == mv_ownvote)
 109         {
 110                 drawfill(rect_pos, rect_size, rgb, 0.1*alpha, DRAWFLAG_NORMAL);
 111                 drawborderlines(autocvar_scoreboard_border_thickness, rect_pos, rect_size, rgb, alpha, DRAWFLAG_NORMAL);
 112         }
 113
 114         vector offset = pos;
 115
 116         float title_gap = gtv_text_size.y * 1.4; // distance between the title and the description
 117         pos.y += title_gap;
 118         maxh -= title_gap;
 119
 120         // Evaluate the image size
 121         vector image_size = '1 1 0' * gtv_text_size.x * 3;
 122         if ( maxh < image_size.y )
 123                 image_size = '1 1 0' * maxh;
 124         image_size *= 0.8;
 125         float desc_padding = gtv_text_size.x * 0.6;
 126         pos.x += image_size.x + desc_padding;
 127         tsize -= image_size.x + desc_padding;
 128
 129         // Split the description into lines
 130         entity title;
 131         title = spawn();
 132         title.message = MapVote_FormatMapItem(id, mv_pk3[id], _count, tsize, gtv_text_size);
 133
 134         string thelabel = mv_desc[id], ts;
 135         entity last = title;
 136         entity next = world;
 137         float nlines = 0;
 138         if( thelabel != "")
 139         {
 140                 float i,n = tokenizebyseparator(thelabel, "\n");
 141                 for(i = 0; i < n && maxh > (nlines+1)*gtv_text_size_small.y; ++i)
 142                 {
 143                         getWrappedLine_remaining = argv(i);
 144                         while(getWrappedLine_remaining && maxh > (nlines+1)*gtv_text_size_small.y)
 145                         {
 146                                 ts = getWrappedLine(tsize, gtv_text_size_small, stringwidth_colors);
 147                                 if (ts != "")
 148                                 {
 149                                         next = spawn();
 150                                         next.message = ts;
 151                                         next.origin = pos-offset;
 152                                         last.chain = next;
 153                                         last = next;
 154                                         pos.y += gtv_text_size_small.y;
 155                                         nlines++;
 156                                 }
 157                         }
 158                 }
 159         }
 160
 161         // Center the contents in the bounding box
 162         maxh -= max(nlines*gtv_text_size_small.y,image_size.y);
 163         if ( maxh > 0 )
 164                 offset.y += maxh/2;
 165
 166         // Draw the title
 167         drawstring(offset, title.message, gtv_text_size, rgb, alpha, DRAWFLAG_NORMAL);
 168
 169         // Draw the icon
 170         if(pic != "")
 171                 drawpic('0 1 0'*title_gap+'0.5 0 0'*desc_padding+offset, pic, image_size, '1 1 1', alpha, DRAWFLAG_NORMAL);
 172
 173         // Draw the description
 174         for ( last = title.chain; last ; )
 175         {
 176                 drawstring(last.origin+offset, last.message, gtv_text_size_small, '1 1 1', alpha, DRAWFLAG_NORMAL);
 177                 next = last;
 178                 last = last.chain;
 179                 remove(next);
 180         }
 181
 182         // Cleanup
 183         remove(title);
 184 }
 185
 186 void MapVote_DrawMapItem(vector pos, float isize, float tsize, string map, string pic, float _count, int id)
 187 {
 188         vector img_size = '0 0 0';
 189         string label;
 190         float text_size;
 191
 192         float rect_margin = hud_fontsize.y / 2;
 193
 194         pos.x += rect_margin + autocvar_scoreboard_border_thickness;
 195         pos.y += rect_margin + autocvar_scoreboard_border_thickness;
 196         isize -= 2 * (rect_margin + autocvar_scoreboard_border_thickness);
 197         tsize -= 2 * (rect_margin + autocvar_scoreboard_border_thickness);
 198
 199         vector rect_pos = pos - '0.5 0.5 0' * rect_margin;
 200         vector rect_size = '1 1 0';
 201         rect_size.x = tsize + rect_margin;
 202         rect_size.y = isize + rect_margin;
 203
 204         float img_ar = 4/3;
 205         img_size.x = min(tsize, isize * img_ar);
 206         img_size.y = img_size.x / img_ar;
 207         img_size.y -= hud_fontsize.y;
 208         img_size.x = img_size.y * img_ar;
 209
 210         pos.y += (isize - img_size.y - hud_fontsize.y) / 2;
 211
 212         label = MapVote_FormatMapItem(id, map, _count, tsize, hud_fontsize);
 213
 214         text_size = stringwidth(label, false, hud_fontsize);
 215
 216         float save_rect_sizex = rect_size.x;
 217         rect_size.x = max(img_size.x, text_size) + rect_margin;
 218         rect_pos.x += (save_rect_sizex - rect_size.x) / 2;
 219
 220         vector text_pos = '0 0 0';
 221         text_pos.x = pos.x + (tsize - text_size) / 2;
 222         text_pos.y = pos.y + img_size.y;
 223
 224         pos.x += (tsize - img_size.x) / 2;
 225
 226         float theAlpha;
 227         if (!(mv_flags[id] & GTV_AVAILABLE) && mv_top2_alpha)
 228                 theAlpha = mv_top2_alpha;
 229         else
 230                 theAlpha = 1;
 231
 232         // Highlight selected item
 233         if(id == mv_selection && (mv_flags[id] & GTV_AVAILABLE))
 234                 drawfill(rect_pos, rect_size, '1 1 1', 0.1, DRAWFLAG_NORMAL);
 235
 236         // Highlight current vote
 237         vector rgb = MapVote_RGB(id);
 238         if(id == mv_ownvote)
 239         {
 240                 drawfill(rect_pos, rect_size, rgb, 0.1*theAlpha, DRAWFLAG_NORMAL);
 241                 drawborderlines(autocvar_scoreboard_border_thickness, rect_pos, rect_size, rgb, theAlpha, DRAWFLAG_NORMAL);
 242         }
 243
 244         drawstring(text_pos, label, hud_fontsize, rgb, theAlpha, DRAWFLAG_NORMAL);
 245
 246         if(pic == "")
 247         {
 248                 drawfill(pos, img_size, '.5 .5 .5', .7 * theAlpha, DRAWFLAG_NORMAL);
 249         }
 250         else
 251         {
 252                 if(drawgetimagesize(pic) == '0 0 0')
 253                         drawpic(pos, draw_UseSkinFor("nopreview_map"), img_size, '1 1 1', theAlpha, DRAWFLAG_NORMAL);
 254                 else
 255                         drawpic(pos, pic, img_size, '1 1 1', theAlpha, DRAWFLAG_NORMAL);
 256         }
 257 }
 258
 259 void MapVote_DrawAbstain(vector pos, float isize, float tsize, float _count, int id)
 260 {
 261         vector rgb;
 262         float text_size;
 263         string label;
 264
 265         rgb = MapVote_RGB(id);
 266
 267         label = MapVote_FormatMapItem(id, _("Don't care"), _count, tsize, hud_fontsize);
 268
 269         text_size = stringwidth(label, false, hud_fontsize);
 270
 271         pos.x -= text_size*0.5;
 272         drawstring(pos, label, hud_fontsize, rgb, 1, DRAWFLAG_NORMAL);
 273 }
 274
 275 vector MapVote_GridVec(vector gridspec, int i, int m)
 276 {
 277         int r = i % m;
 278         return
 279                 '1 0 0' * (gridspec.x * r)
 280                 +
 281                 '0 1 0' * (gridspec.y * (i - r) / m);
 282 }
 283
 284 float MapVote_Selection(vector topleft, vector cellsize, float rows, float columns)
 285 {
 286
 287         float c, r;
 288
 289         mv_mouse_selection = -1;
 290
 291         for (r = 0; r < rows; ++r)
 292                 for (c = 0; c < columns; ++c)
 293                 {
 294                         if (mv_mousepos.x >= topleft.x + cellsize.x *  c &&
 295                                 mv_mousepos.x <= topleft.x + cellsize.x * (c + 1) &&
 296                                 mv_mousepos.y >= topleft.y + cellsize.y *  r &&
 297                                 mv_mousepos.y <= topleft.y + cellsize.y * (r + 1))
 298                         {
 299                                 mv_mouse_selection = r * columns + c;
 300                                 break;
 301                         }
 302                 }
 303
 304         if (mv_mouse_selection >= mv_num_maps)
 305                 mv_mouse_selection = -1;
 306
 307         if (mv_abstain && mv_mouse_selection < 0)
 308                 mv_mouse_selection = mv_num_maps;
 309
 310         if ( mv_selection_keyboard )
 311                 return mv_selection;
 312
 313         return mv_mouse_selection;
 314 }
 315
 316 vector HUD_GetTableSize_BestItemAR(int item_count, vector psize, float item_aspect);
 317 void MapVote_Draw()
 318 {
 319         string map;
 320         int i;
 321         float tmp;
 322         vector pos;
 323         float center;
 324         float rows;
 325         vector dist = '0 0 0';
 326
 327         //if(intermission != 2) return;
 328         if(!mv_active)
 329                 return;
 330
 331         if (!autocvar_hud_cursormode)
 332         {
 333                 vector mpos = mv_mousepos + getmousepos();
 334                 mpos.x = bound(0, mpos.x, vid_conwidth);
 335                 mpos.y = bound(0, mpos.y, vid_conheight);
 336
 337                 if ( mpos.x != mv_mousepos.x || mpos.y != mv_mousepos.y )
 338                         mv_selection_keyboard = 0;
 339                 mv_mousepos = mpos;
 340
 341         }
 342
 343         center = (vid_conwidth - 1)/2;
 344         xmin = vid_conwidth * 0.08;
 345         xmax = vid_conwidth - xmin;
 346         ymin = 20;
 347         ymax = vid_conheight - ymin;
 348
 349         if(chat_posy + chat_sizey / 2 < vid_conheight / 2)
 350                 ymin += chat_sizey;
 351         else
 352                 ymax -= chat_sizey;
 353
 354         hud_fontsize = HUD_GetFontsize("hud_fontsize");
 355
 356         pos.y = ymin;
 357         pos.z = 0;
 358
 359         draw_beginBoldFont();
 360
 361         map = ((gametypevote) ? _("Decide the gametype") : _("Vote for a map"));
 362         pos.x = center - stringwidth(map, false, hud_fontsize * 2) * 0.5;
 363         drawstring(pos, map, hud_fontsize * 2, '1 1 1', 1, DRAWFLAG_NORMAL);
 364         pos.y += hud_fontsize.y * 2;
 365
 366         if( mapvote_chosenmap != "" )
 367         {
 368                 pos.y += hud_fontsize.y * 0.25;
 369                 pos.x = center - stringwidth(mapvote_chosenmap, false, hud_fontsize * 1.5) * 0.5;
 370                 drawstring(pos, mapvote_chosenmap, hud_fontsize * 1.5, '1 1 1', 1, DRAWFLAG_NORMAL);
 371                 pos.y += hud_fontsize.y * 1.5;
 372                 pos.y += hud_fontsize.y * 0.5;
 373         }
 374         else
 375                 pos.y += hud_fontsize.y * 0.5;
 376
 377         draw_endBoldFont();
 378
 379         i = ceil(max(0, mv_timeout - time));
 380         map = sprintf(_("%d seconds left"), i);
 381         pos.x = center - stringwidth(map, false, hud_fontsize * 1.5) * 0.5;
 382         drawstring(pos, map, hud_fontsize * 1.5, '0 1 0', 1, DRAWFLAG_NORMAL);
 383         pos.y += hud_fontsize.y * 1.5;
 384         pos.y += hud_fontsize.y * 0.5;
 385
 386         HUD_Panel_UpdateCvars();
 387
 388         // base for multi-column stuff...
 389         pos.y += hud_fontsize.y;
 390         pos.x = xmin;
 391         ymin = pos.y;
 392         float abstain_spacing = panel_bg_border + hud_fontsize.y;
 393         if(mv_abstain)
 394         {
 395                 mv_num_maps -= 1;
 396                 ymax -= abstain_spacing;
 397         }
 398
 399         // higher than the image itself ratio for mapvote items to reserve space for long map names
 400         int item_aspect = (gametypevote) ? 3/1 : 5/3;
 401         vector table_size = HUD_GetTableSize_BestItemAR(mv_num_maps, eX * (xmax - xmin) + eY * (ymax - ymin), item_aspect);
 402         mv_columns = table_size.x;
 403         rows = table_size.y;
 404
 405         dist.x = (xmax - xmin) / mv_columns;
 406         dist.y = (ymax - pos.y) / rows;
 407
 408         // reduce size of too wide items
 409         tmp = vid_conwidth / 3; // max width
 410         if(dist.x > tmp)
 411         {
 412                 dist.x = tmp;
 413                 dist.y = min(dist.y, dist.x / item_aspect);
 414         }
 415         tmp = vid_conheight / 3; // max height
 416         if(dist.y > tmp)
 417         {
 418                 dist.y = tmp;
 419                 dist.x = min(dist.x, dist.y * item_aspect);
 420         }
 421
 422         // reduce size to fix aspect ratio
 423         if(dist.x / dist.y > item_aspect)
 424                 dist.x = dist.y * item_aspect;
 425         else
 426                 dist.y = dist.x / item_aspect;
 427
 428         // adjust table pos and size according to the new size
 429         float offset;
 430         offset = ((xmax - pos.x) - dist.x * mv_columns) / 2;
 431         xmin = pos.x += offset;
 432         xmax -= offset;
 433         offset = ((ymax - pos.y) - dist.y * rows) / 2;
 434         ymax -= 2 * offset;
 435
 436         // override panel_pos and panel_size
 437         panel_pos.x = pos.x;
 438         panel_pos.y = pos.y;
 439         panel_size.x = xmax - xmin;
 440         panel_size.y = ymax - ymin;
 441         HUD_Panel_DrawBg(1);
 442
 443         if(panel_bg_padding)
 444         {
 445                 // FIXME item AR gets slightly changed here...
 446                 // it's rather hard to avoid it at this point
 447                 dist.x -= 2 * panel_bg_padding / mv_columns;
 448                 dist.y -= 2 * panel_bg_padding / rows;
 449                 xmin = pos.x += panel_bg_padding;
 450                 ymin = pos.y += panel_bg_padding;
 451                 xmax -= 2 * panel_bg_padding;
 452                 ymax -= 2 * panel_bg_padding;
 453         }
 454
 455         mv_selection = MapVote_Selection(pos, dist, rows, mv_columns);
 456
 457         if (mv_top2_time)
 458                 mv_top2_alpha = max(0.2, 1 - (time - mv_top2_time)*(time - mv_top2_time));
 459
 460         void (vector, float, float, string, string, float, float) DrawItem;
 461
 462         if(gametypevote)
 463                 DrawItem = GameTypeVote_DrawGameTypeItem;
 464         else
 465                 DrawItem = MapVote_DrawMapItem;
 466
 467         for(i = 0; i < mv_num_maps; ++i)
 468         {
 469                 tmp = mv_votes[i]; // FTEQCC bug: too many array accesses in the function call screw it up
 470                 map = mv_maps[i];
 471                 if(mv_preview[i])
 472                         DrawItem(pos + MapVote_GridVec(dist, i, mv_columns), dist.y, dist.x, map, mv_pics[i], tmp, i);
 473                 else
 474                         DrawItem(pos + MapVote_GridVec(dist, i, mv_columns), dist.y, dist.x, map, "", tmp, i);
 475         }
 476
 477         if(mv_abstain)
 478                 ++mv_num_maps;
 479
 480         if(mv_abstain && i < mv_num_maps) {
 481                 tmp = mv_votes[i];
 482                 pos.y = ymax + abstain_spacing;
 483                 pos.x = (xmax+xmin)*0.5;
 484                 MapVote_DrawAbstain(pos, dist.x, xmax - xmin, tmp, i);
 485         }
 486
 487         drawpic(mv_mousepos, strcat("gfx/menu/", autocvar_menu_skin, "/cursor.tga"), '32 32 0', '1 1 1', 1 - autocvar__menu_alpha, DRAWFLAG_NORMAL);
 488 }
 489
 490 void Cmd_MapVote_MapDownload(float argc)
 491 {
 492         entity pak;
 493
 494         if(argc != 2 || !mv_pk3list)
 495         {
 496                 LOG_INFO(_("mv_mapdownload: ^3You're not supposed to use this command on your own!\n"));
 497                 return;
 498         }
 499
 500         int id = stof(argv(1));
 501         for(pak = mv_pk3list; pak; pak = pak.chain)
 502                 if(pak.sv_entnum == id)
 503                         break;
 504
 505         if(!pak || pak.sv_entnum != id) {
 506                 LOG_INFO(_("^1Error:^7 Couldn't find pak index.\n"));
 507                 return;
 508         }
 509
 510         if(PreviewExists(pak.message))
 511         {
 512                 mv_preview[id] = true;
 513                 return;
 514         } else {
 515                 LOG_INFO(_("Requesting preview...\n"));
 516                 localcmd(strcat("\ncmd mv_getpicture ", ftos(id), "\n"));
 517         }
 518 }
 519
 520 void MapVote_CheckPK3(string pic, string pk3, int id)
 521 {
 522         entity pak;
 523         pak = spawn();
 524         pak.netname = pk3;
 525         pak.message = pic;
 526         pak.sv_entnum = id;
 527
 528         pak.chain = mv_pk3list;
 529         mv_pk3list = pak;
 530
 531         if(pk3 != "")
 532         {
 533                 localcmd(strcat("\ncurl --pak ", pk3, "; wait; cl_cmd mv_download ", ftos(id), "\n"));
 534         }
 535         else
 536         {
 537                 Cmd_MapVote_MapDownload(tokenize_console(strcat("mv_download ", ftos(id))));
 538         }
 539 }
 540
 541 void MapVote_CheckPic(string pic, string pk3, int id)
 542 {
 543         // never try to retrieve a pic for the "don't care" 'map'
 544         if(mv_abstain && id == mv_num_maps - 1)
 545                 return;
 546
 547         if(PreviewExists(pic))
 548         {
 549                 mv_preview[id] = true;
 550                 return;
 551         }
 552         MapVote_CheckPK3(pic, pk3, id);
 553 }
 554
 555 void MapVote_ReadMask()
 556 {
 557         int i;
 558         if ( mv_num_maps < 24 )
 559         {
 560                 int mask, power;
 561                 if(mv_num_maps < 8)
 562                         mask = ReadByte();
 563                 else if(mv_num_maps < 16)
 564                         mask = ReadShort();
 565                 else
 566                         mask = ReadLong();
 567
 568                 for(i = 0, power = 1; i < mv_num_maps; ++i, power *= 2)
 569                 {
 570                         if ( mask & power )
 571                                 mv_flags[i] |= GTV_AVAILABLE;
 572                         else
 573                                 mv_flags[i] &= ~GTV_AVAILABLE;
 574                 }
 575         }
 576         else
 577         {
 578                 for(i = 0; i < mv_num_maps; ++i )
 579                         mv_flags[i] = ReadByte();
 580         }
 581 }
 582
 583 void MapVote_ReadOption(int i)
 584 {
 585         string map = strzone(ReadString());
 586         string pk3 = strzone(ReadString());
 587         int j = bound(0, ReadByte(), n_ssdirs - 1);
 588
 589         mv_maps[i] = map;
 590         mv_pk3[i] = pk3;
 591         mv_flags[i] = GTV_AVAILABLE;
 592
 593         string pic = strzone(strcat(ssdirs[j], "/", map));
 594         mv_pics[i] = pic;
 595         mv_preview[i] = false;
 596         MapVote_CheckPic(pic, pk3, i);
 597 }
 598
 599 void GameTypeVote_ReadOption(int i)
 600 {
 601         string gt = strzone(ReadString());
 602
 603         mv_maps[i] = gt;
 604         mv_flags[i] = ReadByte();
 605
 606         string mv_picpath = sprintf("gfx/menu/%s/gametype_%s", autocvar_menu_skin, gt);
 607         if(precache_pic(mv_picpath) == "")
 608                 mv_picpath = strcat("gfx/menu/default/gametype_", gt);
 609         string pic = strzone(mv_picpath);
 610         mv_pics[i] = pic;
 611         mv_preview[i] = PreviewExists(pic);
 612
 613         if ( mv_flags[i] & GTV_CUSTOM )
 614         {
 615                 string name = ReadString();
 616                 if ( strlen(name) < 1 )
 617                         name = gt;
 618                 mv_pk3[i] = strzone(name);
 619                 mv_desc[i] = strzone(ReadString());
 620         }
 621         else
 622         {
 623                 int type = MapInfo_Type_FromString(gt);
 624                 mv_pk3[i] = strzone(MapInfo_Type_ToText(type));
 625                 mv_desc[i] = MapInfo_Type_Description(type);
 626         }
 627 }
 628
 629 void MapVote_Init()
 630 {
 631         mv_active = 1;
 632         if(autocvar_hud_cursormode) { setcursormode(1); }
 633         else { mv_mousepos = '0.5 0 0' * vid_conwidth + '0 0.5 0' * vid_conheight; }
 634         mv_selection = -1;
 635         mv_selection_keyboard = 0;
 636
 637         string s;
 638         for(n_ssdirs = 0; ; ++n_ssdirs)
 639         {
 640                 s = ReadString();
 641                 if(s == "")
 642                         break;
 643                 if(n_ssdirs < NUM_SSDIRS)
 644                         ssdirs[n_ssdirs] = s;
 645         }
 646         n_ssdirs = min(n_ssdirs, NUM_SSDIRS);
 647
 648         mv_num_maps = min(MAPVOTE_COUNT, ReadByte());
 649         mv_abstain = ReadByte();
 650         if(mv_abstain)
 651                 mv_abstain = 1; // must be 1 for bool-true, makes stuff easier
 652         mv_detail = ReadByte();
 653
 654         mv_ownvote = -1;
 655         mv_timeout = ReadCoord();
 656
 657         gametypevote = ReadByte();
 658
 659         if(gametypevote)
 660         {
 661                 mapvote_chosenmap = strzone(ReadString());
 662                 if ( gametypevote == 2 )
 663                         gametypevote = 0;
 664
 665                 gtv_text_size = hud_fontsize*1.4;
 666                 gtv_text_size_small = hud_fontsize*1.1;
 667         }
 668
 669         MapVote_ReadMask();
 670         int i;
 671         for(i = 0; i < mv_num_maps; ++i )
 672                 mv_flags_start[i] = mv_flags[i];
 673
 674         // Assume mv_pk3list is world, there should only be 1 mapvote per round
 675         mv_pk3list = world; // I'm still paranoid!
 676
 677         for(i = 0; i < mv_num_maps; ++i)
 678         {
 679                 mv_votes[i] = 0;
 680
 681                 if ( gametypevote )
 682                         GameTypeVote_ReadOption(i);
 683                 else
 684                         MapVote_ReadOption(i);
 685         }
 686
 687         for(i = 0; i < n_ssdirs; ++i)
 688                 ssdirs[n_ssdirs] = string_null;
 689         n_ssdirs = 0;
 690 }
 691
 692 void MapVote_SendChoice(float index)
 693 {
 694         localcmd(strcat("\nimpulse ", ftos(index+1), "\n"));
 695 }
 696
 697 int MapVote_MoveLeft(int pos)
 698 {
 699         int imp;
 700         if ( pos < 0 )
 701                 imp = mv_num_maps - 1;
 702         else
 703                 imp = pos < 1 ? mv_num_maps - 1 : pos - 1;
 704         if ( !(mv_flags[imp] & GTV_AVAILABLE) && imp != mv_ownvote )
 705                 imp = MapVote_MoveLeft(imp);
 706         return imp;
 707 }
 708 int MapVote_MoveRight(int pos)
 709 {
 710         int imp;
 711         if ( pos < 0 )
 712                 imp = 0;
 713         else
 714                 imp = pos >= mv_num_maps - 1 ? 0 : pos + 1;
 715         if ( !(mv_flags[imp] & GTV_AVAILABLE) && imp != mv_ownvote )
 716                 imp = MapVote_MoveRight(imp);
 717         return imp;
 718 }
 719 int MapVote_MoveUp(int pos)
 720 {
 721         int imp;
 722         if ( pos < 0 )
 723                 imp = mv_num_maps - 1;
 724         else
 725         {
 726                 imp = pos - mv_columns;
 727                 if ( imp < 0 )
 728                 {
 729                         imp = floor(mv_num_maps/mv_columns)*mv_columns + pos % mv_columns;
 730                         if ( imp >= mv_num_maps )
 731                                 imp -= mv_columns;
 732                 }
 733         }
 734         if ( !(mv_flags[imp] & GTV_AVAILABLE) && imp != mv_ownvote )
 735                 imp = MapVote_MoveUp(imp);
 736         return imp;
 737 }
 738 int MapVote_MoveDown(int pos)
 739 {
 740         int imp;
 741         if ( pos < 0 )
 742                 imp = 0;
 743         else
 744         {
 745                 imp = pos + mv_columns;
 746                 if ( imp >= mv_num_maps )
 747                         imp = imp % mv_columns;
 748         }
 749         if ( !(mv_flags[imp] & GTV_AVAILABLE) && imp != mv_ownvote )
 750                 imp = MapVote_MoveDown(imp);
 751         return imp;
 752 }
 753
 754 float MapVote_InputEvent(float bInputType, float nPrimary, float nSecondary)
 755 {
 756         float imp;
 757
 758         if (!mv_active)
 759                 return false;
 760
 761         if(bInputType == 3)
 762         {
 763                 mv_mousepos.x = nPrimary;
 764                 mv_mousepos.y = nSecondary;
 765                 mv_selection_keyboard = 0;
 766                 return true;
 767         }
 768
 769         if (bInputType != 0)
 770                 return false;
 771
 772         if ('0' <= nPrimary && nPrimary <= '9')
 773         {
 774                 imp = nPrimary - '0';
 775                 if (imp == 0) imp = 10;
 776                 localcmd(strcat("\nimpulse ", ftos(imp), "\n"));
 777                 return true;
 778         }
 779         switch(nPrimary)
 780         {
 781                 case K_KP_1: localcmd("\nimpulse 1\n"); return true;
 782                 case K_KP_2: localcmd("\nimpulse 2\n"); return true;
 783                 case K_KP_3: localcmd("\nimpulse 3\n"); return true;
 784                 case K_KP_4: localcmd("\nimpulse 4\n"); return true;
 785                 case K_KP_5: localcmd("\nimpulse 5\n"); return true;
 786                 case K_KP_6: localcmd("\nimpulse 6\n"); return true;
 787                 case K_KP_7: localcmd("\nimpulse 7\n"); return true;
 788                 case K_KP_8: localcmd("\nimpulse 8\n"); return true;
 789                 case K_KP_9: localcmd("\nimpulse 9\n"); return true;
 790                 case K_KP_0: localcmd("\nimpulse 10\n"); return true;
 791
 792                 case K_RIGHTARROW:
 793                         mv_selection_keyboard = 1;
 794                         mv_selection = MapVote_MoveRight(mv_selection);
 795                         return true;
 796                 case K_LEFTARROW:
 797                         mv_selection_keyboard = 1;
 798                         mv_selection = MapVote_MoveLeft(mv_selection);
 799                         return true;
 800                 case K_DOWNARROW:
 801                         mv_selection_keyboard = 1;
 802                         mv_selection = MapVote_MoveDown(mv_selection);
 803                         return true;
 804                 case K_UPARROW:
 805                         mv_selection_keyboard = 1;
 806                         mv_selection = MapVote_MoveUp(mv_selection);
 807                         return true;
 808                 case K_KP_ENTER:
 809                 case K_ENTER:
 810                 case K_SPACE:
 811                         if ( mv_selection_keyboard )
 812                                 MapVote_SendChoice(mv_selection);
 813                         return true;
 814         }
 815
 816         if (nPrimary == K_MOUSE1)
 817         {
 818                 mv_selection_keyboard = 0;
 819                 mv_selection = mv_mouse_selection;
 820                 if (mv_selection >= 0)
 821                 {
 822                         imp = min(mv_selection + 1, mv_num_maps);
 823                         localcmd(strcat("\nimpulse ", ftos(imp), "\n"));
 824                         return true;
 825                 }
 826         }
 827
 828         return false;
 829 }
 830
 831 void MapVote_UpdateMask()
 832 {
 833         MapVote_ReadMask();
 834         mv_top2_time = time;
 835 }
 836
 837 void MapVote_UpdateVotes()
 838 {
 839         int i;
 840         for(i = 0; i < mv_num_maps; ++i)
 841         {
 842                 if(mv_flags[i] & GTV_AVAILABLE)
 843                 {
 844                         if(mv_detail)
 845                                 mv_votes[i] = ReadByte();
 846                         else
 847                                 mv_votes[i] = 0;
 848                 }
 849                 else
 850                         mv_votes[i] = -1;
 851         }
 852
 853         mv_ownvote = ReadByte()-1;
 854 }
 855
 856 void Ent_MapVote()
 857 {
 858         int sf = ReadByte();
 859
 860         if(sf & 1)
 861                 MapVote_Init();
 862
 863         if(sf & 2)
 864                 MapVote_UpdateMask();
 865
 866         if(sf & 4)
 867                 MapVote_UpdateVotes();
 868 }
 869
 870 void Net_MapVote_Picture()
 871 {
 872         int type = ReadByte();
 873         mv_preview[type] = true;
 874         mv_pics[type] = strzone(ReadPicture());
 875 }