qcsrc/client/view.qc

   1 #include "view.qh"
   2
   3 #include "announcer.qh"
   4 #include "hud/_mod.qh"
   5 #include "mapvoting.qh"
   6 #include "shownames.qh"
   7 #include "hud/panel/scoreboard.qh"
   8 #include "hud/panel/quickmenu.qh"
   9
  10 #include "mutators/events.qh"
  11
  12 #include <common/animdecide.qh>
  13 #include <common/ent_cs.qh>
  14 #include <common/anim.qh>
  15 #include <common/constants.qh>
  16 #include <common/net_linked.qh>
  17 #include <common/debug.qh>
  18 #include <common/mapinfo.qh>
  19 #include <common/gamemodes/_mod.qh>
  20 #include <common/physics/player.qh>
  21 #include <common/stats.qh>
  22 #include <common/triggers/target/music.qh>
  23 #include <common/teams.qh>
  24
  25 #include <common/weapons/weapon/tuba.qh>
  26
  27 #include <common/vehicles/all.qh>
  28 #include <common/weapons/_all.qh>
  29 #include <common/mutators/mutator/overkill/okvortex.qh>
  30 #include <common/viewloc.qh>
  31 #include <common/minigames/cl_minigames.qh>
  32 #include <common/minigames/cl_minigames_hud.qh>
  33
  34 #include <lib/csqcmodel/cl_player.qh>
  35 #include <lib/csqcmodel/cl_model.qh>
  36 #include "csqcmodel_hooks.qh"
  37
  38 #include <lib/warpzone/client.qh>
  39 #include <lib/warpzone/common.qh>
  40
  41 #define EFMASK_CHEAP (EF_ADDITIVE | EF_DOUBLESIDED | EF_FULLBRIGHT | EF_NODEPTHTEST | EF_NODRAW | EF_NOSHADOW | EF_SELECTABLE | EF_TELEPORT_BIT)
  42
  43 float autocvar_cl_viewmodel_scale;
  44
  45 bool autocvar_cl_bobmodel;
  46 float autocvar_cl_bobmodel_speed;
  47 float autocvar_cl_bobmodel_side;
  48 float autocvar_cl_bobmodel_up;
  49
  50 float autocvar_cl_followmodel;
  51 float autocvar_cl_followmodel_speed = 0.3;
  52 float autocvar_cl_followmodel_limit = 135;
  53 float autocvar_cl_followmodel_velocity_lowpass = 0.05;
  54 float autocvar_cl_followmodel_highpass = 0.05;
  55 float autocvar_cl_followmodel_lowpass = 0.03;
  56 bool autocvar_cl_followmodel_velocity_absolute;
  57
  58 float autocvar_cl_leanmodel;
  59 float autocvar_cl_leanmodel_speed = 0.3;
  60 float autocvar_cl_leanmodel_limit = 30;
  61 float autocvar_cl_leanmodel_highpass1 = 0.2;
  62 float autocvar_cl_leanmodel_highpass = 0.2;
  63 float autocvar_cl_leanmodel_lowpass = 0.05;
  64
  65 #define avg_factor(avg_time) (1 - exp(-frametime / max(0.001, avg_time)))
  66
  67 #define lowpass(value, frac, ref_store, ret) \
  68         ret = ref_store = ref_store * (1 - frac) + (value) * frac;
  69
  70 #define lowpass_limited(value, frac, limit, ref_store, ret) MACRO_BEGIN \
  71 { \
  72         float __ignore; lowpass(value, frac, ref_store, __ignore); \
  73         ret = ref_store = bound((value) - (limit), ref_store, (value) + (limit)); \
  74 } MACRO_END
  75
  76 #define highpass(value, frac, ref_store, ret) MACRO_BEGIN \
  77 { \
  78         float __f = 0; lowpass(value, frac, ref_store, __f); \
  79         ret = (value) - __f; \
  80 } MACRO_END
  81
  82 #define highpass_limited(value, frac, limit, ref_store, ret) MACRO_BEGIN \
  83 { \
  84         float __f = 0; lowpass_limited(value, frac, limit, ref_store, __f); \
  85         ret = (value) - __f; \
  86 } MACRO_END
  87
  88 #define lowpass2(value, frac, ref_store, ref_out) MACRO_BEGIN \
  89 { \
  90         lowpass(value.x, frac, ref_store.x, ref_out.x); \
  91         lowpass(value.y, frac, ref_store.y, ref_out.y); \
  92 } MACRO_END
  93
  94 #define highpass2(value, frac, ref_store, ref_out) MACRO_BEGIN \
  95 { \
  96         highpass(value.x, frac, ref_store.x, ref_out.x); \
  97         highpass(value.y, frac, ref_store.y, ref_out.y); \
  98 } MACRO_END
  99
 100 #define highpass2_limited(value, frac, limit, ref_store, ref_out) MACRO_BEGIN \
 101 { \
 102         highpass_limited(value.x, frac, limit, ref_store.x, ref_out.x); \
 103         highpass_limited(value.y, frac, limit, ref_store.y, ref_out.y); \
 104 } MACRO_END
 105
 106 #define lowpass3(value, frac, ref_store, ref_out) MACRO_BEGIN \
 107 { \
 108         lowpass(value.x, frac, ref_store.x, ref_out.x); \
 109         lowpass(value.y, frac, ref_store.y, ref_out.y); \
 110         lowpass(value.z, frac, ref_store.z, ref_out.z); \
 111 } MACRO_END
 112
 113 #define highpass3(value, frac, ref_store, ref_out) MACRO_BEGIN \
 114 { \
 115         highpass(value.x, frac, ref_store.x, ref_out.x); \
 116         highpass(value.y, frac, ref_store.y, ref_out.y); \
 117         highpass(value.z, frac, ref_store.z, ref_out.z); \
 118 } MACRO_END
 119
 120 void calc_followmodel_ofs(entity view)
 121 {
 122         if(cl_followmodel_time == time)
 123                 return; // cl_followmodel_ofs already calculated for this frame
 124
 125         float frac;
 126         vector gunorg = '0 0 0';
 127         static vector vel_average;
 128         static vector gunorg_adjustment_highpass;
 129         static vector gunorg_adjustment_lowpass;
 130
 131         vector vel;
 132         if (autocvar_cl_followmodel_velocity_absolute)
 133                 vel = view.velocity;
 134         else
 135         {
 136                 vector forward = '0 0 0', right = '0 0 0', up = '0 0 0';
 137                 MAKEVECTORS(makevectors, view_angles, forward, right, up);
 138                 vel.x = view.velocity * forward;
 139                 vel.y = view.velocity * right * -1;
 140                 vel.z = view.velocity * up;
 141         }
 142
 143         vel.x = bound(vel_average.x - autocvar_cl_followmodel_limit, vel.x, vel_average.x + autocvar_cl_followmodel_limit);
 144         vel.y = bound(vel_average.y - autocvar_cl_followmodel_limit, vel.y, vel_average.y + autocvar_cl_followmodel_limit);
 145         vel.z = bound(vel_average.z - autocvar_cl_followmodel_limit, vel.z, vel_average.z + autocvar_cl_followmodel_limit);
 146
 147         frac = avg_factor(autocvar_cl_followmodel_velocity_lowpass);
 148         lowpass3(vel, frac, vel_average, gunorg);
 149
 150         gunorg *= -autocvar_cl_followmodel_speed * 0.042;
 151
 152         // perform highpass/lowpass on the adjustment vectors (turning velocity into acceleration!)
 153         // trick: we must do the lowpass LAST, so the lowpass vector IS the final vector!
 154         frac = avg_factor(autocvar_cl_followmodel_highpass);
 155         highpass3(gunorg, frac, gunorg_adjustment_highpass, gunorg);
 156         frac = avg_factor(autocvar_cl_followmodel_lowpass);
 157         lowpass3(gunorg, frac, gunorg_adjustment_lowpass, gunorg);
 158
 159         if (autocvar_cl_followmodel_velocity_absolute)
 160         {
 161                 vector fixed_gunorg;
 162                 vector forward = '0 0 0', right = '0 0 0', up = '0 0 0';
 163                 MAKEVECTORS(makevectors, view_angles, forward, right, up);
 164                 fixed_gunorg.x = gunorg * forward;
 165                 fixed_gunorg.y = gunorg * right * -1;
 166                 fixed_gunorg.z = gunorg * up;
 167                 gunorg = fixed_gunorg;
 168         }
 169
 170         cl_followmodel_ofs = gunorg;
 171         cl_followmodel_time = time;
 172 }
 173
 174 vector leanmodel_ofs(entity view)
 175 {
 176         float frac;
 177         vector gunangles = '0 0 0';
 178         static vector gunangles_prev = '0 0 0';
 179         static vector gunangles_highpass = '0 0 0';
 180         static vector gunangles_adjustment_highpass;
 181         static vector gunangles_adjustment_lowpass;
 182
 183         if (view.csqcmodel_teleported)
 184                 gunangles_prev = view_angles;
 185
 186         // in the highpass, we _store_ the DIFFERENCE to the actual view angles...
 187         gunangles_highpass += gunangles_prev;
 188         PITCH(gunangles_highpass) += 360 * floor((PITCH(view_angles) - PITCH(gunangles_highpass)) / 360 + 0.5);
 189         YAW(gunangles_highpass) += 360 * floor((YAW(view_angles) - YAW(gunangles_highpass)) / 360 + 0.5);
 190         ROLL(gunangles_highpass) += 360 * floor((ROLL(view_angles) - ROLL(gunangles_highpass)) / 360 + 0.5);
 191         frac = avg_factor(autocvar_cl_leanmodel_highpass1);
 192         highpass2_limited(view_angles, frac, autocvar_cl_leanmodel_limit, gunangles_highpass, gunangles);
 193         gunangles_prev = view_angles;
 194         gunangles_highpass -= gunangles_prev;
 195
 196         PITCH(gunangles) *= -autocvar_cl_leanmodel_speed;
 197         YAW(gunangles) *= -autocvar_cl_leanmodel_speed;
 198
 199         // we assume here: PITCH = 0, YAW = 1, ROLL = 2
 200         frac = avg_factor(autocvar_cl_leanmodel_highpass);
 201         highpass2(gunangles, frac, gunangles_adjustment_highpass, gunangles);
 202         frac = avg_factor(autocvar_cl_leanmodel_lowpass);
 203         lowpass2(gunangles, frac, gunangles_adjustment_lowpass, gunangles);
 204
 205         gunangles.x = -gunangles.x; // pitch was inverted, now that actually matters
 206
 207         return gunangles;
 208 }
 209
 210 vector bobmodel_ofs(entity view)
 211 {
 212         bool clonground = !(view.anim_implicit_state & ANIMIMPLICITSTATE_INAIR);
 213         static bool oldonground;
 214         static float hitgroundtime;
 215         if (clonground)
 216         {
 217                 float f = time; // cl.movecmd[0].time
 218                 if (!oldonground)
 219                         hitgroundtime = f;
 220         }
 221         oldonground = clonground;
 222
 223         // calculate for swinging gun model
 224         // the gun bobs when running on the ground, but doesn't bob when you're in the air.
 225         vector gunorg = '0 0 0';
 226         static float bobmodel_scale = 0;
 227         static float time_ofs = 0; // makes the effect always restart in the same way
 228         if (clonground)
 229         {
 230                 if (time - hitgroundtime > 0.05)
 231                         bobmodel_scale = min(1, bobmodel_scale + frametime * 5);
 232         }
 233         else
 234                 bobmodel_scale = max(0, bobmodel_scale - frametime * 5);
 235
 236         float xyspeed = bound(0, vlen(vec2(view.velocity)), 400);
 237         if (bobmodel_scale && xyspeed)
 238         {
 239                 float bspeed = xyspeed * 0.01 * autocvar_cl_viewmodel_scale * bobmodel_scale;
 240                 float s = (time - time_ofs) * autocvar_cl_bobmodel_speed;
 241                 gunorg.y = bspeed * autocvar_cl_bobmodel_side * sin(s);
 242                 gunorg.z = bspeed * autocvar_cl_bobmodel_up * cos(s * 2);
 243         }
 244         else
 245                 time_ofs = time;
 246
 247         return gunorg;
 248 }
 249
 250 void viewmodel_animate(entity this)
 251 {
 252         if (autocvar_chase_active) return;
 253         if (STAT(HEALTH) <= 0) return;
 254
 255         entity view = CSQCModel_server2csqc(player_localentnum - 1);
 256
 257         if (autocvar_cl_followmodel)
 258         {
 259                 calc_followmodel_ofs(view);
 260                 this.origin += cl_followmodel_ofs;
 261         }
 262
 263         if (autocvar_cl_leanmodel)
 264                 this.angles += leanmodel_ofs(view);
 265
 266         // vertical view bobbing code
 267         // TODO: cl_bob
 268
 269         // horizontal view bobbing code
 270         // TODO: cl_bob2
 271
 272         // fall bobbing code
 273         // causes the view to swing down and back up when touching the ground
 274         // TODO: cl_bobfall
 275
 276         // gun model bobbing code
 277         if (autocvar_cl_bobmodel)
 278                 this.origin += bobmodel_ofs(view);
 279 }
 280
 281 .vector viewmodel_origin, viewmodel_angles;
 282 .float weapon_nextthink;
 283 .float weapon_eta_last;
 284 .float weapon_switchdelay;
 285
 286 .string name_last;
 287
 288 void viewmodel_draw(entity this)
 289 {
 290         if(!this.activeweapon || !autocvar_r_drawviewmodel)
 291                 return;
 292         int mask = (intermission || (STAT(HEALTH) <= 0) || autocvar_chase_active) ? 0 : MASK_NORMAL;
 293         float a = this.alpha;
 294         static bool wasinvehicle;
 295         bool invehicle = player_localentnum > maxclients;
 296         if (invehicle) a = -1;
 297         else if (wasinvehicle) a = 1;
 298         wasinvehicle = invehicle;
 299         Weapon wep = this.activeweapon;
 300         int c = entcs_GetClientColors(current_player);
 301         vector g = weaponentity_glowmod(wep, NULL, c, this);
 302         entity me = CSQCModel_server2csqc(player_localentnum - 1);
 303         int fx = ((me.csqcmodel_effects & EFMASK_CHEAP)
 304                 | EF_NODEPTHTEST)
 305                 &~ (EF_FULLBRIGHT); // can mask team color, so get rid of it
 306         for (entity e = this; e; e = e.weaponchild)
 307         {
 308                 e.drawmask = mask;
 309                 e.alpha = a;
 310                 e.colormap = 256 + c;  // colormap == 0 is black, c == 0 is white
 311                 e.glowmod = g;
 312                 e.csqcmodel_effects = fx;
 313                 CSQCModel_Effects_Apply(e);
 314         }
 315         if(a >= 0)
 316         {
 317                 string name = wep.mdl;
 318                 string newname = wep.wr_viewmodel(wep, this);
 319                 if(newname)
 320                         name = newname;
 321                 bool swap = name != this.name_last;
 322                 // if (swap)
 323                 {
 324                         this.name_last = name;
 325                         CL_WeaponEntity_SetModel(this, name, swap);
 326                         this.viewmodel_origin = this.origin;
 327                         this.viewmodel_angles = this.angles;
 328                 }
 329                 anim_update(this);
 330                 if ((!this.animstate_override && !this.animstate_looping) || time > this.animstate_endtime)
 331                         anim_set(this, this.anim_idle, true, false, false);
 332         }
 333         float f = 0; // 0..1; 0: fully active
 334         float rate = STAT(WEAPONRATEFACTOR);
 335         float eta = rate ? ((this.weapon_nextthink - time) / rate) : 0;
 336         if (eta <= 0) f = this.weapon_eta_last;
 337         else switch (this.state)
 338         {
 339                 case WS_RAISE:
 340                 {
 341                         f = eta / max(eta, this.weapon_switchdelay);
 342                         break;
 343                 }
 344                 case WS_DROP:
 345                 {
 346                         f = 1 - eta / max(eta, this.weapon_switchdelay);
 347                         break;
 348                 }
 349                 case WS_CLEAR:
 350                 {
 351                         f = 1;
 352                         break;
 353                 }
 354         }
 355         this.weapon_eta_last = f;
 356         this.origin = this.viewmodel_origin;
 357         this.angles = this.viewmodel_angles;
 358         this.angles_x = (-90 * f * f);
 359         viewmodel_animate(this);
 360         MUTATOR_CALLHOOK(DrawViewModel, this);
 361         setorigin(this, this.origin);
 362 }
 363
 364 STATIC_INIT(viewmodel) {
 365     for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 366         viewmodels[slot] = new(viewmodel);
 367 }
 368
 369 void Porto_Draw(entity this);
 370 STATIC_INIT(Porto)
 371 {
 372         entity e = new_pure(porto);
 373         e.draw = Porto_Draw;
 374         IL_PUSH(g_drawables, e);
 375         e.dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY | DPCONTENTS_PLAYERCLIP;
 376 }
 377
 378 const int polyline_length = 16;
 379 .vector polyline[polyline_length];
 380 void Porto_Draw(entity this)
 381 {
 382         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 383         {
 384                 entity wepent = viewmodels[slot];
 385
 386                 if (wepent.activeweapon != WEP_PORTO) continue;
 387                 if (spectatee_status) continue;
 388                 if (WEP_CVAR(porto, secondary)) continue;
 389                 if (intermission == 1) continue;
 390                 if (intermission == 2) continue;
 391                 if (STAT(HEALTH) <= 0) continue;
 392
 393                 vector pos = view_origin;
 394                 vector dir = view_forward;
 395                 if (wepent.angles_held_status)
 396                 {
 397                         makevectors(wepent.angles_held);
 398                         dir = v_forward;
 399                 }
 400
 401                 wepent.polyline[0] = pos;
 402
 403                 int portal_number = 0, portal1_idx = 1, portal_max = 2;
 404                 int n = 1 + 2;  // 2 lines == 3 points
 405                 for (int idx = 0; idx < n && idx < polyline_length - 1; )
 406                 {
 407                         traceline(pos, pos + 65536 * dir, true, this);
 408                         dir = reflect(dir, trace_plane_normal);
 409                         pos = trace_endpos;
 410                         wepent.polyline[++idx] = pos;
 411                         if (trace_dphitq3surfaceflags & Q3SURFACEFLAG_SLICK || trace_dphitcontents & DPCONTENTS_PLAYERCLIP)
 412                         {
 413                                 n += 1;
 414                                 continue;
 415                         }
 416                         if (trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT)
 417                         {
 418                                 n = max(2, idx);
 419                                 break;
 420                         }
 421                         // check size
 422                         {
 423                                 vector ang = vectoangles2(trace_plane_normal, dir);
 424                                 ang.x = -ang.x;
 425                                 makevectors(ang);
 426                                 if (!CheckWireframeBox(this, pos - 48 * v_right - 48 * v_up + 16 * v_forward, 96 * v_right, 96 * v_up, 96 * v_forward))
 427                                 {
 428                                         n = max(2, idx);
 429                                         break;
 430                                 }
 431                         }
 432                         portal_number += 1;
 433                         if (portal_number >= portal_max) break;
 434                         if (portal_number == 1) portal1_idx = idx;
 435                 }
 436                 for (int idx = 0; idx < n - 1; ++idx)
 437                 {
 438                         vector p = wepent.polyline[idx], q = wepent.polyline[idx + 1];
 439                         if (idx == 0) p -= view_up * 16;  // line from player
 440                         vector rgb = (idx < portal1_idx) ? '1 0 0' : '0 0 1';
 441                         Draw_CylindricLine(p, q, 4, "", 1, 0, rgb, 0.5, DRAWFLAG_NORMAL, view_origin);
 442                 }
 443         }
 444 }
 445
 446 float drawtime;
 447 float avgspeed;
 448 vector GetCurrentFov(float fov)
 449 {
 450         float zoomsensitivity, zoomspeed, zoomfactor, zoomdir;
 451         float velocityzoom, curspeed;
 452         vector v;
 453
 454         zoomsensitivity = autocvar_cl_zoomsensitivity;
 455         zoomfactor = autocvar_cl_zoomfactor;
 456         if(zoomfactor < 1 || zoomfactor > 30)
 457                 zoomfactor = 2.5;
 458         zoomspeed = autocvar_cl_zoomspeed;
 459         if(zoomspeed >= 0)
 460         if(zoomspeed < 0.5 || zoomspeed > 16)
 461                         zoomspeed = 3.5;
 462
 463         zoomdir = button_zoom;
 464
 465         if(hud == HUD_NORMAL && !spectatee_status)
 466         {
 467                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 468                 {
 469                         entity wepent = viewmodels[slot];
 470                         if(wepent.switchweapon == wepent.activeweapon)
 471                         if((wepent.activeweapon == WEP_VORTEX && !WEP_CVAR(vortex, secondary)) || (wepent.activeweapon == WEP_RIFLE && !WEP_CVAR(rifle, secondary)) || (wepent.activeweapon == WEP_OVERKILL_VORTEX && !WEP_CVAR(okvortex, secondary))) // do NOT use switchweapon here
 472                                 zoomdir += button_attack2;
 473                 }
 474         }
 475         if(spectatee_status > 0 || isdemo())
 476         {
 477                 if(spectatorbutton_zoom)
 478                 {
 479                         if(zoomdir)
 480                                 zoomdir = 0;
 481                         else
 482                                 zoomdir = 1;
 483                 }
 484                 // fteqcc failed twice here already, don't optimize this
 485         }
 486
 487         if(zoomdir) { zoomin_effect = 0; }
 488
 489         if(camera_active)
 490         {
 491                 current_viewzoom = min(1, current_viewzoom + drawframetime);
 492         }
 493         else if(autocvar_cl_spawnzoom && zoomin_effect)
 494         {
 495                 float spawnzoomfactor = bound(1, autocvar_cl_spawnzoom_factor, 30);
 496
 497                 current_viewzoom += (autocvar_cl_spawnzoom_speed * (spawnzoomfactor - current_viewzoom) * drawframetime);
 498                 current_viewzoom = bound(1 / spawnzoomfactor, current_viewzoom, 1);
 499                 if(current_viewzoom == 1) { zoomin_effect = 0; }
 500         }
 501         else
 502         {
 503                 if(zoomspeed < 0) // instant zoom
 504                 {
 505                         if(zoomdir)
 506                                 current_viewzoom = 1 / zoomfactor;
 507                         else
 508                                 current_viewzoom = 1;
 509                 }
 510                 else
 511                 {
 512                         if(zoomdir)
 513                                 current_viewzoom = 1 / bound(1, 1 / current_viewzoom + drawframetime * zoomspeed * (zoomfactor - 1), zoomfactor);
 514                         else
 515                                 current_viewzoom = bound(1 / zoomfactor, current_viewzoom + drawframetime * zoomspeed * (1 - 1 / zoomfactor), 1);
 516                 }
 517         }
 518
 519         if(almost_equals(current_viewzoom, 1))
 520                 current_zoomfraction = 0;
 521         else if(almost_equals(current_viewzoom, 1/zoomfactor))
 522                 current_zoomfraction = 1;
 523         else
 524                 current_zoomfraction = (current_viewzoom - 1) / (1/zoomfactor - 1);
 525
 526         if(zoomsensitivity < 1)
 527                 setsensitivityscale(current_viewzoom ** (1 - zoomsensitivity));
 528         else
 529                 setsensitivityscale(1);
 530
 531         if(autocvar_cl_velocityzoom_enabled && autocvar_cl_velocityzoom_type) // _type = 0 disables velocity zoom too
 532         {
 533                 if(intermission) { curspeed = 0; }
 534                 else
 535                 {
 536
 537                         makevectors(view_angles);
 538                         v = pmove_vel;
 539                         if(csqcplayer)
 540                                 v = csqcplayer.velocity;
 541
 542                         switch(autocvar_cl_velocityzoom_type)
 543                         {
 544                                 case 3: curspeed = max(0, v_forward * v); break;
 545                                 case 2: curspeed = (v_forward * v); break;
 546                                 case 1: default: curspeed = vlen(v); break;
 547                         }
 548                 }
 549
 550                 velocityzoom = bound(0, drawframetime / max(0.000000001, autocvar_cl_velocityzoom_time), 1); // speed at which the zoom adapts to player velocity
 551                 avgspeed = avgspeed * (1 - velocityzoom) + (curspeed / autocvar_cl_velocityzoom_speed) * velocityzoom;
 552                 velocityzoom = exp(float2range11(avgspeed * -autocvar_cl_velocityzoom_factor / 1) * 1);
 553
 554                 //print(ftos(avgspeed), " avgspeed, ", ftos(curspeed), " curspeed, ", ftos(velocityzoom), " return\n"); // for debugging
 555         }
 556         else
 557                 velocityzoom = 1;
 558
 559         float frustumx, frustumy, fovx, fovy;
 560         frustumy = tan(fov * M_PI / 360.0) * 0.75 * current_viewzoom * velocityzoom;
 561         frustumx = frustumy * vid_width / vid_height / vid_pixelheight;
 562         fovx = atan2(frustumx, 1) / M_PI * 360.0;
 563         fovy = atan2(frustumy, 1) / M_PI * 360.0;
 564
 565         return '1 0 0' * fovx + '0 1 0' * fovy;
 566 }
 567
 568 vector GetViewLocationFOV(float fov)
 569 {
 570         float frustumy = tan(fov * M_PI / 360.0) * 0.75;
 571         float frustumx = frustumy * vid_width / vid_height / vid_pixelheight;
 572         float fovx = atan2(frustumx, 1) / M_PI * 360.0;
 573         float fovy = atan2(frustumy, 1) / M_PI * 360.0;
 574         return '1 0 0' * fovx + '0 1 0' * fovy;
 575 }
 576
 577 vector GetOrthoviewFOV(vector ov_worldmin, vector ov_worldmax, vector ov_mid, vector ov_org)
 578 {
 579         float fovx, fovy;
 580         float width = (ov_worldmax.x - ov_worldmin.x);
 581         float height = (ov_worldmax.y - ov_worldmin.y);
 582         float distance_to_middle_of_world = vlen(ov_mid - ov_org);
 583         fovx = atan2(width/2, distance_to_middle_of_world) / M_PI * 360.0;
 584         fovy = atan2(height/2, distance_to_middle_of_world) / M_PI * 360.0;
 585         return '1 0 0' * fovx + '0 1 0' * fovy;
 586 }
 587
 588 // this function must match W_SetupShot!
 589 float zoomscript_caught;
 590
 591 vector wcross_origin;
 592 float wcross_scale_prev, wcross_alpha_prev;
 593 vector wcross_color_prev;
 594 float wcross_scale_goal_prev, wcross_alpha_goal_prev;
 595 vector wcross_color_goal_prev;
 596 float wcross_changedonetime;
 597
 598 string wcross_name_goal_prev, wcross_name_goal_prev_prev;
 599 float wcross_resolution_goal_prev, wcross_resolution_goal_prev_prev;
 600 float wcross_name_changestarttime, wcross_name_changedonetime;
 601 float wcross_name_alpha_goal_prev, wcross_name_alpha_goal_prev_prev;
 602
 603 float wcross_ring_prev;
 604
 605 entity trueaim;
 606 entity trueaim_rifle;
 607
 608 const float SHOTTYPE_HITTEAM = 1;
 609 const float SHOTTYPE_HITOBSTRUCTION = 2;
 610 const float SHOTTYPE_HITWORLD = 3;
 611 const float SHOTTYPE_HITENEMY = 4;
 612
 613 void TrueAim_Init()
 614 {
 615         (trueaim = new_pure(trueaim)).dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY | DPCONTENTS_CORPSE;
 616         (trueaim_rifle = new_pure(trueaim_rifle)).dphitcontentsmask = DPCONTENTS_BODY | DPCONTENTS_CORPSE;
 617 }
 618
 619 float EnemyHitCheck()
 620 {
 621         float t, n;
 622         wcross_origin = project_3d_to_2d(trace_endpos);
 623         wcross_origin.z = 0;
 624         if(trace_ent)
 625                 n = trace_ent.entnum;
 626         else
 627                 n = trace_networkentity;
 628         if(n < 1)
 629                 return SHOTTYPE_HITWORLD;
 630         if(n > maxclients)
 631                 return SHOTTYPE_HITWORLD;
 632         t = entcs_GetTeam(n - 1);
 633         if(teamplay)
 634                 if(t == myteam)
 635                         return SHOTTYPE_HITTEAM;
 636         if(t == NUM_SPECTATOR)
 637                 return SHOTTYPE_HITWORLD;
 638         return SHOTTYPE_HITENEMY;
 639 }
 640
 641 float TrueAimCheck(entity wepent)
 642 {
 643         float nudge = 1; // added to traceline target and subtracted from result TOOD(divVerent): do we still need this? Doesn't the engine do this now for us?
 644         vector vecs, trueaimpoint, w_shotorg;
 645         vector mi, ma, dv;
 646         float shottype;
 647         entity ta;
 648         float mv;
 649
 650         mi = ma = '0 0 0';
 651         ta = trueaim;
 652         mv = MOVE_NOMONSTERS;
 653
 654         switch(wepent.activeweapon) // WEAPONTODO
 655         {
 656                 case WEP_TUBA: // no aim
 657                 case WEP_PORTO: // shoots from eye
 658                 case WEP_NEXBALL: // shoots from eye
 659                 case WEP_HOOK: // no trueaim
 660                 case WEP_MORTAR: // toss curve
 661                         return SHOTTYPE_HITWORLD;
 662                 case WEP_VORTEX:
 663                 case WEP_OVERKILL_VORTEX:
 664                 case WEP_VAPORIZER:
 665                         mv = MOVE_NORMAL;
 666                         break;
 667                 case WEP_RIFLE:
 668                         ta = trueaim_rifle;
 669                         mv = MOVE_NORMAL;
 670                         if(zoomscript_caught)
 671                         {
 672                                 tracebox(view_origin, '0 0 0', '0 0 0', view_origin + view_forward * max_shot_distance, mv, ta);
 673                                 return EnemyHitCheck();
 674                         }
 675                         break;
 676                 case WEP_DEVASTATOR: // projectile has a size!
 677                         mi = '-3 -3 -3';
 678                         ma = '3 3 3';
 679                         break;
 680                 case WEP_FIREBALL: // projectile has a size!
 681                         mi = '-16 -16 -16';
 682                         ma = '16 16 16';
 683                         break;
 684                 case WEP_SEEKER: // projectile has a size!
 685                         mi = '-2 -2 -2';
 686                         ma = '2 2 2';
 687                         break;
 688                 case WEP_ELECTRO: // projectile has a size!
 689                         mi = '0 0 -3';
 690                         ma = '0 0 -3';
 691                         break;
 692         }
 693
 694         vector traceorigin = entcs_receiver(player_localentnum - 1).origin + (eZ * STAT(VIEWHEIGHT));
 695
 696         vecs = decompressShotOrigin(STAT(SHOTORG));
 697
 698         traceline(traceorigin, traceorigin + view_forward * max_shot_distance, mv, ta);
 699         trueaimpoint = trace_endpos;
 700
 701         if(vdist((trueaimpoint - traceorigin), <, g_trueaim_minrange))
 702                 trueaimpoint = traceorigin + view_forward * g_trueaim_minrange;
 703
 704         if(vecs.x > 0)
 705                 vecs.y = -vecs.y;
 706         else
 707                 vecs = '0 0 0';
 708
 709         dv = view_right * vecs.y + view_up * vecs.z;
 710         w_shotorg = traceorigin + dv;
 711
 712         // now move the vecs forward as much as requested if possible
 713         tracebox(w_shotorg, mi, ma, w_shotorg + view_forward * (vecs.x + nudge), MOVE_NORMAL, ta); // FIXME this MOVE_NORMAL part will misbehave a little in csqc
 714         w_shotorg = trace_endpos - view_forward * nudge;
 715
 716         tracebox(w_shotorg, mi, ma, trueaimpoint, MOVE_NORMAL, ta);
 717         shottype = EnemyHitCheck();
 718         if(shottype != SHOTTYPE_HITWORLD)
 719                 return shottype;
 720
 721 #if 0
 722         // FIXME WHY DOES THIS NOT WORK FOR THE ROCKET LAUNCHER?
 723         // or rather, I know why, but see no fix
 724         if(vlen(trace_endpos - trueaimpoint) > vlen(ma) + vlen(mi) + 1)
 725                 // yes, this is an ugly hack... but it seems good enough to find out whether the test hits the same place as the initial trace
 726                 return SHOTTYPE_HITOBSTRUCTION;
 727 #endif
 728
 729         return SHOTTYPE_HITWORLD;
 730 }
 731
 732 void PostInit();
 733 void CSQC_Demo_Camera();
 734 float camera_mode;
 735 const float CAMERA_FREE = 1;
 736 const float CAMERA_CHASE = 2;
 737 float reticle_type;
 738 string NextFrameCommand;
 739
 740 vector freeze_org, freeze_ang;
 741 entity nightvision_noise, nightvision_noise2;
 742
 743 const float MAX_TIME_DIFF = 5;
 744 float pickup_crosshair_time, pickup_crosshair_size;
 745 float hitindication_crosshair_size;
 746 float use_vortex_chargepool;
 747
 748 float myhealth, myhealth_prev;
 749 float myhealth_flash;
 750
 751 float old_blurradius, old_bluralpha;
 752 float old_sharpen_intensity;
 753
 754 vector myhealth_gentlergb;
 755
 756 float contentavgalpha, liquidalpha_prev;
 757 vector liquidcolor_prev;
 758
 759 float eventchase_current_distance;
 760 float eventchase_running;
 761 bool WantEventchase(entity this)
 762 {
 763         if(autocvar_cl_orthoview)
 764                 return false;
 765         if(STAT(GAME_STOPPED) || intermission)
 766                 return true;
 767         if(this.viewloc)
 768                 return true;
 769         if(spectatee_status >= 0)
 770         {
 771                 if(hud != HUD_NORMAL && (autocvar_cl_eventchase_vehicle || spectatee_status > 0))
 772                         return true;
 773                 if(MUTATOR_CALLHOOK(WantEventchase, this))
 774                         return true;
 775                 if(autocvar_cl_eventchase_frozen && STAT(FROZEN))
 776                         return true;
 777                 if(autocvar_cl_eventchase_death && (STAT(HEALTH) <= 0))
 778                 {
 779                         if(autocvar_cl_eventchase_death == 2)
 780                         {
 781                                 // don't stop eventchase once it's started (even if velocity changes afterwards)
 782                                 if(this.velocity == '0 0 0' || eventchase_running)
 783                                         return true;
 784                         }
 785                         else return true;
 786                 }
 787         }
 788         return false;
 789 }
 790
 791 void HUD_Crosshair_Vehicle(entity this)
 792 {
 793         if(hud != HUD_BUMBLEBEE_GUN)
 794         {
 795                 Vehicle info = Vehicles_from(hud);
 796                 info.vr_crosshair(info, this);
 797         }
 798 }
 799
 800 vector damage_blurpostprocess, content_blurpostprocess;
 801
 802 float unaccounted_damage = 0;
 803 void UpdateDamage()
 804 {
 805         // accumulate damage with each stat update
 806         static float damage_total_prev = 0;
 807         float damage_total = STAT(DAMAGE_DEALT_TOTAL);
 808         float unaccounted_damage_new = COMPARE_INCREASING(damage_total, damage_total_prev);
 809         damage_total_prev = damage_total;
 810
 811         static float damage_dealt_time_prev = 0;
 812         float damage_dealt_time = STAT(HIT_TIME);
 813         if (damage_dealt_time != damage_dealt_time_prev)
 814         {
 815                 unaccounted_damage += unaccounted_damage_new;
 816                 LOG_TRACE("dmg total: ", ftos(unaccounted_damage), " (+", ftos(unaccounted_damage_new), ")");
 817         }
 818         damage_dealt_time_prev = damage_dealt_time;
 819
 820         // prevent hitsound when switching spectatee
 821         static float spectatee_status_prev = 0;
 822         if (spectatee_status != spectatee_status_prev)
 823                 unaccounted_damage = 0;
 824         spectatee_status_prev = spectatee_status;
 825 }
 826
 827 void HitSound()
 828 {
 829         // varying sound pitch
 830
 831         bool have_arc = false;
 832         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 833         {
 834                 entity wepent = viewmodels[slot];
 835
 836                 if(wepent.activeweapon == WEP_ARC)
 837                         have_arc = true;
 838         }
 839
 840         static float hitsound_time_prev = 0;
 841         // HACK: the only way to get the arc to sound consistent with pitch shift is to ignore cl_hitsound_antispam_time
 842         bool arc_hack = have_arc && autocvar_cl_hitsound >= 2;
 843         if (arc_hack || COMPARE_INCREASING(time, hitsound_time_prev) > autocvar_cl_hitsound_antispam_time)
 844         {
 845                 if (autocvar_cl_hitsound && unaccounted_damage)
 846                 {
 847                         // customizable gradient function that crosses (0,a), (c,1) and asymptotically approaches b
 848                         float a = autocvar_cl_hitsound_max_pitch;
 849                         float b = autocvar_cl_hitsound_min_pitch;
 850                         float c = autocvar_cl_hitsound_nom_damage;
 851                         float d = unaccounted_damage;
 852                         float pitch_shift = (b*d*(a-1) + a*c*(1-b)) / (d*(a-1) + c*(1-b));
 853
 854                         // if sound variation is disabled, set pitch_shift to 1
 855                         if (autocvar_cl_hitsound == 1)
 856                                 pitch_shift = 1;
 857
 858                         // if pitch shift is reversed, mirror in (max-min)/2 + min
 859                         if (autocvar_cl_hitsound == 3)
 860                         {
 861                                 float mirror_value = (a-b)/2 + b;
 862                                 pitch_shift = mirror_value + (mirror_value - pitch_shift);
 863                         }
 864
 865                         LOG_TRACE("dmg total (dmg): ", ftos(unaccounted_damage), " , pitch shift: ", ftos(pitch_shift));
 866
 867                         // todo: avoid very long and very short sounds from wave stretching using different sound files? seems unnecessary
 868                         // todo: normalize sound pressure levels? seems unnecessary
 869
 870                         sound7(NULL, CH_INFO, SND(HIT), VOL_BASE, ATTN_NONE, pitch_shift * 100, 0);
 871                 }
 872                 unaccounted_damage = 0;
 873                 hitsound_time_prev = time;
 874         }
 875
 876         static float typehit_time_prev = 0;
 877         float typehit_time = STAT(TYPEHIT_TIME);
 878         if (COMPARE_INCREASING(typehit_time, typehit_time_prev) > autocvar_cl_hitsound_antispam_time)
 879         {
 880                 sound(NULL, CH_INFO, SND_TYPEHIT, VOL_BASE, ATTN_NONE);
 881                 typehit_time_prev = typehit_time;
 882         }
 883
 884         static float kill_time_prev = 0;
 885         float kill_time = STAT(KILL_TIME);
 886         if (COMPARE_INCREASING(kill_time, kill_time_prev) > autocvar_cl_hitsound_antispam_time)
 887         {
 888                 sound(NULL, CH_INFO, SND_KILL, VOL_BASE, ATTN_NONE);
 889                 kill_time_prev = kill_time;
 890         }
 891 }
 892
 893 vector crosshair_getcolor(entity this, float health_stat)
 894 {
 895         static float rainbow_last_flicker;
 896         static vector rainbow_prev_color;
 897         vector wcross_color = '0 0 0';
 898         switch(autocvar_crosshair_color_special)
 899         {
 900                 case 1: // crosshair_color_per_weapon
 901                 {
 902                         if(this != WEP_Null && hud == HUD_NORMAL)
 903                         {
 904                                 wcross_color = this.wpcolor;
 905                                 break;
 906                         }
 907                         else { goto normalcolor; }
 908                 }
 909
 910                 case 2: // crosshair_color_by_health
 911                 {
 912                         float hp = health_stat;
 913
 914                         //x = red
 915                         //y = green
 916                         //z = blue
 917
 918                         wcross_color.z = 0;
 919
 920                         if(hp > 200)
 921                         {
 922                                 wcross_color.x = 0;
 923                                 wcross_color.y = 1;
 924                         }
 925                         else if(hp > 150)
 926                         {
 927                                 wcross_color.x = 0.4 - (hp-150)*0.02 * 0.4;
 928                                 wcross_color.y = 0.9 + (hp-150)*0.02 * 0.1;
 929                         }
 930                         else if(hp > 100)
 931                         {
 932                                 wcross_color.x = 1 - (hp-100)*0.02 * 0.6;
 933                                 wcross_color.y = 1 - (hp-100)*0.02 * 0.1;
 934                                 wcross_color.z = 1 - (hp-100)*0.02;
 935                         }
 936                         else if(hp > 50)
 937                         {
 938                                 wcross_color.x = 1;
 939                                 wcross_color.y = 1;
 940                                 wcross_color.z = 0.2 + (hp-50)*0.02 * 0.8;
 941                         }
 942                         else if(hp > 20)
 943                         {
 944                                 wcross_color.x = 1;
 945                                 wcross_color.y = (hp-20)*90/27/100;
 946                                 wcross_color.z = (hp-20)*90/27/100 * 0.2;
 947                         }
 948                         else
 949                         {
 950                                 wcross_color.x = 1;
 951                                 wcross_color.y = 0;
 952                         }
 953                         break;
 954                 }
 955
 956                 case 3: // crosshair_color_rainbow
 957                 {
 958                         if(time >= rainbow_last_flicker)
 959                         {
 960                                 rainbow_prev_color = randomvec() * autocvar_crosshair_color_special_rainbow_brightness;
 961                                 rainbow_last_flicker = time + autocvar_crosshair_color_special_rainbow_delay;
 962                         }
 963                         wcross_color = rainbow_prev_color;
 964                         break;
 965                 }
 966 LABEL(normalcolor)
 967                 default: { wcross_color = stov(autocvar_crosshair_color); break; }
 968         }
 969
 970         return wcross_color;
 971 }
 972
 973 void HUD_Crosshair(entity this)
 974 {
 975         float f, i, j;
 976         vector v;
 977         if(!scoreboard_active && !camera_active && intermission != 2 && !STAT(GAME_STOPPED) &&
 978                 spectatee_status != -1 && !csqcplayer.viewloc && !MUTATOR_CALLHOOK(DrawCrosshair) &&
 979                 !HUD_MinigameMenu_IsOpened() )
 980         {
 981                 if (!autocvar_crosshair_enabled) // main toggle for crosshair rendering
 982                         return;
 983
 984                 if (spectatee_status > 0 && STAT(CAMERA_SPECTATOR) == 2)
 985                         return;
 986
 987                 if (hud != HUD_NORMAL)
 988                 {
 989                         HUD_Crosshair_Vehicle(this);
 990                         return;
 991                 }
 992
 993                 string wcross_style;
 994                 float wcross_alpha, wcross_resolution;
 995                 wcross_style = autocvar_crosshair;
 996                 if (wcross_style == "0")
 997                         return;
 998                 wcross_resolution = autocvar_crosshair_size;
 999                 if (wcross_resolution == 0)
1000                         return;
1001                 wcross_alpha = autocvar_crosshair_alpha;
1002                 if (wcross_alpha == 0)
1003                         return;
1004
1005                 // TrueAim check
1006                 float shottype;
1007
1008                 // wcross_origin = '0.5 0 0' * vid_conwidth + '0 0.5 0' * vid_conheight;
1009                 wcross_origin = project_3d_to_2d(view_origin + max_shot_distance * view_forward);
1010                 wcross_origin.z = 0;
1011                 if(autocvar_crosshair_hittest)
1012                 {
1013                         vector wcross_oldorigin;
1014                         entity thiswep = viewmodels[0]; // TODO: unhardcode
1015                         wcross_oldorigin = wcross_origin;
1016                         shottype = TrueAimCheck(thiswep);
1017                         if(shottype == SHOTTYPE_HITWORLD)
1018                         {
1019                                 v = wcross_origin - wcross_oldorigin;
1020                                 v.x /= vid_conwidth;
1021                                 v.y /= vid_conheight;
1022                                 if(vdist(v, >, 0.01))
1023                                         shottype = SHOTTYPE_HITOBSTRUCTION;
1024                         }
1025                         if(!autocvar_crosshair_hittest_showimpact)
1026                                 wcross_origin = wcross_oldorigin;
1027                 }
1028                 else
1029                         shottype = SHOTTYPE_HITWORLD;
1030
1031                 vector wcross_color = '0 0 0', wcross_size = '0 0 0';
1032                 string wcross_name = "";
1033                 float wcross_scale, wcross_blur;
1034
1035         entity e = WEP_Null;
1036                 if(autocvar_crosshair_per_weapon || (autocvar_crosshair_color_special == 1))
1037                 {
1038                         entity wepent = viewmodels[0]; // TODO: unhardcode
1039                         e = wepent.switchingweapon;
1040                         if(e)
1041                         {
1042                                 if(autocvar_crosshair_per_weapon)
1043                                 {
1044                                         // WEAPONTODO: access these through some general settings (with non-balance config settings)
1045                                         //wcross_resolution *= cvar(strcat("crosshair_", wcross_wep, "_size"));
1046                                         //if (wcross_resolution == 0)
1047                                                 //return;
1048
1049                                         //wcross_style = cvar_string(strcat("crosshair_", wcross_wep));
1050                                         wcross_resolution *= e.w_crosshair_size;
1051                                         wcross_name = e.w_crosshair;
1052                                 }
1053                         }
1054                 }
1055
1056                 if(wcross_name == "")
1057                         wcross_name = strcat("gfx/crosshair", wcross_style);
1058
1059                 // MAIN CROSSHAIR COLOR DECISION
1060                 wcross_color = crosshair_getcolor(e, STAT(HEALTH));
1061
1062                 if(autocvar_crosshair_effect_scalefade)
1063                 {
1064                         wcross_scale = wcross_resolution;
1065                         wcross_resolution = 1;
1066                 }
1067                 else
1068                 {
1069                         wcross_scale = 1;
1070                 }
1071
1072                 if(autocvar_crosshair_pickup)
1073                 {
1074                         float stat_pickup_time = STAT(LAST_PICKUP);
1075
1076                         if(pickup_crosshair_time < stat_pickup_time)
1077                         {
1078                                 if(time - stat_pickup_time < MAX_TIME_DIFF) // don't trigger the animation if it's too old
1079                                         pickup_crosshair_size = 1;
1080
1081                                 pickup_crosshair_time = stat_pickup_time;
1082                         }
1083
1084                         if(pickup_crosshair_size > 0)
1085                                 pickup_crosshair_size -= autocvar_crosshair_pickup_speed * frametime;
1086                         else
1087                                 pickup_crosshair_size = 0;
1088
1089                         wcross_scale += sin(pickup_crosshair_size) * autocvar_crosshair_pickup;
1090                 }
1091
1092                 // todo: make crosshair hit indication dependent on damage dealt
1093                 if(autocvar_crosshair_hitindication)
1094                 {
1095                         vector hitindication_color = ((autocvar_crosshair_color_special == 1) ? stov(autocvar_crosshair_hitindication_per_weapon_color) : stov(autocvar_crosshair_hitindication_color));
1096
1097                         if(unaccounted_damage)
1098                         {
1099                                 hitindication_crosshair_size = 1;
1100                         }
1101
1102                         if(hitindication_crosshair_size > 0)
1103                                 hitindication_crosshair_size -= autocvar_crosshair_hitindication_speed * frametime;
1104                         else
1105                                 hitindication_crosshair_size = 0;
1106
1107                         wcross_scale += sin(hitindication_crosshair_size) * autocvar_crosshair_hitindication;
1108                         wcross_color.x += sin(hitindication_crosshair_size) * hitindication_color.x;
1109                         wcross_color.y += sin(hitindication_crosshair_size) * hitindication_color.y;
1110                         wcross_color.z += sin(hitindication_crosshair_size) * hitindication_color.z;
1111                 }
1112
1113                 if(shottype == SHOTTYPE_HITENEMY)
1114                         wcross_scale *= autocvar_crosshair_hittest; // is not queried if hittest is 0
1115                 if(shottype == SHOTTYPE_HITTEAM)
1116                         wcross_scale /= autocvar_crosshair_hittest; // is not queried if hittest is 0
1117
1118                 f = fabs(autocvar_crosshair_effect_time);
1119                 if(wcross_scale != wcross_scale_goal_prev || wcross_alpha != wcross_alpha_goal_prev || wcross_color != wcross_color_goal_prev)
1120                 {
1121                         wcross_changedonetime = time + f;
1122                 }
1123                 if(wcross_name != wcross_name_goal_prev || wcross_resolution != wcross_resolution_goal_prev)
1124                 {
1125                         wcross_name_changestarttime = time;
1126                         wcross_name_changedonetime = time + f;
1127                         if(wcross_name_goal_prev_prev)
1128                                 strunzone(wcross_name_goal_prev_prev);
1129                         wcross_name_goal_prev_prev = wcross_name_goal_prev;
1130                         wcross_name_goal_prev = strzone(wcross_name);
1131                         wcross_name_alpha_goal_prev_prev = wcross_name_alpha_goal_prev;
1132                         wcross_resolution_goal_prev_prev = wcross_resolution_goal_prev;
1133                         wcross_resolution_goal_prev = wcross_resolution;
1134                 }
1135
1136                 wcross_scale_goal_prev = wcross_scale;
1137                 wcross_alpha_goal_prev = wcross_alpha;
1138                 wcross_color_goal_prev = wcross_color;
1139
1140                 if(spectatee_status == -1 && shottype == SHOTTYPE_HITTEAM || (shottype == SHOTTYPE_HITOBSTRUCTION && autocvar_crosshair_hittest_blur && !autocvar_chase_active))
1141                 {
1142                         wcross_blur = 1;
1143                         wcross_alpha *= 0.75;
1144                 }
1145                 else
1146                         wcross_blur = 0;
1147                 // *_prev is at time-frametime
1148                 // * is at wcross_changedonetime+f
1149                 // what do we have at time?
1150                 if(time < wcross_changedonetime)
1151                 {
1152                         f = frametime / (wcross_changedonetime - time + frametime);
1153                         wcross_scale = f * wcross_scale + (1 - f) * wcross_scale_prev;
1154                         wcross_alpha = f * wcross_alpha + (1 - f) * wcross_alpha_prev;
1155                         wcross_color = f * wcross_color + (1 - f) * wcross_color_prev;
1156                 }
1157
1158                 wcross_scale_prev = wcross_scale;
1159                 wcross_alpha_prev = wcross_alpha;
1160                 wcross_color_prev = wcross_color;
1161
1162                 MUTATOR_CALLHOOK(UpdateCrosshair);
1163
1164                 wcross_scale *= 1 - autocvar__menu_alpha;
1165                 wcross_alpha *= 1 - autocvar__menu_alpha;
1166                 wcross_size = draw_getimagesize(wcross_name) * wcross_scale;
1167
1168                 if(wcross_scale >= 0.001 && wcross_alpha >= 0.001)
1169                 {
1170                         // crosshair rings for weapon stats
1171                         if (autocvar_crosshair_ring || autocvar_crosshair_ring_reload)
1172                         {
1173                                 // declarations and stats
1174                                 float ring_value = 0, ring_scale = 0, ring_alpha = 0, ring_inner_value = 0, ring_inner_alpha = 0;
1175                                 string ring_image = string_null, ring_inner_image = string_null;
1176                                 vector ring_rgb = '0 0 0', ring_inner_rgb = '0 0 0';
1177
1178                                 ring_scale = autocvar_crosshair_ring_size;
1179
1180                                 float weapon_clipload, weapon_clipsize;
1181                                 weapon_clipload = STAT(WEAPON_CLIPLOAD);
1182                                 weapon_clipsize = STAT(WEAPON_CLIPSIZE);
1183
1184                                 float vortex_charge, vortex_chargepool;
1185                                 vortex_charge = STAT(VORTEX_CHARGE);
1186                                 vortex_chargepool = STAT(VORTEX_CHARGEPOOL);
1187
1188                                 float okvortex_charge, okvortex_chargepool;
1189                                 okvortex_charge = STAT(OVERKILL_VORTEX_CHARGE);
1190                                 okvortex_chargepool = STAT(OVERKILL_VORTEX_CHARGEPOOL);
1191
1192                                 float arc_heat = STAT(ARC_HEAT);
1193
1194                                 if(vortex_charge_movingavg == 0) // this should only happen if we have just loaded up the game
1195                                         vortex_charge_movingavg = vortex_charge;
1196
1197                                 entity wepent = viewmodels[0]; // TODO: unhardcode
1198
1199                                 // handle the values
1200                                 if (autocvar_crosshair_ring && wepent.activeweapon == WEP_VORTEX && vortex_charge && autocvar_crosshair_ring_vortex) // ring around crosshair representing velocity-dependent damage for the vortex
1201                                 {
1202                                         if (vortex_chargepool || use_vortex_chargepool) {
1203                                                 use_vortex_chargepool = 1;
1204                                                 ring_inner_value = vortex_chargepool;
1205                                         } else {
1206                                                 vortex_charge_movingavg = (1 - autocvar_crosshair_ring_vortex_currentcharge_movingavg_rate) * vortex_charge_movingavg + autocvar_crosshair_ring_vortex_currentcharge_movingavg_rate * vortex_charge;
1207                                                 ring_inner_value = bound(0, autocvar_crosshair_ring_vortex_currentcharge_scale * (vortex_charge - vortex_charge_movingavg), 1);
1208                                         }
1209
1210                                         ring_inner_alpha = autocvar_crosshair_ring_vortex_inner_alpha;
1211                                         ring_inner_rgb = vec3(autocvar_crosshair_ring_vortex_inner_color_red, autocvar_crosshair_ring_vortex_inner_color_green, autocvar_crosshair_ring_vortex_inner_color_blue);
1212                                         ring_inner_image = "gfx/crosshair_ring_inner.tga";
1213
1214                                         // draw the outer ring to show the current charge of the weapon
1215                                         ring_value = vortex_charge;
1216                                         ring_alpha = autocvar_crosshair_ring_vortex_alpha;
1217                                         ring_rgb = wcross_color;
1218                                         ring_image = "gfx/crosshair_ring_nexgun.tga";
1219                                 }
1220                                 else if (autocvar_crosshair_ring && (wepent.activeweapon == WEP_OVERKILL_VORTEX) && okvortex_charge && autocvar_crosshair_ring_vortex)
1221                                 {
1222                                         if (okvortex_chargepool || use_vortex_chargepool) {
1223                                                 use_vortex_chargepool = 1;
1224                                                 ring_inner_value = okvortex_chargepool;
1225                                         } else {
1226                                                 vortex_charge_movingavg = (1 - autocvar_crosshair_ring_vortex_currentcharge_movingavg_rate) * vortex_charge_movingavg + autocvar_crosshair_ring_vortex_currentcharge_movingavg_rate * okvortex_charge;
1227                                                 ring_inner_value = bound(0, autocvar_crosshair_ring_vortex_currentcharge_scale * (okvortex_charge - vortex_charge_movingavg), 1);
1228                                         }
1229
1230                                         ring_inner_alpha = autocvar_crosshair_ring_vortex_inner_alpha;
1231                                         ring_inner_rgb = eX * autocvar_crosshair_ring_vortex_inner_color_red + eY * autocvar_crosshair_ring_vortex_inner_color_green + eZ * autocvar_crosshair_ring_vortex_inner_color_blue;
1232                                         ring_inner_image = "gfx/crosshair_ring_inner.tga";
1233
1234                                         // draw the outer ring to show the current charge of the weapon
1235                                         ring_value = okvortex_charge;
1236                                         ring_alpha = autocvar_crosshair_ring_vortex_alpha;
1237                                         ring_rgb = wcross_color;
1238                                         ring_image = "gfx/crosshair_ring_nexgun.tga";
1239                                 }
1240                                 else if (autocvar_crosshair_ring && wepent.activeweapon == WEP_MINE_LAYER && WEP_CVAR(minelayer, limit) && autocvar_crosshair_ring_minelayer)
1241                                 {
1242                                         ring_value = bound(0, STAT(LAYED_MINES) / WEP_CVAR(minelayer, limit), 1); // if you later need to use the count of bullets in another place, then add a float for it. For now, no need to.
1243                                         ring_alpha = autocvar_crosshair_ring_minelayer_alpha;
1244                                         ring_rgb = wcross_color;
1245                                         ring_image = "gfx/crosshair_ring.tga";
1246                                 }
1247                                 else if (wepent.activeweapon == WEP_HAGAR && STAT(HAGAR_LOAD) && autocvar_crosshair_ring_hagar)
1248                                 {
1249                                         ring_value = bound(0, STAT(HAGAR_LOAD) / WEP_CVAR_SEC(hagar, load_max), 1);
1250                                         ring_alpha = autocvar_crosshair_ring_hagar_alpha;
1251                                         ring_rgb = wcross_color;
1252                                         ring_image = "gfx/crosshair_ring.tga";
1253                                 }
1254                                 else if(autocvar_crosshair_ring_reload && weapon_clipsize) // forces there to be only an ammo ring
1255                                 {
1256                                         ring_value = bound(0, weapon_clipload / weapon_clipsize, 1);
1257                                         ring_scale = autocvar_crosshair_ring_reload_size;
1258                                         ring_alpha = autocvar_crosshair_ring_reload_alpha;
1259                                         ring_rgb = wcross_color;
1260
1261                                         // Note: This is to stop Taoki from complaining that the image doesn't match all potential balances.
1262                                         // if a new image for another weapon is added, add the code (and its respective file/value) here
1263                                         if ((wepent.activeweapon == WEP_RIFLE) && (weapon_clipsize == 80))
1264                                                 ring_image = "gfx/crosshair_ring_rifle.tga";
1265                                         else
1266                                                 ring_image = "gfx/crosshair_ring.tga";
1267                                 }
1268                                 else if ( autocvar_crosshair_ring && autocvar_crosshair_ring_arc && arc_heat && wepent.activeweapon == WEP_ARC )
1269                                 {
1270                                         ring_value = arc_heat;
1271                                         ring_alpha = (1-arc_heat)*autocvar_crosshair_ring_arc_cold_alpha +
1272                                                 arc_heat*autocvar_crosshair_ring_arc_hot_alpha;
1273                                         ring_rgb = (1-arc_heat)*wcross_color + arc_heat*autocvar_crosshair_ring_arc_hot_color;
1274                                         ring_image = "gfx/crosshair_ring.tga";
1275                                 }
1276
1277                                 // if in weapon switch animation, fade ring out/in
1278                                 if(autocvar_crosshair_effect_time > 0)
1279                                 {
1280                                         f = (time - wcross_name_changestarttime) / autocvar_crosshair_effect_time;
1281                                         if (f >= 1)
1282                                         {
1283                                                 wcross_ring_prev = ((ring_image) ? true : false);
1284                                         }
1285
1286                                         if(wcross_ring_prev)
1287                                         {
1288                                                 if(f < 1)
1289                                                         ring_alpha *= fabs(1 - bound(0, f, 1));
1290                                         }
1291                                         else
1292                                         {
1293                                                 if(f < 1)
1294                                                         ring_alpha *= bound(0, f, 1);
1295                                         }
1296                                 }
1297
1298                                 if (autocvar_crosshair_ring_inner && ring_inner_value) // lets draw a ring inside a ring so you can ring while you ring
1299                                         DrawCircleClippedPic(wcross_origin, wcross_size.x * ring_scale, ring_inner_image, ring_inner_value, ring_inner_rgb, wcross_alpha * ring_inner_alpha, DRAWFLAG_ADDITIVE);
1300
1301                                 if (ring_value)
1302                                         DrawCircleClippedPic(wcross_origin, wcross_size.x * ring_scale, ring_image, ring_value, ring_rgb, wcross_alpha * ring_alpha, DRAWFLAG_ADDITIVE);
1303                         }
1304
1305 #define CROSSHAIR_DO_BLUR(M,sz,wcross_name,wcross_alpha) \
1306                         MACRO_BEGIN { \
1307                                 if(wcross_blur > 0) \
1308                                 { \
1309                                         for(i = -2; i <= 2; ++i) \
1310                                         for(j = -2; j <= 2; ++j) \
1311                                         M(i,j,sz,wcross_name,wcross_alpha*0.04); \
1312                                 } \
1313                                 else \
1314                                 { \
1315                                         M(0,0,sz,wcross_name,wcross_alpha); \
1316                                 } \
1317                         } MACRO_END
1318
1319 #define CROSSHAIR_DRAW_SINGLE(i,j,sz,wcross_name,wcross_alpha) \
1320                         drawpic(wcross_origin - ('0.5 0 0' * (sz * wcross_size.x + i * wcross_blur) + '0 0.5 0' * (sz * wcross_size.y + j * wcross_blur)), wcross_name, sz * wcross_size, wcross_color, wcross_alpha, DRAWFLAG_NORMAL)
1321
1322 #define CROSSHAIR_DRAW(sz,wcross_name,wcross_alpha) \
1323                         CROSSHAIR_DO_BLUR(CROSSHAIR_DRAW_SINGLE,sz,wcross_name,wcross_alpha)
1324
1325                         if(time < wcross_name_changedonetime && wcross_name != wcross_name_goal_prev_prev && wcross_name_goal_prev_prev)
1326                         {
1327                                 f = (wcross_name_changedonetime - time) / (wcross_name_changedonetime - wcross_name_changestarttime);
1328                                 wcross_size = draw_getimagesize(wcross_name_goal_prev_prev) * wcross_scale;
1329                                 CROSSHAIR_DRAW(wcross_resolution_goal_prev_prev, wcross_name_goal_prev_prev, wcross_alpha * f * wcross_name_alpha_goal_prev_prev);
1330                                 f = 1 - f;
1331                         }
1332                         else
1333                         {
1334                                 f = 1;
1335                         }
1336                         wcross_name_alpha_goal_prev = f;
1337
1338                         wcross_size = draw_getimagesize(wcross_name) * wcross_scale;
1339                         CROSSHAIR_DRAW(wcross_resolution, wcross_name, wcross_alpha * f);
1340
1341                         if(autocvar_crosshair_dot)
1342                         {
1343                                 vector wcross_color_old;
1344                                 wcross_color_old = wcross_color;
1345
1346                                 if((autocvar_crosshair_dot_color_custom) && (autocvar_crosshair_dot_color != "0"))
1347                                         wcross_color = stov(autocvar_crosshair_dot_color);
1348
1349                                 CROSSHAIR_DRAW(wcross_resolution * autocvar_crosshair_dot_size, "gfx/crosshairdot.tga", f * autocvar_crosshair_dot_alpha);
1350                                 // FIXME why don't we use wcross_alpha here?
1351                                 wcross_color = wcross_color_old;
1352                         }
1353                 }
1354         }
1355         else
1356         {
1357                 wcross_scale_prev = 0;
1358                 wcross_alpha_prev = 0;
1359                 wcross_scale_goal_prev = 0;
1360                 wcross_alpha_goal_prev = 0;
1361                 wcross_changedonetime = 0;
1362                 if(wcross_name_goal_prev)
1363                         strunzone(wcross_name_goal_prev);
1364                 wcross_name_goal_prev = string_null;
1365                 if(wcross_name_goal_prev_prev)
1366                         strunzone(wcross_name_goal_prev_prev);
1367                 wcross_name_goal_prev_prev = string_null;
1368                 wcross_name_changestarttime = 0;
1369                 wcross_name_changedonetime = 0;
1370                 wcross_name_alpha_goal_prev = 0;
1371                 wcross_name_alpha_goal_prev_prev = 0;
1372                 wcross_resolution_goal_prev = 0;
1373                 wcross_resolution_goal_prev_prev = 0;
1374         }
1375 }
1376
1377 const int MAX_SPECIALCOMMAND = 15;
1378 vector specialcommand_slots[MAX_SPECIALCOMMAND];
1379 vector specialcommand_colors[MAX_SPECIALCOMMAND];
1380 const float SPECIALCOMMAND_SPEED = 150;
1381 const float SPECIALCOMMAND_TURNSPEED = 2;
1382 const float SPECIALCOMMAND_SIZE = 0.025;
1383 const float SPECIALCOMMAND_CHANCE = 0.35;
1384 float sc_spawntime, sc_changetime;
1385 vector sc_color = '1 1 1';
1386 void SpecialCommand()
1387 {
1388         if(!STAT(MOVEVARS_SPECIALCOMMAND))
1389                 return;
1390
1391         if(time >= sc_changetime)
1392         {
1393                 sc_changetime = time + 1;
1394                 sc_color = randomvec() * 1.5;
1395                 sc_color.x = bound(0.2, sc_color.x, 0.75);
1396                 sc_color.y = bound(0.2, sc_color.y, 0.75);
1397                 sc_color.z = bound(0.2, sc_color.z, 0.75);
1398         }
1399         drawfill('0 0 0', vec2(vid_conwidth, vid_conheight), sc_color, autocvar_hud_colorflash_alpha * bound(0.1, sc_changetime - time, 0.3), DRAWFLAG_ADDITIVE);
1400
1401         if(!precache_pic("gfx/smile"))
1402                 return; // damn party poopers
1403
1404         for(int j = MAX_SPECIALCOMMAND - 1; j >= 0; --j)
1405         {
1406                 vector slot = specialcommand_slots[j];
1407                 if(slot.y)
1408                         slot.y += SPECIALCOMMAND_SPEED * frametime;
1409                 if(slot.z)
1410                         slot.z = sin(SPECIALCOMMAND_TURNSPEED * M_PI * time);
1411                 if(slot.y >= vid_conheight)
1412                         slot = '0 0 0';
1413
1414                 if(slot == '0 0 0')
1415                 {
1416                         if(random() <= SPECIALCOMMAND_CHANCE && time > sc_spawntime) // low chance to spawn!
1417                         {
1418                                 slot.x = bound(0, (random() * vid_conwidth + 1), vid_conwidth);
1419                                 slot.y = 1; // start it off 0 so we can use it
1420                                 slot.z = random();
1421                                 sc_spawntime = time + bound(0.4, random(), 0.75); // prevent spawning another one for this amount of time!
1422                                 vector newcolor = randomvec() * 2;
1423                                 newcolor.x = bound(0.4, newcolor.x, 1);
1424                                 newcolor.y = bound(0.4, newcolor.y, 1);
1425                                 newcolor.z = bound(0.4, newcolor.z, 1);
1426                                 specialcommand_colors[j] = newcolor;
1427                         }
1428                 }
1429                 else
1430                 {
1431                         vector splash_size = '0 0 0';
1432                         splash_size.x = max(vid_conwidth, vid_conheight) * SPECIALCOMMAND_SIZE;
1433                         splash_size.y = max(vid_conwidth, vid_conheight) * SPECIALCOMMAND_SIZE;
1434                         drawpic(vec2(slot), "gfx/smile", vec2(splash_size), specialcommand_colors[j], 0.95, DRAWFLAG_NORMAL);
1435                         //drawrotpic(vec2(slot), slot.z, "gfx/smile", vec2(splash_size), vec2(splash_size) / 2, specialcommand_colors[j], 0.95, DRAWFLAG_NORMAL);
1436                 }
1437
1438                 specialcommand_slots[j] = slot;
1439         }
1440 }
1441
1442 void HUD_Draw(entity this)
1443 {
1444         // if we don't know gametype and scores yet avoid drawing the scoreboard
1445         // also in the very first frames, player state may be inconsistent so avoid drawing the hud at all
1446         // e.g. since initial player's health is 0 hud would display the hud_damage effect,
1447         // cl_deathscoreboard would show the scoreboard and so on
1448         if(!gametype)
1449                 return;
1450
1451         Hud_Dynamic_Frame();
1452
1453         if(!intermission)
1454         if (MUTATOR_CALLHOOK(HUD_Draw_overlay))
1455         {
1456                 drawfill('0 0 0', vec2(vid_conwidth, vid_conheight), M_ARGV(0, vector), autocvar_hud_colorflash_alpha * M_ARGV(1, float), DRAWFLAG_ADDITIVE);
1457         }
1458         else if(STAT(FROZEN))
1459         {
1460                 vector col = '0.25 0.90 1';
1461                 if(STAT(REVIVE_PROGRESS))
1462                         col += vec3(STAT(REVIVE_PROGRESS), -STAT(REVIVE_PROGRESS), -STAT(REVIVE_PROGRESS));
1463                 drawfill('0 0 0', vec2(vid_conwidth, vid_conheight), col, autocvar_hud_colorflash_alpha, DRAWFLAG_ADDITIVE);
1464         }
1465
1466         HUD_Scale_Enable();
1467         if(!intermission)
1468         if(STAT(NADE_TIMER) && autocvar_cl_nade_timer) // give nade top priority, as it's a matter of life and death
1469         {
1470                 vector col = '0.25 0.90 1' + vec3(STAT(NADE_TIMER), -STAT(NADE_TIMER), -STAT(NADE_TIMER));
1471                 DrawCircleClippedPic(vec2(0.5 * vid_conwidth, 0.6 * vid_conheight), 0.1 * vid_conheight, "gfx/crosshair_ring.tga", STAT(NADE_TIMER), col, autocvar_hud_colorflash_alpha, DRAWFLAG_ADDITIVE);
1472                 drawstring_aspect(eY * 0.64 * vid_conheight, ((autocvar_cl_nade_timer == 2) ? _("Nade timer") : ""), vec2(vid_conwidth, 0.025 * vid_conheight), '1 1 1', 1, DRAWFLAG_NORMAL);
1473         }
1474         else if(STAT(CAPTURE_PROGRESS))
1475         {
1476                 DrawCircleClippedPic(vec2(0.5 * vid_conwidth, 0.6 * vid_conheight), 0.1 * vid_conheight, "gfx/crosshair_ring.tga", STAT(CAPTURE_PROGRESS), '0.25 0.90 1', autocvar_hud_colorflash_alpha, DRAWFLAG_ADDITIVE);
1477                 drawstring_aspect(eY * 0.64 * vid_conheight, _("Capture progress"), vec2(vid_conwidth, 0.025 * vid_conheight), '1 1 1', 1, DRAWFLAG_NORMAL);
1478         }
1479         else if(STAT(REVIVE_PROGRESS))
1480         {
1481                 DrawCircleClippedPic(vec2(0.5 * vid_conwidth, 0.6 * vid_conheight), 0.1 * vid_conheight, "gfx/crosshair_ring.tga", STAT(REVIVE_PROGRESS), '0.25 0.90 1', autocvar_hud_colorflash_alpha, DRAWFLAG_ADDITIVE);
1482                 drawstring_aspect(eY * 0.64 * vid_conheight, _("Revival progress"), vec2(vid_conwidth, 0.025 * vid_conheight), '1 1 1', 1, DRAWFLAG_NORMAL);
1483         }
1484         HUD_Scale_Disable();
1485
1486         if(autocvar_r_letterbox == 0)
1487                 if(autocvar_viewsize < 120)
1488                 {
1489                         if(!(gametype == MAPINFO_TYPE_RACE || gametype == MAPINFO_TYPE_CTS))
1490                                 Accuracy_LoadLevels();
1491
1492                         HUD_Main();
1493                         HUD_Scale_Disable();
1494                 }
1495
1496         // crosshair goes VERY LAST
1497         SpecialCommand();
1498         UpdateDamage();
1499         HUD_Crosshair(this);
1500         HitSound();
1501 }
1502
1503 bool ov_enabled;
1504 float oldr_nearclip;
1505 float oldr_farclip_base;
1506 float oldr_farclip_world;
1507 float oldr_novis;
1508 float oldr_useportalculling;
1509 float oldr_useinfinitefarclip;
1510
1511 void cl_notice_run();
1512
1513 float prev_myteam;
1514 int lasthud;
1515 float vh_notice_time;
1516 void WaypointSprite_Load();
1517 void CSQC_UpdateView(entity this, float w, float h)
1518 {
1519     TC(int, w); TC(int, h);
1520         entity e;
1521         float fov;
1522         float f;
1523         vector vf_size, vf_min;
1524         float a;
1525
1526         execute_next_frame();
1527
1528         ++framecount;
1529
1530         stats_get();
1531         hud = STAT(HUD);
1532
1533         if(hud != HUD_NORMAL && lasthud == HUD_NORMAL)
1534                 vh_notice_time = time + autocvar_cl_vehicles_notify_time;
1535
1536         lasthud = hud;
1537
1538         HUD_Scale_Disable();
1539
1540         if(autocvar__hud_showbinds_reload) // menu can set this one
1541         {
1542                 db_close(binddb);
1543                 binddb = db_create();
1544                 cvar_set("_hud_showbinds_reload", "0");
1545         }
1546
1547         if(checkextension("DP_CSQC_MINFPS_QUALITY"))
1548                 view_quality = getproperty(VF_MINFPS_QUALITY);
1549         else
1550                 view_quality = 1;
1551
1552         button_attack2 = PHYS_INPUT_BUTTON_ATCK2(this);
1553         button_zoom = PHYS_INPUT_BUTTON_ZOOM(this);
1554
1555         vf_size = getpropertyvec(VF_SIZE);
1556         vf_min = getpropertyvec(VF_MIN);
1557         vid_width = vf_size.x;
1558         vid_height = vf_size.y;
1559
1560         vector reticle_pos = '0 0 0', reticle_size = '0 0 0';
1561         vector splash_pos = '0 0 0', splash_size = '0 0 0';
1562
1563         WaypointSprite_Load();
1564
1565         CSQCPlayer_SetCamera();
1566
1567         if(player_localentnum <= maxclients) // is it a client?
1568                 current_player = player_localentnum - 1;
1569         else // then player_localentnum is the vehicle I'm driving
1570                 current_player = player_localnum;
1571         myteam = entcs_GetTeam(current_player);
1572
1573         if(myteam != prev_myteam)
1574         {
1575                 myteamcolors = colormapPaletteColor(myteam, 1);
1576                 FOREACH(hud_panels, true, it.update_time = time);
1577                 prev_myteam = myteam;
1578         }
1579
1580         ticrate = STAT(MOVEVARS_TICRATE) * STAT(MOVEVARS_TIMESCALE);
1581
1582         float is_dead = (STAT(HEALTH) <= 0);
1583
1584         // FIXME do we need this hack?
1585         if(isdemo())
1586         {
1587                 // in demos, input_buttons do not work
1588                 button_zoom = (autocvar__togglezoom == "-");
1589         }
1590         else if(button_zoom
1591                 && autocvar_cl_unpress_zoom_on_death
1592                 && (spectatee_status >= 0)
1593                 && (is_dead || intermission))
1594         {
1595                 // no zoom while dead or in intermission please
1596                 localcmd("-zoom\n");
1597                 button_zoom = false;
1598         }
1599
1600         // event chase camera
1601         if(autocvar_chase_active <= 0) // greater than 0 means it's enabled manually, and this code is skipped
1602         {
1603                 if(STAT(CAMERA_SPECTATOR))
1604                 {
1605                         if(spectatee_status > 0)
1606                         {
1607                                 if(!autocvar_chase_active)
1608                                 {
1609                                         cvar_set("chase_active", "-2");
1610                                         goto skip_eventchase_death;
1611                                 }
1612                         }
1613                         else if(autocvar_chase_active == -2)
1614                                 cvar_set("chase_active", "0");
1615
1616                         if(autocvar_chase_active == -2)
1617                                 goto skip_eventchase_death;
1618                 }
1619                 else if(autocvar_chase_active == -2)
1620                         cvar_set("chase_active", "0");
1621
1622                 float vehicle_chase = (hud != HUD_NORMAL && (autocvar_cl_eventchase_vehicle || spectatee_status > 0));
1623
1624                 float vehicle_viewdist = 0;
1625                 vector vehicle_viewofs = '0 0 0';
1626
1627                 if(vehicle_chase)
1628                 {
1629                         if(hud != HUD_BUMBLEBEE_GUN)
1630                         {
1631                                 Vehicle info = Vehicles_from(hud);
1632                                 vehicle_viewdist = info.height;
1633                                 vehicle_viewofs = info.view_ofs;
1634                         }
1635                 }
1636
1637                 if(WantEventchase(this))
1638                 {
1639                         vector current_view_origin_override = '0 0 0';
1640                         vector view_offset_override = '0 0 0';
1641                         float chase_distance_override = 0;
1642                         bool custom_eventchase = MUTATOR_CALLHOOK(CustomizeEventchase, this);
1643                         if(custom_eventchase)
1644                         {
1645                                 current_view_origin_override = M_ARGV(0, vector);
1646                                 view_offset_override = M_ARGV(1, vector);
1647                                 chase_distance_override = M_ARGV(0, float);
1648                         }
1649                         eventchase_running = true;
1650
1651                         entity local_player = ((csqcplayer) ? csqcplayer : CSQCModel_server2csqc(player_localentnum - 1));
1652                         if(!local_player)
1653                                 local_player = this; // fall back!
1654
1655                         // make special vector since we can't use view_origin (It is one frame old as of this code, it gets set later with the results this code makes.)
1656                         vector current_view_origin = (csqcplayer ? csqcplayer.origin : pmove_org);
1657                         if (custom_eventchase)
1658                                 current_view_origin = current_view_origin_override;
1659
1660                         // detect maximum viewoffset and use it
1661                         vector view_offset = autocvar_cl_eventchase_viewoffset;
1662                         if(vehicle_chase)
1663                         {
1664                                 if(vehicle_viewofs)
1665                                         view_offset = vehicle_viewofs;
1666                                 else
1667                                         view_offset = autocvar_cl_eventchase_vehicle_viewoffset;
1668                         }
1669                         if (custom_eventchase)
1670                                 view_offset = view_offset_override;
1671
1672                         if(view_offset)
1673                         {
1674                                 WarpZone_TraceLine(current_view_origin, current_view_origin + view_offset + ('0 0 1' * autocvar_cl_eventchase_maxs.z), MOVE_WORLDONLY, this);
1675                                 if(trace_fraction == 1) { current_view_origin += view_offset; }
1676                                 else { current_view_origin.z += max(0, (trace_endpos.z - current_view_origin.z) - autocvar_cl_eventchase_maxs.z); }
1677                         }
1678
1679                         // We must enable chase_active to get a third person view (weapon viewmodel hidden and own player model showing).
1680                         // Ideally, there should be another way to enable third person cameras, such as through setproperty()
1681                         // -1 enables chase_active while marking it as set by this code, and not by the user (which would be 1)
1682                         if(!autocvar_chase_active) { cvar_set("chase_active", "-1"); }
1683
1684                         // make the camera smooth back
1685                         float chase_distance = autocvar_cl_eventchase_distance;
1686                         if(vehicle_chase)
1687                         {
1688                                 if(vehicle_viewofs)
1689                                         chase_distance = vehicle_viewdist;
1690                                 else
1691                                         chase_distance = autocvar_cl_eventchase_vehicle_distance;
1692                         }
1693                         if (custom_eventchase)
1694                                 chase_distance = chase_distance_override;
1695
1696                         if(autocvar_cl_eventchase_speed && eventchase_current_distance < chase_distance)
1697                                 eventchase_current_distance += autocvar_cl_eventchase_speed * (chase_distance - eventchase_current_distance) * frametime; // slow down the further we get
1698                         else if(eventchase_current_distance != chase_distance)
1699                                 eventchase_current_distance = chase_distance;
1700
1701                         makevectors(view_angles);
1702
1703                         vector eventchase_target_origin = (current_view_origin - (v_forward * eventchase_current_distance));
1704                         WarpZone_TraceBox(current_view_origin, autocvar_cl_eventchase_mins, autocvar_cl_eventchase_maxs, eventchase_target_origin, MOVE_WORLDONLY, this);
1705
1706                         // If the boxtrace fails, revert back to line tracing.
1707                         if(!local_player.viewloc)
1708                         if(trace_startsolid)
1709                         {
1710                                 eventchase_target_origin = (current_view_origin - (v_forward * eventchase_current_distance));
1711                                 WarpZone_TraceLine(current_view_origin, eventchase_target_origin, MOVE_WORLDONLY, this);
1712                                 setproperty(VF_ORIGIN, (trace_endpos - (v_forward * autocvar_cl_eventchase_mins.z)));
1713                         }
1714                         else { setproperty(VF_ORIGIN, trace_endpos); }
1715
1716                         if(!local_player.viewloc)
1717                                 setproperty(VF_ANGLES, WarpZone_TransformVAngles(WarpZone_trace_transform, view_angles));
1718                 }
1719                 else if(autocvar_chase_active < 0) // time to disable chase_active if it was set by this code
1720                 {
1721                         eventchase_running = false;
1722                         cvar_set("chase_active", "0");
1723                         eventchase_current_distance = 0; // start from 0 next time
1724                 }
1725         }
1726         // workaround for camera stuck between player's legs when using chase_active 1
1727         // because the engine stops updating the chase_active camera when the game ends
1728         else if(intermission)
1729         {
1730                 cvar_settemp("chase_active", "-1");
1731                 eventchase_current_distance = 0;
1732         }
1733
1734         LABEL(skip_eventchase_death);
1735
1736         // do lockview after event chase camera so that it still applies whenever necessary.
1737         if(autocvar_cl_lockview || (!autocvar_hud_cursormode && (autocvar__hud_configure && spectatee_status <= 0 || intermission > 1 || QuickMenu_IsOpened())))
1738         {
1739                 setproperty(VF_ORIGIN, freeze_org);
1740                 setproperty(VF_ANGLES, freeze_ang);
1741         }
1742         else
1743         {
1744                 freeze_org = getpropertyvec(VF_ORIGIN);
1745                 freeze_ang = getpropertyvec(VF_ANGLES);
1746         }
1747
1748         WarpZone_FixView();
1749         //WarpZone_FixPMove();
1750
1751         vector ov_org = '0 0 0';
1752         vector ov_mid = '0 0 0';
1753         vector ov_worldmin = '0 0 0';
1754         vector ov_worldmax = '0 0 0';
1755         if(autocvar_cl_orthoview)
1756         {
1757                 ov_worldmin = mi_picmin;
1758                 ov_worldmax = mi_picmax;
1759
1760                 float ov_width = (ov_worldmax.x - ov_worldmin.x);
1761                 float ov_height = (ov_worldmax.y - ov_worldmin.y);
1762                 float ov_distance = (max(vid_width, vid_height) * max(ov_width, ov_height));
1763
1764                 ov_mid = ((ov_worldmax + ov_worldmin) * 0.5);
1765                 ov_org = vec3(ov_mid.x, ov_mid.y, (ov_mid.z + ov_distance));
1766
1767                 float ov_nearest = vlen(ov_org - vec3(
1768                         bound(ov_worldmin.x, ov_org.x, ov_worldmax.x),
1769                         bound(ov_worldmin.y, ov_org.y, ov_worldmax.y),
1770                         bound(ov_worldmin.z, ov_org.z, ov_worldmax.z)
1771                 ));
1772
1773                 float ov_furthest = 0;
1774                 float dist = 0;
1775
1776                 if((dist = vdist((vec3(ov_worldmin.x, ov_worldmin.y, ov_worldmin.z) - ov_org), >, ov_furthest))) { ov_furthest = dist; }
1777                 if((dist = vdist((vec3(ov_worldmax.x, ov_worldmin.y, ov_worldmin.z) - ov_org), >, ov_furthest))) { ov_furthest = dist; }
1778                 if((dist = vdist((vec3(ov_worldmin.x, ov_worldmax.y, ov_worldmin.z) - ov_org), >, ov_furthest))) { ov_furthest = dist; }
1779                 if((dist = vdist((vec3(ov_worldmin.x, ov_worldmin.y, ov_worldmax.z) - ov_org), >, ov_furthest))) { ov_furthest = dist; }
1780                 if((dist = vdist((vec3(ov_worldmax.x, ov_worldmax.y, ov_worldmin.z) - ov_org), >, ov_furthest))) { ov_furthest = dist; }
1781                 if((dist = vdist((vec3(ov_worldmin.x, ov_worldmax.y, ov_worldmax.z) - ov_org), >, ov_furthest))) { ov_furthest = dist; }
1782                 if((dist = vdist((vec3(ov_worldmax.x, ov_worldmin.y, ov_worldmax.z) - ov_org), >, ov_furthest))) { ov_furthest = dist; }
1783                 if((dist = vdist((vec3(ov_worldmax.x, ov_worldmax.y, ov_worldmax.z) - ov_org), >, ov_furthest))) { ov_furthest = dist; }
1784
1785                 if(!ov_enabled)
1786                 {
1787                         oldr_nearclip = cvar("r_nearclip");
1788                         oldr_farclip_base = cvar("r_farclip_base");
1789                         oldr_farclip_world = cvar("r_farclip_world");
1790                         oldr_novis = cvar("r_novis");
1791                         oldr_useportalculling = cvar("r_useportalculling");
1792                         oldr_useinfinitefarclip = cvar("r_useinfinitefarclip");
1793                 }
1794
1795                 cvar_settemp("r_nearclip", ftos(ov_nearest));
1796                 cvar_settemp("r_farclip_base", ftos(ov_furthest));
1797                 cvar_settemp("r_farclip_world", "0");
1798                 cvar_settemp("r_novis", "1");
1799                 cvar_settemp("r_useportalculling", "0");
1800                 cvar_settemp("r_useinfinitefarclip", "0");
1801
1802                 setproperty(VF_ORIGIN, ov_org);
1803                 setproperty(VF_ANGLES, '90 0 0');
1804
1805                 ov_enabled = true;
1806
1807                 #if 0
1808                 LOG_INFOF("OrthoView: org = %s, angles = %s, distance = %f, nearest = %f, furthest = %f\n",
1809                         vtos(ov_org),
1810                         vtos(getpropertyvec(VF_ANGLES)),
1811                         ov_distance,
1812                         ov_nearest,
1813                         ov_furthest);
1814                 #endif
1815         }
1816         else
1817         {
1818                 if(ov_enabled)
1819                 {
1820                         cvar_set("r_nearclip", ftos(oldr_nearclip));
1821                         cvar_set("r_farclip_base", ftos(oldr_farclip_base));
1822                         cvar_set("r_farclip_world", ftos(oldr_farclip_world));
1823                         cvar_set("r_novis", ftos(oldr_novis));
1824                         cvar_set("r_useportalculling", ftos(oldr_useportalculling));
1825                         cvar_set("r_useinfinitefarclip", ftos(oldr_useinfinitefarclip));
1826                 }
1827                 ov_enabled = false;
1828         }
1829
1830         // run viewmodel_draw before updating view_angles to the angles calculated by WarpZone_FixView
1831         // viewmodel_draw needs to use the view_angles set by the engine on every CSQC_UpdateView call
1832         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
1833                 viewmodel_draw(viewmodels[slot]);
1834
1835         // Render the Scene
1836         view_origin = getpropertyvec(VF_ORIGIN);
1837         view_angles = getpropertyvec(VF_ANGLES);
1838         makevectors(view_angles);
1839         view_forward = v_forward;
1840         view_right = v_right;
1841         view_up = v_up;
1842
1843 #ifdef BLURTEST
1844         if(time > blurtest_time0 && time < blurtest_time1)
1845         {
1846                 float r, t;
1847
1848                 t = (time - blurtest_time0) / (blurtest_time1 - blurtest_time0);
1849                 r = t * blurtest_radius;
1850                 f = 1 / (t ** blurtest_power) - 1;
1851
1852                 cvar_set("r_glsl_postprocess", "1");
1853                 cvar_set("r_glsl_postprocess_uservec1", strcat(ftos(r), " ", ftos(f), " 0 0"));
1854         }
1855         else
1856         {
1857                 cvar_set("r_glsl_postprocess", "0");
1858                 cvar_set("r_glsl_postprocess_uservec1", "0 0 0 0");
1859         }
1860 #endif
1861
1862         TargetMusic_Advance();
1863         Fog_Force();
1864
1865         if(drawtime == 0)
1866                 drawframetime = 0.01666667; // when we don't know fps yet, we assume 60fps
1867         else
1868                 drawframetime = bound(0.000001, time - drawtime, 1);
1869         drawtime = time;
1870
1871         // watch for gametype changes here...
1872         // in ParseStuffCMD the cmd isn't executed yet :/
1873         // might even be better to add the gametype to TE_CSQC_INIT...?
1874         if(!postinit)
1875                 PostInit();
1876
1877         if(intermission && !intermission_time)
1878                 intermission_time = time;
1879
1880         if(intermission && !isdemo() && !(calledhooks & HOOK_END))
1881         {
1882                 if(calledhooks & HOOK_START)
1883                 {
1884                         localcmd("\ncl_hook_gameend\n");
1885                         calledhooks |= HOOK_END;
1886                 }
1887         }
1888
1889         Announcer();
1890
1891         fov = autocvar_fov;
1892         if(fov <= 59.5)
1893         {
1894                 if(!zoomscript_caught)
1895                 {
1896                         localcmd("+button9\n");
1897                         zoomscript_caught = 1;
1898                 }
1899         }
1900         else
1901         {
1902                 if(zoomscript_caught)
1903                 {
1904                         localcmd("-button9\n");
1905                         zoomscript_caught = 0;
1906                 }
1907         }
1908
1909         ColorTranslateMode = autocvar_cl_stripcolorcodes;
1910
1911         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
1912         {
1913                 entity wepent = viewmodels[slot];
1914
1915                 if(wepent.last_switchweapon != wepent.switchweapon)
1916                 {
1917                         weapontime = time;
1918                         wepent.last_switchweapon = wepent.switchweapon;
1919                         if(slot == 0 && button_zoom && autocvar_cl_unpress_zoom_on_weapon_switch)
1920                         {
1921                                 localcmd("-zoom\n");
1922                                 button_zoom = false;
1923                         }
1924                         if(slot == 0 && autocvar_cl_unpress_attack_on_weapon_switch)
1925                         {
1926                                 localcmd("-fire\n");
1927                                 localcmd("-fire2\n");
1928                                 button_attack2 = false;
1929                         }
1930                 }
1931                 if(wepent.last_activeweapon != wepent.activeweapon)
1932                 {
1933                         wepent.last_activeweapon = wepent.activeweapon;
1934
1935                         e = wepent.activeweapon;
1936                         if(e.netname != "")
1937                                 localcmd(strcat("\ncl_hook_activeweapon ", e.netname), "\n");
1938                         else if(slot == 0)
1939                                 localcmd("\ncl_hook_activeweapon none\n");
1940                 }
1941         }
1942
1943         // ALWAYS Clear Current Scene First
1944         clearscene();
1945
1946         setproperty(VF_ORIGIN, view_origin);
1947         setproperty(VF_ANGLES, view_angles);
1948
1949         // FIXME engine bug? VF_SIZE and VF_MIN are not restored to sensible values by this
1950         setproperty(VF_SIZE, vf_size);
1951         setproperty(VF_MIN, vf_min);
1952
1953         // Assign Standard Viewflags
1954         // Draw the World (and sky)
1955         setproperty(VF_DRAWWORLD, 1);
1956
1957         // Set the console size vars
1958         vid_conwidth = autocvar_vid_conwidth;
1959         vid_conheight = autocvar_vid_conheight;
1960         vid_pixelheight = autocvar_vid_pixelheight;
1961
1962         if(autocvar_cl_orthoview) { setproperty(VF_FOV, GetOrthoviewFOV(ov_worldmin, ov_worldmax, ov_mid, ov_org)); }
1963         else if(csqcplayer.viewloc) { setproperty(VF_FOV, GetViewLocationFOV(110)); } // enforce 110 fov, so things dont look odd
1964         else { setproperty(VF_FOV, GetCurrentFov(fov)); }
1965
1966         if(camera_active) // Camera for demo playback
1967         {
1968                 if(autocvar_camera_enable)
1969                         CSQC_Demo_Camera();
1970                 else
1971                 {
1972                         cvar_set("chase_active", ftos(chase_active_backup));
1973                         cvar_set("cl_demo_mousegrab", "0");
1974                         camera_active = false;
1975                 }
1976         }
1977         else
1978         {
1979 #ifdef CAMERATEST
1980                 if(autocvar_camera_enable)
1981 #else
1982                 if(autocvar_camera_enable && isdemo())
1983 #endif
1984                 {
1985                         // Enable required Darkplaces cvars
1986                         chase_active_backup = autocvar_chase_active;
1987                         cvar_set("chase_active", "2");
1988                         cvar_set("cl_demo_mousegrab", "1");
1989                         camera_active = true;
1990                         camera_mode = false;
1991                 }
1992         }
1993
1994         // Draw the Crosshair
1995         setproperty(VF_DRAWCROSSHAIR, 0); //Make sure engine crosshairs are always hidden
1996
1997         // Draw the Engine Status Bar (the default Quake HUD)
1998         setproperty(VF_DRAWENGINESBAR, 0);
1999
2000         // Update the mouse position
2001         /*
2002            mousepos_x = vid_conwidth;
2003            mousepos_y = vid_conheight;
2004            mousepos = mousepos*0.5 + getmousepos();
2005          */
2006
2007         IL_EACH(g_drawables, it.draw, it.draw(it));
2008
2009         addentities(MASK_NORMAL | MASK_ENGINE | MASK_ENGINEVIEWMODELS);
2010         renderscene();
2011
2012         // now switch to 2D drawing mode by calling a 2D drawing function
2013         // then polygon drawing will draw as 2D stuff, and NOT get queued until the
2014         // next R_RenderScene call
2015         drawstring('0 0 0', "", '1 1 0', '1 1 1', 0, 0);
2016
2017         if(autocvar_r_fakelight >= 2 || autocvar_r_fullbright)
2018         if (!(serverflags & SERVERFLAG_ALLOW_FULLBRIGHT))
2019         {
2020                 // apply night vision effect
2021                 vector tc_00, tc_01, tc_10, tc_11;
2022                 vector rgb = '0 0 0';
2023
2024                 if(!nightvision_noise)
2025                 {
2026                         nightvision_noise = new(nightvision_noise);
2027                 }
2028                 if(!nightvision_noise2)
2029                 {
2030                         nightvision_noise2 = new(nightvision_noise2);
2031                 }
2032
2033                 // color tint in yellow
2034                 drawfill('0 0 0', autocvar_vid_conwidth * '1 0 0' + autocvar_vid_conheight * '0 1 0', '0.5 1 0.3', 1, DRAWFLAG_MODULATE);
2035
2036                 // draw BG
2037                 a = Noise_Pink(nightvision_noise, frametime * 1.5) * 0.05 + 0.15;
2038                 rgb = '1 1 1';
2039                 tc_00 = '0 0 0' + '0.2 0 0' * sin(time * 0.3) + '0 0.3 0' * cos(time * 0.7);
2040                 tc_01 = '0 2.25 0' + '0.6 0 0' * cos(time * 1.2) - '0 0.3 0' * sin(time * 2.2);
2041                 tc_10 = '1.5 0 0' - '0.2 0 0' * sin(time * 0.5) + '0 0.5 0' * cos(time * 1.7);
2042                 //tc_11 = '1 1 0' + '0.6 0 0' * sin(time * 0.6) + '0 0.3 0' * cos(time * 0.1);
2043                 tc_11 = tc_01 + tc_10 - tc_00;
2044                 R_BeginPolygon("gfx/nightvision-bg.tga", DRAWFLAG_ADDITIVE);
2045                 R_PolygonVertex('0 0 0', tc_00, rgb, a);
2046                 R_PolygonVertex(autocvar_vid_conwidth * '1 0 0', tc_10, rgb, a);
2047                 R_PolygonVertex(autocvar_vid_conwidth * '1 0 0' + autocvar_vid_conheight * '0 1 0', tc_11, rgb, a);
2048                 R_PolygonVertex(autocvar_vid_conheight * '0 1 0', tc_01, rgb, a);
2049                 R_EndPolygon();
2050
2051                 // draw FG
2052                 a = Noise_Pink(nightvision_noise2, frametime * 0.1) * 0.05 + 0.12;
2053                 rgb = '0.3 0.6 0.4' + '0.1 0.4 0.2' * Noise_White(nightvision_noise2, frametime);
2054                 tc_00 = '0 0 0' + '1 0 0' * Noise_White(nightvision_noise2, frametime) + '0 1 0' * Noise_White(nightvision_noise2, frametime);
2055                 tc_01 = tc_00 + '0 3 0' * (1 + Noise_White(nightvision_noise2, frametime) * 0.2);
2056                 tc_10 = tc_00 + '2 0 0' * (1 + Noise_White(nightvision_noise2, frametime) * 0.3);
2057                 tc_11 = tc_01 + tc_10 - tc_00;
2058                 R_BeginPolygon("gfx/nightvision-fg.tga", DRAWFLAG_ADDITIVE);
2059                 R_PolygonVertex('0 0 0', tc_00, rgb, a);
2060                 R_PolygonVertex(autocvar_vid_conwidth * '1 0 0', tc_10, rgb, a);
2061                 R_PolygonVertex(autocvar_vid_conwidth * '1 0 0' + autocvar_vid_conheight * '0 1 0', tc_11, rgb, a);
2062                 R_PolygonVertex(autocvar_vid_conheight * '0 1 0', tc_01, rgb, a);
2063                 R_EndPolygon();
2064         }
2065
2066         if(autocvar_cl_reticle)
2067         {
2068                 string reticle_image = string_null;
2069                 bool wep_zoomed = false;
2070                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
2071                 {
2072                         entity wepe = viewmodels[slot];
2073                         Weapon wep = wepe.activeweapon;
2074                         if(wep != WEP_Null && wep.wr_zoom)
2075                         {
2076                                 bool do_zoom = wep.wr_zoom(wep, NULL);
2077                                 if(!reticle_image && wep.w_reticle && wep.w_reticle != "")
2078                                         reticle_image = wep.w_reticle;
2079                                 wep_zoomed += do_zoom;
2080                         }
2081                 }
2082                 // Draw the aiming reticle for weapons that use it
2083                 // reticle_type is changed to the item we are zooming / aiming with, to decide which reticle to use
2084                 // It must be a persisted float for fading out to work properly (you let go of the zoom button for
2085                 // the view to go back to normal, so reticle_type would become 0 as we fade out)
2086                 if(spectatee_status || is_dead || hud != HUD_NORMAL)
2087                 {
2088                         // no zoom reticle while dead
2089                         reticle_type = 0;
2090                 }
2091                 else if(wep_zoomed && autocvar_cl_reticle_weapon)
2092                 {
2093                         if(reticle_image) { reticle_type = 2; }
2094                         else { reticle_type = 0; }
2095                 }
2096                 else if(button_zoom || zoomscript_caught)
2097                 {
2098                         // normal zoom
2099                         reticle_type = 1;
2100                 }
2101
2102                 if(reticle_type)
2103                 {
2104                         if(autocvar_cl_reticle_stretch)
2105                         {
2106                                 reticle_size.x = vid_conwidth;
2107                                 reticle_size.y = vid_conheight;
2108                                 reticle_pos.x = 0;
2109                                 reticle_pos.y = 0;
2110                         }
2111                         else
2112                         {
2113                                 reticle_size.x = max(vid_conwidth, vid_conheight);
2114                                 reticle_size.y = max(vid_conwidth, vid_conheight);
2115                                 reticle_pos.x = (vid_conwidth - reticle_size.x) / 2;
2116                                 reticle_pos.y = (vid_conheight - reticle_size.y) / 2;
2117                         }
2118
2119                         if(zoomscript_caught)
2120                                 f = 1;
2121                         else
2122                                 f = current_zoomfraction;
2123
2124                         if(f)
2125                         {
2126                                 switch(reticle_type)
2127                                 {
2128                                         case 1: drawpic(reticle_pos, "gfx/reticle_normal", reticle_size, '1 1 1', f * autocvar_cl_reticle_normal_alpha, DRAWFLAG_NORMAL); break;
2129                                         case 2: if(reticle_image) drawpic(reticle_pos, reticle_image, reticle_size, '1 1 1', f * autocvar_cl_reticle_weapon_alpha, DRAWFLAG_NORMAL); break;
2130                                 }
2131                         }
2132                 }
2133         }
2134         else
2135         {
2136                 if(reticle_type != 0) { reticle_type = 0; }
2137         }
2138
2139
2140         // improved polyblend
2141         if(autocvar_hud_contents && !MUTATOR_CALLHOOK(HUD_Contents))
2142         {
2143                 float contentalpha_temp, incontent, liquidalpha, contentfadetime;
2144                 vector liquidcolor;
2145
2146                 switch(pointcontents(view_origin))
2147                 {
2148                         case CONTENT_WATER:
2149                                 liquidalpha = autocvar_hud_contents_water_alpha;
2150                                 liquidcolor = stov(autocvar_hud_contents_water_color);
2151                                 incontent = 1;
2152                                 break;
2153
2154                         case CONTENT_LAVA:
2155                                 liquidalpha = autocvar_hud_contents_lava_alpha;
2156                                 liquidcolor = stov(autocvar_hud_contents_lava_color);
2157                                 incontent = 1;
2158                                 break;
2159
2160                         case CONTENT_SLIME:
2161                                 liquidalpha = autocvar_hud_contents_slime_alpha;
2162                                 liquidcolor = stov(autocvar_hud_contents_slime_color);
2163                                 incontent = 1;
2164                                 break;
2165
2166                         default:
2167                                 liquidalpha = 0;
2168                                 liquidcolor = '0 0 0';
2169                                 incontent = 0;
2170                                 break;
2171                 }
2172
2173                 if(incontent) // fade in/out at different speeds so you can do e.g. instant fade when entering water and slow when leaving it.
2174                 { // also lets delcare previous values for blending properties, this way it isn't reset until after you have entered a different content
2175                         contentfadetime = autocvar_hud_contents_fadeintime;
2176                         liquidalpha_prev = liquidalpha;
2177                         liquidcolor_prev = liquidcolor;
2178                 }
2179                 else
2180                         contentfadetime = autocvar_hud_contents_fadeouttime;
2181
2182                 contentalpha_temp = bound(0, drawframetime / max(0.0001, contentfadetime), 1);
2183                 contentavgalpha = contentavgalpha * (1 - contentalpha_temp) + incontent * contentalpha_temp;
2184
2185                 if(contentavgalpha)
2186                         drawfill('0 0 0', vec2(vid_conwidth, vid_conheight), liquidcolor_prev, contentavgalpha * liquidalpha_prev, DRAWFLAG_NORMAL);
2187
2188                 if(autocvar_hud_postprocessing)
2189                 {
2190                         if(autocvar_hud_contents_blur && contentavgalpha)
2191                         {
2192                                 content_blurpostprocess.x = 1;
2193                                 content_blurpostprocess.y = contentavgalpha * autocvar_hud_contents_blur;
2194                                 content_blurpostprocess.z = contentavgalpha * autocvar_hud_contents_blur_alpha;
2195                         }
2196                         else
2197                         {
2198                                 content_blurpostprocess.x = 0;
2199                                 content_blurpostprocess.y = 0;
2200                                 content_blurpostprocess.z = 0;
2201                         }
2202                 }
2203         }
2204
2205         if(autocvar_hud_damage && !STAT(FROZEN))
2206         {
2207                 splash_size.x = max(vid_conwidth, vid_conheight);
2208                 splash_size.y = max(vid_conwidth, vid_conheight);
2209                 splash_pos.x = (vid_conwidth - splash_size.x) / 2;
2210                 splash_pos.y = (vid_conheight - splash_size.y) / 2;
2211
2212                 float myhealth_flash_temp;
2213                 myhealth = STAT(HEALTH);
2214
2215                 // fade out
2216                 myhealth_flash = max(0, myhealth_flash - autocvar_hud_damage_fade_rate * frametime);
2217                 // add new damage
2218                 myhealth_flash = bound(0, myhealth_flash + dmg_take * autocvar_hud_damage_factor, autocvar_hud_damage_maxalpha);
2219
2220                 float pain_threshold, pain_threshold_lower, pain_threshold_lower_health;
2221                 pain_threshold = autocvar_hud_damage_pain_threshold;
2222                 pain_threshold_lower = autocvar_hud_damage_pain_threshold_lower;
2223                 pain_threshold_lower_health = autocvar_hud_damage_pain_threshold_lower_health;
2224
2225                 if(pain_threshold_lower && myhealth < pain_threshold_lower_health)
2226                 {
2227                         pain_threshold = pain_threshold - max(autocvar_hud_damage_pain_threshold_pulsating_min, fabs(sin(M_PI * time / autocvar_hud_damage_pain_threshold_pulsating_period))) * pain_threshold_lower * (1 - max(0, myhealth)/pain_threshold_lower_health);
2228                 }
2229
2230                 myhealth_flash_temp = bound(0, myhealth_flash - pain_threshold, 1);
2231
2232                 if(myhealth_prev < 1)
2233                 {
2234                         if(myhealth >= 1)
2235                         {
2236                                 myhealth_flash = 0; // just spawned, clear the flash immediately
2237                                 myhealth_flash_temp = 0;
2238                         }
2239                         else
2240                         {
2241                                 myhealth_flash += autocvar_hud_damage_fade_rate * frametime; // dead
2242                         }
2243                 }
2244
2245                 if(spectatee_status == -1 || intermission)
2246                 {
2247                         myhealth_flash = 0; // observing, or match ended
2248                         myhealth_flash_temp = 0;
2249                 }
2250
2251                 myhealth_prev = myhealth;
2252
2253                 // IDEA: change damage color/picture based on player model for robot/alien species?
2254                 // pro: matches model better
2255                 // contra: it's not red because blood is red, but because red is an alarming color, so red should stay
2256                 // maybe different reddish pics?
2257                 if(autocvar_cl_gentle_damage || autocvar_cl_gentle)
2258                 {
2259                         if(autocvar_cl_gentle_damage == 2)
2260                         {
2261                                 if(myhealth_flash < pain_threshold) // only randomize when the flash is gone
2262                                         myhealth_gentlergb = randomvec();
2263                         }
2264                         else
2265                                 myhealth_gentlergb = stov(autocvar_hud_damage_gentle_color);
2266
2267                         if(myhealth_flash_temp > 0)
2268                                 drawfill('0 0 0', vec2(vid_conwidth, vid_conheight), myhealth_gentlergb, autocvar_hud_damage_gentle_alpha_multiplier * bound(0, myhealth_flash_temp, 1) * autocvar_hud_damage, DRAWFLAG_NORMAL);
2269                 }
2270                 else if(myhealth_flash_temp > 0)
2271                         drawpic(splash_pos, "gfx/blood", splash_size, stov(autocvar_hud_damage_color), bound(0, myhealth_flash_temp, 1) * autocvar_hud_damage, DRAWFLAG_NORMAL);
2272
2273                 if(autocvar_hud_postprocessing) // we still need to set this anyway even when chase_active is set, this way it doesn't get stuck on.
2274                 {
2275                         if(autocvar_hud_damage_blur && myhealth_flash_temp)
2276                         {
2277                                 damage_blurpostprocess.x = 1;
2278                                 damage_blurpostprocess.y = bound(0, myhealth_flash_temp, 1) * autocvar_hud_damage_blur;
2279                                 damage_blurpostprocess.z = bound(0, myhealth_flash_temp, 1) * autocvar_hud_damage_blur_alpha;
2280                         }
2281                         else
2282                         {
2283                                 damage_blurpostprocess.x = 0;
2284                                 damage_blurpostprocess.y = 0;
2285                                 damage_blurpostprocess.z = 0;
2286                         }
2287                 }
2288         }
2289
2290         float e1 = (autocvar_hud_postprocessing_maxbluralpha != 0);
2291         float e2 = (autocvar_hud_powerup != 0);
2292         if(autocvar_hud_postprocessing && (e1 || e2)) // TODO: Remove this code and re-do the postprocess handling in the engine, where it properly belongs.
2293         {
2294                 // enable or disable rendering types if they are used or not
2295                 if(cvar("r_glsl_postprocess_uservec1_enable") != e1) { cvar_set("r_glsl_postprocess_uservec1_enable", ftos(e1)); }
2296                 if(cvar("r_glsl_postprocess_uservec2_enable") != e2) { cvar_set("r_glsl_postprocess_uservec2_enable", ftos(e2)); }
2297
2298                 // blur postprocess handling done first (used by hud_damage and hud_contents)
2299                 if((damage_blurpostprocess.x || content_blurpostprocess.x))
2300                 {
2301                         float blurradius = bound(0, damage_blurpostprocess.y + content_blurpostprocess.y, autocvar_hud_postprocessing_maxblurradius);
2302                         float bluralpha = bound(0, damage_blurpostprocess.z + content_blurpostprocess.z, autocvar_hud_postprocessing_maxbluralpha);
2303                         if(blurradius != old_blurradius || bluralpha != old_bluralpha) // reduce cvar_set spam as much as possible
2304                         {
2305                                 cvar_set("r_glsl_postprocess_uservec1", strcat(ftos(blurradius), " ", ftos(bluralpha), " 0 0"));
2306                                 old_blurradius = blurradius;
2307                                 old_bluralpha = bluralpha;
2308                         }
2309                 }
2310                 else if(cvar_string("r_glsl_postprocess_uservec1") != "0 0 0 0") // reduce cvar_set spam as much as possible
2311                 {
2312                         cvar_set("r_glsl_postprocess_uservec1", "0 0 0 0");
2313                         old_blurradius = 0;
2314                         old_bluralpha = 0;
2315                 }
2316
2317                 // edge detection postprocess handling done second (used by hud_powerup)
2318                 float sharpen_intensity = 0, strength_finished = STAT(STRENGTH_FINISHED), invincible_finished = STAT(INVINCIBLE_FINISHED);
2319                 if (strength_finished - time > 0) { sharpen_intensity += (strength_finished - time); }
2320                 if (invincible_finished - time > 0) { sharpen_intensity += (invincible_finished - time); }
2321
2322                 sharpen_intensity = bound(0, ((STAT(HEALTH) > 0) ? sharpen_intensity : 0), 5); // Check to see if player is alive (if not, set 0) - also bound to fade out starting at 5 seconds.
2323
2324                 if(autocvar_hud_powerup && sharpen_intensity > 0)
2325                 {
2326                         if(sharpen_intensity != old_sharpen_intensity) // reduce cvar_set spam as much as possible
2327                         {
2328                                 cvar_set("r_glsl_postprocess_uservec2", strcat(ftos((sharpen_intensity / 5) * autocvar_hud_powerup), " ", ftos(-sharpen_intensity * autocvar_hud_powerup), " 0 0"));
2329                                 old_sharpen_intensity = sharpen_intensity;
2330                         }
2331                 }
2332                 else if(cvar_string("r_glsl_postprocess_uservec2") != "0 0 0 0") // reduce cvar_set spam as much as possible
2333                 {
2334                         cvar_set("r_glsl_postprocess_uservec2", "0 0 0 0");
2335                         old_sharpen_intensity = 0;
2336                 }
2337
2338                 if(cvar("r_glsl_postprocess") == 0)
2339                         cvar_set("r_glsl_postprocess", "2");
2340         }
2341         else if(cvar("r_glsl_postprocess") == 2)
2342                 cvar_set("r_glsl_postprocess", "0");
2343
2344         /*if(gametype == MAPINFO_TYPE_CTF)
2345           {
2346           ctf_view();
2347           } else */
2348
2349         // draw 2D entities
2350         IL_EACH(g_drawables_2d, it.draw2d, it.draw2d(it));
2351         Draw_ShowNames_All();
2352 #if ENABLE_DEBUGDRAW
2353         Debug_Draw();
2354 #endif
2355
2356         scoreboard_active = Scoreboard_WouldDraw();
2357
2358         HUD_Draw(this); // this parameter for deep vehicle function
2359
2360         if(NextFrameCommand)
2361         {
2362                 localcmd("\n", NextFrameCommand, "\n");
2363                 NextFrameCommand = string_null;
2364         }
2365
2366         // we must do this check AFTER a frame was rendered, or it won't work
2367         if(cs_project_is_b0rked == 0)
2368         {
2369                 string w0, h0;
2370                 w0 = ftos(autocvar_vid_conwidth);
2371                 h0 = ftos(autocvar_vid_conheight);
2372                 //setproperty(VF_VIEWPORT, '0 0 0', '640 480 0');
2373                 //setproperty(VF_FOV, '90 90 0');
2374                 setproperty(VF_ORIGIN, '0 0 0');
2375                 setproperty(VF_ANGLES, '0 0 0');
2376                 setproperty(VF_PERSPECTIVE, 1);
2377                 makevectors('0 0 0');
2378                 vector v1, v2;
2379                 cvar_set("vid_conwidth", "800");
2380                 cvar_set("vid_conheight", "600");
2381                 v1 = cs_project(v_forward);
2382                 cvar_set("vid_conwidth", "640");
2383                 cvar_set("vid_conheight", "480");
2384                 v2 = cs_project(v_forward);
2385                 if(v1 == v2)
2386                         cs_project_is_b0rked = 1;
2387                 else
2388                         cs_project_is_b0rked = -1;
2389                 cvar_set("vid_conwidth", w0);
2390                 cvar_set("vid_conheight", h0);
2391         }
2392
2393         if(autocvar__hud_configure)
2394                 HUD_Panel_Mouse();
2395         else if (HUD_MinigameMenu_IsOpened() || active_minigame)
2396                 HUD_Minigame_Mouse();
2397         else if(QuickMenu_IsOpened())
2398                 QuickMenu_Mouse();
2399         else
2400                 HUD_Radar_Mouse();
2401
2402         cl_notice_run();
2403         unpause_update();
2404         Net_Flush();
2405
2406         // let's reset the view back to normal for the end
2407         setproperty(VF_MIN, '0 0 0');
2408         setproperty(VF_SIZE, '1 0 0' * w + '0 1 0' * h);
2409
2410         IL_ENDFRAME();
2411 }
2412
2413
2414 // following vectors must be global to allow seamless switching between camera modes
2415 vector camera_offset, current_camera_offset, mouse_angles, current_angles, current_origin, current_position;
2416 void CSQC_Demo_Camera()
2417 {
2418         float speed, attenuation, dimensions;
2419         vector tmp, delta;
2420
2421         if( autocvar_camera_reset || !camera_mode )
2422         {
2423                 camera_offset = '0 0 0';
2424                 current_angles = '0 0 0';
2425                 camera_direction = '0 0 0';
2426                 camera_offset.z += 30;
2427                 camera_offset.x += 30 * -cos(current_angles.y * DEG2RAD);
2428                 camera_offset.y += 30 * -sin(current_angles.y * DEG2RAD);
2429                 current_origin = view_origin;
2430                 current_camera_offset  = camera_offset;
2431                 cvar_set("camera_reset", "0");
2432                 camera_mode = CAMERA_CHASE;
2433         }
2434
2435         // Camera angles
2436         if( camera_roll )
2437                 mouse_angles.z += camera_roll * autocvar_camera_speed_roll;
2438
2439         if(autocvar_camera_look_player)
2440         {
2441                 vector dir;
2442                 float n;
2443
2444                 dir = normalize(view_origin - current_position);
2445                 n = mouse_angles.z;
2446                 mouse_angles = vectoangles(dir);
2447                 mouse_angles.x = mouse_angles.x * -1;
2448                 mouse_angles.z = n;
2449         }
2450         else
2451         {
2452                 tmp = getmousepos() * 0.1;
2453                 if(vdist(tmp, >, autocvar_camera_mouse_threshold))
2454                 {
2455                         mouse_angles.x += tmp.y * cos(mouse_angles.z * DEG2RAD) + (tmp.x * sin(mouse_angles.z * DEG2RAD));
2456                         mouse_angles.y -= tmp.x * cos(mouse_angles.z * DEG2RAD) + (tmp.y * -sin(mouse_angles.z * DEG2RAD));
2457                 }
2458         }
2459
2460         while (mouse_angles.x < -180) mouse_angles.x = mouse_angles.x + 360;
2461         while (mouse_angles.x > 180) mouse_angles.x = mouse_angles.x - 360;
2462         while (mouse_angles.y < -180) mouse_angles.y = mouse_angles.y + 360;
2463         while (mouse_angles.y > 180) mouse_angles.y = mouse_angles.y - 360;
2464
2465         // Fix difference when angles don't have the same sign
2466         delta = '0 0 0';
2467         if(mouse_angles.y < -60 && current_angles.y > 60)
2468                 delta = '0 360 0';
2469         if(mouse_angles.y > 60 && current_angles.y < -60)
2470                 delta = '0 -360 0';
2471
2472         if(autocvar_camera_look_player)
2473                 attenuation = autocvar_camera_look_attenuation;
2474         else
2475                 attenuation = autocvar_camera_speed_attenuation;
2476
2477         attenuation = 1 / max(1, attenuation);
2478         current_angles += (mouse_angles - current_angles + delta) * attenuation;
2479
2480         while (current_angles.x < -180) current_angles.x = current_angles.x + 360;
2481         while (current_angles.x > 180) current_angles.x = current_angles.x - 360;
2482         while (current_angles.y < -180) current_angles.y = current_angles.y + 360;
2483         while (current_angles.y > 180) current_angles.y = current_angles.y - 360;
2484
2485         // Camera position
2486         tmp = '0 0 0';
2487         dimensions = 0;
2488
2489         if( camera_direction.x )
2490         {
2491                 tmp.x = camera_direction.x * cos(current_angles.y * DEG2RAD);
2492                 tmp.y = camera_direction.x * sin(current_angles.y * DEG2RAD);
2493                 if( autocvar_camera_forward_follows && !autocvar_camera_look_player )
2494                         tmp.z = camera_direction.x * -sin(current_angles.x * DEG2RAD);
2495                 ++dimensions;
2496         }
2497
2498         if( camera_direction.y )
2499         {
2500                 tmp.x += camera_direction.y * -sin(current_angles.y * DEG2RAD);
2501                 tmp.y += camera_direction.y * cos(current_angles.y * DEG2RAD) * cos(current_angles.z * DEG2RAD);
2502                 tmp.z += camera_direction.y * sin(current_angles.z * DEG2RAD);
2503                 ++dimensions;
2504         }
2505
2506         if( camera_direction.z )
2507         {
2508                 tmp.z += camera_direction.z * cos(current_angles.z * DEG2RAD);
2509                 ++dimensions;
2510         }
2511
2512         if(autocvar_camera_free)
2513                 speed = autocvar_camera_speed_free;
2514         else
2515                 speed = autocvar_camera_speed_chase;
2516
2517         if(dimensions)
2518         {
2519                 speed = speed * sqrt(1 / dimensions);
2520                 camera_offset += tmp * speed;
2521         }
2522
2523         current_camera_offset += (camera_offset - current_camera_offset) * attenuation;
2524
2525         // Camera modes
2526         if( autocvar_camera_free )
2527         {
2528                 if ( camera_mode == CAMERA_CHASE )
2529                 {
2530                         current_camera_offset = current_origin + current_camera_offset;
2531                         camera_offset = current_origin + camera_offset;
2532                 }
2533
2534                 camera_mode = CAMERA_FREE;
2535                 current_position = current_camera_offset;
2536         }
2537         else
2538         {
2539                 if ( camera_mode == CAMERA_FREE )
2540                 {
2541                         current_origin = view_origin;
2542                         camera_offset = camera_offset - current_origin;
2543                         current_camera_offset = current_camera_offset - current_origin;
2544                 }
2545
2546                 camera_mode = CAMERA_CHASE;
2547
2548                 if(autocvar_camera_chase_smoothly)
2549                         current_origin += (view_origin - current_origin) * attenuation;
2550                 else
2551                         current_origin = view_origin;
2552
2553                 current_position = current_origin + current_camera_offset;
2554         }
2555
2556         setproperty(VF_ANGLES, current_angles);
2557         setproperty(VF_ORIGIN, current_position);
2558 }