qcsrc/client/shownames.qc

   1 // self.isactive = player is in range and coordinates/status (health and armor) are up to date
   2 // self.origin = player origin TODO: should maybe move this so it's the origin of the shownames tag already in SSQC for culling?
   3 // self.healthvalue
   4 // self.armorvalue
   5 // self.sameteam = player is on same team as local client
   6 // self.fadedelay = time to wait before name tag starts fading in for enemies
   7 //
   8 const float SHOWNAMES_FADESPEED = 4;
   9 const float SHOWNAMES_FADEDELAY = 0.5;
  10 void Draw_ShowNames(entity ent)
  11 {
  12         if(!autocvar_hud_shownames)
  13                 return;
  14
  15         if((ent.sv_entnum == player_localentnum) || (ent.sv_entnum == spectatee_status)) // ent is me or person i'm spectating
  16                 if not (autocvar_hud_shownames_self && autocvar_chase_active)
  17                         return;
  18
  19         makevectors(view_angles);
  20
  21         if(ent.sameteam || (!ent.sameteam && autocvar_hud_shownames_enemies))
  22         {
  23                 ent.origin_z += autocvar_hud_shownames_offset;
  24
  25                 float hit;
  26                 if(ent.sameteam)
  27                 {
  28                         hit = 1;
  29                 }
  30                 else
  31                 {
  32                         traceline(view_origin, ent.origin, MOVE_NORMAL, ent);
  33                         if(trace_fraction < 1 && trace_networkentity != ent.sv_entnum)
  34                                 hit = 0;
  35                         else
  36                                 hit = 1;
  37                 }
  38
  39                 vector o, eo;
  40                 o = project_3d_to_2d(ent.origin);
  41                 float overlap, onscreen;
  42
  43                 if(autocvar_hud_shownames_antioverlap)
  44                 {
  45                         // fade tag out if another tag that is closer to you overlaps
  46                         entity e;
  47                         for(e = world; (e = find(e, classname, "shownames_tag")); )
  48                         {
  49                                 if(e == ent)
  50                                         continue;
  51                                 eo = project_3d_to_2d(e.origin);
  52                                 if not(eo_z < 0 || eo_x < 0 || eo_y < 0 || eo_x > vid_conwidth || eo_y > vid_conheight)
  53                                 {
  54                                         eo_z = 0;
  55                                         if(vlen((eX * o_x + eY * o_y) - eo) < autocvar_hud_shownames_antioverlap_distance && vlen(ent.origin - view_origin) > vlen(e.origin - view_origin))
  56                                         {
  57                                                 overlap = TRUE;
  58                                                 break;
  59                                         }
  60                                 }
  61                         }
  62                 }
  63
  64                 onscreen = (o_z >= 0 && o_x >= 0 && o_y >= 0 && o_x <= vid_conwidth && o_y <= vid_conheight);
  65
  66                 if(!ent.fadedelay)
  67                         ent.fadedelay = time + SHOWNAMES_FADEDELAY;
  68
  69                 if(!ent.sameteam && (!onscreen || !hit)) // out of view, fade out
  70                 {
  71                         ent.alpha = max(0, ent.alpha - SHOWNAMES_FADESPEED * frametime);
  72                         ent.fadedelay = 0; // reset fade in delay, enemy has left the view
  73                 }
  74                 else if(ent.healthvalue < 1) // dead player, fade out slowly
  75                         ent.alpha = max(0, ent.alpha - SHOWNAMES_FADESPEED * 0.25 * frametime);
  76                 else if(overlap) // tag overlap detected, fade out
  77                         ent.alpha = max(0, ent.alpha - SHOWNAMES_FADESPEED * frametime);
  78                 else if(ent.sameteam) // fade in for team mates
  79                         ent.alpha = min(1, ent.alpha + SHOWNAMES_FADESPEED * frametime);
  80                 else if(time > ent.fadedelay) // fade in for enemies
  81                         ent.alpha = min(1, ent.alpha + SHOWNAMES_FADESPEED * frametime);
  82
  83                 if(!ent.alpha)
  84                         return;
  85
  86                 float dist;
  87                 dist = vlen(ent.origin - view_origin);
  88
  89                 float a;
  90                 a = autocvar_hud_shownames_alpha;
  91                 a *= ent.alpha;
  92                 if(autocvar_hud_shownames_maxdistance)
  93                 {
  94                         if(dist >= autocvar_hud_shownames_maxdistance)
  95                                 return;
  96                         a *= ((autocvar_hud_shownames_maxdistance - autocvar_hud_shownames_mindistance) - max(0, dist - autocvar_hud_shownames_mindistance)) / (autocvar_hud_shownames_maxdistance - autocvar_hud_shownames_mindistance);
  97                 }
  98
  99                 if(!a)
 100                         return;
 101
 102                 float resize;
 103                 resize = 1;
 104                 if(autocvar_hud_shownames_resize) // limit resize so its never smaller than 0.5... gets unreadable
 105                         resize = 0.5 + 0.5 * ((autocvar_hud_shownames_maxdistance - autocvar_hud_shownames_mindistance) - max(0, dist - autocvar_hud_shownames_mindistance)) / (autocvar_hud_shownames_maxdistance - autocvar_hud_shownames_mindistance);
 106
 107                 // draw the sprite image
 108                 if(o_z >= 0)
 109                 {
 110                         o_z = 0;
 111
 112                         vector myPos, mySize;
 113                         mySize = (eX * autocvar_hud_shownames_aspect + eY) * autocvar_hud_shownames_fontsize;
 114                         myPos = o - '0.5 0 0' * mySize_x - '0 1 0' * mySize_y;
 115
 116                         // size scaling
 117                         mySize_x *= resize;
 118                         mySize_y *= resize;
 119
 120                         myPos_x += 0.5 * (mySize_x / resize - mySize_x);
 121                         myPos_y += (mySize_y / resize - mySize_y);
 122
 123                         vector namepos; // this is where the origin of the string
 124                         float namewidth;
 125
 126                         namepos = myPos;
 127                         namewidth = mySize_x;
 128
 129                         if(autocvar_hud_shownames_status && teamplay)
 130                         {
 131                                 if(ent.sameteam)
 132                                 {
 133                                         if(ent.healthvalue > 0)
 134                                         {
 135                                                 HUD_Panel_DrawProgressBar(namepos + '0 1 0' * autocvar_hud_shownames_fontsize * resize, eX * 0.5 * mySize_x + eY * resize * autocvar_hud_shownames_statusbar_height, "nametag_statusbar", ent.healthvalue/autocvar_hud_panel_healtharmor_maxhealth, 0, 1, '1 0 0', a, DRAWFLAG_NORMAL);
 136
 137                                                 if(ent.armorvalue > 0)
 138                                                         HUD_Panel_DrawProgressBar(namepos + '0 1 0' * autocvar_hud_shownames_fontsize * resize + eX * 0.5 * mySize_x, eX * 0.5 * mySize_x + eY * resize * autocvar_hud_shownames_statusbar_height, "nametag_statusbar", ent.armorvalue/autocvar_hud_panel_healtharmor_maxarmor, 0, 0, '0 1 0', a, DRAWFLAG_NORMAL);
 139                                         }
 140                                 }
 141                         }
 142
 143                         string s;
 144                         s = GetPlayerName(ent.sv_entnum-1);
 145                         if((autocvar_hud_shownames_decolorize == 1 && teamplay) || autocvar_hud_shownames_decolorize == 2)
 146                                 s = playername(s, GetPlayerColor(ent.sv_entnum-1));
 147
 148                         drawfontscale = '1 1 0' * resize;
 149                         s = textShortenToWidth(s, namewidth, '1 1 0' * autocvar_hud_shownames_fontsize, stringwidth_colors);
 150
 151                         float width;
 152                         width = stringwidth(s, TRUE, '1 1 0' * autocvar_hud_shownames_fontsize);
 153
 154                         if (width != namewidth)
 155                                 namepos_x += (namewidth - width) / 2;
 156                         drawcolorcodedstring(namepos, s, '1 1 0' * autocvar_hud_shownames_fontsize, a, DRAWFLAG_NORMAL);
 157                         drawfontscale = '1 1 0';
 158                 }
 159         }
 160 }
 161
 162 entity shownames_ent[255];
 163 void Draw_ShowNames_All()
 164 {
 165         float i;
 166         for(i = 0; i < maxclients; ++i)
 167         {
 168                 float t;
 169                 t = GetPlayerColor(i);
 170                 if(t == COLOR_SPECTATOR)
 171                         continue;
 172
 173                 entity e;
 174                 e = shownames_ent[i];
 175                 if(!e)
 176                 {
 177                         e = spawn();
 178                         e.classname = "shownames_tag";
 179                         e.sv_entnum = i+1;
 180                         shownames_ent[i] = e;
 181                 }
 182
 183                 entity entcs;
 184                 entcs = entcs_receiver[i];
 185                 if(entcs)
 186                 {
 187                         e.healthvalue = entcs.healthvalue;
 188                         e.armorvalue = entcs.armorvalue;
 189                         e.sameteam = 1; /* (teamplay && (t == myteam)); */
 190                 }
 191                 else
 192                 {
 193                         e.healthvalue = 2342;
 194                         e.armorvalue = 0;
 195                         e.sameteam = 0;
 196                 }
 197
 198                 e.origin = getplayerorigin(i);
 199                 if(e.origin == GETPLAYERORIGIN_ERROR)
 200                         continue;
 201
 202                 Draw_ShowNames(e);
 203         }
 204 }