qcsrc/client/shownames.qc

   1 // self.isactive = player is in range and coordinates/status (health and armor) are up to date
   2 // self.origin = player origin TODO: should maybe move this so it's the origin of the shownames tag already in SSQC for culling?
   3 // self.healthvalue
   4 // self.armorvalue
   5 // self.sameteam = player is on same team as local client
   6 //
   7 const float SHOWNAMES_FADESPEED = 4;
   8 void Draw_ShowNames(entity ent)
   9 {
  10         if(!autocvar_hud_shownames)
  11                 return;
  12
  13         if(ent.sv_entnum == player_localentnum && !autocvar_chase_active)
  14                 return;
  15
  16         makevectors(view_angles);
  17
  18         if(ent.sameteam || (!ent.sameteam && autocvar_hud_shownames_enemies))
  19         {
  20                 ent.origin_z += autocvar_hud_shownames_offset;
  21
  22                 if(!ent.sameteam)
  23                         traceline(ent.origin, view_origin, 1, ent);
  24
  25                 vector o, eo;
  26                 o = project_3d_to_2d(ent.origin);
  27                 float overlap, onscreen;
  28
  29                 if(autocvar_hud_shownames_antioverlap)
  30                 {
  31                         // fade tag out if another tag that is closer to you overlaps
  32                         entity e;
  33                         for(e = world; (e = find(e, classname, "shownames_tag")); )
  34                         {
  35                                 if(e == ent)
  36                                         continue;
  37                                 eo = project_3d_to_2d(e.origin);
  38                                 if not(eo_z < 0 || eo_x < 0 || eo_y < 0 || eo_x > vid_conwidth || eo_y > vid_conheight)
  39                                 {
  40                                         eo_z = 0;
  41                                         if(vlen((eX * o_x + eY * o_y) - eo) < autocvar_hud_shownames_antioverlap_distance && vlen(ent.origin - view_origin) > vlen(e.origin - view_origin))
  42                                         {
  43                                                 overlap = TRUE;
  44                                                 break;
  45                                         }
  46                                 }
  47                         }
  48                 }
  49
  50                 onscreen = (o_z >= 0 && o_x >= 0 && o_y >= 0 && o_x <= vid_conwidth && o_y <= vid_conheight);
  51
  52                 if(!ent.sameteam && (!onscreen || trace_endpos != view_origin)) // out of view, fade out
  53                         ent.alpha = max(0, ent.alpha - SHOWNAMES_FADESPEED * frametime);
  54                 else if(ent.healthvalue < 1) // dead player, fade out slowly
  55                         ent.alpha = max(0, ent.alpha - SHOWNAMES_FADESPEED * 0.25 * frametime);
  56                 else if(overlap) // tag overlap detected, fade out
  57                         ent.alpha = max(0, ent.alpha - SHOWNAMES_FADESPEED * frametime);
  58                 else // fade in
  59                         ent.alpha = min(1, ent.alpha + SHOWNAMES_FADESPEED * frametime);
  60
  61                 if(!ent.alpha)
  62                         return;
  63
  64                 float dist;
  65                 dist = vlen(ent.origin - view_origin);
  66
  67                 float a;
  68                 a = autocvar_hud_shownames_alpha;
  69                 a *= ent.alpha;
  70                 if(autocvar_hud_shownames_maxdistance)
  71                 {
  72                         if(dist >= autocvar_hud_shownames_maxdistance)
  73                                 return;
  74                         a *= ((autocvar_hud_shownames_maxdistance - autocvar_hud_shownames_mindistance) - max(0, dist - autocvar_hud_shownames_mindistance)) / (autocvar_hud_shownames_maxdistance - autocvar_hud_shownames_mindistance);
  75                 }
  76
  77                 if(!a)
  78                         return;
  79
  80                 float resize;
  81                 resize = 1;
  82                 if(autocvar_hud_shownames_resize) // limit resize so its never smaller than 0.5... gets unreadable
  83                         resize = 0.5 + 0.5 * ((autocvar_hud_shownames_maxdistance - autocvar_hud_shownames_mindistance) - max(0, dist - autocvar_hud_shownames_mindistance)) / (autocvar_hud_shownames_maxdistance - autocvar_hud_shownames_mindistance);
  84
  85                 // draw the sprite image
  86                 if(o_z >= 0)
  87                 {
  88                         o_z = 0;
  89
  90                         vector myPos, mySize;
  91                         mySize = (eX * autocvar_hud_shownames_aspect + eY) * autocvar_hud_shownames_fontsize;
  92                         myPos = o - '0.5 0 0' * mySize_x - '0 1 0' * mySize_y;
  93
  94                         // size scaling
  95                         mySize_x *= resize;
  96                         mySize_y *= resize;
  97
  98                         myPos_x += 0.5 * (mySize_x / resize - mySize_x);
  99                         myPos_y += (mySize_y / resize - mySize_y);
 100
 101                         vector namepos; // this is where the origin of the string
 102                         float namewidth;
 103
 104                         namepos = myPos;
 105                         namewidth = mySize_x;
 106
 107                         if(autocvar_hud_shownames_status && teamplay)
 108                         {
 109                                 if(ent.sameteam)
 110                                 {
 111                                         if(ent.healthvalue > 0)
 112                                         {
 113                                                 HUD_Panel_DrawProgressBar(namepos + '0 1 0' * autocvar_hud_shownames_fontsize * resize, eX * 0.5 * mySize_x + eY * resize * autocvar_hud_shownames_statusbar_height, "nametag_statusbar", ent.healthvalue/autocvar_hud_panel_healtharmor_maxhealth, 0, 1, '1 0 0', a, DRAWFLAG_NORMAL);
 114
 115                                                 if(ent.armorvalue > 0)
 116                                                         HUD_Panel_DrawProgressBar(namepos + '0 1 0' * autocvar_hud_shownames_fontsize * resize + eX * 0.5 * mySize_x, eX * 0.5 * mySize_x + eY * resize * autocvar_hud_shownames_statusbar_height, "nametag_statusbar", ent.armorvalue/autocvar_hud_panel_healtharmor_maxarmor, 0, 0, '0 1 0', a, DRAWFLAG_NORMAL);
 117                                         }
 118                                 }
 119                         }
 120
 121                         string s;
 122                         s = GetPlayerName(ent.sv_entnum-1);
 123                         if((autocvar_hud_shownames_decolorize == 1 && teamplay) || autocvar_hud_shownames_decolorize == 2)
 124                                 s = playername(s, GetPlayerColor(ent.sv_entnum-1));
 125
 126                         drawfontscale = '1 1 0' * resize;
 127                         s = textShortenToWidth(s, namewidth, '1 1 0' * autocvar_hud_shownames_fontsize, stringwidth_colors);
 128
 129                         float width;
 130                         width = stringwidth(s, TRUE, '1 1 0' * autocvar_hud_shownames_fontsize);
 131
 132                         if (width != namewidth)
 133                                 namepos_x += (namewidth - width) / 2;
 134                         drawcolorcodedstring(namepos, s, '1 1 0' * autocvar_hud_shownames_fontsize, a, DRAWFLAG_NORMAL);
 135                         drawfontscale = '1 1 0';
 136                 }
 137         }
 138 }
 139
 140 entity shownames_ent[255];
 141 void Draw_ShowNames_All()
 142 {
 143         float i;
 144         for(i = 0; i < maxclients; ++i)
 145         {
 146                 float t;
 147                 t = GetPlayerColor(i);
 148                 if(t == COLOR_SPECTATOR)
 149                         continue;
 150
 151                 entity e;
 152                 e = shownames_ent[i];
 153                 if(!e)
 154                 {
 155                         e = spawn();
 156                         e.classname = "shownames_tag";
 157                         e.sv_entnum = i+1;
 158                         shownames_ent[i] = e;
 159                 }
 160
 161                 entity entcs;
 162                 entcs = entcs_receiver[i];
 163                 if(entcs)
 164                 {
 165                         e.healthvalue = entcs.healthvalue;
 166                         e.armorvalue = entcs.armorvalue;
 167                         e.sameteam = 1; /* (teamplay && (t == myteam)); */
 168                 }
 169                 else
 170                 {
 171                         e.healthvalue = 2342;
 172                         e.armorvalue = 0;
 173                         e.sameteam = 0;
 174                 }
 175
 176                 e.origin = getplayerorigin(i);
 177                 if(e.origin == GETPLAYERORIGIN_ERROR)
 178                         continue;
 179
 180                 Draw_ShowNames(e);
 181         }
 182 }