qcsrc/client/mapvoting.qc

   1 #include "mapvoting.qh"
   2 #include "_all.qh"
   3
   4 #include "hud.qh"
   5 #include "scoreboard.qh"
   6
   7 #include "../common/mapinfo.qh"
   8 #include "../common/util.qh"
   9
  10 #include "../dpdefs/keycodes.qh"
  11
  12
  13 int mv_num_maps;
  14
  15 float mv_active;
  16 string mv_maps[MAPVOTE_COUNT];
  17 string mv_pics[MAPVOTE_COUNT];
  18 string mv_pk3[MAPVOTE_COUNT]; // map pk3 name or gametype human readable name
  19 string mv_desc[MAPVOTE_COUNT];
  20 float mv_preview[MAPVOTE_COUNT];
  21 float mv_votes[MAPVOTE_COUNT];
  22 float mv_flags[MAPVOTE_COUNT];
  23 float mv_flags_start[MAPVOTE_COUNT];
  24 entity mv_pk3list;
  25 float mv_abstain;
  26 float mv_ownvote;
  27 float mv_detail;
  28 float mv_timeout;
  29 float mv_top2_time;
  30 float mv_top2_alpha;
  31
  32 vector mv_mousepos;
  33 int mv_selection;
  34 int mv_columns;
  35 int mv_mouse_selection;
  36 int mv_selection_keyboard;
  37
  38 float gametypevote;
  39 string mapvote_chosenmap;
  40 vector gtv_text_size;
  41 vector gtv_text_size_small;
  42
  43 const int NUM_SSDIRS = 4;
  44 string ssdirs[NUM_SSDIRS];
  45 int n_ssdirs;
  46
  47 string MapVote_FormatMapItem(int id, string map, float _count, float maxwidth, vector fontsize)
  48 {
  49         string pre, post;
  50         pre = sprintf("%d. ", id+1);
  51         if(mv_detail)
  52         {
  53                 if(_count == 1)
  54                         post = _(" (1 vote)");
  55                 else if(_count >= 0 && (mv_flags[id] & GTV_AVAILABLE))
  56                         post = sprintf(_(" (%d votes)"), _count);
  57                 else
  58                         post = "";
  59         }
  60         else
  61                 post = "";
  62         maxwidth -= stringwidth(pre, false, fontsize) + stringwidth(post, false, fontsize);
  63         map = textShortenToWidth(map, maxwidth, fontsize, stringwidth_nocolors);
  64         return strcat(pre, map, post);
  65 }
  66
  67 vector MapVote_RGB(int id)
  68 {
  69         if(!(mv_flags[id] & GTV_AVAILABLE))
  70                 return '1 1 1';
  71         if(id == mv_ownvote)
  72                 return '0 1 0';
  73         else if (id == mv_selection)
  74                 return '1 1 0';
  75         else
  76                 return '1 1 1';
  77 }
  78
  79 void GameTypeVote_DrawGameTypeItem(vector pos, float maxh, float tsize, string gtype, string pic, float _count, int id)
  80 {
  81         // Find the correct alpha
  82         float alpha;
  83         if(!(mv_flags_start[id] & GTV_AVAILABLE))
  84                 alpha = 0.2; // The gametype isn't supported by the map
  85         else if ( !(mv_flags[id] & GTV_AVAILABLE) && mv_top2_alpha)
  86                 alpha = mv_top2_alpha; // Fade away if not one of the top 2 choice
  87         else
  88                 alpha = 1; // Normal, full alpha
  89
  90         // Bounding box details
  91         float rect_margin = hud_fontsize.y / 2;
  92
  93         pos.x += rect_margin;
  94         pos.y += rect_margin;
  95         maxh -= 2 * rect_margin;
  96         tsize -= 2 * rect_margin;
  97
  98         vector rect_pos = pos - '0.5 0.5 0' * rect_margin;
  99         vector rect_size = '1 1 0';
 100         rect_size.x = tsize + rect_margin;
 101         rect_size.y = maxh + rect_margin;
 102
 103         // Highlight selected item
 104         if(id == mv_selection && (mv_flags[id] & GTV_AVAILABLE))
 105         {
 106                 drawfill(rect_pos, rect_size, '1 1 1', 0.1, DRAWFLAG_NORMAL);
 107         }
 108
 109         // Highlight current vote
 110         vector rgb = MapVote_RGB(id);
 111         if(id == mv_ownvote)
 112         {
 113                 drawfill(rect_pos, rect_size, rgb, 0.1*alpha, DRAWFLAG_NORMAL);
 114                 drawborderlines(autocvar_scoreboard_border_thickness, rect_pos, rect_size, rgb, alpha, DRAWFLAG_NORMAL);
 115         }
 116
 117         vector offset = pos;
 118
 119         float title_gap = gtv_text_size.y * 1.4; // distance between the title and the description
 120         pos.y += title_gap;
 121         maxh -= title_gap;
 122
 123         // Evaluate the image size
 124         vector image_size = '1 1 0' * gtv_text_size.x * 3;
 125         if ( maxh < image_size.y )
 126                 image_size = '1 1 0' * maxh;
 127         image_size *= 0.8;
 128         float desc_padding = gtv_text_size.x * 0.6;
 129         pos.x += image_size.x + desc_padding;
 130         tsize -= image_size.x + desc_padding;
 131
 132         // Split the description into lines
 133         entity title;
 134         title = spawn();
 135         title.message = MapVote_FormatMapItem(id, mv_pk3[id], _count, tsize, gtv_text_size);
 136
 137         string thelabel = mv_desc[id], ts;
 138         entity last = title;
 139         entity next = world;
 140         float nlines = 0;
 141         if( thelabel != "")
 142         {
 143                 float i,n = tokenizebyseparator(thelabel, "\n");
 144                 for(i = 0; i < n && maxh > (nlines+1)*gtv_text_size_small.y; ++i)
 145                 {
 146                         getWrappedLine_remaining = argv(i);
 147                         while(getWrappedLine_remaining && maxh > (nlines+1)*gtv_text_size_small.y)
 148                         {
 149                                 ts = getWrappedLine(tsize, gtv_text_size_small, stringwidth_colors);
 150                                 if (ts != "")
 151                                 {
 152                                         next = spawn();
 153                                         next.message = ts;
 154                                         next.origin = pos-offset;
 155                                         last.chain = next;
 156                                         last = next;
 157                                         pos.y += gtv_text_size_small.y;
 158                                         nlines++;
 159                                 }
 160                         }
 161                 }
 162         }
 163
 164         // Center the contents in the bounding box
 165         maxh -= max(nlines*gtv_text_size_small.y,image_size.y);
 166         if ( maxh > 0 )
 167                 offset.y += maxh/2;
 168
 169         // Draw the title
 170         drawstring(offset, title.message, gtv_text_size, rgb, alpha, DRAWFLAG_NORMAL);
 171
 172         // Draw the icon
 173         if(pic != "")
 174                 drawpic('0 1 0'*title_gap+'0.5 0 0'*desc_padding+offset, pic, image_size, '1 1 1', alpha, DRAWFLAG_NORMAL);
 175
 176         // Draw the description
 177         for ( last = title.chain; last ; )
 178         {
 179                 drawstring(last.origin+offset, last.message, gtv_text_size_small, '1 1 1', alpha, DRAWFLAG_NORMAL);
 180                 next = last;
 181                 last = last.chain;
 182                 remove(next);
 183         }
 184
 185         // Cleanup
 186         remove(title);
 187 }
 188
 189 void MapVote_DrawMapItem(vector pos, float isize, float tsize, string map, string pic, float _count, int id)
 190 {
 191         vector img_size = '0 0 0';
 192         vector rgb;
 193         string label;
 194         float text_size;
 195
 196         rgb = MapVote_RGB(id);
 197
 198         float padding = hud_fontsize.y / 2;
 199
 200         pos.x += padding;
 201         pos.y += padding;
 202         isize -= 2 * padding;
 203         tsize -= 2 * padding;
 204
 205         float img_ar = 4/3;
 206         img_size.x = min(tsize, isize * img_ar);
 207         img_size.y = img_size.x / img_ar;
 208         img_size.y -= hud_fontsize.y - autocvar_scoreboard_border_thickness * 2;
 209         img_size.x = img_size.y * img_ar;
 210
 211         pos.y += (isize - img_size.y - hud_fontsize.y) / 2;
 212
 213         label = MapVote_FormatMapItem(id, map, _count, tsize, hud_fontsize);
 214
 215         text_size = stringwidth(label, false, hud_fontsize);
 216
 217         vector text_pos = '0 0 0';
 218         text_pos.x = pos.x + (tsize - text_size) / 2;
 219         text_pos.y = pos.y + img_size.y + autocvar_scoreboard_border_thickness;
 220
 221         pos.x += (tsize - img_size.x) / 2;
 222
 223         float theAlpha;
 224         if (!(mv_flags[id] & GTV_AVAILABLE) && mv_top2_alpha)
 225                 theAlpha = mv_top2_alpha;
 226         else
 227                 theAlpha = 1;
 228         drawstring(text_pos, label, hud_fontsize, rgb, theAlpha, DRAWFLAG_NORMAL);
 229
 230         if(pic == "")
 231         {
 232                 drawfill(pos, img_size, '.5 .5 .5', .7 * theAlpha, DRAWFLAG_NORMAL);
 233         }
 234         else
 235         {
 236                 if(drawgetimagesize(pic) == '0 0 0')
 237                         drawpic(pos, draw_UseSkinFor("nopreview_map"), img_size, '1 1 1', theAlpha, DRAWFLAG_NORMAL);
 238                 else
 239                         drawpic(pos, pic, img_size, '1 1 1', theAlpha, DRAWFLAG_NORMAL);
 240         }
 241
 242         if(id == mv_ownvote)
 243                 drawborderlines(autocvar_scoreboard_border_thickness, pos, img_size, rgb, theAlpha, DRAWFLAG_NORMAL);
 244         else
 245                 drawborderlines(autocvar_scoreboard_border_thickness, pos, img_size, '0 0 0', theAlpha, DRAWFLAG_NORMAL);
 246
 247         if(id == mv_selection && (mv_flags[id] & GTV_AVAILABLE))
 248                 drawfill(pos, img_size, '1 1 1', 0.1, DRAWFLAG_NORMAL);
 249 }
 250
 251 void MapVote_DrawAbstain(vector pos, float isize, float tsize, float _count, int id)
 252 {
 253         vector rgb;
 254         float text_size;
 255         string label;
 256
 257         rgb = MapVote_RGB(id);
 258
 259         label = MapVote_FormatMapItem(id, _("Don't care"), _count, tsize, hud_fontsize);
 260
 261         text_size = stringwidth(label, false, hud_fontsize);
 262
 263         pos.x -= text_size*0.5;
 264         drawstring(pos, label, hud_fontsize, rgb, 1, DRAWFLAG_NORMAL);
 265 }
 266
 267 vector MapVote_GridVec(vector gridspec, int i, int m)
 268 {
 269         int r = i % m;
 270         return
 271                 '1 0 0' * (gridspec.x * r)
 272                 +
 273                 '0 1 0' * (gridspec.y * (i - r) / m);
 274 }
 275
 276 float MapVote_Selection(vector topleft, vector cellsize, float rows, float columns)
 277 {
 278
 279         float c, r;
 280
 281         mv_mouse_selection = -1;
 282
 283         for (r = 0; r < rows; ++r)
 284                 for (c = 0; c < columns; ++c)
 285                 {
 286                         if (mv_mousepos.x >= topleft.x + cellsize.x *  c &&
 287                                 mv_mousepos.x <= topleft.x + cellsize.x * (c + 1) &&
 288                                 mv_mousepos.y >= topleft.y + cellsize.y *  r &&
 289                                 mv_mousepos.y <= topleft.y + cellsize.y * (r + 1))
 290                         {
 291                                 mv_mouse_selection = r * columns + c;
 292                                 break;
 293                         }
 294                 }
 295
 296         if (mv_mouse_selection >= mv_num_maps)
 297                 mv_mouse_selection = -1;
 298
 299         if (mv_abstain && mv_mouse_selection < 0)
 300                 mv_mouse_selection = mv_num_maps;
 301
 302         if ( mv_selection_keyboard )
 303                 return mv_selection;
 304
 305         return mv_mouse_selection;
 306 }
 307
 308 vector HUD_GetTableSize_BestItemAR(int item_count, vector psize, float item_aspect);
 309 void MapVote_Draw()
 310 {
 311         string map;
 312         int i;
 313         float tmp;
 314         vector pos;
 315         float center;
 316         float rows;
 317         vector dist = '0 0 0';
 318
 319         if(!mv_active)
 320                 return;
 321
 322         if (!autocvar_hud_cursormode)
 323         {
 324                 vector mpos = mv_mousepos + getmousepos();
 325                 mpos.x = bound(0, mpos.x, vid_conwidth);
 326                 mpos.y = bound(0, mpos.y, vid_conheight);
 327
 328                 if ( mpos.x != mv_mousepos.x || mpos.y != mv_mousepos.y )
 329                         mv_selection_keyboard = 0;
 330                 mv_mousepos = mpos;
 331
 332         }
 333
 334         center = (vid_conwidth - 1)/2;
 335         xmin = vid_conwidth*0.05; // 5% border must suffice
 336         xmax = vid_conwidth - xmin;
 337         ymin = 20;
 338         i = autocvar_con_chatpos; // *autocvar_con_chatsize;
 339         if(i < 0)
 340                 ymax = vid_conheight + (i - autocvar_con_chat) * autocvar_con_chatsize;
 341         if(i >= 0 || ymax < (vid_conheight*0.5))
 342                 ymax = vid_conheight - ymin;
 343
 344         hud_fontsize = HUD_GetFontsize("hud_fontsize");
 345
 346         pos.y = ymin;
 347         pos.z = 0;
 348
 349         draw_beginBoldFont();
 350
 351         map = ((gametypevote) ? _("Decide the gametype") : _("Vote for a map"));
 352         pos.x = center - stringwidth(map, false, hud_fontsize * 2) * 0.5;
 353         drawstring(pos, map, hud_fontsize * 2, '1 1 1', 1, DRAWFLAG_NORMAL);
 354         pos.y += hud_fontsize.y * 2;
 355
 356         if( mapvote_chosenmap != "" )
 357         {
 358                 pos.y += hud_fontsize.y * 0.25;
 359                 pos.x = center - stringwidth(mapvote_chosenmap, false, hud_fontsize * 1.5) * 0.5;
 360                 drawstring(pos, mapvote_chosenmap, hud_fontsize * 1.5, '1 1 1', 1, DRAWFLAG_NORMAL);
 361                 pos.y += hud_fontsize.y * 1.5;
 362                 pos.y += hud_fontsize.y * 0.5;
 363         }
 364         else
 365                 pos.y += hud_fontsize.y * 0.5;
 366
 367         draw_endBoldFont();
 368
 369         i = ceil(max(0, mv_timeout - time));
 370         map = sprintf(_("%d seconds left"), i);
 371         pos.x = center - stringwidth(map, false, hud_fontsize * 1.5) * 0.5;
 372         drawstring(pos, map, hud_fontsize * 1.5, '0 1 0', 1, DRAWFLAG_NORMAL);
 373         pos.y += hud_fontsize.y * 1.5;
 374         pos.y += hud_fontsize.y * 0.5;
 375
 376         // base for multi-column stuff...
 377         pos.y += hud_fontsize.y;
 378         pos.x = xmin;
 379         ymin = pos.y;
 380         if(mv_abstain)
 381                 mv_num_maps -= 1;
 382
 383         // higher than the image itself ratio for mapvote items to reserve space for long map names
 384         int item_aspect = (gametypevote) ? 3/1 : 5/3;
 385         vector table_size = HUD_GetTableSize_BestItemAR(mv_num_maps, eX * (xmax - xmin) + eY * (ymax - ymin), item_aspect);
 386         mv_columns = table_size.x;
 387         rows = table_size.y;
 388
 389         dist.x = (xmax - xmin) / mv_columns;
 390         dist.y = (ymax - pos.y) / rows;
 391
 392         // reduce size of too wide items
 393         tmp = vid_conwidth / 3; // max width
 394         if(dist.x > tmp)
 395         {
 396                 dist.x = tmp;
 397                 dist.y = min(dist.y, dist.x / item_aspect);
 398         }
 399         tmp = vid_conheight / 3; // max height
 400         if(dist.y > tmp)
 401         {
 402                 dist.y = tmp;
 403                 dist.x = min(dist.x, dist.y * item_aspect);
 404         }
 405
 406         // reduce size to fix aspect ratio
 407         if(dist.x / dist.y > item_aspect)
 408                 dist.x = dist.y * item_aspect;
 409         else
 410                 dist.y = dist.x / item_aspect;
 411
 412         // adjust table pos and size according to the new size
 413         float offset;
 414         offset = ((xmax - pos.x) - dist.x * mv_columns) / 2;
 415         xmin = pos.x += offset;
 416         xmax -= offset;
 417         offset = ((ymax - pos.y) - dist.y * rows) / 2;
 418         ymax -= 2 * offset;
 419
 420         mv_selection = MapVote_Selection(pos, dist, rows, mv_columns);
 421
 422         if (mv_top2_time)
 423                 mv_top2_alpha = max(0.2, 1 - (time - mv_top2_time)*(time - mv_top2_time));
 424
 425         void (vector, float, float, string, string, float, float) DrawItem;
 426
 427         if(gametypevote)
 428                 DrawItem = GameTypeVote_DrawGameTypeItem;
 429         else
 430                 DrawItem = MapVote_DrawMapItem;
 431
 432         for(i = 0; i < mv_num_maps; ++i)
 433         {
 434                 tmp = mv_votes[i]; // FTEQCC bug: too many array accesses in the function call screw it up
 435                 map = mv_maps[i];
 436                 if(mv_preview[i])
 437                         DrawItem(pos + MapVote_GridVec(dist, i, mv_columns), dist.y, dist.x, map, mv_pics[i], tmp, i);
 438                 else
 439                         DrawItem(pos + MapVote_GridVec(dist, i, mv_columns), dist.y, dist.x, map, "", tmp, i);
 440         }
 441
 442         if(mv_abstain)
 443                 ++mv_num_maps;
 444
 445         if(mv_abstain && i < mv_num_maps) {
 446                 tmp = mv_votes[i];
 447                 pos.y = ymax + 2 * hud_fontsize.y;
 448                 pos.x = (xmax+xmin)*0.5;
 449                 MapVote_DrawAbstain(pos, dist.x, xmax - xmin, tmp, i);
 450         }
 451
 452         drawpic(mv_mousepos, strcat("gfx/menu/", autocvar_menu_skin, "/cursor.tga"), '32 32 0', '1 1 1', 1 - autocvar__menu_alpha, DRAWFLAG_NORMAL);
 453 }
 454
 455 void Cmd_MapVote_MapDownload(float argc)
 456 {
 457         entity pak;
 458
 459         if(argc != 2 || !mv_pk3list)
 460         {
 461                 print(_("mv_mapdownload: ^3You're not supposed to use this command on your own!\n"));
 462                 return;
 463         }
 464
 465         int id = stof(argv(1));
 466         for(pak = mv_pk3list; pak; pak = pak.chain)
 467                 if(pak.sv_entnum == id)
 468                         break;
 469
 470         if(!pak || pak.sv_entnum != id) {
 471                 print(_("^1Error:^7 Couldn't find pak index.\n"));
 472                 return;
 473         }
 474
 475         if(PreviewExists(pak.message))
 476         {
 477                 mv_preview[id] = true;
 478                 return;
 479         } else {
 480                 print(_("Requesting preview...\n"));
 481                 localcmd(strcat("\ncmd mv_getpicture ", ftos(id), "\n"));
 482         }
 483 }
 484
 485 void MapVote_CheckPK3(string pic, string pk3, int id)
 486 {
 487         entity pak;
 488         pak = spawn();
 489         pak.netname = pk3;
 490         pak.message = pic;
 491         pak.sv_entnum = id;
 492
 493         pak.chain = mv_pk3list;
 494         mv_pk3list = pak;
 495
 496         if(pk3 != "")
 497         {
 498                 localcmd(strcat("\ncurl --pak ", pk3, "; wait; cl_cmd mv_download ", ftos(id), "\n"));
 499         }
 500         else
 501         {
 502                 Cmd_MapVote_MapDownload(tokenize_console(strcat("mv_download ", ftos(id))));
 503         }
 504 }
 505
 506 void MapVote_CheckPic(string pic, string pk3, int id)
 507 {
 508         // never try to retrieve a pic for the "don't care" 'map'
 509         if(mv_abstain && id == mv_num_maps - 1)
 510                 return;
 511
 512         if(PreviewExists(pic))
 513         {
 514                 mv_preview[id] = true;
 515                 return;
 516         }
 517         MapVote_CheckPK3(pic, pk3, id);
 518 }
 519
 520 void MapVote_ReadMask()
 521 {
 522         int i;
 523         if ( mv_num_maps < 24 )
 524         {
 525                 int mask, power;
 526                 if(mv_num_maps < 8)
 527                         mask = ReadByte();
 528                 else if(mv_num_maps < 16)
 529                         mask = ReadShort();
 530                 else
 531                         mask = ReadLong();
 532
 533                 for(i = 0, power = 1; i < mv_num_maps; ++i, power *= 2)
 534                 {
 535                         if ( mask & power )
 536                                 mv_flags[i] |= GTV_AVAILABLE;
 537                         else
 538                                 mv_flags[i] &= ~GTV_AVAILABLE;
 539                 }
 540         }
 541         else
 542         {
 543                 for(i = 0; i < mv_num_maps; ++i )
 544                         mv_flags[i] = ReadByte();
 545         }
 546 }
 547
 548 void MapVote_ReadOption(int i)
 549 {
 550         string map = strzone(ReadString());
 551         string pk3 = strzone(ReadString());
 552         int j = bound(0, ReadByte(), n_ssdirs - 1);
 553
 554         mv_maps[i] = map;
 555         mv_pk3[i] = pk3;
 556         mv_flags[i] = GTV_AVAILABLE;
 557
 558         string pic = strzone(strcat(ssdirs[j], "/", map));
 559         mv_pics[i] = pic;
 560         mv_preview[i] = false;
 561         MapVote_CheckPic(pic, pk3, i);
 562 }
 563
 564 void GameTypeVote_ReadOption(int i)
 565 {
 566         string gt = strzone(ReadString());
 567
 568         mv_maps[i] = gt;
 569         mv_flags[i] = ReadByte();
 570
 571         string mv_picpath = sprintf("gfx/menu/%s/gametype_%s", autocvar_menu_skin, gt);
 572         if(precache_pic(mv_picpath) == "")
 573                 mv_picpath = strcat("gfx/menu/default/gametype_", gt);
 574         string pic = strzone(mv_picpath);
 575         mv_pics[i] = pic;
 576         mv_preview[i] = PreviewExists(pic);
 577
 578         if ( mv_flags[i] & GTV_CUSTOM )
 579         {
 580                 string name = ReadString();
 581                 if ( strlen(name) < 1 )
 582                         name = gt;
 583                 mv_pk3[i] = strzone(name);
 584                 mv_desc[i] = strzone(ReadString());
 585         }
 586         else
 587         {
 588                 int type = MapInfo_Type_FromString(gt);
 589                 mv_pk3[i] = strzone(MapInfo_Type_ToText(type));
 590                 mv_desc[i] = MapInfo_Type_Description(type);
 591         }
 592 }
 593
 594 void MapVote_Init()
 595 {
 596         precache_sound ("misc/invshot.wav");
 597
 598         mv_active = 1;
 599         if(autocvar_hud_cursormode) { setcursormode(1); }
 600         else { mv_mousepos = '0.5 0 0' * vid_conwidth + '0 0.5 0' * vid_conheight; }
 601         mv_selection = -1;
 602         mv_selection_keyboard = 0;
 603
 604         string s;
 605         for(n_ssdirs = 0; ; ++n_ssdirs)
 606         {
 607                 s = ReadString();
 608                 if(s == "")
 609                         break;
 610                 if(n_ssdirs < NUM_SSDIRS)
 611                         ssdirs[n_ssdirs] = s;
 612         }
 613         n_ssdirs = min(n_ssdirs, NUM_SSDIRS);
 614
 615         mv_num_maps = min(MAPVOTE_COUNT, ReadByte());
 616         mv_abstain = ReadByte();
 617         if(mv_abstain)
 618                 mv_abstain = 1; // must be 1 for bool-true, makes stuff easier
 619         mv_detail = ReadByte();
 620
 621         mv_ownvote = -1;
 622         mv_timeout = ReadCoord();
 623
 624         gametypevote = ReadByte();
 625
 626         if(gametypevote)
 627         {
 628                 mapvote_chosenmap = strzone(ReadString());
 629                 if ( gametypevote == 2 )
 630                         gametypevote = 0;
 631
 632                 gtv_text_size = hud_fontsize*1.4;
 633                 gtv_text_size_small = hud_fontsize*1.1;
 634         }
 635
 636         MapVote_ReadMask();
 637         int i;
 638         for(i = 0; i < mv_num_maps; ++i )
 639                 mv_flags_start[i] = mv_flags[i];
 640
 641         // Assume mv_pk3list is world, there should only be 1 mapvote per round
 642         mv_pk3list = world; // I'm still paranoid!
 643
 644         for(i = 0; i < mv_num_maps; ++i)
 645         {
 646                 mv_votes[i] = 0;
 647
 648                 if ( gametypevote )
 649                         GameTypeVote_ReadOption(i);
 650                 else
 651                         MapVote_ReadOption(i);
 652         }
 653
 654         for(i = 0; i < n_ssdirs; ++i)
 655                 ssdirs[n_ssdirs] = string_null;
 656         n_ssdirs = 0;
 657 }
 658
 659 void MapVote_SendChoice(float index)
 660 {
 661         localcmd(strcat("\nimpulse ", ftos(index+1), "\n"));
 662 }
 663
 664 int MapVote_MoveLeft(int pos)
 665 {
 666         int imp;
 667         if ( pos < 0 )
 668                 imp = mv_num_maps - 1;
 669         else
 670                 imp = pos < 1 ? mv_num_maps - 1 : pos - 1;
 671         if ( !(mv_flags[imp] & GTV_AVAILABLE) && imp != mv_ownvote )
 672                 imp = MapVote_MoveLeft(imp);
 673         return imp;
 674 }
 675 int MapVote_MoveRight(int pos)
 676 {
 677         int imp;
 678         if ( pos < 0 )
 679                 imp = 0;
 680         else
 681                 imp = pos >= mv_num_maps - 1 ? 0 : pos + 1;
 682         if ( !(mv_flags[imp] & GTV_AVAILABLE) && imp != mv_ownvote )
 683                 imp = MapVote_MoveRight(imp);
 684         return imp;
 685 }
 686 int MapVote_MoveUp(int pos)
 687 {
 688         int imp;
 689         if ( pos < 0 )
 690                 imp = mv_num_maps - 1;
 691         else
 692         {
 693                 imp = pos - mv_columns;
 694                 if ( imp < 0 )
 695                 {
 696                         imp = floor(mv_num_maps/mv_columns)*mv_columns + pos % mv_columns;
 697                         if ( imp >= mv_num_maps )
 698                                 imp -= mv_columns;
 699                 }
 700         }
 701         if ( !(mv_flags[imp] & GTV_AVAILABLE) && imp != mv_ownvote )
 702                 imp = MapVote_MoveUp(imp);
 703         return imp;
 704 }
 705 int MapVote_MoveDown(int pos)
 706 {
 707         int imp;
 708         if ( pos < 0 )
 709                 imp = 0;
 710         else
 711         {
 712                 imp = pos + mv_columns;
 713                 if ( imp >= mv_num_maps )
 714                         imp = imp % mv_columns;
 715         }
 716         if ( !(mv_flags[imp] & GTV_AVAILABLE) && imp != mv_ownvote )
 717                 imp = MapVote_MoveDown(imp);
 718         return imp;
 719 }
 720
 721 float MapVote_InputEvent(float bInputType, float nPrimary, float nSecondary)
 722 {
 723         float imp;
 724
 725         if (!mv_active)
 726                 return false;
 727
 728         if(bInputType == 3)
 729         {
 730                 mv_mousepos.x = nPrimary;
 731                 mv_mousepos.y = nSecondary;
 732                 mv_selection_keyboard = 0;
 733                 return true;
 734         }
 735
 736         if (bInputType != 0)
 737                 return false;
 738
 739         if ('0' <= nPrimary && nPrimary <= '9')
 740         {
 741                 imp = nPrimary - '0';
 742                 if (imp == 0) imp = 10;
 743                 localcmd(strcat("\nimpulse ", ftos(imp), "\n"));
 744                 return true;
 745         }
 746         switch(nPrimary)
 747         {
 748                 case K_KP_1: localcmd("\nimpulse 1\n"); return true;
 749                 case K_KP_2: localcmd("\nimpulse 2\n"); return true;
 750                 case K_KP_3: localcmd("\nimpulse 3\n"); return true;
 751                 case K_KP_4: localcmd("\nimpulse 4\n"); return true;
 752                 case K_KP_5: localcmd("\nimpulse 5\n"); return true;
 753                 case K_KP_6: localcmd("\nimpulse 6\n"); return true;
 754                 case K_KP_7: localcmd("\nimpulse 7\n"); return true;
 755                 case K_KP_8: localcmd("\nimpulse 8\n"); return true;
 756                 case K_KP_9: localcmd("\nimpulse 9\n"); return true;
 757                 case K_KP_0: localcmd("\nimpulse 10\n"); return true;
 758
 759                 case K_RIGHTARROW:
 760                         mv_selection_keyboard = 1;
 761                         mv_selection = MapVote_MoveRight(mv_selection);
 762                         return true;
 763                 case K_LEFTARROW:
 764                         mv_selection_keyboard = 1;
 765                         mv_selection = MapVote_MoveLeft(mv_selection);
 766                         return true;
 767                 case K_DOWNARROW:
 768                         mv_selection_keyboard = 1;
 769                         mv_selection = MapVote_MoveDown(mv_selection);
 770                         return true;
 771                 case K_UPARROW:
 772                         mv_selection_keyboard = 1;
 773                         mv_selection = MapVote_MoveUp(mv_selection);
 774                         return true;
 775                 case K_KP_ENTER:
 776                 case K_ENTER:
 777                 case K_SPACE:
 778                         if ( mv_selection_keyboard )
 779                                 MapVote_SendChoice(mv_selection);
 780                         return true;
 781         }
 782
 783         if (nPrimary == K_MOUSE1)
 784         {
 785                 mv_selection_keyboard = 0;
 786                 mv_selection = mv_mouse_selection;
 787                 if (mv_selection >= 0)
 788                 {
 789                         imp = min(mv_selection + 1, mv_num_maps);
 790                         localcmd(strcat("\nimpulse ", ftos(imp), "\n"));
 791                         return true;
 792                 }
 793         }
 794
 795         return false;
 796 }
 797
 798 void MapVote_UpdateMask()
 799 {
 800         MapVote_ReadMask();
 801         mv_top2_time = time;
 802 }
 803
 804 void MapVote_UpdateVotes()
 805 {
 806         int i;
 807         for(i = 0; i < mv_num_maps; ++i)
 808         {
 809                 if(mv_flags[i] & GTV_AVAILABLE)
 810                 {
 811                         if(mv_detail)
 812                                 mv_votes[i] = ReadByte();
 813                         else
 814                                 mv_votes[i] = 0;
 815                 }
 816                 else
 817                         mv_votes[i] = -1;
 818         }
 819
 820         mv_ownvote = ReadByte()-1;
 821 }
 822
 823 void Ent_MapVote()
 824 {
 825         int sf = ReadByte();
 826
 827         if(sf & 1)
 828                 MapVote_Init();
 829
 830         if(sf & 2)
 831                 MapVote_UpdateMask();
 832
 833         if(sf & 4)
 834                 MapVote_UpdateVotes();
 835 }
 836
 837 void Net_MapVote_Picture()
 838 {
 839         int type = ReadByte();
 840         mv_preview[type] = true;
 841         mv_pics[type] = strzone(ReadPicture());
 842 }