Fix hud_shownames_antioverlap not ignoring spectators
[xonotic/xonotic-data.pk3dir.git] / qcsrc / client / shownames.qc
1 #include "shownames.qh"
2
3 #include "hud/_mod.qh"
4
5 #include <common/ent_cs.qh>
6 #include <common/constants.qh>
7 #include <common/net_linked.qh>
8 #include <common/mapinfo.qh>
9 #include <common/teams.qh>
10
11 #include <lib/csqcmodel/cl_model.qh>
12
13 // this.isactive = player is in range and coordinates/status (health and armor) are up to date
14 // this.origin = player origin
15 // this.healthvalue
16 // this.armorvalue
17 // this.sameteam = player is on same team as local client
18 // this.fadedelay = time to wait before name tag starts fading in for enemies
19 // this.pointtime = last time you pointed at this player
20 // this.csqcmodel_isdead = value of csqcmodel_isdead to know when the player is dead or not
21
22 LinkedList shownames_ent;
23 STATIC_INIT(shownames_ent)
24 {
25         shownames_ent = LL_NEW();
26         for (int i = 0; i < maxclients; ++i)
27         {
28                 entity e = new_pure(shownames_tag);
29                 e.sv_entnum = i + 1;
30                 LL_PUSH(shownames_ent, e);
31         }
32 }
33
34 const float SHOWNAMES_FADESPEED = 4;
35 const float SHOWNAMES_FADEDELAY = 0.4;
36 void Draw_ShowNames(entity this)
37 {
38         if (this.sv_entnum == (current_player + 1))  // self or spectatee
39                 if (!(autocvar_hud_shownames_self && autocvar_chase_active)) return;
40         if (!this.sameteam && !autocvar_hud_shownames_enemies) return;
41         bool hit;
42         if (!autocvar_hud_shownames_crosshairdistance && this.sameteam)
43         {
44                 hit = true;
45         }
46         else
47         {
48                 traceline(view_origin, this.origin, MOVE_NORMAL, this);
49                 hit = !(trace_fraction < 1 && (trace_networkentity != this.sv_entnum && trace_ent.entnum != this.sv_entnum));
50         }
51         // handle tag fading
52         bool overlap = false;
53         vector o = project_3d_to_2d(this.origin + eZ * autocvar_hud_shownames_offset);
54         float dist = vlen(this.origin - view_origin);
55         if (autocvar_hud_shownames_antioverlap)
56         {
57                 // fade tag out if another tag that is closer to you overlaps
58                 entity entcs = NULL;
59                 LL_EACH(shownames_ent, it != this, {
60                         entcs = entcs_receiver(i);
61                         if (!(entcs && entcs.has_sv_origin))
62                                 continue;
63                         vector eo = project_3d_to_2d(it.origin);
64                         if (eo.z < 0 || eo.x < 0 || eo.y < 0 || eo.x > vid_conwidth || eo.y > vid_conheight) continue;
65                         eo.z = 0;
66                         if (vdist(((eX * o.x + eY * o.y) - eo), <, autocvar_hud_shownames_antioverlap_distance)
67                             && vdist((it.origin - view_origin), <, dist))
68                         {
69                                 overlap = true;
70                                 break;
71                         }
72                 });
73         }
74         bool onscreen = (o.z >= 0 && o.x >= 0 && o.y >= 0 && o.x <= vid_conwidth && o.y <= vid_conheight);
75         if (autocvar_hud_shownames_crosshairdistance)
76         {
77                 float d = autocvar_hud_shownames_crosshairdistance;
78                 float w = o.x - vid_conwidth / 2;
79                 float h = o.y - vid_conheight / 2;
80                 if (d * d > w * w + h * h) this.pointtime = time;
81                 if (this.pointtime + autocvar_hud_shownames_crosshairdistance_time <= time) overlap = true;
82                 else overlap = (autocvar_hud_shownames_crosshairdistance_antioverlap ? overlap : false); // override what antioverlap says unless allowed by cvar.
83         }
84         if (!this.fadedelay) this.fadedelay = time + SHOWNAMES_FADEDELAY;
85         if (this.csqcmodel_isdead)                                                                   // dead player, fade out slowly
86         {
87                 this.alpha = max(0, this.alpha - SHOWNAMES_FADESPEED * 0.25 * frametime);
88         }
89         else if (!onscreen || (!this.sameteam && !hit)) // out of view, fade out
90         {
91                 this.alpha = max(0, this.alpha - SHOWNAMES_FADESPEED * frametime);
92                 this.fadedelay = 0;                         // reset fade in delay, enemy has left the view
93         }
94         else if (overlap)                               // tag overlap detected, fade out
95         {
96                 this.alpha = max(0, this.alpha - SHOWNAMES_FADESPEED * frametime);
97         }
98         else if (this.sameteam)  // fade in for team mates
99         {
100                 this.alpha = min(1, this.alpha + SHOWNAMES_FADESPEED * frametime);
101         }
102         else if (time > this.fadedelay)  // fade in for enemies
103         {
104                 this.alpha = min(1, this.alpha + SHOWNAMES_FADESPEED * frametime);
105         }
106         float a = autocvar_hud_shownames_alpha * this.alpha;
107         // multiply by player alpha
108         if (!this.sameteam || (this.sv_entnum == player_localentnum))
109         {
110                 float f = entcs_GetAlpha(this.sv_entnum - 1);
111                 if (f == 0) f = 1;
112                 if (f < 0) f = 0;
113                 // FIXME: alpha is negative when dead, breaking death fade
114                 if (!this.csqcmodel_isdead) a *= f;
115         }
116         if (a < ALPHA_MIN_VISIBLE && gametype != MAPINFO_TYPE_CTS) return;
117         if (autocvar_hud_shownames_maxdistance)
118         {
119                 if (dist >= autocvar_hud_shownames_maxdistance) return;
120                 float f = autocvar_hud_shownames_maxdistance - autocvar_hud_shownames_mindistance;
121                 a *= (f - max(0, dist - autocvar_hud_shownames_mindistance)) / f;
122         }
123         if (!a) return;
124         float resize = 1;
125         if (autocvar_hud_shownames_resize)  // limit resize so its never smaller than 0.5... gets unreadable
126         {
127                 float f = autocvar_hud_shownames_maxdistance - autocvar_hud_shownames_mindistance;
128                 resize = 0.5 + 0.5 * (f - max(0, dist - autocvar_hud_shownames_mindistance)) / f;
129         }
130         // draw the sprite image
131         if (o.z >= 0)
132         {
133                 o.z = 0;
134                 vector mySize = (eX * autocvar_hud_shownames_aspect + eY) * autocvar_hud_shownames_fontsize;
135                 vector myPos = o - '0.5 0 0' * mySize.x - '0 1 0' * mySize.y;
136                 // size scaling
137                 mySize.x *= resize;
138                 mySize.y *= resize;
139                 myPos.x += 0.5 * (mySize.x / resize - mySize.x);
140                 myPos.y += (mySize.y / resize - mySize.y);
141                 // this is where the origin of the string
142                 vector namepos = myPos;
143                 float namewidth = mySize.x;
144                 if (autocvar_hud_shownames_status && this.sameteam)
145                 {
146                         vector v = namepos + '0 1 0' * autocvar_hud_shownames_fontsize * resize;
147                         vector s = eX * 0.5 * mySize.x + eY * resize * autocvar_hud_shownames_statusbar_height;
148                         if (this.healthvalue > 0)
149                         {
150                                 HUD_Panel_DrawProgressBar(v, s, "nametag_statusbar",
151                                         this.healthvalue / autocvar_hud_panel_healtharmor_maxhealth, false, 1, '1 0 0', a,
152                                         DRAWFLAG_NORMAL);
153                         }
154                         if (this.armorvalue > 0)
155                         {
156                                 HUD_Panel_DrawProgressBar(v + eX * 0.5 * mySize.x, s, "nametag_statusbar",
157                                         this.armorvalue / autocvar_hud_panel_healtharmor_maxarmor, false, 0, '0 1 0', a,
158                                         DRAWFLAG_NORMAL);
159                         }
160                 }
161                 string s = entcs_GetName(this.sv_entnum - 1);
162                 if ((autocvar_hud_shownames_decolorize == 1 && teamplay)
163                     || autocvar_hud_shownames_decolorize == 2) s = playername(s, entcs_GetTeam(this.sv_entnum - 1));
164                 drawfontscale = '1 1 0' * resize;
165                 s = textShortenToWidth(s, namewidth, '1 1 0' * autocvar_hud_shownames_fontsize, stringwidth_colors);
166                 float width = stringwidth(s, true, '1 1 0' * autocvar_hud_shownames_fontsize);
167                 if (width != namewidth) namepos.x += (namewidth - width) / 2;
168                 drawcolorcodedstring(namepos, s, '1 1 0' * autocvar_hud_shownames_fontsize, a, DRAWFLAG_NORMAL);
169                 drawfontscale = '1 1 0';
170         }
171 }
172
173 void Draw_ShowNames_All()
174 {
175         if (!autocvar_hud_shownames) return;
176         LL_EACH(shownames_ent, true, {
177                 entity entcs = entcs_receiver(i);
178                 if (!entcs)
179                 {
180                         make_pure(it);
181                         continue;
182                 }
183                 make_impure(it);
184                 assert(getthink(entcs), eprint(entcs));
185                 getthink(entcs)(entcs);
186                 if (!entcs.has_origin) continue;
187                 if (entcs.m_entcs_private)
188                 {
189                         it.healthvalue = entcs.healthvalue;
190                         it.armorvalue = entcs.armorvalue;
191                         it.sameteam = true;
192                 }
193                 else
194                 {
195                         it.healthvalue = 0;
196                         it.armorvalue = 0;
197                         it.sameteam = false;
198                 }
199                 bool dead = entcs_IsDead(i) || entcs_IsSpectating(i);
200                 if (!it.csqcmodel_isdead) setorigin(it, entcs.origin);
201                 it.csqcmodel_isdead = dead;
202                 Draw_ShowNames(it);
203         });
204 }