qcsrc/client/view.qc

   1
   2 #include "announcer.qh"
   3 #include "hud/all.qh"
   4 #include "mapvoting.qh"
   5 #include "scoreboard.qh"
   6 #include "shownames.qh"
   7 #include "quickmenu.qh"
   8
   9 #include "mutators/events.qh"
  10
  11 #include "../common/anim.qh"
  12 #include "../common/constants.qh"
  13 #include "../common/debug.qh"
  14 #include "../common/mapinfo.qh"
  15 #include <common/gamemodes/all.qh>
  16 #include "../common/physics/player.qh"
  17 #include "../common/stats.qh"
  18 #include "../common/triggers/target/music.qh"
  19 #include "../common/teams.qh"
  20
  21 #include <common/vehicles/all.qh>
  22 #include <common/weapons/all.qh>
  23 #include "../common/viewloc.qh"
  24 #include "../common/minigames/cl_minigames.qh"
  25 #include "../common/minigames/cl_minigames_hud.qh"
  26
  27 #include "../lib/csqcmodel/cl_player.qh"
  28
  29 #include "../lib/warpzone/client.qh"
  30 #include "../lib/warpzone/common.qh"
  31
  32 #define EFMASK_CHEAP (EF_ADDITIVE | EF_DOUBLESIDED | EF_FULLBRIGHT | EF_NODEPTHTEST | EF_NODRAW | EF_NOSHADOW | EF_SELECTABLE | EF_TELEPORT_BIT)
  33
  34 float autocvar_cl_viewmodel_scale;
  35
  36 bool autocvar_cl_bobmodel;
  37 float autocvar_cl_bobmodel_speed;
  38 float autocvar_cl_bobmodel_side;
  39 float autocvar_cl_bobmodel_up;
  40
  41 float autocvar_cl_followmodel;
  42 float autocvar_cl_followmodel_speed = 0.3;
  43 float autocvar_cl_followmodel_limit = 1000;
  44 float autocvar_cl_followmodel_highpass1 = 0.05;
  45 float autocvar_cl_followmodel_highpass = 0.05;
  46 float autocvar_cl_followmodel_lowpass = 0.03;
  47
  48 float autocvar_cl_leanmodel;
  49 float autocvar_cl_leanmodel_speed = 0.3;
  50 float autocvar_cl_leanmodel_limit = 1000;
  51 float autocvar_cl_leanmodel_highpass1 = 0.2;
  52 float autocvar_cl_leanmodel_highpass = 0.2;
  53 float autocvar_cl_leanmodel_lowpass = 0.05;
  54
  55 #define avg_factor(avg_time) (1 - exp(-frametime / max(0.001, avg_time)))
  56 #define lowpass(value, frac, ref_store, ret) MACRO_BEGIN \
  57 { \
  58         ret = ref_store = ref_store * (1 - frac) + (value) * frac; \
  59 } MACRO_END
  60
  61 #define lowpass_limited(value, frac, limit, ref_store, ret) MACRO_BEGIN \
  62 { \
  63         float __ignore; lowpass(value, frac, ref_store, __ignore); \
  64         ret = ref_store = bound((value) - (limit), ref_store, (value) + (limit)); \
  65 } MACRO_END
  66
  67 #define highpass(value, frac, ref_store, ret) MACRO_BEGIN \
  68 { \
  69         float __f = 0; lowpass(value, frac, ref_store, __f); \
  70         ret = (value) - __f; \
  71 } MACRO_END
  72
  73 #define highpass_limited(value, frac, limit, ref_store, ret) MACRO_BEGIN \
  74 { \
  75         float __f = 0; lowpass_limited(value, frac, limit, ref_store, __f); \
  76         ret = (value) - __f; \
  77 } MACRO_END
  78
  79 #define lowpass2(value, frac, ref_store, ref_out) MACRO_BEGIN \
  80 { \
  81         lowpass(value.x, frac, ref_store.x, ref_out.x); \
  82         lowpass(value.y, frac, ref_store.y, ref_out.y); \
  83 } MACRO_END
  84
  85 #define highpass2(value, frac, ref_store, ref_out) MACRO_BEGIN \
  86 { \
  87         highpass(value.x, frac, ref_store.x, ref_out.x); \
  88         highpass(value.y, frac, ref_store.y, ref_out.y); \
  89 } MACRO_END
  90
  91 #define highpass2_limited(value, frac, limit, ref_store, ref_out) MACRO_BEGIN \
  92 { \
  93         highpass_limited(value.x, frac, limit, ref_store.x, ref_out.x); \
  94         highpass_limited(value.y, frac, limit, ref_store.y, ref_out.y); \
  95 } MACRO_END
  96
  97 #define lowpass3(value, frac, ref_store, ref_out) MACRO_BEGIN \
  98 { \
  99         lowpass(value.x, frac, ref_store.x, ref_out.x); \
 100         lowpass(value.y, frac, ref_store.y, ref_out.y); \
 101         lowpass(value.z, frac, ref_store.z, ref_out.z); \
 102 } MACRO_END
 103
 104 #define highpass3(value, frac, ref_store, ref_out) MACRO_BEGIN \
 105 { \
 106         highpass(value.x, frac, ref_store.x, ref_out.x); \
 107         highpass(value.y, frac, ref_store.y, ref_out.y); \
 108         highpass(value.z, frac, ref_store.z, ref_out.z); \
 109 } MACRO_END
 110
 111 #define highpass3_limited(value, frac, limit, ref_store, ref_out) MACRO_BEGIN \
 112 { \
 113         highpass_limited(value.x, frac, limit, ref_store.x, ref_out.x); \
 114         highpass_limited(value.y, frac, limit, ref_store.y, ref_out.y); \
 115         highpass_limited(value.z, frac, limit, ref_store.z, ref_out.z); \
 116 } MACRO_END
 117
 118 void viewmodel_animate(entity this)
 119 {
 120         static float prevtime;
 121         float frametime = (time - prevtime);
 122         prevtime = time;
 123
 124         if (autocvar_chase_active) return;
 125         if (STAT(HEALTH) <= 0) return;
 126
 127         entity view = CSQCModel_server2csqc(player_localentnum - 1);
 128
 129         bool clonground = !(view.anim_implicit_state & ANIMIMPLICITSTATE_INAIR);
 130         static bool oldonground;
 131         static float hitgroundtime;
 132         static float lastongroundtime;
 133         if (clonground)
 134         {
 135                 float f = time; // cl.movecmd[0].time
 136                 if (!oldonground)
 137                         hitgroundtime = f;
 138                 lastongroundtime = f;
 139         }
 140         oldonground = clonground;
 141
 142
 143         bool teleported = view.csqcmodel_teleported;
 144
 145         float frac;
 146         if(autocvar_cl_followmodel)
 147         {
 148                 vector gunorg = '0 0 0';
 149                 static vector gunorg_prev = '0 0 0';
 150                 static vector gunorg_highpass = '0 0 0';
 151                 static vector gunorg_adjustment_highpass;
 152                 static vector gunorg_adjustment_lowpass;
 153
 154                 // if we teleported, clear the frametime... the lowpass will recover the previous value then
 155                 if (teleported)
 156                 {
 157                         // try to fix the first highpass; result is NOT
 158                         // perfect! TODO find a better fix
 159                         gunorg_prev = view_origin;
 160                 }
 161
 162                 // for the gun origin, only keep the high frequency (non-DC) parts, which is "somewhat like velocity"
 163                 gunorg_highpass += gunorg_prev;
 164                 frac = avg_factor(autocvar_cl_followmodel_highpass1);
 165                 highpass3_limited(view_origin, frac, autocvar_cl_followmodel_limit, gunorg_highpass, gunorg);
 166                 gunorg_prev = view_origin;
 167                 gunorg_highpass -= gunorg_prev;
 168
 169                 // calculate the RAW adjustment vectors
 170                 gunorg *= -autocvar_cl_followmodel_speed;
 171
 172                 // perform highpass/lowpass on the adjustment vectors (turning velocity into acceleration!)
 173                 // trick: we must do the lowpass LAST, so the lowpass vector IS the final vector!
 174                 frac = avg_factor(autocvar_cl_followmodel_highpass);
 175                 highpass3(gunorg, frac, gunorg_adjustment_highpass, gunorg);
 176                 frac = avg_factor(autocvar_cl_followmodel_lowpass);
 177                 lowpass3(gunorg, frac, gunorg_adjustment_lowpass, gunorg);
 178
 179                 vector v = rotate(gunorg, YAW(view_angles) * DEG2RAD); // rotate world coordinates to relative ones
 180                 v.z = gunorg.z;
 181                 this.origin += v;
 182         }
 183
 184         if(autocvar_cl_leanmodel)
 185         {
 186                 vector gunangles = '0 0 0';
 187                 static vector gunangles_prev = '0 0 0';
 188                 static vector gunangles_highpass = '0 0 0';
 189                 static vector gunangles_adjustment_highpass;
 190                 static vector gunangles_adjustment_lowpass;
 191
 192                 if (teleported)
 193                         gunangles_prev = view_angles;
 194
 195                 // in the highpass, we _store_ the DIFFERENCE to the actual view angles...
 196                 gunangles_highpass += gunangles_prev;
 197                 PITCH(gunangles_highpass) += 360 * floor((PITCH(view_angles) - PITCH(gunangles_highpass)) / 360 + 0.5);
 198                 YAW(gunangles_highpass) += 360 * floor((YAW(view_angles) - YAW(gunangles_highpass)) / 360 + 0.5);
 199                 ROLL(gunangles_highpass) += 360 * floor((ROLL(view_angles) - ROLL(gunangles_highpass)) / 360 + 0.5);
 200                 frac = avg_factor(autocvar_cl_leanmodel_highpass1);
 201                 highpass2_limited(view_angles, frac, autocvar_cl_leanmodel_limit, gunangles_highpass, gunangles);
 202                 gunangles_prev = view_angles;
 203                 gunangles_highpass -= gunangles_prev;
 204
 205                 PITCH(gunangles) *= -autocvar_cl_leanmodel_speed;
 206                 YAW(gunangles) *= -autocvar_cl_leanmodel_speed;
 207
 208                 // we assume here: PITCH = 0, YAW = 1, ROLL = 2
 209                 frac = avg_factor(autocvar_cl_leanmodel_highpass);
 210                 highpass2(gunangles, frac, gunangles_adjustment_highpass, gunangles);
 211                 frac = avg_factor(autocvar_cl_leanmodel_lowpass);
 212                 lowpass2(gunangles, frac, gunangles_adjustment_lowpass, gunangles);
 213
 214                 gunangles.x = -gunangles.x; // pitch was inverted, now that actually matters
 215                 this.angles += gunangles;
 216         }
 217
 218         float xyspeed = bound(0, vlen(vec2(view.velocity)), 400);
 219
 220         // vertical view bobbing code
 221         // TODO: cl_bob
 222
 223         // horizontal view bobbing code
 224         // TODO: cl_bob2
 225
 226         // fall bobbing code
 227         // causes the view to swing down and back up when touching the ground
 228         // TODO: cl_bobfall
 229
 230         // gun model bobbing code
 231         if (autocvar_cl_bobmodel)
 232         {
 233                 // calculate for swinging gun model
 234                 // the gun bobs when running on the ground, but doesn't bob when you're in the air.
 235                 // Sajt: I tried to smooth out the transitions between bob and no bob, which works
 236                 // for the most part, but for some reason when you go through a message trigger or
 237                 // pick up an item or anything like that it will momentarily jolt the gun.
 238                 float bspeed;
 239                 float t = 1;
 240                 float s = time * autocvar_cl_bobmodel_speed;
 241                 if (clonground)
 242                 {
 243                         if (time - hitgroundtime < 0.2)
 244                         {
 245                                 // just hit the ground, speed the bob back up over the next 0.2 seconds
 246                                 t = time - hitgroundtime;
 247                                 t = bound(0, t, 0.2);
 248                                 t *= 5;
 249                         }
 250                 }
 251                 else
 252                 {
 253                         // recently left the ground, slow the bob down over the next 0.2 seconds
 254                         t = time - lastongroundtime;
 255                         t = 0.2 - bound(0, t, 0.2);
 256                         t *= 5;
 257                 }
 258                 bspeed = xyspeed * 0.01;
 259                 vector gunorg = '0 0 0';
 260                 gunorg.y += bspeed * autocvar_cl_bobmodel_side * autocvar_cl_viewmodel_scale * sin(s) * t;
 261                 gunorg.z += bspeed * autocvar_cl_bobmodel_up * autocvar_cl_viewmodel_scale * cos(s * 2) * t;
 262
 263                 this.origin += gunorg;
 264         }
 265 }
 266
 267 .vector viewmodel_origin, viewmodel_angles;
 268 .float weapon_nextthink;
 269 .float weapon_eta_last;
 270 .float weapon_switchdelay;
 271
 272 void viewmodel_draw(entity this)
 273 {
 274         int mask = (intermission || (STAT(HEALTH) <= 0) || autocvar_chase_active) ? 0 : MASK_NORMAL;
 275         float a = this.alpha;
 276         static bool wasinvehicle;
 277         bool invehicle = player_localentnum > maxclients;
 278         if (invehicle) a = -1;
 279         else if (wasinvehicle) a = 1;
 280         wasinvehicle = invehicle;
 281         Weapon wep = activeweapon;
 282         int c = stof(getplayerkeyvalue(current_player, "colors"));
 283         vector g = weaponentity_glowmod(wep, c);
 284         entity me = CSQCModel_server2csqc(player_localentnum - 1);
 285         int fx = ((me.csqcmodel_effects & EFMASK_CHEAP)
 286                 | EF_NODEPTHTEST)
 287                 &~ (EF_FULLBRIGHT); // can mask team color, so get rid of it
 288         for (entity e = this; e; e = e.weaponchild)
 289         {
 290                 e.drawmask = mask;
 291                 e.alpha = a;
 292                 e.colormap = 256 + c;  // colormap == 0 is black, c == 0 is white
 293                 e.glowmod = g;
 294                 e.csqcmodel_effects = fx;
 295                 CSQCModel_Effects_Apply(e);
 296         }
 297         {
 298                 static string name_last;
 299                 string name = wep.mdl;
 300                 if (name != name_last)
 301                 {
 302                         name_last = name;
 303                         CL_WeaponEntity_SetModel(this, name);
 304                         this.viewmodel_origin = this.origin;
 305                         this.viewmodel_angles = this.angles;
 306                 }
 307                 anim_update(this);
 308                 if (!this.animstate_override)
 309                         anim_set(this, this.anim_idle, true, false, false);
 310         }
 311         float f = 0; // 0..1; 0: fully active
 312         float eta = (this.weapon_nextthink - time) / STAT(WEAPONRATEFACTOR);
 313         if (eta <= 0) f = this.weapon_eta_last;
 314         else switch (this.state)
 315         {
 316                 case WS_RAISE:
 317                 {
 318                         f = eta / max(eta, this.weapon_switchdelay);
 319                         break;
 320                 }
 321                 case WS_DROP:
 322                 {
 323                         f = 1 - eta / max(eta, this.weapon_switchdelay);
 324                         break;
 325                 }
 326                 case WS_CLEAR:
 327                 {
 328                         f = 1;
 329                         break;
 330                 }
 331         }
 332         this.weapon_eta_last = f;
 333         this.origin = this.viewmodel_origin;
 334         this.angles = this.viewmodel_angles;
 335         this.angles_x = (-90 * f * f);
 336         viewmodel_animate(this);
 337         setorigin(this, this.origin);
 338 }
 339
 340 entity viewmodel;
 341 STATIC_INIT(viewmodel) {
 342     viewmodel = new(viewmodel);
 343     make_pure(viewmodel);
 344         viewmodel.draw = viewmodel_draw;
 345 }
 346
 347 entity porto;
 348 vector polyline[16];
 349 void Porto_Draw(entity this)
 350 {
 351         vector p, dir, ang, q, nextdir;
 352         float portal_number, portal1_idx;
 353
 354         if(activeweapon != WEP_PORTO || spectatee_status || gametype == MAPINFO_TYPE_NEXBALL)
 355                 return;
 356         if(WEP_CVAR(porto, secondary))
 357                 return;
 358         if(intermission == 1)
 359                 return;
 360         if(intermission == 2)
 361                 return;
 362         if (STAT(HEALTH) <= 0)
 363                 return;
 364
 365         dir = view_forward;
 366
 367         if(angles_held_status)
 368         {
 369                 makevectors(angles_held);
 370                 dir = v_forward;
 371         }
 372
 373         p = view_origin;
 374
 375         polyline[0] = p;
 376         int idx = 1;
 377         portal_number = 0;
 378         nextdir = dir;
 379
 380         for (;;)
 381         {
 382                 dir = nextdir;
 383                 traceline(p, p + 65536 * dir, true, porto);
 384                 if(trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT)
 385                         return;
 386                 nextdir = dir - 2 * (dir * trace_plane_normal) * trace_plane_normal; // mirror dir at trace_plane_normal
 387                 p = trace_endpos;
 388                 polyline[idx] = p;
 389                 ++idx;
 390                 if(idx >= 16)
 391                         return;
 392                 if(trace_dphitq3surfaceflags & Q3SURFACEFLAG_SLICK || trace_dphitcontents & DPCONTENTS_PLAYERCLIP)
 393                         continue;
 394                 ++portal_number;
 395                 ang = vectoangles2(trace_plane_normal, dir);
 396                 ang.x = -ang.x;
 397                 makevectors(ang);
 398                 if(!CheckWireframeBox(porto, p - 48 * v_right - 48 * v_up + 16 * v_forward, 96 * v_right, 96 * v_up, 96 * v_forward))
 399                         return;
 400                 if(portal_number == 1)
 401                 {
 402                         portal1_idx = idx;
 403                         if(portal_number >= 2)
 404                                 break;
 405                 }
 406         }
 407
 408         while(idx >= 2)
 409         {
 410                 p = polyline[idx-2];
 411                 q = polyline[idx-1];
 412                 if(idx == 2)
 413                         p = p - view_up * 16;
 414                 if(idx-1 >= portal1_idx)
 415                 {
 416                         Draw_CylindricLine(p, q, 4, "", 1, 0, '0 0 1', 0.5, DRAWFLAG_NORMAL, view_origin);
 417                 }
 418                 else
 419                 {
 420                         Draw_CylindricLine(p, q, 4, "", 1, 0, '1 0 0', 0.5, DRAWFLAG_NORMAL, view_origin);
 421                 }
 422                 --idx;
 423         }
 424 }
 425
 426 void Porto_Init()
 427 {
 428         porto = new(porto);
 429         make_pure(porto);
 430         porto.draw = Porto_Draw;
 431         porto.dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY | DPCONTENTS_PLAYERCLIP;
 432 }
 433
 434 float drawtime;
 435 float avgspeed;
 436 vector GetCurrentFov(float fov)
 437 {
 438         float zoomsensitivity, zoomspeed, zoomfactor, zoomdir;
 439         float velocityzoom, curspeed;
 440         vector v;
 441
 442         zoomsensitivity = autocvar_cl_zoomsensitivity;
 443         zoomfactor = autocvar_cl_zoomfactor;
 444         if(zoomfactor < 1 || zoomfactor > 30)
 445                 zoomfactor = 2.5;
 446         zoomspeed = autocvar_cl_zoomspeed;
 447         if(zoomspeed >= 0)
 448         if(zoomspeed < 0.5 || zoomspeed > 16)
 449                         zoomspeed = 3.5;
 450
 451         zoomdir = button_zoom;
 452         if(hud == HUD_NORMAL)
 453         if(switchweapon == activeweapon)
 454         if((activeweapon == WEP_VORTEX && !WEP_CVAR(vortex, secondary)) || (activeweapon == WEP_RIFLE && !WEP_CVAR(rifle, secondary))) // do NOT use switchweapon here
 455                 zoomdir += button_attack2;
 456         if(spectatee_status > 0 || isdemo())
 457         {
 458                 if(spectatorbutton_zoom)
 459                 {
 460                         if(zoomdir)
 461                                 zoomdir = 0;
 462                         else
 463                                 zoomdir = 1;
 464                 }
 465                 // fteqcc failed twice here already, don't optimize this
 466         }
 467
 468         if(zoomdir) { zoomin_effect = 0; }
 469
 470         if(camera_active)
 471         {
 472                 current_viewzoom = min(1, current_viewzoom + drawframetime);
 473         }
 474         else if(autocvar_cl_spawnzoom && zoomin_effect)
 475         {
 476                 float spawnzoomfactor = bound(1, autocvar_cl_spawnzoom_factor, 30);
 477
 478                 current_viewzoom += (autocvar_cl_spawnzoom_speed * (spawnzoomfactor - current_viewzoom) * drawframetime);
 479                 current_viewzoom = bound(1 / spawnzoomfactor, current_viewzoom, 1);
 480                 if(current_viewzoom == 1) { zoomin_effect = 0; }
 481         }
 482         else
 483         {
 484                 if(zoomspeed < 0) // instant zoom
 485                 {
 486                         if(zoomdir)
 487                                 current_viewzoom = 1 / zoomfactor;
 488                         else
 489                                 current_viewzoom = 1;
 490                 }
 491                 else
 492                 {
 493                         if(zoomdir)
 494                                 current_viewzoom = 1 / bound(1, 1 / current_viewzoom + drawframetime * zoomspeed * (zoomfactor - 1), zoomfactor);
 495                         else
 496                                 current_viewzoom = bound(1 / zoomfactor, current_viewzoom + drawframetime * zoomspeed * (1 - 1 / zoomfactor), 1);
 497                 }
 498         }
 499
 500         if(almost_equals(current_viewzoom, 1))
 501                 current_zoomfraction = 0;
 502         else if(almost_equals(current_viewzoom, 1/zoomfactor))
 503                 current_zoomfraction = 1;
 504         else
 505                 current_zoomfraction = (current_viewzoom - 1) / (1/zoomfactor - 1);
 506
 507         if(zoomsensitivity < 1)
 508                 setsensitivityscale(pow(current_viewzoom, 1 - zoomsensitivity));
 509         else
 510                 setsensitivityscale(1);
 511
 512         if(autocvar_cl_velocityzoom_enabled && autocvar_cl_velocityzoom_type) // _type = 0 disables velocity zoom too
 513         {
 514                 if(intermission) { curspeed = 0; }
 515                 else
 516                 {
 517
 518                         makevectors(view_angles);
 519                         v = pmove_vel;
 520                         if(csqcplayer)
 521                                 v = csqcplayer.velocity;
 522
 523                         switch(autocvar_cl_velocityzoom_type)
 524                         {
 525                                 case 3: curspeed = max(0, v_forward * v); break;
 526                                 case 2: curspeed = (v_forward * v); break;
 527                                 case 1: default: curspeed = vlen(v); break;
 528                         }
 529                 }
 530
 531                 velocityzoom = bound(0, drawframetime / max(0.000000001, autocvar_cl_velocityzoom_time), 1); // speed at which the zoom adapts to player velocity
 532                 avgspeed = avgspeed * (1 - velocityzoom) + (curspeed / autocvar_cl_velocityzoom_speed) * velocityzoom;
 533                 velocityzoom = exp(float2range11(avgspeed * -autocvar_cl_velocityzoom_factor / 1) * 1);
 534
 535                 //print(ftos(avgspeed), " avgspeed, ", ftos(curspeed), " curspeed, ", ftos(velocityzoom), " return\n"); // for debugging
 536         }
 537         else
 538                 velocityzoom = 1;
 539
 540         float frustumx, frustumy, fovx, fovy;
 541         frustumy = tan(fov * M_PI / 360.0) * 0.75 * current_viewzoom * velocityzoom;
 542         frustumx = frustumy * vid_width / vid_height / vid_pixelheight;
 543         fovx = atan2(frustumx, 1) / M_PI * 360.0;
 544         fovy = atan2(frustumy, 1) / M_PI * 360.0;
 545
 546         return '1 0 0' * fovx + '0 1 0' * fovy;
 547 }
 548
 549 vector GetViewLocationFOV(float fov)
 550 {
 551         float frustumy = tan(fov * M_PI / 360.0) * 0.75;
 552         float frustumx = frustumy * vid_width / vid_height / vid_pixelheight;
 553         float fovx = atan2(frustumx, 1) / M_PI * 360.0;
 554         float fovy = atan2(frustumy, 1) / M_PI * 360.0;
 555         return '1 0 0' * fovx + '0 1 0' * fovy;
 556 }
 557
 558 vector GetOrthoviewFOV(vector ov_worldmin, vector ov_worldmax, vector ov_mid, vector ov_org)
 559 {
 560         float fovx, fovy;
 561         float width = (ov_worldmax.x - ov_worldmin.x);
 562         float height = (ov_worldmax.y - ov_worldmin.y);
 563         float distance_to_middle_of_world = vlen(ov_mid - ov_org);
 564         fovx = atan2(width/2, distance_to_middle_of_world) / M_PI * 360.0;
 565         fovy = atan2(height/2, distance_to_middle_of_world) / M_PI * 360.0;
 566         return '1 0 0' * fovx + '0 1 0' * fovy;
 567 }
 568
 569 // this function must match W_SetupShot!
 570 float zoomscript_caught;
 571
 572 vector wcross_origin;
 573 float wcross_scale_prev, wcross_alpha_prev;
 574 vector wcross_color_prev;
 575 float wcross_scale_goal_prev, wcross_alpha_goal_prev;
 576 vector wcross_color_goal_prev;
 577 float wcross_changedonetime;
 578
 579 string wcross_name_goal_prev, wcross_name_goal_prev_prev;
 580 float wcross_resolution_goal_prev, wcross_resolution_goal_prev_prev;
 581 float wcross_name_changestarttime, wcross_name_changedonetime;
 582 float wcross_name_alpha_goal_prev, wcross_name_alpha_goal_prev_prev;
 583
 584 float wcross_ring_prev;
 585
 586 entity trueaim;
 587 entity trueaim_rifle;
 588
 589 const float SHOTTYPE_HITTEAM = 1;
 590 const float SHOTTYPE_HITOBSTRUCTION = 2;
 591 const float SHOTTYPE_HITWORLD = 3;
 592 const float SHOTTYPE_HITENEMY = 4;
 593
 594 void TrueAim_Init()
 595 {
 596         trueaim = new(trueaim);
 597         make_pure(trueaim);
 598         trueaim.dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY | DPCONTENTS_CORPSE;
 599         trueaim_rifle = new(trueaim_rifle);
 600         make_pure(trueaim_rifle);
 601         trueaim_rifle.dphitcontentsmask = DPCONTENTS_BODY | DPCONTENTS_CORPSE;
 602 }
 603
 604 float EnemyHitCheck()
 605 {
 606         float t, n;
 607         wcross_origin = project_3d_to_2d(trace_endpos);
 608         wcross_origin.z = 0;
 609         if(trace_ent)
 610                 n = trace_ent.entnum;
 611         else
 612                 n = trace_networkentity;
 613         if(n < 1)
 614                 return SHOTTYPE_HITWORLD;
 615         if(n > maxclients)
 616                 return SHOTTYPE_HITWORLD;
 617         t = entcs_GetTeam(n - 1);
 618         if(teamplay)
 619                 if(t == myteam)
 620                         return SHOTTYPE_HITTEAM;
 621         if(t == NUM_SPECTATOR)
 622                 return SHOTTYPE_HITWORLD;
 623         return SHOTTYPE_HITENEMY;
 624 }
 625
 626 float TrueAimCheck()
 627 {
 628         float nudge = 1; // added to traceline target and subtracted from result TOOD(divVerent): do we still need this? Doesn't the engine do this now for us?
 629         vector vecs, trueaimpoint, w_shotorg;
 630         vector mi, ma, dv;
 631         float shottype;
 632         entity ta;
 633         float mv;
 634
 635         mi = ma = '0 0 0';
 636         ta = trueaim;
 637         mv = MOVE_NOMONSTERS;
 638
 639         switch(activeweapon) // WEAPONTODO
 640         {
 641                 case WEP_TUBA: // no aim
 642                 case WEP_PORTO: // shoots from eye
 643                 case WEP_NEXBALL: // shoots from eye
 644                 case WEP_HOOK: // no trueaim
 645                 case WEP_MORTAR: // toss curve
 646                         return SHOTTYPE_HITWORLD;
 647                 case WEP_VORTEX:
 648                 case WEP_VAPORIZER:
 649                         mv = MOVE_NORMAL;
 650                         break;
 651                 case WEP_RIFLE:
 652                         ta = trueaim_rifle;
 653                         mv = MOVE_NORMAL;
 654                         if(zoomscript_caught)
 655                         {
 656                                 tracebox(view_origin, '0 0 0', '0 0 0', view_origin + view_forward * MAX_SHOT_DISTANCE, mv, ta);
 657                                 return EnemyHitCheck();
 658                         }
 659                         break;
 660                 case WEP_DEVASTATOR: // projectile has a size!
 661                         mi = '-3 -3 -3';
 662                         ma = '3 3 3';
 663                         break;
 664                 case WEP_FIREBALL: // projectile has a size!
 665                         mi = '-16 -16 -16';
 666                         ma = '16 16 16';
 667                         break;
 668                 case WEP_SEEKER: // projectile has a size!
 669                         mi = '-2 -2 -2';
 670                         ma = '2 2 2';
 671                         break;
 672                 case WEP_ELECTRO: // projectile has a size!
 673                         mi = '0 0 -3';
 674                         ma = '0 0 -3';
 675                         break;
 676         }
 677
 678         vector traceorigin = entcs_receiver(player_localentnum - 1).origin + (eZ * STAT(VIEWHEIGHT));
 679
 680         vecs = decompressShotOrigin(STAT(SHOTORG));
 681
 682         traceline(traceorigin, traceorigin + view_forward * MAX_SHOT_DISTANCE, mv, ta);
 683         trueaimpoint = trace_endpos;
 684
 685         if(vdist((trueaimpoint - traceorigin), <, g_trueaim_minrange))
 686                 trueaimpoint = traceorigin + view_forward * g_trueaim_minrange;
 687
 688         if(vecs.x > 0)
 689                 vecs.y = -vecs.y;
 690         else
 691                 vecs = '0 0 0';
 692
 693         dv = view_right * vecs.y + view_up * vecs.z;
 694         w_shotorg = traceorigin + dv;
 695
 696         // now move the vecs forward as much as requested if possible
 697         tracebox(w_shotorg, mi, ma, w_shotorg + view_forward * (vecs.x + nudge), MOVE_NORMAL, ta); // FIXME this MOVE_NORMAL part will misbehave a little in csqc
 698         w_shotorg = trace_endpos - view_forward * nudge;
 699
 700         tracebox(w_shotorg, mi, ma, trueaimpoint, MOVE_NORMAL, ta);
 701         shottype = EnemyHitCheck();
 702         if(shottype != SHOTTYPE_HITWORLD)
 703                 return shottype;
 704
 705 #if 0
 706         // FIXME WHY DOES THIS NOT WORK FOR THE ROCKET LAUNCHER?
 707         // or rather, I know why, but see no fix
 708         if(vlen(trace_endpos - trueaimpoint) > vlen(ma) + vlen(mi) + 1)
 709                 // yes, this is an ugly hack... but it seems good enough to find out whether the test hits the same place as the initial trace
 710                 return SHOTTYPE_HITOBSTRUCTION;
 711 #endif
 712
 713         return SHOTTYPE_HITWORLD;
 714 }
 715
 716 void PostInit();
 717 void CSQC_Demo_Camera();
 718 float HUD_WouldDrawScoreboard();
 719 float camera_mode;
 720 const float CAMERA_FREE = 1;
 721 const float CAMERA_CHASE = 2;
 722 float reticle_type;
 723 string reticle_image;
 724 string NextFrameCommand;
 725
 726 vector freeze_org, freeze_ang;
 727 entity nightvision_noise, nightvision_noise2;
 728
 729 const float MAX_TIME_DIFF = 5;
 730 float pickup_crosshair_time, pickup_crosshair_size;
 731 float hitindication_crosshair_size;
 732 float use_vortex_chargepool;
 733
 734 float myhealth, myhealth_prev;
 735 float myhealth_flash;
 736
 737 float old_blurradius, old_bluralpha;
 738 float old_sharpen_intensity;
 739
 740 vector myhealth_gentlergb;
 741
 742 float contentavgalpha, liquidalpha_prev;
 743 vector liquidcolor_prev;
 744
 745 float eventchase_current_distance;
 746 float eventchase_running;
 747 bool WantEventchase(entity this)
 748 {
 749         if(autocvar_cl_orthoview)
 750                 return false;
 751         if(intermission)
 752                 return true;
 753         if(this.viewloc)
 754                 return true;
 755         if(spectatee_status >= 0)
 756         {
 757                 if(hud != HUD_NORMAL && (autocvar_cl_eventchase_vehicle || spectatee_status > 0))
 758                         return true;
 759                 if(MUTATOR_CALLHOOK(WantEventchase, this))
 760                         return true;
 761                 if(autocvar_cl_eventchase_nexball && gametype == MAPINFO_TYPE_NEXBALL && !(WepSet_GetFromStat() & WEPSET(NEXBALL)))
 762                         return true;
 763                 if(autocvar_cl_eventchase_death && (STAT(HEALTH) <= 0))
 764                 {
 765                         if(autocvar_cl_eventchase_death == 2)
 766                         {
 767                                 // don't stop eventchase once it's started (even if velocity changes afterwards)
 768                                 if(this.velocity == '0 0 0' || eventchase_running)
 769                                         return true;
 770                         }
 771                         else return true;
 772                 }
 773         }
 774         return false;
 775 }
 776
 777 void HUD_Crosshair_Vehicle()
 778 {
 779         if(hud != HUD_BUMBLEBEE_GUN)
 780         {
 781                 Vehicle info = Vehicles_from(hud);
 782                 info.vr_crosshair(info);
 783         }
 784 }
 785
 786 vector damage_blurpostprocess, content_blurpostprocess;
 787
 788 float unaccounted_damage = 0;
 789 void UpdateDamage()
 790 {
 791         // accumulate damage with each stat update
 792         static float damage_total_prev = 0;
 793         float damage_total = STAT(DAMAGE_DEALT_TOTAL);
 794         float unaccounted_damage_new = COMPARE_INCREASING(damage_total, damage_total_prev);
 795         damage_total_prev = damage_total;
 796
 797         static float damage_dealt_time_prev = 0;
 798         float damage_dealt_time = STAT(HIT_TIME);
 799         if (damage_dealt_time != damage_dealt_time_prev)
 800         {
 801                 unaccounted_damage += unaccounted_damage_new;
 802                 LOG_TRACE("dmg total: ", ftos(unaccounted_damage), " (+", ftos(unaccounted_damage_new), ")", "\n");
 803         }
 804         damage_dealt_time_prev = damage_dealt_time;
 805
 806         // prevent hitsound when switching spectatee
 807         static float spectatee_status_prev = 0;
 808         if (spectatee_status != spectatee_status_prev)
 809                 unaccounted_damage = 0;
 810         spectatee_status_prev = spectatee_status;
 811 }
 812
 813 void HitSound()
 814 {
 815         // varying sound pitch
 816
 817         static float hitsound_time_prev = 0;
 818         // HACK: the only way to get the arc to sound consistent with pitch shift is to ignore cl_hitsound_antispam_time
 819         float arc_hack = activeweapon == WEP_ARC && autocvar_cl_hitsound >= 2;
 820         if (arc_hack || COMPARE_INCREASING(time, hitsound_time_prev) > autocvar_cl_hitsound_antispam_time)
 821         {
 822                 if (autocvar_cl_hitsound && unaccounted_damage)
 823                 {
 824                         // customizable gradient function that crosses (0,a), (c,1) and asymptotically approaches b
 825                         float a = autocvar_cl_hitsound_max_pitch;
 826                         float b = autocvar_cl_hitsound_min_pitch;
 827                         float c = autocvar_cl_hitsound_nom_damage;
 828                         float x = unaccounted_damage;
 829                         float pitch_shift = (b*x*(a-1) + a*c*(1-b)) / (x*(a-1) + c*(1-b));
 830
 831                         // if sound variation is disabled, set pitch_shift to 1
 832                         if (autocvar_cl_hitsound == 1)
 833                                 pitch_shift = 1;
 834
 835                         // if pitch shift is reversed, mirror in (max-min)/2 + min
 836                         if (autocvar_cl_hitsound == 3)
 837                         {
 838                                 float mirror_value = (a-b)/2 + b;
 839                                 pitch_shift = mirror_value + (mirror_value - pitch_shift);
 840                         }
 841
 842                         LOG_TRACE("dmg total (dmg): ", ftos(unaccounted_damage), " , pitch shift: ", ftos(pitch_shift), "\n");
 843
 844                         // todo: avoid very long and very short sounds from wave stretching using different sound files? seems unnecessary
 845                         // todo: normalize sound pressure levels? seems unnecessary
 846
 847                         sound7(world, CH_INFO, SND(HIT), VOL_BASE, ATTN_NONE, pitch_shift * 100, 0);
 848                 }
 849                 unaccounted_damage = 0;
 850                 hitsound_time_prev = time;
 851         }
 852
 853         static float typehit_time_prev = 0;
 854         float typehit_time = STAT(TYPEHIT_TIME);
 855         if (COMPARE_INCREASING(typehit_time, typehit_time_prev) > autocvar_cl_hitsound_antispam_time)
 856         {
 857                 sound(world, CH_INFO, SND_TYPEHIT, VOL_BASE, ATTN_NONE);
 858                 typehit_time_prev = typehit_time;
 859         }
 860 }
 861
 862 void HUD_Crosshair()
 863 {SELFPARAM();
 864         static float rainbow_last_flicker;
 865         static vector rainbow_prev_color;
 866         entity e = this;
 867         float f, i, j;
 868         vector v;
 869         if(!scoreboard_active && !camera_active && intermission != 2 &&
 870                 spectatee_status != -1 && !csqcplayer.viewloc &&
 871                 !HUD_MinigameMenu_IsOpened() )
 872         {
 873                 if (!autocvar_crosshair_enabled) // main toggle for crosshair rendering
 874                         return;
 875
 876                 if (hud != HUD_NORMAL)
 877                 {
 878                         HUD_Crosshair_Vehicle();
 879                         return;
 880                 }
 881
 882                 string wcross_style;
 883                 float wcross_alpha, wcross_resolution;
 884                 wcross_style = autocvar_crosshair;
 885                 if (wcross_style == "0")
 886                         return;
 887                 wcross_resolution = autocvar_crosshair_size;
 888                 if (wcross_resolution == 0)
 889                         return;
 890                 wcross_alpha = autocvar_crosshair_alpha;
 891                 if (wcross_alpha == 0)
 892                         return;
 893
 894                 // TrueAim check
 895                 float shottype;
 896
 897                 // wcross_origin = '0.5 0 0' * vid_conwidth + '0 0.5 0' * vid_conheight;
 898                 wcross_origin = project_3d_to_2d(view_origin + MAX_SHOT_DISTANCE * view_forward);
 899                 wcross_origin.z = 0;
 900                 if(autocvar_crosshair_hittest)
 901                 {
 902                         vector wcross_oldorigin;
 903                         wcross_oldorigin = wcross_origin;
 904                         shottype = TrueAimCheck();
 905                         if(shottype == SHOTTYPE_HITWORLD)
 906                         {
 907                                 v = wcross_origin - wcross_oldorigin;
 908                                 v.x /= vid_conwidth;
 909                                 v.y /= vid_conheight;
 910                                 if(vlen(v) > 0.01)
 911                                         shottype = SHOTTYPE_HITOBSTRUCTION;
 912                         }
 913                         if(!autocvar_crosshair_hittest_showimpact)
 914                                 wcross_origin = wcross_oldorigin;
 915                 }
 916                 else
 917                         shottype = SHOTTYPE_HITWORLD;
 918
 919                 vector wcross_color = '0 0 0', wcross_size = '0 0 0';
 920                 string wcross_name = "";
 921                 float wcross_scale, wcross_blur;
 922
 923                 if(autocvar_crosshair_per_weapon || (autocvar_crosshair_color_special == 1))
 924                 {
 925                         e = switchingweapon;
 926                         if(e)
 927                         {
 928                                 if(autocvar_crosshair_per_weapon)
 929                                 {
 930                                         // WEAPONTODO: access these through some general settings (with non-balance config settings)
 931                                         //wcross_resolution *= cvar(strcat("crosshair_", wcross_wep, "_size"));
 932                                         //if (wcross_resolution == 0)
 933                                                 //return;
 934
 935                                         //wcross_style = cvar_string(strcat("crosshair_", wcross_wep));
 936                                         wcross_resolution *= e.w_crosshair_size;
 937                                         wcross_name = e.w_crosshair;
 938                                 }
 939                         }
 940                 }
 941
 942                 if(wcross_name == "")
 943                         wcross_name = strcat("gfx/crosshair", wcross_style);
 944
 945                 // MAIN CROSSHAIR COLOR DECISION
 946                 switch(autocvar_crosshair_color_special)
 947                 {
 948                         case 1: // crosshair_color_per_weapon
 949                         {
 950                                 if(e)
 951                                 {
 952                                         wcross_color = e.wpcolor;
 953                                         break;
 954                                 }
 955                                 else { goto normalcolor; }
 956                         }
 957
 958                         case 2: // crosshair_color_by_health
 959                         {
 960                                 float x = STAT(HEALTH);
 961
 962                                 //x = red
 963                                 //y = green
 964                                 //z = blue
 965
 966                                 wcross_color.z = 0;
 967
 968                                 if(x > 200)
 969                                 {
 970                                         wcross_color.x = 0;
 971                                         wcross_color.y = 1;
 972                                 }
 973                                 else if(x > 150)
 974                                 {
 975                                         wcross_color.x = 0.4 - (x-150)*0.02 * 0.4;
 976                                         wcross_color.y = 0.9 + (x-150)*0.02 * 0.1;
 977                                 }
 978                                 else if(x > 100)
 979                                 {
 980                                         wcross_color.x = 1 - (x-100)*0.02 * 0.6;
 981                                         wcross_color.y = 1 - (x-100)*0.02 * 0.1;
 982                                         wcross_color.z = 1 - (x-100)*0.02;
 983                                 }
 984                                 else if(x > 50)
 985                                 {
 986                                         wcross_color.x = 1;
 987                                         wcross_color.y = 1;
 988                                         wcross_color.z = 0.2 + (x-50)*0.02 * 0.8;
 989                                 }
 990                                 else if(x > 20)
 991                                 {
 992                                         wcross_color.x = 1;
 993                                         wcross_color.y = (x-20)*90/27/100;
 994                                         wcross_color.z = (x-20)*90/27/100 * 0.2;
 995                                 }
 996                                 else
 997                                 {
 998                                         wcross_color.x = 1;
 999                                         wcross_color.y = 0;
1000                                 }
1001                                 break;
1002                         }
1003
1004                         case 3: // crosshair_color_rainbow
1005                         {
1006                                 if(time >= rainbow_last_flicker)
1007                                 {
1008                                         rainbow_prev_color = randomvec() * autocvar_crosshair_color_special_rainbow_brightness;
1009                                         rainbow_last_flicker = time + autocvar_crosshair_color_special_rainbow_delay;
1010                                 }
1011                                 wcross_color = rainbow_prev_color;
1012                                 break;
1013                         }
1014                         :normalcolor
1015                         default: { wcross_color = stov(autocvar_crosshair_color); break; }
1016                 }
1017
1018                 if(autocvar_crosshair_effect_scalefade)
1019                 {
1020                         wcross_scale = wcross_resolution;
1021                         wcross_resolution = 1;
1022                 }
1023                 else
1024                 {
1025                         wcross_scale = 1;
1026                 }
1027
1028                 if(autocvar_crosshair_pickup)
1029                 {
1030                         float stat_pickup_time = STAT(LAST_PICKUP);
1031
1032                         if(pickup_crosshair_time < stat_pickup_time)
1033                         {
1034                                 if(time - stat_pickup_time < MAX_TIME_DIFF) // don't trigger the animation if it's too old
1035                                         pickup_crosshair_size = 1;
1036
1037                                 pickup_crosshair_time = stat_pickup_time;
1038                         }
1039
1040                         if(pickup_crosshair_size > 0)
1041                                 pickup_crosshair_size -= autocvar_crosshair_pickup_speed * frametime;
1042                         else
1043                                 pickup_crosshair_size = 0;
1044
1045                         wcross_scale += sin(pickup_crosshair_size) * autocvar_crosshair_pickup;
1046                 }
1047
1048                 // todo: make crosshair hit indication dependent on damage dealt
1049                 if(autocvar_crosshair_hitindication)
1050                 {
1051                         vector hitindication_color = ((autocvar_crosshair_color_special == 1) ? stov(autocvar_crosshair_hitindication_per_weapon_color) : stov(autocvar_crosshair_hitindication_color));
1052
1053                         if(unaccounted_damage)
1054                         {
1055                                 hitindication_crosshair_size = 1;
1056                         }
1057
1058                         if(hitindication_crosshair_size > 0)
1059                                 hitindication_crosshair_size -= autocvar_crosshair_hitindication_speed * frametime;
1060                         else
1061                                 hitindication_crosshair_size = 0;
1062
1063                         wcross_scale += sin(hitindication_crosshair_size) * autocvar_crosshair_hitindication;
1064                         wcross_color.x += sin(hitindication_crosshair_size) * hitindication_color.x;
1065                         wcross_color.y += sin(hitindication_crosshair_size) * hitindication_color.y;
1066                         wcross_color.z += sin(hitindication_crosshair_size) * hitindication_color.z;
1067                 }
1068
1069                 if(shottype == SHOTTYPE_HITENEMY)
1070                         wcross_scale *= autocvar_crosshair_hittest; // is not queried if hittest is 0
1071                 if(shottype == SHOTTYPE_HITTEAM)
1072                         wcross_scale /= autocvar_crosshair_hittest; // is not queried if hittest is 0
1073
1074                 f = fabs(autocvar_crosshair_effect_time);
1075                 if(wcross_scale != wcross_scale_goal_prev || wcross_alpha != wcross_alpha_goal_prev || wcross_color != wcross_color_goal_prev)
1076                 {
1077                         wcross_changedonetime = time + f;
1078                 }
1079                 if(wcross_name != wcross_name_goal_prev || wcross_resolution != wcross_resolution_goal_prev)
1080                 {
1081                         wcross_name_changestarttime = time;
1082                         wcross_name_changedonetime = time + f;
1083                         if(wcross_name_goal_prev_prev)
1084                                 strunzone(wcross_name_goal_prev_prev);
1085                         wcross_name_goal_prev_prev = wcross_name_goal_prev;
1086                         wcross_name_goal_prev = strzone(wcross_name);
1087                         wcross_name_alpha_goal_prev_prev = wcross_name_alpha_goal_prev;
1088                         wcross_resolution_goal_prev_prev = wcross_resolution_goal_prev;
1089                         wcross_resolution_goal_prev = wcross_resolution;
1090                 }
1091
1092                 wcross_scale_goal_prev = wcross_scale;
1093                 wcross_alpha_goal_prev = wcross_alpha;
1094                 wcross_color_goal_prev = wcross_color;
1095
1096                 if(spectatee_status == -1 && shottype == SHOTTYPE_HITTEAM || (shottype == SHOTTYPE_HITOBSTRUCTION && autocvar_crosshair_hittest_blur && !autocvar_chase_active))
1097                 {
1098                         wcross_blur = 1;
1099                         wcross_alpha *= 0.75;
1100                 }
1101                 else
1102                         wcross_blur = 0;
1103                 // *_prev is at time-frametime
1104                 // * is at wcross_changedonetime+f
1105                 // what do we have at time?
1106                 if(time < wcross_changedonetime)
1107                 {
1108                         f = frametime / (wcross_changedonetime - time + frametime);
1109                         wcross_scale = f * wcross_scale + (1 - f) * wcross_scale_prev;
1110                         wcross_alpha = f * wcross_alpha + (1 - f) * wcross_alpha_prev;
1111                         wcross_color = f * wcross_color + (1 - f) * wcross_color_prev;
1112                 }
1113
1114                 wcross_scale_prev = wcross_scale;
1115                 wcross_alpha_prev = wcross_alpha;
1116                 wcross_color_prev = wcross_color;
1117
1118                 MUTATOR_CALLHOOK(UpdateCrosshair);
1119
1120                 wcross_scale *= 1 - autocvar__menu_alpha;
1121                 wcross_alpha *= 1 - autocvar__menu_alpha;
1122                 wcross_size = draw_getimagesize(wcross_name) * wcross_scale;
1123
1124                 if(wcross_scale >= 0.001 && wcross_alpha >= 0.001)
1125                 {
1126                         // crosshair rings for weapon stats
1127                         if (autocvar_crosshair_ring || autocvar_crosshair_ring_reload)
1128                         {
1129                                 // declarations and stats
1130                                 float ring_value = 0, ring_scale = 0, ring_alpha = 0, ring_inner_value = 0, ring_inner_alpha = 0;
1131                                 string ring_image = string_null, ring_inner_image = string_null;
1132                                 vector ring_rgb = '0 0 0', ring_inner_rgb = '0 0 0';
1133
1134                                 ring_scale = autocvar_crosshair_ring_size;
1135
1136                                 float weapon_clipload, weapon_clipsize;
1137                                 weapon_clipload = STAT(WEAPON_CLIPLOAD);
1138                                 weapon_clipsize = STAT(WEAPON_CLIPSIZE);
1139
1140                                 float ok_ammo_charge, ok_ammo_chargepool;
1141                                 ok_ammo_charge = STAT(OK_AMMO_CHARGE);
1142                                 ok_ammo_chargepool = STAT(OK_AMMO_CHARGEPOOL);
1143
1144                                 float vortex_charge, vortex_chargepool;
1145                                 vortex_charge = STAT(VORTEX_CHARGE);
1146                                 vortex_chargepool = STAT(VORTEX_CHARGEPOOL);
1147
1148                                 float arc_heat = STAT(ARC_HEAT);
1149
1150                                 if(vortex_charge_movingavg == 0) // this should only happen if we have just loaded up the game
1151                                         vortex_charge_movingavg = vortex_charge;
1152
1153
1154                                 // handle the values
1155                                 if (autocvar_crosshair_ring && activeweapon == WEP_VORTEX && vortex_charge && autocvar_crosshair_ring_vortex) // ring around crosshair representing velocity-dependent damage for the vortex
1156                                 {
1157                                         if (vortex_chargepool || use_vortex_chargepool) {
1158                                                 use_vortex_chargepool = 1;
1159                                                 ring_inner_value = vortex_chargepool;
1160                                         } else {
1161                                                 vortex_charge_movingavg = (1 - autocvar_crosshair_ring_vortex_currentcharge_movingavg_rate) * vortex_charge_movingavg + autocvar_crosshair_ring_vortex_currentcharge_movingavg_rate * vortex_charge;
1162                                                 ring_inner_value = bound(0, autocvar_crosshair_ring_vortex_currentcharge_scale * (vortex_charge - vortex_charge_movingavg), 1);
1163                                         }
1164
1165                                         ring_inner_alpha = autocvar_crosshair_ring_vortex_inner_alpha;
1166                                         ring_inner_rgb = eX * autocvar_crosshair_ring_vortex_inner_color_red + eY * autocvar_crosshair_ring_vortex_inner_color_green + eZ * autocvar_crosshair_ring_vortex_inner_color_blue;
1167                                         ring_inner_image = "gfx/crosshair_ring_inner.tga";
1168
1169                                         // draw the outer ring to show the current charge of the weapon
1170                                         ring_value = vortex_charge;
1171                                         ring_alpha = autocvar_crosshair_ring_vortex_alpha;
1172                                         ring_rgb = wcross_color;
1173                                         ring_image = "gfx/crosshair_ring_nexgun.tga";
1174                                 }
1175                                 else if (autocvar_crosshair_ring && activeweapon == WEP_MINE_LAYER && WEP_CVAR(minelayer, limit) && autocvar_crosshair_ring_minelayer)
1176                                 {
1177                                         ring_value = bound(0, STAT(LAYED_MINES) / WEP_CVAR(minelayer, limit), 1); // if you later need to use the count of bullets in another place, then add a float for it. For now, no need to.
1178                                         ring_alpha = autocvar_crosshair_ring_minelayer_alpha;
1179                                         ring_rgb = wcross_color;
1180                                         ring_image = "gfx/crosshair_ring.tga";
1181                                 }
1182                                 else if (activeweapon == WEP_HAGAR && STAT(HAGAR_LOAD) && autocvar_crosshair_ring_hagar)
1183                                 {
1184                                         ring_value = bound(0, STAT(HAGAR_LOAD) / WEP_CVAR_SEC(hagar, load_max), 1);
1185                                         ring_alpha = autocvar_crosshair_ring_hagar_alpha;
1186                                         ring_rgb = wcross_color;
1187                                         ring_image = "gfx/crosshair_ring.tga";
1188                                 }
1189                                 else if (ok_ammo_charge)
1190                                 {
1191                                         ring_value = ok_ammo_chargepool;
1192                                         ring_alpha = autocvar_crosshair_ring_reload_alpha;
1193                                         ring_rgb = wcross_color;
1194                                         ring_image = "gfx/crosshair_ring.tga";
1195                                 }
1196                                 else if(autocvar_crosshair_ring_reload && weapon_clipsize) // forces there to be only an ammo ring
1197                                 {
1198                                         ring_value = bound(0, weapon_clipload / weapon_clipsize, 1);
1199                                         ring_scale = autocvar_crosshair_ring_reload_size;
1200                                         ring_alpha = autocvar_crosshair_ring_reload_alpha;
1201                                         ring_rgb = wcross_color;
1202
1203                                         // Note: This is to stop Taoki from complaining that the image doesn't match all potential balances.
1204                                         // if a new image for another weapon is added, add the code (and its respective file/value) here
1205                                         if ((activeweapon == WEP_RIFLE) && (weapon_clipsize == 80))
1206                                                 ring_image = "gfx/crosshair_ring_rifle.tga";
1207                                         else
1208                                                 ring_image = "gfx/crosshair_ring.tga";
1209                                 }
1210                                 else if ( autocvar_crosshair_ring && autocvar_crosshair_ring_arc && arc_heat && activeweapon == WEP_ARC )
1211                                 {
1212                                         ring_value = arc_heat;
1213                                         ring_alpha = (1-arc_heat)*autocvar_crosshair_ring_arc_cold_alpha +
1214                                                 arc_heat*autocvar_crosshair_ring_arc_hot_alpha;
1215                                         ring_rgb = (1-arc_heat)*wcross_color + arc_heat*autocvar_crosshair_ring_arc_hot_color;
1216                                         ring_image = "gfx/crosshair_ring.tga";
1217                                 }
1218
1219                                 // if in weapon switch animation, fade ring out/in
1220                                 if(autocvar_crosshair_effect_time > 0)
1221                                 {
1222                                         f = (time - wcross_name_changestarttime) / autocvar_crosshair_effect_time;
1223                                         if (f >= 1)
1224                                         {
1225                                                 wcross_ring_prev = ((ring_image) ? true : false);
1226                                         }
1227
1228                                         if(wcross_ring_prev)
1229                                         {
1230                                                 if(f < 1)
1231                                                         ring_alpha *= fabs(1 - bound(0, f, 1));
1232                                         }
1233                                         else
1234                                         {
1235                                                 if(f < 1)
1236                                                         ring_alpha *= bound(0, f, 1);
1237                                         }
1238                                 }
1239
1240                                 if (autocvar_crosshair_ring_inner && ring_inner_value) // lets draw a ring inside a ring so you can ring while you ring
1241                                         DrawCircleClippedPic(wcross_origin, wcross_size.x * ring_scale, ring_inner_image, ring_inner_value, ring_inner_rgb, wcross_alpha * ring_inner_alpha, DRAWFLAG_ADDITIVE);
1242
1243                                 if (ring_value)
1244                                         DrawCircleClippedPic(wcross_origin, wcross_size.x * ring_scale, ring_image, ring_value, ring_rgb, wcross_alpha * ring_alpha, DRAWFLAG_ADDITIVE);
1245                         }
1246
1247 #define CROSSHAIR_DO_BLUR(M,sz,wcross_name,wcross_alpha) \
1248                         MACRO_BEGIN { \
1249                                 if(wcross_blur > 0) \
1250                                 { \
1251                                         for(i = -2; i <= 2; ++i) \
1252                                         for(j = -2; j <= 2; ++j) \
1253                                         M(i,j,sz,wcross_name,wcross_alpha*0.04); \
1254                                 } \
1255                                 else \
1256                                 { \
1257                                         M(0,0,sz,wcross_name,wcross_alpha); \
1258                                 } \
1259                         } MACRO_END
1260
1261 #define CROSSHAIR_DRAW_SINGLE(i,j,sz,wcross_name,wcross_alpha) \
1262                         drawpic(wcross_origin - ('0.5 0 0' * (sz * wcross_size.x + i * wcross_blur) + '0 0.5 0' * (sz * wcross_size.y + j * wcross_blur)), wcross_name, sz * wcross_size, wcross_color, wcross_alpha, DRAWFLAG_NORMAL)
1263
1264 #define CROSSHAIR_DRAW(sz,wcross_name,wcross_alpha) \
1265                         CROSSHAIR_DO_BLUR(CROSSHAIR_DRAW_SINGLE,sz,wcross_name,wcross_alpha)
1266
1267                         if(time < wcross_name_changedonetime && wcross_name != wcross_name_goal_prev_prev && wcross_name_goal_prev_prev)
1268                         {
1269                                 f = (wcross_name_changedonetime - time) / (wcross_name_changedonetime - wcross_name_changestarttime);
1270                                 wcross_size = draw_getimagesize(wcross_name_goal_prev_prev) * wcross_scale;
1271                                 CROSSHAIR_DRAW(wcross_resolution_goal_prev_prev, wcross_name_goal_prev_prev, wcross_alpha * f * wcross_name_alpha_goal_prev_prev);
1272                                 f = 1 - f;
1273                         }
1274                         else
1275                         {
1276                                 f = 1;
1277                         }
1278                         wcross_name_alpha_goal_prev = f;
1279
1280                         wcross_size = draw_getimagesize(wcross_name) * wcross_scale;
1281                         CROSSHAIR_DRAW(wcross_resolution, wcross_name, wcross_alpha * f);
1282
1283                         if(autocvar_crosshair_dot)
1284                         {
1285                                 vector wcross_color_old;
1286                                 wcross_color_old = wcross_color;
1287
1288                                 if((autocvar_crosshair_dot_color_custom) && (autocvar_crosshair_dot_color != "0"))
1289                                         wcross_color = stov(autocvar_crosshair_dot_color);
1290
1291                                 CROSSHAIR_DRAW(wcross_resolution * autocvar_crosshair_dot_size, "gfx/crosshairdot.tga", f * autocvar_crosshair_dot_alpha);
1292                                 // FIXME why don't we use wcross_alpha here?
1293                                 wcross_color = wcross_color_old;
1294                         }
1295                 }
1296         }
1297         else
1298         {
1299                 wcross_scale_prev = 0;
1300                 wcross_alpha_prev = 0;
1301                 wcross_scale_goal_prev = 0;
1302                 wcross_alpha_goal_prev = 0;
1303                 wcross_changedonetime = 0;
1304                 if(wcross_name_goal_prev)
1305                         strunzone(wcross_name_goal_prev);
1306                 wcross_name_goal_prev = string_null;
1307                 if(wcross_name_goal_prev_prev)
1308                         strunzone(wcross_name_goal_prev_prev);
1309                 wcross_name_goal_prev_prev = string_null;
1310                 wcross_name_changestarttime = 0;
1311                 wcross_name_changedonetime = 0;
1312                 wcross_name_alpha_goal_prev = 0;
1313                 wcross_name_alpha_goal_prev_prev = 0;
1314                 wcross_resolution_goal_prev = 0;
1315                 wcross_resolution_goal_prev_prev = 0;
1316         }
1317 }
1318
1319 void HUD_Draw()
1320 {
1321         vector rgb = '0 0 0';
1322         float a = 1;
1323         if (MUTATOR_CALLHOOK(HUD_Draw_overlay))
1324         {
1325                 rgb = MUTATOR_ARGV(0, vector);
1326                 a = MUTATOR_ARGV(0, float);
1327         }
1328         else if(STAT(FROZEN))
1329         {
1330                 rgb = ((STAT(REVIVE_PROGRESS)) ? ('0.25 0.90 1' + ('1 0 0' * STAT(REVIVE_PROGRESS)) + ('0 1 1' * STAT(REVIVE_PROGRESS) * -1)) : '0.25 0.90 1');
1331         }
1332         drawfill('0 0 0', eX * vid_conwidth + eY * vid_conheight, rgb, autocvar_hud_colorflash_alpha * a, DRAWFLAG_ADDITIVE);
1333         if(!intermission)
1334         if(STAT(NADE_TIMER) && autocvar_cl_nade_timer) // give nade top priority, as it's a matter of life and death
1335         {
1336                 DrawCircleClippedPic(eX * 0.5 * vid_conwidth + eY * 0.6 * vid_conheight, 0.1 * vid_conheight, "gfx/crosshair_ring.tga", STAT(NADE_TIMER), '0.25 0.90 1' + ('1 0 0' * STAT(NADE_TIMER)) - ('0 1 1' * STAT(NADE_TIMER)), autocvar_hud_colorflash_alpha, DRAWFLAG_ADDITIVE);
1337                 drawstring_aspect(eY * 0.64 * vid_conheight, ((autocvar_cl_nade_timer == 2) ? _("Nade timer") : ""), eX * vid_conwidth + eY * 0.025 * vid_conheight, '1 1 1', 1, DRAWFLAG_NORMAL);
1338         }
1339         else if(STAT(REVIVE_PROGRESS))
1340         {
1341                 DrawCircleClippedPic(eX * 0.5 * vid_conwidth + eY * 0.6 * vid_conheight, 0.1 * vid_conheight, "gfx/crosshair_ring.tga", STAT(REVIVE_PROGRESS), '0.25 0.90 1', autocvar_hud_colorflash_alpha, DRAWFLAG_ADDITIVE);
1342                 drawstring_aspect(eY * 0.64 * vid_conheight, _("Revival progress"), eX * vid_conwidth + eY * 0.025 * vid_conheight, '1 1 1', 1, DRAWFLAG_NORMAL);
1343         }
1344
1345         if(autocvar_r_letterbox == 0)
1346                 if(autocvar_viewsize < 120)
1347                 {
1348                         if(!(gametype == MAPINFO_TYPE_RACE || gametype == MAPINFO_TYPE_CTS))
1349                                 Accuracy_LoadLevels();
1350
1351                         HUD_Main();
1352                         HUD_DrawScoreboard();
1353                 }
1354
1355         // crosshair goes VERY LAST
1356         UpdateDamage();
1357         HUD_Crosshair();
1358         HitSound();
1359 }
1360
1361 bool ov_enabled;
1362 float oldr_nearclip;
1363 float oldr_farclip_base;
1364 float oldr_farclip_world;
1365 float oldr_novis;
1366 float oldr_useportalculling;
1367 float oldr_useinfinitefarclip;
1368
1369 void cl_notice_run();
1370 float prev_myteam;
1371 int lasthud;
1372 float vh_notice_time;
1373 void WaypointSprite_Load();
1374 void CSQC_UpdateView(float w, float h)
1375 {SELFPARAM();
1376         entity e;
1377         float fov;
1378         float f;
1379         vector vf_size, vf_min;
1380         float a;
1381
1382         execute_next_frame();
1383
1384         ++framecount;
1385
1386         stats_get();
1387         hud = STAT(HUD);
1388
1389         if(hud != HUD_NORMAL && lasthud == HUD_NORMAL)
1390                 vh_notice_time = time + autocvar_cl_vehicles_notify_time;
1391
1392         lasthud = hud;
1393
1394         if(autocvar__hud_showbinds_reload) // menu can set this one
1395         {
1396                 db_close(binddb);
1397                 binddb = db_create();
1398                 cvar_set("_hud_showbinds_reload", "0");
1399         }
1400
1401         if(checkextension("DP_CSQC_MINFPS_QUALITY"))
1402                 view_quality = getproperty(VF_MINFPS_QUALITY);
1403         else
1404                 view_quality = 1;
1405
1406         button_attack2 = PHYS_INPUT_BUTTON_ATCK2(this);
1407         button_zoom = PHYS_INPUT_BUTTON_ZOOM(this);
1408
1409         vf_size = getpropertyvec(VF_SIZE);
1410         vf_min = getpropertyvec(VF_MIN);
1411         vid_width = vf_size.x;
1412         vid_height = vf_size.y;
1413
1414         vector reticle_pos = '0 0 0', reticle_size = '0 0 0';
1415         vector splash_pos = '0 0 0', splash_size = '0 0 0';
1416
1417         WaypointSprite_Load();
1418
1419         CSQCPlayer_SetCamera();
1420
1421         if(player_localentnum <= maxclients) // is it a client?
1422                 current_player = player_localentnum - 1;
1423         else // then player_localentnum is the vehicle I'm driving
1424                 current_player = player_localnum;
1425         myteam = entcs_GetTeam(current_player);
1426
1427         if(myteam != prev_myteam)
1428         {
1429                 myteamcolors = colormapPaletteColor(myteam, 1);
1430                 FOREACH(hud_panels, true, LAMBDA(it.update_time = time));
1431                 prev_myteam = myteam;
1432         }
1433
1434         ticrate = STAT(MOVEVARS_TICRATE) * STAT(MOVEVARS_TIMESCALE);
1435
1436         float is_dead = (STAT(HEALTH) <= 0);
1437
1438         // FIXME do we need this hack?
1439         if(isdemo())
1440         {
1441                 // in demos, input_buttons do not work
1442                 button_zoom = (autocvar__togglezoom == "-");
1443         }
1444         else if(button_zoom
1445                 && autocvar_cl_unpress_zoom_on_death
1446                 && (spectatee_status >= 0)
1447                 && (is_dead || intermission))
1448         {
1449                 // no zoom while dead or in intermission please
1450                 localcmd("-zoom\n");
1451                 button_zoom = false;
1452         }
1453
1454         // event chase camera
1455         if(autocvar_chase_active <= 0) // greater than 0 means it's enabled manually, and this code is skipped
1456         {
1457                 float vehicle_chase = (hud != HUD_NORMAL && (autocvar_cl_eventchase_vehicle || spectatee_status > 0));
1458                 float ons_roundlost = (gametype == MAPINFO_TYPE_ONSLAUGHT && STAT(ROUNDLOST));
1459                 entity gen = world;
1460
1461                 float vehicle_viewdist = 0;
1462                 vector vehicle_viewofs = '0 0 0';
1463
1464                 if(vehicle_chase)
1465                 {
1466                         if(hud != HUD_BUMBLEBEE_GUN)
1467                         {
1468                                 Vehicle info = Vehicles_from(hud);
1469                                 vehicle_viewdist = info.height;
1470                                 vehicle_viewofs = info.view_ofs;
1471                         }
1472                 }
1473
1474                 if(ons_roundlost)
1475                 {
1476                         FOREACH_ENTITY_CLASS("onslaught_generator", it.health <= 0, LAMBDA(
1477                                 gen = it;
1478                                 break;
1479                         ));
1480                         if(!gen)
1481                                 ons_roundlost = false; // don't enforce the 3rd person camera if there is no dead generator to show
1482                 }
1483                 if(WantEventchase(self) || (!autocvar_cl_orthoview && ons_roundlost))
1484                 {
1485                         eventchase_running = true;
1486
1487                         entity local_player = ((csqcplayer) ? csqcplayer : CSQCModel_server2csqc(player_localentnum - 1));
1488                         if(!local_player)
1489                                 local_player = self; // fall back!
1490
1491                         // make special vector since we can't use view_origin (It is one frame old as of this code, it gets set later with the results this code makes.)
1492                         vector current_view_origin = (csqcplayer ? csqcplayer.origin : pmove_org);
1493                         if(ons_roundlost) { current_view_origin = gen.origin; }
1494
1495                         // detect maximum viewoffset and use it
1496                         vector view_offset = autocvar_cl_eventchase_viewoffset;
1497                         if(vehicle_chase)
1498                         {
1499                                 if(vehicle_viewofs)
1500                                         view_offset = vehicle_viewofs;
1501                                 else
1502                                         view_offset = autocvar_cl_eventchase_vehicle_viewoffset;
1503                         }
1504                         if(ons_roundlost) { view_offset = autocvar_cl_eventchase_generator_viewoffset; }
1505
1506                         if(view_offset)
1507                         {
1508                                 WarpZone_TraceLine(current_view_origin, current_view_origin + view_offset + ('0 0 1' * autocvar_cl_eventchase_maxs.z), MOVE_WORLDONLY, self);
1509                                 if(trace_fraction == 1) { current_view_origin += view_offset; }
1510                                 else { current_view_origin.z += max(0, (trace_endpos.z - current_view_origin.z) - autocvar_cl_eventchase_maxs.z); }
1511                         }
1512
1513                         // We must enable chase_active to get a third person view (weapon viewmodel hidden and own player model showing).
1514                         // Ideally, there should be another way to enable third person cameras, such as through setproperty()
1515                         // -1 enables chase_active while marking it as set by this code, and not by the user (which would be 1)
1516                         if(!autocvar_chase_active) { cvar_set("chase_active", "-1"); }
1517
1518                         // make the camera smooth back
1519                         float chase_distance = autocvar_cl_eventchase_distance;
1520                         if(vehicle_chase)
1521                         {
1522                                 if(vehicle_viewofs)
1523                                         chase_distance = vehicle_viewdist;
1524                                 else
1525                                         chase_distance = autocvar_cl_eventchase_vehicle_distance;
1526                         }
1527                         if(ons_roundlost) { chase_distance = autocvar_cl_eventchase_generator_distance; }
1528
1529                         if(autocvar_cl_eventchase_speed && eventchase_current_distance < chase_distance)
1530                                 eventchase_current_distance += autocvar_cl_eventchase_speed * (chase_distance - eventchase_current_distance) * frametime; // slow down the further we get
1531                         else if(eventchase_current_distance != chase_distance)
1532                                 eventchase_current_distance = chase_distance;
1533
1534                         makevectors(view_angles);
1535
1536                         vector eventchase_target_origin = (current_view_origin - (v_forward * eventchase_current_distance));
1537                         WarpZone_TraceBox(current_view_origin, autocvar_cl_eventchase_mins, autocvar_cl_eventchase_maxs, eventchase_target_origin, MOVE_WORLDONLY, self);
1538
1539                         // If the boxtrace fails, revert back to line tracing.
1540                         if(!local_player.viewloc)
1541                         if(trace_startsolid)
1542                         {
1543                                 eventchase_target_origin = (current_view_origin - (v_forward * eventchase_current_distance));
1544                                 WarpZone_TraceLine(current_view_origin, eventchase_target_origin, MOVE_WORLDONLY, self);
1545                                 setproperty(VF_ORIGIN, (trace_endpos - (v_forward * autocvar_cl_eventchase_mins.z)));
1546                         }
1547                         else { setproperty(VF_ORIGIN, trace_endpos); }
1548
1549                         if(!local_player.viewloc)
1550                                 setproperty(VF_ANGLES, WarpZone_TransformVAngles(WarpZone_trace_transform, view_angles));
1551                 }
1552                 else if(autocvar_chase_active < 0) // time to disable chase_active if it was set by this code
1553                 {
1554                         eventchase_running = false;
1555                         cvar_set("chase_active", "0");
1556                         eventchase_current_distance = 0; // start from 0 next time
1557                 }
1558         }
1559         // workaround for camera stuck between player's legs when using chase_active 1
1560         // because the engine stops updating the chase_active camera when the game ends
1561         else if(intermission)
1562         {
1563                 cvar_settemp("chase_active", "-1");
1564                 eventchase_current_distance = 0;
1565         }
1566
1567         // do lockview after event chase camera so that it still applies whenever necessary.
1568         if(autocvar_cl_lockview || (!autocvar_hud_cursormode && (autocvar__hud_configure && spectatee_status <= 0 || intermission > 1 || QuickMenu_IsOpened())))
1569         {
1570                 setproperty(VF_ORIGIN, freeze_org);
1571                 setproperty(VF_ANGLES, freeze_ang);
1572         }
1573         else
1574         {
1575                 freeze_org = getpropertyvec(VF_ORIGIN);
1576                 freeze_ang = getpropertyvec(VF_ANGLES);
1577         }
1578
1579         WarpZone_FixView();
1580         //WarpZone_FixPMove();
1581
1582         vector ov_org = '0 0 0';
1583         vector ov_mid = '0 0 0';
1584         vector ov_worldmin = '0 0 0';
1585         vector ov_worldmax = '0 0 0';
1586         if(autocvar_cl_orthoview)
1587         {
1588                 ov_worldmin = mi_picmin;
1589                 ov_worldmax = mi_picmax;
1590
1591                 float ov_width = (ov_worldmax.x - ov_worldmin.x);
1592                 float ov_height = (ov_worldmax.y - ov_worldmin.y);
1593                 float ov_distance = (max(vid_width, vid_height) * max(ov_width, ov_height));
1594
1595                 ov_mid = ((ov_worldmax + ov_worldmin) * 0.5);
1596                 ov_org = vec3(ov_mid.x, ov_mid.y, (ov_mid.z + ov_distance));
1597
1598                 float ov_nearest = vlen(ov_org - vec3(
1599                         bound(ov_worldmin.x, ov_org.x, ov_worldmax.x),
1600                         bound(ov_worldmin.y, ov_org.y, ov_worldmax.y),
1601                         bound(ov_worldmin.z, ov_org.z, ov_worldmax.z)
1602                 ));
1603
1604                 float ov_furthest = 0;
1605                 float dist = 0;
1606
1607                 if((dist = vdist((vec3(ov_worldmin.x, ov_worldmin.y, ov_worldmin.z) - ov_org), >, ov_furthest))) { ov_furthest = dist; }
1608                 if((dist = vdist((vec3(ov_worldmax.x, ov_worldmin.y, ov_worldmin.z) - ov_org), >, ov_furthest))) { ov_furthest = dist; }
1609                 if((dist = vdist((vec3(ov_worldmin.x, ov_worldmax.y, ov_worldmin.z) - ov_org), >, ov_furthest))) { ov_furthest = dist; }
1610                 if((dist = vdist((vec3(ov_worldmin.x, ov_worldmin.y, ov_worldmax.z) - ov_org), >, ov_furthest))) { ov_furthest = dist; }
1611                 if((dist = vdist((vec3(ov_worldmax.x, ov_worldmax.y, ov_worldmin.z) - ov_org), >, ov_furthest))) { ov_furthest = dist; }
1612                 if((dist = vdist((vec3(ov_worldmin.x, ov_worldmax.y, ov_worldmax.z) - ov_org), >, ov_furthest))) { ov_furthest = dist; }
1613                 if((dist = vdist((vec3(ov_worldmax.x, ov_worldmin.y, ov_worldmax.z) - ov_org), >, ov_furthest))) { ov_furthest = dist; }
1614                 if((dist = vdist((vec3(ov_worldmax.x, ov_worldmax.y, ov_worldmax.z) - ov_org), >, ov_furthest))) { ov_furthest = dist; }
1615
1616                 if(!ov_enabled)
1617                 {
1618                         oldr_nearclip = cvar("r_nearclip");
1619                         oldr_farclip_base = cvar("r_farclip_base");
1620                         oldr_farclip_world = cvar("r_farclip_world");
1621                         oldr_novis = cvar("r_novis");
1622                         oldr_useportalculling = cvar("r_useportalculling");
1623                         oldr_useinfinitefarclip = cvar("r_useinfinitefarclip");
1624                 }
1625
1626                 cvar_settemp("r_nearclip", ftos(ov_nearest));
1627                 cvar_settemp("r_farclip_base", ftos(ov_furthest));
1628                 cvar_settemp("r_farclip_world", "0");
1629                 cvar_settemp("r_novis", "1");
1630                 cvar_settemp("r_useportalculling", "0");
1631                 cvar_settemp("r_useinfinitefarclip", "0");
1632
1633                 setproperty(VF_ORIGIN, ov_org);
1634                 setproperty(VF_ANGLES, '90 0 0');
1635
1636                 ov_enabled = true;
1637
1638                 #if 0
1639                 LOG_INFOF("OrthoView: org = %s, angles = %s, distance = %f, nearest = %f, furthest = %f\n",
1640                         vtos(ov_org),
1641                         vtos(getpropertyvec(VF_ANGLES)),
1642                         ov_distance,
1643                         ov_nearest,
1644                         ov_furthest);
1645                 #endif
1646         }
1647         else
1648         {
1649                 if(ov_enabled)
1650                 {
1651                         cvar_set("r_nearclip", ftos(oldr_nearclip));
1652                         cvar_set("r_farclip_base", ftos(oldr_farclip_base));
1653                         cvar_set("r_farclip_world", ftos(oldr_farclip_world));
1654                         cvar_set("r_novis", ftos(oldr_novis));
1655                         cvar_set("r_useportalculling", ftos(oldr_useportalculling));
1656                         cvar_set("r_useinfinitefarclip", ftos(oldr_useinfinitefarclip));
1657                 }
1658                 ov_enabled = false;
1659         }
1660
1661         // Render the Scene
1662         view_origin = getpropertyvec(VF_ORIGIN);
1663         view_angles = getpropertyvec(VF_ANGLES);
1664         makevectors(view_angles);
1665         view_forward = v_forward;
1666         view_right = v_right;
1667         view_up = v_up;
1668
1669 #ifdef BLURTEST
1670         if(time > blurtest_time0 && time < blurtest_time1)
1671         {
1672                 float r, t;
1673
1674                 t = (time - blurtest_time0) / (blurtest_time1 - blurtest_time0);
1675                 r = t * blurtest_radius;
1676                 f = 1 / pow(t, blurtest_power) - 1;
1677
1678                 cvar_set("r_glsl_postprocess", "1");
1679                 cvar_set("r_glsl_postprocess_uservec1", strcat(ftos(r), " ", ftos(f), " 0 0"));
1680         }
1681         else
1682         {
1683                 cvar_set("r_glsl_postprocess", "0");
1684                 cvar_set("r_glsl_postprocess_uservec1", "0 0 0 0");
1685         }
1686 #endif
1687
1688         TargetMusic_Advance();
1689         Fog_Force();
1690
1691         if(drawtime == 0)
1692                 drawframetime = 0.01666667; // when we don't know fps yet, we assume 60fps
1693         else
1694                 drawframetime = bound(0.000001, time - drawtime, 1);
1695         drawtime = time;
1696
1697         // watch for gametype changes here...
1698         // in ParseStuffCMD the cmd isn't executed yet :/
1699         // might even be better to add the gametype to TE_CSQC_INIT...?
1700         if(!postinit)
1701                 PostInit();
1702
1703         if(intermission && !isdemo() && !(calledhooks & HOOK_END))
1704         {
1705                 if(calledhooks & HOOK_START)
1706                 {
1707                         localcmd("\ncl_hook_gameend\n");
1708                         calledhooks |= HOOK_END;
1709                 }
1710         }
1711
1712         Announcer();
1713
1714         fov = autocvar_fov;
1715         if(fov <= 59.5)
1716         {
1717                 if(!zoomscript_caught)
1718                 {
1719                         localcmd("+button9\n");
1720                         zoomscript_caught = 1;
1721                 }
1722         }
1723         else
1724         {
1725                 if(zoomscript_caught)
1726                 {
1727                         localcmd("-button9\n");
1728                         zoomscript_caught = 0;
1729                 }
1730         }
1731
1732         ColorTranslateMode = autocvar_cl_stripcolorcodes;
1733
1734         // currently switching-to weapon (for crosshair)
1735         switchingweapon = Weapons_from(STAT(SWITCHINGWEAPON));
1736
1737         // actually active weapon (for zoom)
1738         activeweapon = Weapons_from(STAT(ACTIVEWEAPON));
1739
1740         switchweapon = Weapons_from(STAT(SWITCHWEAPON));
1741
1742         f = (serverflags & SERVERFLAG_TEAMPLAY);
1743         if(f != teamplay)
1744         {
1745                 teamplay = f;
1746                 HUD_InitScores();
1747         }
1748
1749         if(last_switchweapon != switchweapon)
1750         {
1751                 weapontime = time;
1752                 last_switchweapon = switchweapon;
1753                 if(button_zoom && autocvar_cl_unpress_zoom_on_weapon_switch)
1754                 {
1755                         localcmd("-zoom\n");
1756                         button_zoom = false;
1757                 }
1758                 if(autocvar_cl_unpress_attack_on_weapon_switch)
1759                 {
1760                         localcmd("-fire\n");
1761                         localcmd("-fire2\n");
1762                         button_attack2 = false;
1763                 }
1764         }
1765         if(last_activeweapon != activeweapon)
1766         {
1767                 last_activeweapon = activeweapon;
1768
1769                 e = activeweapon;
1770                 if(e.netname != "")
1771                         localcmd(strcat("\ncl_hook_activeweapon ", e.netname), "\n");
1772                 else
1773                         localcmd("\ncl_hook_activeweapon none\n");
1774         }
1775
1776         // ALWAYS Clear Current Scene First
1777         clearscene();
1778
1779         setproperty(VF_ORIGIN, view_origin);
1780         setproperty(VF_ANGLES, view_angles);
1781
1782         // FIXME engine bug? VF_SIZE and VF_MIN are not restored to sensible values by this
1783         setproperty(VF_SIZE, vf_size);
1784         setproperty(VF_MIN, vf_min);
1785
1786         // Assign Standard Viewflags
1787         // Draw the World (and sky)
1788         setproperty(VF_DRAWWORLD, 1);
1789
1790         // Set the console size vars
1791         vid_conwidth = autocvar_vid_conwidth;
1792         vid_conheight = autocvar_vid_conheight;
1793         vid_pixelheight = autocvar_vid_pixelheight;
1794
1795         if(autocvar_cl_orthoview) { setproperty(VF_FOV, GetOrthoviewFOV(ov_worldmin, ov_worldmax, ov_mid, ov_org)); }
1796         else if(csqcplayer.viewloc) { setproperty(VF_FOV, GetViewLocationFOV(110)); } // enforce 110 fov, so things dont look odd
1797         else { setproperty(VF_FOV, GetCurrentFov(fov)); }
1798
1799         // Camera for demo playback
1800         if(camera_active)
1801         {
1802                 if(autocvar_camera_enable)
1803                         CSQC_Demo_Camera();
1804                 else
1805                 {
1806                         cvar_set("chase_active", ftos(chase_active_backup));
1807                         cvar_set("cl_demo_mousegrab", "0");
1808                         camera_active = false;
1809                 }
1810         }
1811         else
1812         {
1813 #ifdef CAMERATEST
1814                 if(autocvar_camera_enable)
1815 #else
1816                 if(autocvar_camera_enable && isdemo())
1817 #endif
1818                 {
1819                         // Enable required Darkplaces cvars
1820                         chase_active_backup = autocvar_chase_active;
1821                         cvar_set("chase_active", "2");
1822                         cvar_set("cl_demo_mousegrab", "1");
1823                         camera_active = true;
1824                         camera_mode = false;
1825                 }
1826         }
1827
1828         // Draw the Crosshair
1829         setproperty(VF_DRAWCROSSHAIR, 0); //Make sure engine crosshairs are always hidden
1830
1831         // Draw the Engine Status Bar (the default Quake HUD)
1832         setproperty(VF_DRAWENGINESBAR, 0);
1833
1834         // Update the mouse position
1835         /*
1836            mousepos_x = vid_conwidth;
1837            mousepos_y = vid_conheight;
1838            mousepos = mousepos*0.5 + getmousepos();
1839          */
1840
1841         FOREACH_ENTITY(it.draw, LAMBDA(it.draw(it)));
1842
1843         addentities(MASK_NORMAL | MASK_ENGINE | MASK_ENGINEVIEWMODELS);
1844         renderscene();
1845
1846         // now switch to 2D drawing mode by calling a 2D drawing function
1847         // then polygon drawing will draw as 2D stuff, and NOT get queued until the
1848         // next R_RenderScene call
1849         drawstring('0 0 0', "", '1 1 0', '1 1 1', 0, 0);
1850
1851         if(autocvar_r_fakelight >= 2 || autocvar_r_fullbright)
1852         if (!(serverflags & SERVERFLAG_ALLOW_FULLBRIGHT))
1853         {
1854                 // apply night vision effect
1855                 vector tc_00, tc_01, tc_10, tc_11;
1856                 vector rgb = '0 0 0';
1857
1858                 if(!nightvision_noise)
1859                 {
1860                         nightvision_noise = new(nightvision_noise);
1861                 }
1862                 if(!nightvision_noise2)
1863                 {
1864                         nightvision_noise2 = new(nightvision_noise2);
1865                 }
1866
1867                 // color tint in yellow
1868                 drawfill('0 0 0', autocvar_vid_conwidth * '1 0 0' + autocvar_vid_conheight * '0 1 0', '0.5 1 0.3', 1, DRAWFLAG_MODULATE);
1869
1870                 // draw BG
1871                 a = Noise_Pink(nightvision_noise, frametime * 1.5) * 0.05 + 0.15;
1872                 rgb = '1 1 1';
1873                 tc_00 = '0 0 0' + '0.2 0 0' * sin(time * 0.3) + '0 0.3 0' * cos(time * 0.7);
1874                 tc_01 = '0 2.25 0' + '0.6 0 0' * cos(time * 1.2) - '0 0.3 0' * sin(time * 2.2);
1875                 tc_10 = '1.5 0 0' - '0.2 0 0' * sin(time * 0.5) + '0 0.5 0' * cos(time * 1.7);
1876                 //tc_11 = '1 1 0' + '0.6 0 0' * sin(time * 0.6) + '0 0.3 0' * cos(time * 0.1);
1877                 tc_11 = tc_01 + tc_10 - tc_00;
1878                 R_BeginPolygon("gfx/nightvision-bg.tga", DRAWFLAG_ADDITIVE);
1879                 R_PolygonVertex('0 0 0', tc_00, rgb, a);
1880                 R_PolygonVertex(autocvar_vid_conwidth * '1 0 0', tc_10, rgb, a);
1881                 R_PolygonVertex(autocvar_vid_conwidth * '1 0 0' + autocvar_vid_conheight * '0 1 0', tc_11, rgb, a);
1882                 R_PolygonVertex(autocvar_vid_conheight * '0 1 0', tc_01, rgb, a);
1883                 R_EndPolygon();
1884
1885                 // draw FG
1886                 a = Noise_Pink(nightvision_noise2, frametime * 0.1) * 0.05 + 0.12;
1887                 rgb = '0.3 0.6 0.4' + '0.1 0.4 0.2' * Noise_White(nightvision_noise2, frametime);
1888                 tc_00 = '0 0 0' + '1 0 0' * Noise_White(nightvision_noise2, frametime) + '0 1 0' * Noise_White(nightvision_noise2, frametime);
1889                 tc_01 = tc_00 + '0 3 0' * (1 + Noise_White(nightvision_noise2, frametime) * 0.2);
1890                 tc_10 = tc_00 + '2 0 0' * (1 + Noise_White(nightvision_noise2, frametime) * 0.3);
1891                 tc_11 = tc_01 + tc_10 - tc_00;
1892                 R_BeginPolygon("gfx/nightvision-fg.tga", DRAWFLAG_ADDITIVE);
1893                 R_PolygonVertex('0 0 0', tc_00, rgb, a);
1894                 R_PolygonVertex(autocvar_vid_conwidth * '1 0 0', tc_10, rgb, a);
1895                 R_PolygonVertex(autocvar_vid_conwidth * '1 0 0' + autocvar_vid_conheight * '0 1 0', tc_11, rgb, a);
1896                 R_PolygonVertex(autocvar_vid_conheight * '0 1 0', tc_01, rgb, a);
1897                 R_EndPolygon();
1898         }
1899
1900         if(autocvar_cl_reticle)
1901         {
1902                 Weapon wep = activeweapon;
1903                 // Draw the aiming reticle for weapons that use it
1904                 // reticle_type is changed to the item we are zooming / aiming with, to decide which reticle to use
1905                 // It must be a persisted float for fading out to work properly (you let go of the zoom button for
1906                 // the view to go back to normal, so reticle_type would become 0 as we fade out)
1907                 if(spectatee_status || is_dead || hud != HUD_NORMAL)
1908                 {
1909                         // no zoom reticle while dead
1910                         reticle_type = 0;
1911                 }
1912                 else if(wep.wr_zoomreticle(wep) && autocvar_cl_reticle_weapon)
1913                 {
1914                         if(reticle_image != "") { reticle_type = 2; }
1915                         else { reticle_type = 0; }
1916                 }
1917                 else if(button_zoom || zoomscript_caught)
1918                 {
1919                         // normal zoom
1920                         reticle_type = 1;
1921                 }
1922
1923                 if(reticle_type)
1924                 {
1925                         if(autocvar_cl_reticle_stretch)
1926                         {
1927                                 reticle_size.x = vid_conwidth;
1928                                 reticle_size.y = vid_conheight;
1929                                 reticle_pos.x = 0;
1930                                 reticle_pos.y = 0;
1931                         }
1932                         else
1933                         {
1934                                 reticle_size.x = max(vid_conwidth, vid_conheight);
1935                                 reticle_size.y = max(vid_conwidth, vid_conheight);
1936                                 reticle_pos.x = (vid_conwidth - reticle_size.x) / 2;
1937                                 reticle_pos.y = (vid_conheight - reticle_size.y) / 2;
1938                         }
1939
1940                         if(zoomscript_caught)
1941                                 f = 1;
1942                         else
1943                                 f = current_zoomfraction;
1944
1945                         if(f)
1946                         {
1947                                 switch(reticle_type)
1948                                 {
1949                                         case 1: drawpic(reticle_pos, "gfx/reticle_normal", reticle_size, '1 1 1', f * autocvar_cl_reticle_normal_alpha, DRAWFLAG_NORMAL); break;
1950                                         case 2: drawpic(reticle_pos, reticle_image, reticle_size, '1 1 1', f * autocvar_cl_reticle_weapon_alpha, DRAWFLAG_NORMAL); break;
1951                                 }
1952                         }
1953                 }
1954         }
1955         else
1956         {
1957                 if(reticle_type != 0) { reticle_type = 0; }
1958         }
1959
1960
1961         // improved polyblend
1962         if(autocvar_hud_contents)
1963         {
1964                 float contentalpha_temp, incontent, liquidalpha, contentfadetime;
1965                 vector liquidcolor;
1966
1967                 switch(pointcontents(view_origin))
1968                 {
1969                         case CONTENT_WATER:
1970                                 liquidalpha = autocvar_hud_contents_water_alpha;
1971                                 liquidcolor = stov(autocvar_hud_contents_water_color);
1972                                 incontent = 1;
1973                                 break;
1974
1975                         case CONTENT_LAVA:
1976                                 liquidalpha = autocvar_hud_contents_lava_alpha;
1977                                 liquidcolor = stov(autocvar_hud_contents_lava_color);
1978                                 incontent = 1;
1979                                 break;
1980
1981                         case CONTENT_SLIME:
1982                                 liquidalpha = autocvar_hud_contents_slime_alpha;
1983                                 liquidcolor = stov(autocvar_hud_contents_slime_color);
1984                                 incontent = 1;
1985                                 break;
1986
1987                         default:
1988                                 liquidalpha = 0;
1989                                 liquidcolor = '0 0 0';
1990                                 incontent = 0;
1991                                 break;
1992                 }
1993
1994                 if(incontent) // fade in/out at different speeds so you can do e.g. instant fade when entering water and slow when leaving it.
1995                 { // also lets delcare previous values for blending properties, this way it isn't reset until after you have entered a different content
1996                         contentfadetime = autocvar_hud_contents_fadeintime;
1997                         liquidalpha_prev = liquidalpha;
1998                         liquidcolor_prev = liquidcolor;
1999                 }
2000                 else
2001                         contentfadetime = autocvar_hud_contents_fadeouttime;
2002
2003                 contentalpha_temp = bound(0, drawframetime / max(0.0001, contentfadetime), 1);
2004                 contentavgalpha = contentavgalpha * (1 - contentalpha_temp) + incontent * contentalpha_temp;
2005
2006                 if(contentavgalpha)
2007                         drawfill('0 0 0', eX * vid_conwidth + eY * vid_conheight, liquidcolor_prev, contentavgalpha * liquidalpha_prev, DRAWFLAG_NORMAL);
2008
2009                 if(autocvar_hud_postprocessing)
2010                 {
2011                         if(autocvar_hud_contents_blur && contentavgalpha)
2012                         {
2013                                 content_blurpostprocess.x = 1;
2014                                 content_blurpostprocess.y = contentavgalpha * autocvar_hud_contents_blur;
2015                                 content_blurpostprocess.z = contentavgalpha * autocvar_hud_contents_blur_alpha;
2016                         }
2017                         else
2018                         {
2019                                 content_blurpostprocess.x = 0;
2020                                 content_blurpostprocess.y = 0;
2021                                 content_blurpostprocess.z = 0;
2022                         }
2023                 }
2024         }
2025
2026         if(autocvar_hud_damage && !STAT(FROZEN))
2027         {
2028                 splash_size.x = max(vid_conwidth, vid_conheight);
2029                 splash_size.y = max(vid_conwidth, vid_conheight);
2030                 splash_pos.x = (vid_conwidth - splash_size.x) / 2;
2031                 splash_pos.y = (vid_conheight - splash_size.y) / 2;
2032
2033                 float myhealth_flash_temp;
2034                 myhealth = STAT(HEALTH);
2035
2036                 // fade out
2037                 myhealth_flash = max(0, myhealth_flash - autocvar_hud_damage_fade_rate * frametime);
2038                 // add new damage
2039                 myhealth_flash = bound(0, myhealth_flash + dmg_take * autocvar_hud_damage_factor, autocvar_hud_damage_maxalpha);
2040
2041                 float pain_threshold, pain_threshold_lower, pain_threshold_lower_health;
2042                 pain_threshold = autocvar_hud_damage_pain_threshold;
2043                 pain_threshold_lower = autocvar_hud_damage_pain_threshold_lower;
2044                 pain_threshold_lower_health = autocvar_hud_damage_pain_threshold_lower_health;
2045
2046                 if(pain_threshold_lower && myhealth < pain_threshold_lower_health)
2047                 {
2048                         pain_threshold = pain_threshold - max(autocvar_hud_damage_pain_threshold_pulsating_min, fabs(sin(M_PI * time / autocvar_hud_damage_pain_threshold_pulsating_period))) * pain_threshold_lower * (1 - max(0, myhealth)/pain_threshold_lower_health);
2049                 }
2050
2051                 myhealth_flash_temp = bound(0, myhealth_flash - pain_threshold, 1);
2052
2053                 if(myhealth_prev < 1)
2054                 {
2055                         if(myhealth >= 1)
2056                         {
2057                                 myhealth_flash = 0; // just spawned, clear the flash immediately
2058                                 myhealth_flash_temp = 0;
2059                         }
2060                         else
2061                         {
2062                                 myhealth_flash += autocvar_hud_damage_fade_rate * frametime; // dead
2063                         }
2064                 }
2065
2066                 if(spectatee_status == -1 || intermission)
2067                 {
2068                         myhealth_flash = 0; // observing, or match ended
2069                         myhealth_flash_temp = 0;
2070                 }
2071
2072                 myhealth_prev = myhealth;
2073
2074                 // IDEA: change damage color/picture based on player model for robot/alien species?
2075                 // pro: matches model better
2076                 // contra: it's not red because blood is red, but because red is an alarming color, so red should stay
2077                 // maybe different reddish pics?
2078                 if(autocvar_cl_gentle_damage || autocvar_cl_gentle)
2079                 {
2080                         if(autocvar_cl_gentle_damage == 2)
2081                         {
2082                                 if(myhealth_flash < pain_threshold) // only randomize when the flash is gone
2083                                         myhealth_gentlergb = eX * random() + eY * random() + eZ * random();
2084                         }
2085                         else
2086                                 myhealth_gentlergb = stov(autocvar_hud_damage_gentle_color);
2087
2088                         if(myhealth_flash_temp > 0)
2089                                 drawfill('0 0 0', eX * vid_conwidth + eY * vid_conheight, myhealth_gentlergb, autocvar_hud_damage_gentle_alpha_multiplier * bound(0, myhealth_flash_temp, 1) * autocvar_hud_damage, DRAWFLAG_NORMAL);
2090                 }
2091                 else if(myhealth_flash_temp > 0)
2092                         drawpic(splash_pos, "gfx/blood", splash_size, stov(autocvar_hud_damage_color), bound(0, myhealth_flash_temp, 1) * autocvar_hud_damage, DRAWFLAG_NORMAL);
2093
2094                 if(autocvar_hud_postprocessing) // we still need to set this anyway even when chase_active is set, this way it doesn't get stuck on.
2095                 {
2096                         if(autocvar_hud_damage_blur && myhealth_flash_temp)
2097                         {
2098                                 damage_blurpostprocess.x = 1;
2099                                 damage_blurpostprocess.y = bound(0, myhealth_flash_temp, 1) * autocvar_hud_damage_blur;
2100                                 damage_blurpostprocess.z = bound(0, myhealth_flash_temp, 1) * autocvar_hud_damage_blur_alpha;
2101                         }
2102                         else
2103                         {
2104                                 damage_blurpostprocess.x = 0;
2105                                 damage_blurpostprocess.y = 0;
2106                                 damage_blurpostprocess.z = 0;
2107                         }
2108                 }
2109         }
2110
2111         float e1 = (autocvar_hud_postprocessing_maxbluralpha != 0);
2112         float e2 = (autocvar_hud_powerup != 0);
2113         if(autocvar_hud_postprocessing && (e1 || e2)) // TODO: Remove this code and re-do the postprocess handling in the engine, where it properly belongs.
2114         {
2115                 // enable or disable rendering types if they are used or not
2116                 if(cvar("r_glsl_postprocess_uservec1_enable") != e1) { cvar_set("r_glsl_postprocess_uservec1_enable", ftos(e1)); }
2117                 if(cvar("r_glsl_postprocess_uservec2_enable") != e2) { cvar_set("r_glsl_postprocess_uservec2_enable", ftos(e2)); }
2118
2119                 // blur postprocess handling done first (used by hud_damage and hud_contents)
2120                 if((damage_blurpostprocess.x || content_blurpostprocess.x))
2121                 {
2122                         float blurradius = bound(0, damage_blurpostprocess.y + content_blurpostprocess.y, autocvar_hud_postprocessing_maxblurradius);
2123                         float bluralpha = bound(0, damage_blurpostprocess.z + content_blurpostprocess.z, autocvar_hud_postprocessing_maxbluralpha);
2124                         if(blurradius != old_blurradius || bluralpha != old_bluralpha) // reduce cvar_set spam as much as possible
2125                         {
2126                                 cvar_set("r_glsl_postprocess_uservec1", strcat(ftos(blurradius), " ", ftos(bluralpha), " 0 0"));
2127                                 old_blurradius = blurradius;
2128                                 old_bluralpha = bluralpha;
2129                         }
2130                 }
2131                 else if(cvar_string("r_glsl_postprocess_uservec1") != "0 0 0 0") // reduce cvar_set spam as much as possible
2132                 {
2133                         cvar_set("r_glsl_postprocess_uservec1", "0 0 0 0");
2134                         old_blurradius = 0;
2135                         old_bluralpha = 0;
2136                 }
2137
2138                 // edge detection postprocess handling done second (used by hud_powerup)
2139                 float sharpen_intensity = 0, strength_finished = STAT(STRENGTH_FINISHED), invincible_finished = STAT(INVINCIBLE_FINISHED);
2140                 if (strength_finished - time > 0) { sharpen_intensity += (strength_finished - time); }
2141                 if (invincible_finished - time > 0) { sharpen_intensity += (invincible_finished - time); }
2142
2143                 sharpen_intensity = bound(0, ((STAT(HEALTH) > 0) ? sharpen_intensity : 0), 5); // Check to see if player is alive (if not, set 0) - also bound to fade out starting at 5 seconds.
2144
2145                 if(autocvar_hud_powerup && sharpen_intensity > 0)
2146                 {
2147                         if(sharpen_intensity != old_sharpen_intensity) // reduce cvar_set spam as much as possible
2148                         {
2149                                 cvar_set("r_glsl_postprocess_uservec2", strcat(ftos((sharpen_intensity / 5) * autocvar_hud_powerup), " ", ftos(-sharpen_intensity * autocvar_hud_powerup), " 0 0"));
2150                                 old_sharpen_intensity = sharpen_intensity;
2151                         }
2152                 }
2153                 else if(cvar_string("r_glsl_postprocess_uservec2") != "0 0 0 0") // reduce cvar_set spam as much as possible
2154                 {
2155                         cvar_set("r_glsl_postprocess_uservec2", "0 0 0 0");
2156                         old_sharpen_intensity = 0;
2157                 }
2158
2159                 if(cvar("r_glsl_postprocess") == 0)
2160                         cvar_set("r_glsl_postprocess", "2");
2161         }
2162         else if(cvar("r_glsl_postprocess") == 2)
2163                 cvar_set("r_glsl_postprocess", "0");
2164
2165         /*if(gametype == MAPINFO_TYPE_CTF)
2166           {
2167           ctf_view();
2168           } else */
2169
2170         // draw 2D entities
2171         FOREACH_ENTITY(it.draw2d, LAMBDA(it.draw2d(it)));
2172         Draw_ShowNames_All();
2173         Debug_Draw();
2174
2175         scoreboard_active = HUD_WouldDrawScoreboard();
2176
2177         HUD_Draw();
2178
2179         if(NextFrameCommand)
2180         {
2181                 localcmd("\n", NextFrameCommand, "\n");
2182                 NextFrameCommand = string_null;
2183         }
2184
2185         // we must do this check AFTER a frame was rendered, or it won't work
2186         if(cs_project_is_b0rked == 0)
2187         {
2188                 string w0, h0;
2189                 w0 = ftos(autocvar_vid_conwidth);
2190                 h0 = ftos(autocvar_vid_conheight);
2191                 //setproperty(VF_VIEWPORT, '0 0 0', '640 480 0');
2192                 //setproperty(VF_FOV, '90 90 0');
2193                 setproperty(VF_ORIGIN, '0 0 0');
2194                 setproperty(VF_ANGLES, '0 0 0');
2195                 setproperty(VF_PERSPECTIVE, 1);
2196                 makevectors('0 0 0');
2197                 vector v1, v2;
2198                 cvar_set("vid_conwidth", "800");
2199                 cvar_set("vid_conheight", "600");
2200                 v1 = cs_project(v_forward);
2201                 cvar_set("vid_conwidth", "640");
2202                 cvar_set("vid_conheight", "480");
2203                 v2 = cs_project(v_forward);
2204                 if(v1 == v2)
2205                         cs_project_is_b0rked = 1;
2206                 else
2207                         cs_project_is_b0rked = -1;
2208                 cvar_set("vid_conwidth", w0);
2209                 cvar_set("vid_conheight", h0);
2210         }
2211
2212         if(autocvar__hud_configure)
2213                 HUD_Panel_Mouse();
2214         else if ( HUD_MinigameMenu_IsOpened() || minigame_isactive() )
2215                 HUD_Minigame_Mouse();
2216         else if(QuickMenu_IsOpened())
2217                 QuickMenu_Mouse();
2218         else
2219                 HUD_Radar_Mouse();
2220
2221         cl_notice_run();
2222         unpause_update();
2223         Net_Flush();
2224
2225         // let's reset the view back to normal for the end
2226         setproperty(VF_MIN, '0 0 0');
2227         setproperty(VF_SIZE, '1 0 0' * w + '0 1 0' * h);
2228 }
2229
2230
2231 // following vectors must be global to allow seamless switching between camera modes
2232 vector camera_offset, current_camera_offset, mouse_angles, current_angles, current_origin, current_position;
2233 void CSQC_Demo_Camera()
2234 {
2235         float speed, attenuation, dimensions;
2236         vector tmp, delta;
2237
2238         if( autocvar_camera_reset || !camera_mode )
2239         {
2240                 camera_offset = '0 0 0';
2241                 current_angles = '0 0 0';
2242                 camera_direction = '0 0 0';
2243                 camera_offset.z += 30;
2244                 camera_offset.x += 30 * -cos(current_angles.y * DEG2RAD);
2245                 camera_offset.y += 30 * -sin(current_angles.y * DEG2RAD);
2246                 current_origin = view_origin;
2247                 current_camera_offset  = camera_offset;
2248                 cvar_set("camera_reset", "0");
2249                 camera_mode = CAMERA_CHASE;
2250         }
2251
2252         // Camera angles
2253         if( camera_roll )
2254                 mouse_angles.z += camera_roll * autocvar_camera_speed_roll;
2255
2256         if(autocvar_camera_look_player)
2257         {
2258                 vector dir;
2259                 float n;
2260
2261                 dir = normalize(view_origin - current_position);
2262                 n = mouse_angles.z;
2263                 mouse_angles = vectoangles(dir);
2264                 mouse_angles.x = mouse_angles.x * -1;
2265                 mouse_angles.z = n;
2266         }
2267         else
2268         {
2269                 tmp = getmousepos() * 0.1;
2270                 if(vdist(tmp, >, autocvar_camera_mouse_threshold))
2271                 {
2272                         mouse_angles.x += tmp.y * cos(mouse_angles.z * DEG2RAD) + (tmp.x * sin(mouse_angles.z * DEG2RAD));
2273                         mouse_angles.y -= tmp.x * cos(mouse_angles.z * DEG2RAD) + (tmp.y * -sin(mouse_angles.z * DEG2RAD));
2274                 }
2275         }
2276
2277         while (mouse_angles.x < -180) mouse_angles.x = mouse_angles.x + 360;
2278         while (mouse_angles.x > 180) mouse_angles.x = mouse_angles.x - 360;
2279         while (mouse_angles.y < -180) mouse_angles.y = mouse_angles.y + 360;
2280         while (mouse_angles.y > 180) mouse_angles.y = mouse_angles.y - 360;
2281
2282         // Fix difference when angles don't have the same sign
2283         delta = '0 0 0';
2284         if(mouse_angles.y < -60 && current_angles.y > 60)
2285                 delta = '0 360 0';
2286         if(mouse_angles.y > 60 && current_angles.y < -60)
2287                 delta = '0 -360 0';
2288
2289         if(autocvar_camera_look_player)
2290                 attenuation = autocvar_camera_look_attenuation;
2291         else
2292                 attenuation = autocvar_camera_speed_attenuation;
2293
2294         attenuation = 1 / max(1, attenuation);
2295         current_angles += (mouse_angles - current_angles + delta) * attenuation;
2296
2297         while (current_angles.x < -180) current_angles.x = current_angles.x + 360;
2298         while (current_angles.x > 180) current_angles.x = current_angles.x - 360;
2299         while (current_angles.y < -180) current_angles.y = current_angles.y + 360;
2300         while (current_angles.y > 180) current_angles.y = current_angles.y - 360;
2301
2302         // Camera position
2303         tmp = '0 0 0';
2304         dimensions = 0;
2305
2306         if( camera_direction.x )
2307         {
2308                 tmp.x = camera_direction.x * cos(current_angles.y * DEG2RAD);
2309                 tmp.y = camera_direction.x * sin(current_angles.y * DEG2RAD);
2310                 if( autocvar_camera_forward_follows && !autocvar_camera_look_player )
2311                         tmp.z = camera_direction.x * -sin(current_angles.x * DEG2RAD);
2312                 ++dimensions;
2313         }
2314
2315         if( camera_direction.y )
2316         {
2317                 tmp.x += camera_direction.y * -sin(current_angles.y * DEG2RAD);
2318                 tmp.y += camera_direction.y * cos(current_angles.y * DEG2RAD) * cos(current_angles.z * DEG2RAD);
2319                 tmp.z += camera_direction.y * sin(current_angles.z * DEG2RAD);
2320                 ++dimensions;
2321         }
2322
2323         if( camera_direction.z )
2324         {
2325                 tmp.z += camera_direction.z * cos(current_angles.z * DEG2RAD);
2326                 ++dimensions;
2327         }
2328
2329         if(autocvar_camera_free)
2330                 speed = autocvar_camera_speed_free;
2331         else
2332                 speed = autocvar_camera_speed_chase;
2333
2334         if(dimensions)
2335         {
2336                 speed = speed * sqrt(1 / dimensions);
2337                 camera_offset += tmp * speed;
2338         }
2339
2340         current_camera_offset += (camera_offset - current_camera_offset) * attenuation;
2341
2342         // Camera modes
2343         if( autocvar_camera_free )
2344         {
2345                 if ( camera_mode == CAMERA_CHASE )
2346                 {
2347                         current_camera_offset = current_origin + current_camera_offset;
2348                         camera_offset = current_origin + camera_offset;
2349                 }
2350
2351                 camera_mode = CAMERA_FREE;
2352                 current_position = current_camera_offset;
2353         }
2354         else
2355         {
2356                 if ( camera_mode == CAMERA_FREE )
2357                 {
2358                         current_origin = view_origin;
2359                         camera_offset = camera_offset - current_origin;
2360                         current_camera_offset = current_camera_offset - current_origin;
2361                 }
2362
2363                 camera_mode = CAMERA_CHASE;
2364
2365                 if(autocvar_camera_chase_smoothly)
2366                         current_origin += (view_origin - current_origin) * attenuation;
2367                 else
2368                         current_origin = view_origin;
2369
2370                 current_position = current_origin + current_camera_offset;
2371         }
2372
2373         setproperty(VF_ANGLES, current_angles);
2374         setproperty(VF_ORIGIN, current_position);
2375 }