qcsrc/client/view.qc

   1 #include "view.qh"
   2
   3 #include "autocvars.qh"
   4 #include "miscfunctions.qh"
   5 #include "announcer.qh"
   6 #include "hud/_mod.qh"
   7 #include "mapvoting.qh"
   8 #include "shownames.qh"
   9 #include "hud/panel/scoreboard.qh"
  10 #include "hud/panel/quickmenu.qh"
  11
  12 #include "mutators/events.qh"
  13
  14 #include <common/animdecide.qh>
  15 #include <common/deathtypes/all.qh>
  16 #include <common/ent_cs.qh>
  17 #include <common/anim.qh>
  18 #include <common/constants.qh>
  19 #include <common/net_linked.qh>
  20 #include <common/debug.qh>
  21 #include <common/mapinfo.qh>
  22 #include <common/gamemodes/_mod.qh>
  23 #include <common/physics/player.qh>
  24 #include <common/stats.qh>
  25 #include <common/triggers/target/music.qh>
  26 #include <common/teams.qh>
  27 #include <common/wepent.qh>
  28
  29 #include <common/weapons/weapon/tuba.qh>
  30
  31 #include <common/vehicles/all.qh>
  32 #include <common/weapons/_all.qh>
  33 #include <common/viewloc.qh>
  34 #include <common/triggers/trigger/viewloc.qh>
  35 #include <common/minigames/cl_minigames.qh>
  36 #include <common/minigames/cl_minigames_hud.qh>
  37
  38 #include <lib/csqcmodel/cl_player.qh>
  39 #include <lib/csqcmodel/cl_model.qh>
  40 #include "csqcmodel_hooks.qh"
  41
  42 #include <lib/warpzone/client.qh>
  43 #include <lib/warpzone/common.qh>
  44
  45 #define EFMASK_CHEAP (EF_ADDITIVE | EF_DOUBLESIDED | EF_FULLBRIGHT | EF_NODEPTHTEST | EF_NODRAW | EF_NOSHADOW | EF_SELECTABLE | EF_TELEPORT_BIT)
  46
  47 float autocvar_cl_viewmodel_scale;
  48
  49 bool autocvar_cl_bobmodel;
  50 float autocvar_cl_bobmodel_speed;
  51 float autocvar_cl_bobmodel_side;
  52 float autocvar_cl_bobmodel_up;
  53
  54 float autocvar_cl_followmodel;
  55 float autocvar_cl_followmodel_speed = 0.3;
  56 float autocvar_cl_followmodel_limit = 135;
  57 float autocvar_cl_followmodel_velocity_lowpass = 0.05;
  58 float autocvar_cl_followmodel_highpass = 0.05;
  59 float autocvar_cl_followmodel_lowpass = 0.03;
  60 bool autocvar_cl_followmodel_velocity_absolute;
  61
  62 float autocvar_cl_leanmodel;
  63 float autocvar_cl_leanmodel_speed = 0.3;
  64 float autocvar_cl_leanmodel_limit = 30;
  65 float autocvar_cl_leanmodel_highpass1 = 0.2;
  66 float autocvar_cl_leanmodel_highpass = 0.2;
  67 float autocvar_cl_leanmodel_lowpass = 0.05;
  68
  69 #define avg_factor(avg_time) (1 - exp(-frametime / max(0.001, avg_time)))
  70
  71 #define lowpass(value, frac, ref_store, ret) \
  72         ret = ref_store = ref_store * (1 - frac) + (value) * frac;
  73
  74 #define lowpass_limited(value, frac, limit, ref_store, ret) MACRO_BEGIN \
  75 { \
  76         float __ignore; lowpass(value, frac, ref_store, __ignore); \
  77         ret = ref_store = bound((value) - (limit), ref_store, (value) + (limit)); \
  78 } MACRO_END
  79
  80 #define highpass(value, frac, ref_store, ret) MACRO_BEGIN \
  81 { \
  82         float __f = 0; lowpass(value, frac, ref_store, __f); \
  83         ret = (value) - __f; \
  84 } MACRO_END
  85
  86 #define highpass_limited(value, frac, limit, ref_store, ret) MACRO_BEGIN \
  87 { \
  88         float __f = 0; lowpass_limited(value, frac, limit, ref_store, __f); \
  89         ret = (value) - __f; \
  90 } MACRO_END
  91
  92 #define lowpass2(value, frac, ref_store, ref_out) MACRO_BEGIN \
  93 { \
  94         lowpass(value.x, frac, ref_store.x, ref_out.x); \
  95         lowpass(value.y, frac, ref_store.y, ref_out.y); \
  96 } MACRO_END
  97
  98 #define highpass2(value, frac, ref_store, ref_out) MACRO_BEGIN \
  99 { \
 100         highpass(value.x, frac, ref_store.x, ref_out.x); \
 101         highpass(value.y, frac, ref_store.y, ref_out.y); \
 102 } MACRO_END
 103
 104 #define highpass2_limited(value, frac, limit, ref_store, ref_out) MACRO_BEGIN \
 105 { \
 106         highpass_limited(value.x, frac, limit, ref_store.x, ref_out.x); \
 107         highpass_limited(value.y, frac, limit, ref_store.y, ref_out.y); \
 108 } MACRO_END
 109
 110 #define lowpass3(value, frac, ref_store, ref_out) MACRO_BEGIN \
 111 { \
 112         lowpass(value.x, frac, ref_store.x, ref_out.x); \
 113         lowpass(value.y, frac, ref_store.y, ref_out.y); \
 114         lowpass(value.z, frac, ref_store.z, ref_out.z); \
 115 } MACRO_END
 116
 117 #define highpass3(value, frac, ref_store, ref_out) MACRO_BEGIN \
 118 { \
 119         highpass(value.x, frac, ref_store.x, ref_out.x); \
 120         highpass(value.y, frac, ref_store.y, ref_out.y); \
 121         highpass(value.z, frac, ref_store.z, ref_out.z); \
 122 } MACRO_END
 123
 124 void calc_followmodel_ofs(entity view)
 125 {
 126         if(cl_followmodel_time == time)
 127                 return; // cl_followmodel_ofs already calculated for this frame
 128
 129         float frac;
 130         vector gunorg = '0 0 0';
 131         static vector vel_average;
 132         static vector gunorg_adjustment_highpass;
 133         static vector gunorg_adjustment_lowpass;
 134
 135         vector vel;
 136         if (autocvar_cl_followmodel_velocity_absolute)
 137                 vel = view.velocity;
 138         else
 139         {
 140                 vector forward = '0 0 0', right = '0 0 0', up = '0 0 0';
 141                 MAKEVECTORS(makevectors, view_angles, forward, right, up);
 142                 vel.x = view.velocity * forward;
 143                 vel.y = view.velocity * right * -1;
 144                 vel.z = view.velocity * up;
 145         }
 146
 147         vel.x = bound(vel_average.x - autocvar_cl_followmodel_limit, vel.x, vel_average.x + autocvar_cl_followmodel_limit);
 148         vel.y = bound(vel_average.y - autocvar_cl_followmodel_limit, vel.y, vel_average.y + autocvar_cl_followmodel_limit);
 149         vel.z = bound(vel_average.z - autocvar_cl_followmodel_limit, vel.z, vel_average.z + autocvar_cl_followmodel_limit);
 150
 151         frac = avg_factor(autocvar_cl_followmodel_velocity_lowpass);
 152         lowpass3(vel, frac, vel_average, gunorg);
 153
 154         gunorg *= -autocvar_cl_followmodel_speed * 0.042;
 155
 156         // perform highpass/lowpass on the adjustment vectors (turning velocity into acceleration!)
 157         // trick: we must do the lowpass LAST, so the lowpass vector IS the final vector!
 158         frac = avg_factor(autocvar_cl_followmodel_highpass);
 159         highpass3(gunorg, frac, gunorg_adjustment_highpass, gunorg);
 160         frac = avg_factor(autocvar_cl_followmodel_lowpass);
 161         lowpass3(gunorg, frac, gunorg_adjustment_lowpass, gunorg);
 162
 163         if (autocvar_cl_followmodel_velocity_absolute)
 164         {
 165                 vector fixed_gunorg;
 166                 vector forward = '0 0 0', right = '0 0 0', up = '0 0 0';
 167                 MAKEVECTORS(makevectors, view_angles, forward, right, up);
 168                 fixed_gunorg.x = gunorg * forward;
 169                 fixed_gunorg.y = gunorg * right * -1;
 170                 fixed_gunorg.z = gunorg * up;
 171                 gunorg = fixed_gunorg;
 172         }
 173
 174         cl_followmodel_ofs = gunorg;
 175         cl_followmodel_time = time;
 176 }
 177
 178 vector leanmodel_ofs(entity view)
 179 {
 180         float frac;
 181         vector gunangles = '0 0 0';
 182         static vector gunangles_prev = '0 0 0';
 183         static vector gunangles_highpass = '0 0 0';
 184         static vector gunangles_adjustment_highpass;
 185         static vector gunangles_adjustment_lowpass;
 186
 187         if (view.csqcmodel_teleported)
 188                 gunangles_prev = view_angles;
 189
 190         // in the highpass, we _store_ the DIFFERENCE to the actual view angles...
 191         gunangles_highpass += gunangles_prev;
 192         PITCH(gunangles_highpass) += 360 * floor((PITCH(view_angles) - PITCH(gunangles_highpass)) / 360 + 0.5);
 193         YAW(gunangles_highpass) += 360 * floor((YAW(view_angles) - YAW(gunangles_highpass)) / 360 + 0.5);
 194         ROLL(gunangles_highpass) += 360 * floor((ROLL(view_angles) - ROLL(gunangles_highpass)) / 360 + 0.5);
 195         frac = avg_factor(autocvar_cl_leanmodel_highpass1);
 196         highpass2_limited(view_angles, frac, autocvar_cl_leanmodel_limit, gunangles_highpass, gunangles);
 197         gunangles_prev = view_angles;
 198         gunangles_highpass -= gunangles_prev;
 199
 200         PITCH(gunangles) *= -autocvar_cl_leanmodel_speed;
 201         YAW(gunangles) *= -autocvar_cl_leanmodel_speed;
 202
 203         // we assume here: PITCH = 0, YAW = 1, ROLL = 2
 204         frac = avg_factor(autocvar_cl_leanmodel_highpass);
 205         highpass2(gunangles, frac, gunangles_adjustment_highpass, gunangles);
 206         frac = avg_factor(autocvar_cl_leanmodel_lowpass);
 207         lowpass2(gunangles, frac, gunangles_adjustment_lowpass, gunangles);
 208
 209         gunangles.x = -gunangles.x; // pitch was inverted, now that actually matters
 210
 211         return gunangles;
 212 }
 213
 214 vector bobmodel_ofs(entity view)
 215 {
 216         bool clonground = !(view.anim_implicit_state & ANIMIMPLICITSTATE_INAIR);
 217         static bool oldonground;
 218         static float hitgroundtime;
 219         if (clonground)
 220         {
 221                 float f = time; // cl.movecmd[0].time
 222                 if (!oldonground)
 223                         hitgroundtime = f;
 224         }
 225         oldonground = clonground;
 226
 227         // calculate for swinging gun model
 228         // the gun bobs when running on the ground, but doesn't bob when you're in the air.
 229         vector gunorg = '0 0 0';
 230         static float bobmodel_scale = 0;
 231         static float time_ofs = 0; // makes the effect always restart in the same way
 232         if (clonground)
 233         {
 234                 if (time - hitgroundtime > 0.05)
 235                         bobmodel_scale = min(1, bobmodel_scale + frametime * 5);
 236         }
 237         else
 238                 bobmodel_scale = max(0, bobmodel_scale - frametime * 5);
 239
 240         float xyspeed = bound(0, vlen(vec2(view.velocity)), 400);
 241         if (bobmodel_scale && xyspeed)
 242         {
 243                 float bspeed = xyspeed * 0.01 * autocvar_cl_viewmodel_scale * bobmodel_scale;
 244                 float s = (time - time_ofs) * autocvar_cl_bobmodel_speed;
 245                 gunorg.y = bspeed * autocvar_cl_bobmodel_side * sin(s);
 246                 gunorg.z = bspeed * autocvar_cl_bobmodel_up * cos(s * 2);
 247         }
 248         else
 249                 time_ofs = time;
 250
 251         return gunorg;
 252 }
 253
 254 void viewmodel_animate(entity this)
 255 {
 256         if (autocvar_chase_active) return;
 257         if (STAT(HEALTH) <= 0) return;
 258
 259         entity view = CSQCModel_server2csqc(player_localentnum - 1);
 260
 261         if (autocvar_cl_followmodel)
 262         {
 263                 calc_followmodel_ofs(view);
 264                 this.origin += cl_followmodel_ofs;
 265         }
 266
 267         if (autocvar_cl_leanmodel)
 268                 this.angles += leanmodel_ofs(view);
 269
 270         // vertical view bobbing code
 271         // TODO: cl_bob
 272
 273         // horizontal view bobbing code
 274         // TODO: cl_bob2
 275
 276         // fall bobbing code
 277         // causes the view to swing down and back up when touching the ground
 278         // TODO: cl_bobfall
 279
 280         // gun model bobbing code
 281         if (autocvar_cl_bobmodel)
 282                 this.origin += bobmodel_ofs(view);
 283 }
 284
 285 .vector viewmodel_origin, viewmodel_angles;
 286 .float weapon_nextthink;
 287 .float weapon_eta_last;
 288 .float weapon_switchdelay;
 289
 290 .string name_last;
 291
 292 void viewmodel_draw(entity this)
 293 {
 294         if(!this.activeweapon || !autocvar_r_drawviewmodel)
 295                 return;
 296         int mask = (intermission || (STAT(HEALTH) <= 0) || autocvar_chase_active) ? 0 : MASK_NORMAL;
 297         float a = this.alpha;
 298         static bool wasinvehicle;
 299         bool invehicle = player_localentnum > maxclients;
 300         if (invehicle) a = -1;
 301         else if (wasinvehicle) a = 1;
 302         wasinvehicle = invehicle;
 303         Weapon wep = this.activeweapon;
 304         int c = entcs_GetClientColors(current_player);
 305         vector g = weaponentity_glowmod(wep, NULL, c, this);
 306         entity me = CSQCModel_server2csqc(player_localentnum - 1);
 307         int fx = ((me.csqcmodel_effects & EFMASK_CHEAP)
 308                 | EF_NODEPTHTEST)
 309                 &~ (EF_FULLBRIGHT); // can mask team color, so get rid of it
 310         for (entity e = this; e; e = e.weaponchild)
 311         {
 312                 e.drawmask = mask;
 313                 e.alpha = a;
 314                 e.colormap = 256 + c;  // colormap == 0 is black, c == 0 is white
 315                 e.glowmod = g;
 316                 e.csqcmodel_effects = fx;
 317                 CSQCModel_Effects_Apply(e);
 318         }
 319         if(a >= 0)
 320         {
 321                 string name = wep.mdl;
 322                 string newname = wep.wr_viewmodel(wep, this);
 323                 if(newname)
 324                         name = newname;
 325                 bool swap = name != this.name_last;
 326                 // if (swap)
 327                 {
 328                         this.name_last = name;
 329                         CL_WeaponEntity_SetModel(this, name, swap);
 330                         this.viewmodel_origin = this.origin;
 331                         this.viewmodel_angles = this.angles;
 332                 }
 333                 anim_update(this);
 334                 if ((!this.animstate_override && !this.animstate_looping) || time > this.animstate_endtime)
 335                         anim_set(this, this.anim_idle, true, false, false);
 336         }
 337         float f = 0; // 0..1; 0: fully active
 338         float rate = STAT(WEAPONRATEFACTOR);
 339         float eta = rate ? ((this.weapon_nextthink - time) / rate) : 0;
 340         if (eta <= 0) f = this.weapon_eta_last;
 341         else switch (this.state)
 342         {
 343                 case WS_RAISE:
 344                 {
 345                         f = eta / max(eta, this.weapon_switchdelay);
 346                         break;
 347                 }
 348                 case WS_DROP:
 349                 {
 350                         f = 1 - eta / max(eta, this.weapon_switchdelay);
 351                         break;
 352                 }
 353                 case WS_CLEAR:
 354                 {
 355                         f = 1;
 356                         break;
 357                 }
 358         }
 359         this.weapon_eta_last = f;
 360         this.origin = this.viewmodel_origin;
 361         this.angles = this.viewmodel_angles;
 362         this.angles_x = (-90 * f * f);
 363         viewmodel_animate(this);
 364         MUTATOR_CALLHOOK(DrawViewModel, this);
 365         setorigin(this, this.origin);
 366 }
 367
 368 STATIC_INIT(viewmodel) {
 369     for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 370         viewmodels[slot] = new(viewmodel);
 371 }
 372
 373 void Porto_Draw(entity this);
 374 STATIC_INIT(Porto)
 375 {
 376         entity e = new_pure(porto);
 377         e.draw = Porto_Draw;
 378         IL_PUSH(g_drawables, e);
 379         e.dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY | DPCONTENTS_PLAYERCLIP;
 380 }
 381
 382 const int polyline_length = 16;
 383 .vector polyline[polyline_length];
 384 void Porto_Draw(entity this)
 385 {
 386         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 387         {
 388                 entity wepent = viewmodels[slot];
 389
 390                 if (wepent.activeweapon != WEP_PORTO) continue;
 391                 if (spectatee_status) continue;
 392                 if (WEP_CVAR(porto, secondary)) continue;
 393                 if (intermission == 1) continue;
 394                 if (intermission == 2) continue;
 395                 if (STAT(HEALTH) <= 0) continue;
 396
 397                 vector pos = view_origin;
 398                 vector dir = view_forward;
 399                 if (wepent.angles_held_status)
 400                 {
 401                         makevectors(wepent.angles_held);
 402                         dir = v_forward;
 403                 }
 404
 405                 wepent.polyline[0] = pos;
 406
 407                 int portal_number = 0, portal1_idx = 1, portal_max = 2;
 408                 int n = 1 + 2;  // 2 lines == 3 points
 409                 for (int idx = 0; idx < n && idx < polyline_length - 1; )
 410                 {
 411                         traceline(pos, pos + 65536 * dir, true, this);
 412                         dir = reflect(dir, trace_plane_normal);
 413                         pos = trace_endpos;
 414                         wepent.polyline[++idx] = pos;
 415                         if (trace_dphitq3surfaceflags & Q3SURFACEFLAG_SLICK || trace_dphitcontents & DPCONTENTS_PLAYERCLIP)
 416                         {
 417                                 n += 1;
 418                                 continue;
 419                         }
 420                         if (trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT)
 421                         {
 422                                 n = max(2, idx);
 423                                 break;
 424                         }
 425                         // check size
 426                         {
 427                                 vector ang = vectoangles2(trace_plane_normal, dir);
 428                                 ang.x = -ang.x;
 429                                 makevectors(ang);
 430                                 if (!CheckWireframeBox(this, pos - 48 * v_right - 48 * v_up + 16 * v_forward, 96 * v_right, 96 * v_up, 96 * v_forward))
 431                                 {
 432                                         n = max(2, idx);
 433                                         break;
 434                                 }
 435                         }
 436                         portal_number += 1;
 437                         if (portal_number >= portal_max) break;
 438                         if (portal_number == 1) portal1_idx = idx;
 439                 }
 440                 for (int idx = 0; idx < n - 1; ++idx)
 441                 {
 442                         vector p = wepent.polyline[idx], q = wepent.polyline[idx + 1];
 443                         if (idx == 0) p -= view_up * 16;  // line from player
 444                         vector rgb = (idx < portal1_idx) ? '1 0 0' : '0 0 1';
 445                         Draw_CylindricLine(p, q, 4, "", 1, 0, rgb, 0.5, DRAWFLAG_NORMAL, view_origin);
 446                 }
 447         }
 448 }
 449
 450 float drawtime;
 451 float avgspeed;
 452 vector GetCurrentFov(float fov)
 453 {
 454         float zoomsensitivity, zoomspeed, zoomfactor, zoomdir;
 455         float velocityzoom, curspeed;
 456         vector v;
 457
 458         zoomsensitivity = autocvar_cl_zoomsensitivity;
 459         zoomfactor = autocvar_cl_zoomfactor;
 460         if(zoomfactor < 1 || zoomfactor > 30)
 461                 zoomfactor = 2.5;
 462         zoomspeed = autocvar_cl_zoomspeed;
 463         if(zoomspeed >= 0)
 464         if(zoomspeed < 0.5 || zoomspeed > 16)
 465                         zoomspeed = 3.5;
 466
 467         zoomdir = button_zoom;
 468
 469         if(hud == HUD_NORMAL && !spectatee_status)
 470         {
 471                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 472                 {
 473                         entity wepent = viewmodels[slot];
 474                         if(wepent.switchweapon != wepent.activeweapon)
 475                                 continue;
 476                         Weapon wep = wepent.activeweapon;
 477                         if(wep != WEP_Null && wep.wr_zoomdir)
 478                         {
 479                                 bool do_zoom = wep.wr_zoomdir(wep); // TODO: merge this with wr_zoom?
 480                                 zoomdir += do_zoom;
 481                         }
 482                 }
 483         }
 484         if(spectatee_status > 0 || isdemo())
 485         {
 486                 if(spectatorbutton_zoom)
 487                 {
 488                         if(zoomdir)
 489                                 zoomdir = 0;
 490                         else
 491                                 zoomdir = 1;
 492                 }
 493                 // fteqcc failed twice here already, don't optimize this
 494         }
 495
 496         if(zoomdir) { zoomin_effect = 0; }
 497
 498         if(camera_active)
 499         {
 500                 current_viewzoom = min(1, current_viewzoom + drawframetime);
 501         }
 502         else if(autocvar_cl_spawnzoom && zoomin_effect)
 503         {
 504                 float spawnzoomfactor = bound(1, autocvar_cl_spawnzoom_factor, 30);
 505
 506                 current_viewzoom += (autocvar_cl_spawnzoom_speed * (spawnzoomfactor - current_viewzoom) * drawframetime);
 507                 current_viewzoom = bound(1 / spawnzoomfactor, current_viewzoom, 1);
 508                 if(current_viewzoom == 1) { zoomin_effect = 0; }
 509         }
 510         else
 511         {
 512                 if(zoomspeed < 0) // instant zoom
 513                 {
 514                         if(zoomdir)
 515                                 current_viewzoom = 1 / zoomfactor;
 516                         else
 517                                 current_viewzoom = 1;
 518                 }
 519                 else
 520                 {
 521                         if(zoomdir)
 522                                 current_viewzoom = 1 / bound(1, 1 / current_viewzoom + drawframetime * zoomspeed * (zoomfactor - 1), zoomfactor);
 523                         else
 524                                 current_viewzoom = bound(1 / zoomfactor, current_viewzoom + drawframetime * zoomspeed * (1 - 1 / zoomfactor), 1);
 525                 }
 526         }
 527
 528         if(almost_equals(current_viewzoom, 1))
 529                 current_zoomfraction = 0;
 530         else if(almost_equals(current_viewzoom, 1/zoomfactor))
 531                 current_zoomfraction = 1;
 532         else
 533                 current_zoomfraction = (current_viewzoom - 1) / (1/zoomfactor - 1);
 534
 535         if(zoomsensitivity < 1)
 536                 setsensitivityscale(current_viewzoom ** (1 - zoomsensitivity));
 537         else
 538                 setsensitivityscale(1);
 539
 540         if(autocvar_cl_velocityzoom_enabled && autocvar_cl_velocityzoom_type) // _type = 0 disables velocity zoom too
 541         {
 542                 if(intermission) { curspeed = 0; }
 543                 else
 544                 {
 545
 546                         makevectors(view_angles);
 547                         v = pmove_vel;
 548                         if(csqcplayer)
 549                                 v = csqcplayer.velocity;
 550
 551                         switch(autocvar_cl_velocityzoom_type)
 552                         {
 553                                 case 3: curspeed = max(0, v_forward * v); break;
 554                                 case 2: curspeed = (v_forward * v); break;
 555                                 case 1: default: curspeed = vlen(v); break;
 556                         }
 557                 }
 558
 559                 velocityzoom = bound(0, drawframetime / max(0.000000001, autocvar_cl_velocityzoom_time), 1); // speed at which the zoom adapts to player velocity
 560                 avgspeed = avgspeed * (1 - velocityzoom) + (curspeed / autocvar_cl_velocityzoom_speed) * velocityzoom;
 561                 velocityzoom = exp(float2range11(avgspeed * -autocvar_cl_velocityzoom_factor / 1) * 1);
 562
 563                 //print(ftos(avgspeed), " avgspeed, ", ftos(curspeed), " curspeed, ", ftos(velocityzoom), " return\n"); // for debugging
 564         }
 565         else
 566                 velocityzoom = 1;
 567
 568         float frustumx, frustumy, fovx, fovy;
 569         frustumy = tan(fov * M_PI / 360.0) * 0.75 * current_viewzoom * velocityzoom;
 570         frustumx = frustumy * vid_width / vid_height / vid_pixelheight;
 571         fovx = atan2(frustumx, 1) / M_PI * 360.0;
 572         fovy = atan2(frustumy, 1) / M_PI * 360.0;
 573
 574         return '1 0 0' * fovx + '0 1 0' * fovy;
 575 }
 576
 577 vector GetViewLocationFOV(float fov)
 578 {
 579         float frustumy = tan(fov * M_PI / 360.0) * 0.75;
 580         float frustumx = frustumy * vid_width / vid_height / vid_pixelheight;
 581         float fovx = atan2(frustumx, 1) / M_PI * 360.0;
 582         float fovy = atan2(frustumy, 1) / M_PI * 360.0;
 583         return '1 0 0' * fovx + '0 1 0' * fovy;
 584 }
 585
 586 vector GetOrthoviewFOV(vector ov_worldmin, vector ov_worldmax, vector ov_mid, vector ov_org)
 587 {
 588         float fovx, fovy;
 589         float width = (ov_worldmax.x - ov_worldmin.x);
 590         float height = (ov_worldmax.y - ov_worldmin.y);
 591         float distance_to_middle_of_world = vlen(ov_mid - ov_org);
 592         fovx = atan2(width/2, distance_to_middle_of_world) / M_PI * 360.0;
 593         fovy = atan2(height/2, distance_to_middle_of_world) / M_PI * 360.0;
 594         return '1 0 0' * fovx + '0 1 0' * fovy;
 595 }
 596
 597 // this function must match W_SetupShot!
 598 float zoomscript_caught;
 599
 600 vector wcross_origin;
 601 float wcross_scale_prev, wcross_alpha_prev;
 602 vector wcross_color_prev;
 603 float wcross_scale_goal_prev, wcross_alpha_goal_prev;
 604 vector wcross_color_goal_prev;
 605 float wcross_changedonetime;
 606
 607 string wcross_name_goal_prev, wcross_name_goal_prev_prev;
 608 float wcross_resolution_goal_prev, wcross_resolution_goal_prev_prev;
 609 float wcross_name_changestarttime, wcross_name_changedonetime;
 610 float wcross_name_alpha_goal_prev, wcross_name_alpha_goal_prev_prev;
 611
 612 float wcross_ring_prev;
 613
 614 entity trueaim;
 615 entity trueaim_rifle;
 616
 617 const float SHOTTYPE_HITTEAM = 1;
 618 const float SHOTTYPE_HITOBSTRUCTION = 2;
 619 const float SHOTTYPE_HITWORLD = 3;
 620 const float SHOTTYPE_HITENEMY = 4;
 621
 622 void TrueAim_Init()
 623 {
 624         (trueaim = new_pure(trueaim)).dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY | DPCONTENTS_CORPSE;
 625         (trueaim_rifle = new_pure(trueaim_rifle)).dphitcontentsmask = DPCONTENTS_BODY | DPCONTENTS_CORPSE;
 626 }
 627
 628 float EnemyHitCheck()
 629 {
 630         float t, n;
 631         wcross_origin = project_3d_to_2d(trace_endpos);
 632         wcross_origin.z = 0;
 633         if(trace_ent)
 634                 n = trace_ent.entnum;
 635         else
 636                 n = trace_networkentity;
 637         if(n < 1)
 638                 return SHOTTYPE_HITWORLD;
 639         if(n > maxclients)
 640                 return SHOTTYPE_HITWORLD;
 641         t = entcs_GetTeam(n - 1);
 642         if(teamplay)
 643                 if(t == myteam)
 644                         return SHOTTYPE_HITTEAM;
 645         if(t == NUM_SPECTATOR)
 646                 return SHOTTYPE_HITWORLD;
 647         return SHOTTYPE_HITENEMY;
 648 }
 649
 650 float TrueAimCheck(entity wepent)
 651 {
 652         float nudge = 1; // added to traceline target and subtracted from result TOOD(divVerent): do we still need this? Doesn't the engine do this now for us?
 653         vector vecs, trueaimpoint, w_shotorg;
 654         vector mi, ma, dv;
 655         float shottype;
 656         entity ta;
 657         float mv;
 658
 659         mi = ma = '0 0 0';
 660         ta = trueaim;
 661         mv = MOVE_NOMONSTERS;
 662
 663         switch(wepent.activeweapon) // WEAPONTODO
 664         {
 665                 case WEP_TUBA: // no aim
 666                 case WEP_PORTO: // shoots from eye
 667                 case WEP_NEXBALL: // shoots from eye
 668                 case WEP_HOOK: // no trueaim
 669                 case WEP_MORTAR: // toss curve
 670                         return SHOTTYPE_HITWORLD;
 671                 case WEP_VORTEX:
 672                 case WEP_VAPORIZER:
 673                         mv = MOVE_NORMAL;
 674                         break;
 675                 case WEP_RIFLE:
 676                         ta = trueaim_rifle;
 677                         mv = MOVE_NORMAL;
 678                         if(zoomscript_caught)
 679                         {
 680                                 tracebox(view_origin, '0 0 0', '0 0 0', view_origin + view_forward * max_shot_distance, mv, ta);
 681                                 return EnemyHitCheck();
 682                         }
 683                         break;
 684                 case WEP_DEVASTATOR: // projectile has a size!
 685                         mi = '-3 -3 -3';
 686                         ma = '3 3 3';
 687                         break;
 688                 case WEP_FIREBALL: // projectile has a size!
 689                         mi = '-16 -16 -16';
 690                         ma = '16 16 16';
 691                         break;
 692                 case WEP_SEEKER: // projectile has a size!
 693                         mi = '-2 -2 -2';
 694                         ma = '2 2 2';
 695                         break;
 696                 case WEP_ELECTRO: // projectile has a size!
 697                         mi = '0 0 -3';
 698                         ma = '0 0 -3';
 699                         break;
 700         }
 701
 702         vector traceorigin = entcs_receiver(player_localentnum - 1).origin + (eZ * STAT(VIEWHEIGHT));
 703
 704         vecs = decompressShotOrigin(STAT(SHOTORG));
 705
 706         traceline(traceorigin, traceorigin + view_forward * max_shot_distance, mv, ta);
 707         trueaimpoint = trace_endpos;
 708
 709         if(vdist((trueaimpoint - traceorigin), <, g_trueaim_minrange))
 710                 trueaimpoint = traceorigin + view_forward * g_trueaim_minrange;
 711
 712         if(vecs.x > 0)
 713                 vecs.y = -vecs.y;
 714         else
 715                 vecs = '0 0 0';
 716
 717         dv = view_right * vecs.y + view_up * vecs.z;
 718         w_shotorg = traceorigin + dv;
 719
 720         // now move the vecs forward as much as requested if possible
 721         tracebox(w_shotorg, mi, ma, w_shotorg + view_forward * (vecs.x + nudge), MOVE_NORMAL, ta); // FIXME this MOVE_NORMAL part will misbehave a little in csqc
 722         w_shotorg = trace_endpos - view_forward * nudge;
 723
 724         tracebox(w_shotorg, mi, ma, trueaimpoint, MOVE_NORMAL, ta);
 725         shottype = EnemyHitCheck();
 726         if(shottype != SHOTTYPE_HITWORLD)
 727                 return shottype;
 728
 729 #if 0
 730         // FIXME WHY DOES THIS NOT WORK FOR THE ROCKET LAUNCHER?
 731         // or rather, I know why, but see no fix
 732         if(vlen(trace_endpos - trueaimpoint) > vlen(ma) + vlen(mi) + 1)
 733                 // yes, this is an ugly hack... but it seems good enough to find out whether the test hits the same place as the initial trace
 734                 return SHOTTYPE_HITOBSTRUCTION;
 735 #endif
 736
 737         return SHOTTYPE_HITWORLD;
 738 }
 739
 740 void PostInit();
 741 void CSQC_Demo_Camera();
 742 float camera_mode;
 743 const float CAMERA_FREE = 1;
 744 const float CAMERA_CHASE = 2;
 745 float reticle_type;
 746 string NextFrameCommand;
 747
 748 vector freeze_org, freeze_ang;
 749 entity nightvision_noise, nightvision_noise2;
 750
 751 const float MAX_TIME_DIFF = 5;
 752 float pickup_crosshair_time, pickup_crosshair_size;
 753 float hitindication_crosshair_size;
 754 float use_vortex_chargepool;
 755
 756 float myhealth, myhealth_prev;
 757 float myhealth_flash;
 758
 759 float old_blurradius, old_bluralpha;
 760 float old_sharpen_intensity;
 761
 762 vector myhealth_gentlergb;
 763
 764 float contentavgalpha, liquidalpha_prev;
 765 vector liquidcolor_prev;
 766
 767 float eventchase_current_distance;
 768 float eventchase_running;
 769 bool WantEventchase(entity this)
 770 {
 771         if(autocvar_cl_orthoview)
 772                 return false;
 773         if(STAT(GAME_STOPPED) || intermission)
 774                 return true;
 775         if(this.viewloc)
 776                 return true;
 777         if(spectatee_status >= 0)
 778         {
 779                 if(hud != HUD_NORMAL && (autocvar_cl_eventchase_vehicle || spectatee_status > 0))
 780                         return true;
 781                 if(MUTATOR_CALLHOOK(WantEventchase, this))
 782                         return true;
 783                 if(autocvar_cl_eventchase_frozen && STAT(FROZEN))
 784                         return true;
 785                 if(autocvar_cl_eventchase_death && (STAT(HEALTH) <= 0))
 786                 {
 787                         if(autocvar_cl_eventchase_death == 2)
 788                         {
 789                                 // don't stop eventchase once it's started (even if velocity changes afterwards)
 790                                 if(this.velocity == '0 0 0' || eventchase_running)
 791                                         return true;
 792                         }
 793                         else return true;
 794                 }
 795         }
 796         return false;
 797 }
 798
 799 void HUD_Crosshair_Vehicle(entity this)
 800 {
 801         if(hud != HUD_BUMBLEBEE_GUN)
 802         {
 803                 Vehicle info = Vehicles_from(hud);
 804                 info.vr_crosshair(info, this);
 805         }
 806 }
 807
 808 vector damage_blurpostprocess, content_blurpostprocess;
 809
 810 float unaccounted_damage = 0;
 811 void UpdateDamage()
 812 {
 813         // accumulate damage with each stat update
 814         static float damage_total_prev = 0;
 815         float damage_total = STAT(DAMAGE_DEALT_TOTAL);
 816         float unaccounted_damage_new = COMPARE_INCREASING(damage_total, damage_total_prev);
 817         damage_total_prev = damage_total;
 818
 819         static float damage_dealt_time_prev = 0;
 820         float damage_dealt_time = STAT(HIT_TIME);
 821         if (damage_dealt_time != damage_dealt_time_prev)
 822         {
 823                 unaccounted_damage += unaccounted_damage_new;
 824                 LOG_TRACE("dmg total: ", ftos(unaccounted_damage), " (+", ftos(unaccounted_damage_new), ")");
 825         }
 826         damage_dealt_time_prev = damage_dealt_time;
 827
 828         // prevent hitsound when switching spectatee
 829         static float spectatee_status_prev = 0;
 830         if (spectatee_status != spectatee_status_prev)
 831                 unaccounted_damage = 0;
 832         spectatee_status_prev = spectatee_status;
 833 }
 834
 835 void HitSound()
 836 {
 837         // varying sound pitch
 838
 839         bool have_arc = false;
 840         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 841         {
 842                 entity wepent = viewmodels[slot];
 843
 844                 if(wepent.activeweapon == WEP_ARC)
 845                         have_arc = true;
 846         }
 847
 848         static float hitsound_time_prev = 0;
 849         // HACK: the only way to get the arc to sound consistent with pitch shift is to ignore cl_hitsound_antispam_time
 850         bool arc_hack = have_arc && autocvar_cl_hitsound >= 2;
 851         if (arc_hack || COMPARE_INCREASING(time, hitsound_time_prev) > autocvar_cl_hitsound_antispam_time)
 852         {
 853                 if (autocvar_cl_hitsound && unaccounted_damage)
 854                 {
 855                         // customizable gradient function that crosses (0,a), (c,1) and asymptotically approaches b
 856                         float a = autocvar_cl_hitsound_max_pitch;
 857                         float b = autocvar_cl_hitsound_min_pitch;
 858                         float c = autocvar_cl_hitsound_nom_damage;
 859                         float d = unaccounted_damage;
 860                         float pitch_shift = (b*d*(a-1) + a*c*(1-b)) / (d*(a-1) + c*(1-b));
 861
 862                         // if sound variation is disabled, set pitch_shift to 1
 863                         if (autocvar_cl_hitsound == 1)
 864                                 pitch_shift = 1;
 865
 866                         // if pitch shift is reversed, mirror in (max-min)/2 + min
 867                         if (autocvar_cl_hitsound == 3)
 868                         {
 869                                 float mirror_value = (a-b)/2 + b;
 870                                 pitch_shift = mirror_value + (mirror_value - pitch_shift);
 871                         }
 872
 873                         LOG_TRACE("dmg total (dmg): ", ftos(unaccounted_damage), " , pitch shift: ", ftos(pitch_shift));
 874
 875                         // todo: avoid very long and very short sounds from wave stretching using different sound files? seems unnecessary
 876                         // todo: normalize sound pressure levels? seems unnecessary
 877
 878                         sound7(NULL, CH_INFO, SND(HIT), VOL_BASE, ATTN_NONE, pitch_shift * 100, 0);
 879                 }
 880                 unaccounted_damage = 0;
 881                 hitsound_time_prev = time;
 882         }
 883
 884         static float typehit_time_prev = 0;
 885         float typehit_time = STAT(TYPEHIT_TIME);
 886         if (COMPARE_INCREASING(typehit_time, typehit_time_prev) > autocvar_cl_hitsound_antispam_time)
 887         {
 888                 sound(NULL, CH_INFO, SND_TYPEHIT, VOL_BASE, ATTN_NONE);
 889                 typehit_time_prev = typehit_time;
 890         }
 891
 892         static float kill_time_prev = 0;
 893         float kill_time = STAT(KILL_TIME);
 894         if (COMPARE_INCREASING(kill_time, kill_time_prev) > autocvar_cl_hitsound_antispam_time)
 895         {
 896                 sound(NULL, CH_INFO, SND_KILL, VOL_BASE, ATTN_NONE);
 897                 kill_time_prev = kill_time;
 898         }
 899 }
 900
 901 vector crosshair_getcolor(entity this, float health_stat)
 902 {
 903         static float rainbow_last_flicker;
 904         static vector rainbow_prev_color;
 905         vector wcross_color = '0 0 0';
 906         switch(autocvar_crosshair_color_special)
 907         {
 908                 case 1: // crosshair_color_per_weapon
 909                 {
 910                         if(this != WEP_Null && hud == HUD_NORMAL)
 911                         {
 912                                 wcross_color = this.wpcolor;
 913                                 break;
 914                         }
 915                         else { goto normalcolor; }
 916                 }
 917
 918                 case 2: // crosshair_color_by_health
 919                 {
 920                         vector v = healtharmor_maxdamage(health_stat, STAT(ARMOR), armorblockpercent, DEATH_WEAPON.m_id);
 921                         float hp = floor(v.x + 1);
 922
 923                         //x = red
 924                         //y = green
 925                         //z = blue
 926
 927                         wcross_color.z = 0;
 928
 929                         if(hp > 200)
 930                         {
 931                                 wcross_color.x = 0;
 932                                 wcross_color.y = 1;
 933                         }
 934                         else if(hp > 150)
 935                         {
 936                                 wcross_color.x = 0.4 - (hp-150)*0.02 * 0.4;
 937                                 wcross_color.y = 0.9 + (hp-150)*0.02 * 0.1;
 938                         }
 939                         else if(hp > 100)
 940                         {
 941                                 wcross_color.x = 1 - (hp-100)*0.02 * 0.6;
 942                                 wcross_color.y = 1 - (hp-100)*0.02 * 0.1;
 943                                 wcross_color.z = 1 - (hp-100)*0.02;
 944                         }
 945                         else if(hp > 50)
 946                         {
 947                                 wcross_color.x = 1;
 948                                 wcross_color.y = 1;
 949                                 wcross_color.z = 0.2 + (hp-50)*0.02 * 0.8;
 950                         }
 951                         else if(hp > 20)
 952                         {
 953                                 wcross_color.x = 1;
 954                                 wcross_color.y = (hp-20)*90/27/100;
 955                                 wcross_color.z = (hp-20)*90/27/100 * 0.2;
 956                         }
 957                         else
 958                         {
 959                                 wcross_color.x = 1;
 960                                 wcross_color.y = 0;
 961                         }
 962                         break;
 963                 }
 964
 965                 case 3: // crosshair_color_rainbow
 966                 {
 967                         if(time >= rainbow_last_flicker)
 968                         {
 969                                 rainbow_prev_color = randomvec() * autocvar_crosshair_color_special_rainbow_brightness;
 970                                 rainbow_last_flicker = time + autocvar_crosshair_color_special_rainbow_delay;
 971                         }
 972                         wcross_color = rainbow_prev_color;
 973                         break;
 974                 }
 975 LABEL(normalcolor)
 976                 default: { wcross_color = stov(autocvar_crosshair_color); break; }
 977         }
 978
 979         return wcross_color;
 980 }
 981
 982 void HUD_Crosshair(entity this)
 983 {
 984         float f, i, j;
 985         vector v;
 986         if(!scoreboard_active && !camera_active && intermission != 2 && !STAT(GAME_STOPPED) &&
 987                 spectatee_status != -1 && (!csqcplayer.viewloc || (!spectatee_status && (csqcplayer.viewloc.spawnflags & VIEWLOC_FREEAIM))) && !MUTATOR_CALLHOOK(DrawCrosshair) &&
 988                 !HUD_MinigameMenu_IsOpened() )
 989         {
 990                 if (!autocvar_crosshair_enabled) // main toggle for crosshair rendering
 991                         return;
 992
 993                 if (spectatee_status > 0 && STAT(CAMERA_SPECTATOR) == 2)
 994                         return;
 995
 996                 if (hud != HUD_NORMAL)
 997                 {
 998                         HUD_Crosshair_Vehicle(this);
 999                         return;
1000                 }
1001
1002                 string wcross_style;
1003                 float wcross_alpha, wcross_resolution;
1004                 wcross_style = autocvar_crosshair;
1005                 if (csqcplayer.viewloc && (csqcplayer.viewloc.spawnflags & VIEWLOC_FREEAIM) && autocvar_crosshair_2d != "")
1006                         wcross_style = autocvar_crosshair_2d;
1007                 if (wcross_style == "0")
1008                         return;
1009                 wcross_resolution = autocvar_crosshair_size;
1010                 if (wcross_resolution == 0)
1011                         return;
1012                 wcross_alpha = autocvar_crosshair_alpha;
1013                 if (wcross_alpha == 0)
1014                         return;
1015
1016                 // TrueAim check
1017                 float shottype;
1018
1019                 // wcross_origin = '0.5 0 0' * vid_conwidth + '0 0.5 0' * vid_conheight;
1020                 if(csqcplayer.viewloc && (csqcplayer.viewloc.spawnflags & VIEWLOC_FREEAIM))
1021                         wcross_origin = viewloc_mousepos;
1022                 else
1023                         wcross_origin = project_3d_to_2d(view_origin + max_shot_distance * view_forward);
1024                 wcross_origin.z = 0;
1025                 if(autocvar_crosshair_hittest)
1026                 {
1027                         vector wcross_oldorigin;
1028                         entity thiswep = viewmodels[0]; // TODO: unhardcode
1029                         wcross_oldorigin = wcross_origin;
1030                         shottype = TrueAimCheck(thiswep);
1031                         if(shottype == SHOTTYPE_HITWORLD)
1032                         {
1033                                 v = wcross_origin - wcross_oldorigin;
1034                                 v.x /= vid_conwidth;
1035                                 v.y /= vid_conheight;
1036                                 if(vdist(v, >, 0.01))
1037                                         shottype = SHOTTYPE_HITOBSTRUCTION;
1038                         }
1039                         if(!autocvar_crosshair_hittest_showimpact)
1040                                 wcross_origin = wcross_oldorigin;
1041                 }
1042                 else
1043                         shottype = SHOTTYPE_HITWORLD;
1044
1045                 vector wcross_color = '0 0 0', wcross_size = '0 0 0';
1046                 string wcross_name = "";
1047                 float wcross_scale, wcross_blur;
1048
1049         entity e = WEP_Null;
1050                 if(autocvar_crosshair_per_weapon || (autocvar_crosshair_color_special == 1))
1051                 {
1052                         entity wepent = viewmodels[0]; // TODO: unhardcode
1053                         e = wepent.switchingweapon;
1054                         if(e)
1055                         {
1056                                 if(autocvar_crosshair_per_weapon)
1057                                 {
1058                                         // WEAPONTODO: access these through some general settings (with non-balance config settings)
1059                                         //wcross_resolution *= cvar(strcat("crosshair_", wcross_wep, "_size"));
1060                                         //if (wcross_resolution == 0)
1061                                                 //return;
1062
1063                                         //wcross_style = cvar_string(strcat("crosshair_", wcross_wep));
1064                                         wcross_resolution *= e.w_crosshair_size;
1065                                         wcross_name = e.w_crosshair;
1066                                 }
1067                         }
1068                 }
1069
1070                 if(wcross_name == "")
1071                         wcross_name = strcat("gfx/crosshair", wcross_style);
1072
1073                 // MAIN CROSSHAIR COLOR DECISION
1074                 wcross_color = crosshair_getcolor(e, STAT(HEALTH));
1075
1076                 if(autocvar_crosshair_effect_scalefade)
1077                 {
1078                         wcross_scale = wcross_resolution;
1079                         wcross_resolution = 1;
1080                 }
1081                 else
1082                 {
1083                         wcross_scale = 1;
1084                 }
1085
1086                 if(autocvar_crosshair_pickup)
1087                 {
1088                         float stat_pickup_time = STAT(LAST_PICKUP);
1089
1090                         if(pickup_crosshair_time < stat_pickup_time)
1091                         {
1092                                 if(time - stat_pickup_time < MAX_TIME_DIFF) // don't trigger the animation if it's too old
1093                                         pickup_crosshair_size = 1;
1094
1095                                 pickup_crosshair_time = stat_pickup_time;
1096                         }
1097
1098                         if(pickup_crosshair_size > 0)
1099                                 pickup_crosshair_size -= autocvar_crosshair_pickup_speed * frametime;
1100                         else
1101                                 pickup_crosshair_size = 0;
1102
1103                         wcross_scale += sin(pickup_crosshair_size) * autocvar_crosshair_pickup;
1104                 }
1105
1106                 // todo: make crosshair hit indication dependent on damage dealt
1107                 if(autocvar_crosshair_hitindication)
1108                 {
1109                         vector hitindication_color = ((autocvar_crosshair_color_special == 1) ? stov(autocvar_crosshair_hitindication_per_weapon_color) : stov(autocvar_crosshair_hitindication_color));
1110
1111                         if(unaccounted_damage)
1112                         {
1113                                 hitindication_crosshair_size = 1;
1114                         }
1115
1116                         if(hitindication_crosshair_size > 0)
1117                                 hitindication_crosshair_size -= autocvar_crosshair_hitindication_speed * frametime;
1118                         else
1119                                 hitindication_crosshair_size = 0;
1120
1121                         wcross_scale += sin(hitindication_crosshair_size) * autocvar_crosshair_hitindication;
1122                         wcross_color.x += sin(hitindication_crosshair_size) * hitindication_color.x;
1123                         wcross_color.y += sin(hitindication_crosshair_size) * hitindication_color.y;
1124                         wcross_color.z += sin(hitindication_crosshair_size) * hitindication_color.z;
1125                 }
1126
1127                 if(shottype == SHOTTYPE_HITENEMY)
1128                         wcross_scale *= autocvar_crosshair_hittest; // is not queried if hittest is 0
1129                 if(shottype == SHOTTYPE_HITTEAM)
1130                         wcross_scale /= autocvar_crosshair_hittest; // is not queried if hittest is 0
1131
1132                 f = fabs(autocvar_crosshair_effect_time);
1133                 if(wcross_scale != wcross_scale_goal_prev || wcross_alpha != wcross_alpha_goal_prev || wcross_color != wcross_color_goal_prev)
1134                 {
1135                         wcross_changedonetime = time + f;
1136                 }
1137                 if(wcross_name != wcross_name_goal_prev || wcross_resolution != wcross_resolution_goal_prev)
1138                 {
1139                         wcross_name_changestarttime = time;
1140                         wcross_name_changedonetime = time + f;
1141                         if(wcross_name_goal_prev_prev)
1142                                 strunzone(wcross_name_goal_prev_prev);
1143                         wcross_name_goal_prev_prev = wcross_name_goal_prev;
1144                         wcross_name_goal_prev = strzone(wcross_name);
1145                         wcross_name_alpha_goal_prev_prev = wcross_name_alpha_goal_prev;
1146                         wcross_resolution_goal_prev_prev = wcross_resolution_goal_prev;
1147                         wcross_resolution_goal_prev = wcross_resolution;
1148                 }
1149
1150                 wcross_scale_goal_prev = wcross_scale;
1151                 wcross_alpha_goal_prev = wcross_alpha;
1152                 wcross_color_goal_prev = wcross_color;
1153
1154                 if(spectatee_status == -1 && shottype == SHOTTYPE_HITTEAM || (shottype == SHOTTYPE_HITOBSTRUCTION && autocvar_crosshair_hittest_blur && !autocvar_chase_active))
1155                 {
1156                         wcross_blur = 1;
1157                         wcross_alpha *= 0.75;
1158                 }
1159                 else
1160                         wcross_blur = 0;
1161                 // *_prev is at time-frametime
1162                 // * is at wcross_changedonetime+f
1163                 // what do we have at time?
1164                 if(time < wcross_changedonetime)
1165                 {
1166                         f = frametime / (wcross_changedonetime - time + frametime);
1167                         wcross_scale = f * wcross_scale + (1 - f) * wcross_scale_prev;
1168                         wcross_alpha = f * wcross_alpha + (1 - f) * wcross_alpha_prev;
1169                         wcross_color = f * wcross_color + (1 - f) * wcross_color_prev;
1170                 }
1171
1172                 wcross_scale_prev = wcross_scale;
1173                 wcross_alpha_prev = wcross_alpha;
1174                 wcross_color_prev = wcross_color;
1175
1176                 MUTATOR_CALLHOOK(UpdateCrosshair);
1177
1178                 wcross_scale *= 1 - autocvar__menu_alpha;
1179                 wcross_alpha *= 1 - autocvar__menu_alpha;
1180                 wcross_size = draw_getimagesize(wcross_name) * wcross_scale;
1181
1182                 if(wcross_scale >= 0.001 && wcross_alpha >= 0.001)
1183                 {
1184                         // crosshair rings for weapon stats
1185                         if (autocvar_crosshair_ring || autocvar_crosshair_ring_reload)
1186                         {
1187                                 // declarations and stats
1188                                 float ring_value = 0, ring_scale = 0, ring_alpha = 0, ring_inner_value = 0, ring_inner_alpha = 0;
1189                                 string ring_image = string_null, ring_inner_image = string_null;
1190                                 vector ring_rgb = '0 0 0', ring_inner_rgb = '0 0 0';
1191
1192                                 ring_scale = autocvar_crosshair_ring_size;
1193
1194                                 entity wepent = viewmodels[0]; // TODO: unhardcode
1195
1196                                 int weapon_clipload = wepent.clip_load;
1197                                 int weapon_clipsize = wepent.clip_size;
1198
1199                                 float arc_heat = wepent.arc_heat_percent;
1200                                 float vcharge = wepent.vortex_charge;
1201                                 float vchargepool = wepent.vortex_chargepool_ammo;
1202
1203                                 if(vortex_charge_movingavg == 0) // this should only happen if we have just loaded up the game
1204                                         vortex_charge_movingavg = vcharge;
1205
1206                                 // handle the values
1207                                 if (autocvar_crosshair_ring && wepent.activeweapon == WEP_VORTEX && vcharge && autocvar_crosshair_ring_vortex) // ring around crosshair representing velocity-dependent damage for the vortex
1208                                 {
1209                                         if (vchargepool || use_vortex_chargepool) {
1210                                                 use_vortex_chargepool = 1;
1211                                                 ring_inner_value = vchargepool;
1212                                         } else {
1213                                                 vortex_charge_movingavg = (1 - autocvar_crosshair_ring_vortex_currentcharge_movingavg_rate) * vortex_charge_movingavg + autocvar_crosshair_ring_vortex_currentcharge_movingavg_rate * vcharge;
1214                                                 ring_inner_value = bound(0, autocvar_crosshair_ring_vortex_currentcharge_scale * (vcharge - vortex_charge_movingavg), 1);
1215                                         }
1216
1217                                         ring_inner_alpha = autocvar_crosshair_ring_vortex_inner_alpha;
1218                                         ring_inner_rgb = vec3(autocvar_crosshair_ring_vortex_inner_color_red, autocvar_crosshair_ring_vortex_inner_color_green, autocvar_crosshair_ring_vortex_inner_color_blue);
1219                                         ring_inner_image = "gfx/crosshair_ring_inner.tga";
1220
1221                                         // draw the outer ring to show the current charge of the weapon
1222                                         ring_value = vcharge;
1223                                         ring_alpha = autocvar_crosshair_ring_vortex_alpha;
1224                                         ring_rgb = wcross_color;
1225                                         ring_image = "gfx/crosshair_ring_nexgun.tga";
1226                                 }
1227                                 else if (autocvar_crosshair_ring && wepent.activeweapon == WEP_MINE_LAYER && WEP_CVAR(minelayer, limit) && autocvar_crosshair_ring_minelayer)
1228                                 {
1229                                         ring_value = bound(0, wepent.minelayer_mines / WEP_CVAR(minelayer, limit), 1); // if you later need to use the count of bullets in another place, then add a float for it. For now, no need to.
1230                                         ring_alpha = autocvar_crosshair_ring_minelayer_alpha;
1231                                         ring_rgb = wcross_color;
1232                                         ring_image = "gfx/crosshair_ring.tga";
1233                                 }
1234                                 else if (wepent.activeweapon == WEP_HAGAR && wepent.hagar_load && autocvar_crosshair_ring_hagar)
1235                                 {
1236                                         ring_value = bound(0, wepent.hagar_load / WEP_CVAR_SEC(hagar, load_max), 1);
1237                                         ring_alpha = autocvar_crosshair_ring_hagar_alpha;
1238                                         ring_rgb = wcross_color;
1239                                         ring_image = "gfx/crosshair_ring.tga";
1240                                 }
1241                                 else if(autocvar_crosshair_ring_reload && weapon_clipsize) // forces there to be only an ammo ring
1242                                 {
1243                                         ring_value = bound(0, weapon_clipload / weapon_clipsize, 1);
1244                                         ring_scale = autocvar_crosshair_ring_reload_size;
1245                                         ring_alpha = autocvar_crosshair_ring_reload_alpha;
1246                                         ring_rgb = wcross_color;
1247
1248                                         // Note: This is to stop Taoki from complaining that the image doesn't match all potential balances.
1249                                         // if a new image for another weapon is added, add the code (and its respective file/value) here
1250                                         if ((wepent.activeweapon == WEP_RIFLE) && (weapon_clipsize == 80))
1251                                                 ring_image = "gfx/crosshair_ring_rifle.tga";
1252                                         else
1253                                                 ring_image = "gfx/crosshair_ring.tga";
1254                                 }
1255                                 else if ( autocvar_crosshair_ring && autocvar_crosshair_ring_arc && arc_heat && wepent.activeweapon == WEP_ARC )
1256                                 {
1257                                         ring_value = arc_heat;
1258                                         ring_alpha = (1-arc_heat)*autocvar_crosshair_ring_arc_cold_alpha +
1259                                                 arc_heat*autocvar_crosshair_ring_arc_hot_alpha;
1260                                         ring_rgb = (1-arc_heat)*wcross_color + arc_heat*autocvar_crosshair_ring_arc_hot_color;
1261                                         ring_image = "gfx/crosshair_ring.tga";
1262                                 }
1263
1264                                 // if in weapon switch animation, fade ring out/in
1265                                 if(autocvar_crosshair_effect_time > 0)
1266                                 {
1267                                         f = (time - wcross_name_changestarttime) / autocvar_crosshair_effect_time;
1268                                         if (f >= 1)
1269                                         {
1270                                                 wcross_ring_prev = ((ring_image) ? true : false);
1271                                         }
1272
1273                                         if(wcross_ring_prev)
1274                                         {
1275                                                 if(f < 1)
1276                                                         ring_alpha *= fabs(1 - bound(0, f, 1));
1277                                         }
1278                                         else
1279                                         {
1280                                                 if(f < 1)
1281                                                         ring_alpha *= bound(0, f, 1);
1282                                         }
1283                                 }
1284
1285                                 if (autocvar_crosshair_ring_inner && ring_inner_value) // lets draw a ring inside a ring so you can ring while you ring
1286                                         DrawCircleClippedPic(wcross_origin, wcross_size.x * ring_scale, ring_inner_image, ring_inner_value, ring_inner_rgb, wcross_alpha * ring_inner_alpha, DRAWFLAG_ADDITIVE);
1287
1288                                 if (ring_value)
1289                                         DrawCircleClippedPic(wcross_origin, wcross_size.x * ring_scale, ring_image, ring_value, ring_rgb, wcross_alpha * ring_alpha, DRAWFLAG_ADDITIVE);
1290                         }
1291
1292 #define CROSSHAIR_DO_BLUR(M,sz,wcross_name,wcross_alpha) \
1293                         MACRO_BEGIN { \
1294                                 if(wcross_blur > 0) \
1295                                 { \
1296                                         for(i = -2; i <= 2; ++i) \
1297                                         for(j = -2; j <= 2; ++j) \
1298                                         M(i,j,sz,wcross_name,wcross_alpha*0.04); \
1299                                 } \
1300                                 else \
1301                                 { \
1302                                         M(0,0,sz,wcross_name,wcross_alpha); \
1303                                 } \
1304                         } MACRO_END
1305
1306 #define CROSSHAIR_DRAW_SINGLE(i,j,sz,wcross_name,wcross_alpha) \
1307                         drawpic(wcross_origin - ('0.5 0 0' * (sz * wcross_size.x + i * wcross_blur) + '0 0.5 0' * (sz * wcross_size.y + j * wcross_blur)), wcross_name, sz * wcross_size, wcross_color, wcross_alpha, DRAWFLAG_NORMAL)
1308
1309 #define CROSSHAIR_DRAW(sz,wcross_name,wcross_alpha) \
1310                         CROSSHAIR_DO_BLUR(CROSSHAIR_DRAW_SINGLE,sz,wcross_name,wcross_alpha)
1311
1312                         if(time < wcross_name_changedonetime && wcross_name != wcross_name_goal_prev_prev && wcross_name_goal_prev_prev)
1313                         {
1314                                 f = (wcross_name_changedonetime - time) / (wcross_name_changedonetime - wcross_name_changestarttime);
1315                                 wcross_size = draw_getimagesize(wcross_name_goal_prev_prev) * wcross_scale;
1316                                 CROSSHAIR_DRAW(wcross_resolution_goal_prev_prev, wcross_name_goal_prev_prev, wcross_alpha * f * wcross_name_alpha_goal_prev_prev);
1317                                 f = 1 - f;
1318                         }
1319                         else
1320                         {
1321                                 f = 1;
1322                         }
1323                         wcross_name_alpha_goal_prev = f;
1324
1325                         wcross_size = draw_getimagesize(wcross_name) * wcross_scale;
1326                         CROSSHAIR_DRAW(wcross_resolution, wcross_name, wcross_alpha * f);
1327
1328                         if(autocvar_crosshair_dot)
1329                         {
1330                                 vector wcross_color_old;
1331                                 wcross_color_old = wcross_color;
1332
1333                                 if((autocvar_crosshair_dot_color_custom) && (autocvar_crosshair_dot_color != "0"))
1334                                         wcross_color = stov(autocvar_crosshair_dot_color);
1335
1336                                 CROSSHAIR_DRAW(wcross_resolution * autocvar_crosshair_dot_size, "gfx/crosshairdot.tga", f * autocvar_crosshair_dot_alpha);
1337                                 // FIXME why don't we use wcross_alpha here?
1338                                 wcross_color = wcross_color_old;
1339                         }
1340                 }
1341         }
1342         else
1343         {
1344                 wcross_scale_prev = 0;
1345                 wcross_alpha_prev = 0;
1346                 wcross_scale_goal_prev = 0;
1347                 wcross_alpha_goal_prev = 0;
1348                 wcross_changedonetime = 0;
1349                 if(wcross_name_goal_prev)
1350                         strunzone(wcross_name_goal_prev);
1351                 wcross_name_goal_prev = string_null;
1352                 if(wcross_name_goal_prev_prev)
1353                         strunzone(wcross_name_goal_prev_prev);
1354                 wcross_name_goal_prev_prev = string_null;
1355                 wcross_name_changestarttime = 0;
1356                 wcross_name_changedonetime = 0;
1357                 wcross_name_alpha_goal_prev = 0;
1358                 wcross_name_alpha_goal_prev_prev = 0;
1359                 wcross_resolution_goal_prev = 0;
1360                 wcross_resolution_goal_prev_prev = 0;
1361         }
1362 }
1363
1364 const int MAX_SPECIALCOMMAND = 15;
1365 vector specialcommand_slots[MAX_SPECIALCOMMAND];
1366 vector specialcommand_colors[MAX_SPECIALCOMMAND];
1367 const float SPECIALCOMMAND_SPEED = 150;
1368 const float SPECIALCOMMAND_TURNSPEED = 2;
1369 const float SPECIALCOMMAND_SIZE = 0.025;
1370 const float SPECIALCOMMAND_CHANCE = 0.35;
1371 float sc_spawntime, sc_changetime;
1372 vector sc_color = '1 1 1';
1373 void SpecialCommand()
1374 {
1375         if(!STAT(MOVEVARS_SPECIALCOMMAND))
1376                 return;
1377
1378         if(time >= sc_changetime)
1379         {
1380                 sc_changetime = time + 1;
1381                 sc_color = randomvec() * 1.5;
1382                 sc_color.x = bound(0.2, sc_color.x, 0.75);
1383                 sc_color.y = bound(0.2, sc_color.y, 0.75);
1384                 sc_color.z = bound(0.2, sc_color.z, 0.75);
1385         }
1386         drawfill('0 0 0', vec2(vid_conwidth, vid_conheight), sc_color, autocvar_hud_colorflash_alpha * bound(0.1, sc_changetime - time, 0.3), DRAWFLAG_ADDITIVE);
1387
1388         if(!precache_pic("gfx/smile"))
1389                 return; // damn party poopers
1390
1391         for(int j = MAX_SPECIALCOMMAND - 1; j >= 0; --j)
1392         {
1393                 vector slot = specialcommand_slots[j];
1394                 if(slot.y)
1395                         slot.y += SPECIALCOMMAND_SPEED * frametime;
1396                 //if(slot.z)
1397                         //slot.z = sin(SPECIALCOMMAND_TURNSPEED * M_PI * time);
1398                 if(slot.y >= vid_conheight)
1399                         slot = '0 0 0';
1400
1401                 if(slot == '0 0 0')
1402                 {
1403                         if(random() <= SPECIALCOMMAND_CHANCE && time > sc_spawntime) // low chance to spawn!
1404                         {
1405                                 slot.x = bound(0, (random() * vid_conwidth + 1), vid_conwidth);
1406                                 slot.y = 1; // start it off 0 so we can use it
1407                                 slot.z = floor(random() * Weapons_MAX);
1408                                 sc_spawntime = time + bound(0.4, random(), 0.75); // prevent spawning another one for this amount of time!
1409                                 vector newcolor = randomvec() * 2;
1410                                 newcolor.x = bound(0.4, newcolor.x, 1);
1411                                 newcolor.y = bound(0.4, newcolor.y, 1);
1412                                 newcolor.z = bound(0.4, newcolor.z, 1);
1413                                 specialcommand_colors[j] = newcolor;
1414                         }
1415                 }
1416                 else
1417                 {
1418                         vector splash_size = '0 0 0';
1419                         splash_size.x = max(vid_conwidth, vid_conheight) * SPECIALCOMMAND_SIZE;
1420                         splash_size.y = max(vid_conwidth, vid_conheight) * SPECIALCOMMAND_SIZE;
1421                         entity wep = Weapons_from(slot.z);
1422                         if(wep == WEP_Null)
1423                                 drawpic(vec2(slot), "gfx/smile", vec2(splash_size), specialcommand_colors[j], 0.95, DRAWFLAG_NORMAL);
1424                         else
1425                                 drawpic_skin(vec2(slot), wep.model2, vec2(splash_size), specialcommand_colors[j], 0.95, DRAWFLAG_NORMAL);
1426                         //drawrotpic(vec2(slot), slot.z, "gfx/smile", vec2(splash_size), vec2(splash_size) / 2, specialcommand_colors[j], 0.95, DRAWFLAG_NORMAL);
1427                 }
1428
1429                 specialcommand_slots[j] = slot;
1430         }
1431 }
1432
1433 void HUD_Draw(entity this)
1434 {
1435         // if we don't know gametype and scores yet avoid drawing the scoreboard
1436         // also in the very first frames, player state may be inconsistent so avoid drawing the hud at all
1437         // e.g. since initial player's health is 0 hud would display the hud_damage effect,
1438         // cl_deathscoreboard would show the scoreboard and so on
1439         if(!gametype)
1440                 return;
1441
1442         Hud_Dynamic_Frame();
1443
1444         if(!intermission)
1445         if (MUTATOR_CALLHOOK(HUD_Draw_overlay))
1446         {
1447                 drawfill('0 0 0', vec2(vid_conwidth, vid_conheight), M_ARGV(0, vector), autocvar_hud_colorflash_alpha * M_ARGV(1, float), DRAWFLAG_ADDITIVE);
1448         }
1449         else if(STAT(FROZEN))
1450         {
1451                 vector col = '0.25 0.90 1';
1452                 if(STAT(REVIVE_PROGRESS))
1453                         col += vec3(STAT(REVIVE_PROGRESS), -STAT(REVIVE_PROGRESS), -STAT(REVIVE_PROGRESS));
1454                 drawfill('0 0 0', vec2(vid_conwidth, vid_conheight), col, autocvar_hud_colorflash_alpha, DRAWFLAG_ADDITIVE);
1455         }
1456
1457         HUD_Scale_Enable();
1458         if(!intermission)
1459         if(STAT(NADE_TIMER) && autocvar_cl_nade_timer) // give nade top priority, as it's a matter of life and death
1460         {
1461                 vector col = '0.25 0.90 1' + vec3(STAT(NADE_TIMER), -STAT(NADE_TIMER), -STAT(NADE_TIMER));
1462                 DrawCircleClippedPic(vec2(0.5 * vid_conwidth, 0.6 * vid_conheight), 0.1 * vid_conheight, "gfx/crosshair_ring.tga", STAT(NADE_TIMER), col, autocvar_hud_colorflash_alpha, DRAWFLAG_ADDITIVE);
1463                 drawstring_aspect(eY * 0.64 * vid_conheight, ((autocvar_cl_nade_timer == 2) ? _("Nade timer") : ""), vec2(vid_conwidth, 0.025 * vid_conheight), '1 1 1', 1, DRAWFLAG_NORMAL);
1464         }
1465         else if(STAT(CAPTURE_PROGRESS))
1466         {
1467                 DrawCircleClippedPic(vec2(0.5 * vid_conwidth, 0.6 * vid_conheight), 0.1 * vid_conheight, "gfx/crosshair_ring.tga", STAT(CAPTURE_PROGRESS), '0.25 0.90 1', autocvar_hud_colorflash_alpha, DRAWFLAG_ADDITIVE);
1468                 drawstring_aspect(eY * 0.64 * vid_conheight, _("Capture progress"), vec2(vid_conwidth, 0.025 * vid_conheight), '1 1 1', 1, DRAWFLAG_NORMAL);
1469         }
1470         else if(STAT(REVIVE_PROGRESS))
1471         {
1472                 DrawCircleClippedPic(vec2(0.5 * vid_conwidth, 0.6 * vid_conheight), 0.1 * vid_conheight, "gfx/crosshair_ring.tga", STAT(REVIVE_PROGRESS), '0.25 0.90 1', autocvar_hud_colorflash_alpha, DRAWFLAG_ADDITIVE);
1473                 drawstring_aspect(eY * 0.64 * vid_conheight, _("Revival progress"), vec2(vid_conwidth, 0.025 * vid_conheight), '1 1 1', 1, DRAWFLAG_NORMAL);
1474         }
1475         HUD_Scale_Disable();
1476
1477         if(autocvar_r_letterbox == 0)
1478                 if(autocvar_viewsize < 120)
1479                 {
1480                         if(!(gametype == MAPINFO_TYPE_RACE || gametype == MAPINFO_TYPE_CTS))
1481                                 Accuracy_LoadLevels();
1482
1483                         HUD_Main();
1484                         HUD_Scale_Disable();
1485                 }
1486
1487         // crosshair goes VERY LAST
1488         SpecialCommand();
1489         UpdateDamage();
1490         HUD_Crosshair(this);
1491         HitSound();
1492 }
1493
1494 void ViewLocation_Mouse()
1495 {
1496         if(spectatee_status)
1497                 return; // don't draw it as spectator!
1498
1499         viewloc_mousepos += getmousepos() * autocvar_menu_mouse_speed;
1500         viewloc_mousepos.x = bound(0, viewloc_mousepos.x, vid_conwidth);
1501         viewloc_mousepos.y = bound(0, viewloc_mousepos.y, vid_conheight);
1502
1503         //float cursor_alpha = 1 - autocvar__menu_alpha;
1504         //draw_cursor(viewloc_mousepos, '0.5 0.5 0', "/cursor_move", '1 1 1', cursor_alpha);
1505 }
1506
1507 bool ov_enabled;
1508 float oldr_nearclip;
1509 float oldr_farclip_base;
1510 float oldr_farclip_world;
1511 float oldr_novis;
1512 float oldr_useportalculling;
1513 float oldr_useinfinitefarclip;
1514
1515 void cl_notice_run();
1516
1517 float prev_myteam;
1518 int lasthud;
1519 float vh_notice_time;
1520 void WaypointSprite_Load();
1521 void CSQC_UpdateView(entity this, float w, float h)
1522 {
1523     TC(int, w); TC(int, h);
1524         entity e;
1525         float fov;
1526         float f;
1527         vector vf_size, vf_min;
1528         float a;
1529
1530         execute_next_frame();
1531
1532         ++framecount;
1533
1534         stats_get();
1535         hud = STAT(HUD);
1536
1537         if(hud != HUD_NORMAL && lasthud == HUD_NORMAL)
1538                 vh_notice_time = time + autocvar_cl_vehicles_notify_time;
1539
1540         lasthud = hud;
1541
1542         HUD_Scale_Disable();
1543
1544         if(autocvar__hud_showbinds_reload) // menu can set this one
1545         {
1546                 db_close(binddb);
1547                 binddb = db_create();
1548                 cvar_set("_hud_showbinds_reload", "0");
1549         }
1550
1551         if(checkextension("DP_CSQC_MINFPS_QUALITY"))
1552                 view_quality = getproperty(VF_MINFPS_QUALITY);
1553         else
1554                 view_quality = 1;
1555
1556         button_attack2 = PHYS_INPUT_BUTTON_ATCK2(this);
1557         button_zoom = PHYS_INPUT_BUTTON_ZOOM(this);
1558
1559         vf_size = getpropertyvec(VF_SIZE);
1560         vf_min = getpropertyvec(VF_MIN);
1561         vid_width = vf_size.x;
1562         vid_height = vf_size.y;
1563
1564         vector reticle_pos = '0 0 0', reticle_size = '0 0 0';
1565         vector splash_pos = '0 0 0', splash_size = '0 0 0';
1566
1567         WaypointSprite_Load();
1568
1569         CSQCPlayer_SetCamera();
1570
1571         if(player_localentnum <= maxclients) // is it a client?
1572                 current_player = player_localentnum - 1;
1573         else // then player_localentnum is the vehicle I'm driving
1574                 current_player = player_localnum;
1575         myteam = entcs_GetTeam(current_player);
1576
1577         if(myteam != prev_myteam)
1578         {
1579                 myteamcolors = colormapPaletteColor(myteam, 1);
1580                 FOREACH(hud_panels, true, it.update_time = time);
1581                 prev_myteam = myteam;
1582         }
1583
1584         ticrate = STAT(MOVEVARS_TICRATE) * STAT(MOVEVARS_TIMESCALE);
1585
1586         float is_dead = (STAT(HEALTH) <= 0);
1587
1588         // FIXME do we need this hack?
1589         if(isdemo())
1590         {
1591                 // in demos, input_buttons do not work
1592                 button_zoom = (autocvar__togglezoom == "-");
1593         }
1594         else if(button_zoom
1595                 && autocvar_cl_unpress_zoom_on_death
1596                 && (spectatee_status >= 0)
1597                 && (is_dead || intermission))
1598         {
1599                 // no zoom while dead or in intermission please
1600                 localcmd("-zoom\n");
1601                 button_zoom = false;
1602         }
1603
1604         // abused multiple places below
1605         entity local_player = ((csqcplayer) ? csqcplayer : CSQCModel_server2csqc(player_localentnum - 1));
1606         if(!local_player)
1607                 local_player = this; // fall back!
1608
1609         // event chase camera
1610         if(autocvar_chase_active <= 0) // greater than 0 means it's enabled manually, and this code is skipped
1611         {
1612                 if(STAT(CAMERA_SPECTATOR))
1613                 {
1614                         if(spectatee_status > 0)
1615                         {
1616                                 if(!autocvar_chase_active)
1617                                 {
1618                                         cvar_set("chase_active", "-2");
1619                                         goto skip_eventchase_death;
1620                                 }
1621                         }
1622                         else if(autocvar_chase_active == -2)
1623                                 cvar_set("chase_active", "0");
1624
1625                         if(autocvar_chase_active == -2)
1626                                 goto skip_eventchase_death;
1627                 }
1628                 else if(autocvar_chase_active == -2)
1629                         cvar_set("chase_active", "0");
1630
1631                 float vehicle_chase = (hud != HUD_NORMAL && (autocvar_cl_eventchase_vehicle || spectatee_status > 0));
1632
1633                 float vehicle_viewdist = 0;
1634                 vector vehicle_viewofs = '0 0 0';
1635
1636                 if(vehicle_chase)
1637                 {
1638                         if(hud != HUD_BUMBLEBEE_GUN)
1639                         {
1640                                 Vehicle info = Vehicles_from(hud);
1641                                 vehicle_viewdist = info.height;
1642                                 vehicle_viewofs = info.view_ofs;
1643                         }
1644                 }
1645
1646                 if(WantEventchase(this))
1647                 {
1648                         vector current_view_origin_override = '0 0 0';
1649                         vector view_offset_override = '0 0 0';
1650                         float chase_distance_override = 0;
1651                         bool custom_eventchase = MUTATOR_CALLHOOK(CustomizeEventchase, this);
1652                         if(custom_eventchase)
1653                         {
1654                                 current_view_origin_override = M_ARGV(0, vector);
1655                                 view_offset_override = M_ARGV(1, vector);
1656                                 chase_distance_override = M_ARGV(0, float);
1657                         }
1658                         eventchase_running = true;
1659
1660                         // make special vector since we can't use view_origin (It is one frame old as of this code, it gets set later with the results this code makes.)
1661                         vector current_view_origin = (csqcplayer ? csqcplayer.origin : pmove_org);
1662                         if (custom_eventchase)
1663                                 current_view_origin = current_view_origin_override;
1664
1665                         // detect maximum viewoffset and use it
1666                         vector view_offset = autocvar_cl_eventchase_viewoffset;
1667                         if(vehicle_chase)
1668                         {
1669                                 if(vehicle_viewofs)
1670                                         view_offset = vehicle_viewofs;
1671                                 else
1672                                         view_offset = autocvar_cl_eventchase_vehicle_viewoffset;
1673                         }
1674                         if (custom_eventchase)
1675                                 view_offset = view_offset_override;
1676
1677                         if(view_offset)
1678                         {
1679                                 WarpZone_TraceLine(current_view_origin, current_view_origin + view_offset + ('0 0 1' * autocvar_cl_eventchase_maxs.z), MOVE_WORLDONLY, this);
1680                                 if(trace_fraction == 1) { current_view_origin += view_offset; }
1681                                 else { current_view_origin.z += max(0, (trace_endpos.z - current_view_origin.z) - autocvar_cl_eventchase_maxs.z); }
1682                         }
1683
1684                         // We must enable chase_active to get a third person view (weapon viewmodel hidden and own player model showing).
1685                         // Ideally, there should be another way to enable third person cameras, such as through setproperty()
1686                         // -1 enables chase_active while marking it as set by this code, and not by the user (which would be 1)
1687                         if(!autocvar_chase_active) { cvar_set("chase_active", "-1"); }
1688
1689                         // make the camera smooth back
1690                         float chase_distance = autocvar_cl_eventchase_distance;
1691                         if(vehicle_chase)
1692                         {
1693                                 if(vehicle_viewofs)
1694                                         chase_distance = vehicle_viewdist;
1695                                 else
1696                                         chase_distance = autocvar_cl_eventchase_vehicle_distance;
1697                         }
1698                         if (custom_eventchase)
1699                                 chase_distance = chase_distance_override;
1700
1701                         if(autocvar_cl_eventchase_speed && eventchase_current_distance < chase_distance)
1702                                 eventchase_current_distance += autocvar_cl_eventchase_speed * (chase_distance - eventchase_current_distance) * frametime; // slow down the further we get
1703                         else if(eventchase_current_distance != chase_distance)
1704                                 eventchase_current_distance = chase_distance;
1705
1706                         makevectors(view_angles);
1707
1708                         vector eventchase_target_origin = (current_view_origin - (v_forward * eventchase_current_distance));
1709                         WarpZone_TraceBox(current_view_origin, autocvar_cl_eventchase_mins, autocvar_cl_eventchase_maxs, eventchase_target_origin, MOVE_WORLDONLY, this);
1710
1711                         // If the boxtrace fails, revert back to line tracing.
1712                         if(!local_player.viewloc)
1713                         if(trace_startsolid)
1714                         {
1715                                 eventchase_target_origin = (current_view_origin - (v_forward * eventchase_current_distance));
1716                                 WarpZone_TraceLine(current_view_origin, eventchase_target_origin, MOVE_WORLDONLY, this);
1717                                 setproperty(VF_ORIGIN, (trace_endpos - (v_forward * autocvar_cl_eventchase_mins.z)));
1718                         }
1719                         else { setproperty(VF_ORIGIN, trace_endpos); }
1720
1721                         if(!local_player.viewloc)
1722                                 setproperty(VF_ANGLES, WarpZone_TransformVAngles(WarpZone_trace_transform, view_angles));
1723                 }
1724                 else if(autocvar_chase_active < 0) // time to disable chase_active if it was set by this code
1725                 {
1726                         eventchase_running = false;
1727                         cvar_set("chase_active", "0");
1728                         eventchase_current_distance = 0; // start from 0 next time
1729                 }
1730         }
1731         // workaround for camera stuck between player's legs when using chase_active 1
1732         // because the engine stops updating the chase_active camera when the game ends
1733         else if(intermission)
1734         {
1735                 cvar_settemp("chase_active", "-1");
1736                 eventchase_current_distance = 0;
1737         }
1738
1739         LABEL(skip_eventchase_death);
1740
1741         // do lockview after event chase camera so that it still applies whenever necessary.
1742         if(autocvar_cl_lockview || (!autocvar_hud_cursormode && (autocvar__hud_configure && spectatee_status <= 0 || intermission > 1 || QuickMenu_IsOpened())))
1743         {
1744                 setproperty(VF_ORIGIN, freeze_org);
1745                 setproperty(VF_ANGLES, freeze_ang);
1746         }
1747         else
1748         {
1749                 freeze_org = getpropertyvec(VF_ORIGIN);
1750                 freeze_ang = getpropertyvec(VF_ANGLES);
1751         }
1752
1753         WarpZone_FixView();
1754         //WarpZone_FixPMove();
1755
1756         vector ov_org = '0 0 0';
1757         vector ov_mid = '0 0 0';
1758         vector ov_worldmin = '0 0 0';
1759         vector ov_worldmax = '0 0 0';
1760         if(autocvar_cl_orthoview)
1761         {
1762                 ov_worldmin = mi_picmin;
1763                 ov_worldmax = mi_picmax;
1764
1765                 float ov_width = (ov_worldmax.x - ov_worldmin.x);
1766                 float ov_height = (ov_worldmax.y - ov_worldmin.y);
1767                 float ov_distance = (max(vid_width, vid_height) * max(ov_width, ov_height));
1768
1769                 ov_mid = ((ov_worldmax + ov_worldmin) * 0.5);
1770                 ov_org = vec3(ov_mid.x, ov_mid.y, (ov_mid.z + ov_distance));
1771
1772                 float ov_nearest = vlen(ov_org - vec3(
1773                         bound(ov_worldmin.x, ov_org.x, ov_worldmax.x),
1774                         bound(ov_worldmin.y, ov_org.y, ov_worldmax.y),
1775                         bound(ov_worldmin.z, ov_org.z, ov_worldmax.z)
1776                 ));
1777
1778                 float ov_furthest = 0;
1779                 float dist = 0;
1780
1781                 if((dist = vdist((vec3(ov_worldmin.x, ov_worldmin.y, ov_worldmin.z) - ov_org), >, ov_furthest))) { ov_furthest = dist; }
1782                 if((dist = vdist((vec3(ov_worldmax.x, ov_worldmin.y, ov_worldmin.z) - ov_org), >, ov_furthest))) { ov_furthest = dist; }
1783                 if((dist = vdist((vec3(ov_worldmin.x, ov_worldmax.y, ov_worldmin.z) - ov_org), >, ov_furthest))) { ov_furthest = dist; }
1784                 if((dist = vdist((vec3(ov_worldmin.x, ov_worldmin.y, ov_worldmax.z) - ov_org), >, ov_furthest))) { ov_furthest = dist; }
1785                 if((dist = vdist((vec3(ov_worldmax.x, ov_worldmax.y, ov_worldmin.z) - ov_org), >, ov_furthest))) { ov_furthest = dist; }
1786                 if((dist = vdist((vec3(ov_worldmin.x, ov_worldmax.y, ov_worldmax.z) - ov_org), >, ov_furthest))) { ov_furthest = dist; }
1787                 if((dist = vdist((vec3(ov_worldmax.x, ov_worldmin.y, ov_worldmax.z) - ov_org), >, ov_furthest))) { ov_furthest = dist; }
1788                 if((dist = vdist((vec3(ov_worldmax.x, ov_worldmax.y, ov_worldmax.z) - ov_org), >, ov_furthest))) { ov_furthest = dist; }
1789
1790                 if(!ov_enabled)
1791                 {
1792                         oldr_nearclip = cvar("r_nearclip");
1793                         oldr_farclip_base = cvar("r_farclip_base");
1794                         oldr_farclip_world = cvar("r_farclip_world");
1795                         oldr_novis = cvar("r_novis");
1796                         oldr_useportalculling = cvar("r_useportalculling");
1797                         oldr_useinfinitefarclip = cvar("r_useinfinitefarclip");
1798                 }
1799
1800                 cvar_settemp("r_nearclip", ftos(ov_nearest));
1801                 cvar_settemp("r_farclip_base", ftos(ov_furthest));
1802                 cvar_settemp("r_farclip_world", "0");
1803                 cvar_settemp("r_novis", "1");
1804                 cvar_settemp("r_useportalculling", "0");
1805                 cvar_settemp("r_useinfinitefarclip", "0");
1806
1807                 setproperty(VF_ORIGIN, ov_org);
1808                 setproperty(VF_ANGLES, '90 0 0');
1809
1810                 ov_enabled = true;
1811
1812                 #if 0
1813                 LOG_INFOF("OrthoView: org = %s, angles = %s, distance = %f, nearest = %f, furthest = %f",
1814                         vtos(ov_org),
1815                         vtos(getpropertyvec(VF_ANGLES)),
1816                         ov_distance,
1817                         ov_nearest,
1818                         ov_furthest);
1819                 #endif
1820         }
1821         else
1822         {
1823                 if(ov_enabled)
1824                 {
1825                         cvar_set("r_nearclip", ftos(oldr_nearclip));
1826                         cvar_set("r_farclip_base", ftos(oldr_farclip_base));
1827                         cvar_set("r_farclip_world", ftos(oldr_farclip_world));
1828                         cvar_set("r_novis", ftos(oldr_novis));
1829                         cvar_set("r_useportalculling", ftos(oldr_useportalculling));
1830                         cvar_set("r_useinfinitefarclip", ftos(oldr_useinfinitefarclip));
1831                 }
1832                 ov_enabled = false;
1833         }
1834
1835         // run viewmodel_draw before updating view_angles to the angles calculated by WarpZone_FixView
1836         // viewmodel_draw needs to use the view_angles set by the engine on every CSQC_UpdateView call
1837         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
1838                 viewmodel_draw(viewmodels[slot]);
1839
1840         // Render the Scene
1841         view_origin = getpropertyvec(VF_ORIGIN);
1842         view_angles = getpropertyvec(VF_ANGLES);
1843         makevectors(view_angles);
1844         view_forward = v_forward;
1845         view_right = v_right;
1846         view_up = v_up;
1847
1848 #ifdef BLURTEST
1849         if(time > blurtest_time0 && time < blurtest_time1)
1850         {
1851                 float r, t;
1852
1853                 t = (time - blurtest_time0) / (blurtest_time1 - blurtest_time0);
1854                 r = t * blurtest_radius;
1855                 f = 1 / (t ** blurtest_power) - 1;
1856
1857                 cvar_set("r_glsl_postprocess", "1");
1858                 cvar_set("r_glsl_postprocess_uservec1", strcat(ftos(r), " ", ftos(f), " 0 0"));
1859         }
1860         else
1861         {
1862                 cvar_set("r_glsl_postprocess", "0");
1863                 cvar_set("r_glsl_postprocess_uservec1", "0 0 0 0");
1864         }
1865 #endif
1866
1867         TargetMusic_Advance();
1868         Fog_Force();
1869
1870         if(drawtime == 0)
1871                 drawframetime = 0.01666667; // when we don't know fps yet, we assume 60fps
1872         else
1873                 drawframetime = bound(0.000001, time - drawtime, 1);
1874         drawtime = time;
1875
1876         // watch for gametype changes here...
1877         // in ParseStuffCMD the cmd isn't executed yet :/
1878         // might even be better to add the gametype to TE_CSQC_INIT...?
1879         if(!postinit)
1880                 PostInit();
1881
1882         if(intermission && !intermission_time)
1883                 intermission_time = time;
1884
1885         if(intermission && !isdemo() && !(calledhooks & HOOK_END))
1886         {
1887                 if(calledhooks & HOOK_START)
1888                 {
1889                         localcmd("\ncl_hook_gameend\n");
1890                         calledhooks |= HOOK_END;
1891                 }
1892         }
1893
1894         Announcer();
1895
1896         fov = autocvar_fov;
1897         if(fov <= 59.5)
1898         {
1899                 if(!zoomscript_caught)
1900                 {
1901                         localcmd("+button9\n");
1902                         zoomscript_caught = 1;
1903                 }
1904         }
1905         else
1906         {
1907                 if(zoomscript_caught)
1908                 {
1909                         localcmd("-button9\n");
1910                         zoomscript_caught = 0;
1911                 }
1912         }
1913
1914         ColorTranslateMode = autocvar_cl_stripcolorcodes;
1915
1916         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
1917         {
1918                 entity wepent = viewmodels[slot];
1919
1920                 if(wepent.last_switchweapon != wepent.switchweapon)
1921                 {
1922                         weapontime = time;
1923                         wepent.last_switchweapon = wepent.switchweapon;
1924                         if(slot == 0 && button_zoom && autocvar_cl_unpress_zoom_on_weapon_switch)
1925                         {
1926                                 localcmd("-zoom\n");
1927                                 button_zoom = false;
1928                         }
1929                         if(slot == 0 && autocvar_cl_unpress_attack_on_weapon_switch)
1930                         {
1931                                 localcmd("-fire\n");
1932                                 localcmd("-fire2\n");
1933                                 button_attack2 = false;
1934                         }
1935                 }
1936                 if(wepent.last_activeweapon != wepent.activeweapon)
1937                 {
1938                         wepent.last_activeweapon = wepent.activeweapon;
1939
1940                         e = wepent.activeweapon;
1941                         if(e.netname != "")
1942                                 localcmd(strcat("\ncl_hook_activeweapon ", e.netname), "\n");
1943                         else if(slot == 0)
1944                                 localcmd("\ncl_hook_activeweapon none\n");
1945                 }
1946         }
1947
1948         // ALWAYS Clear Current Scene First
1949         clearscene();
1950
1951         setproperty(VF_ORIGIN, view_origin);
1952         setproperty(VF_ANGLES, view_angles);
1953
1954         // FIXME engine bug? VF_SIZE and VF_MIN are not restored to sensible values by this
1955         setproperty(VF_SIZE, vf_size);
1956         setproperty(VF_MIN, vf_min);
1957
1958         // Assign Standard Viewflags
1959         // Draw the World (and sky)
1960         setproperty(VF_DRAWWORLD, 1);
1961
1962         // Set the console size vars
1963         vid_conwidth = autocvar_vid_conwidth;
1964         vid_conheight = autocvar_vid_conheight;
1965         vid_pixelheight = autocvar_vid_pixelheight;
1966
1967         if(autocvar_cl_orthoview) { setproperty(VF_FOV, GetOrthoviewFOV(ov_worldmin, ov_worldmax, ov_mid, ov_org)); }
1968         else if(csqcplayer.viewloc) { setproperty(VF_FOV, GetViewLocationFOV(110)); } // enforce 110 fov, so things dont look odd
1969         else { setproperty(VF_FOV, GetCurrentFov(fov)); }
1970
1971         if(camera_active) // Camera for demo playback
1972         {
1973                 if(autocvar_camera_enable)
1974                         CSQC_Demo_Camera();
1975                 else
1976                 {
1977                         cvar_set("chase_active", ftos(chase_active_backup));
1978                         cvar_set("cl_demo_mousegrab", "0");
1979                         camera_active = false;
1980                 }
1981         }
1982         else
1983         {
1984 #ifdef CAMERATEST
1985                 if(autocvar_camera_enable)
1986 #else
1987                 if(autocvar_camera_enable && isdemo())
1988 #endif
1989                 {
1990                         // Enable required Darkplaces cvars
1991                         chase_active_backup = autocvar_chase_active;
1992                         cvar_set("chase_active", "2");
1993                         cvar_set("cl_demo_mousegrab", "1");
1994                         camera_active = true;
1995                         camera_mode = false;
1996                 }
1997         }
1998
1999         // Draw the Crosshair
2000         setproperty(VF_DRAWCROSSHAIR, 0); //Make sure engine crosshairs are always hidden
2001
2002         // Draw the Engine Status Bar (the default Quake HUD)
2003         setproperty(VF_DRAWENGINESBAR, 0);
2004
2005         // Update the mouse position
2006         /*
2007            mousepos_x = vid_conwidth;
2008            mousepos_y = vid_conheight;
2009            mousepos = mousepos*0.5 + getmousepos();
2010          */
2011
2012         IL_EACH(g_drawables, it.draw, it.draw(it));
2013
2014         addentities(MASK_NORMAL | MASK_ENGINE | MASK_ENGINEVIEWMODELS);
2015         renderscene();
2016
2017         // now switch to 2D drawing mode by calling a 2D drawing function
2018         // then polygon drawing will draw as 2D stuff, and NOT get queued until the
2019         // next R_RenderScene call
2020         drawstring('0 0 0', "", '1 1 0', '1 1 1', 0, 0);
2021
2022         if(autocvar_r_fakelight >= 2 || autocvar_r_fullbright)
2023         if (!(serverflags & SERVERFLAG_ALLOW_FULLBRIGHT))
2024         {
2025                 // apply night vision effect
2026                 vector tc_00, tc_01, tc_10, tc_11;
2027                 vector rgb = '0 0 0';
2028
2029                 if(!nightvision_noise)
2030                 {
2031                         nightvision_noise = new(nightvision_noise);
2032                 }
2033                 if(!nightvision_noise2)
2034                 {
2035                         nightvision_noise2 = new(nightvision_noise2);
2036                 }
2037
2038                 // color tint in yellow
2039                 drawfill('0 0 0', autocvar_vid_conwidth * '1 0 0' + autocvar_vid_conheight * '0 1 0', '0.5 1 0.3', 1, DRAWFLAG_MODULATE);
2040
2041                 // draw BG
2042                 a = Noise_Pink(nightvision_noise, frametime * 1.5) * 0.05 + 0.15;
2043                 rgb = '1 1 1';
2044                 tc_00 = '0 0 0' + '0.2 0 0' * sin(time * 0.3) + '0 0.3 0' * cos(time * 0.7);
2045                 tc_01 = '0 2.25 0' + '0.6 0 0' * cos(time * 1.2) - '0 0.3 0' * sin(time * 2.2);
2046                 tc_10 = '1.5 0 0' - '0.2 0 0' * sin(time * 0.5) + '0 0.5 0' * cos(time * 1.7);
2047                 //tc_11 = '1 1 0' + '0.6 0 0' * sin(time * 0.6) + '0 0.3 0' * cos(time * 0.1);
2048                 tc_11 = tc_01 + tc_10 - tc_00;
2049                 R_BeginPolygon("gfx/nightvision-bg.tga", DRAWFLAG_ADDITIVE);
2050                 R_PolygonVertex('0 0 0', tc_00, rgb, a);
2051                 R_PolygonVertex(autocvar_vid_conwidth * '1 0 0', tc_10, rgb, a);
2052                 R_PolygonVertex(autocvar_vid_conwidth * '1 0 0' + autocvar_vid_conheight * '0 1 0', tc_11, rgb, a);
2053                 R_PolygonVertex(autocvar_vid_conheight * '0 1 0', tc_01, rgb, a);
2054                 R_EndPolygon();
2055
2056                 // draw FG
2057                 a = Noise_Pink(nightvision_noise2, frametime * 0.1) * 0.05 + 0.12;
2058                 rgb = '0.3 0.6 0.4' + '0.1 0.4 0.2' * Noise_White(nightvision_noise2, frametime);
2059                 tc_00 = '0 0 0' + '1 0 0' * Noise_White(nightvision_noise2, frametime) + '0 1 0' * Noise_White(nightvision_noise2, frametime);
2060                 tc_01 = tc_00 + '0 3 0' * (1 + Noise_White(nightvision_noise2, frametime) * 0.2);
2061                 tc_10 = tc_00 + '2 0 0' * (1 + Noise_White(nightvision_noise2, frametime) * 0.3);
2062                 tc_11 = tc_01 + tc_10 - tc_00;
2063                 R_BeginPolygon("gfx/nightvision-fg.tga", DRAWFLAG_ADDITIVE);
2064                 R_PolygonVertex('0 0 0', tc_00, rgb, a);
2065                 R_PolygonVertex(autocvar_vid_conwidth * '1 0 0', tc_10, rgb, a);
2066                 R_PolygonVertex(autocvar_vid_conwidth * '1 0 0' + autocvar_vid_conheight * '0 1 0', tc_11, rgb, a);
2067                 R_PolygonVertex(autocvar_vid_conheight * '0 1 0', tc_01, rgb, a);
2068                 R_EndPolygon();
2069         }
2070
2071         if(autocvar_cl_reticle)
2072         {
2073                 string reticle_image = string_null;
2074                 bool wep_zoomed = false;
2075                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
2076                 {
2077                         entity wepe = viewmodels[slot];
2078                         Weapon wep = wepe.activeweapon;
2079                         if(wep != WEP_Null && wep.wr_zoom)
2080                         {
2081                                 bool do_zoom = wep.wr_zoom(wep, NULL);
2082                                 if(!reticle_image && wep.w_reticle && wep.w_reticle != "")
2083                                         reticle_image = wep.w_reticle;
2084                                 wep_zoomed += do_zoom;
2085                         }
2086                 }
2087                 // Draw the aiming reticle for weapons that use it
2088                 // reticle_type is changed to the item we are zooming / aiming with, to decide which reticle to use
2089                 // It must be a persisted float for fading out to work properly (you let go of the zoom button for
2090                 // the view to go back to normal, so reticle_type would become 0 as we fade out)
2091                 if(spectatee_status || is_dead || hud != HUD_NORMAL || local_player.viewloc)
2092                 {
2093                         // no zoom reticle while dead
2094                         reticle_type = 0;
2095                 }
2096                 else if(wep_zoomed && autocvar_cl_reticle_weapon)
2097                 {
2098                         if(reticle_image) { reticle_type = 2; }
2099                         else { reticle_type = 0; }
2100                 }
2101                 else if(button_zoom || zoomscript_caught)
2102                 {
2103                         // normal zoom
2104                         reticle_type = 1;
2105                 }
2106
2107                 if(reticle_type)
2108                 {
2109                         if(autocvar_cl_reticle_stretch)
2110                         {
2111                                 reticle_size.x = vid_conwidth;
2112                                 reticle_size.y = vid_conheight;
2113                                 reticle_pos.x = 0;
2114                                 reticle_pos.y = 0;
2115                         }
2116                         else
2117                         {
2118                                 reticle_size.x = max(vid_conwidth, vid_conheight);
2119                                 reticle_size.y = max(vid_conwidth, vid_conheight);
2120                                 reticle_pos.x = (vid_conwidth - reticle_size.x) / 2;
2121                                 reticle_pos.y = (vid_conheight - reticle_size.y) / 2;
2122                         }
2123
2124                         if(zoomscript_caught)
2125                                 f = 1;
2126                         else
2127                                 f = current_zoomfraction;
2128
2129                         if(f)
2130                         {
2131                                 switch(reticle_type)
2132                                 {
2133                                         case 1: drawpic(reticle_pos, "gfx/reticle_normal", reticle_size, '1 1 1', f * autocvar_cl_reticle_normal_alpha, DRAWFLAG_NORMAL); break;
2134                                         case 2: if(reticle_image) drawpic(reticle_pos, reticle_image, reticle_size, '1 1 1', f * autocvar_cl_reticle_weapon_alpha, DRAWFLAG_NORMAL); break;
2135                                 }
2136                         }
2137                 }
2138         }
2139         else
2140         {
2141                 if(reticle_type != 0) { reticle_type = 0; }
2142         }
2143
2144
2145         // improved polyblend
2146         if(autocvar_hud_contents && !MUTATOR_CALLHOOK(HUD_Contents))
2147         {
2148                 float contentalpha_temp, incontent, liquidalpha, contentfadetime;
2149                 vector liquidcolor;
2150
2151                 switch(pointcontents(view_origin))
2152                 {
2153                         case CONTENT_WATER:
2154                                 liquidalpha = autocvar_hud_contents_water_alpha;
2155                                 liquidcolor = stov(autocvar_hud_contents_water_color);
2156                                 incontent = 1;
2157                                 break;
2158
2159                         case CONTENT_LAVA:
2160                                 liquidalpha = autocvar_hud_contents_lava_alpha;
2161                                 liquidcolor = stov(autocvar_hud_contents_lava_color);
2162                                 incontent = 1;
2163                                 break;
2164
2165                         case CONTENT_SLIME:
2166                                 liquidalpha = autocvar_hud_contents_slime_alpha;
2167                                 liquidcolor = stov(autocvar_hud_contents_slime_color);
2168                                 incontent = 1;
2169                                 break;
2170
2171                         default:
2172                                 liquidalpha = 0;
2173                                 liquidcolor = '0 0 0';
2174                                 incontent = 0;
2175                                 break;
2176                 }
2177
2178                 if(incontent) // fade in/out at different speeds so you can do e.g. instant fade when entering water and slow when leaving it.
2179                 { // also lets delcare previous values for blending properties, this way it isn't reset until after you have entered a different content
2180                         contentfadetime = autocvar_hud_contents_fadeintime;
2181                         liquidalpha_prev = liquidalpha;
2182                         liquidcolor_prev = liquidcolor;
2183                 }
2184                 else
2185                         contentfadetime = autocvar_hud_contents_fadeouttime;
2186
2187                 contentalpha_temp = bound(0, drawframetime / max(0.0001, contentfadetime), 1);
2188                 contentavgalpha = contentavgalpha * (1 - contentalpha_temp) + incontent * contentalpha_temp;
2189
2190                 if(contentavgalpha)
2191                         drawfill('0 0 0', vec2(vid_conwidth, vid_conheight), liquidcolor_prev, contentavgalpha * liquidalpha_prev, DRAWFLAG_NORMAL);
2192
2193                 if(autocvar_hud_postprocessing)
2194                 {
2195                         if(autocvar_hud_contents_blur && contentavgalpha)
2196                         {
2197                                 content_blurpostprocess.x = 1;
2198                                 content_blurpostprocess.y = contentavgalpha * autocvar_hud_contents_blur;
2199                                 content_blurpostprocess.z = contentavgalpha * autocvar_hud_contents_blur_alpha;
2200                         }
2201                         else
2202                         {
2203                                 content_blurpostprocess.x = 0;
2204                                 content_blurpostprocess.y = 0;
2205                                 content_blurpostprocess.z = 0;
2206                         }
2207                 }
2208         }
2209
2210         if(autocvar_hud_damage && !STAT(FROZEN))
2211         {
2212                 splash_size.x = max(vid_conwidth, vid_conheight);
2213                 splash_size.y = max(vid_conwidth, vid_conheight);
2214                 splash_pos.x = (vid_conwidth - splash_size.x) / 2;
2215                 splash_pos.y = (vid_conheight - splash_size.y) / 2;
2216
2217                 float myhealth_flash_temp;
2218                 myhealth = STAT(HEALTH);
2219
2220                 // fade out
2221                 myhealth_flash = max(0, myhealth_flash - autocvar_hud_damage_fade_rate * frametime);
2222                 // add new damage
2223                 myhealth_flash = bound(0, myhealth_flash + dmg_take * autocvar_hud_damage_factor, autocvar_hud_damage_maxalpha);
2224
2225                 float pain_threshold, pain_threshold_lower, pain_threshold_lower_health;
2226                 pain_threshold = autocvar_hud_damage_pain_threshold;
2227                 pain_threshold_lower = autocvar_hud_damage_pain_threshold_lower;
2228                 pain_threshold_lower_health = autocvar_hud_damage_pain_threshold_lower_health;
2229
2230                 if(pain_threshold_lower && myhealth < pain_threshold_lower_health)
2231                 {
2232                         pain_threshold = pain_threshold - max(autocvar_hud_damage_pain_threshold_pulsating_min, fabs(sin(M_PI * time / autocvar_hud_damage_pain_threshold_pulsating_period))) * pain_threshold_lower * (1 - max(0, myhealth)/pain_threshold_lower_health);
2233                 }
2234
2235                 myhealth_flash_temp = bound(0, myhealth_flash - pain_threshold, 1);
2236
2237                 if(myhealth_prev < 1)
2238                 {
2239                         if(myhealth >= 1)
2240                         {
2241                                 myhealth_flash = 0; // just spawned, clear the flash immediately
2242                                 myhealth_flash_temp = 0;
2243                         }
2244                         else
2245                         {
2246                                 myhealth_flash += autocvar_hud_damage_fade_rate * frametime; // dead
2247                         }
2248                 }
2249
2250                 if(spectatee_status == -1 || intermission)
2251                 {
2252                         myhealth_flash = 0; // observing, or match ended
2253                         myhealth_flash_temp = 0;
2254                 }
2255
2256                 myhealth_prev = myhealth;
2257
2258                 // IDEA: change damage color/picture based on player model for robot/alien species?
2259                 // pro: matches model better
2260                 // contra: it's not red because blood is red, but because red is an alarming color, so red should stay
2261                 // maybe different reddish pics?
2262                 if(autocvar_cl_gentle_damage || autocvar_cl_gentle)
2263                 {
2264                         if(autocvar_cl_gentle_damage == 2)
2265                         {
2266                                 if(myhealth_flash < pain_threshold) // only randomize when the flash is gone
2267                                         myhealth_gentlergb = randomvec();
2268                         }
2269                         else
2270                                 myhealth_gentlergb = stov(autocvar_hud_damage_gentle_color);
2271
2272                         if(myhealth_flash_temp > 0)
2273                                 drawfill('0 0 0', vec2(vid_conwidth, vid_conheight), myhealth_gentlergb, autocvar_hud_damage_gentle_alpha_multiplier * bound(0, myhealth_flash_temp, 1) * autocvar_hud_damage, DRAWFLAG_NORMAL);
2274                 }
2275                 else if(myhealth_flash_temp > 0)
2276                         drawpic(splash_pos, "gfx/blood", splash_size, stov(autocvar_hud_damage_color), bound(0, myhealth_flash_temp, 1) * autocvar_hud_damage, DRAWFLAG_NORMAL);
2277
2278                 if(autocvar_hud_postprocessing) // we still need to set this anyway even when chase_active is set, this way it doesn't get stuck on.
2279                 {
2280                         if(autocvar_hud_damage_blur && myhealth_flash_temp)
2281                         {
2282                                 damage_blurpostprocess.x = 1;
2283                                 damage_blurpostprocess.y = bound(0, myhealth_flash_temp, 1) * autocvar_hud_damage_blur;
2284                                 damage_blurpostprocess.z = bound(0, myhealth_flash_temp, 1) * autocvar_hud_damage_blur_alpha;
2285                         }
2286                         else
2287                         {
2288                                 damage_blurpostprocess.x = 0;
2289                                 damage_blurpostprocess.y = 0;
2290                                 damage_blurpostprocess.z = 0;
2291                         }
2292                 }
2293         }
2294
2295         float e1 = (autocvar_hud_postprocessing_maxbluralpha != 0);
2296         float e2 = (autocvar_hud_powerup != 0);
2297         if(autocvar_hud_postprocessing && (e1 || e2)) // TODO: Remove this code and re-do the postprocess handling in the engine, where it properly belongs.
2298         {
2299                 // enable or disable rendering types if they are used or not
2300                 if(cvar("r_glsl_postprocess_uservec1_enable") != e1) { cvar_set("r_glsl_postprocess_uservec1_enable", ftos(e1)); }
2301                 if(cvar("r_glsl_postprocess_uservec2_enable") != e2) { cvar_set("r_glsl_postprocess_uservec2_enable", ftos(e2)); }
2302
2303                 // blur postprocess handling done first (used by hud_damage and hud_contents)
2304                 if((damage_blurpostprocess.x || content_blurpostprocess.x))
2305                 {
2306                         float blurradius = bound(0, damage_blurpostprocess.y + content_blurpostprocess.y, autocvar_hud_postprocessing_maxblurradius);
2307                         float bluralpha = bound(0, damage_blurpostprocess.z + content_blurpostprocess.z, autocvar_hud_postprocessing_maxbluralpha);
2308                         if(blurradius != old_blurradius || bluralpha != old_bluralpha) // reduce cvar_set spam as much as possible
2309                         {
2310                                 cvar_set("r_glsl_postprocess_uservec1", strcat(ftos(blurradius), " ", ftos(bluralpha), " 0 0"));
2311                                 old_blurradius = blurradius;
2312                                 old_bluralpha = bluralpha;
2313                         }
2314                 }
2315                 else if(cvar_string("r_glsl_postprocess_uservec1") != "0 0 0 0") // reduce cvar_set spam as much as possible
2316                 {
2317                         cvar_set("r_glsl_postprocess_uservec1", "0 0 0 0");
2318                         old_blurradius = 0;
2319                         old_bluralpha = 0;
2320                 }
2321
2322                 // edge detection postprocess handling done second (used by hud_powerup)
2323                 float sharpen_intensity = 0, strength_finished = STAT(STRENGTH_FINISHED), invincible_finished = STAT(INVINCIBLE_FINISHED);
2324                 if (strength_finished - time > 0) { sharpen_intensity += (strength_finished - time); }
2325                 if (invincible_finished - time > 0) { sharpen_intensity += (invincible_finished - time); }
2326
2327                 sharpen_intensity = bound(0, ((STAT(HEALTH) > 0) ? sharpen_intensity : 0), 5); // Check to see if player is alive (if not, set 0) - also bound to fade out starting at 5 seconds.
2328
2329                 if(autocvar_hud_powerup && sharpen_intensity > 0)
2330                 {
2331                         if(sharpen_intensity != old_sharpen_intensity) // reduce cvar_set spam as much as possible
2332                         {
2333                                 cvar_set("r_glsl_postprocess_uservec2", strcat(ftos((sharpen_intensity / 5) * autocvar_hud_powerup), " ", ftos(-sharpen_intensity * autocvar_hud_powerup), " 0 0"));
2334                                 old_sharpen_intensity = sharpen_intensity;
2335                         }
2336                 }
2337                 else if(cvar_string("r_glsl_postprocess_uservec2") != "0 0 0 0") // reduce cvar_set spam as much as possible
2338                 {
2339                         cvar_set("r_glsl_postprocess_uservec2", "0 0 0 0");
2340                         old_sharpen_intensity = 0;
2341                 }
2342
2343                 if(cvar("r_glsl_postprocess") == 0)
2344                         cvar_set("r_glsl_postprocess", "2");
2345         }
2346         else if(cvar("r_glsl_postprocess") == 2)
2347                 cvar_set("r_glsl_postprocess", "0");
2348
2349         /*if(gametype == MAPINFO_TYPE_CTF)
2350           {
2351           ctf_view();
2352           } else */
2353
2354         // draw 2D entities
2355         IL_EACH(g_drawables_2d, it.draw2d, it.draw2d(it));
2356         Draw_ShowNames_All();
2357 #if ENABLE_DEBUGDRAW
2358         Debug_Draw();
2359 #endif
2360
2361         scoreboard_active = Scoreboard_WouldDraw();
2362
2363         HUD_Draw(this); // this parameter for deep vehicle function
2364
2365         if(NextFrameCommand)
2366         {
2367                 localcmd("\n", NextFrameCommand, "\n");
2368                 NextFrameCommand = string_null;
2369         }
2370
2371         // we must do this check AFTER a frame was rendered, or it won't work
2372         if(cs_project_is_b0rked == 0)
2373         {
2374                 string w0, h0;
2375                 w0 = ftos(autocvar_vid_conwidth);
2376                 h0 = ftos(autocvar_vid_conheight);
2377                 //setproperty(VF_VIEWPORT, '0 0 0', '640 480 0');
2378                 //setproperty(VF_FOV, '90 90 0');
2379                 setproperty(VF_ORIGIN, '0 0 0');
2380                 setproperty(VF_ANGLES, '0 0 0');
2381                 setproperty(VF_PERSPECTIVE, 1);
2382                 makevectors('0 0 0');
2383                 vector v1, v2;
2384                 cvar_set("vid_conwidth", "800");
2385                 cvar_set("vid_conheight", "600");
2386                 v1 = cs_project(v_forward);
2387                 cvar_set("vid_conwidth", "640");
2388                 cvar_set("vid_conheight", "480");
2389                 v2 = cs_project(v_forward);
2390                 if(v1 == v2)
2391                         cs_project_is_b0rked = 1;
2392                 else
2393                         cs_project_is_b0rked = -1;
2394                 cvar_set("vid_conwidth", w0);
2395                 cvar_set("vid_conheight", h0);
2396         }
2397
2398         if(autocvar__hud_configure)
2399                 HUD_Panel_Mouse();
2400         else if (HUD_MinigameMenu_IsOpened() || active_minigame)
2401                 HUD_Minigame_Mouse();
2402         else if(QuickMenu_IsOpened())
2403                 QuickMenu_Mouse();
2404         else if(local_player.viewloc && (local_player.viewloc.spawnflags & VIEWLOC_FREEAIM))
2405                 ViewLocation_Mouse(); // NOTE: doesn't use cursormode
2406         else
2407                 HUD_Radar_Mouse();
2408
2409         cl_notice_run();
2410         unpause_update();
2411         Net_Flush();
2412
2413         // let's reset the view back to normal for the end
2414         setproperty(VF_MIN, '0 0 0');
2415         setproperty(VF_SIZE, '1 0 0' * w + '0 1 0' * h);
2416
2417         IL_ENDFRAME();
2418 }
2419
2420
2421 // following vectors must be global to allow seamless switching between camera modes
2422 vector camera_offset, current_camera_offset, mouse_angles, current_angles, current_origin, current_position;
2423 void CSQC_Demo_Camera()
2424 {
2425         float speed, attenuation, dimensions;
2426         vector tmp, delta;
2427
2428         if( autocvar_camera_reset || !camera_mode )
2429         {
2430                 camera_offset = '0 0 0';
2431                 current_angles = '0 0 0';
2432                 camera_direction = '0 0 0';
2433                 camera_offset.z += 30;
2434                 camera_offset.x += 30 * -cos(current_angles.y * DEG2RAD);
2435                 camera_offset.y += 30 * -sin(current_angles.y * DEG2RAD);
2436                 current_origin = view_origin;
2437                 current_camera_offset  = camera_offset;
2438                 cvar_set("camera_reset", "0");
2439                 camera_mode = CAMERA_CHASE;
2440         }
2441
2442         // Camera angles
2443         if( camera_roll )
2444                 mouse_angles.z += camera_roll * autocvar_camera_speed_roll;
2445
2446         if(autocvar_camera_look_player)
2447         {
2448                 vector dir;
2449                 float n;
2450
2451                 dir = normalize(view_origin - current_position);
2452                 n = mouse_angles.z;
2453                 mouse_angles = vectoangles(dir);
2454                 mouse_angles.x = mouse_angles.x * -1;
2455                 mouse_angles.z = n;
2456         }
2457         else
2458         {
2459                 tmp = getmousepos() * 0.1;
2460                 if(vdist(tmp, >, autocvar_camera_mouse_threshold))
2461                 {
2462                         mouse_angles.x += tmp.y * cos(mouse_angles.z * DEG2RAD) + (tmp.x * sin(mouse_angles.z * DEG2RAD));
2463                         mouse_angles.y -= tmp.x * cos(mouse_angles.z * DEG2RAD) + (tmp.y * -sin(mouse_angles.z * DEG2RAD));
2464                 }
2465         }
2466
2467         while (mouse_angles.x < -180) mouse_angles.x = mouse_angles.x + 360;
2468         while (mouse_angles.x > 180) mouse_angles.x = mouse_angles.x - 360;
2469         while (mouse_angles.y < -180) mouse_angles.y = mouse_angles.y + 360;
2470         while (mouse_angles.y > 180) mouse_angles.y = mouse_angles.y - 360;
2471
2472         // Fix difference when angles don't have the same sign
2473         delta = '0 0 0';
2474         if(mouse_angles.y < -60 && current_angles.y > 60)
2475                 delta = '0 360 0';
2476         if(mouse_angles.y > 60 && current_angles.y < -60)
2477                 delta = '0 -360 0';
2478
2479         if(autocvar_camera_look_player)
2480                 attenuation = autocvar_camera_look_attenuation;
2481         else
2482                 attenuation = autocvar_camera_speed_attenuation;
2483
2484         attenuation = 1 / max(1, attenuation);
2485         current_angles += (mouse_angles - current_angles + delta) * attenuation;
2486
2487         while (current_angles.x < -180) current_angles.x = current_angles.x + 360;
2488         while (current_angles.x > 180) current_angles.x = current_angles.x - 360;
2489         while (current_angles.y < -180) current_angles.y = current_angles.y + 360;
2490         while (current_angles.y > 180) current_angles.y = current_angles.y - 360;
2491
2492         // Camera position
2493         tmp = '0 0 0';
2494         dimensions = 0;
2495
2496         if( camera_direction.x )
2497         {
2498                 tmp.x = camera_direction.x * cos(current_angles.y * DEG2RAD);
2499                 tmp.y = camera_direction.x * sin(current_angles.y * DEG2RAD);
2500                 if( autocvar_camera_forward_follows && !autocvar_camera_look_player )
2501                         tmp.z = camera_direction.x * -sin(current_angles.x * DEG2RAD);
2502                 ++dimensions;
2503         }
2504
2505         if( camera_direction.y )
2506         {
2507                 tmp.x += camera_direction.y * -sin(current_angles.y * DEG2RAD);
2508                 tmp.y += camera_direction.y * cos(current_angles.y * DEG2RAD) * cos(current_angles.z * DEG2RAD);
2509                 tmp.z += camera_direction.y * sin(current_angles.z * DEG2RAD);
2510                 ++dimensions;
2511         }
2512
2513         if( camera_direction.z )
2514         {
2515                 tmp.z += camera_direction.z * cos(current_angles.z * DEG2RAD);
2516                 ++dimensions;
2517         }
2518
2519         if(autocvar_camera_free)
2520                 speed = autocvar_camera_speed_free;
2521         else
2522                 speed = autocvar_camera_speed_chase;
2523
2524         if(dimensions)
2525         {
2526                 speed = speed * sqrt(1 / dimensions);
2527                 camera_offset += tmp * speed;
2528         }
2529
2530         current_camera_offset += (camera_offset - current_camera_offset) * attenuation;
2531
2532         // Camera modes
2533         if( autocvar_camera_free )
2534         {
2535                 if ( camera_mode == CAMERA_CHASE )
2536                 {
2537                         current_camera_offset = current_origin + current_camera_offset;
2538                         camera_offset = current_origin + camera_offset;
2539                 }
2540
2541                 camera_mode = CAMERA_FREE;
2542                 current_position = current_camera_offset;
2543         }
2544         else
2545         {
2546                 if ( camera_mode == CAMERA_FREE )
2547                 {
2548                         current_origin = view_origin;
2549                         camera_offset = camera_offset - current_origin;
2550                         current_camera_offset = current_camera_offset - current_origin;
2551                 }
2552
2553                 camera_mode = CAMERA_CHASE;
2554
2555                 if(autocvar_camera_chase_smoothly)
2556                         current_origin += (view_origin - current_origin) * attenuation;
2557                 else
2558                         current_origin = view_origin;
2559
2560                 current_position = current_origin + current_camera_offset;
2561         }
2562
2563         setproperty(VF_ANGLES, current_angles);
2564         setproperty(VF_ORIGIN, current_position);
2565 }