qcsrc/client/view.qc

   1 #include "_all.qh"
   2
   3 #include "announcer.qh"
   4 #include "hook.qh"
   5 #include "hud.qh"
   6 #include "hud_config.qh"
   7 #include "mapvoting.qh"
   8 #include "scoreboard.qh"
   9 #include "shownames.qh"
  10
  11 #include "mutators/events.qh"
  12
  13 #include "../common/constants.qh"
  14 #include "../common/mapinfo.qh"
  15 #include "../common/nades/all.qh"
  16 #include "../common/stats.qh"
  17 #include "../common/triggers/target/music.qh"
  18 #include "../common/teams.qh"
  19 #include "../common/util.qh"
  20
  21 #include "../common/weapons/all.qh"
  22
  23 #include "../csqcmodellib/cl_player.qh"
  24
  25 #include "../warpzonelib/client.qh"
  26 #include "../warpzonelib/common.qh"
  27
  28 entity porto;
  29 vector polyline[16];
  30 void Porto_Draw(entity this)
  31 {
  32         vector p, dir, ang, q, nextdir;
  33         float portal_number, portal1_idx;
  34
  35         if(activeweapon != WEP_PORTO.m_id || spectatee_status || gametype == MAPINFO_TYPE_NEXBALL)
  36                 return;
  37         if(g_balance_porto_secondary)
  38                 return;
  39         if(intermission == 1)
  40                 return;
  41         if(intermission == 2)
  42                 return;
  43         if (getstati(STAT_HEALTH) <= 0)
  44                 return;
  45
  46         dir = view_forward;
  47
  48         if(angles_held_status)
  49         {
  50                 makevectors(angles_held);
  51                 dir = v_forward;
  52         }
  53
  54         p = view_origin;
  55
  56         polyline[0] = p;
  57         int idx = 1;
  58         portal_number = 0;
  59         nextdir = dir;
  60
  61         for (;;)
  62         {
  63                 dir = nextdir;
  64                 traceline(p, p + 65536 * dir, true, porto);
  65                 if(trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT)
  66                         return;
  67                 nextdir = dir - 2 * (dir * trace_plane_normal) * trace_plane_normal; // mirror dir at trace_plane_normal
  68                 p = trace_endpos;
  69                 polyline[idx] = p;
  70                 ++idx;
  71                 if(idx >= 16)
  72                         return;
  73                 if(trace_dphitq3surfaceflags & Q3SURFACEFLAG_SLICK || trace_dphitcontents & DPCONTENTS_PLAYERCLIP)
  74                         continue;
  75                 ++portal_number;
  76                 ang = vectoangles2(trace_plane_normal, dir);
  77                 ang.x = -ang.x;
  78                 makevectors(ang);
  79                 if(!CheckWireframeBox(porto, p - 48 * v_right - 48 * v_up + 16 * v_forward, 96 * v_right, 96 * v_up, 96 * v_forward))
  80                         return;
  81                 if(portal_number == 1)
  82                 {
  83                         portal1_idx = idx;
  84                         if(portal_number >= 2)
  85                                 break;
  86                 }
  87         }
  88
  89         while(idx >= 2)
  90         {
  91                 p = polyline[idx-2];
  92                 q = polyline[idx-1];
  93                 if(idx == 2)
  94                         p = p - view_up * 16;
  95                 if(idx-1 >= portal1_idx)
  96                 {
  97                         Draw_CylindricLine(p, q, 4, "", 1, 0, '0 0 1', 0.5, DRAWFLAG_NORMAL, view_origin);
  98                 }
  99                 else
 100                 {
 101                         Draw_CylindricLine(p, q, 4, "", 1, 0, '1 0 0', 0.5, DRAWFLAG_NORMAL, view_origin);
 102                 }
 103                 --idx;
 104         }
 105 }
 106
 107 void Porto_Init()
 108 {
 109         porto = spawn();
 110         porto.classname = "porto";
 111         porto.draw = Porto_Draw;
 112         porto.dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY | DPCONTENTS_PLAYERCLIP;
 113 }
 114
 115 float drawtime;
 116 float avgspeed;
 117 vector GetCurrentFov(float fov)
 118 {
 119         float zoomsensitivity, zoomspeed, zoomfactor, zoomdir;
 120         float velocityzoom, curspeed;
 121         vector v;
 122
 123         zoomsensitivity = autocvar_cl_zoomsensitivity;
 124         zoomfactor = autocvar_cl_zoomfactor;
 125         if(zoomfactor < 1 || zoomfactor > 30)
 126                 zoomfactor = 2.5;
 127         zoomspeed = autocvar_cl_zoomspeed;
 128         if(zoomspeed >= 0)
 129         if(zoomspeed < 0.5 || zoomspeed > 16)
 130                         zoomspeed = 3.5;
 131
 132         zoomdir = button_zoom;
 133         if(hud == HUD_NORMAL)
 134         if(switchweapon == activeweapon)
 135         if((activeweapon == WEP_VORTEX.m_id && vortex_scope) || (activeweapon == WEP_RIFLE.m_id && rifle_scope)) // do NOT use switchweapon here
 136                 zoomdir += button_attack2;
 137         if(spectatee_status > 0 || isdemo())
 138         {
 139                 if(spectatorbutton_zoom)
 140                 {
 141                         if(zoomdir)
 142                                 zoomdir = 0;
 143                         else
 144                                 zoomdir = 1;
 145                 }
 146                 // fteqcc failed twice here already, don't optimize this
 147         }
 148
 149         if(zoomdir) { zoomin_effect = 0; }
 150
 151         if(camera_active)
 152         {
 153                 current_viewzoom = min(1, current_viewzoom + drawframetime);
 154         }
 155         else if(autocvar_cl_spawnzoom && zoomin_effect)
 156         {
 157                 float spawnzoomfactor = bound(1, autocvar_cl_spawnzoom_factor, 30);
 158
 159                 current_viewzoom += (autocvar_cl_spawnzoom_speed * (spawnzoomfactor - current_viewzoom) * drawframetime);
 160                 current_viewzoom = bound(1 / spawnzoomfactor, current_viewzoom, 1);
 161                 if(current_viewzoom == 1) { zoomin_effect = 0; }
 162         }
 163         else
 164         {
 165                 if(zoomspeed < 0) // instant zoom
 166                 {
 167                         if(zoomdir)
 168                                 current_viewzoom = 1 / zoomfactor;
 169                         else
 170                                 current_viewzoom = 1;
 171                 }
 172                 else
 173                 {
 174                         if(zoomdir)
 175                                 current_viewzoom = 1 / bound(1, 1 / current_viewzoom + drawframetime * zoomspeed * (zoomfactor - 1), zoomfactor);
 176                         else
 177                                 current_viewzoom = bound(1 / zoomfactor, current_viewzoom + drawframetime * zoomspeed * (1 - 1 / zoomfactor), 1);
 178                 }
 179         }
 180
 181         if(almost_equals(current_viewzoom, 1))
 182                 current_zoomfraction = 0;
 183         else if(almost_equals(current_viewzoom, 1/zoomfactor))
 184                 current_zoomfraction = 1;
 185         else
 186                 current_zoomfraction = (current_viewzoom - 1) / (1/zoomfactor - 1);
 187
 188         if(zoomsensitivity < 1)
 189                 setsensitivityscale(pow(current_viewzoom, 1 - zoomsensitivity));
 190         else
 191                 setsensitivityscale(1);
 192
 193         if(autocvar_cl_velocityzoom_enabled && autocvar_cl_velocityzoom_type) // _type = 0 disables velocity zoom too
 194         {
 195                 if(intermission) { curspeed = 0; }
 196                 else
 197                 {
 198
 199                         makevectors(view_angles);
 200                         v = pmove_vel;
 201                         if(csqcplayer)
 202                                 v = csqcplayer.velocity;
 203
 204                         switch(autocvar_cl_velocityzoom_type)
 205                         {
 206                                 case 3: curspeed = max(0, v_forward * v); break;
 207                                 case 2: curspeed = (v_forward * v); break;
 208                                 case 1: default: curspeed = vlen(v); break;
 209                         }
 210                 }
 211
 212                 velocityzoom = bound(0, drawframetime / max(0.000000001, autocvar_cl_velocityzoom_time), 1); // speed at which the zoom adapts to player velocity
 213                 avgspeed = avgspeed * (1 - velocityzoom) + (curspeed / autocvar_cl_velocityzoom_speed) * velocityzoom;
 214                 velocityzoom = exp(float2range11(avgspeed * -autocvar_cl_velocityzoom_factor / 1) * 1);
 215
 216                 //print(ftos(avgspeed), " avgspeed, ", ftos(curspeed), " curspeed, ", ftos(velocityzoom), " return\n"); // for debugging
 217         }
 218         else
 219                 velocityzoom = 1;
 220
 221         float frustumx, frustumy, fovx, fovy;
 222         frustumy = tan(fov * M_PI / 360.0) * 0.75 * current_viewzoom * velocityzoom;
 223         frustumx = frustumy * vid_width / vid_height / vid_pixelheight;
 224         fovx = atan2(frustumx, 1) / M_PI * 360.0;
 225         fovy = atan2(frustumy, 1) / M_PI * 360.0;
 226
 227         return '1 0 0' * fovx + '0 1 0' * fovy;
 228 }
 229
 230 vector GetViewLocationFOV(float fov)
 231 {
 232         float frustumy = tan(fov * M_PI / 360.0) * 0.75;
 233         float frustumx = frustumy * vid_width / vid_height / vid_pixelheight;
 234         float fovx = atan2(frustumx, 1) / M_PI * 360.0;
 235         float fovy = atan2(frustumy, 1) / M_PI * 360.0;
 236         return '1 0 0' * fovx + '0 1 0' * fovy;
 237 }
 238
 239 vector GetOrthoviewFOV(vector ov_worldmin, vector ov_worldmax, vector ov_mid, vector ov_org)
 240 {
 241         float fovx, fovy;
 242         float width = (ov_worldmax.x - ov_worldmin.x);
 243         float height = (ov_worldmax.y - ov_worldmin.y);
 244         float distance_to_middle_of_world = vlen(ov_mid - ov_org);
 245         fovx = atan2(width/2, distance_to_middle_of_world) / M_PI * 360.0;
 246         fovy = atan2(height/2, distance_to_middle_of_world) / M_PI * 360.0;
 247         return '1 0 0' * fovx + '0 1 0' * fovy;
 248 }
 249
 250 // this function must match W_SetupShot!
 251 float zoomscript_caught;
 252
 253 vector wcross_origin;
 254 float wcross_scale_prev, wcross_alpha_prev;
 255 vector wcross_color_prev;
 256 float wcross_scale_goal_prev, wcross_alpha_goal_prev;
 257 vector wcross_color_goal_prev;
 258 float wcross_changedonetime;
 259
 260 string wcross_name_goal_prev, wcross_name_goal_prev_prev;
 261 float wcross_resolution_goal_prev, wcross_resolution_goal_prev_prev;
 262 float wcross_name_changestarttime, wcross_name_changedonetime;
 263 float wcross_name_alpha_goal_prev, wcross_name_alpha_goal_prev_prev;
 264
 265 float wcross_ring_prev;
 266
 267 entity trueaim;
 268 entity trueaim_rifle;
 269
 270 const float SHOTTYPE_HITTEAM = 1;
 271 const float SHOTTYPE_HITOBSTRUCTION = 2;
 272 const float SHOTTYPE_HITWORLD = 3;
 273 const float SHOTTYPE_HITENEMY = 4;
 274
 275 void TrueAim_Init()
 276 {
 277         trueaim = spawn();
 278         trueaim.classname = "trueaim";
 279         trueaim.dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY | DPCONTENTS_CORPSE;
 280         trueaim_rifle = spawn();
 281         trueaim_rifle.classname = "trueaim_rifle";
 282         trueaim_rifle.dphitcontentsmask = DPCONTENTS_BODY | DPCONTENTS_CORPSE;
 283 }
 284
 285 float EnemyHitCheck()
 286 {
 287         float t, n;
 288         wcross_origin = project_3d_to_2d(trace_endpos);
 289         wcross_origin.z = 0;
 290         if(trace_ent)
 291                 n = trace_ent.entnum;
 292         else
 293                 n = trace_networkentity;
 294         if(n < 1)
 295                 return SHOTTYPE_HITWORLD;
 296         if(n > maxclients)
 297                 return SHOTTYPE_HITWORLD;
 298         t = GetPlayerColor(n - 1);
 299         if(teamplay)
 300                 if(t == myteam)
 301                         return SHOTTYPE_HITTEAM;
 302         if(t == NUM_SPECTATOR)
 303                 return SHOTTYPE_HITWORLD;
 304         return SHOTTYPE_HITENEMY;
 305 }
 306
 307 float TrueAimCheck()
 308 {
 309         float nudge = 1; // added to traceline target and subtracted from result TOOD(divVerent): do we still need this? Doesn't the engine do this now for us?
 310         vector vecs, trueaimpoint, w_shotorg;
 311         vector mi, ma, dv;
 312         float shottype;
 313         entity ta;
 314         float mv;
 315
 316         mi = ma = '0 0 0';
 317         ta = trueaim;
 318         mv = MOVE_NOMONSTERS;
 319
 320         switch(activeweapon) // WEAPONTODO
 321         {
 322                 case WEP_TUBA.m_id: // no aim
 323                 case WEP_PORTO.m_id: // shoots from eye
 324                 case WEP_NEXBALL.m_id: // shoots from eye
 325                 case WEP_HOOK.m_id: // no trueaim
 326                 case WEP_MORTAR.m_id: // toss curve
 327                         return SHOTTYPE_HITWORLD;
 328                 case WEP_VORTEX.m_id:
 329                 case WEP_VAPORIZER.m_id:
 330                         mv = MOVE_NORMAL;
 331                         break;
 332                 case WEP_RIFLE.m_id:
 333                         ta = trueaim_rifle;
 334                         mv = MOVE_NORMAL;
 335                         if(zoomscript_caught)
 336                         {
 337                                 tracebox(view_origin, '0 0 0', '0 0 0', view_origin + view_forward * MAX_SHOT_DISTANCE, mv, ta);
 338                                 return EnemyHitCheck();
 339                         }
 340                         break;
 341                 case WEP_DEVASTATOR.m_id: // projectile has a size!
 342                         mi = '-3 -3 -3';
 343                         ma = '3 3 3';
 344                         break;
 345                 case WEP_FIREBALL.m_id: // projectile has a size!
 346                         mi = '-16 -16 -16';
 347                         ma = '16 16 16';
 348                         break;
 349                 case WEP_SEEKER.m_id: // projectile has a size!
 350                         mi = '-2 -2 -2';
 351                         ma = '2 2 2';
 352                         break;
 353                 case WEP_ELECTRO.m_id: // projectile has a size!
 354                         mi = '0 0 -3';
 355                         ma = '0 0 -3';
 356                         break;
 357         }
 358
 359         vector traceorigin = getplayerorigin(player_localentnum-1) + (eZ * getstati(STAT_VIEWHEIGHT));
 360
 361         vecs = decompressShotOrigin(getstati(STAT_SHOTORG));
 362
 363         traceline(traceorigin, traceorigin + view_forward * MAX_SHOT_DISTANCE, mv, ta);
 364         trueaimpoint = trace_endpos;
 365
 366         if(vlen(trueaimpoint - traceorigin) < g_trueaim_minrange)
 367                 trueaimpoint = traceorigin + view_forward * g_trueaim_minrange;
 368
 369         if(vecs.x > 0)
 370                 vecs.y = -vecs.y;
 371         else
 372                 vecs = '0 0 0';
 373
 374         dv = view_right * vecs.y + view_up * vecs.z;
 375         w_shotorg = traceorigin + dv;
 376
 377         // now move the vecs forward as much as requested if possible
 378         tracebox(w_shotorg, mi, ma, w_shotorg + view_forward * (vecs.x + nudge), MOVE_NORMAL, ta); // FIXME this MOVE_NORMAL part will misbehave a little in csqc
 379         w_shotorg = trace_endpos - view_forward * nudge;
 380
 381         tracebox(w_shotorg, mi, ma, trueaimpoint, MOVE_NORMAL, ta);
 382         shottype = EnemyHitCheck();
 383         if(shottype != SHOTTYPE_HITWORLD)
 384                 return shottype;
 385
 386 #if 0
 387         // FIXME WHY DOES THIS NOT WORK FOR THE ROCKET LAUNCHER?
 388         // or rather, I know why, but see no fix
 389         if(vlen(trace_endpos - trueaimpoint) > vlen(ma) + vlen(mi) + 1)
 390                 // yes, this is an ugly hack... but it seems good enough to find out whether the test hits the same place as the initial trace
 391                 return SHOTTYPE_HITOBSTRUCTION;
 392 #endif
 393
 394         return SHOTTYPE_HITWORLD;
 395 }
 396
 397 void PostInit(void);
 398 void CSQC_Demo_Camera();
 399 float HUD_WouldDrawScoreboard();
 400 float camera_mode;
 401 const float CAMERA_FREE = 1;
 402 const float CAMERA_CHASE = 2;
 403 float reticle_type;
 404 string reticle_image;
 405 string NextFrameCommand;
 406
 407 vector freeze_org, freeze_ang;
 408 entity nightvision_noise, nightvision_noise2;
 409
 410 const float MAX_TIME_DIFF = 5;
 411 float pickup_crosshair_time, pickup_crosshair_size;
 412 float hitindication_crosshair_size;
 413 float use_vortex_chargepool;
 414
 415 float myhealth, myhealth_prev;
 416 float myhealth_flash;
 417
 418 float old_blurradius, old_bluralpha;
 419 float old_sharpen_intensity;
 420
 421 vector myhealth_gentlergb;
 422
 423 float contentavgalpha, liquidalpha_prev;
 424 vector liquidcolor_prev;
 425
 426 float eventchase_current_distance;
 427 float eventchase_running;
 428 bool WantEventchase()
 429 {SELFPARAM();
 430         if(autocvar_cl_orthoview)
 431                 return false;
 432         if(intermission)
 433                 return true;
 434         if(self.viewloc)
 435                 return true;
 436         if(spectatee_status >= 0)
 437         {
 438                 if(hud != HUD_NORMAL && (autocvar_cl_eventchase_vehicle || spectatee_status > 0))
 439                         return true;
 440                 if(MUTATOR_CALLHOOK(WantEventchase, self))
 441                         return true;
 442                 if(autocvar_cl_eventchase_nexball && gametype == MAPINFO_TYPE_NEXBALL && !(WepSet_GetFromStat() & WepSet_FromWeapon(WEP_NEXBALL.m_id)))
 443                         return true;
 444                 if(autocvar_cl_eventchase_death && (getstati(STAT_HEALTH) <= 0))
 445                 {
 446                         if(autocvar_cl_eventchase_death == 2)
 447                         {
 448                                 // don't stop eventchase once it's started (even if velocity changes afterwards)
 449                                 if(self.velocity == '0 0 0' || eventchase_running)
 450                                         return true;
 451                         }
 452                         else return true;
 453                 }
 454         }
 455         return false;
 456 }
 457
 458 void HUD_Crosshair_Vehicle()
 459 {
 460         if(hud != HUD_BUMBLEBEE_GUN)
 461         {
 462                 Vehicle info = get_vehicleinfo(hud);
 463                 info.vr_crosshair(info);
 464         }
 465 }
 466
 467 vector damage_blurpostprocess, content_blurpostprocess;
 468
 469 float unaccounted_damage = 0;
 470 void UpdateDamage()
 471 {
 472         // accumulate damage with each stat update
 473         static float damage_total_prev = 0;
 474         float damage_total = getstati(STAT_DAMAGE_DEALT_TOTAL);
 475         float unaccounted_damage_new = COMPARE_INCREASING(damage_total, damage_total_prev);
 476         damage_total_prev = damage_total;
 477
 478         static float damage_dealt_time_prev = 0;
 479         float damage_dealt_time = getstatf(STAT_HIT_TIME);
 480         if (damage_dealt_time != damage_dealt_time_prev)
 481         {
 482                 unaccounted_damage += unaccounted_damage_new;
 483                 LOG_TRACE("dmg total: ", ftos(unaccounted_damage), " (+", ftos(unaccounted_damage_new), ")", "\n");
 484         }
 485         damage_dealt_time_prev = damage_dealt_time;
 486
 487         // prevent hitsound when switching spectatee
 488         static float spectatee_status_prev = 0;
 489         if (spectatee_status != spectatee_status_prev)
 490                 unaccounted_damage = 0;
 491         spectatee_status_prev = spectatee_status;
 492 }
 493
 494 void HitSound()
 495 {
 496         // varying sound pitch
 497
 498         static float hitsound_time_prev = 0;
 499         // HACK: the only way to get the arc to sound consistent with pitch shift is to ignore cl_hitsound_antispam_time
 500         float arc_hack = activeweapon == WEP_ARC.m_id && autocvar_cl_hitsound >= 2;
 501         if (arc_hack || COMPARE_INCREASING(time, hitsound_time_prev) > autocvar_cl_hitsound_antispam_time)
 502         {
 503                 if (autocvar_cl_hitsound && unaccounted_damage)
 504                 {
 505                         // customizable gradient function that crosses (0,a), (c,1) and asymptotically approaches b
 506                         float a = autocvar_cl_hitsound_max_pitch;
 507                         float b = autocvar_cl_hitsound_min_pitch;
 508                         float c = autocvar_cl_hitsound_nom_damage;
 509                         float x = unaccounted_damage;
 510                         float pitch_shift = (b*x*(a-1) + a*c*(1-b)) / (x*(a-1) + c*(1-b));
 511
 512                         // if sound variation is disabled, set pitch_shift to 1
 513                         if (autocvar_cl_hitsound == 1)
 514                                 pitch_shift = 1;
 515
 516                         // if pitch shift is reversed, mirror in (max-min)/2 + min
 517                         if (autocvar_cl_hitsound == 3)
 518                         {
 519                                 float mirror_value = (a-b)/2 + b;
 520                                 pitch_shift = mirror_value + (mirror_value - pitch_shift);
 521                         }
 522
 523                         LOG_TRACE("dmg total (dmg): ", ftos(unaccounted_damage), " , pitch shift: ", ftos(pitch_shift), "\n");
 524
 525                         // todo: avoid very long and very short sounds from wave stretching using different sound files? seems unnecessary
 526                         // todo: normalize sound pressure levels? seems unnecessary
 527
 528                         sound7(world, CH_INFO, SND(HIT), VOL_BASE, ATTN_NONE, pitch_shift * 100, 0);
 529                 }
 530                 unaccounted_damage = 0;
 531                 hitsound_time_prev = time;
 532         }
 533
 534         static float typehit_time_prev = 0;
 535         float typehit_time = getstatf(STAT_TYPEHIT_TIME);
 536         if (COMPARE_INCREASING(typehit_time, typehit_time_prev) > autocvar_cl_hitsound_antispam_time)
 537         {
 538                 sound(world, CH_INFO, SND_TYPEHIT, VOL_BASE, ATTN_NONE);
 539                 typehit_time_prev = typehit_time;
 540         }
 541 }
 542
 543 void HUD_Crosshair()
 544 {SELFPARAM();
 545         static float rainbow_last_flicker;
 546     static vector rainbow_prev_color;
 547         entity e = self;
 548         float f, i, j;
 549         vector v;
 550         if(!scoreboard_active && !camera_active && intermission != 2 &&
 551                 spectatee_status != -1 && !csqcplayer.viewloc &&
 552                 !HUD_MinigameMenu_IsOpened() )
 553         {
 554                 if (!autocvar_crosshair_enabled) // main toggle for crosshair rendering
 555                         return;
 556
 557                 if (hud != HUD_NORMAL)
 558                 {
 559                         HUD_Crosshair_Vehicle();
 560                         return;
 561                 }
 562
 563                 string wcross_style;
 564                 float wcross_alpha, wcross_resolution;
 565                 wcross_style = autocvar_crosshair;
 566                 if (wcross_style == "0")
 567                         return;
 568                 wcross_resolution = autocvar_crosshair_size;
 569                 if (wcross_resolution == 0)
 570                         return;
 571                 wcross_alpha = autocvar_crosshair_alpha;
 572                 if (wcross_alpha == 0)
 573                         return;
 574
 575                 // TrueAim check
 576                 float shottype;
 577
 578                 // wcross_origin = '0.5 0 0' * vid_conwidth + '0 0.5 0' * vid_conheight;
 579                 wcross_origin = project_3d_to_2d(view_origin + MAX_SHOT_DISTANCE * view_forward);
 580                 wcross_origin.z = 0;
 581                 if(autocvar_crosshair_hittest)
 582                 {
 583                         vector wcross_oldorigin;
 584                         wcross_oldorigin = wcross_origin;
 585                         shottype = TrueAimCheck();
 586                         if(shottype == SHOTTYPE_HITWORLD)
 587                         {
 588                                 v = wcross_origin - wcross_oldorigin;
 589                                 v.x /= vid_conwidth;
 590                                 v.y /= vid_conheight;
 591                                 if(vlen(v) > 0.01)
 592                                         shottype = SHOTTYPE_HITOBSTRUCTION;
 593                         }
 594                         if(!autocvar_crosshair_hittest_showimpact)
 595                                 wcross_origin = wcross_oldorigin;
 596                 }
 597                 else
 598                         shottype = SHOTTYPE_HITWORLD;
 599
 600                 vector wcross_color = '0 0 0', wcross_size = '0 0 0';
 601                 string wcross_name = "";
 602                 float wcross_scale, wcross_blur;
 603
 604                 if(autocvar_crosshair_per_weapon || (autocvar_crosshair_color_special == 1))
 605                 {
 606                         e = get_weaponinfo(switchingweapon);
 607                         if(e)
 608                         {
 609                                 if(autocvar_crosshair_per_weapon)
 610                                 {
 611                                         // WEAPONTODO: access these through some general settings (with non-balance config settings)
 612                                         //wcross_resolution *= cvar(strcat("crosshair_", wcross_wep, "_size"));
 613                                         //if (wcross_resolution == 0)
 614                                                 //return;
 615
 616                                         //wcross_style = cvar_string(strcat("crosshair_", wcross_wep));
 617                                         wcross_resolution *= e.w_crosshair_size;
 618                                         wcross_name = e.w_crosshair;
 619                                 }
 620                         }
 621                 }
 622
 623                 if(wcross_name == "")
 624                         wcross_name = strcat("gfx/crosshair", wcross_style);
 625
 626                 // MAIN CROSSHAIR COLOR DECISION
 627                 switch(autocvar_crosshair_color_special)
 628                 {
 629                         case 1: // crosshair_color_per_weapon
 630                         {
 631                                 if(e)
 632                                 {
 633                                         wcross_color = e.wpcolor;
 634                                         break;
 635                                 }
 636                                 else { goto normalcolor; }
 637                         }
 638
 639                         case 2: // crosshair_color_by_health
 640                         {
 641                                 float x = getstati(STAT_HEALTH);
 642
 643                                 //x = red
 644                                 //y = green
 645                                 //z = blue
 646
 647                                 wcross_color.z = 0;
 648
 649                                 if(x > 200)
 650                                 {
 651                                         wcross_color.x = 0;
 652                                         wcross_color.y = 1;
 653                                 }
 654                                 else if(x > 150)
 655                                 {
 656                                         wcross_color.x = 0.4 - (x-150)*0.02 * 0.4;
 657                                         wcross_color.y = 0.9 + (x-150)*0.02 * 0.1;
 658                                 }
 659                                 else if(x > 100)
 660                                 {
 661                                         wcross_color.x = 1 - (x-100)*0.02 * 0.6;
 662                                         wcross_color.y = 1 - (x-100)*0.02 * 0.1;
 663                                         wcross_color.z = 1 - (x-100)*0.02;
 664                                 }
 665                                 else if(x > 50)
 666                                 {
 667                                         wcross_color.x = 1;
 668                                         wcross_color.y = 1;
 669                                         wcross_color.z = 0.2 + (x-50)*0.02 * 0.8;
 670                                 }
 671                                 else if(x > 20)
 672                                 {
 673                                         wcross_color.x = 1;
 674                                         wcross_color.y = (x-20)*90/27/100;
 675                                         wcross_color.z = (x-20)*90/27/100 * 0.2;
 676                                 }
 677                                 else
 678                                 {
 679                                         wcross_color.x = 1;
 680                                         wcross_color.y = 0;
 681                                 }
 682                                 break;
 683                         }
 684
 685                         case 3: // crosshair_color_rainbow
 686                         {
 687                                 if(time >= rainbow_last_flicker)
 688                                 {
 689                                         rainbow_prev_color = randomvec() * autocvar_crosshair_color_special_rainbow_brightness;
 690                                         rainbow_last_flicker = time + autocvar_crosshair_color_special_rainbow_delay;
 691                                 }
 692                                 wcross_color = rainbow_prev_color;
 693                                 break;
 694                         }
 695                         :normalcolor
 696                         default: { wcross_color = stov(autocvar_crosshair_color); break; }
 697                 }
 698
 699                 if(autocvar_crosshair_effect_scalefade)
 700                 {
 701                         wcross_scale = wcross_resolution;
 702                         wcross_resolution = 1;
 703                 }
 704                 else
 705                 {
 706                         wcross_scale = 1;
 707                 }
 708
 709                 if(autocvar_crosshair_pickup)
 710                 {
 711                         float stat_pickup_time = getstatf(STAT_LAST_PICKUP);
 712
 713                         if(pickup_crosshair_time < stat_pickup_time)
 714                         {
 715                                 if(time - stat_pickup_time < MAX_TIME_DIFF) // don't trigger the animation if it's too old
 716                                         pickup_crosshair_size = 1;
 717
 718                                 pickup_crosshair_time = stat_pickup_time;
 719                         }
 720
 721                         if(pickup_crosshair_size > 0)
 722                                 pickup_crosshair_size -= autocvar_crosshair_pickup_speed * frametime;
 723                         else
 724                                 pickup_crosshair_size = 0;
 725
 726                         wcross_scale += sin(pickup_crosshair_size) * autocvar_crosshair_pickup;
 727                 }
 728
 729                 // todo: make crosshair hit indication dependent on damage dealt
 730                 if(autocvar_crosshair_hitindication)
 731                 {
 732                         vector hitindication_color = ((autocvar_crosshair_color_special == 1) ? stov(autocvar_crosshair_hitindication_per_weapon_color) : stov(autocvar_crosshair_hitindication_color));
 733
 734                         if(unaccounted_damage)
 735                         {
 736                                 hitindication_crosshair_size = 1;
 737                         }
 738
 739                         if(hitindication_crosshair_size > 0)
 740                                 hitindication_crosshair_size -= autocvar_crosshair_hitindication_speed * frametime;
 741                         else
 742                                 hitindication_crosshair_size = 0;
 743
 744                         wcross_scale += sin(hitindication_crosshair_size) * autocvar_crosshair_hitindication;
 745                         wcross_color.x += sin(hitindication_crosshair_size) * hitindication_color.x;
 746                         wcross_color.y += sin(hitindication_crosshair_size) * hitindication_color.y;
 747                         wcross_color.z += sin(hitindication_crosshair_size) * hitindication_color.z;
 748                 }
 749
 750                 if(shottype == SHOTTYPE_HITENEMY)
 751                         wcross_scale *= autocvar_crosshair_hittest; // is not queried if hittest is 0
 752                 if(shottype == SHOTTYPE_HITTEAM)
 753                         wcross_scale /= autocvar_crosshair_hittest; // is not queried if hittest is 0
 754
 755                 f = fabs(autocvar_crosshair_effect_time);
 756                 if(wcross_scale != wcross_scale_goal_prev || wcross_alpha != wcross_alpha_goal_prev || wcross_color != wcross_color_goal_prev)
 757                 {
 758                         wcross_changedonetime = time + f;
 759                 }
 760                 if(wcross_name != wcross_name_goal_prev || wcross_resolution != wcross_resolution_goal_prev)
 761                 {
 762                         wcross_name_changestarttime = time;
 763                         wcross_name_changedonetime = time + f;
 764                         if(wcross_name_goal_prev_prev)
 765                                 strunzone(wcross_name_goal_prev_prev);
 766                         wcross_name_goal_prev_prev = wcross_name_goal_prev;
 767                         wcross_name_goal_prev = strzone(wcross_name);
 768                         wcross_name_alpha_goal_prev_prev = wcross_name_alpha_goal_prev;
 769                         wcross_resolution_goal_prev_prev = wcross_resolution_goal_prev;
 770                         wcross_resolution_goal_prev = wcross_resolution;
 771                 }
 772
 773                 wcross_scale_goal_prev = wcross_scale;
 774                 wcross_alpha_goal_prev = wcross_alpha;
 775                 wcross_color_goal_prev = wcross_color;
 776
 777                 if(spectatee_status == -1 && shottype == SHOTTYPE_HITTEAM || (shottype == SHOTTYPE_HITOBSTRUCTION && autocvar_crosshair_hittest_blur && !autocvar_chase_active))
 778                 {
 779                         wcross_blur = 1;
 780                         wcross_alpha *= 0.75;
 781                 }
 782                 else
 783                         wcross_blur = 0;
 784                 // *_prev is at time-frametime
 785                 // * is at wcross_changedonetime+f
 786                 // what do we have at time?
 787                 if(time < wcross_changedonetime)
 788                 {
 789                         f = frametime / (wcross_changedonetime - time + frametime);
 790                         wcross_scale = f * wcross_scale + (1 - f) * wcross_scale_prev;
 791                         wcross_alpha = f * wcross_alpha + (1 - f) * wcross_alpha_prev;
 792                         wcross_color = f * wcross_color + (1 - f) * wcross_color_prev;
 793                 }
 794
 795                 wcross_scale_prev = wcross_scale;
 796                 wcross_alpha_prev = wcross_alpha;
 797                 wcross_color_prev = wcross_color;
 798
 799                 MUTATOR_CALLHOOK(UpdateCrosshair);
 800
 801                 wcross_scale *= 1 - autocvar__menu_alpha;
 802                 wcross_alpha *= 1 - autocvar__menu_alpha;
 803                 wcross_size = draw_getimagesize(wcross_name) * wcross_scale;
 804
 805                 if(wcross_scale >= 0.001 && wcross_alpha >= 0.001)
 806                 {
 807                         // crosshair rings for weapon stats
 808                         if (autocvar_crosshair_ring || autocvar_crosshair_ring_reload)
 809                         {
 810                                 // declarations and stats
 811                                 float ring_value = 0, ring_scale = 0, ring_alpha = 0, ring_inner_value = 0, ring_inner_alpha = 0;
 812                                 string ring_image = string_null, ring_inner_image = string_null;
 813                                 vector ring_rgb = '0 0 0', ring_inner_rgb = '0 0 0';
 814
 815                                 ring_scale = autocvar_crosshair_ring_size;
 816
 817                                 float weapon_clipload, weapon_clipsize;
 818                                 weapon_clipload = getstati(STAT_WEAPON_CLIPLOAD);
 819                                 weapon_clipsize = getstati(STAT_WEAPON_CLIPSIZE);
 820
 821                                 float ok_ammo_charge, ok_ammo_chargepool;
 822                                 ok_ammo_charge = getstatf(STAT_OK_AMMO_CHARGE);
 823                                 ok_ammo_chargepool = getstatf(STAT_OK_AMMO_CHARGEPOOL);
 824
 825                                 float vortex_charge, vortex_chargepool;
 826                                 vortex_charge = getstatf(STAT_VORTEX_CHARGE);
 827                                 vortex_chargepool = getstatf(STAT_VORTEX_CHARGEPOOL);
 828
 829                                 float arc_heat = getstatf(STAT_ARC_HEAT);
 830
 831                                 if(vortex_charge_movingavg == 0) // this should only happen if we have just loaded up the game
 832                                         vortex_charge_movingavg = vortex_charge;
 833
 834
 835                                 // handle the values
 836                                 if (autocvar_crosshair_ring && activeweapon == WEP_VORTEX.m_id && vortex_charge && autocvar_crosshair_ring_vortex) // ring around crosshair representing velocity-dependent damage for the vortex
 837                                 {
 838                                         if (vortex_chargepool || use_vortex_chargepool) {
 839                                                 use_vortex_chargepool = 1;
 840                                                 ring_inner_value = vortex_chargepool;
 841                                         } else {
 842                                                 vortex_charge_movingavg = (1 - autocvar_crosshair_ring_vortex_currentcharge_movingavg_rate) * vortex_charge_movingavg + autocvar_crosshair_ring_vortex_currentcharge_movingavg_rate * vortex_charge;
 843                                                 ring_inner_value = bound(0, autocvar_crosshair_ring_vortex_currentcharge_scale * (vortex_charge - vortex_charge_movingavg), 1);
 844                                         }
 845
 846                                         ring_inner_alpha = autocvar_crosshair_ring_vortex_inner_alpha;
 847                                         ring_inner_rgb = eX * autocvar_crosshair_ring_vortex_inner_color_red + eY * autocvar_crosshair_ring_vortex_inner_color_green + eZ * autocvar_crosshair_ring_vortex_inner_color_blue;
 848                                         ring_inner_image = "gfx/crosshair_ring_inner.tga";
 849
 850                                         // draw the outer ring to show the current charge of the weapon
 851                                         ring_value = vortex_charge;
 852                                         ring_alpha = autocvar_crosshair_ring_vortex_alpha;
 853                                         ring_rgb = wcross_color;
 854                                         ring_image = "gfx/crosshair_ring_nexgun.tga";
 855                                 }
 856                                 else if (autocvar_crosshair_ring && activeweapon == WEP_MINE_LAYER.m_id && minelayer_maxmines && autocvar_crosshair_ring_minelayer)
 857                                 {
 858                                         ring_value = bound(0, getstati(STAT_LAYED_MINES) / minelayer_maxmines, 1); // if you later need to use the count of bullets in another place, then add a float for it. For now, no need to.
 859                                         ring_alpha = autocvar_crosshair_ring_minelayer_alpha;
 860                                         ring_rgb = wcross_color;
 861                                         ring_image = "gfx/crosshair_ring.tga";
 862                                 }
 863                                 else if (activeweapon == WEP_HAGAR.m_id && getstati(STAT_HAGAR_LOAD) && autocvar_crosshair_ring_hagar)
 864                                 {
 865                                         ring_value = bound(0, getstati(STAT_HAGAR_LOAD) / hagar_maxrockets, 1);
 866                                         ring_alpha = autocvar_crosshair_ring_hagar_alpha;
 867                                         ring_rgb = wcross_color;
 868                                         ring_image = "gfx/crosshair_ring.tga";
 869                                 }
 870                                 else if (ok_ammo_charge)
 871                                 {
 872                                         ring_value = ok_ammo_chargepool;
 873                                         ring_alpha = autocvar_crosshair_ring_reload_alpha;
 874                                         ring_rgb = wcross_color;
 875                                         ring_image = "gfx/crosshair_ring.tga";
 876                                 }
 877                                 else if(autocvar_crosshair_ring_reload && weapon_clipsize) // forces there to be only an ammo ring
 878                                 {
 879                                         ring_value = bound(0, weapon_clipload / weapon_clipsize, 1);
 880                                         ring_scale = autocvar_crosshair_ring_reload_size;
 881                                         ring_alpha = autocvar_crosshair_ring_reload_alpha;
 882                                         ring_rgb = wcross_color;
 883
 884                                         // Note: This is to stop Taoki from complaining that the image doesn't match all potential balances.
 885                                         // if a new image for another weapon is added, add the code (and its respective file/value) here
 886                                         if ((activeweapon == WEP_RIFLE.m_id) && (weapon_clipsize == 80))
 887                                                 ring_image = "gfx/crosshair_ring_rifle.tga";
 888                                         else
 889                                                 ring_image = "gfx/crosshair_ring.tga";
 890                                 }
 891                                 else if ( autocvar_crosshair_ring && autocvar_crosshair_ring_arc && arc_heat && activeweapon == WEP_ARC.m_id )
 892                                 {
 893                                         ring_value = arc_heat;
 894                                         ring_alpha = (1-arc_heat)*autocvar_crosshair_ring_arc_cold_alpha +
 895                                                 arc_heat*autocvar_crosshair_ring_arc_hot_alpha;
 896                                         ring_rgb = (1-arc_heat)*wcross_color + arc_heat*autocvar_crosshair_ring_arc_hot_color;
 897                                         ring_image = "gfx/crosshair_ring.tga";
 898                                 }
 899
 900                                 // if in weapon switch animation, fade ring out/in
 901                                 if(autocvar_crosshair_effect_time > 0)
 902                                 {
 903                                         f = (time - wcross_name_changestarttime) / autocvar_crosshair_effect_time;
 904                                         if (f >= 1)
 905                                         {
 906                                                 wcross_ring_prev = ((ring_image) ? true : false);
 907                                         }
 908
 909                                         if(wcross_ring_prev)
 910                                         {
 911                                                 if(f < 1)
 912                                                         ring_alpha *= fabs(1 - bound(0, f, 1));
 913                                         }
 914                                         else
 915                                         {
 916                                                 if(f < 1)
 917                                                         ring_alpha *= bound(0, f, 1);
 918                                         }
 919                                 }
 920
 921                                 if (autocvar_crosshair_ring_inner && ring_inner_value) // lets draw a ring inside a ring so you can ring while you ring
 922                                         DrawCircleClippedPic(wcross_origin, wcross_size.x * ring_scale, ring_inner_image, ring_inner_value, ring_inner_rgb, wcross_alpha * ring_inner_alpha, DRAWFLAG_ADDITIVE);
 923
 924                                 if (ring_value)
 925                                         DrawCircleClippedPic(wcross_origin, wcross_size.x * ring_scale, ring_image, ring_value, ring_rgb, wcross_alpha * ring_alpha, DRAWFLAG_ADDITIVE);
 926                         }
 927
 928 #define CROSSHAIR_DO_BLUR(M,sz,wcross_name,wcross_alpha) \
 929                         do \
 930                         { \
 931                                 if(wcross_blur > 0) \
 932                                 { \
 933                                         for(i = -2; i <= 2; ++i) \
 934                                         for(j = -2; j <= 2; ++j) \
 935                                         M(i,j,sz,wcross_name,wcross_alpha*0.04); \
 936                                 } \
 937                                 else \
 938                                 { \
 939                                         M(0,0,sz,wcross_name,wcross_alpha); \
 940                                 } \
 941                         } \
 942                         while(0)
 943
 944 #define CROSSHAIR_DRAW_SINGLE(i,j,sz,wcross_name,wcross_alpha) \
 945                         drawpic(wcross_origin - ('0.5 0 0' * (sz * wcross_size.x + i * wcross_blur) + '0 0.5 0' * (sz * wcross_size.y + j * wcross_blur)), wcross_name, sz * wcross_size, wcross_color, wcross_alpha, DRAWFLAG_NORMAL)
 946
 947 #define CROSSHAIR_DRAW(sz,wcross_name,wcross_alpha) \
 948                         CROSSHAIR_DO_BLUR(CROSSHAIR_DRAW_SINGLE,sz,wcross_name,wcross_alpha)
 949
 950                         if(time < wcross_name_changedonetime && wcross_name != wcross_name_goal_prev_prev && wcross_name_goal_prev_prev)
 951                         {
 952                                 f = (wcross_name_changedonetime - time) / (wcross_name_changedonetime - wcross_name_changestarttime);
 953                                 wcross_size = draw_getimagesize(wcross_name_goal_prev_prev) * wcross_scale;
 954                                 CROSSHAIR_DRAW(wcross_resolution_goal_prev_prev, wcross_name_goal_prev_prev, wcross_alpha * f * wcross_name_alpha_goal_prev_prev);
 955                                 f = 1 - f;
 956                         }
 957                         else
 958                         {
 959                                 f = 1;
 960                         }
 961                         wcross_name_alpha_goal_prev = f;
 962
 963                         wcross_size = draw_getimagesize(wcross_name) * wcross_scale;
 964                         CROSSHAIR_DRAW(wcross_resolution, wcross_name, wcross_alpha * f);
 965
 966                         if(autocvar_crosshair_dot)
 967                         {
 968                                 vector wcross_color_old;
 969                                 wcross_color_old = wcross_color;
 970
 971                                 if((autocvar_crosshair_dot_color_custom) && (autocvar_crosshair_dot_color != "0"))
 972                                         wcross_color = stov(autocvar_crosshair_dot_color);
 973
 974                                 CROSSHAIR_DRAW(wcross_resolution * autocvar_crosshair_dot_size, "gfx/crosshairdot.tga", f * autocvar_crosshair_dot_alpha);
 975                                 // FIXME why don't we use wcross_alpha here?cl_notice_run();
 976                                 wcross_color = wcross_color_old;
 977                         }
 978                 }
 979         }
 980         else
 981         {
 982                 wcross_scale_prev = 0;
 983                 wcross_alpha_prev = 0;
 984                 wcross_scale_goal_prev = 0;
 985                 wcross_alpha_goal_prev = 0;
 986                 wcross_changedonetime = 0;
 987                 if(wcross_name_goal_prev)
 988                         strunzone(wcross_name_goal_prev);
 989                 wcross_name_goal_prev = string_null;
 990                 if(wcross_name_goal_prev_prev)
 991                         strunzone(wcross_name_goal_prev_prev);
 992                 wcross_name_goal_prev_prev = string_null;
 993                 wcross_name_changestarttime = 0;
 994                 wcross_name_changedonetime = 0;
 995                 wcross_name_alpha_goal_prev = 0;
 996                 wcross_name_alpha_goal_prev_prev = 0;
 997                 wcross_resolution_goal_prev = 0;
 998                 wcross_resolution_goal_prev_prev = 0;
 999         }
1000 }
1001
1002 void HUD_Draw()
1003 {
1004         if(getstati(STAT_FROZEN))
1005                 drawfill('0 0 0', eX * vid_conwidth + eY * vid_conheight, ((getstatf(STAT_REVIVE_PROGRESS)) ? ('0.25 0.90 1' + ('1 0 0' * getstatf(STAT_REVIVE_PROGRESS)) + ('0 1 1' * getstatf(STAT_REVIVE_PROGRESS) * -1)) : '0.25 0.90 1'), autocvar_hud_colorflash_alpha, DRAWFLAG_ADDITIVE);
1006         else if (getstatf(STAT_HEALING_ORB)>time)
1007                 drawfill('0 0 0', eX * vid_conwidth + eY * vid_conheight, NADE_TYPE_HEAL.m_color, autocvar_hud_colorflash_alpha*getstatf(STAT_HEALING_ORB_ALPHA), DRAWFLAG_ADDITIVE);
1008         if(!intermission)
1009         if(getstatf(STAT_NADE_TIMER) && autocvar_cl_nade_timer) // give nade top priority, as it's a matter of life and death
1010         {
1011                 DrawCircleClippedPic(eX * 0.5 * vid_conwidth + eY * 0.6 * vid_conheight, 0.1 * vid_conheight, "gfx/crosshair_ring.tga", getstatf(STAT_NADE_TIMER), '0.25 0.90 1' + ('1 0 0' * getstatf(STAT_NADE_TIMER)) - ('0 1 1' * getstatf(STAT_NADE_TIMER)), autocvar_hud_colorflash_alpha, DRAWFLAG_ADDITIVE);
1012                 drawstring_aspect(eY * 0.64 * vid_conheight, ((autocvar_cl_nade_timer == 2) ? _("Nade timer") : ""), eX * vid_conwidth + eY * 0.025 * vid_conheight, '1 1 1', 1, DRAWFLAG_NORMAL);
1013         }
1014         else if(getstatf(STAT_REVIVE_PROGRESS))
1015         {
1016                 DrawCircleClippedPic(eX * 0.5 * vid_conwidth + eY * 0.6 * vid_conheight, 0.1 * vid_conheight, "gfx/crosshair_ring.tga", getstatf(STAT_REVIVE_PROGRESS), '0.25 0.90 1', autocvar_hud_colorflash_alpha, DRAWFLAG_ADDITIVE);
1017                 drawstring_aspect(eY * 0.64 * vid_conheight, _("Revival progress"), eX * vid_conwidth + eY * 0.025 * vid_conheight, '1 1 1', 1, DRAWFLAG_NORMAL);
1018         }
1019
1020         if(autocvar_r_letterbox == 0)
1021                 if(autocvar_viewsize < 120)
1022                 {
1023                         if(!(gametype == MAPINFO_TYPE_RACE || gametype == MAPINFO_TYPE_CTS))
1024                                 Accuracy_LoadLevels();
1025
1026                         HUD_Main();
1027                         HUD_DrawScoreboard();
1028                 }
1029
1030         // crosshair goes VERY LAST
1031         UpdateDamage();
1032         HUD_Crosshair();
1033         HitSound();
1034 }
1035
1036 bool ov_enabled;
1037 float oldr_nearclip;
1038 float oldr_farclip_base;
1039 float oldr_farclip_world;
1040 float oldr_novis;
1041 float oldr_useportalculling;
1042 float oldr_useinfinitefarclip;
1043
1044 const int BUTTON_3 = 4;
1045 const int BUTTON_4 = 8;
1046 float cl_notice_run();
1047 float prev_myteam;
1048 int lasthud;
1049 float vh_notice_time;
1050 void WaypointSprite_Load();
1051 void CSQC_UpdateView(float w, float h)
1052 {SELFPARAM();
1053         entity e;
1054         float fov;
1055         float f;
1056         vector vf_size, vf_min;
1057         float a;
1058
1059         execute_next_frame();
1060
1061         ++framecount;
1062
1063         hud = getstati(STAT_HUD);
1064
1065         if(hud != HUD_NORMAL && lasthud == HUD_NORMAL)
1066                 vh_notice_time = time + autocvar_cl_vehicles_notify_time;
1067
1068         lasthud = hud;
1069
1070         if(autocvar__hud_showbinds_reload) // menu can set this one
1071         {
1072                 db_close(binddb);
1073                 binddb = db_create();
1074                 cvar_set("_hud_showbinds_reload", "0");
1075         }
1076
1077         if(checkextension("DP_CSQC_MINFPS_QUALITY"))
1078                 view_quality = getproperty(VF_MINFPS_QUALITY);
1079         else
1080                 view_quality = 1;
1081
1082         button_attack2 = (input_buttons & BUTTON_3);
1083         button_zoom = (input_buttons & BUTTON_4);
1084
1085         vf_size = getpropertyvec(VF_SIZE);
1086         vf_min = getpropertyvec(VF_MIN);
1087         vid_width = vf_size.x;
1088         vid_height = vf_size.y;
1089
1090         vector reticle_pos = '0 0 0', reticle_size = '0 0 0';
1091         vector splash_pos = '0 0 0', splash_size = '0 0 0';
1092
1093         WaypointSprite_Load();
1094
1095         CSQCPlayer_SetCamera();
1096
1097         if(player_localentnum <= maxclients) // is it a client?
1098                 current_player = player_localentnum - 1;
1099         else // then player_localentnum is the vehicle I'm driving
1100                 current_player = player_localnum;
1101         myteam = GetPlayerColor(current_player);
1102
1103         if(myteam != prev_myteam)
1104         {
1105                 myteamcolors = colormapPaletteColor(myteam, 1);
1106                 FOREACH(hud_panels, true, LAMBDA(it.update_time = time));
1107                 prev_myteam = myteam;
1108         }
1109
1110         ticrate = getstatf(STAT_MOVEVARS_TICRATE) * getstatf(STAT_MOVEVARS_TIMESCALE);
1111
1112         float is_dead = (getstati(STAT_HEALTH) <= 0);
1113
1114         // FIXME do we need this hack?
1115         if(isdemo())
1116         {
1117                 // in demos, input_buttons do not work
1118                 button_zoom = (autocvar__togglezoom == "-");
1119         }
1120         else if(button_zoom
1121                 && autocvar_cl_unpress_zoom_on_death
1122                 && (spectatee_status >= 0)
1123                 && (is_dead || intermission))
1124         {
1125                 // no zoom while dead or in intermission please
1126                 localcmd("-zoom\n");
1127                 button_zoom = false;
1128         }
1129
1130         // event chase camera
1131         if(autocvar_chase_active <= 0) // greater than 0 means it's enabled manually, and this code is skipped
1132         {
1133                 float vehicle_chase = (hud != HUD_NORMAL && (autocvar_cl_eventchase_vehicle || spectatee_status > 0));
1134                 float ons_roundlost = (gametype == MAPINFO_TYPE_ONSLAUGHT && getstati(STAT_ROUNDLOST));
1135                 entity gen = world;
1136
1137                 if(ons_roundlost)
1138                 {
1139                         entity e;
1140                         for(e = world; (e = find(e, classname, "onslaught_generator")); )
1141                         {
1142                                 if(e.health <= 0)
1143                                 {
1144                                         gen = e;
1145                                         break;
1146                                 }
1147                         }
1148                         if(!gen)
1149                                 ons_roundlost = FALSE; // don't enforce the 3rd person camera if there is no dead generator to show
1150                 }
1151                 if(WantEventchase() || (!autocvar_cl_orthoview && ons_roundlost))
1152                 {
1153                         eventchase_running = true;
1154
1155                         // make special vector since we can't use view_origin (It is one frame old as of this code, it gets set later with the results this code makes.)
1156                         vector current_view_origin = (csqcplayer ? csqcplayer.origin : pmove_org);
1157                         if(ons_roundlost) { current_view_origin = gen.origin; }
1158
1159                         // detect maximum viewoffset and use it
1160                         vector view_offset = autocvar_cl_eventchase_viewoffset;
1161                         if(vehicle_chase && autocvar_cl_eventchase_vehicle_viewoffset) { view_offset = autocvar_cl_eventchase_vehicle_viewoffset; }
1162                         if(ons_roundlost) { view_offset = autocvar_cl_eventchase_generator_viewoffset; }
1163
1164                         if(view_offset)
1165                         {
1166                                 WarpZone_TraceLine(current_view_origin, current_view_origin + view_offset + ('0 0 1' * autocvar_cl_eventchase_maxs.z), MOVE_WORLDONLY, self);
1167                                 if(trace_fraction == 1) { current_view_origin += view_offset; }
1168                                 else { current_view_origin.z += max(0, (trace_endpos.z - current_view_origin.z) - autocvar_cl_eventchase_maxs.z); }
1169                         }
1170
1171                         // We must enable chase_active to get a third person view (weapon viewmodel hidden and own player model showing).
1172                         // Ideally, there should be another way to enable third person cameras, such as through setproperty()
1173                         // -1 enables chase_active while marking it as set by this code, and not by the user (which would be 1)
1174                         if(!autocvar_chase_active) { cvar_set("chase_active", "-1"); }
1175
1176                         // make the camera smooth back
1177                         float chase_distance = autocvar_cl_eventchase_distance;
1178                         if(vehicle_chase && autocvar_cl_eventchase_vehicle_distance) { chase_distance = autocvar_cl_eventchase_vehicle_distance; }
1179                         if(ons_roundlost) { chase_distance = autocvar_cl_eventchase_generator_distance; }
1180
1181                         if(autocvar_cl_eventchase_speed && eventchase_current_distance < chase_distance)
1182                                 eventchase_current_distance += autocvar_cl_eventchase_speed * (chase_distance - eventchase_current_distance) * frametime; // slow down the further we get
1183                         else if(eventchase_current_distance != chase_distance)
1184                                 eventchase_current_distance = chase_distance;
1185
1186                         makevectors(view_angles);
1187
1188                         vector eventchase_target_origin = (current_view_origin - (v_forward * eventchase_current_distance));
1189                         WarpZone_TraceBox(current_view_origin, autocvar_cl_eventchase_mins, autocvar_cl_eventchase_maxs, eventchase_target_origin, MOVE_WORLDONLY, self);
1190
1191                         // If the boxtrace fails, revert back to line tracing.
1192                         if(!self.viewloc)
1193                         if(trace_startsolid)
1194                         {
1195                                 eventchase_target_origin = (current_view_origin - (v_forward * eventchase_current_distance));
1196                                 WarpZone_TraceLine(current_view_origin, eventchase_target_origin, MOVE_WORLDONLY, self);
1197                                 setproperty(VF_ORIGIN, (trace_endpos - (v_forward * autocvar_cl_eventchase_mins.z)));
1198                         }
1199                         else { setproperty(VF_ORIGIN, trace_endpos); }
1200
1201                         if(!self.viewloc)
1202                                 setproperty(VF_ANGLES, WarpZone_TransformVAngles(WarpZone_trace_transform, view_angles));
1203                 }
1204                 else if(autocvar_chase_active < 0) // time to disable chase_active if it was set by this code
1205                 {
1206                         eventchase_running = false;
1207                         cvar_set("chase_active", "0");
1208                         eventchase_current_distance = 0; // start from 0 next time
1209                 }
1210         }
1211         // workaround for camera stuck between player's legs when using chase_active 1
1212         // because the engine stops updating the chase_active camera when the game ends
1213         else if(intermission)
1214         {
1215                 cvar_settemp("chase_active", "-1");
1216                 eventchase_current_distance = 0;
1217         }
1218
1219         // do lockview after event chase camera so that it still applies whenever necessary.
1220         if(autocvar_cl_lockview || (!autocvar_hud_cursormode && (autocvar__hud_configure && spectatee_status <= 0 || intermission > 1 || QuickMenu_IsOpened())))
1221         {
1222                 setproperty(VF_ORIGIN, freeze_org);
1223                 setproperty(VF_ANGLES, freeze_ang);
1224         }
1225         else
1226         {
1227                 freeze_org = getpropertyvec(VF_ORIGIN);
1228                 freeze_ang = getpropertyvec(VF_ANGLES);
1229         }
1230
1231         WarpZone_FixView();
1232         //WarpZone_FixPMove();
1233
1234         vector ov_org = '0 0 0';
1235         vector ov_mid = '0 0 0';
1236         vector ov_worldmin = '0 0 0';
1237         vector ov_worldmax = '0 0 0';
1238         if(autocvar_cl_orthoview)
1239         {
1240                 ov_worldmin = mi_picmin;
1241                 ov_worldmax = mi_picmax;
1242
1243                 float ov_width = (ov_worldmax.x - ov_worldmin.x);
1244                 float ov_height = (ov_worldmax.y - ov_worldmin.y);
1245                 float ov_distance = (max(vid_width, vid_height) * max(ov_width, ov_height));
1246
1247                 ov_mid = ((ov_worldmax + ov_worldmin) * 0.5);
1248                 ov_org = vec3(ov_mid.x, ov_mid.y, (ov_mid.z + ov_distance));
1249
1250                 float ov_nearest = vlen(ov_org - vec3(
1251                         bound(ov_worldmin.x, ov_org.x, ov_worldmax.x),
1252                         bound(ov_worldmin.y, ov_org.y, ov_worldmax.y),
1253                         bound(ov_worldmin.z, ov_org.z, ov_worldmax.z)
1254                 ));
1255
1256                 float ov_furthest = 0;
1257                 float dist = 0;
1258
1259                 if((dist = vlen(vec3(ov_worldmin.x, ov_worldmin.y, ov_worldmin.z) - ov_org)) > ov_furthest) { ov_furthest = dist; }
1260                 if((dist = vlen(vec3(ov_worldmax.x, ov_worldmin.y, ov_worldmin.z) - ov_org)) > ov_furthest) { ov_furthest = dist; }
1261                 if((dist = vlen(vec3(ov_worldmin.x, ov_worldmax.y, ov_worldmin.z) - ov_org)) > ov_furthest) { ov_furthest = dist; }
1262                 if((dist = vlen(vec3(ov_worldmin.x, ov_worldmin.y, ov_worldmax.z) - ov_org)) > ov_furthest) { ov_furthest = dist; }
1263                 if((dist = vlen(vec3(ov_worldmax.x, ov_worldmax.y, ov_worldmin.z) - ov_org)) > ov_furthest) { ov_furthest = dist; }
1264                 if((dist = vlen(vec3(ov_worldmin.x, ov_worldmax.y, ov_worldmax.z) - ov_org)) > ov_furthest) { ov_furthest = dist; }
1265                 if((dist = vlen(vec3(ov_worldmax.x, ov_worldmin.y, ov_worldmax.z) - ov_org)) > ov_furthest) { ov_furthest = dist; }
1266                 if((dist = vlen(vec3(ov_worldmax.x, ov_worldmax.y, ov_worldmax.z) - ov_org)) > ov_furthest) { ov_furthest = dist; }
1267
1268                 if(!ov_enabled)
1269                 {
1270                         oldr_nearclip = cvar("r_nearclip");
1271                         oldr_farclip_base = cvar("r_farclip_base");
1272                         oldr_farclip_world = cvar("r_farclip_world");
1273                         oldr_novis = cvar("r_novis");
1274                         oldr_useportalculling = cvar("r_useportalculling");
1275                         oldr_useinfinitefarclip = cvar("r_useinfinitefarclip");
1276                 }
1277
1278                 cvar_settemp("r_nearclip", ftos(ov_nearest));
1279                 cvar_settemp("r_farclip_base", ftos(ov_furthest));
1280                 cvar_settemp("r_farclip_world", "0");
1281                 cvar_settemp("r_novis", "1");
1282                 cvar_settemp("r_useportalculling", "0");
1283                 cvar_settemp("r_useinfinitefarclip", "0");
1284
1285                 setproperty(VF_ORIGIN, ov_org);
1286                 setproperty(VF_ANGLES, '90 0 0');
1287
1288                 ov_enabled = true;
1289
1290                 #if 0
1291                 LOG_INFOF("OrthoView: org = %s, angles = %s, distance = %f, nearest = %f, furthest = %f\n",
1292                         vtos(ov_org),
1293                         vtos(getpropertyvec(VF_ANGLES)),
1294                         ov_distance,
1295                         ov_nearest,
1296                         ov_furthest);
1297                 #endif
1298         }
1299         else
1300         {
1301                 if(ov_enabled)
1302                 {
1303                         cvar_set("r_nearclip", ftos(oldr_nearclip));
1304                         cvar_set("r_farclip_base", ftos(oldr_farclip_base));
1305                         cvar_set("r_farclip_world", ftos(oldr_farclip_world));
1306                         cvar_set("r_novis", ftos(oldr_novis));
1307                         cvar_set("r_useportalculling", ftos(oldr_useportalculling));
1308                         cvar_set("r_useinfinitefarclip", ftos(oldr_useinfinitefarclip));
1309                 }
1310                 ov_enabled = false;
1311         }
1312
1313         // Render the Scene
1314         view_origin = getpropertyvec(VF_ORIGIN);
1315         view_angles = getpropertyvec(VF_ANGLES);
1316         makevectors(view_angles);
1317         view_forward = v_forward;
1318         view_right = v_right;
1319         view_up = v_up;
1320
1321 #ifdef BLURTEST
1322         if(time > blurtest_time0 && time < blurtest_time1)
1323         {
1324                 float r, t;
1325
1326                 t = (time - blurtest_time0) / (blurtest_time1 - blurtest_time0);
1327                 r = t * blurtest_radius;
1328                 f = 1 / pow(t, blurtest_power) - 1;
1329
1330                 cvar_set("r_glsl_postprocess", "1");
1331                 cvar_set("r_glsl_postprocess_uservec1", strcat(ftos(r), " ", ftos(f), " 0 0"));
1332         }
1333         else
1334         {
1335                 cvar_set("r_glsl_postprocess", "0");
1336                 cvar_set("r_glsl_postprocess_uservec1", "0 0 0 0");
1337         }
1338 #endif
1339
1340         TargetMusic_Advance();
1341         Fog_Force();
1342
1343         if(drawtime == 0)
1344                 drawframetime = 0.01666667; // when we don't know fps yet, we assume 60fps
1345         else
1346                 drawframetime = bound(0.000001, time - drawtime, 1);
1347         drawtime = time;
1348
1349         // watch for gametype changes here...
1350         // in ParseStuffCMD the cmd isn't executed yet :/
1351         // might even be better to add the gametype to TE_CSQC_INIT...?
1352         if(!postinit)
1353                 PostInit();
1354
1355         if(intermission && !isdemo() && !(calledhooks & HOOK_END))
1356         {
1357                 if(calledhooks & HOOK_START)
1358                 {
1359                         localcmd("\ncl_hook_gameend\n");
1360                         calledhooks |= HOOK_END;
1361                 }
1362         }
1363
1364         Announcer();
1365
1366         fov = autocvar_fov;
1367         if(fov <= 59.5)
1368         {
1369                 if(!zoomscript_caught)
1370                 {
1371                         localcmd("+button9\n");
1372                         zoomscript_caught = 1;
1373                 }
1374         }
1375         else
1376         {
1377                 if(zoomscript_caught)
1378                 {
1379                         localcmd("-button9\n");
1380                         zoomscript_caught = 0;
1381                 }
1382         }
1383
1384         ColorTranslateMode = autocvar_cl_stripcolorcodes;
1385
1386         // next WANTED weapon (for HUD)
1387         switchweapon = getstati(STAT_SWITCHWEAPON);
1388
1389         // currently switching-to weapon (for crosshair)
1390         switchingweapon = getstati(STAT_SWITCHINGWEAPON);
1391
1392         // actually active weapon (for zoom)
1393         activeweapon = getstati(STAT_ACTIVEWEAPON);
1394
1395         f = (serverflags & SERVERFLAG_TEAMPLAY);
1396         if(f != teamplay)
1397         {
1398                 teamplay = f;
1399                 HUD_InitScores();
1400         }
1401
1402         if(last_switchweapon != switchweapon)
1403         {
1404                 weapontime = time;
1405                 last_switchweapon = switchweapon;
1406                 if(button_zoom && autocvar_cl_unpress_zoom_on_weapon_switch)
1407                 {
1408                         localcmd("-zoom\n");
1409                         button_zoom = false;
1410                 }
1411                 if(autocvar_cl_unpress_attack_on_weapon_switch)
1412                 {
1413                         localcmd("-fire\n");
1414                         localcmd("-fire2\n");
1415                         button_attack2 = false;
1416                 }
1417         }
1418         if(last_activeweapon != activeweapon)
1419         {
1420                 last_activeweapon = activeweapon;
1421
1422                 e = get_weaponinfo(activeweapon);
1423                 if(e.netname != "")
1424                         localcmd(strcat("\ncl_hook_activeweapon ", e.netname), "\n");
1425                 else
1426                         localcmd("\ncl_hook_activeweapon none\n");
1427         }
1428
1429         // ALWAYS Clear Current Scene First
1430         clearscene();
1431
1432         setproperty(VF_ORIGIN, view_origin);
1433         setproperty(VF_ANGLES, view_angles);
1434
1435         // FIXME engine bug? VF_SIZE and VF_MIN are not restored to sensible values by this
1436         setproperty(VF_SIZE, vf_size);
1437         setproperty(VF_MIN, vf_min);
1438
1439         // Assign Standard Viewflags
1440         // Draw the World (and sky)
1441         setproperty(VF_DRAWWORLD, 1);
1442
1443         // Set the console size vars
1444         vid_conwidth = autocvar_vid_conwidth;
1445         vid_conheight = autocvar_vid_conheight;
1446         vid_pixelheight = autocvar_vid_pixelheight;
1447
1448         if(autocvar_cl_orthoview) { setproperty(VF_FOV, GetOrthoviewFOV(ov_worldmin, ov_worldmax, ov_mid, ov_org)); }
1449         else if(csqcplayer.viewloc) { setproperty(VF_FOV, GetViewLocationFOV(110)); } // enforce 110 fov, so things dont look odd
1450         else { setproperty(VF_FOV, GetCurrentFov(fov)); }
1451
1452         // Camera for demo playback
1453         if(camera_active)
1454         {
1455                 if(autocvar_camera_enable)
1456                         CSQC_Demo_Camera();
1457                 else
1458                 {
1459                         cvar_set("chase_active", ftos(chase_active_backup));
1460                         cvar_set("cl_demo_mousegrab", "0");
1461                         camera_active = false;
1462                 }
1463         }
1464         else
1465         {
1466 #ifdef CAMERATEST
1467                 if(autocvar_camera_enable)
1468 #else
1469                 if(autocvar_camera_enable && isdemo())
1470 #endif
1471                 {
1472                         // Enable required Darkplaces cvars
1473                         chase_active_backup = autocvar_chase_active;
1474                         cvar_set("chase_active", "2");
1475                         cvar_set("cl_demo_mousegrab", "1");
1476                         camera_active = true;
1477                         camera_mode = false;
1478                 }
1479         }
1480
1481         // Draw the Crosshair
1482         setproperty(VF_DRAWCROSSHAIR, 0); //Make sure engine crosshairs are always hidden
1483
1484         // Draw the Engine Status Bar (the default Quake HUD)
1485         setproperty(VF_DRAWENGINESBAR, 0);
1486
1487         // Update the mouse position
1488         /*
1489            mousepos_x = vid_conwidth;
1490            mousepos_y = vid_conheight;
1491            mousepos = mousepos*0.5 + getmousepos();
1492          */
1493
1494         for(entity e = NULL; (e = nextent(e)); ) if (e.draw) {
1495                 WITH(entity, self, e, e.draw(e));
1496         }
1497
1498         addentities(MASK_NORMAL | MASK_ENGINE | MASK_ENGINEVIEWMODELS);
1499         renderscene();
1500
1501         // now switch to 2D drawing mode by calling a 2D drawing function
1502         // then polygon drawing will draw as 2D stuff, and NOT get queued until the
1503         // next R_RenderScene call
1504         drawstring('0 0 0', "", '1 1 0', '1 1 1', 0, 0);
1505
1506         if(autocvar_r_fakelight >= 2 || autocvar_r_fullbright)
1507         if (!(serverflags & SERVERFLAG_ALLOW_FULLBRIGHT))
1508         {
1509                 // apply night vision effect
1510                 vector tc_00, tc_01, tc_10, tc_11;
1511                 vector rgb = '0 0 0';
1512
1513                 if(!nightvision_noise)
1514                 {
1515                         nightvision_noise = spawn();
1516                         nightvision_noise.classname = "nightvision_noise";
1517                 }
1518                 if(!nightvision_noise2)
1519                 {
1520                         nightvision_noise2 = spawn();
1521                         nightvision_noise2.classname = "nightvision_noise2";
1522                 }
1523
1524                 // color tint in yellow
1525                 drawfill('0 0 0', autocvar_vid_conwidth * '1 0 0' + autocvar_vid_conheight * '0 1 0', '0.5 1 0.3', 1, DRAWFLAG_MODULATE);
1526
1527                 // draw BG
1528                 a = Noise_Pink(nightvision_noise, frametime * 1.5) * 0.05 + 0.15;
1529                 rgb = '1 1 1';
1530                 tc_00 = '0 0 0' + '0.2 0 0' * sin(time * 0.3) + '0 0.3 0' * cos(time * 0.7);
1531                 tc_01 = '0 2.25 0' + '0.6 0 0' * cos(time * 1.2) - '0 0.3 0' * sin(time * 2.2);
1532                 tc_10 = '1.5 0 0' - '0.2 0 0' * sin(time * 0.5) + '0 0.5 0' * cos(time * 1.7);
1533                 //tc_11 = '1 1 0' + '0.6 0 0' * sin(time * 0.6) + '0 0.3 0' * cos(time * 0.1);
1534                 tc_11 = tc_01 + tc_10 - tc_00;
1535                 R_BeginPolygon("gfx/nightvision-bg.tga", DRAWFLAG_ADDITIVE);
1536                 R_PolygonVertex('0 0 0', tc_00, rgb, a);
1537                 R_PolygonVertex(autocvar_vid_conwidth * '1 0 0', tc_10, rgb, a);
1538                 R_PolygonVertex(autocvar_vid_conwidth * '1 0 0' + autocvar_vid_conheight * '0 1 0', tc_11, rgb, a);
1539                 R_PolygonVertex(autocvar_vid_conheight * '0 1 0', tc_01, rgb, a);
1540                 R_EndPolygon();
1541
1542                 // draw FG
1543                 a = Noise_Pink(nightvision_noise2, frametime * 0.1) * 0.05 + 0.12;
1544                 rgb = '0.3 0.6 0.4' + '0.1 0.4 0.2' * Noise_White(nightvision_noise2, frametime);
1545                 tc_00 = '0 0 0' + '1 0 0' * Noise_White(nightvision_noise2, frametime) + '0 1 0' * Noise_White(nightvision_noise2, frametime);
1546                 tc_01 = tc_00 + '0 3 0' * (1 + Noise_White(nightvision_noise2, frametime) * 0.2);
1547                 tc_10 = tc_00 + '2 0 0' * (1 + Noise_White(nightvision_noise2, frametime) * 0.3);
1548                 tc_11 = tc_01 + tc_10 - tc_00;
1549                 R_BeginPolygon("gfx/nightvision-fg.tga", DRAWFLAG_ADDITIVE);
1550                 R_PolygonVertex('0 0 0', tc_00, rgb, a);
1551                 R_PolygonVertex(autocvar_vid_conwidth * '1 0 0', tc_10, rgb, a);
1552                 R_PolygonVertex(autocvar_vid_conwidth * '1 0 0' + autocvar_vid_conheight * '0 1 0', tc_11, rgb, a);
1553                 R_PolygonVertex(autocvar_vid_conheight * '0 1 0', tc_01, rgb, a);
1554                 R_EndPolygon();
1555         }
1556
1557         if(autocvar_cl_reticle)
1558         {
1559                 Weapon wep = get_weaponinfo(activeweapon);
1560                 // Draw the aiming reticle for weapons that use it
1561                 // reticle_type is changed to the item we are zooming / aiming with, to decide which reticle to use
1562                 // It must be a persisted float for fading out to work properly (you let go of the zoom button for
1563                 // the view to go back to normal, so reticle_type would become 0 as we fade out)
1564                 if(spectatee_status || is_dead || hud != HUD_NORMAL)
1565                 {
1566                         // no zoom reticle while dead
1567                         reticle_type = 0;
1568                 }
1569                 else if(wep.wr_zoomreticle(wep) && autocvar_cl_reticle_weapon)
1570                 {
1571                         if(reticle_image != "") { reticle_type = 2; }
1572                         else { reticle_type = 0; }
1573                 }
1574                 else if(button_zoom || zoomscript_caught)
1575                 {
1576                         // normal zoom
1577                         reticle_type = 1;
1578                 }
1579
1580                 if(reticle_type)
1581                 {
1582                         if(autocvar_cl_reticle_stretch)
1583                         {
1584                                 reticle_size.x = vid_conwidth;
1585                                 reticle_size.y = vid_conheight;
1586                                 reticle_pos.x = 0;
1587                                 reticle_pos.y = 0;
1588                         }
1589                         else
1590                         {
1591                                 reticle_size.x = max(vid_conwidth, vid_conheight);
1592                                 reticle_size.y = max(vid_conwidth, vid_conheight);
1593                                 reticle_pos.x = (vid_conwidth - reticle_size.x) / 2;
1594                                 reticle_pos.y = (vid_conheight - reticle_size.y) / 2;
1595                         }
1596
1597                         if(zoomscript_caught)
1598                                 f = 1;
1599                         else
1600                                 f = current_zoomfraction;
1601
1602                         if(f)
1603                         {
1604                                 switch(reticle_type)
1605                                 {
1606                                         case 1: drawpic(reticle_pos, "gfx/reticle_normal", reticle_size, '1 1 1', f * autocvar_cl_reticle_normal_alpha, DRAWFLAG_NORMAL); break;
1607                                         case 2: drawpic(reticle_pos, reticle_image, reticle_size, '1 1 1', f * autocvar_cl_reticle_weapon_alpha, DRAWFLAG_NORMAL); break;
1608                                 }
1609                         }
1610                 }
1611         }
1612         else
1613         {
1614                 if(reticle_type != 0) { reticle_type = 0; }
1615         }
1616
1617
1618         // improved polyblend
1619         if(autocvar_hud_contents)
1620         {
1621                 float contentalpha_temp, incontent, liquidalpha, contentfadetime;
1622                 vector liquidcolor;
1623
1624                 switch(pointcontents(view_origin))
1625                 {
1626                         case CONTENT_WATER:
1627                                 liquidalpha = autocvar_hud_contents_water_alpha;
1628                                 liquidcolor = stov(autocvar_hud_contents_water_color);
1629                                 incontent = 1;
1630                                 break;
1631
1632                         case CONTENT_LAVA:
1633                                 liquidalpha = autocvar_hud_contents_lava_alpha;
1634                                 liquidcolor = stov(autocvar_hud_contents_lava_color);
1635                                 incontent = 1;
1636                                 break;
1637
1638                         case CONTENT_SLIME:
1639                                 liquidalpha = autocvar_hud_contents_slime_alpha;
1640                                 liquidcolor = stov(autocvar_hud_contents_slime_color);
1641                                 incontent = 1;
1642                                 break;
1643
1644                         default:
1645                                 liquidalpha = 0;
1646                                 liquidcolor = '0 0 0';
1647                                 incontent = 0;
1648                                 break;
1649                 }
1650
1651                 if(incontent) // fade in/out at different speeds so you can do e.g. instant fade when entering water and slow when leaving it.
1652                 { // also lets delcare previous values for blending properties, this way it isn't reset until after you have entered a different content
1653                         contentfadetime = autocvar_hud_contents_fadeintime;
1654                         liquidalpha_prev = liquidalpha;
1655                         liquidcolor_prev = liquidcolor;
1656                 }
1657                 else
1658                         contentfadetime = autocvar_hud_contents_fadeouttime;
1659
1660                 contentalpha_temp = bound(0, drawframetime / max(0.0001, contentfadetime), 1);
1661                 contentavgalpha = contentavgalpha * (1 - contentalpha_temp) + incontent * contentalpha_temp;
1662
1663                 if(contentavgalpha)
1664                         drawfill('0 0 0', eX * vid_conwidth + eY * vid_conheight, liquidcolor_prev, contentavgalpha * liquidalpha_prev, DRAWFLAG_NORMAL);
1665
1666                 if(autocvar_hud_postprocessing)
1667                 {
1668                         if(autocvar_hud_contents_blur && contentavgalpha)
1669                         {
1670                                 content_blurpostprocess.x = 1;
1671                                 content_blurpostprocess.y = contentavgalpha * autocvar_hud_contents_blur;
1672                                 content_blurpostprocess.z = contentavgalpha * autocvar_hud_contents_blur_alpha;
1673                         }
1674                         else
1675                         {
1676                                 content_blurpostprocess.x = 0;
1677                                 content_blurpostprocess.y = 0;
1678                                 content_blurpostprocess.z = 0;
1679                         }
1680                 }
1681         }
1682
1683         if(autocvar_hud_damage && !getstati(STAT_FROZEN))
1684         {
1685                 splash_size.x = max(vid_conwidth, vid_conheight);
1686                 splash_size.y = max(vid_conwidth, vid_conheight);
1687                 splash_pos.x = (vid_conwidth - splash_size.x) / 2;
1688                 splash_pos.y = (vid_conheight - splash_size.y) / 2;
1689
1690                 float myhealth_flash_temp;
1691                 myhealth = getstati(STAT_HEALTH);
1692
1693                 // fade out
1694                 myhealth_flash = max(0, myhealth_flash - autocvar_hud_damage_fade_rate * frametime);
1695                 // add new damage
1696                 myhealth_flash = bound(0, myhealth_flash + dmg_take * autocvar_hud_damage_factor, autocvar_hud_damage_maxalpha);
1697
1698                 float pain_threshold, pain_threshold_lower, pain_threshold_lower_health;
1699                 pain_threshold = autocvar_hud_damage_pain_threshold;
1700                 pain_threshold_lower = autocvar_hud_damage_pain_threshold_lower;
1701                 pain_threshold_lower_health = autocvar_hud_damage_pain_threshold_lower_health;
1702
1703                 if(pain_threshold_lower && myhealth < pain_threshold_lower_health)
1704                 {
1705                         pain_threshold = pain_threshold - max(autocvar_hud_damage_pain_threshold_pulsating_min, fabs(sin(M_PI * time / autocvar_hud_damage_pain_threshold_pulsating_period))) * pain_threshold_lower * (1 - max(0, myhealth)/pain_threshold_lower_health);
1706                 }
1707
1708                 myhealth_flash_temp = bound(0, myhealth_flash - pain_threshold, 1);
1709
1710                 if(myhealth_prev < 1)
1711                 {
1712                         if(myhealth >= 1)
1713                         {
1714                                 myhealth_flash = 0; // just spawned, clear the flash immediately
1715                                 myhealth_flash_temp = 0;
1716                         }
1717                         else
1718                         {
1719                                 myhealth_flash += autocvar_hud_damage_fade_rate * frametime; // dead
1720                         }
1721                 }
1722
1723                 if(spectatee_status == -1 || intermission)
1724                 {
1725                         myhealth_flash = 0; // observing, or match ended
1726                         myhealth_flash_temp = 0;
1727                 }
1728
1729                 myhealth_prev = myhealth;
1730
1731                 // IDEA: change damage color/picture based on player model for robot/alien species?
1732                 // pro: matches model better
1733                 // contra: it's not red because blood is red, but because red is an alarming color, so red should stay
1734                 // maybe different reddish pics?
1735                 if(autocvar_cl_gentle_damage || autocvar_cl_gentle)
1736                 {
1737                         if(autocvar_cl_gentle_damage == 2)
1738                         {
1739                                 if(myhealth_flash < pain_threshold) // only randomize when the flash is gone
1740                                 {
1741                                         myhealth_gentlergb = eX * random() + eY * random() + eZ * random();
1742                                 }
1743                         }
1744                         else
1745                                 myhealth_gentlergb = stov(autocvar_hud_damage_gentle_color);
1746
1747                         drawfill('0 0 0', eX * vid_conwidth + eY * vid_conheight, myhealth_gentlergb, autocvar_hud_damage_gentle_alpha_multiplier * bound(0, myhealth_flash_temp, 1) * autocvar_hud_damage, DRAWFLAG_NORMAL);
1748                 }
1749                 else
1750                         drawpic(splash_pos, "gfx/blood", splash_size, stov(autocvar_hud_damage_color), bound(0, myhealth_flash_temp, 1) * autocvar_hud_damage, DRAWFLAG_NORMAL);
1751
1752                 if(autocvar_hud_postprocessing) // we still need to set this anyway even when chase_active is set, this way it doesn't get stuck on.
1753                 {
1754                         if(autocvar_hud_damage_blur && myhealth_flash_temp)
1755                         {
1756                                 damage_blurpostprocess.x = 1;
1757                                 damage_blurpostprocess.y = bound(0, myhealth_flash_temp, 1) * autocvar_hud_damage_blur;
1758                                 damage_blurpostprocess.z = bound(0, myhealth_flash_temp, 1) * autocvar_hud_damage_blur_alpha;
1759                         }
1760                         else
1761                         {
1762                                 damage_blurpostprocess.x = 0;
1763                                 damage_blurpostprocess.y = 0;
1764                                 damage_blurpostprocess.z = 0;
1765                         }
1766                 }
1767         }
1768
1769         float e1 = (autocvar_hud_postprocessing_maxbluralpha != 0);
1770         float e2 = (autocvar_hud_powerup != 0);
1771         if(autocvar_hud_postprocessing && (e1 || e2)) // TODO: Remove this code and re-do the postprocess handling in the engine, where it properly belongs.
1772         {
1773                 // enable or disable rendering types if they are used or not
1774                 if(cvar("r_glsl_postprocess_uservec1_enable") != e1) { cvar_set("r_glsl_postprocess_uservec1_enable", ftos(e1)); }
1775                 if(cvar("r_glsl_postprocess_uservec2_enable") != e2) { cvar_set("r_glsl_postprocess_uservec2_enable", ftos(e2)); }
1776
1777                 // blur postprocess handling done first (used by hud_damage and hud_contents)
1778                 if((damage_blurpostprocess.x || content_blurpostprocess.x))
1779                 {
1780                         float blurradius = bound(0, damage_blurpostprocess.y + content_blurpostprocess.y, autocvar_hud_postprocessing_maxblurradius);
1781                         float bluralpha = bound(0, damage_blurpostprocess.z + content_blurpostprocess.z, autocvar_hud_postprocessing_maxbluralpha);
1782                         if(blurradius != old_blurradius || bluralpha != old_bluralpha) // reduce cvar_set spam as much as possible
1783                         {
1784                                 cvar_set("r_glsl_postprocess_uservec1", strcat(ftos(blurradius), " ", ftos(bluralpha), " 0 0"));
1785                                 old_blurradius = blurradius;
1786                                 old_bluralpha = bluralpha;
1787                         }
1788                 }
1789                 else if(cvar_string("r_glsl_postprocess_uservec1") != "0 0 0 0") // reduce cvar_set spam as much as possible
1790                 {
1791                         cvar_set("r_glsl_postprocess_uservec1", "0 0 0 0");
1792                         old_blurradius = 0;
1793                         old_bluralpha = 0;
1794                 }
1795
1796                 // edge detection postprocess handling done second (used by hud_powerup)
1797                 float sharpen_intensity = 0, strength_finished = getstatf(STAT_STRENGTH_FINISHED), invincible_finished = getstatf(STAT_INVINCIBLE_FINISHED);
1798                 if (strength_finished - time > 0) { sharpen_intensity += (strength_finished - time); }
1799                 if (invincible_finished - time > 0) { sharpen_intensity += (invincible_finished - time); }
1800
1801                 sharpen_intensity = bound(0, ((getstati(STAT_HEALTH) > 0) ? sharpen_intensity : 0), 5); // Check to see if player is alive (if not, set 0) - also bound to fade out starting at 5 seconds.
1802
1803                 if(autocvar_hud_powerup && sharpen_intensity > 0)
1804                 {
1805                         if(sharpen_intensity != old_sharpen_intensity) // reduce cvar_set spam as much as possible
1806                         {
1807                                 cvar_set("r_glsl_postprocess_uservec2", strcat(ftos((sharpen_intensity / 5) * autocvar_hud_powerup), " ", ftos(-sharpen_intensity * autocvar_hud_powerup), " 0 0"));
1808                                 old_sharpen_intensity = sharpen_intensity;
1809                         }
1810                 }
1811                 else if(cvar_string("r_glsl_postprocess_uservec2") != "0 0 0 0") // reduce cvar_set spam as much as possible
1812                 {
1813                         cvar_set("r_glsl_postprocess_uservec2", "0 0 0 0");
1814                         old_sharpen_intensity = 0;
1815                 }
1816
1817                 if(cvar("r_glsl_postprocess") == 0)
1818                         cvar_set("r_glsl_postprocess", "2");
1819         }
1820         else if(cvar("r_glsl_postprocess") == 2)
1821                 cvar_set("r_glsl_postprocess", "0");
1822
1823         if(menu_visible)
1824                 menu_show();
1825
1826         /*if(gametype == MAPINFO_TYPE_CTF)
1827           {
1828           ctf_view();
1829           } else */
1830
1831         // draw 2D entities
1832         for (entity e = NULL; (e = nextent(e)); ) if (e.draw2d) {
1833                 WITH(entity, self, e, e.draw2d(e));
1834         }
1835         Draw_ShowNames_All();
1836
1837         scoreboard_active = HUD_WouldDrawScoreboard();
1838
1839         HUD_Draw();
1840
1841         if(NextFrameCommand)
1842         {
1843                 localcmd("\n", NextFrameCommand, "\n");
1844                 NextFrameCommand = string_null;
1845         }
1846
1847         // we must do this check AFTER a frame was rendered, or it won't work
1848         if(cs_project_is_b0rked == 0)
1849         {
1850                 string w0, h0;
1851                 w0 = ftos(autocvar_vid_conwidth);
1852                 h0 = ftos(autocvar_vid_conheight);
1853                 //setproperty(VF_VIEWPORT, '0 0 0', '640 480 0');
1854                 //setproperty(VF_FOV, '90 90 0');
1855                 setproperty(VF_ORIGIN, '0 0 0');
1856                 setproperty(VF_ANGLES, '0 0 0');
1857                 setproperty(VF_PERSPECTIVE, 1);
1858                 makevectors('0 0 0');
1859                 vector v1, v2;
1860                 cvar_set("vid_conwidth", "800");
1861                 cvar_set("vid_conheight", "600");
1862                 v1 = cs_project(v_forward);
1863                 cvar_set("vid_conwidth", "640");
1864                 cvar_set("vid_conheight", "480");
1865                 v2 = cs_project(v_forward);
1866                 if(v1 == v2)
1867                         cs_project_is_b0rked = 1;
1868                 else
1869                         cs_project_is_b0rked = -1;
1870                 cvar_set("vid_conwidth", w0);
1871                 cvar_set("vid_conheight", h0);
1872         }
1873
1874         if(autocvar__hud_configure)
1875                 HUD_Panel_Mouse();
1876         else if ( HUD_MinigameMenu_IsOpened() || minigame_isactive() )
1877                 HUD_Minigame_Mouse();
1878         else if(QuickMenu_IsOpened())
1879                 QuickMenu_Mouse();
1880         else
1881                 HUD_Radar_Mouse();
1882
1883         cl_notice_run();
1884
1885         // let's reset the view back to normal for the end
1886         setproperty(VF_MIN, '0 0 0');
1887         setproperty(VF_SIZE, '1 0 0' * w + '0 1 0' * h);
1888 }
1889
1890
1891 // following vectors must be global to allow seamless switching between camera modes
1892 vector camera_offset, current_camera_offset, mouse_angles, current_angles, current_origin, current_position;
1893 void CSQC_Demo_Camera()
1894 {
1895         float speed, attenuation, dimensions;
1896         vector tmp, delta;
1897
1898         if( autocvar_camera_reset || !camera_mode )
1899         {
1900                 camera_offset = '0 0 0';
1901                 current_angles = '0 0 0';
1902                 camera_direction = '0 0 0';
1903                 camera_offset.z += 30;
1904                 camera_offset.x += 30 * -cos(current_angles.y * DEG2RAD);
1905                 camera_offset.y += 30 * -sin(current_angles.y * DEG2RAD);
1906                 current_origin = view_origin;
1907                 current_camera_offset  = camera_offset;
1908                 cvar_set("camera_reset", "0");
1909                 camera_mode = CAMERA_CHASE;
1910         }
1911
1912         // Camera angles
1913         if( camera_roll )
1914                 mouse_angles.z += camera_roll * autocvar_camera_speed_roll;
1915
1916         if(autocvar_camera_look_player)
1917         {
1918                 vector dir;
1919                 float n;
1920
1921                 dir = normalize(view_origin - current_position);
1922                 n = mouse_angles.z;
1923                 mouse_angles = vectoangles(dir);
1924                 mouse_angles.x = mouse_angles.x * -1;
1925                 mouse_angles.z = n;
1926         }
1927         else
1928         {
1929                 tmp = getmousepos() * 0.1;
1930                 if(vlen(tmp)>autocvar_camera_mouse_threshold)
1931                 {
1932                         mouse_angles.x += tmp.y * cos(mouse_angles.z * DEG2RAD) + (tmp.x * sin(mouse_angles.z * DEG2RAD));
1933                         mouse_angles.y -= tmp.x * cos(mouse_angles.z * DEG2RAD) + (tmp.y * -sin(mouse_angles.z * DEG2RAD));
1934                 }
1935         }
1936
1937         while (mouse_angles.x < -180) mouse_angles.x = mouse_angles.x + 360;
1938         while (mouse_angles.x > 180) mouse_angles.x = mouse_angles.x - 360;
1939         while (mouse_angles.y < -180) mouse_angles.y = mouse_angles.y + 360;
1940         while (mouse_angles.y > 180) mouse_angles.y = mouse_angles.y - 360;
1941
1942         // Fix difference when angles don't have the same sign
1943         delta = '0 0 0';
1944         if(mouse_angles.y < -60 && current_angles.y > 60)
1945                 delta = '0 360 0';
1946         if(mouse_angles.y > 60 && current_angles.y < -60)
1947                 delta = '0 -360 0';
1948
1949         if(autocvar_camera_look_player)
1950                 attenuation = autocvar_camera_look_attenuation;
1951         else
1952                 attenuation = autocvar_camera_speed_attenuation;
1953
1954         attenuation = 1 / max(1, attenuation);
1955         current_angles += (mouse_angles - current_angles + delta) * attenuation;
1956
1957         while (current_angles.x < -180) current_angles.x = current_angles.x + 360;
1958         while (current_angles.x > 180) current_angles.x = current_angles.x - 360;
1959         while (current_angles.y < -180) current_angles.y = current_angles.y + 360;
1960         while (current_angles.y > 180) current_angles.y = current_angles.y - 360;
1961
1962         // Camera position
1963         tmp = '0 0 0';
1964         dimensions = 0;
1965
1966         if( camera_direction.x )
1967         {
1968                 tmp.x = camera_direction.x * cos(current_angles.y * DEG2RAD);
1969                 tmp.y = camera_direction.x * sin(current_angles.y * DEG2RAD);
1970                 if( autocvar_camera_forward_follows && !autocvar_camera_look_player )
1971                         tmp.z = camera_direction.x * -sin(current_angles.x * DEG2RAD);
1972                 ++dimensions;
1973         }
1974
1975         if( camera_direction.y )
1976         {
1977                 tmp.x += camera_direction.y * -sin(current_angles.y * DEG2RAD);
1978                 tmp.y += camera_direction.y * cos(current_angles.y * DEG2RAD) * cos(current_angles.z * DEG2RAD);
1979                 tmp.z += camera_direction.y * sin(current_angles.z * DEG2RAD);
1980                 ++dimensions;
1981         }
1982
1983         if( camera_direction.z )
1984         {
1985                 tmp.z += camera_direction.z * cos(current_angles.z * DEG2RAD);
1986                 ++dimensions;
1987         }
1988
1989         if(autocvar_camera_free)
1990                 speed = autocvar_camera_speed_free;
1991         else
1992                 speed = autocvar_camera_speed_chase;
1993
1994         if(dimensions)
1995         {
1996                 speed = speed * sqrt(1 / dimensions);
1997                 camera_offset += tmp * speed;
1998         }
1999
2000         current_camera_offset += (camera_offset - current_camera_offset) * attenuation;
2001
2002         // Camera modes
2003         if( autocvar_camera_free )
2004         {
2005                 if ( camera_mode == CAMERA_CHASE )
2006                 {
2007                         current_camera_offset = current_origin + current_camera_offset;
2008                         camera_offset = current_origin + camera_offset;
2009                 }
2010
2011                 camera_mode = CAMERA_FREE;
2012                 current_position = current_camera_offset;
2013         }
2014         else
2015         {
2016                 if ( camera_mode == CAMERA_FREE )
2017                 {
2018                         current_origin = view_origin;
2019                         camera_offset = camera_offset - current_origin;
2020                         current_camera_offset = current_camera_offset - current_origin;
2021                 }
2022
2023                 camera_mode = CAMERA_CHASE;
2024
2025                 if(autocvar_camera_chase_smoothly)
2026                         current_origin += (view_origin - current_origin) * attenuation;
2027                 else
2028                         current_origin = view_origin;
2029
2030                 current_position = current_origin + current_camera_offset;
2031         }
2032
2033         setproperty(VF_ANGLES, current_angles);
2034         setproperty(VF_ORIGIN, current_position);
2035 }