qcsrc/client/view.qc

   1 #include "announcer.qh"
   2 #include "autocvars.qh"
   3 #include "defs.qh"
   4 #include "hook.qh"
   5 #include "hud.qh"
   6 #include "hud_config.qh"
   7 #include "main.qh"
   8 #include "mapvoting.qh"
   9 #include "miscfunctions.qh"
  10 #include "noise.qh"
  11 #include "scoreboard.qh"
  12 #include "shownames.qh"
  13 #include "target_music.qh"
  14 #include "vehicles/vehicles.qh"
  15 #include "waypointsprites.qh"
  16
  17 #include "../common/constants.qh"
  18 #include "../common/mapinfo.qh"
  19 #include "../common/nades.qh"
  20 #include "../common/stats.qh"
  21 #include "../common/teams.qh"
  22 #include "../common/util.qh"
  23
  24 #include "../common/weapons/weapons.qh"
  25
  26 #include "../csqcmodellib/cl_player.qh"
  27
  28 #include "../dpdefs/csprogsdefs.qh"
  29
  30 #include "../warpzonelib/client.qh"
  31 #include "../warpzonelib/common.qh"
  32 #include "../warpzonelib/mathlib.qh"
  33
  34 entity porto;
  35 vector polyline[16];
  36 void Porto_Draw()
  37 {
  38         vector p, dir, ang, q, nextdir;
  39         float portal_number, portal1_idx;
  40
  41         if(activeweapon != WEP_PORTO || spectatee_status || gametype == MAPINFO_TYPE_NEXBALL)
  42                 return;
  43         if(g_balance_porto_secondary)
  44                 return;
  45         if(intermission == 1)
  46                 return;
  47         if(intermission == 2)
  48                 return;
  49         if (getstati(STAT_HEALTH) <= 0)
  50                 return;
  51
  52         dir = view_forward;
  53
  54         if(angles_held_status)
  55         {
  56                 makevectors(angles_held);
  57                 dir = v_forward;
  58         }
  59
  60         p = view_origin;
  61
  62         polyline[0] = p;
  63         int idx = 1;
  64         portal_number = 0;
  65         nextdir = dir;
  66
  67         for (;;)
  68         {
  69                 dir = nextdir;
  70                 traceline(p, p + 65536 * dir, true, porto);
  71                 if(trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT)
  72                         return;
  73                 nextdir = dir - 2 * (dir * trace_plane_normal) * trace_plane_normal; // mirror dir at trace_plane_normal
  74                 p = trace_endpos;
  75                 polyline[idx] = p;
  76                 ++idx;
  77                 if(idx >= 16)
  78                         return;
  79                 if(trace_dphitq3surfaceflags & Q3SURFACEFLAG_SLICK || trace_dphitcontents & DPCONTENTS_PLAYERCLIP)
  80                         continue;
  81                 ++portal_number;
  82                 ang = vectoangles2(trace_plane_normal, dir);
  83                 ang.x = -ang.x;
  84                 makevectors(ang);
  85                 if(!CheckWireframeBox(porto, p - 48 * v_right - 48 * v_up + 16 * v_forward, 96 * v_right, 96 * v_up, 96 * v_forward))
  86                         return;
  87                 if(portal_number == 1)
  88                 {
  89                         portal1_idx = idx;
  90                         if(portal_number >= 2)
  91                                 break;
  92                 }
  93         }
  94
  95         while(idx >= 2)
  96         {
  97                 p = polyline[idx-2];
  98                 q = polyline[idx-1];
  99                 if(idx == 2)
 100                         p = p - view_up * 16;
 101                 if(idx-1 >= portal1_idx)
 102                 {
 103                         Draw_CylindricLine(p, q, 4, "", 1, 0, '0 0 1', 0.5, DRAWFLAG_NORMAL, view_origin);
 104                 }
 105                 else
 106                 {
 107                         Draw_CylindricLine(p, q, 4, "", 1, 0, '1 0 0', 0.5, DRAWFLAG_NORMAL, view_origin);
 108                 }
 109                 --idx;
 110         }
 111 }
 112
 113 void Porto_Init()
 114 {
 115         porto = spawn();
 116         porto.classname = "porto";
 117         porto.draw = Porto_Draw;
 118         porto.dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY | DPCONTENTS_PLAYERCLIP;
 119 }
 120
 121 float drawtime;
 122 float avgspeed;
 123 vector GetCurrentFov(float fov)
 124 {
 125         float zoomsensitivity, zoomspeed, zoomfactor, zoomdir;
 126         float velocityzoom, curspeed;
 127         vector v;
 128
 129         zoomsensitivity = autocvar_cl_zoomsensitivity;
 130         zoomfactor = autocvar_cl_zoomfactor;
 131         if(zoomfactor < 1 || zoomfactor > 16)
 132                 zoomfactor = 2.5;
 133         zoomspeed = autocvar_cl_zoomspeed;
 134         if(zoomspeed >= 0)
 135         if(zoomspeed < 0.5 || zoomspeed > 16)
 136                         zoomspeed = 3.5;
 137
 138         zoomdir = button_zoom;
 139         if(hud == HUD_NORMAL)
 140         if((activeweapon == WEP_VORTEX && vortex_scope) || (activeweapon == WEP_RIFLE && rifle_scope)) // do NOT use switchweapon here
 141                 zoomdir += button_attack2;
 142         if(spectatee_status > 0 || isdemo())
 143         {
 144                 if(spectatorbutton_zoom)
 145                 {
 146                         if(zoomdir)
 147                                 zoomdir = 0;
 148                         else
 149                                 zoomdir = 1;
 150                 }
 151                 // fteqcc failed twice here already, don't optimize this
 152         }
 153
 154         if(zoomdir) { zoomin_effect = 0; }
 155
 156         if(camera_active)
 157         {
 158                 current_viewzoom = min(1, current_viewzoom + drawframetime);
 159         }
 160         else if(autocvar_cl_spawnzoom && zoomin_effect)
 161         {
 162                 float spawnzoomfactor = bound(1, autocvar_cl_spawnzoom_factor, 16);
 163
 164                 current_viewzoom += (autocvar_cl_spawnzoom_speed * (spawnzoomfactor - current_viewzoom) * drawframetime);
 165                 current_viewzoom = bound(1 / spawnzoomfactor, current_viewzoom, 1);
 166                 if(current_viewzoom == 1) { zoomin_effect = 0; }
 167         }
 168         else
 169         {
 170                 if(zoomspeed < 0) // instant zoom
 171                 {
 172                         if(zoomdir)
 173                                 current_viewzoom = 1 / zoomfactor;
 174                         else
 175                                 current_viewzoom = 1;
 176                 }
 177                 else
 178                 {
 179                         if(zoomdir)
 180                                 current_viewzoom = 1 / bound(1, 1 / current_viewzoom + drawframetime * zoomspeed * (zoomfactor - 1), zoomfactor);
 181                         else
 182                                 current_viewzoom = bound(1 / zoomfactor, current_viewzoom + drawframetime * zoomspeed * (1 - 1 / zoomfactor), 1);
 183                 }
 184         }
 185
 186         if(almost_equals(current_viewzoom, 1))
 187                 current_zoomfraction = 0;
 188         else if(almost_equals(current_viewzoom, 1/zoomfactor))
 189                 current_zoomfraction = 1;
 190         else
 191                 current_zoomfraction = (current_viewzoom - 1) / (1/zoomfactor - 1);
 192
 193         if(zoomsensitivity < 1)
 194                 setsensitivityscale(pow(current_viewzoom, 1 - zoomsensitivity));
 195         else
 196                 setsensitivityscale(1);
 197
 198         if(autocvar_cl_velocityzoom_enabled && autocvar_cl_velocityzoom_type) // _type = 0 disables velocity zoom too
 199         {
 200                 if(intermission) { curspeed = 0; }
 201                 else
 202                 {
 203
 204                         makevectors(view_angles);
 205                         v = pmove_vel;
 206                         if(csqcplayer)
 207                                 v = csqcplayer.velocity;
 208
 209                         switch(autocvar_cl_velocityzoom_type)
 210                         {
 211                                 case 3: curspeed = max(0, v_forward * v); break;
 212                                 case 2: curspeed = (v_forward * v); break;
 213                                 case 1: default: curspeed = vlen(v); break;
 214                         }
 215                 }
 216
 217                 velocityzoom = bound(0, drawframetime / max(0.000000001, autocvar_cl_velocityzoom_time), 1); // speed at which the zoom adapts to player velocity
 218                 avgspeed = avgspeed * (1 - velocityzoom) + (curspeed / autocvar_cl_velocityzoom_speed) * velocityzoom;
 219                 velocityzoom = exp(float2range11(avgspeed * -autocvar_cl_velocityzoom_factor / 1) * 1);
 220
 221                 //print(ftos(avgspeed), " avgspeed, ", ftos(curspeed), " curspeed, ", ftos(velocityzoom), " return\n"); // for debugging
 222         }
 223         else
 224                 velocityzoom = 1;
 225
 226         float frustumx, frustumy, fovx, fovy;
 227         frustumy = tan(fov * M_PI / 360.0) * 0.75 * current_viewzoom * velocityzoom;
 228         frustumx = frustumy * vid_width / vid_height / vid_pixelheight;
 229         fovx = atan2(frustumx, 1) / M_PI * 360.0;
 230         fovy = atan2(frustumy, 1) / M_PI * 360.0;
 231
 232         return '1 0 0' * fovx + '0 1 0' * fovy;
 233 }
 234
 235 vector GetOrthoviewFOV(vector ov_worldmin, vector ov_worldmax, vector ov_mid, vector ov_org)
 236 {
 237         float fovx, fovy;
 238         float width = (ov_worldmax.x - ov_worldmin.x);
 239         float height = (ov_worldmax.y - ov_worldmin.y);
 240         float distance_to_middle_of_world = vlen(ov_mid - ov_org);
 241         fovx = atan2(width/2, distance_to_middle_of_world) / M_PI * 360.0;
 242         fovy = atan2(height/2, distance_to_middle_of_world) / M_PI * 360.0;
 243         return '1 0 0' * fovx + '0 1 0' * fovy;
 244 }
 245
 246 // this function must match W_SetupShot!
 247 float zoomscript_caught;
 248
 249 vector wcross_origin;
 250 float wcross_scale_prev, wcross_alpha_prev;
 251 vector wcross_color_prev;
 252 float wcross_scale_goal_prev, wcross_alpha_goal_prev;
 253 vector wcross_color_goal_prev;
 254 float wcross_changedonetime;
 255
 256 string wcross_name_goal_prev, wcross_name_goal_prev_prev;
 257 float wcross_resolution_goal_prev, wcross_resolution_goal_prev_prev;
 258 float wcross_name_changestarttime, wcross_name_changedonetime;
 259 float wcross_name_alpha_goal_prev, wcross_name_alpha_goal_prev_prev;
 260
 261 float wcross_ring_prev;
 262
 263 entity trueaim;
 264 entity trueaim_rifle;
 265
 266 const float SHOTTYPE_HITTEAM = 1;
 267 const float SHOTTYPE_HITOBSTRUCTION = 2;
 268 const float SHOTTYPE_HITWORLD = 3;
 269 const float SHOTTYPE_HITENEMY = 4;
 270
 271 void TrueAim_Init()
 272 {
 273         trueaim = spawn();
 274         trueaim.classname = "trueaim";
 275         trueaim.dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY | DPCONTENTS_CORPSE;
 276         trueaim_rifle = spawn();
 277         trueaim_rifle.classname = "trueaim_rifle";
 278         trueaim_rifle.dphitcontentsmask = DPCONTENTS_BODY | DPCONTENTS_CORPSE;
 279 }
 280
 281 float EnemyHitCheck()
 282 {
 283         float t, n;
 284         wcross_origin = project_3d_to_2d(trace_endpos);
 285         wcross_origin.z = 0;
 286         if(trace_ent)
 287                 n = trace_ent.entnum;
 288         else
 289                 n = trace_networkentity;
 290         if(n < 1)
 291                 return SHOTTYPE_HITWORLD;
 292         if(n > maxclients)
 293                 return SHOTTYPE_HITWORLD;
 294         t = GetPlayerColor(n - 1);
 295         if(teamplay)
 296                 if(t == myteam)
 297                         return SHOTTYPE_HITTEAM;
 298         if(t == NUM_SPECTATOR)
 299                 return SHOTTYPE_HITWORLD;
 300         return SHOTTYPE_HITENEMY;
 301 }
 302
 303 float TrueAimCheck()
 304 {
 305         float nudge = 1; // added to traceline target and subtracted from result TOOD(divVerent): do we still need this? Doesn't the engine do this now for us?
 306         vector vecs, trueaimpoint, w_shotorg;
 307         vector mi, ma, dv;
 308         float shottype;
 309         entity ta;
 310         float mv;
 311
 312         mi = ma = '0 0 0';
 313         ta = trueaim;
 314         mv = MOVE_NOMONSTERS;
 315
 316         switch(activeweapon) // WEAPONTODO
 317         {
 318                 case WEP_TUBA: // no aim
 319                 case WEP_PORTO: // shoots from eye
 320                 case WEP_HOOK: // no trueaim
 321                 case WEP_MORTAR: // toss curve
 322                         return SHOTTYPE_HITWORLD;
 323                 case WEP_VORTEX:
 324                 case WEP_VAPORIZER:
 325                         mv = MOVE_NORMAL;
 326                         break;
 327                 case WEP_RIFLE:
 328                         ta = trueaim_rifle;
 329                         mv = MOVE_NORMAL;
 330                         if(zoomscript_caught)
 331                         {
 332                                 tracebox(view_origin, '0 0 0', '0 0 0', view_origin + view_forward * MAX_SHOT_DISTANCE, mv, ta);
 333                                 return EnemyHitCheck();
 334                         }
 335                         break;
 336                 case WEP_DEVASTATOR: // projectile has a size!
 337                         mi = '-3 -3 -3';
 338                         ma = '3 3 3';
 339                         break;
 340                 case WEP_FIREBALL: // projectile has a size!
 341                         mi = '-16 -16 -16';
 342                         ma = '16 16 16';
 343                         break;
 344                 case WEP_SEEKER: // projectile has a size!
 345                         mi = '-2 -2 -2';
 346                         ma = '2 2 2';
 347                         break;
 348                 case WEP_ELECTRO: // projectile has a size!
 349                         mi = '0 0 -3';
 350                         ma = '0 0 -3';
 351                         break;
 352         }
 353
 354         vector traceorigin = getplayerorigin(player_localentnum-1) + (eZ * getstati(STAT_VIEWHEIGHT));
 355
 356         vecs = decompressShotOrigin(getstati(STAT_SHOTORG));
 357
 358         traceline(traceorigin, traceorigin + view_forward * MAX_SHOT_DISTANCE, mv, ta);
 359         trueaimpoint = trace_endpos;
 360
 361         if(vlen(trueaimpoint - traceorigin) < g_trueaim_minrange)
 362                 trueaimpoint = traceorigin + view_forward * g_trueaim_minrange;
 363
 364         if(vecs.x > 0)
 365                 vecs.y = -vecs.y;
 366         else
 367                 vecs = '0 0 0';
 368
 369         dv = view_right * vecs.y + view_up * vecs.z;
 370         w_shotorg = traceorigin + dv;
 371
 372         // now move the vecs forward as much as requested if possible
 373         tracebox(w_shotorg, mi, ma, w_shotorg + view_forward * (vecs.x + nudge), MOVE_NORMAL, ta); // FIXME this MOVE_NORMAL part will misbehave a little in csqc
 374         w_shotorg = trace_endpos - view_forward * nudge;
 375
 376         tracebox(w_shotorg, mi, ma, trueaimpoint, MOVE_NORMAL, ta);
 377         shottype = EnemyHitCheck();
 378         if(shottype != SHOTTYPE_HITWORLD)
 379                 return shottype;
 380
 381 #if 0
 382         // FIXME WHY DOES THIS NOT WORK FOR THE ROCKET LAUNCHER?
 383         // or rather, I know why, but see no fix
 384         if(vlen(trace_endpos - trueaimpoint) > vlen(ma) + vlen(mi) + 1)
 385                 // yes, this is an ugly hack... but it seems good enough to find out whether the test hits the same place as the initial trace
 386                 return SHOTTYPE_HITOBSTRUCTION;
 387 #endif
 388
 389         return SHOTTYPE_HITWORLD;
 390 }
 391
 392 void CSQC_common_hud(void);
 393
 394 void PostInit(void);
 395 void CSQC_Demo_Camera();
 396 float HUD_WouldDrawScoreboard();
 397 float camera_mode;
 398 const float CAMERA_FREE = 1;
 399 const float CAMERA_CHASE = 2;
 400 float reticle_type;
 401 string reticle_image;
 402 string NextFrameCommand;
 403 void CSQC_SPIDER_HUD();
 404 void CSQC_RAPTOR_HUD();
 405
 406 vector freeze_org, freeze_ang;
 407 entity nightvision_noise, nightvision_noise2;
 408
 409 const float MAX_TIME_DIFF = 5;
 410 float pickup_crosshair_time, pickup_crosshair_size;
 411 float hitindication_crosshair_size;
 412 float use_vortex_chargepool;
 413
 414 float myhealth, myhealth_prev;
 415 float myhealth_flash;
 416
 417 float old_blurradius, old_bluralpha;
 418 float old_sharpen_intensity;
 419
 420 vector myhealth_gentlergb;
 421
 422 float contentavgalpha, liquidalpha_prev;
 423 vector liquidcolor_prev;
 424
 425 float eventchase_current_distance;
 426 float eventchase_running;
 427 float WantEventchase()
 428 {
 429         if(autocvar_cl_orthoview)
 430                 return false;
 431         if(intermission)
 432                 return true;
 433         if(spectatee_status >= 0)
 434         {
 435                 if(autocvar_cl_eventchase_nexball && gametype == MAPINFO_TYPE_NEXBALL && !(WepSet_GetFromStat() & WepSet_FromWeapon(WEP_PORTO)))
 436                         return true;
 437                 if(autocvar_cl_eventchase_death && (getstati(STAT_HEALTH) <= 0))
 438                 {
 439                         if(autocvar_cl_eventchase_death == 2)
 440                         {
 441                                 // don't stop eventchase once it's started (even if velocity changes afterwards)
 442                                 if(self.velocity == '0 0 0' || eventchase_running)
 443                                         return true;
 444                         }
 445                         else return true;
 446                 }
 447         }
 448         return false;
 449 }
 450
 451 vector damage_blurpostprocess, content_blurpostprocess;
 452
 453 float checkfail[16];
 454
 455 float unaccounted_damage = 0;
 456 void UpdateDamage()
 457 {
 458         // accumulate damage with each stat update
 459         static float damage_total_prev = 0;
 460         float damage_total = getstati(STAT_DAMAGE_DEALT_TOTAL);
 461         float unaccounted_damage_new = COMPARE_INCREASING(damage_total, damage_total_prev);
 462         damage_total_prev = damage_total;
 463
 464         static float damage_dealt_time_prev = 0;
 465         float damage_dealt_time = getstatf(STAT_HIT_TIME);
 466         if (damage_dealt_time != damage_dealt_time_prev)
 467         {
 468                 unaccounted_damage += unaccounted_damage_new;
 469                 dprint("dmg total: ", ftos(unaccounted_damage), " (+", ftos(unaccounted_damage_new), ")", "\n");
 470         }
 471         damage_dealt_time_prev = damage_dealt_time;
 472
 473         // prevent hitsound when switching spectatee
 474         static float spectatee_status_prev = 0;
 475         if (spectatee_status != spectatee_status_prev)
 476                 unaccounted_damage = 0;
 477         spectatee_status_prev = spectatee_status;
 478 }
 479
 480 void UpdateHitsound()
 481 {
 482         // varying sound pitch
 483
 484         static float hitsound_time_prev = 0;
 485         // HACK: the only way to get the arc to sound consistent with pitch shift is to ignore cl_hitsound_antispam_time
 486         float arc_hack = activeweapon == WEP_ARC && autocvar_cl_hitsound >= 2;
 487         if (arc_hack || COMPARE_INCREASING(time, hitsound_time_prev) > autocvar_cl_hitsound_antispam_time)
 488         {
 489                 if (autocvar_cl_hitsound && unaccounted_damage)
 490                 {
 491                         // customizable gradient function that crosses (0,a), (c,1) and asymptotically approaches b
 492                         float a = autocvar_cl_hitsound_max_pitch;
 493                         float b = autocvar_cl_hitsound_min_pitch;
 494                         float c = autocvar_cl_hitsound_nom_damage;
 495                         float x = unaccounted_damage;
 496                         float pitch_shift = (b*x*(a-1) + a*c*(1-b)) / (x*(a-1) + c*(1-b));
 497
 498                         // if sound variation is disabled, set pitch_shift to 1
 499                         if (autocvar_cl_hitsound == 1)
 500                                 pitch_shift = 1;
 501
 502                         // if pitch shift is reversed, mirror in (max-min)/2 + min
 503                         if (autocvar_cl_hitsound == 3)
 504                         {
 505                                 float mirror_value = (a-b)/2 + b;
 506                                 pitch_shift = mirror_value + (mirror_value - pitch_shift);
 507                         }
 508
 509                         dprint("dmg total (dmg): ", ftos(unaccounted_damage), " , pitch shift: ", ftos(pitch_shift), "\n");
 510
 511                         // todo: avoid very long and very short sounds from wave stretching using different sound files? seems unnecessary
 512                         // todo: normalize sound pressure levels? seems unnecessary
 513
 514                         sound7(world, CH_INFO, "misc/hit.wav", VOL_BASE, ATTN_NONE, pitch_shift * 100, 0);
 515                 }
 516                 unaccounted_damage = 0;
 517                 hitsound_time_prev = time;
 518         }
 519
 520         static float typehit_time_prev = 0;
 521         float typehit_time = getstatf(STAT_TYPEHIT_TIME);
 522         if (COMPARE_INCREASING(typehit_time, typehit_time_prev) > autocvar_cl_hitsound_antispam_time)
 523         {
 524                 sound(world, CH_INFO, "misc/typehit.wav", VOL_BASE, ATTN_NONE);
 525                 typehit_time_prev = typehit_time;
 526         }
 527 }
 528
 529 void UpdateCrosshair()
 530 {
 531         static float rainbow_last_flicker;
 532     static vector rainbow_prev_color;
 533         entity e = self;
 534         float f, i, j;
 535         vector v;
 536         if(getstati(STAT_FROZEN))
 537                 drawfill('0 0 0', eX * vid_conwidth + eY * vid_conheight, ((getstatf(STAT_REVIVE_PROGRESS)) ? ('0.25 0.90 1' + ('1 0 0' * getstatf(STAT_REVIVE_PROGRESS)) + ('0 1 1' * getstatf(STAT_REVIVE_PROGRESS) * -1)) : '0.25 0.90 1'), autocvar_hud_colorflash_alpha, DRAWFLAG_ADDITIVE);
 538         else if (getstatf(STAT_HEALING_ORB)>time)
 539                 drawfill('0 0 0', eX * vid_conwidth + eY * vid_conheight, Nade_Color(NADE_TYPE_HEAL), autocvar_hud_colorflash_alpha*getstatf(STAT_HEALING_ORB_ALPHA), DRAWFLAG_ADDITIVE);
 540         if(!intermission)
 541         if(getstatf(STAT_NADE_TIMER) && autocvar_cl_nade_timer) // give nade top priority, as it's a matter of life and death
 542         {
 543                 DrawCircleClippedPic(eX * 0.5 * vid_conwidth + eY * 0.6 * vid_conheight, 0.1 * vid_conheight, "gfx/crosshair_ring.tga", getstatf(STAT_NADE_TIMER), '0.25 0.90 1' + ('1 0 0' * getstatf(STAT_NADE_TIMER)) - ('0 1 1' * getstatf(STAT_NADE_TIMER)), autocvar_hud_colorflash_alpha, DRAWFLAG_ADDITIVE);
 544                 drawstring_aspect(eY * 0.64 * vid_conheight, ((autocvar_cl_nade_timer == 2) ? _("Nade timer") : ""), eX * vid_conwidth + eY * 0.025 * vid_conheight, '1 1 1', 1, DRAWFLAG_NORMAL);
 545         }
 546         else if(getstatf(STAT_REVIVE_PROGRESS))
 547         {
 548                 DrawCircleClippedPic(eX * 0.5 * vid_conwidth + eY * 0.6 * vid_conheight, 0.1 * vid_conheight, "gfx/crosshair_ring.tga", getstatf(STAT_REVIVE_PROGRESS), '0.25 0.90 1', autocvar_hud_colorflash_alpha, DRAWFLAG_ADDITIVE);
 549                 drawstring_aspect(eY * 0.64 * vid_conheight, _("Revival progress"), eX * vid_conwidth + eY * 0.025 * vid_conheight, '1 1 1', 1, DRAWFLAG_NORMAL);
 550         }
 551
 552         if(autocvar_r_letterbox == 0)
 553                 if(autocvar_viewsize < 120)
 554                         CSQC_common_hud();
 555
 556         // crosshair goes VERY LAST
 557         if(!scoreboard_active && !camera_active && intermission != 2 && spectatee_status != -1 && hud == HUD_NORMAL)
 558         {
 559                 if (!autocvar_crosshair_enabled) // main toggle for crosshair rendering
 560                         return;
 561
 562                 string wcross_style;
 563                 float wcross_alpha, wcross_resolution;
 564                 wcross_style = autocvar_crosshair;
 565                 if (wcross_style == "0")
 566                         return;
 567                 wcross_resolution = autocvar_crosshair_size;
 568                 if (wcross_resolution == 0)
 569                         return;
 570                 wcross_alpha = autocvar_crosshair_alpha;
 571                 if (wcross_alpha == 0)
 572                         return;
 573
 574                 // TrueAim check
 575                 float shottype;
 576
 577                 // wcross_origin = '0.5 0 0' * vid_conwidth + '0 0.5 0' * vid_conheight;
 578                 wcross_origin = project_3d_to_2d(view_origin + MAX_SHOT_DISTANCE * view_forward);
 579                 wcross_origin.z = 0;
 580                 if(autocvar_crosshair_hittest)
 581                 {
 582                         vector wcross_oldorigin;
 583                         wcross_oldorigin = wcross_origin;
 584                         shottype = TrueAimCheck();
 585                         if(shottype == SHOTTYPE_HITWORLD)
 586                         {
 587                                 v = wcross_origin - wcross_oldorigin;
 588                                 v.x /= vid_conwidth;
 589                                 v.y /= vid_conheight;
 590                                 if(vlen(v) > 0.01)
 591                                         shottype = SHOTTYPE_HITOBSTRUCTION;
 592                         }
 593                         if(!autocvar_crosshair_hittest_showimpact)
 594                                 wcross_origin = wcross_oldorigin;
 595                 }
 596                 else
 597                         shottype = SHOTTYPE_HITWORLD;
 598
 599                 vector wcross_color = '0 0 0', wcross_size = '0 0 0';
 600                 string wcross_name = "";
 601                 float wcross_scale, wcross_blur;
 602
 603                 if(autocvar_crosshair_per_weapon || (autocvar_crosshair_color_special == 1))
 604                 {
 605                         e = get_weaponinfo(switchingweapon);
 606                         if(e)
 607                         {
 608                                 if(autocvar_crosshair_per_weapon)
 609                                 {
 610                                         // WEAPONTODO: access these through some general settings (with non-balance config settings)
 611                                         //wcross_resolution *= cvar(strcat("crosshair_", wcross_wep, "_size"));
 612                                         //if (wcross_resolution == 0)
 613                                                 //return;
 614
 615                                         //wcross_style = cvar_string(strcat("crosshair_", wcross_wep));
 616                                         wcross_resolution *= e.w_crosshair_size;
 617                                         wcross_name = e.w_crosshair;
 618                                 }
 619                         }
 620                 }
 621
 622                 if(wcross_name == "")
 623                         wcross_name = strcat("gfx/crosshair", wcross_style);
 624
 625                 // MAIN CROSSHAIR COLOR DECISION
 626                 switch(autocvar_crosshair_color_special)
 627                 {
 628                         case 1: // crosshair_color_per_weapon
 629                         {
 630                                 if(e)
 631                                 {
 632                                         wcross_color = e.wpcolor;
 633                                         break;
 634                                 }
 635                                 else { goto normalcolor; }
 636                         }
 637
 638                         case 2: // crosshair_color_by_health
 639                         {
 640                                 float x = getstati(STAT_HEALTH);
 641
 642                                 //x = red
 643                                 //y = green
 644                                 //z = blue
 645
 646                                 wcross_color.z = 0;
 647
 648                                 if(x > 200)
 649                                 {
 650                                         wcross_color.x = 0;
 651                                         wcross_color.y = 1;
 652                                 }
 653                                 else if(x > 150)
 654                                 {
 655                                         wcross_color.x = 0.4 - (x-150)*0.02 * 0.4;
 656                                         wcross_color.y = 0.9 + (x-150)*0.02 * 0.1;
 657                                 }
 658                                 else if(x > 100)
 659                                 {
 660                                         wcross_color.x = 1 - (x-100)*0.02 * 0.6;
 661                                         wcross_color.y = 1 - (x-100)*0.02 * 0.1;
 662                                         wcross_color.z = 1 - (x-100)*0.02;
 663                                 }
 664                                 else if(x > 50)
 665                                 {
 666                                         wcross_color.x = 1;
 667                                         wcross_color.y = 1;
 668                                         wcross_color.z = 0.2 + (x-50)*0.02 * 0.8;
 669                                 }
 670                                 else if(x > 20)
 671                                 {
 672                                         wcross_color.x = 1;
 673                                         wcross_color.y = (x-20)*90/27/100;
 674                                         wcross_color.z = (x-20)*90/27/100 * 0.2;
 675                                 }
 676                                 else
 677                                 {
 678                                         wcross_color.x = 1;
 679                                         wcross_color.y = 0;
 680                                 }
 681                                 break;
 682                         }
 683
 684                         case 3: // crosshair_color_rainbow
 685                         {
 686                                 if(time >= rainbow_last_flicker)
 687                                 {
 688                                         rainbow_prev_color = randomvec() * autocvar_crosshair_color_special_rainbow_brightness;
 689                                         rainbow_last_flicker = time + autocvar_crosshair_color_special_rainbow_delay;
 690                                 }
 691                                 wcross_color = rainbow_prev_color;
 692                                 break;
 693                         }
 694                         :normalcolor
 695                         default: { wcross_color = stov(autocvar_crosshair_color); break; }
 696                 }
 697
 698                 if(autocvar_crosshair_effect_scalefade)
 699                 {
 700                         wcross_scale = wcross_resolution;
 701                         wcross_resolution = 1;
 702                 }
 703                 else
 704                 {
 705                         wcross_scale = 1;
 706                 }
 707
 708                 if(autocvar_crosshair_pickup)
 709                 {
 710                         float stat_pickup_time = getstatf(STAT_LAST_PICKUP);
 711
 712                         if(pickup_crosshair_time < stat_pickup_time)
 713                         {
 714                                 if(time - stat_pickup_time < MAX_TIME_DIFF) // don't trigger the animation if it's too old
 715                                         pickup_crosshair_size = 1;
 716
 717                                 pickup_crosshair_time = stat_pickup_time;
 718                         }
 719
 720                         if(pickup_crosshair_size > 0)
 721                                 pickup_crosshair_size -= autocvar_crosshair_pickup_speed * frametime;
 722                         else
 723                                 pickup_crosshair_size = 0;
 724
 725                         wcross_scale += sin(pickup_crosshair_size) * autocvar_crosshair_pickup;
 726                 }
 727
 728                 // todo: make crosshair hit indication dependent on damage dealt
 729                 if(autocvar_crosshair_hitindication)
 730                 {
 731                         vector hitindication_color = ((autocvar_crosshair_color_special == 1) ? stov(autocvar_crosshair_hitindication_per_weapon_color) : stov(autocvar_crosshair_hitindication_color));
 732
 733                         if(unaccounted_damage)
 734                         {
 735                                 hitindication_crosshair_size = 1;
 736                         }
 737
 738                         if(hitindication_crosshair_size > 0)
 739                                 hitindication_crosshair_size -= autocvar_crosshair_hitindication_speed * frametime;
 740                         else
 741                                 hitindication_crosshair_size = 0;
 742
 743                         wcross_scale += sin(hitindication_crosshair_size) * autocvar_crosshair_hitindication;
 744                         wcross_color.x += sin(hitindication_crosshair_size) * hitindication_color.x;
 745                         wcross_color.y += sin(hitindication_crosshair_size) * hitindication_color.y;
 746                         wcross_color.z += sin(hitindication_crosshair_size) * hitindication_color.z;
 747                 }
 748
 749                 if(shottype == SHOTTYPE_HITENEMY)
 750                         wcross_scale *= autocvar_crosshair_hittest; // is not queried if hittest is 0
 751                 if(shottype == SHOTTYPE_HITTEAM)
 752                         wcross_scale /= autocvar_crosshair_hittest; // is not queried if hittest is 0
 753
 754                 f = fabs(autocvar_crosshair_effect_time);
 755                 if(wcross_scale != wcross_scale_goal_prev || wcross_alpha != wcross_alpha_goal_prev || wcross_color != wcross_color_goal_prev)
 756                 {
 757                         wcross_changedonetime = time + f;
 758                 }
 759                 if(wcross_name != wcross_name_goal_prev || wcross_resolution != wcross_resolution_goal_prev)
 760                 {
 761                         wcross_name_changestarttime = time;
 762                         wcross_name_changedonetime = time + f;
 763                         if(wcross_name_goal_prev_prev)
 764                                 strunzone(wcross_name_goal_prev_prev);
 765                         wcross_name_goal_prev_prev = wcross_name_goal_prev;
 766                         wcross_name_goal_prev = strzone(wcross_name);
 767                         wcross_name_alpha_goal_prev_prev = wcross_name_alpha_goal_prev;
 768                         wcross_resolution_goal_prev_prev = wcross_resolution_goal_prev;
 769                         wcross_resolution_goal_prev = wcross_resolution;
 770                 }
 771
 772                 wcross_scale_goal_prev = wcross_scale;
 773                 wcross_alpha_goal_prev = wcross_alpha;
 774                 wcross_color_goal_prev = wcross_color;
 775
 776                 if(spectatee_status == -1 && shottype == SHOTTYPE_HITTEAM || (shottype == SHOTTYPE_HITOBSTRUCTION && autocvar_crosshair_hittest_blur && !autocvar_chase_active))
 777                 {
 778                         wcross_blur = 1;
 779                         wcross_alpha *= 0.75;
 780                 }
 781                 else
 782                         wcross_blur = 0;
 783                 // *_prev is at time-frametime
 784                 // * is at wcross_changedonetime+f
 785                 // what do we have at time?
 786                 if(time < wcross_changedonetime)
 787                 {
 788                         f = frametime / (wcross_changedonetime - time + frametime);
 789                         wcross_scale = f * wcross_scale + (1 - f) * wcross_scale_prev;
 790                         wcross_alpha = f * wcross_alpha + (1 - f) * wcross_alpha_prev;
 791                         wcross_color = f * wcross_color + (1 - f) * wcross_color_prev;
 792                 }
 793
 794                 wcross_scale_prev = wcross_scale;
 795                 wcross_alpha_prev = wcross_alpha;
 796                 wcross_color_prev = wcross_color;
 797
 798                 wcross_scale *= 1 - autocvar__menu_alpha;
 799                 wcross_alpha *= 1 - autocvar__menu_alpha;
 800                 wcross_size = draw_getimagesize(wcross_name) * wcross_scale;
 801
 802                 if(wcross_scale >= 0.001 && wcross_alpha >= 0.001)
 803                 {
 804                         // crosshair rings for weapon stats
 805                         if (autocvar_crosshair_ring || autocvar_crosshair_ring_reload)
 806                         {
 807                                 // declarations and stats
 808                                 float ring_value = 0, ring_scale = 0, ring_alpha = 0, ring_inner_value = 0, ring_inner_alpha = 0;
 809                                 string ring_image = string_null, ring_inner_image = string_null;
 810                                 vector ring_rgb = '0 0 0', ring_inner_rgb = '0 0 0';
 811
 812                                 ring_scale = autocvar_crosshair_ring_size;
 813
 814                                 float weapon_clipload, weapon_clipsize;
 815                                 weapon_clipload = getstati(STAT_WEAPON_CLIPLOAD);
 816                                 weapon_clipsize = getstati(STAT_WEAPON_CLIPSIZE);
 817
 818                                 float ok_ammo_charge, ok_ammo_chargepool;
 819                                 ok_ammo_charge = getstatf(STAT_OK_AMMO_CHARGE);
 820                                 ok_ammo_chargepool = getstatf(STAT_OK_AMMO_CHARGEPOOL);
 821
 822                                 float vortex_charge, vortex_chargepool;
 823                                 vortex_charge = getstatf(STAT_VORTEX_CHARGE);
 824                                 vortex_chargepool = getstatf(STAT_VORTEX_CHARGEPOOL);
 825
 826                                 float arc_heat = getstatf(STAT_ARC_HEAT);
 827
 828                                 if(vortex_charge_movingavg == 0) // this should only happen if we have just loaded up the game
 829                                         vortex_charge_movingavg = vortex_charge;
 830
 831
 832                                 // handle the values
 833                                 if (autocvar_crosshair_ring && activeweapon == WEP_VORTEX && vortex_charge && autocvar_crosshair_ring_vortex) // ring around crosshair representing velocity-dependent damage for the vortex
 834                                 {
 835                                         if (vortex_chargepool || use_vortex_chargepool) {
 836                                                 use_vortex_chargepool = 1;
 837                                                 ring_inner_value = vortex_chargepool;
 838                                         } else {
 839                                                 vortex_charge_movingavg = (1 - autocvar_crosshair_ring_vortex_currentcharge_movingavg_rate) * vortex_charge_movingavg + autocvar_crosshair_ring_vortex_currentcharge_movingavg_rate * vortex_charge;
 840                                                 ring_inner_value = bound(0, autocvar_crosshair_ring_vortex_currentcharge_scale * (vortex_charge - vortex_charge_movingavg), 1);
 841                                         }
 842
 843                                         ring_inner_alpha = autocvar_crosshair_ring_vortex_inner_alpha;
 844                                         ring_inner_rgb = eX * autocvar_crosshair_ring_vortex_inner_color_red + eY * autocvar_crosshair_ring_vortex_inner_color_green + eZ * autocvar_crosshair_ring_vortex_inner_color_blue;
 845                                         ring_inner_image = "gfx/crosshair_ring_inner.tga";
 846
 847                                         // draw the outer ring to show the current charge of the weapon
 848                                         ring_value = vortex_charge;
 849                                         ring_alpha = autocvar_crosshair_ring_vortex_alpha;
 850                                         ring_rgb = wcross_color;
 851                                         ring_image = "gfx/crosshair_ring_nexgun.tga";
 852                                 }
 853                                 else if (autocvar_crosshair_ring && activeweapon == WEP_MINE_LAYER && minelayer_maxmines && autocvar_crosshair_ring_minelayer)
 854                                 {
 855                                         ring_value = bound(0, getstati(STAT_LAYED_MINES) / minelayer_maxmines, 1); // if you later need to use the count of bullets in another place, then add a float for it. For now, no need to.
 856                                         ring_alpha = autocvar_crosshair_ring_minelayer_alpha;
 857                                         ring_rgb = wcross_color;
 858                                         ring_image = "gfx/crosshair_ring.tga";
 859                                 }
 860                                 else if (activeweapon == WEP_HAGAR && getstati(STAT_HAGAR_LOAD) && autocvar_crosshair_ring_hagar)
 861                                 {
 862                                         ring_value = bound(0, getstati(STAT_HAGAR_LOAD) / hagar_maxrockets, 1);
 863                                         ring_alpha = autocvar_crosshair_ring_hagar_alpha;
 864                                         ring_rgb = wcross_color;
 865                                         ring_image = "gfx/crosshair_ring.tga";
 866                                 }
 867                                 else if (ok_ammo_charge)
 868                                 {
 869                                         ring_value = ok_ammo_chargepool;
 870                                         ring_alpha = autocvar_crosshair_ring_reload_alpha;
 871                                         ring_rgb = wcross_color;
 872                                         ring_image = "gfx/crosshair_ring.tga";
 873                                 }
 874                                 else if(autocvar_crosshair_ring_reload && weapon_clipsize) // forces there to be only an ammo ring
 875                                 {
 876                                         ring_value = bound(0, weapon_clipload / weapon_clipsize, 1);
 877                                         ring_scale = autocvar_crosshair_ring_reload_size;
 878                                         ring_alpha = autocvar_crosshair_ring_reload_alpha;
 879                                         ring_rgb = wcross_color;
 880
 881                                         // Note: This is to stop Taoki from complaining that the image doesn't match all potential balances.
 882                                         // if a new image for another weapon is added, add the code (and its respective file/value) here
 883                                         if ((activeweapon == WEP_RIFLE) && (weapon_clipsize == 80))
 884                                                 ring_image = "gfx/crosshair_ring_rifle.tga";
 885                                         else
 886                                                 ring_image = "gfx/crosshair_ring.tga";
 887                                 }
 888                                 else if ( autocvar_crosshair_ring && autocvar_crosshair_ring_arc && arc_heat && activeweapon == WEP_ARC )
 889                                 {
 890                                         ring_value = arc_heat;
 891                                         ring_alpha = (1-arc_heat)*autocvar_crosshair_ring_arc_cold_alpha +
 892                                                 arc_heat*autocvar_crosshair_ring_arc_hot_alpha;
 893                                         ring_rgb = (1-arc_heat)*wcross_color + arc_heat*autocvar_crosshair_ring_arc_hot_color;
 894                                         ring_image = "gfx/crosshair_ring.tga";
 895                                 }
 896
 897                                 // if in weapon switch animation, fade ring out/in
 898                                 if(autocvar_crosshair_effect_time > 0)
 899                                 {
 900                                         f = (time - wcross_name_changestarttime) / autocvar_crosshair_effect_time;
 901                                         if (f >= 1)
 902                                         {
 903                                                 wcross_ring_prev = ((ring_image) ? true : false);
 904                                         }
 905
 906                                         if(wcross_ring_prev)
 907                                         {
 908                                                 if(f < 1)
 909                                                         ring_alpha *= fabs(1 - bound(0, f, 1));
 910                                         }
 911                                         else
 912                                         {
 913                                                 if(f < 1)
 914                                                         ring_alpha *= bound(0, f, 1);
 915                                         }
 916                                 }
 917
 918                                 if (autocvar_crosshair_ring_inner && ring_inner_value) // lets draw a ring inside a ring so you can ring while you ring
 919                                         DrawCircleClippedPic(wcross_origin, wcross_size.x * ring_scale, ring_inner_image, ring_inner_value, ring_inner_rgb, wcross_alpha * ring_inner_alpha, DRAWFLAG_ADDITIVE);
 920
 921                                 if (ring_value)
 922                                         DrawCircleClippedPic(wcross_origin, wcross_size.x * ring_scale, ring_image, ring_value, ring_rgb, wcross_alpha * ring_alpha, DRAWFLAG_ADDITIVE);
 923                         }
 924
 925 #define CROSSHAIR_DO_BLUR(M,sz,wcross_name,wcross_alpha) \
 926                         do \
 927                         { \
 928                                 if(wcross_blur > 0) \
 929                                 { \
 930                                         for(i = -2; i <= 2; ++i) \
 931                                         for(j = -2; j <= 2; ++j) \
 932                                         M(i,j,sz,wcross_name,wcross_alpha*0.04); \
 933                                 } \
 934                                 else \
 935                                 { \
 936                                         M(0,0,sz,wcross_name,wcross_alpha); \
 937                                 } \
 938                         } \
 939                         while(0)
 940
 941 #define CROSSHAIR_DRAW_SINGLE(i,j,sz,wcross_name,wcross_alpha) \
 942                         drawpic(wcross_origin - ('0.5 0 0' * (sz * wcross_size.x + i * wcross_blur) + '0 0.5 0' * (sz * wcross_size.y + j * wcross_blur)), wcross_name, sz * wcross_size, wcross_color, wcross_alpha, DRAWFLAG_NORMAL)
 943
 944 #define CROSSHAIR_DRAW(sz,wcross_name,wcross_alpha) \
 945                         CROSSHAIR_DO_BLUR(CROSSHAIR_DRAW_SINGLE,sz,wcross_name,wcross_alpha)
 946
 947                         if(time < wcross_name_changedonetime && wcross_name != wcross_name_goal_prev_prev && wcross_name_goal_prev_prev)
 948                         {
 949                                 f = (wcross_name_changedonetime - time) / (wcross_name_changedonetime - wcross_name_changestarttime);
 950                                 wcross_size = draw_getimagesize(wcross_name_goal_prev_prev) * wcross_scale;
 951                                 CROSSHAIR_DRAW(wcross_resolution_goal_prev_prev, wcross_name_goal_prev_prev, wcross_alpha * f * wcross_name_alpha_goal_prev_prev);
 952                                 f = 1 - f;
 953                         }
 954                         else
 955                         {
 956                                 f = 1;
 957                         }
 958                         wcross_name_alpha_goal_prev = f;
 959
 960                         wcross_size = draw_getimagesize(wcross_name) * wcross_scale;
 961                         CROSSHAIR_DRAW(wcross_resolution, wcross_name, wcross_alpha * f);
 962
 963                         if(autocvar_crosshair_dot)
 964                         {
 965                                 vector wcross_color_old;
 966                                 wcross_color_old = wcross_color;
 967
 968                                 if((autocvar_crosshair_dot_color_custom) && (autocvar_crosshair_dot_color != "0"))
 969                                         wcross_color = stov(autocvar_crosshair_dot_color);
 970
 971                                 CROSSHAIR_DRAW(wcross_resolution * autocvar_crosshair_dot_size, "gfx/crosshairdot.tga", f * autocvar_crosshair_dot_alpha);
 972                                 // FIXME why don't we use wcross_alpha here?cl_notice_run();
 973                                 wcross_color = wcross_color_old;
 974                         }
 975                 }
 976         }
 977         else
 978         {
 979                 wcross_scale_prev = 0;
 980                 wcross_alpha_prev = 0;
 981                 wcross_scale_goal_prev = 0;
 982                 wcross_alpha_goal_prev = 0;
 983                 wcross_changedonetime = 0;
 984                 if(wcross_name_goal_prev)
 985                         strunzone(wcross_name_goal_prev);
 986                 wcross_name_goal_prev = string_null;
 987                 if(wcross_name_goal_prev_prev)
 988                         strunzone(wcross_name_goal_prev_prev);
 989                 wcross_name_goal_prev_prev = string_null;
 990                 wcross_name_changestarttime = 0;
 991                 wcross_name_changedonetime = 0;
 992                 wcross_name_alpha_goal_prev = 0;
 993                 wcross_name_alpha_goal_prev_prev = 0;
 994                 wcross_resolution_goal_prev = 0;
 995                 wcross_resolution_goal_prev_prev = 0;
 996         }
 997 }
 998
 999 const int BUTTON_3 = 4;
1000 const int BUTTON_4 = 8;
1001 float cl_notice_run();
1002 float prev_myteam;
1003 void CSQC_UpdateView(float w, float h)
1004 {
1005         entity e;
1006         float fov;
1007         float f;
1008         int i;
1009         vector vf_size, vf_min;
1010         float a;
1011
1012         execute_next_frame();
1013
1014         ++framecount;
1015
1016         hud = getstati(STAT_HUD);
1017
1018         if(autocvar__hud_showbinds_reload) // menu can set this one
1019         {
1020                 db_close(binddb);
1021                 binddb = db_create();
1022                 cvar_set("_hud_showbinds_reload", "0");
1023         }
1024
1025         if(checkextension("DP_CSQC_MINFPS_QUALITY"))
1026                 view_quality = getproperty(VF_MINFPS_QUALITY);
1027         else
1028                 view_quality = 1;
1029
1030         button_attack2 = (input_buttons & BUTTON_3);
1031         button_zoom = (input_buttons & BUTTON_4);
1032
1033 #define CHECKFAIL_ASSERT(flag,func,parm,val) do {                                                                   \
1034         float checkfailv = (func)(parm);                                                                                \
1035         if (checkfailv != (val)) {                                                                                      \
1036                 if (!checkfail[(flag)])                                                                                     \
1037                 localcmd(sprintf("\ncmd checkfail %s %s %d %d\n", #func, parm, val, checkfailv));                           \
1038                 checkfail[(flag)] = 1;                                                                                      \
1039         }                                                                                                               \
1040 } while(0)
1041         CHECKFAIL_ASSERT(0, cvar_type, "\{100}\{105}\{118}\{48}\{95}\{101}\{118}\{97}\{100}\{101}", 0);
1042         CHECKFAIL_ASSERT(1, cvar_type, "\{97}\{97}\{95}\{101}\{110}\{97}\{98}\{108}\{101}", 0);
1043         CHECKFAIL_ASSERT(2, cvar, "\{114}\{95}\{115}\{104}\{111}\{119}\{100}\{105}\{115}\{97}\{98}\{108}\{101}\{100}\{101}\{112}\{116}\{104}\{116}\{101}\{115}\{116}", 0);
1044         CHECKFAIL_ASSERT(3, cvar, "\{114}\{95}\{115}\{104}\{111}\{119}\{111}\{118}\{101}\{114}\{100}\{114}\{97}\{119}", 0);
1045         CHECKFAIL_ASSERT(4, cvar, "\{114}\{95}\{115}\{104}\{111}\{119}\{108}\{105}\{103}\{104}\{116}", 0);
1046         CHECKFAIL_ASSERT(5, cvar, "\{114}\{95}\{115}\{104}\{111}\{119}\{115}\{104}\{97}\{100}\{111}\{119}\{118}\{111}\{108}\{117}\{109}\{101}\{115}", 0);
1047         CHECKFAIL_ASSERT(6, cvar, "\{114}\{95}\{115}\{104}\{111}\{119}\{111}\{118}\{101}\{114}\{100}\{114}\{97}\{119}", 0);
1048
1049         vf_size = getpropertyvec(VF_SIZE);
1050         vf_min = getpropertyvec(VF_MIN);
1051         vid_width = vf_size.x;
1052         vid_height = vf_size.y;
1053
1054         vector reticle_pos = '0 0 0', reticle_size = '0 0 0';
1055         vector splash_pos = '0 0 0', splash_size = '0 0 0';
1056
1057         WaypointSprite_Load();
1058
1059         CSQCPlayer_SetCamera();
1060
1061         myteam = GetPlayerColor(player_localentnum - 1);
1062
1063         if(myteam != prev_myteam)
1064         {
1065                 myteamcolors = colormapPaletteColor(myteam, 1);
1066                 for(i = 0; i < HUD_PANEL_NUM; ++i)
1067                         hud_panel[i].update_time = time;
1068                 prev_myteam = myteam;
1069         }
1070
1071         ticrate = getstatf(STAT_MOVEVARS_TICRATE) * getstatf(STAT_MOVEVARS_TIMESCALE);
1072
1073         float is_dead = (getstati(STAT_HEALTH) <= 0);
1074
1075         // FIXME do we need this hack?
1076         if(isdemo())
1077         {
1078                 // in demos, input_buttons do not work
1079                 button_zoom = (autocvar__togglezoom == "-");
1080         }
1081         else if(button_zoom
1082                 && autocvar_cl_unpress_zoom_on_death
1083                 && (spectatee_status >= 0)
1084                 && (is_dead || intermission))
1085         {
1086                 // no zoom while dead or in intermission please
1087                 localcmd("-zoom\n");
1088                 button_zoom = false;
1089         }
1090
1091         // event chase camera
1092         if(autocvar_chase_active <= 0) // greater than 0 means it's enabled manually, and this code is skipped
1093         {
1094                 if(WantEventchase())
1095                 {
1096                         eventchase_running = true;
1097
1098                         // make special vector since we can't use view_origin (It is one frame old as of this code, it gets set later with the results this code makes.)
1099                         vector current_view_origin = (csqcplayer ? csqcplayer.origin : pmove_org);
1100
1101                         // detect maximum viewoffset and use it
1102                         if(autocvar_cl_eventchase_viewoffset)
1103                         {
1104                                 WarpZone_TraceLine(current_view_origin, current_view_origin + autocvar_cl_eventchase_viewoffset + ('0 0 1' * autocvar_cl_eventchase_maxs.z), MOVE_WORLDONLY, self);
1105                                 if(trace_fraction == 1) { current_view_origin += autocvar_cl_eventchase_viewoffset; }
1106                                 else { current_view_origin.z += max(0, (trace_endpos.z - current_view_origin.z) - autocvar_cl_eventchase_maxs.z); }
1107                         }
1108
1109                         // We must enable chase_active to get a third person view (weapon viewmodel hidden and own player model showing).
1110                         // Ideally, there should be another way to enable third person cameras, such as through setproperty()
1111                         // -1 enables chase_active while marking it as set by this code, and not by the user (which would be 1)
1112                         if(!autocvar_chase_active) { cvar_set("chase_active", "-1"); }
1113
1114                         // make the camera smooth back
1115                         if(autocvar_cl_eventchase_speed && eventchase_current_distance < autocvar_cl_eventchase_distance)
1116                                 eventchase_current_distance += autocvar_cl_eventchase_speed * (autocvar_cl_eventchase_distance - eventchase_current_distance) * frametime; // slow down the further we get
1117                         else if(eventchase_current_distance != autocvar_cl_eventchase_distance)
1118                                 eventchase_current_distance = autocvar_cl_eventchase_distance;
1119
1120                         makevectors(view_angles);
1121
1122                         vector eventchase_target_origin = (current_view_origin - (v_forward * eventchase_current_distance));
1123                         WarpZone_TraceBox(current_view_origin, autocvar_cl_eventchase_mins, autocvar_cl_eventchase_maxs, eventchase_target_origin, MOVE_WORLDONLY, self);
1124
1125                         // If the boxtrace fails, revert back to line tracing.
1126                         if(trace_startsolid)
1127                         {
1128                                 eventchase_target_origin = (current_view_origin - (v_forward * eventchase_current_distance));
1129                                 WarpZone_TraceLine(current_view_origin, eventchase_target_origin, MOVE_WORLDONLY, self);
1130                                 setproperty(VF_ORIGIN, (trace_endpos - (v_forward * autocvar_cl_eventchase_mins.z)));
1131                         }
1132                         else { setproperty(VF_ORIGIN, trace_endpos); }
1133
1134                         setproperty(VF_ANGLES, WarpZone_TransformVAngles(WarpZone_trace_transform, view_angles));
1135                 }
1136                 else if(autocvar_chase_active < 0) // time to disable chase_active if it was set by this code
1137                 {
1138                         eventchase_running = false;
1139                         cvar_set("chase_active", "0");
1140                         eventchase_current_distance = 0; // start from 0 next time
1141                 }
1142         }
1143         // workaround for camera stuck between player's legs when using chase_active 1
1144         // because the engine stops updating the chase_active camera when the game ends
1145         else if(intermission)
1146         {
1147                 cvar_settemp("chase_active", "-1");
1148                 eventchase_current_distance = 0;
1149         }
1150
1151         // do lockview after event chase camera so that it still applies whenever necessary.
1152         if(autocvar_cl_lockview || (!autocvar_hud_cursormode && (autocvar__hud_configure && spectatee_status <= 0 || intermission > 1)))
1153         {
1154                 setproperty(VF_ORIGIN, freeze_org);
1155                 setproperty(VF_ANGLES, freeze_ang);
1156         }
1157         else
1158         {
1159                 freeze_org = getpropertyvec(VF_ORIGIN);
1160                 freeze_ang = getpropertyvec(VF_ANGLES);
1161         }
1162
1163         WarpZone_FixView();
1164         //WarpZone_FixPMove();
1165
1166         vector ov_org = '0 0 0';
1167         vector ov_mid = '0 0 0';
1168         vector ov_worldmin = '0 0 0';
1169         vector ov_worldmax = '0 0 0';
1170         if(autocvar_cl_orthoview)
1171         {
1172                 ov_worldmin = mi_picmin;
1173                 ov_worldmax = mi_picmax;
1174
1175                 float ov_width = (ov_worldmax.x - ov_worldmin.x);
1176                 float ov_height = (ov_worldmax.y - ov_worldmin.y);
1177                 float ov_distance = (max(vid_width, vid_height) * max(ov_width, ov_height));
1178
1179                 ov_mid = ((ov_worldmax + ov_worldmin) * 0.5);
1180                 ov_org = vec3(ov_mid.x, ov_mid.y, (ov_mid.z + ov_distance));
1181
1182                 float ov_nearest = vlen(ov_org - vec3(
1183                         bound(ov_worldmin.x, ov_org.x, ov_worldmax.x),
1184                         bound(ov_worldmin.y, ov_org.y, ov_worldmax.y),
1185                         bound(ov_worldmin.z, ov_org.z, ov_worldmax.z)
1186                 ));
1187
1188                 float ov_furthest = 0;
1189                 float dist = 0;
1190
1191                 if((dist = vlen(vec3(ov_worldmin.x, ov_worldmin.y, ov_worldmin.z) - ov_org)) > ov_furthest) { ov_furthest = dist; }
1192                 if((dist = vlen(vec3(ov_worldmax.x, ov_worldmin.y, ov_worldmin.z) - ov_org)) > ov_furthest) { ov_furthest = dist; }
1193                 if((dist = vlen(vec3(ov_worldmin.x, ov_worldmax.y, ov_worldmin.z) - ov_org)) > ov_furthest) { ov_furthest = dist; }
1194                 if((dist = vlen(vec3(ov_worldmin.x, ov_worldmin.y, ov_worldmax.z) - ov_org)) > ov_furthest) { ov_furthest = dist; }
1195                 if((dist = vlen(vec3(ov_worldmax.x, ov_worldmax.y, ov_worldmin.z) - ov_org)) > ov_furthest) { ov_furthest = dist; }
1196                 if((dist = vlen(vec3(ov_worldmin.x, ov_worldmax.y, ov_worldmax.z) - ov_org)) > ov_furthest) { ov_furthest = dist; }
1197                 if((dist = vlen(vec3(ov_worldmax.x, ov_worldmin.y, ov_worldmax.z) - ov_org)) > ov_furthest) { ov_furthest = dist; }
1198                 if((dist = vlen(vec3(ov_worldmax.x, ov_worldmax.y, ov_worldmax.z) - ov_org)) > ov_furthest) { ov_furthest = dist; }
1199
1200                 cvar_settemp("r_nearclip", ftos(ov_nearest));
1201                 cvar_settemp("r_farclip_base", ftos(ov_furthest));
1202                 cvar_settemp("r_farclip_world", "0");
1203                 cvar_settemp("r_novis", "1");
1204                 cvar_settemp("r_useportalculling", "0");
1205                 cvar_settemp("r_useinfinitefarclip", "0");
1206
1207                 setproperty(VF_ORIGIN, ov_org);
1208                 setproperty(VF_ANGLES, '90 0 0');
1209
1210                 #if 0
1211                 printf("OrthoView: org = %s, angles = %s, distance = %f, nearest = %f, furthest = %f\n",
1212                         vtos(ov_org),
1213                         vtos(getpropertyvec(VF_ANGLES)),
1214                         ov_distance,
1215                         ov_nearest,
1216                         ov_furthest);
1217                 #endif
1218         }
1219
1220         // Render the Scene
1221         view_origin = getpropertyvec(VF_ORIGIN);
1222         view_angles = getpropertyvec(VF_ANGLES);
1223         makevectors(view_angles);
1224         view_forward = v_forward;
1225         view_right = v_right;
1226         view_up = v_up;
1227
1228 #ifdef BLURTEST
1229         if(time > blurtest_time0 && time < blurtest_time1)
1230         {
1231                 float r, t;
1232
1233                 t = (time - blurtest_time0) / (blurtest_time1 - blurtest_time0);
1234                 r = t * blurtest_radius;
1235                 f = 1 / pow(t, blurtest_power) - 1;
1236
1237                 cvar_set("r_glsl_postprocess", "1");
1238                 cvar_set("r_glsl_postprocess_uservec1", strcat(ftos(r), " ", ftos(f), " 0 0"));
1239         }
1240         else
1241         {
1242                 cvar_set("r_glsl_postprocess", "0");
1243                 cvar_set("r_glsl_postprocess_uservec1", "0 0 0 0");
1244         }
1245 #endif
1246
1247         TargetMusic_Advance();
1248         Fog_Force();
1249
1250         if(drawtime == 0)
1251                 drawframetime = 0.01666667; // when we don't know fps yet, we assume 60fps
1252         else
1253                 drawframetime = bound(0.000001, time - drawtime, 1);
1254         drawtime = time;
1255
1256         // watch for gametype changes here...
1257         // in ParseStuffCMD the cmd isn't executed yet :/
1258         // might even be better to add the gametype to TE_CSQC_INIT...?
1259         if(!postinit)
1260                 PostInit();
1261
1262         if(intermission && !isdemo() && !(calledhooks & HOOK_END))
1263         {
1264                 if(calledhooks & HOOK_START)
1265                 {
1266                         localcmd("\ncl_hook_gameend\n");
1267                         calledhooks |= HOOK_END;
1268                 }
1269         }
1270
1271         Announcer();
1272
1273         fov = autocvar_fov;
1274         if(fov <= 59.5)
1275         {
1276                 if(!zoomscript_caught)
1277                 {
1278                         localcmd("+button9\n");
1279                         zoomscript_caught = 1;
1280                 }
1281         }
1282         else
1283         {
1284                 if(zoomscript_caught)
1285                 {
1286                         localcmd("-button9\n");
1287                         zoomscript_caught = 0;
1288                 }
1289         }
1290
1291         ColorTranslateMode = autocvar_cl_stripcolorcodes;
1292
1293         // next WANTED weapon (for HUD)
1294         switchweapon = getstati(STAT_SWITCHWEAPON);
1295
1296         // currently switching-to weapon (for crosshair)
1297         switchingweapon = getstati(STAT_SWITCHINGWEAPON);
1298
1299         // actually active weapon (for zoom)
1300         activeweapon = getstati(STAT_ACTIVEWEAPON);
1301
1302         f = (serverflags & SERVERFLAG_TEAMPLAY);
1303         if(f != teamplay)
1304         {
1305                 teamplay = f;
1306                 HUD_InitScores();
1307         }
1308
1309         if(last_switchweapon != switchweapon)
1310         {
1311                 weapontime = time;
1312                 last_switchweapon = switchweapon;
1313                 if(button_zoom && autocvar_cl_unpress_zoom_on_weapon_switch)
1314                 {
1315                         localcmd("-zoom\n");
1316                         button_zoom = false;
1317                 }
1318                 if(autocvar_cl_unpress_attack_on_weapon_switch)
1319                 {
1320                         localcmd("-fire\n");
1321                         localcmd("-fire2\n");
1322                         button_attack2 = false;
1323                 }
1324         }
1325         if(last_activeweapon != activeweapon)
1326         {
1327                 last_activeweapon = activeweapon;
1328
1329                 e = get_weaponinfo(activeweapon);
1330                 if(e.netname != "")
1331                         localcmd(strcat("\ncl_hook_activeweapon ", e.netname), "\n");
1332                 else
1333                         localcmd("\ncl_hook_activeweapon none\n");
1334         }
1335
1336         // ALWAYS Clear Current Scene First
1337         clearscene();
1338
1339         setproperty(VF_ORIGIN, view_origin);
1340         setproperty(VF_ANGLES, view_angles);
1341
1342         // FIXME engine bug? VF_SIZE and VF_MIN are not restored to sensible values by this
1343         setproperty(VF_SIZE, vf_size);
1344         setproperty(VF_MIN, vf_min);
1345
1346         // Assign Standard Viewflags
1347         // Draw the World (and sky)
1348         setproperty(VF_DRAWWORLD, 1);
1349
1350         // Set the console size vars
1351         vid_conwidth = autocvar_vid_conwidth;
1352         vid_conheight = autocvar_vid_conheight;
1353         vid_pixelheight = autocvar_vid_pixelheight;
1354
1355         if(autocvar_cl_orthoview) { setproperty(VF_FOV, GetOrthoviewFOV(ov_worldmin, ov_worldmax, ov_mid, ov_org)); }
1356         else { setproperty(VF_FOV, GetCurrentFov(fov)); }
1357
1358         // Camera for demo playback
1359         if(camera_active)
1360         {
1361                 if(autocvar_camera_enable)
1362                         CSQC_Demo_Camera();
1363                 else
1364                 {
1365                         cvar_set("chase_active", ftos(chase_active_backup));
1366                         cvar_set("cl_demo_mousegrab", "0");
1367                         camera_active = false;
1368                 }
1369         }
1370         else
1371         {
1372 #ifdef CAMERATEST
1373                 if(autocvar_camera_enable)
1374 #else
1375                 if(autocvar_camera_enable && isdemo())
1376 #endif
1377                 {
1378                         // Enable required Darkplaces cvars
1379                         chase_active_backup = autocvar_chase_active;
1380                         cvar_set("chase_active", "2");
1381                         cvar_set("cl_demo_mousegrab", "1");
1382                         camera_active = true;
1383                         camera_mode = false;
1384                 }
1385         }
1386
1387         // Draw the Crosshair
1388         setproperty(VF_DRAWCROSSHAIR, 0); //Make sure engine crosshairs are always hidden
1389
1390         // Draw the Engine Status Bar (the default Quake HUD)
1391         setproperty(VF_DRAWENGINESBAR, 0);
1392
1393         // Update the mouse position
1394         /*
1395            mousepos_x = vid_conwidth;
1396            mousepos_y = vid_conheight;
1397            mousepos = mousepos*0.5 + getmousepos();
1398          */
1399
1400         e = self;
1401         for(self = world; (self = nextent(self)); )
1402                 if(self.draw)
1403                         self.draw();
1404         self = e;
1405
1406         addentities(MASK_NORMAL | MASK_ENGINE | MASK_ENGINEVIEWMODELS);
1407         renderscene();
1408
1409         // now switch to 2D drawing mode by calling a 2D drawing function
1410         // then polygon drawing will draw as 2D stuff, and NOT get queued until the
1411         // next R_RenderScene call
1412         drawstring('0 0 0', "", '1 1 0', '1 1 1', 0, 0);
1413
1414         if(autocvar_r_fakelight >= 2 || autocvar_r_fullbright)
1415         if (!(serverflags & SERVERFLAG_ALLOW_FULLBRIGHT))
1416         {
1417                 // apply night vision effect
1418                 vector tc_00, tc_01, tc_10, tc_11;
1419                 vector rgb = '0 0 0';
1420
1421                 if(!nightvision_noise)
1422                 {
1423                         nightvision_noise = spawn();
1424                         nightvision_noise.classname = "nightvision_noise";
1425                 }
1426                 if(!nightvision_noise2)
1427                 {
1428                         nightvision_noise2 = spawn();
1429                         nightvision_noise2.classname = "nightvision_noise2";
1430                 }
1431
1432                 // color tint in yellow
1433                 drawfill('0 0 0', autocvar_vid_conwidth * '1 0 0' + autocvar_vid_conheight * '0 1 0', '0.5 1 0.3', 1, DRAWFLAG_MODULATE);
1434
1435                 // draw BG
1436                 a = Noise_Pink(nightvision_noise, frametime * 1.5) * 0.05 + 0.15;
1437                 rgb = '1 1 1';
1438                 tc_00 = '0 0 0' + '0.2 0 0' * sin(time * 0.3) + '0 0.3 0' * cos(time * 0.7);
1439                 tc_01 = '0 2.25 0' + '0.6 0 0' * cos(time * 1.2) - '0 0.3 0' * sin(time * 2.2);
1440                 tc_10 = '1.5 0 0' - '0.2 0 0' * sin(time * 0.5) + '0 0.5 0' * cos(time * 1.7);
1441                 //tc_11 = '1 1 0' + '0.6 0 0' * sin(time * 0.6) + '0 0.3 0' * cos(time * 0.1);
1442                 tc_11 = tc_01 + tc_10 - tc_00;
1443                 R_BeginPolygon("gfx/nightvision-bg.tga", DRAWFLAG_ADDITIVE);
1444                 R_PolygonVertex('0 0 0', tc_00, rgb, a);
1445                 R_PolygonVertex(autocvar_vid_conwidth * '1 0 0', tc_10, rgb, a);
1446                 R_PolygonVertex(autocvar_vid_conwidth * '1 0 0' + autocvar_vid_conheight * '0 1 0', tc_11, rgb, a);
1447                 R_PolygonVertex(autocvar_vid_conheight * '0 1 0', tc_01, rgb, a);
1448                 R_EndPolygon();
1449
1450                 // draw FG
1451                 a = Noise_Pink(nightvision_noise2, frametime * 0.1) * 0.05 + 0.12;
1452                 rgb = '0.3 0.6 0.4' + '0.1 0.4 0.2' * Noise_White(nightvision_noise2, frametime);
1453                 tc_00 = '0 0 0' + '1 0 0' * Noise_White(nightvision_noise2, frametime) + '0 1 0' * Noise_White(nightvision_noise2, frametime);
1454                 tc_01 = tc_00 + '0 3 0' * (1 + Noise_White(nightvision_noise2, frametime) * 0.2);
1455                 tc_10 = tc_00 + '2 0 0' * (1 + Noise_White(nightvision_noise2, frametime) * 0.3);
1456                 tc_11 = tc_01 + tc_10 - tc_00;
1457                 R_BeginPolygon("gfx/nightvision-fg.tga", DRAWFLAG_ADDITIVE);
1458                 R_PolygonVertex('0 0 0', tc_00, rgb, a);
1459                 R_PolygonVertex(autocvar_vid_conwidth * '1 0 0', tc_10, rgb, a);
1460                 R_PolygonVertex(autocvar_vid_conwidth * '1 0 0' + autocvar_vid_conheight * '0 1 0', tc_11, rgb, a);
1461                 R_PolygonVertex(autocvar_vid_conheight * '0 1 0', tc_01, rgb, a);
1462                 R_EndPolygon();
1463         }
1464
1465         if(autocvar_cl_reticle)
1466         {
1467                 // Draw the aiming reticle for weapons that use it
1468                 // reticle_type is changed to the item we are zooming / aiming with, to decide which reticle to use
1469                 // It must be a persisted float for fading out to work properly (you let go of the zoom button for
1470                 // the view to go back to normal, so reticle_type would become 0 as we fade out)
1471                 if(spectatee_status || is_dead || hud != HUD_NORMAL)
1472                 {
1473                         // no zoom reticle while dead
1474                         reticle_type = 0;
1475                 }
1476                 else if(WEP_ACTION(activeweapon, WR_ZOOMRETICLE) && autocvar_cl_reticle_weapon)
1477                 {
1478                         if(reticle_image != "") { reticle_type = 2; }
1479                         else { reticle_type = 0; }
1480                 }
1481                 else if(button_zoom || zoomscript_caught)
1482                 {
1483                         // normal zoom
1484                         reticle_type = 1;
1485                 }
1486
1487                 if(reticle_type)
1488                 {
1489                         if(autocvar_cl_reticle_stretch)
1490                         {
1491                                 reticle_size.x = vid_conwidth;
1492                                 reticle_size.y = vid_conheight;
1493                                 reticle_pos.x = 0;
1494                                 reticle_pos.y = 0;
1495                         }
1496                         else
1497                         {
1498                                 reticle_size.x = max(vid_conwidth, vid_conheight);
1499                                 reticle_size.y = max(vid_conwidth, vid_conheight);
1500                                 reticle_pos.x = (vid_conwidth - reticle_size.x) / 2;
1501                                 reticle_pos.y = (vid_conheight - reticle_size.y) / 2;
1502                         }
1503
1504                         if(zoomscript_caught)
1505                                 f = 1;
1506                         else
1507                                 f = current_zoomfraction;
1508
1509                         if(f)
1510                         {
1511                                 switch(reticle_type)
1512                                 {
1513                                         case 1: drawpic(reticle_pos, "gfx/reticle_normal", reticle_size, '1 1 1', f * autocvar_cl_reticle_normal_alpha, DRAWFLAG_NORMAL); break;
1514                                         case 2: drawpic(reticle_pos, reticle_image, reticle_size, '1 1 1', f * autocvar_cl_reticle_weapon_alpha, DRAWFLAG_NORMAL); break;
1515                                 }
1516                         }
1517                 }
1518         }
1519         else
1520         {
1521                 if(reticle_type != 0) { reticle_type = 0; }
1522         }
1523
1524
1525         // improved polyblend
1526         if(autocvar_hud_contents)
1527         {
1528                 float contentalpha_temp, incontent, liquidalpha, contentfadetime;
1529                 vector liquidcolor;
1530
1531                 switch(pointcontents(view_origin))
1532                 {
1533                         case CONTENT_WATER:
1534                                 liquidalpha = autocvar_hud_contents_water_alpha;
1535                                 liquidcolor = stov(autocvar_hud_contents_water_color);
1536                                 incontent = 1;
1537                                 break;
1538
1539                         case CONTENT_LAVA:
1540                                 liquidalpha = autocvar_hud_contents_lava_alpha;
1541                                 liquidcolor = stov(autocvar_hud_contents_lava_color);
1542                                 incontent = 1;
1543                                 break;
1544
1545                         case CONTENT_SLIME:
1546                                 liquidalpha = autocvar_hud_contents_slime_alpha;
1547                                 liquidcolor = stov(autocvar_hud_contents_slime_color);
1548                                 incontent = 1;
1549                                 break;
1550
1551                         default:
1552                                 liquidalpha = 0;
1553                                 liquidcolor = '0 0 0';
1554                                 incontent = 0;
1555                                 break;
1556                 }
1557
1558                 if(incontent) // fade in/out at different speeds so you can do e.g. instant fade when entering water and slow when leaving it.
1559                 { // also lets delcare previous values for blending properties, this way it isn't reset until after you have entered a different content
1560                         contentfadetime = autocvar_hud_contents_fadeintime;
1561                         liquidalpha_prev = liquidalpha;
1562                         liquidcolor_prev = liquidcolor;
1563                 }
1564                 else
1565                         contentfadetime = autocvar_hud_contents_fadeouttime;
1566
1567                 contentalpha_temp = bound(0, drawframetime / max(0.0001, contentfadetime), 1);
1568                 contentavgalpha = contentavgalpha * (1 - contentalpha_temp) + incontent * contentalpha_temp;
1569
1570                 if(contentavgalpha)
1571                         drawfill('0 0 0', eX * vid_conwidth + eY * vid_conheight, liquidcolor_prev, contentavgalpha * liquidalpha_prev, DRAWFLAG_NORMAL);
1572
1573                 if(autocvar_hud_postprocessing)
1574                 {
1575                         if(autocvar_hud_contents_blur && contentavgalpha)
1576                         {
1577                                 content_blurpostprocess.x = 1;
1578                                 content_blurpostprocess.y = contentavgalpha * autocvar_hud_contents_blur;
1579                                 content_blurpostprocess.z = contentavgalpha * autocvar_hud_contents_blur_alpha;
1580                         }
1581                         else
1582                         {
1583                                 content_blurpostprocess.x = 0;
1584                                 content_blurpostprocess.y = 0;
1585                                 content_blurpostprocess.z = 0;
1586                         }
1587                 }
1588         }
1589
1590         if(autocvar_hud_damage && !getstati(STAT_FROZEN))
1591         {
1592                 splash_size.x = max(vid_conwidth, vid_conheight);
1593                 splash_size.y = max(vid_conwidth, vid_conheight);
1594                 splash_pos.x = (vid_conwidth - splash_size.x) / 2;
1595                 splash_pos.y = (vid_conheight - splash_size.y) / 2;
1596
1597                 float myhealth_flash_temp;
1598                 myhealth = getstati(STAT_HEALTH);
1599
1600                 // fade out
1601                 myhealth_flash = max(0, myhealth_flash - autocvar_hud_damage_fade_rate * frametime);
1602                 // add new damage
1603                 myhealth_flash = bound(0, myhealth_flash + dmg_take * autocvar_hud_damage_factor, autocvar_hud_damage_maxalpha);
1604
1605                 float pain_threshold, pain_threshold_lower, pain_threshold_lower_health;
1606                 pain_threshold = autocvar_hud_damage_pain_threshold;
1607                 pain_threshold_lower = autocvar_hud_damage_pain_threshold_lower;
1608                 pain_threshold_lower_health = autocvar_hud_damage_pain_threshold_lower_health;
1609
1610                 if(pain_threshold_lower && myhealth < pain_threshold_lower_health)
1611                 {
1612                         pain_threshold = pain_threshold - max(autocvar_hud_damage_pain_threshold_pulsating_min, fabs(sin(M_PI * time / autocvar_hud_damage_pain_threshold_pulsating_period))) * pain_threshold_lower * (1 - max(0, myhealth)/pain_threshold_lower_health);
1613                 }
1614
1615                 myhealth_flash_temp = bound(0, myhealth_flash - pain_threshold, 1);
1616
1617                 if(myhealth_prev < 1)
1618                 {
1619                         if(myhealth >= 1)
1620                         {
1621                                 myhealth_flash = 0; // just spawned, clear the flash immediately
1622                                 myhealth_flash_temp = 0;
1623                         }
1624                         else
1625                         {
1626                                 myhealth_flash += autocvar_hud_damage_fade_rate * frametime; // dead
1627                         }
1628                 }
1629
1630                 if(spectatee_status == -1 || intermission)
1631                 {
1632                         myhealth_flash = 0; // observing, or match ended
1633                         myhealth_flash_temp = 0;
1634                 }
1635
1636                 myhealth_prev = myhealth;
1637
1638                 // IDEA: change damage color/picture based on player model for robot/alien species?
1639                 // pro: matches model better
1640                 // contra: it's not red because blood is red, but because red is an alarming color, so red should stay
1641                 // maybe different reddish pics?
1642                 if(autocvar_cl_gentle_damage || autocvar_cl_gentle)
1643                 {
1644                         if(autocvar_cl_gentle_damage == 2)
1645                         {
1646                                 if(myhealth_flash < pain_threshold) // only randomize when the flash is gone
1647                                 {
1648                                         myhealth_gentlergb = eX * random() + eY * random() + eZ * random();
1649                                 }
1650                         }
1651                         else
1652                                 myhealth_gentlergb = stov(autocvar_hud_damage_gentle_color);
1653
1654                         drawfill('0 0 0', eX * vid_conwidth + eY * vid_conheight, myhealth_gentlergb, autocvar_hud_damage_gentle_alpha_multiplier * bound(0, myhealth_flash_temp, 1) * autocvar_hud_damage, DRAWFLAG_NORMAL);
1655                 }
1656                 else
1657                         drawpic(splash_pos, "gfx/blood", splash_size, stov(autocvar_hud_damage_color), bound(0, myhealth_flash_temp, 1) * autocvar_hud_damage, DRAWFLAG_NORMAL);
1658
1659                 if(autocvar_hud_postprocessing) // we still need to set this anyway even when chase_active is set, this way it doesn't get stuck on.
1660                 {
1661                         if(autocvar_hud_damage_blur && myhealth_flash_temp)
1662                         {
1663                                 damage_blurpostprocess.x = 1;
1664                                 damage_blurpostprocess.y = bound(0, myhealth_flash_temp, 1) * autocvar_hud_damage_blur;
1665                                 damage_blurpostprocess.z = bound(0, myhealth_flash_temp, 1) * autocvar_hud_damage_blur_alpha;
1666                         }
1667                         else
1668                         {
1669                                 damage_blurpostprocess.x = 0;
1670                                 damage_blurpostprocess.y = 0;
1671                                 damage_blurpostprocess.z = 0;
1672                         }
1673                 }
1674         }
1675
1676         float e1 = (autocvar_hud_postprocessing_maxbluralpha != 0);
1677         float e2 = (autocvar_hud_powerup != 0);
1678         if(autocvar_hud_postprocessing && (e1 || e2)) // TODO: Remove this code and re-do the postprocess handling in the engine, where it properly belongs.
1679         {
1680                 // enable or disable rendering types if they are used or not
1681                 if(cvar("r_glsl_postprocess_uservec1_enable") != e1) { cvar_set("r_glsl_postprocess_uservec1_enable", ftos(e1)); }
1682                 if(cvar("r_glsl_postprocess_uservec2_enable") != e2) { cvar_set("r_glsl_postprocess_uservec2_enable", ftos(e2)); }
1683
1684                 // blur postprocess handling done first (used by hud_damage and hud_contents)
1685                 if((damage_blurpostprocess.x || content_blurpostprocess.x))
1686                 {
1687                         float blurradius = bound(0, damage_blurpostprocess.y + content_blurpostprocess.y, autocvar_hud_postprocessing_maxblurradius);
1688                         float bluralpha = bound(0, damage_blurpostprocess.z + content_blurpostprocess.z, autocvar_hud_postprocessing_maxbluralpha);
1689                         if(blurradius != old_blurradius || bluralpha != old_bluralpha) // reduce cvar_set spam as much as possible
1690                         {
1691                                 cvar_set("r_glsl_postprocess_uservec1", strcat(ftos(blurradius), " ", ftos(bluralpha), " 0 0"));
1692                                 old_blurradius = blurradius;
1693                                 old_bluralpha = bluralpha;
1694                         }
1695                 }
1696                 else if(cvar_string("r_glsl_postprocess_uservec1") != "0 0 0 0") // reduce cvar_set spam as much as possible
1697                 {
1698                         cvar_set("r_glsl_postprocess_uservec1", "0 0 0 0");
1699                         old_blurradius = 0;
1700                         old_bluralpha = 0;
1701                 }
1702
1703                 // edge detection postprocess handling done second (used by hud_powerup)
1704                 float sharpen_intensity = 0, strength_finished = getstatf(STAT_STRENGTH_FINISHED), invincible_finished = getstatf(STAT_INVINCIBLE_FINISHED);
1705                 if (strength_finished - time > 0) { sharpen_intensity += (strength_finished - time); }
1706                 if (invincible_finished - time > 0) { sharpen_intensity += (invincible_finished - time); }
1707
1708                 sharpen_intensity = bound(0, ((getstati(STAT_HEALTH) > 0) ? sharpen_intensity : 0), 5); // Check to see if player is alive (if not, set 0) - also bound to fade out starting at 5 seconds.
1709
1710                 if(autocvar_hud_powerup && sharpen_intensity > 0)
1711                 {
1712                         if(sharpen_intensity != old_sharpen_intensity) // reduce cvar_set spam as much as possible
1713                         {
1714                                 cvar_set("r_glsl_postprocess_uservec2", strcat(ftos((sharpen_intensity / 5) * autocvar_hud_powerup), " ", ftos(-sharpen_intensity * autocvar_hud_powerup), " 0 0"));
1715                                 old_sharpen_intensity = sharpen_intensity;
1716                         }
1717                 }
1718                 else if(cvar_string("r_glsl_postprocess_uservec2") != "0 0 0 0") // reduce cvar_set spam as much as possible
1719                 {
1720                         cvar_set("r_glsl_postprocess_uservec2", "0 0 0 0");
1721                         old_sharpen_intensity = 0;
1722                 }
1723
1724                 if(cvar("r_glsl_postprocess") == 0)
1725                         cvar_set("r_glsl_postprocess", "2");
1726         }
1727         else if(cvar("r_glsl_postprocess") == 2)
1728                 cvar_set("r_glsl_postprocess", "0");
1729
1730         if(menu_visible)
1731                 menu_show();
1732
1733         /*if(gametype == MAPINFO_TYPE_CTF)
1734           {
1735           ctf_view();
1736           } else */
1737
1738         // draw 2D entities
1739         e = self;
1740         for(self = world; (self = nextent(self)); )
1741                 if(self.draw2d)
1742                         self.draw2d();
1743         self = e;
1744         Draw_ShowNames_All();
1745
1746         scoreboard_active = HUD_WouldDrawScoreboard();
1747
1748         UpdateDamage();
1749         UpdateCrosshair();
1750         UpdateHitsound();
1751
1752         if(NextFrameCommand)
1753         {
1754                 localcmd("\n", NextFrameCommand, "\n");
1755                 NextFrameCommand = string_null;
1756         }
1757
1758         // we must do this check AFTER a frame was rendered, or it won't work
1759         if(cs_project_is_b0rked == 0)
1760         {
1761                 string w0, h0;
1762                 w0 = ftos(autocvar_vid_conwidth);
1763                 h0 = ftos(autocvar_vid_conheight);
1764                 //setproperty(VF_VIEWPORT, '0 0 0', '640 480 0');
1765                 //setproperty(VF_FOV, '90 90 0');
1766                 setproperty(VF_ORIGIN, '0 0 0');
1767                 setproperty(VF_ANGLES, '0 0 0');
1768                 setproperty(VF_PERSPECTIVE, 1);
1769                 makevectors('0 0 0');
1770                 vector v1, v2;
1771                 cvar_set("vid_conwidth", "800");
1772                 cvar_set("vid_conheight", "600");
1773                 v1 = cs_project(v_forward);
1774                 cvar_set("vid_conwidth", "640");
1775                 cvar_set("vid_conheight", "480");
1776                 v2 = cs_project(v_forward);
1777                 if(v1 == v2)
1778                         cs_project_is_b0rked = 1;
1779                 else
1780                         cs_project_is_b0rked = -1;
1781                 cvar_set("vid_conwidth", w0);
1782                 cvar_set("vid_conheight", h0);
1783         }
1784
1785         if(autocvar__hud_configure)
1786                 HUD_Panel_Mouse();
1787
1788     if(hud && !intermission)
1789     {
1790         if(hud == HUD_SPIDERBOT)
1791             CSQC_SPIDER_HUD();
1792         else if(hud == HUD_WAKIZASHI)
1793             CSQC_WAKIZASHI_HUD();
1794         else if(hud == HUD_RAPTOR)
1795             CSQC_RAPTOR_HUD();
1796         else if(hud == HUD_BUMBLEBEE)
1797             CSQC_BUMBLE_HUD();
1798         else if(hud == HUD_BUMBLEBEE_GUN)
1799             CSQC_BUMBLE_GUN_HUD();
1800     }
1801
1802         cl_notice_run();
1803
1804         // let's reset the view back to normal for the end
1805         setproperty(VF_MIN, '0 0 0');
1806         setproperty(VF_SIZE, '1 0 0' * w + '0 1 0' * h);
1807 }
1808
1809
1810 void CSQC_common_hud(void)
1811 {
1812         if(!(gametype == MAPINFO_TYPE_RACE || gametype == MAPINFO_TYPE_CTS))
1813                 Accuracy_LoadLevels();
1814
1815         HUD_Main(); // always run these functions for alpha checks
1816         HUD_DrawScoreboard();
1817
1818         if (scoreboard_active) // scoreboard/accuracy
1819                 HUD_Reset();
1820         else if (intermission == 2) // map voting screen
1821         {
1822                 MapVote_Draw();
1823                 HUD_Reset();
1824         }
1825 }
1826
1827
1828 // following vectors must be global to allow seamless switching between camera modes
1829 vector camera_offset, current_camera_offset, mouse_angles, current_angles, current_origin, current_position;
1830 void CSQC_Demo_Camera()
1831 {
1832         float speed, attenuation, dimensions;
1833         vector tmp, delta;
1834
1835         if( autocvar_camera_reset || !camera_mode )
1836         {
1837                 camera_offset = '0 0 0';
1838                 current_angles = '0 0 0';
1839                 camera_direction = '0 0 0';
1840                 camera_offset.z += 30;
1841                 camera_offset.x += 30 * -cos(current_angles.y * DEG2RAD);
1842                 camera_offset.y += 30 * -sin(current_angles.y * DEG2RAD);
1843                 current_origin = view_origin;
1844                 current_camera_offset  = camera_offset;
1845                 cvar_set("camera_reset", "0");
1846                 camera_mode = CAMERA_CHASE;
1847         }
1848
1849         // Camera angles
1850         if( camera_roll )
1851                 mouse_angles.z += camera_roll * autocvar_camera_speed_roll;
1852
1853         if(autocvar_camera_look_player)
1854         {
1855                 vector dir;
1856                 float n;
1857
1858                 dir = normalize(view_origin - current_position);
1859                 n = mouse_angles.z;
1860                 mouse_angles = vectoangles(dir);
1861                 mouse_angles.x = mouse_angles.x * -1;
1862                 mouse_angles.z = n;
1863         }
1864         else
1865         {
1866                 tmp = getmousepos() * 0.1;
1867                 if(vlen(tmp)>autocvar_camera_mouse_threshold)
1868                 {
1869                         mouse_angles.x += tmp.y * cos(mouse_angles.z * DEG2RAD) + (tmp.x * sin(mouse_angles.z * DEG2RAD));
1870                         mouse_angles.y -= tmp.x * cos(mouse_angles.z * DEG2RAD) + (tmp.y * -sin(mouse_angles.z * DEG2RAD));
1871                 }
1872         }
1873
1874         while (mouse_angles.x < -180) mouse_angles.x = mouse_angles.x + 360;
1875         while (mouse_angles.x > 180) mouse_angles.x = mouse_angles.x - 360;
1876         while (mouse_angles.y < -180) mouse_angles.y = mouse_angles.y + 360;
1877         while (mouse_angles.y > 180) mouse_angles.y = mouse_angles.y - 360;
1878
1879         // Fix difference when angles don't have the same sign
1880         delta = '0 0 0';
1881         if(mouse_angles.y < -60 && current_angles.y > 60)
1882                 delta = '0 360 0';
1883         if(mouse_angles.y > 60 && current_angles.y < -60)
1884                 delta = '0 -360 0';
1885
1886         if(autocvar_camera_look_player)
1887                 attenuation = autocvar_camera_look_attenuation;
1888         else
1889                 attenuation = autocvar_camera_speed_attenuation;
1890
1891         attenuation = 1 / max(1, attenuation);
1892         current_angles += (mouse_angles - current_angles + delta) * attenuation;
1893
1894         while (current_angles.x < -180) current_angles.x = current_angles.x + 360;
1895         while (current_angles.x > 180) current_angles.x = current_angles.x - 360;
1896         while (current_angles.y < -180) current_angles.y = current_angles.y + 360;
1897         while (current_angles.y > 180) current_angles.y = current_angles.y - 360;
1898
1899         // Camera position
1900         tmp = '0 0 0';
1901         dimensions = 0;
1902
1903         if( camera_direction.x )
1904         {
1905                 tmp.x = camera_direction.x * cos(current_angles.y * DEG2RAD);
1906                 tmp.y = camera_direction.x * sin(current_angles.y * DEG2RAD);
1907                 if( autocvar_camera_forward_follows && !autocvar_camera_look_player )
1908                         tmp.z = camera_direction.x * -sin(current_angles.x * DEG2RAD);
1909                 ++dimensions;
1910         }
1911
1912         if( camera_direction.y )
1913         {
1914                 tmp.x += camera_direction.y * -sin(current_angles.y * DEG2RAD);
1915                 tmp.y += camera_direction.y * cos(current_angles.y * DEG2RAD) * cos(current_angles.z * DEG2RAD);
1916                 tmp.z += camera_direction.y * sin(current_angles.z * DEG2RAD);
1917                 ++dimensions;
1918         }
1919
1920         if( camera_direction.z )
1921         {
1922                 tmp.z += camera_direction.z * cos(current_angles.z * DEG2RAD);
1923                 ++dimensions;
1924         }
1925
1926         if(autocvar_camera_free)
1927                 speed = autocvar_camera_speed_free;
1928         else
1929                 speed = autocvar_camera_speed_chase;
1930
1931         if(dimensions)
1932         {
1933                 speed = speed * sqrt(1 / dimensions);
1934                 camera_offset += tmp * speed;
1935         }
1936
1937         current_camera_offset += (camera_offset - current_camera_offset) * attenuation;
1938
1939         // Camera modes
1940         if( autocvar_camera_free )
1941         {
1942                 if ( camera_mode == CAMERA_CHASE )
1943                 {
1944                         current_camera_offset = current_origin + current_camera_offset;
1945                         camera_offset = current_origin + camera_offset;
1946                 }
1947
1948                 camera_mode = CAMERA_FREE;
1949                 current_position = current_camera_offset;
1950         }
1951         else
1952         {
1953                 if ( camera_mode == CAMERA_FREE )
1954                 {
1955                         current_origin = view_origin;
1956                         camera_offset = camera_offset - current_origin;
1957                         current_camera_offset = current_camera_offset - current_origin;
1958                 }
1959
1960                 camera_mode = CAMERA_CHASE;
1961
1962                 if(autocvar_camera_chase_smoothly)
1963                         current_origin += (view_origin - current_origin) * attenuation;
1964                 else
1965                         current_origin = view_origin;
1966
1967                 current_position = current_origin + current_camera_offset;
1968         }
1969
1970         setproperty(VF_ANGLES, current_angles);
1971         setproperty(VF_ORIGIN, current_position);
1972 }