qcsrc/client/player_skeleton.qc

   1 #if defined(CSQC)
   2         #include "../dpdefs/csprogsdefs.qc"
   3         #include "../common/util.qh"
   4         #include "../csqcmodellib/interpolate.qh"
   5         #include "player_skeleton.qh"
   6 #elif defined(MENUQC)
   7 #elif defined(SVQC)
   8 #endif
   9
  10 .float skeleton_info_modelindex;
  11 .float skeleton_info_skin;
  12 const int BONETYPE_LOWER = 0;
  13 const int BONETYPE_UPPER = 1;
  14 const int MAX_BONES = 128;
  15 .float skeleton_bonetype[MAX_BONES];
  16 .float skeleton_numbones;
  17
  18 void skeleton_loadinfo(entity e)
  19 {
  20         int i;
  21         if(e.skeleton_info_modelindex == e.modelindex && e.skeleton_info_skin == e.skin)
  22                 return;
  23         e.bone_upperbody = 0;
  24         e.bone_weapon = gettagindex(e, "weapon");
  25         if(!e.bone_weapon)
  26                 e.bone_weapon = gettagindex(e, "tag_weapon");
  27         if(!e.bone_weapon)
  28                 e.bone_weapon = gettagindex(e, "bip01 r hand");
  29         for(i = 0; i < MAX_AIM_BONES; ++i)
  30         {
  31                 e.(bone_aim[i]) = 0;
  32                 e.(bone_aimweight[i]) = 0;
  33         }
  34         e.fixbone = 0;
  35         if(get_model_parameters(e.model, e.skin))
  36         {
  37                 if(get_model_parameters_bone_upperbody)
  38                         e.bone_upperbody = gettagindex(e, get_model_parameters_bone_upperbody);
  39                 if(e.bone_upperbody)
  40                         e.fixbone = get_model_parameters_fixbone;
  41                 if(get_model_parameters_bone_weapon)
  42                         e.bone_weapon = gettagindex(e, get_model_parameters_bone_weapon);
  43                 for(i = 0; i < MAX_AIM_BONES; ++i)
  44                 {
  45                         if(get_model_parameters_bone_aim[i])
  46                                 e.(bone_aim[i]) = gettagindex(e, get_model_parameters_bone_aim[i]);
  47                         if(e.bone_aim[i])
  48                                 e.(bone_aimweight[i]) = get_model_parameters_bone_aimweight[i];
  49                 }
  50         }
  51         else
  52                 dprint("No model parameters for ", e.model, "\n");
  53         dprint(e.model, " uses ", ftos(e.bone_upperbody), " ", ftos(e.fixbone), "\n");
  54         get_model_parameters(string_null, 0);
  55         e.skeleton_info_modelindex = e.modelindex;
  56         e.skeleton_info_skin = e.skin;
  57         if(e.skeletonindex)
  58         {
  59                 skel_delete(e.skeletonindex);
  60                 e.skeletonindex = 0;
  61         }
  62 }
  63
  64 void skeleton_markbones(entity e)
  65 {
  66         float s = e.skeletonindex;
  67         float n = (e.skeleton_numbones = skel_get_numbones(s));
  68         int i;
  69         for(i = 1; i <= n; ++i)
  70         {
  71                 float t = BONETYPE_LOWER;
  72                 int p = skel_get_boneparent(s, i);
  73                 if(p > 0)
  74                         t = e.(skeleton_bonetype[p-1]);
  75                 if(i == e.bone_upperbody)
  76                         t = BONETYPE_UPPER;
  77                 e.(skeleton_bonetype[i-1]) = t;
  78         }
  79 }
  80
  81 void skel_set_boneabs(float s, float bone, vector absorg)
  82 {
  83         vector absang = fixedvectoangles2(v_forward, v_up);
  84
  85         vector parentorg = skel_get_boneabs(s, skel_get_boneparent(s, bone));
  86         vector parentang = fixedvectoangles2(v_forward, v_up);
  87
  88         vector relang = AnglesTransform_LeftDivide(parentang, absang);
  89         vector relorg = AnglesTransform_Apply(AnglesTransform_Invert(parentang), absorg - parentorg);
  90
  91         fixedmakevectors(relang);
  92         skel_set_bone(s, bone, relorg);
  93
  94         /*
  95         vector neworg = skel_get_boneabs(s, bone);
  96         printf("ANG: want: %v, got: %v\n", absang, fixedvectoangles2(v_forward, v_up));
  97         printf("ORG: want: %v, got: %v\n", absorg, neworg);
  98         */
  99 }
 100
 101 void free_skeleton_from_frames(entity e)
 102 {
 103         if(e.skeletonindex)
 104         {
 105                 skel_delete(e.skeletonindex);
 106                 e.skeletonindex = 0;
 107         }
 108 }
 109
 110 void skeleton_from_frames(entity e, float is_dead)
 111 {
 112         float m = e.modelindex;
 113         if(!e.skeletonindex)
 114         {
 115                 e.skeletonindex = skel_create(m);
 116                 skeleton_markbones(e);
 117         }
 118         float s = e.skeletonindex;
 119         if(!s)
 120                 return;
 121         float n = e.skeleton_numbones;
 122         float savelerpfrac = e.lerpfrac;
 123         float savelerpfrac3 = e.lerpfrac3;
 124         float savelerpfrac4 = e.lerpfrac4;
 125
 126         vector fixbone_oldangles = '0 0 0';
 127         if(e.fixbone)
 128         {
 129                 // make all bones BONETYPE_UPPER
 130                 e.lerpfrac = 0;
 131                 e.lerpfrac3 = savelerpfrac3 * 2;
 132                 e.lerpfrac4 = 0;
 133                 // build skeleton
 134                 skel_build(s, e, m, 0, 1, n);
 135                 // get hip bone
 136                 skel_get_boneabs(s, e.bone_upperbody);
 137                 fixbone_oldangles = fixedvectoangles2(v_forward, v_up);
 138         }
 139         int bone;
 140         for(bone = 0; bone < n; )
 141         {
 142                 float firstbone = bone;
 143                 float bonetype = e.skeleton_bonetype[bone];
 144                 for(++bone; (bone < n) && (e.skeleton_bonetype[bone] == bonetype); ++bone)
 145                         ;
 146                 if(bonetype == BONETYPE_UPPER)
 147                 {
 148                         // only show frames 1+3 (upper body)
 149                         e.lerpfrac = 0;
 150                         e.lerpfrac3 = savelerpfrac3 * 2;
 151                         e.lerpfrac4 = 0;
 152                 }
 153                 else
 154                 {
 155                         // only show frames 2+4 (lower body)
 156                         e.lerpfrac = savelerpfrac * 2;
 157                         e.lerpfrac3 = 0;
 158                         e.lerpfrac4 = savelerpfrac4 * 2;
 159                 }
 160                 //printf("Run: bone %d to %d, type %d\n", firstbone + 1, bone, bonetype);
 161                 //printf("frame %d %d %d %d lerpfrac * %d %d %d\n", e.frame, e.frame2, e.frame3, e.frame4, e.lerpfrac, e.lerpfrac3, e.lerpfrac4);
 162                 skel_build(s, e, m, 0, firstbone + 1, bone);
 163         }
 164         e.lerpfrac = savelerpfrac;
 165         e.lerpfrac3 = savelerpfrac3;
 166         e.lerpfrac4 = savelerpfrac4;
 167
 168         if(e.fixbone)
 169         {
 170                 // FIX IT
 171                 vector org = skel_get_boneabs(s, e.bone_upperbody);
 172                 fixedmakevectors(fixbone_oldangles);
 173                 skel_set_boneabs(s, e.bone_upperbody, org);
 174         }
 175
 176         if(!is_dead)
 177         {
 178                 int i;
 179                 for(i = 0; i < MAX_AIM_BONES; ++i)
 180                 {
 181                         if(e.(bone_aim[i]))
 182                         {
 183                                 vector aim = '1 0 0' * bound(-90, self.v_angle.x, 90) * e.(bone_aimweight[i]);
 184                                 vector org = skel_get_boneabs(s, e.(bone_aim[i]));
 185                                 vector ang_cur = fixedvectoangles2(v_forward, v_up);
 186                                 vector ang = AnglesTransform_Multiply(aim, ang_cur);
 187                                 fixedmakevectors(ang);
 188                                 skel_set_boneabs(s, e.(bone_aim[i]), org);
 189                         }
 190                 }
 191         }
 192 }