qcsrc/client/view.qc

   1 #include "view.qh"
   2
   3 #include "announcer.qh"
   4 #include "hud/_mod.qh"
   5 #include "mapvoting.qh"
   6 #include "shownames.qh"
   7 #include "hud/panel/scoreboard.qh"
   8 #include "hud/panel/quickmenu.qh"
   9
  10 #include "mutators/events.qh"
  11
  12 #include <common/animdecide.qh>
  13 #include <common/ent_cs.qh>
  14 #include <common/anim.qh>
  15 #include <common/constants.qh>
  16 #include <common/debug.qh>
  17 #include <common/mapinfo.qh>
  18 #include <common/gamemodes/_mod.qh>
  19 #include <common/physics/player.qh>
  20 #include <common/stats.qh>
  21 #include <common/triggers/target/music.qh>
  22 #include <common/teams.qh>
  23
  24 #include <common/vehicles/all.qh>
  25 #include <common/weapons/_all.qh>
  26 #include <common/viewloc.qh>
  27 #include <common/minigames/cl_minigames.qh>
  28 #include <common/minigames/cl_minigames_hud.qh>
  29
  30 #include <lib/csqcmodel/cl_player.qh>
  31 #include <lib/csqcmodel/cl_model.qh>
  32 #include "csqcmodel_hooks.qh"
  33
  34 #include <lib/warpzone/client.qh>
  35 #include <lib/warpzone/common.qh>
  36
  37 #define EFMASK_CHEAP (EF_ADDITIVE | EF_DOUBLESIDED | EF_FULLBRIGHT | EF_NODEPTHTEST | EF_NODRAW | EF_NOSHADOW | EF_SELECTABLE | EF_TELEPORT_BIT)
  38
  39 float autocvar_cl_viewmodel_scale;
  40
  41 bool autocvar_cl_bobmodel;
  42 float autocvar_cl_bobmodel_speed;
  43 float autocvar_cl_bobmodel_side;
  44 float autocvar_cl_bobmodel_up;
  45
  46 float autocvar_cl_followmodel;
  47 float autocvar_cl_followmodel_speed = 0.3;
  48 float autocvar_cl_followmodel_limit = 135;
  49 float autocvar_cl_followmodel_velocity_lowpass = 0.05;
  50 float autocvar_cl_followmodel_highpass = 0.05;
  51 float autocvar_cl_followmodel_lowpass = 0.03;
  52 bool autocvar_cl_followmodel_velocity_absolute;
  53
  54 float autocvar_cl_leanmodel;
  55 float autocvar_cl_leanmodel_speed = 0.3;
  56 float autocvar_cl_leanmodel_limit = 30;
  57 float autocvar_cl_leanmodel_highpass1 = 0.2;
  58 float autocvar_cl_leanmodel_highpass = 0.2;
  59 float autocvar_cl_leanmodel_lowpass = 0.05;
  60
  61 #define avg_factor(avg_time) (1 - exp(-frametime / max(0.001, avg_time)))
  62 #define lowpass(value, frac, ref_store, ret) MACRO_BEGIN \
  63 { \
  64         ret = ref_store = ref_store * (1 - frac) + (value) * frac; \
  65 } MACRO_END
  66
  67 #define lowpass_limited(value, frac, limit, ref_store, ret) MACRO_BEGIN \
  68 { \
  69         float __ignore; lowpass(value, frac, ref_store, __ignore); \
  70         ret = ref_store = bound((value) - (limit), ref_store, (value) + (limit)); \
  71 } MACRO_END
  72
  73 #define highpass(value, frac, ref_store, ret) MACRO_BEGIN \
  74 { \
  75         float __f = 0; lowpass(value, frac, ref_store, __f); \
  76         ret = (value) - __f; \
  77 } MACRO_END
  78
  79 #define highpass_limited(value, frac, limit, ref_store, ret) MACRO_BEGIN \
  80 { \
  81         float __f = 0; lowpass_limited(value, frac, limit, ref_store, __f); \
  82         ret = (value) - __f; \
  83 } MACRO_END
  84
  85 #define lowpass2(value, frac, ref_store, ref_out) MACRO_BEGIN \
  86 { \
  87         lowpass(value.x, frac, ref_store.x, ref_out.x); \
  88         lowpass(value.y, frac, ref_store.y, ref_out.y); \
  89 } MACRO_END
  90
  91 #define highpass2(value, frac, ref_store, ref_out) MACRO_BEGIN \
  92 { \
  93         highpass(value.x, frac, ref_store.x, ref_out.x); \
  94         highpass(value.y, frac, ref_store.y, ref_out.y); \
  95 } MACRO_END
  96
  97 #define highpass2_limited(value, frac, limit, ref_store, ref_out) MACRO_BEGIN \
  98 { \
  99         highpass_limited(value.x, frac, limit, ref_store.x, ref_out.x); \
 100         highpass_limited(value.y, frac, limit, ref_store.y, ref_out.y); \
 101 } MACRO_END
 102
 103 #define lowpass3(value, frac, ref_store, ref_out) MACRO_BEGIN \
 104 { \
 105         lowpass(value.x, frac, ref_store.x, ref_out.x); \
 106         lowpass(value.y, frac, ref_store.y, ref_out.y); \
 107         lowpass(value.z, frac, ref_store.z, ref_out.z); \
 108 } MACRO_END
 109
 110 #define highpass3(value, frac, ref_store, ref_out) MACRO_BEGIN \
 111 { \
 112         highpass(value.x, frac, ref_store.x, ref_out.x); \
 113         highpass(value.y, frac, ref_store.y, ref_out.y); \
 114         highpass(value.z, frac, ref_store.z, ref_out.z); \
 115 } MACRO_END
 116
 117 void calc_followmodel_ofs(entity view)
 118 {
 119         if(cl_followmodel_time == time)
 120                 return; // cl_followmodel_ofs already calculated for this frame
 121
 122         float frac;
 123         vector gunorg = '0 0 0';
 124         static vector vel_average;
 125         static vector gunorg_prev = '0 0 0';
 126         static vector gunorg_adjustment_highpass;
 127         static vector gunorg_adjustment_lowpass;
 128
 129         vector vel;
 130         if (autocvar_cl_followmodel_velocity_absolute)
 131                 vel = view.velocity;
 132         else
 133         {
 134                 vector forward = '0 0 0', right = '0 0 0', up = '0 0 0';
 135                 MAKEVECTORS(makevectors, view_angles, forward, right, up);
 136                 vel.x = view.velocity * forward;
 137                 vel.y = view.velocity * right * -1;
 138                 vel.z = view.velocity * up;
 139         }
 140
 141         vel.x = bound(vel_average.x - autocvar_cl_followmodel_limit, vel.x, vel_average.x + autocvar_cl_followmodel_limit);
 142         vel.y = bound(vel_average.y - autocvar_cl_followmodel_limit, vel.y, vel_average.y + autocvar_cl_followmodel_limit);
 143         vel.z = bound(vel_average.z - autocvar_cl_followmodel_limit, vel.z, vel_average.z + autocvar_cl_followmodel_limit);
 144
 145         frac = avg_factor(autocvar_cl_followmodel_velocity_lowpass);
 146         lowpass3(vel, frac, vel_average, gunorg);
 147
 148         gunorg *= -autocvar_cl_followmodel_speed * 0.042;
 149
 150         // perform highpass/lowpass on the adjustment vectors (turning velocity into acceleration!)
 151         // trick: we must do the lowpass LAST, so the lowpass vector IS the final vector!
 152         frac = avg_factor(autocvar_cl_followmodel_highpass);
 153         highpass3(gunorg, frac, gunorg_adjustment_highpass, gunorg);
 154         frac = avg_factor(autocvar_cl_followmodel_lowpass);
 155         lowpass3(gunorg, frac, gunorg_adjustment_lowpass, gunorg);
 156
 157         if (autocvar_cl_followmodel_velocity_absolute)
 158         {
 159                 vector fixed_gunorg;
 160                 vector forward = '0 0 0', right = '0 0 0', up = '0 0 0';
 161                 MAKEVECTORS(makevectors, view_angles, forward, right, up);
 162                 fixed_gunorg.x = gunorg * forward;
 163                 fixed_gunorg.y = gunorg * right * -1;
 164                 fixed_gunorg.z = gunorg * up;
 165                 gunorg = fixed_gunorg;
 166         }
 167
 168         cl_followmodel_ofs = gunorg;
 169         cl_followmodel_time = time;
 170 }
 171
 172 vector leanmodel_ofs(entity view)
 173 {
 174         float frac;
 175         vector gunangles = '0 0 0';
 176         static vector gunangles_prev = '0 0 0';
 177         static vector gunangles_highpass = '0 0 0';
 178         static vector gunangles_adjustment_highpass;
 179         static vector gunangles_adjustment_lowpass;
 180
 181         if (view.csqcmodel_teleported)
 182                 gunangles_prev = view_angles;
 183
 184         // in the highpass, we _store_ the DIFFERENCE to the actual view angles...
 185         gunangles_highpass += gunangles_prev;
 186         PITCH(gunangles_highpass) += 360 * floor((PITCH(view_angles) - PITCH(gunangles_highpass)) / 360 + 0.5);
 187         YAW(gunangles_highpass) += 360 * floor((YAW(view_angles) - YAW(gunangles_highpass)) / 360 + 0.5);
 188         ROLL(gunangles_highpass) += 360 * floor((ROLL(view_angles) - ROLL(gunangles_highpass)) / 360 + 0.5);
 189         frac = avg_factor(autocvar_cl_leanmodel_highpass1);
 190         highpass2_limited(view_angles, frac, autocvar_cl_leanmodel_limit, gunangles_highpass, gunangles);
 191         gunangles_prev = view_angles;
 192         gunangles_highpass -= gunangles_prev;
 193
 194         PITCH(gunangles) *= -autocvar_cl_leanmodel_speed;
 195         YAW(gunangles) *= -autocvar_cl_leanmodel_speed;
 196
 197         // we assume here: PITCH = 0, YAW = 1, ROLL = 2
 198         frac = avg_factor(autocvar_cl_leanmodel_highpass);
 199         highpass2(gunangles, frac, gunangles_adjustment_highpass, gunangles);
 200         frac = avg_factor(autocvar_cl_leanmodel_lowpass);
 201         lowpass2(gunangles, frac, gunangles_adjustment_lowpass, gunangles);
 202
 203         gunangles.x = -gunangles.x; // pitch was inverted, now that actually matters
 204
 205         return gunangles;
 206 }
 207
 208 vector bobmodel_ofs(entity view)
 209 {
 210         bool clonground = !(view.anim_implicit_state & ANIMIMPLICITSTATE_INAIR);
 211         static bool oldonground;
 212         static float hitgroundtime;
 213         if (clonground)
 214         {
 215                 float f = time; // cl.movecmd[0].time
 216                 if (!oldonground)
 217                         hitgroundtime = f;
 218         }
 219         oldonground = clonground;
 220
 221         // calculate for swinging gun model
 222         // the gun bobs when running on the ground, but doesn't bob when you're in the air.
 223         vector gunorg = '0 0 0';
 224         static float bobmodel_scale = 0;
 225         static float time_ofs = 0; // makes the effect always restart in the same way
 226         if (clonground)
 227         {
 228                 if (time - hitgroundtime > 0.05)
 229                         bobmodel_scale = min(1, bobmodel_scale + frametime * 5);
 230         }
 231         else
 232                 bobmodel_scale = max(0, bobmodel_scale - frametime * 5);
 233
 234         float xyspeed = bound(0, vlen(vec2(view.velocity)), 400);
 235         if (bobmodel_scale && xyspeed)
 236         {
 237                 float bspeed = xyspeed * 0.01 * autocvar_cl_viewmodel_scale * bobmodel_scale;
 238                 float s = (time - time_ofs) * autocvar_cl_bobmodel_speed;
 239                 gunorg.y = bspeed * autocvar_cl_bobmodel_side * sin(s);
 240                 gunorg.z = bspeed * autocvar_cl_bobmodel_up * cos(s * 2);
 241         }
 242         else
 243                 time_ofs = time;
 244
 245         return gunorg;
 246 }
 247
 248 void viewmodel_animate(entity this)
 249 {
 250         if (autocvar_chase_active) return;
 251         if (STAT(HEALTH) <= 0) return;
 252
 253         entity view = CSQCModel_server2csqc(player_localentnum - 1);
 254
 255         if (autocvar_cl_followmodel)
 256         {
 257                 calc_followmodel_ofs(view);
 258                 this.origin += cl_followmodel_ofs;
 259         }
 260
 261         if (autocvar_cl_leanmodel)
 262                 this.angles += leanmodel_ofs(view);
 263
 264         // vertical view bobbing code
 265         // TODO: cl_bob
 266
 267         // horizontal view bobbing code
 268         // TODO: cl_bob2
 269
 270         // fall bobbing code
 271         // causes the view to swing down and back up when touching the ground
 272         // TODO: cl_bobfall
 273
 274         // gun model bobbing code
 275         if (autocvar_cl_bobmodel)
 276                 this.origin += bobmodel_ofs(view);
 277 }
 278
 279 .vector viewmodel_origin, viewmodel_angles;
 280 .float weapon_nextthink;
 281 .float weapon_eta_last;
 282 .float weapon_switchdelay;
 283
 284 .string name_last;
 285
 286 void viewmodel_draw(entity this)
 287 {
 288         if(!this.activeweapon || !autocvar_r_drawviewmodel)
 289                 return;
 290         int mask = (intermission || (STAT(HEALTH) <= 0) || autocvar_chase_active) ? 0 : MASK_NORMAL;
 291         float a = this.alpha;
 292         static bool wasinvehicle;
 293         bool invehicle = player_localentnum > maxclients;
 294         if (invehicle) a = -1;
 295         else if (wasinvehicle) a = 1;
 296         wasinvehicle = invehicle;
 297         Weapon wep = this.activeweapon;
 298         int c = entcs_GetClientColors(current_player);
 299         vector g = weaponentity_glowmod(wep, NULL, c, this);
 300         entity me = CSQCModel_server2csqc(player_localentnum - 1);
 301         int fx = ((me.csqcmodel_effects & EFMASK_CHEAP)
 302                 | EF_NODEPTHTEST)
 303                 &~ (EF_FULLBRIGHT); // can mask team color, so get rid of it
 304         for (entity e = this; e; e = e.weaponchild)
 305         {
 306                 e.drawmask = mask;
 307                 e.alpha = a;
 308                 e.colormap = 256 + c;  // colormap == 0 is black, c == 0 is white
 309                 e.glowmod = g;
 310                 e.csqcmodel_effects = fx;
 311                 CSQCModel_Effects_Apply(e);
 312         }
 313         {
 314                 string name = wep.mdl;
 315                 bool swap = name != this.name_last;
 316                 // if (swap)
 317                 {
 318                         this.name_last = name;
 319                         CL_WeaponEntity_SetModel(this, name, swap);
 320                         this.viewmodel_origin = this.origin;
 321                         this.viewmodel_angles = this.angles;
 322                 }
 323                 anim_update(this);
 324                 if (!this.animstate_override && !this.animstate_looping)
 325                         anim_set(this, this.anim_idle, true, false, false);
 326         }
 327         float f = 0; // 0..1; 0: fully active
 328         float rate = STAT(WEAPONRATEFACTOR);
 329         float eta = rate ? ((this.weapon_nextthink - time) / rate) : 0;
 330         if (eta <= 0) f = this.weapon_eta_last;
 331         else switch (this.state)
 332         {
 333                 case WS_RAISE:
 334                 {
 335                         f = eta / max(eta, this.weapon_switchdelay);
 336                         break;
 337                 }
 338                 case WS_DROP:
 339                 {
 340                         f = 1 - eta / max(eta, this.weapon_switchdelay);
 341                         break;
 342                 }
 343                 case WS_CLEAR:
 344                 {
 345                         f = 1;
 346                         break;
 347                 }
 348         }
 349         this.weapon_eta_last = f;
 350         this.origin = this.viewmodel_origin;
 351         this.angles = this.viewmodel_angles;
 352         this.angles_x = (-90 * f * f);
 353         viewmodel_animate(this);
 354         setorigin(this, this.origin);
 355 }
 356
 357 entity viewmodels[MAX_WEAPONSLOTS];
 358 STATIC_INIT(viewmodel) {
 359     for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 360         viewmodels[slot] = new(viewmodel);
 361 }
 362
 363 void Porto_Draw(entity this);
 364 STATIC_INIT(Porto)
 365 {
 366         entity e = new_pure(porto);
 367         e.draw = Porto_Draw;
 368         IL_PUSH(g_drawables, e);
 369         e.dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY | DPCONTENTS_PLAYERCLIP;
 370 }
 371
 372 const int polyline_length = 16;
 373 vector polyline[polyline_length];
 374 void Porto_Draw(entity this)
 375 {
 376         entity wepent = viewmodels[0]; // TODO: unhardcode
 377         if (wepent.activeweapon != WEP_PORTO) return;
 378         if (spectatee_status) return;
 379         if (WEP_CVAR(porto, secondary)) return;
 380         if (intermission == 1) return;
 381         if (intermission == 2) return;
 382         if (STAT(HEALTH) <= 0) return;
 383
 384         vector pos = view_origin;
 385         vector dir = view_forward;
 386         if (angles_held_status)
 387         {
 388                 makevectors(angles_held);
 389                 dir = v_forward;
 390         }
 391
 392         polyline[0] = pos;
 393
 394         int portal_number = 0, portal1_idx = 1, portal_max = 2;
 395         int n = 1 + 2;  // 2 lines == 3 points
 396         for (int idx = 0; idx < n && idx < polyline_length - 1; )
 397         {
 398                 traceline(pos, pos + 65536 * dir, true, this);
 399                 dir = reflect(dir, trace_plane_normal);
 400                 pos = trace_endpos;
 401                 polyline[++idx] = pos;
 402                 if (trace_dphitq3surfaceflags & Q3SURFACEFLAG_SLICK || trace_dphitcontents & DPCONTENTS_PLAYERCLIP)
 403                 {
 404                         n += 1;
 405                         continue;
 406                 }
 407                 if (trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT)
 408                 {
 409                         n = max(2, idx);
 410                         break;
 411                 }
 412                 // check size
 413                 {
 414                         vector ang = vectoangles2(trace_plane_normal, dir);
 415                         ang.x = -ang.x;
 416                         makevectors(ang);
 417                         if (!CheckWireframeBox(this, pos - 48 * v_right - 48 * v_up + 16 * v_forward, 96 * v_right, 96 * v_up, 96 * v_forward))
 418                         {
 419                                 n = max(2, idx);
 420                                 break;
 421                         }
 422                 }
 423                 portal_number += 1;
 424                 if (portal_number >= portal_max) break;
 425                 if (portal_number == 1) portal1_idx = idx;
 426         }
 427         for (int idx = 0; idx < n - 1; ++idx)
 428         {
 429                 vector p = polyline[idx], q = polyline[idx + 1];
 430                 if (idx == 0) p -= view_up * 16;  // line from player
 431                 vector rgb = (idx < portal1_idx) ? '1 0 0' : '0 0 1';
 432                 Draw_CylindricLine(p, q, 4, "", 1, 0, rgb, 0.5, DRAWFLAG_NORMAL, view_origin);
 433         }
 434 }
 435
 436 float drawtime;
 437 float avgspeed;
 438 vector GetCurrentFov(float fov)
 439 {
 440         float zoomsensitivity, zoomspeed, zoomfactor, zoomdir;
 441         float velocityzoom, curspeed;
 442         vector v;
 443
 444         zoomsensitivity = autocvar_cl_zoomsensitivity;
 445         zoomfactor = autocvar_cl_zoomfactor;
 446         if(zoomfactor < 1 || zoomfactor > 30)
 447                 zoomfactor = 2.5;
 448         zoomspeed = autocvar_cl_zoomspeed;
 449         if(zoomspeed >= 0)
 450         if(zoomspeed < 0.5 || zoomspeed > 16)
 451                         zoomspeed = 3.5;
 452
 453         zoomdir = button_zoom;
 454
 455         if(hud == HUD_NORMAL && !spectatee_status)
 456         {
 457                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 458                 {
 459                         entity wepent = viewmodels[slot];
 460                         if(wepent.switchweapon == wepent.activeweapon)
 461                         if((wepent.activeweapon == WEP_VORTEX && !WEP_CVAR(vortex, secondary)) || (wepent.activeweapon == WEP_RIFLE && !WEP_CVAR(rifle, secondary))) // do NOT use switchweapon here
 462                                 zoomdir += button_attack2;
 463                 }
 464         }
 465         if(spectatee_status > 0 || isdemo())
 466         {
 467                 if(spectatorbutton_zoom)
 468                 {
 469                         if(zoomdir)
 470                                 zoomdir = 0;
 471                         else
 472                                 zoomdir = 1;
 473                 }
 474                 // fteqcc failed twice here already, don't optimize this
 475         }
 476
 477         if(zoomdir) { zoomin_effect = 0; }
 478
 479         if(camera_active)
 480         {
 481                 current_viewzoom = min(1, current_viewzoom + drawframetime);
 482         }
 483         else if(autocvar_cl_spawnzoom && zoomin_effect)
 484         {
 485                 float spawnzoomfactor = bound(1, autocvar_cl_spawnzoom_factor, 30);
 486
 487                 current_viewzoom += (autocvar_cl_spawnzoom_speed * (spawnzoomfactor - current_viewzoom) * drawframetime);
 488                 current_viewzoom = bound(1 / spawnzoomfactor, current_viewzoom, 1);
 489                 if(current_viewzoom == 1) { zoomin_effect = 0; }
 490         }
 491         else
 492         {
 493                 if(zoomspeed < 0) // instant zoom
 494                 {
 495                         if(zoomdir)
 496                                 current_viewzoom = 1 / zoomfactor;
 497                         else
 498                                 current_viewzoom = 1;
 499                 }
 500                 else
 501                 {
 502                         if(zoomdir)
 503                                 current_viewzoom = 1 / bound(1, 1 / current_viewzoom + drawframetime * zoomspeed * (zoomfactor - 1), zoomfactor);
 504                         else
 505                                 current_viewzoom = bound(1 / zoomfactor, current_viewzoom + drawframetime * zoomspeed * (1 - 1 / zoomfactor), 1);
 506                 }
 507         }
 508
 509         if(almost_equals(current_viewzoom, 1))
 510                 current_zoomfraction = 0;
 511         else if(almost_equals(current_viewzoom, 1/zoomfactor))
 512                 current_zoomfraction = 1;
 513         else
 514                 current_zoomfraction = (current_viewzoom - 1) / (1/zoomfactor - 1);
 515
 516         if(zoomsensitivity < 1)
 517                 setsensitivityscale(pow(current_viewzoom, 1 - zoomsensitivity));
 518         else
 519                 setsensitivityscale(1);
 520
 521         if(autocvar_cl_velocityzoom_enabled && autocvar_cl_velocityzoom_type) // _type = 0 disables velocity zoom too
 522         {
 523                 if(intermission) { curspeed = 0; }
 524                 else
 525                 {
 526
 527                         makevectors(view_angles);
 528                         v = pmove_vel;
 529                         if(csqcplayer)
 530                                 v = csqcplayer.velocity;
 531
 532                         switch(autocvar_cl_velocityzoom_type)
 533                         {
 534                                 case 3: curspeed = max(0, v_forward * v); break;
 535                                 case 2: curspeed = (v_forward * v); break;
 536                                 case 1: default: curspeed = vlen(v); break;
 537                         }
 538                 }
 539
 540                 velocityzoom = bound(0, drawframetime / max(0.000000001, autocvar_cl_velocityzoom_time), 1); // speed at which the zoom adapts to player velocity
 541                 avgspeed = avgspeed * (1 - velocityzoom) + (curspeed / autocvar_cl_velocityzoom_speed) * velocityzoom;
 542                 velocityzoom = exp(float2range11(avgspeed * -autocvar_cl_velocityzoom_factor / 1) * 1);
 543
 544                 //print(ftos(avgspeed), " avgspeed, ", ftos(curspeed), " curspeed, ", ftos(velocityzoom), " return\n"); // for debugging
 545         }
 546         else
 547                 velocityzoom = 1;
 548
 549         float frustumx, frustumy, fovx, fovy;
 550         frustumy = tan(fov * M_PI / 360.0) * 0.75 * current_viewzoom * velocityzoom;
 551         frustumx = frustumy * vid_width / vid_height / vid_pixelheight;
 552         fovx = atan2(frustumx, 1) / M_PI * 360.0;
 553         fovy = atan2(frustumy, 1) / M_PI * 360.0;
 554
 555         return '1 0 0' * fovx + '0 1 0' * fovy;
 556 }
 557
 558 vector GetViewLocationFOV(float fov)
 559 {
 560         float frustumy = tan(fov * M_PI / 360.0) * 0.75;
 561         float frustumx = frustumy * vid_width / vid_height / vid_pixelheight;
 562         float fovx = atan2(frustumx, 1) / M_PI * 360.0;
 563         float fovy = atan2(frustumy, 1) / M_PI * 360.0;
 564         return '1 0 0' * fovx + '0 1 0' * fovy;
 565 }
 566
 567 vector GetOrthoviewFOV(vector ov_worldmin, vector ov_worldmax, vector ov_mid, vector ov_org)
 568 {
 569         float fovx, fovy;
 570         float width = (ov_worldmax.x - ov_worldmin.x);
 571         float height = (ov_worldmax.y - ov_worldmin.y);
 572         float distance_to_middle_of_world = vlen(ov_mid - ov_org);
 573         fovx = atan2(width/2, distance_to_middle_of_world) / M_PI * 360.0;
 574         fovy = atan2(height/2, distance_to_middle_of_world) / M_PI * 360.0;
 575         return '1 0 0' * fovx + '0 1 0' * fovy;
 576 }
 577
 578 // this function must match W_SetupShot!
 579 float zoomscript_caught;
 580
 581 vector wcross_origin;
 582 float wcross_scale_prev, wcross_alpha_prev;
 583 vector wcross_color_prev;
 584 float wcross_scale_goal_prev, wcross_alpha_goal_prev;
 585 vector wcross_color_goal_prev;
 586 float wcross_changedonetime;
 587
 588 string wcross_name_goal_prev, wcross_name_goal_prev_prev;
 589 float wcross_resolution_goal_prev, wcross_resolution_goal_prev_prev;
 590 float wcross_name_changestarttime, wcross_name_changedonetime;
 591 float wcross_name_alpha_goal_prev, wcross_name_alpha_goal_prev_prev;
 592
 593 float wcross_ring_prev;
 594
 595 entity trueaim;
 596 entity trueaim_rifle;
 597
 598 const float SHOTTYPE_HITTEAM = 1;
 599 const float SHOTTYPE_HITOBSTRUCTION = 2;
 600 const float SHOTTYPE_HITWORLD = 3;
 601 const float SHOTTYPE_HITENEMY = 4;
 602
 603 void TrueAim_Init()
 604 {
 605         (trueaim = new_pure(trueaim)).dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY | DPCONTENTS_CORPSE;
 606         (trueaim_rifle = new_pure(trueaim_rifle)).dphitcontentsmask = DPCONTENTS_BODY | DPCONTENTS_CORPSE;
 607 }
 608
 609 float EnemyHitCheck()
 610 {
 611         float t, n;
 612         wcross_origin = project_3d_to_2d(trace_endpos);
 613         wcross_origin.z = 0;
 614         if(trace_ent)
 615                 n = trace_ent.entnum;
 616         else
 617                 n = trace_networkentity;
 618         if(n < 1)
 619                 return SHOTTYPE_HITWORLD;
 620         if(n > maxclients)
 621                 return SHOTTYPE_HITWORLD;
 622         t = entcs_GetTeam(n - 1);
 623         if(teamplay)
 624                 if(t == myteam)
 625                         return SHOTTYPE_HITTEAM;
 626         if(t == NUM_SPECTATOR)
 627                 return SHOTTYPE_HITWORLD;
 628         return SHOTTYPE_HITENEMY;
 629 }
 630
 631 float TrueAimCheck()
 632 {
 633         float nudge = 1; // added to traceline target and subtracted from result TOOD(divVerent): do we still need this? Doesn't the engine do this now for us?
 634         vector vecs, trueaimpoint, w_shotorg;
 635         vector mi, ma, dv;
 636         float shottype;
 637         entity ta;
 638         float mv;
 639
 640         mi = ma = '0 0 0';
 641         ta = trueaim;
 642         mv = MOVE_NOMONSTERS;
 643
 644         entity wepent = viewmodels[0]; // TODO: unhardcode
 645
 646         switch(wepent.activeweapon) // WEAPONTODO
 647         {
 648                 case WEP_TUBA: // no aim
 649                 case WEP_PORTO: // shoots from eye
 650                 case WEP_NEXBALL: // shoots from eye
 651                 case WEP_HOOK: // no trueaim
 652                 case WEP_MORTAR: // toss curve
 653                         return SHOTTYPE_HITWORLD;
 654                 case WEP_VORTEX:
 655                 case WEP_VAPORIZER:
 656                         mv = MOVE_NORMAL;
 657                         break;
 658                 case WEP_RIFLE:
 659                         ta = trueaim_rifle;
 660                         mv = MOVE_NORMAL;
 661                         if(zoomscript_caught)
 662                         {
 663                                 tracebox(view_origin, '0 0 0', '0 0 0', view_origin + view_forward * MAX_SHOT_DISTANCE, mv, ta);
 664                                 return EnemyHitCheck();
 665                         }
 666                         break;
 667                 case WEP_DEVASTATOR: // projectile has a size!
 668                         mi = '-3 -3 -3';
 669                         ma = '3 3 3';
 670                         break;
 671                 case WEP_FIREBALL: // projectile has a size!
 672                         mi = '-16 -16 -16';
 673                         ma = '16 16 16';
 674                         break;
 675                 case WEP_SEEKER: // projectile has a size!
 676                         mi = '-2 -2 -2';
 677                         ma = '2 2 2';
 678                         break;
 679                 case WEP_ELECTRO: // projectile has a size!
 680                         mi = '0 0 -3';
 681                         ma = '0 0 -3';
 682                         break;
 683         }
 684
 685         vector traceorigin = entcs_receiver(player_localentnum - 1).origin + (eZ * STAT(VIEWHEIGHT));
 686
 687         vecs = decompressShotOrigin(STAT(SHOTORG));
 688
 689         traceline(traceorigin, traceorigin + view_forward * MAX_SHOT_DISTANCE, mv, ta);
 690         trueaimpoint = trace_endpos;
 691
 692         if(vdist((trueaimpoint - traceorigin), <, g_trueaim_minrange))
 693                 trueaimpoint = traceorigin + view_forward * g_trueaim_minrange;
 694
 695         if(vecs.x > 0)
 696                 vecs.y = -vecs.y;
 697         else
 698                 vecs = '0 0 0';
 699
 700         dv = view_right * vecs.y + view_up * vecs.z;
 701         w_shotorg = traceorigin + dv;
 702
 703         // now move the vecs forward as much as requested if possible
 704         tracebox(w_shotorg, mi, ma, w_shotorg + view_forward * (vecs.x + nudge), MOVE_NORMAL, ta); // FIXME this MOVE_NORMAL part will misbehave a little in csqc
 705         w_shotorg = trace_endpos - view_forward * nudge;
 706
 707         tracebox(w_shotorg, mi, ma, trueaimpoint, MOVE_NORMAL, ta);
 708         shottype = EnemyHitCheck();
 709         if(shottype != SHOTTYPE_HITWORLD)
 710                 return shottype;
 711
 712 #if 0
 713         // FIXME WHY DOES THIS NOT WORK FOR THE ROCKET LAUNCHER?
 714         // or rather, I know why, but see no fix
 715         if(vlen(trace_endpos - trueaimpoint) > vlen(ma) + vlen(mi) + 1)
 716                 // yes, this is an ugly hack... but it seems good enough to find out whether the test hits the same place as the initial trace
 717                 return SHOTTYPE_HITOBSTRUCTION;
 718 #endif
 719
 720         return SHOTTYPE_HITWORLD;
 721 }
 722
 723 void PostInit();
 724 void CSQC_Demo_Camera();
 725 float camera_mode;
 726 const float CAMERA_FREE = 1;
 727 const float CAMERA_CHASE = 2;
 728 float reticle_type;
 729 string NextFrameCommand;
 730
 731 vector freeze_org, freeze_ang;
 732 entity nightvision_noise, nightvision_noise2;
 733
 734 const float MAX_TIME_DIFF = 5;
 735 float pickup_crosshair_time, pickup_crosshair_size;
 736 float hitindication_crosshair_size;
 737 float use_vortex_chargepool;
 738
 739 float myhealth, myhealth_prev;
 740 float myhealth_flash;
 741
 742 float old_blurradius, old_bluralpha;
 743 float old_sharpen_intensity;
 744
 745 vector myhealth_gentlergb;
 746
 747 float contentavgalpha, liquidalpha_prev;
 748 vector liquidcolor_prev;
 749
 750 float eventchase_current_distance;
 751 float eventchase_running;
 752 bool WantEventchase(entity this)
 753 {
 754         if(autocvar_cl_orthoview)
 755                 return false;
 756         if(intermission)
 757                 return true;
 758         if(this.viewloc)
 759                 return true;
 760         if(spectatee_status >= 0)
 761         {
 762                 if(hud != HUD_NORMAL && (autocvar_cl_eventchase_vehicle || spectatee_status > 0))
 763                         return true;
 764                 if(MUTATOR_CALLHOOK(WantEventchase, this))
 765                         return true;
 766                 if(autocvar_cl_eventchase_death && (STAT(HEALTH) <= 0))
 767                 {
 768                         if(autocvar_cl_eventchase_death == 2)
 769                         {
 770                                 // don't stop eventchase once it's started (even if velocity changes afterwards)
 771                                 if(this.velocity == '0 0 0' || eventchase_running)
 772                                         return true;
 773                         }
 774                         else return true;
 775                 }
 776         }
 777         return false;
 778 }
 779
 780 void HUD_Crosshair_Vehicle(entity this)
 781 {
 782         if(hud != HUD_BUMBLEBEE_GUN)
 783         {
 784                 Vehicle info = Vehicles_from(hud);
 785                 info.vr_crosshair(info, this);
 786         }
 787 }
 788
 789 vector damage_blurpostprocess, content_blurpostprocess;
 790
 791 float unaccounted_damage = 0;
 792 void UpdateDamage()
 793 {
 794         // accumulate damage with each stat update
 795         static float damage_total_prev = 0;
 796         float damage_total = STAT(DAMAGE_DEALT_TOTAL);
 797         float unaccounted_damage_new = COMPARE_INCREASING(damage_total, damage_total_prev);
 798         damage_total_prev = damage_total;
 799
 800         static float damage_dealt_time_prev = 0;
 801         float damage_dealt_time = STAT(HIT_TIME);
 802         if (damage_dealt_time != damage_dealt_time_prev)
 803         {
 804                 unaccounted_damage += unaccounted_damage_new;
 805                 LOG_TRACE("dmg total: ", ftos(unaccounted_damage), " (+", ftos(unaccounted_damage_new), ")");
 806         }
 807         damage_dealt_time_prev = damage_dealt_time;
 808
 809         // prevent hitsound when switching spectatee
 810         static float spectatee_status_prev = 0;
 811         if (spectatee_status != spectatee_status_prev)
 812                 unaccounted_damage = 0;
 813         spectatee_status_prev = spectatee_status;
 814 }
 815
 816 void HitSound()
 817 {
 818         // varying sound pitch
 819
 820         entity wepent = viewmodels[0]; // TODO: unhardcode
 821
 822         static float hitsound_time_prev = 0;
 823         // HACK: the only way to get the arc to sound consistent with pitch shift is to ignore cl_hitsound_antispam_time
 824         float arc_hack = wepent.activeweapon == WEP_ARC && autocvar_cl_hitsound >= 2;
 825         if (arc_hack || COMPARE_INCREASING(time, hitsound_time_prev) > autocvar_cl_hitsound_antispam_time)
 826         {
 827                 if (autocvar_cl_hitsound && unaccounted_damage)
 828                 {
 829                         // customizable gradient function that crosses (0,a), (c,1) and asymptotically approaches b
 830                         float a = autocvar_cl_hitsound_max_pitch;
 831                         float b = autocvar_cl_hitsound_min_pitch;
 832                         float c = autocvar_cl_hitsound_nom_damage;
 833                         float x = unaccounted_damage;
 834                         float pitch_shift = (b*x*(a-1) + a*c*(1-b)) / (x*(a-1) + c*(1-b));
 835
 836                         // if sound variation is disabled, set pitch_shift to 1
 837                         if (autocvar_cl_hitsound == 1)
 838                                 pitch_shift = 1;
 839
 840                         // if pitch shift is reversed, mirror in (max-min)/2 + min
 841                         if (autocvar_cl_hitsound == 3)
 842                         {
 843                                 float mirror_value = (a-b)/2 + b;
 844                                 pitch_shift = mirror_value + (mirror_value - pitch_shift);
 845                         }
 846
 847                         LOG_TRACE("dmg total (dmg): ", ftos(unaccounted_damage), " , pitch shift: ", ftos(pitch_shift));
 848
 849                         // todo: avoid very long and very short sounds from wave stretching using different sound files? seems unnecessary
 850                         // todo: normalize sound pressure levels? seems unnecessary
 851
 852                         sound7(NULL, CH_INFO, SND(HIT), VOL_BASE, ATTN_NONE, pitch_shift * 100, 0);
 853                 }
 854                 unaccounted_damage = 0;
 855                 hitsound_time_prev = time;
 856         }
 857
 858         static float typehit_time_prev = 0;
 859         float typehit_time = STAT(TYPEHIT_TIME);
 860         if (COMPARE_INCREASING(typehit_time, typehit_time_prev) > autocvar_cl_hitsound_antispam_time)
 861         {
 862                 sound(NULL, CH_INFO, SND_TYPEHIT, VOL_BASE, ATTN_NONE);
 863                 typehit_time_prev = typehit_time;
 864         }
 865 }
 866
 867 vector crosshair_getcolor(entity this, float health_stat)
 868 {
 869         static float rainbow_last_flicker;
 870         static vector rainbow_prev_color;
 871         vector wcross_color = '0 0 0';
 872         switch(autocvar_crosshair_color_special)
 873         {
 874                 case 1: // crosshair_color_per_weapon
 875                 {
 876                         if(this != WEP_Null && hud == HUD_NORMAL)
 877                         {
 878                                 wcross_color = this.wpcolor;
 879                                 break;
 880                         }
 881                         else { goto normalcolor; }
 882                 }
 883
 884                 case 2: // crosshair_color_by_health
 885                 {
 886                         float x = health_stat;
 887
 888                         //x = red
 889                         //y = green
 890                         //z = blue
 891
 892                         wcross_color.z = 0;
 893
 894                         if(x > 200)
 895                         {
 896                                 wcross_color.x = 0;
 897                                 wcross_color.y = 1;
 898                         }
 899                         else if(x > 150)
 900                         {
 901                                 wcross_color.x = 0.4 - (x-150)*0.02 * 0.4;
 902                                 wcross_color.y = 0.9 + (x-150)*0.02 * 0.1;
 903                         }
 904                         else if(x > 100)
 905                         {
 906                                 wcross_color.x = 1 - (x-100)*0.02 * 0.6;
 907                                 wcross_color.y = 1 - (x-100)*0.02 * 0.1;
 908                                 wcross_color.z = 1 - (x-100)*0.02;
 909                         }
 910                         else if(x > 50)
 911                         {
 912                                 wcross_color.x = 1;
 913                                 wcross_color.y = 1;
 914                                 wcross_color.z = 0.2 + (x-50)*0.02 * 0.8;
 915                         }
 916                         else if(x > 20)
 917                         {
 918                                 wcross_color.x = 1;
 919                                 wcross_color.y = (x-20)*90/27/100;
 920                                 wcross_color.z = (x-20)*90/27/100 * 0.2;
 921                         }
 922                         else
 923                         {
 924                                 wcross_color.x = 1;
 925                                 wcross_color.y = 0;
 926                         }
 927                         break;
 928                 }
 929
 930                 case 3: // crosshair_color_rainbow
 931                 {
 932                         if(time >= rainbow_last_flicker)
 933                         {
 934                                 rainbow_prev_color = randomvec() * autocvar_crosshair_color_special_rainbow_brightness;
 935                                 rainbow_last_flicker = time + autocvar_crosshair_color_special_rainbow_delay;
 936                         }
 937                         wcross_color = rainbow_prev_color;
 938                         break;
 939                 }
 940 LABEL(normalcolor)
 941                 default: { wcross_color = stov(autocvar_crosshair_color); break; }
 942         }
 943
 944         return wcross_color;
 945 }
 946
 947 void HUD_Crosshair(entity this)
 948 {
 949         float f, i, j;
 950         vector v;
 951         if(!scoreboard_active && !camera_active && intermission != 2 &&
 952                 spectatee_status != -1 && !csqcplayer.viewloc && !MUTATOR_CALLHOOK(DrawCrosshair) &&
 953                 !HUD_MinigameMenu_IsOpened() )
 954         {
 955                 if (!autocvar_crosshair_enabled) // main toggle for crosshair rendering
 956                         return;
 957
 958                 if (spectatee_status > 0 && STAT(CAMERA_SPECTATOR) == 2)
 959                         return;
 960
 961                 if (hud != HUD_NORMAL)
 962                 {
 963                         HUD_Crosshair_Vehicle(this);
 964                         return;
 965                 }
 966
 967                 string wcross_style;
 968                 float wcross_alpha, wcross_resolution;
 969                 wcross_style = autocvar_crosshair;
 970                 if (wcross_style == "0")
 971                         return;
 972                 wcross_resolution = autocvar_crosshair_size;
 973                 if (wcross_resolution == 0)
 974                         return;
 975                 wcross_alpha = autocvar_crosshair_alpha;
 976                 if (wcross_alpha == 0)
 977                         return;
 978
 979                 // TrueAim check
 980                 float shottype;
 981
 982                 // wcross_origin = '0.5 0 0' * vid_conwidth + '0 0.5 0' * vid_conheight;
 983                 wcross_origin = project_3d_to_2d(view_origin + MAX_SHOT_DISTANCE * view_forward);
 984                 wcross_origin.z = 0;
 985                 if(autocvar_crosshair_hittest)
 986                 {
 987                         vector wcross_oldorigin;
 988                         wcross_oldorigin = wcross_origin;
 989                         shottype = TrueAimCheck();
 990                         if(shottype == SHOTTYPE_HITWORLD)
 991                         {
 992                                 v = wcross_origin - wcross_oldorigin;
 993                                 v.x /= vid_conwidth;
 994                                 v.y /= vid_conheight;
 995                                 if(vdist(v, >, 0.01))
 996                                         shottype = SHOTTYPE_HITOBSTRUCTION;
 997                         }
 998                         if(!autocvar_crosshair_hittest_showimpact)
 999                                 wcross_origin = wcross_oldorigin;
1000                 }
1001                 else
1002                         shottype = SHOTTYPE_HITWORLD;
1003
1004                 vector wcross_color = '0 0 0', wcross_size = '0 0 0';
1005                 string wcross_name = "";
1006                 float wcross_scale, wcross_blur;
1007
1008         entity e = WEP_Null;
1009                 if(autocvar_crosshair_per_weapon || (autocvar_crosshair_color_special == 1))
1010                 {
1011                         entity wepent = viewmodels[0]; // TODO: unhardcode
1012                         e = wepent.switchingweapon;
1013                         if(e)
1014                         {
1015                                 if(autocvar_crosshair_per_weapon)
1016                                 {
1017                                         // WEAPONTODO: access these through some general settings (with non-balance config settings)
1018                                         //wcross_resolution *= cvar(strcat("crosshair_", wcross_wep, "_size"));
1019                                         //if (wcross_resolution == 0)
1020                                                 //return;
1021
1022                                         //wcross_style = cvar_string(strcat("crosshair_", wcross_wep));
1023                                         wcross_resolution *= e.w_crosshair_size;
1024                                         wcross_name = e.w_crosshair;
1025                                 }
1026                         }
1027                 }
1028
1029                 if(wcross_name == "")
1030                         wcross_name = strcat("gfx/crosshair", wcross_style);
1031
1032                 // MAIN CROSSHAIR COLOR DECISION
1033                 wcross_color = crosshair_getcolor(e, STAT(HEALTH));
1034
1035                 if(autocvar_crosshair_effect_scalefade)
1036                 {
1037                         wcross_scale = wcross_resolution;
1038                         wcross_resolution = 1;
1039                 }
1040                 else
1041                 {
1042                         wcross_scale = 1;
1043                 }
1044
1045                 if(autocvar_crosshair_pickup)
1046                 {
1047                         float stat_pickup_time = STAT(LAST_PICKUP);
1048
1049                         if(pickup_crosshair_time < stat_pickup_time)
1050                         {
1051                                 if(time - stat_pickup_time < MAX_TIME_DIFF) // don't trigger the animation if it's too old
1052                                         pickup_crosshair_size = 1;
1053
1054                                 pickup_crosshair_time = stat_pickup_time;
1055                         }
1056
1057                         if(pickup_crosshair_size > 0)
1058                                 pickup_crosshair_size -= autocvar_crosshair_pickup_speed * frametime;
1059                         else
1060                                 pickup_crosshair_size = 0;
1061
1062                         wcross_scale += sin(pickup_crosshair_size) * autocvar_crosshair_pickup;
1063                 }
1064
1065                 // todo: make crosshair hit indication dependent on damage dealt
1066                 if(autocvar_crosshair_hitindication)
1067                 {
1068                         vector hitindication_color = ((autocvar_crosshair_color_special == 1) ? stov(autocvar_crosshair_hitindication_per_weapon_color) : stov(autocvar_crosshair_hitindication_color));
1069
1070                         if(unaccounted_damage)
1071                         {
1072                                 hitindication_crosshair_size = 1;
1073                         }
1074
1075                         if(hitindication_crosshair_size > 0)
1076                                 hitindication_crosshair_size -= autocvar_crosshair_hitindication_speed * frametime;
1077                         else
1078                                 hitindication_crosshair_size = 0;
1079
1080                         wcross_scale += sin(hitindication_crosshair_size) * autocvar_crosshair_hitindication;
1081                         wcross_color.x += sin(hitindication_crosshair_size) * hitindication_color.x;
1082                         wcross_color.y += sin(hitindication_crosshair_size) * hitindication_color.y;
1083                         wcross_color.z += sin(hitindication_crosshair_size) * hitindication_color.z;
1084                 }
1085
1086                 if(shottype == SHOTTYPE_HITENEMY)
1087                         wcross_scale *= autocvar_crosshair_hittest; // is not queried if hittest is 0
1088                 if(shottype == SHOTTYPE_HITTEAM)
1089                         wcross_scale /= autocvar_crosshair_hittest; // is not queried if hittest is 0
1090
1091                 f = fabs(autocvar_crosshair_effect_time);
1092                 if(wcross_scale != wcross_scale_goal_prev || wcross_alpha != wcross_alpha_goal_prev || wcross_color != wcross_color_goal_prev)
1093                 {
1094                         wcross_changedonetime = time + f;
1095                 }
1096                 if(wcross_name != wcross_name_goal_prev || wcross_resolution != wcross_resolution_goal_prev)
1097                 {
1098                         wcross_name_changestarttime = time;
1099                         wcross_name_changedonetime = time + f;
1100                         if(wcross_name_goal_prev_prev)
1101                                 strunzone(wcross_name_goal_prev_prev);
1102                         wcross_name_goal_prev_prev = wcross_name_goal_prev;
1103                         wcross_name_goal_prev = strzone(wcross_name);
1104                         wcross_name_alpha_goal_prev_prev = wcross_name_alpha_goal_prev;
1105                         wcross_resolution_goal_prev_prev = wcross_resolution_goal_prev;
1106                         wcross_resolution_goal_prev = wcross_resolution;
1107                 }
1108
1109                 wcross_scale_goal_prev = wcross_scale;
1110                 wcross_alpha_goal_prev = wcross_alpha;
1111                 wcross_color_goal_prev = wcross_color;
1112
1113                 if(spectatee_status == -1 && shottype == SHOTTYPE_HITTEAM || (shottype == SHOTTYPE_HITOBSTRUCTION && autocvar_crosshair_hittest_blur && !autocvar_chase_active))
1114                 {
1115                         wcross_blur = 1;
1116                         wcross_alpha *= 0.75;
1117                 }
1118                 else
1119                         wcross_blur = 0;
1120                 // *_prev is at time-frametime
1121                 // * is at wcross_changedonetime+f
1122                 // what do we have at time?
1123                 if(time < wcross_changedonetime)
1124                 {
1125                         f = frametime / (wcross_changedonetime - time + frametime);
1126                         wcross_scale = f * wcross_scale + (1 - f) * wcross_scale_prev;
1127                         wcross_alpha = f * wcross_alpha + (1 - f) * wcross_alpha_prev;
1128                         wcross_color = f * wcross_color + (1 - f) * wcross_color_prev;
1129                 }
1130
1131                 wcross_scale_prev = wcross_scale;
1132                 wcross_alpha_prev = wcross_alpha;
1133                 wcross_color_prev = wcross_color;
1134
1135                 MUTATOR_CALLHOOK(UpdateCrosshair);
1136
1137                 wcross_scale *= 1 - autocvar__menu_alpha;
1138                 wcross_alpha *= 1 - autocvar__menu_alpha;
1139                 wcross_size = draw_getimagesize(wcross_name) * wcross_scale;
1140
1141                 if(wcross_scale >= 0.001 && wcross_alpha >= 0.001)
1142                 {
1143                         // crosshair rings for weapon stats
1144                         if (autocvar_crosshair_ring || autocvar_crosshair_ring_reload)
1145                         {
1146                                 // declarations and stats
1147                                 float ring_value = 0, ring_scale = 0, ring_alpha = 0, ring_inner_value = 0, ring_inner_alpha = 0;
1148                                 string ring_image = string_null, ring_inner_image = string_null;
1149                                 vector ring_rgb = '0 0 0', ring_inner_rgb = '0 0 0';
1150
1151                                 ring_scale = autocvar_crosshair_ring_size;
1152
1153                                 float weapon_clipload, weapon_clipsize;
1154                                 weapon_clipload = STAT(WEAPON_CLIPLOAD);
1155                                 weapon_clipsize = STAT(WEAPON_CLIPSIZE);
1156
1157                                 float vortex_charge, vortex_chargepool;
1158                                 vortex_charge = STAT(VORTEX_CHARGE);
1159                                 vortex_chargepool = STAT(VORTEX_CHARGEPOOL);
1160
1161                                 float arc_heat = STAT(ARC_HEAT);
1162
1163                                 if(vortex_charge_movingavg == 0) // this should only happen if we have just loaded up the game
1164                                         vortex_charge_movingavg = vortex_charge;
1165
1166                                 entity wepent = viewmodels[0]; // TODO: unhardcode
1167
1168                                 // handle the values
1169                                 if (autocvar_crosshair_ring && wepent.activeweapon == WEP_VORTEX && vortex_charge && autocvar_crosshair_ring_vortex) // ring around crosshair representing velocity-dependent damage for the vortex
1170                                 {
1171                                         if (vortex_chargepool || use_vortex_chargepool) {
1172                                                 use_vortex_chargepool = 1;
1173                                                 ring_inner_value = vortex_chargepool;
1174                                         } else {
1175                                                 vortex_charge_movingavg = (1 - autocvar_crosshair_ring_vortex_currentcharge_movingavg_rate) * vortex_charge_movingavg + autocvar_crosshair_ring_vortex_currentcharge_movingavg_rate * vortex_charge;
1176                                                 ring_inner_value = bound(0, autocvar_crosshair_ring_vortex_currentcharge_scale * (vortex_charge - vortex_charge_movingavg), 1);
1177                                         }
1178
1179                                         ring_inner_alpha = autocvar_crosshair_ring_vortex_inner_alpha;
1180                                         ring_inner_rgb = eX * autocvar_crosshair_ring_vortex_inner_color_red + eY * autocvar_crosshair_ring_vortex_inner_color_green + eZ * autocvar_crosshair_ring_vortex_inner_color_blue;
1181                                         ring_inner_image = "gfx/crosshair_ring_inner.tga";
1182
1183                                         // draw the outer ring to show the current charge of the weapon
1184                                         ring_value = vortex_charge;
1185                                         ring_alpha = autocvar_crosshair_ring_vortex_alpha;
1186                                         ring_rgb = wcross_color;
1187                                         ring_image = "gfx/crosshair_ring_nexgun.tga";
1188                                 }
1189                                 else if (autocvar_crosshair_ring && wepent.activeweapon == WEP_MINE_LAYER && WEP_CVAR(minelayer, limit) && autocvar_crosshair_ring_minelayer)
1190                                 {
1191                                         ring_value = bound(0, STAT(LAYED_MINES) / WEP_CVAR(minelayer, limit), 1); // if you later need to use the count of bullets in another place, then add a float for it. For now, no need to.
1192                                         ring_alpha = autocvar_crosshair_ring_minelayer_alpha;
1193                                         ring_rgb = wcross_color;
1194                                         ring_image = "gfx/crosshair_ring.tga";
1195                                 }
1196                                 else if (wepent.activeweapon == WEP_HAGAR && STAT(HAGAR_LOAD) && autocvar_crosshair_ring_hagar)
1197                                 {
1198                                         ring_value = bound(0, STAT(HAGAR_LOAD) / WEP_CVAR_SEC(hagar, load_max), 1);
1199                                         ring_alpha = autocvar_crosshair_ring_hagar_alpha;
1200                                         ring_rgb = wcross_color;
1201                                         ring_image = "gfx/crosshair_ring.tga";
1202                                 }
1203                                 else if(autocvar_crosshair_ring_reload && weapon_clipsize) // forces there to be only an ammo ring
1204                                 {
1205                                         ring_value = bound(0, weapon_clipload / weapon_clipsize, 1);
1206                                         ring_scale = autocvar_crosshair_ring_reload_size;
1207                                         ring_alpha = autocvar_crosshair_ring_reload_alpha;
1208                                         ring_rgb = wcross_color;
1209
1210                                         // Note: This is to stop Taoki from complaining that the image doesn't match all potential balances.
1211                                         // if a new image for another weapon is added, add the code (and its respective file/value) here
1212                                         if ((wepent.activeweapon == WEP_RIFLE) && (weapon_clipsize == 80))
1213                                                 ring_image = "gfx/crosshair_ring_rifle.tga";
1214                                         else
1215                                                 ring_image = "gfx/crosshair_ring.tga";
1216                                 }
1217                                 else if ( autocvar_crosshair_ring && autocvar_crosshair_ring_arc && arc_heat && wepent.activeweapon == WEP_ARC )
1218                                 {
1219                                         ring_value = arc_heat;
1220                                         ring_alpha = (1-arc_heat)*autocvar_crosshair_ring_arc_cold_alpha +
1221                                                 arc_heat*autocvar_crosshair_ring_arc_hot_alpha;
1222                                         ring_rgb = (1-arc_heat)*wcross_color + arc_heat*autocvar_crosshair_ring_arc_hot_color;
1223                                         ring_image = "gfx/crosshair_ring.tga";
1224                                 }
1225
1226                                 // if in weapon switch animation, fade ring out/in
1227                                 if(autocvar_crosshair_effect_time > 0)
1228                                 {
1229                                         f = (time - wcross_name_changestarttime) / autocvar_crosshair_effect_time;
1230                                         if (f >= 1)
1231                                         {
1232                                                 wcross_ring_prev = ((ring_image) ? true : false);
1233                                         }
1234
1235                                         if(wcross_ring_prev)
1236                                         {
1237                                                 if(f < 1)
1238                                                         ring_alpha *= fabs(1 - bound(0, f, 1));
1239                                         }
1240                                         else
1241                                         {
1242                                                 if(f < 1)
1243                                                         ring_alpha *= bound(0, f, 1);
1244                                         }
1245                                 }
1246
1247                                 if (autocvar_crosshair_ring_inner && ring_inner_value) // lets draw a ring inside a ring so you can ring while you ring
1248                                         DrawCircleClippedPic(wcross_origin, wcross_size.x * ring_scale, ring_inner_image, ring_inner_value, ring_inner_rgb, wcross_alpha * ring_inner_alpha, DRAWFLAG_ADDITIVE);
1249
1250                                 if (ring_value)
1251                                         DrawCircleClippedPic(wcross_origin, wcross_size.x * ring_scale, ring_image, ring_value, ring_rgb, wcross_alpha * ring_alpha, DRAWFLAG_ADDITIVE);
1252                         }
1253
1254 #define CROSSHAIR_DO_BLUR(M,sz,wcross_name,wcross_alpha) \
1255                         MACRO_BEGIN { \
1256                                 if(wcross_blur > 0) \
1257                                 { \
1258                                         for(i = -2; i <= 2; ++i) \
1259                                         for(j = -2; j <= 2; ++j) \
1260                                         M(i,j,sz,wcross_name,wcross_alpha*0.04); \
1261                                 } \
1262                                 else \
1263                                 { \
1264                                         M(0,0,sz,wcross_name,wcross_alpha); \
1265                                 } \
1266                         } MACRO_END
1267
1268 #define CROSSHAIR_DRAW_SINGLE(i,j,sz,wcross_name,wcross_alpha) \
1269                         drawpic(wcross_origin - ('0.5 0 0' * (sz * wcross_size.x + i * wcross_blur) + '0 0.5 0' * (sz * wcross_size.y + j * wcross_blur)), wcross_name, sz * wcross_size, wcross_color, wcross_alpha, DRAWFLAG_NORMAL)
1270
1271 #define CROSSHAIR_DRAW(sz,wcross_name,wcross_alpha) \
1272                         CROSSHAIR_DO_BLUR(CROSSHAIR_DRAW_SINGLE,sz,wcross_name,wcross_alpha)
1273
1274                         if(time < wcross_name_changedonetime && wcross_name != wcross_name_goal_prev_prev && wcross_name_goal_prev_prev)
1275                         {
1276                                 f = (wcross_name_changedonetime - time) / (wcross_name_changedonetime - wcross_name_changestarttime);
1277                                 wcross_size = draw_getimagesize(wcross_name_goal_prev_prev) * wcross_scale;
1278                                 CROSSHAIR_DRAW(wcross_resolution_goal_prev_prev, wcross_name_goal_prev_prev, wcross_alpha * f * wcross_name_alpha_goal_prev_prev);
1279                                 f = 1 - f;
1280                         }
1281                         else
1282                         {
1283                                 f = 1;
1284                         }
1285                         wcross_name_alpha_goal_prev = f;
1286
1287                         wcross_size = draw_getimagesize(wcross_name) * wcross_scale;
1288                         CROSSHAIR_DRAW(wcross_resolution, wcross_name, wcross_alpha * f);
1289
1290                         if(autocvar_crosshair_dot)
1291                         {
1292                                 vector wcross_color_old;
1293                                 wcross_color_old = wcross_color;
1294
1295                                 if((autocvar_crosshair_dot_color_custom) && (autocvar_crosshair_dot_color != "0"))
1296                                         wcross_color = stov(autocvar_crosshair_dot_color);
1297
1298                                 CROSSHAIR_DRAW(wcross_resolution * autocvar_crosshair_dot_size, "gfx/crosshairdot.tga", f * autocvar_crosshair_dot_alpha);
1299                                 // FIXME why don't we use wcross_alpha here?
1300                                 wcross_color = wcross_color_old;
1301                         }
1302                 }
1303         }
1304         else
1305         {
1306                 wcross_scale_prev = 0;
1307                 wcross_alpha_prev = 0;
1308                 wcross_scale_goal_prev = 0;
1309                 wcross_alpha_goal_prev = 0;
1310                 wcross_changedonetime = 0;
1311                 if(wcross_name_goal_prev)
1312                         strunzone(wcross_name_goal_prev);
1313                 wcross_name_goal_prev = string_null;
1314                 if(wcross_name_goal_prev_prev)
1315                         strunzone(wcross_name_goal_prev_prev);
1316                 wcross_name_goal_prev_prev = string_null;
1317                 wcross_name_changestarttime = 0;
1318                 wcross_name_changedonetime = 0;
1319                 wcross_name_alpha_goal_prev = 0;
1320                 wcross_name_alpha_goal_prev_prev = 0;
1321                 wcross_resolution_goal_prev = 0;
1322                 wcross_resolution_goal_prev_prev = 0;
1323         }
1324 }
1325
1326 void HUD_Draw(entity this)
1327 {
1328         // if we don't know gametype and scores yet avoid drawing the scoreboard
1329         // also in the very first frames, player state may be inconsistent so avoid drawing the hud at all
1330         // e.g. since initial player's health is 0 hud would display the hud_damage effect,
1331         // cl_deathscoreboard would show the scoreboard and so on
1332         if(!gametype)
1333                 return;
1334
1335         if(!intermission)
1336         if (MUTATOR_CALLHOOK(HUD_Draw_overlay))
1337         {
1338                 drawfill('0 0 0', eX * vid_conwidth + eY * vid_conheight, M_ARGV(0, vector), autocvar_hud_colorflash_alpha * M_ARGV(1, float), DRAWFLAG_ADDITIVE);
1339         }
1340         else if(STAT(FROZEN))
1341         {
1342                 drawfill('0 0 0', eX * vid_conwidth + eY * vid_conheight, ((STAT(REVIVE_PROGRESS)) ? ('0.25 0.90 1' + ('1 0 0' * STAT(REVIVE_PROGRESS)) + ('0 1 1' * STAT(REVIVE_PROGRESS) * -1)) : '0.25 0.90 1'), autocvar_hud_colorflash_alpha, DRAWFLAG_ADDITIVE);
1343         }
1344         if(!intermission)
1345         if(STAT(NADE_TIMER) && autocvar_cl_nade_timer) // give nade top priority, as it's a matter of life and death
1346         {
1347                 DrawCircleClippedPic(eX * 0.5 * vid_conwidth + eY * 0.6 * vid_conheight, 0.1 * vid_conheight, "gfx/crosshair_ring.tga", STAT(NADE_TIMER), '0.25 0.90 1' + ('1 0 0' * STAT(NADE_TIMER)) - ('0 1 1' * STAT(NADE_TIMER)), autocvar_hud_colorflash_alpha, DRAWFLAG_ADDITIVE);
1348                 drawstring_aspect(eY * 0.64 * vid_conheight, ((autocvar_cl_nade_timer == 2) ? _("Nade timer") : ""), eX * vid_conwidth + eY * 0.025 * vid_conheight, '1 1 1', 1, DRAWFLAG_NORMAL);
1349         }
1350         else if(STAT(CAPTURE_PROGRESS))
1351         {
1352                 DrawCircleClippedPic(eX * 0.5 * vid_conwidth + eY * 0.6 * vid_conheight, 0.1 * vid_conheight, "gfx/crosshair_ring.tga", STAT(CAPTURE_PROGRESS), '0.25 0.90 1', autocvar_hud_colorflash_alpha, DRAWFLAG_ADDITIVE);
1353                 drawstring_aspect(eY * 0.64 * vid_conheight, _("Capture progress"), eX * vid_conwidth + eY * 0.025 * vid_conheight, '1 1 1', 1, DRAWFLAG_NORMAL);
1354         }
1355         else if(STAT(REVIVE_PROGRESS))
1356         {
1357                 DrawCircleClippedPic(eX * 0.5 * vid_conwidth + eY * 0.6 * vid_conheight, 0.1 * vid_conheight, "gfx/crosshair_ring.tga", STAT(REVIVE_PROGRESS), '0.25 0.90 1', autocvar_hud_colorflash_alpha, DRAWFLAG_ADDITIVE);
1358                 drawstring_aspect(eY * 0.64 * vid_conheight, _("Revival progress"), eX * vid_conwidth + eY * 0.025 * vid_conheight, '1 1 1', 1, DRAWFLAG_NORMAL);
1359         }
1360
1361         if(autocvar_r_letterbox == 0)
1362                 if(autocvar_viewsize < 120)
1363                 {
1364                         if(!(gametype == MAPINFO_TYPE_RACE || gametype == MAPINFO_TYPE_CTS))
1365                                 Accuracy_LoadLevels();
1366
1367                         HUD_Main();
1368                         HUD_Scale_Disable();
1369                 }
1370
1371         // crosshair goes VERY LAST
1372         UpdateDamage();
1373         HUD_Crosshair(this);
1374         HitSound();
1375 }
1376
1377 bool ov_enabled;
1378 float oldr_nearclip;
1379 float oldr_farclip_base;
1380 float oldr_farclip_world;
1381 float oldr_novis;
1382 float oldr_useportalculling;
1383 float oldr_useinfinitefarclip;
1384
1385 void cl_notice_run();
1386
1387 float prev_myteam;
1388 int lasthud;
1389 float vh_notice_time;
1390 void WaypointSprite_Load();
1391 void CSQC_UpdateView(entity this, float w, float h)
1392 {
1393     TC(int, w); TC(int, h);
1394         entity e;
1395         float fov;
1396         float f;
1397         vector vf_size, vf_min;
1398         float a;
1399
1400         execute_next_frame();
1401
1402         ++framecount;
1403
1404         stats_get();
1405         hud = STAT(HUD);
1406
1407         if(hud != HUD_NORMAL && lasthud == HUD_NORMAL)
1408                 vh_notice_time = time + autocvar_cl_vehicles_notify_time;
1409
1410         lasthud = hud;
1411
1412         HUD_Scale_Disable();
1413
1414         if(autocvar__hud_showbinds_reload) // menu can set this one
1415         {
1416                 db_close(binddb);
1417                 binddb = db_create();
1418                 cvar_set("_hud_showbinds_reload", "0");
1419         }
1420
1421         if(checkextension("DP_CSQC_MINFPS_QUALITY"))
1422                 view_quality = getproperty(VF_MINFPS_QUALITY);
1423         else
1424                 view_quality = 1;
1425
1426         button_attack2 = PHYS_INPUT_BUTTON_ATCK2(this);
1427         button_zoom = PHYS_INPUT_BUTTON_ZOOM(this);
1428
1429         vf_size = getpropertyvec(VF_SIZE);
1430         vf_min = getpropertyvec(VF_MIN);
1431         vid_width = vf_size.x;
1432         vid_height = vf_size.y;
1433
1434         vector reticle_pos = '0 0 0', reticle_size = '0 0 0';
1435         vector splash_pos = '0 0 0', splash_size = '0 0 0';
1436
1437         WaypointSprite_Load();
1438
1439         CSQCPlayer_SetCamera();
1440
1441         if(player_localentnum <= maxclients) // is it a client?
1442                 current_player = player_localentnum - 1;
1443         else // then player_localentnum is the vehicle I'm driving
1444                 current_player = player_localnum;
1445         myteam = entcs_GetTeam(current_player);
1446
1447         if(myteam != prev_myteam)
1448         {
1449                 myteamcolors = colormapPaletteColor(myteam, 1);
1450                 FOREACH(hud_panels, true, it.update_time = time);
1451                 prev_myteam = myteam;
1452         }
1453
1454         ticrate = STAT(MOVEVARS_TICRATE) * STAT(MOVEVARS_TIMESCALE);
1455
1456         float is_dead = (STAT(HEALTH) <= 0);
1457
1458         // FIXME do we need this hack?
1459         if(isdemo())
1460         {
1461                 // in demos, input_buttons do not work
1462                 button_zoom = (autocvar__togglezoom == "-");
1463         }
1464         else if(button_zoom
1465                 && autocvar_cl_unpress_zoom_on_death
1466                 && (spectatee_status >= 0)
1467                 && (is_dead || intermission))
1468         {
1469                 // no zoom while dead or in intermission please
1470                 localcmd("-zoom\n");
1471                 button_zoom = false;
1472         }
1473
1474         // event chase camera
1475         if(autocvar_chase_active <= 0) // greater than 0 means it's enabled manually, and this code is skipped
1476         {
1477                 if(STAT(CAMERA_SPECTATOR))
1478                 {
1479                         if(spectatee_status > 0)
1480                         {
1481                                 if(!autocvar_chase_active)
1482                                 {
1483                                         cvar_set("chase_active", "-2");
1484                                         goto skip_eventchase_death;
1485                                 }
1486                         }
1487                         else if(autocvar_chase_active == -2)
1488                                 cvar_set("chase_active", "0");
1489
1490                         if(autocvar_chase_active == -2)
1491                                 goto skip_eventchase_death;
1492                 }
1493                 else if(autocvar_chase_active == -2)
1494                         cvar_set("chase_active", "0");
1495
1496                 float vehicle_chase = (hud != HUD_NORMAL && (autocvar_cl_eventchase_vehicle || spectatee_status > 0));
1497
1498                 float vehicle_viewdist = 0;
1499                 vector vehicle_viewofs = '0 0 0';
1500
1501                 if(vehicle_chase)
1502                 {
1503                         if(hud != HUD_BUMBLEBEE_GUN)
1504                         {
1505                                 Vehicle info = Vehicles_from(hud);
1506                                 vehicle_viewdist = info.height;
1507                                 vehicle_viewofs = info.view_ofs;
1508                         }
1509                 }
1510
1511                 if(WantEventchase(this))
1512                 {
1513                         vector current_view_origin_override = '0 0 0';
1514                         vector view_offset_override = '0 0 0';
1515                         float chase_distance_override = 0;
1516                         bool custom_eventchase = MUTATOR_CALLHOOK(CustomizeEventchase, this);
1517                         if(custom_eventchase)
1518                         {
1519                                 current_view_origin_override = M_ARGV(0, vector);
1520                                 view_offset_override = M_ARGV(1, vector);
1521                                 chase_distance_override = M_ARGV(0, float);
1522                         }
1523                         eventchase_running = true;
1524
1525                         entity local_player = ((csqcplayer) ? csqcplayer : CSQCModel_server2csqc(player_localentnum - 1));
1526                         if(!local_player)
1527                                 local_player = this; // fall back!
1528
1529                         // make special vector since we can't use view_origin (It is one frame old as of this code, it gets set later with the results this code makes.)
1530                         vector current_view_origin = (csqcplayer ? csqcplayer.origin : pmove_org);
1531                         if (custom_eventchase)
1532                                 current_view_origin = current_view_origin_override;
1533
1534                         // detect maximum viewoffset and use it
1535                         vector view_offset = autocvar_cl_eventchase_viewoffset;
1536                         if(vehicle_chase)
1537                         {
1538                                 if(vehicle_viewofs)
1539                                         view_offset = vehicle_viewofs;
1540                                 else
1541                                         view_offset = autocvar_cl_eventchase_vehicle_viewoffset;
1542                         }
1543                         if (custom_eventchase)
1544                                 view_offset = view_offset_override;
1545
1546                         if(view_offset)
1547                         {
1548                                 WarpZone_TraceLine(current_view_origin, current_view_origin + view_offset + ('0 0 1' * autocvar_cl_eventchase_maxs.z), MOVE_WORLDONLY, this);
1549                                 if(trace_fraction == 1) { current_view_origin += view_offset; }
1550                                 else { current_view_origin.z += max(0, (trace_endpos.z - current_view_origin.z) - autocvar_cl_eventchase_maxs.z); }
1551                         }
1552
1553                         // We must enable chase_active to get a third person view (weapon viewmodel hidden and own player model showing).
1554                         // Ideally, there should be another way to enable third person cameras, such as through setproperty()
1555                         // -1 enables chase_active while marking it as set by this code, and not by the user (which would be 1)
1556                         if(!autocvar_chase_active) { cvar_set("chase_active", "-1"); }
1557
1558                         // make the camera smooth back
1559                         float chase_distance = autocvar_cl_eventchase_distance;
1560                         if(vehicle_chase)
1561                         {
1562                                 if(vehicle_viewofs)
1563                                         chase_distance = vehicle_viewdist;
1564                                 else
1565                                         chase_distance = autocvar_cl_eventchase_vehicle_distance;
1566                         }
1567                         if (custom_eventchase)
1568                                 chase_distance = chase_distance_override;
1569
1570                         if(autocvar_cl_eventchase_speed && eventchase_current_distance < chase_distance)
1571                                 eventchase_current_distance += autocvar_cl_eventchase_speed * (chase_distance - eventchase_current_distance) * frametime; // slow down the further we get
1572                         else if(eventchase_current_distance != chase_distance)
1573                                 eventchase_current_distance = chase_distance;
1574
1575                         makevectors(view_angles);
1576
1577                         vector eventchase_target_origin = (current_view_origin - (v_forward * eventchase_current_distance));
1578                         WarpZone_TraceBox(current_view_origin, autocvar_cl_eventchase_mins, autocvar_cl_eventchase_maxs, eventchase_target_origin, MOVE_WORLDONLY, this);
1579
1580                         // If the boxtrace fails, revert back to line tracing.
1581                         if(!local_player.viewloc)
1582                         if(trace_startsolid)
1583                         {
1584                                 eventchase_target_origin = (current_view_origin - (v_forward * eventchase_current_distance));
1585                                 WarpZone_TraceLine(current_view_origin, eventchase_target_origin, MOVE_WORLDONLY, this);
1586                                 setproperty(VF_ORIGIN, (trace_endpos - (v_forward * autocvar_cl_eventchase_mins.z)));
1587                         }
1588                         else { setproperty(VF_ORIGIN, trace_endpos); }
1589
1590                         if(!local_player.viewloc)
1591                                 setproperty(VF_ANGLES, WarpZone_TransformVAngles(WarpZone_trace_transform, view_angles));
1592                 }
1593                 else if(autocvar_chase_active < 0) // time to disable chase_active if it was set by this code
1594                 {
1595                         eventchase_running = false;
1596                         cvar_set("chase_active", "0");
1597                         eventchase_current_distance = 0; // start from 0 next time
1598                 }
1599         }
1600         // workaround for camera stuck between player's legs when using chase_active 1
1601         // because the engine stops updating the chase_active camera when the game ends
1602         else if(intermission)
1603         {
1604                 cvar_settemp("chase_active", "-1");
1605                 eventchase_current_distance = 0;
1606         }
1607
1608         LABEL(skip_eventchase_death);
1609
1610         // do lockview after event chase camera so that it still applies whenever necessary.
1611         if(autocvar_cl_lockview || (!autocvar_hud_cursormode && (autocvar__hud_configure && spectatee_status <= 0 || intermission > 1 || QuickMenu_IsOpened())))
1612         {
1613                 setproperty(VF_ORIGIN, freeze_org);
1614                 setproperty(VF_ANGLES, freeze_ang);
1615         }
1616         else
1617         {
1618                 freeze_org = getpropertyvec(VF_ORIGIN);
1619                 freeze_ang = getpropertyvec(VF_ANGLES);
1620         }
1621
1622         WarpZone_FixView();
1623         //WarpZone_FixPMove();
1624
1625         vector ov_org = '0 0 0';
1626         vector ov_mid = '0 0 0';
1627         vector ov_worldmin = '0 0 0';
1628         vector ov_worldmax = '0 0 0';
1629         if(autocvar_cl_orthoview)
1630         {
1631                 ov_worldmin = mi_picmin;
1632                 ov_worldmax = mi_picmax;
1633
1634                 float ov_width = (ov_worldmax.x - ov_worldmin.x);
1635                 float ov_height = (ov_worldmax.y - ov_worldmin.y);
1636                 float ov_distance = (max(vid_width, vid_height) * max(ov_width, ov_height));
1637
1638                 ov_mid = ((ov_worldmax + ov_worldmin) * 0.5);
1639                 ov_org = vec3(ov_mid.x, ov_mid.y, (ov_mid.z + ov_distance));
1640
1641                 float ov_nearest = vlen(ov_org - vec3(
1642                         bound(ov_worldmin.x, ov_org.x, ov_worldmax.x),
1643                         bound(ov_worldmin.y, ov_org.y, ov_worldmax.y),
1644                         bound(ov_worldmin.z, ov_org.z, ov_worldmax.z)
1645                 ));
1646
1647                 float ov_furthest = 0;
1648                 float dist = 0;
1649
1650                 if((dist = vdist((vec3(ov_worldmin.x, ov_worldmin.y, ov_worldmin.z) - ov_org), >, ov_furthest))) { ov_furthest = dist; }
1651                 if((dist = vdist((vec3(ov_worldmax.x, ov_worldmin.y, ov_worldmin.z) - ov_org), >, ov_furthest))) { ov_furthest = dist; }
1652                 if((dist = vdist((vec3(ov_worldmin.x, ov_worldmax.y, ov_worldmin.z) - ov_org), >, ov_furthest))) { ov_furthest = dist; }
1653                 if((dist = vdist((vec3(ov_worldmin.x, ov_worldmin.y, ov_worldmax.z) - ov_org), >, ov_furthest))) { ov_furthest = dist; }
1654                 if((dist = vdist((vec3(ov_worldmax.x, ov_worldmax.y, ov_worldmin.z) - ov_org), >, ov_furthest))) { ov_furthest = dist; }
1655                 if((dist = vdist((vec3(ov_worldmin.x, ov_worldmax.y, ov_worldmax.z) - ov_org), >, ov_furthest))) { ov_furthest = dist; }
1656                 if((dist = vdist((vec3(ov_worldmax.x, ov_worldmin.y, ov_worldmax.z) - ov_org), >, ov_furthest))) { ov_furthest = dist; }
1657                 if((dist = vdist((vec3(ov_worldmax.x, ov_worldmax.y, ov_worldmax.z) - ov_org), >, ov_furthest))) { ov_furthest = dist; }
1658
1659                 if(!ov_enabled)
1660                 {
1661                         oldr_nearclip = cvar("r_nearclip");
1662                         oldr_farclip_base = cvar("r_farclip_base");
1663                         oldr_farclip_world = cvar("r_farclip_world");
1664                         oldr_novis = cvar("r_novis");
1665                         oldr_useportalculling = cvar("r_useportalculling");
1666                         oldr_useinfinitefarclip = cvar("r_useinfinitefarclip");
1667                 }
1668
1669                 cvar_settemp("r_nearclip", ftos(ov_nearest));
1670                 cvar_settemp("r_farclip_base", ftos(ov_furthest));
1671                 cvar_settemp("r_farclip_world", "0");
1672                 cvar_settemp("r_novis", "1");
1673                 cvar_settemp("r_useportalculling", "0");
1674                 cvar_settemp("r_useinfinitefarclip", "0");
1675
1676                 setproperty(VF_ORIGIN, ov_org);
1677                 setproperty(VF_ANGLES, '90 0 0');
1678
1679                 ov_enabled = true;
1680
1681                 #if 0
1682                 LOG_INFOF("OrthoView: org = %s, angles = %s, distance = %f, nearest = %f, furthest = %f\n",
1683                         vtos(ov_org),
1684                         vtos(getpropertyvec(VF_ANGLES)),
1685                         ov_distance,
1686                         ov_nearest,
1687                         ov_furthest);
1688                 #endif
1689         }
1690         else
1691         {
1692                 if(ov_enabled)
1693                 {
1694                         cvar_set("r_nearclip", ftos(oldr_nearclip));
1695                         cvar_set("r_farclip_base", ftos(oldr_farclip_base));
1696                         cvar_set("r_farclip_world", ftos(oldr_farclip_world));
1697                         cvar_set("r_novis", ftos(oldr_novis));
1698                         cvar_set("r_useportalculling", ftos(oldr_useportalculling));
1699                         cvar_set("r_useinfinitefarclip", ftos(oldr_useinfinitefarclip));
1700                 }
1701                 ov_enabled = false;
1702         }
1703
1704         // run viewmodel_draw before updating view_angles to the angles calculated by WarpZone_FixView
1705         // viewmodel_draw needs to use the view_angles set by the engine on every CSQC_UpdateView call
1706         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
1707                 viewmodel_draw(viewmodels[slot]);
1708
1709         // Render the Scene
1710         view_origin = getpropertyvec(VF_ORIGIN);
1711         view_angles = getpropertyvec(VF_ANGLES);
1712         makevectors(view_angles);
1713         view_forward = v_forward;
1714         view_right = v_right;
1715         view_up = v_up;
1716
1717 #ifdef BLURTEST
1718         if(time > blurtest_time0 && time < blurtest_time1)
1719         {
1720                 float r, t;
1721
1722                 t = (time - blurtest_time0) / (blurtest_time1 - blurtest_time0);
1723                 r = t * blurtest_radius;
1724                 f = 1 / pow(t, blurtest_power) - 1;
1725
1726                 cvar_set("r_glsl_postprocess", "1");
1727                 cvar_set("r_glsl_postprocess_uservec1", strcat(ftos(r), " ", ftos(f), " 0 0"));
1728         }
1729         else
1730         {
1731                 cvar_set("r_glsl_postprocess", "0");
1732                 cvar_set("r_glsl_postprocess_uservec1", "0 0 0 0");
1733         }
1734 #endif
1735
1736         TargetMusic_Advance();
1737         Fog_Force();
1738
1739         if(drawtime == 0)
1740                 drawframetime = 0.01666667; // when we don't know fps yet, we assume 60fps
1741         else
1742                 drawframetime = bound(0.000001, time - drawtime, 1);
1743         drawtime = time;
1744
1745         // watch for gametype changes here...
1746         // in ParseStuffCMD the cmd isn't executed yet :/
1747         // might even be better to add the gametype to TE_CSQC_INIT...?
1748         if(!postinit)
1749                 PostInit();
1750
1751         if(intermission && !gameover_time)
1752                 gameover_time = time;
1753
1754         if(intermission && !isdemo() && !(calledhooks & HOOK_END))
1755         {
1756                 if(calledhooks & HOOK_START)
1757                 {
1758                         localcmd("\ncl_hook_gameend\n");
1759                         calledhooks |= HOOK_END;
1760                 }
1761         }
1762
1763         Announcer();
1764
1765         fov = autocvar_fov;
1766         if(fov <= 59.5)
1767         {
1768                 if(!zoomscript_caught)
1769                 {
1770                         localcmd("+button9\n");
1771                         zoomscript_caught = 1;
1772                 }
1773         }
1774         else
1775         {
1776                 if(zoomscript_caught)
1777                 {
1778                         localcmd("-button9\n");
1779                         zoomscript_caught = 0;
1780                 }
1781         }
1782
1783         ColorTranslateMode = autocvar_cl_stripcolorcodes;
1784
1785         entity wepent = viewmodels[0]; // TODO: unhardcode
1786
1787         if(last_switchweapon != wepent.switchweapon)
1788         {
1789                 weapontime = time;
1790                 last_switchweapon = wepent.switchweapon;
1791                 if(button_zoom && autocvar_cl_unpress_zoom_on_weapon_switch)
1792                 {
1793                         localcmd("-zoom\n");
1794                         button_zoom = false;
1795                 }
1796                 if(autocvar_cl_unpress_attack_on_weapon_switch)
1797                 {
1798                         localcmd("-fire\n");
1799                         localcmd("-fire2\n");
1800                         button_attack2 = false;
1801                 }
1802         }
1803         if(last_activeweapon != wepent.activeweapon)
1804         {
1805                 last_activeweapon = wepent.activeweapon;
1806
1807                 e = wepent.activeweapon;
1808                 if(e.netname != "")
1809                         localcmd(strcat("\ncl_hook_activeweapon ", e.netname), "\n");
1810                 else
1811                         localcmd("\ncl_hook_activeweapon none\n");
1812         }
1813
1814         // ALWAYS Clear Current Scene First
1815         clearscene();
1816
1817         setproperty(VF_ORIGIN, view_origin);
1818         setproperty(VF_ANGLES, view_angles);
1819
1820         // FIXME engine bug? VF_SIZE and VF_MIN are not restored to sensible values by this
1821         setproperty(VF_SIZE, vf_size);
1822         setproperty(VF_MIN, vf_min);
1823
1824         // Assign Standard Viewflags
1825         // Draw the World (and sky)
1826         setproperty(VF_DRAWWORLD, 1);
1827
1828         // Set the console size vars
1829         vid_conwidth = autocvar_vid_conwidth;
1830         vid_conheight = autocvar_vid_conheight;
1831         vid_pixelheight = autocvar_vid_pixelheight;
1832
1833         if(autocvar_cl_orthoview) { setproperty(VF_FOV, GetOrthoviewFOV(ov_worldmin, ov_worldmax, ov_mid, ov_org)); }
1834         else if(csqcplayer.viewloc) { setproperty(VF_FOV, GetViewLocationFOV(110)); } // enforce 110 fov, so things dont look odd
1835         else { setproperty(VF_FOV, GetCurrentFov(fov)); }
1836
1837         if(camera_active) // Camera for demo playback
1838         {
1839                 if(autocvar_camera_enable)
1840                         CSQC_Demo_Camera();
1841                 else
1842                 {
1843                         cvar_set("chase_active", ftos(chase_active_backup));
1844                         cvar_set("cl_demo_mousegrab", "0");
1845                         camera_active = false;
1846                 }
1847         }
1848         else
1849         {
1850 #ifdef CAMERATEST
1851                 if(autocvar_camera_enable)
1852 #else
1853                 if(autocvar_camera_enable && isdemo())
1854 #endif
1855                 {
1856                         // Enable required Darkplaces cvars
1857                         chase_active_backup = autocvar_chase_active;
1858                         cvar_set("chase_active", "2");
1859                         cvar_set("cl_demo_mousegrab", "1");
1860                         camera_active = true;
1861                         camera_mode = false;
1862                 }
1863         }
1864
1865         // Draw the Crosshair
1866         setproperty(VF_DRAWCROSSHAIR, 0); //Make sure engine crosshairs are always hidden
1867
1868         // Draw the Engine Status Bar (the default Quake HUD)
1869         setproperty(VF_DRAWENGINESBAR, 0);
1870
1871         // Update the mouse position
1872         /*
1873            mousepos_x = vid_conwidth;
1874            mousepos_y = vid_conheight;
1875            mousepos = mousepos*0.5 + getmousepos();
1876          */
1877
1878         IL_EACH(g_drawables, it.draw, it.draw(it));
1879
1880         addentities(MASK_NORMAL | MASK_ENGINE | MASK_ENGINEVIEWMODELS);
1881         renderscene();
1882
1883         // now switch to 2D drawing mode by calling a 2D drawing function
1884         // then polygon drawing will draw as 2D stuff, and NOT get queued until the
1885         // next R_RenderScene call
1886         drawstring('0 0 0', "", '1 1 0', '1 1 1', 0, 0);
1887
1888         if(autocvar_r_fakelight >= 2 || autocvar_r_fullbright)
1889         if (!(serverflags & SERVERFLAG_ALLOW_FULLBRIGHT))
1890         {
1891                 // apply night vision effect
1892                 vector tc_00, tc_01, tc_10, tc_11;
1893                 vector rgb = '0 0 0';
1894
1895                 if(!nightvision_noise)
1896                 {
1897                         nightvision_noise = new(nightvision_noise);
1898                 }
1899                 if(!nightvision_noise2)
1900                 {
1901                         nightvision_noise2 = new(nightvision_noise2);
1902                 }
1903
1904                 // color tint in yellow
1905                 drawfill('0 0 0', autocvar_vid_conwidth * '1 0 0' + autocvar_vid_conheight * '0 1 0', '0.5 1 0.3', 1, DRAWFLAG_MODULATE);
1906
1907                 // draw BG
1908                 a = Noise_Pink(nightvision_noise, frametime * 1.5) * 0.05 + 0.15;
1909                 rgb = '1 1 1';
1910                 tc_00 = '0 0 0' + '0.2 0 0' * sin(time * 0.3) + '0 0.3 0' * cos(time * 0.7);
1911                 tc_01 = '0 2.25 0' + '0.6 0 0' * cos(time * 1.2) - '0 0.3 0' * sin(time * 2.2);
1912                 tc_10 = '1.5 0 0' - '0.2 0 0' * sin(time * 0.5) + '0 0.5 0' * cos(time * 1.7);
1913                 //tc_11 = '1 1 0' + '0.6 0 0' * sin(time * 0.6) + '0 0.3 0' * cos(time * 0.1);
1914                 tc_11 = tc_01 + tc_10 - tc_00;
1915                 R_BeginPolygon("gfx/nightvision-bg.tga", DRAWFLAG_ADDITIVE);
1916                 R_PolygonVertex('0 0 0', tc_00, rgb, a);
1917                 R_PolygonVertex(autocvar_vid_conwidth * '1 0 0', tc_10, rgb, a);
1918                 R_PolygonVertex(autocvar_vid_conwidth * '1 0 0' + autocvar_vid_conheight * '0 1 0', tc_11, rgb, a);
1919                 R_PolygonVertex(autocvar_vid_conheight * '0 1 0', tc_01, rgb, a);
1920                 R_EndPolygon();
1921
1922                 // draw FG
1923                 a = Noise_Pink(nightvision_noise2, frametime * 0.1) * 0.05 + 0.12;
1924                 rgb = '0.3 0.6 0.4' + '0.1 0.4 0.2' * Noise_White(nightvision_noise2, frametime);
1925                 tc_00 = '0 0 0' + '1 0 0' * Noise_White(nightvision_noise2, frametime) + '0 1 0' * Noise_White(nightvision_noise2, frametime);
1926                 tc_01 = tc_00 + '0 3 0' * (1 + Noise_White(nightvision_noise2, frametime) * 0.2);
1927                 tc_10 = tc_00 + '2 0 0' * (1 + Noise_White(nightvision_noise2, frametime) * 0.3);
1928                 tc_11 = tc_01 + tc_10 - tc_00;
1929                 R_BeginPolygon("gfx/nightvision-fg.tga", DRAWFLAG_ADDITIVE);
1930                 R_PolygonVertex('0 0 0', tc_00, rgb, a);
1931                 R_PolygonVertex(autocvar_vid_conwidth * '1 0 0', tc_10, rgb, a);
1932                 R_PolygonVertex(autocvar_vid_conwidth * '1 0 0' + autocvar_vid_conheight * '0 1 0', tc_11, rgb, a);
1933                 R_PolygonVertex(autocvar_vid_conheight * '0 1 0', tc_01, rgb, a);
1934                 R_EndPolygon();
1935         }
1936
1937         if(autocvar_cl_reticle)
1938         {
1939                 string reticle_image = wepent.activeweapon.w_reticle;
1940                 bool wep_zoomed = false;
1941                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
1942                 {
1943                         entity wepe = viewmodels[slot];
1944                         Weapon wep = wepe.activeweapon;
1945                         if(wep != WEP_Null && wep.wr_zoom)
1946                         {
1947                                 bool do_zoom = wep.wr_zoom(wep, NULL);
1948                                 reticle_image = wep.w_reticle;
1949                                 wep_zoomed += do_zoom;
1950                         }
1951                 }
1952                 // Draw the aiming reticle for weapons that use it
1953                 // reticle_type is changed to the item we are zooming / aiming with, to decide which reticle to use
1954                 // It must be a persisted float for fading out to work properly (you let go of the zoom button for
1955                 // the view to go back to normal, so reticle_type would become 0 as we fade out)
1956                 if(spectatee_status || is_dead || hud != HUD_NORMAL)
1957                 {
1958                         // no zoom reticle while dead
1959                         reticle_type = 0;
1960                 }
1961                 else if(wep_zoomed && autocvar_cl_reticle_weapon)
1962                 {
1963                         if(reticle_image && reticle_image != "") { reticle_type = 2; }
1964                         else { reticle_type = 0; }
1965                 }
1966                 else if(button_zoom || zoomscript_caught)
1967                 {
1968                         // normal zoom
1969                         reticle_type = 1;
1970                 }
1971
1972                 if(reticle_type)
1973                 {
1974                         if(autocvar_cl_reticle_stretch)
1975                         {
1976                                 reticle_size.x = vid_conwidth;
1977                                 reticle_size.y = vid_conheight;
1978                                 reticle_pos.x = 0;
1979                                 reticle_pos.y = 0;
1980                         }
1981                         else
1982                         {
1983                                 reticle_size.x = max(vid_conwidth, vid_conheight);
1984                                 reticle_size.y = max(vid_conwidth, vid_conheight);
1985                                 reticle_pos.x = (vid_conwidth - reticle_size.x) / 2;
1986                                 reticle_pos.y = (vid_conheight - reticle_size.y) / 2;
1987                         }
1988
1989                         if(zoomscript_caught)
1990                                 f = 1;
1991                         else
1992                                 f = current_zoomfraction;
1993
1994                         if(f)
1995                         {
1996                                 switch(reticle_type)
1997                                 {
1998                                         case 1: drawpic(reticle_pos, "gfx/reticle_normal", reticle_size, '1 1 1', f * autocvar_cl_reticle_normal_alpha, DRAWFLAG_NORMAL); break;
1999                                         case 2: drawpic(reticle_pos, reticle_image, reticle_size, '1 1 1', f * autocvar_cl_reticle_weapon_alpha, DRAWFLAG_NORMAL); break;
2000                                 }
2001                         }
2002                 }
2003         }
2004         else
2005         {
2006                 if(reticle_type != 0) { reticle_type = 0; }
2007         }
2008
2009
2010         // improved polyblend
2011         if(autocvar_hud_contents)
2012         {
2013                 float contentalpha_temp, incontent, liquidalpha, contentfadetime;
2014                 vector liquidcolor;
2015
2016                 switch(pointcontents(view_origin))
2017                 {
2018                         case CONTENT_WATER:
2019                                 liquidalpha = autocvar_hud_contents_water_alpha;
2020                                 liquidcolor = stov(autocvar_hud_contents_water_color);
2021                                 incontent = 1;
2022                                 break;
2023
2024                         case CONTENT_LAVA:
2025                                 liquidalpha = autocvar_hud_contents_lava_alpha;
2026                                 liquidcolor = stov(autocvar_hud_contents_lava_color);
2027                                 incontent = 1;
2028                                 break;
2029
2030                         case CONTENT_SLIME:
2031                                 liquidalpha = autocvar_hud_contents_slime_alpha;
2032                                 liquidcolor = stov(autocvar_hud_contents_slime_color);
2033                                 incontent = 1;
2034                                 break;
2035
2036                         default:
2037                                 liquidalpha = 0;
2038                                 liquidcolor = '0 0 0';
2039                                 incontent = 0;
2040                                 break;
2041                 }
2042
2043                 if(incontent) // fade in/out at different speeds so you can do e.g. instant fade when entering water and slow when leaving it.
2044                 { // also lets delcare previous values for blending properties, this way it isn't reset until after you have entered a different content
2045                         contentfadetime = autocvar_hud_contents_fadeintime;
2046                         liquidalpha_prev = liquidalpha;
2047                         liquidcolor_prev = liquidcolor;
2048                 }
2049                 else
2050                         contentfadetime = autocvar_hud_contents_fadeouttime;
2051
2052                 contentalpha_temp = bound(0, drawframetime / max(0.0001, contentfadetime), 1);
2053                 contentavgalpha = contentavgalpha * (1 - contentalpha_temp) + incontent * contentalpha_temp;
2054
2055                 if(contentavgalpha)
2056                         drawfill('0 0 0', eX * vid_conwidth + eY * vid_conheight, liquidcolor_prev, contentavgalpha * liquidalpha_prev, DRAWFLAG_NORMAL);
2057
2058                 if(autocvar_hud_postprocessing)
2059                 {
2060                         if(autocvar_hud_contents_blur && contentavgalpha)
2061                         {
2062                                 content_blurpostprocess.x = 1;
2063                                 content_blurpostprocess.y = contentavgalpha * autocvar_hud_contents_blur;
2064                                 content_blurpostprocess.z = contentavgalpha * autocvar_hud_contents_blur_alpha;
2065                         }
2066                         else
2067                         {
2068                                 content_blurpostprocess.x = 0;
2069                                 content_blurpostprocess.y = 0;
2070                                 content_blurpostprocess.z = 0;
2071                         }
2072                 }
2073         }
2074
2075         if(autocvar_hud_damage && !STAT(FROZEN))
2076         {
2077                 splash_size.x = max(vid_conwidth, vid_conheight);
2078                 splash_size.y = max(vid_conwidth, vid_conheight);
2079                 splash_pos.x = (vid_conwidth - splash_size.x) / 2;
2080                 splash_pos.y = (vid_conheight - splash_size.y) / 2;
2081
2082                 float myhealth_flash_temp;
2083                 myhealth = STAT(HEALTH);
2084
2085                 // fade out
2086                 myhealth_flash = max(0, myhealth_flash - autocvar_hud_damage_fade_rate * frametime);
2087                 // add new damage
2088                 myhealth_flash = bound(0, myhealth_flash + dmg_take * autocvar_hud_damage_factor, autocvar_hud_damage_maxalpha);
2089
2090                 float pain_threshold, pain_threshold_lower, pain_threshold_lower_health;
2091                 pain_threshold = autocvar_hud_damage_pain_threshold;
2092                 pain_threshold_lower = autocvar_hud_damage_pain_threshold_lower;
2093                 pain_threshold_lower_health = autocvar_hud_damage_pain_threshold_lower_health;
2094
2095                 if(pain_threshold_lower && myhealth < pain_threshold_lower_health)
2096                 {
2097                         pain_threshold = pain_threshold - max(autocvar_hud_damage_pain_threshold_pulsating_min, fabs(sin(M_PI * time / autocvar_hud_damage_pain_threshold_pulsating_period))) * pain_threshold_lower * (1 - max(0, myhealth)/pain_threshold_lower_health);
2098                 }
2099
2100                 myhealth_flash_temp = bound(0, myhealth_flash - pain_threshold, 1);
2101
2102                 if(myhealth_prev < 1)
2103                 {
2104                         if(myhealth >= 1)
2105                         {
2106                                 myhealth_flash = 0; // just spawned, clear the flash immediately
2107                                 myhealth_flash_temp = 0;
2108                         }
2109                         else
2110                         {
2111                                 myhealth_flash += autocvar_hud_damage_fade_rate * frametime; // dead
2112                         }
2113                 }
2114
2115                 if(spectatee_status == -1 || intermission)
2116                 {
2117                         myhealth_flash = 0; // observing, or match ended
2118                         myhealth_flash_temp = 0;
2119                 }
2120
2121                 myhealth_prev = myhealth;
2122
2123                 // IDEA: change damage color/picture based on player model for robot/alien species?
2124                 // pro: matches model better
2125                 // contra: it's not red because blood is red, but because red is an alarming color, so red should stay
2126                 // maybe different reddish pics?
2127                 if(autocvar_cl_gentle_damage || autocvar_cl_gentle)
2128                 {
2129                         if(autocvar_cl_gentle_damage == 2)
2130                         {
2131                                 if(myhealth_flash < pain_threshold) // only randomize when the flash is gone
2132                                         myhealth_gentlergb = eX * random() + eY * random() + eZ * random();
2133                         }
2134                         else
2135                                 myhealth_gentlergb = stov(autocvar_hud_damage_gentle_color);
2136
2137                         if(myhealth_flash_temp > 0)
2138                                 drawfill('0 0 0', eX * vid_conwidth + eY * vid_conheight, myhealth_gentlergb, autocvar_hud_damage_gentle_alpha_multiplier * bound(0, myhealth_flash_temp, 1) * autocvar_hud_damage, DRAWFLAG_NORMAL);
2139                 }
2140                 else if(myhealth_flash_temp > 0)
2141                         drawpic(splash_pos, "gfx/blood", splash_size, stov(autocvar_hud_damage_color), bound(0, myhealth_flash_temp, 1) * autocvar_hud_damage, DRAWFLAG_NORMAL);
2142
2143                 if(autocvar_hud_postprocessing) // we still need to set this anyway even when chase_active is set, this way it doesn't get stuck on.
2144                 {
2145                         if(autocvar_hud_damage_blur && myhealth_flash_temp)
2146                         {
2147                                 damage_blurpostprocess.x = 1;
2148                                 damage_blurpostprocess.y = bound(0, myhealth_flash_temp, 1) * autocvar_hud_damage_blur;
2149                                 damage_blurpostprocess.z = bound(0, myhealth_flash_temp, 1) * autocvar_hud_damage_blur_alpha;
2150                         }
2151                         else
2152                         {
2153                                 damage_blurpostprocess.x = 0;
2154                                 damage_blurpostprocess.y = 0;
2155                                 damage_blurpostprocess.z = 0;
2156                         }
2157                 }
2158         }
2159
2160         float e1 = (autocvar_hud_postprocessing_maxbluralpha != 0);
2161         float e2 = (autocvar_hud_powerup != 0);
2162         if(autocvar_hud_postprocessing && (e1 || e2)) // TODO: Remove this code and re-do the postprocess handling in the engine, where it properly belongs.
2163         {
2164                 // enable or disable rendering types if they are used or not
2165                 if(cvar("r_glsl_postprocess_uservec1_enable") != e1) { cvar_set("r_glsl_postprocess_uservec1_enable", ftos(e1)); }
2166                 if(cvar("r_glsl_postprocess_uservec2_enable") != e2) { cvar_set("r_glsl_postprocess_uservec2_enable", ftos(e2)); }
2167
2168                 // blur postprocess handling done first (used by hud_damage and hud_contents)
2169                 if((damage_blurpostprocess.x || content_blurpostprocess.x))
2170                 {
2171                         float blurradius = bound(0, damage_blurpostprocess.y + content_blurpostprocess.y, autocvar_hud_postprocessing_maxblurradius);
2172                         float bluralpha = bound(0, damage_blurpostprocess.z + content_blurpostprocess.z, autocvar_hud_postprocessing_maxbluralpha);
2173                         if(blurradius != old_blurradius || bluralpha != old_bluralpha) // reduce cvar_set spam as much as possible
2174                         {
2175                                 cvar_set("r_glsl_postprocess_uservec1", strcat(ftos(blurradius), " ", ftos(bluralpha), " 0 0"));
2176                                 old_blurradius = blurradius;
2177                                 old_bluralpha = bluralpha;
2178                         }
2179                 }
2180                 else if(cvar_string("r_glsl_postprocess_uservec1") != "0 0 0 0") // reduce cvar_set spam as much as possible
2181                 {
2182                         cvar_set("r_glsl_postprocess_uservec1", "0 0 0 0");
2183                         old_blurradius = 0;
2184                         old_bluralpha = 0;
2185                 }
2186
2187                 // edge detection postprocess handling done second (used by hud_powerup)
2188                 float sharpen_intensity = 0, strength_finished = STAT(STRENGTH_FINISHED), invincible_finished = STAT(INVINCIBLE_FINISHED);
2189                 if (strength_finished - time > 0) { sharpen_intensity += (strength_finished - time); }
2190                 if (invincible_finished - time > 0) { sharpen_intensity += (invincible_finished - time); }
2191
2192                 sharpen_intensity = bound(0, ((STAT(HEALTH) > 0) ? sharpen_intensity : 0), 5); // Check to see if player is alive (if not, set 0) - also bound to fade out starting at 5 seconds.
2193
2194                 if(autocvar_hud_powerup && sharpen_intensity > 0)
2195                 {
2196                         if(sharpen_intensity != old_sharpen_intensity) // reduce cvar_set spam as much as possible
2197                         {
2198                                 cvar_set("r_glsl_postprocess_uservec2", strcat(ftos((sharpen_intensity / 5) * autocvar_hud_powerup), " ", ftos(-sharpen_intensity * autocvar_hud_powerup), " 0 0"));
2199                                 old_sharpen_intensity = sharpen_intensity;
2200                         }
2201                 }
2202                 else if(cvar_string("r_glsl_postprocess_uservec2") != "0 0 0 0") // reduce cvar_set spam as much as possible
2203                 {
2204                         cvar_set("r_glsl_postprocess_uservec2", "0 0 0 0");
2205                         old_sharpen_intensity = 0;
2206                 }
2207
2208                 if(cvar("r_glsl_postprocess") == 0)
2209                         cvar_set("r_glsl_postprocess", "2");
2210         }
2211         else if(cvar("r_glsl_postprocess") == 2)
2212                 cvar_set("r_glsl_postprocess", "0");
2213
2214         /*if(gametype == MAPINFO_TYPE_CTF)
2215           {
2216           ctf_view();
2217           } else */
2218
2219         // draw 2D entities
2220         IL_EACH(g_drawables_2d, it.draw2d, it.draw2d(it));
2221         Draw_ShowNames_All();
2222         Debug_Draw();
2223
2224         scoreboard_active = Scoreboard_WouldDraw();
2225
2226         HUD_Draw(this); // this parameter for deep vehicle function
2227
2228         if(NextFrameCommand)
2229         {
2230                 localcmd("\n", NextFrameCommand, "\n");
2231                 NextFrameCommand = string_null;
2232         }
2233
2234         // we must do this check AFTER a frame was rendered, or it won't work
2235         if(cs_project_is_b0rked == 0)
2236         {
2237                 string w0, h0;
2238                 w0 = ftos(autocvar_vid_conwidth);
2239                 h0 = ftos(autocvar_vid_conheight);
2240                 //setproperty(VF_VIEWPORT, '0 0 0', '640 480 0');
2241                 //setproperty(VF_FOV, '90 90 0');
2242                 setproperty(VF_ORIGIN, '0 0 0');
2243                 setproperty(VF_ANGLES, '0 0 0');
2244                 setproperty(VF_PERSPECTIVE, 1);
2245                 makevectors('0 0 0');
2246                 vector v1, v2;
2247                 cvar_set("vid_conwidth", "800");
2248                 cvar_set("vid_conheight", "600");
2249                 v1 = cs_project(v_forward);
2250                 cvar_set("vid_conwidth", "640");
2251                 cvar_set("vid_conheight", "480");
2252                 v2 = cs_project(v_forward);
2253                 if(v1 == v2)
2254                         cs_project_is_b0rked = 1;
2255                 else
2256                         cs_project_is_b0rked = -1;
2257                 cvar_set("vid_conwidth", w0);
2258                 cvar_set("vid_conheight", h0);
2259         }
2260
2261         if(autocvar__hud_configure)
2262                 HUD_Panel_Mouse();
2263         else if (HUD_MinigameMenu_IsOpened() || active_minigame)
2264                 HUD_Minigame_Mouse();
2265         else if(QuickMenu_IsOpened())
2266                 QuickMenu_Mouse();
2267         else
2268                 HUD_Radar_Mouse();
2269
2270         cl_notice_run();
2271         unpause_update();
2272         Net_Flush();
2273
2274         // let's reset the view back to normal for the end
2275         setproperty(VF_MIN, '0 0 0');
2276         setproperty(VF_SIZE, '1 0 0' * w + '0 1 0' * h);
2277
2278         IL_ENDFRAME();
2279 }
2280
2281
2282 // following vectors must be global to allow seamless switching between camera modes
2283 vector camera_offset, current_camera_offset, mouse_angles, current_angles, current_origin, current_position;
2284 void CSQC_Demo_Camera()
2285 {
2286         float speed, attenuation, dimensions;
2287         vector tmp, delta;
2288
2289         if( autocvar_camera_reset || !camera_mode )
2290         {
2291                 camera_offset = '0 0 0';
2292                 current_angles = '0 0 0';
2293                 camera_direction = '0 0 0';
2294                 camera_offset.z += 30;
2295                 camera_offset.x += 30 * -cos(current_angles.y * DEG2RAD);
2296                 camera_offset.y += 30 * -sin(current_angles.y * DEG2RAD);
2297                 current_origin = view_origin;
2298                 current_camera_offset  = camera_offset;
2299                 cvar_set("camera_reset", "0");
2300                 camera_mode = CAMERA_CHASE;
2301         }
2302
2303         // Camera angles
2304         if( camera_roll )
2305                 mouse_angles.z += camera_roll * autocvar_camera_speed_roll;
2306
2307         if(autocvar_camera_look_player)
2308         {
2309                 vector dir;
2310                 float n;
2311
2312                 dir = normalize(view_origin - current_position);
2313                 n = mouse_angles.z;
2314                 mouse_angles = vectoangles(dir);
2315                 mouse_angles.x = mouse_angles.x * -1;
2316                 mouse_angles.z = n;
2317         }
2318         else
2319         {
2320                 tmp = getmousepos() * 0.1;
2321                 if(vdist(tmp, >, autocvar_camera_mouse_threshold))
2322                 {
2323                         mouse_angles.x += tmp.y * cos(mouse_angles.z * DEG2RAD) + (tmp.x * sin(mouse_angles.z * DEG2RAD));
2324                         mouse_angles.y -= tmp.x * cos(mouse_angles.z * DEG2RAD) + (tmp.y * -sin(mouse_angles.z * DEG2RAD));
2325                 }
2326         }
2327
2328         while (mouse_angles.x < -180) mouse_angles.x = mouse_angles.x + 360;
2329         while (mouse_angles.x > 180) mouse_angles.x = mouse_angles.x - 360;
2330         while (mouse_angles.y < -180) mouse_angles.y = mouse_angles.y + 360;
2331         while (mouse_angles.y > 180) mouse_angles.y = mouse_angles.y - 360;
2332
2333         // Fix difference when angles don't have the same sign
2334         delta = '0 0 0';
2335         if(mouse_angles.y < -60 && current_angles.y > 60)
2336                 delta = '0 360 0';
2337         if(mouse_angles.y > 60 && current_angles.y < -60)
2338                 delta = '0 -360 0';
2339
2340         if(autocvar_camera_look_player)
2341                 attenuation = autocvar_camera_look_attenuation;
2342         else
2343                 attenuation = autocvar_camera_speed_attenuation;
2344
2345         attenuation = 1 / max(1, attenuation);
2346         current_angles += (mouse_angles - current_angles + delta) * attenuation;
2347
2348         while (current_angles.x < -180) current_angles.x = current_angles.x + 360;
2349         while (current_angles.x > 180) current_angles.x = current_angles.x - 360;
2350         while (current_angles.y < -180) current_angles.y = current_angles.y + 360;
2351         while (current_angles.y > 180) current_angles.y = current_angles.y - 360;
2352
2353         // Camera position
2354         tmp = '0 0 0';
2355         dimensions = 0;
2356
2357         if( camera_direction.x )
2358         {
2359                 tmp.x = camera_direction.x * cos(current_angles.y * DEG2RAD);
2360                 tmp.y = camera_direction.x * sin(current_angles.y * DEG2RAD);
2361                 if( autocvar_camera_forward_follows && !autocvar_camera_look_player )
2362                         tmp.z = camera_direction.x * -sin(current_angles.x * DEG2RAD);
2363                 ++dimensions;
2364         }
2365
2366         if( camera_direction.y )
2367         {
2368                 tmp.x += camera_direction.y * -sin(current_angles.y * DEG2RAD);
2369                 tmp.y += camera_direction.y * cos(current_angles.y * DEG2RAD) * cos(current_angles.z * DEG2RAD);
2370                 tmp.z += camera_direction.y * sin(current_angles.z * DEG2RAD);
2371                 ++dimensions;
2372         }
2373
2374         if( camera_direction.z )
2375         {
2376                 tmp.z += camera_direction.z * cos(current_angles.z * DEG2RAD);
2377                 ++dimensions;
2378         }
2379
2380         if(autocvar_camera_free)
2381                 speed = autocvar_camera_speed_free;
2382         else
2383                 speed = autocvar_camera_speed_chase;
2384
2385         if(dimensions)
2386         {
2387                 speed = speed * sqrt(1 / dimensions);
2388                 camera_offset += tmp * speed;
2389         }
2390
2391         current_camera_offset += (camera_offset - current_camera_offset) * attenuation;
2392
2393         // Camera modes
2394         if( autocvar_camera_free )
2395         {
2396                 if ( camera_mode == CAMERA_CHASE )
2397                 {
2398                         current_camera_offset = current_origin + current_camera_offset;
2399                         camera_offset = current_origin + camera_offset;
2400                 }
2401
2402                 camera_mode = CAMERA_FREE;
2403                 current_position = current_camera_offset;
2404         }
2405         else
2406         {
2407                 if ( camera_mode == CAMERA_FREE )
2408                 {
2409                         current_origin = view_origin;
2410                         camera_offset = camera_offset - current_origin;
2411                         current_camera_offset = current_camera_offset - current_origin;
2412                 }
2413
2414                 camera_mode = CAMERA_CHASE;
2415
2416                 if(autocvar_camera_chase_smoothly)
2417                         current_origin += (view_origin - current_origin) * attenuation;
2418                 else
2419                         current_origin = view_origin;
2420
2421                 current_position = current_origin + current_camera_offset;
2422         }
2423
2424         setproperty(VF_ANGLES, current_angles);
2425         setproperty(VF_ORIGIN, current_position);
2426 }