qcsrc/client/shownames.qc

   1 // self.isactive = player is in range and coordinates/status (health and armor) are up to date
   2 // self.origin = player origin TODO: should maybe move this so it's the origin of the shownames tag already in SSQC for culling?
   3 // self.healthvalue
   4 // self.armorvalue
   5 // self.sameteam = player is on same team as local client
   6 //
   7 const float SHOWNAMES_FADESPEED = 4;
   8 void Draw_ShowNames(entity ent)
   9 {
  10         if(!autocvar_hud_shownames)
  11                 return;
  12
  13         if(ent.sv_entnum == player_localentnum && !autocvar_chase_active)
  14                 return;
  15
  16         if(ent.sameteam || (!ent.sameteam && autocvar_hud_shownames_enemies))
  17         {
  18                 ent.origin_z += autocvar_hud_shownames_offset;
  19
  20                 if(!ent.sameteam)
  21                 {
  22                         /* WIP, why does trace_ent != ent not work as intended here?
  23                            if(autocvar_hud_shownames_enemies != 2) // player has to point at enemy if so
  24                            {
  25                            traceline(view_origin, view_origin + view_forward * MAX_SHOT_DISTANCE, MOVETYPE_FLY, world);
  26                            print("trace_endpos: ", vtos(trace_endpos), " view_origin: ", vtos(view_origin), "\n");
  27                            if(trace_ent != ent)
  28                            return;
  29                            }*/
  30
  31                         traceline(ent.origin, view_origin, 1, ent);
  32                 }
  33
  34                 vector o, eo;
  35                 o = project_3d_to_2d(ent.origin);
  36                 float overlap;
  37
  38                 if(autocvar_hud_shownames_antioverlap)
  39                 {
  40                         // fade tag out if another tag that is closer to you overlaps
  41                         entity e;
  42                         for(e = world; (e = find(e, classname, "shownames_tag")); )
  43                         {
  44                                 if(e == ent)
  45                                         continue;
  46                                 eo = project_3d_to_2d(e.origin);
  47                                 if not(eo_z < 0 || eo_x < 0 || eo_y < 0 || eo_x > vid_conwidth || eo_y > vid_conheight)
  48                                 {
  49                                         eo_z = 0;
  50                                         if(vlen((eX * o_x + eY * o_y) - eo) < autocvar_hud_shownames_antioverlap_distance && vlen(ent.origin - view_origin) > vlen(e.origin - view_origin))
  51                                         {
  52                                                 overlap = TRUE;
  53                                                 break;
  54                                         }
  55                                 }
  56                         }
  57                 }
  58
  59                 if(!ent.sameteam && trace_endpos != view_origin) // out of view, fade out
  60                         ent.alpha = max(0, ent.alpha - SHOWNAMES_FADESPEED * frametime);
  61                 else if(ent.healthvalue < 1) // dead player, fade out slowly
  62                         ent.alpha = max(0, ent.alpha - SHOWNAMES_FADESPEED * 0.25 * frametime);
  63                 else if(overlap) // tag overlap detected, fade out
  64                         ent.alpha = max(0, ent.alpha - SHOWNAMES_FADESPEED * frametime);
  65                 else // fade in
  66                         ent.alpha = min(1, ent.alpha + SHOWNAMES_FADESPEED * frametime);
  67
  68                 if(!ent.alpha)
  69                         return;
  70
  71                 float dist;
  72                 dist = vlen(ent.origin - view_origin);
  73
  74                 float a;
  75                 a = autocvar_hud_shownames_alpha;
  76                 a *= ent.alpha;
  77                 if(autocvar_hud_shownames_maxdistance)
  78                 {
  79                         if(dist >= autocvar_hud_shownames_maxdistance)
  80                                 return;
  81                         a *= ((autocvar_hud_shownames_maxdistance - autocvar_hud_shownames_mindistance) - max(0, dist - autocvar_hud_shownames_mindistance)) / (autocvar_hud_shownames_maxdistance - autocvar_hud_shownames_mindistance);
  82                 }
  83
  84                 if(!a)
  85                         return;
  86
  87                 float resize;
  88                 resize = 1;
  89                 if(autocvar_hud_shownames_resize) // limit resize so its never smaller than 0.5... gets unreadable
  90                         resize = 0.5 + 0.5 * ((autocvar_hud_shownames_maxdistance - autocvar_hud_shownames_mindistance) - max(0, dist - autocvar_hud_shownames_mindistance)) / (autocvar_hud_shownames_maxdistance - autocvar_hud_shownames_mindistance);
  91
  92                 // draw the sprite image
  93                 if not(o_z < 0 || o_x < 0 || o_y < 0 || o_x > vid_conwidth || o_y > vid_conheight)
  94                 {
  95                         o_z = 0;
  96
  97                         vector myPos, mySize;
  98                         mySize = (eX * autocvar_hud_shownames_aspect + eY) * autocvar_hud_shownames_fontsize;
  99                         myPos = o - '0.5 0 0' * mySize_x - '0 1 0' * mySize_y;
 100
 101                         // size scaling
 102                         mySize_x *= resize;
 103                         mySize_y *= resize;
 104
 105                         myPos_x += 0.5 * (mySize_x / resize - mySize_x);
 106                         myPos_y += (mySize_y / resize - mySize_y);
 107
 108                         vector namepos; // this is where the origin of the string
 109                         float namewidth;
 110
 111                         namepos = myPos;
 112                         namewidth = mySize_x;
 113
 114                         if(autocvar_hud_shownames_status && teamplay)
 115                         {
 116                                 if(ent.sameteam)
 117                                 {
 118                                         if(ent.healthvalue > 0)
 119                                         {
 120                                                 HUD_Panel_DrawProgressBar(namepos + '0 1 0' * autocvar_hud_shownames_fontsize * resize, eX * 0.5 * mySize_x + eY * resize * autocvar_hud_shownames_statusbar_height, "nametag_statusbar", ent.healthvalue/autocvar_hud_panel_healtharmor_maxhealth, 0, 1, '1 0 0', a, DRAWFLAG_NORMAL);
 121
 122                                                 if(ent.armorvalue > 0)
 123                                                         HUD_Panel_DrawProgressBar(namepos + '0 1 0' * autocvar_hud_shownames_fontsize * resize + eX * 0.5 * mySize_x, eX * 0.5 * mySize_x + eY * resize * autocvar_hud_shownames_statusbar_height, "nametag_statusbar", ent.armorvalue/autocvar_hud_panel_healtharmor_maxarmor, 0, 0, '0 1 0', a, DRAWFLAG_NORMAL);
 124                                         }
 125                                 }
 126                         }
 127
 128                         string s;
 129                         s = GetPlayerName(ent.sv_entnum-1);
 130                         if((autocvar_hud_shownames_decolorize == 1 && teamplay) || autocvar_hud_shownames_decolorize == 2)
 131                                 s = playername(s, GetPlayerColor(ent.sv_entnum-1));
 132
 133                         drawfontscale = '1 1 0' * resize;
 134                         s = textShortenToWidth(s, namewidth, '1 1 0' * autocvar_hud_shownames_fontsize, stringwidth_colors);
 135
 136                         float width;
 137                         width = stringwidth(s, TRUE, '1 1 0' * autocvar_hud_shownames_fontsize);
 138
 139                         if (width != namewidth)
 140                                 namepos_x += (namewidth - width) / 2;
 141                         drawcolorcodedstring(namepos, s, '1 1 0' * autocvar_hud_shownames_fontsize, a, DRAWFLAG_NORMAL);
 142                         drawfontscale = '1 1 0';
 143                 }
 144         }
 145 }
 146
 147 entity shownames_ent[255];
 148 void Draw_ShowNames_All()
 149 {
 150         float i;
 151         for(i = 0; i < maxclients; ++i)
 152         {
 153                 vector o;
 154                 float t;
 155                 t = GetPlayerColor(i);
 156                 if(t == COLOR_SPECTATOR)
 157                         continue;
 158
 159                 entity e;
 160                 e = shownames_ent[i];
 161                 if(!e)
 162                 {
 163                         e = spawn();
 164                         e.classname = "shownames_tag";
 165                         e.sv_entnum = i+1;
 166                         shownames_ent[i] = e;
 167                 }
 168
 169                 entity entcs;
 170                 entcs = entcs_receiver[i];
 171                 if(entcs)
 172                 {
 173                         e.healthvalue = entcs.healthvalue;
 174                         e.armorvalue = entcs.armorvalue;
 175                         e.sameteam = 1; /* (teamplay && (t == myteam)); */
 176                 }
 177                 else
 178                 {
 179                         e.healthvalue = 2342;
 180                         e.armorvalue = 0;
 181                         e.sameteam = 0;
 182                 }
 183
 184                 e.origin = getplayerorigin(i);
 185                 if(e.origin == GETPLAYERORIGIN_ERROR)
 186                         continue;
 187
 188                 Draw_ShowNames(e);
 189         }
 190 }