qcsrc/client/mapvoting.qc

   1 #include "mapvoting.qh"
   2 #include "_all.qh"
   3
   4 #include "hud.qh"
   5 #include "scoreboard.qh"
   6
   7 #include "../common/mapinfo.qh"
   8 #include "../common/util.qh"
   9
  10 #include "../dpdefs/keycodes.qh"
  11
  12
  13 int mv_num_maps;
  14
  15 float mv_active;
  16 string mv_maps[MAPVOTE_COUNT];
  17 string mv_pics[MAPVOTE_COUNT];
  18 string mv_pk3[MAPVOTE_COUNT]; // map pk3 name or gametype human readable name
  19 string mv_desc[MAPVOTE_COUNT];
  20 float mv_preview[MAPVOTE_COUNT];
  21 float mv_votes[MAPVOTE_COUNT];
  22 float mv_flags[MAPVOTE_COUNT];
  23 float mv_flags_start[MAPVOTE_COUNT];
  24 entity mv_pk3list;
  25 float mv_abstain;
  26 float mv_ownvote;
  27 float mv_detail;
  28 float mv_timeout;
  29 float mv_top2_time;
  30 float mv_top2_alpha;
  31
  32 vector mv_mousepos;
  33 int mv_selection;
  34 int mv_columns;
  35 int mv_mouse_selection;
  36 int mv_selection_keyboard;
  37
  38 float gametypevote;
  39 string mapvote_chosenmap;
  40 vector gtv_text_size;
  41 vector gtv_text_size_small;
  42
  43 const int NUM_SSDIRS = 4;
  44 string ssdirs[NUM_SSDIRS];
  45 int n_ssdirs;
  46
  47 string MapVote_FormatMapItem(int id, string map, float _count, float maxwidth, vector fontsize)
  48 {
  49         string pre, post;
  50         pre = sprintf("%d. ", id+1);
  51         if(mv_detail)
  52         {
  53                 if(_count == 1)
  54                         post = _(" (1 vote)");
  55                 else if(_count >= 0 && (mv_flags[id] & GTV_AVAILABLE))
  56                         post = sprintf(_(" (%d votes)"), _count);
  57                 else
  58                         post = "";
  59         }
  60         else
  61                 post = "";
  62         maxwidth -= stringwidth(pre, false, fontsize) + stringwidth(post, false, fontsize);
  63         map = textShortenToWidth(map, maxwidth, fontsize, stringwidth_nocolors);
  64         return strcat(pre, map, post);
  65 }
  66
  67 vector MapVote_RGB(int id)
  68 {
  69         if(!(mv_flags[id] & GTV_AVAILABLE))
  70                 return '1 1 1';
  71         if(id == mv_ownvote)
  72                 return '0 1 0';
  73         else if (id == mv_selection)
  74                 return '1 1 0';
  75         else
  76                 return '1 1 1';
  77 }
  78
  79 void GameTypeVote_DrawGameTypeItem(vector pos, float maxh, float tsize, string gtype, string pic, float _count, int id)
  80 {
  81         // Find the correct alpha
  82         float alpha;
  83         if(!(mv_flags_start[id] & GTV_AVAILABLE))
  84                 alpha = 0.2; // The gametype isn't supported by the map
  85         else if ( !(mv_flags[id] & GTV_AVAILABLE) && mv_top2_alpha)
  86                 alpha = mv_top2_alpha; // Fade away if not one of the top 2 choice
  87         else
  88                 alpha = 1; // Normal, full alpha
  89
  90         // Bounding box details
  91         float rect_margin = hud_fontsize.y / 2;
  92
  93         pos.x += rect_margin + autocvar_scoreboard_border_thickness;
  94         pos.y += rect_margin + autocvar_scoreboard_border_thickness;
  95         maxh -= 2 * (rect_margin + autocvar_scoreboard_border_thickness);
  96         tsize -= 2 * (rect_margin + autocvar_scoreboard_border_thickness);
  97
  98         vector rect_pos = pos - '0.5 0.5 0' * rect_margin;
  99         vector rect_size = '1 1 0';
 100         rect_size.x = tsize + rect_margin;
 101         rect_size.y = maxh + rect_margin;
 102
 103         // Highlight selected item
 104         if(id == mv_selection && (mv_flags[id] & GTV_AVAILABLE))
 105         {
 106                 drawfill(rect_pos, rect_size, '1 1 1', 0.1, DRAWFLAG_NORMAL);
 107         }
 108
 109         // Highlight current vote
 110         vector rgb = MapVote_RGB(id);
 111         if(id == mv_ownvote)
 112         {
 113                 drawfill(rect_pos, rect_size, rgb, 0.1*alpha, DRAWFLAG_NORMAL);
 114                 drawborderlines(autocvar_scoreboard_border_thickness, rect_pos, rect_size, rgb, alpha, DRAWFLAG_NORMAL);
 115         }
 116
 117         vector offset = pos;
 118
 119         float title_gap = gtv_text_size.y * 1.4; // distance between the title and the description
 120         pos.y += title_gap;
 121         maxh -= title_gap;
 122
 123         // Evaluate the image size
 124         vector image_size = '1 1 0' * gtv_text_size.x * 3;
 125         if ( maxh < image_size.y )
 126                 image_size = '1 1 0' * maxh;
 127         image_size *= 0.8;
 128         float desc_padding = gtv_text_size.x * 0.6;
 129         pos.x += image_size.x + desc_padding;
 130         tsize -= image_size.x + desc_padding;
 131
 132         // Split the description into lines
 133         entity title;
 134         title = spawn();
 135         title.message = MapVote_FormatMapItem(id, mv_pk3[id], _count, tsize, gtv_text_size);
 136
 137         string thelabel = mv_desc[id], ts;
 138         entity last = title;
 139         entity next = world;
 140         float nlines = 0;
 141         if( thelabel != "")
 142         {
 143                 float i,n = tokenizebyseparator(thelabel, "\n");
 144                 for(i = 0; i < n && maxh > (nlines+1)*gtv_text_size_small.y; ++i)
 145                 {
 146                         getWrappedLine_remaining = argv(i);
 147                         while(getWrappedLine_remaining && maxh > (nlines+1)*gtv_text_size_small.y)
 148                         {
 149                                 ts = getWrappedLine(tsize, gtv_text_size_small, stringwidth_colors);
 150                                 if (ts != "")
 151                                 {
 152                                         next = spawn();
 153                                         next.message = ts;
 154                                         next.origin = pos-offset;
 155                                         last.chain = next;
 156                                         last = next;
 157                                         pos.y += gtv_text_size_small.y;
 158                                         nlines++;
 159                                 }
 160                         }
 161                 }
 162         }
 163
 164         // Center the contents in the bounding box
 165         maxh -= max(nlines*gtv_text_size_small.y,image_size.y);
 166         if ( maxh > 0 )
 167                 offset.y += maxh/2;
 168
 169         // Draw the title
 170         drawstring(offset, title.message, gtv_text_size, rgb, alpha, DRAWFLAG_NORMAL);
 171
 172         // Draw the icon
 173         if(pic != "")
 174                 drawpic('0 1 0'*title_gap+'0.5 0 0'*desc_padding+offset, pic, image_size, '1 1 1', alpha, DRAWFLAG_NORMAL);
 175
 176         // Draw the description
 177         for ( last = title.chain; last ; )
 178         {
 179                 drawstring(last.origin+offset, last.message, gtv_text_size_small, '1 1 1', alpha, DRAWFLAG_NORMAL);
 180                 next = last;
 181                 last = last.chain;
 182                 remove(next);
 183         }
 184
 185         // Cleanup
 186         remove(title);
 187 }
 188
 189 void MapVote_DrawMapItem(vector pos, float isize, float tsize, string map, string pic, float _count, int id)
 190 {
 191         vector img_size = '0 0 0';
 192         vector rgb;
 193         string label;
 194         float text_size;
 195
 196         rgb = MapVote_RGB(id);
 197
 198         float padding = hud_fontsize.y / 2;
 199
 200         pos.x += padding;
 201         pos.y += padding;
 202         isize -= 2 * padding;
 203         tsize -= 2 * padding;
 204
 205         float img_ar = 4/3;
 206         img_size.x = min(tsize, isize * img_ar);
 207         img_size.y = img_size.x / img_ar;
 208         img_size.y -= hud_fontsize.y - autocvar_scoreboard_border_thickness * 2;
 209         img_size.x = img_size.y * img_ar;
 210
 211         pos.y += (isize - img_size.y - hud_fontsize.y) / 2;
 212
 213         label = MapVote_FormatMapItem(id, map, _count, tsize, hud_fontsize);
 214
 215         text_size = stringwidth(label, false, hud_fontsize);
 216
 217         vector text_pos = '0 0 0';
 218         text_pos.x = pos.x + (tsize - text_size) / 2;
 219         text_pos.y = pos.y + img_size.y + autocvar_scoreboard_border_thickness;
 220
 221         pos.x += (tsize - img_size.x) / 2;
 222
 223         float theAlpha;
 224         if (!(mv_flags[id] & GTV_AVAILABLE) && mv_top2_alpha)
 225                 theAlpha = mv_top2_alpha;
 226         else
 227                 theAlpha = 1;
 228         drawstring(text_pos, label, hud_fontsize, rgb, theAlpha, DRAWFLAG_NORMAL);
 229
 230         if(pic == "")
 231         {
 232                 drawfill(pos, img_size, '.5 .5 .5', .7 * theAlpha, DRAWFLAG_NORMAL);
 233         }
 234         else
 235         {
 236                 if(drawgetimagesize(pic) == '0 0 0')
 237                         drawpic(pos, draw_UseSkinFor("nopreview_map"), img_size, '1 1 1', theAlpha, DRAWFLAG_NORMAL);
 238                 else
 239                         drawpic(pos, pic, img_size, '1 1 1', theAlpha, DRAWFLAG_NORMAL);
 240         }
 241
 242         if(id == mv_ownvote)
 243                 drawborderlines(autocvar_scoreboard_border_thickness, pos, img_size, rgb, theAlpha, DRAWFLAG_NORMAL);
 244         else
 245                 drawborderlines(autocvar_scoreboard_border_thickness, pos, img_size, '0 0 0', theAlpha, DRAWFLAG_NORMAL);
 246
 247         if(id == mv_selection && (mv_flags[id] & GTV_AVAILABLE))
 248                 drawfill(pos, img_size, '1 1 1', 0.1, DRAWFLAG_NORMAL);
 249 }
 250
 251 void MapVote_DrawAbstain(vector pos, float isize, float tsize, float _count, int id)
 252 {
 253         vector rgb;
 254         float text_size;
 255         string label;
 256
 257         rgb = MapVote_RGB(id);
 258
 259         label = MapVote_FormatMapItem(id, _("Don't care"), _count, tsize, hud_fontsize);
 260
 261         text_size = stringwidth(label, false, hud_fontsize);
 262
 263         pos.x -= text_size*0.5;
 264         drawstring(pos, label, hud_fontsize, rgb, 1, DRAWFLAG_NORMAL);
 265 }
 266
 267 vector MapVote_GridVec(vector gridspec, int i, int m)
 268 {
 269         int r = i % m;
 270         return
 271                 '1 0 0' * (gridspec.x * r)
 272                 +
 273                 '0 1 0' * (gridspec.y * (i - r) / m);
 274 }
 275
 276 float MapVote_Selection(vector topleft, vector cellsize, float rows, float columns)
 277 {
 278
 279         float c, r;
 280
 281         mv_mouse_selection = -1;
 282
 283         for (r = 0; r < rows; ++r)
 284                 for (c = 0; c < columns; ++c)
 285                 {
 286                         if (mv_mousepos.x >= topleft.x + cellsize.x *  c &&
 287                                 mv_mousepos.x <= topleft.x + cellsize.x * (c + 1) &&
 288                                 mv_mousepos.y >= topleft.y + cellsize.y *  r &&
 289                                 mv_mousepos.y <= topleft.y + cellsize.y * (r + 1))
 290                         {
 291                                 mv_mouse_selection = r * columns + c;
 292                                 break;
 293                         }
 294                 }
 295
 296         if (mv_mouse_selection >= mv_num_maps)
 297                 mv_mouse_selection = -1;
 298
 299         if (mv_abstain && mv_mouse_selection < 0)
 300                 mv_mouse_selection = mv_num_maps;
 301
 302         if ( mv_selection_keyboard )
 303                 return mv_selection;
 304
 305         return mv_mouse_selection;
 306 }
 307
 308 vector HUD_GetTableSize_BestItemAR(int item_count, vector psize, float item_aspect);
 309 void MapVote_Draw()
 310 {
 311         string map;
 312         int i;
 313         float tmp;
 314         vector pos;
 315         float center;
 316         float rows;
 317         vector dist = '0 0 0';
 318
 319         //if(intermission != 2) return;
 320         if(!mv_active)
 321                 return;
 322
 323         if (!autocvar_hud_cursormode)
 324         {
 325                 vector mpos = mv_mousepos + getmousepos();
 326                 mpos.x = bound(0, mpos.x, vid_conwidth);
 327                 mpos.y = bound(0, mpos.y, vid_conheight);
 328
 329                 if ( mpos.x != mv_mousepos.x || mpos.y != mv_mousepos.y )
 330                         mv_selection_keyboard = 0;
 331                 mv_mousepos = mpos;
 332
 333         }
 334
 335         center = (vid_conwidth - 1)/2;
 336         xmin = vid_conwidth*0.05; // 5% border must suffice
 337         xmax = vid_conwidth - xmin;
 338         ymin = 20;
 339         i = autocvar_con_chatpos; // *autocvar_con_chatsize;
 340         if(i < 0)
 341                 ymax = vid_conheight + (i - autocvar_con_chat) * autocvar_con_chatsize;
 342         if(i >= 0 || ymax < (vid_conheight*0.5))
 343                 ymax = vid_conheight - ymin;
 344
 345         hud_fontsize = HUD_GetFontsize("hud_fontsize");
 346
 347         pos.y = ymin;
 348         pos.z = 0;
 349
 350         draw_beginBoldFont();
 351
 352         map = ((gametypevote) ? _("Decide the gametype") : _("Vote for a map"));
 353         pos.x = center - stringwidth(map, false, hud_fontsize * 2) * 0.5;
 354         drawstring(pos, map, hud_fontsize * 2, '1 1 1', 1, DRAWFLAG_NORMAL);
 355         pos.y += hud_fontsize.y * 2;
 356
 357         if( mapvote_chosenmap != "" )
 358         {
 359                 pos.y += hud_fontsize.y * 0.25;
 360                 pos.x = center - stringwidth(mapvote_chosenmap, false, hud_fontsize * 1.5) * 0.5;
 361                 drawstring(pos, mapvote_chosenmap, hud_fontsize * 1.5, '1 1 1', 1, DRAWFLAG_NORMAL);
 362                 pos.y += hud_fontsize.y * 1.5;
 363                 pos.y += hud_fontsize.y * 0.5;
 364         }
 365         else
 366                 pos.y += hud_fontsize.y * 0.5;
 367
 368         draw_endBoldFont();
 369
 370         i = ceil(max(0, mv_timeout - time));
 371         map = sprintf(_("%d seconds left"), i);
 372         pos.x = center - stringwidth(map, false, hud_fontsize * 1.5) * 0.5;
 373         drawstring(pos, map, hud_fontsize * 1.5, '0 1 0', 1, DRAWFLAG_NORMAL);
 374         pos.y += hud_fontsize.y * 1.5;
 375         pos.y += hud_fontsize.y * 0.5;
 376
 377         // base for multi-column stuff...
 378         pos.y += hud_fontsize.y;
 379         pos.x = xmin;
 380         ymin = pos.y;
 381         if(mv_abstain)
 382                 mv_num_maps -= 1;
 383
 384         HUD_Panel_UpdateCvars();
 385
 386         // higher than the image itself ratio for mapvote items to reserve space for long map names
 387         int item_aspect = (gametypevote) ? 3/1 : 5/3;
 388         vector table_size = HUD_GetTableSize_BestItemAR(mv_num_maps, eX * (xmax - xmin) + eY * (ymax - ymin), item_aspect);
 389         mv_columns = table_size.x;
 390         rows = table_size.y;
 391
 392         dist.x = (xmax - xmin) / mv_columns;
 393         dist.y = (ymax - pos.y) / rows;
 394
 395         // reduce size of too wide items
 396         tmp = vid_conwidth / 3; // max width
 397         if(dist.x > tmp)
 398         {
 399                 dist.x = tmp;
 400                 dist.y = min(dist.y, dist.x / item_aspect);
 401         }
 402         tmp = vid_conheight / 3; // max height
 403         if(dist.y > tmp)
 404         {
 405                 dist.y = tmp;
 406                 dist.x = min(dist.x, dist.y * item_aspect);
 407         }
 408
 409         // reduce size to fix aspect ratio
 410         if(dist.x / dist.y > item_aspect)
 411                 dist.x = dist.y * item_aspect;
 412         else
 413                 dist.y = dist.x / item_aspect;
 414
 415         // adjust table pos and size according to the new size
 416         float offset;
 417         offset = ((xmax - pos.x) - dist.x * mv_columns) / 2;
 418         xmin = pos.x += offset;
 419         xmax -= offset;
 420         offset = ((ymax - pos.y) - dist.y * rows) / 2;
 421         ymax -= 2 * offset;
 422
 423         // override panel_pos and panel_size
 424         panel_pos.x = pos.x;
 425         panel_pos.y = pos.y;
 426         panel_size.x = xmax - xmin;
 427         panel_size.y = ymax - ymin;
 428         HUD_Panel_DrawBg(1);
 429
 430         if(panel_bg_padding)
 431         {
 432                 // FIXME item AR gets slightly changed here...
 433                 // it's rather hard to avoid it at this point
 434                 dist.x -= 2 * panel_bg_padding / mv_columns;
 435                 dist.y -= 2 * panel_bg_padding / rows;
 436                 xmin = pos.x += panel_bg_padding;
 437                 ymin = pos.y += panel_bg_padding;
 438                 xmax -= 2 * panel_bg_padding;
 439                 ymax -= 2 * panel_bg_padding;
 440         }
 441
 442         mv_selection = MapVote_Selection(pos, dist, rows, mv_columns);
 443
 444         if (mv_top2_time)
 445                 mv_top2_alpha = max(0.2, 1 - (time - mv_top2_time)*(time - mv_top2_time));
 446
 447         void (vector, float, float, string, string, float, float) DrawItem;
 448
 449         if(gametypevote)
 450                 DrawItem = GameTypeVote_DrawGameTypeItem;
 451         else
 452                 DrawItem = MapVote_DrawMapItem;
 453
 454         for(i = 0; i < mv_num_maps; ++i)
 455         {
 456                 tmp = mv_votes[i]; // FTEQCC bug: too many array accesses in the function call screw it up
 457                 map = mv_maps[i];
 458                 if(mv_preview[i])
 459                         DrawItem(pos + MapVote_GridVec(dist, i, mv_columns), dist.y, dist.x, map, mv_pics[i], tmp, i);
 460                 else
 461                         DrawItem(pos + MapVote_GridVec(dist, i, mv_columns), dist.y, dist.x, map, "", tmp, i);
 462         }
 463
 464         if(mv_abstain)
 465                 ++mv_num_maps;
 466
 467         if(mv_abstain && i < mv_num_maps) {
 468                 tmp = mv_votes[i];
 469                 pos.y = ymax + 2 * hud_fontsize.y;
 470                 pos.x = (xmax+xmin)*0.5;
 471                 MapVote_DrawAbstain(pos, dist.x, xmax - xmin, tmp, i);
 472         }
 473
 474         drawpic(mv_mousepos, strcat("gfx/menu/", autocvar_menu_skin, "/cursor.tga"), '32 32 0', '1 1 1', 1 - autocvar__menu_alpha, DRAWFLAG_NORMAL);
 475 }
 476
 477 void Cmd_MapVote_MapDownload(float argc)
 478 {
 479         entity pak;
 480
 481         if(argc != 2 || !mv_pk3list)
 482         {
 483                 print(_("mv_mapdownload: ^3You're not supposed to use this command on your own!\n"));
 484                 return;
 485         }
 486
 487         int id = stof(argv(1));
 488         for(pak = mv_pk3list; pak; pak = pak.chain)
 489                 if(pak.sv_entnum == id)
 490                         break;
 491
 492         if(!pak || pak.sv_entnum != id) {
 493                 print(_("^1Error:^7 Couldn't find pak index.\n"));
 494                 return;
 495         }
 496
 497         if(PreviewExists(pak.message))
 498         {
 499                 mv_preview[id] = true;
 500                 return;
 501         } else {
 502                 print(_("Requesting preview...\n"));
 503                 localcmd(strcat("\ncmd mv_getpicture ", ftos(id), "\n"));
 504         }
 505 }
 506
 507 void MapVote_CheckPK3(string pic, string pk3, int id)
 508 {
 509         entity pak;
 510         pak = spawn();
 511         pak.netname = pk3;
 512         pak.message = pic;
 513         pak.sv_entnum = id;
 514
 515         pak.chain = mv_pk3list;
 516         mv_pk3list = pak;
 517
 518         if(pk3 != "")
 519         {
 520                 localcmd(strcat("\ncurl --pak ", pk3, "; wait; cl_cmd mv_download ", ftos(id), "\n"));
 521         }
 522         else
 523         {
 524                 Cmd_MapVote_MapDownload(tokenize_console(strcat("mv_download ", ftos(id))));
 525         }
 526 }
 527
 528 void MapVote_CheckPic(string pic, string pk3, int id)
 529 {
 530         // never try to retrieve a pic for the "don't care" 'map'
 531         if(mv_abstain && id == mv_num_maps - 1)
 532                 return;
 533
 534         if(PreviewExists(pic))
 535         {
 536                 mv_preview[id] = true;
 537                 return;
 538         }
 539         MapVote_CheckPK3(pic, pk3, id);
 540 }
 541
 542 void MapVote_ReadMask()
 543 {
 544         int i;
 545         if ( mv_num_maps < 24 )
 546         {
 547                 int mask, power;
 548                 if(mv_num_maps < 8)
 549                         mask = ReadByte();
 550                 else if(mv_num_maps < 16)
 551                         mask = ReadShort();
 552                 else
 553                         mask = ReadLong();
 554
 555                 for(i = 0, power = 1; i < mv_num_maps; ++i, power *= 2)
 556                 {
 557                         if ( mask & power )
 558                                 mv_flags[i] |= GTV_AVAILABLE;
 559                         else
 560                                 mv_flags[i] &= ~GTV_AVAILABLE;
 561                 }
 562         }
 563         else
 564         {
 565                 for(i = 0; i < mv_num_maps; ++i )
 566                         mv_flags[i] = ReadByte();
 567         }
 568 }
 569
 570 void MapVote_ReadOption(int i)
 571 {
 572         string map = strzone(ReadString());
 573         string pk3 = strzone(ReadString());
 574         int j = bound(0, ReadByte(), n_ssdirs - 1);
 575
 576         mv_maps[i] = map;
 577         mv_pk3[i] = pk3;
 578         mv_flags[i] = GTV_AVAILABLE;
 579
 580         string pic = strzone(strcat(ssdirs[j], "/", map));
 581         mv_pics[i] = pic;
 582         mv_preview[i] = false;
 583         MapVote_CheckPic(pic, pk3, i);
 584 }
 585
 586 void GameTypeVote_ReadOption(int i)
 587 {
 588         string gt = strzone(ReadString());
 589
 590         mv_maps[i] = gt;
 591         mv_flags[i] = ReadByte();
 592
 593         string mv_picpath = sprintf("gfx/menu/%s/gametype_%s", autocvar_menu_skin, gt);
 594         if(precache_pic(mv_picpath) == "")
 595                 mv_picpath = strcat("gfx/menu/default/gametype_", gt);
 596         string pic = strzone(mv_picpath);
 597         mv_pics[i] = pic;
 598         mv_preview[i] = PreviewExists(pic);
 599
 600         if ( mv_flags[i] & GTV_CUSTOM )
 601         {
 602                 string name = ReadString();
 603                 if ( strlen(name) < 1 )
 604                         name = gt;
 605                 mv_pk3[i] = strzone(name);
 606                 mv_desc[i] = strzone(ReadString());
 607         }
 608         else
 609         {
 610                 int type = MapInfo_Type_FromString(gt);
 611                 mv_pk3[i] = strzone(MapInfo_Type_ToText(type));
 612                 mv_desc[i] = MapInfo_Type_Description(type);
 613         }
 614 }
 615
 616 void MapVote_Init()
 617 {
 618         precache_sound ("misc/invshot.wav");
 619
 620         mv_active = 1;
 621         if(autocvar_hud_cursormode) { setcursormode(1); }
 622         else { mv_mousepos = '0.5 0 0' * vid_conwidth + '0 0.5 0' * vid_conheight; }
 623         mv_selection = -1;
 624         mv_selection_keyboard = 0;
 625
 626         string s;
 627         for(n_ssdirs = 0; ; ++n_ssdirs)
 628         {
 629                 s = ReadString();
 630                 if(s == "")
 631                         break;
 632                 if(n_ssdirs < NUM_SSDIRS)
 633                         ssdirs[n_ssdirs] = s;
 634         }
 635         n_ssdirs = min(n_ssdirs, NUM_SSDIRS);
 636
 637         mv_num_maps = min(MAPVOTE_COUNT, ReadByte());
 638         mv_abstain = ReadByte();
 639         if(mv_abstain)
 640                 mv_abstain = 1; // must be 1 for bool-true, makes stuff easier
 641         mv_detail = ReadByte();
 642
 643         mv_ownvote = -1;
 644         mv_timeout = ReadCoord();
 645
 646         gametypevote = ReadByte();
 647
 648         if(gametypevote)
 649         {
 650                 mapvote_chosenmap = strzone(ReadString());
 651                 if ( gametypevote == 2 )
 652                         gametypevote = 0;
 653
 654                 gtv_text_size = hud_fontsize*1.4;
 655                 gtv_text_size_small = hud_fontsize*1.1;
 656         }
 657
 658         MapVote_ReadMask();
 659         int i;
 660         for(i = 0; i < mv_num_maps; ++i )
 661                 mv_flags_start[i] = mv_flags[i];
 662
 663         // Assume mv_pk3list is world, there should only be 1 mapvote per round
 664         mv_pk3list = world; // I'm still paranoid!
 665
 666         for(i = 0; i < mv_num_maps; ++i)
 667         {
 668                 mv_votes[i] = 0;
 669
 670                 if ( gametypevote )
 671                         GameTypeVote_ReadOption(i);
 672                 else
 673                         MapVote_ReadOption(i);
 674         }
 675
 676         for(i = 0; i < n_ssdirs; ++i)
 677                 ssdirs[n_ssdirs] = string_null;
 678         n_ssdirs = 0;
 679 }
 680
 681 void MapVote_SendChoice(float index)
 682 {
 683         localcmd(strcat("\nimpulse ", ftos(index+1), "\n"));
 684 }
 685
 686 int MapVote_MoveLeft(int pos)
 687 {
 688         int imp;
 689         if ( pos < 0 )
 690                 imp = mv_num_maps - 1;
 691         else
 692                 imp = pos < 1 ? mv_num_maps - 1 : pos - 1;
 693         if ( !(mv_flags[imp] & GTV_AVAILABLE) && imp != mv_ownvote )
 694                 imp = MapVote_MoveLeft(imp);
 695         return imp;
 696 }
 697 int MapVote_MoveRight(int pos)
 698 {
 699         int imp;
 700         if ( pos < 0 )
 701                 imp = 0;
 702         else
 703                 imp = pos >= mv_num_maps - 1 ? 0 : pos + 1;
 704         if ( !(mv_flags[imp] & GTV_AVAILABLE) && imp != mv_ownvote )
 705                 imp = MapVote_MoveRight(imp);
 706         return imp;
 707 }
 708 int MapVote_MoveUp(int pos)
 709 {
 710         int imp;
 711         if ( pos < 0 )
 712                 imp = mv_num_maps - 1;
 713         else
 714         {
 715                 imp = pos - mv_columns;
 716                 if ( imp < 0 )
 717                 {
 718                         imp = floor(mv_num_maps/mv_columns)*mv_columns + pos % mv_columns;
 719                         if ( imp >= mv_num_maps )
 720                                 imp -= mv_columns;
 721                 }
 722         }
 723         if ( !(mv_flags[imp] & GTV_AVAILABLE) && imp != mv_ownvote )
 724                 imp = MapVote_MoveUp(imp);
 725         return imp;
 726 }
 727 int MapVote_MoveDown(int pos)
 728 {
 729         int imp;
 730         if ( pos < 0 )
 731                 imp = 0;
 732         else
 733         {
 734                 imp = pos + mv_columns;
 735                 if ( imp >= mv_num_maps )
 736                         imp = imp % mv_columns;
 737         }
 738         if ( !(mv_flags[imp] & GTV_AVAILABLE) && imp != mv_ownvote )
 739                 imp = MapVote_MoveDown(imp);
 740         return imp;
 741 }
 742
 743 float MapVote_InputEvent(float bInputType, float nPrimary, float nSecondary)
 744 {
 745         float imp;
 746
 747         if (!mv_active)
 748                 return false;
 749
 750         if(bInputType == 3)
 751         {
 752                 mv_mousepos.x = nPrimary;
 753                 mv_mousepos.y = nSecondary;
 754                 mv_selection_keyboard = 0;
 755                 return true;
 756         }
 757
 758         if (bInputType != 0)
 759                 return false;
 760
 761         if ('0' <= nPrimary && nPrimary <= '9')
 762         {
 763                 imp = nPrimary - '0';
 764                 if (imp == 0) imp = 10;
 765                 localcmd(strcat("\nimpulse ", ftos(imp), "\n"));
 766                 return true;
 767         }
 768         switch(nPrimary)
 769         {
 770                 case K_KP_1: localcmd("\nimpulse 1\n"); return true;
 771                 case K_KP_2: localcmd("\nimpulse 2\n"); return true;
 772                 case K_KP_3: localcmd("\nimpulse 3\n"); return true;
 773                 case K_KP_4: localcmd("\nimpulse 4\n"); return true;
 774                 case K_KP_5: localcmd("\nimpulse 5\n"); return true;
 775                 case K_KP_6: localcmd("\nimpulse 6\n"); return true;
 776                 case K_KP_7: localcmd("\nimpulse 7\n"); return true;
 777                 case K_KP_8: localcmd("\nimpulse 8\n"); return true;
 778                 case K_KP_9: localcmd("\nimpulse 9\n"); return true;
 779                 case K_KP_0: localcmd("\nimpulse 10\n"); return true;
 780
 781                 case K_RIGHTARROW:
 782                         mv_selection_keyboard = 1;
 783                         mv_selection = MapVote_MoveRight(mv_selection);
 784                         return true;
 785                 case K_LEFTARROW:
 786                         mv_selection_keyboard = 1;
 787                         mv_selection = MapVote_MoveLeft(mv_selection);
 788                         return true;
 789                 case K_DOWNARROW:
 790                         mv_selection_keyboard = 1;
 791                         mv_selection = MapVote_MoveDown(mv_selection);
 792                         return true;
 793                 case K_UPARROW:
 794                         mv_selection_keyboard = 1;
 795                         mv_selection = MapVote_MoveUp(mv_selection);
 796                         return true;
 797                 case K_KP_ENTER:
 798                 case K_ENTER:
 799                 case K_SPACE:
 800                         if ( mv_selection_keyboard )
 801                                 MapVote_SendChoice(mv_selection);
 802                         return true;
 803         }
 804
 805         if (nPrimary == K_MOUSE1)
 806         {
 807                 mv_selection_keyboard = 0;
 808                 mv_selection = mv_mouse_selection;
 809                 if (mv_selection >= 0)
 810                 {
 811                         imp = min(mv_selection + 1, mv_num_maps);
 812                         localcmd(strcat("\nimpulse ", ftos(imp), "\n"));
 813                         return true;
 814                 }
 815         }
 816
 817         return false;
 818 }
 819
 820 void MapVote_UpdateMask()
 821 {
 822         MapVote_ReadMask();
 823         mv_top2_time = time;
 824 }
 825
 826 void MapVote_UpdateVotes()
 827 {
 828         int i;
 829         for(i = 0; i < mv_num_maps; ++i)
 830         {
 831                 if(mv_flags[i] & GTV_AVAILABLE)
 832                 {
 833                         if(mv_detail)
 834                                 mv_votes[i] = ReadByte();
 835                         else
 836                                 mv_votes[i] = 0;
 837                 }
 838                 else
 839                         mv_votes[i] = -1;
 840         }
 841
 842         mv_ownvote = ReadByte()-1;
 843 }
 844
 845 void Ent_MapVote()
 846 {
 847         int sf = ReadByte();
 848
 849         if(sf & 1)
 850                 MapVote_Init();
 851
 852         if(sf & 2)
 853                 MapVote_UpdateMask();
 854
 855         if(sf & 4)
 856                 MapVote_UpdateVotes();
 857 }
 858
 859 void Net_MapVote_Picture()
 860 {
 861         int type = ReadByte();
 862         mv_preview[type] = true;
 863         mv_pics[type] = strzone(ReadPicture());
 864 }