qcsrc/client/view.qc

   1 #include "view.qh"
   2
   3 #include "autocvars.qh"
   4 #include "miscfunctions.qh"
   5 #include "announcer.qh"
   6 #include "hud/_mod.qh"
   7 #include "mapvoting.qh"
   8 #include "shownames.qh"
   9 #include "hud/panel/scoreboard.qh"
  10 #include "hud/panel/quickmenu.qh"
  11
  12 #include <client/mutators/_mod.qh>
  13
  14 #include <common/animdecide.qh>
  15 #include <common/deathtypes/all.qh>
  16 #include <common/ent_cs.qh>
  17 #include <common/anim.qh>
  18 #include <common/constants.qh>
  19 #include <common/net_linked.qh>
  20 #include <common/net_notice.qh>
  21 #include <common/debug.qh>
  22 #include <common/mapinfo.qh>
  23 #include <common/gamemodes/_mod.qh>
  24 #include <common/physics/player.qh>
  25 #include <common/stats.qh>
  26 #include <common/mapobjects/target/music.qh>
  27 #include <common/teams.qh>
  28 #include <common/wepent.qh>
  29
  30 #include <common/weapons/weapon/tuba.qh>
  31
  32 #include <common/vehicles/all.qh>
  33 #include <common/weapons/_all.qh>
  34 #include <common/mutators/mutator/overkill/oknex.qh>
  35 #include <common/mutators/mutator/waypoints/all.qh>
  36 #include <common/viewloc.qh>
  37 #include <common/mapobjects/trigger/viewloc.qh>
  38 #include <common/minigames/cl_minigames.qh>
  39 #include <common/minigames/cl_minigames_hud.qh>
  40
  41 #include <lib/csqcmodel/cl_player.qh>
  42 #include <lib/csqcmodel/cl_model.qh>
  43 #include "csqcmodel_hooks.qh"
  44
  45 #include <lib/warpzone/client.qh>
  46 #include <lib/warpzone/common.qh>
  47
  48 #define EFMASK_CHEAP (EF_ADDITIVE | EF_DOUBLESIDED | EF_FULLBRIGHT | EF_NODEPTHTEST | EF_NODRAW | EF_NOSHADOW | EF_SELECTABLE | EF_TELEPORT_BIT)
  49
  50 float autocvar_cl_viewmodel_scale;
  51
  52 bool autocvar_cl_bobmodel;
  53 float autocvar_cl_bobmodel_speed;
  54 float autocvar_cl_bobmodel_side;
  55 float autocvar_cl_bobmodel_up;
  56
  57 float autocvar_cl_followmodel;
  58 float autocvar_cl_followmodel_speed = 0.3;
  59 float autocvar_cl_followmodel_limit = 135;
  60 float autocvar_cl_followmodel_velocity_lowpass = 0.05;
  61 float autocvar_cl_followmodel_highpass = 0.05;
  62 float autocvar_cl_followmodel_lowpass = 0.03;
  63 bool autocvar_cl_followmodel_velocity_absolute;
  64
  65 float autocvar_cl_leanmodel;
  66 float autocvar_cl_leanmodel_speed = 0.3;
  67 float autocvar_cl_leanmodel_limit = 30;
  68 float autocvar_cl_leanmodel_highpass1 = 0.2;
  69 float autocvar_cl_leanmodel_highpass = 0.2;
  70 float autocvar_cl_leanmodel_lowpass = 0.05;
  71
  72 #define avg_factor(avg_time) (1 - exp(-frametime / max(0.001, avg_time)))
  73
  74 #define lowpass(value, frac, ref_store, ret) \
  75         ret = ref_store = ref_store * (1 - frac) + (value) * frac;
  76
  77 #define lowpass_limited(value, frac, limit, ref_store, ret) MACRO_BEGIN \
  78 { \
  79         float __ignore; lowpass(value, frac, ref_store, __ignore); \
  80         ret = ref_store = bound((value) - (limit), ref_store, (value) + (limit)); \
  81 } MACRO_END
  82
  83 #define highpass(value, frac, ref_store, ret) MACRO_BEGIN \
  84 { \
  85         float __f = 0; lowpass(value, frac, ref_store, __f); \
  86         ret = (value) - __f; \
  87 } MACRO_END
  88
  89 #define highpass_limited(value, frac, limit, ref_store, ret) MACRO_BEGIN \
  90 { \
  91         float __f = 0; lowpass_limited(value, frac, limit, ref_store, __f); \
  92         ret = (value) - __f; \
  93 } MACRO_END
  94
  95 #define lowpass2(value, frac, ref_store, ref_out) MACRO_BEGIN \
  96 { \
  97         lowpass(value.x, frac, ref_store.x, ref_out.x); \
  98         lowpass(value.y, frac, ref_store.y, ref_out.y); \
  99 } MACRO_END
 100
 101 #define highpass2(value, frac, ref_store, ref_out) MACRO_BEGIN \
 102 { \
 103         highpass(value.x, frac, ref_store.x, ref_out.x); \
 104         highpass(value.y, frac, ref_store.y, ref_out.y); \
 105 } MACRO_END
 106
 107 #define highpass2_limited(value, frac, limit, ref_store, ref_out) MACRO_BEGIN \
 108 { \
 109         highpass_limited(value.x, frac, limit, ref_store.x, ref_out.x); \
 110         highpass_limited(value.y, frac, limit, ref_store.y, ref_out.y); \
 111 } MACRO_END
 112
 113 #define lowpass3(value, frac, ref_store, ref_out) MACRO_BEGIN \
 114 { \
 115         lowpass(value.x, frac, ref_store.x, ref_out.x); \
 116         lowpass(value.y, frac, ref_store.y, ref_out.y); \
 117         lowpass(value.z, frac, ref_store.z, ref_out.z); \
 118 } MACRO_END
 119
 120 #define highpass3(value, frac, ref_store, ref_out) MACRO_BEGIN \
 121 { \
 122         highpass(value.x, frac, ref_store.x, ref_out.x); \
 123         highpass(value.y, frac, ref_store.y, ref_out.y); \
 124         highpass(value.z, frac, ref_store.z, ref_out.z); \
 125 } MACRO_END
 126
 127 void calc_followmodel_ofs(entity view)
 128 {
 129         if(cl_followmodel_time == time)
 130                 return; // cl_followmodel_ofs already calculated for this frame
 131
 132         float frac;
 133         vector gunorg = '0 0 0';
 134         static vector vel_average;
 135         static vector gunorg_adjustment_highpass;
 136         static vector gunorg_adjustment_lowpass;
 137
 138         vector vel;
 139         if (autocvar_cl_followmodel_velocity_absolute)
 140                 vel = view.velocity;
 141         else
 142         {
 143                 vector forward = '0 0 0', right = '0 0 0', up = '0 0 0';
 144                 MAKEVECTORS(makevectors, view_angles, forward, right, up);
 145                 vel.x = view.velocity * forward;
 146                 vel.y = view.velocity * right * -1;
 147                 vel.z = view.velocity * up;
 148         }
 149
 150         vel.x = bound(vel_average.x - autocvar_cl_followmodel_limit, vel.x, vel_average.x + autocvar_cl_followmodel_limit);
 151         vel.y = bound(vel_average.y - autocvar_cl_followmodel_limit, vel.y, vel_average.y + autocvar_cl_followmodel_limit);
 152         vel.z = bound(vel_average.z - autocvar_cl_followmodel_limit, vel.z, vel_average.z + autocvar_cl_followmodel_limit);
 153
 154         frac = avg_factor(autocvar_cl_followmodel_velocity_lowpass);
 155         lowpass3(vel, frac, vel_average, gunorg);
 156
 157         gunorg *= -autocvar_cl_followmodel_speed * 0.042;
 158
 159         // perform highpass/lowpass on the adjustment vectors (turning velocity into acceleration!)
 160         // trick: we must do the lowpass LAST, so the lowpass vector IS the final vector!
 161         frac = avg_factor(autocvar_cl_followmodel_highpass);
 162         highpass3(gunorg, frac, gunorg_adjustment_highpass, gunorg);
 163         frac = avg_factor(autocvar_cl_followmodel_lowpass);
 164         lowpass3(gunorg, frac, gunorg_adjustment_lowpass, gunorg);
 165
 166         if (autocvar_cl_followmodel_velocity_absolute)
 167         {
 168                 vector fixed_gunorg;
 169                 vector forward = '0 0 0', right = '0 0 0', up = '0 0 0';
 170                 MAKEVECTORS(makevectors, view_angles, forward, right, up);
 171                 fixed_gunorg.x = gunorg * forward;
 172                 fixed_gunorg.y = gunorg * right * -1;
 173                 fixed_gunorg.z = gunorg * up;
 174                 gunorg = fixed_gunorg;
 175         }
 176
 177         cl_followmodel_ofs = gunorg;
 178         cl_followmodel_time = time;
 179 }
 180
 181 vector leanmodel_ofs(entity view)
 182 {
 183         float frac;
 184         vector gunangles = '0 0 0';
 185         static vector gunangles_prev = '0 0 0';
 186         static vector gunangles_highpass = '0 0 0';
 187         static vector gunangles_adjustment_highpass;
 188         static vector gunangles_adjustment_lowpass;
 189
 190         if (view.csqcmodel_teleported)
 191                 gunangles_prev = view_angles;
 192
 193         // in the highpass, we _store_ the DIFFERENCE to the actual view angles...
 194         gunangles_highpass += gunangles_prev;
 195         PITCH(gunangles_highpass) += 360 * floor((PITCH(view_angles) - PITCH(gunangles_highpass)) / 360 + 0.5);
 196         YAW(gunangles_highpass) += 360 * floor((YAW(view_angles) - YAW(gunangles_highpass)) / 360 + 0.5);
 197         ROLL(gunangles_highpass) += 360 * floor((ROLL(view_angles) - ROLL(gunangles_highpass)) / 360 + 0.5);
 198         frac = avg_factor(autocvar_cl_leanmodel_highpass1);
 199         highpass2_limited(view_angles, frac, autocvar_cl_leanmodel_limit, gunangles_highpass, gunangles);
 200         gunangles_prev = view_angles;
 201         gunangles_highpass -= gunangles_prev;
 202
 203         PITCH(gunangles) *= -autocvar_cl_leanmodel_speed;
 204         YAW(gunangles) *= -autocvar_cl_leanmodel_speed;
 205
 206         // we assume here: PITCH = 0, YAW = 1, ROLL = 2
 207         frac = avg_factor(autocvar_cl_leanmodel_highpass);
 208         highpass2(gunangles, frac, gunangles_adjustment_highpass, gunangles);
 209         frac = avg_factor(autocvar_cl_leanmodel_lowpass);
 210         lowpass2(gunangles, frac, gunangles_adjustment_lowpass, gunangles);
 211
 212         gunangles.x = -gunangles.x; // pitch was inverted, now that actually matters
 213
 214         return gunangles;
 215 }
 216
 217 vector bobmodel_ofs(entity view)
 218 {
 219         bool clonground = !(view.anim_implicit_state & ANIMIMPLICITSTATE_INAIR);
 220         static bool oldonground;
 221         static float hitgroundtime;
 222         if (clonground)
 223         {
 224                 float f = time; // cl.movecmd[0].time
 225                 if (!oldonground)
 226                         hitgroundtime = f;
 227         }
 228         oldonground = clonground;
 229
 230         // calculate for swinging gun model
 231         // the gun bobs when running on the ground, but doesn't bob when you're in the air.
 232         vector gunorg = '0 0 0';
 233         static float bobmodel_scale = 0;
 234         static float time_ofs = 0; // makes the effect always restart in the same way
 235         if (clonground)
 236         {
 237                 if (time - hitgroundtime > 0.05)
 238                         bobmodel_scale = min(1, bobmodel_scale + frametime * 5);
 239         }
 240         else
 241                 bobmodel_scale = max(0, bobmodel_scale - frametime * 5);
 242
 243         float xyspeed = bound(0, vlen(vec2(view.velocity)), 400);
 244         if (bobmodel_scale && xyspeed)
 245         {
 246                 float bspeed = xyspeed * 0.01 * autocvar_cl_viewmodel_scale * bobmodel_scale;
 247                 float s = (time - time_ofs) * autocvar_cl_bobmodel_speed;
 248                 gunorg.y = bspeed * autocvar_cl_bobmodel_side * sin(s);
 249                 gunorg.z = bspeed * autocvar_cl_bobmodel_up * cos(s * 2);
 250         }
 251         else
 252                 time_ofs = time;
 253
 254         return gunorg;
 255 }
 256
 257 void viewmodel_animate(entity this)
 258 {
 259         if (autocvar_chase_active) return;
 260         if (STAT(HEALTH) <= 0) return;
 261
 262         entity view = CSQCModel_server2csqc(player_localentnum - 1);
 263
 264         if (autocvar_cl_followmodel)
 265         {
 266                 calc_followmodel_ofs(view);
 267                 this.origin += cl_followmodel_ofs;
 268         }
 269
 270         if (autocvar_cl_leanmodel)
 271                 this.angles += leanmodel_ofs(view);
 272
 273         // vertical view bobbing code
 274         // TODO: cl_bob
 275
 276         // horizontal view bobbing code
 277         // TODO: cl_bob2
 278
 279         // fall bobbing code
 280         // causes the view to swing down and back up when touching the ground
 281         // TODO: cl_bobfall
 282
 283         // gun model bobbing code
 284         if (autocvar_cl_bobmodel)
 285                 this.origin += bobmodel_ofs(view);
 286 }
 287
 288 .vector viewmodel_origin, viewmodel_angles;
 289 .float weapon_nextthink;
 290 .float weapon_eta_last;
 291 .float weapon_switchdelay;
 292
 293 .string name_last;
 294
 295 void viewmodel_draw(entity this)
 296 {
 297         if(!this.activeweapon || !autocvar_r_drawviewmodel)
 298                 return;
 299         int mask = (intermission || (STAT(HEALTH) <= 0) || autocvar_chase_active) ? 0 : MASK_NORMAL;
 300         float a = this.alpha;
 301         static bool wasinvehicle;
 302         bool invehicle = player_localentnum > maxclients;
 303         if (invehicle) a = -1;
 304         else if (wasinvehicle) a = 1;
 305         wasinvehicle = invehicle;
 306         Weapon wep = this.activeweapon;
 307         int c = entcs_GetClientColors(current_player);
 308         vector g = weaponentity_glowmod(wep, NULL, c, this);
 309         entity me = CSQCModel_server2csqc(player_localentnum - 1);
 310         int fx = ((me.csqcmodel_effects & EFMASK_CHEAP)
 311                 | EF_NODEPTHTEST)
 312                 &~ (EF_FULLBRIGHT); // can mask team color, so get rid of it
 313         for (entity e = this; e; e = e.weaponchild)
 314         {
 315                 e.drawmask = mask;
 316                 e.alpha = a;
 317                 e.colormap = 256 + c;  // colormap == 0 is black, c == 0 is white
 318                 e.glowmod = g;
 319                 e.csqcmodel_effects = fx;
 320                 CSQCModel_Effects_Apply(e);
 321         }
 322         if(a >= 0)
 323         {
 324                 string name = wep.mdl;
 325                 string newname = wep.wr_viewmodel(wep, this);
 326                 if(newname)
 327                         name = newname;
 328                 bool swap = name != this.name_last;
 329                 // if (swap)
 330                 {
 331                         this.name_last = name;
 332                         CL_WeaponEntity_SetModel(this, name, swap);
 333                         this.viewmodel_origin = this.origin;
 334                         this.viewmodel_angles = this.angles;
 335                 }
 336                 anim_update(this);
 337                 if ((!this.animstate_override && !this.animstate_looping) || time > this.animstate_endtime)
 338                         anim_set(this, this.anim_idle, true, false, false);
 339         }
 340         float f = 0; // 0..1; 0: fully active
 341         float rate = STAT(WEAPONRATEFACTOR);
 342         float eta = rate ? ((this.weapon_nextthink - time) / rate) : 0;
 343         if (eta <= 0) f = this.weapon_eta_last;
 344         else switch (this.state)
 345         {
 346                 case WS_RAISE:
 347                 {
 348                         f = eta / max(eta, this.weapon_switchdelay);
 349                         break;
 350                 }
 351                 case WS_DROP:
 352                 {
 353                         f = 1 - eta / max(eta, this.weapon_switchdelay);
 354                         break;
 355                 }
 356                 case WS_CLEAR:
 357                 {
 358                         f = 1;
 359                         break;
 360                 }
 361         }
 362         this.weapon_eta_last = f;
 363         this.origin = this.viewmodel_origin;
 364         this.angles = this.viewmodel_angles;
 365         this.angles_x = (-90 * f * f);
 366         viewmodel_animate(this);
 367         MUTATOR_CALLHOOK(DrawViewModel, this);
 368         setorigin(this, this.origin);
 369 }
 370
 371 STATIC_INIT(viewmodel) {
 372     for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 373         viewmodels[slot] = new(viewmodel);
 374 }
 375
 376 float showfps_prevfps;
 377 float showfps_prevfps_time;
 378 int showfps_framecounter;
 379
 380 void fpscounter_update()
 381 {
 382         if(!STAT(SHOWFPS))
 383                 return;
 384
 385         float currentTime = gettime(GETTIME_REALTIME);
 386         showfps_framecounter += 1;
 387         if(currentTime - showfps_prevfps_time > STAT(SHOWFPS))
 388         {
 389                 showfps_prevfps = showfps_framecounter/(currentTime - showfps_prevfps_time);
 390                 showfps_framecounter = 0;
 391                 showfps_prevfps_time = currentTime;
 392
 393                 int channel = MSG_C2S;
 394                 WriteHeader(channel, fpsreport);
 395                 WriteShort(channel, bound(0, rint(showfps_prevfps), 65535)); // prevent insane fps values
 396         }
 397 }
 398
 399 STATIC_INIT(fpscounter_init)
 400 {
 401         float currentTime = gettime(GETTIME_REALTIME);
 402         showfps_prevfps_time = currentTime; // we must initialize it to avoid an instant low frame sending
 403 }
 404
 405 STATIC_INIT(Porto)
 406 {
 407         entity e = new_pure(porto);
 408         e.draw = Porto_Draw;
 409         IL_PUSH(g_drawables, e);
 410         e.dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY | DPCONTENTS_PLAYERCLIP;
 411 }
 412
 413 const int polyline_length = 16;
 414 .vector polyline[polyline_length];
 415 void Porto_Draw(entity this)
 416 {
 417         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 418         {
 419                 entity wepent = viewmodels[slot];
 420
 421                 if (wepent.activeweapon != WEP_PORTO) continue;
 422                 if (spectatee_status) continue;
 423                 if (WEP_CVAR(porto, secondary)) continue;
 424                 if (intermission == 1) continue;
 425                 if (intermission == 2) continue;
 426                 if (STAT(HEALTH) <= 0) continue;
 427
 428                 vector pos = view_origin;
 429                 vector dir = view_forward;
 430                 makevectors(((autocvar_chase_active) ? warpzone_save_view_angles : view_angles));
 431                 pos += v_right * -wepent.movedir.y
 432                         +  v_up * wepent.movedir.z;
 433
 434                 if (wepent.angles_held_status)
 435                 {
 436                         makevectors(wepent.angles_held);
 437                         dir = v_forward;
 438                 }
 439
 440                 wepent.polyline[0] = pos;
 441
 442                 int portal_number = 0, portal1_idx = 1, portal_max = 2;
 443                 int n = 1 + 2;  // 2 lines == 3 points
 444                 for (int idx = 0; idx < n && idx < polyline_length - 1; )
 445                 {
 446                         traceline(pos, pos + 65536 * dir, true, this);
 447                         dir = reflect(dir, trace_plane_normal);
 448                         pos = trace_endpos;
 449                         wepent.polyline[++idx] = pos;
 450                         if (trace_dphitq3surfaceflags & Q3SURFACEFLAG_SLICK || trace_dphitcontents & DPCONTENTS_PLAYERCLIP)
 451                         {
 452                                 n += 1;
 453                                 continue;
 454                         }
 455                         if (trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT)
 456                         {
 457                                 n = max(2, idx);
 458                                 break;
 459                         }
 460                         // check size
 461                         {
 462                                 vector ang = vectoangles2(trace_plane_normal, dir);
 463                                 ang.x = -ang.x;
 464                                 makevectors(ang);
 465                                 if (!CheckWireframeBox(this, pos - 48 * v_right - 48 * v_up + 16 * v_forward, 96 * v_right, 96 * v_up, 96 * v_forward))
 466                                 {
 467                                         n = max(2, idx);
 468                                         break;
 469                                 }
 470                         }
 471                         portal_number += 1;
 472                         if (portal_number >= portal_max) break;
 473                         if (portal_number == 1) portal1_idx = idx;
 474                 }
 475                 for (int idx = 0; idx < n - 1; ++idx)
 476                 {
 477                         vector p = wepent.polyline[idx], q = wepent.polyline[idx + 1];
 478                         if (idx == 0) p -= view_up * 16;  // line from player
 479                         vector rgb = (idx < portal1_idx) ? '1 0 0' : '0 0 1';
 480                         Draw_CylindricLine(p, q, 4, "", 1, 0, rgb, 0.5, DRAWFLAG_NORMAL, view_origin);
 481                 }
 482         }
 483 }
 484
 485 float drawtime;
 486 float avgspeed;
 487 vector GetCurrentFov(float fov)
 488 {
 489         float zoomsensitivity, zoomspeed, zoomfactor, zoomdir;
 490         float velocityzoom, curspeed;
 491         vector v;
 492
 493         zoomsensitivity = autocvar_cl_zoomsensitivity;
 494         zoomfactor = autocvar_cl_zoomfactor;
 495         if(zoomfactor < 1 || zoomfactor > 30)
 496                 zoomfactor = 2.5;
 497         zoomspeed = autocvar_cl_zoomspeed;
 498         if (zoomspeed >= 0 && (zoomspeed < 0.5 || zoomspeed > 16))
 499                 zoomspeed = 3.5;
 500
 501         zoomdir = button_zoom;
 502
 503         if(hud == HUD_NORMAL && !spectatee_status)
 504         {
 505                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 506                 {
 507                         entity wepent = viewmodels[slot];
 508                         if(wepent.switchweapon != wepent.activeweapon)
 509                                 continue;
 510                         Weapon wep = wepent.activeweapon;
 511                         if(wep != WEP_Null && wep.wr_zoomdir)
 512                         {
 513                                 bool do_zoom = wep.wr_zoomdir(wep); // TODO: merge this with wr_zoom?
 514                                 zoomdir += do_zoom;
 515                         }
 516                 }
 517         }
 518         if(spectatee_status > 0 || isdemo())
 519         {
 520                 if(spectatorbutton_zoom)
 521                 {
 522                         if(zoomdir)
 523                                 zoomdir = 0;
 524                         else
 525                                 zoomdir = 1;
 526                 }
 527                 // fteqcc failed twice here already, don't optimize this
 528         }
 529
 530         if(zoomdir) { zoomin_effect = 0; }
 531
 532         if (spectatee_status > 0 && STAT(CAMERA_SPECTATOR) == 2)
 533         {
 534                 current_viewzoom = 1;
 535         }
 536         else if (camera_active)
 537         {
 538                 current_viewzoom = min(1, current_viewzoom + drawframetime);
 539         }
 540         else if(autocvar_cl_spawnzoom && zoomin_effect)
 541         {
 542                 float spawnzoomfactor = bound(1, autocvar_cl_spawnzoom_factor, 30);
 543
 544                 current_viewzoom += (autocvar_cl_spawnzoom_speed * (spawnzoomfactor - current_viewzoom) * drawframetime);
 545                 current_viewzoom = bound(1 / spawnzoomfactor, current_viewzoom, 1);
 546                 if(current_viewzoom == 1) { zoomin_effect = 0; }
 547         }
 548         else
 549         {
 550                 if(zoomspeed < 0) // instant zoom
 551                 {
 552                         if(zoomdir)
 553                                 current_viewzoom = 1 / zoomfactor;
 554                         else
 555                                 current_viewzoom = 1;
 556                 }
 557                 else
 558                 {
 559                         if(zoomdir)
 560                                 current_viewzoom = 1 / bound(1, 1 / current_viewzoom + drawframetime * zoomspeed * (zoomfactor - 1), zoomfactor);
 561                         else
 562                                 current_viewzoom = bound(1 / zoomfactor, current_viewzoom + drawframetime * zoomspeed * (1 - 1 / zoomfactor), 1);
 563                 }
 564         }
 565
 566         if(almost_equals(current_viewzoom, 1))
 567                 current_zoomfraction = 0;
 568         else if(almost_equals(current_viewzoom, 1/zoomfactor))
 569                 current_zoomfraction = 1;
 570         else
 571                 current_zoomfraction = (current_viewzoom - 1) / (1/zoomfactor - 1);
 572
 573         if(zoomsensitivity < 1)
 574                 setsensitivityscale(current_viewzoom ** (1 - zoomsensitivity));
 575         else
 576                 setsensitivityscale(1);
 577
 578         if(autocvar_cl_velocityzoom_enabled && autocvar_cl_velocityzoom_type) // _type = 0 disables velocity zoom too
 579         {
 580                 if (intermission || (spectatee_status > 0 && STAT(CAMERA_SPECTATOR) == 2))
 581                         curspeed = 0;
 582                 else
 583                 {
 584                         makevectors(view_angles);
 585                         v = pmove_vel;
 586                         if(csqcplayer)
 587                                 v = csqcplayer.velocity;
 588
 589                         switch(autocvar_cl_velocityzoom_type)
 590                         {
 591                                 case 3: curspeed = max(0, v_forward * v); break;
 592                                 case 2: curspeed = (v_forward * v); break;
 593                                 case 1: default: curspeed = vlen(v); break;
 594                         }
 595                 }
 596
 597                 velocityzoom = bound(0, drawframetime / max(0.000000001, autocvar_cl_velocityzoom_time), 1); // speed at which the zoom adapts to player velocity
 598                 avgspeed = avgspeed * (1 - velocityzoom) + (curspeed / autocvar_cl_velocityzoom_speed) * velocityzoom;
 599                 velocityzoom = exp(float2range11(avgspeed * -autocvar_cl_velocityzoom_factor / 1) * 1);
 600
 601                 //print(ftos(avgspeed), " avgspeed, ", ftos(curspeed), " curspeed, ", ftos(velocityzoom), " return\n"); // for debugging
 602         }
 603         else
 604                 velocityzoom = 1;
 605
 606         float frustumx, frustumy, fovx, fovy;
 607         frustumy = tan(fov * M_PI / 360.0) * 0.75 * current_viewzoom * velocityzoom;
 608         frustumx = frustumy * vid_width / vid_height / vid_pixelheight;
 609         fovx = atan2(frustumx, 1) / M_PI * 360.0;
 610         fovy = atan2(frustumy, 1) / M_PI * 360.0;
 611
 612         return '1 0 0' * fovx + '0 1 0' * fovy;
 613 }
 614
 615 vector GetViewLocationFOV(float fov)
 616 {
 617         float frustumy = tan(fov * M_PI / 360.0) * 0.75;
 618         float frustumx = frustumy * vid_width / vid_height / vid_pixelheight;
 619         float fovx = atan2(frustumx, 1) / M_PI * 360.0;
 620         float fovy = atan2(frustumy, 1) / M_PI * 360.0;
 621         return '1 0 0' * fovx + '0 1 0' * fovy;
 622 }
 623
 624 vector GetOrthoviewFOV(vector ov_worldmin, vector ov_worldmax, vector ov_mid, vector ov_org)
 625 {
 626         float fovx, fovy;
 627         float width = (ov_worldmax.x - ov_worldmin.x);
 628         float height = (ov_worldmax.y - ov_worldmin.y);
 629         float distance_to_middle_of_world = vlen(ov_mid - ov_org);
 630         fovx = atan2(width/2, distance_to_middle_of_world) / M_PI * 360.0;
 631         fovy = atan2(height/2, distance_to_middle_of_world) / M_PI * 360.0;
 632         return '1 0 0' * fovx + '0 1 0' * fovy;
 633 }
 634
 635 // this function must match W_SetupShot!
 636 float zoomscript_caught;
 637
 638 vector wcross_origin;
 639 float wcross_scale_prev, wcross_alpha_prev;
 640 vector wcross_color_prev;
 641 float wcross_scale_goal_prev, wcross_alpha_goal_prev;
 642 vector wcross_color_goal_prev;
 643 float wcross_changedonetime;
 644
 645 string wcross_name_goal_prev, wcross_name_goal_prev_prev;
 646 float wcross_resolution_goal_prev, wcross_resolution_goal_prev_prev;
 647 float wcross_name_changestarttime, wcross_name_changedonetime;
 648 float wcross_name_alpha_goal_prev, wcross_name_alpha_goal_prev_prev;
 649
 650 float wcross_ring_prev;
 651
 652 entity trueaim;
 653 entity trueaim_rifle;
 654
 655 const float SHOTTYPE_HITTEAM = 1;
 656 const float SHOTTYPE_HITOBSTRUCTION = 2;
 657 const float SHOTTYPE_HITWORLD = 3;
 658 const float SHOTTYPE_HITENEMY = 4;
 659
 660 void TrueAim_Init()
 661 {
 662         (trueaim = new_pure(trueaim)).dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY | DPCONTENTS_CORPSE;
 663         (trueaim_rifle = new_pure(trueaim_rifle)).dphitcontentsmask = DPCONTENTS_BODY | DPCONTENTS_CORPSE;
 664 }
 665
 666 float EnemyHitCheck()
 667 {
 668         float t, n;
 669         wcross_origin = project_3d_to_2d(trace_endpos);
 670         wcross_origin.z = 0;
 671         if(trace_ent)
 672                 n = trace_ent.entnum;
 673         else
 674                 n = trace_networkentity;
 675         if(n < 1)
 676                 return SHOTTYPE_HITWORLD;
 677         if(n > maxclients)
 678                 return SHOTTYPE_HITWORLD;
 679         t = entcs_GetTeam(n - 1);
 680         if(teamplay)
 681                 if(t == myteam)
 682                         return SHOTTYPE_HITTEAM;
 683         if(t == NUM_SPECTATOR)
 684                 return SHOTTYPE_HITWORLD;
 685         return SHOTTYPE_HITENEMY;
 686 }
 687
 688 float TrueAimCheck(entity wepent)
 689 {
 690         float nudge = 1; // added to traceline target and subtracted from result TOOD(divVerent): do we still need this? Doesn't the engine do this now for us?
 691         vector vecs, trueaimpoint, w_shotorg;
 692         vector mi, ma, dv;
 693         float shottype;
 694         entity ta;
 695         float mv;
 696
 697         mi = ma = '0 0 0';
 698         ta = trueaim;
 699         mv = MOVE_NOMONSTERS;
 700
 701         switch(wepent.activeweapon) // WEAPONTODO
 702         {
 703                 case WEP_TUBA: // no aim
 704                 case WEP_PORTO: // shoots from eye
 705                 case WEP_NEXBALL: // shoots from eye
 706                 case WEP_HOOK: // no trueaim
 707                 case WEP_MORTAR: // toss curve
 708                         return SHOTTYPE_HITWORLD;
 709                 case WEP_VORTEX:
 710                 case WEP_OVERKILL_NEX:
 711                 case WEP_VAPORIZER:
 712                         mv = MOVE_NORMAL;
 713                         break;
 714                 case WEP_RIFLE:
 715                         ta = trueaim_rifle;
 716                         mv = MOVE_NORMAL;
 717                         if(zoomscript_caught)
 718                         {
 719                                 tracebox(view_origin, '0 0 0', '0 0 0', view_origin + view_forward * max_shot_distance, mv, ta);
 720                                 return EnemyHitCheck();
 721                         }
 722                         break;
 723                 case WEP_DEVASTATOR: // projectile has a size!
 724                         mi = '-3 -3 -3';
 725                         ma = '3 3 3';
 726                         break;
 727                 case WEP_FIREBALL: // projectile has a size!
 728                         mi = '-16 -16 -16';
 729                         ma = '16 16 16';
 730                         break;
 731                 case WEP_SEEKER: // projectile has a size!
 732                         mi = '-2 -2 -2';
 733                         ma = '2 2 2';
 734                         break;
 735                 case WEP_ELECTRO: // projectile has a size!
 736                         mi = '0 0 -3';
 737                         ma = '0 0 -3';
 738                         break;
 739         }
 740
 741         vector traceorigin = entcs_receiver(player_localentnum - 1).origin + (eZ * STAT(VIEWHEIGHT));
 742
 743         vecs = decompressShotOrigin(STAT(SHOTORG));
 744
 745         traceline(traceorigin, traceorigin + view_forward * max_shot_distance, mv, ta);
 746         trueaimpoint = trace_endpos;
 747
 748         if(vdist((trueaimpoint - traceorigin), <, g_trueaim_minrange))
 749                 trueaimpoint = traceorigin + view_forward * g_trueaim_minrange;
 750
 751         if(vecs.x > 0)
 752                 vecs.y = -vecs.y;
 753         else
 754                 vecs = '0 0 0';
 755
 756         dv = view_right * vecs.y + view_up * vecs.z;
 757         w_shotorg = traceorigin + dv;
 758
 759         // now move the vecs forward as much as requested if possible
 760         tracebox(w_shotorg, mi, ma, w_shotorg + view_forward * (vecs.x + nudge), MOVE_NORMAL, ta); // FIXME this MOVE_NORMAL part will misbehave a little in csqc
 761         w_shotorg = trace_endpos - view_forward * nudge;
 762
 763         tracebox(w_shotorg, mi, ma, trueaimpoint, MOVE_NORMAL, ta);
 764         shottype = EnemyHitCheck();
 765         if(shottype != SHOTTYPE_HITWORLD)
 766                 return shottype;
 767
 768 #if 0
 769         // FIXME WHY DOES THIS NOT WORK FOR THE ROCKET LAUNCHER?
 770         // or rather, I know why, but see no fix
 771         if(vlen(trace_endpos - trueaimpoint) > vlen(ma) + vlen(mi) + 1)
 772                 // yes, this is an ugly hack... but it seems good enough to find out whether the test hits the same place as the initial trace
 773                 return SHOTTYPE_HITOBSTRUCTION;
 774 #endif
 775
 776         return SHOTTYPE_HITWORLD;
 777 }
 778
 779 float camera_mode;
 780 const float CAMERA_FREE = 1;
 781 const float CAMERA_CHASE = 2;
 782 float reticle_type;
 783 string NextFrameCommand;
 784
 785 vector freeze_org, freeze_ang;
 786 entity nightvision_noise, nightvision_noise2;
 787
 788 const float MAX_TIME_DIFF = 5;
 789 float pickup_crosshair_time, pickup_crosshair_size;
 790 float hitindication_crosshair_size;
 791 float use_vortex_chargepool;
 792
 793 float myhealth, myhealth_prev;
 794 float myhealth_flash;
 795
 796 float old_blurradius, old_bluralpha;
 797 float old_sharpen_intensity;
 798
 799 vector myhealth_gentlergb;
 800
 801 float contentavgalpha, liquidalpha_prev;
 802 vector liquidcolor_prev;
 803
 804 float eventchase_current_distance;
 805 float eventchase_running;
 806 bool WantEventchase(entity this)
 807 {
 808         if(autocvar_cl_orthoview)
 809                 return false;
 810         if(STAT(GAME_STOPPED) || intermission)
 811                 return true;
 812         if(this.viewloc)
 813                 return true;
 814         if(spectatee_status >= 0)
 815         {
 816                 if(hud != HUD_NORMAL && (autocvar_cl_eventchase_vehicle || spectatee_status > 0))
 817                         return true;
 818                 if(MUTATOR_CALLHOOK(WantEventchase, this))
 819                         return true;
 820                 if(autocvar_cl_eventchase_frozen && STAT(FROZEN))
 821                         return true;
 822                 if(autocvar_cl_eventchase_death && (STAT(HEALTH) <= 0))
 823                 {
 824                         if(autocvar_cl_eventchase_death == 2)
 825                         {
 826                                 // don't stop eventchase once it's started (even if velocity changes afterwards)
 827                                 if(this.velocity == '0 0 0' || eventchase_running)
 828                                         return true;
 829                         }
 830                         else return true;
 831                 }
 832         }
 833         return false;
 834 }
 835
 836 void HUD_Crosshair_Vehicle(entity this)
 837 {
 838         if(hud != HUD_BUMBLEBEE_GUN)
 839         {
 840                 Vehicle info = Vehicles_from(hud);
 841                 info.vr_crosshair(info, this);
 842         }
 843 }
 844
 845 vector damage_blurpostprocess, content_blurpostprocess;
 846
 847 float unaccounted_damage = 0;
 848 void UpdateDamage()
 849 {
 850         // accumulate damage with each stat update
 851         static float damage_total_prev = 0;
 852         float damage_total = STAT(DAMAGE_DEALT_TOTAL);
 853         float unaccounted_damage_new = COMPARE_INCREASING(damage_total, damage_total_prev);
 854         damage_total_prev = damage_total;
 855
 856         static float damage_dealt_time_prev = 0;
 857         float damage_dealt_time = STAT(HIT_TIME);
 858         if (damage_dealt_time != damage_dealt_time_prev)
 859         {
 860                 unaccounted_damage += unaccounted_damage_new;
 861                 LOG_TRACE("dmg total: ", ftos(unaccounted_damage), " (+", ftos(unaccounted_damage_new), ")");
 862         }
 863         damage_dealt_time_prev = damage_dealt_time;
 864
 865         // prevent hitsound when switching spectatee
 866         static float spectatee_status_prev = 0;
 867         if (spectatee_status != spectatee_status_prev)
 868                 unaccounted_damage = 0;
 869         spectatee_status_prev = spectatee_status;
 870 }
 871
 872 void HitSound()
 873 {
 874         // varying sound pitch
 875
 876         bool have_arc = false;
 877         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 878         {
 879                 entity wepent = viewmodels[slot];
 880
 881                 if(wepent.activeweapon == WEP_ARC)
 882                         have_arc = true;
 883         }
 884
 885         static float hitsound_time_prev = 0;
 886         // HACK: the only way to get the arc to sound consistent with pitch shift is to ignore cl_hitsound_antispam_time
 887         bool arc_hack = have_arc && autocvar_cl_hitsound >= 2;
 888         if (arc_hack || COMPARE_INCREASING(time, hitsound_time_prev) > autocvar_cl_hitsound_antispam_time)
 889         {
 890                 if (autocvar_cl_hitsound && unaccounted_damage)
 891                 {
 892                         // customizable gradient function that crosses (0,a), (c,1) and asymptotically approaches b
 893                         float a = autocvar_cl_hitsound_max_pitch;
 894                         float b = autocvar_cl_hitsound_min_pitch;
 895                         float c = autocvar_cl_hitsound_nom_damage;
 896                         float d = unaccounted_damage;
 897                         float pitch_shift = (b*d*(a-1) + a*c*(1-b)) / (d*(a-1) + c*(1-b));
 898
 899                         // if sound variation is disabled, set pitch_shift to 1
 900                         if (autocvar_cl_hitsound == 1)
 901                                 pitch_shift = 1;
 902
 903                         // if pitch shift is reversed, mirror in (max-min)/2 + min
 904                         if (autocvar_cl_hitsound == 3)
 905                         {
 906                                 float mirror_value = (a-b)/2 + b;
 907                                 pitch_shift = mirror_value + (mirror_value - pitch_shift);
 908                         }
 909
 910                         LOG_TRACE("dmg total (dmg): ", ftos(unaccounted_damage), " , pitch shift: ", ftos(pitch_shift));
 911
 912                         // todo: avoid very long and very short sounds from wave stretching using different sound files? seems unnecessary
 913                         // todo: normalize sound pressure levels? seems unnecessary
 914
 915                         sound7(NULL, CH_INFO, SND(HIT), VOL_BASE, ATTN_NONE, pitch_shift * 100, 0);
 916                 }
 917                 unaccounted_damage = 0;
 918                 hitsound_time_prev = time;
 919         }
 920
 921         static float typehit_time_prev = 0;
 922         float typehit_time = STAT(TYPEHIT_TIME);
 923         if (COMPARE_INCREASING(typehit_time, typehit_time_prev) > autocvar_cl_hitsound_antispam_time)
 924         {
 925                 sound(NULL, CH_INFO, SND_TYPEHIT, VOL_BASE, ATTN_NONE);
 926                 typehit_time_prev = typehit_time;
 927         }
 928
 929         static float kill_time_prev = 0;
 930         float kill_time = STAT(KILL_TIME);
 931         if (COMPARE_INCREASING(kill_time, kill_time_prev) > autocvar_cl_hitsound_antispam_time)
 932         {
 933                 sound(NULL, CH_INFO, SND_KILL, VOL_BASE, ATTN_NONE);
 934                 kill_time_prev = kill_time;
 935         }
 936 }
 937
 938 vector crosshair_getcolor(entity this, float health_stat)
 939 {
 940         static float rainbow_last_flicker;
 941         static vector rainbow_prev_color;
 942         vector wcross_color = '0 0 0';
 943         switch(autocvar_crosshair_color_special)
 944         {
 945                 case 1: // crosshair_color_per_weapon
 946                 {
 947                         if(this != WEP_Null && hud == HUD_NORMAL)
 948                         {
 949                                 wcross_color = this.wpcolor;
 950                                 break;
 951                         }
 952                         else { goto normalcolor; }
 953                 }
 954
 955                 case 2: // crosshair_color_by_health
 956                 {
 957                         vector v = healtharmor_maxdamage(health_stat, STAT(ARMOR), armorblockpercent, DEATH_WEAPON.m_id);
 958                         float hp = floor(v.x + 1);
 959
 960                         //x = red
 961                         //y = green
 962                         //z = blue
 963
 964                         wcross_color.z = 0;
 965
 966                         if(hp > 200)
 967                         {
 968                                 wcross_color.x = 0;
 969                                 wcross_color.y = 1;
 970                         }
 971                         else if(hp > 150)
 972                         {
 973                                 wcross_color.x = 0.4 - (hp-150)*0.02 * 0.4;
 974                                 wcross_color.y = 0.9 + (hp-150)*0.02 * 0.1;
 975                         }
 976                         else if(hp > 100)
 977                         {
 978                                 wcross_color.x = 1 - (hp-100)*0.02 * 0.6;
 979                                 wcross_color.y = 1 - (hp-100)*0.02 * 0.1;
 980                                 wcross_color.z = 1 - (hp-100)*0.02;
 981                         }
 982                         else if(hp > 50)
 983                         {
 984                                 wcross_color.x = 1;
 985                                 wcross_color.y = 1;
 986                                 wcross_color.z = 0.2 + (hp-50)*0.02 * 0.8;
 987                         }
 988                         else if(hp > 20)
 989                         {
 990                                 wcross_color.x = 1;
 991                                 wcross_color.y = (hp-20)*90/27/100;
 992                                 wcross_color.z = (hp-20)*90/27/100 * 0.2;
 993                         }
 994                         else
 995                         {
 996                                 wcross_color.x = 1;
 997                                 wcross_color.y = 0;
 998                         }
 999                         break;
1000                 }
1001
1002                 case 3: // crosshair_color_rainbow
1003                 {
1004                         if(time >= rainbow_last_flicker)
1005                         {
1006                                 rainbow_prev_color = randomvec() * autocvar_crosshair_color_special_rainbow_brightness;
1007                                 rainbow_last_flicker = time + autocvar_crosshair_color_special_rainbow_delay;
1008                         }
1009                         wcross_color = rainbow_prev_color;
1010                         break;
1011                 }
1012 LABEL(normalcolor)
1013                 default: { wcross_color = stov(autocvar_crosshair_color); break; }
1014         }
1015
1016         return wcross_color;
1017 }
1018
1019 void HUD_Crosshair(entity this)
1020 {
1021         float f, i, j;
1022         vector v;
1023         if(!scoreboard_active && !camera_active && intermission != 2 && !STAT(GAME_STOPPED) &&
1024                 spectatee_status != -1 && (!csqcplayer.viewloc || (!spectatee_status && (csqcplayer.viewloc.spawnflags & VIEWLOC_FREEAIM))) && !MUTATOR_CALLHOOK(DrawCrosshair) &&
1025                 !HUD_MinigameMenu_IsOpened() )
1026         {
1027                 if (!autocvar_crosshair_enabled) // main toggle for crosshair rendering
1028                         return;
1029
1030                 if (spectatee_status > 0 && STAT(CAMERA_SPECTATOR) == 2)
1031                         return;
1032
1033                 if (hud != HUD_NORMAL)
1034                 {
1035                         HUD_Crosshair_Vehicle(this);
1036                         return;
1037                 }
1038
1039                 string wcross_style;
1040                 float wcross_alpha, wcross_resolution;
1041                 wcross_style = autocvar_crosshair;
1042                 if (csqcplayer.viewloc && (csqcplayer.viewloc.spawnflags & VIEWLOC_FREEAIM) && autocvar_crosshair_2d != "")
1043                         wcross_style = autocvar_crosshair_2d;
1044                 if (wcross_style == "0")
1045                         return;
1046                 wcross_resolution = autocvar_crosshair_size;
1047                 if (wcross_resolution == 0)
1048                         return;
1049                 wcross_alpha = autocvar_crosshair_alpha;
1050                 if (wcross_alpha == 0)
1051                         return;
1052
1053                 // TrueAim check
1054                 float shottype;
1055
1056                 // wcross_origin = '0.5 0 0' * vid_conwidth + '0 0.5 0' * vid_conheight;
1057                 if(csqcplayer.viewloc && (csqcplayer.viewloc.spawnflags & VIEWLOC_FREEAIM))
1058                         wcross_origin = viewloc_mousepos;
1059                 else
1060                         wcross_origin = project_3d_to_2d(view_origin + max_shot_distance * view_forward);
1061                 wcross_origin.z = 0;
1062                 if(autocvar_crosshair_hittest)
1063                 {
1064                         vector wcross_oldorigin;
1065                         entity thiswep = viewmodels[0]; // TODO: unhardcode
1066                         wcross_oldorigin = wcross_origin;
1067                         shottype = TrueAimCheck(thiswep);
1068                         if(shottype == SHOTTYPE_HITWORLD)
1069                         {
1070                                 v = wcross_origin - wcross_oldorigin;
1071                                 v.x /= vid_conwidth;
1072                                 v.y /= vid_conheight;
1073                                 if(vdist(v, >, 0.01))
1074                                         shottype = SHOTTYPE_HITOBSTRUCTION;
1075                         }
1076                         if(!autocvar_crosshair_hittest_showimpact)
1077                                 wcross_origin = wcross_oldorigin;
1078                 }
1079                 else
1080                         shottype = SHOTTYPE_HITWORLD;
1081
1082                 vector wcross_color = '0 0 0', wcross_size = '0 0 0';
1083                 string wcross_name = "";
1084                 float wcross_scale, wcross_blur;
1085
1086         entity e = WEP_Null;
1087                 if(autocvar_crosshair_per_weapon || (autocvar_crosshair_color_special == 1))
1088                 {
1089                         entity wepent = viewmodels[0]; // TODO: unhardcode
1090                         e = wepent.switchingweapon;
1091                         if(e)
1092                         {
1093                                 if(autocvar_crosshair_per_weapon)
1094                                 {
1095                                         // WEAPONTODO: access these through some general settings (with non-balance config settings)
1096                                         //wcross_resolution *= cvar(strcat("crosshair_", wcross_wep, "_size"));
1097                                         //if (wcross_resolution == 0)
1098                                                 //return;
1099
1100                                         //wcross_style = cvar_string(strcat("crosshair_", wcross_wep));
1101                                         wcross_resolution *= e.w_crosshair_size;
1102                                         wcross_name = e.w_crosshair;
1103                                 }
1104                         }
1105                 }
1106
1107                 if(wcross_name == "")
1108                         wcross_name = strcat("gfx/crosshair", wcross_style);
1109
1110                 // MAIN CROSSHAIR COLOR DECISION
1111                 wcross_color = crosshair_getcolor(e, STAT(HEALTH));
1112
1113                 if(autocvar_crosshair_effect_scalefade)
1114                 {
1115                         wcross_scale = wcross_resolution;
1116                         wcross_resolution = 1;
1117                 }
1118                 else
1119                 {
1120                         wcross_scale = 1;
1121                 }
1122
1123                 if(autocvar_crosshair_pickup)
1124                 {
1125                         float stat_pickup_time = STAT(LAST_PICKUP);
1126
1127                         if(pickup_crosshair_time < stat_pickup_time)
1128                         {
1129                                 if(time - stat_pickup_time < MAX_TIME_DIFF) // don't trigger the animation if it's too old
1130                                         pickup_crosshair_size = 1;
1131
1132                                 pickup_crosshair_time = stat_pickup_time;
1133                         }
1134
1135                         if(pickup_crosshair_size > 0)
1136                                 pickup_crosshair_size -= autocvar_crosshair_pickup_speed * frametime;
1137                         else
1138                                 pickup_crosshair_size = 0;
1139
1140                         wcross_scale += sin(pickup_crosshair_size) * autocvar_crosshair_pickup;
1141                 }
1142
1143                 // todo: make crosshair hit indication dependent on damage dealt
1144                 if(autocvar_crosshair_hitindication)
1145                 {
1146                         vector hitindication_color = ((autocvar_crosshair_color_special == 1) ? stov(autocvar_crosshair_hitindication_per_weapon_color) : stov(autocvar_crosshair_hitindication_color));
1147
1148                         if(unaccounted_damage)
1149                         {
1150                                 hitindication_crosshair_size = 1;
1151                         }
1152
1153                         if(hitindication_crosshair_size > 0)
1154                                 hitindication_crosshair_size -= autocvar_crosshair_hitindication_speed * frametime;
1155                         else
1156                                 hitindication_crosshair_size = 0;
1157
1158                         wcross_scale += sin(hitindication_crosshair_size) * autocvar_crosshair_hitindication;
1159                         wcross_color.x += sin(hitindication_crosshair_size) * hitindication_color.x;
1160                         wcross_color.y += sin(hitindication_crosshair_size) * hitindication_color.y;
1161                         wcross_color.z += sin(hitindication_crosshair_size) * hitindication_color.z;
1162                 }
1163
1164                 if(shottype == SHOTTYPE_HITENEMY)
1165                         wcross_scale *= autocvar_crosshair_hittest; // is not queried if hittest is 0
1166                 if(shottype == SHOTTYPE_HITTEAM)
1167                         wcross_scale /= autocvar_crosshair_hittest; // is not queried if hittest is 0
1168
1169                 f = fabs(autocvar_crosshair_effect_time);
1170                 if(wcross_scale != wcross_scale_goal_prev || wcross_alpha != wcross_alpha_goal_prev || wcross_color != wcross_color_goal_prev)
1171                 {
1172                         wcross_changedonetime = time + f;
1173                 }
1174                 if(wcross_name != wcross_name_goal_prev || wcross_resolution != wcross_resolution_goal_prev)
1175                 {
1176                         wcross_name_changestarttime = time;
1177                         wcross_name_changedonetime = time + f;
1178                         if(wcross_name_goal_prev_prev)
1179                                 strunzone(wcross_name_goal_prev_prev);
1180                         wcross_name_goal_prev_prev = wcross_name_goal_prev;
1181                         wcross_name_goal_prev = strzone(wcross_name);
1182                         wcross_name_alpha_goal_prev_prev = wcross_name_alpha_goal_prev;
1183                         wcross_resolution_goal_prev_prev = wcross_resolution_goal_prev;
1184                         wcross_resolution_goal_prev = wcross_resolution;
1185                 }
1186
1187                 wcross_scale_goal_prev = wcross_scale;
1188                 wcross_alpha_goal_prev = wcross_alpha;
1189                 wcross_color_goal_prev = wcross_color;
1190
1191                 if(spectatee_status == -1 && shottype == SHOTTYPE_HITTEAM || (shottype == SHOTTYPE_HITOBSTRUCTION && autocvar_crosshair_hittest_blur && !autocvar_chase_active))
1192                 {
1193                         wcross_blur = 1;
1194                         wcross_alpha *= 0.75;
1195                 }
1196                 else
1197                         wcross_blur = 0;
1198                 // *_prev is at time-frametime
1199                 // * is at wcross_changedonetime+f
1200                 // what do we have at time?
1201                 if(time < wcross_changedonetime)
1202                 {
1203                         f = frametime / (wcross_changedonetime - time + frametime);
1204                         wcross_scale = f * wcross_scale + (1 - f) * wcross_scale_prev;
1205                         wcross_alpha = f * wcross_alpha + (1 - f) * wcross_alpha_prev;
1206                         wcross_color = f * wcross_color + (1 - f) * wcross_color_prev;
1207                 }
1208
1209                 wcross_scale_prev = wcross_scale;
1210                 wcross_alpha_prev = wcross_alpha;
1211                 wcross_color_prev = wcross_color;
1212
1213                 MUTATOR_CALLHOOK(UpdateCrosshair);
1214
1215                 wcross_scale *= 1 - autocvar__menu_alpha;
1216                 wcross_alpha *= 1 - autocvar__menu_alpha;
1217                 wcross_size = draw_getimagesize(wcross_name) * wcross_scale;
1218
1219                 if(wcross_scale >= 0.001 && wcross_alpha >= 0.001)
1220                 {
1221                         // crosshair rings for weapon stats
1222                         if (autocvar_crosshair_ring || autocvar_crosshair_ring_reload)
1223                         {
1224                                 // declarations and stats
1225                                 float ring_value = 0, ring_scale = 0, ring_alpha = 0, ring_inner_value = 0, ring_inner_alpha = 0;
1226                                 string ring_image = string_null, ring_inner_image = string_null;
1227                                 vector ring_rgb = '0 0 0', ring_inner_rgb = '0 0 0';
1228
1229                                 ring_scale = autocvar_crosshair_ring_size;
1230
1231                                 entity wepent = viewmodels[0]; // TODO: unhardcode
1232
1233                                 int weapon_clipload = wepent.clip_load;
1234                                 int weapon_clipsize = wepent.clip_size;
1235
1236                                 float arc_heat = wepent.arc_heat_percent;
1237                                 float vcharge = wepent.vortex_charge;
1238                                 float vchargepool = wepent.vortex_chargepool_ammo;
1239                                 float oknex_charge_ = wepent.oknex_charge;
1240                                 float oknex_chargepool_ = wepent.oknex_chargepool_ammo;
1241
1242                                 if(vortex_charge_movingavg == 0) // this should only happen if we have just loaded up the game
1243                                         vortex_charge_movingavg = vcharge;
1244
1245                                 // handle the values
1246                                 if (autocvar_crosshair_ring && wepent.activeweapon == WEP_VORTEX && vcharge && autocvar_crosshair_ring_vortex) // ring around crosshair representing velocity-dependent damage for the vortex
1247                                 {
1248                                         if (vchargepool || use_vortex_chargepool) {
1249                                                 use_vortex_chargepool = 1;
1250                                                 ring_inner_value = vchargepool;
1251                                         } else {
1252                                                 vortex_charge_movingavg = (1 - autocvar_crosshair_ring_vortex_currentcharge_movingavg_rate) * vortex_charge_movingavg + autocvar_crosshair_ring_vortex_currentcharge_movingavg_rate * vcharge;
1253                                                 ring_inner_value = bound(0, autocvar_crosshair_ring_vortex_currentcharge_scale * (vcharge - vortex_charge_movingavg), 1);
1254                                         }
1255
1256                                         ring_inner_alpha = autocvar_crosshair_ring_vortex_inner_alpha;
1257                                         ring_inner_rgb = vec3(autocvar_crosshair_ring_vortex_inner_color_red, autocvar_crosshair_ring_vortex_inner_color_green, autocvar_crosshair_ring_vortex_inner_color_blue);
1258                                         ring_inner_image = "gfx/crosshair_ring_inner.tga";
1259
1260                                         // draw the outer ring to show the current charge of the weapon
1261                                         ring_value = vcharge;
1262                                         ring_alpha = autocvar_crosshair_ring_vortex_alpha;
1263                                         ring_rgb = wcross_color;
1264                                         ring_image = "gfx/crosshair_ring_nexgun.tga";
1265                                 }
1266                                 else if (autocvar_crosshair_ring && (wepent.activeweapon == WEP_OVERKILL_NEX) && oknex_charge_ && autocvar_crosshair_ring_vortex)
1267                                 {
1268                                         if (oknex_chargepool_ || use_vortex_chargepool) {
1269                                                 use_vortex_chargepool = 1;
1270                                                 ring_inner_value = oknex_chargepool_;
1271                                         } else {
1272                                                 vortex_charge_movingavg = (1 - autocvar_crosshair_ring_vortex_currentcharge_movingavg_rate) * vortex_charge_movingavg + autocvar_crosshair_ring_vortex_currentcharge_movingavg_rate * oknex_charge_;
1273                                                 ring_inner_value = bound(0, autocvar_crosshair_ring_vortex_currentcharge_scale * (oknex_charge_ - vortex_charge_movingavg), 1);
1274                                         }
1275
1276                                         ring_inner_alpha = autocvar_crosshair_ring_vortex_inner_alpha;
1277                                         ring_inner_rgb = eX * autocvar_crosshair_ring_vortex_inner_color_red + eY * autocvar_crosshair_ring_vortex_inner_color_green + eZ * autocvar_crosshair_ring_vortex_inner_color_blue;
1278                                         ring_inner_image = "gfx/crosshair_ring_inner.tga";
1279
1280                                         // draw the outer ring to show the current charge of the weapon
1281                                         ring_value = oknex_charge_;
1282                                         ring_alpha = autocvar_crosshair_ring_vortex_alpha;
1283                                         ring_rgb = wcross_color;
1284                                         ring_image = "gfx/crosshair_ring_nexgun.tga";
1285                                 }
1286                                 else if (autocvar_crosshair_ring && wepent.activeweapon == WEP_MINE_LAYER && WEP_CVAR(minelayer, limit) && autocvar_crosshair_ring_minelayer)
1287                                 {
1288                                         ring_value = bound(0, wepent.minelayer_mines / WEP_CVAR(minelayer, limit), 1); // if you later need to use the count of bullets in another place, then add a float for it. For now, no need to.
1289                                         ring_alpha = autocvar_crosshair_ring_minelayer_alpha;
1290                                         ring_rgb = wcross_color;
1291                                         ring_image = "gfx/crosshair_ring.tga";
1292                                 }
1293                                 else if (wepent.activeweapon == WEP_HAGAR && wepent.hagar_load && autocvar_crosshair_ring_hagar)
1294                                 {
1295                                         ring_value = bound(0, wepent.hagar_load / WEP_CVAR_SEC(hagar, load_max), 1);
1296                                         ring_alpha = autocvar_crosshair_ring_hagar_alpha;
1297                                         ring_rgb = wcross_color;
1298                                         ring_image = "gfx/crosshair_ring.tga";
1299                                 }
1300                                 else if(autocvar_crosshair_ring_reload && weapon_clipsize) // forces there to be only an ammo ring
1301                                 {
1302                                         ring_value = bound(0, weapon_clipload / weapon_clipsize, 1);
1303                                         ring_scale = autocvar_crosshair_ring_reload_size;
1304                                         ring_alpha = autocvar_crosshair_ring_reload_alpha;
1305                                         ring_rgb = wcross_color;
1306
1307                                         // Note: This is to stop Taoki from complaining that the image doesn't match all potential balances.
1308                                         // if a new image for another weapon is added, add the code (and its respective file/value) here
1309                                         if ((wepent.activeweapon == WEP_RIFLE) && (weapon_clipsize == 80))
1310                                                 ring_image = "gfx/crosshair_ring_rifle.tga";
1311                                         else
1312                                                 ring_image = "gfx/crosshair_ring.tga";
1313                                 }
1314                                 else if ( autocvar_crosshair_ring && autocvar_crosshair_ring_arc && arc_heat && wepent.activeweapon == WEP_ARC )
1315                                 {
1316                                         ring_value = arc_heat;
1317                                         ring_alpha = (1-arc_heat)*autocvar_crosshair_ring_arc_cold_alpha +
1318                                                 arc_heat*autocvar_crosshair_ring_arc_hot_alpha;
1319                                         ring_rgb = (1-arc_heat)*wcross_color + arc_heat*autocvar_crosshair_ring_arc_hot_color;
1320                                         ring_image = "gfx/crosshair_ring.tga";
1321                                 }
1322
1323                                 // if in weapon switch animation, fade ring out/in
1324                                 if(autocvar_crosshair_effect_time > 0)
1325                                 {
1326                                         f = (time - wcross_name_changestarttime) / autocvar_crosshair_effect_time;
1327                                         if (f >= 1)
1328                                         {
1329                                                 wcross_ring_prev = ((ring_image) ? true : false);
1330                                         }
1331
1332                                         if(wcross_ring_prev)
1333                                         {
1334                                                 if(f < 1)
1335                                                         ring_alpha *= fabs(1 - bound(0, f, 1));
1336                                         }
1337                                         else
1338                                         {
1339                                                 if(f < 1)
1340                                                         ring_alpha *= bound(0, f, 1);
1341                                         }
1342                                 }
1343
1344                                 if (autocvar_crosshair_ring_inner && ring_inner_value) // lets draw a ring inside a ring so you can ring while you ring
1345                                         DrawCircleClippedPic(wcross_origin, wcross_size.x * ring_scale, ring_inner_image, ring_inner_value, ring_inner_rgb, wcross_alpha * ring_inner_alpha, DRAWFLAG_ADDITIVE);
1346
1347                                 if (ring_value)
1348                                         DrawCircleClippedPic(wcross_origin, wcross_size.x * ring_scale, ring_image, ring_value, ring_rgb, wcross_alpha * ring_alpha, DRAWFLAG_ADDITIVE);
1349                         }
1350
1351 #define CROSSHAIR_DO_BLUR(M,sz,wcross_name,wcross_alpha) \
1352                         MACRO_BEGIN { \
1353                                 if(wcross_blur > 0) \
1354                                 { \
1355                                         for(i = -2; i <= 2; ++i) \
1356                                         for(j = -2; j <= 2; ++j) \
1357                                         M(i,j,sz,wcross_name,wcross_alpha*0.04); \
1358                                 } \
1359                                 else \
1360                                 { \
1361                                         M(0,0,sz,wcross_name,wcross_alpha); \
1362                                 } \
1363                         } MACRO_END
1364
1365 #define CROSSHAIR_DRAW_SINGLE(i,j,sz,wcross_name,wcross_alpha) \
1366                         drawpic(wcross_origin - ('0.5 0 0' * (sz * wcross_size.x + i * wcross_blur) + '0 0.5 0' * (sz * wcross_size.y + j * wcross_blur)), wcross_name, sz * wcross_size, wcross_color, wcross_alpha, DRAWFLAG_NORMAL)
1367
1368 #define CROSSHAIR_DRAW(sz,wcross_name,wcross_alpha) \
1369                         CROSSHAIR_DO_BLUR(CROSSHAIR_DRAW_SINGLE,sz,wcross_name,wcross_alpha)
1370
1371                         if(time < wcross_name_changedonetime && wcross_name != wcross_name_goal_prev_prev && wcross_name_goal_prev_prev)
1372                         {
1373                                 f = (wcross_name_changedonetime - time) / (wcross_name_changedonetime - wcross_name_changestarttime);
1374                                 wcross_size = draw_getimagesize(wcross_name_goal_prev_prev) * wcross_scale;
1375                                 CROSSHAIR_DRAW(wcross_resolution_goal_prev_prev, wcross_name_goal_prev_prev, wcross_alpha * f * wcross_name_alpha_goal_prev_prev);
1376                                 f = 1 - f;
1377                         }
1378                         else
1379                         {
1380                                 f = 1;
1381                         }
1382                         wcross_name_alpha_goal_prev = f;
1383
1384                         wcross_size = draw_getimagesize(wcross_name) * wcross_scale;
1385                         CROSSHAIR_DRAW(wcross_resolution, wcross_name, wcross_alpha * f);
1386
1387                         if(autocvar_crosshair_dot)
1388                         {
1389                                 vector wcross_color_old;
1390                                 wcross_color_old = wcross_color;
1391
1392                                 if((autocvar_crosshair_dot_color_custom) && (autocvar_crosshair_dot_color != "0"))
1393                                         wcross_color = stov(autocvar_crosshair_dot_color);
1394
1395                                 CROSSHAIR_DRAW(wcross_resolution * autocvar_crosshair_dot_size, "gfx/crosshairdot.tga", f * autocvar_crosshair_dot_alpha);
1396                                 // FIXME why don't we use wcross_alpha here?
1397                                 wcross_color = wcross_color_old;
1398                         }
1399                 }
1400         }
1401         else
1402         {
1403                 wcross_scale_prev = 0;
1404                 wcross_alpha_prev = 0;
1405                 wcross_scale_goal_prev = 0;
1406                 wcross_alpha_goal_prev = 0;
1407                 wcross_changedonetime = 0;
1408                 strfree(wcross_name_goal_prev);
1409                 strfree(wcross_name_goal_prev_prev);
1410                 wcross_name_changestarttime = 0;
1411                 wcross_name_changedonetime = 0;
1412                 wcross_name_alpha_goal_prev = 0;
1413                 wcross_name_alpha_goal_prev_prev = 0;
1414                 wcross_resolution_goal_prev = 0;
1415                 wcross_resolution_goal_prev_prev = 0;
1416         }
1417 }
1418
1419 const int MAX_SPECIALCOMMAND = 15;
1420 vector specialcommand_slots[MAX_SPECIALCOMMAND];
1421 vector specialcommand_colors[MAX_SPECIALCOMMAND];
1422 const float SPECIALCOMMAND_SPEED = 150;
1423 const float SPECIALCOMMAND_TURNSPEED = 2;
1424 const float SPECIALCOMMAND_SIZE = 0.025;
1425 const float SPECIALCOMMAND_CHANCE = 0.35;
1426 float sc_spawntime, sc_changetime;
1427 vector sc_color = '1 1 1';
1428 void SpecialCommand()
1429 {
1430         if(!STAT(MOVEVARS_SPECIALCOMMAND))
1431                 return;
1432
1433         if(time >= sc_changetime)
1434         {
1435                 sc_changetime = time + 1;
1436                 sc_color = randomvec() * 1.5;
1437                 sc_color.x = bound(0.2, sc_color.x, 0.75);
1438                 sc_color.y = bound(0.2, sc_color.y, 0.75);
1439                 sc_color.z = bound(0.2, sc_color.z, 0.75);
1440         }
1441         drawfill('0 0 0', vec2(vid_conwidth, vid_conheight), sc_color, autocvar_hud_colorflash_alpha * bound(0.1, sc_changetime - time, 0.3), DRAWFLAG_ADDITIVE);
1442
1443         if(!precache_pic("gfx/smile"))
1444                 return; // damn party poopers
1445
1446         for(int j = MAX_SPECIALCOMMAND - 1; j >= 0; --j)
1447         {
1448                 vector slot = specialcommand_slots[j];
1449                 if(slot.y)
1450                         slot.y += SPECIALCOMMAND_SPEED * frametime;
1451                 //if(slot.z)
1452                         //slot.z = sin(SPECIALCOMMAND_TURNSPEED * M_PI * time);
1453                 if(slot.y >= vid_conheight)
1454                         slot = '0 0 0';
1455
1456                 if(slot == '0 0 0')
1457                 {
1458                         if(random() <= SPECIALCOMMAND_CHANCE && time > sc_spawntime) // low chance to spawn!
1459                         {
1460                                 slot.x = bound(0, (random() * vid_conwidth + 1), vid_conwidth);
1461                                 slot.y = 1; // start it off 0 so we can use it
1462                                 slot.z = floor(random() * Weapons_MAX);
1463                                 sc_spawntime = time + bound(0.4, random(), 0.75); // prevent spawning another one for this amount of time!
1464                                 vector newcolor = randomvec() * 2;
1465                                 newcolor.x = bound(0.4, newcolor.x, 1);
1466                                 newcolor.y = bound(0.4, newcolor.y, 1);
1467                                 newcolor.z = bound(0.4, newcolor.z, 1);
1468                                 specialcommand_colors[j] = newcolor;
1469                         }
1470                 }
1471                 else
1472                 {
1473                         vector splash_size = '0 0 0';
1474                         splash_size.x = max(vid_conwidth, vid_conheight) * SPECIALCOMMAND_SIZE;
1475                         splash_size.y = max(vid_conwidth, vid_conheight) * SPECIALCOMMAND_SIZE;
1476                         entity wep = Weapons_from(slot.z);
1477                         if(wep == WEP_Null)
1478                                 drawpic(vec2(slot), "gfx/smile", vec2(splash_size), specialcommand_colors[j], 0.95, DRAWFLAG_NORMAL);
1479                         else
1480                                 drawpic_skin(vec2(slot), wep.model2, vec2(splash_size), specialcommand_colors[j], 0.95, DRAWFLAG_NORMAL);
1481                         //drawrotpic(vec2(slot), slot.z, "gfx/smile", vec2(splash_size), vec2(splash_size) / 2, specialcommand_colors[j], 0.95, DRAWFLAG_NORMAL);
1482                 }
1483
1484                 specialcommand_slots[j] = slot;
1485         }
1486 }
1487
1488 void HUD_Draw(entity this)
1489 {
1490         // if we don't know gametype and scores yet avoid drawing the scoreboard
1491         // also in the very first frames, player state may be inconsistent so avoid drawing the hud at all
1492         // e.g. since initial player's health is 0 hud would display the hud_damage effect,
1493         // cl_deathscoreboard would show the scoreboard and so on
1494         if(!gametype)
1495                 return;
1496
1497         Hud_Dynamic_Frame();
1498
1499         if(!intermission)
1500         if (MUTATOR_CALLHOOK(HUD_Draw_overlay))
1501         {
1502                 drawfill('0 0 0', vec2(vid_conwidth, vid_conheight), M_ARGV(0, vector), autocvar_hud_colorflash_alpha * M_ARGV(1, float), DRAWFLAG_ADDITIVE);
1503         }
1504         else if(STAT(FROZEN))
1505         {
1506                 vector col = '0.25 0.90 1';
1507                 if(STAT(REVIVE_PROGRESS))
1508                         col += vec3(STAT(REVIVE_PROGRESS), -STAT(REVIVE_PROGRESS), -STAT(REVIVE_PROGRESS));
1509                 drawfill('0 0 0', vec2(vid_conwidth, vid_conheight), col, autocvar_hud_colorflash_alpha, DRAWFLAG_ADDITIVE);
1510         }
1511
1512         HUD_Scale_Enable();
1513         if(!intermission)
1514         if(STAT(NADE_TIMER) && autocvar_cl_nade_timer) // give nade top priority, as it's a matter of life and death
1515         {
1516                 vector col = '0.25 0.90 1' + vec3(STAT(NADE_TIMER), -STAT(NADE_TIMER), -STAT(NADE_TIMER));
1517                 DrawCircleClippedPic(vec2(0.5 * vid_conwidth, 0.6 * vid_conheight), 0.1 * vid_conheight, "gfx/crosshair_ring.tga", STAT(NADE_TIMER), col, autocvar_hud_colorflash_alpha, DRAWFLAG_ADDITIVE);
1518                 drawstring_aspect(eY * 0.64 * vid_conheight, ((autocvar_cl_nade_timer == 2) ? _("Nade timer") : ""), vec2(vid_conwidth, 0.025 * vid_conheight), '1 1 1', 1, DRAWFLAG_NORMAL);
1519         }
1520         else if(STAT(CAPTURE_PROGRESS))
1521         {
1522                 DrawCircleClippedPic(vec2(0.5 * vid_conwidth, 0.6 * vid_conheight), 0.1 * vid_conheight, "gfx/crosshair_ring.tga", STAT(CAPTURE_PROGRESS), '0.25 0.90 1', autocvar_hud_colorflash_alpha, DRAWFLAG_ADDITIVE);
1523                 drawstring_aspect(eY * 0.64 * vid_conheight, _("Capture progress"), vec2(vid_conwidth, 0.025 * vid_conheight), '1 1 1', 1, DRAWFLAG_NORMAL);
1524         }
1525         else if(STAT(REVIVE_PROGRESS))
1526         {
1527                 DrawCircleClippedPic(vec2(0.5 * vid_conwidth, 0.6 * vid_conheight), 0.1 * vid_conheight, "gfx/crosshair_ring.tga", STAT(REVIVE_PROGRESS), '0.25 0.90 1', autocvar_hud_colorflash_alpha, DRAWFLAG_ADDITIVE);
1528                 drawstring_aspect(eY * 0.64 * vid_conheight, _("Revival progress"), vec2(vid_conwidth, 0.025 * vid_conheight), '1 1 1', 1, DRAWFLAG_NORMAL);
1529         }
1530         HUD_Scale_Disable();
1531
1532         if(autocvar_r_letterbox == 0)
1533                 if(autocvar_viewsize < 120)
1534                 {
1535                         if(!(gametype == MAPINFO_TYPE_RACE || gametype == MAPINFO_TYPE_CTS))
1536                                 Accuracy_LoadLevels();
1537
1538                         HUD_Main();
1539                         HUD_Scale_Disable();
1540                 }
1541
1542         // crosshair goes VERY LAST
1543         SpecialCommand();
1544         UpdateDamage();
1545         HUD_Crosshair(this);
1546         HitSound();
1547 }
1548
1549 void ViewLocation_Mouse()
1550 {
1551         if(spectatee_status)
1552                 return; // don't draw it as spectator!
1553
1554         viewloc_mousepos += getmousepos() * autocvar_menu_mouse_speed;
1555         viewloc_mousepos.x = bound(0, viewloc_mousepos.x, vid_conwidth);
1556         viewloc_mousepos.y = bound(0, viewloc_mousepos.y, vid_conheight);
1557
1558         //float cursor_alpha = 1 - autocvar__menu_alpha;
1559         //draw_cursor(viewloc_mousepos, '0.5 0.5 0', "/cursor_move", '1 1 1', cursor_alpha);
1560 }
1561
1562 bool ov_enabled;
1563 float oldr_nearclip;
1564 float oldr_farclip_base;
1565 float oldr_farclip_world;
1566 float oldr_novis;
1567 float oldr_useportalculling;
1568 float oldr_useinfinitefarclip;
1569
1570 float prev_myteam;
1571 int lasthud;
1572 float vh_notice_time;
1573 void CSQC_UpdateView(entity this, float w, float h)
1574 {
1575         TC(int, w); TC(int, h);
1576         entity e;
1577         float fov;
1578         float f;
1579         vector vf_size, vf_min;
1580         float a;
1581
1582         execute_next_frame();
1583
1584         ++framecount;
1585
1586         stats_get();
1587         hud = STAT(HUD);
1588
1589         if(hud != HUD_NORMAL && lasthud == HUD_NORMAL)
1590                 vh_notice_time = time + autocvar_cl_vehicles_notify_time;
1591
1592         lasthud = hud;
1593
1594         HUD_Scale_Disable();
1595
1596         if(autocvar__hud_showbinds_reload) // menu can set this one
1597         {
1598                 db_close(binddb);
1599                 binddb = db_create();
1600                 cvar_set("_hud_showbinds_reload", "0");
1601         }
1602
1603         if(checkextension("DP_CSQC_MINFPS_QUALITY"))
1604                 view_quality = getproperty(VF_MINFPS_QUALITY);
1605         else
1606                 view_quality = 1;
1607
1608         button_attack2 = PHYS_INPUT_BUTTON_ATCK2(this);
1609         button_zoom = PHYS_INPUT_BUTTON_ZOOM(this);
1610
1611         vf_size = getpropertyvec(VF_SIZE);
1612         vf_min = getpropertyvec(VF_MIN);
1613         vid_width = vf_size.x;
1614         vid_height = vf_size.y;
1615
1616         vector reticle_pos = '0 0 0', reticle_size = '0 0 0';
1617         vector splash_pos = '0 0 0', splash_size = '0 0 0';
1618
1619         WaypointSprite_Load();
1620
1621         CSQCPlayer_SetCamera();
1622
1623         if(player_localentnum <= maxclients) // is it a client?
1624                 current_player = player_localentnum - 1;
1625         else // then player_localentnum is the vehicle I'm driving
1626                 current_player = player_localnum;
1627         myteam = entcs_GetTeam(current_player);
1628
1629         if(myteam != prev_myteam)
1630         {
1631                 myteamcolors = colormapPaletteColor(myteam, 1);
1632                 FOREACH(hud_panels, true, it.update_time = time);
1633                 prev_myteam = myteam;
1634         }
1635
1636         ticrate = STAT(MOVEVARS_TICRATE) * STAT(MOVEVARS_TIMESCALE);
1637
1638         float is_dead = (STAT(HEALTH) <= 0);
1639
1640         // FIXME do we need this hack?
1641         if(isdemo())
1642         {
1643                 // in demos, input_buttons do not work
1644                 button_zoom = (autocvar__togglezoom == "-");
1645         }
1646         else if(button_zoom
1647                 && autocvar_cl_unpress_zoom_on_death
1648                 && (spectatee_status >= 0)
1649                 && (is_dead || intermission))
1650         {
1651                 // no zoom while dead or in intermission please
1652                 localcmd("-zoom\n");
1653                 button_zoom = false;
1654         }
1655
1656         // abused multiple places below
1657         entity local_player = ((csqcplayer) ? csqcplayer : CSQCModel_server2csqc(player_localentnum - 1));
1658         if(!local_player)
1659                 local_player = this; // fall back!
1660
1661         // event chase camera
1662         if(autocvar_chase_active <= 0) // greater than 0 means it's enabled manually, and this code is skipped
1663         {
1664                 if(STAT(CAMERA_SPECTATOR))
1665                 {
1666                         if(spectatee_status > 0)
1667                         {
1668                                 if(!autocvar_chase_active)
1669                                 {
1670                                         cvar_set("chase_active", "-2");
1671                                         goto skip_eventchase_death;
1672                                 }
1673                         }
1674                         else if(autocvar_chase_active == -2)
1675                                 cvar_set("chase_active", "0");
1676
1677                         if(autocvar_chase_active == -2)
1678                                 goto skip_eventchase_death;
1679                 }
1680                 else if(autocvar_chase_active == -2)
1681                         cvar_set("chase_active", "0");
1682
1683                 float vehicle_chase = (hud != HUD_NORMAL && (autocvar_cl_eventchase_vehicle || spectatee_status > 0));
1684
1685                 float vehicle_viewdist = 0;
1686                 vector vehicle_viewofs = '0 0 0';
1687
1688                 if(vehicle_chase)
1689                 {
1690                         if(hud != HUD_BUMBLEBEE_GUN)
1691                         {
1692                                 Vehicle info = Vehicles_from(hud);
1693                                 vehicle_viewdist = info.height;
1694                                 vehicle_viewofs = info.view_ofs;
1695                         }
1696                 }
1697
1698                 if(WantEventchase(this))
1699                 {
1700                         vector current_view_origin_override = '0 0 0';
1701                         vector view_offset_override = '0 0 0';
1702                         float chase_distance_override = 0;
1703                         bool custom_eventchase = MUTATOR_CALLHOOK(CustomizeEventchase, this);
1704                         if(custom_eventchase)
1705                         {
1706                                 current_view_origin_override = M_ARGV(0, vector);
1707                                 view_offset_override = M_ARGV(1, vector);
1708                                 chase_distance_override = M_ARGV(0, float);
1709                         }
1710                         eventchase_running = true;
1711
1712                         // make special vector since we can't use view_origin (It is one frame old as of this code, it gets set later with the results this code makes.)
1713                         vector current_view_origin = (csqcplayer ? csqcplayer.origin : pmove_org);
1714                         if (custom_eventchase)
1715                                 current_view_origin = current_view_origin_override;
1716
1717                         // detect maximum viewoffset and use it
1718                         vector view_offset = autocvar_cl_eventchase_viewoffset;
1719                         if(vehicle_chase)
1720                         {
1721                                 if(vehicle_viewofs)
1722                                         view_offset = vehicle_viewofs;
1723                                 else
1724                                         view_offset = autocvar_cl_eventchase_vehicle_viewoffset;
1725                         }
1726                         if (custom_eventchase)
1727                                 view_offset = view_offset_override;
1728
1729                         if(view_offset)
1730                         {
1731                                 WarpZone_TraceLine(current_view_origin, current_view_origin + view_offset + ('0 0 1' * autocvar_cl_eventchase_maxs.z), MOVE_WORLDONLY, this);
1732                                 if(trace_fraction == 1) { current_view_origin += view_offset; }
1733                                 else { current_view_origin.z += max(0, (trace_endpos.z - current_view_origin.z) - autocvar_cl_eventchase_maxs.z); }
1734                         }
1735
1736                         // We must enable chase_active to get a third person view (weapon viewmodel hidden and own player model showing).
1737                         // Ideally, there should be another way to enable third person cameras, such as through setproperty()
1738                         // -1 enables chase_active while marking it as set by this code, and not by the user (which would be 1)
1739                         if(!autocvar_chase_active) { cvar_set("chase_active", "-1"); }
1740
1741                         // make the camera smooth back
1742                         float chase_distance = autocvar_cl_eventchase_distance;
1743                         if(vehicle_chase)
1744                         {
1745                                 if(vehicle_viewofs)
1746                                         chase_distance = vehicle_viewdist;
1747                                 else
1748                                         chase_distance = autocvar_cl_eventchase_vehicle_distance;
1749                         }
1750                         if (custom_eventchase)
1751                                 chase_distance = chase_distance_override;
1752
1753                         if(autocvar_cl_eventchase_speed && eventchase_current_distance < chase_distance)
1754                                 eventchase_current_distance += autocvar_cl_eventchase_speed * (chase_distance - eventchase_current_distance) * frametime; // slow down the further we get
1755                         else if(eventchase_current_distance != chase_distance)
1756                                 eventchase_current_distance = chase_distance;
1757
1758                         makevectors(view_angles);
1759
1760                         vector eventchase_target_origin = (current_view_origin - (v_forward * eventchase_current_distance));
1761                         WarpZone_TraceBox(current_view_origin, autocvar_cl_eventchase_mins, autocvar_cl_eventchase_maxs, eventchase_target_origin, MOVE_WORLDONLY, this);
1762
1763                         // If the boxtrace fails, revert back to line tracing.
1764                         if(!local_player.viewloc)
1765                         if(trace_startsolid)
1766                         {
1767                                 eventchase_target_origin = (current_view_origin - (v_forward * eventchase_current_distance));
1768                                 WarpZone_TraceLine(current_view_origin, eventchase_target_origin, MOVE_WORLDONLY, this);
1769                                 setproperty(VF_ORIGIN, (trace_endpos - (v_forward * autocvar_cl_eventchase_mins.z)));
1770                         }
1771                         else { setproperty(VF_ORIGIN, trace_endpos); }
1772
1773                         if(!local_player.viewloc)
1774                                 setproperty(VF_ANGLES, WarpZone_TransformVAngles(WarpZone_trace_transform, view_angles));
1775                 }
1776                 else if(autocvar_chase_active < 0) // time to disable chase_active if it was set by this code
1777                 {
1778                         eventchase_running = false;
1779                         cvar_set("chase_active", "0");
1780                         eventchase_current_distance = 0; // start from 0 next time
1781                 }
1782         }
1783         // workaround for camera stuck between player's legs when using chase_active 1
1784         // because the engine stops updating the chase_active camera when the game ends
1785         else if(intermission)
1786         {
1787                 cvar_settemp("chase_active", "-1");
1788                 eventchase_current_distance = 0;
1789         }
1790
1791         LABEL(skip_eventchase_death);
1792
1793         // do lockview after event chase camera so that it still applies whenever necessary.
1794         if(autocvar_cl_lockview || (!autocvar_hud_cursormode && (autocvar__hud_configure && spectatee_status <= 0 || intermission > 1 || QuickMenu_IsOpened())))
1795         {
1796                 setproperty(VF_ORIGIN, freeze_org);
1797                 setproperty(VF_ANGLES, freeze_ang);
1798         }
1799         else
1800         {
1801                 freeze_org = getpropertyvec(VF_ORIGIN);
1802                 freeze_ang = getpropertyvec(VF_ANGLES);
1803         }
1804
1805         WarpZone_FixView();
1806         //WarpZone_FixPMove();
1807
1808         vector ov_org = '0 0 0';
1809         vector ov_mid = '0 0 0';
1810         vector ov_worldmin = '0 0 0';
1811         vector ov_worldmax = '0 0 0';
1812         if(autocvar_cl_orthoview)
1813         {
1814                 ov_worldmin = mi_picmin;
1815                 ov_worldmax = mi_picmax;
1816
1817                 float ov_width = (ov_worldmax.x - ov_worldmin.x);
1818                 float ov_height = (ov_worldmax.y - ov_worldmin.y);
1819                 float ov_distance = (max(vid_width, vid_height) * max(ov_width, ov_height));
1820
1821                 ov_mid = ((ov_worldmax + ov_worldmin) * 0.5);
1822                 ov_org = vec3(ov_mid.x, ov_mid.y, (ov_mid.z + ov_distance));
1823
1824                 float ov_nearest = vlen(ov_org - vec3(
1825                         bound(ov_worldmin.x, ov_org.x, ov_worldmax.x),
1826                         bound(ov_worldmin.y, ov_org.y, ov_worldmax.y),
1827                         bound(ov_worldmin.z, ov_org.z, ov_worldmax.z)
1828                 ));
1829
1830                 float ov_furthest = 0;
1831                 float dist = 0;
1832
1833                 if((dist = vdist((vec3(ov_worldmin.x, ov_worldmin.y, ov_worldmin.z) - ov_org), >, ov_furthest))) { ov_furthest = dist; }
1834                 if((dist = vdist((vec3(ov_worldmax.x, ov_worldmin.y, ov_worldmin.z) - ov_org), >, ov_furthest))) { ov_furthest = dist; }
1835                 if((dist = vdist((vec3(ov_worldmin.x, ov_worldmax.y, ov_worldmin.z) - ov_org), >, ov_furthest))) { ov_furthest = dist; }
1836                 if((dist = vdist((vec3(ov_worldmin.x, ov_worldmin.y, ov_worldmax.z) - ov_org), >, ov_furthest))) { ov_furthest = dist; }
1837                 if((dist = vdist((vec3(ov_worldmax.x, ov_worldmax.y, ov_worldmin.z) - ov_org), >, ov_furthest))) { ov_furthest = dist; }
1838                 if((dist = vdist((vec3(ov_worldmin.x, ov_worldmax.y, ov_worldmax.z) - ov_org), >, ov_furthest))) { ov_furthest = dist; }
1839                 if((dist = vdist((vec3(ov_worldmax.x, ov_worldmin.y, ov_worldmax.z) - ov_org), >, ov_furthest))) { ov_furthest = dist; }
1840                 if((dist = vdist((vec3(ov_worldmax.x, ov_worldmax.y, ov_worldmax.z) - ov_org), >, ov_furthest))) { ov_furthest = dist; }
1841
1842                 if(!ov_enabled)
1843                 {
1844                         oldr_nearclip = cvar("r_nearclip");
1845                         oldr_farclip_base = cvar("r_farclip_base");
1846                         oldr_farclip_world = cvar("r_farclip_world");
1847                         oldr_novis = cvar("r_novis");
1848                         oldr_useportalculling = cvar("r_useportalculling");
1849                         oldr_useinfinitefarclip = cvar("r_useinfinitefarclip");
1850                 }
1851
1852                 cvar_settemp("r_nearclip", ftos(ov_nearest));
1853                 cvar_settemp("r_farclip_base", ftos(ov_furthest));
1854                 cvar_settemp("r_farclip_world", "0");
1855                 cvar_settemp("r_novis", "1");
1856                 cvar_settemp("r_useportalculling", "0");
1857                 cvar_settemp("r_useinfinitefarclip", "0");
1858
1859                 setproperty(VF_ORIGIN, ov_org);
1860                 setproperty(VF_ANGLES, '90 0 0');
1861
1862                 ov_enabled = true;
1863
1864                 #if 0
1865                 LOG_INFOF("OrthoView: org = %s, angles = %s, distance = %f, nearest = %f, furthest = %f",
1866                         vtos(ov_org),
1867                         vtos(getpropertyvec(VF_ANGLES)),
1868                         ov_distance,
1869                         ov_nearest,
1870                         ov_furthest);
1871                 #endif
1872         }
1873         else
1874         {
1875                 if(ov_enabled)
1876                 {
1877                         cvar_set("r_nearclip", ftos(oldr_nearclip));
1878                         cvar_set("r_farclip_base", ftos(oldr_farclip_base));
1879                         cvar_set("r_farclip_world", ftos(oldr_farclip_world));
1880                         cvar_set("r_novis", ftos(oldr_novis));
1881                         cvar_set("r_useportalculling", ftos(oldr_useportalculling));
1882                         cvar_set("r_useinfinitefarclip", ftos(oldr_useinfinitefarclip));
1883                 }
1884                 ov_enabled = false;
1885         }
1886
1887         // run viewmodel_draw before updating view_angles to the angles calculated by WarpZone_FixView
1888         // viewmodel_draw needs to use the view_angles set by the engine on every CSQC_UpdateView call
1889         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
1890                 viewmodel_draw(viewmodels[slot]);
1891
1892         // Render the Scene
1893         view_origin = getpropertyvec(VF_ORIGIN);
1894         view_angles = getpropertyvec(VF_ANGLES);
1895         makevectors(view_angles);
1896         view_forward = v_forward;
1897         view_right = v_right;
1898         view_up = v_up;
1899
1900 #ifdef BLURTEST
1901         if(time > blurtest_time0 && time < blurtest_time1)
1902         {
1903                 float r, t;
1904
1905                 t = (time - blurtest_time0) / (blurtest_time1 - blurtest_time0);
1906                 r = t * blurtest_radius;
1907                 f = 1 / (t ** blurtest_power) - 1;
1908
1909                 cvar_set("r_glsl_postprocess", "1");
1910                 cvar_set("r_glsl_postprocess_uservec1", strcat(ftos(r), " ", ftos(f), " 0 0"));
1911         }
1912         else
1913         {
1914                 cvar_set("r_glsl_postprocess", "0");
1915                 cvar_set("r_glsl_postprocess_uservec1", "0 0 0 0");
1916         }
1917 #endif
1918
1919         TargetMusic_Advance();
1920         Fog_Force();
1921         fpscounter_update();
1922
1923         if(drawtime == 0)
1924                 drawframetime = 0.01666667; // when we don't know fps yet, we assume 60fps
1925         else
1926                 drawframetime = bound(0.000001, time - drawtime, 1);
1927         drawtime = time;
1928
1929         // watch for gametype changes here...
1930         // in ParseStuffCMD the cmd isn't executed yet :/
1931         // might even be better to add the gametype to TE_CSQC_INIT...?
1932         if(!postinit)
1933                 PostInit();
1934
1935         if(intermission && !intermission_time)
1936                 intermission_time = time;
1937
1938         if(intermission && !isdemo() && !(calledhooks & HOOK_END))
1939         {
1940                 if(calledhooks & HOOK_START)
1941                 {
1942                         localcmd("\ncl_hook_gameend\n");
1943                         calledhooks |= HOOK_END;
1944                 }
1945         }
1946
1947         Announcer();
1948
1949         fov = autocvar_fov;
1950         if(fov <= 59.5)
1951         {
1952                 if(!zoomscript_caught)
1953                 {
1954                         localcmd("+button9\n");
1955                         zoomscript_caught = 1;
1956                 }
1957         }
1958         else
1959         {
1960                 if(zoomscript_caught)
1961                 {
1962                         localcmd("-button9\n");
1963                         zoomscript_caught = 0;
1964                 }
1965         }
1966
1967         ColorTranslateMode = autocvar_cl_stripcolorcodes;
1968
1969         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
1970         {
1971                 entity wepent = viewmodels[slot];
1972
1973                 if(wepent.last_switchweapon != wepent.switchweapon)
1974                 {
1975                         weapontime = time;
1976                         wepent.last_switchweapon = wepent.switchweapon;
1977                         if(slot == 0 && button_zoom && autocvar_cl_unpress_zoom_on_weapon_switch)
1978                         {
1979                                 localcmd("-zoom\n");
1980                                 button_zoom = false;
1981                         }
1982                         if(slot == 0 && autocvar_cl_unpress_attack_on_weapon_switch)
1983                         {
1984                                 localcmd("-fire\n");
1985                                 localcmd("-fire2\n");
1986                                 button_attack2 = false;
1987                         }
1988                 }
1989                 if(wepent.last_activeweapon != wepent.activeweapon)
1990                 {
1991                         wepent.last_activeweapon = wepent.activeweapon;
1992
1993                         e = wepent.activeweapon;
1994                         if(e.netname != "")
1995                                 localcmd(strcat("\ncl_hook_activeweapon ", e.netname), "\n");
1996                         else if(slot == 0)
1997                                 localcmd("\ncl_hook_activeweapon none\n");
1998                 }
1999         }
2000
2001         // ALWAYS Clear Current Scene First
2002         clearscene();
2003
2004         setproperty(VF_ORIGIN, view_origin);
2005         setproperty(VF_ANGLES, view_angles);
2006
2007         // FIXME engine bug? VF_SIZE and VF_MIN are not restored to sensible values by this
2008         setproperty(VF_SIZE, vf_size);
2009         setproperty(VF_MIN, vf_min);
2010
2011         // Assign Standard Viewflags
2012         // Draw the World (and sky)
2013         setproperty(VF_DRAWWORLD, 1);
2014
2015         // Set the console size vars
2016         vid_conwidth = autocvar_vid_conwidth;
2017         vid_conheight = autocvar_vid_conheight;
2018         vid_pixelheight = autocvar_vid_pixelheight;
2019
2020         if(autocvar_cl_orthoview) { setproperty(VF_FOV, GetOrthoviewFOV(ov_worldmin, ov_worldmax, ov_mid, ov_org)); }
2021         else if(csqcplayer.viewloc) { setproperty(VF_FOV, GetViewLocationFOV(110)); } // enforce 110 fov, so things dont look odd
2022         else { setproperty(VF_FOV, GetCurrentFov(fov)); }
2023
2024         if(camera_active) // Camera for demo playback
2025         {
2026                 if(autocvar_camera_enable)
2027                         CSQC_Demo_Camera();
2028                 else
2029                 {
2030                         cvar_set("chase_active", ftos(chase_active_backup));
2031                         cvar_set("cl_demo_mousegrab", "0");
2032                         camera_active = false;
2033                 }
2034         }
2035         else
2036         {
2037 #ifdef CAMERATEST
2038                 if(autocvar_camera_enable)
2039 #else
2040                 if(autocvar_camera_enable && isdemo())
2041 #endif
2042                 {
2043                         // Enable required Darkplaces cvars
2044                         chase_active_backup = autocvar_chase_active;
2045                         cvar_set("chase_active", "2");
2046                         cvar_set("cl_demo_mousegrab", "1");
2047                         camera_active = true;
2048                         camera_mode = false;
2049                 }
2050         }
2051
2052         // Draw the Crosshair
2053         setproperty(VF_DRAWCROSSHAIR, 0); //Make sure engine crosshairs are always hidden
2054
2055         // Draw the Engine Status Bar (the default Quake HUD)
2056         setproperty(VF_DRAWENGINESBAR, 0);
2057
2058         // Update the mouse position
2059         /*
2060            mousepos_x = vid_conwidth;
2061            mousepos_y = vid_conheight;
2062            mousepos = mousepos*0.5 + getmousepos();
2063          */
2064
2065         IL_EACH(g_drawables, it.draw, it.draw(it));
2066
2067         addentities(MASK_NORMAL | MASK_ENGINE | MASK_ENGINEVIEWMODELS); // TODO: .health is used in cl_deathfade (a feature we have turned off currently)
2068         renderscene();
2069
2070         // now switch to 2D drawing mode by calling a 2D drawing function
2071         // then polygon drawing will draw as 2D stuff, and NOT get queued until the
2072         // next R_RenderScene call
2073         drawstring('0 0 0', "", '1 1 0', '1 1 1', 0, 0);
2074
2075         if(autocvar_r_fakelight >= 2 || autocvar_r_fullbright)
2076         if (!(serverflags & SERVERFLAG_ALLOW_FULLBRIGHT))
2077         {
2078                 // apply night vision effect
2079                 vector tc_00, tc_01, tc_10, tc_11;
2080                 vector rgb = '0 0 0';
2081
2082                 if(!nightvision_noise)
2083                 {
2084                         nightvision_noise = new(nightvision_noise);
2085                 }
2086                 if(!nightvision_noise2)
2087                 {
2088                         nightvision_noise2 = new(nightvision_noise2);
2089                 }
2090
2091                 // color tint in yellow
2092                 drawfill('0 0 0', autocvar_vid_conwidth * '1 0 0' + autocvar_vid_conheight * '0 1 0', '0.5 1 0.3', 1, DRAWFLAG_MODULATE);
2093
2094                 // draw BG
2095                 a = Noise_Pink(nightvision_noise, frametime * 1.5) * 0.05 + 0.15;
2096                 rgb = '1 1 1';
2097                 tc_00 = '0 0 0' + '0.2 0 0' * sin(time * 0.3) + '0 0.3 0' * cos(time * 0.7);
2098                 tc_01 = '0 2.25 0' + '0.6 0 0' * cos(time * 1.2) - '0 0.3 0' * sin(time * 2.2);
2099                 tc_10 = '1.5 0 0' - '0.2 0 0' * sin(time * 0.5) + '0 0.5 0' * cos(time * 1.7);
2100                 //tc_11 = '1 1 0' + '0.6 0 0' * sin(time * 0.6) + '0 0.3 0' * cos(time * 0.1);
2101                 tc_11 = tc_01 + tc_10 - tc_00;
2102                 R_BeginPolygon("gfx/nightvision-bg.tga", DRAWFLAG_ADDITIVE);
2103                 R_PolygonVertex('0 0 0', tc_00, rgb, a);
2104                 R_PolygonVertex(autocvar_vid_conwidth * '1 0 0', tc_10, rgb, a);
2105                 R_PolygonVertex(autocvar_vid_conwidth * '1 0 0' + autocvar_vid_conheight * '0 1 0', tc_11, rgb, a);
2106                 R_PolygonVertex(autocvar_vid_conheight * '0 1 0', tc_01, rgb, a);
2107                 R_EndPolygon();
2108
2109                 // draw FG
2110                 a = Noise_Pink(nightvision_noise2, frametime * 0.1) * 0.05 + 0.12;
2111                 rgb = '0.3 0.6 0.4' + '0.1 0.4 0.2' * Noise_White(nightvision_noise2, frametime);
2112                 tc_00 = '0 0 0' + '1 0 0' * Noise_White(nightvision_noise2, frametime) + '0 1 0' * Noise_White(nightvision_noise2, frametime);
2113                 tc_01 = tc_00 + '0 3 0' * (1 + Noise_White(nightvision_noise2, frametime) * 0.2);
2114                 tc_10 = tc_00 + '2 0 0' * (1 + Noise_White(nightvision_noise2, frametime) * 0.3);
2115                 tc_11 = tc_01 + tc_10 - tc_00;
2116                 R_BeginPolygon("gfx/nightvision-fg.tga", DRAWFLAG_ADDITIVE);
2117                 R_PolygonVertex('0 0 0', tc_00, rgb, a);
2118                 R_PolygonVertex(autocvar_vid_conwidth * '1 0 0', tc_10, rgb, a);
2119                 R_PolygonVertex(autocvar_vid_conwidth * '1 0 0' + autocvar_vid_conheight * '0 1 0', tc_11, rgb, a);
2120                 R_PolygonVertex(autocvar_vid_conheight * '0 1 0', tc_01, rgb, a);
2121                 R_EndPolygon();
2122         }
2123
2124         if(autocvar_cl_reticle)
2125         {
2126                 string reticle_image = string_null;
2127                 bool wep_zoomed = false;
2128                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
2129                 {
2130                         entity wepe = viewmodels[slot];
2131                         Weapon wep = wepe.activeweapon;
2132                         if(wep != WEP_Null && wep.wr_zoom)
2133                         {
2134                                 bool do_zoom = wep.wr_zoom(wep, NULL);
2135                                 if(!reticle_image && wep.w_reticle && wep.w_reticle != "")
2136                                         reticle_image = wep.w_reticle;
2137                                 wep_zoomed += do_zoom;
2138                         }
2139                 }
2140                 // Draw the aiming reticle for weapons that use it
2141                 // reticle_type is changed to the item we are zooming / aiming with, to decide which reticle to use
2142                 // It must be a persisted float for fading out to work properly (you let go of the zoom button for
2143                 // the view to go back to normal, so reticle_type would become 0 as we fade out)
2144                 if(spectatee_status || is_dead || hud != HUD_NORMAL || local_player.viewloc)
2145                 {
2146                         // no zoom reticle while dead
2147                         reticle_type = 0;
2148                 }
2149                 else if(wep_zoomed && autocvar_cl_reticle_weapon)
2150                 {
2151                         if(reticle_image) { reticle_type = 2; }
2152                         else { reticle_type = 0; }
2153                 }
2154                 else if(button_zoom || zoomscript_caught)
2155                 {
2156                         // normal zoom
2157                         reticle_type = 1;
2158                 }
2159
2160                 if(reticle_type)
2161                 {
2162                         if(autocvar_cl_reticle_stretch)
2163                         {
2164                                 reticle_size.x = vid_conwidth;
2165                                 reticle_size.y = vid_conheight;
2166                                 reticle_pos.x = 0;
2167                                 reticle_pos.y = 0;
2168                         }
2169                         else
2170                         {
2171                                 reticle_size.x = max(vid_conwidth, vid_conheight);
2172                                 reticle_size.y = max(vid_conwidth, vid_conheight);
2173                                 reticle_pos.x = (vid_conwidth - reticle_size.x) / 2;
2174                                 reticle_pos.y = (vid_conheight - reticle_size.y) / 2;
2175                         }
2176
2177                         if(zoomscript_caught)
2178                                 f = 1;
2179                         else
2180                                 f = current_zoomfraction;
2181
2182                         if(f)
2183                         {
2184                                 switch(reticle_type)
2185                                 {
2186                                         case 1: drawpic(reticle_pos, "gfx/reticle_normal", reticle_size, '1 1 1', f * autocvar_cl_reticle_normal_alpha, DRAWFLAG_NORMAL); break;
2187                                         case 2: if(reticle_image) drawpic(reticle_pos, reticle_image, reticle_size, '1 1 1', f * autocvar_cl_reticle_weapon_alpha, DRAWFLAG_NORMAL); break;
2188                                 }
2189                         }
2190                 }
2191         }
2192         else
2193         {
2194                 if(reticle_type != 0) { reticle_type = 0; }
2195         }
2196
2197
2198         // improved polyblend
2199         if(autocvar_hud_contents && !MUTATOR_CALLHOOK(HUD_Contents))
2200         {
2201                 float contentalpha_temp, incontent, liquidalpha, contentfadetime;
2202                 vector liquidcolor;
2203
2204                 switch(pointcontents(view_origin))
2205                 {
2206                         case CONTENT_WATER:
2207                                 liquidalpha = autocvar_hud_contents_water_alpha;
2208                                 liquidcolor = stov(autocvar_hud_contents_water_color);
2209                                 incontent = 1;
2210                                 break;
2211
2212                         case CONTENT_LAVA:
2213                                 liquidalpha = autocvar_hud_contents_lava_alpha;
2214                                 liquidcolor = stov(autocvar_hud_contents_lava_color);
2215                                 incontent = 1;
2216                                 break;
2217
2218                         case CONTENT_SLIME:
2219                                 liquidalpha = autocvar_hud_contents_slime_alpha;
2220                                 liquidcolor = stov(autocvar_hud_contents_slime_color);
2221                                 incontent = 1;
2222                                 break;
2223
2224                         default:
2225                                 liquidalpha = 0;
2226                                 liquidcolor = '0 0 0';
2227                                 incontent = 0;
2228                                 break;
2229                 }
2230
2231                 if(incontent) // fade in/out at different speeds so you can do e.g. instant fade when entering water and slow when leaving it.
2232                 { // also lets delcare previous values for blending properties, this way it isn't reset until after you have entered a different content
2233                         contentfadetime = autocvar_hud_contents_fadeintime;
2234                         liquidalpha_prev = liquidalpha;
2235                         liquidcolor_prev = liquidcolor;
2236                 }
2237                 else
2238                         contentfadetime = autocvar_hud_contents_fadeouttime;
2239
2240                 contentalpha_temp = bound(0, drawframetime / max(0.0001, contentfadetime), 1);
2241                 contentavgalpha = contentavgalpha * (1 - contentalpha_temp) + incontent * contentalpha_temp;
2242
2243                 if(contentavgalpha)
2244                         drawfill('0 0 0', vec2(vid_conwidth, vid_conheight), liquidcolor_prev, contentavgalpha * liquidalpha_prev, DRAWFLAG_NORMAL);
2245
2246                 if(autocvar_hud_postprocessing)
2247                 {
2248                         if(autocvar_hud_contents_blur && contentavgalpha)
2249                         {
2250                                 content_blurpostprocess.x = 1;
2251                                 content_blurpostprocess.y = contentavgalpha * autocvar_hud_contents_blur;
2252                                 content_blurpostprocess.z = contentavgalpha * autocvar_hud_contents_blur_alpha;
2253                         }
2254                         else
2255                         {
2256                                 content_blurpostprocess.x = 0;
2257                                 content_blurpostprocess.y = 0;
2258                                 content_blurpostprocess.z = 0;
2259                         }
2260                 }
2261         }
2262
2263         if(autocvar_hud_damage && !STAT(FROZEN))
2264         {
2265                 splash_size.x = max(vid_conwidth, vid_conheight);
2266                 splash_size.y = max(vid_conwidth, vid_conheight);
2267                 splash_pos.x = (vid_conwidth - splash_size.x) / 2;
2268                 splash_pos.y = (vid_conheight - splash_size.y) / 2;
2269
2270                 float myhealth_flash_temp;
2271                 myhealth = STAT(HEALTH);
2272
2273                 // fade out
2274                 myhealth_flash = max(0, myhealth_flash - autocvar_hud_damage_fade_rate * frametime);
2275                 // add new damage
2276                 myhealth_flash = bound(0, myhealth_flash + dmg_take * autocvar_hud_damage_factor, autocvar_hud_damage_maxalpha);
2277
2278                 float pain_threshold, pain_threshold_lower, pain_threshold_lower_health;
2279                 pain_threshold = autocvar_hud_damage_pain_threshold;
2280                 pain_threshold_lower = autocvar_hud_damage_pain_threshold_lower;
2281                 pain_threshold_lower_health = autocvar_hud_damage_pain_threshold_lower_health;
2282
2283                 if(pain_threshold_lower && myhealth < pain_threshold_lower_health)
2284                 {
2285                         pain_threshold = pain_threshold - max(autocvar_hud_damage_pain_threshold_pulsating_min, fabs(sin(M_PI * time / autocvar_hud_damage_pain_threshold_pulsating_period))) * pain_threshold_lower * (1 - max(0, myhealth)/pain_threshold_lower_health);
2286                 }
2287
2288                 myhealth_flash_temp = bound(0, myhealth_flash - pain_threshold, 1);
2289
2290                 if(myhealth_prev < 1)
2291                 {
2292                         if(myhealth >= 1)
2293                         {
2294                                 myhealth_flash = 0; // just spawned, clear the flash immediately
2295                                 myhealth_flash_temp = 0;
2296                         }
2297                         else
2298                         {
2299                                 myhealth_flash += autocvar_hud_damage_fade_rate * frametime; // dead
2300                         }
2301                 }
2302
2303                 if(spectatee_status == -1 || intermission)
2304                 {
2305                         myhealth_flash = 0; // observing, or match ended
2306                         myhealth_flash_temp = 0;
2307                 }
2308
2309                 myhealth_prev = myhealth;
2310
2311                 // IDEA: change damage color/picture based on player model for robot/alien species?
2312                 // pro: matches model better
2313                 // contra: it's not red because blood is red, but because red is an alarming color, so red should stay
2314                 // maybe different reddish pics?
2315                 if(autocvar_cl_gentle_damage || autocvar_cl_gentle)
2316                 {
2317                         if(autocvar_cl_gentle_damage == 2)
2318                         {
2319                                 if(myhealth_flash < pain_threshold) // only randomize when the flash is gone
2320                                         myhealth_gentlergb = randomvec();
2321                         }
2322                         else
2323                                 myhealth_gentlergb = stov(autocvar_hud_damage_gentle_color);
2324
2325                         if(myhealth_flash_temp > 0)
2326                                 drawfill('0 0 0', vec2(vid_conwidth, vid_conheight), myhealth_gentlergb, autocvar_hud_damage_gentle_alpha_multiplier * bound(0, myhealth_flash_temp, 1) * autocvar_hud_damage, DRAWFLAG_NORMAL);
2327                 }
2328                 else if(myhealth_flash_temp > 0)
2329                         drawpic(splash_pos, "gfx/blood", splash_size, stov(autocvar_hud_damage_color), bound(0, myhealth_flash_temp, 1) * autocvar_hud_damage, DRAWFLAG_NORMAL);
2330
2331                 if(autocvar_hud_postprocessing) // we still need to set this anyway even when chase_active is set, this way it doesn't get stuck on.
2332                 {
2333                         if(autocvar_hud_damage_blur && myhealth_flash_temp)
2334                         {
2335                                 damage_blurpostprocess.x = 1;
2336                                 damage_blurpostprocess.y = bound(0, myhealth_flash_temp, 1) * autocvar_hud_damage_blur;
2337                                 damage_blurpostprocess.z = bound(0, myhealth_flash_temp, 1) * autocvar_hud_damage_blur_alpha;
2338                         }
2339                         else
2340                         {
2341                                 damage_blurpostprocess.x = 0;
2342                                 damage_blurpostprocess.y = 0;
2343                                 damage_blurpostprocess.z = 0;
2344                         }
2345                 }
2346         }
2347
2348         float e1 = (autocvar_hud_postprocessing_maxbluralpha != 0);
2349         float e2 = (autocvar_hud_powerup != 0);
2350         if(autocvar_hud_postprocessing && (e1 || e2)) // TODO: Remove this code and re-do the postprocess handling in the engine, where it properly belongs.
2351         {
2352                 // enable or disable rendering types if they are used or not
2353                 if(cvar("r_glsl_postprocess_uservec1_enable") != e1) { cvar_set("r_glsl_postprocess_uservec1_enable", ftos(e1)); }
2354                 if(cvar("r_glsl_postprocess_uservec2_enable") != e2) { cvar_set("r_glsl_postprocess_uservec2_enable", ftos(e2)); }
2355
2356                 // blur postprocess handling done first (used by hud_damage and hud_contents)
2357                 if((damage_blurpostprocess.x || content_blurpostprocess.x))
2358                 {
2359                         float blurradius = bound(0, damage_blurpostprocess.y + content_blurpostprocess.y, autocvar_hud_postprocessing_maxblurradius);
2360                         float bluralpha = bound(0, damage_blurpostprocess.z + content_blurpostprocess.z, autocvar_hud_postprocessing_maxbluralpha);
2361                         if(blurradius != old_blurradius || bluralpha != old_bluralpha) // reduce cvar_set spam as much as possible
2362                         {
2363                                 cvar_set("r_glsl_postprocess_uservec1", strcat(ftos(blurradius), " ", ftos(bluralpha), " 0 0"));
2364                                 old_blurradius = blurradius;
2365                                 old_bluralpha = bluralpha;
2366                         }
2367                 }
2368                 else if(cvar_string("r_glsl_postprocess_uservec1") != "0 0 0 0") // reduce cvar_set spam as much as possible
2369                 {
2370                         cvar_set("r_glsl_postprocess_uservec1", "0 0 0 0");
2371                         old_blurradius = 0;
2372                         old_bluralpha = 0;
2373                 }
2374
2375                 // edge detection postprocess handling done second (used by hud_powerup)
2376                 float sharpen_intensity = 0, strength_finished = STAT(STRENGTH_FINISHED), invincible_finished = STAT(INVINCIBLE_FINISHED);
2377                 if (strength_finished - time > 0) { sharpen_intensity += (strength_finished - time); }
2378                 if (invincible_finished - time > 0) { sharpen_intensity += (invincible_finished - time); }
2379
2380                 sharpen_intensity = bound(0, ((STAT(HEALTH) > 0) ? sharpen_intensity : 0), 5); // Check to see if player is alive (if not, set 0) - also bound to fade out starting at 5 seconds.
2381
2382                 if(autocvar_hud_powerup && sharpen_intensity > 0)
2383                 {
2384                         if(sharpen_intensity != old_sharpen_intensity) // reduce cvar_set spam as much as possible
2385                         {
2386                                 cvar_set("r_glsl_postprocess_uservec2", strcat(ftos((sharpen_intensity / 5) * autocvar_hud_powerup), " ", ftos(-sharpen_intensity * autocvar_hud_powerup), " 0 0"));
2387                                 old_sharpen_intensity = sharpen_intensity;
2388                         }
2389                 }
2390                 else if(cvar_string("r_glsl_postprocess_uservec2") != "0 0 0 0") // reduce cvar_set spam as much as possible
2391                 {
2392                         cvar_set("r_glsl_postprocess_uservec2", "0 0 0 0");
2393                         old_sharpen_intensity = 0;
2394                 }
2395
2396                 if(cvar("r_glsl_postprocess") == 0)
2397                         cvar_set("r_glsl_postprocess", "2");
2398         }
2399         else if(cvar("r_glsl_postprocess") == 2)
2400                 cvar_set("r_glsl_postprocess", "0");
2401
2402         /*if(gametype == MAPINFO_TYPE_CTF)
2403           {
2404           ctf_view();
2405           } else */
2406
2407         // draw 2D entities
2408         IL_EACH(g_drawables_2d, it.draw2d, it.draw2d(it));
2409         Draw_ShowNames_All();
2410 #if ENABLE_DEBUGDRAW
2411         Debug_Draw();
2412 #endif
2413
2414         scoreboard_active = Scoreboard_WouldDraw();
2415
2416         HUD_Draw(this); // this parameter for deep vehicle function
2417
2418         if(NextFrameCommand)
2419         {
2420                 localcmd("\n", NextFrameCommand, "\n");
2421                 NextFrameCommand = string_null;
2422         }
2423
2424         // we must do this check AFTER a frame was rendered, or it won't work
2425         if(cs_project_is_b0rked == 0)
2426         {
2427                 string w0, h0;
2428                 w0 = ftos(autocvar_vid_conwidth);
2429                 h0 = ftos(autocvar_vid_conheight);
2430                 //setproperty(VF_VIEWPORT, '0 0 0', '640 480 0');
2431                 //setproperty(VF_FOV, '90 90 0');
2432                 setproperty(VF_ORIGIN, '0 0 0');
2433                 setproperty(VF_ANGLES, '0 0 0');
2434                 setproperty(VF_PERSPECTIVE, 1);
2435                 makevectors('0 0 0');
2436                 vector v1, v2;
2437                 cvar_set("vid_conwidth", "800");
2438                 cvar_set("vid_conheight", "600");
2439                 v1 = cs_project(v_forward);
2440                 cvar_set("vid_conwidth", "640");
2441                 cvar_set("vid_conheight", "480");
2442                 v2 = cs_project(v_forward);
2443                 if(v1 == v2)
2444                         cs_project_is_b0rked = 1;
2445                 else
2446                         cs_project_is_b0rked = -1;
2447                 cvar_set("vid_conwidth", w0);
2448                 cvar_set("vid_conheight", h0);
2449         }
2450
2451         if(autocvar__hud_configure)
2452                 HUD_Panel_Mouse();
2453         else if (HUD_MinigameMenu_IsOpened() || active_minigame)
2454                 HUD_Minigame_Mouse();
2455         else if(QuickMenu_IsOpened())
2456                 QuickMenu_Mouse();
2457         else if(local_player.viewloc && (local_player.viewloc.spawnflags & VIEWLOC_FREEAIM))
2458                 ViewLocation_Mouse(); // NOTE: doesn't use cursormode
2459         else
2460                 HUD_Radar_Mouse();
2461
2462         cl_notice_run();
2463         unpause_update();
2464         Net_Flush();
2465
2466         // let's reset the view back to normal for the end
2467         setproperty(VF_MIN, '0 0 0');
2468         setproperty(VF_SIZE, '1 0 0' * w + '0 1 0' * h);
2469
2470         IL_ENDFRAME();
2471 }
2472
2473
2474 // following vectors must be global to allow seamless switching between camera modes
2475 vector camera_offset, current_camera_offset, mouse_angles, current_angles, current_origin, current_position;
2476 void CSQC_Demo_Camera()
2477 {
2478         float speed, attenuation, dimensions;
2479         vector tmp, delta;
2480
2481         if( autocvar_camera_reset || !camera_mode )
2482         {
2483                 camera_offset = '0 0 0';
2484                 current_angles = '0 0 0';
2485                 camera_direction = '0 0 0';
2486                 camera_offset.z += 30;
2487                 camera_offset.x += 30 * -cos(current_angles.y * DEG2RAD);
2488                 camera_offset.y += 30 * -sin(current_angles.y * DEG2RAD);
2489                 current_origin = view_origin;
2490                 current_camera_offset  = camera_offset;
2491                 cvar_set("camera_reset", "0");
2492                 camera_mode = CAMERA_CHASE;
2493         }
2494
2495         // Camera angles
2496         if( camera_roll )
2497                 mouse_angles.z += camera_roll * autocvar_camera_speed_roll;
2498
2499         if(autocvar_camera_look_player)
2500         {
2501                 vector dir;
2502                 float n;
2503
2504                 dir = normalize(view_origin - current_position);
2505                 n = mouse_angles.z;
2506                 mouse_angles = vectoangles(dir);
2507                 mouse_angles.x = mouse_angles.x * -1;
2508                 mouse_angles.z = n;
2509         }
2510         else
2511         {
2512                 tmp = getmousepos() * 0.1;
2513                 if(vdist(tmp, >, autocvar_camera_mouse_threshold))
2514                 {
2515                         mouse_angles.x += tmp.y * cos(mouse_angles.z * DEG2RAD) + (tmp.x * sin(mouse_angles.z * DEG2RAD));
2516                         mouse_angles.y -= tmp.x * cos(mouse_angles.z * DEG2RAD) + (tmp.y * -sin(mouse_angles.z * DEG2RAD));
2517                 }
2518         }
2519
2520         while (mouse_angles.x < -180) mouse_angles.x = mouse_angles.x + 360;
2521         while (mouse_angles.x > 180) mouse_angles.x = mouse_angles.x - 360;
2522         while (mouse_angles.y < -180) mouse_angles.y = mouse_angles.y + 360;
2523         while (mouse_angles.y > 180) mouse_angles.y = mouse_angles.y - 360;
2524
2525         // Fix difference when angles don't have the same sign
2526         delta = '0 0 0';
2527         if(mouse_angles.y < -60 && current_angles.y > 60)
2528                 delta = '0 360 0';
2529         if(mouse_angles.y > 60 && current_angles.y < -60)
2530                 delta = '0 -360 0';
2531
2532         if(autocvar_camera_look_player)
2533                 attenuation = autocvar_camera_look_attenuation;
2534         else
2535                 attenuation = autocvar_camera_speed_attenuation;
2536
2537         attenuation = 1 / max(1, attenuation);
2538         current_angles += (mouse_angles - current_angles + delta) * attenuation;
2539
2540         while (current_angles.x < -180) current_angles.x = current_angles.x + 360;
2541         while (current_angles.x > 180) current_angles.x = current_angles.x - 360;
2542         while (current_angles.y < -180) current_angles.y = current_angles.y + 360;
2543         while (current_angles.y > 180) current_angles.y = current_angles.y - 360;
2544
2545         // Camera position
2546         tmp = '0 0 0';
2547         dimensions = 0;
2548
2549         if( camera_direction.x )
2550         {
2551                 tmp.x = camera_direction.x * cos(current_angles.y * DEG2RAD);
2552                 tmp.y = camera_direction.x * sin(current_angles.y * DEG2RAD);
2553                 if( autocvar_camera_forward_follows && !autocvar_camera_look_player )
2554                         tmp.z = camera_direction.x * -sin(current_angles.x * DEG2RAD);
2555                 ++dimensions;
2556         }
2557
2558         if( camera_direction.y )
2559         {
2560                 tmp.x += camera_direction.y * -sin(current_angles.y * DEG2RAD);
2561                 tmp.y += camera_direction.y * cos(current_angles.y * DEG2RAD) * cos(current_angles.z * DEG2RAD);
2562                 tmp.z += camera_direction.y * sin(current_angles.z * DEG2RAD);
2563                 ++dimensions;
2564         }
2565
2566         if( camera_direction.z )
2567         {
2568                 tmp.z += camera_direction.z * cos(current_angles.z * DEG2RAD);
2569                 ++dimensions;
2570         }
2571
2572         if(autocvar_camera_free)
2573                 speed = autocvar_camera_speed_free;
2574         else
2575                 speed = autocvar_camera_speed_chase;
2576
2577         if(dimensions)
2578         {
2579                 speed = speed * sqrt(1 / dimensions);
2580                 camera_offset += tmp * speed;
2581         }
2582
2583         current_camera_offset += (camera_offset - current_camera_offset) * attenuation;
2584
2585         // Camera modes
2586         if( autocvar_camera_free )
2587         {
2588                 if ( camera_mode == CAMERA_CHASE )
2589                 {
2590                         current_camera_offset = current_origin + current_camera_offset;
2591                         camera_offset = current_origin + camera_offset;
2592                 }
2593
2594                 camera_mode = CAMERA_FREE;
2595                 current_position = current_camera_offset;
2596         }
2597         else
2598         {
2599                 if ( camera_mode == CAMERA_FREE )
2600                 {
2601                         current_origin = view_origin;
2602                         camera_offset = camera_offset - current_origin;
2603                         current_camera_offset = current_camera_offset - current_origin;
2604                 }
2605
2606                 camera_mode = CAMERA_CHASE;
2607
2608                 if(autocvar_camera_chase_smoothly)
2609                         current_origin += (view_origin - current_origin) * attenuation;
2610                 else
2611                         current_origin = view_origin;
2612
2613                 current_position = current_origin + current_camera_offset;
2614         }
2615
2616         setproperty(VF_ANGLES, current_angles);
2617         setproperty(VF_ORIGIN, current_position);
2618 }