qcsrc/client/view.qc

   1 #include "view.qh"
   2
   3 #include "autocvars.qh"
   4 #include "miscfunctions.qh"
   5 #include "announcer.qh"
   6 #include "hud/_mod.qh"
   7 #include "mapvoting.qh"
   8 #include "shownames.qh"
   9 #include "hud/panel/scoreboard.qh"
  10 #include "hud/panel/quickmenu.qh"
  11
  12 #include "mutators/events.qh"
  13
  14 #include <common/animdecide.qh>
  15 #include <common/deathtypes/all.qh>
  16 #include <common/ent_cs.qh>
  17 #include <common/anim.qh>
  18 #include <common/constants.qh>
  19 #include <common/net_linked.qh>
  20 #include <common/debug.qh>
  21 #include <common/mapinfo.qh>
  22 #include <common/gamemodes/_mod.qh>
  23 #include <common/physics/player.qh>
  24 #include <common/stats.qh>
  25 #include <common/triggers/target/music.qh>
  26 #include <common/teams.qh>
  27 #include <common/wepent.qh>
  28
  29 #include <common/weapons/weapon/tuba.qh>
  30
  31 #include <common/vehicles/all.qh>
  32 #include <common/weapons/_all.qh>
  33 #include <common/viewloc.qh>
  34 #include <common/triggers/trigger/viewloc.qh>
  35 #include <common/minigames/cl_minigames.qh>
  36 #include <common/minigames/cl_minigames_hud.qh>
  37
  38 #include <lib/csqcmodel/cl_player.qh>
  39 #include <lib/csqcmodel/cl_model.qh>
  40 #include "csqcmodel_hooks.qh"
  41
  42 #include <lib/warpzone/client.qh>
  43 #include <lib/warpzone/common.qh>
  44
  45 #define EFMASK_CHEAP (EF_ADDITIVE | EF_DOUBLESIDED | EF_FULLBRIGHT | EF_NODEPTHTEST | EF_NODRAW | EF_NOSHADOW | EF_SELECTABLE | EF_TELEPORT_BIT)
  46
  47 float autocvar_cl_viewmodel_scale;
  48
  49 bool autocvar_cl_bobmodel;
  50 float autocvar_cl_bobmodel_speed;
  51 float autocvar_cl_bobmodel_side;
  52 float autocvar_cl_bobmodel_up;
  53
  54 float autocvar_cl_followmodel;
  55 float autocvar_cl_followmodel_speed = 0.3;
  56 float autocvar_cl_followmodel_limit = 135;
  57 float autocvar_cl_followmodel_velocity_lowpass = 0.05;
  58 float autocvar_cl_followmodel_highpass = 0.05;
  59 float autocvar_cl_followmodel_lowpass = 0.03;
  60 bool autocvar_cl_followmodel_velocity_absolute;
  61
  62 float autocvar_cl_leanmodel;
  63 float autocvar_cl_leanmodel_speed = 0.3;
  64 float autocvar_cl_leanmodel_limit = 30;
  65 float autocvar_cl_leanmodel_highpass1 = 0.2;
  66 float autocvar_cl_leanmodel_highpass = 0.2;
  67 float autocvar_cl_leanmodel_lowpass = 0.05;
  68
  69 #define avg_factor(avg_time) (1 - exp(-frametime / max(0.001, avg_time)))
  70
  71 #define lowpass(value, frac, ref_store, ret) \
  72         ret = ref_store = ref_store * (1 - frac) + (value) * frac;
  73
  74 #define lowpass_limited(value, frac, limit, ref_store, ret) MACRO_BEGIN \
  75 { \
  76         float __ignore; lowpass(value, frac, ref_store, __ignore); \
  77         ret = ref_store = bound((value) - (limit), ref_store, (value) + (limit)); \
  78 } MACRO_END
  79
  80 #define highpass(value, frac, ref_store, ret) MACRO_BEGIN \
  81 { \
  82         float __f = 0; lowpass(value, frac, ref_store, __f); \
  83         ret = (value) - __f; \
  84 } MACRO_END
  85
  86 #define highpass_limited(value, frac, limit, ref_store, ret) MACRO_BEGIN \
  87 { \
  88         float __f = 0; lowpass_limited(value, frac, limit, ref_store, __f); \
  89         ret = (value) - __f; \
  90 } MACRO_END
  91
  92 #define lowpass2(value, frac, ref_store, ref_out) MACRO_BEGIN \
  93 { \
  94         lowpass(value.x, frac, ref_store.x, ref_out.x); \
  95         lowpass(value.y, frac, ref_store.y, ref_out.y); \
  96 } MACRO_END
  97
  98 #define highpass2(value, frac, ref_store, ref_out) MACRO_BEGIN \
  99 { \
 100         highpass(value.x, frac, ref_store.x, ref_out.x); \
 101         highpass(value.y, frac, ref_store.y, ref_out.y); \
 102 } MACRO_END
 103
 104 #define highpass2_limited(value, frac, limit, ref_store, ref_out) MACRO_BEGIN \
 105 { \
 106         highpass_limited(value.x, frac, limit, ref_store.x, ref_out.x); \
 107         highpass_limited(value.y, frac, limit, ref_store.y, ref_out.y); \
 108 } MACRO_END
 109
 110 #define lowpass3(value, frac, ref_store, ref_out) MACRO_BEGIN \
 111 { \
 112         lowpass(value.x, frac, ref_store.x, ref_out.x); \
 113         lowpass(value.y, frac, ref_store.y, ref_out.y); \
 114         lowpass(value.z, frac, ref_store.z, ref_out.z); \
 115 } MACRO_END
 116
 117 #define highpass3(value, frac, ref_store, ref_out) MACRO_BEGIN \
 118 { \
 119         highpass(value.x, frac, ref_store.x, ref_out.x); \
 120         highpass(value.y, frac, ref_store.y, ref_out.y); \
 121         highpass(value.z, frac, ref_store.z, ref_out.z); \
 122 } MACRO_END
 123
 124 void calc_followmodel_ofs(entity view)
 125 {
 126         if(cl_followmodel_time == time)
 127                 return; // cl_followmodel_ofs already calculated for this frame
 128
 129         float frac;
 130         vector gunorg = '0 0 0';
 131         static vector vel_average;
 132         static vector gunorg_adjustment_highpass;
 133         static vector gunorg_adjustment_lowpass;
 134
 135         vector vel;
 136         if (autocvar_cl_followmodel_velocity_absolute)
 137                 vel = view.velocity;
 138         else
 139         {
 140                 vector forward = '0 0 0', right = '0 0 0', up = '0 0 0';
 141                 MAKEVECTORS(makevectors, view_angles, forward, right, up);
 142                 vel.x = view.velocity * forward;
 143                 vel.y = view.velocity * right * -1;
 144                 vel.z = view.velocity * up;
 145         }
 146
 147         vel.x = bound(vel_average.x - autocvar_cl_followmodel_limit, vel.x, vel_average.x + autocvar_cl_followmodel_limit);
 148         vel.y = bound(vel_average.y - autocvar_cl_followmodel_limit, vel.y, vel_average.y + autocvar_cl_followmodel_limit);
 149         vel.z = bound(vel_average.z - autocvar_cl_followmodel_limit, vel.z, vel_average.z + autocvar_cl_followmodel_limit);
 150
 151         frac = avg_factor(autocvar_cl_followmodel_velocity_lowpass);
 152         lowpass3(vel, frac, vel_average, gunorg);
 153
 154         gunorg *= -autocvar_cl_followmodel_speed * 0.042;
 155
 156         // perform highpass/lowpass on the adjustment vectors (turning velocity into acceleration!)
 157         // trick: we must do the lowpass LAST, so the lowpass vector IS the final vector!
 158         frac = avg_factor(autocvar_cl_followmodel_highpass);
 159         highpass3(gunorg, frac, gunorg_adjustment_highpass, gunorg);
 160         frac = avg_factor(autocvar_cl_followmodel_lowpass);
 161         lowpass3(gunorg, frac, gunorg_adjustment_lowpass, gunorg);
 162
 163         if (autocvar_cl_followmodel_velocity_absolute)
 164         {
 165                 vector fixed_gunorg;
 166                 vector forward = '0 0 0', right = '0 0 0', up = '0 0 0';
 167                 MAKEVECTORS(makevectors, view_angles, forward, right, up);
 168                 fixed_gunorg.x = gunorg * forward;
 169                 fixed_gunorg.y = gunorg * right * -1;
 170                 fixed_gunorg.z = gunorg * up;
 171                 gunorg = fixed_gunorg;
 172         }
 173
 174         cl_followmodel_ofs = gunorg;
 175         cl_followmodel_time = time;
 176 }
 177
 178 vector leanmodel_ofs(entity view)
 179 {
 180         float frac;
 181         vector gunangles = '0 0 0';
 182         static vector gunangles_prev = '0 0 0';
 183         static vector gunangles_highpass = '0 0 0';
 184         static vector gunangles_adjustment_highpass;
 185         static vector gunangles_adjustment_lowpass;
 186
 187         if (view.csqcmodel_teleported)
 188                 gunangles_prev = view_angles;
 189
 190         // in the highpass, we _store_ the DIFFERENCE to the actual view angles...
 191         gunangles_highpass += gunangles_prev;
 192         PITCH(gunangles_highpass) += 360 * floor((PITCH(view_angles) - PITCH(gunangles_highpass)) / 360 + 0.5);
 193         YAW(gunangles_highpass) += 360 * floor((YAW(view_angles) - YAW(gunangles_highpass)) / 360 + 0.5);
 194         ROLL(gunangles_highpass) += 360 * floor((ROLL(view_angles) - ROLL(gunangles_highpass)) / 360 + 0.5);
 195         frac = avg_factor(autocvar_cl_leanmodel_highpass1);
 196         highpass2_limited(view_angles, frac, autocvar_cl_leanmodel_limit, gunangles_highpass, gunangles);
 197         gunangles_prev = view_angles;
 198         gunangles_highpass -= gunangles_prev;
 199
 200         PITCH(gunangles) *= -autocvar_cl_leanmodel_speed;
 201         YAW(gunangles) *= -autocvar_cl_leanmodel_speed;
 202
 203         // we assume here: PITCH = 0, YAW = 1, ROLL = 2
 204         frac = avg_factor(autocvar_cl_leanmodel_highpass);
 205         highpass2(gunangles, frac, gunangles_adjustment_highpass, gunangles);
 206         frac = avg_factor(autocvar_cl_leanmodel_lowpass);
 207         lowpass2(gunangles, frac, gunangles_adjustment_lowpass, gunangles);
 208
 209         gunangles.x = -gunangles.x; // pitch was inverted, now that actually matters
 210
 211         return gunangles;
 212 }
 213
 214 vector bobmodel_ofs(entity view)
 215 {
 216         bool clonground = !(view.anim_implicit_state & ANIMIMPLICITSTATE_INAIR);
 217         static bool oldonground;
 218         static float hitgroundtime;
 219         if (clonground)
 220         {
 221                 float f = time; // cl.movecmd[0].time
 222                 if (!oldonground)
 223                         hitgroundtime = f;
 224         }
 225         oldonground = clonground;
 226
 227         // calculate for swinging gun model
 228         // the gun bobs when running on the ground, but doesn't bob when you're in the air.
 229         vector gunorg = '0 0 0';
 230         static float bobmodel_scale = 0;
 231         static float time_ofs = 0; // makes the effect always restart in the same way
 232         if (clonground)
 233         {
 234                 if (time - hitgroundtime > 0.05)
 235                         bobmodel_scale = min(1, bobmodel_scale + frametime * 5);
 236         }
 237         else
 238                 bobmodel_scale = max(0, bobmodel_scale - frametime * 5);
 239
 240         float xyspeed = bound(0, vlen(vec2(view.velocity)), 400);
 241         if (bobmodel_scale && xyspeed)
 242         {
 243                 float bspeed = xyspeed * 0.01 * autocvar_cl_viewmodel_scale * bobmodel_scale;
 244                 float s = (time - time_ofs) * autocvar_cl_bobmodel_speed;
 245                 gunorg.y = bspeed * autocvar_cl_bobmodel_side * sin(s);
 246                 gunorg.z = bspeed * autocvar_cl_bobmodel_up * cos(s * 2);
 247         }
 248         else
 249                 time_ofs = time;
 250
 251         return gunorg;
 252 }
 253
 254 void viewmodel_animate(entity this)
 255 {
 256         if (autocvar_chase_active) return;
 257         if (STAT(HEALTH) <= 0) return;
 258
 259         entity view = CSQCModel_server2csqc(player_localentnum - 1);
 260
 261         if (autocvar_cl_followmodel)
 262         {
 263                 calc_followmodel_ofs(view);
 264                 this.origin += cl_followmodel_ofs;
 265         }
 266
 267         if (autocvar_cl_leanmodel)
 268                 this.angles += leanmodel_ofs(view);
 269
 270         // vertical view bobbing code
 271         // TODO: cl_bob
 272
 273         // horizontal view bobbing code
 274         // TODO: cl_bob2
 275
 276         // fall bobbing code
 277         // causes the view to swing down and back up when touching the ground
 278         // TODO: cl_bobfall
 279
 280         // gun model bobbing code
 281         if (autocvar_cl_bobmodel)
 282                 this.origin += bobmodel_ofs(view);
 283 }
 284
 285 .vector viewmodel_origin, viewmodel_angles;
 286 .float weapon_nextthink;
 287 .float weapon_eta_last;
 288 .float weapon_switchdelay;
 289
 290 .string name_last;
 291
 292 void viewmodel_draw(entity this)
 293 {
 294         if(!this.activeweapon || !autocvar_r_drawviewmodel)
 295                 return;
 296         int mask = (intermission || (STAT(HEALTH) <= 0) || autocvar_chase_active) ? 0 : MASK_NORMAL;
 297         float a = this.alpha;
 298         static bool wasinvehicle;
 299         bool invehicle = player_localentnum > maxclients;
 300         if (invehicle) a = -1;
 301         else if (wasinvehicle) a = 1;
 302         wasinvehicle = invehicle;
 303         Weapon wep = this.activeweapon;
 304         int c = entcs_GetClientColors(current_player);
 305         vector g = weaponentity_glowmod(wep, NULL, c, this);
 306         entity me = CSQCModel_server2csqc(player_localentnum - 1);
 307         int fx = ((me.csqcmodel_effects & EFMASK_CHEAP)
 308                 | EF_NODEPTHTEST)
 309                 &~ (EF_FULLBRIGHT); // can mask team color, so get rid of it
 310         for (entity e = this; e; e = e.weaponchild)
 311         {
 312                 e.drawmask = mask;
 313                 e.alpha = a;
 314                 e.colormap = 256 + c;  // colormap == 0 is black, c == 0 is white
 315                 e.glowmod = g;
 316                 e.csqcmodel_effects = fx;
 317                 CSQCModel_Effects_Apply(e);
 318         }
 319         if(a >= 0)
 320         {
 321                 string name = wep.mdl;
 322                 string newname = wep.wr_viewmodel(wep, this);
 323                 if(newname)
 324                         name = newname;
 325                 bool swap = name != this.name_last;
 326                 // if (swap)
 327                 {
 328                         this.name_last = name;
 329                         CL_WeaponEntity_SetModel(this, name, swap);
 330                         this.viewmodel_origin = this.origin;
 331                         this.viewmodel_angles = this.angles;
 332                 }
 333                 anim_update(this);
 334                 if ((!this.animstate_override && !this.animstate_looping) || time > this.animstate_endtime)
 335                         anim_set(this, this.anim_idle, true, false, false);
 336         }
 337         float f = 0; // 0..1; 0: fully active
 338         float rate = STAT(WEAPONRATEFACTOR);
 339         float eta = rate ? ((this.weapon_nextthink - time) / rate) : 0;
 340         if (eta <= 0) f = this.weapon_eta_last;
 341         else switch (this.state)
 342         {
 343                 case WS_RAISE:
 344                 {
 345                         f = eta / max(eta, this.weapon_switchdelay);
 346                         break;
 347                 }
 348                 case WS_DROP:
 349                 {
 350                         f = 1 - eta / max(eta, this.weapon_switchdelay);
 351                         break;
 352                 }
 353                 case WS_CLEAR:
 354                 {
 355                         f = 1;
 356                         break;
 357                 }
 358         }
 359         this.weapon_eta_last = f;
 360         this.origin = this.viewmodel_origin;
 361         this.angles = this.viewmodel_angles;
 362         this.angles_x = (-90 * f * f);
 363         viewmodel_animate(this);
 364         MUTATOR_CALLHOOK(DrawViewModel, this);
 365         setorigin(this, this.origin);
 366 }
 367
 368 STATIC_INIT(viewmodel) {
 369     for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 370         viewmodels[slot] = new(viewmodel);
 371 }
 372
 373 float showfps_prevfps;
 374 float showfps_prevfps_time;
 375 int showfps_framecounter;
 376
 377 void fpscounter_update()
 378 {
 379         if(!STAT(SHOWFPS))
 380                 return;
 381
 382         float currentTime = gettime(GETTIME_REALTIME);
 383         showfps_framecounter += 1;
 384         if(currentTime - showfps_prevfps_time > STAT(SHOWFPS))
 385         {
 386                 showfps_prevfps = showfps_framecounter/(currentTime - showfps_prevfps_time);
 387                 showfps_framecounter = 0;
 388                 showfps_prevfps_time = currentTime;
 389
 390                 int channel = MSG_C2S;
 391                 WriteHeader(channel, fpsreport);
 392                 WriteShort(channel, bound(0, rint(showfps_prevfps), 65535)); // prevent insane fps values
 393         }
 394 }
 395
 396 STATIC_INIT(fpscounter_init)
 397 {
 398         float currentTime = gettime(GETTIME_REALTIME);
 399         showfps_prevfps_time = currentTime; // we must initialize it to avoid an instant low frame sending
 400 }
 401
 402 void Porto_Draw(entity this);
 403 STATIC_INIT(Porto)
 404 {
 405         entity e = new_pure(porto);
 406         e.draw = Porto_Draw;
 407         IL_PUSH(g_drawables, e);
 408         e.dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY | DPCONTENTS_PLAYERCLIP;
 409 }
 410
 411 const int polyline_length = 16;
 412 .vector polyline[polyline_length];
 413 void Porto_Draw(entity this)
 414 {
 415         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 416         {
 417                 entity wepent = viewmodels[slot];
 418
 419                 if (wepent.activeweapon != WEP_PORTO) continue;
 420                 if (spectatee_status) continue;
 421                 if (WEP_CVAR(porto, secondary)) continue;
 422                 if (intermission == 1) continue;
 423                 if (intermission == 2) continue;
 424                 if (STAT(HEALTH) <= 0) continue;
 425
 426                 vector pos = view_origin;
 427                 vector dir = view_forward;
 428                 if (wepent.angles_held_status)
 429                 {
 430                         makevectors(wepent.angles_held);
 431                         dir = v_forward;
 432                 }
 433
 434                 wepent.polyline[0] = pos;
 435
 436                 int portal_number = 0, portal1_idx = 1, portal_max = 2;
 437                 int n = 1 + 2;  // 2 lines == 3 points
 438                 for (int idx = 0; idx < n && idx < polyline_length - 1; )
 439                 {
 440                         traceline(pos, pos + 65536 * dir, true, this);
 441                         dir = reflect(dir, trace_plane_normal);
 442                         pos = trace_endpos;
 443                         wepent.polyline[++idx] = pos;
 444                         if (trace_dphitq3surfaceflags & Q3SURFACEFLAG_SLICK || trace_dphitcontents & DPCONTENTS_PLAYERCLIP)
 445                         {
 446                                 n += 1;
 447                                 continue;
 448                         }
 449                         if (trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT)
 450                         {
 451                                 n = max(2, idx);
 452                                 break;
 453                         }
 454                         // check size
 455                         {
 456                                 vector ang = vectoangles2(trace_plane_normal, dir);
 457                                 ang.x = -ang.x;
 458                                 makevectors(ang);
 459                                 if (!CheckWireframeBox(this, pos - 48 * v_right - 48 * v_up + 16 * v_forward, 96 * v_right, 96 * v_up, 96 * v_forward))
 460                                 {
 461                                         n = max(2, idx);
 462                                         break;
 463                                 }
 464                         }
 465                         portal_number += 1;
 466                         if (portal_number >= portal_max) break;
 467                         if (portal_number == 1) portal1_idx = idx;
 468                 }
 469                 for (int idx = 0; idx < n - 1; ++idx)
 470                 {
 471                         vector p = wepent.polyline[idx], q = wepent.polyline[idx + 1];
 472                         if (idx == 0) p -= view_up * 16;  // line from player
 473                         vector rgb = (idx < portal1_idx) ? '1 0 0' : '0 0 1';
 474                         Draw_CylindricLine(p, q, 4, "", 1, 0, rgb, 0.5, DRAWFLAG_NORMAL, view_origin);
 475                 }
 476         }
 477 }
 478
 479 float drawtime;
 480 float avgspeed;
 481 vector GetCurrentFov(float fov)
 482 {
 483         float zoomsensitivity, zoomspeed, zoomfactor, zoomdir;
 484         float velocityzoom, curspeed;
 485         vector v;
 486
 487         zoomsensitivity = autocvar_cl_zoomsensitivity;
 488         zoomfactor = autocvar_cl_zoomfactor;
 489         if(zoomfactor < 1 || zoomfactor > 30)
 490                 zoomfactor = 2.5;
 491         zoomspeed = autocvar_cl_zoomspeed;
 492         if(zoomspeed >= 0)
 493         if(zoomspeed < 0.5 || zoomspeed > 16)
 494                         zoomspeed = 3.5;
 495
 496         zoomdir = button_zoom;
 497
 498         if(hud == HUD_NORMAL && !spectatee_status)
 499         {
 500                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 501                 {
 502                         entity wepent = viewmodels[slot];
 503                         if(wepent.switchweapon != wepent.activeweapon)
 504                                 continue;
 505                         Weapon wep = wepent.activeweapon;
 506                         if(wep != WEP_Null && wep.wr_zoomdir)
 507                         {
 508                                 bool do_zoom = wep.wr_zoomdir(wep); // TODO: merge this with wr_zoom?
 509                                 zoomdir += do_zoom;
 510                         }
 511                 }
 512         }
 513         if(spectatee_status > 0 || isdemo())
 514         {
 515                 if(spectatorbutton_zoom)
 516                 {
 517                         if(zoomdir)
 518                                 zoomdir = 0;
 519                         else
 520                                 zoomdir = 1;
 521                 }
 522                 // fteqcc failed twice here already, don't optimize this
 523         }
 524
 525         if(zoomdir) { zoomin_effect = 0; }
 526
 527         if(camera_active)
 528         {
 529                 current_viewzoom = min(1, current_viewzoom + drawframetime);
 530         }
 531         else if(autocvar_cl_spawnzoom && zoomin_effect)
 532         {
 533                 float spawnzoomfactor = bound(1, autocvar_cl_spawnzoom_factor, 30);
 534
 535                 current_viewzoom += (autocvar_cl_spawnzoom_speed * (spawnzoomfactor - current_viewzoom) * drawframetime);
 536                 current_viewzoom = bound(1 / spawnzoomfactor, current_viewzoom, 1);
 537                 if(current_viewzoom == 1) { zoomin_effect = 0; }
 538         }
 539         else
 540         {
 541                 if(zoomspeed < 0) // instant zoom
 542                 {
 543                         if(zoomdir)
 544                                 current_viewzoom = 1 / zoomfactor;
 545                         else
 546                                 current_viewzoom = 1;
 547                 }
 548                 else
 549                 {
 550                         if(zoomdir)
 551                                 current_viewzoom = 1 / bound(1, 1 / current_viewzoom + drawframetime * zoomspeed * (zoomfactor - 1), zoomfactor);
 552                         else
 553                                 current_viewzoom = bound(1 / zoomfactor, current_viewzoom + drawframetime * zoomspeed * (1 - 1 / zoomfactor), 1);
 554                 }
 555         }
 556
 557         if(almost_equals(current_viewzoom, 1))
 558                 current_zoomfraction = 0;
 559         else if(almost_equals(current_viewzoom, 1/zoomfactor))
 560                 current_zoomfraction = 1;
 561         else
 562                 current_zoomfraction = (current_viewzoom - 1) / (1/zoomfactor - 1);
 563
 564         if(zoomsensitivity < 1)
 565                 setsensitivityscale(current_viewzoom ** (1 - zoomsensitivity));
 566         else
 567                 setsensitivityscale(1);
 568
 569         if(autocvar_cl_velocityzoom_enabled && autocvar_cl_velocityzoom_type) // _type = 0 disables velocity zoom too
 570         {
 571                 if(intermission) { curspeed = 0; }
 572                 else
 573                 {
 574
 575                         makevectors(view_angles);
 576                         v = pmove_vel;
 577                         if(csqcplayer)
 578                                 v = csqcplayer.velocity;
 579
 580                         switch(autocvar_cl_velocityzoom_type)
 581                         {
 582                                 case 3: curspeed = max(0, v_forward * v); break;
 583                                 case 2: curspeed = (v_forward * v); break;
 584                                 case 1: default: curspeed = vlen(v); break;
 585                         }
 586                 }
 587
 588                 velocityzoom = bound(0, drawframetime / max(0.000000001, autocvar_cl_velocityzoom_time), 1); // speed at which the zoom adapts to player velocity
 589                 avgspeed = avgspeed * (1 - velocityzoom) + (curspeed / autocvar_cl_velocityzoom_speed) * velocityzoom;
 590                 velocityzoom = exp(float2range11(avgspeed * -autocvar_cl_velocityzoom_factor / 1) * 1);
 591
 592                 //print(ftos(avgspeed), " avgspeed, ", ftos(curspeed), " curspeed, ", ftos(velocityzoom), " return\n"); // for debugging
 593         }
 594         else
 595                 velocityzoom = 1;
 596
 597         float frustumx, frustumy, fovx, fovy;
 598         frustumy = tan(fov * M_PI / 360.0) * 0.75 * current_viewzoom * velocityzoom;
 599         frustumx = frustumy * vid_width / vid_height / vid_pixelheight;
 600         fovx = atan2(frustumx, 1) / M_PI * 360.0;
 601         fovy = atan2(frustumy, 1) / M_PI * 360.0;
 602
 603         return '1 0 0' * fovx + '0 1 0' * fovy;
 604 }
 605
 606 vector GetViewLocationFOV(float fov)
 607 {
 608         float frustumy = tan(fov * M_PI / 360.0) * 0.75;
 609         float frustumx = frustumy * vid_width / vid_height / vid_pixelheight;
 610         float fovx = atan2(frustumx, 1) / M_PI * 360.0;
 611         float fovy = atan2(frustumy, 1) / M_PI * 360.0;
 612         return '1 0 0' * fovx + '0 1 0' * fovy;
 613 }
 614
 615 vector GetOrthoviewFOV(vector ov_worldmin, vector ov_worldmax, vector ov_mid, vector ov_org)
 616 {
 617         float fovx, fovy;
 618         float width = (ov_worldmax.x - ov_worldmin.x);
 619         float height = (ov_worldmax.y - ov_worldmin.y);
 620         float distance_to_middle_of_world = vlen(ov_mid - ov_org);
 621         fovx = atan2(width/2, distance_to_middle_of_world) / M_PI * 360.0;
 622         fovy = atan2(height/2, distance_to_middle_of_world) / M_PI * 360.0;
 623         return '1 0 0' * fovx + '0 1 0' * fovy;
 624 }
 625
 626 // this function must match W_SetupShot!
 627 float zoomscript_caught;
 628
 629 vector wcross_origin;
 630 float wcross_scale_prev, wcross_alpha_prev;
 631 vector wcross_color_prev;
 632 float wcross_scale_goal_prev, wcross_alpha_goal_prev;
 633 vector wcross_color_goal_prev;
 634 float wcross_changedonetime;
 635
 636 string wcross_name_goal_prev, wcross_name_goal_prev_prev;
 637 float wcross_resolution_goal_prev, wcross_resolution_goal_prev_prev;
 638 float wcross_name_changestarttime, wcross_name_changedonetime;
 639 float wcross_name_alpha_goal_prev, wcross_name_alpha_goal_prev_prev;
 640
 641 float wcross_ring_prev;
 642
 643 entity trueaim;
 644 entity trueaim_rifle;
 645
 646 const float SHOTTYPE_HITTEAM = 1;
 647 const float SHOTTYPE_HITOBSTRUCTION = 2;
 648 const float SHOTTYPE_HITWORLD = 3;
 649 const float SHOTTYPE_HITENEMY = 4;
 650
 651 void TrueAim_Init()
 652 {
 653         (trueaim = new_pure(trueaim)).dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY | DPCONTENTS_CORPSE;
 654         (trueaim_rifle = new_pure(trueaim_rifle)).dphitcontentsmask = DPCONTENTS_BODY | DPCONTENTS_CORPSE;
 655 }
 656
 657 float EnemyHitCheck()
 658 {
 659         float t, n;
 660         wcross_origin = project_3d_to_2d(trace_endpos);
 661         wcross_origin.z = 0;
 662         if(trace_ent)
 663                 n = trace_ent.entnum;
 664         else
 665                 n = trace_networkentity;
 666         if(n < 1)
 667                 return SHOTTYPE_HITWORLD;
 668         if(n > maxclients)
 669                 return SHOTTYPE_HITWORLD;
 670         t = entcs_GetTeam(n - 1);
 671         if(teamplay)
 672                 if(t == myteam)
 673                         return SHOTTYPE_HITTEAM;
 674         if(t == NUM_SPECTATOR)
 675                 return SHOTTYPE_HITWORLD;
 676         return SHOTTYPE_HITENEMY;
 677 }
 678
 679 float TrueAimCheck(entity wepent)
 680 {
 681         float nudge = 1; // added to traceline target and subtracted from result TOOD(divVerent): do we still need this? Doesn't the engine do this now for us?
 682         vector vecs, trueaimpoint, w_shotorg;
 683         vector mi, ma, dv;
 684         float shottype;
 685         entity ta;
 686         float mv;
 687
 688         mi = ma = '0 0 0';
 689         ta = trueaim;
 690         mv = MOVE_NOMONSTERS;
 691
 692         switch(wepent.activeweapon) // WEAPONTODO
 693         {
 694                 case WEP_TUBA: // no aim
 695                 case WEP_PORTO: // shoots from eye
 696                 case WEP_NEXBALL: // shoots from eye
 697                 case WEP_HOOK: // no trueaim
 698                 case WEP_MORTAR: // toss curve
 699                         return SHOTTYPE_HITWORLD;
 700                 case WEP_VORTEX:
 701                 case WEP_VAPORIZER:
 702                         mv = MOVE_NORMAL;
 703                         break;
 704                 case WEP_RIFLE:
 705                         ta = trueaim_rifle;
 706                         mv = MOVE_NORMAL;
 707                         if(zoomscript_caught)
 708                         {
 709                                 tracebox(view_origin, '0 0 0', '0 0 0', view_origin + view_forward * max_shot_distance, mv, ta);
 710                                 return EnemyHitCheck();
 711                         }
 712                         break;
 713                 case WEP_DEVASTATOR: // projectile has a size!
 714                         mi = '-3 -3 -3';
 715                         ma = '3 3 3';
 716                         break;
 717                 case WEP_FIREBALL: // projectile has a size!
 718                         mi = '-16 -16 -16';
 719                         ma = '16 16 16';
 720                         break;
 721                 case WEP_SEEKER: // projectile has a size!
 722                         mi = '-2 -2 -2';
 723                         ma = '2 2 2';
 724                         break;
 725                 case WEP_ELECTRO: // projectile has a size!
 726                         mi = '0 0 -3';
 727                         ma = '0 0 -3';
 728                         break;
 729         }
 730
 731         vector traceorigin = entcs_receiver(player_localentnum - 1).origin + (eZ * STAT(VIEWHEIGHT));
 732
 733         vecs = decompressShotOrigin(STAT(SHOTORG));
 734
 735         traceline(traceorigin, traceorigin + view_forward * max_shot_distance, mv, ta);
 736         trueaimpoint = trace_endpos;
 737
 738         if(vdist((trueaimpoint - traceorigin), <, g_trueaim_minrange))
 739                 trueaimpoint = traceorigin + view_forward * g_trueaim_minrange;
 740
 741         if(vecs.x > 0)
 742                 vecs.y = -vecs.y;
 743         else
 744                 vecs = '0 0 0';
 745
 746         dv = view_right * vecs.y + view_up * vecs.z;
 747         w_shotorg = traceorigin + dv;
 748
 749         // now move the vecs forward as much as requested if possible
 750         tracebox(w_shotorg, mi, ma, w_shotorg + view_forward * (vecs.x + nudge), MOVE_NORMAL, ta); // FIXME this MOVE_NORMAL part will misbehave a little in csqc
 751         w_shotorg = trace_endpos - view_forward * nudge;
 752
 753         tracebox(w_shotorg, mi, ma, trueaimpoint, MOVE_NORMAL, ta);
 754         shottype = EnemyHitCheck();
 755         if(shottype != SHOTTYPE_HITWORLD)
 756                 return shottype;
 757
 758 #if 0
 759         // FIXME WHY DOES THIS NOT WORK FOR THE ROCKET LAUNCHER?
 760         // or rather, I know why, but see no fix
 761         if(vlen(trace_endpos - trueaimpoint) > vlen(ma) + vlen(mi) + 1)
 762                 // yes, this is an ugly hack... but it seems good enough to find out whether the test hits the same place as the initial trace
 763                 return SHOTTYPE_HITOBSTRUCTION;
 764 #endif
 765
 766         return SHOTTYPE_HITWORLD;
 767 }
 768
 769 void PostInit();
 770 void CSQC_Demo_Camera();
 771 float camera_mode;
 772 const float CAMERA_FREE = 1;
 773 const float CAMERA_CHASE = 2;
 774 float reticle_type;
 775 string NextFrameCommand;
 776
 777 vector freeze_org, freeze_ang;
 778 entity nightvision_noise, nightvision_noise2;
 779
 780 const float MAX_TIME_DIFF = 5;
 781 float pickup_crosshair_time, pickup_crosshair_size;
 782 float hitindication_crosshair_size;
 783 float use_vortex_chargepool;
 784
 785 float myhealth, myhealth_prev;
 786 float myhealth_flash;
 787
 788 float old_blurradius, old_bluralpha;
 789 float old_sharpen_intensity;
 790
 791 vector myhealth_gentlergb;
 792
 793 float contentavgalpha, liquidalpha_prev;
 794 vector liquidcolor_prev;
 795
 796 float eventchase_current_distance;
 797 float eventchase_running;
 798 bool WantEventchase(entity this)
 799 {
 800         if(autocvar_cl_orthoview)
 801                 return false;
 802         if(STAT(GAME_STOPPED) || intermission)
 803                 return true;
 804         if(this.viewloc)
 805                 return true;
 806         if(spectatee_status >= 0)
 807         {
 808                 if(hud != HUD_NORMAL && (autocvar_cl_eventchase_vehicle || spectatee_status > 0))
 809                         return true;
 810                 if(MUTATOR_CALLHOOK(WantEventchase, this))
 811                         return true;
 812                 if(autocvar_cl_eventchase_frozen && STAT(FROZEN))
 813                         return true;
 814                 if(autocvar_cl_eventchase_death && (STAT(HEALTH) <= 0))
 815                 {
 816                         if(autocvar_cl_eventchase_death == 2)
 817                         {
 818                                 // don't stop eventchase once it's started (even if velocity changes afterwards)
 819                                 if(this.velocity == '0 0 0' || eventchase_running)
 820                                         return true;
 821                         }
 822                         else return true;
 823                 }
 824         }
 825         return false;
 826 }
 827
 828 void HUD_Crosshair_Vehicle(entity this)
 829 {
 830         if(hud != HUD_BUMBLEBEE_GUN)
 831         {
 832                 Vehicle info = Vehicles_from(hud);
 833                 info.vr_crosshair(info, this);
 834         }
 835 }
 836
 837 vector damage_blurpostprocess, content_blurpostprocess;
 838
 839 float unaccounted_damage = 0;
 840 void UpdateDamage()
 841 {
 842         // accumulate damage with each stat update
 843         static float damage_total_prev = 0;
 844         float damage_total = STAT(DAMAGE_DEALT_TOTAL);
 845         float unaccounted_damage_new = COMPARE_INCREASING(damage_total, damage_total_prev);
 846         damage_total_prev = damage_total;
 847
 848         static float damage_dealt_time_prev = 0;
 849         float damage_dealt_time = STAT(HIT_TIME);
 850         if (damage_dealt_time != damage_dealt_time_prev)
 851         {
 852                 unaccounted_damage += unaccounted_damage_new;
 853                 LOG_TRACE("dmg total: ", ftos(unaccounted_damage), " (+", ftos(unaccounted_damage_new), ")");
 854         }
 855         damage_dealt_time_prev = damage_dealt_time;
 856
 857         // prevent hitsound when switching spectatee
 858         static float spectatee_status_prev = 0;
 859         if (spectatee_status != spectatee_status_prev)
 860                 unaccounted_damage = 0;
 861         spectatee_status_prev = spectatee_status;
 862 }
 863
 864 void HitSound()
 865 {
 866         // varying sound pitch
 867
 868         bool have_arc = false;
 869         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 870         {
 871                 entity wepent = viewmodels[slot];
 872
 873                 if(wepent.activeweapon == WEP_ARC)
 874                         have_arc = true;
 875         }
 876
 877         static float hitsound_time_prev = 0;
 878         // HACK: the only way to get the arc to sound consistent with pitch shift is to ignore cl_hitsound_antispam_time
 879         bool arc_hack = have_arc && autocvar_cl_hitsound >= 2;
 880         if (arc_hack || COMPARE_INCREASING(time, hitsound_time_prev) > autocvar_cl_hitsound_antispam_time)
 881         {
 882                 if (autocvar_cl_hitsound && unaccounted_damage)
 883                 {
 884                         // customizable gradient function that crosses (0,a), (c,1) and asymptotically approaches b
 885                         float a = autocvar_cl_hitsound_max_pitch;
 886                         float b = autocvar_cl_hitsound_min_pitch;
 887                         float c = autocvar_cl_hitsound_nom_damage;
 888                         float d = unaccounted_damage;
 889                         float pitch_shift = (b*d*(a-1) + a*c*(1-b)) / (d*(a-1) + c*(1-b));
 890
 891                         // if sound variation is disabled, set pitch_shift to 1
 892                         if (autocvar_cl_hitsound == 1)
 893                                 pitch_shift = 1;
 894
 895                         // if pitch shift is reversed, mirror in (max-min)/2 + min
 896                         if (autocvar_cl_hitsound == 3)
 897                         {
 898                                 float mirror_value = (a-b)/2 + b;
 899                                 pitch_shift = mirror_value + (mirror_value - pitch_shift);
 900                         }
 901
 902                         LOG_TRACE("dmg total (dmg): ", ftos(unaccounted_damage), " , pitch shift: ", ftos(pitch_shift));
 903
 904                         // todo: avoid very long and very short sounds from wave stretching using different sound files? seems unnecessary
 905                         // todo: normalize sound pressure levels? seems unnecessary
 906
 907                         sound7(NULL, CH_INFO, SND(HIT), VOL_BASE, ATTN_NONE, pitch_shift * 100, 0);
 908                 }
 909                 unaccounted_damage = 0;
 910                 hitsound_time_prev = time;
 911         }
 912
 913         static float typehit_time_prev = 0;
 914         float typehit_time = STAT(TYPEHIT_TIME);
 915         if (COMPARE_INCREASING(typehit_time, typehit_time_prev) > autocvar_cl_hitsound_antispam_time)
 916         {
 917                 sound(NULL, CH_INFO, SND_TYPEHIT, VOL_BASE, ATTN_NONE);
 918                 typehit_time_prev = typehit_time;
 919         }
 920
 921         static float kill_time_prev = 0;
 922         float kill_time = STAT(KILL_TIME);
 923         if (COMPARE_INCREASING(kill_time, kill_time_prev) > autocvar_cl_hitsound_antispam_time)
 924         {
 925                 sound(NULL, CH_INFO, SND_KILL, VOL_BASE, ATTN_NONE);
 926                 kill_time_prev = kill_time;
 927         }
 928 }
 929
 930 vector crosshair_getcolor(entity this, float health_stat)
 931 {
 932         static float rainbow_last_flicker;
 933         static vector rainbow_prev_color;
 934         vector wcross_color = '0 0 0';
 935         switch(autocvar_crosshair_color_special)
 936         {
 937                 case 1: // crosshair_color_per_weapon
 938                 {
 939                         if(this != WEP_Null && hud == HUD_NORMAL)
 940                         {
 941                                 wcross_color = this.wpcolor;
 942                                 break;
 943                         }
 944                         else { goto normalcolor; }
 945                 }
 946
 947                 case 2: // crosshair_color_by_health
 948                 {
 949                         vector v = healtharmor_maxdamage(health_stat, STAT(ARMOR), armorblockpercent, DEATH_WEAPON.m_id);
 950                         float hp = floor(v.x + 1);
 951
 952                         //x = red
 953                         //y = green
 954                         //z = blue
 955
 956                         wcross_color.z = 0;
 957
 958                         if(hp > 200)
 959                         {
 960                                 wcross_color.x = 0;
 961                                 wcross_color.y = 1;
 962                         }
 963                         else if(hp > 150)
 964                         {
 965                                 wcross_color.x = 0.4 - (hp-150)*0.02 * 0.4;
 966                                 wcross_color.y = 0.9 + (hp-150)*0.02 * 0.1;
 967                         }
 968                         else if(hp > 100)
 969                         {
 970                                 wcross_color.x = 1 - (hp-100)*0.02 * 0.6;
 971                                 wcross_color.y = 1 - (hp-100)*0.02 * 0.1;
 972                                 wcross_color.z = 1 - (hp-100)*0.02;
 973                         }
 974                         else if(hp > 50)
 975                         {
 976                                 wcross_color.x = 1;
 977                                 wcross_color.y = 1;
 978                                 wcross_color.z = 0.2 + (hp-50)*0.02 * 0.8;
 979                         }
 980                         else if(hp > 20)
 981                         {
 982                                 wcross_color.x = 1;
 983                                 wcross_color.y = (hp-20)*90/27/100;
 984                                 wcross_color.z = (hp-20)*90/27/100 * 0.2;
 985                         }
 986                         else
 987                         {
 988                                 wcross_color.x = 1;
 989                                 wcross_color.y = 0;
 990                         }
 991                         break;
 992                 }
 993
 994                 case 3: // crosshair_color_rainbow
 995                 {
 996                         if(time >= rainbow_last_flicker)
 997                         {
 998                                 rainbow_prev_color = randomvec() * autocvar_crosshair_color_special_rainbow_brightness;
 999                                 rainbow_last_flicker = time + autocvar_crosshair_color_special_rainbow_delay;
1000                         }
1001                         wcross_color = rainbow_prev_color;
1002                         break;
1003                 }
1004 LABEL(normalcolor)
1005                 default: { wcross_color = stov(autocvar_crosshair_color); break; }
1006         }
1007
1008         return wcross_color;
1009 }
1010
1011 void HUD_Crosshair(entity this)
1012 {
1013         float f, i, j;
1014         vector v;
1015         if(!scoreboard_active && !camera_active && intermission != 2 && !STAT(GAME_STOPPED) &&
1016                 spectatee_status != -1 && (!csqcplayer.viewloc || (!spectatee_status && (csqcplayer.viewloc.spawnflags & VIEWLOC_FREEAIM))) && !MUTATOR_CALLHOOK(DrawCrosshair) &&
1017                 !HUD_MinigameMenu_IsOpened() )
1018         {
1019                 if (!autocvar_crosshair_enabled) // main toggle for crosshair rendering
1020                         return;
1021
1022                 if (spectatee_status > 0 && STAT(CAMERA_SPECTATOR) == 2)
1023                         return;
1024
1025                 if (hud != HUD_NORMAL)
1026                 {
1027                         HUD_Crosshair_Vehicle(this);
1028                         return;
1029                 }
1030
1031                 string wcross_style;
1032                 float wcross_alpha, wcross_resolution;
1033                 wcross_style = autocvar_crosshair;
1034                 if (csqcplayer.viewloc && (csqcplayer.viewloc.spawnflags & VIEWLOC_FREEAIM) && autocvar_crosshair_2d != "")
1035                         wcross_style = autocvar_crosshair_2d;
1036                 if (wcross_style == "0")
1037                         return;
1038                 wcross_resolution = autocvar_crosshair_size;
1039                 if (wcross_resolution == 0)
1040                         return;
1041                 wcross_alpha = autocvar_crosshair_alpha;
1042                 if (wcross_alpha == 0)
1043                         return;
1044
1045                 // TrueAim check
1046                 float shottype;
1047
1048                 // wcross_origin = '0.5 0 0' * vid_conwidth + '0 0.5 0' * vid_conheight;
1049                 if(csqcplayer.viewloc && (csqcplayer.viewloc.spawnflags & VIEWLOC_FREEAIM))
1050                         wcross_origin = viewloc_mousepos;
1051                 else
1052                         wcross_origin = project_3d_to_2d(view_origin + max_shot_distance * view_forward);
1053                 wcross_origin.z = 0;
1054                 if(autocvar_crosshair_hittest)
1055                 {
1056                         vector wcross_oldorigin;
1057                         entity thiswep = viewmodels[0]; // TODO: unhardcode
1058                         wcross_oldorigin = wcross_origin;
1059                         shottype = TrueAimCheck(thiswep);
1060                         if(shottype == SHOTTYPE_HITWORLD)
1061                         {
1062                                 v = wcross_origin - wcross_oldorigin;
1063                                 v.x /= vid_conwidth;
1064                                 v.y /= vid_conheight;
1065                                 if(vdist(v, >, 0.01))
1066                                         shottype = SHOTTYPE_HITOBSTRUCTION;
1067                         }
1068                         if(!autocvar_crosshair_hittest_showimpact)
1069                                 wcross_origin = wcross_oldorigin;
1070                 }
1071                 else
1072                         shottype = SHOTTYPE_HITWORLD;
1073
1074                 vector wcross_color = '0 0 0', wcross_size = '0 0 0';
1075                 string wcross_name = "";
1076                 float wcross_scale, wcross_blur;
1077
1078         entity e = WEP_Null;
1079                 if(autocvar_crosshair_per_weapon || (autocvar_crosshair_color_special == 1))
1080                 {
1081                         entity wepent = viewmodels[0]; // TODO: unhardcode
1082                         e = wepent.switchingweapon;
1083                         if(e)
1084                         {
1085                                 if(autocvar_crosshair_per_weapon)
1086                                 {
1087                                         // WEAPONTODO: access these through some general settings (with non-balance config settings)
1088                                         //wcross_resolution *= cvar(strcat("crosshair_", wcross_wep, "_size"));
1089                                         //if (wcross_resolution == 0)
1090                                                 //return;
1091
1092                                         //wcross_style = cvar_string(strcat("crosshair_", wcross_wep));
1093                                         wcross_resolution *= e.w_crosshair_size;
1094                                         wcross_name = e.w_crosshair;
1095                                 }
1096                         }
1097                 }
1098
1099                 if(wcross_name == "")
1100                         wcross_name = strcat("gfx/crosshair", wcross_style);
1101
1102                 // MAIN CROSSHAIR COLOR DECISION
1103                 wcross_color = crosshair_getcolor(e, STAT(HEALTH));
1104
1105                 if(autocvar_crosshair_effect_scalefade)
1106                 {
1107                         wcross_scale = wcross_resolution;
1108                         wcross_resolution = 1;
1109                 }
1110                 else
1111                 {
1112                         wcross_scale = 1;
1113                 }
1114
1115                 if(autocvar_crosshair_pickup)
1116                 {
1117                         float stat_pickup_time = STAT(LAST_PICKUP);
1118
1119                         if(pickup_crosshair_time < stat_pickup_time)
1120                         {
1121                                 if(time - stat_pickup_time < MAX_TIME_DIFF) // don't trigger the animation if it's too old
1122                                         pickup_crosshair_size = 1;
1123
1124                                 pickup_crosshair_time = stat_pickup_time;
1125                         }
1126
1127                         if(pickup_crosshair_size > 0)
1128                                 pickup_crosshair_size -= autocvar_crosshair_pickup_speed * frametime;
1129                         else
1130                                 pickup_crosshair_size = 0;
1131
1132                         wcross_scale += sin(pickup_crosshair_size) * autocvar_crosshair_pickup;
1133                 }
1134
1135                 // todo: make crosshair hit indication dependent on damage dealt
1136                 if(autocvar_crosshair_hitindication)
1137                 {
1138                         vector hitindication_color = ((autocvar_crosshair_color_special == 1) ? stov(autocvar_crosshair_hitindication_per_weapon_color) : stov(autocvar_crosshair_hitindication_color));
1139
1140                         if(unaccounted_damage)
1141                         {
1142                                 hitindication_crosshair_size = 1;
1143                         }
1144
1145                         if(hitindication_crosshair_size > 0)
1146                                 hitindication_crosshair_size -= autocvar_crosshair_hitindication_speed * frametime;
1147                         else
1148                                 hitindication_crosshair_size = 0;
1149
1150                         wcross_scale += sin(hitindication_crosshair_size) * autocvar_crosshair_hitindication;
1151                         wcross_color.x += sin(hitindication_crosshair_size) * hitindication_color.x;
1152                         wcross_color.y += sin(hitindication_crosshair_size) * hitindication_color.y;
1153                         wcross_color.z += sin(hitindication_crosshair_size) * hitindication_color.z;
1154                 }
1155
1156                 if(shottype == SHOTTYPE_HITENEMY)
1157                         wcross_scale *= autocvar_crosshair_hittest; // is not queried if hittest is 0
1158                 if(shottype == SHOTTYPE_HITTEAM)
1159                         wcross_scale /= autocvar_crosshair_hittest; // is not queried if hittest is 0
1160
1161                 f = fabs(autocvar_crosshair_effect_time);
1162                 if(wcross_scale != wcross_scale_goal_prev || wcross_alpha != wcross_alpha_goal_prev || wcross_color != wcross_color_goal_prev)
1163                 {
1164                         wcross_changedonetime = time + f;
1165                 }
1166                 if(wcross_name != wcross_name_goal_prev || wcross_resolution != wcross_resolution_goal_prev)
1167                 {
1168                         wcross_name_changestarttime = time;
1169                         wcross_name_changedonetime = time + f;
1170                         if(wcross_name_goal_prev_prev)
1171                                 strunzone(wcross_name_goal_prev_prev);
1172                         wcross_name_goal_prev_prev = wcross_name_goal_prev;
1173                         wcross_name_goal_prev = strzone(wcross_name);
1174                         wcross_name_alpha_goal_prev_prev = wcross_name_alpha_goal_prev;
1175                         wcross_resolution_goal_prev_prev = wcross_resolution_goal_prev;
1176                         wcross_resolution_goal_prev = wcross_resolution;
1177                 }
1178
1179                 wcross_scale_goal_prev = wcross_scale;
1180                 wcross_alpha_goal_prev = wcross_alpha;
1181                 wcross_color_goal_prev = wcross_color;
1182
1183                 if(spectatee_status == -1 && shottype == SHOTTYPE_HITTEAM || (shottype == SHOTTYPE_HITOBSTRUCTION && autocvar_crosshair_hittest_blur && !autocvar_chase_active))
1184                 {
1185                         wcross_blur = 1;
1186                         wcross_alpha *= 0.75;
1187                 }
1188                 else
1189                         wcross_blur = 0;
1190                 // *_prev is at time-frametime
1191                 // * is at wcross_changedonetime+f
1192                 // what do we have at time?
1193                 if(time < wcross_changedonetime)
1194                 {
1195                         f = frametime / (wcross_changedonetime - time + frametime);
1196                         wcross_scale = f * wcross_scale + (1 - f) * wcross_scale_prev;
1197                         wcross_alpha = f * wcross_alpha + (1 - f) * wcross_alpha_prev;
1198                         wcross_color = f * wcross_color + (1 - f) * wcross_color_prev;
1199                 }
1200
1201                 wcross_scale_prev = wcross_scale;
1202                 wcross_alpha_prev = wcross_alpha;
1203                 wcross_color_prev = wcross_color;
1204
1205                 MUTATOR_CALLHOOK(UpdateCrosshair);
1206
1207                 wcross_scale *= 1 - autocvar__menu_alpha;
1208                 wcross_alpha *= 1 - autocvar__menu_alpha;
1209                 wcross_size = draw_getimagesize(wcross_name) * wcross_scale;
1210
1211                 if(wcross_scale >= 0.001 && wcross_alpha >= 0.001)
1212                 {
1213                         // crosshair rings for weapon stats
1214                         if (autocvar_crosshair_ring || autocvar_crosshair_ring_reload)
1215                         {
1216                                 // declarations and stats
1217                                 float ring_value = 0, ring_scale = 0, ring_alpha = 0, ring_inner_value = 0, ring_inner_alpha = 0;
1218                                 string ring_image = string_null, ring_inner_image = string_null;
1219                                 vector ring_rgb = '0 0 0', ring_inner_rgb = '0 0 0';
1220
1221                                 ring_scale = autocvar_crosshair_ring_size;
1222
1223                                 entity wepent = viewmodels[0]; // TODO: unhardcode
1224
1225                                 int weapon_clipload = wepent.clip_load;
1226                                 int weapon_clipsize = wepent.clip_size;
1227
1228                                 float arc_heat = wepent.arc_heat_percent;
1229                                 float vcharge = wepent.vortex_charge;
1230                                 float vchargepool = wepent.vortex_chargepool_ammo;
1231
1232                                 if(vortex_charge_movingavg == 0) // this should only happen if we have just loaded up the game
1233                                         vortex_charge_movingavg = vcharge;
1234
1235                                 // handle the values
1236                                 if (autocvar_crosshair_ring && wepent.activeweapon == WEP_VORTEX && vcharge && autocvar_crosshair_ring_vortex) // ring around crosshair representing velocity-dependent damage for the vortex
1237                                 {
1238                                         if (vchargepool || use_vortex_chargepool) {
1239                                                 use_vortex_chargepool = 1;
1240                                                 ring_inner_value = vchargepool;
1241                                         } else {
1242                                                 vortex_charge_movingavg = (1 - autocvar_crosshair_ring_vortex_currentcharge_movingavg_rate) * vortex_charge_movingavg + autocvar_crosshair_ring_vortex_currentcharge_movingavg_rate * vcharge;
1243                                                 ring_inner_value = bound(0, autocvar_crosshair_ring_vortex_currentcharge_scale * (vcharge - vortex_charge_movingavg), 1);
1244                                         }
1245
1246                                         ring_inner_alpha = autocvar_crosshair_ring_vortex_inner_alpha;
1247                                         ring_inner_rgb = vec3(autocvar_crosshair_ring_vortex_inner_color_red, autocvar_crosshair_ring_vortex_inner_color_green, autocvar_crosshair_ring_vortex_inner_color_blue);
1248                                         ring_inner_image = "gfx/crosshair_ring_inner.tga";
1249
1250                                         // draw the outer ring to show the current charge of the weapon
1251                                         ring_value = vcharge;
1252                                         ring_alpha = autocvar_crosshair_ring_vortex_alpha;
1253                                         ring_rgb = wcross_color;
1254                                         ring_image = "gfx/crosshair_ring_nexgun.tga";
1255                                 }
1256                                 else if (autocvar_crosshair_ring && wepent.activeweapon == WEP_MINE_LAYER && WEP_CVAR(minelayer, limit) && autocvar_crosshair_ring_minelayer)
1257                                 {
1258                                         ring_value = bound(0, wepent.minelayer_mines / WEP_CVAR(minelayer, limit), 1); // if you later need to use the count of bullets in another place, then add a float for it. For now, no need to.
1259                                         ring_alpha = autocvar_crosshair_ring_minelayer_alpha;
1260                                         ring_rgb = wcross_color;
1261                                         ring_image = "gfx/crosshair_ring.tga";
1262                                 }
1263                                 else if (wepent.activeweapon == WEP_HAGAR && wepent.hagar_load && autocvar_crosshair_ring_hagar)
1264                                 {
1265                                         ring_value = bound(0, wepent.hagar_load / WEP_CVAR_SEC(hagar, load_max), 1);
1266                                         ring_alpha = autocvar_crosshair_ring_hagar_alpha;
1267                                         ring_rgb = wcross_color;
1268                                         ring_image = "gfx/crosshair_ring.tga";
1269                                 }
1270                                 else if(autocvar_crosshair_ring_reload && weapon_clipsize) // forces there to be only an ammo ring
1271                                 {
1272                                         ring_value = bound(0, weapon_clipload / weapon_clipsize, 1);
1273                                         ring_scale = autocvar_crosshair_ring_reload_size;
1274                                         ring_alpha = autocvar_crosshair_ring_reload_alpha;
1275                                         ring_rgb = wcross_color;
1276
1277                                         // Note: This is to stop Taoki from complaining that the image doesn't match all potential balances.
1278                                         // if a new image for another weapon is added, add the code (and its respective file/value) here
1279                                         if ((wepent.activeweapon == WEP_RIFLE) && (weapon_clipsize == 80))
1280                                                 ring_image = "gfx/crosshair_ring_rifle.tga";
1281                                         else
1282                                                 ring_image = "gfx/crosshair_ring.tga";
1283                                 }
1284                                 else if ( autocvar_crosshair_ring && autocvar_crosshair_ring_arc && arc_heat && wepent.activeweapon == WEP_ARC )
1285                                 {
1286                                         ring_value = arc_heat;
1287                                         ring_alpha = (1-arc_heat)*autocvar_crosshair_ring_arc_cold_alpha +
1288                                                 arc_heat*autocvar_crosshair_ring_arc_hot_alpha;
1289                                         ring_rgb = (1-arc_heat)*wcross_color + arc_heat*autocvar_crosshair_ring_arc_hot_color;
1290                                         ring_image = "gfx/crosshair_ring.tga";
1291                                 }
1292
1293                                 // if in weapon switch animation, fade ring out/in
1294                                 if(autocvar_crosshair_effect_time > 0)
1295                                 {
1296                                         f = (time - wcross_name_changestarttime) / autocvar_crosshair_effect_time;
1297                                         if (f >= 1)
1298                                         {
1299                                                 wcross_ring_prev = ((ring_image) ? true : false);
1300                                         }
1301
1302                                         if(wcross_ring_prev)
1303                                         {
1304                                                 if(f < 1)
1305                                                         ring_alpha *= fabs(1 - bound(0, f, 1));
1306                                         }
1307                                         else
1308                                         {
1309                                                 if(f < 1)
1310                                                         ring_alpha *= bound(0, f, 1);
1311                                         }
1312                                 }
1313
1314                                 if (autocvar_crosshair_ring_inner && ring_inner_value) // lets draw a ring inside a ring so you can ring while you ring
1315                                         DrawCircleClippedPic(wcross_origin, wcross_size.x * ring_scale, ring_inner_image, ring_inner_value, ring_inner_rgb, wcross_alpha * ring_inner_alpha, DRAWFLAG_ADDITIVE);
1316
1317                                 if (ring_value)
1318                                         DrawCircleClippedPic(wcross_origin, wcross_size.x * ring_scale, ring_image, ring_value, ring_rgb, wcross_alpha * ring_alpha, DRAWFLAG_ADDITIVE);
1319                         }
1320
1321 #define CROSSHAIR_DO_BLUR(M,sz,wcross_name,wcross_alpha) \
1322                         MACRO_BEGIN { \
1323                                 if(wcross_blur > 0) \
1324                                 { \
1325                                         for(i = -2; i <= 2; ++i) \
1326                                         for(j = -2; j <= 2; ++j) \
1327                                         M(i,j,sz,wcross_name,wcross_alpha*0.04); \
1328                                 } \
1329                                 else \
1330                                 { \
1331                                         M(0,0,sz,wcross_name,wcross_alpha); \
1332                                 } \
1333                         } MACRO_END
1334
1335 #define CROSSHAIR_DRAW_SINGLE(i,j,sz,wcross_name,wcross_alpha) \
1336                         drawpic(wcross_origin - ('0.5 0 0' * (sz * wcross_size.x + i * wcross_blur) + '0 0.5 0' * (sz * wcross_size.y + j * wcross_blur)), wcross_name, sz * wcross_size, wcross_color, wcross_alpha, DRAWFLAG_NORMAL)
1337
1338 #define CROSSHAIR_DRAW(sz,wcross_name,wcross_alpha) \
1339                         CROSSHAIR_DO_BLUR(CROSSHAIR_DRAW_SINGLE,sz,wcross_name,wcross_alpha)
1340
1341                         if(time < wcross_name_changedonetime && wcross_name != wcross_name_goal_prev_prev && wcross_name_goal_prev_prev)
1342                         {
1343                                 f = (wcross_name_changedonetime - time) / (wcross_name_changedonetime - wcross_name_changestarttime);
1344                                 wcross_size = draw_getimagesize(wcross_name_goal_prev_prev) * wcross_scale;
1345                                 CROSSHAIR_DRAW(wcross_resolution_goal_prev_prev, wcross_name_goal_prev_prev, wcross_alpha * f * wcross_name_alpha_goal_prev_prev);
1346                                 f = 1 - f;
1347                         }
1348                         else
1349                         {
1350                                 f = 1;
1351                         }
1352                         wcross_name_alpha_goal_prev = f;
1353
1354                         wcross_size = draw_getimagesize(wcross_name) * wcross_scale;
1355                         CROSSHAIR_DRAW(wcross_resolution, wcross_name, wcross_alpha * f);
1356
1357                         if(autocvar_crosshair_dot)
1358                         {
1359                                 vector wcross_color_old;
1360                                 wcross_color_old = wcross_color;
1361
1362                                 if((autocvar_crosshair_dot_color_custom) && (autocvar_crosshair_dot_color != "0"))
1363                                         wcross_color = stov(autocvar_crosshair_dot_color);
1364
1365                                 CROSSHAIR_DRAW(wcross_resolution * autocvar_crosshair_dot_size, "gfx/crosshairdot.tga", f * autocvar_crosshair_dot_alpha);
1366                                 // FIXME why don't we use wcross_alpha here?
1367                                 wcross_color = wcross_color_old;
1368                         }
1369                 }
1370         }
1371         else
1372         {
1373                 wcross_scale_prev = 0;
1374                 wcross_alpha_prev = 0;
1375                 wcross_scale_goal_prev = 0;
1376                 wcross_alpha_goal_prev = 0;
1377                 wcross_changedonetime = 0;
1378                 strfree(wcross_name_goal_prev);
1379                 strfree(wcross_name_goal_prev_prev);
1380                 wcross_name_changestarttime = 0;
1381                 wcross_name_changedonetime = 0;
1382                 wcross_name_alpha_goal_prev = 0;
1383                 wcross_name_alpha_goal_prev_prev = 0;
1384                 wcross_resolution_goal_prev = 0;
1385                 wcross_resolution_goal_prev_prev = 0;
1386         }
1387 }
1388
1389 const int MAX_SPECIALCOMMAND = 15;
1390 vector specialcommand_slots[MAX_SPECIALCOMMAND];
1391 vector specialcommand_colors[MAX_SPECIALCOMMAND];
1392 const float SPECIALCOMMAND_SPEED = 150;
1393 const float SPECIALCOMMAND_TURNSPEED = 2;
1394 const float SPECIALCOMMAND_SIZE = 0.025;
1395 const float SPECIALCOMMAND_CHANCE = 0.35;
1396 float sc_spawntime, sc_changetime;
1397 vector sc_color = '1 1 1';
1398 void SpecialCommand()
1399 {
1400         if(!STAT(MOVEVARS_SPECIALCOMMAND))
1401                 return;
1402
1403         if(time >= sc_changetime)
1404         {
1405                 sc_changetime = time + 1;
1406                 sc_color = randomvec() * 1.5;
1407                 sc_color.x = bound(0.2, sc_color.x, 0.75);
1408                 sc_color.y = bound(0.2, sc_color.y, 0.75);
1409                 sc_color.z = bound(0.2, sc_color.z, 0.75);
1410         }
1411         drawfill('0 0 0', vec2(vid_conwidth, vid_conheight), sc_color, autocvar_hud_colorflash_alpha * bound(0.1, sc_changetime - time, 0.3), DRAWFLAG_ADDITIVE);
1412
1413         if(!precache_pic("gfx/smile"))
1414                 return; // damn party poopers
1415
1416         for(int j = MAX_SPECIALCOMMAND - 1; j >= 0; --j)
1417         {
1418                 vector slot = specialcommand_slots[j];
1419                 if(slot.y)
1420                         slot.y += SPECIALCOMMAND_SPEED * frametime;
1421                 //if(slot.z)
1422                         //slot.z = sin(SPECIALCOMMAND_TURNSPEED * M_PI * time);
1423                 if(slot.y >= vid_conheight)
1424                         slot = '0 0 0';
1425
1426                 if(slot == '0 0 0')
1427                 {
1428                         if(random() <= SPECIALCOMMAND_CHANCE && time > sc_spawntime) // low chance to spawn!
1429                         {
1430                                 slot.x = bound(0, (random() * vid_conwidth + 1), vid_conwidth);
1431                                 slot.y = 1; // start it off 0 so we can use it
1432                                 slot.z = floor(random() * Weapons_MAX);
1433                                 sc_spawntime = time + bound(0.4, random(), 0.75); // prevent spawning another one for this amount of time!
1434                                 vector newcolor = randomvec() * 2;
1435                                 newcolor.x = bound(0.4, newcolor.x, 1);
1436                                 newcolor.y = bound(0.4, newcolor.y, 1);
1437                                 newcolor.z = bound(0.4, newcolor.z, 1);
1438                                 specialcommand_colors[j] = newcolor;
1439                         }
1440                 }
1441                 else
1442                 {
1443                         vector splash_size = '0 0 0';
1444                         splash_size.x = max(vid_conwidth, vid_conheight) * SPECIALCOMMAND_SIZE;
1445                         splash_size.y = max(vid_conwidth, vid_conheight) * SPECIALCOMMAND_SIZE;
1446                         entity wep = Weapons_from(slot.z);
1447                         if(wep == WEP_Null)
1448                                 drawpic(vec2(slot), "gfx/smile", vec2(splash_size), specialcommand_colors[j], 0.95, DRAWFLAG_NORMAL);
1449                         else
1450                                 drawpic_skin(vec2(slot), wep.model2, vec2(splash_size), specialcommand_colors[j], 0.95, DRAWFLAG_NORMAL);
1451                         //drawrotpic(vec2(slot), slot.z, "gfx/smile", vec2(splash_size), vec2(splash_size) / 2, specialcommand_colors[j], 0.95, DRAWFLAG_NORMAL);
1452                 }
1453
1454                 specialcommand_slots[j] = slot;
1455         }
1456 }
1457
1458 void HUD_Draw(entity this)
1459 {
1460         // if we don't know gametype and scores yet avoid drawing the scoreboard
1461         // also in the very first frames, player state may be inconsistent so avoid drawing the hud at all
1462         // e.g. since initial player's health is 0 hud would display the hud_damage effect,
1463         // cl_deathscoreboard would show the scoreboard and so on
1464         if(!gametype)
1465                 return;
1466
1467         Hud_Dynamic_Frame();
1468
1469         if(!intermission)
1470         if (MUTATOR_CALLHOOK(HUD_Draw_overlay))
1471         {
1472                 drawfill('0 0 0', vec2(vid_conwidth, vid_conheight), M_ARGV(0, vector), autocvar_hud_colorflash_alpha * M_ARGV(1, float), DRAWFLAG_ADDITIVE);
1473         }
1474         else if(STAT(FROZEN))
1475         {
1476                 vector col = '0.25 0.90 1';
1477                 if(STAT(REVIVE_PROGRESS))
1478                         col += vec3(STAT(REVIVE_PROGRESS), -STAT(REVIVE_PROGRESS), -STAT(REVIVE_PROGRESS));
1479                 drawfill('0 0 0', vec2(vid_conwidth, vid_conheight), col, autocvar_hud_colorflash_alpha, DRAWFLAG_ADDITIVE);
1480         }
1481
1482         HUD_Scale_Enable();
1483         if(!intermission)
1484         if(STAT(NADE_TIMER) && autocvar_cl_nade_timer) // give nade top priority, as it's a matter of life and death
1485         {
1486                 vector col = '0.25 0.90 1' + vec3(STAT(NADE_TIMER), -STAT(NADE_TIMER), -STAT(NADE_TIMER));
1487                 DrawCircleClippedPic(vec2(0.5 * vid_conwidth, 0.6 * vid_conheight), 0.1 * vid_conheight, "gfx/crosshair_ring.tga", STAT(NADE_TIMER), col, autocvar_hud_colorflash_alpha, DRAWFLAG_ADDITIVE);
1488                 drawstring_aspect(eY * 0.64 * vid_conheight, ((autocvar_cl_nade_timer == 2) ? _("Nade timer") : ""), vec2(vid_conwidth, 0.025 * vid_conheight), '1 1 1', 1, DRAWFLAG_NORMAL);
1489         }
1490         else if(STAT(CAPTURE_PROGRESS))
1491         {
1492                 DrawCircleClippedPic(vec2(0.5 * vid_conwidth, 0.6 * vid_conheight), 0.1 * vid_conheight, "gfx/crosshair_ring.tga", STAT(CAPTURE_PROGRESS), '0.25 0.90 1', autocvar_hud_colorflash_alpha, DRAWFLAG_ADDITIVE);
1493                 drawstring_aspect(eY * 0.64 * vid_conheight, _("Capture progress"), vec2(vid_conwidth, 0.025 * vid_conheight), '1 1 1', 1, DRAWFLAG_NORMAL);
1494         }
1495         else if(STAT(REVIVE_PROGRESS))
1496         {
1497                 DrawCircleClippedPic(vec2(0.5 * vid_conwidth, 0.6 * vid_conheight), 0.1 * vid_conheight, "gfx/crosshair_ring.tga", STAT(REVIVE_PROGRESS), '0.25 0.90 1', autocvar_hud_colorflash_alpha, DRAWFLAG_ADDITIVE);
1498                 drawstring_aspect(eY * 0.64 * vid_conheight, _("Revival progress"), vec2(vid_conwidth, 0.025 * vid_conheight), '1 1 1', 1, DRAWFLAG_NORMAL);
1499         }
1500         HUD_Scale_Disable();
1501
1502         if(autocvar_r_letterbox == 0)
1503                 if(autocvar_viewsize < 120)
1504                 {
1505                         if(!(gametype == MAPINFO_TYPE_RACE || gametype == MAPINFO_TYPE_CTS))
1506                                 Accuracy_LoadLevels();
1507
1508                         HUD_Main();
1509                         HUD_Scale_Disable();
1510                 }
1511
1512         // crosshair goes VERY LAST
1513         SpecialCommand();
1514         UpdateDamage();
1515         HUD_Crosshair(this);
1516         HitSound();
1517 }
1518
1519 void ViewLocation_Mouse()
1520 {
1521         if(spectatee_status)
1522                 return; // don't draw it as spectator!
1523
1524         viewloc_mousepos += getmousepos() * autocvar_menu_mouse_speed;
1525         viewloc_mousepos.x = bound(0, viewloc_mousepos.x, vid_conwidth);
1526         viewloc_mousepos.y = bound(0, viewloc_mousepos.y, vid_conheight);
1527
1528         //float cursor_alpha = 1 - autocvar__menu_alpha;
1529         //draw_cursor(viewloc_mousepos, '0.5 0.5 0', "/cursor_move", '1 1 1', cursor_alpha);
1530 }
1531
1532 bool ov_enabled;
1533 float oldr_nearclip;
1534 float oldr_farclip_base;
1535 float oldr_farclip_world;
1536 float oldr_novis;
1537 float oldr_useportalculling;
1538 float oldr_useinfinitefarclip;
1539
1540 void cl_notice_run();
1541
1542 float prev_myteam;
1543 int lasthud;
1544 float vh_notice_time;
1545 void WaypointSprite_Load();
1546 void CSQC_UpdateView(entity this, float w, float h)
1547 {
1548     TC(int, w); TC(int, h);
1549         entity e;
1550         float fov;
1551         float f;
1552         vector vf_size, vf_min;
1553         float a;
1554
1555         execute_next_frame();
1556
1557         ++framecount;
1558
1559         stats_get();
1560         hud = STAT(HUD);
1561
1562         if(hud != HUD_NORMAL && lasthud == HUD_NORMAL)
1563                 vh_notice_time = time + autocvar_cl_vehicles_notify_time;
1564
1565         lasthud = hud;
1566
1567         HUD_Scale_Disable();
1568
1569         if(autocvar__hud_showbinds_reload) // menu can set this one
1570         {
1571                 db_close(binddb);
1572                 binddb = db_create();
1573                 cvar_set("_hud_showbinds_reload", "0");
1574         }
1575
1576         if(checkextension("DP_CSQC_MINFPS_QUALITY"))
1577                 view_quality = getproperty(VF_MINFPS_QUALITY);
1578         else
1579                 view_quality = 1;
1580
1581         button_attack2 = PHYS_INPUT_BUTTON_ATCK2(this);
1582         button_zoom = PHYS_INPUT_BUTTON_ZOOM(this);
1583
1584         vf_size = getpropertyvec(VF_SIZE);
1585         vf_min = getpropertyvec(VF_MIN);
1586         vid_width = vf_size.x;
1587         vid_height = vf_size.y;
1588
1589         vector reticle_pos = '0 0 0', reticle_size = '0 0 0';
1590         vector splash_pos = '0 0 0', splash_size = '0 0 0';
1591
1592         WaypointSprite_Load();
1593
1594         CSQCPlayer_SetCamera();
1595
1596         if(player_localentnum <= maxclients) // is it a client?
1597                 current_player = player_localentnum - 1;
1598         else // then player_localentnum is the vehicle I'm driving
1599                 current_player = player_localnum;
1600         myteam = entcs_GetTeam(current_player);
1601
1602         if(myteam != prev_myteam)
1603         {
1604                 myteamcolors = colormapPaletteColor(myteam, 1);
1605                 FOREACH(hud_panels, true, it.update_time = time);
1606                 prev_myteam = myteam;
1607         }
1608
1609         ticrate = STAT(MOVEVARS_TICRATE) * STAT(MOVEVARS_TIMESCALE);
1610
1611         float is_dead = (STAT(HEALTH) <= 0);
1612
1613         // FIXME do we need this hack?
1614         if(isdemo())
1615         {
1616                 // in demos, input_buttons do not work
1617                 button_zoom = (autocvar__togglezoom == "-");
1618         }
1619         else if(button_zoom
1620                 && autocvar_cl_unpress_zoom_on_death
1621                 && (spectatee_status >= 0)
1622                 && (is_dead || intermission))
1623         {
1624                 // no zoom while dead or in intermission please
1625                 localcmd("-zoom\n");
1626                 button_zoom = false;
1627         }
1628
1629         // abused multiple places below
1630         entity local_player = ((csqcplayer) ? csqcplayer : CSQCModel_server2csqc(player_localentnum - 1));
1631         if(!local_player)
1632                 local_player = this; // fall back!
1633
1634         // event chase camera
1635         if(autocvar_chase_active <= 0) // greater than 0 means it's enabled manually, and this code is skipped
1636         {
1637                 if(STAT(CAMERA_SPECTATOR))
1638                 {
1639                         if(spectatee_status > 0)
1640                         {
1641                                 if(!autocvar_chase_active)
1642                                 {
1643                                         cvar_set("chase_active", "-2");
1644                                         goto skip_eventchase_death;
1645                                 }
1646                         }
1647                         else if(autocvar_chase_active == -2)
1648                                 cvar_set("chase_active", "0");
1649
1650                         if(autocvar_chase_active == -2)
1651                                 goto skip_eventchase_death;
1652                 }
1653                 else if(autocvar_chase_active == -2)
1654                         cvar_set("chase_active", "0");
1655
1656                 float vehicle_chase = (hud != HUD_NORMAL && (autocvar_cl_eventchase_vehicle || spectatee_status > 0));
1657
1658                 float vehicle_viewdist = 0;
1659                 vector vehicle_viewofs = '0 0 0';
1660
1661                 if(vehicle_chase)
1662                 {
1663                         if(hud != HUD_BUMBLEBEE_GUN)
1664                         {
1665                                 Vehicle info = Vehicles_from(hud);
1666                                 vehicle_viewdist = info.height;
1667                                 vehicle_viewofs = info.view_ofs;
1668                         }
1669                 }
1670
1671                 if(WantEventchase(this))
1672                 {
1673                         vector current_view_origin_override = '0 0 0';
1674                         vector view_offset_override = '0 0 0';
1675                         float chase_distance_override = 0;
1676                         bool custom_eventchase = MUTATOR_CALLHOOK(CustomizeEventchase, this);
1677                         if(custom_eventchase)
1678                         {
1679                                 current_view_origin_override = M_ARGV(0, vector);
1680                                 view_offset_override = M_ARGV(1, vector);
1681                                 chase_distance_override = M_ARGV(0, float);
1682                         }
1683                         eventchase_running = true;
1684
1685                         // make special vector since we can't use view_origin (It is one frame old as of this code, it gets set later with the results this code makes.)
1686                         vector current_view_origin = (csqcplayer ? csqcplayer.origin : pmove_org);
1687                         if (custom_eventchase)
1688                                 current_view_origin = current_view_origin_override;
1689
1690                         // detect maximum viewoffset and use it
1691                         vector view_offset = autocvar_cl_eventchase_viewoffset;
1692                         if(vehicle_chase)
1693                         {
1694                                 if(vehicle_viewofs)
1695                                         view_offset = vehicle_viewofs;
1696                                 else
1697                                         view_offset = autocvar_cl_eventchase_vehicle_viewoffset;
1698                         }
1699                         if (custom_eventchase)
1700                                 view_offset = view_offset_override;
1701
1702                         if(view_offset)
1703                         {
1704                                 WarpZone_TraceLine(current_view_origin, current_view_origin + view_offset + ('0 0 1' * autocvar_cl_eventchase_maxs.z), MOVE_WORLDONLY, this);
1705                                 if(trace_fraction == 1) { current_view_origin += view_offset; }
1706                                 else { current_view_origin.z += max(0, (trace_endpos.z - current_view_origin.z) - autocvar_cl_eventchase_maxs.z); }
1707                         }
1708
1709                         // We must enable chase_active to get a third person view (weapon viewmodel hidden and own player model showing).
1710                         // Ideally, there should be another way to enable third person cameras, such as through setproperty()
1711                         // -1 enables chase_active while marking it as set by this code, and not by the user (which would be 1)
1712                         if(!autocvar_chase_active) { cvar_set("chase_active", "-1"); }
1713
1714                         // make the camera smooth back
1715                         float chase_distance = autocvar_cl_eventchase_distance;
1716                         if(vehicle_chase)
1717                         {
1718                                 if(vehicle_viewofs)
1719                                         chase_distance = vehicle_viewdist;
1720                                 else
1721                                         chase_distance = autocvar_cl_eventchase_vehicle_distance;
1722                         }
1723                         if (custom_eventchase)
1724                                 chase_distance = chase_distance_override;
1725
1726                         if(autocvar_cl_eventchase_speed && eventchase_current_distance < chase_distance)
1727                                 eventchase_current_distance += autocvar_cl_eventchase_speed * (chase_distance - eventchase_current_distance) * frametime; // slow down the further we get
1728                         else if(eventchase_current_distance != chase_distance)
1729                                 eventchase_current_distance = chase_distance;
1730
1731                         makevectors(view_angles);
1732
1733                         vector eventchase_target_origin = (current_view_origin - (v_forward * eventchase_current_distance));
1734                         WarpZone_TraceBox(current_view_origin, autocvar_cl_eventchase_mins, autocvar_cl_eventchase_maxs, eventchase_target_origin, MOVE_WORLDONLY, this);
1735
1736                         // If the boxtrace fails, revert back to line tracing.
1737                         if(!local_player.viewloc)
1738                         if(trace_startsolid)
1739                         {
1740                                 eventchase_target_origin = (current_view_origin - (v_forward * eventchase_current_distance));
1741                                 WarpZone_TraceLine(current_view_origin, eventchase_target_origin, MOVE_WORLDONLY, this);
1742                                 setproperty(VF_ORIGIN, (trace_endpos - (v_forward * autocvar_cl_eventchase_mins.z)));
1743                         }
1744                         else { setproperty(VF_ORIGIN, trace_endpos); }
1745
1746                         if(!local_player.viewloc)
1747                                 setproperty(VF_ANGLES, WarpZone_TransformVAngles(WarpZone_trace_transform, view_angles));
1748                 }
1749                 else if(autocvar_chase_active < 0) // time to disable chase_active if it was set by this code
1750                 {
1751                         eventchase_running = false;
1752                         cvar_set("chase_active", "0");
1753                         eventchase_current_distance = 0; // start from 0 next time
1754                 }
1755         }
1756         // workaround for camera stuck between player's legs when using chase_active 1
1757         // because the engine stops updating the chase_active camera when the game ends
1758         else if(intermission)
1759         {
1760                 cvar_settemp("chase_active", "-1");
1761                 eventchase_current_distance = 0;
1762         }
1763
1764         LABEL(skip_eventchase_death);
1765
1766         // do lockview after event chase camera so that it still applies whenever necessary.
1767         if(autocvar_cl_lockview || (!autocvar_hud_cursormode && (autocvar__hud_configure && spectatee_status <= 0 || intermission > 1 || QuickMenu_IsOpened())))
1768         {
1769                 setproperty(VF_ORIGIN, freeze_org);
1770                 setproperty(VF_ANGLES, freeze_ang);
1771         }
1772         else
1773         {
1774                 freeze_org = getpropertyvec(VF_ORIGIN);
1775                 freeze_ang = getpropertyvec(VF_ANGLES);
1776         }
1777
1778         WarpZone_FixView();
1779         //WarpZone_FixPMove();
1780
1781         vector ov_org = '0 0 0';
1782         vector ov_mid = '0 0 0';
1783         vector ov_worldmin = '0 0 0';
1784         vector ov_worldmax = '0 0 0';
1785         if(autocvar_cl_orthoview)
1786         {
1787                 ov_worldmin = mi_picmin;
1788                 ov_worldmax = mi_picmax;
1789
1790                 float ov_width = (ov_worldmax.x - ov_worldmin.x);
1791                 float ov_height = (ov_worldmax.y - ov_worldmin.y);
1792                 float ov_distance = (max(vid_width, vid_height) * max(ov_width, ov_height));
1793
1794                 ov_mid = ((ov_worldmax + ov_worldmin) * 0.5);
1795                 ov_org = vec3(ov_mid.x, ov_mid.y, (ov_mid.z + ov_distance));
1796
1797                 float ov_nearest = vlen(ov_org - vec3(
1798                         bound(ov_worldmin.x, ov_org.x, ov_worldmax.x),
1799                         bound(ov_worldmin.y, ov_org.y, ov_worldmax.y),
1800                         bound(ov_worldmin.z, ov_org.z, ov_worldmax.z)
1801                 ));
1802
1803                 float ov_furthest = 0;
1804                 float dist = 0;
1805
1806                 if((dist = vdist((vec3(ov_worldmin.x, ov_worldmin.y, ov_worldmin.z) - ov_org), >, ov_furthest))) { ov_furthest = dist; }
1807                 if((dist = vdist((vec3(ov_worldmax.x, ov_worldmin.y, ov_worldmin.z) - ov_org), >, ov_furthest))) { ov_furthest = dist; }
1808                 if((dist = vdist((vec3(ov_worldmin.x, ov_worldmax.y, ov_worldmin.z) - ov_org), >, ov_furthest))) { ov_furthest = dist; }
1809                 if((dist = vdist((vec3(ov_worldmin.x, ov_worldmin.y, ov_worldmax.z) - ov_org), >, ov_furthest))) { ov_furthest = dist; }
1810                 if((dist = vdist((vec3(ov_worldmax.x, ov_worldmax.y, ov_worldmin.z) - ov_org), >, ov_furthest))) { ov_furthest = dist; }
1811                 if((dist = vdist((vec3(ov_worldmin.x, ov_worldmax.y, ov_worldmax.z) - ov_org), >, ov_furthest))) { ov_furthest = dist; }
1812                 if((dist = vdist((vec3(ov_worldmax.x, ov_worldmin.y, ov_worldmax.z) - ov_org), >, ov_furthest))) { ov_furthest = dist; }
1813                 if((dist = vdist((vec3(ov_worldmax.x, ov_worldmax.y, ov_worldmax.z) - ov_org), >, ov_furthest))) { ov_furthest = dist; }
1814
1815                 if(!ov_enabled)
1816                 {
1817                         oldr_nearclip = cvar("r_nearclip");
1818                         oldr_farclip_base = cvar("r_farclip_base");
1819                         oldr_farclip_world = cvar("r_farclip_world");
1820                         oldr_novis = cvar("r_novis");
1821                         oldr_useportalculling = cvar("r_useportalculling");
1822                         oldr_useinfinitefarclip = cvar("r_useinfinitefarclip");
1823                 }
1824
1825                 cvar_settemp("r_nearclip", ftos(ov_nearest));
1826                 cvar_settemp("r_farclip_base", ftos(ov_furthest));
1827                 cvar_settemp("r_farclip_world", "0");
1828                 cvar_settemp("r_novis", "1");
1829                 cvar_settemp("r_useportalculling", "0");
1830                 cvar_settemp("r_useinfinitefarclip", "0");
1831
1832                 setproperty(VF_ORIGIN, ov_org);
1833                 setproperty(VF_ANGLES, '90 0 0');
1834
1835                 ov_enabled = true;
1836
1837                 #if 0
1838                 LOG_INFOF("OrthoView: org = %s, angles = %s, distance = %f, nearest = %f, furthest = %f",
1839                         vtos(ov_org),
1840                         vtos(getpropertyvec(VF_ANGLES)),
1841                         ov_distance,
1842                         ov_nearest,
1843                         ov_furthest);
1844                 #endif
1845         }
1846         else
1847         {
1848                 if(ov_enabled)
1849                 {
1850                         cvar_set("r_nearclip", ftos(oldr_nearclip));
1851                         cvar_set("r_farclip_base", ftos(oldr_farclip_base));
1852                         cvar_set("r_farclip_world", ftos(oldr_farclip_world));
1853                         cvar_set("r_novis", ftos(oldr_novis));
1854                         cvar_set("r_useportalculling", ftos(oldr_useportalculling));
1855                         cvar_set("r_useinfinitefarclip", ftos(oldr_useinfinitefarclip));
1856                 }
1857                 ov_enabled = false;
1858         }
1859
1860         // run viewmodel_draw before updating view_angles to the angles calculated by WarpZone_FixView
1861         // viewmodel_draw needs to use the view_angles set by the engine on every CSQC_UpdateView call
1862         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
1863                 viewmodel_draw(viewmodels[slot]);
1864
1865         // Render the Scene
1866         view_origin = getpropertyvec(VF_ORIGIN);
1867         view_angles = getpropertyvec(VF_ANGLES);
1868         makevectors(view_angles);
1869         view_forward = v_forward;
1870         view_right = v_right;
1871         view_up = v_up;
1872
1873 #ifdef BLURTEST
1874         if(time > blurtest_time0 && time < blurtest_time1)
1875         {
1876                 float r, t;
1877
1878                 t = (time - blurtest_time0) / (blurtest_time1 - blurtest_time0);
1879                 r = t * blurtest_radius;
1880                 f = 1 / (t ** blurtest_power) - 1;
1881
1882                 cvar_set("r_glsl_postprocess", "1");
1883                 cvar_set("r_glsl_postprocess_uservec1", strcat(ftos(r), " ", ftos(f), " 0 0"));
1884         }
1885         else
1886         {
1887                 cvar_set("r_glsl_postprocess", "0");
1888                 cvar_set("r_glsl_postprocess_uservec1", "0 0 0 0");
1889         }
1890 #endif
1891
1892         TargetMusic_Advance();
1893         Fog_Force();
1894         fpscounter_update();
1895
1896         if(drawtime == 0)
1897                 drawframetime = 0.01666667; // when we don't know fps yet, we assume 60fps
1898         else
1899                 drawframetime = bound(0.000001, time - drawtime, 1);
1900         drawtime = time;
1901
1902         // watch for gametype changes here...
1903         // in ParseStuffCMD the cmd isn't executed yet :/
1904         // might even be better to add the gametype to TE_CSQC_INIT...?
1905         if(!postinit)
1906                 PostInit();
1907
1908         if(intermission && !intermission_time)
1909                 intermission_time = time;
1910
1911         if(intermission && !isdemo() && !(calledhooks & HOOK_END))
1912         {
1913                 if(calledhooks & HOOK_START)
1914                 {
1915                         localcmd("\ncl_hook_gameend\n");
1916                         calledhooks |= HOOK_END;
1917                 }
1918         }
1919
1920         Announcer();
1921
1922         fov = autocvar_fov;
1923         if(fov <= 59.5)
1924         {
1925                 if(!zoomscript_caught)
1926                 {
1927                         localcmd("+button9\n");
1928                         zoomscript_caught = 1;
1929                 }
1930         }
1931         else
1932         {
1933                 if(zoomscript_caught)
1934                 {
1935                         localcmd("-button9\n");
1936                         zoomscript_caught = 0;
1937                 }
1938         }
1939
1940         ColorTranslateMode = autocvar_cl_stripcolorcodes;
1941
1942         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
1943         {
1944                 entity wepent = viewmodels[slot];
1945
1946                 if(wepent.last_switchweapon != wepent.switchweapon)
1947                 {
1948                         weapontime = time;
1949                         wepent.last_switchweapon = wepent.switchweapon;
1950                         if(slot == 0 && button_zoom && autocvar_cl_unpress_zoom_on_weapon_switch)
1951                         {
1952                                 localcmd("-zoom\n");
1953                                 button_zoom = false;
1954                         }
1955                         if(slot == 0 && autocvar_cl_unpress_attack_on_weapon_switch)
1956                         {
1957                                 localcmd("-fire\n");
1958                                 localcmd("-fire2\n");
1959                                 button_attack2 = false;
1960                         }
1961                 }
1962                 if(wepent.last_activeweapon != wepent.activeweapon)
1963                 {
1964                         wepent.last_activeweapon = wepent.activeweapon;
1965
1966                         e = wepent.activeweapon;
1967                         if(e.netname != "")
1968                                 localcmd(strcat("\ncl_hook_activeweapon ", e.netname), "\n");
1969                         else if(slot == 0)
1970                                 localcmd("\ncl_hook_activeweapon none\n");
1971                 }
1972         }
1973
1974         // ALWAYS Clear Current Scene First
1975         clearscene();
1976
1977         setproperty(VF_ORIGIN, view_origin);
1978         setproperty(VF_ANGLES, view_angles);
1979
1980         // FIXME engine bug? VF_SIZE and VF_MIN are not restored to sensible values by this
1981         setproperty(VF_SIZE, vf_size);
1982         setproperty(VF_MIN, vf_min);
1983
1984         // Assign Standard Viewflags
1985         // Draw the World (and sky)
1986         setproperty(VF_DRAWWORLD, 1);
1987
1988         // Set the console size vars
1989         vid_conwidth = autocvar_vid_conwidth;
1990         vid_conheight = autocvar_vid_conheight;
1991         vid_pixelheight = autocvar_vid_pixelheight;
1992
1993         if(autocvar_cl_orthoview) { setproperty(VF_FOV, GetOrthoviewFOV(ov_worldmin, ov_worldmax, ov_mid, ov_org)); }
1994         else if(csqcplayer.viewloc) { setproperty(VF_FOV, GetViewLocationFOV(110)); } // enforce 110 fov, so things dont look odd
1995         else { setproperty(VF_FOV, GetCurrentFov(fov)); }
1996
1997         if(camera_active) // Camera for demo playback
1998         {
1999                 if(autocvar_camera_enable)
2000                         CSQC_Demo_Camera();
2001                 else
2002                 {
2003                         cvar_set("chase_active", ftos(chase_active_backup));
2004                         cvar_set("cl_demo_mousegrab", "0");
2005                         camera_active = false;
2006                 }
2007         }
2008         else
2009         {
2010 #ifdef CAMERATEST
2011                 if(autocvar_camera_enable)
2012 #else
2013                 if(autocvar_camera_enable && isdemo())
2014 #endif
2015                 {
2016                         // Enable required Darkplaces cvars
2017                         chase_active_backup = autocvar_chase_active;
2018                         cvar_set("chase_active", "2");
2019                         cvar_set("cl_demo_mousegrab", "1");
2020                         camera_active = true;
2021                         camera_mode = false;
2022                 }
2023         }
2024
2025         // Draw the Crosshair
2026         setproperty(VF_DRAWCROSSHAIR, 0); //Make sure engine crosshairs are always hidden
2027
2028         // Draw the Engine Status Bar (the default Quake HUD)
2029         setproperty(VF_DRAWENGINESBAR, 0);
2030
2031         // Update the mouse position
2032         /*
2033            mousepos_x = vid_conwidth;
2034            mousepos_y = vid_conheight;
2035            mousepos = mousepos*0.5 + getmousepos();
2036          */
2037
2038         IL_EACH(g_drawables, it.draw, it.draw(it));
2039
2040         addentities(MASK_NORMAL | MASK_ENGINE | MASK_ENGINEVIEWMODELS);
2041         renderscene();
2042
2043         // now switch to 2D drawing mode by calling a 2D drawing function
2044         // then polygon drawing will draw as 2D stuff, and NOT get queued until the
2045         // next R_RenderScene call
2046         drawstring('0 0 0', "", '1 1 0', '1 1 1', 0, 0);
2047
2048         if(autocvar_r_fakelight >= 2 || autocvar_r_fullbright)
2049         if (!(serverflags & SERVERFLAG_ALLOW_FULLBRIGHT))
2050         {
2051                 // apply night vision effect
2052                 vector tc_00, tc_01, tc_10, tc_11;
2053                 vector rgb = '0 0 0';
2054
2055                 if(!nightvision_noise)
2056                 {
2057                         nightvision_noise = new(nightvision_noise);
2058                 }
2059                 if(!nightvision_noise2)
2060                 {
2061                         nightvision_noise2 = new(nightvision_noise2);
2062                 }
2063
2064                 // color tint in yellow
2065                 drawfill('0 0 0', autocvar_vid_conwidth * '1 0 0' + autocvar_vid_conheight * '0 1 0', '0.5 1 0.3', 1, DRAWFLAG_MODULATE);
2066
2067                 // draw BG
2068                 a = Noise_Pink(nightvision_noise, frametime * 1.5) * 0.05 + 0.15;
2069                 rgb = '1 1 1';
2070                 tc_00 = '0 0 0' + '0.2 0 0' * sin(time * 0.3) + '0 0.3 0' * cos(time * 0.7);
2071                 tc_01 = '0 2.25 0' + '0.6 0 0' * cos(time * 1.2) - '0 0.3 0' * sin(time * 2.2);
2072                 tc_10 = '1.5 0 0' - '0.2 0 0' * sin(time * 0.5) + '0 0.5 0' * cos(time * 1.7);
2073                 //tc_11 = '1 1 0' + '0.6 0 0' * sin(time * 0.6) + '0 0.3 0' * cos(time * 0.1);
2074                 tc_11 = tc_01 + tc_10 - tc_00;
2075                 R_BeginPolygon("gfx/nightvision-bg.tga", DRAWFLAG_ADDITIVE);
2076                 R_PolygonVertex('0 0 0', tc_00, rgb, a);
2077                 R_PolygonVertex(autocvar_vid_conwidth * '1 0 0', tc_10, rgb, a);
2078                 R_PolygonVertex(autocvar_vid_conwidth * '1 0 0' + autocvar_vid_conheight * '0 1 0', tc_11, rgb, a);
2079                 R_PolygonVertex(autocvar_vid_conheight * '0 1 0', tc_01, rgb, a);
2080                 R_EndPolygon();
2081
2082                 // draw FG
2083                 a = Noise_Pink(nightvision_noise2, frametime * 0.1) * 0.05 + 0.12;
2084                 rgb = '0.3 0.6 0.4' + '0.1 0.4 0.2' * Noise_White(nightvision_noise2, frametime);
2085                 tc_00 = '0 0 0' + '1 0 0' * Noise_White(nightvision_noise2, frametime) + '0 1 0' * Noise_White(nightvision_noise2, frametime);
2086                 tc_01 = tc_00 + '0 3 0' * (1 + Noise_White(nightvision_noise2, frametime) * 0.2);
2087                 tc_10 = tc_00 + '2 0 0' * (1 + Noise_White(nightvision_noise2, frametime) * 0.3);
2088                 tc_11 = tc_01 + tc_10 - tc_00;
2089                 R_BeginPolygon("gfx/nightvision-fg.tga", DRAWFLAG_ADDITIVE);
2090                 R_PolygonVertex('0 0 0', tc_00, rgb, a);
2091                 R_PolygonVertex(autocvar_vid_conwidth * '1 0 0', tc_10, rgb, a);
2092                 R_PolygonVertex(autocvar_vid_conwidth * '1 0 0' + autocvar_vid_conheight * '0 1 0', tc_11, rgb, a);
2093                 R_PolygonVertex(autocvar_vid_conheight * '0 1 0', tc_01, rgb, a);
2094                 R_EndPolygon();
2095         }
2096
2097         if(autocvar_cl_reticle)
2098         {
2099                 string reticle_image = string_null;
2100                 bool wep_zoomed = false;
2101                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
2102                 {
2103                         entity wepe = viewmodels[slot];
2104                         Weapon wep = wepe.activeweapon;
2105                         if(wep != WEP_Null && wep.wr_zoom)
2106                         {
2107                                 bool do_zoom = wep.wr_zoom(wep, NULL);
2108                                 if(!reticle_image && wep.w_reticle && wep.w_reticle != "")
2109                                         reticle_image = wep.w_reticle;
2110                                 wep_zoomed += do_zoom;
2111                         }
2112                 }
2113                 // Draw the aiming reticle for weapons that use it
2114                 // reticle_type is changed to the item we are zooming / aiming with, to decide which reticle to use
2115                 // It must be a persisted float for fading out to work properly (you let go of the zoom button for
2116                 // the view to go back to normal, so reticle_type would become 0 as we fade out)
2117                 if(spectatee_status || is_dead || hud != HUD_NORMAL || local_player.viewloc)
2118                 {
2119                         // no zoom reticle while dead
2120                         reticle_type = 0;
2121                 }
2122                 else if(wep_zoomed && autocvar_cl_reticle_weapon)
2123                 {
2124                         if(reticle_image) { reticle_type = 2; }
2125                         else { reticle_type = 0; }
2126                 }
2127                 else if(button_zoom || zoomscript_caught)
2128                 {
2129                         // normal zoom
2130                         reticle_type = 1;
2131                 }
2132
2133                 if(reticle_type)
2134                 {
2135                         if(autocvar_cl_reticle_stretch)
2136                         {
2137                                 reticle_size.x = vid_conwidth;
2138                                 reticle_size.y = vid_conheight;
2139                                 reticle_pos.x = 0;
2140                                 reticle_pos.y = 0;
2141                         }
2142                         else
2143                         {
2144                                 reticle_size.x = max(vid_conwidth, vid_conheight);
2145                                 reticle_size.y = max(vid_conwidth, vid_conheight);
2146                                 reticle_pos.x = (vid_conwidth - reticle_size.x) / 2;
2147                                 reticle_pos.y = (vid_conheight - reticle_size.y) / 2;
2148                         }
2149
2150                         if(zoomscript_caught)
2151                                 f = 1;
2152                         else
2153                                 f = current_zoomfraction;
2154
2155                         if(f)
2156                         {
2157                                 switch(reticle_type)
2158                                 {
2159                                         case 1: drawpic(reticle_pos, "gfx/reticle_normal", reticle_size, '1 1 1', f * autocvar_cl_reticle_normal_alpha, DRAWFLAG_NORMAL); break;
2160                                         case 2: if(reticle_image) drawpic(reticle_pos, reticle_image, reticle_size, '1 1 1', f * autocvar_cl_reticle_weapon_alpha, DRAWFLAG_NORMAL); break;
2161                                 }
2162                         }
2163                 }
2164         }
2165         else
2166         {
2167                 if(reticle_type != 0) { reticle_type = 0; }
2168         }
2169
2170
2171         // improved polyblend
2172         if(autocvar_hud_contents && !MUTATOR_CALLHOOK(HUD_Contents))
2173         {
2174                 float contentalpha_temp, incontent, liquidalpha, contentfadetime;
2175                 vector liquidcolor;
2176
2177                 switch(pointcontents(view_origin))
2178                 {
2179                         case CONTENT_WATER:
2180                                 liquidalpha = autocvar_hud_contents_water_alpha;
2181                                 liquidcolor = stov(autocvar_hud_contents_water_color);
2182                                 incontent = 1;
2183                                 break;
2184
2185                         case CONTENT_LAVA:
2186                                 liquidalpha = autocvar_hud_contents_lava_alpha;
2187                                 liquidcolor = stov(autocvar_hud_contents_lava_color);
2188                                 incontent = 1;
2189                                 break;
2190
2191                         case CONTENT_SLIME:
2192                                 liquidalpha = autocvar_hud_contents_slime_alpha;
2193                                 liquidcolor = stov(autocvar_hud_contents_slime_color);
2194                                 incontent = 1;
2195                                 break;
2196
2197                         default:
2198                                 liquidalpha = 0;
2199                                 liquidcolor = '0 0 0';
2200                                 incontent = 0;
2201                                 break;
2202                 }
2203
2204                 if(incontent) // fade in/out at different speeds so you can do e.g. instant fade when entering water and slow when leaving it.
2205                 { // also lets delcare previous values for blending properties, this way it isn't reset until after you have entered a different content
2206                         contentfadetime = autocvar_hud_contents_fadeintime;
2207                         liquidalpha_prev = liquidalpha;
2208                         liquidcolor_prev = liquidcolor;
2209                 }
2210                 else
2211                         contentfadetime = autocvar_hud_contents_fadeouttime;
2212
2213                 contentalpha_temp = bound(0, drawframetime / max(0.0001, contentfadetime), 1);
2214                 contentavgalpha = contentavgalpha * (1 - contentalpha_temp) + incontent * contentalpha_temp;
2215
2216                 if(contentavgalpha)
2217                         drawfill('0 0 0', vec2(vid_conwidth, vid_conheight), liquidcolor_prev, contentavgalpha * liquidalpha_prev, DRAWFLAG_NORMAL);
2218
2219                 if(autocvar_hud_postprocessing)
2220                 {
2221                         if(autocvar_hud_contents_blur && contentavgalpha)
2222                         {
2223                                 content_blurpostprocess.x = 1;
2224                                 content_blurpostprocess.y = contentavgalpha * autocvar_hud_contents_blur;
2225                                 content_blurpostprocess.z = contentavgalpha * autocvar_hud_contents_blur_alpha;
2226                         }
2227                         else
2228                         {
2229                                 content_blurpostprocess.x = 0;
2230                                 content_blurpostprocess.y = 0;
2231                                 content_blurpostprocess.z = 0;
2232                         }
2233                 }
2234         }
2235
2236         if(autocvar_hud_damage && !STAT(FROZEN))
2237         {
2238                 splash_size.x = max(vid_conwidth, vid_conheight);
2239                 splash_size.y = max(vid_conwidth, vid_conheight);
2240                 splash_pos.x = (vid_conwidth - splash_size.x) / 2;
2241                 splash_pos.y = (vid_conheight - splash_size.y) / 2;
2242
2243                 float myhealth_flash_temp;
2244                 myhealth = STAT(HEALTH);
2245
2246                 // fade out
2247                 myhealth_flash = max(0, myhealth_flash - autocvar_hud_damage_fade_rate * frametime);
2248                 // add new damage
2249                 myhealth_flash = bound(0, myhealth_flash + dmg_take * autocvar_hud_damage_factor, autocvar_hud_damage_maxalpha);
2250
2251                 float pain_threshold, pain_threshold_lower, pain_threshold_lower_health;
2252                 pain_threshold = autocvar_hud_damage_pain_threshold;
2253                 pain_threshold_lower = autocvar_hud_damage_pain_threshold_lower;
2254                 pain_threshold_lower_health = autocvar_hud_damage_pain_threshold_lower_health;
2255
2256                 if(pain_threshold_lower && myhealth < pain_threshold_lower_health)
2257                 {
2258                         pain_threshold = pain_threshold - max(autocvar_hud_damage_pain_threshold_pulsating_min, fabs(sin(M_PI * time / autocvar_hud_damage_pain_threshold_pulsating_period))) * pain_threshold_lower * (1 - max(0, myhealth)/pain_threshold_lower_health);
2259                 }
2260
2261                 myhealth_flash_temp = bound(0, myhealth_flash - pain_threshold, 1);
2262
2263                 if(myhealth_prev < 1)
2264                 {
2265                         if(myhealth >= 1)
2266                         {
2267                                 myhealth_flash = 0; // just spawned, clear the flash immediately
2268                                 myhealth_flash_temp = 0;
2269                         }
2270                         else
2271                         {
2272                                 myhealth_flash += autocvar_hud_damage_fade_rate * frametime; // dead
2273                         }
2274                 }
2275
2276                 if(spectatee_status == -1 || intermission)
2277                 {
2278                         myhealth_flash = 0; // observing, or match ended
2279                         myhealth_flash_temp = 0;
2280                 }
2281
2282                 myhealth_prev = myhealth;
2283
2284                 // IDEA: change damage color/picture based on player model for robot/alien species?
2285                 // pro: matches model better
2286                 // contra: it's not red because blood is red, but because red is an alarming color, so red should stay
2287                 // maybe different reddish pics?
2288                 if(autocvar_cl_gentle_damage || autocvar_cl_gentle)
2289                 {
2290                         if(autocvar_cl_gentle_damage == 2)
2291                         {
2292                                 if(myhealth_flash < pain_threshold) // only randomize when the flash is gone
2293                                         myhealth_gentlergb = randomvec();
2294                         }
2295                         else
2296                                 myhealth_gentlergb = stov(autocvar_hud_damage_gentle_color);
2297
2298                         if(myhealth_flash_temp > 0)
2299                                 drawfill('0 0 0', vec2(vid_conwidth, vid_conheight), myhealth_gentlergb, autocvar_hud_damage_gentle_alpha_multiplier * bound(0, myhealth_flash_temp, 1) * autocvar_hud_damage, DRAWFLAG_NORMAL);
2300                 }
2301                 else if(myhealth_flash_temp > 0)
2302                         drawpic(splash_pos, "gfx/blood", splash_size, stov(autocvar_hud_damage_color), bound(0, myhealth_flash_temp, 1) * autocvar_hud_damage, DRAWFLAG_NORMAL);
2303
2304                 if(autocvar_hud_postprocessing) // we still need to set this anyway even when chase_active is set, this way it doesn't get stuck on.
2305                 {
2306                         if(autocvar_hud_damage_blur && myhealth_flash_temp)
2307                         {
2308                                 damage_blurpostprocess.x = 1;
2309                                 damage_blurpostprocess.y = bound(0, myhealth_flash_temp, 1) * autocvar_hud_damage_blur;
2310                                 damage_blurpostprocess.z = bound(0, myhealth_flash_temp, 1) * autocvar_hud_damage_blur_alpha;
2311                         }
2312                         else
2313                         {
2314                                 damage_blurpostprocess.x = 0;
2315                                 damage_blurpostprocess.y = 0;
2316                                 damage_blurpostprocess.z = 0;
2317                         }
2318                 }
2319         }
2320
2321         float e1 = (autocvar_hud_postprocessing_maxbluralpha != 0);
2322         float e2 = (autocvar_hud_powerup != 0);
2323         if(autocvar_hud_postprocessing && (e1 || e2)) // TODO: Remove this code and re-do the postprocess handling in the engine, where it properly belongs.
2324         {
2325                 // enable or disable rendering types if they are used or not
2326                 if(cvar("r_glsl_postprocess_uservec1_enable") != e1) { cvar_set("r_glsl_postprocess_uservec1_enable", ftos(e1)); }
2327                 if(cvar("r_glsl_postprocess_uservec2_enable") != e2) { cvar_set("r_glsl_postprocess_uservec2_enable", ftos(e2)); }
2328
2329                 // blur postprocess handling done first (used by hud_damage and hud_contents)
2330                 if((damage_blurpostprocess.x || content_blurpostprocess.x))
2331                 {
2332                         float blurradius = bound(0, damage_blurpostprocess.y + content_blurpostprocess.y, autocvar_hud_postprocessing_maxblurradius);
2333                         float bluralpha = bound(0, damage_blurpostprocess.z + content_blurpostprocess.z, autocvar_hud_postprocessing_maxbluralpha);
2334                         if(blurradius != old_blurradius || bluralpha != old_bluralpha) // reduce cvar_set spam as much as possible
2335                         {
2336                                 cvar_set("r_glsl_postprocess_uservec1", strcat(ftos(blurradius), " ", ftos(bluralpha), " 0 0"));
2337                                 old_blurradius = blurradius;
2338                                 old_bluralpha = bluralpha;
2339                         }
2340                 }
2341                 else if(cvar_string("r_glsl_postprocess_uservec1") != "0 0 0 0") // reduce cvar_set spam as much as possible
2342                 {
2343                         cvar_set("r_glsl_postprocess_uservec1", "0 0 0 0");
2344                         old_blurradius = 0;
2345                         old_bluralpha = 0;
2346                 }
2347
2348                 // edge detection postprocess handling done second (used by hud_powerup)
2349                 float sharpen_intensity = 0, strength_finished = STAT(STRENGTH_FINISHED), invincible_finished = STAT(INVINCIBLE_FINISHED);
2350                 if (strength_finished - time > 0) { sharpen_intensity += (strength_finished - time); }
2351                 if (invincible_finished - time > 0) { sharpen_intensity += (invincible_finished - time); }
2352
2353                 sharpen_intensity = bound(0, ((STAT(HEALTH) > 0) ? sharpen_intensity : 0), 5); // Check to see if player is alive (if not, set 0) - also bound to fade out starting at 5 seconds.
2354
2355                 if(autocvar_hud_powerup && sharpen_intensity > 0)
2356                 {
2357                         if(sharpen_intensity != old_sharpen_intensity) // reduce cvar_set spam as much as possible
2358                         {
2359                                 cvar_set("r_glsl_postprocess_uservec2", strcat(ftos((sharpen_intensity / 5) * autocvar_hud_powerup), " ", ftos(-sharpen_intensity * autocvar_hud_powerup), " 0 0"));
2360                                 old_sharpen_intensity = sharpen_intensity;
2361                         }
2362                 }
2363                 else if(cvar_string("r_glsl_postprocess_uservec2") != "0 0 0 0") // reduce cvar_set spam as much as possible
2364                 {
2365                         cvar_set("r_glsl_postprocess_uservec2", "0 0 0 0");
2366                         old_sharpen_intensity = 0;
2367                 }
2368
2369                 if(cvar("r_glsl_postprocess") == 0)
2370                         cvar_set("r_glsl_postprocess", "2");
2371         }
2372         else if(cvar("r_glsl_postprocess") == 2)
2373                 cvar_set("r_glsl_postprocess", "0");
2374
2375         /*if(gametype == MAPINFO_TYPE_CTF)
2376           {
2377           ctf_view();
2378           } else */
2379
2380         // draw 2D entities
2381         IL_EACH(g_drawables_2d, it.draw2d, it.draw2d(it));
2382         Draw_ShowNames_All();
2383 #if ENABLE_DEBUGDRAW
2384         Debug_Draw();
2385 #endif
2386
2387         scoreboard_active = Scoreboard_WouldDraw();
2388
2389         HUD_Draw(this); // this parameter for deep vehicle function
2390
2391         if(NextFrameCommand)
2392         {
2393                 localcmd("\n", NextFrameCommand, "\n");
2394                 NextFrameCommand = string_null;
2395         }
2396
2397         // we must do this check AFTER a frame was rendered, or it won't work
2398         if(cs_project_is_b0rked == 0)
2399         {
2400                 string w0, h0;
2401                 w0 = ftos(autocvar_vid_conwidth);
2402                 h0 = ftos(autocvar_vid_conheight);
2403                 //setproperty(VF_VIEWPORT, '0 0 0', '640 480 0');
2404                 //setproperty(VF_FOV, '90 90 0');
2405                 setproperty(VF_ORIGIN, '0 0 0');
2406                 setproperty(VF_ANGLES, '0 0 0');
2407                 setproperty(VF_PERSPECTIVE, 1);
2408                 makevectors('0 0 0');
2409                 vector v1, v2;
2410                 cvar_set("vid_conwidth", "800");
2411                 cvar_set("vid_conheight", "600");
2412                 v1 = cs_project(v_forward);
2413                 cvar_set("vid_conwidth", "640");
2414                 cvar_set("vid_conheight", "480");
2415                 v2 = cs_project(v_forward);
2416                 if(v1 == v2)
2417                         cs_project_is_b0rked = 1;
2418                 else
2419                         cs_project_is_b0rked = -1;
2420                 cvar_set("vid_conwidth", w0);
2421                 cvar_set("vid_conheight", h0);
2422         }
2423
2424         if(autocvar__hud_configure)
2425                 HUD_Panel_Mouse();
2426         else if (HUD_MinigameMenu_IsOpened() || active_minigame)
2427                 HUD_Minigame_Mouse();
2428         else if(QuickMenu_IsOpened())
2429                 QuickMenu_Mouse();
2430         else if(local_player.viewloc && (local_player.viewloc.spawnflags & VIEWLOC_FREEAIM))
2431                 ViewLocation_Mouse(); // NOTE: doesn't use cursormode
2432         else
2433                 HUD_Radar_Mouse();
2434
2435         cl_notice_run();
2436         unpause_update();
2437         Net_Flush();
2438
2439         // let's reset the view back to normal for the end
2440         setproperty(VF_MIN, '0 0 0');
2441         setproperty(VF_SIZE, '1 0 0' * w + '0 1 0' * h);
2442
2443         IL_ENDFRAME();
2444 }
2445
2446
2447 // following vectors must be global to allow seamless switching between camera modes
2448 vector camera_offset, current_camera_offset, mouse_angles, current_angles, current_origin, current_position;
2449 void CSQC_Demo_Camera()
2450 {
2451         float speed, attenuation, dimensions;
2452         vector tmp, delta;
2453
2454         if( autocvar_camera_reset || !camera_mode )
2455         {
2456                 camera_offset = '0 0 0';
2457                 current_angles = '0 0 0';
2458                 camera_direction = '0 0 0';
2459                 camera_offset.z += 30;
2460                 camera_offset.x += 30 * -cos(current_angles.y * DEG2RAD);
2461                 camera_offset.y += 30 * -sin(current_angles.y * DEG2RAD);
2462                 current_origin = view_origin;
2463                 current_camera_offset  = camera_offset;
2464                 cvar_set("camera_reset", "0");
2465                 camera_mode = CAMERA_CHASE;
2466         }
2467
2468         // Camera angles
2469         if( camera_roll )
2470                 mouse_angles.z += camera_roll * autocvar_camera_speed_roll;
2471
2472         if(autocvar_camera_look_player)
2473         {
2474                 vector dir;
2475                 float n;
2476
2477                 dir = normalize(view_origin - current_position);
2478                 n = mouse_angles.z;
2479                 mouse_angles = vectoangles(dir);
2480                 mouse_angles.x = mouse_angles.x * -1;
2481                 mouse_angles.z = n;
2482         }
2483         else
2484         {
2485                 tmp = getmousepos() * 0.1;
2486                 if(vdist(tmp, >, autocvar_camera_mouse_threshold))
2487                 {
2488                         mouse_angles.x += tmp.y * cos(mouse_angles.z * DEG2RAD) + (tmp.x * sin(mouse_angles.z * DEG2RAD));
2489                         mouse_angles.y -= tmp.x * cos(mouse_angles.z * DEG2RAD) + (tmp.y * -sin(mouse_angles.z * DEG2RAD));
2490                 }
2491         }
2492
2493         while (mouse_angles.x < -180) mouse_angles.x = mouse_angles.x + 360;
2494         while (mouse_angles.x > 180) mouse_angles.x = mouse_angles.x - 360;
2495         while (mouse_angles.y < -180) mouse_angles.y = mouse_angles.y + 360;
2496         while (mouse_angles.y > 180) mouse_angles.y = mouse_angles.y - 360;
2497
2498         // Fix difference when angles don't have the same sign
2499         delta = '0 0 0';
2500         if(mouse_angles.y < -60 && current_angles.y > 60)
2501                 delta = '0 360 0';
2502         if(mouse_angles.y > 60 && current_angles.y < -60)
2503                 delta = '0 -360 0';
2504
2505         if(autocvar_camera_look_player)
2506                 attenuation = autocvar_camera_look_attenuation;
2507         else
2508                 attenuation = autocvar_camera_speed_attenuation;
2509
2510         attenuation = 1 / max(1, attenuation);
2511         current_angles += (mouse_angles - current_angles + delta) * attenuation;
2512
2513         while (current_angles.x < -180) current_angles.x = current_angles.x + 360;
2514         while (current_angles.x > 180) current_angles.x = current_angles.x - 360;
2515         while (current_angles.y < -180) current_angles.y = current_angles.y + 360;
2516         while (current_angles.y > 180) current_angles.y = current_angles.y - 360;
2517
2518         // Camera position
2519         tmp = '0 0 0';
2520         dimensions = 0;
2521
2522         if( camera_direction.x )
2523         {
2524                 tmp.x = camera_direction.x * cos(current_angles.y * DEG2RAD);
2525                 tmp.y = camera_direction.x * sin(current_angles.y * DEG2RAD);
2526                 if( autocvar_camera_forward_follows && !autocvar_camera_look_player )
2527                         tmp.z = camera_direction.x * -sin(current_angles.x * DEG2RAD);
2528                 ++dimensions;
2529         }
2530
2531         if( camera_direction.y )
2532         {
2533                 tmp.x += camera_direction.y * -sin(current_angles.y * DEG2RAD);
2534                 tmp.y += camera_direction.y * cos(current_angles.y * DEG2RAD) * cos(current_angles.z * DEG2RAD);
2535                 tmp.z += camera_direction.y * sin(current_angles.z * DEG2RAD);
2536                 ++dimensions;
2537         }
2538
2539         if( camera_direction.z )
2540         {
2541                 tmp.z += camera_direction.z * cos(current_angles.z * DEG2RAD);
2542                 ++dimensions;
2543         }
2544
2545         if(autocvar_camera_free)
2546                 speed = autocvar_camera_speed_free;
2547         else
2548                 speed = autocvar_camera_speed_chase;
2549
2550         if(dimensions)
2551         {
2552                 speed = speed * sqrt(1 / dimensions);
2553                 camera_offset += tmp * speed;
2554         }
2555
2556         current_camera_offset += (camera_offset - current_camera_offset) * attenuation;
2557
2558         // Camera modes
2559         if( autocvar_camera_free )
2560         {
2561                 if ( camera_mode == CAMERA_CHASE )
2562                 {
2563                         current_camera_offset = current_origin + current_camera_offset;
2564                         camera_offset = current_origin + camera_offset;
2565                 }
2566
2567                 camera_mode = CAMERA_FREE;
2568                 current_position = current_camera_offset;
2569         }
2570         else
2571         {
2572                 if ( camera_mode == CAMERA_FREE )
2573                 {
2574                         current_origin = view_origin;
2575                         camera_offset = camera_offset - current_origin;
2576                         current_camera_offset = current_camera_offset - current_origin;
2577                 }
2578
2579                 camera_mode = CAMERA_CHASE;
2580
2581                 if(autocvar_camera_chase_smoothly)
2582                         current_origin += (view_origin - current_origin) * attenuation;
2583                 else
2584                         current_origin = view_origin;
2585
2586                 current_position = current_origin + current_camera_offset;
2587         }
2588
2589         setproperty(VF_ANGLES, current_angles);
2590         setproperty(VF_ORIGIN, current_position);
2591 }